source: libcfa/src/concurrency/io/setup.cfa @ ec19b21

arm-ehenumforall-pointer-decayjacob/cs343-translationnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since ec19b21 was ec19b21, checked in by Thierry Delisle <tdelisle@…>, 23 months ago

Fixed compile for older versions of io_uring

  • Property mode set to 100644
File size: 17.7 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2020 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// io/setup.cfa --
8//
9// Author           : Thierry Delisle
10// Created On       : Fri Jul 31 16:25:51 2020
11// Last Modified By :
12// Last Modified On :
13// Update Count     :
14//
15
16#define __cforall_thread__
17#define _GNU_SOURCE         /* See feature_test_macros(7) */
18
19#if defined(__CFA_DEBUG__)
20        // #define __CFA_DEBUG_PRINT_IO__
21        // #define __CFA_DEBUG_PRINT_IO_CORE__
22#endif
23
24#include "io/types.hfa"
25#include "kernel.hfa"
26
27#if !defined(CFA_HAVE_LINUX_IO_URING_H)
28        void __kernel_io_startup() {
29                // Nothing to do without io_uring
30        }
31
32        void __kernel_io_shutdown() {
33                // Nothing to do without io_uring
34        }
35
36        void ?{}(io_context_params & this) {}
37
38        void ?{}(io_context & this, struct cluster & cl) {}
39        void ?{}(io_context & this, struct cluster & cl, const io_context_params & params) {}
40
41        void ^?{}(io_context & this) {}
42        void ^?{}(io_context & this, bool cluster_context) {}
43
44#else
45        #include <errno.h>
46        #include <stdint.h>
47        #include <string.h>
48        #include <signal.h>
49        #include <unistd.h>
50
51        extern "C" {
52                #include <pthread.h>
53                #include <sys/epoll.h>
54                #include <sys/eventfd.h>
55                #include <sys/mman.h>
56                #include <sys/syscall.h>
57
58                #include <linux/io_uring.h>
59        }
60
61        #include "bitmanip.hfa"
62        #include "kernel_private.hfa"
63        #include "thread.hfa"
64
65        void ?{}(io_context_params & this) {
66                this.num_entries = 256;
67                this.num_ready = 256;
68                this.submit_aff = -1;
69                this.eager_submits = false;
70                this.poller_submits = false;
71                this.poll_submit = false;
72                this.poll_complete = false;
73        }
74
75        static void * __io_poller_slow( void * arg );
76
77        // Weirdly, some systems that do support io_uring don't actually define these
78        #ifdef __alpha__
79                /*
80                * alpha is the only exception, all other architectures
81                * have common numbers for new system calls.
82                */
83                #ifndef __NR_io_uring_setup
84                        #define __NR_io_uring_setup           535
85                #endif
86                #ifndef __NR_io_uring_enter
87                        #define __NR_io_uring_enter           536
88                #endif
89                #ifndef __NR_io_uring_register
90                        #define __NR_io_uring_register        537
91                #endif
92        #else /* !__alpha__ */
93                #ifndef __NR_io_uring_setup
94                        #define __NR_io_uring_setup           425
95                #endif
96                #ifndef __NR_io_uring_enter
97                        #define __NR_io_uring_enter           426
98                #endif
99                #ifndef __NR_io_uring_register
100                        #define __NR_io_uring_register        427
101                #endif
102        #endif
103
104//=============================================================================================
105// I/O Startup / Shutdown logic + Master Poller
106//=============================================================================================
107
108        // IO Master poller loop forward
109        static void * iopoll_loop( __attribute__((unused)) void * args );
110
111        static struct {
112                pthread_t     thrd;    // pthread handle to io poller thread
113                void *        stack;   // pthread stack for io poller thread
114                int           epollfd; // file descriptor to the epoll instance
115                volatile bool run;     // Whether or not to continue
116        } iopoll;
117
118        void __kernel_io_startup(void) {
119                __cfadbg_print_safe(io_core, "Kernel : Creating EPOLL instance\n" );
120
121                iopoll.epollfd = epoll_create1(0);
122                if (iopoll.epollfd == -1) {
123                        abort( "internal error, epoll_create1\n");
124                }
125
126                __cfadbg_print_safe(io_core, "Kernel : Starting io poller thread\n" );
127
128                iopoll.run = true;
129                iopoll.stack = __create_pthread( &iopoll.thrd, iopoll_loop, 0p );
130        }
131
132        void __kernel_io_shutdown(void) {
133                // Notify the io poller thread of the shutdown
134                iopoll.run = false;
135                sigval val = { 1 };
136                pthread_sigqueue( iopoll.thrd, SIGUSR1, val );
137
138                // Wait for the io poller thread to finish
139
140                __destroy_pthread( iopoll.thrd, iopoll.stack, 0p );
141
142                int ret = close(iopoll.epollfd);
143                if (ret == -1) {
144                        abort( "internal error, close epoll\n");
145                }
146
147                // Io polling is now fully stopped
148
149                __cfadbg_print_safe(io_core, "Kernel : IO poller stopped\n" );
150        }
151
152        static void * iopoll_loop( __attribute__((unused)) void * args ) {
153                __processor_id_t id;
154                id.full_proc = false;
155                id.id = doregister(&id);
156                __cfaabi_tls.this_proc_id = &id;
157                __cfadbg_print_safe(io_core, "Kernel : IO poller thread starting\n" );
158
159                // Block signals to control when they arrive
160                sigset_t mask;
161                sigfillset(&mask);
162                if ( pthread_sigmask( SIG_BLOCK, &mask, 0p ) == -1 ) {
163                abort( "internal error, pthread_sigmask" );
164                }
165
166                sigdelset( &mask, SIGUSR1 );
167
168                // Create sufficient events
169                struct epoll_event events[10];
170                // Main loop
171                while( iopoll.run ) {
172                        __cfadbg_print_safe(io_core, "Kernel I/O - epoll : waiting on io_uring contexts\n");
173
174                        // Wait for events
175                        int nfds = epoll_pwait( iopoll.epollfd, events, 10, -1, &mask );
176
177                        __cfadbg_print_safe(io_core, "Kernel I/O - epoll : %d io contexts events, waking up\n", nfds);
178
179                        // Check if an error occured
180                        if (nfds == -1) {
181                                if( errno == EINTR ) continue;
182                                abort( "internal error, pthread_sigmask" );
183                        }
184
185                        for(i; nfds) {
186                                $io_ctx_thread * io_ctx = ($io_ctx_thread *)(uintptr_t)events[i].data.u64;
187                                /* paranoid */ verify( io_ctx );
188                                __cfadbg_print_safe(io_core, "Kernel I/O - epoll : Unparking io poller %d (%p)\n", io_ctx->ring->fd, io_ctx);
189                                #if !defined( __CFA_NO_STATISTICS__ )
190                                        __cfaabi_tls.this_stats = io_ctx->self.curr_cluster->stats;
191                                #endif
192
193                                eventfd_t v;
194                                eventfd_read(io_ctx->ring->efd, &v);
195
196                                post( io_ctx->sem );
197                        }
198                }
199
200                __cfadbg_print_safe(io_core, "Kernel : IO poller thread stopping\n" );
201                unregister(&id);
202                return 0p;
203        }
204
205//=============================================================================================
206// I/O Context Constrution/Destruction
207//=============================================================================================
208
209        void ?{}($io_ctx_thread & this, struct cluster & cl) { (this.self){ "IO Poller", cl }; }
210        void main( $io_ctx_thread & this );
211        static inline $thread * get_thread( $io_ctx_thread & this ) { return &this.self; }
212        void ^?{}( $io_ctx_thread & mutex this ) {}
213
214        static void __io_create ( __io_data & this, const io_context_params & params_in );
215        static void __io_destroy( __io_data & this );
216
217        void ?{}(io_context & this, struct cluster & cl, const io_context_params & params) {
218                (this.thrd){ cl };
219                this.thrd.ring = malloc();
220                __cfadbg_print_safe(io_core, "Kernel I/O : Creating ring for io_context %p\n", &this);
221                __io_create( *this.thrd.ring, params );
222
223                __cfadbg_print_safe(io_core, "Kernel I/O : Starting poller thread for io_context %p\n", &this);
224                this.thrd.done = false;
225                __thrd_start( this.thrd, main );
226
227                __cfadbg_print_safe(io_core, "Kernel I/O : io_context %p ready\n", &this);
228        }
229
230        void ?{}(io_context & this, struct cluster & cl) {
231                io_context_params params;
232                (this){ cl, params };
233        }
234
235        void ^?{}(io_context & this, bool cluster_context) {
236                __cfadbg_print_safe(io_core, "Kernel I/O : tearing down io_context %p\n", &this);
237
238                // Notify the thread of the shutdown
239                __atomic_store_n(&this.thrd.done, true, __ATOMIC_SEQ_CST);
240
241                // If this is an io_context within a cluster, things get trickier
242                $thread & thrd = this.thrd.self;
243                if( cluster_context ) {
244                        // We are about to do weird things with the threads
245                        // we don't need interrupts to complicate everything
246                        disable_interrupts();
247
248                        // Get cluster info
249                        cluster & cltr = *thrd.curr_cluster;
250                        /* paranoid */ verify( cltr.idles.total == 0 || &cltr == mainCluster );
251                        /* paranoid */ verify( !ready_mutate_islocked() );
252
253                        // We need to adjust the clean-up based on where the thread is
254                        if( thrd.state == Ready || thrd.preempted != __NO_PREEMPTION ) {
255                                // This is the tricky case
256                                // The thread was preempted or ready to run and now it is on the ready queue
257                                // but the cluster is shutting down, so there aren't any processors to run the ready queue
258                                // the solution is to steal the thread from the ready-queue and pretend it was blocked all along
259
260                                ready_schedule_lock();
261                                        // The thread should on the list
262                                        /* paranoid */ verify( thrd.link.next != 0p );
263
264                                        // Remove the thread from the ready queue of this cluster
265                                        // The thread should be the last on the list
266                                        __attribute__((unused)) bool removed = remove_head( &cltr, &thrd );
267                                        /* paranoid */ verify( removed );
268                                        thrd.link.next = 0p;
269                                        thrd.link.prev = 0p;
270
271                                        // Fixup the thread state
272                                        thrd.state = Blocked;
273                                        thrd.ticket = TICKET_BLOCKED;
274                                        thrd.preempted = __NO_PREEMPTION;
275
276                                ready_schedule_unlock();
277
278                                // Pretend like the thread was blocked all along
279                        }
280                        // !!! This is not an else if !!!
281                        // Ok, now the thread is blocked (whether we cheated to get here or not)
282                        if( thrd.state == Blocked ) {
283                                // This is the "easy case"
284                                // The thread is parked and can easily be moved to active cluster
285                                verify( thrd.curr_cluster != active_cluster() || thrd.curr_cluster == mainCluster );
286                                thrd.curr_cluster = active_cluster();
287
288                                // unpark the fast io_poller
289                                unpark( &thrd );
290                        }
291                        else {
292                                // The thread is in a weird state
293                                // I don't know what to do here
294                                abort("io_context poller thread is in unexpected state, cannot clean-up correctly\n");
295                        }
296
297                        // The weird thread kidnapping stuff is over, restore interrupts.
298                        enable_interrupts( __cfaabi_dbg_ctx );
299                } else {
300                        post( this.thrd.sem );
301                }
302
303                ^(this.thrd){};
304                __cfadbg_print_safe(io_core, "Kernel I/O : Stopped poller thread for io_context %p\n", &this);
305
306                __io_destroy( *this.thrd.ring );
307                __cfadbg_print_safe(io_core, "Kernel I/O : Destroyed ring for io_context %p\n", &this);
308
309                free(this.thrd.ring);
310        }
311
312        void ^?{}(io_context & this) {
313                ^(this){ false };
314        }
315
316        static void __io_create( __io_data & this, const io_context_params & params_in ) {
317                // Step 1 : call to setup
318                struct io_uring_params params;
319                memset(&params, 0, sizeof(params));
320                if( params_in.poll_submit   ) params.flags |= IORING_SETUP_SQPOLL;
321                if( params_in.poll_complete ) params.flags |= IORING_SETUP_IOPOLL;
322
323                __u32 nentries = params_in.num_entries != 0 ? params_in.num_entries : 256;
324                if( !is_pow2(nentries) ) {
325                        abort("ERROR: I/O setup 'num_entries' must be a power of 2\n");
326                }
327                if( params_in.poller_submits && params_in.eager_submits ) {
328                        abort("ERROR: I/O setup 'poller_submits' and 'eager_submits' cannot be used together\n");
329                }
330
331                int fd = syscall(__NR_io_uring_setup, nentries, &params );
332                if(fd < 0) {
333                        abort("KERNEL ERROR: IO_URING SETUP - %s\n", strerror(errno));
334                }
335
336                // Step 2 : mmap result
337                memset( &this, 0, sizeof(struct __io_data) );
338                struct __submition_data  & sq = this.submit_q;
339                struct __completion_data & cq = this.completion_q;
340
341                // calculate the right ring size
342                sq.ring_sz = params.sq_off.array + (params.sq_entries * sizeof(unsigned)           );
343                cq.ring_sz = params.cq_off.cqes  + (params.cq_entries * sizeof(struct io_uring_cqe));
344
345                // Requires features
346                #if defined(IORING_FEAT_SINGLE_MMAP)
347                        // adjust the size according to the parameters
348                        if ((params.features & IORING_FEAT_SINGLE_MMAP) != 0) {
349                                cq.ring_sz = sq.ring_sz = max(cq.ring_sz, sq.ring_sz);
350                        }
351                #endif
352
353                // mmap the Submit Queue into existence
354                sq.ring_ptr = mmap(0, sq.ring_sz, PROT_READ | PROT_WRITE, MAP_SHARED | MAP_POPULATE, fd, IORING_OFF_SQ_RING);
355                if (sq.ring_ptr == (void*)MAP_FAILED) {
356                        abort("KERNEL ERROR: IO_URING MMAP1 - %s\n", strerror(errno));
357                }
358
359                // Requires features
360                #if defined(IORING_FEAT_SINGLE_MMAP)
361                        // mmap the Completion Queue into existence (may or may not be needed)
362                        if ((params.features & IORING_FEAT_SINGLE_MMAP) != 0) {
363                                cq.ring_ptr = sq.ring_ptr;
364                        }
365                        else
366                #endif
367                {
368                        // We need multiple call to MMAP
369                        cq.ring_ptr = mmap(0, cq.ring_sz, PROT_READ | PROT_WRITE, MAP_SHARED | MAP_POPULATE, fd, IORING_OFF_CQ_RING);
370                        if (cq.ring_ptr == (void*)MAP_FAILED) {
371                                munmap(sq.ring_ptr, sq.ring_sz);
372                                abort("KERNEL ERROR: IO_URING MMAP2 - %s\n", strerror(errno));
373                        }
374                }
375
376                // mmap the submit queue entries
377                size_t size = params.sq_entries * sizeof(struct io_uring_sqe);
378                sq.sqes = (struct io_uring_sqe *)mmap(0, size, PROT_READ | PROT_WRITE, MAP_SHARED | MAP_POPULATE, fd, IORING_OFF_SQES);
379                if (sq.sqes == (struct io_uring_sqe *)MAP_FAILED) {
380                        munmap(sq.ring_ptr, sq.ring_sz);
381                        if (cq.ring_ptr != sq.ring_ptr) munmap(cq.ring_ptr, cq.ring_sz);
382                        abort("KERNEL ERROR: IO_URING MMAP3 - %s\n", strerror(errno));
383                }
384
385                // Step 3 : Initialize the data structure
386                // Get the pointers from the kernel to fill the structure
387                // submit queue
388                sq.head    = (volatile __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.head);
389                sq.tail    = (volatile __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.tail);
390                sq.mask    = (   const __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.ring_mask);
391                sq.num     = (   const __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.ring_entries);
392                sq.flags   = (         __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.flags);
393                sq.dropped = (         __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.dropped);
394                sq.array   = (         __u32 *)(((intptr_t)sq.ring_ptr) + params.sq_off.array);
395                sq.prev_head = *sq.head;
396
397                {
398                        const __u32 num = *sq.num;
399                        for( i; num ) {
400                                __sqe_clean( &sq.sqes[i] );
401                        }
402                }
403
404                (sq.submit_lock){};
405                (sq.release_lock){};
406
407                if( params_in.poller_submits || params_in.eager_submits ) {
408                        /* paranoid */ verify( is_pow2( params_in.num_ready ) || (params_in.num_ready < 8) );
409                        sq.ready_cnt = max( params_in.num_ready, 8 );
410                        sq.ready = alloc( sq.ready_cnt, 64`align );
411                        for(i; sq.ready_cnt) {
412                                sq.ready[i] = -1ul32;
413                        }
414                        sq.prev_ready = 0;
415                }
416                else {
417                        sq.ready_cnt = 0;
418                        sq.ready = 0p;
419                        sq.prev_ready = 0;
420                }
421
422                // completion queue
423                cq.head      = (volatile __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.head);
424                cq.tail      = (volatile __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.tail);
425                cq.mask      = (   const __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.ring_mask);
426                cq.num       = (   const __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.ring_entries);
427                cq.overflow  = (         __u32 *)(((intptr_t)cq.ring_ptr) + params.cq_off.overflow);
428                cq.cqes = (struct io_uring_cqe *)(((intptr_t)cq.ring_ptr) + params.cq_off.cqes);
429
430                // Step 4 : eventfd
431                int efd;
432                for() {
433                        efd = eventfd(0, 0);
434                        if (efd < 0) {
435                                if (errno == EINTR) continue;
436                                abort("KERNEL ERROR: IO_URING EVENTFD - %s\n", strerror(errno));
437                        }
438                        break;
439                }
440
441                int ret;
442                for() {
443                        ret = syscall( __NR_io_uring_register, fd, IORING_REGISTER_EVENTFD, &efd, 1);
444                        if (ret < 0) {
445                                if (errno == EINTR) continue;
446                                abort("KERNEL ERROR: IO_URING EVENTFD REGISTER - %s\n", strerror(errno));
447                        }
448                        break;
449                }
450
451                // some paranoid checks
452                /* paranoid */ verifyf( (*cq.mask) == ((*cq.num) - 1ul32), "IO_URING Expected mask to be %u (%u entries), was %u", (*cq.num) - 1ul32, *cq.num, *cq.mask  );
453                /* paranoid */ verifyf( (*cq.num)  >= nentries, "IO_URING Expected %u entries, got %u", nentries, *cq.num );
454                /* paranoid */ verifyf( (*cq.head) == 0, "IO_URING Expected head to be 0, got %u", *cq.head );
455                /* paranoid */ verifyf( (*cq.tail) == 0, "IO_URING Expected tail to be 0, got %u", *cq.tail );
456
457                /* paranoid */ verifyf( (*sq.mask) == ((*sq.num) - 1ul32), "IO_URING Expected mask to be %u (%u entries), was %u", (*sq.num) - 1ul32, *sq.num, *sq.mask );
458                /* paranoid */ verifyf( (*sq.num) >= nentries, "IO_URING Expected %u entries, got %u", nentries, *sq.num );
459                /* paranoid */ verifyf( (*sq.head) == 0, "IO_URING Expected head to be 0, got %u", *sq.head );
460                /* paranoid */ verifyf( (*sq.tail) == 0, "IO_URING Expected tail to be 0, got %u", *sq.tail );
461
462                // Update the global ring info
463                this.ring_flags = params.flags;
464                this.fd         = fd;
465                this.efd        = efd;
466                this.eager_submits  = params_in.eager_submits;
467                this.poller_submits = params_in.poller_submits;
468        }
469
470        static void __io_destroy( __io_data & this ) {
471                // Shutdown the io rings
472                struct __submition_data  & sq = this.submit_q;
473                struct __completion_data & cq = this.completion_q;
474
475                // unmap the submit queue entries
476                munmap(sq.sqes, (*sq.num) * sizeof(struct io_uring_sqe));
477
478                // unmap the Submit Queue ring
479                munmap(sq.ring_ptr, sq.ring_sz);
480
481                // unmap the Completion Queue ring, if it is different
482                if (cq.ring_ptr != sq.ring_ptr) {
483                        munmap(cq.ring_ptr, cq.ring_sz);
484                }
485
486                // close the file descriptor
487                close(this.fd);
488                close(this.efd);
489
490                free( this.submit_q.ready ); // Maybe null, doesn't matter
491        }
492
493//=============================================================================================
494// I/O Context Sleep
495//=============================================================================================
496        #define IOEVENTS EPOLLIN | EPOLLONESHOT
497
498        static inline void __ioctx_epoll_ctl($io_ctx_thread & ctx, int op, const char * error) {
499                struct epoll_event ev;
500                ev.events = IOEVENTS;
501                ev.data.u64 = (__u64)&ctx;
502                int ret = epoll_ctl(iopoll.epollfd, op, ctx.ring->efd, &ev);
503                if (ret < 0) {
504                        abort( "KERNEL ERROR: EPOLL %s - (%d) %s\n", error, (int)errno, strerror(errno) );
505                }
506        }
507
508        void __ioctx_register($io_ctx_thread & ctx) {
509                __ioctx_epoll_ctl(ctx, EPOLL_CTL_ADD, "ADD");
510        }
511
512        void __ioctx_prepare_block($io_ctx_thread & ctx) {
513                __cfadbg_print_safe(io_core, "Kernel I/O - epoll : Re-arming io poller %d (%p)\n", ctx.ring->fd, &ctx);
514                __ioctx_epoll_ctl(ctx, EPOLL_CTL_MOD, "REARM");
515        }
516
517//=============================================================================================
518// I/O Context Misc Setup
519//=============================================================================================
520        void register_fixed_files( io_context & ctx, int * files, unsigned count ) {
521                int ret = syscall( __NR_io_uring_register, ctx.thrd.ring->fd, IORING_REGISTER_FILES, files, count );
522                if( ret < 0 ) {
523                        abort( "KERNEL ERROR: IO_URING SYSCALL - (%d) %s\n", (int)errno, strerror(errno) );
524                }
525
526                __cfadbg_print_safe( io_core, "Kernel I/O : Performed io_register for %p, returned %d\n", active_thread(), ret );
527        }
528
529        void register_fixed_files( cluster & cltr, int * files, unsigned count ) {
530                for(i; cltr.io.cnt) {
531                        register_fixed_files( cltr.io.ctxs[i], files, count );
532                }
533        }
534#endif
Note: See TracBrowser for help on using the repository browser.