source: doc/theses/mike_brooks_MMath/plots/list-legend-rel-i-swift.gp

set terminal pdfcairo color enhanced size 6.5in,2.0in font "Times,17"

set size 1.0, 1.0    # scale of plot area inside terminal
set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"

set macros
set output OUTDIR."/plot-list-legend-rel-i-swift.pdf"

set grid
set nokey

set logscale y (2**0.2)
set yrange [0.47:2.1];
set format y ""
set ytics (0.5, 0.6, 0.7, 0.8, 0.9, 1.0, 1.2, 1.4, 1.6, 1.8, 2.0) scale 0

set logscale y2 (2**0.2)
set y2range [0.47:2.1];
set format y2 ""
set y2tics (0.5, 0.6, 0.7, 0.8, 0.9, 1.0, 1.2, 1.4, 1.6, 1.8, 2.0) nomirror

# Draw fake x axis at y=1.0; use vertical-only bounding 'H'
unset border
set arrow from graph 0, first 1 to graph 1, first 1 nohead lt -1 lw 2
set arrow 101 from graph 1, graph 0 to graph 1, graph 1 nohead lw 1 front

set xrange [-0.75:16.5];
set xlabel "Size Zone;  Prevalence"
set xtics ( \
   ""              0, \
   "Small (/4)"    1, \
   ""              2, \
   ""              3, \
\
   ""              6, \
   "Medium (/4)"   7, \
   ""              8, \
   ""              9, \
\
   ""             12, \
   "Both (/8)"    13, \
   ""             14, \
   ""             15, \
) scale 0 offset first 0.5,0

#set bmargin 0
#set tmargin 0.1
set lmargin 0
set rmargin 0.1

barHtScale_fx = 0.30


#---------------------

# legend, augmented
set key outside top center horizontal maxrows 1 samplen 2 width +1 # offset -10,0
set object 2 rect from first  2.62, screen 0.882 to first  3.42, screen 0.972 fc rgb "blue"        fs transparent solid 0.20 border lc rgb "blue"        lw 0.3
set object 3 rect from first  5.5,  screen 0.882 to first  6.3 , screen 0.972 fc rgb "dark-orange" fs transparent solid 0.25 border lc rgb "dark-orange" lw 0.3
set object 4 rect from first  8.4,  screen 0.882 to first  9.2 , screen 0.972 fc rgb "magenta"     fs transparent solid 0.20 border lc rgb "magenta"     lw 0.3
set object 5 rect from first 11.3,  screen 0.882 to first 12.1 , screen 0.972 fc rgb "dark-violet" fs transparent solid 0.25 border lc rgb "dark-violet" lw 0.3
# word "mean" is title of a data series plotted froom $Singleton
set arrow 99 from first 12.2, screen 0.925 to first 12.8, screen 0.925  nohead lw 1 dt 2
#---------------------

set errorbars 0 linewidth 4
set pointintervalbox 0

# One row, to plot one-off points
$Singleton <<EOD
0
EOD


plot INDIR."/plot-list-histo-rel-i-swift.sum.dat" \
       i 4 + 0 using ( 0 + 0):1:( 0 + 0):( 0 + 0 + .8) title "{/Helvetica=15 C{/Symbol \42}}" with xerrorbars lc rgb "blue"        pt  7  ps 1.0, \
    '' i 4 + 3 using ( 0 + 1):1:( 0 + 1):( 0 + 1 + .8) title "{/Symbol \155}C++"              with xerrorbars lc rgb "dark-orange" pt  9  ps 1.2, \
    '' i 4 + 2 using ( 0 + 2):1:( 0 + 2):( 0 + 2 + .8) title "LQ {/Helvetica=15 tailq}"       with xerrorbars lc rgb "magenta"     pt  11 ps 1.2, \
    '' i 4 + 1 using ( 0 + 3):1:( 0 + 3):( 0 + 3 + .8) title "LQ {/Helvetica=15 list}"        with xerrorbars lc rgb "dark-violet" pt  13 ps 1.4, \
    $Singleton \
       using (0):(0.1):("This text is placed offscrean-low") title "↕ mean" with labels, \