source: src/Parser/parser.yy @ d69f4bb

aaron-thesisarm-ehcleanup-dtorsdeferred_resnjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprno_listpersistent-indexer
Last change on this file since d69f4bb was d69f4bb, checked in by Peter A. Buhr <pabuhr@…>, 3 years ago

add downto to for control

  • Property mode set to 100644
File size: 131.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Aug 29 16:44:17 2018
13// Update Count     : 4006
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        //cur->addType( specifier );
102        for ( cur = dynamic_cast< DeclarationNode * >( cur->get_next() ); cur != nullptr; cur = dynamic_cast< DeclarationNode * >( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106//      delete cl;
107        return declList;
108} // distAttr
109
110void distExt( DeclarationNode * declaration ) {
111        // distribute EXTENSION across all declarations
112        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
113                iter->set_extension( true );
114        } // for
115} // distExt
116
117void distInl( DeclarationNode * declaration ) {
118        // distribute EXTENSION across all declarations
119        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
120                iter->set_inLine( true );
121        } // for
122} // distInl
123
124void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
125        // distribute qualifiers across all non-variable declarations in a distribution statemement
126        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
127                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
128                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
129                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
130                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
131                DeclarationNode * clone = qualifiers->clone();
132                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
133                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
134                                swap( clone->type->forall, iter->type->aggregate.params );
135                                iter->addQualifiers( clone );
136                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
137                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
138                                DeclarationNode newnode;
139                                swap( newnode.type, iter->type->aggInst.aggregate );
140                                swap( clone->type->forall, newnode.type->aggregate.params );
141                                newnode.addQualifiers( clone );
142                                swap( newnode.type, iter->type->aggInst.aggregate );
143                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
144                                swap( clone->type->forall, iter->type->forall );
145                                iter->addQualifiers( clone );
146                        } // if
147                } else {                                                                                // just SC qualifiers
148                        iter->addQualifiers( clone );
149                } // if
150        } // for
151        delete qualifiers;
152} // distQual
153
154// There is an ambiguity for inline generic-routine return-types and generic routines.
155//   forall( otype T ) struct S { int i; } bar( T ) {}
156// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
157//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
158// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
159//   forall( otype T ) struct S { int T; };
160//   forall( otype W ) bar( W ) {}
161
162void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
163        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
164                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
165                declSpec->type->aggregate.params = nullptr;
166        } // if
167} // rebindForall
168
169NameExpr * build_postfix_name( const string * name ) {
170        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
171        delete name;
172        return new_name;
173} // build_postfix_name
174
175DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
176        if ( ! fieldList ) {                                                            // field declarator ?
177                if ( ! ( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) {
178                        stringstream ss;
179                        typeSpec->type->print( ss );
180                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
181                        return nullptr;
182                } // if
183                fieldList = DeclarationNode::newName( nullptr );
184        } // if
185        return distAttr( typeSpec, fieldList );                         // mark all fields in list
186} // fieldDecl
187
188ExpressionNode *forInc( const OperKinds op ) {
189        return new ExpressionNode( build_constantInteger( *new string( op == OperKinds::LThan || op == OperKinds::LEThan ? "1" : "-1" ) ) );
190} // forInc
191
192ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
193        return new ForCtrl(
194                distAttr( DeclarationNode::newTypeof( type ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
195                new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ),
196                new ExpressionNode( build_binary_val( OperKinds::PlusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) );
197} // forCtrl
198
199
200bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
201
202// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
203#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
204if ( N ) {                                                                                                                                              \
205        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
206        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
207        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
208        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
209        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
210} else {                                                                                                                                                \
211        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
212        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
213        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
214}
215%}
216
217%define parse.error verbose
218
219// Types declaration for productions
220%union
221{
222        Token tok;
223        ParseNode * pn;
224        ExpressionNode * en;
225        DeclarationNode * decl;
226        DeclarationNode::Aggregate aggKey;
227        DeclarationNode::TypeClass tclass;
228        StatementNode * sn;
229        WaitForStmt * wfs;
230        Expression * constant;
231        IfCtrl * ifctl;
232        ForCtrl * fctl;
233        enum OperKinds compop;
234        LabelNode * label;
235        InitializerNode * in;
236        OperKinds op;
237        std::string * str;
238        bool flag;
239        CatchStmt::Kind catch_kind;
240        GenericExpr * genexpr;
241}
242
243//************************* TERMINAL TOKENS ********************************
244
245// keywords
246%token TYPEDEF
247%token EXTERN STATIC AUTO REGISTER
248%token THREADLOCAL                                                                              // C11
249%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
250%token NORETURN                                                                                 // C11
251%token CONST VOLATILE
252%token RESTRICT                                                                                 // C99
253%token ATOMIC                                                                                   // C11
254%token FORALL MUTEX VIRTUAL                                                             // CFA
255%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
256%token BOOL COMPLEX IMAGINARY                                                   // C99
257%token INT128 FLOAT80 FLOAT128                                                  // GCC
258%token ZERO_T ONE_T                                                                             // CFA
259%token VALIST                                                                                   // GCC
260%token TYPEOF LABEL                                                                             // GCC
261%token ENUM STRUCT UNION
262%token EXCEPTION                                                                                // CFA
263%token COROUTINE MONITOR THREAD                                                 // CFA
264%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
265%token SIZEOF OFFSETOF
266%token ATTRIBUTE EXTENSION                                                              // GCC
267%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
268%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
269%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
270%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
271
272// names and constants: lexer differentiates between identifier and typedef names
273%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
274%token<tok> TIMEOUT                             WOR
275%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
276%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
277%token<tok> DIRECTIVE
278// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
279// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
280// converted into the tuple index (.)(1). e.g., 3.x
281%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
282
283// multi-character operators
284%token ARROW                                                                                    // ->
285%token ICR DECR                                                                                 // ++   --
286%token LS RS                                                                                    // <<   >>
287%token LE GE EQ NE                                                                              // <=   >=      ==      !=
288%token ANDAND OROR                                                                              // &&   ||
289%token ELLIPSIS                                                                                 // ...
290
291%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
292%token PLUSassign       MINUSassign                                                     // +=   -=
293%token LSassign         RSassign                                                        // <<=  >>=
294%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
295
296%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
297%token ATassign                                                                                 // @=
298
299%type<tok> identifier  no_attr_identifier
300%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
301%type<tok> quasi_keyword
302%type<constant> string_literal
303%type<str> string_literal_list
304
305// expressions
306%type<en> constant
307%type<en> tuple                                                 tuple_expression_list
308%type<op> ptrref_operator                               unary_operator                          assignment_operator
309%type<en> primary_expression                    postfix_expression                      unary_expression
310%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
311%type<en> shift_expression                              relational_expression           equality_expression
312%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
313%type<en> logical_AND_expression                logical_OR_expression
314%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
315%type<en> comma_expression                              comma_expression_opt
316%type<en> argument_expression_list              argument_expression                     default_initialize_opt
317%type<ifctl> if_control_expression
318%type<fctl> for_control_expression
319%type<compop> inclexcl
320%type<en> subrange
321%type<decl> asm_name_opt
322%type<en> asm_operands_opt asm_operands_list asm_operand
323%type<label> label_list
324%type<en> asm_clobbers_list_opt
325%type<flag> asm_volatile_opt
326%type<en> handler_predicate_opt
327%type<genexpr> generic_association generic_assoc_list
328
329// statements
330%type<sn> statement                                             labeled_statement                       compound_statement
331%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
332%type<sn> selection_statement                   if_statement
333%type<sn> switch_clause_list_opt                switch_clause_list
334%type<en> case_value
335%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
336%type<sn> iteration_statement                   jump_statement
337%type<sn> expression_statement                  asm_statement
338%type<sn> with_statement
339%type<en> with_clause_opt
340%type<sn> exception_statement                   handler_clause                          finally_clause
341%type<catch_kind> handler_key
342%type<sn> mutex_statement
343%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
344%type<sn> waitfor_statement
345%type<wfs> waitfor_clause
346
347// declarations
348%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
349%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
350%type<decl> abstract_parameter_declaration
351
352%type<aggKey> aggregate_key
353%type<decl> aggregate_type aggregate_type_nobody
354
355%type<decl> assertion assertion_list assertion_list_opt
356
357%type<en>   bit_subrange_size_opt bit_subrange_size
358
359%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
360
361%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
362
363%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
364%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
365
366%type<decl> elaborated_type elaborated_type_nobody
367
368%type<decl> enumerator_list enum_type enum_type_nobody
369%type<en> enumerator_value_opt
370
371%type<decl> external_definition external_definition_list external_definition_list_opt
372
373%type<decl> exception_declaration
374
375%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
376%type<en> field field_name_list field_name fraction_constants_opt
377
378%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
379
380%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
381%type<decl> identifier_list
382
383%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
384%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
385%type<decl> cfa_abstract_ptr cfa_abstract_tuple
386
387%type<decl> cfa_array_parameter_1st_dimension
388
389%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
390%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
391
392%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
393%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
394
395%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
396
397%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
398
399%type<decl> c_declaration static_assert
400%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
401%type<decl> KR_parameter_list KR_parameter_list_opt
402
403%type<decl> parameter_declaration parameter_list parameter_type_list_opt
404
405%type<decl> paren_identifier paren_type
406
407%type<decl> storage_class storage_class_list
408
409%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
410
411%type<tclass> type_class
412%type<decl> type_declarator type_declarator_name type_declaring_list
413
414%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
415%type<decl> typedef typedef_declaration typedef_expression
416
417%type<decl> variable_type_redeclarator type_ptr type_array type_function
418
419%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
420
421%type<decl> type type_no_function
422%type<decl> type_parameter type_parameter_list type_initializer_opt
423
424%type<en> type_parameters_opt type_list
425
426%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
427%type<decl> type_specifier type_specifier_nobody
428
429%type<decl> variable_declarator variable_ptr variable_array variable_function
430%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
431
432%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
433
434// initializers
435%type<in>  initializer initializer_list_opt initializer_opt
436
437// designators
438%type<en>  designator designator_list designation
439
440
441// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
442//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
443//   if ( C ) S1 else S2
444//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
445// Similar issues exit with the waitfor statement.
446
447// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
448// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
449%precedence THEN        // rule precedence for IF/WAITFOR statement
450%precedence WOR         // token precedence for start of WOR in WAITFOR statement
451%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
452%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
453
454// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
455//   forall( otype T ) struct Foo { T v; };
456//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
457//   Foo ( *fp )( int );
458//   `---'                                              matches start of TYPEGENname '('
459// must be:
460//   Foo( int ) ( *fp )( int );
461// The same problem occurs here:
462//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
463// must be:
464//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
465
466// Order of these lines matters (low-to-high precedence).
467%precedence TYPEGENname
468%precedence '}'
469%precedence '('
470
471%locations                                                                                              // support location tracking for error messages
472
473%start translation_unit                                                                 // parse-tree root
474
475%%
476//************************* Namespace Management ********************************
477
478// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
479// which are lexically identical.
480//
481//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
482//   foo f;           // to allow it to appear in this context
483//
484// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
485// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
486// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
487// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
488// must be distinguished by the lexical scanner.
489//
490// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
491// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
492// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
493// each context that introduces a name scope, a new level is created in the type table and that level is popped on
494// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
495// This requires distinguishing between type names that are local to the current declaration scope and those that
496// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
497//
498// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
499// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
500// around the list separator.
501//
502//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
503//      push               pop   push                   pop
504
505push:
506                { typedefTable.enterScope(); }
507        ;
508
509pop:
510                { typedefTable.leaveScope(); }
511        ;
512
513//************************* CONSTANTS ********************************
514
515constant:
516                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
517        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
518        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
519        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
520        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
521        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
522        ;
523
524quasi_keyword:                                                                                  // CFA
525        TIMEOUT
526        | WOR
527        ;
528
529no_attr_identifier:
530        IDENTIFIER
531        | quasi_keyword
532        | '@'                                                                                           // CFA
533                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
534        ;
535
536identifier:
537        no_attr_identifier
538        | ATTR_IDENTIFIER                                                                       // CFA
539        ;
540
541string_literal:
542        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
543        ;
544
545string_literal_list:                                                                    // juxtaposed strings are concatenated
546        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
547        | string_literal_list STRINGliteral
548                {
549                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
550                        delete $2;                                                                      // allocated by lexer
551                        $$ = $1;                                                                        // conversion from tok to str
552                }
553        ;
554
555//************************* EXPRESSIONS ********************************
556
557primary_expression:
558        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
559                { $$ = new ExpressionNode( build_varref( $1 ) ); }
560        | quasi_keyword
561                { $$ = new ExpressionNode( build_varref( $1 ) ); }
562        | tuple
563        | '(' comma_expression ')'
564                { $$ = $2; }
565        | '(' compound_statement ')'                                            // GCC, lambda expression
566                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
567        | constant '`' IDENTIFIER                                                       // CFA, postfix call
568                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
569        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
570                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
571        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
572                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
573        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
574                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
575        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
576                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
577        | type_name '.' no_attr_identifier                                      // CFA, nested type
578                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
579        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
580                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
581        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
582                {
583                        // add the missing control expression to the GenericExpr and return it
584                        $5->control = maybeMoveBuild<Expression>( $3 );
585                        $$ = new ExpressionNode( $5 );
586                }
587        ;
588
589generic_assoc_list:                                                                             // C11
590        generic_association
591        | generic_assoc_list ',' generic_association
592                {
593                        // steal the association node from the singleton and delete the wrapper
594                        $1->associations.splice($1->associations.end(), $3->associations);
595                        delete $3;
596                        $$ = $1;
597                }
598        ;
599
600generic_association:                                                                    // C11
601        type_no_function ':' assignment_expression
602                {
603                        // create a GenericExpr wrapper with one association pair
604                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
605                }
606        | DEFAULT ':' assignment_expression
607                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
608        ;
609
610postfix_expression:
611        primary_expression
612        | postfix_expression '[' assignment_expression ']'
613                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
614                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
615                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
616                // equivalent to the old x[i,j].
617                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
618        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
619                {
620                        Token fn;
621                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
622                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
623                }
624        | postfix_expression '(' argument_expression_list ')'
625                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
626        | postfix_expression '.' no_attr_identifier
627                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
628        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
629                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
630        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
631                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
632        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
633                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
634        | postfix_expression ARROW no_attr_identifier
635                {
636                        $$ = new ExpressionNode( build_pfieldSel( $1, *$3 == "0" || *$3 == "1" ? build_constantInteger( *$3 ) : build_varref( $3 ) ) );
637                }
638        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
639                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
640        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
641                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
642        | postfix_expression ICR
643                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
644        | postfix_expression DECR
645                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
646        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
647                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
648        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
649                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
650        | '^' primary_expression '{' argument_expression_list '}' // CFA
651                {
652                        Token fn;
653                        fn.str = new string( "^?{}" );                          // location undefined
654                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
655                }
656        ;
657
658argument_expression_list:
659        argument_expression
660        | argument_expression_list ',' argument_expression
661                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
662        ;
663
664argument_expression:
665        // empty
666                { $$ = nullptr; }
667        | '?'                                                                                           // CFA, default parameter
668                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
669                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
670        | assignment_expression
671        ;
672
673field_name_list:                                                                                // CFA, tuple field selector
674        field
675        | field_name_list ',' field                                     { $$ = (ExpressionNode *)$1->set_last( $3 ); }
676        ;
677
678field:                                                                                                  // CFA, tuple field selector
679        field_name
680        | FLOATING_DECIMALconstant field
681                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
682        | FLOATING_DECIMALconstant '[' field_name_list ']'
683                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
684        | field_name '.' field
685                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
686        | field_name '.' '[' field_name_list ']'
687                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
688        | field_name ARROW field
689                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
690        | field_name ARROW '[' field_name_list ']'
691                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
692        ;
693
694field_name:
695        INTEGERconstant fraction_constants_opt
696                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
697        | FLOATINGconstant fraction_constants_opt
698                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
699        | no_attr_identifier fraction_constants_opt
700                {
701                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
702                }
703        ;
704
705fraction_constants_opt:
706        // empty
707                { $$ = nullptr; }
708        | fraction_constants_opt FLOATING_FRACTIONconstant
709                {
710                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
711                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
712                }
713        ;
714
715unary_expression:
716        postfix_expression
717                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
718                // semantics checks, e.g., ++3, 3--, *3, &&3
719        | constant
720        | string_literal
721                { $$ = new ExpressionNode( $1 ); }
722        | EXTENSION cast_expression                                                     // GCC
723                { $$ = $2->set_extension( true ); }
724                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
725                //              { * X; }         // dereference X
726                //              { * int X; } // CFA declaration of pointer to int
727        | ptrref_operator cast_expression                                       // CFA
728                {
729                        switch ( $1 ) {
730                          case OperKinds::AddressOf:
731                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
732                                break;
733                          case OperKinds::PointTo:
734                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
735                                break;
736                          case OperKinds::And:
737                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
738                                break;
739                          default:
740                                assert( false );
741                        }
742                }
743        | unary_operator cast_expression
744                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
745        | ICR unary_expression
746                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
747        | DECR unary_expression
748                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
749        | SIZEOF unary_expression
750                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
751        | SIZEOF '(' type_no_function ')'
752                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
753        | ALIGNOF unary_expression                                                      // GCC, variable alignment
754                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
755        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
756                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
757        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
758                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
759        | ATTR_IDENTIFIER
760                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
761        | ATTR_IDENTIFIER '(' argument_expression ')'
762                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
763        | ATTR_IDENTIFIER '(' type ')'
764                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
765        ;
766
767ptrref_operator:
768        '*'                                                                                     { $$ = OperKinds::PointTo; }
769        | '&'                                                                           { $$ = OperKinds::AddressOf; }
770                // GCC, address of label must be handled by semantic check for ref,ref,label
771        | ANDAND                                                                        { $$ = OperKinds::And; }
772        ;
773
774unary_operator:
775        '+'                                                                                     { $$ = OperKinds::UnPlus; }
776        | '-'                                                                           { $$ = OperKinds::UnMinus; }
777        | '!'                                                                           { $$ = OperKinds::Neg; }
778        | '~'                                                                           { $$ = OperKinds::BitNeg; }
779        ;
780
781cast_expression:
782        unary_expression
783        | '(' type_no_function ')' cast_expression
784                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
785        | '(' COROUTINE '&' ')' cast_expression                         // CFA
786                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
787        | '(' THREAD '&' ')' cast_expression                            // CFA
788                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
789        | '(' MONITOR '&' ')' cast_expression                           // CFA
790                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
791                // VIRTUAL cannot be opt because of look ahead issues
792        | '(' VIRTUAL ')' cast_expression                                       // CFA
793                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
794        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
795                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
796//      | '(' type_no_function ')' tuple
797//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
798        ;
799
800exponential_expression:
801        cast_expression
802        | exponential_expression '\\' cast_expression
803                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
804        ;
805
806multiplicative_expression:
807        exponential_expression
808        | multiplicative_expression '*' exponential_expression
809                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
810        | multiplicative_expression '/' exponential_expression
811                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
812        | multiplicative_expression '%' exponential_expression
813                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
814        ;
815
816additive_expression:
817        multiplicative_expression
818        | additive_expression '+' multiplicative_expression
819                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
820        | additive_expression '-' multiplicative_expression
821                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
822        ;
823
824shift_expression:
825        additive_expression
826        | shift_expression LS additive_expression
827                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
828        | shift_expression RS additive_expression
829                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
830        ;
831
832relational_expression:
833        shift_expression
834        | relational_expression '<' shift_expression
835                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
836        | relational_expression '>' shift_expression
837                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
838        | relational_expression LE shift_expression
839                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
840        | relational_expression GE shift_expression
841                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
842        ;
843
844equality_expression:
845        relational_expression
846        | equality_expression EQ relational_expression
847                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
848        | equality_expression NE relational_expression
849                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
850        ;
851
852AND_expression:
853        equality_expression
854        | AND_expression '&' equality_expression
855                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
856        ;
857
858exclusive_OR_expression:
859        AND_expression
860        | exclusive_OR_expression '^' AND_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
862        ;
863
864inclusive_OR_expression:
865        exclusive_OR_expression
866        | inclusive_OR_expression '|' exclusive_OR_expression
867                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
868        ;
869
870logical_AND_expression:
871        inclusive_OR_expression
872        | logical_AND_expression ANDAND inclusive_OR_expression
873                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
874        ;
875
876logical_OR_expression:
877        logical_AND_expression
878        | logical_OR_expression OROR logical_AND_expression
879                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
880        ;
881
882conditional_expression:
883        logical_OR_expression
884        | logical_OR_expression '?' comma_expression ':' conditional_expression
885                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
886                // FIX ME: computes $1 twice
887        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
888                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
889        ;
890
891constant_expression:
892        conditional_expression
893        ;
894
895assignment_expression:
896                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
897        conditional_expression
898        | unary_expression assignment_operator assignment_expression
899                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
900        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
901                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
902        ;
903
904assignment_expression_opt:
905        // empty
906                { $$ = nullptr; }
907        | assignment_expression
908        ;
909
910assignment_operator:
911        '='                                                                                     { $$ = OperKinds::Assign; }
912        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
913        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
914        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
915        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
916        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
917        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
918        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
919        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
920        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
921        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
922        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
923        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
924        ;
925
926tuple:                                                                                                  // CFA, tuple
927                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
928                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
929//      '[' ']'
930//              { $$ = new ExpressionNode( build_tuple() ); }
931//      | '[' push assignment_expression pop ']'
932//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
933        '[' ',' tuple_expression_list ']'
934                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
935        | '[' push assignment_expression pop ',' tuple_expression_list ']'
936                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $6 ) ) ); }
937        ;
938
939tuple_expression_list:
940        assignment_expression_opt
941        | tuple_expression_list ',' assignment_expression_opt
942                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
943        ;
944
945comma_expression:
946        assignment_expression
947        | comma_expression ',' assignment_expression
948                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
949        ;
950
951comma_expression_opt:
952        // empty
953                { $$ = nullptr; }
954        | comma_expression
955        ;
956
957//*************************** STATEMENTS *******************************
958
959statement:
960        labeled_statement
961        | compound_statement
962        | expression_statement
963        | selection_statement
964        | iteration_statement
965        | jump_statement
966        | with_statement
967        | mutex_statement
968        | waitfor_statement
969        | exception_statement
970        | enable_disable_statement
971                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
972        | asm_statement
973        | DIRECTIVE
974                { $$ = new StatementNode( build_directive( $1 ) ); }
975        ;
976
977labeled_statement:
978                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
979        identifier_or_type_name ':' attribute_list_opt statement
980                {
981                        $$ = $4->add_label( $1, $3 );
982                }
983        ;
984
985compound_statement:
986        '{' '}'
987                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
988        | '{' push
989          local_label_declaration_opt                                           // GCC, local labels
990          statement_decl_list                                                           // C99, intermix declarations and statements
991          pop '}'
992                { $$ = new StatementNode( build_compound( $4 ) ); }
993        ;
994
995statement_decl_list:                                                                    // C99
996        statement_decl
997        | statement_decl_list statement_decl
998                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
999        ;
1000
1001statement_decl:
1002        declaration                                                                                     // CFA, new & old style declarations
1003                { $$ = new StatementNode( $1 ); }
1004        | EXTENSION declaration                                                         // GCC
1005                {
1006                        distExt( $2 );
1007                        $$ = new StatementNode( $2 );
1008                }
1009        | function_definition
1010                { $$ = new StatementNode( $1 ); }
1011        | EXTENSION function_definition                                         // GCC
1012                {
1013                        distExt( $2 );
1014                        $$ = new StatementNode( $2 );
1015                }
1016        | statement
1017        ;
1018
1019statement_list_nodecl:
1020        statement
1021        | statement_list_nodecl statement
1022                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
1023        ;
1024
1025expression_statement:
1026        comma_expression_opt ';'
1027                { $$ = new StatementNode( build_expr( $1 ) ); }
1028        ;
1029
1030selection_statement:
1031                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1032                        // the inherent S/R conflict with THEN/ELSE.
1033        push if_statement pop
1034                { $$ = $2; }
1035        | SWITCH '(' comma_expression ')' case_clause
1036                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1037        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1038                {
1039                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1040                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1041                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1042                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1043                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1044                        // statement.
1045                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1046                }
1047        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1048                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1049        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1050                {
1051                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1052                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1053                }
1054        ;
1055
1056if_statement:
1057        IF '(' if_control_expression ')' statement                      %prec THEN
1058                // explicitly deal with the shift/reduce conflict on if/else
1059                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1060        | IF '(' if_control_expression ')' statement ELSE statement
1061                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1062        ;
1063
1064if_control_expression:
1065        comma_expression
1066                { $$ = new IfCtrl( nullptr, $1 ); }
1067        | c_declaration                                                                         // no semi-colon
1068                { $$ = new IfCtrl( $1, nullptr ); }
1069        | cfa_declaration                                                                       // no semi-colon
1070                { $$ = new IfCtrl( $1, nullptr ); }
1071        | declaration comma_expression                                          // semi-colon separated
1072                { $$ = new IfCtrl( $1, $2 ); }
1073        ;
1074
1075// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1076// clause allows a list of values and subranges.
1077
1078case_value:                                                                                             // CFA
1079        constant_expression                                                     { $$ = $1; }
1080        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1081                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1082        | subrange                                                                                      // CFA, subrange
1083        ;
1084
1085case_value_list:                                                                                // CFA
1086        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1087                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1088        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1089        ;
1090
1091case_label:                                                                                             // CFA
1092        CASE case_value_list ':'                                        { $$ = $2; }
1093        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1094                // A semantic check is required to ensure only one default clause per switch/choose statement.
1095        ;
1096
1097//label_list_opt:
1098//      // empty
1099//      | identifier_or_type_name ':'
1100//      | label_list_opt identifier_or_type_name ':'
1101//      ;
1102
1103case_label_list:                                                                                // CFA
1104        case_label
1105        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1106        ;
1107
1108case_clause:                                                                                    // CFA
1109        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1110        ;
1111
1112switch_clause_list_opt:                                                                 // CFA
1113        // empty
1114                { $$ = nullptr; }
1115        | switch_clause_list
1116        ;
1117
1118switch_clause_list:                                                                             // CFA
1119        case_label_list statement_list_nodecl
1120                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1121        | switch_clause_list case_label_list statement_list_nodecl
1122                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1123        ;
1124
1125iteration_statement:
1126        WHILE '(' push if_control_expression ')' statement pop
1127                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1128        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1129                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1130        | DO statement WHILE '(' comma_expression ')' ';'
1131                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1132        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1133                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1134        | FOR '(' push for_control_expression ')' statement pop
1135                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1136        ;
1137
1138for_control_expression:
1139        comma_expression_opt                                                            // CFA
1140                {
1141                        if ( ! $1 ) {                                                           // => for ( ;; )
1142                                $$ = new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr );
1143                        } else {
1144                                $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1145                                                          OperKinds::LThan, $1->clone(), forInc( OperKinds::LThan ) );
1146                        } // if
1147                }
1148        | constant_expression inclexcl constant_expression      // CFA
1149                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, forInc( $2 ) ); }
1150        | constant_expression inclexcl constant_expression '~' constant_expression // CFA
1151                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1152        | comma_expression_opt ';' comma_expression                     // CFA
1153                {
1154                        if ( ! $1 ) {
1155                                SemanticError( yylloc, "Missing loop index." ); $$ = nullptr;
1156                        } else if ( ! $3 ) {
1157                                SemanticError( yylloc, "Missing loop range." ); $$ = nullptr;
1158                        } else {
1159                                if ( NameExpr *identifier = dynamic_cast<NameExpr *>($1->get_expr()) ) {
1160                                        $$ = forCtrl( $3, new string( identifier->name ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1161                                                                  OperKinds::LThan, $3->clone(), forInc( OperKinds::LThan ) );
1162                                } else {
1163                                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); $$ = nullptr;
1164                                } // if
1165                        } // if
1166                }
1167        | comma_expression_opt ';' constant_expression inclexcl constant_expression // CFA
1168                {
1169                        if ( ! $1 ) {
1170                                SemanticError( yylloc, "Missing loop index." ); $$ = nullptr;
1171                        } else {
1172                                if ( NameExpr *identifier = dynamic_cast<NameExpr *>($1->get_expr()) ) {
1173                                        $$ = forCtrl( $3, new string( identifier->name ), $3->clone(), $4, $5, forInc( $4 ) );
1174                                } else {
1175                                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); $$ = nullptr;
1176                                } // if
1177                        } // if
1178                }
1179        | comma_expression_opt ';' constant_expression inclexcl constant_expression '~' constant_expression // CFA
1180                {
1181                        if ( ! $1 ) {
1182                                SemanticError( yylloc, "Missing loop index." ); $$ = nullptr;
1183                        } else {
1184                                if ( NameExpr *identifier = dynamic_cast<NameExpr *>($1->get_expr()) ) {
1185                                        $$ = forCtrl( $3, new string( identifier->name ), $3->clone(), $4, $5, $7 );
1186                                } else {
1187                                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); $$ = nullptr;
1188                                } // if
1189                        } // if
1190                }
1191        | comma_expression_opt ';' comma_expression_opt ';' comma_expression_opt
1192                { $$ = new ForCtrl( $1, $3, $5 ); }
1193        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1194                { $$ = new ForCtrl( $1, $2, $4 ); }
1195        ;
1196
1197inclexcl:
1198        '~'
1199                { $$ = OperKinds::LThan; }
1200        | ErangeUpEq
1201                { $$ = OperKinds::LEThan; }
1202        | ErangeDown
1203                { $$ = OperKinds::GThan; }
1204        | ErangeDownEq
1205                { $$ = OperKinds::GEThan; }
1206        ;
1207
1208jump_statement:
1209        GOTO identifier_or_type_name ';'
1210                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1211        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1212                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1213                // whereas normal operator precedence yields goto (*i)+3;
1214                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1215                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1216    | fall_through_name ';'                                                             // CFA
1217                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1218    | fall_through_name identifier_or_type_name ';'             // CFA
1219                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1220        | fall_through_name DEFAULT ';'                                         // CFA
1221                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1222        | CONTINUE ';'
1223                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1224                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1225        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1226                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1227                // the target of the transfer appears only at the start of an iteration statement.
1228                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1229        | BREAK ';'
1230                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1231                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1232        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1233                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1234                // the target of the transfer appears only at the start of an iteration statement.
1235                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1236        | RETURN comma_expression_opt ';'
1237                { $$ = new StatementNode( build_return( $2 ) ); }
1238        | RETURN '{' initializer_list_opt comma_opt '}'
1239                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1240        | THROW assignment_expression_opt ';'                           // handles rethrow
1241                { $$ = new StatementNode( build_throw( $2 ) ); }
1242        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1243                { $$ = new StatementNode( build_resume( $2 ) ); }
1244        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1245                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1246        ;
1247
1248fall_through_name:                                                                              // CFA
1249        FALLTHRU
1250        | FALLTHROUGH
1251        ;
1252
1253with_statement:
1254        WITH '(' tuple_expression_list ')' statement
1255                {
1256                        $$ = new StatementNode( build_with( $3, $5 ) );
1257                }
1258        ;
1259
1260// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1261mutex_statement:
1262        MUTEX '(' argument_expression_list ')' statement
1263                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1264        ;
1265
1266when_clause:
1267        WHEN '(' comma_expression ')'                           { $$ = $3; }
1268        ;
1269
1270when_clause_opt:
1271        // empty
1272                { $$ = nullptr; }
1273        | when_clause
1274        ;
1275
1276waitfor:
1277        WAITFOR '(' cast_expression ')'
1278                { $$ = $3; }
1279        | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1280                { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1281        ;
1282
1283timeout:
1284        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1285        ;
1286
1287waitfor_clause:
1288        when_clause_opt waitfor statement                                       %prec THEN
1289                { $$ = build_waitfor( $2, $3, $1 ); }
1290        | when_clause_opt waitfor statement WOR waitfor_clause
1291                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1292        | when_clause_opt timeout statement                                     %prec THEN
1293                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1294        | when_clause_opt ELSE statement
1295                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1296                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1297        | when_clause_opt timeout statement WOR ELSE statement
1298                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1299        | when_clause_opt timeout statement WOR when_clause ELSE statement
1300                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1301        ;
1302
1303waitfor_statement:
1304        when_clause_opt waitfor statement                                       %prec THEN
1305                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1306        | when_clause_opt waitfor statement WOR waitfor_clause
1307                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1308        ;
1309
1310exception_statement:
1311        TRY compound_statement handler_clause
1312                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1313        | TRY compound_statement finally_clause
1314                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1315        | TRY compound_statement handler_clause finally_clause
1316                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1317        ;
1318
1319handler_clause:
1320        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1321                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1322        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1323                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1324        ;
1325
1326handler_predicate_opt:
1327        // empty
1328                { $$ = nullptr; }
1329        | ';' conditional_expression                            { $$ = $2; }
1330        ;
1331
1332handler_key:
1333        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1334        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1335        ;
1336
1337finally_clause:
1338        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1339        ;
1340
1341exception_declaration:
1342                // No SUE declaration in parameter list.
1343        type_specifier_nobody
1344        | type_specifier_nobody declarator
1345                { $$ = $2->addType( $1 ); }
1346        | type_specifier_nobody variable_abstract_declarator
1347                { $$ = $2->addType( $1 ); }
1348        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1349                { $$ = $1->addName( $2 ); }
1350        | cfa_abstract_declarator_tuple                                         // CFA
1351        ;
1352
1353enable_disable_statement:
1354        enable_disable_key identifier_list compound_statement
1355        ;
1356
1357enable_disable_key:
1358        ENABLE
1359        | DISABLE
1360        ;
1361
1362asm_statement:
1363        ASM asm_volatile_opt '(' string_literal ')' ';'
1364                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1365        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1366                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1367        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1368                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1369        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1370                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1371        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1372                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1373        ;
1374
1375asm_volatile_opt:                                                                               // GCC
1376        // empty
1377                { $$ = false; }
1378        | VOLATILE
1379                { $$ = true; }
1380        ;
1381
1382asm_operands_opt:                                                                               // GCC
1383        // empty
1384                { $$ = nullptr; }                                                               // use default argument
1385        | asm_operands_list
1386        ;
1387
1388asm_operands_list:                                                                              // GCC
1389        asm_operand
1390        | asm_operands_list ',' asm_operand
1391                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1392        ;
1393
1394asm_operand:                                                                                    // GCC
1395        string_literal '(' constant_expression ')'
1396                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1397        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1398                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1399        ;
1400
1401asm_clobbers_list_opt:                                                                  // GCC
1402        // empty
1403                { $$ = nullptr; }                                                               // use default argument
1404        | string_literal
1405                { $$ = new ExpressionNode( $1 ); }
1406        | asm_clobbers_list_opt ',' string_literal
1407                // set_last returns ParseNode *
1408                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1409        ;
1410
1411label_list:
1412        no_attr_identifier
1413                {
1414                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1415                        delete $1;                                                                      // allocated by lexer
1416                }
1417        | label_list ',' no_attr_identifier
1418                {
1419                        $$ = $1; $1->labels.push_back( *$3 );
1420                        delete $3;                                                                      // allocated by lexer
1421                }
1422        ;
1423
1424//******************************* DECLARATIONS *********************************
1425
1426declaration_list_opt:                                                                   // used at beginning of switch statement
1427        // empty
1428                { $$ = nullptr; }
1429        | declaration_list
1430        ;
1431
1432declaration_list:
1433        declaration
1434        | declaration_list declaration
1435                { $$ = $1->appendList( $2 ); }
1436        ;
1437
1438KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1439        // empty
1440                { $$ = nullptr; }
1441        | KR_parameter_list
1442        ;
1443
1444KR_parameter_list:
1445        push c_declaration pop ';'
1446                { $$ = $2; }
1447        | KR_parameter_list push c_declaration pop ';'
1448                { $$ = $1->appendList( $3 ); }
1449        ;
1450
1451local_label_declaration_opt:                                                    // GCC, local label
1452        // empty
1453        | local_label_declaration_list
1454        ;
1455
1456local_label_declaration_list:                                                   // GCC, local label
1457        LABEL local_label_list ';'
1458        | local_label_declaration_list LABEL local_label_list ';'
1459        ;
1460
1461local_label_list:                                                                               // GCC, local label
1462        no_attr_identifier_or_type_name
1463        | local_label_list ',' no_attr_identifier_or_type_name
1464        ;
1465
1466declaration:                                                                                    // old & new style declarations
1467        c_declaration ';'
1468        | cfa_declaration ';'                                                           // CFA
1469        | static_assert                                                                         // C11
1470        ;
1471
1472static_assert:
1473        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1474                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1475        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1476                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1477
1478// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1479// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1480// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1481// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1482// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1483// block, but cannot be mixed within a specific declaration.
1484//
1485//                      CFA                                     C
1486//              [10] int x;                     int x[10];              // array of 10 integers
1487//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1488
1489cfa_declaration:                                                                                // CFA
1490        cfa_variable_declaration
1491        | cfa_typedef_declaration
1492        | cfa_function_declaration
1493        | type_declaring_list
1494        | trait_specifier
1495        ;
1496
1497cfa_variable_declaration:                                                               // CFA
1498        cfa_variable_specifier initializer_opt
1499                { $$ = $1->addInitializer( $2 ); }
1500        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1501                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1502                // them as a type_qualifier cannot appear in that context.
1503                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1504        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1505                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1506        ;
1507
1508cfa_variable_specifier:                                                                 // CFA
1509                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1510                // storage-class
1511        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1512                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1513        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1514                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1515        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1516                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1517        ;
1518
1519cfa_function_declaration:                                                               // CFA
1520        cfa_function_specifier
1521        | type_qualifier_list cfa_function_specifier
1522                { $$ = $2->addQualifiers( $1 ); }
1523        | declaration_qualifier_list cfa_function_specifier
1524                { $$ = $2->addQualifiers( $1 ); }
1525        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1526                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1527        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1528                {
1529                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1530                        DeclarationNode * ret = new DeclarationNode;
1531                        ret->type = maybeClone( $1->type->base );
1532                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1533                }
1534        ;
1535
1536cfa_function_specifier:                                                                 // CFA
1537//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1538//              {
1539//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1540//              }
1541//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1542//              {
1543//                      typedefTable.setNextIdentifier( *$5 );
1544//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1545//              }
1546//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1547//              {
1548//                      typedefTable.setNextIdentifier( *$5 );
1549//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1550//              }
1551//      | '[' ']' typegen_name
1552                // identifier_or_type_name must be broken apart because of the sequence:
1553                //
1554                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1555                //   '[' ']' type_specifier
1556                //
1557                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1558                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1559        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1560                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1561                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1562        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1563                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1564        ;
1565
1566cfa_function_return:                                                                    // CFA
1567        '[' push cfa_parameter_list pop ']'
1568                { $$ = DeclarationNode::newTuple( $3 ); }
1569        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1570                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1571                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1572        ;
1573
1574cfa_typedef_declaration:                                                                // CFA
1575        TYPEDEF cfa_variable_specifier
1576                {
1577                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1578                        $$ = $2->addTypedef();
1579                }
1580        | TYPEDEF cfa_function_specifier
1581                {
1582                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1583                        $$ = $2->addTypedef();
1584                }
1585        | cfa_typedef_declaration pop ',' push no_attr_identifier
1586                {
1587                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1588                        $$ = $1->appendList( $1->cloneType( $5 ) );
1589                }
1590        ;
1591
1592// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1593// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1594
1595typedef_declaration:
1596        TYPEDEF type_specifier declarator
1597                {
1598                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1599                        $$ = $3->addType( $2 )->addTypedef();
1600                }
1601        | typedef_declaration pop ',' push declarator
1602                {
1603                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1604                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1605                }
1606        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1607                {
1608                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1609                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1610                }
1611        | type_specifier TYPEDEF declarator
1612                {
1613                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1614                        $$ = $3->addType( $1 )->addTypedef();
1615                }
1616        | type_specifier TYPEDEF type_qualifier_list declarator
1617                {
1618                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1619                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1620                }
1621        ;
1622
1623typedef_expression:
1624                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1625        TYPEDEF no_attr_identifier '=' assignment_expression
1626                {
1627                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1628                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1629                }
1630        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1631                {
1632                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1633                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1634                }
1635        ;
1636
1637//c_declaration:
1638//      declaring_list pop ';'
1639//      | typedef_declaration pop ';'
1640//      | typedef_expression pop ';'                                            // GCC, naming expression type
1641//      | sue_declaration_specifier pop ';'
1642//      ;
1643//
1644//declaring_list:
1645//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1646//              // storage-class
1647//       declarator asm_name_opt initializer_opt
1648//              {
1649//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1650//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1651//              }
1652//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1653//              {
1654//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1655//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1656//              }
1657//      ;
1658
1659c_declaration:
1660        declaration_specifier declaring_list
1661                { $$ = distAttr( $1, $2 ); }
1662        | typedef_declaration
1663        | typedef_expression                                                            // GCC, naming expression type
1664        | sue_declaration_specifier
1665        ;
1666
1667declaring_list:
1668                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1669                // storage-class
1670        declarator asm_name_opt initializer_opt
1671                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1672        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1673                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1674        ;
1675
1676declaration_specifier:                                                                  // type specifier + storage class
1677        basic_declaration_specifier
1678        | sue_declaration_specifier
1679        | type_declaration_specifier
1680        ;
1681
1682declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1683                // Preclude SUE declarations in restricted scopes:
1684                //
1685                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1686                //
1687                // because it is impossible to call f due to name equivalence.
1688        basic_declaration_specifier
1689        | sue_declaration_specifier_nobody
1690        | type_declaration_specifier
1691        ;
1692
1693type_specifier:                                                                                 // type specifier
1694        basic_type_specifier
1695        | sue_type_specifier
1696        | type_type_specifier
1697        ;
1698
1699type_specifier_nobody:                                                                  // type specifier - {...}
1700                // Preclude SUE declarations in restricted scopes:
1701                //
1702                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1703                //
1704                // because it is impossible to call f due to name equivalence.
1705        basic_type_specifier
1706        | sue_type_specifier_nobody
1707        | type_type_specifier
1708        ;
1709
1710type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1711        // empty
1712                { $$ = nullptr; }
1713        | type_qualifier_list
1714        ;
1715
1716type_qualifier_list:
1717                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1718                //
1719                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1720                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1721                // appeared only once.
1722        type_qualifier
1723        | type_qualifier_list type_qualifier
1724                { $$ = $1->addQualifiers( $2 ); }
1725        ;
1726
1727type_qualifier:
1728        type_qualifier_name
1729        | attribute
1730        ;
1731
1732type_qualifier_name:
1733        CONST
1734                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1735        | RESTRICT
1736                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1737        | VOLATILE
1738                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1739        | ATOMIC
1740                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1741        | forall
1742        ;
1743
1744forall:
1745        FORALL '(' type_parameter_list ')'                                      // CFA
1746                { $$ = DeclarationNode::newForall( $3 ); }
1747        ;
1748
1749declaration_qualifier_list:
1750        storage_class_list
1751        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1752                { $$ = $1->addQualifiers( $2 ); }
1753        | declaration_qualifier_list type_qualifier_list storage_class_list
1754                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1755        ;
1756
1757storage_class_list:
1758                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1759                // only one of each is specified, except for inline, which can appear with the others.
1760                //
1761                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1762                // specifiers in a declaration.
1763        storage_class
1764        | storage_class_list storage_class
1765                { $$ = $1->addQualifiers( $2 ); }
1766        ;
1767
1768storage_class:
1769        EXTERN
1770                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1771        | STATIC
1772                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1773        | AUTO
1774                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1775        | REGISTER
1776                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1777        | THREADLOCAL                                                                           // C11
1778                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1779                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1780        | INLINE                                                                                        // C99
1781                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1782        | FORTRAN                                                                                       // C99
1783                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1784        | NORETURN                                                                                      // C11
1785                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1786        ;
1787
1788basic_type_name:
1789        VOID
1790                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1791        | BOOL                                                                                          // C99
1792                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1793        | CHAR
1794                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1795        | INT
1796                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1797        | INT128
1798                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1799        | FLOAT
1800                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1801        | FLOAT80
1802                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float80 ); }
1803        | FLOAT128
1804                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float128 ); }
1805        | DOUBLE
1806                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1807        | COMPLEX                                                                                       // C99
1808                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1809        | IMAGINARY                                                                                     // C99
1810                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1811        | SIGNED
1812                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1813        | UNSIGNED
1814                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1815        | SHORT
1816                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1817        | LONG
1818                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1819        | VALIST                                                                                        // GCC, __builtin_va_list
1820                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1821        ;
1822
1823basic_declaration_specifier:
1824                // A semantic check is necessary for conflicting storage classes.
1825        basic_type_specifier
1826        | declaration_qualifier_list basic_type_specifier
1827                { $$ = $2->addQualifiers( $1 ); }
1828        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1829                { $$ = $1->addQualifiers( $2 ); }
1830        | basic_declaration_specifier storage_class type_qualifier_list
1831                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1832        | basic_declaration_specifier storage_class basic_type_specifier
1833                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1834        ;
1835
1836basic_type_specifier:
1837        direct_type
1838                // Cannot have type modifiers, e.g., short, long, etc.
1839        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1840                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1841        ;
1842
1843direct_type:
1844        basic_type_name
1845        | type_qualifier_list basic_type_name
1846                { $$ = $2->addQualifiers( $1 ); }
1847        | direct_type type_qualifier
1848                { $$ = $1->addQualifiers( $2 ); }
1849        | direct_type basic_type_name
1850                { $$ = $1->addType( $2 ); }
1851        ;
1852
1853indirect_type:
1854        TYPEOF '(' type ')'                                                                     // GCC: typeof(x) y;
1855                { $$ = $3; }
1856        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1857                { $$ = DeclarationNode::newTypeof( $3 ); }
1858        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type(x) y;
1859                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1860        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1861                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1862        | ZERO_T                                                                                        // CFA
1863                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1864        | ONE_T                                                                                         // CFA
1865                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1866        ;
1867
1868sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1869        sue_type_specifier
1870        | declaration_qualifier_list sue_type_specifier
1871                { $$ = $2->addQualifiers( $1 ); }
1872        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1873                { $$ = $1->addQualifiers( $2 ); }
1874        | sue_declaration_specifier storage_class type_qualifier_list
1875                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1876        ;
1877
1878sue_type_specifier:                                                                             // struct, union, enum + type specifier
1879        elaborated_type
1880        | type_qualifier_list
1881                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1882          elaborated_type
1883                { $$ = $3->addQualifiers( $1 ); }
1884        | sue_type_specifier type_qualifier
1885                {
1886                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1887                        $$ = $1->addQualifiers( $2 );
1888                }
1889        ;
1890
1891sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1892        sue_type_specifier_nobody
1893        | declaration_qualifier_list sue_type_specifier_nobody
1894                { $$ = $2->addQualifiers( $1 ); }
1895        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1896                { $$ = $1->addQualifiers( $2 ); }
1897        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1898                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1899        ;
1900
1901sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1902        elaborated_type_nobody
1903        | type_qualifier_list elaborated_type_nobody
1904                { $$ = $2->addQualifiers( $1 ); }
1905        | sue_type_specifier_nobody type_qualifier
1906                { $$ = $1->addQualifiers( $2 ); }
1907        ;
1908
1909type_declaration_specifier:
1910        type_type_specifier
1911        | declaration_qualifier_list type_type_specifier
1912                { $$ = $2->addQualifiers( $1 ); }
1913        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1914                { $$ = $1->addQualifiers( $2 ); }
1915        | type_declaration_specifier storage_class type_qualifier_list
1916                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1917        ;
1918
1919type_type_specifier:                                                                    // typedef types
1920        type_name
1921        | type_qualifier_list type_name
1922                { $$ = $2->addQualifiers( $1 ); }
1923        | type_type_specifier type_qualifier
1924                { $$ = $1->addQualifiers( $2 ); }
1925        ;
1926
1927type_name:
1928        TYPEDEFname
1929                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1930        | '.' TYPEDEFname
1931                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1932        | type_name '.' TYPEDEFname
1933                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1934        | typegen_name
1935        | '.' typegen_name
1936                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1937        | type_name '.' typegen_name
1938                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1939        ;
1940
1941typegen_name:                                                                                   // CFA
1942        TYPEGENname
1943                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1944        | TYPEGENname '(' ')'
1945                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1946        | TYPEGENname '(' type_list ')'
1947                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1948        ;
1949
1950elaborated_type:                                                                                // struct, union, enum
1951        aggregate_type
1952        | enum_type
1953        ;
1954
1955elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1956        aggregate_type_nobody
1957        | enum_type_nobody
1958        ;
1959
1960fred:
1961        // empty
1962                { yyy = false; }
1963        ;
1964
1965aggregate_type:                                                                                 // struct, union
1966        aggregate_key attribute_list_opt
1967                { forall = false; }                                                             // reset
1968          '{' field_declaration_list_opt '}' type_parameters_opt
1969                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
1970        | aggregate_key attribute_list_opt no_attr_identifier fred
1971                {
1972                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
1973                        forall = false;                                                         // reset
1974                }
1975          '{' field_declaration_list_opt '}' type_parameters_opt
1976                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
1977        | aggregate_key attribute_list_opt type_name fred
1978                {
1979                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
1980                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
1981                        forall = false;                                                         // reset
1982                }
1983          '{' field_declaration_list_opt '}' type_parameters_opt
1984                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
1985        | aggregate_type_nobody
1986        ;
1987
1988type_parameters_opt:
1989        // empty
1990                { $$ = nullptr; }                                                               %prec '}'
1991        | '(' type_list ')'
1992                { $$ = $2; }
1993        ;
1994
1995aggregate_type_nobody:                                                                  // struct, union - {...}
1996        aggregate_key attribute_list_opt no_attr_identifier fred
1997                {
1998                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
1999                        forall = false;                                                         // reset
2000                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2001                }
2002        | aggregate_key attribute_list_opt type_name fred
2003                {
2004                        forall = false;                                                         // reset
2005                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2006                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2007                        // delete newFromTypeGen.
2008                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2009                        $3->type->symbolic.name = nullptr;
2010                        $3->type->symbolic.actuals = nullptr;
2011                        delete $3;
2012                }
2013        ;
2014
2015aggregate_key:
2016        STRUCT
2017                { yyy = true; $$ = DeclarationNode::Struct; }
2018        | UNION
2019                { yyy = true; $$ = DeclarationNode::Union; }
2020        | EXCEPTION
2021                { yyy = true; $$ = DeclarationNode::Exception; }
2022        | COROUTINE
2023                { yyy = true; $$ = DeclarationNode::Coroutine; }
2024        | MONITOR
2025                { yyy = true; $$ = DeclarationNode::Monitor; }
2026        | THREAD
2027                { yyy = true; $$ = DeclarationNode::Thread; }
2028        ;
2029
2030field_declaration_list_opt:
2031        // empty
2032                { $$ = nullptr; }
2033        | field_declaration_list_opt field_declaration
2034                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2035        ;
2036
2037field_declaration:
2038        type_specifier field_declaring_list_opt ';'
2039                { $$ = fieldDecl( $1, $2 ); }
2040        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2041                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2042        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2043                {
2044                        if ( ! $3 ) {                                                           // field declarator ?
2045                                $3 = DeclarationNode::newName( nullptr );
2046                        } // if
2047                        $3->inLine = true;
2048                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2049                        distInl( $3 );
2050                }
2051        | typedef_declaration ';'                                                       // CFA
2052        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2053        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2054                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2055        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2056                { $$ = $2; }                                                                    // mark all fields in list
2057        | cfa_typedef_declaration ';'                                           // CFA
2058        | static_assert                                                                         // C11
2059        ;
2060
2061field_declaring_list_opt:
2062        // empty
2063                { $$ = nullptr; }
2064        | field_declarator
2065        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2066                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2067        ;
2068
2069field_declarator:
2070        bit_subrange_size                                                                       // C special case, no field name
2071                { $$ = DeclarationNode::newBitfield( $1 ); }
2072        | variable_declarator bit_subrange_size_opt
2073                // A semantic check is required to ensure bit_subrange only appears on integral types.
2074                { $$ = $1->addBitfield( $2 ); }
2075        | variable_type_redeclarator bit_subrange_size_opt
2076                // A semantic check is required to ensure bit_subrange only appears on integral types.
2077                { $$ = $1->addBitfield( $2 ); }
2078        ;
2079
2080field_abstract_list_opt:
2081        // empty
2082                { $$ = nullptr; }
2083        | field_abstract
2084        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2085                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2086        ;
2087
2088field_abstract:
2089                //      no bit fields
2090        variable_abstract_declarator
2091        ;
2092
2093cfa_field_declaring_list:                                                               // CFA, new style field declaration
2094        // bit-fields are handled by C declarations
2095        cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
2096                { $$ = $1->addName( $2 ); }
2097        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
2098                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2099        ;
2100
2101cfa_field_abstract_list:                                                                // CFA, new style field declaration
2102        // bit-fields are handled by C declarations
2103        cfa_abstract_declarator_tuple
2104        | cfa_field_abstract_list ','
2105                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2106        ;
2107
2108bit_subrange_size_opt:
2109        // empty
2110                { $$ = nullptr; }
2111        | bit_subrange_size
2112        ;
2113
2114bit_subrange_size:
2115        ':' constant_expression
2116                { $$ = $2; }
2117        ;
2118
2119enum_type:                                                                                              // enum
2120        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2121                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2122        | ENUM attribute_list_opt no_attr_identifier
2123                { typedefTable.makeTypedef( *$3 ); }
2124          '{' enumerator_list comma_opt '}'
2125                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2126        | ENUM attribute_list_opt type_name
2127          '{' enumerator_list comma_opt '}'
2128                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2129        | enum_type_nobody
2130        ;
2131
2132enum_type_nobody:                                                                               // enum - {...}
2133        ENUM attribute_list_opt no_attr_identifier
2134                {
2135                        typedefTable.makeTypedef( *$3 );
2136                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2137                }
2138        | ENUM attribute_list_opt type_name
2139                {
2140                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2141                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2142                }
2143        ;
2144
2145enumerator_list:
2146        no_attr_identifier_or_type_name enumerator_value_opt
2147                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2148        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
2149                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2150        ;
2151
2152enumerator_value_opt:
2153        // empty
2154                { $$ = nullptr; }
2155        | '=' constant_expression
2156                { $$ = $2; }
2157        ;
2158
2159cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2160        // empty
2161                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2162        | ELLIPSIS
2163                { $$ = nullptr; }
2164        | cfa_abstract_parameter_list
2165        | cfa_parameter_list
2166        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2167                { $$ = $1->appendList( $5 ); }
2168        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2169                { $$ = $1->addVarArgs(); }
2170        | cfa_parameter_list pop ',' push ELLIPSIS
2171                { $$ = $1->addVarArgs(); }
2172        ;
2173
2174cfa_parameter_list:                                                                             // CFA
2175                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2176                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2177        cfa_parameter_declaration
2178        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2179                { $$ = $1->appendList( $5 ); }
2180        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2181                { $$ = $1->appendList( $5 ); }
2182        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2183                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2184        ;
2185
2186cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2187        cfa_abstract_parameter_declaration
2188        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2189                { $$ = $1->appendList( $5 ); }
2190        ;
2191
2192parameter_type_list_opt:
2193        // empty
2194                { $$ = nullptr; }
2195        | ELLIPSIS
2196                { $$ = nullptr; }
2197        | parameter_list
2198        | parameter_list pop ',' push ELLIPSIS
2199                { $$ = $1->addVarArgs(); }
2200        ;
2201
2202parameter_list:                                                                                 // abstract + real
2203        abstract_parameter_declaration
2204        | parameter_declaration
2205        | parameter_list pop ',' push abstract_parameter_declaration
2206                { $$ = $1->appendList( $5 ); }
2207        | parameter_list pop ',' push parameter_declaration
2208                { $$ = $1->appendList( $5 ); }
2209        ;
2210
2211// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2212// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2213
2214cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2215        parameter_declaration
2216        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2217                { $$ = $1->addName( $2 ); }
2218        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2219                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2220                { $$ = $1->addName( $2 ); }
2221        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2222                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2223        | cfa_function_specifier
2224        ;
2225
2226cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2227        abstract_parameter_declaration
2228        | cfa_identifier_parameter_declarator_no_tuple
2229        | cfa_abstract_tuple
2230                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2231        | type_qualifier_list cfa_abstract_tuple
2232                { $$ = $2->addQualifiers( $1 ); }
2233        | cfa_abstract_function
2234        ;
2235
2236parameter_declaration:
2237                // No SUE declaration in parameter list.
2238        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2239                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2240        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2241                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2242        ;
2243
2244abstract_parameter_declaration:
2245        declaration_specifier_nobody default_initialize_opt
2246                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2247        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2248                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2249        ;
2250
2251// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2252// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2253// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2254
2255identifier_list:                                                                                // K&R-style parameter list => no types
2256        no_attr_identifier
2257                { $$ = DeclarationNode::newName( $1 ); }
2258        | identifier_list ',' no_attr_identifier
2259                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2260        ;
2261
2262identifier_or_type_name:
2263        identifier
2264        | TYPEDEFname
2265        | TYPEGENname
2266        ;
2267
2268no_attr_identifier_or_type_name:
2269        no_attr_identifier
2270        | TYPEDEFname
2271        | TYPEGENname
2272        ;
2273
2274type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2275        cfa_abstract_declarator_tuple                                           // CFA
2276        | type_specifier
2277        | type_specifier abstract_declarator
2278                { $$ = $2->addType( $1 ); }
2279        ;
2280
2281type:                                                                                                   // typeof, assertion
2282        type_no_function
2283        | cfa_abstract_function                                                         // CFA
2284        ;
2285
2286initializer_opt:
2287        // empty
2288                { $$ = nullptr; }
2289        | '=' initializer
2290                { $$ = $2; }
2291        | '=' VOID
2292                { $$ = new InitializerNode( true ); }
2293        | ATassign initializer
2294                { $$ = $2->set_maybeConstructed( false ); }
2295        ;
2296
2297initializer:
2298        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2299        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2300        ;
2301
2302initializer_list_opt:
2303        // empty
2304                { $$ = nullptr; }
2305        | initializer
2306        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2307        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2308        | initializer_list_opt ',' designation initializer
2309                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2310        ;
2311
2312// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2313// '=' to separator the designator from the initializer value, as in:
2314//
2315//              int x[10] = { [1] = 3 };
2316//
2317// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2318// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2319// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2320// shift/reduce conflicts
2321
2322designation:
2323        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2324        | no_attr_identifier ':'                                                        // GCC, field name
2325                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2326        ;
2327
2328designator_list:                                                                                // C99
2329        designator
2330        | designator_list designator
2331                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2332        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2333        ;
2334
2335designator:
2336        '.' no_attr_identifier                                                          // C99, field name
2337                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2338        | '[' push assignment_expression pop ']'                        // C99, single array element
2339                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2340                { $$ = $3; }
2341        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2342                { $$ = $3; }
2343        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2344                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2345        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2346                { $$ = $4; }
2347        ;
2348
2349// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2350// rather than an object-oriented type system. This required four groups of extensions:
2351//
2352// Overloading: function, data, and operator identifiers may be overloaded.
2353//
2354// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2355//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2356//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2357//
2358// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2359//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2360//
2361// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2362//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2363//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2364//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2365//     on type arguments of polymorphic functions.
2366
2367type_parameter_list:                                                                    // CFA
2368        type_parameter
2369        | type_parameter_list ',' type_parameter
2370                { $$ = $1->appendList( $3 ); }
2371        ;
2372
2373type_initializer_opt:                                                                   // CFA
2374        // empty
2375                { $$ = nullptr; }
2376        | '=' type
2377                { $$ = $2; }
2378        ;
2379
2380type_parameter:                                                                                 // CFA
2381        type_class no_attr_identifier_or_type_name
2382                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2383          type_initializer_opt assertion_list_opt
2384                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2385        | type_specifier identifier_parameter_declarator
2386        | assertion_list
2387                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2388        ;
2389
2390type_class:                                                                                             // CFA
2391        OTYPE
2392                { $$ = DeclarationNode::Otype; }
2393        | DTYPE
2394                { $$ = DeclarationNode::Dtype; }
2395        | FTYPE
2396                { $$ = DeclarationNode::Ftype; }
2397        | TTYPE
2398                { $$ = DeclarationNode::Ttype; }
2399        ;
2400
2401assertion_list_opt:                                                                             // CFA
2402        // empty
2403                { $$ = nullptr; }
2404        | assertion_list
2405        ;
2406
2407assertion_list:                                                                                 // CFA
2408        assertion
2409        | assertion_list assertion
2410                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2411        ;
2412
2413assertion:                                                                                              // CFA
2414        '|' no_attr_identifier_or_type_name '(' type_list ')'
2415                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2416        | '|' '{' push trait_declaration_list pop '}'
2417                { $$ = $4; }
2418        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2419        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2420        ;
2421
2422type_list:                                                                                              // CFA
2423        type
2424                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2425        | assignment_expression
2426                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2427        | type_list ',' type
2428                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2429        | type_list ',' assignment_expression
2430                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2431                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2432        ;
2433
2434type_declaring_list:                                                                    // CFA
2435        OTYPE type_declarator
2436                { $$ = $2; }
2437        | storage_class_list OTYPE type_declarator
2438                { $$ = $3->addQualifiers( $1 ); }
2439        | type_declaring_list ',' type_declarator
2440                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2441        ;
2442
2443type_declarator:                                                                                // CFA
2444        type_declarator_name assertion_list_opt
2445                { $$ = $1->addAssertions( $2 ); }
2446        | type_declarator_name assertion_list_opt '=' type
2447                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2448        ;
2449
2450type_declarator_name:                                                                   // CFA
2451        no_attr_identifier_or_type_name
2452                {
2453                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2454                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2455                }
2456        | no_attr_identifier_or_type_name '(' type_parameter_list ')'
2457                {
2458                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2459                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2460                }
2461        ;
2462
2463trait_specifier:                                                                                // CFA
2464        TRAIT no_attr_identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2465                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2466        | TRAIT no_attr_identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2467                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2468        ;
2469
2470trait_declaration_list:                                                                 // CFA
2471        trait_declaration
2472        | trait_declaration_list pop push trait_declaration
2473                { $$ = $1->appendList( $4 ); }
2474        ;
2475
2476trait_declaration:                                                                              // CFA
2477        cfa_trait_declaring_list ';'
2478        | trait_declaring_list ';'
2479        ;
2480
2481cfa_trait_declaring_list:                                                               // CFA
2482        cfa_variable_specifier
2483        | cfa_function_specifier
2484        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2485                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2486        ;
2487
2488trait_declaring_list:                                                                   // CFA
2489        type_specifier declarator
2490                { $$ = $2->addType( $1 ); }
2491        | trait_declaring_list pop ',' push declarator
2492                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2493        ;
2494
2495//***************************** EXTERNAL DEFINITIONS *****************************
2496
2497translation_unit:
2498        // empty, input file
2499        | external_definition_list
2500                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2501        ;
2502
2503external_definition_list:
2504        push external_definition pop
2505                { $$ = $2; }
2506        | external_definition_list push external_definition pop
2507                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2508        ;
2509
2510external_definition_list_opt:
2511        // empty
2512                { $$ = nullptr; }
2513        | external_definition_list
2514        ;
2515
2516up:
2517                { typedefTable.up( forall ); forall = false; }
2518        ;
2519
2520down:
2521                { typedefTable.down(); }
2522        ;
2523
2524external_definition:
2525        declaration
2526        | external_function_definition
2527        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2528                {
2529                        distExt( $2 );                                                          // mark all fields in list
2530                        $$ = $2;
2531                }
2532        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2533                {
2534                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2535                }
2536        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2537                {
2538                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2539                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2540                }
2541          '{' up external_definition_list_opt down '}'
2542                {
2543                        linkage = linkageStack.top();
2544                        linkageStack.pop();
2545                        $$ = $6;
2546                }
2547        | type_qualifier_list
2548                {
2549                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2550                        if ( $1->type->forall ) forall = true;          // remember generic type
2551                }
2552          '{' up external_definition_list_opt down '}'          // CFA, namespace
2553                {
2554                        distQual( $5, $1 );
2555                        forall = false;
2556                        $$ = $5;
2557                }
2558        | declaration_qualifier_list
2559                {
2560                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2561                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2562                }
2563          '{' up external_definition_list_opt down '}'          // CFA, namespace
2564                {
2565                        distQual( $5, $1 );
2566                        forall = false;
2567                        $$ = $5;
2568                }
2569        | declaration_qualifier_list type_qualifier_list
2570                {
2571                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2572                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2573                }
2574          '{' up external_definition_list_opt down '}'          // CFA, namespace
2575                {
2576                        distQual( $6, $1->addQualifiers( $2 ) );
2577                        forall = false;
2578                        $$ = $6;
2579                }
2580        ;
2581
2582external_function_definition:
2583        function_definition
2584                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2585                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2586                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2587                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2588                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2589        | function_declarator compound_statement
2590                { $$ = $1->addFunctionBody( $2 ); }
2591        | KR_function_declarator KR_parameter_list_opt compound_statement
2592                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2593        ;
2594
2595with_clause_opt:
2596        // empty
2597                { $$ = nullptr; forall = false; }
2598        | WITH '(' tuple_expression_list ')'
2599                { $$ = $3; forall = false; }
2600        ;
2601
2602function_definition:
2603        cfa_function_declaration with_clause_opt compound_statement     // CFA
2604                {
2605                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2606                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2607                        $1->get_last()->addFunctionBody( $3, $2 );
2608                        $$ = $1;
2609                }
2610        | declaration_specifier function_declarator with_clause_opt compound_statement
2611                {
2612                        rebindForall( $1, $2 );
2613                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2614                }
2615        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2616                {
2617                        rebindForall( $1, $2 );
2618                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2619                }
2620                // handles default int return type, OBSOLESCENT (see 1)
2621        | type_qualifier_list function_declarator with_clause_opt compound_statement
2622                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2623                // handles default int return type, OBSOLESCENT (see 1)
2624        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2625                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2626                // handles default int return type, OBSOLESCENT (see 1)
2627        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2628                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2629
2630                // Old-style K&R function definition, OBSOLESCENT (see 4)
2631        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2632                {
2633                        rebindForall( $1, $2 );
2634                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2635                }
2636                // handles default int return type, OBSOLESCENT (see 1)
2637        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2638                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2639                // handles default int return type, OBSOLESCENT (see 1)
2640        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2641                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2642                // handles default int return type, OBSOLESCENT (see 1)
2643        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2644                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2645        ;
2646
2647declarator:
2648        variable_declarator
2649        | variable_type_redeclarator
2650        | function_declarator
2651        ;
2652
2653subrange:
2654        constant_expression '~' constant_expression                     // CFA, integer subrange
2655                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2656        ;
2657
2658asm_name_opt:                                                                                   // GCC
2659        // empty
2660                { $$ = nullptr; }
2661        | ASM '(' string_literal ')' attribute_list_opt
2662                {
2663                        DeclarationNode * name = new DeclarationNode();
2664                        name->asmName = $3;
2665                        $$ = name->addQualifiers( $5 );
2666                }
2667        ;
2668
2669attribute_list_opt:                                                                             // GCC
2670        // empty
2671                { $$ = nullptr; }
2672        | attribute_list
2673        ;
2674
2675attribute_list:                                                                                 // GCC
2676        attribute
2677        | attribute_list attribute
2678                { $$ = $2->addQualifiers( $1 ); }
2679        ;
2680
2681attribute:                                                                                              // GCC
2682        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2683                { $$ = $4; }
2684        ;
2685
2686attribute_name_list:                                                                    // GCC
2687        attribute_name
2688        | attribute_name_list ',' attribute_name
2689                { $$ = $3->addQualifiers( $1 ); }
2690        ;
2691
2692attribute_name:                                                                                 // GCC
2693        // empty
2694                { $$ = nullptr; }
2695        | attr_name
2696                { $$ = DeclarationNode::newAttribute( $1 ); }
2697        | attr_name '(' argument_expression_list ')'
2698                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2699        ;
2700
2701attr_name:                                                                                              // GCC
2702        IDENTIFIER
2703        | quasi_keyword
2704        | TYPEDEFname
2705        | TYPEGENname
2706        | FALLTHROUGH
2707                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2708        | CONST
2709                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2710        ;
2711
2712// ============================================================================
2713// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2714// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2715// in:
2716//
2717//              int (*f())[10] { ... };
2718//              ... (*f())[3] += 1;             // definition mimics usage
2719//
2720// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2721// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2722// ============================================================================
2723
2724// ----------------------------------------------------------------------------
2725// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2726// to define a variable or function prototype, e.g.:
2727//
2728//              valid declaration               invalid definition
2729//              -----------------               ------------------
2730//              int f;                                  int f {}
2731//              int *f;                                 int *f {}
2732//              int f[10];                              int f[10] {}
2733//              int (*f)(int);                  int (*f)(int) {}
2734//
2735// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2736// variable_declarator and function_declarator.
2737// ----------------------------------------------------------------------------
2738
2739// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2740// declaring an array of functions versus a pointer to an array of functions.
2741
2742variable_declarator:
2743        paren_identifier attribute_list_opt
2744                { $$ = $1->addQualifiers( $2 ); }
2745        | variable_ptr
2746        | variable_array attribute_list_opt
2747                { $$ = $1->addQualifiers( $2 ); }
2748        | variable_function attribute_list_opt
2749                { $$ = $1->addQualifiers( $2 ); }
2750        ;
2751
2752paren_identifier:
2753        identifier
2754                { $$ = DeclarationNode::newName( $1 ); }
2755        | '(' paren_identifier ')'                                                      // redundant parenthesis
2756                { $$ = $2; }
2757        ;
2758
2759variable_ptr:
2760        ptrref_operator variable_declarator
2761                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2762        | ptrref_operator type_qualifier_list variable_declarator
2763                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2764        | '(' variable_ptr ')' attribute_list_opt
2765                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2766        ;
2767
2768variable_array:
2769        paren_identifier array_dimension
2770                { $$ = $1->addArray( $2 ); }
2771        | '(' variable_ptr ')' array_dimension
2772                { $$ = $2->addArray( $4 ); }
2773        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2774                { $$ = $2->addArray( $4 ); }
2775        | '(' variable_array ')'                                                        // redundant parenthesis
2776                { $$ = $2; }
2777        ;
2778
2779variable_function:
2780        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2781                { $$ = $2->addParamList( $6 ); }
2782        | '(' variable_function ')'                                                     // redundant parenthesis
2783                { $$ = $2; }
2784        ;
2785
2786// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2787// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2788// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2789
2790function_declarator:
2791        function_no_ptr attribute_list_opt
2792                { $$ = $1->addQualifiers( $2 ); }
2793        | function_ptr
2794        | function_array attribute_list_opt
2795                { $$ = $1->addQualifiers( $2 ); }
2796        ;
2797
2798function_no_ptr:
2799        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2800                { $$ = $1->addParamList( $4 ); }
2801        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2802                { $$ = $2->addParamList( $6 ); }
2803        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2804                { $$ = $2; }
2805        ;
2806
2807function_ptr:
2808        ptrref_operator function_declarator
2809                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2810        | ptrref_operator type_qualifier_list function_declarator
2811                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2812        | '(' function_ptr ')'
2813                { $$ = $2; }
2814        ;
2815
2816function_array:
2817        '(' function_ptr ')' array_dimension
2818                { $$ = $2->addArray( $4 ); }
2819        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2820                { $$ = $2->addArray( $4 ); }
2821        | '(' function_array ')'                                                        // redundant parenthesis
2822                { $$ = $2; }
2823        ;
2824
2825// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2826//
2827//   f( a, b, c ) int a, *b, c[]; {}
2828//
2829// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2830// returning arrays and functions versus pointers to arrays and functions.
2831
2832KR_function_declarator:
2833        KR_function_no_ptr
2834        | KR_function_ptr
2835        | KR_function_array
2836        ;
2837
2838KR_function_no_ptr:
2839        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2840                { $$ = $1->addIdList( $3 ); }
2841        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2842                { $$ = $2->addParamList( $6 ); }
2843        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2844                { $$ = $2; }
2845        ;
2846
2847KR_function_ptr:
2848        ptrref_operator KR_function_declarator
2849                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2850        | ptrref_operator type_qualifier_list KR_function_declarator
2851                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2852        | '(' KR_function_ptr ')'
2853                { $$ = $2; }
2854        ;
2855
2856KR_function_array:
2857        '(' KR_function_ptr ')' array_dimension
2858                { $$ = $2->addArray( $4 ); }
2859        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2860                { $$ = $2->addArray( $4 ); }
2861        | '(' KR_function_array ')'                                                     // redundant parenthesis
2862                { $$ = $2; }
2863        ;
2864
2865// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2866//
2867//              typedef int foo;
2868//              {
2869//                 int foo; // redefine typedef name in new scope
2870//              }
2871//
2872// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2873// and functions versus pointers to arrays and functions.
2874
2875variable_type_redeclarator:
2876        paren_type attribute_list_opt
2877                { $$ = $1->addQualifiers( $2 ); }
2878        | type_ptr
2879        | type_array attribute_list_opt
2880                { $$ = $1->addQualifiers( $2 ); }
2881        | type_function attribute_list_opt
2882                { $$ = $1->addQualifiers( $2 ); }
2883        ;
2884
2885paren_type:
2886        typedef
2887                // hide type name in enclosing scope by variable name
2888                {
2889                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2890                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2891                        // } else {
2892                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2893                        // } // if
2894                }
2895        | '(' paren_type ')'
2896                { $$ = $2; }
2897        ;
2898
2899type_ptr:
2900        ptrref_operator variable_type_redeclarator
2901                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2902        | ptrref_operator type_qualifier_list variable_type_redeclarator
2903                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2904        | '(' type_ptr ')' attribute_list_opt
2905                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2906        ;
2907
2908type_array:
2909        paren_type array_dimension
2910                { $$ = $1->addArray( $2 ); }
2911        | '(' type_ptr ')' array_dimension
2912                { $$ = $2->addArray( $4 ); }
2913        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2914                { $$ = $2->addArray( $4 ); }
2915        | '(' type_array ')'                                                            // redundant parenthesis
2916                { $$ = $2; }
2917        ;
2918
2919type_function:
2920        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2921                { $$ = $1->addParamList( $4 ); }
2922        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2923                { $$ = $2->addParamList( $6 ); }
2924        | '(' type_function ')'                                                         // redundant parenthesis
2925                { $$ = $2; }
2926        ;
2927
2928// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2929// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2930// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2931// pointers to arrays and functions.
2932
2933identifier_parameter_declarator:
2934        paren_identifier attribute_list_opt
2935                { $$ = $1->addQualifiers( $2 ); }
2936        | '&' MUTEX paren_identifier attribute_list_opt
2937                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2938        | identifier_parameter_ptr
2939        | identifier_parameter_array attribute_list_opt
2940                { $$ = $1->addQualifiers( $2 ); }
2941        | identifier_parameter_function attribute_list_opt
2942                { $$ = $1->addQualifiers( $2 ); }
2943        ;
2944
2945identifier_parameter_ptr:
2946        ptrref_operator identifier_parameter_declarator
2947                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2948        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2949                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2950        | '(' identifier_parameter_ptr ')' attribute_list_opt
2951                { $$ = $2->addQualifiers( $4 ); }
2952        ;
2953
2954identifier_parameter_array:
2955        paren_identifier array_parameter_dimension
2956                { $$ = $1->addArray( $2 ); }
2957        | '(' identifier_parameter_ptr ')' array_dimension
2958                { $$ = $2->addArray( $4 ); }
2959        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2960                { $$ = $2->addArray( $4 ); }
2961        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2962                { $$ = $2; }
2963        ;
2964
2965identifier_parameter_function:
2966        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2967                { $$ = $1->addParamList( $4 ); }
2968        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2969                { $$ = $2->addParamList( $6 ); }
2970        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2971                { $$ = $2; }
2972        ;
2973
2974// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2975// e.g.:
2976//
2977//              typedef int foo;
2978//              forall( otype T ) struct foo;
2979//              int f( int foo ); // redefine typedef name in new scope
2980//
2981// and allows the C99 array options, which can only appear in a parameter list.
2982
2983type_parameter_redeclarator:
2984        typedef attribute_list_opt
2985                { $$ = $1->addQualifiers( $2 ); }
2986        | '&' MUTEX typedef attribute_list_opt
2987                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2988        | type_parameter_ptr
2989        | type_parameter_array attribute_list_opt
2990                { $$ = $1->addQualifiers( $2 ); }
2991        | type_parameter_function attribute_list_opt
2992                { $$ = $1->addQualifiers( $2 ); }
2993        ;
2994
2995typedef:
2996        TYPEDEFname
2997                { $$ = DeclarationNode::newName( $1 ); }
2998        | TYPEGENname
2999                { $$ = DeclarationNode::newName( $1 ); }
3000        ;
3001
3002type_parameter_ptr:
3003        ptrref_operator type_parameter_redeclarator
3004                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3005        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3006                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3007        | '(' type_parameter_ptr ')' attribute_list_opt
3008                { $$ = $2->addQualifiers( $4 ); }
3009        ;
3010
3011type_parameter_array:
3012        typedef array_parameter_dimension
3013                { $$ = $1->addArray( $2 ); }
3014        | '(' type_parameter_ptr ')' array_parameter_dimension
3015                { $$ = $2->addArray( $4 ); }
3016        ;
3017
3018type_parameter_function:
3019        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3020                { $$ = $1->addParamList( $4 ); }
3021        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3022                { $$ = $2->addParamList( $6 ); }
3023        ;
3024
3025// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3026// which the type applies, e.g.:
3027//
3028//              sizeof( int );
3029//              sizeof( int * );
3030//              sizeof( int [10] );
3031//              sizeof( int (*)() );
3032//              sizeof( int () );
3033//
3034// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3035// and functions versus pointers to arrays and functions.
3036
3037abstract_declarator:
3038        abstract_ptr
3039        | abstract_array attribute_list_opt
3040                { $$ = $1->addQualifiers( $2 ); }
3041        | abstract_function attribute_list_opt
3042                { $$ = $1->addQualifiers( $2 ); }
3043        ;
3044
3045abstract_ptr:
3046        ptrref_operator
3047                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3048        | ptrref_operator type_qualifier_list
3049                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3050        | ptrref_operator abstract_declarator
3051                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3052        | ptrref_operator type_qualifier_list abstract_declarator
3053                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3054        | '(' abstract_ptr ')' attribute_list_opt
3055                { $$ = $2->addQualifiers( $4 ); }
3056        ;
3057
3058abstract_array:
3059        array_dimension
3060        | '(' abstract_ptr ')' array_dimension
3061                { $$ = $2->addArray( $4 ); }
3062        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3063                { $$ = $2->addArray( $4 ); }
3064        | '(' abstract_array ')'                                                        // redundant parenthesis
3065                { $$ = $2; }
3066        ;
3067
3068abstract_function:
3069        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3070                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3071        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3072                { $$ = $2->addParamList( $6 ); }
3073        | '(' abstract_function ')'                                                     // redundant parenthesis
3074                { $$ = $2; }
3075        ;
3076
3077array_dimension:
3078                // Only the first dimension can be empty.
3079        '[' ']'
3080                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3081        | '[' ']' multi_array_dimension
3082                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3083        | multi_array_dimension
3084        ;
3085
3086multi_array_dimension:
3087        '[' push assignment_expression pop ']'
3088                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3089        | '[' push '*' pop ']'                                                          // C99
3090                { $$ = DeclarationNode::newVarArray( 0 ); }
3091        | multi_array_dimension '[' push assignment_expression pop ']'
3092                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3093        | multi_array_dimension '[' push '*' pop ']'            // C99
3094                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3095        ;
3096
3097// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3098// identifier to which the type applies, e.g.:
3099//
3100//              int f( int );                   // not handled here
3101//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3102//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3103//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3104//
3105// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3106// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3107// special meaning of parenthesis around a typedef name:
3108//
3109//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3110//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3111//              not as redundant parentheses around the identifier."
3112//
3113// For example:
3114//
3115//              typedef float T;
3116//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3117//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3118//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3119//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3120//
3121// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3122// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3123// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3124// functions.
3125
3126abstract_parameter_declarator:
3127        abstract_parameter_ptr
3128        | '&' MUTEX attribute_list_opt
3129                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3130        | abstract_parameter_array attribute_list_opt
3131                { $$ = $1->addQualifiers( $2 ); }
3132        | abstract_parameter_function attribute_list_opt
3133                { $$ = $1->addQualifiers( $2 ); }
3134        ;
3135
3136abstract_parameter_ptr:
3137        ptrref_operator
3138                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3139        | ptrref_operator type_qualifier_list
3140                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3141        | ptrref_operator abstract_parameter_declarator
3142                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3143        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3144                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3145        | '(' abstract_parameter_ptr ')' attribute_list_opt
3146                { $$ = $2->addQualifiers( $4 ); }
3147        ;
3148
3149abstract_parameter_array:
3150        array_parameter_dimension
3151        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3152                { $$ = $2->addArray( $4 ); }
3153        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3154                { $$ = $2->addArray( $4 ); }
3155        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3156                { $$ = $2; }
3157        ;
3158
3159abstract_parameter_function:
3160        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3161                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3162        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3163                { $$ = $2->addParamList( $6 ); }
3164        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3165                { $$ = $2; }
3166        ;
3167
3168array_parameter_dimension:
3169                // Only the first dimension can be empty or have qualifiers.
3170        array_parameter_1st_dimension
3171        | array_parameter_1st_dimension multi_array_dimension
3172                { $$ = $1->addArray( $2 ); }
3173        | multi_array_dimension
3174        ;
3175
3176// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3177//
3178//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3179//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3180
3181array_parameter_1st_dimension:
3182        '[' ']'
3183                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3184                // multi_array_dimension handles the '[' '*' ']' case
3185        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3186                { $$ = DeclarationNode::newVarArray( $3 ); }
3187        | '[' push type_qualifier_list pop ']'
3188                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3189                // multi_array_dimension handles the '[' assignment_expression ']' case
3190        | '[' push type_qualifier_list assignment_expression pop ']'
3191                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3192        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3193                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3194        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3195                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3196        ;
3197
3198// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3199//
3200//              struct S {
3201//          int;
3202//          int *;
3203//          int [10];
3204//          int (*)();
3205//      };
3206
3207variable_abstract_declarator:
3208        variable_abstract_ptr
3209        | variable_abstract_array attribute_list_opt
3210                { $$ = $1->addQualifiers( $2 ); }
3211        | variable_abstract_function attribute_list_opt
3212                { $$ = $1->addQualifiers( $2 ); }
3213        ;
3214
3215variable_abstract_ptr:
3216        ptrref_operator
3217                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3218        | ptrref_operator type_qualifier_list
3219                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3220        | ptrref_operator variable_abstract_declarator
3221                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3222        | ptrref_operator type_qualifier_list variable_abstract_declarator
3223                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3224        | '(' variable_abstract_ptr ')' attribute_list_opt
3225                { $$ = $2->addQualifiers( $4 ); }
3226        ;
3227
3228variable_abstract_array:
3229        array_dimension
3230        | '(' variable_abstract_ptr ')' array_dimension
3231                { $$ = $2->addArray( $4 ); }
3232        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3233                { $$ = $2->addArray( $4 ); }
3234        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3235                { $$ = $2; }
3236        ;
3237
3238variable_abstract_function:
3239        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3240                { $$ = $2->addParamList( $6 ); }
3241        | '(' variable_abstract_function ')'                            // redundant parenthesis
3242                { $$ = $2; }
3243        ;
3244
3245// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3246// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3247
3248cfa_identifier_parameter_declarator_tuple:                              // CFA
3249        cfa_identifier_parameter_declarator_no_tuple
3250        | cfa_abstract_tuple
3251        | type_qualifier_list cfa_abstract_tuple
3252                { $$ = $2->addQualifiers( $1 ); }
3253        ;
3254
3255cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3256        cfa_identifier_parameter_ptr
3257        | cfa_identifier_parameter_array
3258        ;
3259
3260cfa_identifier_parameter_ptr:                                                   // CFA
3261                // No SUE declaration in parameter list.
3262        ptrref_operator type_specifier_nobody
3263                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3264        | type_qualifier_list ptrref_operator type_specifier_nobody
3265                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3266        | ptrref_operator cfa_abstract_function
3267                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3268        | type_qualifier_list ptrref_operator cfa_abstract_function
3269                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3270        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3271                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3272        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3273                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3274        ;
3275
3276cfa_identifier_parameter_array:                                                 // CFA
3277                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3278                // shift/reduce conflict with new-style empty (void) function return type.
3279        '[' ']' type_specifier_nobody
3280                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3281        | cfa_array_parameter_1st_dimension type_specifier_nobody
3282                { $$ = $2->addNewArray( $1 ); }
3283        | '[' ']' multi_array_dimension type_specifier_nobody
3284                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3285        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3286                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3287        | multi_array_dimension type_specifier_nobody
3288                { $$ = $2->addNewArray( $1 ); }
3289
3290        | '[' ']' cfa_identifier_parameter_ptr
3291                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3292        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3293                { $$ = $2->addNewArray( $1 ); }
3294        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3295                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3296        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3297                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3298        | multi_array_dimension cfa_identifier_parameter_ptr
3299                { $$ = $2->addNewArray( $1 ); }
3300        ;
3301
3302cfa_array_parameter_1st_dimension:
3303        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3304                { $$ = DeclarationNode::newVarArray( $3 ); }
3305        | '[' push type_qualifier_list assignment_expression pop ']'
3306                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3307        | '[' push declaration_qualifier_list assignment_expression pop ']'
3308                // declaration_qualifier_list must be used because of shift/reduce conflict with
3309                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3310                // appear in this context.
3311                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3312        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3313                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3314        ;
3315
3316// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3317// identifier to which the type applies, e.g.:
3318//
3319//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3320//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3321//
3322// These rules need LR(3):
3323//
3324//              cfa_abstract_tuple identifier_or_type_name
3325//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3326//
3327// since a function return type can be syntactically identical to a tuple type:
3328//
3329//              [int, int] t;
3330//              [int, int] f( int );
3331//
3332// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3333// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3334// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3335// duplicated when appearing with cfa_function_specifier.
3336
3337cfa_abstract_declarator_tuple:                                                  // CFA
3338        cfa_abstract_tuple
3339        | type_qualifier_list cfa_abstract_tuple
3340                { $$ = $2->addQualifiers( $1 ); }
3341        | cfa_abstract_declarator_no_tuple
3342        ;
3343
3344cfa_abstract_declarator_no_tuple:                                               // CFA
3345        cfa_abstract_ptr
3346        | cfa_abstract_array
3347        ;
3348
3349cfa_abstract_ptr:                                                                               // CFA
3350        ptrref_operator type_specifier
3351                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3352        | type_qualifier_list ptrref_operator type_specifier
3353                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3354        | ptrref_operator cfa_abstract_function
3355                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3356        | type_qualifier_list ptrref_operator cfa_abstract_function
3357                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3358        | ptrref_operator cfa_abstract_declarator_tuple
3359                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3360        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3361                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3362        ;
3363
3364cfa_abstract_array:                                                                             // CFA
3365                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3366                // empty (void) function return type.
3367        '[' ']' type_specifier
3368                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3369        | '[' ']' multi_array_dimension type_specifier
3370                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3371        | multi_array_dimension type_specifier
3372                { $$ = $2->addNewArray( $1 ); }
3373        | '[' ']' cfa_abstract_ptr
3374                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3375        | '[' ']' multi_array_dimension cfa_abstract_ptr
3376                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3377        | multi_array_dimension cfa_abstract_ptr
3378                { $$ = $2->addNewArray( $1 ); }
3379        ;
3380
3381cfa_abstract_tuple:                                                                             // CFA
3382        '[' push cfa_abstract_parameter_list pop ']'
3383                { $$ = DeclarationNode::newTuple( $3 ); }
3384        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3385                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3386        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3387                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3388        ;
3389
3390cfa_abstract_function:                                                                  // CFA
3391//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3392//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3393        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3394                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3395        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3396                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3397        ;
3398
3399// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3400//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3401//
3402// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3403//    the declaration specifiers in a declaration is an obsolescent feature."
3404//
3405// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3406//    prototype-format parameter type declarators) is an obsolescent feature."
3407//
3408// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3409//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3410
3411//************************* MISCELLANEOUS ********************************
3412
3413comma_opt:                                                                                              // redundant comma
3414        // empty
3415        | ','
3416        ;
3417
3418default_initialize_opt:
3419        // empty
3420                { $$ = nullptr; }
3421        | '=' assignment_expression
3422                { $$ = $2; }
3423        ;
3424
3425%%
3426
3427// ----end of grammar----
3428
3429// Local Variables: //
3430// mode: c++ //
3431// tab-width: 4 //
3432// compile-command: "make install" //
3433// End: //
Note: See TracBrowser for help on using the repository browser.