set terminal pdfcairo color enhanced size 3.0in,2.5in font "Times,17"

set size 1.0, 1.0    # scale of plot area inside terminal
set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"

set macros
set output OUTDIR."/plot-list-zoomin-rel-java.pdf"

set grid
set key bottom right
set logscale x 2
set logscale y 2
set yrange [0.3:1.8];
set ytics ( \
   "" 1.666666667, \
   "" 1.428571429, \
   "" 1.25, \
   "" 1.111111111, \
   "" 1, \
   "" 0.833333333, \
   "" 0.714285714, \
   "" 0.625, \
   "" 0.555555556, \
   "" 0.5, \
   "" 0.434782609, \
   "" 0.384615385, \
   "" 0.333333333 \
)
set xrange [0.75:180];
set xlabel "List length (item count)" offset 2,0
unset ylabel
set errorbars 2.0
set pointintervalbox 0

# Draw axis-like line at speedup=0% (y=1.0)
set arrow from graph 0, first 1 to graph 1, first 1 nohead lt -1 lw 2

plot INDIR."/plot-list-zoomin-rel-java.dat" \
       i 0 using ($1 * 0.98):8:4:5 title columnheader(1) with yerrorbars lt rgb "blue" 	      pt  6  ps 0.85 lw 1, \
    '' i 9 using ($1 * 0.94):8:4:5 title columnheader(1) with yerrorbars lt rgb "dark-orange"	pt  8  ps 0.75 lw 1, \
    '' i 8 using ($1 * 1.02):8:4:5 title columnheader(1) with yerrorbars lt rgb "magenta"	      pt  10 ps 0.85 lw 1, \
    '' i 7 using ($1 * 1.06):8:4:5 title columnheader(1) with yerrorbars lt rgb "purple"	      pt  12 ps 1.0  lw 1