set terminal pdfcairo color enhanced size 3.625in,3.0in font "Times,17"

# set size 1.0, 1.0    # scale of plot area inside terminal
# set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"
SRCDIR="plots"

set output OUTDIR.'/plot-list-cmp-exout-swift.pdf'

set xrange [1:9]
set xlabel " "  offset 0,-1,0
set xtics offset 2.1,0

set logscale y 2
set yrange [0.3:2.0];
set ytics ( \
   "+40%%" 1.666666667, \
   "+20%%" 1.25, \
   "0" 1, \
   "-20%%" 0.833333333, \
   "-60%%" 0.625, \
   "-100%%" 0.5, \
   "-200%%" 0.333333333 \
)
set ylabel "Duration (tailq-Relative)" offset -1.0,0

# Draw axis-like line at speedup=0% (y=1.0)
set arrow from graph 0, first 1 to graph 1, first 1 nohead lt -1 lw 2

set grid
set key top center horizontal

BOXSPACING=0.25
BOXWIDTH=BOXSPACING * .88
set boxwidth BOXWIDTH absolute

NUM_FXS=3

offset(opNum, fxNum) = opNum + fxNum * BOXSPACING - (NUM_FXS+1) * BOXSPACING / 2 + 0.5

# One row, to plot one-off points
$Singleton <<EOD
0
EOD

# empty candlesticks for quantiles, then
# varyiously styled points for means, then
# x axis values, then
# legend symbol augmentation
plot INDIR.'/plot-list-cmp-exout-swift.dat' \
        using ($2 == 1 ? (offset($1, $2)) : 1/0):10:9:13:12 title 'cfa-cfa' with candlesticks lt rgb "blue"	   , \
     '' using ($2 == 2 ? (offset($1, $2)) : 1/0):10:9:13:12 title 'upp-upp' with candlesticks lt rgb "dark-orange", \
     '' using ($2 == 3 ? (offset($1, $2)) : 1/0):10:9:13:12 title 'lq-list' with candlesticks lt rgb "purple"	, \
     '' using ($2 == 1 ? (offset($1, $2)) : 1/0):4          notitle         with points pt 7  lt rgb "blue"	   , \
     '' using ($2 == 2 ? (offset($1, $2)) : 1/0):4          notitle         with points pt 9  lt rgb "dark-orange", \
     '' using ($2 == 3 ? (offset($1, $2)) : 1/0):4          notitle         with points pt 13 lt rgb "purple"	, \
     SRCDIR.'/list-cmp-exout-meta.dat' \
        using 1:(-999):xtic(2) notitle with points, \
     $Singleton using (3.73):(7.50)                         notitle         with points pt 7  lt rgb "blue"	   , \
     $Singleton using (5.44):(7.50)                         notitle         with points pt 9  lt rgb "dark-orange", \
     $Singleton using (7.14):(7.50)                         notitle         with points pt 13 lt rgb "purple"