source: doc/theses/mike_brooks_MMath/plots/list-mchn-szz.gp

set terminal pdfcairo color enhanced size 6.5in,2.5in font "Times,17"

set size 1.0, 1.0    # scale of plot area inside terminal
set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"

set macros
set output OUTDIR."/plot-list-mchn-szz.pdf"

set lmargin 10
set bmargin 4

set grid
unset key

relDurBot = 0.3
relDurTop = 3.0
meanDurAbs = 4.18468330


set ylabel "Duration (relative)" offset -1.0,0
set logscale y 2
set yrange [relDurBot:relDurTop];
set ytics ( \
   "+40%%" 1.666666667, \
   "+30%%" 1.428571429, \
   "+20%%" 1.25, \
   "+10%%" 1.111111111, \
   "0" 1, \
   "-20%%" 0.833333333, \
   "-40%%" 0.714285714, \
   "-60%%" 0.625, \
   "-80%%" 0.555555556, \
   "-100%%" 0.5, \
   "-130%%" 0.434782609, \
   "-160%%" 0.384615385, \
   "-200%%" 0.333333333 \
) nomirror
set y2label "Duration (ns)" offset 0,0
set logscale y2 2
set y2range [ relDurBot*meanDurAbs : relDurTop * meanDurAbs ];
set y2tics (1,2,3,4,5,6,7,8,10,12,14)


set xrange [-0.25:4.25];
set xlabel "Machine, Size Zone; Prevalence" offset 2,-1
set xtics (\
    "AMD\nsmall" 0, \
    "AMD\nmed." 1, \
    "Intel\nsmall" 2, \
    "Intel\nmed." 3 \
)

set errorbars 2.0
set pointintervalbox 0

barHtScale = 0.04


plot INDIR."/plot-list-mchn-szz.dat" \
       i 3 using (0):(0):(0):(0 + barHtScale * $3):1:2 title columnheader(1) with boxxyerror fc rgb "black"  fs transparent solid 0.15 noborder, \
    '' i 2 using (0):(0):(1):(1 + barHtScale * $3):1:2 title columnheader(1) with boxxyerror fc rgb "black"  fs transparent solid 0.15 noborder, \
    '' i 1 using (0):(0):(2):(2 + barHtScale * $3):1:2 title columnheader(1) with boxxyerror fc rgb "black"  fs transparent solid 0.15 noborder, \
    '' i 0 using (0):(0):(3):(3 + barHtScale * $3):1:2 title columnheader(1) with boxxyerror fc rgb "black"  fs transparent solid 0.15 noborder, \
    '' i 3 using (0 + barHtScale * $3):2 notitle with steps lc rgb "black"  lw 0.3, \
    '' i 2 using (1 + barHtScale * $3):2 notitle with steps lc rgb "black"  lw 0.3, \
    '' i 1 using (2 + barHtScale * $3):2 notitle with steps lc rgb "black"  lw 0.3, \
    '' i 0 using (3 + barHtScale * $3):2 notitle with steps lc rgb "black"  lw 0.3