source: src/Parser/parser.yy @ dafbde8

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since dafbde8 was fd54fef, checked in by Michael Brooks <mlbrooks@…>, 3 years ago

Converting the project to use the new syntax for otype, dtype and ttytpe.

Changed prelude (gen), libcfa and test suite to use it. Added a simple deprecation rule of the old syntax to the parser; we might wish to support both syntaxes "officially," like with an extra CLI switch, but this measure should serve as a simple reminder for our team to try the new syntax.

  • Property mode set to 100644
File size: 137.6 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Mon Jan 11 21:32:10 2021
13// Update Count     : 4633
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169        *name = string("__postfix_func_") + *name;
170        return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
210        } // if
211} // forCtrl
212
213bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
217if ( N ) {                                                                                                                                              \
218        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
219        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
220        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
221        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
222        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
223} else {                                                                                                                                                \
224        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
225        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
226        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234        Token tok;
235        ParseNode * pn;
236        ExpressionNode * en;
237        DeclarationNode * decl;
238        AggregateDecl::Aggregate aggKey;
239        TypeDecl::Kind tclass;
240        StatementNode * sn;
241        WaitForStmt * wfs;
242        Expression * constant;
243        IfCtrl * ifctl;
244        ForCtrl * fctl;
245        enum OperKinds compop;
246        LabelNode * label;
247        InitializerNode * in;
248        OperKinds op;
249        std::string * str;
250        bool flag;
251        CatchStmt::Kind catch_kind;
252        GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL                                                                              // C11
261%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN                                                                                 // C11
263%token CONST VOLATILE
264%token RESTRICT                                                                                 // C99
265%token ATOMIC                                                                                   // C11
266%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY                                                   // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T                                                                             // CFA
272%token VALIST                                                                                   // GCC
273%token AUTO_TYPE                                                                                // GCC
274%token TYPEOF BASETYPEOF LABEL                                                  // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION                                                                                // CFA
277%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
279%token SIZEOF OFFSETOF
280// %token RESUME                                                                                        // CFA
281%token SUSPEND                                                                                  // CFA
282%token ATTRIBUTE EXTENSION                                                              // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
290%token<tok> TIMEOUT                             WOR
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list_opt  argument_expression                     default_initializer_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en> bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class new_type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581        | type_name '.' identifier                                                      // CFA, nested type
582                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
583        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
584                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
585        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
586                {
587                        // add the missing control expression to the GenericExpr and return it
588                        $5->control = maybeMoveBuild<Expression>( $3 );
589                        $$ = new ExpressionNode( $5 );
590                }
591        // | RESUME '(' comma_expression ')'
592        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
593        // | RESUME '(' comma_expression ')' compound_statement
594        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
595        ;
596
597generic_assoc_list:                                                                             // C11
598        generic_association
599        | generic_assoc_list ',' generic_association
600                {
601                        // steal the association node from the singleton and delete the wrapper
602                        $1->associations.splice($1->associations.end(), $3->associations);
603                        delete $3;
604                        $$ = $1;
605                }
606        ;
607
608generic_association:                                                                    // C11
609        type_no_function ':' assignment_expression
610                {
611                        // create a GenericExpr wrapper with one association pair
612                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
613                }
614        | DEFAULT ':' assignment_expression
615                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
616        ;
617
618postfix_expression:
619        primary_expression
620        | postfix_expression '[' assignment_expression ']'
621                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
622                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
623                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
624                // equivalent to the old x[i,j].
625                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
626        | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
627                {
628                        Token fn;
629                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
630                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
631                }
632        | postfix_expression '(' argument_expression_list_opt ')'
633                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
634        | postfix_expression '`' identifier                                     // CFA, postfix call
635                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
636        | constant '`' identifier                                                       // CFA, postfix call
637                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
638        | string_literal '`' identifier                                         // CFA, postfix call
639                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
640        | postfix_expression '.' identifier
641                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
642        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
643                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
644        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
645                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
646        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
647                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
648        | postfix_expression '.' aggregate_control
649                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
650        | postfix_expression ARROW identifier
651                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
652        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
653                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
654        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
655                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
656        | postfix_expression ICR
657                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
658        | postfix_expression DECR
659                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
660        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
661                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
662        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
663                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
664        | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
665                {
666                        Token fn;
667                        fn.str = new string( "^?{}" );                          // location undefined
668                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
669                }
670        ;
671
672argument_expression_list_opt:
673        // empty
674                { $$ = nullptr; }
675        | argument_expression
676        | argument_expression_list_opt ',' argument_expression
677                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
678        ;
679
680argument_expression:
681        '@'                                                                                                     // CFA, default parameter
682                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
683                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
684        | assignment_expression
685        ;
686
687field_name_list:                                                                                // CFA, tuple field selector
688        field
689        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
690        ;
691
692field:                                                                                                  // CFA, tuple field selector
693        field_name
694        | FLOATING_DECIMALconstant field
695                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
696        | FLOATING_DECIMALconstant '[' field_name_list ']'
697                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
698        | field_name '.' field
699                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
700        | field_name '.' '[' field_name_list ']'
701                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
702        | field_name ARROW field
703                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704        | field_name ARROW '[' field_name_list ']'
705                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
706        ;
707
708field_name:
709        INTEGERconstant fraction_constants_opt
710                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
711        | FLOATINGconstant fraction_constants_opt
712                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
713        | identifier fraction_constants_opt
714                {
715                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
716                }
717        ;
718
719fraction_constants_opt:
720        // empty
721                { $$ = nullptr; }
722        | fraction_constants_opt FLOATING_FRACTIONconstant
723                {
724                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
725                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
726                }
727        ;
728
729unary_expression:
730        postfix_expression
731                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
732                // semantics checks, e.g., ++3, 3--, *3, &&3
733        | constant
734        | string_literal
735                { $$ = new ExpressionNode( $1 ); }
736        | EXTENSION cast_expression                                                     // GCC
737                { $$ = $2->set_extension( true ); }
738                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
739                //              { * X; }         // dereference X
740                //              { * int X; } // CFA declaration of pointer to int
741        | ptrref_operator cast_expression                                       // CFA
742                {
743                        switch ( $1 ) {
744                          case OperKinds::AddressOf:
745                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
746                                break;
747                          case OperKinds::PointTo:
748                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
749                                break;
750                          case OperKinds::And:
751                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
752                                break;
753                          default:
754                                assert( false );
755                        }
756                }
757        | unary_operator cast_expression
758                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
759        | ICR unary_expression
760                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
761        | DECR unary_expression
762                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
763        | SIZEOF unary_expression
764                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
765        | SIZEOF '(' type_no_function ')'
766                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
767        | ALIGNOF unary_expression                                                      // GCC, variable alignment
768                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
770                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
771        | OFFSETOF '(' type_no_function ',' identifier ')'
772                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
773        ;
774
775ptrref_operator:
776        '*'                                                                                     { $$ = OperKinds::PointTo; }
777        | '&'                                                                           { $$ = OperKinds::AddressOf; }
778                // GCC, address of label must be handled by semantic check for ref,ref,label
779        | ANDAND                                                                        { $$ = OperKinds::And; }
780        ;
781
782unary_operator:
783        '+'                                                                                     { $$ = OperKinds::UnPlus; }
784        | '-'                                                                           { $$ = OperKinds::UnMinus; }
785        | '!'                                                                           { $$ = OperKinds::Neg; }
786        | '~'                                                                           { $$ = OperKinds::BitNeg; }
787        ;
788
789cast_expression:
790        unary_expression
791        | '(' type_no_function ')' cast_expression
792                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
793        | '(' aggregate_control '&' ')' cast_expression         // CFA
794                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
795        | '(' VIRTUAL ')' cast_expression                                       // CFA
796                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
797        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
798                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
799        | '(' RETURN type_no_function ')' cast_expression       // CFA
800                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
801        | '(' COERCE type_no_function ')' cast_expression       // CFA
802                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
803        | '(' qualifier_cast_list ')' cast_expression           // CFA
804                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
805//      | '(' type_no_function ')' tuple
806//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
807        ;
808
809qualifier_cast_list:
810        cast_modifier type_qualifier_name
811        | cast_modifier MUTEX
812        | qualifier_cast_list cast_modifier type_qualifier_name
813        | qualifier_cast_list cast_modifier MUTEX
814        ;
815
816cast_modifier:
817        '-'
818        | '+'
819        ;
820
821exponential_expression:
822        cast_expression
823        | exponential_expression '\\' cast_expression
824                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
825        ;
826
827multiplicative_expression:
828        exponential_expression
829        | multiplicative_expression '*' exponential_expression
830                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
831        | multiplicative_expression '/' exponential_expression
832                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
833        | multiplicative_expression '%' exponential_expression
834                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
835        ;
836
837additive_expression:
838        multiplicative_expression
839        | additive_expression '+' multiplicative_expression
840                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
841        | additive_expression '-' multiplicative_expression
842                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
843        ;
844
845shift_expression:
846        additive_expression
847        | shift_expression LS additive_expression
848                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
849        | shift_expression RS additive_expression
850                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
851        ;
852
853relational_expression:
854        shift_expression
855        | relational_expression '<' shift_expression
856                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
857        | relational_expression '>' shift_expression
858                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
859        | relational_expression LE shift_expression
860                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
861        | relational_expression GE shift_expression
862                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
863        ;
864
865equality_expression:
866        relational_expression
867        | equality_expression EQ relational_expression
868                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
869        | equality_expression NE relational_expression
870                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
871        ;
872
873AND_expression:
874        equality_expression
875        | AND_expression '&' equality_expression
876                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
877        ;
878
879exclusive_OR_expression:
880        AND_expression
881        | exclusive_OR_expression '^' AND_expression
882                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
883        ;
884
885inclusive_OR_expression:
886        exclusive_OR_expression
887        | inclusive_OR_expression '|' exclusive_OR_expression
888                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
889        ;
890
891logical_AND_expression:
892        inclusive_OR_expression
893        | logical_AND_expression ANDAND inclusive_OR_expression
894                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
895        ;
896
897logical_OR_expression:
898        logical_AND_expression
899        | logical_OR_expression OROR logical_AND_expression
900                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
901        ;
902
903conditional_expression:
904        logical_OR_expression
905        | logical_OR_expression '?' comma_expression ':' conditional_expression
906                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
907                // FIX ME: computes $1 twice
908        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
909                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
910        ;
911
912constant_expression:
913        conditional_expression
914        ;
915
916assignment_expression:
917                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
918        conditional_expression
919        | unary_expression assignment_operator assignment_expression
920                {
921//                      if ( $2 == OperKinds::AtAssn ) {
922//                              SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
923//                      } else {
924                                $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
925//                      } // if
926                }
927        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
928                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
929        ;
930
931assignment_expression_opt:
932        // empty
933                { $$ = nullptr; }
934        | assignment_expression
935        ;
936
937assignment_operator:
938        '='                                                                                     { $$ = OperKinds::Assign; }
939        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
940        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
941        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
942        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
943        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
944        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
945        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
946        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
947        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
948        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
949        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
950        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
951        ;
952
953tuple:                                                                                                  // CFA, tuple
954                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
955                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
956//      '[' ']'
957//              { $$ = new ExpressionNode( build_tuple() ); }
958//      | '[' push assignment_expression pop ']'
959//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
960        '[' ',' tuple_expression_list ']'
961                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
962        | '[' push assignment_expression pop ',' tuple_expression_list ']'
963                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
964        ;
965
966tuple_expression_list:
967        assignment_expression
968        | '@'                                                                                           // CFA
969                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
970        | tuple_expression_list ',' assignment_expression
971                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
972        | tuple_expression_list ',' '@'
973                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
974        ;
975
976comma_expression:
977        assignment_expression
978        | comma_expression ',' assignment_expression
979                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
980        ;
981
982comma_expression_opt:
983        // empty
984                { $$ = nullptr; }
985        | comma_expression
986        ;
987
988//*************************** STATEMENTS *******************************
989
990statement:
991        labeled_statement
992        | compound_statement
993        | expression_statement
994        | selection_statement
995        | iteration_statement
996        | jump_statement
997        | with_statement
998        | mutex_statement
999        | waitfor_statement
1000        | exception_statement
1001        | enable_disable_statement
1002                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1003        | asm_statement
1004        | DIRECTIVE
1005                { $$ = new StatementNode( build_directive( $1 ) ); }
1006        ;
1007
1008labeled_statement:
1009                // labels cannot be identifiers 0 or 1
1010        identifier_or_type_name ':' attribute_list_opt statement
1011                { $$ = $4->add_label( $1, $3 ); }
1012        ;
1013
1014compound_statement:
1015        '{' '}'
1016                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1017        | '{' push
1018          local_label_declaration_opt                                           // GCC, local labels
1019          statement_decl_list                                                           // C99, intermix declarations and statements
1020          pop '}'
1021                { $$ = new StatementNode( build_compound( $4 ) ); }
1022        ;
1023
1024statement_decl_list:                                                                    // C99
1025        statement_decl
1026        | statement_decl_list statement_decl
1027                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1028        ;
1029
1030statement_decl:
1031        declaration                                                                                     // CFA, new & old style declarations
1032                { $$ = new StatementNode( $1 ); }
1033        | EXTENSION declaration                                                         // GCC
1034                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1035        | function_definition
1036                { $$ = new StatementNode( $1 ); }
1037        | EXTENSION function_definition                                         // GCC
1038                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1039        | statement
1040        ;
1041
1042statement_list_nodecl:
1043        statement
1044        | statement_list_nodecl statement
1045                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1046        ;
1047
1048expression_statement:
1049        comma_expression_opt ';'
1050                { $$ = new StatementNode( build_expr( $1 ) ); }
1051        ;
1052
1053selection_statement:
1054                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1055                        // the inherent S/R conflict with THEN/ELSE.
1056        push if_statement pop
1057                { $$ = $2; }
1058        | SWITCH '(' comma_expression ')' case_clause
1059                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1060        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1061                {
1062                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1063                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1064                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1065                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1066                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1067                        // statement.
1068                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1069                }
1070        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1071                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1072        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1073                {
1074                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1075                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1076                }
1077        ;
1078
1079if_statement:
1080        IF '(' if_control_expression ')' statement                      %prec THEN
1081                // explicitly deal with the shift/reduce conflict on if/else
1082                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1083        | IF '(' if_control_expression ')' statement ELSE statement
1084                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1085        ;
1086
1087if_control_expression:
1088        comma_expression
1089                { $$ = new IfCtrl( nullptr, $1 ); }
1090        | c_declaration                                                                         // no semi-colon
1091                { $$ = new IfCtrl( $1, nullptr ); }
1092        | cfa_declaration                                                                       // no semi-colon
1093                { $$ = new IfCtrl( $1, nullptr ); }
1094        | declaration comma_expression                                          // semi-colon separated
1095                { $$ = new IfCtrl( $1, $2 ); }
1096        ;
1097
1098// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1099// clause allows a list of values and subranges.
1100
1101case_value:                                                                                             // CFA
1102        constant_expression                                                     { $$ = $1; }
1103        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1104                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1105        | subrange                                                                                      // CFA, subrange
1106        ;
1107
1108case_value_list:                                                                                // CFA
1109        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1110                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1111        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1112        ;
1113
1114case_label:                                                                                             // CFA
1115        CASE case_value_list ':'                                        { $$ = $2; }
1116        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1117                // A semantic check is required to ensure only one default clause per switch/choose statement.
1118        ;
1119
1120//label_list_opt:
1121//      // empty
1122//      | identifier_or_type_name ':'
1123//      | label_list_opt identifier_or_type_name ':'
1124//      ;
1125
1126case_label_list:                                                                                // CFA
1127        case_label
1128        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1129        ;
1130
1131case_clause:                                                                                    // CFA
1132        case_label_list statement                                       { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1133        ;
1134
1135switch_clause_list_opt:                                                                 // CFA
1136        // empty
1137                { $$ = nullptr; }
1138        | switch_clause_list
1139        ;
1140
1141switch_clause_list:                                                                             // CFA
1142        case_label_list statement_list_nodecl
1143                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1144        | switch_clause_list case_label_list statement_list_nodecl
1145                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1146        ;
1147
1148iteration_statement:
1149        WHILE '(' push if_control_expression ')' statement pop
1150                { $$ = new StatementNode( build_while( $4, maybe_build_compound( $6 ) ) ); }
1151        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1152                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1153        | DO statement WHILE '(' comma_expression ')' ';'
1154                { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1155        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1156                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1157        | FOR '(' push for_control_expression_list ')' statement pop
1158                { $$ = new StatementNode( build_for( $4, maybe_build_compound( $6 ) ) ); }
1159        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1160                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1161        ;
1162
1163for_control_expression_list:
1164        for_control_expression
1165        | for_control_expression_list ':' for_control_expression
1166                // ForCtrl + ForCtrl:
1167                //    init + init => multiple declaration statements that are hoisted
1168                //    condition + condition => (expression) && (expression)
1169                //    change + change => (expression), (expression)
1170                {
1171                        $1->init->set_last( $3->init );
1172                        if ( $1->condition ) {
1173                                if ( $3->condition ) {
1174                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1175                                } // if
1176                        } else $1->condition = $3->condition;
1177                        if ( $1->change ) {
1178                                if ( $3->change ) {
1179                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1180                                } // if
1181                        } else $1->change = $3->change;
1182                        $$ = $1;
1183                }
1184        ;
1185
1186for_control_expression:
1187        ';' comma_expression_opt ';' comma_expression_opt
1188                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1189        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1190                { $$ = new ForCtrl( $1, $3, $5 ); }
1191        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1192                { $$ = new ForCtrl( $1, $2, $4 ); }
1193
1194        | comma_expression                                                                      // CFA
1195                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1196                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1197        | '=' comma_expression                                                          // CFA
1198                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1199                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1200        | comma_expression inclexcl comma_expression            // CFA
1201                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1202        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1203                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1204        | comma_expression ';'                                                          // CFA
1205                { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1206        | comma_expression ';' comma_expression                         // CFA
1207                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1208                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1209        | comma_expression ';' '=' comma_expression                     // CFA
1210                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1211                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1212        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1213                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1214        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1215                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1216
1217                // There is a S/R conflicit if ~ and -~ are factored out.
1218        | comma_expression ';' comma_expression '~' '@'         // CFA
1219                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1220        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1221                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1222        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1223                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1224        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1225                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1226        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1227                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1228        ;
1229
1230inclexcl:
1231        '~'
1232                { $$ = OperKinds::LThan; }
1233        | ErangeUpEq
1234                { $$ = OperKinds::LEThan; }
1235        | ErangeDown
1236                { $$ = OperKinds::GThan; }
1237        | ErangeDownEq
1238                { $$ = OperKinds::GEThan; }
1239        ;
1240
1241jump_statement:
1242        GOTO identifier_or_type_name ';'
1243                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1244        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1245                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1246                // whereas normal operator precedence yields goto (*i)+3;
1247                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1248                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1249    | fall_through_name ';'                                                             // CFA
1250                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1251    | fall_through_name identifier_or_type_name ';'             // CFA
1252                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1253        | fall_through_name DEFAULT ';'                                         // CFA
1254                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1255        | CONTINUE ';'
1256                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1257                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1258        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1259                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1260                // the target of the transfer appears only at the start of an iteration statement.
1261                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1262        | BREAK ';'
1263                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1264                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1265        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1266                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1267                // the target of the transfer appears only at the start of an iteration statement.
1268                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1269        | RETURN comma_expression_opt ';'
1270                { $$ = new StatementNode( build_return( $2 ) ); }
1271        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1272                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1273        | SUSPEND ';'
1274                { $$ = new StatementNode( build_suspend( nullptr ) ); }
1275        | SUSPEND compound_statement
1276                { $$ = new StatementNode( build_suspend( $2 ) ); }
1277        | SUSPEND COROUTINE ';'
1278                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1279        | SUSPEND COROUTINE compound_statement
1280                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1281        | SUSPEND GENERATOR ';'
1282                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1283        | SUSPEND GENERATOR compound_statement
1284                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1285        | THROW assignment_expression_opt ';'                           // handles rethrow
1286                { $$ = new StatementNode( build_throw( $2 ) ); }
1287        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1288                { $$ = new StatementNode( build_resume( $2 ) ); }
1289        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1290                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1291        ;
1292
1293fall_through_name:                                                                              // CFA
1294        FALLTHRU
1295        | FALLTHROUGH
1296        ;
1297
1298with_statement:
1299        WITH '(' tuple_expression_list ')' statement
1300                {
1301                        $$ = new StatementNode( build_with( $3, $5 ) );
1302                }
1303        ;
1304
1305// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1306mutex_statement:
1307        MUTEX '(' argument_expression_list_opt ')' statement
1308                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1309        ;
1310
1311when_clause:
1312        WHEN '(' comma_expression ')'                           { $$ = $3; }
1313        ;
1314
1315when_clause_opt:
1316        // empty
1317                { $$ = nullptr; }
1318        | when_clause
1319        ;
1320
1321waitfor:
1322        WAITFOR '(' cast_expression ')'
1323                { $$ = $3; }
1324//      | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1325//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1326        | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1327                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1328        ;
1329
1330cast_expression_list:
1331        cast_expression
1332        | cast_expression_list ',' cast_expression
1333                // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1334                { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1335        ;
1336
1337timeout:
1338        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1339        ;
1340
1341waitfor_clause:
1342        when_clause_opt waitfor statement                                       %prec THEN
1343                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1344        | when_clause_opt waitfor statement WOR waitfor_clause
1345                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1346        | when_clause_opt timeout statement                                     %prec THEN
1347                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1348        | when_clause_opt ELSE statement
1349                { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1350                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1351        | when_clause_opt timeout statement WOR ELSE statement
1352                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1353        | when_clause_opt timeout statement WOR when_clause ELSE statement
1354                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1355        ;
1356
1357waitfor_statement:
1358        when_clause_opt waitfor statement                                       %prec THEN
1359                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1360        | when_clause_opt waitfor statement WOR waitfor_clause
1361                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1362        ;
1363
1364exception_statement:
1365        TRY compound_statement handler_clause
1366                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1367        | TRY compound_statement finally_clause
1368                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1369        | TRY compound_statement handler_clause finally_clause
1370                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1371        ;
1372
1373handler_clause:
1374        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1375                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1376        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1377                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1378        ;
1379
1380handler_predicate_opt:
1381        // empty
1382                { $$ = nullptr; }
1383        | ';' conditional_expression                            { $$ = $2; }
1384        ;
1385
1386handler_key:
1387        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1388        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1389        ;
1390
1391finally_clause:
1392        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1393        ;
1394
1395exception_declaration:
1396                // No SUE declaration in parameter list.
1397        type_specifier_nobody
1398        | type_specifier_nobody declarator
1399                { $$ = $2->addType( $1 ); }
1400        | type_specifier_nobody variable_abstract_declarator
1401                { $$ = $2->addType( $1 ); }
1402        | cfa_abstract_declarator_tuple identifier                      // CFA
1403                { $$ = $1->addName( $2 ); }
1404        | cfa_abstract_declarator_tuple                                         // CFA
1405        ;
1406
1407enable_disable_statement:
1408        enable_disable_key identifier_list compound_statement
1409        ;
1410
1411enable_disable_key:
1412        ENABLE
1413        | DISABLE
1414        ;
1415
1416asm_statement:
1417        ASM asm_volatile_opt '(' string_literal ')' ';'
1418                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1419        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1420                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1421        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1422                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1423        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1424                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1425        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1426                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1427        ;
1428
1429asm_volatile_opt:                                                                               // GCC
1430        // empty
1431                { $$ = false; }
1432        | VOLATILE
1433                { $$ = true; }
1434        ;
1435
1436asm_operands_opt:                                                                               // GCC
1437        // empty
1438                { $$ = nullptr; }                                                               // use default argument
1439        | asm_operands_list
1440        ;
1441
1442asm_operands_list:                                                                              // GCC
1443        asm_operand
1444        | asm_operands_list ',' asm_operand
1445                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1446        ;
1447
1448asm_operand:                                                                                    // GCC
1449        string_literal '(' constant_expression ')'
1450                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1451        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1452                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1453        ;
1454
1455asm_clobbers_list_opt:                                                                  // GCC
1456        // empty
1457                { $$ = nullptr; }                                                               // use default argument
1458        | string_literal
1459                { $$ = new ExpressionNode( $1 ); }
1460        | asm_clobbers_list_opt ',' string_literal
1461                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1462        ;
1463
1464label_list:
1465        identifier
1466                {
1467                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1468                        delete $1;                                                                      // allocated by lexer
1469                }
1470        | label_list ',' identifier
1471                {
1472                        $$ = $1; $1->labels.push_back( *$3 );
1473                        delete $3;                                                                      // allocated by lexer
1474                }
1475        ;
1476
1477//******************************* DECLARATIONS *********************************
1478
1479declaration_list_opt:                                                                   // used at beginning of switch statement
1480        // empty
1481                { $$ = nullptr; }
1482        | declaration_list
1483        ;
1484
1485declaration_list:
1486        declaration
1487        | declaration_list declaration
1488                { $$ = $1->appendList( $2 ); }
1489        ;
1490
1491KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1492        // empty
1493                { $$ = nullptr; }
1494        | KR_parameter_list
1495        ;
1496
1497KR_parameter_list:
1498        push c_declaration pop ';'
1499                { $$ = $2; }
1500        | KR_parameter_list push c_declaration pop ';'
1501                { $$ = $1->appendList( $3 ); }
1502        ;
1503
1504local_label_declaration_opt:                                                    // GCC, local label
1505        // empty
1506        | local_label_declaration_list
1507        ;
1508
1509local_label_declaration_list:                                                   // GCC, local label
1510        LABEL local_label_list ';'
1511        | local_label_declaration_list LABEL local_label_list ';'
1512        ;
1513
1514local_label_list:                                                                               // GCC, local label
1515        identifier_or_type_name
1516        | local_label_list ',' identifier_or_type_name
1517        ;
1518
1519declaration:                                                                                    // old & new style declarations
1520        c_declaration ';'
1521        | cfa_declaration ';'                                                           // CFA
1522        | static_assert                                                                         // C11
1523        ;
1524
1525static_assert:
1526        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1527                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1528        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1529                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1530
1531// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1532// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1533// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1534// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1535// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1536// block, but cannot be mixed within a specific declaration.
1537//
1538//                      CFA                                     C
1539//              [10] int x;                     int x[10];              // array of 10 integers
1540//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1541
1542cfa_declaration:                                                                                // CFA
1543        cfa_variable_declaration
1544        | cfa_typedef_declaration
1545        | cfa_function_declaration
1546        | type_declaring_list
1547                { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1548        | trait_specifier
1549        ;
1550
1551cfa_variable_declaration:                                                               // CFA
1552        cfa_variable_specifier initializer_opt
1553                { $$ = $1->addInitializer( $2 ); }
1554        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1555                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1556                // them as a type_qualifier cannot appear in that context.
1557                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1558        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1559                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1560        ;
1561
1562cfa_variable_specifier:                                                                 // CFA
1563                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1564                // storage-class
1565        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1566                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1567        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1568                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1569        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1570                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1571        ;
1572
1573cfa_function_declaration:                                                               // CFA
1574        cfa_function_specifier
1575        | type_qualifier_list cfa_function_specifier
1576                { $$ = $2->addQualifiers( $1 ); }
1577        | declaration_qualifier_list cfa_function_specifier
1578                { $$ = $2->addQualifiers( $1 ); }
1579        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1580                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1581        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1582                {
1583                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1584                        DeclarationNode * ret = new DeclarationNode;
1585                        ret->type = maybeClone( $1->type->base );
1586                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1587                }
1588        ;
1589
1590cfa_function_specifier:                                                                 // CFA
1591//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1592//              {
1593//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1594//              }
1595//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1596//              {
1597//                      typedefTable.setNextIdentifier( *$5 );
1598//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1599//              }
1600//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1601//              {
1602//                      typedefTable.setNextIdentifier( *$5 );
1603//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1604//              }
1605//      | '[' ']' typegen_name
1606                // identifier_or_type_name must be broken apart because of the sequence:
1607                //
1608                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1609                //   '[' ']' type_specifier
1610                //
1611                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1612                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1613        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1614                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1615                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1616        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1617                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1618        ;
1619
1620cfa_function_return:                                                                    // CFA
1621        '[' push cfa_parameter_list pop ']'
1622                { $$ = DeclarationNode::newTuple( $3 ); }
1623        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1624                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1625                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1626        ;
1627
1628cfa_typedef_declaration:                                                                // CFA
1629        TYPEDEF cfa_variable_specifier
1630                {
1631                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1632                        $$ = $2->addTypedef();
1633                }
1634        | TYPEDEF cfa_function_specifier
1635                {
1636                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1637                        $$ = $2->addTypedef();
1638                }
1639        | cfa_typedef_declaration pop ',' push identifier
1640                {
1641                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1642                        $$ = $1->appendList( $1->cloneType( $5 ) );
1643                }
1644        ;
1645
1646// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1647// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1648
1649typedef_declaration:
1650        TYPEDEF type_specifier declarator
1651                {
1652                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1653                        $$ = $3->addType( $2 )->addTypedef();
1654                }
1655        | typedef_declaration pop ',' push declarator
1656                {
1657                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1658                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1659                }
1660        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1661                {
1662                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1663                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1664                }
1665        | type_specifier TYPEDEF declarator
1666                {
1667                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1668                        $$ = $3->addType( $1 )->addTypedef();
1669                }
1670        | type_specifier TYPEDEF type_qualifier_list declarator
1671                {
1672                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1673                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1674                }
1675        ;
1676
1677typedef_expression:
1678                // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1679        TYPEDEF identifier '=' assignment_expression
1680                {
1681                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1682                }
1683        | typedef_expression pop ',' push identifier '=' assignment_expression
1684                {
1685                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1686                }
1687        ;
1688
1689c_declaration:
1690        declaration_specifier declaring_list
1691                { $$ = distAttr( $1, $2 ); }
1692        | typedef_declaration
1693        | typedef_expression                                                            // deprecated GCC, naming expression type
1694        | sue_declaration_specifier
1695        ;
1696
1697declaring_list:
1698                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1699                // storage-class
1700        declarator asm_name_opt initializer_opt
1701                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1702        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1703                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1704        ;
1705
1706declaration_specifier:                                                                  // type specifier + storage class
1707        basic_declaration_specifier
1708        | sue_declaration_specifier
1709        | type_declaration_specifier
1710        ;
1711
1712declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1713                // Preclude SUE declarations in restricted scopes:
1714                //
1715                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1716                //
1717                // because it is impossible to call f due to name equivalence.
1718        basic_declaration_specifier
1719        | sue_declaration_specifier_nobody
1720        | type_declaration_specifier
1721        ;
1722
1723type_specifier:                                                                                 // type specifier
1724        basic_type_specifier
1725        | sue_type_specifier
1726        | type_type_specifier
1727        ;
1728
1729type_specifier_nobody:                                                                  // type specifier - {...}
1730                // Preclude SUE declarations in restricted scopes:
1731                //
1732                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1733                //
1734                // because it is impossible to call f due to name equivalence.
1735        basic_type_specifier
1736        | sue_type_specifier_nobody
1737        | type_type_specifier
1738        ;
1739
1740type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1741        // empty
1742                { $$ = nullptr; }
1743        | type_qualifier_list
1744        ;
1745
1746type_qualifier_list:
1747                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1748                //
1749                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1750                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1751                // appeared only once.
1752        type_qualifier
1753        | type_qualifier_list type_qualifier
1754                { $$ = $1->addQualifiers( $2 ); }
1755        ;
1756
1757type_qualifier:
1758        type_qualifier_name
1759        | attribute
1760        ;
1761
1762type_qualifier_name:
1763        CONST
1764                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1765        | RESTRICT
1766                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1767        | VOLATILE
1768                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1769        | ATOMIC
1770                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1771        | forall
1772        ;
1773
1774forall:
1775        FORALL '(' type_parameter_list ')'                                      // CFA
1776                { $$ = DeclarationNode::newForall( $3 ); }
1777        ;
1778
1779declaration_qualifier_list:
1780        storage_class_list
1781        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1782                { $$ = $1->addQualifiers( $2 ); }
1783        | declaration_qualifier_list type_qualifier_list storage_class_list
1784                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1785        ;
1786
1787storage_class_list:
1788                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1789                // only one of each is specified, except for inline, which can appear with the others.
1790                //
1791                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1792                // specifiers in a declaration.
1793        storage_class
1794        | storage_class_list storage_class
1795                { $$ = $1->addQualifiers( $2 ); }
1796        ;
1797
1798storage_class:
1799        EXTERN
1800                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1801        | STATIC
1802                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1803        | AUTO
1804                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1805        | REGISTER
1806                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1807        | THREADLOCAL                                                                           // C11
1808                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1809                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1810        | INLINE                                                                                        // C99
1811                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1812        | FORTRAN                                                                                       // C99
1813                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1814        | NORETURN                                                                                      // C11
1815                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1816        ;
1817
1818basic_type_name:
1819        VOID
1820                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1821        | BOOL                                                                                          // C99
1822                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1823        | CHAR
1824                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1825        | INT
1826                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1827        | INT128
1828                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1829        | UINT128
1830                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1831        | FLOAT
1832                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1833        | DOUBLE
1834                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1835        | uuFLOAT80
1836                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1837        | uuFLOAT128
1838                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1839        | uFLOAT16
1840                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1841        | uFLOAT32
1842                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1843        | uFLOAT32X
1844                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1845        | uFLOAT64
1846                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1847        | uFLOAT64X
1848                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1849        | uFLOAT128
1850                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1851        | COMPLEX                                                                                       // C99
1852                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1853        | IMAGINARY                                                                                     // C99
1854                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1855        | SIGNED
1856                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1857        | UNSIGNED
1858                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1859        | SHORT
1860                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1861        | LONG
1862                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1863        | VALIST                                                                                        // GCC, __builtin_va_list
1864                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1865        | AUTO_TYPE
1866                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1867        ;
1868
1869basic_declaration_specifier:
1870                // A semantic check is necessary for conflicting storage classes.
1871        basic_type_specifier
1872        | declaration_qualifier_list basic_type_specifier
1873                { $$ = $2->addQualifiers( $1 ); }
1874        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1875                { $$ = $1->addQualifiers( $2 ); }
1876        | basic_declaration_specifier storage_class type_qualifier_list
1877                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1878        | basic_declaration_specifier storage_class basic_type_specifier
1879                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1880        ;
1881
1882basic_type_specifier:
1883        direct_type
1884                // Cannot have type modifiers, e.g., short, long, etc.
1885        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1886                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1887        ;
1888
1889direct_type:
1890        basic_type_name
1891        | type_qualifier_list basic_type_name
1892                { $$ = $2->addQualifiers( $1 ); }
1893        | direct_type type_qualifier
1894                { $$ = $1->addQualifiers( $2 ); }
1895        | direct_type basic_type_name
1896                { $$ = $1->addType( $2 ); }
1897        ;
1898
1899indirect_type:
1900        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1901                { $$ = $3; }
1902        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1903                { $$ = DeclarationNode::newTypeof( $3 ); }
1904        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1905                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1906        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1907                { $$ = DeclarationNode::newTypeof( $3, true ); }
1908        | ZERO_T                                                                                        // CFA
1909                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1910        | ONE_T                                                                                         // CFA
1911                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1912        ;
1913
1914sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1915        sue_type_specifier
1916        | declaration_qualifier_list sue_type_specifier
1917                { $$ = $2->addQualifiers( $1 ); }
1918        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1919                { $$ = $1->addQualifiers( $2 ); }
1920        | sue_declaration_specifier storage_class type_qualifier_list
1921                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1922        ;
1923
1924sue_type_specifier:                                                                             // struct, union, enum + type specifier
1925        elaborated_type
1926        | type_qualifier_list
1927                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1928          elaborated_type
1929                { $$ = $3->addQualifiers( $1 ); }
1930        | sue_type_specifier type_qualifier
1931                {
1932                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1933                        $$ = $1->addQualifiers( $2 );
1934                }
1935        ;
1936
1937sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1938        sue_type_specifier_nobody
1939        | declaration_qualifier_list sue_type_specifier_nobody
1940                { $$ = $2->addQualifiers( $1 ); }
1941        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1942                { $$ = $1->addQualifiers( $2 ); }
1943        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1944                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1945        ;
1946
1947sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1948        elaborated_type_nobody
1949        | type_qualifier_list elaborated_type_nobody
1950                { $$ = $2->addQualifiers( $1 ); }
1951        | sue_type_specifier_nobody type_qualifier
1952                { $$ = $1->addQualifiers( $2 ); }
1953        ;
1954
1955type_declaration_specifier:
1956        type_type_specifier
1957        | declaration_qualifier_list type_type_specifier
1958                { $$ = $2->addQualifiers( $1 ); }
1959        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1960                { $$ = $1->addQualifiers( $2 ); }
1961        | type_declaration_specifier storage_class type_qualifier_list
1962                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1963        ;
1964
1965type_type_specifier:                                                                    // typedef types
1966        type_name
1967        | type_qualifier_list type_name
1968                { $$ = $2->addQualifiers( $1 ); }
1969        | type_type_specifier type_qualifier
1970                { $$ = $1->addQualifiers( $2 ); }
1971        ;
1972
1973type_name:
1974        TYPEDEFname
1975                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1976        | '.' TYPEDEFname
1977                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1978        | type_name '.' TYPEDEFname
1979                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1980        | typegen_name
1981        | '.' typegen_name
1982                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1983        | type_name '.' typegen_name
1984                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1985        ;
1986
1987typegen_name:                                                                                   // CFA
1988        TYPEGENname
1989                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1990        | TYPEGENname '(' ')'
1991                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1992        | TYPEGENname '(' type_list ')'
1993                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1994        ;
1995
1996elaborated_type:                                                                                // struct, union, enum
1997        aggregate_type
1998        | enum_type
1999        ;
2000
2001elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2002        aggregate_type_nobody
2003        | enum_type_nobody
2004        ;
2005
2006fred:
2007        // empty
2008                { yyy = false; }
2009        ;
2010
2011aggregate_type:                                                                                 // struct, union
2012        aggregate_key attribute_list_opt
2013                { forall = false; }                                                             // reset
2014          '{' field_declaration_list_opt '}' type_parameters_opt
2015                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2016        | aggregate_key attribute_list_opt identifier fred
2017                {
2018                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2019                        forall = false;                                                         // reset
2020                }
2021          '{' field_declaration_list_opt '}' type_parameters_opt
2022                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2023        | aggregate_key attribute_list_opt type_name fred
2024                {
2025                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2026                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2027                        forall = false;                                                         // reset
2028                }
2029          '{' field_declaration_list_opt '}' type_parameters_opt
2030                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2031        | aggregate_type_nobody
2032        ;
2033
2034type_parameters_opt:
2035        // empty
2036                { $$ = nullptr; }                                                               %prec '}'
2037        | '(' type_list ')'
2038                { $$ = $2; }
2039        ;
2040
2041aggregate_type_nobody:                                                                  // struct, union - {...}
2042        aggregate_key attribute_list_opt identifier fred
2043                {
2044                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2045                        forall = false;                                                         // reset
2046                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2047                }
2048        | aggregate_key attribute_list_opt type_name fred
2049                {
2050                        forall = false;                                                         // reset
2051                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2052                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2053                        // delete newFromTypeGen.
2054                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2055                        $3->type->symbolic.name = nullptr;
2056                        $3->type->symbolic.actuals = nullptr;
2057                        delete $3;
2058                }
2059        ;
2060
2061aggregate_key:
2062        aggregate_data
2063        | aggregate_control
2064        ;
2065
2066aggregate_data:
2067        STRUCT
2068                { yyy = true; $$ = AggregateDecl::Struct; }
2069        | UNION
2070                { yyy = true; $$ = AggregateDecl::Union; }
2071        | EXCEPTION                                                                                     // CFA
2072                // { yyy = true; $$ = AggregateDecl::Exception; }
2073                { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2074        ;
2075
2076aggregate_control:                                                                              // CFA
2077        MONITOR
2078                { yyy = true; $$ = AggregateDecl::Monitor; }
2079        | MUTEX STRUCT
2080                { yyy = true; $$ = AggregateDecl::Monitor; }
2081        | GENERATOR
2082                { yyy = true; $$ = AggregateDecl::Generator; }
2083        | MUTEX GENERATOR
2084                { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2085        | COROUTINE
2086                { yyy = true; $$ = AggregateDecl::Coroutine; }
2087        | MUTEX COROUTINE
2088                { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2089        | THREAD
2090                { yyy = true; $$ = AggregateDecl::Thread; }
2091        | MUTEX THREAD
2092                { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2093        ;
2094
2095field_declaration_list_opt:
2096        // empty
2097                { $$ = nullptr; }
2098        | field_declaration_list_opt field_declaration
2099                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2100        ;
2101
2102field_declaration:
2103        type_specifier field_declaring_list_opt ';'
2104                { $$ = fieldDecl( $1, $2 ); }
2105        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2106                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2107        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2108                {
2109                        if ( ! $3 ) {                                                           // field declarator ?
2110                                $3 = DeclarationNode::newName( nullptr );
2111                        } // if
2112                        $3->inLine = true;
2113                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2114                        distInl( $3 );
2115                }
2116        | INLINE aggregate_control ';'                                          // CFA
2117                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2118        | typedef_declaration ';'                                                       // CFA
2119        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2120        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2121                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2122        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2123                { $$ = $2; }                                                                    // mark all fields in list
2124        | cfa_typedef_declaration ';'                                           // CFA
2125        | static_assert                                                                         // C11
2126        ;
2127
2128field_declaring_list_opt:
2129        // empty
2130                { $$ = nullptr; }
2131        | field_declarator
2132        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2133                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2134        ;
2135
2136field_declarator:
2137        bit_subrange_size                                                                       // C special case, no field name
2138                { $$ = DeclarationNode::newBitfield( $1 ); }
2139        | variable_declarator bit_subrange_size_opt
2140                // A semantic check is required to ensure bit_subrange only appears on integral types.
2141                { $$ = $1->addBitfield( $2 ); }
2142        | variable_type_redeclarator bit_subrange_size_opt
2143                // A semantic check is required to ensure bit_subrange only appears on integral types.
2144                { $$ = $1->addBitfield( $2 ); }
2145        ;
2146
2147field_abstract_list_opt:
2148        // empty
2149                { $$ = nullptr; }
2150        | field_abstract
2151        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2152                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2153        ;
2154
2155field_abstract:
2156                //      no bit fields
2157        variable_abstract_declarator
2158        ;
2159
2160cfa_field_declaring_list:                                                               // CFA, new style field declaration
2161        // bit-fields are handled by C declarations
2162        cfa_abstract_declarator_tuple identifier_or_type_name
2163                { $$ = $1->addName( $2 ); }
2164        | cfa_field_declaring_list ',' identifier_or_type_name
2165                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2166        ;
2167
2168cfa_field_abstract_list:                                                                // CFA, new style field declaration
2169        // bit-fields are handled by C declarations
2170        cfa_abstract_declarator_tuple
2171        | cfa_field_abstract_list ','
2172                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2173        ;
2174
2175bit_subrange_size_opt:
2176        // empty
2177                { $$ = nullptr; }
2178        | bit_subrange_size
2179        ;
2180
2181bit_subrange_size:
2182        ':' assignment_expression
2183                { $$ = $2; }
2184        ;
2185
2186enum_type:                                                                                              // enum
2187        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2188                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2189        | ENUM attribute_list_opt identifier
2190                { typedefTable.makeTypedef( *$3 ); }
2191          '{' enumerator_list comma_opt '}'
2192                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2193        | ENUM attribute_list_opt type_name
2194          '{' enumerator_list comma_opt '}'
2195                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2196        | enum_type_nobody
2197        ;
2198
2199enum_type_nobody:                                                                               // enum - {...}
2200        ENUM attribute_list_opt identifier
2201                {
2202                        typedefTable.makeTypedef( *$3 );
2203                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2204                }
2205        | ENUM attribute_list_opt type_name
2206                {
2207                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2208                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2209                }
2210        ;
2211
2212enumerator_list:
2213        identifier_or_type_name enumerator_value_opt
2214                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2215        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2216                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2217        ;
2218
2219enumerator_value_opt:
2220        // empty
2221                { $$ = nullptr; }
2222        | '=' constant_expression
2223                { $$ = $2; }
2224        ;
2225
2226cfa_parameter_ellipsis_list_opt:                                                // CFA, abstract + real
2227        // empty
2228                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2229        | ELLIPSIS
2230                { $$ = nullptr; }
2231        | cfa_abstract_parameter_list
2232        | cfa_parameter_list
2233        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2234                { $$ = $1->appendList( $5 ); }
2235        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2236                { $$ = $1->addVarArgs(); }
2237        | cfa_parameter_list pop ',' push ELLIPSIS
2238                { $$ = $1->addVarArgs(); }
2239        ;
2240
2241cfa_parameter_list:                                                                             // CFA
2242                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2243                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2244        cfa_parameter_declaration
2245        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2246                { $$ = $1->appendList( $5 ); }
2247        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2248                { $$ = $1->appendList( $5 ); }
2249        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2250                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2251        ;
2252
2253cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2254        cfa_abstract_parameter_declaration
2255        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2256                { $$ = $1->appendList( $5 ); }
2257        ;
2258
2259parameter_type_list_opt:
2260        // empty
2261                { $$ = nullptr; }
2262        | ELLIPSIS
2263                { $$ = nullptr; }
2264        | parameter_list
2265        | parameter_list pop ',' push ELLIPSIS
2266                { $$ = $1->addVarArgs(); }
2267        ;
2268
2269parameter_list:                                                                                 // abstract + real
2270        abstract_parameter_declaration
2271        | parameter_declaration
2272        | parameter_list pop ',' push abstract_parameter_declaration
2273                { $$ = $1->appendList( $5 ); }
2274        | parameter_list pop ',' push parameter_declaration
2275                { $$ = $1->appendList( $5 ); }
2276        ;
2277
2278// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2279// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2280
2281cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2282        parameter_declaration
2283        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2284                { $$ = $1->addName( $2 ); }
2285        | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2286                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2287                { $$ = $1->addName( $2 ); }
2288        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2289                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2290        | cfa_function_specifier
2291        ;
2292
2293cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2294        abstract_parameter_declaration
2295        | cfa_identifier_parameter_declarator_no_tuple
2296        | cfa_abstract_tuple
2297                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2298        | type_qualifier_list cfa_abstract_tuple
2299                { $$ = $2->addQualifiers( $1 ); }
2300        | cfa_abstract_function
2301        ;
2302
2303parameter_declaration:
2304                // No SUE declaration in parameter list.
2305        declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2306                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2307        | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2308                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2309        ;
2310
2311abstract_parameter_declaration:
2312        declaration_specifier_nobody default_initializer_opt
2313                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2314        | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2315                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2316        ;
2317
2318// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2319// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2320// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2321
2322identifier_list:                                                                                // K&R-style parameter list => no types
2323        identifier
2324                { $$ = DeclarationNode::newName( $1 ); }
2325        | identifier_list ',' identifier
2326                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2327        ;
2328
2329identifier_or_type_name:
2330        identifier
2331        | TYPEDEFname
2332        | TYPEGENname
2333        ;
2334
2335type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2336        cfa_abstract_declarator_tuple                                           // CFA
2337        | type_specifier
2338        | type_specifier abstract_declarator
2339                { $$ = $2->addType( $1 ); }
2340        ;
2341
2342type:                                                                                                   // typeof, assertion
2343        type_no_function
2344        | cfa_abstract_function                                                         // CFA
2345        ;
2346
2347initializer_opt:
2348        // empty
2349                { $$ = nullptr; }
2350        | '=' initializer
2351                { $$ = $2; }
2352        | '=' VOID
2353                { $$ = new InitializerNode( true ); }
2354        | ATassign initializer
2355                { $$ = $2->set_maybeConstructed( false ); }
2356        ;
2357
2358initializer:
2359        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2360        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2361        ;
2362
2363initializer_list_opt:
2364        // empty
2365                { $$ = nullptr; }
2366        | initializer
2367        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2368        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2369        | initializer_list_opt ',' designation initializer
2370                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2371        ;
2372
2373// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2374// '=' to separator the designator from the initializer value, as in:
2375//
2376//              int x[10] = { [1] = 3 };
2377//
2378// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2379// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2380// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2381// shift/reduce conflicts
2382
2383designation:
2384        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2385        | identifier ':'                                                                        // GCC, field name
2386                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2387        ;
2388
2389designator_list:                                                                                // C99
2390        designator
2391        | designator_list designator
2392                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2393        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2394        ;
2395
2396designator:
2397        '.' identifier                                                                          // C99, field name
2398                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2399        | '[' push assignment_expression pop ']'                        // C99, single array element
2400                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2401                { $$ = $3; }
2402        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2403                { $$ = $3; }
2404        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2405                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2406        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2407                { $$ = $4; }
2408        ;
2409
2410// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2411// rather than an object-oriented type system. This required four groups of extensions:
2412//
2413// Overloading: function, data, and operator identifiers may be overloaded.
2414//
2415// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2416//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2417//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2418//
2419// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2420//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2421//
2422// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2423//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2424//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2425//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2426//     on type arguments of polymorphic functions.
2427
2428type_parameter_list:                                                                    // CFA
2429        type_parameter
2430        | type_parameter_list ',' type_parameter
2431                { $$ = $1->appendList( $3 ); }
2432        ;
2433
2434type_initializer_opt:                                                                   // CFA
2435        // empty
2436                { $$ = nullptr; }
2437        | '=' type
2438                { $$ = $2; }
2439        ;
2440
2441type_parameter:                                                                                 // CFA
2442        type_class identifier_or_type_name
2443                {   typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2444                        if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated" ); }
2445                        if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated" ); }
2446                        if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated" ); }
2447                }
2448          type_initializer_opt assertion_list_opt
2449                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2450        | identifier_or_type_name new_type_class
2451                { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2452          type_initializer_opt assertion_list_opt
2453                { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2454        | '[' identifier_or_type_name ']'
2455                {
2456                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2457                        $$ = DeclarationNode::newTypeParam( TypeDecl::ALtype, $2 );
2458                }
2459        // | type_specifier identifier_parameter_declarator
2460        | assertion_list
2461                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2462        ;
2463
2464new_type_class:                                                                                 // CFA
2465        // empty
2466                { $$ = TypeDecl::Otype; }
2467        | '&'
2468                { $$ = TypeDecl::Dtype; }
2469        | '*'
2470                { $$ = TypeDecl::DStype; }                                              // dtype + sized
2471        | ELLIPSIS
2472                { $$ = TypeDecl::Ttype; }
2473        ;
2474
2475type_class:                                                                                             // CFA
2476        OTYPE
2477                { $$ = TypeDecl::Otype; }
2478        | DTYPE
2479                { $$ = TypeDecl::Dtype; }
2480        | FTYPE
2481                { $$ = TypeDecl::Ftype; }
2482        | TTYPE
2483                { $$ = TypeDecl::Ttype; }
2484        ;
2485
2486assertion_list_opt:                                                                             // CFA
2487        // empty
2488                { $$ = nullptr; }
2489        | assertion_list
2490        ;
2491
2492assertion_list:                                                                                 // CFA
2493        assertion
2494        | assertion_list assertion
2495                { $$ = $1->appendList( $2 ); }
2496        ;
2497
2498assertion:                                                                                              // CFA
2499        '|' identifier_or_type_name '(' type_list ')'
2500                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2501        | '|' '{' push trait_declaration_list pop '}'
2502                { $$ = $4; }
2503        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2504        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2505        ;
2506
2507type_list:                                                                                              // CFA
2508        type
2509                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2510        | assignment_expression
2511                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2512        | type_list ',' type
2513                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2514        | type_list ',' assignment_expression
2515                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2516                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2517        ;
2518
2519type_declaring_list:                                                                    // CFA
2520        OTYPE type_declarator
2521                { $$ = $2; }
2522        | storage_class_list OTYPE type_declarator
2523                { $$ = $3->addQualifiers( $1 ); }
2524        | type_declaring_list ',' type_declarator
2525                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2526        ;
2527
2528type_declarator:                                                                                // CFA
2529        type_declarator_name assertion_list_opt
2530                { $$ = $1->addAssertions( $2 ); }
2531        | type_declarator_name assertion_list_opt '=' type
2532                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2533        ;
2534
2535type_declarator_name:                                                                   // CFA
2536        identifier_or_type_name
2537                {
2538                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2539                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2540                }
2541        | identifier_or_type_name '(' type_parameter_list ')'
2542                {
2543                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2544                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2545                }
2546        ;
2547
2548trait_specifier:                                                                                // CFA
2549        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2550                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2551        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2552                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2553        ;
2554
2555trait_declaration_list:                                                                 // CFA
2556        trait_declaration
2557        | trait_declaration_list pop push trait_declaration
2558                { $$ = $1->appendList( $4 ); }
2559        ;
2560
2561trait_declaration:                                                                              // CFA
2562        cfa_trait_declaring_list ';'
2563        | trait_declaring_list ';'
2564        ;
2565
2566cfa_trait_declaring_list:                                                               // CFA
2567        cfa_variable_specifier
2568        | cfa_function_specifier
2569        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2570                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2571        ;
2572
2573trait_declaring_list:                                                                   // CFA
2574        type_specifier declarator
2575                { $$ = $2->addType( $1 ); }
2576        | trait_declaring_list pop ',' push declarator
2577                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2578        ;
2579
2580//***************************** EXTERNAL DEFINITIONS *****************************
2581
2582translation_unit:
2583        // empty, input file
2584        | external_definition_list
2585                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2586        ;
2587
2588external_definition_list:
2589        push external_definition pop
2590                { $$ = $2; }
2591        | external_definition_list push external_definition pop
2592                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2593        ;
2594
2595external_definition_list_opt:
2596        // empty
2597                { $$ = nullptr; }
2598        | external_definition_list
2599        ;
2600
2601up:
2602                { typedefTable.up( forall ); forall = false; }
2603        ;
2604
2605down:
2606                { typedefTable.down(); }
2607        ;
2608
2609external_definition:
2610        declaration
2611        | external_function_definition
2612        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2613                {
2614                        distExt( $2 );                                                          // mark all fields in list
2615                        $$ = $2;
2616                }
2617        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2618                {
2619                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2620                }
2621        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2622                {
2623                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2624                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2625                }
2626          '{' up external_definition_list_opt down '}'
2627                {
2628                        linkage = linkageStack.top();
2629                        linkageStack.pop();
2630                        $$ = $6;
2631                }
2632        | type_qualifier_list
2633                {
2634                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2635                        if ( $1->type->forall ) forall = true;          // remember generic type
2636                }
2637          '{' up external_definition_list_opt down '}'          // CFA, namespace
2638                {
2639                        distQual( $5, $1 );
2640                        forall = false;
2641                        $$ = $5;
2642                }
2643        | declaration_qualifier_list
2644                {
2645                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2646                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2647                }
2648          '{' up external_definition_list_opt down '}'          // CFA, namespace
2649                {
2650                        distQual( $5, $1 );
2651                        forall = false;
2652                        $$ = $5;
2653                }
2654        | declaration_qualifier_list type_qualifier_list
2655                {
2656                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2657                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2658                }
2659          '{' up external_definition_list_opt down '}'          // CFA, namespace
2660                {
2661                        distQual( $6, $1->addQualifiers( $2 ) );
2662                        forall = false;
2663                        $$ = $6;
2664                }
2665        ;
2666
2667external_function_definition:
2668        function_definition
2669                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2670                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2671                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2672                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2673                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2674        | function_declarator compound_statement
2675                { $$ = $1->addFunctionBody( $2 ); }
2676        | KR_function_declarator KR_parameter_list_opt compound_statement
2677                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2678        ;
2679
2680with_clause_opt:
2681        // empty
2682                { $$ = nullptr; forall = false; }
2683        | WITH '(' tuple_expression_list ')'
2684                { $$ = $3; forall = false; }
2685        ;
2686
2687function_definition:
2688        cfa_function_declaration with_clause_opt compound_statement     // CFA
2689                {
2690                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2691                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2692                        $1->get_last()->addFunctionBody( $3, $2 );
2693                        $$ = $1;
2694                }
2695        | declaration_specifier function_declarator with_clause_opt compound_statement
2696                {
2697                        rebindForall( $1, $2 );
2698                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2699                }
2700        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2701                {
2702                        rebindForall( $1, $2 );
2703                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2704                }
2705                // handles default int return type, OBSOLESCENT (see 1)
2706        | type_qualifier_list function_declarator with_clause_opt compound_statement
2707                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2708                // handles default int return type, OBSOLESCENT (see 1)
2709        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2710                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2711                // handles default int return type, OBSOLESCENT (see 1)
2712        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2713                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2714
2715                // Old-style K&R function definition, OBSOLESCENT (see 4)
2716        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2717                {
2718                        rebindForall( $1, $2 );
2719                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2720                }
2721                // handles default int return type, OBSOLESCENT (see 1)
2722        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2723                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2724                // handles default int return type, OBSOLESCENT (see 1)
2725        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2726                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2727                // handles default int return type, OBSOLESCENT (see 1)
2728        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2729                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2730        ;
2731
2732declarator:
2733        variable_declarator
2734        | variable_type_redeclarator
2735        | function_declarator
2736        ;
2737
2738subrange:
2739        constant_expression '~' constant_expression                     // CFA, integer subrange
2740                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2741        ;
2742
2743asm_name_opt:                                                                                   // GCC
2744        // empty
2745                { $$ = nullptr; }
2746        | ASM '(' string_literal ')' attribute_list_opt
2747                {
2748                        DeclarationNode * name = new DeclarationNode();
2749                        name->asmName = $3;
2750                        $$ = name->addQualifiers( $5 );
2751                }
2752        ;
2753
2754attribute_list_opt:                                                                             // GCC
2755        // empty
2756                { $$ = nullptr; }
2757        | attribute_list
2758        ;
2759
2760attribute_list:                                                                                 // GCC
2761        attribute
2762        | attribute_list attribute
2763                { $$ = $2->addQualifiers( $1 ); }
2764        ;
2765
2766attribute:                                                                                              // GCC
2767        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2768                { $$ = $4; }
2769        ;
2770
2771attribute_name_list:                                                                    // GCC
2772        attribute_name
2773        | attribute_name_list ',' attribute_name
2774                { $$ = $3->addQualifiers( $1 ); }
2775        ;
2776
2777attribute_name:                                                                                 // GCC
2778        // empty
2779                { $$ = nullptr; }
2780        | attr_name
2781                { $$ = DeclarationNode::newAttribute( $1 ); }
2782        | attr_name '(' argument_expression_list_opt ')'
2783                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2784        ;
2785
2786attr_name:                                                                                              // GCC
2787        IDENTIFIER
2788        | quasi_keyword
2789        | TYPEDEFname
2790        | TYPEGENname
2791        | FALLTHROUGH
2792                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2793        | CONST
2794                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2795        ;
2796
2797// ============================================================================
2798// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2799// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2800// in:
2801//
2802//              int (*f())[10] { ... };
2803//              ... (*f())[3] += 1;             // definition mimics usage
2804//
2805// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2806// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2807// ============================================================================
2808
2809// ----------------------------------------------------------------------------
2810// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2811// to define a variable or function prototype, e.g.:
2812//
2813//              valid declaration               invalid definition
2814//              -----------------               ------------------
2815//              int f;                                  int f {}
2816//              int *f;                                 int *f {}
2817//              int f[10];                              int f[10] {}
2818//              int (*f)(int);                  int (*f)(int) {}
2819//
2820// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2821// variable_declarator and function_declarator.
2822// ----------------------------------------------------------------------------
2823
2824// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2825// declaring an array of functions versus a pointer to an array of functions.
2826
2827variable_declarator:
2828        paren_identifier attribute_list_opt
2829                { $$ = $1->addQualifiers( $2 ); }
2830        | variable_ptr
2831        | variable_array attribute_list_opt
2832                { $$ = $1->addQualifiers( $2 ); }
2833        | variable_function attribute_list_opt
2834                { $$ = $1->addQualifiers( $2 ); }
2835        ;
2836
2837paren_identifier:
2838        identifier
2839                { $$ = DeclarationNode::newName( $1 ); }
2840        | '(' paren_identifier ')'                                                      // redundant parenthesis
2841                { $$ = $2; }
2842        ;
2843
2844variable_ptr:
2845        ptrref_operator variable_declarator
2846                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2847        | ptrref_operator type_qualifier_list variable_declarator
2848                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2849        | '(' variable_ptr ')' attribute_list_opt
2850                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2851        ;
2852
2853variable_array:
2854        paren_identifier array_dimension
2855                { $$ = $1->addArray( $2 ); }
2856        | '(' variable_ptr ')' array_dimension
2857                { $$ = $2->addArray( $4 ); }
2858        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2859                { $$ = $2->addArray( $4 ); }
2860        | '(' variable_array ')'                                                        // redundant parenthesis
2861                { $$ = $2; }
2862        ;
2863
2864variable_function:
2865        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2866                { $$ = $2->addParamList( $6 ); }
2867        | '(' variable_function ')'                                                     // redundant parenthesis
2868                { $$ = $2; }
2869        ;
2870
2871// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2872// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2873// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2874
2875function_declarator:
2876        function_no_ptr attribute_list_opt
2877                { $$ = $1->addQualifiers( $2 ); }
2878        | function_ptr
2879        | function_array attribute_list_opt
2880                { $$ = $1->addQualifiers( $2 ); }
2881        ;
2882
2883function_no_ptr:
2884        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2885                { $$ = $1->addParamList( $4 ); }
2886        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2887                { $$ = $2->addParamList( $6 ); }
2888        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2889                { $$ = $2; }
2890        ;
2891
2892function_ptr:
2893        ptrref_operator function_declarator
2894                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2895        | ptrref_operator type_qualifier_list function_declarator
2896                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2897        | '(' function_ptr ')'
2898                { $$ = $2; }
2899        ;
2900
2901function_array:
2902        '(' function_ptr ')' array_dimension
2903                { $$ = $2->addArray( $4 ); }
2904        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2905                { $$ = $2->addArray( $4 ); }
2906        | '(' function_array ')'                                                        // redundant parenthesis
2907                { $$ = $2; }
2908        ;
2909
2910// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2911//
2912//   f( a, b, c ) int a, *b, c[]; {}
2913//
2914// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2915// returning arrays and functions versus pointers to arrays and functions.
2916
2917KR_function_declarator:
2918        KR_function_no_ptr
2919        | KR_function_ptr
2920        | KR_function_array
2921        ;
2922
2923KR_function_no_ptr:
2924        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2925                { $$ = $1->addIdList( $3 ); }
2926        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2927                { $$ = $2->addParamList( $6 ); }
2928        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2929                { $$ = $2; }
2930        ;
2931
2932KR_function_ptr:
2933        ptrref_operator KR_function_declarator
2934                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2935        | ptrref_operator type_qualifier_list KR_function_declarator
2936                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2937        | '(' KR_function_ptr ')'
2938                { $$ = $2; }
2939        ;
2940
2941KR_function_array:
2942        '(' KR_function_ptr ')' array_dimension
2943                { $$ = $2->addArray( $4 ); }
2944        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2945                { $$ = $2->addArray( $4 ); }
2946        | '(' KR_function_array ')'                                                     // redundant parenthesis
2947                { $$ = $2; }
2948        ;
2949
2950// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2951//
2952//              typedef int foo;
2953//              {
2954//                 int foo; // redefine typedef name in new scope
2955//              }
2956//
2957// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2958// and functions versus pointers to arrays and functions.
2959
2960variable_type_redeclarator:
2961        paren_type attribute_list_opt
2962                { $$ = $1->addQualifiers( $2 ); }
2963        | type_ptr
2964        | type_array attribute_list_opt
2965                { $$ = $1->addQualifiers( $2 ); }
2966        | type_function attribute_list_opt
2967                { $$ = $1->addQualifiers( $2 ); }
2968        ;
2969
2970paren_type:
2971        typedef
2972                // hide type name in enclosing scope by variable name
2973                {
2974                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2975                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2976                        // } else {
2977                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2978                        // } // if
2979                }
2980        | '(' paren_type ')'
2981                { $$ = $2; }
2982        ;
2983
2984type_ptr:
2985        ptrref_operator variable_type_redeclarator
2986                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2987        | ptrref_operator type_qualifier_list variable_type_redeclarator
2988                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2989        | '(' type_ptr ')' attribute_list_opt
2990                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2991        ;
2992
2993type_array:
2994        paren_type array_dimension
2995                { $$ = $1->addArray( $2 ); }
2996        | '(' type_ptr ')' array_dimension
2997                { $$ = $2->addArray( $4 ); }
2998        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2999                { $$ = $2->addArray( $4 ); }
3000        | '(' type_array ')'                                                            // redundant parenthesis
3001                { $$ = $2; }
3002        ;
3003
3004type_function:
3005        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3006                { $$ = $1->addParamList( $4 ); }
3007        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3008                { $$ = $2->addParamList( $6 ); }
3009        | '(' type_function ')'                                                         // redundant parenthesis
3010                { $$ = $2; }
3011        ;
3012
3013// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3014// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
3015// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3016// pointers to arrays and functions.
3017
3018identifier_parameter_declarator:
3019        paren_identifier attribute_list_opt
3020                { $$ = $1->addQualifiers( $2 ); }
3021        | '&' MUTEX paren_identifier attribute_list_opt
3022                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3023        | identifier_parameter_ptr
3024        | identifier_parameter_array attribute_list_opt
3025                { $$ = $1->addQualifiers( $2 ); }
3026        | identifier_parameter_function attribute_list_opt
3027                { $$ = $1->addQualifiers( $2 ); }
3028        ;
3029
3030identifier_parameter_ptr:
3031        ptrref_operator identifier_parameter_declarator
3032                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3033        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3034                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3035        | '(' identifier_parameter_ptr ')' attribute_list_opt
3036                { $$ = $2->addQualifiers( $4 ); }
3037        ;
3038
3039identifier_parameter_array:
3040        paren_identifier array_parameter_dimension
3041                { $$ = $1->addArray( $2 ); }
3042        | '(' identifier_parameter_ptr ')' array_dimension
3043                { $$ = $2->addArray( $4 ); }
3044        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3045                { $$ = $2->addArray( $4 ); }
3046        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3047                { $$ = $2; }
3048        ;
3049
3050identifier_parameter_function:
3051        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3052                { $$ = $1->addParamList( $4 ); }
3053        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3054                { $$ = $2->addParamList( $6 ); }
3055        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3056                { $$ = $2; }
3057        ;
3058
3059// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3060// e.g.:
3061//
3062//              typedef int foo;
3063//              forall( otype T ) struct foo;
3064//              int f( int foo ); // redefine typedef name in new scope
3065//
3066// and allows the C99 array options, which can only appear in a parameter list.
3067
3068type_parameter_redeclarator:
3069        typedef attribute_list_opt
3070                { $$ = $1->addQualifiers( $2 ); }
3071        | '&' MUTEX typedef attribute_list_opt
3072                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3073        | type_parameter_ptr
3074        | type_parameter_array attribute_list_opt
3075                { $$ = $1->addQualifiers( $2 ); }
3076        | type_parameter_function attribute_list_opt
3077                { $$ = $1->addQualifiers( $2 ); }
3078        ;
3079
3080typedef:
3081        TYPEDEFname
3082                { $$ = DeclarationNode::newName( $1 ); }
3083        | TYPEGENname
3084                { $$ = DeclarationNode::newName( $1 ); }
3085        ;
3086
3087type_parameter_ptr:
3088        ptrref_operator type_parameter_redeclarator
3089                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3090        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3091                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3092        | '(' type_parameter_ptr ')' attribute_list_opt
3093                { $$ = $2->addQualifiers( $4 ); }
3094        ;
3095
3096type_parameter_array:
3097        typedef array_parameter_dimension
3098                { $$ = $1->addArray( $2 ); }
3099        | '(' type_parameter_ptr ')' array_parameter_dimension
3100                { $$ = $2->addArray( $4 ); }
3101        ;
3102
3103type_parameter_function:
3104        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3105                { $$ = $1->addParamList( $4 ); }
3106        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3107                { $$ = $2->addParamList( $6 ); }
3108        ;
3109
3110// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3111// which the type applies, e.g.:
3112//
3113//              sizeof( int );
3114//              sizeof( int * );
3115//              sizeof( int [10] );
3116//              sizeof( int (*)() );
3117//              sizeof( int () );
3118//
3119// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3120// and functions versus pointers to arrays and functions.
3121
3122abstract_declarator:
3123        abstract_ptr
3124        | abstract_array attribute_list_opt
3125                { $$ = $1->addQualifiers( $2 ); }
3126        | abstract_function attribute_list_opt
3127                { $$ = $1->addQualifiers( $2 ); }
3128        ;
3129
3130abstract_ptr:
3131        ptrref_operator
3132                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3133        | ptrref_operator type_qualifier_list
3134                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3135        | ptrref_operator abstract_declarator
3136                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3137        | ptrref_operator type_qualifier_list abstract_declarator
3138                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3139        | '(' abstract_ptr ')' attribute_list_opt
3140                { $$ = $2->addQualifiers( $4 ); }
3141        ;
3142
3143abstract_array:
3144        array_dimension
3145        | '(' abstract_ptr ')' array_dimension
3146                { $$ = $2->addArray( $4 ); }
3147        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3148                { $$ = $2->addArray( $4 ); }
3149        | '(' abstract_array ')'                                                        // redundant parenthesis
3150                { $$ = $2; }
3151        ;
3152
3153abstract_function:
3154        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3155                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3156        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3157                { $$ = $2->addParamList( $6 ); }
3158        | '(' abstract_function ')'                                                     // redundant parenthesis
3159                { $$ = $2; }
3160        ;
3161
3162array_dimension:
3163                // Only the first dimension can be empty.
3164        '[' ']'
3165                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3166        | '[' ']' multi_array_dimension
3167                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3168        | multi_array_dimension
3169        ;
3170
3171multi_array_dimension:
3172        '[' push assignment_expression pop ']'
3173                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3174        | '[' push '*' pop ']'                                                          // C99
3175                { $$ = DeclarationNode::newVarArray( 0 ); }
3176        | multi_array_dimension '[' push assignment_expression pop ']'
3177                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3178        | multi_array_dimension '[' push '*' pop ']'            // C99
3179                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3180        ;
3181
3182// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3183// identifier to which the type applies, e.g.:
3184//
3185//              int f( int );                   // not handled here
3186//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3187//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3188//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3189//
3190// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3191// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3192// special meaning of parenthesis around a typedef name:
3193//
3194//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3195//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3196//              not as redundant parentheses around the identifier."
3197//
3198// For example:
3199//
3200//              typedef float T;
3201//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3202//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3203//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3204//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3205//
3206// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3207// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3208// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3209// functions.
3210
3211abstract_parameter_declarator:
3212        abstract_parameter_ptr
3213        | '&' MUTEX attribute_list_opt
3214                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3215        | abstract_parameter_array attribute_list_opt
3216                { $$ = $1->addQualifiers( $2 ); }
3217        | abstract_parameter_function attribute_list_opt
3218                { $$ = $1->addQualifiers( $2 ); }
3219        ;
3220
3221abstract_parameter_ptr:
3222        ptrref_operator
3223                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3224        | ptrref_operator type_qualifier_list
3225                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3226        | ptrref_operator abstract_parameter_declarator
3227                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3228        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3229                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3230        | '(' abstract_parameter_ptr ')' attribute_list_opt
3231                { $$ = $2->addQualifiers( $4 ); }
3232        ;
3233
3234abstract_parameter_array:
3235        array_parameter_dimension
3236        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3237                { $$ = $2->addArray( $4 ); }
3238        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3239                { $$ = $2->addArray( $4 ); }
3240        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3241                { $$ = $2; }
3242        ;
3243
3244abstract_parameter_function:
3245        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3246                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3247        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3248                { $$ = $2->addParamList( $6 ); }
3249        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3250                { $$ = $2; }
3251        ;
3252
3253array_parameter_dimension:
3254                // Only the first dimension can be empty or have qualifiers.
3255        array_parameter_1st_dimension
3256        | array_parameter_1st_dimension multi_array_dimension
3257                { $$ = $1->addArray( $2 ); }
3258        | multi_array_dimension
3259        ;
3260
3261// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3262//
3263//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3264//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3265
3266array_parameter_1st_dimension:
3267        '[' ']'
3268                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3269                // multi_array_dimension handles the '[' '*' ']' case
3270        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3271                { $$ = DeclarationNode::newVarArray( $3 ); }
3272        | '[' push type_qualifier_list pop ']'
3273                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3274                // multi_array_dimension handles the '[' assignment_expression ']' case
3275        | '[' push type_qualifier_list assignment_expression pop ']'
3276                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3277        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3278                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3279        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3280                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3281        ;
3282
3283// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3284//
3285//              struct S {
3286//          int;
3287//          int *;
3288//          int [10];
3289//          int (*)();
3290//      };
3291
3292variable_abstract_declarator:
3293        variable_abstract_ptr
3294        | variable_abstract_array attribute_list_opt
3295                { $$ = $1->addQualifiers( $2 ); }
3296        | variable_abstract_function attribute_list_opt
3297                { $$ = $1->addQualifiers( $2 ); }
3298        ;
3299
3300variable_abstract_ptr:
3301        ptrref_operator
3302                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3303        | ptrref_operator type_qualifier_list
3304                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3305        | ptrref_operator variable_abstract_declarator
3306                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3307        | ptrref_operator type_qualifier_list variable_abstract_declarator
3308                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3309        | '(' variable_abstract_ptr ')' attribute_list_opt
3310                { $$ = $2->addQualifiers( $4 ); }
3311        ;
3312
3313variable_abstract_array:
3314        array_dimension
3315        | '(' variable_abstract_ptr ')' array_dimension
3316                { $$ = $2->addArray( $4 ); }
3317        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3318                { $$ = $2->addArray( $4 ); }
3319        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3320                { $$ = $2; }
3321        ;
3322
3323variable_abstract_function:
3324        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3325                { $$ = $2->addParamList( $6 ); }
3326        | '(' variable_abstract_function ')'                            // redundant parenthesis
3327                { $$ = $2; }
3328        ;
3329
3330// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3331// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3332
3333cfa_identifier_parameter_declarator_tuple:                              // CFA
3334        cfa_identifier_parameter_declarator_no_tuple
3335        | cfa_abstract_tuple
3336        | type_qualifier_list cfa_abstract_tuple
3337                { $$ = $2->addQualifiers( $1 ); }
3338        ;
3339
3340cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3341        cfa_identifier_parameter_ptr
3342        | cfa_identifier_parameter_array
3343        ;
3344
3345cfa_identifier_parameter_ptr:                                                   // CFA
3346                // No SUE declaration in parameter list.
3347        ptrref_operator type_specifier_nobody
3348                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3349        | type_qualifier_list ptrref_operator type_specifier_nobody
3350                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3351        | ptrref_operator cfa_abstract_function
3352                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3353        | type_qualifier_list ptrref_operator cfa_abstract_function
3354                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3355        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3356                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3357        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3358                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3359        ;
3360
3361cfa_identifier_parameter_array:                                                 // CFA
3362                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3363                // shift/reduce conflict with new-style empty (void) function return type.
3364        '[' ']' type_specifier_nobody
3365                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3366        | cfa_array_parameter_1st_dimension type_specifier_nobody
3367                { $$ = $2->addNewArray( $1 ); }
3368        | '[' ']' multi_array_dimension type_specifier_nobody
3369                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3370        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3371                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3372        | multi_array_dimension type_specifier_nobody
3373                { $$ = $2->addNewArray( $1 ); }
3374
3375        | '[' ']' cfa_identifier_parameter_ptr
3376                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3377        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3378                { $$ = $2->addNewArray( $1 ); }
3379        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3380                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3381        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3382                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3383        | multi_array_dimension cfa_identifier_parameter_ptr
3384                { $$ = $2->addNewArray( $1 ); }
3385        ;
3386
3387cfa_array_parameter_1st_dimension:
3388        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3389                { $$ = DeclarationNode::newVarArray( $3 ); }
3390        | '[' push type_qualifier_list assignment_expression pop ']'
3391                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3392        | '[' push declaration_qualifier_list assignment_expression pop ']'
3393                // declaration_qualifier_list must be used because of shift/reduce conflict with
3394                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3395                // appear in this context.
3396                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3397        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3398                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3399        ;
3400
3401// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3402// identifier to which the type applies, e.g.:
3403//
3404//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3405//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3406//
3407// These rules need LR(3):
3408//
3409//              cfa_abstract_tuple identifier_or_type_name
3410//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3411//
3412// since a function return type can be syntactically identical to a tuple type:
3413//
3414//              [int, int] t;
3415//              [int, int] f( int );
3416//
3417// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3418// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3419// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3420// duplicated when appearing with cfa_function_specifier.
3421
3422cfa_abstract_declarator_tuple:                                                  // CFA
3423        cfa_abstract_tuple
3424        | type_qualifier_list cfa_abstract_tuple
3425                { $$ = $2->addQualifiers( $1 ); }
3426        | cfa_abstract_declarator_no_tuple
3427        ;
3428
3429cfa_abstract_declarator_no_tuple:                                               // CFA
3430        cfa_abstract_ptr
3431        | cfa_abstract_array
3432        ;
3433
3434cfa_abstract_ptr:                                                                               // CFA
3435        ptrref_operator type_specifier
3436                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3437        | type_qualifier_list ptrref_operator type_specifier
3438                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3439        | ptrref_operator cfa_abstract_function
3440                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3441        | type_qualifier_list ptrref_operator cfa_abstract_function
3442                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3443        | ptrref_operator cfa_abstract_declarator_tuple
3444                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3445        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3446                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3447        ;
3448
3449cfa_abstract_array:                                                                             // CFA
3450                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3451                // empty (void) function return type.
3452        '[' ']' type_specifier
3453                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3454        | '[' ']' multi_array_dimension type_specifier
3455                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3456        | multi_array_dimension type_specifier
3457                { $$ = $2->addNewArray( $1 ); }
3458        | '[' ']' cfa_abstract_ptr
3459                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3460        | '[' ']' multi_array_dimension cfa_abstract_ptr
3461                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3462        | multi_array_dimension cfa_abstract_ptr
3463                { $$ = $2->addNewArray( $1 ); }
3464        ;
3465
3466cfa_abstract_tuple:                                                                             // CFA
3467        '[' push cfa_abstract_parameter_list pop ']'
3468                { $$ = DeclarationNode::newTuple( $3 ); }
3469        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3470                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3471        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3472                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3473        ;
3474
3475cfa_abstract_function:                                                                  // CFA
3476//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3477//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3478        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3479                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3480        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3481                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3482        ;
3483
3484// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3485//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3486//
3487// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3488//    the declaration specifiers in a declaration is an obsolescent feature."
3489//
3490// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3491//    prototype-format parameter type declarators) is an obsolescent feature."
3492//
3493// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3494//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3495
3496//************************* MISCELLANEOUS ********************************
3497
3498comma_opt:                                                                                              // redundant comma
3499        // empty
3500        | ','
3501        ;
3502
3503default_initializer_opt:
3504        // empty
3505                { $$ = nullptr; }
3506        | '=' assignment_expression
3507                { $$ = $2; }
3508        ;
3509
3510%%
3511
3512// ----end of grammar----
3513
3514// Local Variables: //
3515// mode: c++ //
3516// tab-width: 4 //
3517// compile-command: "make install" //
3518// End: //
Note: See TracBrowser for help on using the repository browser.