Context Navigation

parser.yy @ fa463f1

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newwith_gc

Last change on this file since fa463f1 was 413ad05, checked in by Peter A. Buhr <pabuhr@…>, 8 years ago
more refactoring of parser code
Property mode set to `100644`
File size: 103.3 KB

Line
1	//
2	// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3	//
4	// The contents of this file are covered under the licence agreement in the
5	// file "LICENCE" distributed with Cforall.
6	//
7	// cfa.y --
8	//
9	// Author : Peter A. Buhr
10	// Created On : Sat Sep 1 20:22:55 2001
11	// Last Modified By : Peter A. Buhr
12	// Last Modified On : Fri Aug 26 16:45:44 2016
13	// Update Count : 1964
14	//
15
16	// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17	// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18	// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19	// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20	// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21	// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23	// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24	// the grammar.
25
26	// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27	//
28	// 1. designation with '=' (use ':' instead)
29	//
30	// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31	// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32	//
33	// 1. designation with and without '=' (use ':' instead)
34	// 2. attributes not allowed in parenthesis of declarator
35	//
36	// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37	// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38	// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39	// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40	// grammar rule.
41
42	%{
43	#define YYDEBUG_LEXER_TEXT (yylval) // lexer loads this up each time
44	#define YYDEBUG 1 // get the pretty debugging code to compile
45
46	#undef __GNUC_MINOR__
47
48	#include <cstdio>
49	#include <stack>
50	#include "lex.h"
51	#include "parser.h"
52	#include "ParseNode.h"
53	#include "TypedefTable.h"
54	#include "TypeData.h"
55	#include "LinkageSpec.h"
56
57	extern DeclarationNode * parseTree;
58	extern LinkageSpec::Spec linkage;
59	extern TypedefTable typedefTable;
60
61	std::stack< LinkageSpec::Spec > linkageStack;
62
63	void appendStr( std::string to, std::string from ) {
64	// "abc" "def" "ghi" => "abcdefghi", remove new text from quotes and insert before last quote in old string.
65	to->insert( to->length() - 1, from->substr( 1, from->length() - 2 ) );
66	} // appendStr
67	%}
68
69	//*********************** TERMINAL TOKENS ******************************
70
71	// keywords
72	%token TYPEDEF
73	%token AUTO EXTERN REGISTER STATIC
74	%token INLINE // C99
75	%token FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
76	%token CONST VOLATILE
77	%token RESTRICT // C99
78	%token FORALL LVALUE // CFA
79	%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
80	%token VALIST // GCC
81	%token BOOL COMPLEX IMAGINARY // C99
82	%token TYPEOF LABEL // GCC
83	%token ENUM STRUCT UNION
84	%token OTYPE FTYPE DTYPE TRAIT // CFA
85	%token SIZEOF OFFSETOF
86	%token ATTRIBUTE EXTENSION // GCC
87	%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
88	%token CHOOSE DISABLE ENABLE FALLTHRU TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT // CFA
89	%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
90	%token ALIGNAS ALIGNOF ATOMIC GENERIC NORETURN STATICASSERT THREADLOCAL // C11
91
92	// names and constants: lexer differentiates between identifier and typedef names
93	%token<tok> IDENTIFIER QUOTED_IDENTIFIER TYPEDEFname TYPEGENname
94	%token<tok> ATTR_IDENTIFIER ATTR_TYPEDEFname ATTR_TYPEGENname
95	%token<tok> INTEGERconstant FLOATINGconstant CHARACTERconstant STRINGliteral
96	%token<tok> ZERO ONE // CFA
97
98	// multi-character operators
99	%token ARROW // ->
100	%token ICR DECR // ++ --
101	%token LS RS // << >>
102	%token LE GE EQ NE // <= >= == !=
103	%token ANDAND OROR // && \|\|
104	%token ELLIPSIS // ...
105
106	%token MULTassign DIVassign MODassign // *= /= %=/
107	%token PLUSassign MINUSassign // += -=
108	%token LSassign RSassign // <<= >>=
109	%token ANDassign ERassign ORassign // &= ^= \|=
110
111	%token ATassign // @=
112
113	// Types declaration
114	%union
115	{
116	Token tok;
117	ParseNode *pn;
118	ExpressionNode *en;
119	DeclarationNode *decl;
120	DeclarationNode::Aggregate aggKey;
121	DeclarationNode::TypeClass tclass;
122	StatementNode *sn;
123	ConstantExpr *constant;
124	ForCtl *fctl;
125	LabelNode *label;
126	InitializerNode *in;
127	OperKinds op;
128	std::string *str;
129	bool flag;
130	}
131
132	%type<tok> identifier no_01_identifier no_attr_identifier zero_one
133	%type<tok> identifier_or_type_name no_attr_identifier_or_type_name no_01_identifier_or_type_name
134	%type<constant> string_literal
135	%type<str> string_literal_list
136
137	// expressions
138	%type<en> constant
139	%type<en> tuple tuple_expression_list
140	%type<op> ptrref_operator unary_operator assignment_operator
141	%type<en> primary_expression postfix_expression unary_expression
142	%type<en> cast_expression multiplicative_expression additive_expression shift_expression
143	%type<en> relational_expression equality_expression AND_expression exclusive_OR_expression
144	%type<en> inclusive_OR_expression logical_AND_expression logical_OR_expression conditional_expression
145	%type<en> constant_expression assignment_expression assignment_expression_opt
146	%type<en> comma_expression comma_expression_opt
147	%type<en> argument_expression_list argument_expression assignment_opt
148	%type<fctl> for_control_expression
149	%type<en> subrange
150	%type<en> asm_operands_opt asm_operands_list asm_operand
151	%type<label> label_list
152	%type<en> asm_clobbers_list_opt
153	%type<flag> asm_volatile_opt
154
155	// statements
156	%type<sn> labeled_statement compound_statement expression_statement selection_statement
157	%type<sn> iteration_statement jump_statement exception_statement asm_statement
158	%type<sn> fall_through_opt fall_through
159	%type<sn> statement statement_list
160	%type<sn> block_item_list block_item
161	%type<sn> case_clause
162	%type<en> case_value
163	%type<sn> case_value_list case_label case_label_list
164	%type<sn> switch_clause_list_opt switch_clause_list choose_clause_list_opt choose_clause_list
165	%type<sn> handler_list handler_clause finally_clause
166
167	// declarations
168	%type<decl> abstract_array abstract_declarator abstract_function abstract_parameter_array
169	%type<decl> abstract_parameter_declaration abstract_parameter_declarator abstract_parameter_function
170	%type<decl> abstract_parameter_ptr abstract_ptr
171
172	%type<aggKey> aggregate_key
173	%type<decl> aggregate_name
174
175	%type<decl> array_dimension array_parameter_1st_dimension array_parameter_dimension multi_array_dimension
176
177	%type<decl> assertion assertion_list_opt
178
179	%type<en> bit_subrange_size_opt bit_subrange_size
180
181	%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type_name indirect_type_name
182
183	%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
184
185	%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
186	%type<decl> declaration_specifier declarator declaring_list
187
188	%type<decl> elaborated_type_name
189
190	%type<decl> enumerator_list enum_name
191	%type<en> enumerator_value_opt
192
193	%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
194
195	%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
196	%type<en> field field_list
197
198	%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
199
200	%type<decl> identifier_parameter_array identifier_parameter_declarator identifier_parameter_function
201	%type<decl> identifier_parameter_ptr identifier_list
202
203	%type<decl> new_abstract_array new_abstract_declarator_no_tuple new_abstract_declarator_tuple
204	%type<decl> new_abstract_function new_abstract_parameter_declaration new_abstract_parameter_list
205	%type<decl> new_abstract_ptr new_abstract_tuple
206
207	%type<decl> new_array_parameter_1st_dimension
208
209	%type<decl> new_trait_declaring_list new_declaration new_field_declaring_list
210	%type<decl> new_function_declaration new_function_return new_function_specifier
211
212	%type<decl> new_identifier_parameter_array new_identifier_parameter_declarator_no_tuple
213	%type<decl> new_identifier_parameter_declarator_tuple new_identifier_parameter_ptr
214
215	%type<decl> new_parameter_declaration new_parameter_list new_parameter_type_list new_parameter_type_list_opt
216
217	%type<decl> new_typedef_declaration new_variable_declaration new_variable_specifier
218
219	%type<decl> old_declaration old_declaration_list old_declaration_list_opt old_function_array
220	%type<decl> old_function_declarator old_function_no_ptr old_function_ptr
221
222	%type<decl> parameter_declaration parameter_list parameter_type_list
223	%type<decl> parameter_type_list_opt
224
225	%type<decl> paren_identifier paren_type
226
227	%type<decl> storage_class storage_class_list
228
229	%type<decl> sue_declaration_specifier sue_type_specifier
230
231	%type<tclass> type_class
232	%type<decl> type_declarator type_declarator_name type_declaring_list
233
234	%type<decl> typedef type_array typedef_declaration typedef_declaration_specifier typedef_expression
235	%type<decl> type_function type_parameter_array type_parameter_function type_parameter_ptr
236	%type<decl> type_parameter_redeclarator type_ptr variable_type_redeclarator typedef_type_specifier
237	%type<decl> typegen_declaration_specifier typegen_type_specifier typegen_name
238
239	%type<decl> type_name type_name_no_function
240	%type<decl> type_parameter type_parameter_list
241
242	%type<en> type_name_list
243
244	%type<decl> type_qualifier type_qualifier_name type_qualifier_list type_qualifier_list_opt type_specifier
245
246	%type<decl> variable_abstract_array variable_abstract_declarator variable_abstract_function
247	%type<decl> variable_abstract_ptr variable_array variable_declarator variable_function variable_ptr
248
249	%type<decl> attribute_list_opt attribute_list attribute
250
251	// initializers
252	%type<in> initializer initializer_list initializer_opt
253
254	// designators
255	%type<en> designator designator_list designation
256
257
258	// Handle single shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string
259	// is ambiguous:
260	// .---------. matches IF '(' comma_expression ')' statement
261	// if ( C ) S1 else S2
262	// `-----------------' matches IF '(' comma_expression ')' statement ELSE statement */
263
264	%nonassoc THEN // rule precedence for IF '(' comma_expression ')' statement
265	%nonassoc ELSE // token precedence for start of else clause in IF statement
266
267	%start translation_unit // parse-tree root
268
269	%%
270	//*********************** Namespace Management ******************************
271
272	// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
273	// "identifier" and "TYPEDEFname" that are lexically identical. While it is possible to write a purely context-free
274	// grammar, such a grammar would obscure the relationship between syntactic and semantic constructs. Hence, this
275	// grammar uses the ANSI style.
276	//
277	// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
278	// introduced through "forall" qualifiers), and by introducing "type generators" -- parametrized types. This latter
279	// type name creates a third class of identifiers that must be distinguished by the scanner.
280	//
281	// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
282	// accesses a data structure (the TypedefTable) to allow classification of an identifier that it has just read.
283	// Semantic actions during the parser update this data structure when the class of identifiers change.
284	//
285	// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its class in a
286	// local scope; it must revert to its original class at the end of the block. Since type names can be local to a
287	// particular declaration, each declaration is itself a scope. This requires distinguishing between type names that are
288	// local to the current declaration scope and those that persist past the end of the declaration (i.e., names defined in
289	// "typedef" or "type" declarations).
290	//
291	// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and closing of
292	// scopes. Every push must have a matching pop, although it is regrettable the matching pairs do not always occur
293	// within the same rule. These non-terminals may appear in more contexts than strictly necessary from a semantic point
294	// of view. Unfortunately, these extra rules are necessary to prevent parsing conflicts -- the parser may not have
295	// enough context and look-ahead information to decide whether a new scope is necessary, so the effect of these extra
296	// rules is to open a new scope unconditionally. As the grammar evolves, it may be neccesary to add or move around
297	// "push" and "pop" nonterminals to resolve conflicts of this sort.
298
299	push:
300	{ typedefTable.enterScope(); }
301	;
302
303	pop:
304	{ typedefTable.leaveScope(); }
305	;
306
307	//*********************** CONSTANTS ******************************
308
309	constant:
310	// ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
311	INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
312	\| FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
313	\| CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
314	;
315
316	identifier:
317	IDENTIFIER
318	\| ATTR_IDENTIFIER // CFA
319	\| zero_one // CFA
320	;
321
322	no_01_identifier:
323	IDENTIFIER
324	\| ATTR_IDENTIFIER // CFA
325	;
326
327	no_attr_identifier:
328	IDENTIFIER
329	\| zero_one // CFA
330	;
331
332	zero_one: // CFA
333	ZERO
334	\| ONE
335	;
336
337	string_literal:
338	string_literal_list { $$ = build_constantStr( *$1 ); }
339	;
340
341	string_literal_list: // juxtaposed strings are concatenated
342	STRINGliteral { $$ = $1; } // conversion from tok to str
343	\| string_literal_list STRINGliteral
344	{
345	appendStr( $1, $2 ); // append 2nd juxtaposed string to 1st
346	delete $2; // allocated by lexer
347	$$ = $1; // conversion from tok to str
348	}
349	;
350
351	//*********************** EXPRESSIONS ******************************
352
353	primary_expression:
354	IDENTIFIER // typedef name cannot be used as a variable name
355	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
356	\| zero_one
357	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
358	\| '(' comma_expression ')'
359	{ $$ = $2; }
360	\| '(' compound_statement ')' // GCC, lambda expression
361	{ $$ = new ExpressionNode( build_valexpr( $2 ) ); }
362	;
363
364	postfix_expression:
365	primary_expression
366	\| postfix_expression '[' push assignment_expression pop ']'
367	// CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
368	// matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
369	// little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
370	// equivalent to the old x[i,j].
371	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $4 ) ); }
372	\| postfix_expression '(' argument_expression_list ')'
373	{ $$ = new ExpressionNode( build_func( $1, $3 ) ); }
374	// ambiguity with .0 so space required after field-selection, e.g.
375	// struct S { int 0, 1; } s; s. 0 = 0; s. 1 = 1;
376	\| postfix_expression '.' no_attr_identifier
377	{ $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
378	\| postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
379	\| postfix_expression ARROW no_attr_identifier
380	{ $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
381	\| postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
382	\| postfix_expression ICR
383	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
384	\| postfix_expression DECR
385	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
386	\| '(' type_name_no_function ')' '{' initializer_list comma_opt '}' // C99
387	{ $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
388	\| postfix_expression '{' argument_expression_list '}' // CFA
389	{
390	Token fn;
391	fn.str = new std::string( "?{}" ); // location undefined
392	$$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) );
393	}
394	;
395
396	argument_expression_list:
397	argument_expression
398	\| argument_expression_list ',' argument_expression
399	{ $$ = (ExpressionNode *)( $1->set_last( $3 )); }
400	;
401
402	argument_expression:
403	// empty
404	{ $$ = 0; } // use default argument
405	\| assignment_expression
406	;
407
408	field_list: // CFA, tuple field selector
409	field
410	\| field_list ',' field { $$ = (ExpressionNode *)$1->set_last( $3 ); }
411	;
412
413	field: // CFA, tuple field selector
414	no_attr_identifier
415	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
416	// ambiguity with .0 so space required after field-selection, e.g.
417	// struct S { int 0, 1; } s; s. 0 = 0; s. 1 = 1;
418	\| no_attr_identifier '.' field
419	{ $$ = new ExpressionNode( build_fieldSel( $3, build_varref( $1 ) ) ); }
420	\| no_attr_identifier '.' '[' push field_list pop ']'
421	{ $$ = new ExpressionNode( build_fieldSel( $5, build_varref( $1 ) ) ); }
422	\| no_attr_identifier ARROW field
423	{ $$ = new ExpressionNode( build_pfieldSel( $3, build_varref( $1 ) ) ); }
424	\| no_attr_identifier ARROW '[' push field_list pop ']'
425	{ $$ = new ExpressionNode( build_pfieldSel( $5, build_varref( $1 ) ) ); }
426	;
427
428	unary_expression:
429	postfix_expression
430	// first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
431	// semantics checks, e.g., ++3, 3--, *3, &&3
432	\| constant
433	{ $$ = $1; }
434	\| string_literal
435	{ $$ = new ExpressionNode( $1 ); }
436	\| EXTENSION cast_expression // GCC
437	{ $$ = $2->set_extension( true ); }
438	// '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
439	// { * X; } // dereference X
440	// { * int X; } // CFA declaration of pointer to int
441	\| ptrref_operator cast_expression // CFA
442	{
443	switch ( $1 ) {
444	case OperKinds::AddressOf:
445	$$ = new ExpressionNode( build_addressOf( $2 ) );
446	break;
447	case OperKinds::PointTo:
448	$$ = new ExpressionNode( build_unary_val( $1, $2 ) );
449	break;
450	default:
451	assert( false );
452	}
453	}
454	\| unary_operator cast_expression
455	{ $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
456	\| ICR unary_expression
457	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
458	\| DECR unary_expression
459	{ $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
460	\| SIZEOF unary_expression
461	{ $$ = new ExpressionNode( build_sizeOfexpr( $2 ) ); }
462	\| SIZEOF '(' type_name_no_function ')'
463	{ $$ = new ExpressionNode( build_sizeOftype( $3 ) ); }
464	\| ALIGNOF unary_expression // GCC, variable alignment
465	{ $$ = new ExpressionNode( build_alignOfexpr( $2 ) ); }
466	\| ALIGNOF '(' type_name_no_function ')' // GCC, type alignment
467	{ $$ = new ExpressionNode( build_alignOftype( $3 ) ); }
468	\| OFFSETOF '(' type_name_no_function ',' no_attr_identifier ')'
469	{ $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
470	\| ATTR_IDENTIFIER
471	{ $$ = new ExpressionNode( build_attrexpr( build_varref( $1 ), nullptr ) ); }
472	\| ATTR_IDENTIFIER '(' argument_expression ')'
473	{ $$ = new ExpressionNode( build_attrexpr( build_varref( $1 ), $3 ) ); }
474	\| ATTR_IDENTIFIER '(' type_name ')'
475	{ $$ = new ExpressionNode( build_attrtype( build_varref( $1 ), $3 ) ); }
476	// \| ANDAND IDENTIFIER // GCC, address of label
477	// { $$ = new ExpressionNode( new OperatorNode( OperKinds::LabelAddress ), new ExpressionNode( build_varref( $2, true ) ); }
478	;
479
480	ptrref_operator:
481	'*' { $$ = OperKinds::PointTo; }
482	\| '&' { $$ = OperKinds::AddressOf; }
483	// GCC, address of label must be handled by semantic check for ref,ref,label
484	// \| ANDAND { $$ = OperKinds::And; }
485	;
486
487	unary_operator:
488	'+' { $$ = OperKinds::UnPlus; }
489	\| '-' { $$ = OperKinds::UnMinus; }
490	\| '!' { $$ = OperKinds::Neg; }
491	\| '~' { $$ = OperKinds::BitNeg; }
492	;
493
494	cast_expression:
495	unary_expression
496	\| '(' type_name_no_function ')' cast_expression
497	{ $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
498	\| '(' type_name_no_function ')' tuple
499	{ $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
500	;
501
502	multiplicative_expression:
503	cast_expression
504	\| multiplicative_expression '*' cast_expression
505	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
506	\| multiplicative_expression '/' cast_expression
507	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
508	\| multiplicative_expression '%' cast_expression
509	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
510	;
511
512	additive_expression:
513	multiplicative_expression
514	\| additive_expression '+' multiplicative_expression
515	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
516	\| additive_expression '-' multiplicative_expression
517	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
518	;
519
520	shift_expression:
521	additive_expression
522	\| shift_expression LS additive_expression
523	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
524	\| shift_expression RS additive_expression
525	{ $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
526	;
527
528	relational_expression:
529	shift_expression
530	\| relational_expression '<' shift_expression
531	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
532	\| relational_expression '>' shift_expression
533	{ $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
534	\| relational_expression LE shift_expression
535	{ $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
536	\| relational_expression GE shift_expression
537	{ $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
538	;
539
540	equality_expression:
541	relational_expression
542	\| equality_expression EQ relational_expression
543	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
544	\| equality_expression NE relational_expression
545	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
546	;
547
548	AND_expression:
549	equality_expression
550	\| AND_expression '&' equality_expression
551	{ $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
552	;
553
554	exclusive_OR_expression:
555	AND_expression
556	\| exclusive_OR_expression '^' AND_expression
557	{ $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
558	;
559
560	inclusive_OR_expression:
561	exclusive_OR_expression
562	\| inclusive_OR_expression '\|' exclusive_OR_expression
563	{ $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
564	;
565
566	logical_AND_expression:
567	inclusive_OR_expression
568	\| logical_AND_expression ANDAND inclusive_OR_expression
569	{ $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
570	;
571
572	logical_OR_expression:
573	logical_AND_expression
574	\| logical_OR_expression OROR logical_AND_expression
575	{ $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
576	;
577
578	conditional_expression:
579	logical_OR_expression
580	\| logical_OR_expression '?' comma_expression ':' conditional_expression
581	{ $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
582	// FIX ME: this hack computes $1 twice
583	\| logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
584	{ $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
585	\| logical_OR_expression '?' comma_expression ':' tuple // CFA, tuple expression
586	{ $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
587	;
588
589	constant_expression:
590	conditional_expression
591	;
592
593	assignment_expression:
594	// CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
595	conditional_expression
596	\| unary_expression assignment_operator assignment_expression
597	{ $$ = new ExpressionNode( build_binary_ptr( $2, $1, $3 ) ); }
598	\| tuple assignment_opt // CFA, tuple expression
599	{ $$ = ( $2 == 0 ) ? $1 : new ExpressionNode( build_binary_ptr( OperKinds::Assign, $1, $2 ) ); }
600	;
601
602	assignment_expression_opt:
603	// empty
604	{ $$ = nullptr; }
605	\| assignment_expression
606	;
607
608	assignment_operator:
609	'=' { $$ = OperKinds::Assign; }
610	\| ATassign { $$ = OperKinds::AtAssn; }
611	\| MULTassign { $$ = OperKinds::MulAssn; }
612	\| DIVassign { $$ = OperKinds::DivAssn; }
613	\| MODassign { $$ = OperKinds::ModAssn; }
614	\| PLUSassign { $$ = OperKinds::PlusAssn; }
615	\| MINUSassign { $$ = OperKinds::MinusAssn; }
616	\| LSassign { $$ = OperKinds::LSAssn; }
617	\| RSassign { $$ = OperKinds::RSAssn; }
618	\| ANDassign { $$ = OperKinds::AndAssn; }
619	\| ERassign { $$ = OperKinds::ERAssn; }
620	\| ORassign { $$ = OperKinds::OrAssn; }
621	;
622
623	tuple: // CFA, tuple
624	// CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
625	// comma_expression in new_identifier_parameter_array and new_abstract_array
626	'[' ']'
627	{ $$ = new ExpressionNode( build_tuple() ); }
628	\| '[' push assignment_expression pop ']'
629	{ $$ = new ExpressionNode( build_tuple( $3 ) ); }
630	\| '[' push ',' tuple_expression_list pop ']'
631	{ $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
632	\| '[' push assignment_expression ',' tuple_expression_list pop ']'
633	{ $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
634	;
635
636	tuple_expression_list:
637	assignment_expression_opt
638	\| tuple_expression_list ',' assignment_expression_opt
639	{ $$ = (ExpressionNode *)$1->set_last( $3 ); }
640	;
641
642	comma_expression:
643	assignment_expression
644	\| comma_expression ',' assignment_expression
645	{ $$ = new ExpressionNode( build_comma( $1, $3 ) ); }
646	;
647
648	comma_expression_opt:
649	// empty
650	{ $$ = 0; }
651	\| comma_expression
652	;
653
654	//************************* STATEMENTS *****************************
655
656	statement:
657	labeled_statement
658	\| compound_statement
659	\| expression_statement { $$ = $1; }
660	\| selection_statement
661	\| iteration_statement
662	\| jump_statement
663	\| exception_statement
664	\| asm_statement
665	\| '^' postfix_expression '{' argument_expression_list '}' ';' // CFA
666	{
667	Token fn;
668	fn.str = new std::string( "^?{}" ); // location undefined
669	$$ = new StatementNode( build_expr( new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) ) ) );
670	}
671	;
672
673	labeled_statement:
674	// labels cannot be identifiers 0 or 1
675	IDENTIFIER ':' attribute_list_opt statement
676	{
677	$$ = $4->add_label( $1 );
678	}
679	;
680
681	compound_statement:
682	'{' '}'
683	{ $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
684	\| '{'
685	// Two scopes are necessary because the block itself has a scope, but every declaration within the block also
686	// requires its own scope
687	push push
688	local_label_declaration_opt // GCC, local labels
689	block_item_list pop '}' // C99, intermix declarations and statements
690	{ $$ = new StatementNode( build_compound( $5 ) ); }
691	;
692
693	block_item_list: // C99
694	block_item
695	\| block_item_list push block_item
696	{ if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
697	;
698
699	block_item:
700	declaration // CFA, new & old style declarations
701	{ $$ = new StatementNode( $1 ); }
702	\| EXTENSION declaration // GCC
703	{ // mark all fields in list
704	for ( DeclarationNode iter = $2; iter != nullptr; iter = (DeclarationNode )iter->get_next() )
705	iter->set_extension( true );
706	$$ = new StatementNode( $2 );
707	}
708	\| function_definition
709	{ $$ = new StatementNode( $1 ); }
710	\| statement pop
711	;
712
713	statement_list:
714	statement
715	\| statement_list statement
716	{ if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
717	;
718
719	expression_statement:
720	comma_expression_opt ';'
721	{ $$ = new StatementNode( build_expr( $1 ) ); }
722	;
723
724	selection_statement:
725	IF '(' comma_expression ')' statement %prec THEN
726	// explicitly deal with the shift/reduce conflict on if/else
727	{ $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
728	\| IF '(' comma_expression ')' statement ELSE statement
729	{ $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
730	\| SWITCH '(' comma_expression ')' case_clause // CFA
731	{ $$ = new StatementNode( build_switch( $3, $5 ) ); }
732	\| SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
733	{
734	StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
735	// The semantics of the declaration list is changed to include associated initialization, which is performed
736	// before the transfer to the appropriate case clause by hoisting the declarations into a compound
737	// statement around the switch. Statements after the initial declaration list can never be executed, and
738	// therefore, are removed from the grammar even though C allows it. The change also applies to choose
739	// statement.
740	$$ = $7 != 0 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
741	}
742	\| CHOOSE '(' comma_expression ')' case_clause // CFA
743	{ $$ = new StatementNode( build_switch( $3, $5 ) ); }
744	\| CHOOSE '(' comma_expression ')' '{' push declaration_list_opt choose_clause_list_opt '}' // CFA
745	{
746	StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
747	$$ = $7 != 0 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
748	}
749	;
750
751	// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
752	// clause allows a list of values and subranges.
753
754	case_value: // CFA
755	constant_expression { $$ = $1; }
756	\| constant_expression ELLIPSIS constant_expression // GCC, subrange
757	{ $$ = new ExpressionNode( build_range( $1, $3 ) ); }
758	\| subrange // CFA, subrange
759	;
760
761	case_value_list: // CFA
762	case_value { $$ = new StatementNode( build_case( $1 ) ); }
763	// convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
764	\| case_value_list ',' case_value { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
765	;
766
767	case_label: // CFA
768	CASE case_value_list ':' { $$ = $2; }
769	\| DEFAULT ':' { $$ = new StatementNode( build_default() ); }
770	// A semantic check is required to ensure only one default clause per switch/choose statement.
771	;
772
773	case_label_list: // CFA
774	case_label
775	\| case_label_list case_label { $$ = (StatementNode *)( $1->set_last( $2 )); }
776	;
777
778	case_clause: // CFA
779	case_label_list statement { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
780	;
781
782	switch_clause_list_opt: // CFA
783	// empty
784	{ $$ = 0; }
785	\| switch_clause_list
786	;
787
788	switch_clause_list: // CFA
789	case_label_list statement_list
790	{ $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
791	\| switch_clause_list case_label_list statement_list
792	{ $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
793	;
794
795	choose_clause_list_opt: // CFA
796	// empty
797	{ $$ = 0; }
798	\| choose_clause_list
799	;
800
801	choose_clause_list: // CFA
802	case_label_list fall_through
803	{ $$ = $1->append_last_case( $2 ); }
804	\| case_label_list statement_list fall_through_opt
805	{ $$ = $1->append_last_case( new StatementNode( build_compound( (StatementNode *)$2->set_last( $3 ) ) ) ); }
806	\| choose_clause_list case_label_list fall_through
807	{ $$ = (StatementNode *)( $1->set_last( $2->append_last_case( $3 ))); }
808	\| choose_clause_list case_label_list statement_list fall_through_opt
809	{ $$ = (StatementNode )( $1->set_last( $2->append_last_case( new StatementNode( build_compound( (StatementNode )$3->set_last( $4 ) ) ) ) ) ); }
810	;
811
812	fall_through_opt: // CFA
813	// empty
814	{ $$ = new StatementNode( build_branch( BranchStmt::Break ) ); } // insert implicit break
815	\| fall_through
816	;
817
818	fall_through: // CFA
819	FALLTHRU
820	{ $$ = 0; }
821	\| FALLTHRU ';'
822	{ $$ = 0; }
823	;
824
825	iteration_statement:
826	WHILE '(' comma_expression ')' statement
827	{ $$ = new StatementNode( build_while( $3, $5 ) ); }
828	\| DO statement WHILE '(' comma_expression ')' ';'
829	{ $$ = new StatementNode( build_while( $5, $2 ) ); }
830	\| FOR '(' push for_control_expression ')' statement
831	{ $$ = new StatementNode( build_for( $4, $6 ) ); }
832	;
833
834	for_control_expression:
835	comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
836	{ $$ = new ForCtl( $1, $4, $6 ); }
837	\| declaration comma_expression_opt ';' comma_expression_opt // C99
838	{ $$ = new ForCtl( $1, $2, $4 ); }
839	;
840
841	jump_statement:
842	GOTO IDENTIFIER ';'
843	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
844	\| GOTO '*' comma_expression ';' // GCC, computed goto
845	// The syntax for the GCC computed goto violates normal expression precedence, e.g., goto i+3; => goto (i+3);
846	// whereas normal operator precedence yields goto (*i)+3;
847	{ $$ = new StatementNode( build_computedgoto( $3 ) ); }
848	\| CONTINUE ';'
849	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
850	{ $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
851	\| CONTINUE IDENTIFIER ';' // CFA, multi-level continue
852	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
853	// the target of the transfer appears only at the start of an iteration statement.
854	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
855	\| BREAK ';'
856	// A semantic check is required to ensure this statement appears only in the body of an iteration statement.
857	{ $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
858	\| BREAK IDENTIFIER ';' // CFA, multi-level exit
859	// A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
860	// the target of the transfer appears only at the start of an iteration statement.
861	{ $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
862	\| RETURN comma_expression_opt ';'
863	{ $$ = new StatementNode( build_return( $2 ) ); }
864	\| THROW assignment_expression_opt ';' // handles rethrow
865	{ $$ = new StatementNode( build_throw( $2 ) ); }
866	\| THROWRESUME assignment_expression_opt ';' // handles reresume
867	{ $$ = new StatementNode( build_throw( $2 ) ); }
868	\| THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
869	{ $$ = new StatementNode( build_throw( $2 ) ); }
870	;
871
872	exception_statement:
873	TRY compound_statement handler_list
874	{ $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
875	\| TRY compound_statement finally_clause
876	{ $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
877	\| TRY compound_statement handler_list finally_clause
878	{ $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
879	;
880
881	handler_list:
882	handler_clause
883	// ISO/IEC 9899:1999 Section 15.3(6 ) If present, a "..." handler shall be the last handler for its try block.
884	\| CATCH '(' ELLIPSIS ')' compound_statement
885	{ $$ = new StatementNode( build_catch( 0, $5, true ) ); }
886	\| handler_clause CATCH '(' ELLIPSIS ')' compound_statement
887	{ $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( 0, $6, true ) ) ); }
888	\| CATCHRESUME '(' ELLIPSIS ')' compound_statement
889	{ $$ = new StatementNode( build_catch( 0, $5, true ) ); }
890	\| handler_clause CATCHRESUME '(' ELLIPSIS ')' compound_statement
891	{ $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( 0, $6, true ) ) ); }
892	;
893
894	handler_clause:
895	CATCH '(' push push exception_declaration pop ')' compound_statement pop
896	{ $$ = new StatementNode( build_catch( $5, $8 ) ); }
897	\| handler_clause CATCH '(' push push exception_declaration pop ')' compound_statement pop
898	{ $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $6, $9 ) ) ); }
899	\| CATCHRESUME '(' push push exception_declaration pop ')' compound_statement pop
900	{ $$ = new StatementNode( build_catch( $5, $8 ) ); }
901	\| handler_clause CATCHRESUME '(' push push exception_declaration pop ')' compound_statement pop
902	{ $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $6, $9 ) ) ); }
903	;
904
905	finally_clause:
906	FINALLY compound_statement
907	{
908	$$ = new StatementNode( build_finally( $2 ) );
909	}
910	;
911
912	exception_declaration:
913	// A semantic check is required to ensure type_specifier does not create a new type, e.g.:
914	//
915	// catch ( struct { int i; } x ) ...
916	//
917	// This new type cannot catch any thrown type because of name equivalence among types.
918	type_specifier
919	\| type_specifier declarator
920	{
921	typedefTable.addToEnclosingScope( TypedefTable::ID );
922	$$ = $2->addType( $1 );
923	}
924	\| type_specifier variable_abstract_declarator
925	{ $$ = $2->addType( $1 ); }
926	\| new_abstract_declarator_tuple no_attr_identifier // CFA
927	{
928	typedefTable.addToEnclosingScope( TypedefTable::ID );
929	$$ = $1->addName( $2 );
930	}
931	\| new_abstract_declarator_tuple // CFA
932	;
933
934	asm_statement:
935	ASM asm_volatile_opt '(' string_literal ')' ';'
936	{ $$ = new StatementNode( build_asmstmt( $2, $4, 0 ) ); }
937	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
938	{ $$ = new StatementNode( build_asmstmt( $2, $4, $6 ) ); }
939	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
940	{ $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8 ) ); }
941	\| ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
942	{ $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8, $10 ) ); }
943	\| ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
944	{ $$ = new StatementNode( build_asmstmt( $2, $5, 0, $8, $10, $12 ) ); }
945	;
946
947	asm_volatile_opt: // GCC
948	// empty
949	{ $$ = false; }
950	\| VOLATILE
951	{ $$ = true; }
952	;
953
954	asm_operands_opt: // GCC
955	// empty
956	{ $$ = 0; } // use default argument
957	\| asm_operands_list
958	;
959
960	asm_operands_list: // GCC
961	asm_operand
962	\| asm_operands_list ',' asm_operand
963	{ $$ = (ExpressionNode *)$1->set_last( $3 ); }
964	;
965
966	asm_operand: // GCC
967	string_literal '(' constant_expression ')'
968	{ $$ = new ExpressionNode( build_asmexpr( 0, $1, $3 ) ); }
969	\| '[' constant_expression ']' string_literal '(' constant_expression ')'
970	{ $$ = new ExpressionNode( build_asmexpr( $2, $4, $6 ) ); }
971	;
972
973	asm_clobbers_list_opt: // GCC
974	// empty
975	{ $$ = 0; } // use default argument
976	\| string_literal
977	{ $$ = new ExpressionNode( $1 ); }
978	\| asm_clobbers_list_opt ',' string_literal
979	{ $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
980	;
981
982	label_list:
983	no_attr_identifier
984	{
985	$$ = new LabelNode(); $$->labels.push_back( *$1 );
986	delete $1; // allocated by lexer
987	}
988	\| label_list ',' no_attr_identifier
989	{
990	$$ = $1; $1->labels.push_back( *$3 );
991	delete $3; // allocated by lexer
992	}
993	;
994
995	//***************************** DECLARATIONS *******************************
996
997	declaration_list_opt: // used at beginning of switch statement
998	pop
999	{ $$ = 0; }
1000	\| declaration_list
1001	;
1002
1003	declaration_list:
1004	declaration
1005	\| declaration_list push declaration
1006	{ $$ = $1->appendList( $3 ); }
1007	;
1008
1009	old_declaration_list_opt: // used to declare parameter types in K&R style functions
1010	pop
1011	{ $$ = 0; }
1012	\| old_declaration_list
1013	;
1014
1015	old_declaration_list:
1016	old_declaration
1017	\| old_declaration_list push old_declaration
1018	{ $$ = $1->appendList( $3 ); }
1019	;
1020
1021	local_label_declaration_opt: // GCC, local label
1022	// empty
1023	\| local_label_declaration_list
1024	;
1025
1026	local_label_declaration_list: // GCC, local label
1027	LABEL local_label_list ';'
1028	\| local_label_declaration_list LABEL local_label_list ';'
1029	;
1030
1031	local_label_list: // GCC, local label
1032	no_attr_identifier_or_type_name {}
1033	\| local_label_list ',' no_attr_identifier_or_type_name {}
1034	;
1035
1036	declaration: // CFA, new & old style declarations
1037	new_declaration
1038	\| old_declaration
1039	;
1040
1041	// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1042	// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1043	// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1044	// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1045	// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1046	// block, but cannot be mixed within a specific declaration.
1047	//
1048	// CFA C
1049	// [10] int x; int x[10]; // array of 10 integers
1050	// [10] * char y; char *y[10]; // array of 10 pointers to char
1051
1052	new_declaration: // CFA
1053	new_variable_declaration pop ';'
1054	\| new_typedef_declaration pop ';'
1055	\| new_function_declaration pop ';'
1056	\| type_declaring_list pop ';'
1057	\| trait_specifier pop ';'
1058	;
1059
1060	new_variable_declaration: // CFA
1061	new_variable_specifier initializer_opt
1062	{
1063	typedefTable.addToEnclosingScope( TypedefTable::ID );
1064	$$ = $1->addInitializer( $2 );
1065	}
1066	\| declaration_qualifier_list new_variable_specifier initializer_opt
1067	// declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1068	// them as a type_qualifier cannot appear in that context.
1069	{
1070	typedefTable.addToEnclosingScope( TypedefTable::ID );
1071	$$ = $2->addQualifiers( $1 )->addInitializer( $3 );;
1072	}
1073	\| new_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1074	{
1075	typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1076	$$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) );
1077	}
1078	;
1079
1080	new_variable_specifier: // CFA
1081	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1082	// storage-class
1083	new_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1084	{
1085	typedefTable.setNextIdentifier( *$2 );
1086	$$ = $1->addName( $2 );
1087	}
1088	\| new_abstract_tuple identifier_or_type_name asm_name_opt
1089	{
1090	typedefTable.setNextIdentifier( *$2 );
1091	$$ = $1->addName( $2 );
1092	}
1093	\| type_qualifier_list new_abstract_tuple identifier_or_type_name asm_name_opt
1094	{
1095	typedefTable.setNextIdentifier( *$3 );
1096	$$ = $2->addQualifiers( $1 )->addName( $3 );
1097	}
1098	;
1099
1100	new_function_declaration: // CFA
1101	new_function_specifier
1102	{
1103	typedefTable.addToEnclosingScope( TypedefTable::ID );
1104	$$ = $1;
1105	}
1106	\| type_qualifier_list new_function_specifier
1107	{
1108	typedefTable.addToEnclosingScope( TypedefTable::ID );
1109	$$ = $2->addQualifiers( $1 );
1110	}
1111	\| declaration_qualifier_list new_function_specifier
1112	{
1113	typedefTable.addToEnclosingScope( TypedefTable::ID );
1114	$$ = $2->addQualifiers( $1 );
1115	}
1116	\| declaration_qualifier_list type_qualifier_list new_function_specifier
1117	{
1118	typedefTable.addToEnclosingScope( TypedefTable::ID );
1119	$$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1120	}
1121	\| new_function_declaration pop ',' push identifier_or_type_name
1122	{
1123	typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1124	$$ = $1->appendList( $1->cloneType( $5 ) );
1125	}
1126	;
1127
1128	new_function_specifier: // CFA
1129	'[' ']' identifier_or_type_name '(' push new_parameter_type_list_opt pop ')' // S/R conflict
1130	{
1131	$$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1132	}
1133	// '[' ']' identifier '(' push new_parameter_type_list_opt pop ')'
1134	// {
1135	// typedefTable.setNextIdentifier( *$5 );
1136	// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1137	// }
1138	// \| '[' ']' TYPEDEFname '(' push new_parameter_type_list_opt pop ')'
1139	// {
1140	// typedefTable.setNextIdentifier( *$5 );
1141	// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1142	// }
1143	// \| '[' ']' typegen_name
1144	// identifier_or_type_name must be broken apart because of the sequence:
1145	//
1146	// '[' ']' identifier_or_type_name '(' new_parameter_type_list_opt ')'
1147	// '[' ']' type_specifier
1148	//
1149	// type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1150	// flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1151	\| new_abstract_tuple identifier_or_type_name '(' push new_parameter_type_list_opt pop ')'
1152	// To obtain LR(1 ), this rule must be factored out from function return type (see new_abstract_declarator).
1153	{
1154	$$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1155	}
1156	\| new_function_return identifier_or_type_name '(' push new_parameter_type_list_opt pop ')'
1157	{
1158	$$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1159	}
1160	;
1161
1162	new_function_return: // CFA
1163	'[' push new_parameter_list pop ']'
1164	{ $$ = DeclarationNode::newTuple( $3 ); }
1165	\| '[' push new_parameter_list pop ',' push new_abstract_parameter_list pop ']'
1166	// To obtain LR(1 ), the last new_abstract_parameter_list is added into this flattened rule to lookahead to the
1167	// ']'.
1168	{ $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1169	;
1170
1171	new_typedef_declaration: // CFA
1172	TYPEDEF new_variable_specifier
1173	{
1174	typedefTable.addToEnclosingScope( TypedefTable::TD );
1175	$$ = $2->addTypedef();
1176	}
1177	\| TYPEDEF new_function_specifier
1178	{
1179	typedefTable.addToEnclosingScope( TypedefTable::TD );
1180	$$ = $2->addTypedef();
1181	}
1182	\| new_typedef_declaration pop ',' push no_attr_identifier
1183	{
1184	typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1185	$$ = $1->appendList( $1->cloneType( $5 ) );
1186	}
1187	;
1188
1189	// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1190	// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1191
1192	typedef_declaration:
1193	TYPEDEF type_specifier declarator
1194	{
1195	typedefTable.addToEnclosingScope( TypedefTable::TD );
1196	$$ = $3->addType( $2 )->addTypedef();
1197	}
1198	\| typedef_declaration pop ',' push declarator
1199	{
1200	typedefTable.addToEnclosingScope( TypedefTable::TD );
1201	$$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1202	}
1203	\| type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1204	{
1205	typedefTable.addToEnclosingScope( TypedefTable::TD );
1206	$$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1207	}
1208	\| type_specifier TYPEDEF declarator
1209	{
1210	typedefTable.addToEnclosingScope( TypedefTable::TD );
1211	$$ = $3->addType( $1 )->addTypedef();
1212	}
1213	\| type_specifier TYPEDEF type_qualifier_list declarator
1214	{
1215	typedefTable.addToEnclosingScope( TypedefTable::TD );
1216	$$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1217	}
1218	;
1219
1220	typedef_expression:
1221	// GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1222	TYPEDEF no_attr_identifier '=' assignment_expression
1223	{
1224	typedefTable.addToEnclosingScope( *$2, TypedefTable::TD );
1225	$$ = DeclarationNode::newName( 0 ); // XXX
1226	}
1227	\| typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1228	{
1229	typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1230	$$ = DeclarationNode::newName( 0 ); // XXX
1231	}
1232	;
1233
1234	old_declaration:
1235	declaring_list pop ';'
1236	\| typedef_declaration pop ';'
1237	\| typedef_expression pop ';' // GCC, naming expression type
1238	\| sue_declaration_specifier pop ';'
1239	;
1240
1241	declaring_list:
1242	// A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1243	// storage-class
1244	declaration_specifier declarator asm_name_opt initializer_opt
1245	{
1246	typedefTable.addToEnclosingScope( TypedefTable::ID );
1247	$$ = ( $2->addType( $1 ))->addInitializer( $4 );
1248	}
1249	\| declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1250	{
1251	typedefTable.addToEnclosingScope( TypedefTable::ID );
1252	$$ = $1->appendList( $1->cloneBaseType( $4->addInitializer( $6 ) ) );
1253	}
1254	;
1255
1256	declaration_specifier: // type specifier + storage class
1257	basic_declaration_specifier
1258	\| sue_declaration_specifier
1259	\| typedef_declaration_specifier
1260	\| typegen_declaration_specifier
1261	;
1262
1263	type_specifier: // declaration specifier - storage class
1264	basic_type_specifier
1265	\| sue_type_specifier
1266	\| typedef_type_specifier
1267	\| typegen_type_specifier
1268	;
1269
1270	type_qualifier_list_opt: // GCC, used in asm_statement
1271	// empty
1272	{ $$ = 0; }
1273	\| type_qualifier_list
1274	;
1275
1276	type_qualifier_list:
1277	// A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1278	//
1279	// ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1280	// specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1281	// appeared only once.
1282	type_qualifier
1283	\| type_qualifier_list type_qualifier
1284	{ $$ = $1->addQualifiers( $2 ); }
1285	;
1286
1287	type_qualifier:
1288	type_qualifier_name
1289	\| attribute
1290	//{ $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
1291	;
1292
1293	type_qualifier_name:
1294	CONST
1295	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Const ); }
1296	\| RESTRICT
1297	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Restrict ); }
1298	\| VOLATILE
1299	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Volatile ); }
1300	\| LVALUE // CFA
1301	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Lvalue ); }
1302	\| ATOMIC
1303	{ $$ = DeclarationNode::newQualifier( DeclarationNode::Atomic ); }
1304	\| FORALL '('
1305	{
1306	typedefTable.enterScope();
1307	}
1308	type_parameter_list ')' // CFA
1309	{
1310	typedefTable.leaveScope();
1311	$$ = DeclarationNode::newForall( $4 );
1312	}
1313	;
1314
1315	declaration_qualifier_list:
1316	storage_class_list
1317	\| type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
1318	{ $$ = $1->addQualifiers( $2 ); }
1319	\| declaration_qualifier_list type_qualifier_list storage_class_list
1320	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1321	;
1322
1323	storage_class_list:
1324	// A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1325	// only one of each is specified, except for inline, which can appear with the others.
1326	//
1327	// ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1328	// specifiers in a declaration.
1329	storage_class
1330	\| storage_class_list storage_class
1331	{ $$ = $1->addQualifiers( $2 ); }
1332	;
1333
1334	storage_class:
1335	EXTERN
1336	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Extern ); }
1337	\| STATIC
1338	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Static ); }
1339	\| AUTO
1340	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Auto ); }
1341	\| REGISTER
1342	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Register ); }
1343	\| INLINE // C99
1344	//{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Inline ); }
1345	{ $$ = new DeclarationNode; $$->isInline = true; }
1346	\| FORTRAN // C99
1347	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Fortran ); }
1348	\| NORETURN // C11
1349	//{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Noreturn ); }
1350	{ $$ = new DeclarationNode; $$->isNoreturn = true; }
1351	\| THREADLOCAL // C11
1352	{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Threadlocal ); }
1353	;
1354
1355	basic_type_name:
1356	CHAR
1357	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1358	\| DOUBLE
1359	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1360	\| FLOAT
1361	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1362	\| INT
1363	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1364	\| LONG
1365	{ $$ = DeclarationNode::newModifier( DeclarationNode::Long ); }
1366	\| SHORT
1367	{ $$ = DeclarationNode::newModifier( DeclarationNode::Short ); }
1368	\| SIGNED
1369	{ $$ = DeclarationNode::newModifier( DeclarationNode::Signed ); }
1370	\| UNSIGNED
1371	{ $$ = DeclarationNode::newModifier( DeclarationNode::Unsigned ); }
1372	\| VOID
1373	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1374	\| BOOL // C99
1375	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1376	\| COMPLEX // C99
1377	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Complex ); }
1378	\| IMAGINARY // C99
1379	{ $$ = DeclarationNode::newBasicType( DeclarationNode::Imaginary ); }
1380	\| VALIST // GCC, __builtin_va_list
1381	{ $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1382	;
1383
1384	basic_declaration_specifier:
1385	// A semantic check is necessary for conflicting storage classes.
1386	basic_type_specifier
1387	\| declaration_qualifier_list basic_type_specifier
1388	{ $$ = $2->addQualifiers( $1 ); }
1389	\| basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1390	{ $$ = $1->addQualifiers( $2 ); }
1391	\| basic_declaration_specifier storage_class type_qualifier_list
1392	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1393	\| basic_declaration_specifier storage_class basic_type_specifier
1394	{ $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1395	;
1396
1397	basic_type_specifier:
1398	direct_type_name
1399	\| type_qualifier_list_opt indirect_type_name type_qualifier_list_opt
1400	{ $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1401	;
1402
1403	direct_type_name:
1404	// A semantic check is necessary for conflicting type qualifiers.
1405	basic_type_name
1406	\| type_qualifier_list basic_type_name
1407	{ $$ = $2->addQualifiers( $1 ); }
1408	\| direct_type_name type_qualifier
1409	{ $$ = $1->addQualifiers( $2 ); }
1410	\| direct_type_name basic_type_name
1411	{ $$ = $1->addType( $2 ); }
1412	;
1413
1414	indirect_type_name:
1415	TYPEOF '(' type_name ')' // GCC: typeof(x) y;
1416	{ $$ = $3; }
1417	\| TYPEOF '(' comma_expression ')' // GCC: typeof(a+b) y;
1418	{ $$ = DeclarationNode::newTypeof( $3 ); }
1419	\| ATTR_TYPEGENname '(' type_name ')' // CFA: e.g., @type(x) y;
1420	{ $$ = DeclarationNode::newAttr( $1, $3 ); }
1421	\| ATTR_TYPEGENname '(' comma_expression ')' // CFA: e.g., @type(a+b) y;
1422	{ $$ = DeclarationNode::newAttr( $1, $3 ); }
1423	;
1424
1425	sue_declaration_specifier:
1426	sue_type_specifier
1427	\| declaration_qualifier_list sue_type_specifier
1428	{ $$ = $2->addQualifiers( $1 ); }
1429	\| sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1430	{ $$ = $1->addQualifiers( $2 ); }
1431	\| sue_declaration_specifier storage_class type_qualifier_list
1432	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1433	;
1434
1435	sue_type_specifier:
1436	elaborated_type_name // struct, union, enum
1437	\| type_qualifier_list elaborated_type_name
1438	{ $$ = $2->addQualifiers( $1 ); }
1439	\| sue_type_specifier type_qualifier
1440	{ $$ = $1->addQualifiers( $2 ); }
1441	;
1442
1443	typedef_declaration_specifier:
1444	typedef_type_specifier
1445	\| declaration_qualifier_list typedef_type_specifier
1446	{ $$ = $2->addQualifiers( $1 ); }
1447	\| typedef_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1448	{ $$ = $1->addQualifiers( $2 ); }
1449	\| typedef_declaration_specifier storage_class type_qualifier_list
1450	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1451	;
1452
1453	typedef_type_specifier: // typedef types
1454	TYPEDEFname
1455	{ $$ = DeclarationNode::newFromTypedef( $1 ); }
1456	\| type_qualifier_list TYPEDEFname
1457	{ $$ = DeclarationNode::newFromTypedef( $2 )->addQualifiers( $1 ); }
1458	\| typedef_type_specifier type_qualifier
1459	{ $$ = $1->addQualifiers( $2 ); }
1460	;
1461
1462	elaborated_type_name:
1463	aggregate_name
1464	\| enum_name
1465	;
1466
1467	aggregate_name:
1468	aggregate_key '{' field_declaration_list '}'
1469	{ $$ = DeclarationNode::newAggregate( $1, 0, 0, $3, true ); }
1470	\| aggregate_key no_attr_identifier_or_type_name
1471	{
1472	typedefTable.makeTypedef( *$2 );
1473	$$ = DeclarationNode::newAggregate( $1, $2, 0, 0, false );
1474	}
1475	\| aggregate_key no_attr_identifier_or_type_name
1476	{ typedefTable.makeTypedef( *$2 ); }
1477	'{' field_declaration_list '}'
1478	{ $$ = DeclarationNode::newAggregate( $1, $2, 0, $5, true ); }
1479	\| aggregate_key '(' type_name_list ')' '{' field_declaration_list '}' // CFA
1480	{ $$ = DeclarationNode::newAggregate( $1, 0, $3, $6, false ); }
1481	\| aggregate_key typegen_name // CFA, S/R conflict
1482	{ $$ = $2; }
1483	;
1484
1485	aggregate_key:
1486	STRUCT attribute_list_opt
1487	{ $$ = DeclarationNode::Struct; }
1488	\| UNION attribute_list_opt
1489	{ $$ = DeclarationNode::Union; }
1490	;
1491
1492	field_declaration_list:
1493	// empty
1494	{ $$ = 0; }
1495	\| field_declaration_list field_declaration
1496	{ $$ = $1 != 0 ? $1->appendList( $2 ) : $2; }
1497	;
1498
1499	field_declaration:
1500	new_field_declaring_list ';' // CFA, new style field declaration
1501	\| EXTENSION new_field_declaring_list ';' // GCC
1502	{ $$ = $2->set_extension( true ); }
1503	\| field_declaring_list ';'
1504	\| EXTENSION field_declaring_list ';' // GCC
1505	{ // mark all fields in list
1506	for ( DeclarationNode iter = $2; iter != nullptr; iter = (DeclarationNode )iter->get_next() )
1507	iter->set_extension( true );
1508	$$ = $2;
1509	}
1510	;
1511
1512	new_field_declaring_list: // CFA, new style field declaration
1513	new_abstract_declarator_tuple // CFA, no field name
1514	\| new_abstract_declarator_tuple no_attr_identifier_or_type_name
1515	{ $$ = $1->addName( $2 ); }
1516	\| new_field_declaring_list ',' no_attr_identifier_or_type_name
1517	{ $$ = $1->appendList( $1->cloneType( $3 ) ); }
1518	\| new_field_declaring_list ',' // CFA, no field name
1519	{ $$ = $1->appendList( $1->cloneType( 0 ) ); }
1520	;
1521
1522	field_declaring_list:
1523	type_specifier field_declarator
1524	{ $$ = $2->addType( $1 ); }
1525	\| field_declaring_list ',' attribute_list_opt field_declarator
1526	{ $$ = $1->appendList( $1->cloneBaseType( $4 ) ); }
1527	;
1528
1529	field_declarator:
1530	// empty
1531	{ $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1532	\| bit_subrange_size // no field name
1533	{ $$ = DeclarationNode::newBitfield( $1 ); }
1534	\| variable_declarator bit_subrange_size_opt
1535	// A semantic check is required to ensure bit_subrange only appears on base type int.
1536	{ $$ = $1->addBitfield( $2 ); }
1537	\| variable_type_redeclarator bit_subrange_size_opt
1538	// A semantic check is required to ensure bit_subrange only appears on base type int.
1539	{ $$ = $1->addBitfield( $2 ); }
1540	\| variable_abstract_declarator // CFA, no field name
1541	;
1542
1543	bit_subrange_size_opt:
1544	// empty
1545	{ $$ = 0; }
1546	\| bit_subrange_size
1547	{ $$ = $1; }
1548	;
1549
1550	bit_subrange_size:
1551	':' constant_expression
1552	{ $$ = $2; }
1553	;
1554
1555	enum_key:
1556	ENUM attribute_list_opt
1557	;
1558
1559	enum_name:
1560	enum_key '{' enumerator_list comma_opt '}'
1561	{ $$ = DeclarationNode::newEnum( 0, $3 ); }
1562	\| enum_key no_attr_identifier_or_type_name
1563	{
1564	typedefTable.makeTypedef( *$2 );
1565	$$ = DeclarationNode::newEnum( $2, 0 );
1566	}
1567	\| enum_key no_attr_identifier_or_type_name
1568	{ typedefTable.makeTypedef( *$2 ); }
1569	'{' enumerator_list comma_opt '}'
1570	{ $$ = DeclarationNode::newEnum( $2, $5 ); }
1571	;
1572
1573	enumerator_list:
1574	no_attr_identifier_or_type_name enumerator_value_opt
1575	{ $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1576	\| enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1577	{ $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1578	;
1579
1580	enumerator_value_opt:
1581	// empty
1582	{ $$ = 0; }
1583	\| '=' constant_expression
1584	{ $$ = $2; }
1585	;
1586
1587	// Minimum of one parameter after which ellipsis is allowed only at the end.
1588
1589	new_parameter_type_list_opt: // CFA
1590	// empty
1591	{ $$ = 0; }
1592	\| new_parameter_type_list
1593	;
1594
1595	new_parameter_type_list: // CFA, abstract + real
1596	new_abstract_parameter_list
1597	\| new_parameter_list
1598	\| new_parameter_list pop ',' push new_abstract_parameter_list
1599	{ $$ = $1->appendList( $5 ); }
1600	\| new_abstract_parameter_list pop ',' push ELLIPSIS
1601	{ $$ = $1->addVarArgs(); }
1602	\| new_parameter_list pop ',' push ELLIPSIS
1603	{ $$ = $1->addVarArgs(); }
1604	;
1605
1606	new_parameter_list: // CFA
1607	// To obtain LR(1) between new_parameter_list and new_abstract_tuple, the last new_abstract_parameter_list is
1608	// factored out from new_parameter_list, flattening the rules to get lookahead to the ']'.
1609	new_parameter_declaration
1610	\| new_abstract_parameter_list pop ',' push new_parameter_declaration
1611	{ $$ = $1->appendList( $5 ); }
1612	\| new_parameter_list pop ',' push new_parameter_declaration
1613	{ $$ = $1->appendList( $5 ); }
1614	\| new_parameter_list pop ',' push new_abstract_parameter_list pop ',' push new_parameter_declaration
1615	{ $$ = $1->appendList( $5 )->appendList( $9 ); }
1616	;
1617
1618	new_abstract_parameter_list: // CFA, new & old style abstract
1619	new_abstract_parameter_declaration
1620	\| new_abstract_parameter_list pop ',' push new_abstract_parameter_declaration
1621	{ $$ = $1->appendList( $5 ); }
1622	;
1623
1624	parameter_type_list_opt:
1625	// empty
1626	{ $$ = 0; }
1627	\| parameter_type_list
1628	;
1629
1630	parameter_type_list:
1631	parameter_list
1632	\| parameter_list pop ',' push ELLIPSIS
1633	{ $$ = $1->addVarArgs(); }
1634	;
1635
1636	parameter_list: // abstract + real
1637	abstract_parameter_declaration
1638	\| parameter_declaration
1639	\| parameter_list pop ',' push abstract_parameter_declaration
1640	{ $$ = $1->appendList( $5 ); }
1641	\| parameter_list pop ',' push parameter_declaration
1642	{ $$ = $1->appendList( $5 ); }
1643	;
1644
1645	// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
1646	// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
1647
1648	new_parameter_declaration: // CFA, new & old style parameter declaration
1649	parameter_declaration
1650	\| new_identifier_parameter_declarator_no_tuple identifier_or_type_name assignment_opt
1651	{ $$ = $1->addName( $2 ); }
1652	\| new_abstract_tuple identifier_or_type_name assignment_opt
1653	// To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1654	{ $$ = $1->addName( $2 ); }
1655	\| type_qualifier_list new_abstract_tuple identifier_or_type_name assignment_opt
1656	{ $$ = $2->addName( $3 )->addQualifiers( $1 ); }
1657	\| new_function_specifier
1658	;
1659
1660	new_abstract_parameter_declaration: // CFA, new & old style parameter declaration
1661	abstract_parameter_declaration
1662	\| new_identifier_parameter_declarator_no_tuple
1663	\| new_abstract_tuple
1664	// To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1665	\| type_qualifier_list new_abstract_tuple
1666	{ $$ = $2->addQualifiers( $1 ); }
1667	\| new_abstract_function
1668	;
1669
1670	parameter_declaration:
1671	declaration_specifier identifier_parameter_declarator assignment_opt
1672	{
1673	typedefTable.addToEnclosingScope( TypedefTable::ID );
1674	$$ = $2->addType( $1 )->addInitializer( new InitializerNode( $3 ) );
1675	}
1676	\| declaration_specifier type_parameter_redeclarator assignment_opt
1677	{
1678	typedefTable.addToEnclosingScope( TypedefTable::ID );
1679	$$ = $2->addType( $1 )->addInitializer( new InitializerNode( $3 ) );
1680	}
1681	;
1682
1683	abstract_parameter_declaration:
1684	declaration_specifier
1685	\| declaration_specifier abstract_parameter_declarator
1686	{ $$ = $2->addType( $1 ); }
1687	;
1688
1689	// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
1690	// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
1691	// identifiers. The ANSI-style parameter-list can redefine a typedef name.
1692
1693	identifier_list: // K&R-style parameter list => no types
1694	no_attr_identifier
1695	{ $$ = DeclarationNode::newName( $1 ); }
1696	\| identifier_list ',' no_attr_identifier
1697	{ $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
1698	;
1699
1700	identifier_or_type_name:
1701	identifier
1702	\| TYPEDEFname
1703	\| TYPEGENname
1704	;
1705
1706	no_01_identifier_or_type_name:
1707	no_01_identifier
1708	\| TYPEDEFname
1709	\| TYPEGENname
1710	;
1711
1712	no_attr_identifier_or_type_name:
1713	no_attr_identifier
1714	\| TYPEDEFname
1715	\| TYPEGENname
1716	;
1717
1718	type_name_no_function: // sizeof, alignof, cast (constructor)
1719	new_abstract_declarator_tuple // CFA
1720	\| type_specifier
1721	\| type_specifier variable_abstract_declarator
1722	{ $$ = $2->addType( $1 ); }
1723	;
1724
1725	type_name: // typeof, assertion
1726	new_abstract_declarator_tuple // CFA
1727	\| new_abstract_function // CFA
1728	\| type_specifier
1729	\| type_specifier abstract_declarator
1730	{ $$ = $2->addType( $1 ); }
1731	;
1732
1733	initializer_opt:
1734	// empty
1735	{ $$ = 0; }
1736	\| '=' initializer
1737	{ $$ = $2; }
1738	\| ATassign initializer
1739	{ $$ = $2->set_maybeConstructed( false ); }
1740	;
1741
1742	initializer:
1743	assignment_expression { $$ = new InitializerNode( $1 ); }
1744	\| '{' initializer_list comma_opt '}' { $$ = new InitializerNode( $2, true ); }
1745	;
1746
1747	initializer_list:
1748	// empty
1749	{ $$ = 0; }
1750	\| initializer
1751	\| designation initializer { $$ = $2->set_designators( $1 ); }
1752	\| initializer_list ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
1753	\| initializer_list ',' designation initializer
1754	{ $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
1755	;
1756
1757	// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
1758	// '=' to separator the designator from the initializer value, as in:
1759	//
1760	// int x[10] = { [1] = 3 };
1761	//
1762	// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
1763	// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
1764	// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
1765	// shift/reduce conflicts
1766
1767	designation:
1768	designator_list ':' // C99, CFA uses ":" instead of "="
1769	\| no_attr_identifier_or_type_name ':' // GCC, field name
1770	{ $$ = new ExpressionNode( build_varref( $1 ) ); }
1771	;
1772
1773	designator_list: // C99
1774	designator
1775	\| designator_list designator
1776	{ $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
1777	//\| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
1778	;
1779
1780	designator:
1781	'.' no_attr_identifier_or_type_name // C99, field name
1782	{ $$ = new ExpressionNode( build_varref( $2 ) ); }
1783	\| '[' push assignment_expression pop ']' // C99, single array element
1784	// assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
1785	{ $$ = $3; }
1786	\| '[' push subrange pop ']' // CFA, multiple array elements
1787	{ $$ = $3; }
1788	\| '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
1789	{ $$ = new ExpressionNode( build_range( $3, $5 ) ); }
1790	\| '.' '[' push field_list pop ']' // CFA, tuple field selector
1791	{ $$ = $4; }
1792	;
1793
1794	// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
1795	// rather than an object-oriented type system. This required four groups of extensions:
1796	//
1797	// Overloading: function, data, and operator identifiers may be overloaded.
1798	//
1799	// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
1800	// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
1801	// definitions of new types. Type declarations with storage class "extern" provide opaque types.
1802	//
1803	// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
1804	// site. A polymorphic function is not a template; it is a function, with an address and a type.
1805	//
1806	// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
1807	// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
1808	// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
1809	// types provide the operations declared by a specification. Assertions are normally used to declare requirements
1810	// on type arguments of polymorphic functions.
1811
1812	typegen_declaration_specifier: // CFA
1813	typegen_type_specifier
1814	\| declaration_qualifier_list typegen_type_specifier
1815	{ $$ = $2->addQualifiers( $1 ); }
1816	\| typegen_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
1817	{ $$ = $1->addQualifiers( $2 ); }
1818	\| typegen_declaration_specifier storage_class type_qualifier_list
1819	{ $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1820	;
1821
1822	typegen_type_specifier: // CFA
1823	typegen_name
1824	\| type_qualifier_list typegen_name
1825	{ $$ = $2->addQualifiers( $1 ); }
1826	\| typegen_type_specifier type_qualifier
1827	{ $$ = $1->addQualifiers( $2 ); }
1828	;
1829
1830	typegen_name: // CFA
1831	TYPEGENname '(' type_name_list ')'
1832	{ $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1833	;
1834
1835	type_parameter_list: // CFA
1836	type_parameter assignment_opt
1837	\| type_parameter_list ',' type_parameter assignment_opt
1838	{ $$ = $1->appendList( $3 ); }
1839	;
1840
1841	type_parameter: // CFA
1842	type_class no_attr_identifier_or_type_name
1843	{ typedefTable.addToEnclosingScope( *$2, TypedefTable::TD ); }
1844	assertion_list_opt
1845	{ $$ = DeclarationNode::newTypeParam( $1, $2 )->addAssertions( $4 ); }
1846	\| type_specifier identifier_parameter_declarator
1847	;
1848
1849	type_class: // CFA
1850	OTYPE
1851	{ $$ = DeclarationNode::Type; }
1852	\| DTYPE
1853	{ $$ = DeclarationNode::Ftype; }
1854	\| FTYPE
1855	{ $$ = DeclarationNode::Dtype; }
1856	;
1857
1858	assertion_list_opt: // CFA
1859	// empty
1860	{ $$ = 0; }
1861	\| assertion_list_opt assertion
1862	{ $$ = $1 != 0 ? $1->appendList( $2 ) : $2; }
1863	;
1864
1865	assertion: // CFA
1866	'\|' no_attr_identifier_or_type_name '(' type_name_list ')'
1867	{
1868	typedefTable.openTrait( *$2 );
1869	$$ = DeclarationNode::newTraitUse( $2, $4 );
1870	}
1871	\| '\|' '{' push trait_declaration_list '}'
1872	{ $$ = $4; }
1873	\| '\|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_name_list ')'
1874	{ $$ = 0; }
1875	;
1876
1877	type_name_list: // CFA
1878	type_name
1879	{ $$ = new ExpressionNode( build_typevalue( $1 ) ); }
1880	\| assignment_expression
1881	\| type_name_list ',' type_name
1882	{ $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( build_typevalue( $3 ) ) ) ); }
1883	\| type_name_list ',' assignment_expression
1884	{ $$ = (ExpressionNode *)( $1->set_last( $3 )); }
1885	;
1886
1887	type_declaring_list: // CFA
1888	OTYPE type_declarator
1889	{ $$ = $2; }
1890	\| storage_class_list OTYPE type_declarator
1891	{ $$ = $3->addQualifiers( $1 ); }
1892	\| type_declaring_list ',' type_declarator
1893	{ $$ = $1->appendList( $3->copyStorageClasses( $1 ) ); }
1894	;
1895
1896	type_declarator: // CFA
1897	type_declarator_name assertion_list_opt
1898	{ $$ = $1->addAssertions( $2 ); }
1899	\| type_declarator_name assertion_list_opt '=' type_name
1900	{ $$ = $1->addAssertions( $2 )->addType( $4 ); }
1901	;
1902
1903	type_declarator_name: // CFA
1904	no_attr_identifier_or_type_name
1905	{
1906	typedefTable.addToEnclosingScope( *$1, TypedefTable::TD );
1907	$$ = DeclarationNode::newTypeDecl( $1, 0 );
1908	}
1909	\| no_01_identifier_or_type_name '(' push type_parameter_list pop ')'
1910	{
1911	typedefTable.addToEnclosingScope( *$1, TypedefTable::TG );
1912	$$ = DeclarationNode::newTypeDecl( $1, $4 );
1913	}
1914	;
1915
1916	trait_specifier: // CFA
1917	TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
1918	{
1919	typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
1920	$$ = DeclarationNode::newTrait( $2, $5, 0 );
1921	}
1922	\| TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
1923	{
1924	typedefTable.enterTrait( *$2 );
1925	typedefTable.enterScope();
1926	}
1927	trait_declaration_list '}'
1928	{
1929	typedefTable.leaveTrait();
1930	typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
1931	$$ = DeclarationNode::newTrait( $2, $5, $10 );
1932	}
1933	;
1934
1935	trait_declaration_list: // CFA
1936	trait_declaration
1937	\| trait_declaration_list push trait_declaration
1938	{ $$ = $1->appendList( $3 ); }
1939	;
1940
1941	trait_declaration: // CFA
1942	new_trait_declaring_list pop ';'
1943	\| trait_declaring_list pop ';'
1944	;
1945
1946	new_trait_declaring_list: // CFA
1947	new_variable_specifier
1948	{
1949	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1950	$$ = $1;
1951	}
1952	\| new_function_specifier
1953	{
1954	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1955	$$ = $1;
1956	}
1957	\| new_trait_declaring_list pop ',' push identifier_or_type_name
1958	{
1959	typedefTable.addToEnclosingScope2( *$5, TypedefTable::ID );
1960	$$ = $1->appendList( $1->cloneType( $5 ) );
1961	}
1962	;
1963
1964	trait_declaring_list: // CFA
1965	type_specifier declarator
1966	{
1967	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1968	$$ = $2->addType( $1 );
1969	}
1970	\| trait_declaring_list pop ',' push declarator
1971	{
1972	typedefTable.addToEnclosingScope2( TypedefTable::ID );
1973	$$ = $1->appendList( $1->cloneBaseType( $5 ) );
1974	}
1975	;
1976
1977	//*************************** EXTERNAL DEFINITIONS ***************************
1978
1979	translation_unit:
1980	// empty
1981	{} // empty input file
1982	\| external_definition_list
1983	{ parseTree = parseTree != nullptr ? parseTree->appendList( $1 ) : $1; }
1984	;
1985
1986	external_definition_list:
1987	external_definition
1988	\| external_definition_list push external_definition
1989	{ $$ = $1 != nullptr ? $1->appendList( $3 ) : $3; }
1990	;
1991
1992	external_definition_list_opt:
1993	// empty
1994	{ $$ = 0; }
1995	\| external_definition_list
1996	;
1997
1998	external_definition:
1999	declaration
2000	\| external_function_definition
2001	\| asm_statement // GCC, global assembler statement
2002	{}
2003	\| EXTERN STRINGliteral
2004	{
2005	linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
2006	linkage = LinkageSpec::fromString( *$2 );
2007	}
2008	'{' external_definition_list_opt '}' // C++-style linkage specifier
2009	{
2010	linkage = linkageStack.top();
2011	linkageStack.pop();
2012	$$ = $5;
2013	}
2014	\| EXTENSION external_definition
2015	{ // mark all fields in list
2016	for ( DeclarationNode iter = $2; iter != nullptr; iter = (DeclarationNode )iter->get_next() )
2017	iter->set_extension( true );
2018	$$ = $2;
2019	}
2020	;
2021
2022	external_function_definition:
2023	function_definition
2024	// These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2025	// legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2026	// Parsing is possible because function_definition does not appear in the context of an expression (nested
2027	// functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2028	// declaration must still have a type_specifier. OBSOLESCENT (see 1)
2029	\| function_declarator compound_statement
2030	{
2031	typedefTable.addToEnclosingScope( TypedefTable::ID );
2032	typedefTable.leaveScope();
2033	$$ = $1->addFunctionBody( $2 );
2034	}
2035	\| old_function_declarator push old_declaration_list_opt compound_statement
2036	{
2037	typedefTable.addToEnclosingScope( TypedefTable::ID );
2038	typedefTable.leaveScope();
2039	$$ = $1->addOldDeclList( $3 )->addFunctionBody( $4 );
2040	}
2041	;
2042
2043	function_definition:
2044	new_function_declaration compound_statement // CFA
2045	{
2046	typedefTable.addToEnclosingScope( TypedefTable::ID );
2047	typedefTable.leaveScope();
2048	$$ = $1->addFunctionBody( $2 );
2049	}
2050	\| declaration_specifier function_declarator compound_statement
2051	{
2052	typedefTable.addToEnclosingScope( TypedefTable::ID );
2053	typedefTable.leaveScope();
2054	$$ = $2->addFunctionBody( $3 )->addType( $1 );
2055	}
2056	\| type_qualifier_list function_declarator compound_statement
2057	{
2058	typedefTable.addToEnclosingScope( TypedefTable::ID );
2059	typedefTable.leaveScope();
2060	$$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
2061	}
2062	\| declaration_qualifier_list function_declarator compound_statement
2063	{
2064	typedefTable.addToEnclosingScope( TypedefTable::ID );
2065	typedefTable.leaveScope();
2066	$$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
2067	}
2068	\| declaration_qualifier_list type_qualifier_list function_declarator compound_statement
2069	{
2070	typedefTable.addToEnclosingScope( TypedefTable::ID );
2071	typedefTable.leaveScope();
2072	$$ = $3->addFunctionBody( $4 )->addQualifiers( $2 )->addQualifiers( $1 );
2073	}
2074
2075	// Old-style K&R function definition, OBSOLESCENT (see 4)
2076	\| declaration_specifier old_function_declarator push old_declaration_list_opt compound_statement
2077	{
2078	typedefTable.addToEnclosingScope( TypedefTable::ID );
2079	typedefTable.leaveScope();
2080	$$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addType( $1 );
2081	}
2082	\| type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2083	{
2084	typedefTable.addToEnclosingScope( TypedefTable::ID );
2085	typedefTable.leaveScope();
2086	$$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
2087	}
2088
2089	// Old-style K&R function definition with "implicit int" type_specifier, OBSOLESCENT (see 4)
2090	\| declaration_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2091	{
2092	typedefTable.addToEnclosingScope( TypedefTable::ID );
2093	typedefTable.leaveScope();
2094	$$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
2095	}
2096	\| declaration_qualifier_list type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2097	{
2098	typedefTable.addToEnclosingScope( TypedefTable::ID );
2099	typedefTable.leaveScope();
2100	$$ = $3->addOldDeclList( $5 )->addFunctionBody( $6 )->addQualifiers( $2 )->addQualifiers( $1 );
2101	}
2102	;
2103
2104	declarator:
2105	variable_declarator
2106	\| variable_type_redeclarator
2107	\| function_declarator
2108	;
2109
2110	subrange:
2111	constant_expression '~' constant_expression // CFA, integer subrange
2112	{ $$ = new ExpressionNode( build_range( $1, $3 ) ); }
2113	;
2114
2115	asm_name_opt: // GCC
2116	// empty
2117	\| ASM '(' string_literal_list ')' attribute_list_opt { delete $3; } // FIX ME: unimplemented
2118	;
2119
2120	attribute_list_opt: // GCC
2121	// empty
2122	{ $$ = 0; }
2123	\| attribute_list
2124	;
2125
2126	attribute_list: // GCC
2127	attribute
2128	\| attribute_list attribute
2129	{ $$ = $2->addQualifiers( $1 ); }
2130	;
2131
2132	attribute: // GCC
2133	ATTRIBUTE '(' '(' attribute_parameter_list ')' ')'
2134	// { $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
2135	{ $$ = 0; }
2136	;
2137
2138	attribute_parameter_list: // GCC
2139	attrib
2140	\| attribute_parameter_list ',' attrib
2141	;
2142
2143	attrib: // GCC
2144	// empty
2145	\| any_word
2146	\| any_word '(' comma_expression_opt ')' { delete $3; } // FIX ME: unimplemented
2147	;
2148
2149	any_word: // GCC
2150	identifier_or_type_name { delete $1; } // FIX ME: unimplemented
2151	\| storage_class { delete $1; } // FIX ME: unimplemented
2152	\| basic_type_name { delete $1; } // FIX ME: unimplemented
2153	\| type_qualifier { delete $1; } // FIX ME: unimplemented
2154	;
2155
2156	// ============================================================================
2157	// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2158	// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2159	// in:
2160	//
2161	// int (*f())[10] { ... };
2162	// ... (*f())[3] += 1; // definition mimics usage
2163	//
2164	// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2165	// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2166	// ============================================================================
2167
2168	// ----------------------------------------------------------------------------
2169	// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2170	// to define a variable or function prototype, e.g.:
2171	//
2172	// valid declaration invalid definition
2173	// ----------------- ------------------
2174	// int f; int f {}
2175	// int f; int f {}
2176	// int f[10]; int f[10] {}
2177	// int (f)(int); int (f)(int) {}
2178	//
2179	// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2180	// variable_declarator and function_declarator.
2181	// ----------------------------------------------------------------------------
2182
2183	// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2184	// declaring an array of functions versus a pointer to an array of functions.
2185
2186	variable_declarator:
2187	paren_identifier attribute_list_opt
2188	{ $$ = $1->addQualifiers( $2 ); }
2189	\| variable_ptr
2190	\| variable_array attribute_list_opt
2191	{ $$ = $1->addQualifiers( $2 ); }
2192	\| variable_function attribute_list_opt
2193	{ $$ = $1->addQualifiers( $2 ); }
2194	;
2195
2196	paren_identifier:
2197	identifier
2198	{
2199	typedefTable.setNextIdentifier( *$1 );
2200	$$ = DeclarationNode::newName( $1 );
2201	}
2202	\| '(' paren_identifier ')' // redundant parenthesis
2203	{ $$ = $2; }
2204	;
2205
2206	variable_ptr:
2207	ptrref_operator variable_declarator
2208	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2209	\| ptrref_operator type_qualifier_list variable_declarator
2210	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2211	\| '(' variable_ptr ')'
2212	{ $$ = $2; }
2213	;
2214
2215	variable_array:
2216	paren_identifier array_dimension
2217	{ $$ = $1->addArray( $2 ); }
2218	\| '(' variable_ptr ')' array_dimension
2219	{ $$ = $2->addArray( $4 ); }
2220	\| '(' variable_array ')' multi_array_dimension // redundant parenthesis
2221	{ $$ = $2->addArray( $4 ); }
2222	\| '(' variable_array ')' // redundant parenthesis
2223	{ $$ = $2; }
2224	;
2225
2226	variable_function:
2227	'(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2228	{ $$ = $2->addParamList( $6 ); }
2229	\| '(' variable_function ')' // redundant parenthesis
2230	{ $$ = $2; }
2231	;
2232
2233	// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2234	// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2235	// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2236
2237	function_declarator:
2238	function_no_ptr attribute_list_opt
2239	{ $$ = $1->addQualifiers( $2 ); }
2240	\| function_ptr
2241	\| function_array attribute_list_opt
2242	{ $$ = $1->addQualifiers( $2 ); }
2243	;
2244
2245	function_no_ptr:
2246	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2247	{ $$ = $1->addParamList( $4 ); }
2248	\| '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2249	{ $$ = $2->addParamList( $6 ); }
2250	\| '(' function_no_ptr ')' // redundant parenthesis
2251	{ $$ = $2; }
2252	;
2253
2254	function_ptr:
2255	ptrref_operator function_declarator
2256	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2257	\| ptrref_operator type_qualifier_list function_declarator
2258	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2259	\| '(' function_ptr ')'
2260	{ $$ = $2; }
2261	;
2262
2263	function_array:
2264	'(' function_ptr ')' array_dimension
2265	{ $$ = $2->addArray( $4 ); }
2266	\| '(' function_array ')' multi_array_dimension // redundant parenthesis
2267	{ $$ = $2->addArray( $4 ); }
2268	\| '(' function_array ')' // redundant parenthesis
2269	{ $$ = $2; }
2270	;
2271
2272	// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4) that is not redefining a typedef name
2273	// (see function_declarator for additional comments). The pattern precludes returning arrays and functions versus
2274	// pointers to arrays and functions.
2275
2276	old_function_declarator:
2277	old_function_no_ptr
2278	\| old_function_ptr
2279	\| old_function_array
2280	;
2281
2282	old_function_no_ptr:
2283	paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
2284	{ $$ = $1->addIdList( $3 ); }
2285	\| '(' old_function_ptr ')' '(' identifier_list ')'
2286	{ $$ = $2->addIdList( $5 ); }
2287	\| '(' old_function_no_ptr ')' // redundant parenthesis
2288	{ $$ = $2; }
2289	;
2290
2291	old_function_ptr:
2292	ptrref_operator old_function_declarator
2293	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2294	\| ptrref_operator type_qualifier_list old_function_declarator
2295	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2296	\| '(' old_function_ptr ')'
2297	{ $$ = $2; }
2298	;
2299
2300	old_function_array:
2301	'(' old_function_ptr ')' array_dimension
2302	{ $$ = $2->addArray( $4 ); }
2303	\| '(' old_function_array ')' multi_array_dimension // redundant parenthesis
2304	{ $$ = $2->addArray( $4 ); }
2305	\| '(' old_function_array ')' // redundant parenthesis
2306	{ $$ = $2; }
2307	;
2308
2309	// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2310	//
2311	// typedef int foo;
2312	// {
2313	// int foo; // redefine typedef name in new scope
2314	// }
2315	//
2316	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2317	// and functions versus pointers to arrays and functions.
2318
2319	variable_type_redeclarator:
2320	paren_type attribute_list_opt
2321	{ $$ = $1->addQualifiers( $2 ); }
2322	\| type_ptr
2323	\| type_array attribute_list_opt
2324	{ $$ = $1->addQualifiers( $2 ); }
2325	\| type_function attribute_list_opt
2326	{ $$ = $1->addQualifiers( $2 ); }
2327	;
2328
2329	paren_type:
2330	typedef
2331	\| '(' paren_type ')'
2332	{ $$ = $2; }
2333	;
2334
2335	type_ptr:
2336	ptrref_operator variable_type_redeclarator
2337	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2338	\| ptrref_operator type_qualifier_list variable_type_redeclarator
2339	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2340	\| '(' type_ptr ')'
2341	{ $$ = $2; }
2342	;
2343
2344	type_array:
2345	paren_type array_dimension
2346	{ $$ = $1->addArray( $2 ); }
2347	\| '(' type_ptr ')' array_dimension
2348	{ $$ = $2->addArray( $4 ); }
2349	\| '(' type_array ')' multi_array_dimension // redundant parenthesis
2350	{ $$ = $2->addArray( $4 ); }
2351	\| '(' type_array ')' // redundant parenthesis
2352	{ $$ = $2; }
2353	;
2354
2355	type_function:
2356	paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2357	{ $$ = $1->addParamList( $4 ); }
2358	\| '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2359	{ $$ = $2->addParamList( $6 ); }
2360	\| '(' type_function ')' // redundant parenthesis
2361	{ $$ = $2; }
2362	;
2363
2364	// This pattern parses a declaration for a parameter variable or function prototype that is not redefining a typedef
2365	// name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes declaring an
2366	// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
2367	// arrays and functions.
2368
2369	identifier_parameter_declarator:
2370	paren_identifier attribute_list_opt
2371	{ $$ = $1->addQualifiers( $2 ); }
2372	\| identifier_parameter_ptr
2373	\| identifier_parameter_array attribute_list_opt
2374	{ $$ = $1->addQualifiers( $2 ); }
2375	\| identifier_parameter_function attribute_list_opt
2376	{ $$ = $1->addQualifiers( $2 ); }
2377	;
2378
2379	identifier_parameter_ptr:
2380	ptrref_operator identifier_parameter_declarator
2381	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2382	\| ptrref_operator type_qualifier_list identifier_parameter_declarator
2383	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2384	\| '(' identifier_parameter_ptr ')'
2385	{ $$ = $2; }
2386	;
2387
2388	identifier_parameter_array:
2389	paren_identifier array_parameter_dimension
2390	{ $$ = $1->addArray( $2 ); }
2391	\| '(' identifier_parameter_ptr ')' array_dimension
2392	{ $$ = $2->addArray( $4 ); }
2393	\| '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2394	{ $$ = $2->addArray( $4 ); }
2395	\| '(' identifier_parameter_array ')' // redundant parenthesis
2396	{ $$ = $2; }
2397	;
2398
2399	identifier_parameter_function:
2400	paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2401	{ $$ = $1->addParamList( $4 ); }
2402	\| '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2403	{ $$ = $2->addParamList( $6 ); }
2404	\| '(' identifier_parameter_function ')' // redundant parenthesis
2405	{ $$ = $2; }
2406	;
2407
2408	// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2409	// e.g.:
2410	//
2411	// typedef int foo;
2412	// int f( int foo ); // redefine typedef name in new scope
2413	//
2414	// and allows the C99 array options, which can only appear in a parameter list. In addition, the pattern handles the
2415	// special meaning of parenthesis around a typedef name:
2416	//
2417	// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2418	// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2419	// not as redundant parentheses around the identifier."
2420	//
2421	// For example:
2422	//
2423	// typedef float T;
2424	// int f( int ( T [5] ) ); // see abstract_parameter_declarator
2425	// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
2426	// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
2427	// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
2428	//
2429	// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2430	// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2431	// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2432	// functions.
2433
2434	type_parameter_redeclarator:
2435	typedef attribute_list_opt
2436	{ $$ = $1->addQualifiers( $2 ); }
2437	\| type_parameter_ptr
2438	\| type_parameter_array attribute_list_opt
2439	{ $$ = $1->addQualifiers( $2 ); }
2440	\| type_parameter_function attribute_list_opt
2441	{ $$ = $1->addQualifiers( $2 ); }
2442	;
2443
2444	typedef:
2445	TYPEDEFname
2446	{
2447	typedefTable.setNextIdentifier( *$1 );
2448	$$ = DeclarationNode::newName( $1 );
2449	}
2450	\| TYPEGENname
2451	{
2452	typedefTable.setNextIdentifier( *$1 );
2453	$$ = DeclarationNode::newName( $1 );
2454	}
2455	;
2456
2457	type_parameter_ptr:
2458	ptrref_operator type_parameter_redeclarator
2459	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2460	\| ptrref_operator type_qualifier_list type_parameter_redeclarator
2461	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2462	\| '(' type_parameter_ptr ')'
2463	{ $$ = $2; }
2464	;
2465
2466	type_parameter_array:
2467	typedef array_parameter_dimension
2468	{ $$ = $1->addArray( $2 ); }
2469	\| '(' type_parameter_ptr ')' array_parameter_dimension
2470	{ $$ = $2->addArray( $4 ); }
2471	;
2472
2473	type_parameter_function:
2474	typedef '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2475	{ $$ = $1->addParamList( $4 ); }
2476	\| '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2477	{ $$ = $2->addParamList( $6 ); }
2478	;
2479
2480	// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2481	// which the type applies, e.g.:
2482	//
2483	// sizeof( int );
2484	// sizeof( int [10] );
2485	//
2486	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2487	// and functions versus pointers to arrays and functions.
2488
2489	abstract_declarator:
2490	abstract_ptr
2491	\| abstract_array attribute_list_opt
2492	{ $$ = $1->addQualifiers( $2 ); }
2493	\| abstract_function attribute_list_opt
2494	{ $$ = $1->addQualifiers( $2 ); }
2495	;
2496
2497	abstract_ptr:
2498	ptrref_operator
2499	{ $$ = DeclarationNode::newPointer( 0 ); }
2500	\| ptrref_operator type_qualifier_list
2501	{ $$ = DeclarationNode::newPointer( $2 ); }
2502	\| ptrref_operator abstract_declarator
2503	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2504	\| ptrref_operator type_qualifier_list abstract_declarator
2505	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2506	\| '(' abstract_ptr ')'
2507	{ $$ = $2; }
2508	;
2509
2510	abstract_array:
2511	array_dimension
2512	\| '(' abstract_ptr ')' array_dimension
2513	{ $$ = $2->addArray( $4 ); }
2514	\| '(' abstract_array ')' multi_array_dimension // redundant parenthesis
2515	{ $$ = $2->addArray( $4 ); }
2516	\| '(' abstract_array ')' // redundant parenthesis
2517	{ $$ = $2; }
2518	;
2519
2520	abstract_function:
2521	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2522	{ $$ = DeclarationNode::newFunction( 0, 0, $3, 0 ); }
2523	\| '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2524	{ $$ = $2->addParamList( $6 ); }
2525	\| '(' abstract_function ')' // redundant parenthesis
2526	{ $$ = $2; }
2527	;
2528
2529	array_dimension:
2530	// Only the first dimension can be empty.
2531	'[' ']'
2532	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
2533	\| '[' ']' multi_array_dimension
2534	{ $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2535	\| multi_array_dimension
2536	;
2537
2538	multi_array_dimension:
2539	'[' push assignment_expression pop ']'
2540	{ $$ = DeclarationNode::newArray( $3, 0, false ); }
2541	\| '[' push '*' pop ']' // C99
2542	{ $$ = DeclarationNode::newVarArray( 0 ); }
2543	\| multi_array_dimension '[' push assignment_expression pop ']'
2544	{ $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2545	\| multi_array_dimension '[' push '*' pop ']' // C99
2546	{ $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2547	;
2548
2549	// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2550	// identifier to which the type applies, e.g.:
2551	//
2552	// int f( int ); // abstract variable parameter; no parameter name specified
2553	// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
2554	//
2555	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2556	// and functions versus pointers to arrays and functions.
2557
2558	abstract_parameter_declarator:
2559	abstract_parameter_ptr
2560	\| abstract_parameter_array attribute_list_opt
2561	{ $$ = $1->addQualifiers( $2 ); }
2562	\| abstract_parameter_function attribute_list_opt
2563	{ $$ = $1->addQualifiers( $2 ); }
2564	;
2565
2566	abstract_parameter_ptr:
2567	ptrref_operator
2568	{ $$ = DeclarationNode::newPointer( 0 ); }
2569	\| ptrref_operator type_qualifier_list
2570	{ $$ = DeclarationNode::newPointer( $2 ); }
2571	\| ptrref_operator abstract_parameter_declarator
2572	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2573	\| ptrref_operator type_qualifier_list abstract_parameter_declarator
2574	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2575	\| '(' abstract_parameter_ptr ')'
2576	{ $$ = $2; }
2577	;
2578
2579	abstract_parameter_array:
2580	array_parameter_dimension
2581	\| '(' abstract_parameter_ptr ')' array_parameter_dimension
2582	{ $$ = $2->addArray( $4 ); }
2583	\| '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2584	{ $$ = $2->addArray( $4 ); }
2585	\| '(' abstract_parameter_array ')' // redundant parenthesis
2586	{ $$ = $2; }
2587	;
2588
2589	abstract_parameter_function:
2590	'(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2591	{ $$ = DeclarationNode::newFunction( 0, 0, $3, 0 ); }
2592	\| '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2593	{ $$ = $2->addParamList( $6 ); }
2594	\| '(' abstract_parameter_function ')' // redundant parenthesis
2595	{ $$ = $2; }
2596	;
2597
2598	array_parameter_dimension:
2599	// Only the first dimension can be empty or have qualifiers.
2600	array_parameter_1st_dimension
2601	\| array_parameter_1st_dimension multi_array_dimension
2602	{ $$ = $1->addArray( $2 ); }
2603	\| multi_array_dimension
2604	;
2605
2606	// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
2607	//
2608	// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
2609	// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
2610
2611	array_parameter_1st_dimension:
2612	'[' ']'
2613	{ $$ = DeclarationNode::newArray( 0, 0, false ); }
2614	// multi_array_dimension handles the '[' '*' ']' case
2615	\| '[' push type_qualifier_list '*' pop ']' // remaining C99
2616	{ $$ = DeclarationNode::newVarArray( $3 ); }
2617	\| '[' push type_qualifier_list pop ']'
2618	{ $$ = DeclarationNode::newArray( 0, $3, false ); }
2619	// multi_array_dimension handles the '[' assignment_expression ']' case
2620	\| '[' push type_qualifier_list assignment_expression pop ']'
2621	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
2622	\| '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
2623	{ $$ = DeclarationNode::newArray( $5, $4, true ); }
2624	\| '[' push type_qualifier_list STATIC assignment_expression pop ']'
2625	{ $$ = DeclarationNode::newArray( $5, $3, true ); }
2626	;
2627
2628	// This pattern parses a declaration of an abstract variable, i.e., there is no identifier to which the type applies,
2629	// e.g.:
2630	//
2631	// sizeof( int ); // abstract variable; no identifier name specified
2632	//
2633	// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2634	// and functions versus pointers to arrays and functions.
2635
2636	variable_abstract_declarator:
2637	variable_abstract_ptr
2638	\| variable_abstract_array attribute_list_opt
2639	{ $$ = $1->addQualifiers( $2 ); }
2640	\| variable_abstract_function attribute_list_opt
2641	{ $$ = $1->addQualifiers( $2 ); }
2642	;
2643
2644	variable_abstract_ptr:
2645	ptrref_operator
2646	{ $$ = DeclarationNode::newPointer( 0 ); }
2647	\| ptrref_operator type_qualifier_list
2648	{ $$ = DeclarationNode::newPointer( $2 ); }
2649	\| ptrref_operator variable_abstract_declarator
2650	{ $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2651	\| ptrref_operator type_qualifier_list variable_abstract_declarator
2652	{ $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2653	\| '(' variable_abstract_ptr ')'
2654	{ $$ = $2; }
2655	;
2656
2657	variable_abstract_array:
2658	array_dimension
2659	\| '(' variable_abstract_ptr ')' array_dimension
2660	{ $$ = $2->addArray( $4 ); }
2661	\| '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
2662	{ $$ = $2->addArray( $4 ); }
2663	\| '(' variable_abstract_array ')' // redundant parenthesis
2664	{ $$ = $2; }
2665	;
2666
2667	variable_abstract_function:
2668	'(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2669	{ $$ = $2->addParamList( $6 ); }
2670	\| '(' variable_abstract_function ')' // redundant parenthesis
2671	{ $$ = $2; }
2672	;
2673
2674	// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
2675	// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
2676
2677	new_identifier_parameter_declarator_tuple: // CFA
2678	new_identifier_parameter_declarator_no_tuple
2679	\| new_abstract_tuple
2680	\| type_qualifier_list new_abstract_tuple
2681	{ $$ = $2->addQualifiers( $1 ); }
2682	;
2683
2684	new_identifier_parameter_declarator_no_tuple: // CFA
2685	new_identifier_parameter_ptr
2686	\| new_identifier_parameter_array
2687	;
2688
2689	new_identifier_parameter_ptr: // CFA
2690	ptrref_operator type_specifier
2691	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2692	\| type_qualifier_list ptrref_operator type_specifier
2693	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2694	\| ptrref_operator new_abstract_function
2695	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2696	\| type_qualifier_list ptrref_operator new_abstract_function
2697	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2698	\| ptrref_operator new_identifier_parameter_declarator_tuple
2699	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2700	\| type_qualifier_list ptrref_operator new_identifier_parameter_declarator_tuple
2701	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2702	;
2703
2704	new_identifier_parameter_array: // CFA
2705	// Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
2706	// shift/reduce conflict with new-style empty (void) function return type.
2707	'[' ']' type_specifier
2708	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2709	\| new_array_parameter_1st_dimension type_specifier
2710	{ $$ = $2->addNewArray( $1 ); }
2711	\| '[' ']' multi_array_dimension type_specifier
2712	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2713	\| new_array_parameter_1st_dimension multi_array_dimension type_specifier
2714	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2715	\| multi_array_dimension type_specifier
2716	{ $$ = $2->addNewArray( $1 ); }
2717	\| '[' ']' new_identifier_parameter_ptr
2718	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2719	\| new_array_parameter_1st_dimension new_identifier_parameter_ptr
2720	{ $$ = $2->addNewArray( $1 ); }
2721	\| '[' ']' multi_array_dimension new_identifier_parameter_ptr
2722	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2723	\| new_array_parameter_1st_dimension multi_array_dimension new_identifier_parameter_ptr
2724	{ $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2725	\| multi_array_dimension new_identifier_parameter_ptr
2726	{ $$ = $2->addNewArray( $1 ); }
2727	;
2728
2729	new_array_parameter_1st_dimension:
2730	'[' push type_qualifier_list '*' pop ']' // remaining C99
2731	{ $$ = DeclarationNode::newVarArray( $3 ); }
2732	\| '[' push type_qualifier_list assignment_expression pop ']'
2733	{ $$ = DeclarationNode::newArray( $4, $3, false ); }
2734	\| '[' push declaration_qualifier_list assignment_expression pop ']'
2735	// declaration_qualifier_list must be used because of shift/reduce conflict with
2736	// assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
2737	// appear in this context.
2738	{ $$ = DeclarationNode::newArray( $4, $3, true ); }
2739	\| '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
2740	{ $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
2741	;
2742
2743	// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
2744	// identifier to which the type applies, e.g.:
2745	//
2746	// [int] f( int ); // abstract variable parameter; no parameter name specified
2747	// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
2748	//
2749	// These rules need LR(3):
2750	//
2751	// new_abstract_tuple identifier_or_type_name
2752	// '[' new_parameter_list ']' identifier_or_type_name '(' new_parameter_type_list_opt ')'
2753	//
2754	// since a function return type can be syntactically identical to a tuple type:
2755	//
2756	// [int, int] t;
2757	// [int, int] f( int );
2758	//
2759	// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
2760	// new_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
2761	// lookahead. To accomplish this, new_abstract_declarator has an entry point without tuple, and tuple declarations are
2762	// duplicated when appearing with new_function_specifier.
2763
2764	new_abstract_declarator_tuple: // CFA
2765	new_abstract_tuple
2766	\| type_qualifier_list new_abstract_tuple
2767	{ $$ = $2->addQualifiers( $1 ); }
2768	\| new_abstract_declarator_no_tuple
2769	;
2770
2771	new_abstract_declarator_no_tuple: // CFA
2772	new_abstract_ptr
2773	\| new_abstract_array
2774	;
2775
2776	new_abstract_ptr: // CFA
2777	ptrref_operator type_specifier
2778	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2779	\| type_qualifier_list ptrref_operator type_specifier
2780	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2781	\| ptrref_operator new_abstract_function
2782	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2783	\| type_qualifier_list ptrref_operator new_abstract_function
2784	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2785	\| ptrref_operator new_abstract_declarator_tuple
2786	{ $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2787	\| type_qualifier_list ptrref_operator new_abstract_declarator_tuple
2788	{ $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2789	;
2790
2791	new_abstract_array: // CFA
2792	// Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
2793	// empty (void) function return type.
2794	'[' ']' type_specifier
2795	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2796	\| '[' ']' multi_array_dimension type_specifier
2797	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2798	\| multi_array_dimension type_specifier
2799	{ $$ = $2->addNewArray( $1 ); }
2800	\| '[' ']' new_abstract_ptr
2801	{ $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2802	\| '[' ']' multi_array_dimension new_abstract_ptr
2803	{ $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2804	\| multi_array_dimension new_abstract_ptr
2805	{ $$ = $2->addNewArray( $1 ); }
2806	;
2807
2808	new_abstract_tuple: // CFA
2809	'[' push new_abstract_parameter_list pop ']'
2810	{ $$ = DeclarationNode::newTuple( $3 ); }
2811	;
2812
2813	new_abstract_function: // CFA
2814	'[' ']' '(' new_parameter_type_list_opt ')'
2815	{ $$ = DeclarationNode::newFunction( 0, DeclarationNode::newTuple( 0 ), $4, 0 ); }
2816	\| new_abstract_tuple '(' push new_parameter_type_list_opt pop ')'
2817	{ $$ = DeclarationNode::newFunction( 0, $1, $4, 0 ); }
2818	\| new_function_return '(' push new_parameter_type_list_opt pop ')'
2819	{ $$ = DeclarationNode::newFunction( 0, $1, $4, 0 ); }
2820	;
2821
2822	// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
2823	// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
2824	//
2825	// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
2826	// the declaration specifiers in a declaration is an obsolescent feature."
2827	//
2828	// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
2829	// prototype-format parameter type declarators) is an obsolescent feature."
2830	//
2831	// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
2832	// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
2833
2834	//*********************** MISCELLANEOUS ******************************
2835
2836	comma_opt: // redundant comma
2837	// empty
2838	\| ','
2839	;
2840
2841	assignment_opt:
2842	// empty
2843	{ $$ = 0; }
2844	\| '=' assignment_expression
2845	{ $$ = $2; }
2846	;
2847
2848	%%
2849	// ----end of grammar----
2850
2851	extern char *yytext;
2852
2853	void yyerror( const char * ) {
2854	std::cout << "Error ";
2855	if ( yyfilename ) {
2856	std::cout << "in file " << yyfilename << " ";
2857	} // if
2858	std::cout << "at line " << yylineno << " reading token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << "\"" << std::endl;
2859	}
2860
2861	// Local Variables: //
2862	// mode: c++ //
2863	// tab-width: 4 //
2864	// compile-command: "make install" //
2865	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format