#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.68])
AC_INIT([cfa-cc],[1.0.0.0],[cforall@plg.uwaterloo.ca])
AC_CONFIG_AUX_DIR([automake])
#AC_CONFIG_SRCDIR([src/main.cc])
AC_CONFIG_HEADERS([config.h:src/config.h.in])
AM_SILENT_RULES([no])

AM_INIT_AUTOMAKE([subdir-objects])

# Allow program name tansformation
# will fill program_transform_name with appropriate sed regex
AC_ARG_PROGRAM

#==============================================================================
#Trasforming cc1 will break compilation
if test "${program_transform_name}" = ""; then
    AC_MSG_ERROR([Program transform not supported.
		Use --with-cfa-name='[[Desired name here]]' instead])
fi

#Define the new name of the installed command
AC_ARG_WITH(cfa-name,
	[  --with-cfa-name=NAME     NAME too which cfa will be installed],
	cfa_name=$withval, cfa_name="cfa")

AC_SUBST(CFA_NAME, ${cfa_name})


#==============================================================================
# version information

rm -f version
echo ${PACKAGE_VERSION} > version		# file containing version number for other tools
chmod ugo-w version
ver_major=`cut -d '.' -f1 version`		# subdivide version number into components at periods
ver_minor=`cut -d '.' -f2 version`
ver_patch=`cut -d '.' -f3 version`
ver_build=`cut -d '.' -f4 version`

# AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/version'])
AC_DEFINE_UNQUOTED(CFA_VERSION_MAJOR, ${ver_major}, [Major version number.])
AC_DEFINE_UNQUOTED(CFA_VERSION_MINOR, ${ver_minor}, [Minor version number.])
AC_DEFINE_UNQUOTED(CFA_VERSION_PATCH, ${ver_patch}, [Patch version number.])
AC_DEFINE_UNQUOTED(CFA_VERSION_BUILD, ${ver_build}, [Build version number.])
AC_DEFINE_UNQUOTED(CFA_VERSION_SHORT, ["${ver_major}"], [Major])
AC_DEFINE_UNQUOTED(CFA_VERSION, ["${ver_major}.${ver_minor}"], [Major.Minor])
AC_DEFINE_UNQUOTED(CFA_VERSION_LONG, ["${ver_major}.${ver_minor}.${ver_patch}"], [Major.Minor.Patch])
AC_DEFINE_UNQUOTED(CFA_VERSION_FULL, ["${ver_major}.${ver_minor}.${ver_patch}.${ver_build}"], [Major.Minor.Patch.Build])

#==============================================================================
# HACK to be able to use conditionnals inside makefiles
DOifskipcompile='ifeq ($(skipcompile),yes)
else'
AC_SUBST([DOifskipcompile])
AM_SUBST_NOTMAKE([DOifskipcompile])

DOendif='endif'
AC_SUBST([DOendif])
AM_SUBST_NOTMAKE([DOendif])

#==============================================================================
# backend compiler implementation
AC_ARG_WITH(backend-compiler,
       [  --with-backend-compiler=PROGRAM     PROGRAM that performs the final code compilation (must be gcc-compatible) ],
       backendcompiler=$withval, backendcompiler="")
if test "x$backendcompiler" != "x"; then
       BACKEND_CC=${backendcompiler}
else
       AC_PATH_PROG(BACKEND_CC, gcc, [])       # check gcc installed
       if test "x$BACKEND_CC" = "x"; then
               AC_MSG_ERROR(some version of gcc is needed. Get it at ftp://ftp.gnu.org)
               exit 1
       fi
fi
AC_DEFINE_UNQUOTED(CFA_BACKEND_CC, "${BACKEND_CC}", [Location of include files.])
AC_SUBST(CFA_BACKEND_CC)

#==============================================================================
# Installation paths
if test "x$prefix" = "xNONE"; then
	cfa_prefix=${ac_default_prefix}
else
	cfa_prefix=${prefix}
fi
AC_DEFINE_UNQUOTED(CFA_PREFIX, "${cfa_prefix}", [Location of cfa install.])
AC_SUBST(CFA_PREFIX, ${cfa_prefix})

if test "$includedir" = '${prefix}/include'; then
 	cfa_incdir="${cfa_prefix}/include/${cfa_name}"
else
 	cfa_incdir=${includedir}
fi
AC_DEFINE_UNQUOTED(CFA_INCDIR, "${cfa_incdir}", [Location of include files.])
AC_SUBST(CFA_INCDIR, ${cfa_incdir})

if test "$bindir" = '${exec_prefix}/bin'; then
 	cfa_bindir="${cfa_prefix}/bin"
else
 	cfa_bindir=${bindir}
fi
AC_DEFINE_UNQUOTED(CFA_BINDIR, "${cfa_bindir}", [Location of cfa command.])
AC_SUBST(CFA_BINDIR, ${cfa_bindir})

if test "$libdir" = '${exec_prefix}/lib'; then
 	cfa_libdir="${cfa_prefix}/lib/${cfa_name}"
else
 	cfa_libdir=${libdir}
fi
AC_DEFINE_UNQUOTED(CFA_LIBDIR, "${cfa_libdir}", [Location of cc1 and cfa-cpp commands.])
AC_SUBST(CFA_LIBDIR, ${cfa_libdir})

#==============================================================================
# Create variables for commonly used targets

TOP_SRCDIR=$ac_pwd/$ac_confdir/
TOP_BUILDDIR=$ac_pwd/
PRELUDE_BUILDDIR=$ac_pwd/libcfa-x86_64-debug/prelude/

AC_DEFINE_UNQUOTED(TOP_SRCDIR, "$TOP_SRCDIR", [Top src directory])
AC_DEFINE_UNQUOTED(TOP_BUILDDIR, "$TOP_BUILDDIR", [Top build directory])
AC_DEFINE_UNQUOTED(PRELUDE_BUILDDIR, "$PRELUDE_BUILDDIR", [Directory where the prelude files are built])

DRIVER_DIR=${TOP_BUILDDIR}driver/
CFACC=${DRIVER_DIR}cfa
CFACPP=${DRIVER_DIR}cfa-cpp
AC_SUBST(DRIVER_DIR)
AC_SUBST(CFACC)
AC_SUBST(CFACPP)

#==============================================================================
# Flag variables needed to build in tree
LIBCFA_SRC='${TOP_SRCDIR}/libcfa/src'
BUILD_IN_TREE_FLAGS="-XCFA -t -B${DRIVER_DIR}"
AC_SUBST(BUILD_IN_TREE_FLAGS)

#==============================================================================
# handle the list of hosts to build for
for var in $ac_configure_args
do
	#strip quotes surrouding values
	var=$(echo $var | sed s/\'//g)
	case $var in
		# skip cross compilation related arguments
		--host=*) ;; host_alias=*) ;; --build=*) ;; build_alias=*) ;; --target=*) ;; target_alias=*) ;;

		# skip the target hosts
		--with-target-hosts=*) ;;

		# append all other arguments to the sub configure arguments
		*) LIBCFA_GENERAL_ARGS="${LIBCFA_GENERAL_ARGS} $var";;
	esac
done

#==============================================================================
# handle the list of hosts to build for
AC_CANONICAL_BUILD
AC_CANONICAL_HOST

default_target="${host_cpu}:debug, ${host_cpu}:nodebug"
AC_ARG_WITH(target-hosts,
	[  --with-target-hosts=HOSTS     HOSTS comma seperated list of hosts to build for, format ARCH:[debug|nodebug|nolib]],
	target_hosts=$withval, target_hosts=${default_target})

AC_SUBST(TARGET_HOSTS, ${target_hosts})

LIBCFA_PATHS="DRIVER_DIR=${DRIVER_DIR}"

for i in $(echo $target_hosts | sed "s/,/ /g")
do
	# call your procedure/other scripts here below
	lib_arch=$(echo $i | sed -r "s/:(.*)//g")
	lib_config=$(echo $i | sed -r "s/(.*)://g")
	lib_dir="libcfa-${lib_arch}-${lib_config}"

	LIBCFA_TARGET_DIRS="${LIBCFA_TARGET_DIRS} ${lib_dir}"
	LIBCFA_TARGET_MAKEFILES="${LIBCFA_TARGET_MAKEFILES} ${lib_dir}/Makefile"

	mkdir -p libcfa-${lib_arch}-${lib_config}
	echo -n "${LIBCFA_GENERAL_ARGS} " > libcfa-${lib_arch}-${lib_config}/config.data
	echo -n "${LIBCFA_PATHS} " >> libcfa-${lib_arch}-${lib_config}/config.data
	echo -n "--host=${lib_arch} " >> libcfa-${lib_arch}-${lib_config}/config.data
	echo -n "CONFIGURATION=${lib_config}" >> libcfa-${lib_arch}-${lib_config}/config.data
done

AC_SUBST(LIBCFA_TARGET_DIRS)
AC_SUBST(LIBCFA_TARGET_MAKEFILES)

#==============================================================================
# CAFLAGS
AC_DEFINE_UNQUOTED(CFA_FLAGS, "${CFAFLAGS}", [compilation flags for cfa libraries and test programs.])
AC_SUBST(CFA_FLAGS, ${CFAFLAGS})

#==============================================================================
# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AM_PROG_AS
AM_PROG_CC_C_O	# deprecated
# These are often not installed and people miss seeing the "no", so stop the configure.
AC_PROG_YACC
if test "${YACC}" = "yacc" ; then echo "Error: bison required." ; exit 1 ; fi
AC_PROG_LEX
if test "${LEX}" = "lex" ; then echo "Error: flex required." ; exit 1 ; fi
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

# Checks for libraries.

# Checks for header files.
AC_FUNC_ALLOCA
AC_CHECK_HEADERS([fenv.h float.h inttypes.h libintl.h limits.h malloc.h stddef.h stdlib.h string.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_INLINE
AC_TYPE_INT16_T
AC_TYPE_INT32_T
AC_TYPE_INT8_T
AC_C_RESTRICT
AC_TYPE_SIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT8_T

# Checks for library functions.
AC_CHECK_FUNCS([memset putenv strchr strtol])

#==============================================================================
AC_CONFIG_FILES([
	Makefile
	driver/Makefile
	src/Makefile
	benchmark/Makefile
	tests/Makefile
	tests/preempt_longrun/Makefile
	tools/Makefile
	tools/prettyprinter/Makefile
	])

AC_CONFIG_LINKS([tests/test.py:tests/test.py])

AC_OUTPUT(tests/config.py)

# Final text
AC_MSG_RESULT(Cforall configuraton completed. Type "make -j 8 install".)