source: libcfa/src/iostream.hfa

Last change on this file was c0363be, checked in by Peter A. Buhr <pabuhr@…>, 5 weeks ago

formatting

  • Property mode set to 100644
File size: 22.4 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// iostream.hfa --
8//
9// Author           : Peter A. Buhr
10// Created On       : Wed May 27 17:56:53 2015
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sun Apr 21 07:32:19 2024
13// Update Count     : 744
14//
15
16#pragma once
17
18#include "iterator.hfa"
19#include "Exception.hfa"
20
21// *********************************** ostream ***********************************
22
23forall( ostype & )
24trait basic_ostream {
25        // private
26        bool sepPrt$( ostype & );                                                       // get separator state (on/off)
27        void sepReset$( ostype & );                                                     // set separator state to default state
28        void sepReset$( ostype &, bool );                                       // set separator and default state
29        const char * sepGetCur$( ostype & );                            // get current separator string
30        void sepSetCur$( ostype &, const char [] );                     // set current separator string
31        bool getNL$( ostype & );                                                        // get newline
32        bool setNL$( ostype &, bool );                                          // set newline
33        bool getANL$( ostype & );                                                       // get auto newline (on/off)
34        bool setANL$( ostype &, bool );                                         // set auto newline (on/off), and return previous state
35        bool getPrt$( ostype & );                                                       // get fmt called in output cascade
36        bool setPrt$( ostype &, bool );                                         // set fmt called in output cascade
37        // public
38        void nlOn( ostype & );                                                          // turn auto-newline state on
39        void nlOff( ostype & );                                                         // turn auto-newline state off
40
41        void sep( ostype & );                                                           // turn separator state on
42        void nosep( ostype & );                                                         // turn separator state off
43        bool sepOn( ostype & );                                                         // set default state to on, and return previous state
44        bool sepOff( ostype & );                                                        // set default state to off, and return previous state
45        const char * sepGet( ostype & );                                        // get separator string
46        void sepSet( ostype &, const char [] );                         // set separator to string (15 character maximum)
47        const char * sepGetTuple( ostype & );                           // get tuple separator string
48        void sepSetTuple( ostype &, const char [] );            // set tuple separator to string (15 character maximum)
49
50        void ends( ostype & );                                                          // end of output statement
51        int fmt( ostype &, const char format[], ... ) __attribute__(( format(printf, 2, 3) ));
52}; // basic_ostream
53
54forall( ostype & | basic_ostream( ostype ) )
55trait ostream {
56        bool fail( ostype & );                                                          // operation failed?
57        void clear( ostype & );
58        int flush( ostype & );
59        void open( ostype &, const char name[], const char mode[] );
60        void close( ostype & );
61        ostype & write( ostype &, const char [], size_t );
62}; // ostream
63
64// forall( T )
65// trait writeable {
66//      forall( ostype & | ostream( ostype ) ) ostype & ?|?( ostype &, T );
67// }; // writeable
68
69forall( T, ostype & | ostream( ostype ) )
70trait writeable {
71        ostype & ?|?( ostype &, T );
72}; // writeable
73
74// implement writable for intrinsic types
75
76#define OSTYPE_VOID( T ) void ?|?( ostype &, T )
77#define OSTYPE_VOID_IMPL( T ) \
78        void ?|?( ostype & os, T t ) { \
79                (ostype &)(os | t); ends( os ); \
80        } // ?|?
81
82forall( ostype & | basic_ostream( ostype ) ) {
83        ostype & ?|?( ostype &, bool );
84        OSTYPE_VOID( bool );
85
86        ostype & ?|?( ostype &, char );
87        OSTYPE_VOID( char );
88        ostype & ?|?( ostype &, signed char );
89        OSTYPE_VOID( signed char );
90        ostype & ?|?( ostype &, unsigned char );
91        OSTYPE_VOID( unsigned char );
92
93        ostype & ?|?( ostype &, short int );
94        OSTYPE_VOID( short int );
95        ostype & ?|?( ostype &, unsigned short int );
96        OSTYPE_VOID( unsigned short int );
97        ostype & ?|?( ostype &, int );
98        OSTYPE_VOID( int );
99        ostype & ?|?( ostype &, unsigned int );
100        OSTYPE_VOID( unsigned int );
101        ostype & ?|?( ostype &, long int );
102        OSTYPE_VOID( long int );
103        ostype & ?|?( ostype &, long long int );
104        OSTYPE_VOID( long long int );
105        ostype & ?|?( ostype &, unsigned long int );
106        OSTYPE_VOID( unsigned long int );
107        ostype & ?|?( ostype &, unsigned long long int );
108        OSTYPE_VOID( unsigned long long int );
109        #if defined( __SIZEOF_INT128__ )
110        ostype & ?|?( ostype &, int128 );
111        OSTYPE_VOID( int128 );
112        ostype & ?|?( ostype &, unsigned int128 );
113        OSTYPE_VOID( unsigned int128 );
114        #endif // __SIZEOF_INT128__
115
116        ostype & ?|?( ostype &, float );
117        OSTYPE_VOID( float );
118        ostype & ?|?( ostype &, double );
119        OSTYPE_VOID( double );
120        ostype & ?|?( ostype &, long double );
121        OSTYPE_VOID( long double );
122
123        ostype & ?|?( ostype &, float _Complex );
124        OSTYPE_VOID( float _Complex );
125        ostype & ?|?( ostype &, double _Complex );
126        OSTYPE_VOID( double _Complex );
127        ostype & ?|?( ostype &, long double _Complex );
128        OSTYPE_VOID( long double _Complex );
129
130        ostype & ?|?( ostype &, const char [] );
131        OSTYPE_VOID( const char [] );
132        // ostype & ?|?( ostype &, const char16_t [] );
133        #if ! ( __ARM_ARCH_ISA_ARM == 1 && __ARM_32BIT_STATE == 1 ) // char32_t == wchar_t => ambiguous
134        // ostype & ?|?( ostype &, const char32_t [] );
135        #endif // ! ( __ARM_ARCH_ISA_ARM == 1 && __ARM_32BIT_STATE == 1 )
136        // ostype & ?|?( ostype &, const wchar_t [] );
137        ostype & ?|?( ostype &, const void * );
138        OSTYPE_VOID( const void * );
139
140        // FIX-ME: does not work so using macros
141        // forall( T | { ostype & ?|?( ostype &, T ); } )
142        // void ?|?( ostype & os, T );
143
144        // manipulators
145        ostype & ?|?( ostype &, ostype & (*)( ostype & ) );
146        OSTYPE_VOID( ostype & (*)( ostype & ) );
147
148        ostype & nl( ostype & );
149        ostype & nonl( ostype & );
150        ostype & nlOn( ostype & );
151        ostype & nlOff( ostype & );
152
153        ostype & sepVal( ostype & );
154        ostype & sepTupleVal( ostype & );
155        ostype & sep( ostype & );
156        ostype & nosep( ostype & );
157        ostype & sepOn( ostype & );
158        ostype & sepOff( ostype & );
159} // distribution
160
161// tuples
162forall( ostype &, T, List ... | writeable( T, ostype ) | { ostype & ?|?( ostype &, List ); } ) {
163        ostype & ?|?( ostype & os, T arg, List rest );
164        void ?|?( ostype & os, T arg, List rest );
165} // distribution
166
167// writes the range [begin, end) to the given stream
168forall( ostype &, elt_type | writeable( elt_type, ostype ), iterator_type | iterator( iterator_type, elt_type ) ) {
169        void write( iterator_type begin, iterator_type end, ostype & os );
170        void write_reverse( iterator_type begin, iterator_type end, ostype & os );
171} // distribution
172
173// *********************************** manipulators ***********************************
174
175struct _Ostream_Flags {
176        unsigned char eng:1;                                                            // engineering notation
177        unsigned char neg:1;                                                            // val is negative
178        unsigned char pc:1;                                                                     // precision specified
179        unsigned char left:1;                                                           // left justify
180        unsigned char nobsdp:1;                                                         // base prefix / decimal point
181        unsigned char sign:1;                                                           // plus / minus sign
182        unsigned char pad0:1;                                                           // zero pad
183};
184
185forall( T )
186struct _Ostream_Manip {
187        T val;                                                                                          // polymorphic base-type
188        int wd, pc;                                                                                     // width, precision: signed for computations
189        char base;                                                                                      // numeric base / floating-point style
190        union {
191                unsigned char all;
192                _Ostream_Flags flags;
193        };
194}; // _Ostream_Manip
195
196// *********************************** integral ***********************************
197
198#define INTEGRAL_FMT_DECL( T, CODE ) \
199static inline { \
200        _Ostream_Manip(T) bin( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'b', { .all : 0 } }; } \
201        _Ostream_Manip(T) oct( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'o', { .all : 0 } }; } \
202        _Ostream_Manip(T) hex( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'x', { .all : 0 } }; } \
203        _Ostream_Manip(T) wd( unsigned int wd, T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : wd, .pc : 0, .base : CODE, { .all : 0 } }; } \
204        _Ostream_Manip(T) wd( unsigned int wd, unsigned int pc, T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : wd, .pc : pc, .base : CODE, { .flags.pc : true } }; } \
205        _Ostream_Manip(T) & wd( unsigned int wd, _Ostream_Manip(T) & fmt ) { fmt.wd = wd; return fmt; } \
206        _Ostream_Manip(T) & wd( unsigned int wd, unsigned int pc, _Ostream_Manip(T) & fmt ) { fmt.wd = wd; fmt.pc = pc; fmt.flags.pc = true; return fmt; } \
207        _Ostream_Manip(T) & left( _Ostream_Manip(T) & fmt ) { fmt.flags.left = true; return fmt; } \
208        _Ostream_Manip(T) & upcase( _Ostream_Manip(T) & fmt ) { if ( fmt.base == 'x' || fmt.base == 'b' ) fmt.base -= 32; /* upper case */ return fmt; } \
209        _Ostream_Manip(T) & nobase( _Ostream_Manip(T) & fmt ) { fmt.flags.nobsdp = true; return fmt; } \
210        _Ostream_Manip(T) & pad0( _Ostream_Manip(T) & fmt ) { fmt.flags.pad0 = true; return fmt; } \
211        _Ostream_Manip(T) sign( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : CODE, { .flags.sign : true } }; } \
212        _Ostream_Manip(T) & sign( _Ostream_Manip(T) & fmt ) { fmt.flags.sign = true; return fmt; } \
213} /* distribution */ \
214forall( ostype & | basic_ostream( ostype ) ) { \
215        ostype & ?|?( ostype & os, _Ostream_Manip(T) f ); \
216        OSTYPE_VOID( _Ostream_Manip(T) ); \
217} // ?|?
218
219INTEGRAL_FMT_DECL( signed char, 'd' )
220INTEGRAL_FMT_DECL( unsigned char, 'u' )
221INTEGRAL_FMT_DECL( signed short int, 'd' )
222INTEGRAL_FMT_DECL( unsigned short int, 'u' )
223INTEGRAL_FMT_DECL( signed int, 'd' )
224INTEGRAL_FMT_DECL( unsigned int, 'u' )
225INTEGRAL_FMT_DECL( signed long int, 'd' )
226INTEGRAL_FMT_DECL( unsigned long int, 'u' )
227INTEGRAL_FMT_DECL( signed long long int, 'd' )
228INTEGRAL_FMT_DECL( unsigned long long int, 'u' )
229#if defined( __SIZEOF_INT128__ )
230INTEGRAL_FMT_DECL( int128, 'd' )
231INTEGRAL_FMT_DECL( unsigned int128, 'u' )
232#endif // __SIZEOF_INT128__
233
234// *********************************** floating point ***********************************
235
236// Default suffix for values with no fraction is "."
237#define FLOATING_POINT_FMT_DECL( T ) \
238static inline { \
239        _Ostream_Manip(T) hex( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'a', { .all : 0 } }; } \
240        _Ostream_Manip(T) sci( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'e', { .all : 0 } }; } \
241        _Ostream_Manip(T) eng( T val ) { return (_Ostream_Manip(T))@{ .val : val, 1, -1, .base : 'g', { .flags.eng : true } }; } \
242        _Ostream_Manip(T) wd( unsigned int wd, T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : wd, .pc : 0, .base : 'g', { .all : 0 } }; } \
243        _Ostream_Manip(T) wd( unsigned int wd, unsigned int pc, T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : wd, .pc : pc, .base : 'f', { .flags.pc : true } }; } \
244        _Ostream_Manip(T) ws( unsigned int wd, unsigned int pc, T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : wd, .pc : pc, .base : 'g', { .flags.pc : true } }; } \
245        _Ostream_Manip(T) & wd( unsigned int wd, _Ostream_Manip(T) & fmt ) { if ( fmt.flags.eng ) fmt.base = 'f'; fmt.wd = wd; return fmt; } \
246        _Ostream_Manip(T) & wd( unsigned int wd, unsigned int pc, _Ostream_Manip(T) & fmt ) { \
247                if ( fmt.flags.eng ) fmt.base = 'f'; fmt.wd = wd; fmt.pc = pc; fmt.flags.pc = true; return fmt; } \
248        _Ostream_Manip(T) & ws( unsigned int wd, unsigned int pc, _Ostream_Manip(T) & fmt ) { fmt.wd = wd; fmt.pc = pc; fmt.flags.pc = true; return fmt; } \
249        _Ostream_Manip(T) & left( _Ostream_Manip(T) & fmt ) { fmt.flags.left = true; return fmt; } \
250        _Ostream_Manip(T) upcase( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'G', { .all : 0 } }; } \
251        _Ostream_Manip(T) & upcase( _Ostream_Manip(T) & fmt ) { fmt.base -= 32; /* upper case */ return fmt; } \
252        _Ostream_Manip(T) & pad0( _Ostream_Manip(T) & fmt ) { fmt.flags.pad0 = true; return fmt; } \
253        _Ostream_Manip(T) sign( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'g', { .flags.sign : true } }; } \
254        _Ostream_Manip(T) & sign( _Ostream_Manip(T) & fmt ) { fmt.flags.sign = true; return fmt; } \
255        _Ostream_Manip(T) nodp( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'g', { .flags.nobsdp : true } }; } \
256        _Ostream_Manip(T) & nodp( _Ostream_Manip(T) & fmt ) { fmt.flags.nobsdp = true; return fmt; } \
257        _Ostream_Manip(T) unit( T val ) { return (_Ostream_Manip(T))@{ .val : val, .wd : 1, .pc : 0, .base : 'g', { .flags.nobsdp : true } }; } \
258        _Ostream_Manip(T) & unit( _Ostream_Manip(T) & fmt ) { fmt.flags.nobsdp = true; return fmt; } \
259} /* distribution */ \
260forall( ostype & | basic_ostream( ostype ) ) { \
261        ostype & ?|?( ostype & os, _Ostream_Manip(T) f ); \
262        OSTYPE_VOID( _Ostream_Manip(T) ); \
263} // ?|?
264
265FLOATING_POINT_FMT_DECL( double )
266FLOATING_POINT_FMT_DECL( long double )
267
268// *********************************** character ***********************************
269
270static inline {
271        _Ostream_Manip(char) bin( char c ) { return (_Ostream_Manip(char))@{ .val : c, .wd : 1, .pc : 0, .base : 'b', { .all : 0 } }; }
272        _Ostream_Manip(char) oct( char c ) { return (_Ostream_Manip(char))@{ .val : c, .wd : 1, .pc : 0, .base : 'o', { .all : 0 } }; }
273        _Ostream_Manip(char) hex( char c ) { return (_Ostream_Manip(char))@{ .val : c, .wd : 1, .pc : 0, .base : 'x', { .all : 0 } }; }
274        _Ostream_Manip(char) wd( unsigned int wd, char c ) { return (_Ostream_Manip(char))@{ c, wd, 0, .base : 'c', { .all : 0 } }; }
275        _Ostream_Manip(char) & wd( unsigned int wd, _Ostream_Manip(char) & fmt ) { fmt.wd = wd; return fmt; }
276        _Ostream_Manip(char) & left( _Ostream_Manip(char) & fmt ) { fmt.flags.left = true; return fmt; }
277        _Ostream_Manip(char) & upcase( _Ostream_Manip(char) & fmt ) { if ( fmt.base == 'x' || fmt.base == 'b' ) fmt.base -= 32; /* upper case */ return fmt; }
278        _Ostream_Manip(char) & nobase( _Ostream_Manip(char) & fmt ) { fmt.flags.nobsdp = true; return fmt; }
279} // distribution
280forall( ostype & | basic_ostream( ostype ) ) {
281        ostype & ?|?( ostype & os, _Ostream_Manip(char) f );
282        OSTYPE_VOID( _Ostream_Manip(char) ); \
283} // ?|?
284
285// *********************************** C string ***********************************
286
287static inline {
288        _Ostream_Manip(const char *) bin( const char s[] ) { return (_Ostream_Manip(const char *))@{ .val : s, .wd : 1, .pc : 0, .base : 'b', { .all : 0 } }; }
289        _Ostream_Manip(const char *) oct( const char s[] ) { return (_Ostream_Manip(const char *))@{ .val : s, .wd : 1, .pc : 0, .base : 'o', { .all : 0 } }; }
290        _Ostream_Manip(const char *) hex( const char s[] ) { return (_Ostream_Manip(const char *))@{ .val : s, .wd : 1, .pc : 0, .base : 'x', { .all : 0 } }; }
291        _Ostream_Manip(const char *) wd( unsigned int wd, const char s[] ) { return (_Ostream_Manip(const char *))@{ s, wd, 0, .base : 's', { .all : 0 } }; }
292        _Ostream_Manip(const char *) wd( unsigned int wd, unsigned int pc, const char s[] ) { return (_Ostream_Manip(const char *))@{ s, .wd : wd, .pc : pc, .base : 's', { .flags.pc : true } }; }
293        _Ostream_Manip(const char *) & wd( unsigned int wd, _Ostream_Manip(const char *) & fmt ) { fmt.wd = wd; return fmt; }
294        _Ostream_Manip(const char *) & wd( unsigned int wd, unsigned int pc, _Ostream_Manip(const char *) & fmt ) { fmt.wd = wd; fmt.pc = pc; fmt.flags.pc = true; return fmt; }
295        _Ostream_Manip(const char *) & left( _Ostream_Manip(const char *) & fmt ) { fmt.flags.left = true; return fmt; }
296        _Ostream_Manip(const char *) & nobase( _Ostream_Manip(const char *) & fmt ) { fmt.flags.nobsdp = true; return fmt; }
297} // distribution
298forall( ostype & | basic_ostream( ostype ) ) {
299        ostype & ?|?( ostype & os, _Ostream_Manip(const char *) f );
300        OSTYPE_VOID( _Ostream_Manip(const char *) ); \
301} // ?|?
302
303// *********************************** istream ***********************************
304
305forall( istype & )
306trait basic_istream {
307        // private
308        bool getANL$( istype & );                                                       // get scan newline (on/off)
309        bool setANL$( istype &, bool );                                         // set scan newline (on/off)
310        // public
311        void nlOn( istype & );                                                          // read newline
312        void nlOff( istype & );                                                         // scan newline
313        int fmt( istype &, const char format[], ... ) __attribute__(( format(scanf, 2, 3) ));
314        istype & ungetc( istype &, char );
315        bool eof( istype & );
316        void clear( istype & );
317}; // basic_istream
318
319forall( istype & | basic_istream( istype ) )
320trait istream {
321        bool fail( istype & );
322        void open( istype & is, const char name[], const char mode[] );
323        void open( istype & is, const char name[] );
324        void close( istype & is );
325        istype & read( istype &, char [], size_t );
326}; // istream
327
328forall( T )
329trait readable {
330        forall( istype & | istream( istype ) ) istype & ?|?( istype &, T );
331}; // readable
332
333forall( istype & | basic_istream( istype ) ) {
334        istype & ?|?( istype &, bool & );
335
336        istype & ?|?( istype &, char & );
337        istype & ?|?( istype &, signed char & );
338        istype & ?|?( istype &, unsigned char & );
339
340        istype & ?|?( istype &, short int & );
341        istype & ?|?( istype &, unsigned short int & );
342        istype & ?|?( istype &, int & );
343        istype & ?|?( istype &, unsigned int & );
344        istype & ?|?( istype &, long int & );
345        istype & ?|?( istype &, unsigned long int & );
346        istype & ?|?( istype &, long long int & );
347        istype & ?|?( istype &, unsigned long long int & );
348        #if defined( __SIZEOF_INT128__ )
349        istype & ?|?( istype &, int128 & );
350        istype & ?|?( istype &, unsigned int128 & );
351        #endif // __SIZEOF_INT128__
352
353        istype & ?|?( istype &, float & );
354        istype & ?|?( istype &, double & );
355        istype & ?|?( istype &, long double & );
356
357        istype & ?|?( istype &, float _Complex & );
358        istype & ?|?( istype &, double _Complex & );
359        istype & ?|?( istype &, long double _Complex & );
360
361        istype & ?|?( istype &, const char [] );
362
363        // manipulators
364        istype & ?|?( istype &, istype & (*)( istype & ) );
365        istype & nl( istype & is );
366        istype & nlOn( istype & );
367        istype & nlOff( istype & );
368} // distribution
369
370// *********************************** exceptions ***********************************
371
372ExceptionDecl( missing_data );                                                  // read finds no appropriate data
373ExceptionDecl( cstring_length );                                                // character string size exceeded
374ExceptionDecl( data_range );                                                    // value too large for numerical type
375
376// *********************************** manipulators ***********************************
377
378// skip does not compose with other C string manipulators.
379struct _Istream_Cskip {
380        const char * scanset;
381        unsigned wd;                                                                            // scan width
382}; // _Istream_Cskip
383
384static inline {
385        _Istream_Cskip skip( const char scanset[] ) { return (_Istream_Cskip)@{ .scanset : scanset, .wd : 0 }; }
386        _Istream_Cskip skip( unsigned int wd ) { return (_Istream_Cskip)@{ .scanset : 0p, .wd : wd }; }
387} // distribution
388
389struct _Istream_str_base {
390        union {
391                const char * scanset;
392                char delimiters[3];                                                             // [0] => left, [1] => right
393        };
394        int wd;                                                                                         // width
395        union {
396                unsigned char all;
397                struct {
398                        unsigned char ignore:1;                                         // do not change input argument
399                        unsigned char inex:1;                                           // include/exclude characters in scanset
400                        unsigned char delimiter:1;                                      // delimit character(s)
401                        unsigned char rwd:1;                                            // read width
402                } flags;
403        };
404}; // _Istream_str_base
405
406struct _Istream_Cwidth {
407        char * s;
408        inline _Istream_str_base;
409}; // _Istream_Cwidth
410
411// Restrict nesting of input manipulators to those combinations that make sense.
412
413struct _Istream_Cquoted {
414        _Istream_Cwidth cstr;
415}; // _Istream_Cquoted
416
417struct _Istream_Cstr {
418        _Istream_Cwidth cstr;
419}; // _Istream_Cstr
420
421static inline {
422        // width must include room for null terminator, (gcc) scanf does not allow a 0 width => wd > 1 (1 char and null) and rd > 0 (1 char);
423        _Istream_Cwidth wdi( unsigned int wd, char s[] ) {
424                if ( wd <= 1 ) throwResume ExceptionInst( cstring_length ); // minimum 1 character and null terminator
425                return (_Istream_Cwidth)@{ .s : s, { {.scanset : 0p}, .wd : wd, {.all : 0} } };
426        }
427        _Istream_Cwidth wdi( unsigned int wd, unsigned int rwd, char s[] ) {
428                if ( wd <= 1 || wd <= rwd ) throwResume ExceptionInst( cstring_length ); // minimum 1 character, null terminator, plus subset
429                return (_Istream_Cwidth)@{ .s : s, { {.scanset : 0p}, .wd : rwd, {.flags.rwd : true} } };
430        }
431        _Istream_Cstr & getline( _Istream_Cwidth & f, const char delimiter = '\n' ) {
432                f.delimiters[0] = delimiter; f.delimiters[1] = '\0'; f.flags.delimiter = true; return (_Istream_Cstr &)f;
433        }
434        _Istream_Cquoted quoted( char & ch, const char Ldelimiter = '\'', const char Rdelimiter = '\0' ) {
435                return (_Istream_Cquoted)@{ { .s : &ch, { {.delimiters : { Ldelimiter, Rdelimiter, '\1' }}, .wd : 1, {.flags.rwd : true} } } };
436        }
437        _Istream_Cquoted & quoted( _Istream_Cwidth & f, const char Ldelimiter = '"', const char Rdelimiter = '\0' ) {
438                f.delimiters[0] = Ldelimiter;  f.delimiters[1] = Rdelimiter;  f.delimiters[2] = '\0';
439                return (_Istream_Cquoted &)f;
440        }
441        _Istream_Cstr & incl( const char scanset[], _Istream_Cwidth & f ) { f.scanset = scanset; f.flags.inex = false; return (_Istream_Cstr &)f; }
442        _Istream_Cstr & excl( const char scanset[], _Istream_Cwidth & f ) { f.scanset = scanset; f.flags.inex = true; return (_Istream_Cstr &)f; }
443        _Istream_Cstr ignore( const char s[] ) { return (_Istream_Cstr)@{ { .s : (char *)s, { {.scanset : 0p}, .wd : -1, {.flags.ignore : true} } } }; }
444        _Istream_Cstr & ignore( _Istream_Cwidth & f ) { f.flags.ignore = true; return (_Istream_Cstr &)f; }
445        _Istream_Cquoted & ignore( _Istream_Cquoted & f ) { f.cstr.flags.ignore = true; return (_Istream_Cquoted &)f; }
446        _Istream_Cstr & ignore( _Istream_Cstr & f ) { f.cstr.flags.ignore = true; return (_Istream_Cstr &)f; }
447} // distribution
448
449forall( istype & | basic_istream( istype ) ) {
450        istype & ?|?( istype & is, _Istream_Cskip f );
451        istype & ?|?( istype & is, _Istream_Cquoted f );
452        istype & ?|?( istype & is, _Istream_Cstr f );
453        static inline istype & ?|?( istype & is, _Istream_Cwidth f ) { return is | *(_Istream_Cstr *)&f; }
454} // distribution
455
456forall( T & | sized( T ) )
457struct _Istream_Manip {
458        T & val;                                                                                        // polymorphic base-type
459        int wd;                                                                                         // width
460        bool ignore;                                                                            // do not change input argument
461}; // _Istream_Manip
462
463#define INPUT_FMT_DECL( T ) \
464static inline { \
465        _Istream_Manip(T) wdi( unsigned int wd, T & val ) { return (_Istream_Manip(T))@{ .val : val, .wd : wd, .ignore : false }; } \
466        _Istream_Manip(T) ignore( const T & val ) { return (_Istream_Manip(T))@{ .val : (T &)val, .wd : -1, .ignore : true }; } \
467        _Istream_Manip(T) & ignore( _Istream_Manip(T) & fmt ) { fmt.ignore = true; return fmt; } \
468} /* distribution */ \
469forall( istype & | basic_istream( istype ) ) { \
470        istype & ?|?( istype & is, _Istream_Manip(T) f ); \
471} // ?|?
472
473INPUT_FMT_DECL( char )
474INPUT_FMT_DECL( signed char )
475INPUT_FMT_DECL( unsigned char )
476INPUT_FMT_DECL( signed short int )
477INPUT_FMT_DECL( unsigned short int )
478INPUT_FMT_DECL( signed int )
479INPUT_FMT_DECL( unsigned int )
480INPUT_FMT_DECL( signed long int )
481INPUT_FMT_DECL( unsigned long int )
482INPUT_FMT_DECL( signed long long int )
483INPUT_FMT_DECL( unsigned long long int )
484
485INPUT_FMT_DECL( float )
486INPUT_FMT_DECL( double )
487INPUT_FMT_DECL( long double )
488
489INPUT_FMT_DECL( float _Complex )
490INPUT_FMT_DECL( double _Complex )
491INPUT_FMT_DECL( long double _Complex )
492
493// *********************************** time ***********************************
494
495#include <time_t.hfa>                                                                   // Duration (constructors) / Time (constructors)
496
497forall( ostype & | ostream( ostype ) ) {
498        ostype & ?|?( ostype & os, Duration dur );
499        OSTYPE_VOID( Duration );
500        ostype & ?|?( ostype & os, Time time );
501        OSTYPE_VOID( Time );
502} // distribution
503
504// Local Variables: //
505// tab-width: 4 //
506// End: //
Note: See TracBrowser for help on using the repository browser.