source: doc/papers/OOPSLA17/evaluation/cfa-pair.c @ 01f78e0

#include "cfa-pair.h"

forall(otype R, otype S 
        | { int ?==?(R, R); int ?<?(R, R); int ?<?(S, S); })
int ?<?(pair(R, S) p, pair(R, S) q) {
        return p.first < q.first || ( p.first == q.first && p.second < q.second );
}

forall(otype R, otype S 
        | { int ?==?(R, R); int ?<?(R, R); int ?<=?(S, S); })
int ?<=?(pair(R, S) p, pair(R, S) q) {
        return p.first < q.first || ( p.first == q.first && p.second <= q.second );
}

forall(otype R, otype S | { int ?==?(R, R); int ?==?(S, S); })
int ?==?(pair(R, S) p, pair(R, S) q) {
        return p.first == q.first && p.second == q.second;
}

forall(otype R, otype S | { int ?!=?(R, R); int ?!=?(S, S); })
int ?!=?(pair(R, S) p, pair(R, S) q) {
        return p.first != q.first || p.second != q.second;
}

forall(otype R, otype S 
        | { int ?==?(R, R); int ?>?(R, R); int ?>?(S, S); })
int ?>?(pair(R, S) p, pair(R, S) q) {
        return p.first > q.first || ( p.first == q.first && p.second > q.second );
}

forall(otype R, otype S 
        | { int ?==?(R, R); int ?>?(R, R); int ?>=?(S, S); })
int ?>=?(pair(R, S) p, pair(R, S) q) {
        return p.first > q.first || ( p.first == q.first && p.second >= q.second );
}