source: tests/loopctrl.cfa @ ff36907

pthread-emulation
Last change on this file since ff36907 was ff36907, checked in by Peter A. Buhr <pabuhr@…>, 4 months ago

update loop-control test and expected output

  • Property mode set to 100644
File size: 7.6 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// loopctrl.cfa --
8//
9// Author           : Peter A. Buhr
10// Created On       : Wed Aug  8 18:32:59 2018
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Tue Aug  9 20:42:27 2022
13// Update Count     : 145
14//
15
16#include <fstream.hfa>
17
18void fred() {
19        // Test all possible loop syntax.
20
21        int s = 0, c = 10, i = 2;
22
23        for ( c ) { sout | "A"; }                                               sout | nl;
24        for ( ~= c ) { sout | "B"; }                                    sout | nl;
25        for ( -~ c ) { sout | "C"; }                                    sout | nl;
26        for ( -~= c ) { sout | "D"; }                                   sout | nl;
27
28        for ( s ~ c ) { sout | "A"; }                                   sout | nl;
29        for ( s ~= c ) { sout | "B"; }                                  sout | nl;
30        for ( s -~ c ) { sout | "C"; }                                  sout | nl;
31        for ( s -~= c ) { sout | "D"; }                                 sout | nl;
32
33        for ( s ~ c ~ i ) { sout | "A"; }                               sout | nl;
34        for ( s ~= c ~ i ) { sout | "B"; }                              sout | nl;
35        for ( s -~ c ~ i ) { sout | "C"; }                              sout | nl;
36        for ( s -~= c ~ i ) { sout | "D"; }                             sout | nl;
37
38        for ( j; c ) { sout | j; }                                                      sout | nl;
39        for ( j; ~= c ) { sout | j; }                                   sout | nl;
40        for ( j; -~ c ) { sout | j; }                                   sout | nl;
41        for ( j; -~= c ) { sout | j; }                                  sout | nl;
42
43        for ( j; s ~ c ) { sout | j; }                                  sout | nl;
44        for ( j; s ~= c ) { sout | j; }                                 sout | nl;
45        for ( j; s -~ c ) { sout | j; }                                 sout | nl;
46        for ( j; s -~= c ) { sout | j; }                                sout | nl;
47
48        for ( j; s ~ c ~ i ) { sout | j; }                              sout | nl;
49        for ( j; s ~= c ~ i ) { sout | j; }                             sout | nl;
50        for ( j; s -~ c ~ i ) { sout | j; }                             sout | nl;
51        for ( j; s -~= c ~ i ) { sout | j; }                    sout | nl;
52
53        // CANNOT DIRECTLY INITIALIZE INDEX VARIABLE, ONLY SINGLE LOOP INDEX VARIABLE IN DECLARATION
54
55        for ( j; c ) { sout | j; }                                              sout | nl;
56        for ( int j; c ) { sout | j; }                                  sout | nl;
57        for ( int j; ~= c ) { sout | j; }                               sout | nl;
58        for ( int j; -~ c ) { sout | j; }                               sout | nl;
59        for ( int j; -~= c ) { sout | j; }                              sout | nl;
60
61        for ( int j; s ~ c ) { sout | j; }                              sout | nl;
62        for ( int j; s ~= c ) { sout | j; }                             sout | nl;
63        for ( int j; s -~ c ) { sout | j; }                             sout | nl;
64        for ( int j; s -~= c ) { sout | j; }                    sout | nl;
65
66        for ( int j; s ~ c ~ i ) { sout | j; }                  sout | nl;
67        for ( int j; s ~= c ~ i ) { sout | j; }                 sout | nl;
68        for ( int j; s -~ c ~ i ) { sout | j; }                 sout | nl;
69        for ( int j; s -~= c ~ i ) { sout | j; }                sout | nl;
70
71        for ( j; s ~ @ ) { if ( j == 10 ) break; sout | j; }                            sout | nl;
72        for ( j; s -~ @ ) { if ( j == -10 ) break; sout | j; }                          sout | nl;
73        for ( j; s ~ @ ~ i ) { if ( j == 10 ) break; sout | j; }                        sout | nl;
74        for ( j; s -~ @ ~ i ) { if ( j == -10 ) break; sout | j; }                      sout | nl;
75        for ( j; s ~ @ ~ @ ) { if ( j == 10 ) break; sout | j; j += 1; }        sout | nl;
76
77        for ( int j; s ~ @ ) { if ( j == 10 ) break; sout | j; j += 1; }        sout | nl;
78        for ( int j; s -~ @ ) { if ( j == -10 ) break; sout | j; j -= 1; }      sout | nl;
79        for ( int j; s ~ @ ~ i ) { if ( j == 10 ) break; sout | j; }            sout | nl;
80        for ( int j; s -~ @ ~ i ) { if ( j == -10 ) break; sout | j; }          sout | nl;
81        for ( int j; s ~ @ ~ @ ) { if ( j == 10 ) break; sout | j; j += 1; } sout | nl;
82
83        // enum E { A, B, C, D };
84        // for ( e; A ~= C ) { sout | j; }
85        // for ( e; A ~= D ) { sout | j; }
86        // for ( e; A -~= D ~ 2 ) { sout | j; }
87        // for ( e; E ) { sout | j; }
88        // for ( e; -~ E ) { sout | j; }
89}
90
91struct S { int i, j; };
92void ?{}( S & s ) { s.[i, j] = 0; }
93void ?{}( S & s, int i ) { s.[i, j] = [i, 0]; }
94void ?{}( S & s, int i, int j ) { s.[i, j] = [i, j]; }
95void ?{}( S & s, zero_t ) { s.[i, j] = 0; }
96void ?{}( S & s, one_t ) { s.[i, j] = 1; }
97int ?<?( S t1, S t2 ) { return t1.i < t2.i && t1.j < t2.j; }
98int ?<=?( S t1, S t2 ) { return t1.i <= t2.i && t1.j <= t2.j; }
99int ?>?( S t1, S t2 ) { return t1.i > t2.i && t1.j > t2.j; }
100int ?>=?( S t1, S t2 ) { return t1.i >= t2.i && t1.j >= t2.j; }
101S ?=?( S & t1, S t2 ) { t1.i = t2.i; t1.j = t2.j; return t1; }
102S ?+=?( S & t1, S t2 ) { t1.i += t2.i; t1.j += t2.j; return t1; }
103S ?+=?( S & t, one_t ) { t.i += 1; t.j += 1; return t; }
104S ?-=?( S & t1, S t2 ) { t1.i -= t2.i; t1.j -= t2.j; return t1; }
105S ?-=?( S & t, one_t ) { t.i -= 1; t.j -= 1; return t; }
106ofstream & ?|?( ofstream & os, S v ) { return os | '(' | v.i | v.j | ')'; }
107void & ?|?( ofstream & os, S v ) { (ofstream &)(os | v); ends( os ); }
108
109int main() {
110        // Test some loop options.
111
112        sout | nlOff;                                                                           // turn off auto newline
113        while () { sout | "empty"; break; }                                     sout | nl;
114        do { sout | "empty"; break; } while ();                         sout | nl;
115        for () { sout | "empty"; break; }                                       sout | nl | nl;
116
117        for ( 0 ) { sout | "A"; }                                                       sout | "zero" | nl;
118        for ( 1 ) { sout | "A"; }                                                       sout | nl;
119        for ( 10 ) { sout | "A"; }                                                      sout | nl;
120        for ( ~= 10 ) { sout | "A"; }                                           sout | nl;
121        for ( 1 ~= 10 ~ 2 ) { sout | "B"; }                                     sout | nl;
122        for ( 1 -~= 10 ~ 2 ) { sout | "C"; }                            sout | nl;
123        for ( 0.5 ~ 5.5 ) { sout | "D"; }                                       sout | nl;
124        for ( 0.5 -~ 5.5 ) { sout | "E"; }                                      sout | nl | nl;
125
126        for ( i; 10 ) { sout | i; }                                                     sout | nl;
127        for ( i; ~= 10 ) { sout | i; }                                          sout | nl;
128        for ( i; 1 ~= 10 ~ 2 ) { sout | i; }                            sout | nl;
129        for ( i; 1 -~= 10 ~ 2 ) { sout | i; }                           sout | nl;
130        for ( i; 0.5 ~ 5.5 ) { sout | i; }                                      sout | nl;
131        for ( i; 0.5 -~ 5.5 ) { sout | i; }                                     sout | nl;
132        for ( ui; 2u ~= 10u ~ 2u ) { sout | ui; }                       sout | nl;
133        for ( ui; 2u -~= 10u ~ 2u ) { sout | ui; }                      sout | nl | nl;
134
135        // @ means do nothing
136        for ( i; 1 ~ @ ) {
137          if ( i > 10 ) break;
138                sout | i;
139        }                                                                                                       sout | nl;
140        for ( i; 10 -~ @ ) {
141          if ( i < 0 ) break;
142                sout | i;
143        }                                                                                                       sout | nl;
144        for ( i; 2 ~ @ ~ 2 ) {
145          if ( i > 10 ) break;
146                sout | i;
147        }                                                                                                       sout | nl;
148        for ( i; 2.1 ~ @ ~ @ ) {
149          if ( i > 10.5 ) break;
150                sout | i;
151                i += 1.7;
152        }                                                                                                       sout | nl;
153        for ( i; 10 -~ @ ~ 2 ) {
154          if ( i < 0 ) break;
155                sout | i;
156        }                                                                                                       sout | nl;
157        for ( i; 12.1 ~ @ ~ @ ) {
158          if ( i < 2.5 ) break;
159                sout | i;
160                i -= 1.7;
161        }                                                                                                       sout | nl | nl;
162       
163        enum { N = 10 };
164        for ( N ) { sout | "N"; }                                                       sout | nl;
165        for ( i; N ) { sout | i; }                                                      sout | nl;
166        for ( i; ~=  N ) { sout | i; }                                          sout | nl;
167        for ( i; -~= N ) { sout | i; }                                          sout | nl | nl;
168
169        const int start = 3, comp = 10, inc = 2;
170        for ( i; start ~ comp ~ inc + 1 ) { sout | i; }         sout | nl | nl;
171
172        for ( i; 10 : j; -5 ~ @ ) { sout | i | j; } sout | nl;
173        for ( i; 10 : j; -5 -~ @ ) { sout | i | j; } sout | nl;
174        for ( i; 10 : j; -5 ~ @ ~ 2 ) { sout | i | j; } sout | nl;
175        for ( i; 10 : j; -5 -~ @ ~ 2 ) { sout | i | j; } sout | nl | nl;
176
177        for ( j; -5 ~ @ : i; 10 ) { sout | i | j; } sout | nl;
178        for ( j; -5 -~ @ : i; 10 ) { sout | i | j; } sout | nl;
179        for ( j; -5 ~ @ ~ 2 : i; 10 ) { sout | i | j; } sout | nl;
180        for ( j; -5 -~ @ ~ 2 : i; 10 ) { sout | i | j; } sout | nl | nl;
181
182        for ( j; -5 -~ @ ~ 2 : i; 10 : k; 1.5 ~ @ ) { sout | i | j | k; } sout | nl;
183        for ( j; -5 -~ @ ~ 2 : k; 1.5 ~ @ : i; 10 ) { sout | i | j | k; } sout | nl;
184        for ( k; 1.5 ~ @ : j; -5 -~ @ ~ 2 : i; 10 ) { sout | i | j | k; } sout | nl;
185
186        for ( S s = (S){0}; s < (S){10,10}; s += (S){1} ) { sout | s; } sout | nl;
187        for ( s; (S){10,10} ) { sout | s; } sout | nl;
188        sout | nl;
189        for ( s; (S){0} ~ (S){10,10} ) { sout | s; }             sout | nl;
190        for ( s; (S){0} ~ (S){10,10} ~ (S){1} ) { sout | s; } sout | nl;
191        for ( s; (S){0} ~= (S){10,10} ) { sout | s; }            sout | nl;
192        for ( s; (S){0} ~= (S){10,10} ~ (S){1} ) { sout | s; } sout | nl;
193        sout | nl;
194        for ( s; (S){0} -~  (S){10,10} ) { sout | s; }           sout | nl;
195        for ( s; (S){0} -~  (S){10,10} ~ (S){1} ) { sout | s; } sout | nl;
196        for ( s; (S){0} -~= (S){10,10} ) { sout | s; }           sout | nl;
197        for ( s; (S){0} -~= (S){10,10} ~ (S){1} ) { sout | s; } sout | nl | nl;
198
199        fred();
200}
201
202// Local Variables: //
203// tab-width: 4 //
204// compile-command: "cfa loopctrl.cfa" //
205// End: //
Note: See TracBrowser for help on using the repository browser.