set terminal pdfcairo color enhanced size 2.9375in,2.5in font "Times,17"

set size 1.0, 1.0    # scale of plot area inside terminal
set origin 0.0, 0.0  # bottom-left corner

INDIR="build"
OUTDIR="build"

set macros
set output OUTDIR."/plot-list-zoomin-abs-viii-java.pdf"

set grid
set key bottom right
set key noopaque

set logscale y
set yrange [1:15];
set ytics (1,2,3,4,5,6,7,8,10,12,14) scale 0
#set ylabel "Duration (ns)" offset -3.0,0
set format y ""

set logscale y2
set y2range [1:15];
set y2tics (1,2,3,4,5,6,7,8,10,12,14) nomirror
set format y2 ""

set logscale x 2
set xrange [0.75:180];
set xlabel "List length (item count)"
# set format x ""

# "drop" page-centre side of bounding box (drop whole box, re-draw desired three)
unset border
set arrow from graph 1, graph 0 to graph 1, graph 1 nohead lw 1 front  # right
set arrow from graph 0, graph 1 to graph 1, graph 1 nohead lw 1 front  # top
set arrow from graph 0, graph 0 to graph 1, graph 0 nohead lw 1 front  # bot

# labelled boxes around size zones
set object rect  from first  6, first 1.4 to first 23,   first 4.8 fc rgb "black"       fs empty         lw 2.0
set object rect  from first 45, first 3.5 to graph 0.99, first 6.5 fc rgb "black"       fs empty         lw 2.0
set label "small"  at first  6,                          first (4.8 * 1.15) left
set label "medium" at first 45,                          first (6.5 * 1.15) left


#set bmargin 0
set tmargin 0.1
set lmargin 0
set rmargin 0.1

set label "{/Times-Bold= Use Case VIII,}\n{/Times-Bold= Intel}"                           at first 1, graph  0.9 left

set errorbars 2.0
set pointintervalbox 0

plot INDIR."/plot-list-zoomin-abs-viii-java.dat" \
       i 0 using ($1 * 0.98):8:4:5 title "{/Helvetica=15 C{/Symbol \42}}"  with yerrorbars lt rgb "blue" 	      pt  6  ps 0.85 lw 1, \
    '' i 3 using ($1 * 0.94):8:4:5 title "{/Symbol \155}C++"               with yerrorbars lt rgb "dark-orange"	pt  8  ps 0.75 lw 1, \
    '' i 2 using ($1 * 1.02):8:4:5 title "LQ {/Helvetica=15 tailq}"        with yerrorbars lt rgb "magenta"	      pt  10 ps 0.85 lw 1