source: Jenkinsfile @ ab5cd196

#!groovy

//===========================================================================================================
// Main loop of the compilation
//===========================================================================================================
node ('master'){

        boolean bIsSandbox = env.BRANCH_NAME == "jenkins-sandbox"
        def err = null
        def log_needed = false

        stage_name              = ''

        compiler                = null
        arch_name               = ''
        architecture    = ''

        do_alltests             = false
        do_benchmark    = false
        do_doc          = false
        do_publish              = false
        do_sendemail    = true

        builddir = pwd tmp: true
        srcdir   = pwd tmp: false

        currentBuild.result = "SUCCESS"

        try {
                //Wrap build to add timestamp to command line
                wrap([$class: 'TimestamperBuildWrapper']) {

                        notify_server(0)

                        prepare_build()

                        clean()

                        checkout()

                        notify_server(0)

                        build()

                        test()

                        benchmark()

                        build_doc()

                        publish()

                        notify_server(45)
                }
        }

        //If an exception is caught we need to change the status and remember to
        //attach the build log to the email
        catch (Exception caughtError) {
                //rethrow error later
                err = caughtError

                //An error has occured, the build log is relevent
                log_needed = true

                //Store the result of the build log
                currentBuild.result = "${stage_name} FAILURE".trim()
        }

        finally {
                //Send email with final results if this is not a full build
                if( do_sendemail ) {
                        echo 'Notifying users of result'
                        email(currentBuild.result, log_needed, bIsSandbox)
                }

                echo 'Build Completed'

                /* Must re-throw exception to propagate error */
                if (err) {
                        throw err
                }
        }
}

//===========================================================================================================
// Helper classes/variables/routines
//===========================================================================================================
//Helper routine to collect information about the git history
def collect_git_info() {

        checkout scm

        //create the temporary output directory in case it doesn't already exist
        def out_dir = pwd tmp: true
        sh "mkdir -p ${out_dir}"

        //parse git logs to find what changed
        gitRefName = env.BRANCH_NAME
        sh "git reflog > ${out_dir}/GIT_COMMIT"
        git_reflog = readFile("${out_dir}/GIT_COMMIT")
        gitRefOldValue = (git_reflog =~ /moving from (.+) to (.+)/)[0][1]
        gitRefNewValue = (git_reflog =~ /moving from (.+) to (.+)/)[0][2]
}

def prepare_build() {
        properties ([                                                                                                   \
                [$class: 'ParametersDefinitionProperty',                                                                \
                        parameterDefinitions: [                                                                         \
                                [$class: 'ChoiceParameterDefinition',                                           \
                                        description: 'Which compiler to use',                                   \
                                        name: 'Compiler',                                                                       \
                                        choices: 'gcc-6\ngcc-5\ngcc-4.9\nclang',                                        \
                                        defaultValue: 'gcc-6',                                                          \
                                ],                                                                                              \
                                [$class: 'ChoiceParameterDefinition',                                           \
                                        description: 'The target architecture',                                 \
                                        name: 'Architecture',                                                           \
                                        choices: 'x64\nx86',                                                            \
                                        defaultValue: 'x64',                                                            \
                                ],                                                                                              \
                                [$class: 'BooleanParameterDefinition',                                                  \
                                        description: 'If false, only the quick test suite is ran',              \
                                        name: 'RunAllTests',                                                            \
                                        defaultValue: false,                                                            \
                                ],                                                                                              \
                                [$class: 'BooleanParameterDefinition',                                                  \
                                        description: 'If true, jenkins also runs benchmarks',           \
                                        name: 'RunBenchmark',                                                           \
                                        defaultValue: false,                                                            \
                                ],                                                                                              \
                                [$class: 'BooleanParameterDefinition',                                                  \
                                        description: 'If true, jenkins also builds documentation',              \
                                        name: 'BuildDocumentation',                                                     \
                                        defaultValue: true,                                                             \
                                ],                                                                                              \
                                [$class: 'BooleanParameterDefinition',                                                  \
                                        description: 'If true, jenkins also publishes results',                 \
                                        name: 'Publish',                                                                        \
                                        defaultValue: false,                                                            \
                                ],                                                                                              \
                                [$class: 'BooleanParameterDefinition',                                                  \
                                        description: 'If true, jenkins will not send emails',           \
                                        name: 'Silent',                                                                         \
                                        defaultValue: false,                                                            \
                                ],                                                                                              \
                        ],
                ]])

        compiler                = compiler_from_params( params.Compiler )
        arch_name               = params.Architecture
        architecture    = architecture_from_params( arch_name )

        do_alltests             = (params.RunAllTests == 'true')
        do_benchmark    = (params.RunBenchmark == 'true')
        do_doc          = (params.BuildDocumentation == 'true')
        do_publish              = (params.Publish == 'true')
        do_sendemail    = ! (params.Silent == 'true')

        echo params.RunAllTests.getClass().toString();

        collect_git_info()

        def full = do_alltests ? " (Full)" : ""
        currentBuild.description = "${compiler.cc_name}:${arch_name}${full}"

        echo """Compiler                 : ${ compiler.cc_name } (${ compiler.cpp_cc }/${ compiler.cfa_cc })
Architecture            : ${ arch_name }
Arc Flags               : ${ architecture }
Run All Tests           : ${ params.RunAllTests.toString() }
Run Benchmark           : ${ params.RunBenchmark.toString() }
Build Documentation     : ${ params.BuildDocumentation.toString() }
Publish                 : ${ params.Publish.toString() }
Silent                  : ${ params.Silent.toString() }
"""
}

def build_stage(String name, Closure block ) {
        stage_name = name
        stage(name, block)
}

def notify_server(int wait) {
        sh """curl --silent --show-error --data "wait=${wait}" -X POST https://cforall.uwaterloo.ca:8082/jenkins/notify > /dev/null || true"""
        return
}

def make_doc() {
        def err = null
        try {
                sh 'make clean > /dev/null'
                sh 'make > /dev/null 2>&1'
        }
        catch (Exception caughtError) {
                err = caughtError //rethrow error later
                sh 'cat *.log'
        }
        finally {
                if (err) throw err // Must re-throw exception to propagate error
        }
}

//Description of a compiler (Must be serializable since pipelines are persistent)
class CC_Desc implements Serializable {
        public String cc_name
        public String cpp_cc
        public String cfa_cc

        CC_Desc(String cc_name, String cpp_cc, String cfa_cc) {
                this.cc_name = cc_name
                this.cpp_cc = cpp_cc
                this.cfa_cc = cfa_cc
        }
}

def compiler_from_params(cc) {
        switch( cc ) {
                case 'gcc-6':
                        return new CC_Desc('gcc-6', 'g++-6', 'gcc-6')
                break
                case 'gcc-5':
                        return new CC_Desc('gcc-5', 'g++-5', 'gcc-5')
                break
                case 'gcc-4.9':
                        return new CC_Desc('gcc-4.9', 'g++-4.9', 'gcc-4.9')
                break
                case 'clang':
                        return new CC_Desc('clang', 'clang++', 'gcc-6')
                break
                default :
                        error "Unhandled compiler : ${cc}"
        }
}

def architecture_from_params( arch ) {
        switch( arch ) {
                case 'x64':
                        return '--host=x86_64'
                break
                case 'x86':
                        return '--host=i386'
                break
                default :
                        error "Unhandled architecture : ${arch}"
        }
}

//===========================================================================================================
// Main compilation routines
//===========================================================================================================
def clean() {
        build_stage('Cleanup') {
                // clean the build by wipping the build directory
                dir(builddir) {
                        deleteDir()
                }

                //Clean all temporary files to make sure no artifacts of the previous build remain
                sh 'git clean -fdqx'

                //Reset the git repo so no local changes persist
                sh 'git reset --hard'
        }
}

//Compilation script is done here but environnement set-up and error handling is done in main loop
def checkout() {
        build_stage('Checkout') {
                //checkout the source code and clean the repo
                checkout scm
        }
}

def build() {
        build_stage('Build') {
                // Build outside of the src tree to ease cleaning
                dir (builddir) {
                        //Configure the conpilation (Output is not relevant)
                        //Use the current directory as the installation target so nothing escapes the sandbox
                        //Also specify the compiler by hand
                        targets=""
                        if(do_alltests) {
                                targets="--with-target-hosts='host:debug,host:nodebug'"
                        } else {
                                targets="--with-target-hosts='host:debug'"
                        }

                        sh "${srcdir}/configure CXX=${compiler.cpp_cc} ${architecture} ${targets} --with-backend-compiler=${compiler.cfa_cc} --quiet"

                        //Compile the project
                        sh 'make -j 8 --no-print-directory'
                }
        }
}

def test() {
        build_stage('Test') {

                dir (builddir) {
                        //Run the tests from the tests directory
                        if ( do_alltests ) {
                                sh 'make --no-print-directory -C tests all-tests debug=yes'
                                sh 'make --no-print-directory -C tests all-tests debug=no '
                        }
                        else {
                                sh 'make --no-print-directory -C tests'
                        }
                }
        }
}

def benchmark() {
        build_stage('Benchmark') {

                if( !do_benchmark ) return

                dir (builddir) {
                        //Append bench results
                        sh "make --no-print-directory -C benchmark jenkins githash=${gitRefNewValue} arch=${arch_name} | tee ${srcdir}/bench.json"
                }
        }
}

def build_doc() {
        build_stage('Documentation') {

                if( !do_doc ) return

                dir ('doc/user') {
                        make_doc()
                }

                dir ('doc/refrat') {
                        make_doc()
                }
        }
}

def publish() {
        build_stage('Publish') {

                if( !do_publish ) return

                //Then publish the results
                sh 'curl --silent --show-error -H \'Content-Type: application/json\' --data @bench.json https://cforall.uwaterloo.ca:8082/jenkins/publish > /dev/null || true'
        }
}

//===========================================================================================================
//Routine responsible of sending the email notification once the build is completed
//===========================================================================================================
def gitBranchUpdate(String gitRefOldValue, String gitRefNewValue) {
        def update = ""
        sh "git rev-list ${gitRefOldValue}..${gitRefNewValue} > GIT_LOG";
        readFile('GIT_LOG').eachLine { rev ->
                sh "git cat-file -t ${rev} > GIT_TYPE"
                def type = readFile('GIT_TYPE')

                update += "       via  ${rev} (${type})\n"
        }
        def rev = gitRefOldValue
        sh "git cat-file -t ${rev} > GIT_TYPE"
        def type = readFile('GIT_TYPE')

        update += "      from  ${rev} (${type})\n"
        return update

def output=readFile('result').trim()
echo "output=$output";
}

//Standard build email notification
def email(String status, boolean log, boolean bIsSandbox) {
        //Since tokenizer doesn't work, figure stuff out from the environnement variables and command line
        //Configurations for email format
        def project_name = (env.JOB_NAME =~ /(.+)\/.+/)[0][1].toLowerCase()

        def gitLog = 'Error retrieving git logs'
        def gitDiff = 'Error retrieving git diff'
        def gitUpdate = 'Error retrieving update'

        try {
                gitUpdate = gitBranchUpdate(gitRefOldValue, gitRefNewValue)

                sh "git rev-list --format=short ${gitRefOldValue}...${gitRefNewValue} > GIT_LOG"
                gitLog = readFile('GIT_LOG')

                sh "git diff --stat ${gitRefNewValue} ${gitRefOldValue} > GIT_DIFF"
                gitDiff = readFile('GIT_DIFF')
        }
        catch (Exception error) {
                echo error.toString()
                echo error.getMessage()
        }

        def email_subject = "[${project_name} git][BUILD# ${env.BUILD_NUMBER} - ${status}] - branch ${env.BRANCH_NAME}"
        def email_body = """This is an automated email from the Jenkins build machine. It was
generated because of a git hooks/post-receive script following
a ref change was pushed to the repository containing
the project "UNNAMED PROJECT".

The branch ${env.BRANCH_NAME} has been updated.
${gitUpdate}

Check console output at ${env.BUILD_URL} to view the results.

- Status --------------------------------------------------------------

BUILD# ${env.BUILD_NUMBER} - ${status}

- Log -----------------------------------------------------------------
${gitLog}
-----------------------------------------------------------------------
Summary of changes:
${gitDiff}
"""

        def email_to = "cforall@lists.uwaterloo.ca"

        if( !bIsSandbox ) {
                //send email notification
                emailext body: email_body, subject: email_subject, to: email_to, attachLog: log
        } else {
                echo "Would send email to: ${email_to}"
                echo "With title: ${email_subject}"
                echo "Content: \n${email_body}"
        }
}