| 1 | set terminal pdf color enhanced size 6.0in,3.0in font "Times,17"
|
|---|
| 2 |
|
|---|
| 3 | INDIR="build"
|
|---|
| 4 | OUTDIR="build"
|
|---|
| 5 | SRCDIR="plots"
|
|---|
| 6 |
|
|---|
| 7 | set output OUTDIR.'/plot-list-cmp-survey.pdf'
|
|---|
| 8 |
|
|---|
| 9 | set bmargin 6 # extra room at bottom for multiline x axis labels
|
|---|
| 10 |
|
|---|
| 11 | set xrange [1:9]
|
|---|
| 12 | set xlabel "Operation (movement / polarity / accessor)" offset 0,-2,0
|
|---|
| 13 | set xtics offset 4.2,0
|
|---|
| 14 |
|
|---|
| 15 | set logscale y 2
|
|---|
| 16 | set yrange [0.3:10];
|
|---|
| 17 | set ytics ( \
|
|---|
| 18 | "+85%%" 6.666666667, \
|
|---|
| 19 | "+80%%" 5, \
|
|---|
| 20 | "+70%%" 3.333333333, \
|
|---|
| 21 | "+60%%" 2.5, \
|
|---|
| 22 | "+40%%" 1.666666667, \
|
|---|
| 23 | "+20%%" 1.25, \
|
|---|
| 24 | "0" 1, \
|
|---|
| 25 | "-20%%" 0.833333333, \
|
|---|
| 26 | "-60%%" 0.625, \
|
|---|
| 27 | "-100%%" 0.5, \
|
|---|
| 28 | "-200%%" 0.333333333 \
|
|---|
| 29 | )
|
|---|
| 30 | set ylabel "Duration (tailq-Relative)" offset -1.0,0
|
|---|
| 31 |
|
|---|
| 32 | # Draw axis-like line at speedup=0% (y=1.0)
|
|---|
| 33 | set arrow from graph 0, first 1 to graph 1, first 1 nohead lt -1 lw 2
|
|---|
| 34 |
|
|---|
| 35 | set grid
|
|---|
| 36 | set key top center horizontal
|
|---|
| 37 |
|
|---|
| 38 | BOXSPACING=0.25
|
|---|
| 39 | BOXWIDTH=BOXSPACING * .88
|
|---|
| 40 | set boxwidth BOXWIDTH absolute
|
|---|
| 41 |
|
|---|
| 42 | NUM_FXS=3
|
|---|
| 43 |
|
|---|
| 44 | offset(opNum, fxNum) = opNum + fxNum * BOXSPACING - (NUM_FXS+1) * BOXSPACING / 2 + 0.5
|
|---|
| 45 |
|
|---|
| 46 | # One row, to plot one-off points
|
|---|
| 47 | $Singleton <<EOD
|
|---|
| 48 | 0
|
|---|
| 49 | EOD
|
|---|
| 50 |
|
|---|
| 51 | # empty candlesticks for quantiles, then
|
|---|
| 52 | # varyiously styled points for means, then
|
|---|
| 53 | # x axis values, then
|
|---|
| 54 | # legend symbol augmentation
|
|---|
| 55 | plot INDIR.'/plot-list-cmp-survey.dat' \
|
|---|
| 56 | using ($2 == 1 ? (offset($1, $2)) : 1/0):10:9:13:12 title 'cfa-cfa' with candlesticks lt rgb "blue" , \
|
|---|
| 57 | '' using ($2 == 2 ? (offset($1, $2)) : 1/0):10:9:13:12 title 'upp-upp' with candlesticks lt rgb "dark-orange", \
|
|---|
| 58 | '' using ($2 == 3 ? (offset($1, $2)) : 1/0):10:9:13:12 title 'lq-list' with candlesticks lt rgb "purple" , \
|
|---|
| 59 | '' using ($2 == 1 ? (offset($1, $2)) : 1/0):4 notitle with points pt 7 lt rgb "blue" , \
|
|---|
| 60 | '' using ($2 == 2 ? (offset($1, $2)) : 1/0):4 notitle with points pt 9 lt rgb "dark-orange", \
|
|---|
| 61 | '' using ($2 == 3 ? (offset($1, $2)) : 1/0):4 notitle with points pt 13 lt rgb "purple" , \
|
|---|
| 62 | SRCDIR.'/list-cmp-survey-meta.dat' \
|
|---|
| 63 | using 1:(-999):xtic(2) notitle with points, \
|
|---|
| 64 | $Singleton using (3.73):(7.50) notitle with points pt 7 lt rgb "blue" , \
|
|---|
| 65 | $Singleton using (5.44):(7.50) notitle with points pt 9 lt rgb "dark-orange", \
|
|---|
| 66 | $Singleton using (7.14):(7.50) notitle with points pt 13 lt rgb "purple"
|
|---|
