source: src/Parser/parser.yy @ c27fb59

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerresolv-newwith_gc
Last change on this file since c27fb59 was c27fb59, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

add aggregate kind "exception"

  • Property mode set to 100644
File size: 121.3 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Thu Feb 22 17:48:54 2018
13// Update Count     : 3028
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        //cur->addType( specifier );
102        for ( cur = dynamic_cast< DeclarationNode * >( cur->get_next() ); cur != nullptr; cur = dynamic_cast< DeclarationNode * >( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106//      delete cl;
107        return declList;
108} // distAttr
109
110void distExt( DeclarationNode * declaration ) {
111        // distribute EXTENSION across all declarations
112        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
113                iter->set_extension( true );
114        } // for
115} // distExt
116
117// There is an ambiguity for inline generic-routine return-types and generic routines.
118//   forall( otype T ) struct S { int i; } bar( T ) {}
119// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
120//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
121
122void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
123        if ( declSpec->type->kind == TypeData::Aggregate ) { // return is aggregate definition
124                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
125                declSpec->type->aggregate.params = nullptr;
126        } // if
127} // rebindForall
128
129bool forall = false;                                                                    // aggregate have one or more forall qualifiers ?
130
131// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
132#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
133if ( N ) {                                                                                                                                              \
134        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
135        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
136        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
137        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
138        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
139} else {                                                                                                                                                \
140        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
141        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
142        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
143}
144%}
145
146%define parse.error verbose
147
148// Types declaration for productions
149%union
150{
151        Token tok;
152        ParseNode * pn;
153        ExpressionNode * en;
154        DeclarationNode * decl;
155        DeclarationNode::Aggregate aggKey;
156        DeclarationNode::TypeClass tclass;
157        StatementNode * sn;
158        WaitForStmt * wfs;
159        Expression * constant;
160        IfCtl * ifctl;
161        ForCtl * fctl;
162        LabelNode * label;
163        InitializerNode * in;
164        OperKinds op;
165        std::string * str;
166        bool flag;
167        CatchStmt::Kind catch_kind;
168}
169
170//************************* TERMINAL TOKENS ********************************
171
172// keywords
173%token TYPEDEF
174%token EXTERN STATIC AUTO REGISTER
175%token THREADLOCAL                                                                              // C11
176%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
177%token NORETURN                                                                                 // C11
178%token CONST VOLATILE
179%token RESTRICT                                                                                 // C99
180%token ATOMIC                                                                                   // C11
181%token FORALL MUTEX VIRTUAL                                                             // CFA
182%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
183%token BOOL COMPLEX IMAGINARY                                                   // C99
184%token INT128 FLOAT80 FLOAT128                                                  // GCC
185%token ZERO_T ONE_T                                                                             // CFA
186%token VALIST                                                                                   // GCC
187%token TYPEOF LABEL                                                                             // GCC
188%token ENUM STRUCT UNION
189%token EXCEPTION                                                                                // CFA
190%token COROUTINE MONITOR THREAD                                                 // CFA
191%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
192%token SIZEOF OFFSETOF
193%token ATTRIBUTE EXTENSION                                                              // GCC
194%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
195%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
196%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
197%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
198
199// names and constants: lexer differentiates between identifier and typedef names
200%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
201%token<tok> TIMEOUT                             WOR
202%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
203%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
204// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
205// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
206// converted into the tuple index (.)(1). e.g., 3.x
207%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
208
209// multi-character operators
210%token ARROW                                                                                    // ->
211%token ICR DECR                                                                                 // ++   --
212%token LS RS                                                                                    // <<   >>
213%token LE GE EQ NE                                                                              // <=   >=      ==      !=
214%token ANDAND OROR                                                                              // &&   ||
215%token ELLIPSIS                                                                                 // ...
216
217%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
218%token PLUSassign       MINUSassign                                                     // +=   -=
219%token LSassign         RSassign                                                        // <<=  >>=
220%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
221
222%token ATassign                                                                                 // @=
223
224%type<tok> identifier  no_attr_identifier
225%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
226%type<tok> quasi_keyword
227%type<constant> string_literal
228%type<str> string_literal_list
229
230// expressions
231%type<en> constant
232%type<en> tuple                                                 tuple_expression_list
233%type<op> ptrref_operator                               unary_operator                          assignment_operator
234%type<en> primary_expression                    postfix_expression                      unary_expression
235%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
236%type<en> shift_expression                              relational_expression           equality_expression
237%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
238%type<en> logical_AND_expression                logical_OR_expression
239%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
240%type<en> comma_expression                              comma_expression_opt
241%type<en> argument_expression_list              argument_expression                     default_initialize_opt
242%type<ifctl> if_control_expression
243%type<fctl> for_control_expression
244%type<en> subrange
245%type<decl> asm_name_opt
246%type<en> asm_operands_opt asm_operands_list asm_operand
247%type<label> label_list
248%type<en> asm_clobbers_list_opt
249%type<flag> asm_volatile_opt
250%type<en> handler_predicate_opt
251
252// statements
253%type<sn> statement                                             labeled_statement                       compound_statement
254%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
255%type<sn> selection_statement
256%type<sn> switch_clause_list_opt                switch_clause_list                      choose_clause_list_opt          choose_clause_list
257%type<en> case_value
258%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
259%type<sn> fall_through                                  fall_through_opt
260%type<sn> iteration_statement                   jump_statement
261%type<sn> expression_statement                  asm_statement
262%type<sn> with_statement
263%type<en> with_clause_opt
264%type<sn> exception_statement                   handler_clause                          finally_clause
265%type<catch_kind> handler_key
266%type<sn> mutex_statement
267%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
268%type<sn> waitfor_statement
269%type<wfs> waitfor_clause
270
271// declarations
272%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
273%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
274%type<decl> abstract_parameter_declaration
275
276%type<aggKey> aggregate_key
277%type<decl> aggregate_type aggregate_type_nobody
278
279%type<decl> assertion assertion_list_opt
280
281%type<en>   bit_subrange_size_opt bit_subrange_size
282
283%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
284
285%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
286
287%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
288%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
289
290%type<decl> elaborated_type elaborated_type_nobody
291
292%type<decl> enumerator_list enum_type enum_type_nobody
293%type<en> enumerator_value_opt
294
295%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
296
297%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
298%type<en> field field_list field_name fraction_constants
299
300%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
301
302%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
303%type<decl> identifier_list
304
305%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
306%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
307%type<decl> cfa_abstract_ptr cfa_abstract_tuple
308
309%type<decl> cfa_array_parameter_1st_dimension
310
311%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list
312%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
313
314%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
315%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
316
317%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_type_list_opt
318
319%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
320
321%type<decl> c_declaration static_assert
322%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
323%type<decl> KR_declaration_list KR_declaration_list_opt
324
325%type<decl> parameter_declaration parameter_list parameter_type_list_opt
326
327%type<decl> paren_identifier paren_type
328
329%type<decl> storage_class storage_class_list
330
331%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
332
333%type<tclass> type_class
334%type<decl> type_declarator type_declarator_name type_declaring_list
335
336%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
337%type<decl> typedef typedef_declaration typedef_expression
338
339%type<decl> variable_type_redeclarator type_ptr type_array type_function
340
341%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
342
343%type<decl> type type_no_function
344%type<decl> type_parameter type_parameter_list type_initializer_opt
345
346%type<en> type_list
347
348%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
349%type<decl> type_specifier type_specifier_nobody
350
351%type<decl> variable_declarator variable_ptr variable_array variable_function
352%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
353
354%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
355
356// initializers
357%type<in>  initializer initializer_list initializer_opt
358
359// designators
360%type<en>  designator designator_list designation
361
362
363// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
364//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
365//   if ( C ) S1 else S2
366//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
367// Similar issues exit with the waitfor statement.
368
369// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
370// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
371%precedence THEN        // rule precedence for IF/WAITFOR statement
372%precedence WOR         // token precedence for start of WOR in WAITFOR statement
373%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
374%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
375
376// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
377//   forall( otype T ) struct Foo { T v; };
378//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
379//   Foo ( *fp )( int );
380//   `---'                                              matches start of TYPEGENname '('
381// Must be:
382//   Foo( int ) ( *fp )( int );
383
384// Order of these lines matters (low-to-high precedence).
385%precedence TYPEGENname
386%precedence '('
387
388%locations                      // support location tracking for error messages
389
390%start translation_unit                                                                 // parse-tree root
391
392%%
393//************************* Namespace Management ********************************
394
395// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
396// "identifier", "TYPEDEFname", and "TYPEGENname" that are lexically identical.  While it is possible to write a purely
397// context-free grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.
398// Hence, this grammar uses the ANSI style.
399//
400// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
401// introduced through "forall" qualifiers), and by introducing "type generators" -- parameterized types.  This latter
402// type name creates a third class of identifiers that must be distinguished by the scanner.
403//
404// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
405// accesses a data structure (TypedefTable) to allow classification of an identifier that it has just read.  Semantic
406// actions during the parser update this data structure when the class of identifiers change.
407//
408// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its class in a
409// local scope; it must revert to its original class at the end of the block.  Since type names can be local to a
410// particular declaration, each declaration is itself a scope.  This requires distinguishing between type names that are
411// local to the current declaration scope and those that persist past the end of the declaration (i.e., names defined in
412// "typedef" or "otype" declarations).
413//
414// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and closing of
415// scopes.  Every push must have a matching pop, although it is regrettable the matching pairs do not always occur
416// within the same rule.  These non-terminals may appear in more contexts than strictly necessary from a semantic point
417// of view.  Unfortunately, these extra rules are necessary to prevent parsing conflicts -- the parser may not have
418// enough context and look-ahead information to decide whether a new scope is necessary, so the effect of these extra
419// rules is to open a new scope unconditionally.  As the grammar evolves, it may be neccesary to add or move around
420// "push" and "pop" nonterminals to resolve conflicts of this sort.
421
422push:
423                { typedefTable.enterScope(); }
424        ;
425
426pop:
427                { typedefTable.leaveScope(); }
428        ;
429
430//************************* CONSTANTS ********************************
431
432constant:
433                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
434        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
435        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
436        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
437        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
438        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
439        ;
440
441quasi_keyword:                                                                                  // CFA
442        TIMEOUT
443        | WOR
444        ;
445
446identifier:
447        IDENTIFIER
448        | ATTR_IDENTIFIER                                                                       // CFA
449        | quasi_keyword
450        ;
451
452no_attr_identifier:
453        IDENTIFIER
454        | quasi_keyword
455        ;
456
457string_literal:
458        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
459        ;
460
461string_literal_list:                                                                    // juxtaposed strings are concatenated
462        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
463        | string_literal_list STRINGliteral
464                {
465                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
466                        delete $2;                                                                      // allocated by lexer
467                        $$ = $1;                                                                        // conversion from tok to str
468                }
469        ;
470
471//************************* EXPRESSIONS ********************************
472
473primary_expression:
474        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
475                { $$ = new ExpressionNode( build_varref( $1 ) ); }
476        | quasi_keyword
477                { $$ = new ExpressionNode( build_varref( $1 ) ); }
478        | tuple
479        | '(' comma_expression ')'
480                { $$ = $2; }
481        | '(' compound_statement ')'                                            // GCC, lambda expression
482                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
483        | type_name '.' no_attr_identifier                                      // CFA, nested type
484                { throw SemanticError( yylloc, "Qualified names are currently unimplemented." ); $$ = nullptr; } // FIX ME
485        | type_name '.' '[' push field_list pop ']'                     // CFA, nested type / tuple field selector
486                { throw SemanticError( yylloc, "Qualified names are currently unimplemented." ); $$ = nullptr; } // FIX ME
487        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
488                { throw SemanticError( yylloc, "_Generic is currently unimplemented." ); $$ = nullptr; } // FIX ME
489        ;
490
491generic_assoc_list:                                                                             // C11
492        | generic_association
493        | generic_assoc_list ',' generic_association
494        ;
495
496generic_association:                                                                    // C11
497        type_no_function ':' assignment_expression
498        | DEFAULT ':' assignment_expression
499        ;
500
501postfix_expression:
502        primary_expression
503        | postfix_expression '[' push assignment_expression pop ']'
504                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
505                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
506                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
507                // equivalent to the old x[i,j].
508                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $4 ) ); }
509        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
510                {
511                        Token fn;
512                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
513                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
514                }
515        | postfix_expression '(' argument_expression_list ')'
516                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
517        | postfix_expression '.' no_attr_identifier
518                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
519        | postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
520                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
521        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
522                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
523        | postfix_expression ARROW no_attr_identifier
524                {
525                        $$ = new ExpressionNode( build_pfieldSel( $1, *$3 == "0" || *$3 == "1" ? build_constantInteger( *$3 ) : build_varref( $3 ) ) );
526                }
527        | postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
528                        { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
529        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
530                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
531        | postfix_expression ICR
532                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
533        | postfix_expression DECR
534                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
535        | '(' type_no_function ')' '{' initializer_list comma_opt '}' // C99, compound-literal
536                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
537        | '^' primary_expression '{' argument_expression_list '}' // CFA
538                {
539                        Token fn;
540                        fn.str = new string( "^?{}" );                          // location undefined
541                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
542                }
543        ;
544
545argument_expression_list:
546        argument_expression
547        | argument_expression_list ',' argument_expression
548                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
549        ;
550
551argument_expression:
552        // empty
553                { $$ = nullptr; }
554        // | '@'                                                                                                // use default argument
555        //      { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
556        | assignment_expression
557        ;
558
559field_list:                                                                                             // CFA, tuple field selector
560        field
561        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
562        ;
563
564field:                                                                                                  // CFA, tuple field selector
565        field_name
566        | FLOATING_DECIMALconstant field
567                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
568        | FLOATING_DECIMALconstant '[' push field_list pop ']'
569                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $4 ) ) ); }
570        | field_name '.' field
571                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
572        | field_name '.' '[' push field_list pop ']'
573                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
574        | field_name ARROW field
575                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
576        | field_name ARROW '[' push field_list pop ']'
577                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
578        ;
579
580field_name:
581        INTEGERconstant fraction_constants
582                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
583        | FLOATINGconstant fraction_constants
584                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
585        | no_attr_identifier fraction_constants
586                {
587                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
588                }
589        ;
590
591fraction_constants:
592        // empty
593                { $$ = nullptr; }
594        | fraction_constants FLOATING_FRACTIONconstant
595                {
596                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
597                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
598                }
599        ;
600
601unary_expression:
602        postfix_expression
603                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
604                // semantics checks, e.g., ++3, 3--, *3, &&3
605        | constant
606                { $$ = $1; }
607        | string_literal
608                { $$ = new ExpressionNode( $1 ); }
609        | EXTENSION cast_expression                                                     // GCC
610                { $$ = $2->set_extension( true ); }
611                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
612                //              { * X; }         // dereference X
613                //              { * int X; } // CFA declaration of pointer to int
614        | ptrref_operator cast_expression                                       // CFA
615                {
616                        switch ( $1 ) {
617                          case OperKinds::AddressOf:
618                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
619                                break;
620                          case OperKinds::PointTo:
621                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
622                                break;
623                          case OperKinds::And:
624                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
625                                break;
626                          default:
627                                assert( false );
628                        }
629                }
630        | unary_operator cast_expression
631                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
632        | ICR unary_expression
633                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
634        | DECR unary_expression
635                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
636        | SIZEOF unary_expression
637                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
638        | SIZEOF '(' type_no_function ')'
639                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
640        | ALIGNOF unary_expression                                                      // GCC, variable alignment
641                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
642        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
643                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
644        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
645                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
646        | ATTR_IDENTIFIER
647                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
648        | ATTR_IDENTIFIER '(' argument_expression ')'
649                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
650        | ATTR_IDENTIFIER '(' type ')'
651                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
652        ;
653
654ptrref_operator:
655        '*'                                                                                     { $$ = OperKinds::PointTo; }
656        | '&'                                                                           { $$ = OperKinds::AddressOf; }
657                // GCC, address of label must be handled by semantic check for ref,ref,label
658        | ANDAND                                                                        { $$ = OperKinds::And; }
659        ;
660
661unary_operator:
662        '+'                                                                                     { $$ = OperKinds::UnPlus; }
663        | '-'                                                                           { $$ = OperKinds::UnMinus; }
664        | '!'                                                                           { $$ = OperKinds::Neg; }
665        | '~'                                                                           { $$ = OperKinds::BitNeg; }
666        ;
667
668cast_expression:
669        unary_expression
670        | '(' type_no_function ')' cast_expression
671                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
672                // VIRTUAL cannot be opt because of look ahead issues
673        | '(' VIRTUAL ')' cast_expression
674                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
675        | '(' VIRTUAL type_no_function ')' cast_expression
676                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
677//      | '(' type_no_function ')' tuple
678//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
679        ;
680
681exponential_expression:
682        cast_expression
683        | exponential_expression '\\' cast_expression
684                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
685        ;
686
687multiplicative_expression:
688        exponential_expression
689        | multiplicative_expression '*' exponential_expression
690                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
691        | multiplicative_expression '/' exponential_expression
692                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
693        | multiplicative_expression '%' exponential_expression
694                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
695        ;
696
697additive_expression:
698        multiplicative_expression
699        | additive_expression '+' multiplicative_expression
700                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
701        | additive_expression '-' multiplicative_expression
702                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
703        ;
704
705shift_expression:
706        additive_expression
707        | shift_expression LS additive_expression
708                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
709        | shift_expression RS additive_expression
710                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
711        ;
712
713relational_expression:
714        shift_expression
715        | relational_expression '<' shift_expression
716                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
717        | relational_expression '>' shift_expression
718                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
719        | relational_expression LE shift_expression
720                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
721        | relational_expression GE shift_expression
722                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
723        ;
724
725equality_expression:
726        relational_expression
727        | equality_expression EQ relational_expression
728                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
729        | equality_expression NE relational_expression
730                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
731        ;
732
733AND_expression:
734        equality_expression
735        | AND_expression '&' equality_expression
736                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
737        ;
738
739exclusive_OR_expression:
740        AND_expression
741        | exclusive_OR_expression '^' AND_expression
742                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
743        ;
744
745inclusive_OR_expression:
746        exclusive_OR_expression
747        | inclusive_OR_expression '|' exclusive_OR_expression
748                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
749        ;
750
751logical_AND_expression:
752        inclusive_OR_expression
753        | logical_AND_expression ANDAND inclusive_OR_expression
754                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
755        ;
756
757logical_OR_expression:
758        logical_AND_expression
759        | logical_OR_expression OROR logical_AND_expression
760                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
761        ;
762
763conditional_expression:
764        logical_OR_expression
765        | logical_OR_expression '?' comma_expression ':' conditional_expression
766                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
767                // FIX ME: this hack computes $1 twice
768        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
769                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
770        ;
771
772constant_expression:
773        conditional_expression
774        ;
775
776assignment_expression:
777                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
778        conditional_expression
779        | unary_expression assignment_operator assignment_expression
780                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
781        | unary_expression '=' '{' initializer_list comma_opt '}'
782                { throw SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; } // FIX ME
783        ;
784
785assignment_expression_opt:
786        // empty
787                { $$ = nullptr; }
788        | assignment_expression
789        ;
790
791assignment_operator:
792        '='                                                                                     { $$ = OperKinds::Assign; }
793        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
794        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
795        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
796        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
797        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
798        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
799        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
800        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
801        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
802        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
803        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
804        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
805        ;
806
807tuple:                                                                                                  // CFA, tuple
808                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
809                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
810//      '[' ']'
811//              { $$ = new ExpressionNode( build_tuple() ); }
812//      '[' push assignment_expression pop ']'
813//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
814        '[' push ',' tuple_expression_list pop ']'
815                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
816        | '[' push assignment_expression ',' tuple_expression_list pop ']'
817                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
818        ;
819
820tuple_expression_list:
821        assignment_expression_opt
822        | tuple_expression_list ',' assignment_expression_opt
823                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
824        ;
825
826comma_expression:
827        assignment_expression
828        | comma_expression ',' assignment_expression
829                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
830        ;
831
832comma_expression_opt:
833        // empty
834                { $$ = nullptr; }
835        | comma_expression
836        ;
837
838//*************************** STATEMENTS *******************************
839
840statement:
841        labeled_statement
842        | compound_statement
843        | expression_statement                                          { $$ = $1; }
844        | selection_statement
845        | iteration_statement
846        | jump_statement
847        | with_statement
848        | mutex_statement
849        | waitfor_statement
850        | exception_statement
851        | enable_disable_statement
852                { throw SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; } // FIX ME
853        | asm_statement
854        ;
855
856labeled_statement:
857                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
858        identifier_or_type_name ':' attribute_list_opt statement
859                {
860                        $$ = $4->add_label( $1, $3 );
861                }
862        ;
863
864compound_statement:
865        '{' '}'
866                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
867        | '{'
868                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
869                // requires its own scope.
870          push push
871          local_label_declaration_opt                                           // GCC, local labels
872          statement_decl_list                                                           // C99, intermix declarations and statements
873          pop '}'
874                { $$ = new StatementNode( build_compound( $5 ) ); }
875        ;
876
877statement_decl_list:                                                                    // C99
878        statement_decl
879        | statement_decl_list push statement_decl
880                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
881        ;
882
883statement_decl:
884        declaration                                                                                     // CFA, new & old style declarations
885                { $$ = new StatementNode( $1 ); }
886        | EXTENSION declaration                                                         // GCC
887                {
888                        distExt( $2 );
889                        $$ = new StatementNode( $2 );
890                }
891        | function_definition
892                { $$ = new StatementNode( $1 ); }
893        | EXTENSION function_definition                                         // GCC
894                {
895                        distExt( $2 );
896                        $$ = new StatementNode( $2 );
897                }
898        | statement pop
899        ;
900
901statement_list_nodecl:
902        statement
903        | statement_list_nodecl statement
904                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
905        ;
906
907expression_statement:
908        comma_expression_opt ';'
909                { $$ = new StatementNode( build_expr( $1 ) ); }
910        ;
911
912selection_statement:
913        IF '(' push if_control_expression ')' statement         %prec THEN
914                // explicitly deal with the shift/reduce conflict on if/else
915                { $$ = new StatementNode( build_if( $4, $6, nullptr ) ); }
916        | IF '(' push if_control_expression ')' statement ELSE statement
917                { $$ = new StatementNode( build_if( $4, $6, $8 ) ); }
918        | SWITCH '(' comma_expression ')' case_clause
919                { $$ = new StatementNode( build_switch( $3, $5 ) ); }
920        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
921                {
922                        StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
923                        // The semantics of the declaration list is changed to include associated initialization, which is performed
924                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
925                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
926                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
927                        // statement.
928                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
929                }
930        | CHOOSE '(' comma_expression ')' case_clause           // CFA
931                { $$ = new StatementNode( build_switch( $3, $5 ) ); }
932        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt choose_clause_list_opt '}' // CFA
933                {
934                        StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
935                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
936                }
937        ;
938
939if_control_expression:
940        comma_expression pop
941                { $$ = new IfCtl( nullptr, $1 ); }
942        | c_declaration pop                                                                     // no semi-colon
943                { $$ = new IfCtl( $1, nullptr ); }
944        | cfa_declaration pop                                                           // no semi-colon
945                { $$ = new IfCtl( $1, nullptr ); }
946        | declaration comma_expression                                          // semi-colon separated
947                { $$ = new IfCtl( $1, $2 ); }
948        ;
949
950// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
951// clause allows a list of values and subranges.
952
953case_value:                                                                                             // CFA
954        constant_expression                                                     { $$ = $1; }
955        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
956                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
957        | subrange                                                                                      // CFA, subrange
958        ;
959
960case_value_list:                                                                                // CFA
961        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
962                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
963        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
964        ;
965
966case_label:                                                                                             // CFA
967        CASE case_value_list ':'                                        { $$ = $2; }
968        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
969                // A semantic check is required to ensure only one default clause per switch/choose statement.
970        ;
971
972case_label_list:                                                                                // CFA
973        case_label
974        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
975        ;
976
977case_clause:                                                                                    // CFA
978        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
979        ;
980
981switch_clause_list_opt:                                                                 // CFA
982        // empty
983                { $$ = nullptr; }
984        | switch_clause_list
985        ;
986
987switch_clause_list:                                                                             // CFA
988        case_label_list statement_list_nodecl
989                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
990        | switch_clause_list case_label_list statement_list_nodecl
991                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
992        ;
993
994choose_clause_list_opt:                                                                 // CFA
995        // empty
996                { $$ = nullptr; }
997        | choose_clause_list
998        ;
999
1000choose_clause_list:                                                                             // CFA
1001        case_label_list fall_through
1002                { $$ = $1->append_last_case( $2 ); }
1003        | case_label_list statement_list_nodecl fall_through_opt
1004                { $$ = $1->append_last_case( new StatementNode( build_compound( (StatementNode *)$2->set_last( $3 ) ) ) ); }
1005        | choose_clause_list case_label_list fall_through
1006                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( $3 ))); }
1007        | choose_clause_list case_label_list statement_list_nodecl fall_through_opt
1008                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( (StatementNode *)$3->set_last( $4 ) ) ) ) ) ); }
1009        ;
1010
1011fall_through_opt:                                                                               // CFA
1012        // empty
1013                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); } // insert implicit break
1014        | fall_through
1015        ;
1016
1017fall_through_name:                                                                              // CFA
1018        FALLTHRU
1019        | FALLTHROUGH
1020        ;
1021
1022fall_through:                                                                                   // CFA
1023        fall_through_name
1024                { $$ = nullptr; }
1025        | fall_through_name ';'
1026                { $$ = nullptr; }
1027        ;
1028
1029iteration_statement:
1030        WHILE '(' comma_expression ')' statement
1031                { $$ = new StatementNode( build_while( $3, $5 ) ); }
1032        | DO statement WHILE '(' comma_expression ')' ';'
1033                { $$ = new StatementNode( build_while( $5, $2, true ) ); }
1034        | FOR '(' push for_control_expression ')' statement
1035                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1036        ;
1037
1038for_control_expression:
1039        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
1040                { $$ = new ForCtl( $1, $4, $6 ); }
1041        | declaration comma_expression_opt ';' comma_expression_opt // C99
1042                { $$ = new ForCtl( $1, $2, $4 ); }
1043        ;
1044
1045jump_statement:
1046        GOTO identifier_or_type_name ';'
1047                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1048        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1049                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1050                // whereas normal operator precedence yields goto (*i)+3;
1051                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1052        | CONTINUE ';'
1053                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1054                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1055        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1056                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1057                // the target of the transfer appears only at the start of an iteration statement.
1058                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1059        | BREAK ';'
1060                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1061                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1062        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1063                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1064                // the target of the transfer appears only at the start of an iteration statement.
1065                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1066        | RETURN comma_expression_opt ';'
1067                { $$ = new StatementNode( build_return( $2 ) ); }
1068        | RETURN '{' initializer_list comma_opt '}'
1069                { throw SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; } // FIX ME
1070        | THROW assignment_expression_opt ';'                           // handles rethrow
1071                { $$ = new StatementNode( build_throw( $2 ) ); }
1072        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1073                { $$ = new StatementNode( build_resume( $2 ) ); }
1074        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1075                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1076        ;
1077
1078with_statement:
1079        WITH '(' tuple_expression_list ')' statement
1080                {
1081                        $$ = new StatementNode( build_with( $3, $5 ) );
1082                }
1083        ;
1084
1085// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1086mutex_statement:
1087        MUTEX '(' argument_expression_list ')' statement
1088                { throw SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; } // FIX ME
1089        ;
1090
1091when_clause:
1092        WHEN '(' comma_expression ')'
1093                { $$ = $3; }
1094        ;
1095
1096when_clause_opt:
1097        // empty
1098                { $$ = nullptr; }
1099        | when_clause
1100        ;
1101
1102waitfor:
1103        WAITFOR '(' identifier ')'
1104                {
1105                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1106                        delete $3;
1107                }
1108        | WAITFOR '(' identifier ',' argument_expression_list ')'
1109                {
1110                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1111                        $$->set_last( $5 );
1112                        delete $3;
1113                }
1114        ;
1115
1116timeout:
1117        TIMEOUT '(' comma_expression ')'
1118                { $$ = $3; }
1119        ;
1120
1121waitfor_clause:
1122        when_clause_opt waitfor statement                                       %prec THEN
1123                { $$ = build_waitfor( $2, $3, $1 ); }
1124        | when_clause_opt waitfor statement WOR waitfor_clause
1125                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1126        | when_clause_opt timeout statement                                     %prec THEN
1127                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1128        | when_clause_opt ELSE statement
1129                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1130                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1131        | when_clause_opt timeout statement WOR when_clause ELSE statement
1132                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1133        ;
1134
1135waitfor_statement:
1136        when_clause_opt waitfor statement                                       %prec THEN
1137                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1138        | when_clause_opt waitfor statement WOR waitfor_clause
1139                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1140        ;
1141
1142exception_statement:
1143        TRY compound_statement handler_clause
1144                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1145        | TRY compound_statement finally_clause
1146                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1147        | TRY compound_statement handler_clause finally_clause
1148                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1149        ;
1150
1151handler_clause:
1152        handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1153                { $$ = new StatementNode( build_catch( $1, $5, $7, $9 ) ); }
1154        | handler_clause handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1155                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $6, $8, $10 ) ) ); }
1156        ;
1157
1158handler_predicate_opt:
1159        //empty
1160                { $$ = nullptr; }
1161        | ';' conditional_expression
1162                { $$ = $2; }
1163        ;
1164
1165handler_key:
1166        CATCH
1167                { $$ = CatchStmt::Terminate; }
1168        | CATCHRESUME
1169                { $$ = CatchStmt::Resume; }
1170        ;
1171
1172finally_clause:
1173        FINALLY compound_statement
1174                {
1175                        $$ = new StatementNode( build_finally( $2 ) );
1176                }
1177        ;
1178
1179exception_declaration:
1180                // No SUE declaration in parameter list.
1181        type_specifier_nobody
1182        | type_specifier_nobody declarator
1183                {
1184                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1185                        $$ = $2->addType( $1 );
1186                }
1187        | type_specifier_nobody variable_abstract_declarator
1188                { $$ = $2->addType( $1 ); }
1189        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1190                {
1191                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1192                        $$ = $1->addName( $2 );
1193                }
1194        | cfa_abstract_declarator_tuple                                         // CFA
1195        ;
1196
1197enable_disable_statement:
1198        enable_disable_key identifier_list compound_statement
1199        ;
1200
1201enable_disable_key:
1202        ENABLE
1203        | DISABLE
1204        ;
1205
1206asm_statement:
1207        ASM asm_volatile_opt '(' string_literal ')' ';'
1208                { $$ = new StatementNode( build_asmstmt( $2, $4, 0 ) ); }
1209        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1210                { $$ = new StatementNode( build_asmstmt( $2, $4, $6 ) ); }
1211        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1212                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8 ) ); }
1213        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1214                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8, $10 ) ); }
1215        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1216                { $$ = new StatementNode( build_asmstmt( $2, $5, 0, $8, $10, $12 ) ); }
1217        ;
1218
1219asm_volatile_opt:                                                                               // GCC
1220        // empty
1221                { $$ = false; }
1222        | VOLATILE
1223                { $$ = true; }
1224        ;
1225
1226asm_operands_opt:                                                                               // GCC
1227        // empty
1228                { $$ = nullptr; }                                                               // use default argument
1229        | asm_operands_list
1230        ;
1231
1232asm_operands_list:                                                                              // GCC
1233        asm_operand
1234        | asm_operands_list ',' asm_operand
1235                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1236        ;
1237
1238asm_operand:                                                                                    // GCC
1239        string_literal '(' constant_expression ')'
1240                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1241        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1242                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1243        ;
1244
1245asm_clobbers_list_opt:                                                                  // GCC
1246        // empty
1247                { $$ = nullptr; }                                                               // use default argument
1248        | string_literal
1249                { $$ = new ExpressionNode( $1 ); }
1250        | asm_clobbers_list_opt ',' string_literal
1251                // set_last returns ParseNode *
1252                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1253        ;
1254
1255label_list:
1256        no_attr_identifier
1257                {
1258                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1259                        delete $1;                                                                      // allocated by lexer
1260                }
1261        | label_list ',' no_attr_identifier
1262                {
1263                        $$ = $1; $1->labels.push_back( *$3 );
1264                        delete $3;                                                                      // allocated by lexer
1265                }
1266        ;
1267
1268//******************************* DECLARATIONS *********************************
1269
1270declaration_list_opt:                                                                   // used at beginning of switch statement
1271        pop
1272                { $$ = nullptr; }
1273        | declaration_list
1274        ;
1275
1276declaration_list:
1277        declaration
1278        | declaration_list push declaration
1279                { $$ = $1->appendList( $3 ); }
1280        ;
1281
1282KR_declaration_list_opt:                                                                // used to declare parameter types in K&R style functions
1283        // empty
1284                { $$ = nullptr; }
1285        | KR_declaration_list
1286        ;
1287
1288KR_declaration_list:
1289        push c_declaration pop ';'
1290                { $$ = $2; }
1291        | KR_declaration_list push c_declaration pop ';'
1292                { $$ = $1->appendList( $3 ); }
1293        ;
1294
1295local_label_declaration_opt:                                                    // GCC, local label
1296        // empty
1297        | local_label_declaration_list
1298        ;
1299
1300local_label_declaration_list:                                                   // GCC, local label
1301        LABEL local_label_list ';'
1302        | local_label_declaration_list LABEL local_label_list ';'
1303        ;
1304
1305local_label_list:                                                                               // GCC, local label
1306        no_attr_identifier_or_type_name                         {}
1307        | local_label_list ',' no_attr_identifier_or_type_name {}
1308        ;
1309
1310declaration:                                                                                    // old & new style declarations
1311        c_declaration pop ';'
1312        | cfa_declaration pop ';'                                                       // CFA
1313        | static_assert
1314        ;
1315
1316static_assert:
1317        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1318                { throw SemanticError( yylloc, "Static assert is currently unimplemented." ); $$ = nullptr; }   // FIX ME
1319
1320// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1321// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1322// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1323// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1324// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1325// block, but cannot be mixed within a specific declaration.
1326//
1327//                      CFA                                     C
1328//              [10] int x;                     int x[10];              // array of 10 integers
1329//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1330
1331cfa_declaration:                                                                                // CFA
1332        cfa_variable_declaration
1333        | cfa_typedef_declaration
1334        | cfa_function_declaration
1335        | type_declaring_list
1336        | trait_specifier
1337        ;
1338
1339cfa_variable_declaration:                                                               // CFA
1340        cfa_variable_specifier initializer_opt
1341                {
1342                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1343                        $$ = $1->addInitializer( $2 );
1344                }
1345        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1346                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1347                // them as a type_qualifier cannot appear in that context.
1348                {
1349                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1350                        $$ = $2->addQualifiers( $1 )->addInitializer( $3 );;
1351                }
1352        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1353                {
1354                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1355                        $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) );
1356                }
1357        ;
1358
1359cfa_variable_specifier:                                                                 // CFA
1360                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1361                // storage-class
1362        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1363                {
1364                        typedefTable.setNextIdentifier( *$2 );
1365                        $$ = $1->addName( $2 )->addAsmName( $3 );
1366                }
1367        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1368                {
1369                        typedefTable.setNextIdentifier( *$2 );
1370                        $$ = $1->addName( $2 )->addAsmName( $3 );
1371                }
1372        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1373                {
1374                        typedefTable.setNextIdentifier( *$3 );
1375                        $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 );
1376                }
1377        ;
1378
1379cfa_function_declaration:                                                               // CFA
1380        cfa_function_specifier
1381                {
1382                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1383                        $$ = $1;
1384                }
1385        | type_qualifier_list cfa_function_specifier
1386                {
1387                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1388                        $$ = $2->addQualifiers( $1 );
1389                }
1390        | declaration_qualifier_list cfa_function_specifier
1391                {
1392                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1393                        $$ = $2->addQualifiers( $1 );
1394                }
1395        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1396                {
1397                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1398                        $$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1399                }
1400        | cfa_function_declaration pop ',' push identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1401                {
1402                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1403                        DeclarationNode * ret = new DeclarationNode;
1404                        ret->type = maybeClone( $1->type->base );
1405                        $$ = $1->appendList( DeclarationNode::newFunction( $5, ret, $8, nullptr ) );
1406                }
1407        ;
1408
1409cfa_function_specifier:                                                                 // CFA
1410//      '[' ']' identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')' // S/R conflict
1411//              {
1412//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1413//              }
1414//      '[' ']' identifier '(' push cfa_parameter_type_list_opt pop ')'
1415//              {
1416//                      typedefTable.setNextIdentifier( *$5 );
1417//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1418//              }
1419//      | '[' ']' TYPEDEFname '(' push cfa_parameter_type_list_opt pop ')'
1420//              {
1421//                      typedefTable.setNextIdentifier( *$5 );
1422//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1423//              }
1424//      | '[' ']' typegen_name
1425                // identifier_or_type_name must be broken apart because of the sequence:
1426                //
1427                //   '[' ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
1428                //   '[' ']' type_specifier
1429                //
1430                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1431                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1432        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1433                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1434                {
1435                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0 );
1436                }
1437        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1438                {
1439                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0 );
1440                }
1441        ;
1442
1443cfa_function_return:                                                                    // CFA
1444        '[' push cfa_parameter_list pop ']'
1445                { $$ = DeclarationNode::newTuple( $3 ); }
1446        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1447                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the
1448                // ']'.
1449                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1450        ;
1451
1452cfa_typedef_declaration:                                                                // CFA
1453        TYPEDEF cfa_variable_specifier
1454                {
1455                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1456                        $$ = $2->addTypedef();
1457                }
1458        | TYPEDEF cfa_function_specifier
1459                {
1460                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1461                        $$ = $2->addTypedef();
1462                }
1463        | cfa_typedef_declaration pop ',' push no_attr_identifier
1464                {
1465                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1466                        $$ = $1->appendList( $1->cloneType( $5 ) );
1467                }
1468        ;
1469
1470// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1471// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1472
1473typedef_declaration:
1474        TYPEDEF type_specifier declarator
1475                {
1476                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1477                        $$ = $3->addType( $2 )->addTypedef();
1478                }
1479        | typedef_declaration pop ',' push declarator
1480                {
1481                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1482                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1483                }
1484        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1485                {
1486                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1487                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1488                }
1489        | type_specifier TYPEDEF declarator
1490                {
1491                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1492                        $$ = $3->addType( $1 )->addTypedef();
1493                }
1494        | type_specifier TYPEDEF type_qualifier_list declarator
1495                {
1496                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1497                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1498                }
1499        ;
1500
1501typedef_expression:
1502                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1503        TYPEDEF no_attr_identifier '=' assignment_expression
1504                {
1505                        typedefTable.addToEnclosingScope( *$2, TypedefTable::TD );
1506                        $$ = DeclarationNode::newName( 0 );                     // unimplemented
1507                }
1508        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1509                {
1510                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1511                        $$ = DeclarationNode::newName( 0 );                     // unimplemented
1512                }
1513        ;
1514
1515//c_declaration:
1516//      declaring_list pop ';'
1517//      | typedef_declaration pop ';'
1518//      | typedef_expression pop ';'                                            // GCC, naming expression type
1519//      | sue_declaration_specifier pop ';'
1520//      ;
1521//
1522//declaring_list:
1523//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1524//              // storage-class
1525//       declarator asm_name_opt initializer_opt
1526//              {
1527//                      typedefTable.addToEnclosingScope( TypedefTable::ID );
1528//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1529//              }
1530//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1531//              {
1532//                      typedefTable.addToEnclosingScope( TypedefTable::ID );
1533//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1534//              }
1535//      ;
1536
1537c_declaration:
1538        declaration_specifier declaring_list
1539                {
1540                        $$ = distAttr( $1, $2 );
1541                }
1542        | typedef_declaration
1543        | typedef_expression                                                            // GCC, naming expression type
1544        | sue_declaration_specifier
1545        ;
1546
1547declaring_list:
1548                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1549                // storage-class
1550        declarator asm_name_opt initializer_opt
1551                {
1552                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1553                        $$ = $1->addAsmName( $2 )->addInitializer( $3 );
1554                }
1555        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1556                {
1557                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1558                        $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) );
1559                }
1560        ;
1561
1562declaration_specifier:                                                                  // type specifier + storage class
1563        basic_declaration_specifier
1564        | sue_declaration_specifier
1565        | type_declaration_specifier
1566        ;
1567
1568declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1569                // Preclude SUE declarations in restricted scopes:
1570                //
1571                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1572                //
1573                // because it is impossible to call f due to name equivalence.
1574        basic_declaration_specifier
1575        | sue_declaration_specifier_nobody
1576        | type_declaration_specifier
1577        ;
1578
1579type_specifier:                                                                                 // type specifier
1580        basic_type_specifier
1581        | sue_type_specifier
1582        | type_type_specifier
1583        ;
1584
1585type_specifier_nobody:                                                                  // type specifier - {...}
1586                // Preclude SUE declarations in restricted scopes:
1587                //
1588                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1589                //
1590                // because it is impossible to call f due to name equivalence.
1591        basic_type_specifier
1592        | sue_type_specifier_nobody
1593        | type_type_specifier
1594        ;
1595
1596type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1597        // empty
1598                { $$ = nullptr; }
1599        | type_qualifier_list
1600        ;
1601
1602type_qualifier_list:
1603                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1604                //
1605                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1606                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1607                // appeared only once.
1608        type_qualifier
1609        | type_qualifier_list type_qualifier
1610                { $$ = $1->addQualifiers( $2 ); }
1611        ;
1612
1613type_qualifier:
1614        type_qualifier_name
1615        | attribute
1616        ;
1617
1618type_qualifier_name:
1619        CONST
1620                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1621        | RESTRICT
1622                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1623        | VOLATILE
1624                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1625        | ATOMIC
1626                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1627        | forall
1628        ;
1629
1630forall:
1631        FORALL '('
1632                {
1633                        typedefTable.enterScope();
1634                }
1635          type_parameter_list ')'                                                       // CFA
1636                {
1637                        typedefTable.leaveScope();
1638                        $$ = DeclarationNode::newForall( $4 );
1639                }
1640        ;
1641
1642declaration_qualifier_list:
1643        storage_class_list
1644        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1645                { $$ = $1->addQualifiers( $2 ); }
1646        | declaration_qualifier_list type_qualifier_list storage_class_list
1647                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1648        ;
1649
1650storage_class_list:
1651                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1652                // only one of each is specified, except for inline, which can appear with the others.
1653                //
1654                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1655                // specifiers in a declaration.
1656        storage_class
1657        | storage_class_list storage_class
1658                { $$ = $1->addQualifiers( $2 ); }
1659        ;
1660
1661storage_class:
1662        EXTERN
1663                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1664        | STATIC
1665                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1666        | AUTO
1667                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1668        | REGISTER
1669                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1670        | THREADLOCAL                                                                           // C11
1671                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1672                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1673        | INLINE                                                                                        // C99
1674                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1675        | FORTRAN                                                                                       // C99
1676                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1677        | NORETURN                                                                                      // C11
1678                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1679        ;
1680
1681basic_type_name:
1682        VOID
1683                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1684        | BOOL                                                                                          // C99
1685                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1686        | CHAR
1687                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1688        | INT
1689                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1690        | INT128
1691                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1692        | FLOAT
1693                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1694        | FLOAT80
1695                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float80 ); }
1696        | FLOAT128
1697                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float128 ); }
1698        | DOUBLE
1699                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1700        | COMPLEX                                                                                       // C99
1701                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1702        | IMAGINARY                                                                                     // C99
1703                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1704        | SIGNED
1705                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1706        | UNSIGNED
1707                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1708        | SHORT
1709                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1710        | LONG
1711                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1712        | ZERO_T
1713                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1714        | ONE_T
1715                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1716        | VALIST                                                                                        // GCC, __builtin_va_list
1717                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1718        ;
1719
1720basic_declaration_specifier:
1721                // A semantic check is necessary for conflicting storage classes.
1722        basic_type_specifier
1723        | declaration_qualifier_list basic_type_specifier
1724                { $$ = $2->addQualifiers( $1 ); }
1725        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1726                { $$ = $1->addQualifiers( $2 ); }
1727        | basic_declaration_specifier storage_class type_qualifier_list
1728                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1729        | basic_declaration_specifier storage_class basic_type_specifier
1730                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1731        ;
1732
1733basic_type_specifier:
1734        direct_type
1735        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1736                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1737        ;
1738
1739direct_type:
1740                // A semantic check is necessary for conflicting type qualifiers.
1741        basic_type_name
1742        | type_qualifier_list basic_type_name
1743                { $$ = $2->addQualifiers( $1 ); }
1744        | direct_type type_qualifier
1745                { $$ = $1->addQualifiers( $2 ); }
1746        | direct_type basic_type_name
1747                { $$ = $1->addType( $2 ); }
1748        ;
1749
1750indirect_type:
1751        TYPEOF '(' type ')'                                                                     // GCC: typeof(x) y;
1752                { $$ = $3; }
1753        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1754                { $$ = DeclarationNode::newTypeof( $3 ); }
1755        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type(x) y;
1756                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1757        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1758                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1759        ;
1760
1761sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1762        sue_type_specifier
1763        | declaration_qualifier_list sue_type_specifier
1764                { $$ = $2->addQualifiers( $1 ); }
1765        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1766                { $$ = $1->addQualifiers( $2 ); }
1767        | sue_declaration_specifier storage_class type_qualifier_list
1768                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1769        ;
1770
1771sue_type_specifier:                                                                             // struct, union, enum + type specifier
1772        elaborated_type
1773        | type_qualifier_list
1774                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1775          elaborated_type
1776                { $$ = $3->addQualifiers( $1 ); }
1777        | sue_type_specifier type_qualifier
1778                { $$ = $1->addQualifiers( $2 ); }
1779        ;
1780
1781sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1782        sue_type_specifier_nobody
1783        | declaration_qualifier_list sue_type_specifier_nobody
1784                { $$ = $2->addQualifiers( $1 ); }
1785        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1786                { $$ = $1->addQualifiers( $2 ); }
1787        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1788                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1789        ;
1790
1791sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1792        elaborated_type_nobody
1793        | type_qualifier_list elaborated_type_nobody
1794                { $$ = $2->addQualifiers( $1 ); }
1795        | sue_type_specifier_nobody type_qualifier
1796                { $$ = $1->addQualifiers( $2 ); }
1797        ;
1798
1799type_declaration_specifier:
1800        type_type_specifier
1801        | declaration_qualifier_list type_type_specifier
1802                { $$ = $2->addQualifiers( $1 ); }
1803        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1804                { $$ = $1->addQualifiers( $2 ); }
1805        | type_declaration_specifier storage_class type_qualifier_list
1806                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1807        ;
1808
1809type_type_specifier:                                                                    // typedef types
1810        type_name
1811        | type_qualifier_list type_name
1812                { $$ = $2->addQualifiers( $1 ); }
1813        | type_type_specifier type_qualifier
1814                { $$ = $1->addQualifiers( $2 ); }
1815        ;
1816
1817type_name:
1818        TYPEDEFname
1819                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1820        | '.' TYPEDEFname
1821                { $$ = DeclarationNode::newFromTypedef( $2 ); } // FIX ME
1822        | type_name '.' TYPEDEFname
1823                { $$ = DeclarationNode::newFromTypedef( $3 ); } // FIX ME
1824        | typegen_name
1825        | '.' typegen_name
1826                { $$ = $2; }                                                                    // FIX ME
1827        | type_name '.' typegen_name
1828                { $$ = $3; }                                                                    // FIX ME
1829        ;
1830
1831typegen_name:                                                                                   // CFA
1832        TYPEGENname
1833                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1834        | TYPEGENname '(' ')'
1835                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1836        | TYPEGENname '(' type_list ')'
1837                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1838        ;
1839
1840elaborated_type:                                                                                // struct, union, enum
1841        aggregate_type
1842        | enum_type
1843        ;
1844
1845elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1846        aggregate_type_nobody
1847        | enum_type_nobody
1848        ;
1849
1850aggregate_type:                                                                                 // struct, union
1851        aggregate_key attribute_list_opt '{' field_declaration_list '}'
1852                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), nullptr, $4, true )->addQualifiers( $2 ); }
1853        | aggregate_key attribute_list_opt no_attr_identifier_or_type_name
1854                {
1855                        typedefTable.makeTypedef( *$3 );                        // create typedef
1856                        if ( forall ) typedefTable.changeKind( *$3, TypedefTable::TG ); // possibly update
1857                        forall = false;                                                         // reset
1858                }
1859          '{' field_declaration_list '}'
1860                { $$ = DeclarationNode::newAggregate( $1, $3, nullptr, $6, true )->addQualifiers( $2 ); }
1861        | aggregate_key attribute_list_opt '(' type_list ')' '{' field_declaration_list '}' // CFA
1862                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), $4, $7, false )->addQualifiers( $2 ); }
1863        | aggregate_type_nobody
1864        ;
1865
1866aggregate_type_nobody:                                                                  // struct, union - {...}
1867        aggregate_key attribute_list_opt no_attr_identifier
1868                {
1869                        typedefTable.makeTypedef( *$3 );
1870                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1871                }
1872        | aggregate_key attribute_list_opt TYPEDEFname
1873                {
1874                        typedefTable.makeTypedef( *$3 );
1875                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1876                }
1877        | aggregate_key attribute_list_opt typegen_name         // CFA
1878                {
1879                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
1880                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
1881                        // delete newFromTypeGen.
1882                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
1883                        $3->type->symbolic.name = nullptr;
1884                        $3->type->symbolic.actuals = nullptr;
1885                        delete $3;
1886                }
1887        ;
1888
1889aggregate_key:
1890        STRUCT
1891                { $$ = DeclarationNode::Struct; }
1892        | UNION
1893                { $$ = DeclarationNode::Union; }
1894        | EXCEPTION
1895                { $$ = DeclarationNode::Exception; }
1896        | COROUTINE
1897                { $$ = DeclarationNode::Coroutine; }
1898        | MONITOR
1899                { $$ = DeclarationNode::Monitor; }
1900        | THREAD
1901                { $$ = DeclarationNode::Thread; }
1902        ;
1903
1904field_declaration_list:
1905        // empty
1906                { $$ = nullptr; }
1907        | field_declaration_list field_declaration
1908                { $$ = $1 ? $1->appendList( $2 ) : $2; }
1909        ;
1910
1911field_declaration:
1912        cfa_field_declaring_list ';'                                            // CFA, new style field declaration
1913        | EXTENSION cfa_field_declaring_list ';'                        // GCC
1914                {
1915                        distExt( $2 );                                                          // mark all fields in list
1916                        $$ = $2;
1917                }
1918        | type_specifier field_declaring_list ';'
1919                {
1920                        $$ = distAttr( $1, $2 ); }
1921        | EXTENSION type_specifier field_declaring_list ';'     // GCC
1922                {
1923                        distExt( $3 );                                                          // mark all fields in list
1924                        $$ = distAttr( $2, $3 );
1925                }
1926        | static_assert
1927        ;
1928
1929cfa_field_declaring_list:                                                               // CFA, new style field declaration
1930        cfa_abstract_declarator_tuple                                           // CFA, no field name
1931        | cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
1932                { $$ = $1->addName( $2 ); }
1933        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
1934                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1935        | cfa_field_declaring_list ','                                          // CFA, no field name
1936                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1937        ;
1938
1939field_declaring_list:
1940        field_declarator
1941        | field_declaring_list ',' attribute_list_opt field_declarator
1942                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
1943        ;
1944
1945field_declarator:
1946        // empty
1947                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1948        // '@'
1949        //      { $$ = DeclarationNode::newName( new string( DeclarationNode::anonymous.newName() ) ); } // CFA, no field name
1950        | bit_subrange_size                                                                     // no field name
1951                { $$ = DeclarationNode::newBitfield( $1 ); }
1952        | variable_declarator bit_subrange_size_opt
1953                // A semantic check is required to ensure bit_subrange only appears on base type int.
1954                { $$ = $1->addBitfield( $2 ); }
1955        | variable_type_redeclarator bit_subrange_size_opt
1956                // A semantic check is required to ensure bit_subrange only appears on base type int.
1957                { $$ = $1->addBitfield( $2 ); }
1958        | variable_abstract_declarator                                          // CFA, no field name
1959        ;
1960
1961bit_subrange_size_opt:
1962        // empty
1963                { $$ = nullptr; }
1964        | bit_subrange_size
1965                { $$ = $1; }
1966        ;
1967
1968bit_subrange_size:
1969        ':' constant_expression
1970                { $$ = $2; }
1971        ;
1972
1973enum_type:                                                                                              // enum
1974        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
1975                { $$ = DeclarationNode::newEnum( new string( DeclarationNode::anonymous.newName() ), $4, true )->addQualifiers( $2 ); }
1976        | ENUM attribute_list_opt no_attr_identifier_or_type_name
1977                { typedefTable.makeTypedef( *$3 ); }
1978          '{' enumerator_list comma_opt '}'
1979                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
1980        | enum_type_nobody
1981        ;
1982
1983enum_type_nobody:                                                                               // enum - {...}
1984        ENUM attribute_list_opt no_attr_identifier_or_type_name
1985                {
1986                        typedefTable.makeTypedef( *$3 );
1987                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
1988                }
1989        ;
1990
1991enumerator_list:
1992        no_attr_identifier_or_type_name enumerator_value_opt
1993                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1994        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1995                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1996        ;
1997
1998enumerator_value_opt:
1999        // empty
2000                { $$ = nullptr; }
2001        | '=' constant_expression
2002                { $$ = $2; }
2003        ;
2004
2005cfa_parameter_type_list_opt:                                                    // CFA, abstract + real
2006        // empty
2007                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2008        | ELLIPSIS
2009                { $$ = nullptr; }
2010        | cfa_abstract_parameter_list
2011        | cfa_parameter_list
2012        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2013                { $$ = $1->appendList( $5 ); }
2014        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2015                { $$ = $1->addVarArgs(); }
2016        | cfa_parameter_list pop ',' push ELLIPSIS
2017                { $$ = $1->addVarArgs(); }
2018        ;
2019
2020cfa_parameter_list:                                                                             // CFA
2021                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2022                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2023        cfa_parameter_declaration
2024        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2025                { $$ = $1->appendList( $5 ); }
2026        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2027                { $$ = $1->appendList( $5 ); }
2028        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2029                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2030        ;
2031
2032cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2033        cfa_abstract_parameter_declaration
2034        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2035                { $$ = $1->appendList( $5 ); }
2036        ;
2037
2038parameter_type_list_opt:
2039        // empty
2040                { $$ = nullptr; }
2041        | ELLIPSIS
2042                { $$ = nullptr; }
2043        | parameter_list
2044        | parameter_list pop ',' push ELLIPSIS
2045                { $$ = $1->addVarArgs(); }
2046        ;
2047
2048parameter_list:                                                                                 // abstract + real
2049        abstract_parameter_declaration
2050        | parameter_declaration
2051        | parameter_list pop ',' push abstract_parameter_declaration
2052                { $$ = $1->appendList( $5 ); }
2053        | parameter_list pop ',' push parameter_declaration
2054                { $$ = $1->appendList( $5 ); }
2055        ;
2056
2057// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2058// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2059
2060cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2061        parameter_declaration
2062        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2063                { $$ = $1->addName( $2 ); }
2064        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2065                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2066                { $$ = $1->addName( $2 ); }
2067        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2068                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2069        | cfa_function_specifier
2070        ;
2071
2072cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2073        abstract_parameter_declaration
2074        | cfa_identifier_parameter_declarator_no_tuple
2075        | cfa_abstract_tuple
2076                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2077        | type_qualifier_list cfa_abstract_tuple
2078                { $$ = $2->addQualifiers( $1 ); }
2079        | cfa_abstract_function
2080        ;
2081
2082parameter_declaration:
2083                // No SUE declaration in parameter list.
2084        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2085                {
2086                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2087                        $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr );
2088                }
2089        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2090                {
2091                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2092                        $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr );
2093                }
2094        ;
2095
2096abstract_parameter_declaration:
2097        declaration_specifier_nobody default_initialize_opt
2098                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2099        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2100                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2101        ;
2102
2103// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2104// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2105// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2106
2107identifier_list:                                                                                // K&R-style parameter list => no types
2108        no_attr_identifier
2109                { $$ = DeclarationNode::newName( $1 ); }
2110        | identifier_list ',' no_attr_identifier
2111                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2112        ;
2113
2114identifier_or_type_name:
2115        identifier
2116        | TYPEDEFname
2117        | TYPEGENname
2118        ;
2119
2120no_attr_identifier_or_type_name:
2121        no_attr_identifier
2122        | TYPEDEFname
2123        | TYPEGENname
2124        ;
2125
2126type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2127        cfa_abstract_declarator_tuple                                           // CFA
2128        | type_specifier
2129        | type_specifier abstract_declarator
2130                { $$ = $2->addType( $1 ); }
2131        ;
2132
2133type:                                                                                                   // typeof, assertion
2134        type_no_function
2135        | cfa_abstract_function                                                         // CFA
2136        ;
2137
2138initializer_opt:
2139        // empty
2140                { $$ = nullptr; }
2141        | '=' initializer
2142                { $$ = $2; }
2143        | '=' VOID
2144                { $$ = nullptr; }
2145        | ATassign initializer
2146                { $$ = $2->set_maybeConstructed( false ); }
2147        ;
2148
2149initializer:
2150        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2151        | '{' initializer_list comma_opt '}'            { $$ = new InitializerNode( $2, true ); }
2152        ;
2153
2154initializer_list:
2155        // empty
2156                { $$ = nullptr; }
2157        | initializer
2158        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2159        | initializer_list ',' initializer                      { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2160        | initializer_list ',' designation initializer
2161                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2162        ;
2163
2164// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2165// '=' to separator the designator from the initializer value, as in:
2166//
2167//              int x[10] = { [1] = 3 };
2168//
2169// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2170// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2171// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2172// shift/reduce conflicts
2173
2174designation:
2175        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2176        | no_attr_identifier ':'                                                        // GCC, field name
2177                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2178        ;
2179
2180designator_list:                                                                                // C99
2181        designator
2182        | designator_list designator
2183                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2184        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2185        ;
2186
2187designator:
2188        '.' no_attr_identifier                                                          // C99, field name
2189                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2190        | '[' push assignment_expression pop ']'                        // C99, single array element
2191                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2192                { $$ = $3; }
2193        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2194                { $$ = $3; }
2195        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2196                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2197        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
2198                { $$ = $4; }
2199        ;
2200
2201// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2202// rather than an object-oriented type system. This required four groups of extensions:
2203//
2204// Overloading: function, data, and operator identifiers may be overloaded.
2205//
2206// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2207//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2208//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2209//
2210// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2211//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2212//
2213// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2214//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2215//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2216//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2217//     on type arguments of polymorphic functions.
2218
2219type_parameter_list:                                                                    // CFA
2220        type_parameter
2221                { $$ = $1; }
2222        | type_parameter_list ',' type_parameter
2223                { $$ = $1->appendList( $3 ); }
2224        ;
2225
2226type_initializer_opt:                                                                   // CFA
2227        // empty
2228                { $$ = nullptr; }
2229        | '=' type
2230                { $$ = $2; }
2231        ;
2232
2233type_parameter:                                                                                 // CFA
2234        type_class no_attr_identifier_or_type_name
2235                { typedefTable.addToEnclosingScope( *$2, TypedefTable::TD ); }
2236          type_initializer_opt assertion_list_opt
2237                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2238        | type_specifier identifier_parameter_declarator
2239        ;
2240
2241type_class:                                                                                             // CFA
2242        OTYPE
2243                { $$ = DeclarationNode::Otype; }
2244        | DTYPE
2245                { $$ = DeclarationNode::Dtype; }
2246        | FTYPE
2247                { $$ = DeclarationNode::Ftype; }
2248        | TTYPE
2249                { $$ = DeclarationNode::Ttype; }
2250        ;
2251
2252assertion_list_opt:                                                                             // CFA
2253        // empty
2254                { $$ = nullptr; }
2255        | assertion_list_opt assertion
2256                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2257        ;
2258
2259assertion:                                                                                              // CFA
2260        '|' no_attr_identifier_or_type_name '(' type_list ')'
2261                {
2262                        typedefTable.openTrait( *$2 );
2263                        $$ = DeclarationNode::newTraitUse( $2, $4 );
2264                }
2265        | '|' '{' push trait_declaration_list '}'
2266                { $$ = $4; }
2267        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_list ')'
2268                { $$ = nullptr; }
2269        ;
2270
2271type_list:                                                                                              // CFA
2272        type
2273                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2274        | assignment_expression
2275        | type_list ',' type
2276                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2277        | type_list ',' assignment_expression
2278                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2279        ;
2280
2281type_declaring_list:                                                                    // CFA
2282        OTYPE type_declarator
2283                { $$ = $2; }
2284        | storage_class_list OTYPE type_declarator
2285                { $$ = $3->addQualifiers( $1 ); }
2286        | type_declaring_list ',' type_declarator
2287                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2288        ;
2289
2290type_declarator:                                                                                // CFA
2291        type_declarator_name assertion_list_opt
2292                { $$ = $1->addAssertions( $2 ); }
2293        | type_declarator_name assertion_list_opt '=' type
2294                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2295        ;
2296
2297type_declarator_name:                                                                   // CFA
2298        no_attr_identifier_or_type_name
2299                {
2300                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TD );
2301                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2302                }
2303        | no_attr_identifier_or_type_name '(' push type_parameter_list pop ')'
2304                {
2305                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TG );
2306                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
2307                }
2308        ;
2309
2310trait_specifier:                                                                                // CFA
2311        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
2312                {
2313                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
2314                        $$ = DeclarationNode::newTrait( $2, $5, 0 );
2315                }
2316        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
2317                {
2318                        typedefTable.enterTrait( *$2 );
2319                        typedefTable.enterScope();
2320                }
2321          trait_declaration_list '}'
2322                {
2323                        typedefTable.leaveTrait();
2324                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
2325                        $$ = DeclarationNode::newTrait( $2, $5, $10 );
2326                }
2327        ;
2328
2329trait_declaration_list:                                                                 // CFA
2330        trait_declaration
2331        | trait_declaration_list push trait_declaration
2332                { $$ = $1->appendList( $3 ); }
2333        ;
2334
2335trait_declaration:                                                                              // CFA
2336        cfa_trait_declaring_list pop ';'
2337        | trait_declaring_list pop ';'
2338        ;
2339
2340cfa_trait_declaring_list:                                                               // CFA
2341        cfa_variable_specifier
2342                {
2343                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2344                        $$ = $1;
2345                }
2346        | cfa_function_specifier
2347                {
2348                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2349                        $$ = $1;
2350                }
2351        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2352                {
2353                        typedefTable.addToEnclosingScope2( *$5, TypedefTable::ID );
2354                        $$ = $1->appendList( $1->cloneType( $5 ) );
2355                }
2356        ;
2357
2358trait_declaring_list:                                                                   // CFA
2359        type_specifier declarator
2360                {
2361                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2362                        $$ = $2->addType( $1 );
2363                }
2364        | trait_declaring_list pop ',' push declarator
2365                {
2366                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2367                        $$ = $1->appendList( $1->cloneBaseType( $5 ) );
2368                }
2369        ;
2370
2371//***************************** EXTERNAL DEFINITIONS *****************************
2372
2373translation_unit:
2374        // empty
2375                {}                                                                                              // empty input file
2376        | external_definition_list
2377                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2378        ;
2379
2380external_definition_list:
2381        external_definition
2382        | external_definition_list push external_definition
2383                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2384        ;
2385
2386external_definition_list_opt:
2387        // empty
2388                { $$ = nullptr; }
2389        | external_definition_list
2390        ;
2391
2392external_definition:
2393        declaration
2394        | external_function_definition
2395        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2396                {
2397                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asmstmt( false, $3, 0 ) ) );
2398                }
2399        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2400                {
2401                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2402                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2403                }
2404          '{' external_definition_list_opt '}'
2405                {
2406                        linkage = linkageStack.top();
2407                        linkageStack.pop();
2408                        $$ = $5;
2409                }
2410        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2411                {
2412                        distExt( $2 );                                                          // mark all fields in list
2413                        $$ = $2;
2414                }
2415        | forall '{' external_definition_list '}'                       // CFA, namespace
2416        ;
2417
2418external_function_definition:
2419        function_definition
2420                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2421                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2422                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2423                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2424                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2425        | function_declarator compound_statement
2426                {
2427                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2428                        typedefTable.leaveScope();
2429                        $$ = $1->addFunctionBody( $2 );
2430                }
2431        | KR_function_declarator KR_declaration_list_opt compound_statement
2432                {
2433                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2434                        typedefTable.leaveScope();
2435                        $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 );
2436                }
2437        ;
2438
2439with_clause_opt:
2440        // empty
2441                { $$ = nullptr; }
2442        | WITH '(' tuple_expression_list ')'
2443                { $$ = $3; }
2444        ;
2445
2446function_definition:
2447        cfa_function_declaration with_clause_opt compound_statement     // CFA
2448                {
2449                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2450                        typedefTable.leaveScope();
2451                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2452                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2453                        $1->get_last()->addFunctionBody( $3, $2 );
2454                        $$ = $1;
2455                }
2456        | declaration_specifier function_declarator with_clause_opt compound_statement
2457                {
2458                        rebindForall( $1, $2 );
2459                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2460                        typedefTable.leaveScope();
2461                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2462                }
2463                // handles default int return type, OBSOLESCENT (see 1)
2464        | type_qualifier_list function_declarator with_clause_opt compound_statement
2465                {
2466                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2467                        typedefTable.leaveScope();
2468                        $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 );
2469                }
2470                // handles default int return type, OBSOLESCENT (see 1)
2471        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2472                {
2473                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2474                        typedefTable.leaveScope();
2475                        $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 );
2476                }
2477                // handles default int return type, OBSOLESCENT (see 1)
2478        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2479                {
2480                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2481                        typedefTable.leaveScope();
2482                        $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 );
2483                }
2484
2485                // Old-style K&R function definition, OBSOLESCENT (see 4)
2486        | declaration_specifier KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2487                {
2488                        rebindForall( $1, $2 );
2489                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2490                        typedefTable.leaveScope();
2491                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2492                }
2493                // handles default int return type, OBSOLESCENT (see 1)
2494        | type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2495                {
2496                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2497                        typedefTable.leaveScope();
2498                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 );
2499                }
2500                // handles default int return type, OBSOLESCENT (see 1)
2501        | declaration_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2502                {
2503                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2504                        typedefTable.leaveScope();
2505                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 );
2506                }
2507                // handles default int return type, OBSOLESCENT (see 1)
2508        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2509                {
2510                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2511                        typedefTable.leaveScope();
2512                        $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 );
2513                }
2514        ;
2515
2516declarator:
2517        variable_declarator
2518        | variable_type_redeclarator
2519        | function_declarator
2520        ;
2521
2522subrange:
2523        constant_expression '~' constant_expression                     // CFA, integer subrange
2524                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2525        ;
2526
2527asm_name_opt:                                                                                   // GCC
2528        // empty
2529                { $$ = nullptr; }
2530        | ASM '(' string_literal ')' attribute_list_opt
2531                {
2532                        DeclarationNode * name = new DeclarationNode();
2533                        name->asmName = $3;
2534                        $$ = name->addQualifiers( $5 );
2535                }
2536        ;
2537
2538attribute_list_opt:                                                                             // GCC
2539        // empty
2540                { $$ = nullptr; }
2541        | attribute_list
2542        ;
2543
2544attribute_list:                                                                                 // GCC
2545        attribute
2546        | attribute_list attribute
2547                { $$ = $2->addQualifiers( $1 ); }
2548        ;
2549
2550attribute:                                                                                              // GCC
2551        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2552                { $$ = $4; }
2553        ;
2554
2555attribute_name_list:                                                                    // GCC
2556        attribute_name
2557        | attribute_name_list ',' attribute_name
2558                { $$ = $3->addQualifiers( $1 ); }
2559        ;
2560
2561attribute_name:                                                                                 // GCC
2562        // empty
2563                { $$ = nullptr; }
2564        | attr_name
2565                { $$ = DeclarationNode::newAttribute( $1 ); }
2566        | attr_name '(' argument_expression_list ')'
2567                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2568        ;
2569
2570attr_name:                                                                                              // GCC
2571        IDENTIFIER
2572        | quasi_keyword
2573        | TYPEDEFname
2574        | TYPEGENname
2575        | FALLTHROUGH
2576                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2577        | CONST
2578                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2579        ;
2580
2581// ============================================================================
2582// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2583// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2584// in:
2585//
2586//              int (*f())[10] { ... };
2587//              ... (*f())[3] += 1;             // definition mimics usage
2588//
2589// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2590// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2591// ============================================================================
2592
2593// ----------------------------------------------------------------------------
2594// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2595// to define a variable or function prototype, e.g.:
2596//
2597//              valid declaration               invalid definition
2598//              -----------------               ------------------
2599//              int f;                                  int f {}
2600//              int *f;                                 int *f {}
2601//              int f[10];                              int f[10] {}
2602//              int (*f)(int);                  int (*f)(int) {}
2603//
2604// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2605// variable_declarator and function_declarator.
2606// ----------------------------------------------------------------------------
2607
2608// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2609// declaring an array of functions versus a pointer to an array of functions.
2610
2611variable_declarator:
2612        paren_identifier attribute_list_opt
2613                { $$ = $1->addQualifiers( $2 ); }
2614        | variable_ptr
2615        | variable_array attribute_list_opt
2616                { $$ = $1->addQualifiers( $2 ); }
2617        | variable_function attribute_list_opt
2618                { $$ = $1->addQualifiers( $2 ); }
2619        ;
2620
2621paren_identifier:
2622        identifier
2623                {
2624                        typedefTable.setNextIdentifier( *$1 );
2625                        $$ = DeclarationNode::newName( $1 );
2626                }
2627        | '(' paren_identifier ')'                                                      // redundant parenthesis
2628                { $$ = $2; }
2629        ;
2630
2631variable_ptr:
2632        ptrref_operator variable_declarator
2633                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2634        | ptrref_operator type_qualifier_list variable_declarator
2635                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2636        | '(' variable_ptr ')' attribute_list_opt
2637                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2638        ;
2639
2640variable_array:
2641        paren_identifier array_dimension
2642                { $$ = $1->addArray( $2 ); }
2643        | '(' variable_ptr ')' array_dimension
2644                { $$ = $2->addArray( $4 ); }
2645        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2646                { $$ = $2->addArray( $4 ); }
2647        | '(' variable_array ')'                                                        // redundant parenthesis
2648                { $$ = $2; }
2649        ;
2650
2651variable_function:
2652        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2653                { $$ = $2->addParamList( $6 ); }
2654        | '(' variable_function ')'                                                     // redundant parenthesis
2655                { $$ = $2; }
2656        ;
2657
2658// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2659// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2660// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2661
2662function_declarator:
2663        function_no_ptr attribute_list_opt
2664                { $$ = $1->addQualifiers( $2 ); }
2665        | function_ptr
2666        | function_array attribute_list_opt
2667                { $$ = $1->addQualifiers( $2 ); }
2668        ;
2669
2670function_no_ptr:
2671        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2672                { $$ = $1->addParamList( $4 ); }
2673        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2674                { $$ = $2->addParamList( $6 ); }
2675        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2676                { $$ = $2; }
2677        ;
2678
2679function_ptr:
2680        ptrref_operator function_declarator
2681                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2682        | ptrref_operator type_qualifier_list function_declarator
2683                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2684        | '(' function_ptr ')'
2685                { $$ = $2; }
2686        ;
2687
2688function_array:
2689        '(' function_ptr ')' array_dimension
2690                { $$ = $2->addArray( $4 ); }
2691        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2692                { $$ = $2->addArray( $4 ); }
2693        | '(' function_array ')'                                                        // redundant parenthesis
2694                { $$ = $2; }
2695        ;
2696
2697// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2698//
2699//   f( a, b, c ) int a, *b, c[]; {}
2700//
2701// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2702// returning arrays and functions versus pointers to arrays and functions.
2703
2704KR_function_declarator:
2705        KR_function_no_ptr
2706        | KR_function_ptr
2707        | KR_function_array
2708        ;
2709
2710KR_function_no_ptr:
2711        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2712                { $$ = $1->addIdList( $3 ); }
2713        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2714                { $$ = $2->addParamList( $6 ); }
2715        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2716                { $$ = $2; }
2717        ;
2718
2719KR_function_ptr:
2720        ptrref_operator KR_function_declarator
2721                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2722        | ptrref_operator type_qualifier_list KR_function_declarator
2723                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2724        | '(' KR_function_ptr ')'
2725                { $$ = $2; }
2726        ;
2727
2728KR_function_array:
2729        '(' KR_function_ptr ')' array_dimension
2730                { $$ = $2->addArray( $4 ); }
2731        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2732                { $$ = $2->addArray( $4 ); }
2733        | '(' KR_function_array ')'                                                     // redundant parenthesis
2734                { $$ = $2; }
2735        ;
2736
2737// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2738//
2739//              typedef int foo;
2740//              {
2741//                 int foo; // redefine typedef name in new scope
2742//              }
2743//
2744// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2745// and functions versus pointers to arrays and functions.
2746
2747variable_type_redeclarator:
2748        paren_type attribute_list_opt
2749                { $$ = $1->addQualifiers( $2 ); }
2750        | type_ptr
2751        | type_array attribute_list_opt
2752                { $$ = $1->addQualifiers( $2 ); }
2753        | type_function attribute_list_opt
2754                { $$ = $1->addQualifiers( $2 ); }
2755        ;
2756
2757paren_type:
2758        typedef
2759        | '(' paren_type ')'
2760                { $$ = $2; }
2761        ;
2762
2763type_ptr:
2764        ptrref_operator variable_type_redeclarator
2765                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2766        | ptrref_operator type_qualifier_list variable_type_redeclarator
2767                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2768        | '(' type_ptr ')' attribute_list_opt
2769                { $$ = $2->addQualifiers( $4 ); }
2770        ;
2771
2772type_array:
2773        paren_type array_dimension
2774                { $$ = $1->addArray( $2 ); }
2775        | '(' type_ptr ')' array_dimension
2776                { $$ = $2->addArray( $4 ); }
2777        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2778                { $$ = $2->addArray( $4 ); }
2779        | '(' type_array ')'                                                            // redundant parenthesis
2780                { $$ = $2; }
2781        ;
2782
2783type_function:
2784        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2785                { $$ = $1->addParamList( $4 ); }
2786        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2787                { $$ = $2->addParamList( $6 ); }
2788        | '(' type_function ')'                                                         // redundant parenthesis
2789                { $$ = $2; }
2790        ;
2791
2792// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2793// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2794// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2795// pointers to arrays and functions.
2796
2797identifier_parameter_declarator:
2798        paren_identifier attribute_list_opt
2799                { $$ = $1->addQualifiers( $2 ); }
2800        | '&' MUTEX paren_identifier attribute_list_opt
2801                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2802        | identifier_parameter_ptr
2803        | identifier_parameter_array attribute_list_opt
2804                { $$ = $1->addQualifiers( $2 ); }
2805        | identifier_parameter_function attribute_list_opt
2806                { $$ = $1->addQualifiers( $2 ); }
2807        ;
2808
2809identifier_parameter_ptr:
2810        ptrref_operator identifier_parameter_declarator
2811                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2812        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2813                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2814        | '(' identifier_parameter_ptr ')' attribute_list_opt
2815                { $$ = $2->addQualifiers( $4 ); }
2816        ;
2817
2818identifier_parameter_array:
2819        paren_identifier array_parameter_dimension
2820                { $$ = $1->addArray( $2 ); }
2821        | '(' identifier_parameter_ptr ')' array_dimension
2822                { $$ = $2->addArray( $4 ); }
2823        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2824                { $$ = $2->addArray( $4 ); }
2825        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2826                { $$ = $2; }
2827        ;
2828
2829identifier_parameter_function:
2830        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2831                { $$ = $1->addParamList( $4 ); }
2832        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2833                { $$ = $2->addParamList( $6 ); }
2834        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2835                { $$ = $2; }
2836        ;
2837
2838// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2839// e.g.:
2840//
2841//              typedef int foo;
2842//              forall( otype T ) struct foo;
2843//              int f( int foo ); // redefine typedef name in new scope
2844//
2845// and allows the C99 array options, which can only appear in a parameter list.
2846
2847type_parameter_redeclarator:
2848        typedef attribute_list_opt
2849                { $$ = $1->addQualifiers( $2 ); }
2850        | '&' MUTEX typedef attribute_list_opt
2851                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2852        | type_parameter_ptr
2853        | type_parameter_array attribute_list_opt
2854                { $$ = $1->addQualifiers( $2 ); }
2855        | type_parameter_function attribute_list_opt
2856                { $$ = $1->addQualifiers( $2 ); }
2857        ;
2858
2859typedef:
2860        TYPEDEFname
2861                {
2862                        typedefTable.setNextIdentifier( *$1 );
2863                        $$ = DeclarationNode::newName( $1 );
2864                }
2865        | TYPEGENname
2866                {
2867                        typedefTable.setNextIdentifier( *$1 );
2868                        $$ = DeclarationNode::newName( $1 );
2869                }
2870        ;
2871
2872type_parameter_ptr:
2873        ptrref_operator type_parameter_redeclarator
2874                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2875        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2876                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2877        | '(' type_parameter_ptr ')' attribute_list_opt
2878                { $$ = $2->addQualifiers( $4 ); }
2879        ;
2880
2881type_parameter_array:
2882        typedef array_parameter_dimension
2883                { $$ = $1->addArray( $2 ); }
2884        | '(' type_parameter_ptr ')' array_parameter_dimension
2885                { $$ = $2->addArray( $4 ); }
2886        ;
2887
2888type_parameter_function:
2889        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2890                { $$ = $1->addParamList( $4 ); }
2891        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2892                { $$ = $2->addParamList( $6 ); }
2893        ;
2894
2895// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2896// which the type applies, e.g.:
2897//
2898//              sizeof( int );
2899//              sizeof( int * );
2900//              sizeof( int [10] );
2901//              sizeof( int (*)() );
2902//              sizeof( int () );
2903//
2904// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2905// and functions versus pointers to arrays and functions.
2906
2907abstract_declarator:
2908        abstract_ptr
2909        | abstract_array attribute_list_opt
2910                { $$ = $1->addQualifiers( $2 ); }
2911        | abstract_function attribute_list_opt
2912                { $$ = $1->addQualifiers( $2 ); }
2913        ;
2914
2915abstract_ptr:
2916        ptrref_operator
2917                { $$ = DeclarationNode::newPointer( 0, $1 ); }
2918        | ptrref_operator type_qualifier_list
2919                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2920        | ptrref_operator abstract_declarator
2921                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2922        | ptrref_operator type_qualifier_list abstract_declarator
2923                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2924        | '(' abstract_ptr ')' attribute_list_opt
2925                { $$ = $2->addQualifiers( $4 ); }
2926        ;
2927
2928abstract_array:
2929        array_dimension
2930        | '(' abstract_ptr ')' array_dimension
2931                { $$ = $2->addArray( $4 ); }
2932        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2933                { $$ = $2->addArray( $4 ); }
2934        | '(' abstract_array ')'                                                        // redundant parenthesis
2935                { $$ = $2; }
2936        ;
2937
2938abstract_function:
2939        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2940                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2941        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2942                { $$ = $2->addParamList( $6 ); }
2943        | '(' abstract_function ')'                                                     // redundant parenthesis
2944                { $$ = $2; }
2945        ;
2946
2947array_dimension:
2948                // Only the first dimension can be empty.
2949        '[' ']'
2950                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2951        | '[' ']' multi_array_dimension
2952                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2953        | multi_array_dimension
2954        ;
2955
2956multi_array_dimension:
2957        '[' push assignment_expression pop ']'
2958                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2959        | '[' push '*' pop ']'                                                          // C99
2960                { $$ = DeclarationNode::newVarArray( 0 ); }
2961        | multi_array_dimension '[' push assignment_expression pop ']'
2962                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2963        | multi_array_dimension '[' push '*' pop ']'            // C99
2964                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2965        ;
2966
2967// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2968// identifier to which the type applies, e.g.:
2969//
2970//              int f( int );                   // not handled here
2971//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
2972//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
2973//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2974//
2975// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2976// and functions versus pointers to arrays and functions. In addition, the pattern handles the
2977// special meaning of parenthesis around a typedef name:
2978//
2979//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2980//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2981//              not as redundant parentheses around the identifier."
2982//
2983// For example:
2984//
2985//              typedef float T;
2986//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2987//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2988//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2989//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2990//
2991// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2992// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2993// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2994// functions.
2995
2996abstract_parameter_declarator:
2997        abstract_parameter_ptr
2998        | '&' MUTEX attribute_list_opt
2999                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3000        | abstract_parameter_array attribute_list_opt
3001                { $$ = $1->addQualifiers( $2 ); }
3002        | abstract_parameter_function attribute_list_opt
3003                { $$ = $1->addQualifiers( $2 ); }
3004        ;
3005
3006abstract_parameter_ptr:
3007        ptrref_operator
3008                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3009        | ptrref_operator type_qualifier_list
3010                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3011        | ptrref_operator abstract_parameter_declarator
3012                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3013        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3014                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3015        | '(' abstract_parameter_ptr ')' attribute_list_opt
3016                { $$ = $2->addQualifiers( $4 ); }
3017        ;
3018
3019abstract_parameter_array:
3020        array_parameter_dimension
3021        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3022                { $$ = $2->addArray( $4 ); }
3023        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3024                { $$ = $2->addArray( $4 ); }
3025        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3026                { $$ = $2; }
3027        ;
3028
3029abstract_parameter_function:
3030        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3031                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3032        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3033                { $$ = $2->addParamList( $6 ); }
3034        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3035                { $$ = $2; }
3036        ;
3037
3038array_parameter_dimension:
3039                // Only the first dimension can be empty or have qualifiers.
3040        array_parameter_1st_dimension
3041        | array_parameter_1st_dimension multi_array_dimension
3042                { $$ = $1->addArray( $2 ); }
3043        | multi_array_dimension
3044        ;
3045
3046// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3047//
3048//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3049//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3050
3051array_parameter_1st_dimension:
3052        '[' ']'
3053                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3054        // multi_array_dimension handles the '[' '*' ']' case
3055        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3056                { $$ = DeclarationNode::newVarArray( $3 ); }
3057        | '[' push type_qualifier_list pop ']'
3058                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3059        // multi_array_dimension handles the '[' assignment_expression ']' case
3060        | '[' push type_qualifier_list assignment_expression pop ']'
3061                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3062        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3063                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3064        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3065                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3066        ;
3067
3068// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3069//
3070//              struct S {
3071//          int;
3072//          int *;
3073//          int [10];
3074//          int (*)();
3075//      };
3076
3077variable_abstract_declarator:
3078        variable_abstract_ptr
3079        | variable_abstract_array attribute_list_opt
3080                { $$ = $1->addQualifiers( $2 ); }
3081        | variable_abstract_function attribute_list_opt
3082                { $$ = $1->addQualifiers( $2 ); }
3083        ;
3084
3085variable_abstract_ptr:
3086        ptrref_operator
3087                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3088        | ptrref_operator type_qualifier_list
3089                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3090        | ptrref_operator variable_abstract_declarator
3091                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3092        | ptrref_operator type_qualifier_list variable_abstract_declarator
3093                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3094        | '(' variable_abstract_ptr ')' attribute_list_opt
3095                { $$ = $2->addQualifiers( $4 ); }
3096        ;
3097
3098variable_abstract_array:
3099        array_dimension
3100        | '(' variable_abstract_ptr ')' array_dimension
3101                { $$ = $2->addArray( $4 ); }
3102        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3103                { $$ = $2->addArray( $4 ); }
3104        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3105                { $$ = $2; }
3106        ;
3107
3108variable_abstract_function:
3109        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3110                { $$ = $2->addParamList( $6 ); }
3111        | '(' variable_abstract_function ')'                            // redundant parenthesis
3112                { $$ = $2; }
3113        ;
3114
3115// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3116// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3117
3118cfa_identifier_parameter_declarator_tuple:                              // CFA
3119        cfa_identifier_parameter_declarator_no_tuple
3120        | cfa_abstract_tuple
3121        | type_qualifier_list cfa_abstract_tuple
3122                { $$ = $2->addQualifiers( $1 ); }
3123        ;
3124
3125cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3126        cfa_identifier_parameter_ptr
3127        | cfa_identifier_parameter_array
3128        ;
3129
3130cfa_identifier_parameter_ptr:                                                   // CFA
3131                // No SUE declaration in parameter list.
3132        ptrref_operator type_specifier_nobody
3133                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3134        | type_qualifier_list ptrref_operator type_specifier_nobody
3135                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3136        | ptrref_operator cfa_abstract_function
3137                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3138        | type_qualifier_list ptrref_operator cfa_abstract_function
3139                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3140        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3141                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3142        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3143                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3144        ;
3145
3146cfa_identifier_parameter_array:                                                 // CFA
3147                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3148                // shift/reduce conflict with new-style empty (void) function return type.
3149        '[' ']' type_specifier_nobody
3150                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3151        | cfa_array_parameter_1st_dimension type_specifier_nobody
3152                { $$ = $2->addNewArray( $1 ); }
3153        | '[' ']' multi_array_dimension type_specifier_nobody
3154                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3155        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3156                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3157        | multi_array_dimension type_specifier_nobody
3158                { $$ = $2->addNewArray( $1 ); }
3159
3160        | '[' ']' cfa_identifier_parameter_ptr
3161                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3162        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3163                { $$ = $2->addNewArray( $1 ); }
3164        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3165                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3166        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3167                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3168        | multi_array_dimension cfa_identifier_parameter_ptr
3169                { $$ = $2->addNewArray( $1 ); }
3170        ;
3171
3172cfa_array_parameter_1st_dimension:
3173        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3174                { $$ = DeclarationNode::newVarArray( $3 ); }
3175        | '[' push type_qualifier_list assignment_expression pop ']'
3176                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3177        | '[' push declaration_qualifier_list assignment_expression pop ']'
3178                // declaration_qualifier_list must be used because of shift/reduce conflict with
3179                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3180                // appear in this context.
3181                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3182        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3183                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3184        ;
3185
3186// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3187// identifier to which the type applies, e.g.:
3188//
3189//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3190//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3191//
3192// These rules need LR(3):
3193//
3194//              cfa_abstract_tuple identifier_or_type_name
3195//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
3196//
3197// since a function return type can be syntactically identical to a tuple type:
3198//
3199//              [int, int] t;
3200//              [int, int] f( int );
3201//
3202// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3203// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3204// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3205// duplicated when appearing with cfa_function_specifier.
3206
3207cfa_abstract_declarator_tuple:                                                  // CFA
3208        cfa_abstract_tuple
3209        | type_qualifier_list cfa_abstract_tuple
3210                { $$ = $2->addQualifiers( $1 ); }
3211        | cfa_abstract_declarator_no_tuple
3212        ;
3213
3214cfa_abstract_declarator_no_tuple:                                               // CFA
3215        cfa_abstract_ptr
3216        | cfa_abstract_array
3217        ;
3218
3219cfa_abstract_ptr:                                                                               // CFA
3220        ptrref_operator type_specifier
3221                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3222        | type_qualifier_list ptrref_operator type_specifier
3223                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3224        | ptrref_operator cfa_abstract_function
3225                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3226        | type_qualifier_list ptrref_operator cfa_abstract_function
3227                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3228        | ptrref_operator cfa_abstract_declarator_tuple
3229                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3230        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3231                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3232        ;
3233
3234cfa_abstract_array:                                                                             // CFA
3235                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3236                // empty (void) function return type.
3237        '[' ']' type_specifier
3238                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3239        | '[' ']' multi_array_dimension type_specifier
3240                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3241        | multi_array_dimension type_specifier
3242                { $$ = $2->addNewArray( $1 ); }
3243        | '[' ']' cfa_abstract_ptr
3244                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3245        | '[' ']' multi_array_dimension cfa_abstract_ptr
3246                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3247        | multi_array_dimension cfa_abstract_ptr
3248                { $$ = $2->addNewArray( $1 ); }
3249        ;
3250
3251cfa_abstract_tuple:                                                                             // CFA
3252        '[' push cfa_abstract_parameter_list pop ']'
3253                { $$ = DeclarationNode::newTuple( $3 ); }
3254        ;
3255
3256cfa_abstract_function:                                                                  // CFA
3257//      '[' ']' '(' cfa_parameter_type_list_opt ')'
3258//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3259        cfa_abstract_tuple '(' push cfa_parameter_type_list_opt pop ')'
3260                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3261        | cfa_function_return '(' push cfa_parameter_type_list_opt pop ')'
3262                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3263        ;
3264
3265// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3266//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3267//
3268// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3269//    the declaration specifiers in a declaration is an obsolescent feature."
3270//
3271// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3272//    prototype-format parameter type declarators) is an obsolescent feature."
3273//
3274// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3275//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3276
3277//************************* MISCELLANEOUS ********************************
3278
3279comma_opt:                                                                                              // redundant comma
3280        // empty
3281        | ','
3282        ;
3283
3284default_initialize_opt:
3285        // empty
3286                { $$ = nullptr; }
3287        | '=' assignment_expression
3288                { $$ = $2; }
3289        ;
3290
3291%%
3292// ----end of grammar----
3293
3294// Local Variables: //
3295// mode: c++ //
3296// tab-width: 4 //
3297// compile-command: "make install" //
3298// End: //
Note: See TracBrowser for help on using the repository browser.