source: tests/exceptions/resume.cfa @ 6d43cdde

// Resumption Exception Tests

#include "except-mac.hfa"
#include "except-io.hfa"

TRIVIAL_EXCEPTION(yin);
TRIVIAL_EXCEPTION(yang);
TRIVIAL_EXCEPTION(zen);
TRIVIAL_EXCEPTION(moment_of, zen);

int main(int argc, char * argv[]) {
        // The simple throw catchResume test.
        try {
                loud_exit a = "simple try clause";
                printf("simple throw\n");
                THROW_RESUME(&(zen){});
                printf("end of try clause\n");
        } catchResume (zen * error) {
                loud_exit a = "simple catch clause";
                printf("simple catch\n");
        }
        printf("\n");

        // Catch a parent of the given exception.
        try {
                printf("throwing child exception\n");
                THROW_RESUME(&(moment_of){});
        } catchResume (zen *) {
                printf("inner parent match\n");
        } catchResume (moment_of *) {
                printf("outer exact match\n");
        }
        printf("\n");

        // Don't catch if handler does not match exception.
        try {
                try {
                        THROW_RESUME(&(yin){});
                } catchResume (zen *) {
                        printf("caught yin as zen\n");
                }
        } catchResume (yang *) {
                printf("caught yin as yang\n");
        } catchResume (yin *) {
                printf("caught yin as yin\n");
        }
        printf("\n");

        // Test rethrowing an exception.
        try {
                try {
                        loud_exit a = "rethrow inner try";
                        printf("rethrow inner try\n");
                        THROW_RESUME(&(zen){});
                } catchResume (zen *) {
                        loud_exit a = "rethrowing catch clause";
                        printf("caught throw, will rethrow\n");
                        throwResume;
                }
        } catchResume (zen *) {
                loud_exit a = "rethrow catch clause";
                printf("caught rethrow\n");
        }
        printf("\n");

        // Throw a different exception in a catch.
        try {
                try {
                        THROW_RESUME(&(yin){});
                } catchResume (yin *) {
                        printf("caught yin, will throw yang\n");
                        THROW_RESUME(&(yang){});
                } catchResume (yang *) {
                        printf("caught exception from same try\n");
                }
        } catchResume (yang *) {
                printf("caught yang\n");
        }
#ifdef FAILING
        printf("\n");

        // Another throw in the catch does not interfere.
        try {
                try {
                        printf("throwing first exception\n");
                        THROW_RESUME(&(yin){});
                } catchResume (yin *) {
                        printf("caught first exception\n");
                        try {
                                printf("throwing second exception\n");
                                THROW_RESUME(&(yang){});
                        } catchResume (yang *) {
                                printf("caught second exception\n");
                        }
                        throwResume;
                }
        } catchResume (yin *) {
                printf("recaught first exception\n");
        } catchResume (yang *) {
                printf("caught second exception (bad location)\n");
        }
#endif
}