source: tests/concurrent/barrier/order.cfa @ 93b8cf4

//
// Cforall Version 1.0.0 Copyright (C) 2022 University of Waterloo
//
// The contents of this file are covered under the licence agreement in the
// file "LICENCE" distributed with Cforall.
//
// concurrent/barrier/order.cfa -- validates barriers the return value of
//                                 barrier block
//
// Author           : Thierry Delisle
// Created On       : Fri Apr 01 11:39:09 2022
// Last Modified By :
// Last Modified On :
// Update Count     :
//

#include <concurrency/barrier.hfa>
#include <fstream.hfa>
#include <mutex_stmt.hfa>
#include <thread.hfa>

const int NUM_LAPS = 173;
const int NUM_THREADS = 11;

barrier bar = { NUM_THREADS };
volatile int * generation;

thread Tester {};
void main( Tester & ) {
        for(l; NUM_LAPS) {
                int ret = block(bar);
                int g = generation[ret];
                if(g != l) {
                        sout | "Gen" | l | ": Expeced generation at" | ret | "to be" | l | "was" | g;
                }
                generation[ret] = g+1;
        }
}

int main() {
        volatile int gen_data[NUM_THREADS];
        for(t; NUM_THREADS)
                gen_data[t] = 0;

        generation = gen_data;

        processor p[4];
        {
                Tester testers[NUM_THREADS];
        }
        sout | "done";
}