| 1 | # -*- Autoconf -*- |
|---|
| 2 | # Process this file with autoconf to produce a configure script. |
|---|
| 3 | |
|---|
| 4 | AC_PREREQ([2.68]) |
|---|
| 5 | AC_INIT([cfa-cc],[1.0.0],[cforall@plg.uwaterloo.ca]) |
|---|
| 6 | AC_CONFIG_AUX_DIR([automake]) |
|---|
| 7 | AC_CONFIG_MACRO_DIRS([automake]) |
|---|
| 8 | AC_CONFIG_HEADERS([config.h:src/config.h.in]) |
|---|
| 9 | AM_SILENT_RULES([yes]) |
|---|
| 10 | |
|---|
| 11 | m4_include([tools/build/cfa.m4]) |
|---|
| 12 | |
|---|
| 13 | # don't use the default CFLAGS as they unconditonnaly add -O2 |
|---|
| 14 | : ${CFLAGS=""} |
|---|
| 15 | : ${CXXFLAGS=""} |
|---|
| 16 | |
|---|
| 17 | AM_INIT_AUTOMAKE([subdir-objects]) |
|---|
| 18 | |
|---|
| 19 | # Allow program name tansformation |
|---|
| 20 | # will fill program_transform_name with appropriate sed regex |
|---|
| 21 | AC_ARG_PROGRAM |
|---|
| 22 | |
|---|
| 23 | #============================================================================== |
|---|
| 24 | #Trasforming cc1 will break compilation |
|---|
| 25 | M4CFA_PROGRAM_NAME |
|---|
| 26 | |
|---|
| 27 | #============================================================================== |
|---|
| 28 | # version information |
|---|
| 29 | |
|---|
| 30 | rm -f version |
|---|
| 31 | echo ${PACKAGE_VERSION} > version # file containing version number for other tools |
|---|
| 32 | chmod ugo-w version |
|---|
| 33 | ver_major=`cut -d '.' -f1 version` # subdivide version number into components at periods |
|---|
| 34 | ver_minor=`cut -d '.' -f2 version` |
|---|
| 35 | ver_patch=`cut -d '.' -f3 version` |
|---|
| 36 | ver_build=`cut -d '.' -f4 version` |
|---|
| 37 | |
|---|
| 38 | # AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/version']) |
|---|
| 39 | AC_DEFINE_UNQUOTED(CFA_VERSION_MAJOR, ${ver_major}, [Major version number.]) |
|---|
| 40 | AC_DEFINE_UNQUOTED(CFA_VERSION_MINOR, ${ver_minor}, [Minor version number.]) |
|---|
| 41 | AC_DEFINE_UNQUOTED(CFA_VERSION_PATCH, ${ver_patch}, [Patch version number.]) |
|---|
| 42 | AC_DEFINE_UNQUOTED(CFA_VERSION_BUILD, ${ver_build}, [Build version number.]) |
|---|
| 43 | AC_DEFINE_UNQUOTED(CFA_VERSION_SHORT, ["${ver_major}"], [Major]) |
|---|
| 44 | AC_DEFINE_UNQUOTED(CFA_VERSION, ["${ver_major}.${ver_minor}"], [Major.Minor]) |
|---|
| 45 | AC_DEFINE_UNQUOTED(CFA_VERSION_LONG, ["${ver_major}.${ver_minor}.${ver_patch}"], [Major.Minor.Patch]) |
|---|
| 46 | AC_DEFINE_UNQUOTED(CFA_VERSION_FULL, ["${ver_major}.${ver_minor}.${ver_patch}.${ver_build}"], [Major.Minor.Patch.Build]) |
|---|
| 47 | |
|---|
| 48 | #============================================================================== |
|---|
| 49 | # HACK to be able to use conditionals inside makefiles |
|---|
| 50 | DOifskipcompile='ifeq ($(skipcompile),yes) |
|---|
| 51 | else' |
|---|
| 52 | AC_SUBST([DOifskipcompile]) |
|---|
| 53 | AM_SUBST_NOTMAKE([DOifskipcompile]) |
|---|
| 54 | |
|---|
| 55 | DOendif='endif' |
|---|
| 56 | AC_SUBST([DOendif]) |
|---|
| 57 | AM_SUBST_NOTMAKE([DOendif]) |
|---|
| 58 | |
|---|
| 59 | #============================================================================== |
|---|
| 60 | # distcc support |
|---|
| 61 | |
|---|
| 62 | AC_ARG_ENABLE(distcc, |
|---|
| 63 | [ --enable-distcc whether or not to enable distributed compilation], |
|---|
| 64 | enable_distcc=$enableval, enable_distcc=no) |
|---|
| 65 | |
|---|
| 66 | AC_ARG_WITH(bwlimit, |
|---|
| 67 | [ --with-bwlimit=RATE RATE the maximum rate at which rsync will be limited when using distributed builds], |
|---|
| 68 | [], []) |
|---|
| 69 | |
|---|
| 70 | AM_CONDITIONAL([ENABLE_DISTCC], [test x$enable_distcc = xyes]) |
|---|
| 71 | HAS_DISTCC="False" |
|---|
| 72 | |
|---|
| 73 | if test x$enable_distcc = xyes; then |
|---|
| 74 | CXX="distcc ${CXX}" |
|---|
| 75 | LD="distcc ${LD} -lstdc++" |
|---|
| 76 | HAS_DISTCC="True" |
|---|
| 77 | echo "Enabling distributed builds" |
|---|
| 78 | fi |
|---|
| 79 | |
|---|
| 80 | AC_SUBST(CXX) |
|---|
| 81 | AC_SUBST(LD) |
|---|
| 82 | AC_SUBST(HAS_DISTCC) |
|---|
| 83 | |
|---|
| 84 | #============================================================================== |
|---|
| 85 | # Installation paths |
|---|
| 86 | M4CFA_PARSE_PREFIX |
|---|
| 87 | |
|---|
| 88 | #============================================================================== |
|---|
| 89 | # Create variables for commonly used targets |
|---|
| 90 | |
|---|
| 91 | TOP_SRCDIR="$(readlink -e $ac_abs_confdir/)/" |
|---|
| 92 | TOP_BUILDDIR="$(readlink -e $ac_pwd/)/" |
|---|
| 93 | |
|---|
| 94 | AC_DEFINE_UNQUOTED(TOP_SRCDIR, "$TOP_SRCDIR", [Top src directory]) |
|---|
| 95 | AC_DEFINE_UNQUOTED(TOP_BUILDDIR, "$TOP_BUILDDIR", [Top build directory]) |
|---|
| 96 | |
|---|
| 97 | DRIVER_DIR=${TOP_BUILDDIR}driver/ |
|---|
| 98 | CFACC=${DRIVER_DIR}cfa |
|---|
| 99 | CFACC_INSTALL=${CFA_BINDIR}${CFA_NAME} |
|---|
| 100 | CFACPP=${DRIVER_DIR}cfa-cpp |
|---|
| 101 | AC_SUBST(DRIVER_DIR) |
|---|
| 102 | AC_SUBST(CFACC) |
|---|
| 103 | AC_SUBST(CFACC_INSTALL) |
|---|
| 104 | AC_SUBST(CFACPP) |
|---|
| 105 | |
|---|
| 106 | #============================================================================== |
|---|
| 107 | # Flag variables needed to build in tree |
|---|
| 108 | LIBCFA_SRC='${TOP_SRCDIR}/libcfa/src' |
|---|
| 109 | BUILD_IN_TREE_FLAGS="-XCFA -t -B${DRIVER_DIR}" |
|---|
| 110 | AC_SUBST(BUILD_IN_TREE_FLAGS) |
|---|
| 111 | |
|---|
| 112 | #============================================================================== |
|---|
| 113 | # handle the list of hosts to build for |
|---|
| 114 | for var in $ac_configure_args |
|---|
| 115 | do |
|---|
| 116 | #strip quotes surrouding values |
|---|
| 117 | case $var in |
|---|
| 118 | # skip cross compilation related arguments |
|---|
| 119 | \'--host=*) ;; \'host_alias=*) ;; \'--build=*) ;; \'build_alias=*) ;; \'--target=*) ;; \'target_alias=*) ;; |
|---|
| 120 | |
|---|
| 121 | # skip the target hosts |
|---|
| 122 | \'--with-target-hosts=*) ;; |
|---|
| 123 | |
|---|
| 124 | # skip gprofiler for libcfa |
|---|
| 125 | \'--enable-gprofiler=*) ;; |
|---|
| 126 | \'--disable-gprofiler) ;; |
|---|
| 127 | |
|---|
| 128 | # skip this, it only causes problems |
|---|
| 129 | \'--srcdir=*) ;; |
|---|
| 130 | |
|---|
| 131 | # append all other arguments to the sub configure arguments |
|---|
| 132 | *) LIBCFA_GENERAL_ARGS="${LIBCFA_GENERAL_ARGS} $var";; |
|---|
| 133 | esac |
|---|
| 134 | done |
|---|
| 135 | |
|---|
| 136 | #============================================================================== |
|---|
| 137 | # handle the list of hosts to build for |
|---|
| 138 | AC_CANONICAL_BUILD |
|---|
| 139 | AC_CANONICAL_HOST |
|---|
| 140 | |
|---|
| 141 | if ! test "$host_cpu" = "$build_cpu"; then |
|---|
| 142 | case $host_cpu in |
|---|
| 143 | i386) |
|---|
| 144 | HOST_FLAGS="-m32" |
|---|
| 145 | ;; |
|---|
| 146 | i686) |
|---|
| 147 | HOST_FLAGS="-m32" |
|---|
| 148 | ;; |
|---|
| 149 | x86_64) |
|---|
| 150 | HOST_FLAGS="-m64" |
|---|
| 151 | ;; |
|---|
| 152 | esac |
|---|
| 153 | fi |
|---|
| 154 | AC_SUBST(HOST_FLAGS) |
|---|
| 155 | |
|---|
| 156 | default_target="${host_cpu}:debug, ${host_cpu}:nodebug" |
|---|
| 157 | AC_ARG_WITH(target-hosts, |
|---|
| 158 | [ --with-target-hosts=HOSTS HOSTS comma seperated list of hosts to build for, format ARCH:[debug|nodebug|nolib]], |
|---|
| 159 | target_hosts=$withval, target_hosts=${default_target}) |
|---|
| 160 | |
|---|
| 161 | AC_ARG_ENABLE(gprofiler, |
|---|
| 162 | [ --enable-gprofiler whether or not to enable gprofiler tools (if available)], |
|---|
| 163 | enable_gprofiler=$enableval, enable_gprofiler=yes) |
|---|
| 164 | |
|---|
| 165 | AC_ARG_ENABLE(demangler, |
|---|
| 166 | [ --enable-demangler whether or not to build the demangler (executable and library)], |
|---|
| 167 | enable_demangler=$enableval, enable_demangler=no) |
|---|
| 168 | |
|---|
| 169 | AC_SUBST(TARGET_HOSTS, ${target_hosts}) |
|---|
| 170 | |
|---|
| 171 | LIBCFA_PATHS="DRIVER_DIR=${DRIVER_DIR}" |
|---|
| 172 | |
|---|
| 173 | for i in $(echo $target_hosts | sed "s/,/ /g") |
|---|
| 174 | do |
|---|
| 175 | # call your procedure/other scripts here below |
|---|
| 176 | arch_name=$(echo $i | sed -r "s/:(.*)//g") |
|---|
| 177 | lib_config=$(echo $i | sed -r "s/(.*)://g") |
|---|
| 178 | |
|---|
| 179 | case $lib_config in |
|---|
| 180 | "nodebug") ;; |
|---|
| 181 | "debug") ;; |
|---|
| 182 | "nolib") ;; |
|---|
| 183 | "profile") ;; |
|---|
| 184 | *) |
|---|
| 185 | >&2 echo "Configuration must be 'debug', 'nodebug' or 'nolib'" |
|---|
| 186 | exit 1 |
|---|
| 187 | ;; |
|---|
| 188 | esac |
|---|
| 189 | |
|---|
| 190 | M4CFA_CANNON_CPU([${arch_name}]) |
|---|
| 191 | lib_arch=${cannon_arch_name} |
|---|
| 192 | lib_dir="libcfa/${lib_arch}-${lib_config}" |
|---|
| 193 | |
|---|
| 194 | LIBCFA_TARGET_DIRS="${LIBCFA_TARGET_DIRS} ${lib_dir}" |
|---|
| 195 | LIBCFA_1TARGET_DIR="${lib_dir}" |
|---|
| 196 | LIBCFA_TARGET_MAKEFILES="${LIBCFA_TARGET_MAKEFILES} ${lib_dir}/Makefile" |
|---|
| 197 | |
|---|
| 198 | mkdir -p ${lib_dir} |
|---|
| 199 | echo -n "${LIBCFA_GENERAL_ARGS} " > ${lib_dir}/config.data |
|---|
| 200 | echo -n "${LIBCFA_PATHS} " >> ${lib_dir}/config.data |
|---|
| 201 | echo -n "ARCHITECTURE=${lib_arch} " >> ${lib_dir}/config.data |
|---|
| 202 | echo -n "CONFIGURATION=${lib_config} " >> ${lib_dir}/config.data |
|---|
| 203 | echo -n "CFA_VERSION=${ver_major}:${ver_minor}:${ver_patch}" >> ${lib_dir}/config.data |
|---|
| 204 | done |
|---|
| 205 | |
|---|
| 206 | AC_SUBST(LIBCFA_TARGET_DIRS) |
|---|
| 207 | AC_SUBST(LIBCFA_1TARGET_DIR) |
|---|
| 208 | AC_SUBST(LIBCFA_TARGET_MAKEFILES) |
|---|
| 209 | |
|---|
| 210 | M4CFA_CANNON_CPU([${host_cpu}]) |
|---|
| 211 | AC_DEFINE_UNQUOTED(CFA_DEFAULT_CPU, "$cannon_arch_name", [Default cpu to use if neither -m32 or -m64 are defined.]) |
|---|
| 212 | AC_DEFINE_UNQUOTED(CFA_64_CPU, "x64", [CPU to use if the -m64 flags is given.]) |
|---|
| 213 | AC_DEFINE_UNQUOTED(CFA_32_CPU, "x86", [CPU to use if the -m32 flags is given.]) |
|---|
| 214 | |
|---|
| 215 | #============================================================================== |
|---|
| 216 | # CAFLAGS |
|---|
| 217 | AC_DEFINE_UNQUOTED(CFA_FLAGS, "${CFAFLAGS}", [compilation flags for cfa libraries and test programs.]) |
|---|
| 218 | AC_SUBST(CFA_FLAGS, ${CFAFLAGS}) |
|---|
| 219 | |
|---|
| 220 | #============================================================================== |
|---|
| 221 | # Checks for programs. |
|---|
| 222 | AC_PROG_CXX |
|---|
| 223 | AC_PROG_CC |
|---|
| 224 | AM_PROG_AS |
|---|
| 225 | # These are often not installed and people miss seeing the "no", so stop the configure. |
|---|
| 226 | AC_PROG_YACC |
|---|
| 227 | if test "${YACC}" = "yacc" ; then echo "Error: bison required." ; exit 1 ; fi |
|---|
| 228 | AC_PROG_LEX(yywrap) |
|---|
| 229 | if test "${LEX}" = "lex" ; then echo "Error: flex required." ; exit 1 ; fi |
|---|
| 230 | LT_INIT |
|---|
| 231 | AC_PROG_INSTALL |
|---|
| 232 | |
|---|
| 233 | # Checks for libraries. |
|---|
| 234 | AC_CHECK_LIB([fibre], [Fibre::yield], [HAVE_LIBFIBRE=1], [HAVE_LIBFIBRE=0]) |
|---|
| 235 | AM_CONDITIONAL([WITH_LIBFIBRE], [test "$HAVE_LIBFIBRE" -eq 1]) |
|---|
| 236 | |
|---|
| 237 | AC_CHECK_LIB([profiler], [ProfilingIsEnabledForAllThreads], [HAVE_LIBPROFILER=1], [HAVE_LIBPROFILER=0]) |
|---|
| 238 | AM_CONDITIONAL([WITH_LIBPROFILER], [test "x$enable_gprofiler" = "xyes" -a "$HAVE_LIBPROFILER" -eq 1]) |
|---|
| 239 | |
|---|
| 240 | AC_CHECK_LIB([tcmalloc], [malloc], [HAVE_LIBTCMALLOC=1], [HAVE_LIBTCMALLOC=0]) |
|---|
| 241 | AM_CONDITIONAL([WITH_LIBTCMALLOC], [test "x$enable_gprofiler" = "xyes" -a "$HAVE_LIBTCMALLOC" -eq 1]) |
|---|
| 242 | |
|---|
| 243 | # conditionnally build the demangler |
|---|
| 244 | if test "x$enable_demangler" == xyes; then |
|---|
| 245 | LIBDEMANGLE="libdemangle.a" |
|---|
| 246 | DEMANGLER="../driver/demangler" |
|---|
| 247 | else |
|---|
| 248 | LIBDEMANGLE="" |
|---|
| 249 | DEMANGLER="" |
|---|
| 250 | fi |
|---|
| 251 | AC_SUBST([LIBDEMANGLE]) |
|---|
| 252 | AC_SUBST([DEMANGLER]) |
|---|
| 253 | |
|---|
| 254 | # Checks for header files. |
|---|
| 255 | AC_CHECK_HEADERS([libintl.h malloc.h unistd.h], [], [echo "Error: Missing required header"; exit 1]) |
|---|
| 256 | |
|---|
| 257 | # Checks for typedefs, structures, and compiler characteristics. |
|---|
| 258 | AC_CHECK_TYPES([_Float32], AC_DEFINE([HAVE_KEYWORDS_FLOATXX], [], [Have keywords _FloatXX.]), [], [[]]) |
|---|
| 259 | |
|---|
| 260 | # Checks for compiler flags. |
|---|
| 261 | M4CFA_CHECK_COMPILE_FLAG([-Wcast-function-type], AC_DEFINE([HAVE_CAST_FUNCTION_TYPE], [], [Have compiler warning cast-function-type.])) |
|---|
| 262 | |
|---|
| 263 | #============================================================================== |
|---|
| 264 | # backend compiler implementation |
|---|
| 265 | AC_DEFINE_UNQUOTED(CFA_BACKEND_CC, "${CC}", [Backend compiler to use.]) |
|---|
| 266 | AC_SUBST(CFA_BACKEND_CC) |
|---|
| 267 | |
|---|
| 268 | #============================================================================== |
|---|
| 269 | AC_CONFIG_FILES([ |
|---|
| 270 | Makefile |
|---|
| 271 | driver/Makefile |
|---|
| 272 | src/Makefile |
|---|
| 273 | libcfa/Makefile:libcfa/Makefile.dist.in |
|---|
| 274 | tests/Makefile |
|---|
| 275 | tools/prettyprinter/Makefile |
|---|
| 276 | ]) |
|---|
| 277 | |
|---|
| 278 | # Some of our makefile don't need to be distributed |
|---|
| 279 | AM_CONDITIONAL([CFORALL_DISTRIBUTE], [test -e $TOP_SRCDIR/autogen.sh]) |
|---|
| 280 | AM_COND_IF([CFORALL_DISTRIBUTE], [ |
|---|
| 281 | AC_CONFIG_FILES([ |
|---|
| 282 | longrun_tests/Makefile |
|---|
| 283 | benchmark/Makefile |
|---|
| 284 | benchmark/io/http/Makefile |
|---|
| 285 | tools/Makefile |
|---|
| 286 | benchmark/Cargo.toml |
|---|
| 287 | ]) |
|---|
| 288 | ]) |
|---|
| 289 | |
|---|
| 290 | AC_CONFIG_LINKS([tests/test.py:tests/test.py]) |
|---|
| 291 | AC_CONFIG_FILES([tests/config.py]) |
|---|
| 292 | |
|---|
| 293 | AC_OUTPUT |
|---|
| 294 | |
|---|
| 295 | # Final text |
|---|
| 296 | AC_MSG_RESULT(Cforall configuraton completed. Type "make -j 8 install".) |
|---|
