set terminal pdfcairo color enhanced size 3.4375in,2.5in font "Times,17"

set size 1.0, 1.0    # scale of plot area inside terminal
set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"

set macros
set output OUTDIR."/plot-list-zoomin-abs-i-swift.pdf"

set lmargin screen (0.5/3.4375) # half inch

set grid
set key bottom right

set logscale y
set yrange [1:15];
set ytics (1,2,3,4,5,6,7,8,10,12,14) nomirror
set ylabel "Duration (ns)"

set logscale x 2
set xrange [0.75:180];
set xlabel "List length (item count)"
# set format x ""

# "drop" page-centre side of bounding box (drop whole box, re-draw desired three)
unset border
set arrow from graph 0, graph 0 to graph 0, graph 1 nohead lw 1 front  # left
set arrow from graph 0, graph 1 to graph 1, graph 1 nohead lw 1 front  # top
set arrow from graph 0, graph 0 to graph 1, graph 0 nohead lw 1 front  # bot

# labelled boxes around size zones
set object rect from first  6, first 2.5 to first 23,   first 10 fc rgb "black"       fs empty         lw 2.0
set object rect from first 45, first 3.5 to graph 0.99, first 12 fc rgb "black"       fs empty         lw 2.0
set label "small"                        at first 23,   first (2.5 * 0.9) right
set label "medium"                       at graph 0.99, first (3.5 * 0.9) right


#set bmargin 0
set tmargin 0.1
#set lmargin 0
set rmargin 0.1

set label "{/Times-Bold= Use Case I,}\n{/Times-Bold= AMD}"                           at first 1, graph  0.9 left

set errorbars 2.0
set pointintervalbox 0

plot INDIR."/plot-list-zoomin-abs-i-swift.dat" \
       i 0 using ($1 * 0.98):8:4:5 notitle                         with yerrorbars lt rgb "blue" 	      pt  6  ps 0.85 lw 1, \
    '' i 4 using ($1 * 0.94):8:4:5 notitle                         with yerrorbars lt rgb "dark-orange"	pt  8  ps 0.75 lw 1, \
    '' i 3 using ($1 * 1.02):8:4:5 notitle                         with yerrorbars lt rgb "magenta"	      pt  10 ps 0.85 lw 1, \
    '' i 2 using ($1 * 1.06):8:4:5 title "LQ {/Helvetica=15 list}" with yerrorbars lt rgb "purple"	      pt  12 ps 1.0  lw 1