#pragma once

#include <iostream.hfa>
#include "vec.hfa"

forall (otype T) {
    struct vec4 {
        T x, y, z, w;
    };
}


forall (otype T) {
    static inline {

    void ?{}(vec4(T)& v, T x, T y, T z, T w) {
        v.[x, y, z, w] = [x, y, z, w];
    }

    forall(| zero_assign(T))
    void ?{}(vec4(T)& vec, zero_t) with (vec) {
        x = y = z = w = 0;
    }

    void ?{}(vec4(T)& vec, T val) with (vec) {
        x = y = z = w = val;
    }

    void ?{}(vec4(T)& vec, vec4(T) other) with (vec) {
        [x,y,z,w] = other.[x,y,z,w];
    }

    // Assignment
    void ?=?(vec4(T)& vec, vec4(T) other) with (vec) {
        [x,y,z,w] = other.[x,y,z,w];
    }
    forall(| zero_assign(T))
    void ?=?(vec4(T)& vec, zero_t) with (vec) {
        x = y = z = w = 0;
    }

    // Primitive mathematical operations

    // Subtraction

    forall(| subtract(T)) {
    vec4(T) ?-?(vec4(T) u, vec4(T) v) { // TODO( can't make this const ref )
        return [u.x - v.x, u.y - v.y, u.z - v.z, u.w - v.w];
    }
    vec4(T)& ?-=?(vec4(T)& u, vec4(T) v) {
        u = u - v;
        return u;
    }
    }

    forall(| negate(T)) {
    vec4(T) -?(vec4(T) v) with (v) {
        return [-x, -y, -z, -w];
    }
    }

    // Addition
    forall(| add(T)) {
    vec4(T) ?+?(vec4(T) u, vec4(T) v) { // TODO( can't make this const ref )
        return [u.x + v.x, u.y + v.y, u.z + v.z, u.w + v.w];
    }
    vec4(T)& ?+=?(vec4(T)& u, vec4(T) v) {
        u = u + v;
        return u;
    }
    }

    // Scalar Multiplication
    forall(| multiply(T)) {
    vec4(T) ?*?(vec4(T) v, T scalar) with (v) { // TODO (can't make this const ref)
        return [x * scalar, y * scalar, z * scalar, w * scalar];
    }
    vec4(T) ?*?(T scalar, vec4(T) v) { // TODO (can't make this const ref)
        return v * scalar;
    }
    vec4(T)& ?*=?(vec4(T)& v, T scalar) {
        v = v * scalar;
        return v;
    }
    }

    // Scalar Division
    forall(| divide(T)) {
    vec4(T) ?/?(vec4(T) v, T scalar) with (v) {
        return [x / scalar, y / scalar, z / scalar, w / scalar];
    }
    vec4(T)& ?/=?(vec4(T)& v, T scalar) with (v) {
        v = v / scalar;
        return v;
    }
    }

    // Relational Operators
    forall(| equality(T)) {
    bool ?==?(vec4(T) u, vec4(T) v) with (u) {
        return x == v.x && y == v.y && z == v.z && w == v.w;
    }
    bool ?!=?(vec4(T) u, vec4(T) v) {
        return !(u == v);
    }
    }

    // Geometric functions
    forall(| add(T) | multiply(T))
    T dot(vec4(T) u, vec4(T) v) {
        return u.x * v.x + u.y * v.y + u.z * v.z + u.w * v.w;
    }

    } // static inline
}

forall(dtype ostype, otype T | writeable(T, ostype)) {
    ostype & ?|?(ostype & os, vec4(T) v) with (v) {
        return os | '<' | x | ',' | y | ',' | z | ',' | w | '>';
    }
    void ?|?(ostype & os, vec4(T) v ) with (v) {
        (ostype &)(os | v); ends(os);
    }
}