source: libcfa/src/concurrency/ready_queue.cfa@ ff79d5e

//
// Cforall Version 1.0.0 Copyright (C) 2019 University of Waterloo
//
// The contents of this file are covered under the licence agreement in the
// file "LICENCE" distributed with Cforall.
//
// ready_queue.cfa --
//
// Author           : Thierry Delisle
// Created On       : Mon Nov dd 16:29:18 2019
// Last Modified By :
// Last Modified On :
// Update Count     :
//

#define __cforall_thread__
// #define __CFA_DEBUG_PRINT_READY_QUEUE__

#include "bits/defs.hfa"
#include "kernel_private.hfa"

#define _GNU_SOURCE
#include "stdlib.hfa"
#include "math.hfa"

static const size_t cache_line_size = 64;

// No overriden function, no environment variable, no define
// fall back to a magic number
#ifndef __CFA_MAX_PROCESSORS__
        #define __CFA_MAX_PROCESSORS__ 1024
#endif

// returns the maximum number of processors the RWLock support
__attribute__((weak)) unsigned __max_processors() {
        const char * max_cores_s = getenv("CFA_MAX_PROCESSORS");
        if(!max_cores_s) {
                __cfadbg_print_nolock(ready_queue, "No CFA_MAX_PROCESSORS in ENV\n");
                return __CFA_MAX_PROCESSORS__;
        }

        char * endptr = 0p;
        long int max_cores_l = strtol(max_cores_s, &endptr, 10);
        if(max_cores_l < 1 || max_cores_l > 65535) {
                __cfadbg_print_nolock(ready_queue, "CFA_MAX_PROCESSORS out of range : %ld\n", max_cores_l);
                return __CFA_MAX_PROCESSORS__;
        }
        if('\0' != *endptr) {
                __cfadbg_print_nolock(ready_queue, "CFA_MAX_PROCESSORS not a decimal number : %s\n", max_cores_s);
                return __CFA_MAX_PROCESSORS__;
        }

        return max_cores_l;
}

//=======================================================================
// Cluster wide reader-writer lock
//=======================================================================
void  ?{}(__scheduler_RWLock_t & this) {
        this.max   = __max_processors();
        this.alloc = 0;
        this.ready = 0;
        this.lock  = false;
        this.data  = alloc(this.max);

        /*paranoid*/ verify( 0 == (((uintptr_t)(this.data    )) % 64) );
        /*paranoid*/ verify( 0 == (((uintptr_t)(this.data + 1)) % 64) );
        /*paranoid*/ verify(__atomic_is_lock_free(sizeof(this.alloc), &this.alloc));
        /*paranoid*/ verify(__atomic_is_lock_free(sizeof(this.ready), &this.ready));

}
void ^?{}(__scheduler_RWLock_t & this) {
        free(this.data);
}

void ?{}( __scheduler_lock_id_t & this, __processor_id_t * proc ) {
        this.handle = proc;
        this.lock   = false;
}

//=======================================================================
// Lock-Free registering/unregistering of threads
unsigned doregister( struct __processor_id_t * proc ) with(*__scheduler_lock) {
        __cfadbg_print_safe(ready_queue, "Kernel : Registering proc %p for RW-Lock\n", proc);

        // Step - 1 : check if there is already space in the data
        uint_fast32_t s = ready;

        // Check among all the ready
        for(uint_fast32_t i = 0; i < s; i++) {
                __processor_id_t * null = 0p; // Re-write every loop since compare thrashes it
                if( __atomic_load_n(&data[i].handle, (int)__ATOMIC_RELAXED) == null
                        && __atomic_compare_exchange_n( &data[i].handle, &null, proc, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST)) {
                        /*paranoid*/ verify(i < ready);
                        /*paranoid*/ verify(__alignof__(data[i]) == cache_line_size);
                        /*paranoid*/ verify((((uintptr_t)&data[i]) % cache_line_size) == 0);
                        return i;
                }
        }

        if(max <= alloc) abort("Trying to create more than %ud processors", __scheduler_lock->max);

        // Step - 2 : F&A to get a new spot in the array.
        uint_fast32_t n = __atomic_fetch_add(&alloc, 1, __ATOMIC_SEQ_CST);
        if(max <= n) abort("Trying to create more than %ud processors", __scheduler_lock->max);

        // Step - 3 : Mark space as used and then publish it.
        __scheduler_lock_id_t * storage = (__scheduler_lock_id_t *)&data[n];
        (*storage){ proc };
        while(true) {
                unsigned copy = n;
                if( __atomic_load_n(&ready, __ATOMIC_RELAXED) == n
                        && __atomic_compare_exchange_n(&ready, &copy, n + 1, true, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST))
                        break;
                asm volatile("pause");
        }

        __cfadbg_print_safe(ready_queue, "Kernel : Registering proc %p done, id %lu\n", proc, n);

        // Return new spot.
        /*paranoid*/ verify(n < ready);
        /*paranoid*/ verify(__alignof__(data[n]) == cache_line_size);
        /*paranoid*/ verify((((uintptr_t)&data[n]) % cache_line_size) == 0);
        return n;
}

void unregister( struct __processor_id_t * proc ) with(*__scheduler_lock) {
        unsigned id = proc->id;
        /*paranoid*/ verify(id < ready);
        /*paranoid*/ verify(proc == __atomic_load_n(&data[id].handle, __ATOMIC_RELAXED));
        __atomic_store_n(&data[id].handle, 0p, __ATOMIC_RELEASE);

        __cfadbg_print_safe(ready_queue, "Kernel : Unregister proc %p\n", proc);
}

//-----------------------------------------------------------------------
// Writer side : acquire when changing the ready queue, e.g. adding more
//  queues or removing them.
uint_fast32_t ready_mutate_lock( void ) with(*__scheduler_lock) {
        // Step 1 : lock global lock
        // It is needed to avoid processors that register mid Critical-Section
        //   to simply lock their own lock and enter.
        __atomic_acquire( &lock );

        // Step 2 : lock per-proc lock
        // Processors that are currently being registered aren't counted
        //   but can't be in read_lock or in the critical section.
        // All other processors are counted
        uint_fast32_t s = ready;
        for(uint_fast32_t i = 0; i < s; i++) {
                __atomic_acquire( &data[i].lock );
        }

        return s;
}

void ready_mutate_unlock( uint_fast32_t last_s ) with(*__scheduler_lock) {
        // Step 1 : release local locks
        // This must be done while the global lock is held to avoid
        //   threads that where created mid critical section
        //   to race to lock their local locks and have the writer
        //   immidiately unlock them
        // Alternative solution : return s in write_lock and pass it to write_unlock
        for(uint_fast32_t i = 0; i < last_s; i++) {
                verify(data[i].lock);
                __atomic_store_n(&data[i].lock, (bool)false, __ATOMIC_RELEASE);
        }

        // Step 2 : release global lock
        /*paranoid*/ assert(true == lock);
        __atomic_store_n(&lock, (bool)false, __ATOMIC_RELEASE);
}

//=======================================================================
// Intrusive Queue used by ready queue
//=======================================================================
// Intrusives lanes which are used by the relaxed ready queue
struct __attribute__((aligned(128))) __intrusive_lane_t {
        // spin lock protecting the queue
        volatile bool lock;

        // anchor for the head and the tail of the queue
        struct __sentinel_t {
                // Link lists fields
                // instrusive link field for threads
                // must be exactly as in $thread
                __thread_desc_link link;
        } before, after;

        // Optional statistic counters
        #if !defined(__CFA_NO_SCHED_STATS__)
                struct __attribute__((aligned(64))) {
                        // difference between number of push and pops
                        ssize_t diff;

                        // total number of pushes and pops
                        size_t  push;
                        size_t  pop ;
                } stat;
        #endif
};

void  ?{}(__intrusive_lane_t & this);
void ^?{}(__intrusive_lane_t & this);

// Get the head pointer (one before the first element) from the anchor
static inline $thread * head(const __intrusive_lane_t & this) {
        $thread * rhead = ($thread *)(
                (uintptr_t)( &this.before ) - offsetof( $thread, link )
        );
        /* paranoid */ verify(rhead);
        return rhead;
}

// Get the tail pointer (one after the last element) from the anchor
static inline $thread * tail(const __intrusive_lane_t & this) {
        $thread * rtail = ($thread *)(
                (uintptr_t)( &this.after ) - offsetof( $thread, link )
        );
        /* paranoid */ verify(rtail);
        return rtail;
}

// Ctor
void ?{}( __intrusive_lane_t & this ) {
        this.lock = false;

        this.before.link.prev = 0p;
        this.before.link.next = tail(this);
        this.before.link.ts   = 0;

        this.after .link.prev = head(this);
        this.after .link.next = 0p;
        this.after .link.ts   = 0;

        #if !defined(__CFA_NO_SCHED_STATS__)
                this.stat.diff = 0;
                this.stat.push = 0;
                this.stat.pop  = 0;
        #endif

        // We add a boat-load of assertions here because the anchor code is very fragile
        /* paranoid */ verify(((uintptr_t)( head(this) ) + offsetof( $thread, link )) == (uintptr_t)(&this.before));
        /* paranoid */ verify(((uintptr_t)( tail(this) ) + offsetof( $thread, link )) == (uintptr_t)(&this.after ));
        /* paranoid */ verify(head(this)->link.prev == 0p );
        /* paranoid */ verify(head(this)->link.next == tail(this) );
        /* paranoid */ verify(tail(this)->link.next == 0p );
        /* paranoid */ verify(tail(this)->link.prev == head(this) );
        /* paranoid */ verify(&head(this)->link.prev == &this.before.link.prev );
        /* paranoid */ verify(&head(this)->link.next == &this.before.link.next );
        /* paranoid */ verify(&tail(this)->link.prev == &this.after .link.prev );
        /* paranoid */ verify(&tail(this)->link.next == &this.after .link.next );
        /* paranoid */ verify(sizeof(__intrusive_lane_t) == 128);
        /* paranoid */ verify(sizeof(this) == 128);
        /* paranoid */ verify(__alignof__(__intrusive_lane_t) == 128);
        /* paranoid */ verify(__alignof__(this) == 128);
        /* paranoid */ verifyf(((intptr_t)(&this) % 128) == 0, "Expected address to be aligned %p %% 128 == %zd", &this, ((intptr_t)(&this) % 128));
}

// Dtor is trivial
void ^?{}( __intrusive_lane_t & this ) {
        // Make sure the list is empty
        /* paranoid */ verify(head(this)->link.prev == 0p );
        /* paranoid */ verify(head(this)->link.next == tail(this) );
        /* paranoid */ verify(tail(this)->link.next == 0p );
        /* paranoid */ verify(tail(this)->link.prev == head(this) );
}

// Push a thread onto this lane
// returns true of lane was empty before push, false otherwise
bool push(__intrusive_lane_t & this, $thread * node) {
        #if defined(__CFA_WITH_VERIFY__)
                /* paranoid */ verify(this.lock);
                /* paranoid */ verify(node->link.ts != 0);
                /* paranoid */ verify(node->link.next == 0p);
                /* paranoid */ verify(node->link.prev == 0p);
                /* paranoid */ verify(tail(this)->link.next == 0p);
                /* paranoid */ verify(head(this)->link.prev == 0p);

                if(this.before.link.ts == 0l) {
                        /* paranoid */ verify(tail(this)->link.prev == head(this));
                        /* paranoid */ verify(head(this)->link.next == tail(this));
                } else {
                        /* paranoid */ verify(tail(this)->link.prev != head(this));
                        /* paranoid */ verify(head(this)->link.next != tail(this));
                }
        #endif

        // Get the relevant nodes locally
        $thread * tail = tail(this);
        $thread * prev = tail->link.prev;

        // Do the push
        node->link.next = tail;
        node->link.prev = prev;
        prev->link.next = node;
        tail->link.prev = node;

        // Update stats
        #if !defined(__CFA_NO_SCHED_STATS__)
                this.stat.diff++;
                this.stat.push++;
        #endif

        verify(node->link.next == tail(this));

        // Check if the queue used to be empty
        if(this.before.link.ts == 0l) {
                this.before.link.ts = node->link.ts;
                /* paranoid */ verify(node->link.prev == head(this));
                return true;
        }
        return false;
}

// Pop a thread from this lane (must be non-empty)
// returns popped
// returns true of lane was empty before push, false otherwise
[$thread *, bool] pop(__intrusive_lane_t & this) {
        /* paranoid */ verify(this.lock);
        /* paranoid */ verify(this.before.link.ts != 0ul);

        // Get anchors locally
        $thread * head = head(this);
        $thread * tail = tail(this);

        // Get the relevant nodes locally
        $thread * node = head->link.next;
        $thread * next = node->link.next;

        /* paranoid */ verify(node != tail);
        /* paranoid */ verify(node);

        // Do the pop
        head->link.next = next;
        next->link.prev = head;
        node->link.[next, prev] = 0p;

        // Update head time stamp
        this.before.link.ts = next->link.ts;

        // Update stats
        #ifndef __CFA_NO_SCHED_STATS__
                this.stat.diff--;
                this.stat.pop ++;
        #endif

        // Check if we emptied list and return accordingly
        /* paranoid */ verify(tail(this)->link.next == 0p);
        /* paranoid */ verify(head(this)->link.prev == 0p);
        if(next == tail) {
                /* paranoid */ verify(this.before.link.ts == 0);
                /* paranoid */ verify(tail(this)->link.prev == head(this));
                /* paranoid */ verify(head(this)->link.next == tail(this));
                return [node, true];
        }
        else {
                /* paranoid */ verify(next->link.ts != 0);
                /* paranoid */ verify(tail(this)->link.prev != head(this));
                /* paranoid */ verify(head(this)->link.next != tail(this));
                /* paranoid */ verify(this.before.link.ts != 0);
                return [node, false];
        }
}

// Check whether or not list is empty
static inline bool is_empty(__intrusive_lane_t & this) {
        // Cannot verify here since it may not be locked
        return this.before.link.ts == 0;
}

// Return the timestamp
static inline unsigned long long ts(__intrusive_lane_t & this) {
        // Cannot verify here since it may not be locked
        return this.before.link.ts;
}

//=======================================================================
// Scalable Non-Zero counter
//=======================================================================

union __snzi_val_t {
        uint64_t _all;
        struct __attribute__((packed)) {
                char cnt;
                uint64_t ver:56;
        };
};

bool cas(volatile __snzi_val_t & self, __snzi_val_t & exp, char _cnt, uint64_t _ver) {
        __snzi_val_t t;
        t.ver = _ver;
        t.cnt = _cnt;
        /* paranoid */ verify(t._all == ((_ver << 8) | ((unsigned char)_cnt)));
        return __atomic_compare_exchange_n(&self._all, &exp._all, t._all, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST);
}

bool cas(volatile __snzi_val_t & self, __snzi_val_t & exp, const __snzi_val_t & tar) {
        return __atomic_compare_exchange_n(&self._all, &exp._all, tar._all, false, __ATOMIC_SEQ_CST, __ATOMIC_SEQ_CST);
}

void ?{}( __snzi_val_t & this ) { this._all = 0; }
void ?{}( __snzi_val_t & this, const volatile __snzi_val_t & o) { this._all = o._all; }

struct __attribute__((aligned(128))) __snzi_node_t {
        volatile __snzi_val_t value;
        struct __snzi_node_t * parent;
        bool is_root;
};

static inline void arrive( __snzi_node_t & );
static inline void depart( __snzi_node_t & );

#define __snzi_half -1

//--------------------------------------------------
// Root node
static void arrive_r( __snzi_node_t & this ) {
        /* paranoid */ verify( this.is_root );
        __atomic_fetch_add(&this.value._all, 1, __ATOMIC_SEQ_CST);
}

static void depart_r( __snzi_node_t & this ) {
        /* paranoid */ verify( this.is_root );
        __atomic_fetch_sub(&this.value._all, 1, __ATOMIC_SEQ_CST);
}

//--------------------------------------------------
// Hierarchical node
static void arrive_h( __snzi_node_t & this ) {
        int undoArr = 0;
        bool success = false;
        while(!success) {
                __snzi_val_t x = { this.value };
                /* paranoid */ verify(x.cnt <= 120);
                if( x.cnt >= 1 ) {
                        if( cas( this.value, x, x.cnt + 1, x.ver ) ) {
                                success = true;
                        }
                }
                /* paranoid */ verify(x.cnt <= 120);
                if( x.cnt == 0 ) {
                        if( cas( this.value, x, __snzi_half, x.ver + 1) ) {
                                success = true;
                                x.cnt = __snzi_half;
                                x.ver = x.ver + 1;
                        }
                }
                /* paranoid */ verify(x.cnt <= 120);
                if( x.cnt == __snzi_half ) {
                        /* paranoid */ verify( this.parent);
                        arrive( *this.parent );
                        if( !cas( this.value, x, 1, x.ver) ) {
                                undoArr = undoArr + 1;
                        }
                }
        }

        for(int i = 0; i < undoArr; i++) {
                /* paranoid */ verify( this.parent );
                depart( *this.parent );
        }
}

static void depart_h( __snzi_node_t & this ) {
        while(true) {
                const __snzi_val_t x = { this.value };
                /* paranoid */ verifyf(x.cnt >= 1, "%d", x.cnt);
                if( cas( this.value, x, x.cnt - 1, x.ver ) ) {
                        if( x.cnt == 1 ) {
                                /* paranoid */ verify( this.parent );
                                depart( *this.parent );
                        }
                        return;
                }
        }
}

//--------------------------------------------------
// All nodes
static inline void arrive( __snzi_node_t & this ) {
        if(this.is_root) arrive_r( this );
        else arrive_h( this );
}

static inline void depart( __snzi_node_t & this ) {
        if(this.is_root) depart_r( this );
        else depart_h( this );
}

static inline bool query( __snzi_node_t & this ) {
        /* paranoid */ verify( this.is_root );
        return this.value._all > 0;
}

//--------------------------------------------------
// SNZI object
void  ?{}( __snzi_t & this, unsigned depth ) with( this ) {
        mask = (1 << depth) - 1;
        root = (1 << (depth + 1)) - 2;
        nodes = alloc( root + 1 );

        int width = 1 << depth;
        for(int i = 0; i < root; i++) {
                nodes[i].value._all = 0;
                nodes[i].parent = &nodes[(i / 2) + width ];
                nodes[i].is_root = false;
        }

        nodes[ root ].value._all = 0;
        nodes[ root ].parent = 0p;
        nodes[ root ].is_root = true;
}

void ^?{}( __snzi_t & this ) {
        free( this.nodes );
}

static inline void arrive( __snzi_t & this, int idx) {
        idx &= this.mask;
        arrive( this.nodes[idx] );
}

static inline void depart( __snzi_t & this, int idx) {
        idx &= this.mask;
        depart( this.nodes[idx] );
}

static inline bool query( const __snzi_t & this ) {
        return query( this.nodes[ this.root ] );
}

//=======================================================================
// Cforall Reqdy Queue used by ready queue
//=======================================================================

// Thread local mirror of ready queue statistics
#if !defined(__CFA_NO_STATISTICS__)
static __attribute__((aligned(128))) thread_local struct {
        struct {
                struct {
                        size_t attempt;
                        size_t success;
                } push;
                struct {
                        size_t maskrds;
                        size_t attempt;
                        size_t success;
                } pop;
        } pick;
        struct {
                size_t value;
                size_t count;
        } used;
} tls = {
        /* pick */{
                /* push */{ 0, 0 },
                /* pop  */{ 0, 0, 0 },
        },
        /* used */{ 0, 0 }
};
#endif

//-----------------------------------------------------------------------

void ?{}(__ready_queue_t & this) with (this) {

        lanes.data = alloc(4);
        for( i; 4 ) {
                (lanes.data[i]){};
        }
        lanes.count = 4;
        snzi{ log2( lanes.count / 8 ) };

        #if !defined(__CFA_NO_STATISTICS__)
                global_stats.pick.push.attempt = 0;
                global_stats.pick.push.success = 0;
                global_stats.pick.pop .maskrds = 0;
                global_stats.pick.pop .attempt = 0;
                global_stats.pick.pop .success = 0;

                global_stats.used.value = 0;
                global_stats.used.count = 0;
        #endif
}

void ^?{}(__ready_queue_t & this) with (this) {
        verify( 4  == lanes.count );
        verify( !query( snzi ) );

        ^(snzi){};

        for( i; 4 ) {
                ^(lanes.data[i]){};
        }
        free(lanes.data);
}

//-----------------------------------------------------------------------
__attribute__((hot)) bool push(struct cluster * cltr, struct $thread * thrd) with (cltr->ready_queue) {
        __cfadbg_print_safe(ready_queue, "Kernel : Pushing %p on cluster %p\n", thrd, cltr);

        // write timestamp
        thrd->link.ts = rdtscl();

        // Try to pick a lane and lock it
        unsigned i;
        do {
                // Pick the index of a lane
                i = __tls_rand() % lanes.count;

                #if !defined(__CFA_NO_STATISTICS__)
                        tls.pick.push.attempt++;
                #endif

                // If we can't lock it retry
        } while( !__atomic_try_acquire( &lanes.data[i].lock ) );

        bool first = false;

        // Actually push it
        bool lane_first = push(lanes.data[i], thrd);

        // If this lane used to be empty we need to do more
        if(lane_first) {
                // Check if the entire queue used to be empty
                first = !query(snzi);

                // Update the snzi
                arrive( snzi, i );
        }

        // Unlock and return
        __atomic_unlock( &lanes.data[i].lock );

        __cfadbg_print_safe(ready_queue, "Kernel : Pushed %p on cluster %p (idx: %u, mask %llu, first %d)\n", thrd, cltr, i, used.mask[0], lane_first);

        // Update statistics
        #if !defined(__CFA_NO_STATISTICS__)
                tls.pick.push.success++;
        #endif

        // return whether or not the list was empty before this push
        return first;
}

//-----------------------------------------------------------------------
// Given 2 indexes, pick the list with the oldest push an try to pop from it
static struct $thread * try_pop(struct cluster * cltr, unsigned i, unsigned j) with (cltr->ready_queue) {
        #if !defined(__CFA_NO_STATISTICS__)
                tls.pick.pop.attempt++;
        #endif

        // Pick the bet list
        int w = i;
        if( __builtin_expect(!is_empty(lanes.data[j]), true) ) {
                w = (ts(lanes.data[i]) < ts(lanes.data[j])) ? i : j;
        }

        // Get relevant elements locally
        __intrusive_lane_t & lane = lanes.data[w];

        // If list looks empty retry
        if( is_empty(lane) ) return 0p;

        // If we can't get the lock retry
        if( !__atomic_try_acquire(&lane.lock) ) return 0p;


        // If list is empty, unlock and retry
        if( is_empty(lane) ) {
                __atomic_unlock(&lane.lock);
                return 0p;
        }

        // Actually pop the list
        struct $thread * thrd;
        bool emptied;
        [thrd, emptied] = pop(lane);

        /* paranoid */ verify(thrd);
        /* paranoid */ verify(lane.lock);

        // If this was the last element in the lane
        if(emptied) {
                depart( snzi, w );
        }

        // Unlock and return
        __atomic_unlock(&lane.lock);

        // Update statistics
        #if !defined(__CFA_NO_STATISTICS__)
                tls.pick.pop.success++;
        #endif

        // return the popped thread
        return thrd;
}

// Pop from the ready queue from a given cluster
__attribute__((hot)) $thread * pop(struct cluster * cltr) with (cltr->ready_queue) {
        /* paranoid */ verify( lanes.count > 0 );

        // As long as the list is not empty, try finding a lane that isn't empty and pop from it
        while( query(snzi) ) {
                // Pick two lists at random
                int i = __tls_rand() % __atomic_load_n( &lanes.count, __ATOMIC_RELAXED );
                int j = __tls_rand() % __atomic_load_n( &lanes.count, __ATOMIC_RELAXED );

                // try popping from the 2 picked lists
                struct $thread * thrd = try_pop(cltr, i, j);
                if(thrd) return thrd;
        }

        // All lanes where empty return 0p
        return 0p;
}

//-----------------------------------------------------------------------

static void check( __ready_queue_t & q ) with (q) {
        #if defined(__CFA_WITH_VERIFY__)
                {
                        for( idx ; lanes.count ) {
                                __intrusive_lane_t & sl = lanes.data[idx];
                                assert(!lanes.data[idx].lock);

                                assert(head(sl)->link.prev == 0p );
                                assert(head(sl)->link.next->link.prev == head(sl) );
                                assert(tail(sl)->link.next == 0p );
                                assert(tail(sl)->link.prev->link.next == tail(sl) );

                                if(sl.before.link.ts == 0l) {
                                        assert(tail(sl)->link.prev == head(sl));
                                        assert(head(sl)->link.next == tail(sl));
                                } else {
                                        assert(tail(sl)->link.prev != head(sl));
                                        assert(head(sl)->link.next != tail(sl));
                                }
                        }
                }
        #endif
}

// Call this function of the intrusive list was moved using memcpy
// fixes the list so that the pointers back to anchors aren't left dangling
static inline void fix(__intrusive_lane_t & ll) {
        // if the list is not empty then follow he pointer and fix its reverse
        if(!is_empty(ll)) {
                head(ll)->link.next->link.prev = head(ll);
                tail(ll)->link.prev->link.next = tail(ll);
        }
        // Otherwise just reset the list
        else {
                verify(tail(ll)->link.next == 0p);
                tail(ll)->link.prev = head(ll);
                head(ll)->link.next = tail(ll);
                verify(head(ll)->link.prev == 0p);
        }
}

// Grow the ready queue
void ready_queue_grow  (struct cluster * cltr) {
        // Lock the RWlock so no-one pushes/pops while we are changing the queue
        uint_fast32_t last_size = ready_mutate_lock();

        __cfadbg_print_safe(ready_queue, "Kernel : Growing ready queue\n");

        // Make sure that everything is consistent
        /* paranoid */ check( cltr->ready_queue );

        // grow the ready queue
        with( cltr->ready_queue ) {
                ^(snzi){};

                size_t ncount = lanes.count;

                // increase count
                ncount += 4;

                // Allocate new array (uses realloc and memcpies the data)
                lanes.data = alloc(lanes.data, ncount);

                // Fix the moved data
                for( idx; (size_t)lanes.count ) {
                        fix(lanes.data[idx]);
                }

                // Construct new data
                for( idx; (size_t)lanes.count ~ ncount) {
                        (lanes.data[idx]){};
                }

                // Update original
                lanes.count = ncount;

                // Re-create the snzi
                snzi{ log2( lanes.count / 8 ) };
                for( idx; (size_t)lanes.count ) {
                        if( !is_empty(lanes.data[idx]) ) {
                                arrive(snzi, idx);
                        }
                }
        }

        // Make sure that everything is consistent
        /* paranoid */ check( cltr->ready_queue );

        __cfadbg_print_safe(ready_queue, "Kernel : Growing ready queue done\n");

        // Unlock the RWlock
        ready_mutate_unlock( last_size );
}

// Shrink the ready queue
void ready_queue_shrink(struct cluster * cltr) {
        // Lock the RWlock so no-one pushes/pops while we are changing the queue
        uint_fast32_t last_size = ready_mutate_lock();

        __cfadbg_print_safe(ready_queue, "Kernel : Shrinking ready queue\n");

        // Make sure that everything is consistent
        /* paranoid */ check( cltr->ready_queue );

        with( cltr->ready_queue ) {
                ^(snzi){};

                size_t ocount = lanes.count;
                // Check that we have some space left
                if(ocount < 8) abort("Program attempted to destroy more Ready Queues than were created");

                // reduce the actual count so push doesn't use the old queues
                lanes.count -= 4;
                verify(ocount > lanes.count);

                // for printing count the number of displaced threads
                #if defined(__CFA_DEBUG_PRINT__) || defined(__CFA_DEBUG_PRINT_READY_QUEUE__)
                        __attribute__((unused)) size_t displaced = 0;
                #endif

                // redistribute old data
                for( idx; (size_t)lanes.count ~ ocount) {
                        // Lock is not strictly needed but makes checking invariants much easier
                        __attribute__((unused)) bool locked = __atomic_try_acquire(&lanes.data[idx].lock);
                        verify(locked);

                        // As long as we can pop from this lane to push the threads somewhere else in the queue
                        while(!is_empty(lanes.data[idx])) {
                                struct $thread * thrd;
                                __attribute__((unused)) bool _;
                                [thrd, _] = pop(lanes.data[idx]);

                                push(cltr, thrd);

                                // for printing count the number of displaced threads
                                #if defined(__CFA_DEBUG_PRINT__) || defined(__CFA_DEBUG_PRINT_READY_QUEUE__)
                                        displaced++;
                                #endif
                        }

                        // Unlock the lane
                        __atomic_unlock(&lanes.data[idx].lock);

                        // TODO print the queue statistics here

                        ^(lanes.data[idx]){};
                }

                __cfadbg_print_safe(ready_queue, "Kernel : Shrinking ready queue displaced %zu threads\n", displaced);

                // Allocate new array (uses realloc and memcpies the data)
                lanes.data = alloc(lanes.data, lanes.count);

                // Fix the moved data
                for( idx; (size_t)lanes.count ) {
                        fix(lanes.data[idx]);
                }

                // Re-create the snzi
                snzi{ log2( lanes.count / 8 ) };
                for( idx; (size_t)lanes.count ) {
                        if( !is_empty(lanes.data[idx]) ) {
                                arrive(snzi, idx);
                        }
                }
        }

        // Make sure that everything is consistent
        /* paranoid */ check( cltr->ready_queue );

        __cfadbg_print_safe(ready_queue, "Kernel : Shrinking ready queue done\n");

        // Unlock the RWlock
        ready_mutate_unlock( last_size );
}

//-----------------------------------------------------------------------

#if !defined(__CFA_NO_STATISTICS__)
void stats_tls_tally(struct cluster * cltr) with (cltr->ready_queue) {
        __atomic_fetch_add( &global_stats.pick.push.attempt, tls.pick.push.attempt, __ATOMIC_SEQ_CST );
        __atomic_fetch_add( &global_stats.pick.push.success, tls.pick.push.success, __ATOMIC_SEQ_CST );
        __atomic_fetch_add( &global_stats.pick.pop .maskrds, tls.pick.pop .maskrds, __ATOMIC_SEQ_CST );
        __atomic_fetch_add( &global_stats.pick.pop .attempt, tls.pick.pop .attempt, __ATOMIC_SEQ_CST );
        __atomic_fetch_add( &global_stats.pick.pop .success, tls.pick.pop .success, __ATOMIC_SEQ_CST );

        __atomic_fetch_add( &global_stats.used.value, tls.used.value, __ATOMIC_SEQ_CST );
        __atomic_fetch_add( &global_stats.used.count, tls.used.count, __ATOMIC_SEQ_CST );
}
#endif