source: benchmark/io/http/worker.cfa @ ece0e80

#include "worker.hfa"

#include <errno.h>
#include <stdio.h>
#include <string.h>
#include <unistd.h>

#include <iofwd.hfa>

#include "options.hfa"
#include "protocol.hfa"
#include "filecache.hfa"

//=============================================================================================
// Worker Thread
//=============================================================================================
void ?{}( Worker & this ) {
        ((thread&)this){ "Server Worker Thread", *options.clopts.instance };
        this.pipe[0] = -1;
        this.pipe[1] = -1;
}

void main( Worker & this ) {
        park();
        /* paranoid */ assert( this.pipe[0] != -1 );
        /* paranoid */ assert( this.pipe[1] != -1 );

        CONNECTION:
        for() {
                printf("=== Accepting connection ===\n");
                int fd = cfa_accept4( this.[sockfd, addr, addrlen, flags], 0, -1`s, &this.cancel, 0p );
                if(fd < 0) {
                        if( errno == ECONNABORTED ) break;
                        if( errno == EINVAL ) break;
                        abort( "accept error: (%d) %s\n", (int)errno, strerror(errno) );
                }

                printf("=== New connection %d, waiting for requests ===\n", fd);
                REQUEST:
                for() {
                        bool closed;
                        HttpCode code;
                        const char * file;
                        size_t name_size;

                        // Read the http request
                        size_t len = options.socket.buflen;
                        char buffer[len];
                        printf("=== Reading request ===\n");
                        [code, closed, file, name_size] = http_read(fd, buffer, len, &this.cancel);

                        // if we are done, break out of the loop
                        if( closed ) {
                                printf("=== Connection closed ===\n");
                                continue CONNECTION;
                        }

                        // If this wasn't a request retrun 400
                        if( code != OK200 ) {
                                printf("=== Invalid Request : %d ===\n", code_val(code));
                                answer_error(fd, code);
                                continue REQUEST;
                        }

                        printf("=== Request for file %.*s ===\n", (int)name_size, file);

                        // Get the fd from the file cache
                        int ans_fd;
                        size_t count;
                        [ans_fd, count] = get_file( file, name_size );

                        // If we can't find the file, return 404
                        if( ans_fd < 0 ) {
                                printf("=== File Not Found ===\n");
                                answer_error(fd, E404);
                                continue REQUEST;
                        }

                        // Send the header
                        answer_header(fd, count);

                        // Send the desired file
                        sendfile( this.pipe, fd, ans_fd, count);

                        printf("=== File sent ===\n");
                }
        }
}