source: tests/collections/queue.cfa@ 62a7cc0

#include <fstream.hfa>
#include <stdlib.hfa>                                                                   // new, delete
#include <bits/queue.hfa>

int main() {
        // Fred test

        struct Fred {
                inline Colable;                                                                 // Plan 9 inheritance
                int i;
        };
        void ?{}( Fred & fred ) { abort(); }
        void ?{}( Fred & fred, int p ) with( fred ) {
                i = p;
        }
        Fred *& Next( Fred * n ) {
                return (Fred *)Next( (Colable *)n );
        }

        Queue(Fred) fred;
        QueueIter(Fred) fredIter = { fred };
        Fred & f;

        sout | nlOff;                                                                           // turn off auto newline

        for ( ; fredIter >> f; ) {                                                      // empty list
                sout | f.i | ' ';
        }
        sout | "empty" | nl;
        
        for ( i; 10 ) {
                add( fred, *new( 2 * i ) );
        }

        sout | head( fred ).i | tail( fred ).i | nl;

        for ( QueueIter(Fred) iter = { fred }; iter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( i; 9 ) {
                delete( &drop( fred ) );
        }

        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;
        
        for ( i; 10 ) {
                add( fred, *new( 2 * i + 1 ) );
        }

        Fred * head = new( -1 ), tail = { -2 };
        addHead( fred, *head );
        addTail( fred, tail );

        sout | head( fred ).i | succ( fred, head )->i | tail( fred ).i | nl;
        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        remove( fred, *head );
        remove( fred, tail );
        delete( head );
        delete( &dropTail( fred ) );

        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( i; 5 ) {
                delete( &dropTail( fred ) );
        }
        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( over( fredIter, fred ); fredIter >> f; ) {
                delete( &remove( fred, f ) );
        }
        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | "empty" | nl;

        Fred & middle;
        for ( i; 10 ) {
                add( fred, *new( i ) );
                if ( i == 4 ) {
                        &middle = &tail( fred );
                }
        }
        for ( QueueIter(Fred) iter = { fred }; iter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        Queue(Fred) fred2;

        split( fred2, fred, middle );

        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( over( fredIter, fred2 ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        transfer( fred, fred2 );

        for ( over( fredIter, fred ); fredIter >> f; ) {
                sout | f.i | ' ';
        }
        sout | nl;

        for ( over( fredIter, fred ); fredIter >> f; ) {
                delete( &f );
        }

        // Mary test

        struct Mary {
                inline Fred;                                                                    // Plan 9 inheritance
                int j;
        };
        void ?{}( Mary & mary ) { abort(); }
        void ?{}( Mary & mary, int p ) with( mary ) {
                ((Fred &)mary){ p };
                j = p;
        }
        Mary *& Next( Mary * n ) {
                return (Mary *)Next( (Fred *)n );
        }

        Queue(Mary) mary;
        QueueIter(Mary) maryIter = { mary };
        Mary & m;

        for ( ; maryIter >> m; ) {                                                      // empty list
                sout | m.i | m.j | ' ';
        }
        sout | "empty" | nl;
        
        for ( i; 10 ) {
                add( mary, *new( 2 * i ) );
        }

        sout | head( mary ).i | tail( mary ).i | nl;

        for ( QueueIter(Mary) iter = { mary }; iter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;
        
        for ( i; 9 ) {
                delete( &drop( mary ) );
        }

        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;
        
        for ( i; 10 ) {
                add( mary, *new( 2 * i + 1 ) );
        }

        Mary * head = new( -1 ), tail = { -1 };
        addHead( mary, *head );
        addTail( mary, tail );
        sout | head( mary ).i | succ( mary, head )->i | tail( mary ).i | nl;
        remove( mary, *head );
        remove( mary, tail );
        delete( (Mary *)head );
        delete( &dropTail( mary ) );

        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;

        for ( over( maryIter, mary ); maryIter >> m; ) {
                delete( &remove( mary, m ) );
        }

        Mary & middle;
        for ( i; 10 ) {
                add( mary, *new( i ) );
                if ( i == 4 ) {
                        &middle = &tail( mary );
                }
        }
        for ( QueueIter(Mary) iter = { mary }; iter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;

        Queue(Mary) mary2;

        split( mary2, mary, middle );

        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;
        for ( over( maryIter, mary2 ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;

        transfer( mary, mary2 );

        for ( over( maryIter, mary ); maryIter >> m; ) {
                sout | m.i | m.j | ' ';
        }
        sout | nl;
        for ( over( maryIter, mary ); maryIter >> m; ) {
                delete( &m );
        }
}