source: configure.ac @ 2fa483c

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprno_listpersistent-indexerpthread-emulationqualifiedEnum
Last change on this file since 2fa483c was 56de5932, checked in by Thierry Delisle <tdelisle@…>, 6 years ago

configure now creates a symlink in the test folder when building outside of the tree
  • Property mode set to 100644
File size: 7.3 KB
Line 
1#                                               -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4AC_PREREQ([2.68])
5AC_INIT([cfa-cc],[1.0.0.0],[cforall@plg.uwaterloo.ca])
6AC_CONFIG_AUX_DIR([automake])
7#AC_CONFIG_SRCDIR([src/main.cc])
8AC_CONFIG_HEADERS([config.h:src/config.h.in])
9AM_SILENT_RULES([no])
10
11AM_INIT_AUTOMAKE([subdir-objects])
12
13# Allow program name tansformation
14# will fill program_transform_name with appropriate sed regex
15AC_ARG_PROGRAM
16
17#Trasforming cc1 will break compilation
18if test "${program_transform_name}" = ""; then
19    AC_MSG_ERROR([Program transform not supported.
20                Use --with-cfa-name='[[Desired name here]]' instead])
21fi
22
23AC_ARG_WITH(cfa-name,
24        [  --with-cfa-name=NAME     NAME too which cfa will be installed],
25        cfa_name=$withval, cfa_name="cfa")
26
27#Define the new name of the installed command
28AC_SUBST(CFA_NAME, ${cfa_name})
29
30rm -f version
31echo ${PACKAGE_VERSION} > version               # file containing version number for other tools
32chmod ugo-w version
33ver_major=`cut -d '.' -f1 version`              # subdivide version number into components at periods
34ver_minor=`cut -d '.' -f2 version`
35ver_patch=`cut -d '.' -f3 version`
36ver_build=`cut -d '.' -f4 version`
37
38# AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/version'])
39AC_DEFINE_UNQUOTED(CFA_VERSION_MAJOR, ${ver_major}, [Major version number.])
40AC_DEFINE_UNQUOTED(CFA_VERSION_MINOR, ${ver_minor}, [Minor version number.])
41AC_DEFINE_UNQUOTED(CFA_VERSION_PATCH, ${ver_patch}, [Patch version number.])
42AC_DEFINE_UNQUOTED(CFA_VERSION_BUILD, ${ver_build}, [Build version number.])
43AC_DEFINE_UNQUOTED(CFA_VERSION_SHORT, ["${ver_major}"], [Major])
44AC_DEFINE_UNQUOTED(CFA_VERSION, ["${ver_major}.${ver_minor}"], [Major.Minor])
45AC_DEFINE_UNQUOTED(CFA_VERSION_LONG, ["${ver_major}.${ver_minor}.${ver_patch}"], [Major.Minor.Patch])
46AC_DEFINE_UNQUOTED(CFA_VERSION_FULL, ["${ver_major}.${ver_minor}.${ver_patch}.${ver_build}"], [Major.Minor.Patch.Build])
47
48# Installation paths
49
50AC_ARG_WITH(backend-compiler,
51        [  --with-backend-compiler=PROGRAM     PROGRAM that performs the final code compilation (must be gcc-compatible) ],
52        backendcompiler=$withval, backendcompiler="")
53if test "x$backendcompiler" != "x"; then
54        BACKEND_CC=${backendcompiler}
55else
56        AC_PATH_PROG(BACKEND_CC, gcc, [])       # check gcc installed
57        if test "x$BACKEND_CC" = "x"; then
58                AC_MSG_ERROR(some version of gcc is needed. Get it at ftp://ftp.gnu.org)
59                exit 1
60        fi
61fi
62AC_DEFINE_UNQUOTED(CFA_BACKEND_CC, "${BACKEND_CC}", [Location of include files.])
63AC_SUBST(CFA_BACKEND_CC)
64
65
66
67AC_ARG_ENABLE(target-release, AS_HELP_STRING([--enable-target-release], [Build and install the release target]))
68AC_ARG_ENABLE(target-debug, AS_HELP_STRING([--enable-target-debug], [Build and install the debug target]))
69AC_ARG_ENABLE(threading, AS_HELP_STRING([--enable-threading], [Build and install libcfa with threading support (Enabled by default)]),
70[case "${enableval}" in
71  yes) build_threading="yes" ;;
72  no)  build_threading="no" ;;
73  *) AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;
74esac],[build_threading="yes"])
75
76case "$enable_target_release" in
77        yes)
78                case "$enable_target_debug" in
79                        yes)
80                                build_release="yes"
81                                build_debug="yes"
82                                ;;
83                        no)
84                                build_release="yes"
85                                build_debug="no"
86                                ;;
87                        *)
88                                build_release="yes"
89                                build_debug="no"
90                                ;;
91                esac
92                ;;
93        no)
94                case "$enable_target_debug" in
95                        yes)
96                                build_release="no"
97                                build_debug="yes"
98                                ;;
99                        no)
100                                build_release="no"
101                                build_debug="no"
102                                ;;
103                        *)
104                                build_release="no"
105                                build_debug="yes"
106                                ;;
107                esac
108                ;;
109        *)
110                case "$enable_target_debug" in
111                        yes)
112                                build_release="no"
113                                build_debug="yes"
114                                ;;
115                        no)
116                                build_release="yes"
117                                build_debug="no"
118                                ;;
119                        *)
120                                build_release="yes"
121                                build_debug="yes"
122                                ;;
123                esac
124                ;;
125esac
126
127AM_CONDITIONAL([BUILD_RELEASE], [test "x$build_release" = "xyes"])
128AM_CONDITIONAL([BUILD_DEBUG], [test "x$build_debug" = "xyes"])
129AM_CONDITIONAL([BUILD_NO_LIB], [test "x$build_release$build_debug" = "xnono"])
130AM_CONDITIONAL([BUILD_CONCURRENCY], [test "x$build_threading" = "xyes"])
131
132DOifskipcompile='ifeq ($(skipcompile),yes)
133else'
134AC_SUBST([DOifskipcompile])
135AM_SUBST_NOTMAKE([DOifskipcompile])
136
137DOendif='endif'
138AC_SUBST([DOendif])
139AM_SUBST_NOTMAKE([DOendif])
140
141if test "x$prefix" = "xNONE"; then
142        cfa_prefix=${ac_default_prefix}
143else
144        cfa_prefix=${prefix}
145fi
146AC_DEFINE_UNQUOTED(CFA_PREFIX, "${cfa_prefix}", [Location of cfa install.])
147AC_SUBST(CFA_PREFIX, ${cfa_prefix})
148
149if test "$includedir" = '${prefix}/include'; then
150        cfa_incdir="${cfa_prefix}/include/${cfa_name}"
151else
152        cfa_incdir=${includedir}
153fi
154AC_DEFINE_UNQUOTED(CFA_INCDIR, "${cfa_incdir}", [Location of include files.])
155AC_SUBST(CFA_INCDIR, ${cfa_incdir})
156
157if test "$bindir" = '${exec_prefix}/bin'; then
158        cfa_bindir="${cfa_prefix}/bin"
159else
160        cfa_bindir=${bindir}
161fi
162AC_DEFINE_UNQUOTED(CFA_BINDIR, "${cfa_bindir}", [Location of cfa command.])
163AC_SUBST(CFA_BINDIR, ${cfa_bindir})
164
165if test "$libdir" = '${exec_prefix}/lib'; then
166        cfa_libdir="${cfa_prefix}/lib/${cfa_name}"
167else
168        cfa_libdir=${libdir}
169fi
170AC_DEFINE_UNQUOTED(CFA_LIBDIR, "${cfa_libdir}", [Location of cc1 and cfa-cpp commands.])
171AC_SUBST(CFA_LIBDIR, ${cfa_libdir})
172
173AC_CANONICAL_BUILD
174AC_CANONICAL_HOST
175AC_SUBST([MACHINE_TYPE],[$host_cpu])
176
177if ! test "$host_cpu" = "$build_cpu"; then
178        case $host_cpu in
179                i386)
180                        CFLAGS+=" -m32 "
181                        CXXFLAGS+=" -m32 "
182                        CFAFLAGS+=" -m32 "
183                        LDFLAGS+=" -m32 "
184                        ;;
185                i686)
186                        CFLAGS+=" -m32 "
187                  CXXFLAGS+=" -m32 "
188                  CFAFLAGS+=" -m32 "
189                  LDFLAGS+=" -m32 "
190                        ;;
191                x86_64)
192                        CFLAGS+=" -m64 "
193                        CXXFLAGS+=" -m64 "
194                        CFAFLAGS+=" -m64 "
195                        LDFLAGS+=" -m64 "
196                        ;;
197        esac
198fi
199
200AC_DEFINE_UNQUOTED(CFA_FLAGS, "${CFAFLAGS}", [compilation flags for cfa libraries and test programs.])
201AC_SUBST(CFA_FLAGS, ${CFAFLAGS})
202
203# Checks for programs.
204AC_PROG_CXX
205AC_PROG_CC
206AM_PROG_AS
207AM_PROG_CC_C_O  # deprecated
208# These are often not installed and people miss seeing the "no", so stop the configure.
209AC_PROG_YACC
210if test "${YACC}" = "yacc" ; then echo "Error: bison required." ; exit 1 ; fi
211AC_PROG_LEX
212if test "${LEX}" = "lex" ; then echo "Error: flex required." ; exit 1 ; fi
213AC_PROG_INSTALL
214AC_PROG_MAKE_SET
215AC_PROG_RANLIB
216
217# Checks for libraries.
218
219# Checks for header files.
220AC_FUNC_ALLOCA
221AC_CHECK_HEADERS([fenv.h float.h inttypes.h libintl.h limits.h malloc.h stddef.h stdlib.h string.h unistd.h])
222
223# Checks for typedefs, structures, and compiler characteristics.
224AC_HEADER_STDBOOL
225AC_C_INLINE
226AC_TYPE_INT16_T
227AC_TYPE_INT32_T
228AC_TYPE_INT8_T
229AC_C_RESTRICT
230AC_TYPE_SIZE_T
231AC_TYPE_UINT16_T
232AC_TYPE_UINT32_T
233AC_TYPE_UINT8_T
234
235# Checks for library functions.
236AC_CHECK_FUNCS([memset putenv strchr strtol])
237
238AC_CONFIG_FILES([
239        Makefile
240        src/driver/Makefile
241        src/Makefile
242        src/benchmark/Makefile
243        src/examples/Makefile
244        src/tests/Makefile
245        src/tests/preempt_longrun/Makefile
246        src/prelude/Makefile
247        src/libcfa/Makefile
248        tools/Makefile
249        tools/prettyprinter/Makefile
250        ])
251
252AC_CONFIG_LINKS([src/tests/test.py:src/tests/test.py])
253
254AC_OUTPUT(src/tests/config.py)
255
256AM_COND_IF([BUILD_RELEASE],
257        [AM_COND_IF([BUILD_DEBUG],
258                [AC_MSG_NOTICE(Building libcfa for target: release & debug)],
259                [AC_MSG_NOTICE(Building libcfa for target: release)])],
260        [AM_COND_IF([BUILD_DEBUG],
261                [AC_MSG_NOTICE(Building libcfa for target: debug)],
262                [AC_MSG_NOTICE(Running cfa without libcfa)])])
263
264# Final text
265AC_MSG_RESULT(Cforall configuraton completed. Type "make -j 8 install".)
Note: See TracBrowser for help on using the repository browser.