source: src/Parser/parser.yy @ c1e66d9

Last change on this file since c1e66d9 was c1e66d9, checked in by JiadaL <j82liang@…>, 5 months ago

Fix designator value in enumerated array and implemented enumerated array with inlined enume declaration

  • Property mode set to 100644
File size: 174.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Mon Sep  4 18:28:12 2023
13// Update Count     : 6393
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28//   designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule.  Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval )                                    // lexer loads this up each time
40#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
41#define YYERROR_VERBOSE                                                                 // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "SynTree/Type.h"                               // for Type
51#include "DeclarationNode.h"                            // for DeclarationNode, ...
52#include "ExpressionNode.h"                             // for ExpressionNode, ...
53#include "InitializerNode.h"                            // for InitializerNode, ...
54#include "ParserTypes.h"
55#include "StatementNode.h"                              // for build_...
56#include "TypedefTable.h"
57#include "TypeData.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61#include "SynTree/Attribute.h"                                                  // for Attribute
62
63// lex uses __null in a boolean context, it's fine.
64#ifdef __clang__
65#pragma GCC diagnostic ignored "-Wparentheses-equality"
66#endif
67
68extern DeclarationNode * parseTree;
69extern ast::Linkage::Spec linkage;
70extern TypedefTable typedefTable;
71
72stack<ast::Linkage::Spec> linkageStack;
73
74bool appendStr( string & to, string & from ) {
75        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
76        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
77        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
78        //    easier to let the C compiler handle this case.
79        //
80        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
81        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
82        //    e.g., u"a" U"b" L"c" is disallowed.
83
84        if ( from[0] != '"' ) {                                                         // encoding ?
85                if ( to[0] != '"' ) {                                                   // encoding ?
86                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
87                                yyerror( "non-matching string encodings for string-literal concatenation" );
88                                return false;                                                   // parse error, must call YYERROR in action
89                        } else if ( from[1] == '8' ) {
90                                from.erase( 0, 1 );                                             // remove 2nd encoding
91                        } // if
92                } else {
93                        if ( from[1] == '8' ) {                                         // move encoding to start
94                                to = "u8" + to;
95                                from.erase( 0, 1 );                                             // remove 2nd encoding
96                        } else {
97                                to = from[0] + to;
98                        } // if
99                } // if
100                from.erase( 0, 1 );                                                             // remove 2nd encoding
101        } // if
102        to += " " + from;                                                                       // concatenated into single string
103        return true;
104} // appendStr
105
106DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
107        // distribute declaration_specifier across all declared variables, e.g., static, const, but not __attribute__.
108        assert( declList );
109        // printf( "distAttr1 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout );
110        DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec );
111        // printf( "distAttr2 cl %p\n", cl ); cl->type->print( std::cout );
112        // cl->type->aggregate.name = cl->type->aggInst.aggregate->aggregate.name;
113
114        for ( DeclarationNode * cur = dynamic_cast<DeclarationNode *>( declList->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
115                cl->cloneBaseType( cur );
116        } // for
117        declList->addType( cl );
118        // printf( "distAttr3 declList %p\n", declList ); declList->print( std::cout, 0 );
119        return declList;
120} // distAttr
121
122void distExt( DeclarationNode * declaration ) {
123        // distribute EXTENSION across all declarations
124        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
125                iter->set_extension( true );
126        } // for
127} // distExt
128
129void distInl( DeclarationNode * declaration ) {
130        // distribute INLINE across all declarations
131        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
132                iter->set_inLine( true );
133        } // for
134} // distInl
135
136void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
137        // distribute qualifiers across all non-variable declarations in a distribution statemement
138        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
139                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
140                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
141                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
142                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
143                DeclarationNode * clone = qualifiers->clone();
144                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
145                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
146                                swap( clone->type->forall, iter->type->aggregate.params );
147                                iter->addQualifiers( clone );
148                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
149                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
150                                DeclarationNode newnode;
151                                swap( newnode.type, iter->type->aggInst.aggregate );
152                                swap( clone->type->forall, newnode.type->aggregate.params );
153                                newnode.addQualifiers( clone );
154                                swap( newnode.type, iter->type->aggInst.aggregate );
155                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
156                                swap( clone->type->forall, iter->type->forall );
157                                iter->addQualifiers( clone );
158                        } // if
159                } else {                                                                                // just SC qualifiers
160                        iter->addQualifiers( clone );
161                } // if
162        } // for
163        delete qualifiers;
164} // distQual
165
166// There is an ambiguity for inline generic-routine return-types and generic routines.
167//   forall( otype T ) struct S { int i; } bar( T ) {}
168// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
169//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
170// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
171//   forall( otype T ) struct S { int T; };
172//   forall( otype W ) bar( W ) {}
173
174void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
175        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
176                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
177                declSpec->type->aggregate.params = nullptr;
178        } // if
179} // rebindForall
180
181string * build_postfix_name( string * name ) {
182        *name = string("__postfix_func_") + *name;
183        return name;
184} // build_postfix_name
185
186DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
187        if ( ! fieldList ) {                                                            // field declarator ?
188                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
189                        stringstream ss;
190                        // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
191                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
192                        return nullptr;
193                } // if
194                // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
195                fieldList = DeclarationNode::newName( nullptr );
196        } // if
197//      return distAttr( typeSpec, fieldList );                         // mark all fields in list
198
199        // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
200        DeclarationNode * temp = distAttr( typeSpec, fieldList );                               // mark all fields in list
201        // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
202        return temp;
203} // fieldDecl
204
205#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
206#define NEW_ONE  new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
207#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
208#define MISSING_ANON_FIELD "syntax error, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
209#define MISSING_LOW "syntax error, missing low value for up-to range so index is uninitialized."
210#define MISSING_HIGH "syntax error, missing high value for down-to range so index is uninitialized."
211
212static ForCtrl * makeForCtrl(
213                const CodeLocation & location,
214                DeclarationNode * init,
215                enum OperKinds compop,
216                ExpressionNode * comp,
217                ExpressionNode * inc ) {
218        // Wrap both comp/inc if they are non-null.
219        if ( comp ) comp = new ExpressionNode( build_binary_val( location,
220                compop,
221                new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
222                comp ) );
223        if ( inc ) inc = new ExpressionNode( build_binary_val( location,
224                // choose += or -= for upto/downto
225                compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
226                new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
227                inc ) );
228        // The StatementNode call frees init->name, it must happen later.
229        return new ForCtrl( new StatementNode( init ), comp, inc );
230}
231
232ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
233        if ( index->initializer ) {
234                SemanticError( yylloc, "syntax error, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
235        } // if
236        if ( index->next ) {
237                SemanticError( yylloc, "syntax error, multiple loop indexes disallowed in for-loop declaration." );
238        } // if
239        DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
240        return makeForCtrl( location, initDecl, compop, comp, inc );
241} // forCtrl
242
243ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
244        ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
245        if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
246                type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicType::SignedInt ) ) );
247        } // if
248        DeclarationNode * initDecl = distAttr(
249                DeclarationNode::newTypeof( type, true ),
250                DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
251        );
252        return makeForCtrl( location, initDecl, compop, comp, inc );
253} // forCtrl
254
255ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
256        if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
257                return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
258        } else if ( auto commaExpr = dynamic_cast<ast::CommaExpr *>( index->expr.get() ) ) {
259                if ( auto identifier = commaExpr->arg1.as<ast::NameExpr>() ) {
260                        return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
261                } else {
262                        SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
263                } // if
264        } else {
265                SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed. ." ); return nullptr;
266        } // if
267} // forCtrl
268
269static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
270        SemanticError( yylloc, ::toString( "syntax error, adjacent identifiers \"", identifier1, "\" and \"", identifier2, "\" are not meaningful in a", kind, ".\n"
271                                   "Possible cause is misspelled type name or missing generic parameter." ) );
272} // IdentifierBeforeIdentifier
273
274static void IdentifierBeforeType( string & identifier, const char * kind ) {
275        SemanticError( yylloc, ::toString( "syntax error, identifier \"", identifier, "\" cannot appear before a ", kind, ".\n"
276                                   "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter." ) );
277} // IdentifierBeforeType
278
279bool forall = false;                                                                    // aggregate have one or more forall qualifiers ?
280
281// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
282#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
283if ( N ) {                                                                                                                                              \
284        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
285        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
286        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
287        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
288        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
289} else {                                                                                                                                                \
290        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
291        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
292        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
293}
294%}
295
296%define parse.error verbose
297
298// Types declaration for productions
299
300%union {
301        Token tok;
302        ExpressionNode * expr;
303        DeclarationNode * decl;
304        ast::AggregateDecl::Aggregate aggKey;
305        ast::TypeDecl::Kind tclass;
306        StatementNode * stmt;
307        ClauseNode * clause;
308        ast::WaitForStmt * wfs;
309    ast::WaitUntilStmt::ClauseNode * wucn;
310        CondCtl * ifctl;
311        ForCtrl * forctl;
312        LabelNode * labels;
313        InitializerNode * init;
314        OperKinds oper;
315        std::string * str;
316        bool is_volatile;
317        EnumHiding enum_hiding;
318        ast::ExceptionKind except_kind;
319        ast::GenericExpr * genexpr;
320}
321
322// ************************ TERMINAL TOKENS ********************************
323
324// keywords
325%token TYPEDEF
326%token EXTERN STATIC AUTO REGISTER
327%token THREADLOCALGCC THREADLOCALC11                                    // GCC, C11
328%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
329%token NORETURN                                                                                 // C11
330%token CONST VOLATILE
331%token RESTRICT                                                                                 // C99
332%token ATOMIC                                                                                   // C11
333%token FORALL MUTEX VIRTUAL VTABLE COERCE                               // CFA
334%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
335%token BOOL COMPLEX IMAGINARY                                                   // C99
336%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
337%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
338%token DECIMAL32 DECIMAL64 DECIMAL128                                   // GCC
339%token ZERO_T ONE_T                                                                             // CFA
340%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE                   // GCC
341%token OFFSETOF BASETYPEOF TYPEID                                               // CFA
342%token ENUM STRUCT UNION
343%token EXCEPTION                                                                                // CFA
344%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
345%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
346// %token RESUME                                                                                        // CFA
347%token LABEL                                                                                    // GCC
348%token SUSPEND                                                                                  // CFA
349%token ATTRIBUTE EXTENSION                                                              // GCC
350%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
351%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
352%token DISABLE ENABLE TRY THROW THROWRESUME AT                  // CFA
353%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
354%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
355
356// names and constants: lexer differentiates between identifier and typedef names
357%token<tok> IDENTIFIER          TYPEDIMname             TYPEDEFname             TYPEGENname
358%token<tok> TIMEOUT                     WAND    WOR                     CATCH                   RECOVER                 CATCHRESUME             FIXUP           FINALLY         // CFA
359%token<tok> INTEGERconstant     CHARACTERconstant       STRINGliteral
360%token<tok> DIRECTIVE
361// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
362// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
363// converted into the tuple index (.)(1). e.g., 3.x
364%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
365
366// multi-character operators
367%token ARROW                                                                                    // ->
368%token ICR DECR                                                                                 // ++   --
369%token LS RS                                                                                    // <<   >>
370%token LE GE EQ NE                                                                              // <=   >=      ==      !=
371%token ANDAND OROR                                                                              // &&   ||
372%token ELLIPSIS                                                                                 // ...
373
374%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
375%token PLUSassign       MINUSassign                                                     // +=   -=
376%token LSassign         RSassign                                                        // <<=  >>=
377%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
378
379%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
380%token ATassign                                                                                 // @=
381
382%type<tok> identifier                                   identifier_at                           identifier_or_type_name         attr_name
383%type<tok> quasi_keyword
384%type<expr> string_literal
385%type<str> string_literal_list
386
387%type<enum_hiding> hide_opt                             visible_hide_opt
388
389// expressions
390%type<expr> constant
391%type<expr> tuple                                               tuple_expression_list
392%type<oper> ptrref_operator                             unary_operator                          assignment_operator                     simple_assignment_operator      compound_assignment_operator
393%type<expr> primary_expression                  postfix_expression                      unary_expression
394%type<expr> cast_expression_list                cast_expression                         exponential_expression          multiplicative_expression       additive_expression
395%type<expr> shift_expression                    relational_expression           equality_expression
396%type<expr> AND_expression                              exclusive_OR_expression         inclusive_OR_expression
397%type<expr> logical_AND_expression              logical_OR_expression
398%type<expr> conditional_expression              constant_expression                     assignment_expression           assignment_expression_opt
399%type<expr> comma_expression                    comma_expression_opt
400%type<expr> argument_expression_list_opt argument_expression_list       argument_expression                     default_initializer_opt
401%type<ifctl> conditional_declaration
402%type<forctl> for_control_expression    for_control_expression_list
403%type<oper> upupeq updown updowneq downupdowneq
404%type<expr> subrange
405%type<decl> asm_name_opt
406%type<expr> asm_operands_opt                    asm_operands_list                       asm_operand
407%type<labels> label_list
408%type<expr> asm_clobbers_list_opt
409%type<is_volatile> asm_volatile_opt
410%type<expr> handler_predicate_opt
411%type<genexpr> generic_association              generic_assoc_list
412
413// statements
414%type<stmt> statement                                   labeled_statement                       compound_statement
415%type<stmt> statement_decl                              statement_decl_list                     statement_list_nodecl
416%type<stmt> selection_statement                 if_statement
417%type<clause> switch_clause_list_opt    switch_clause_list
418%type<expr> case_value
419%type<clause> case_clause                               case_value_list                         case_label      case_label_list
420%type<stmt> iteration_statement                 jump_statement
421%type<stmt> expression_statement                asm_statement
422%type<stmt> with_statement
423%type<expr> with_clause_opt
424%type<stmt> exception_statement
425%type<clause> handler_clause                    finally_clause
426%type<except_kind> handler_key
427%type<stmt> mutex_statement
428%type<expr> when_clause                                 when_clause_opt                         waitfor         waituntil               timeout
429%type<stmt> waitfor_statement                   waituntil_statement
430%type<wfs> wor_waitfor_clause
431%type<wucn> waituntil_clause                    wand_waituntil_clause       wor_waituntil_clause
432
433// declarations
434%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
435%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
436%type<decl> abstract_parameter_declaration
437
438%type<aggKey> aggregate_key aggregate_data aggregate_control
439%type<decl> aggregate_type aggregate_type_nobody
440
441%type<decl> assertion assertion_list assertion_list_opt
442
443%type<expr> bit_subrange_size_opt bit_subrange_size
444
445%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
446%type<decl> vtable vtable_opt default_opt
447
448%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
449
450%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
451%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
452
453%type<decl> elaborated_type elaborated_type_nobody
454
455%type<decl> enumerator_list enum_type enum_type_nobody
456%type<init> enumerator_value_opt
457
458%type<decl> external_definition external_definition_list external_definition_list_opt
459
460%type<decl> exception_declaration
461
462%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
463%type<expr> field field_name_list field_name fraction_constants_opt
464
465%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
466
467%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
468%type<decl> identifier_list
469
470%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
471%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
472%type<decl> cfa_abstract_ptr cfa_abstract_tuple
473
474%type<decl> cfa_array_parameter_1st_dimension
475
476%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
477%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
478
479%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
480%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
481
482%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
483
484%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
485
486%type<decl> c_declaration static_assert
487%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
488%type<decl> KR_parameter_list KR_parameter_list_opt
489
490%type<decl> parameter_declaration parameter_list parameter_type_list_opt
491
492%type<decl> paren_identifier paren_type
493
494%type<decl> storage_class storage_class_list
495
496%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
497
498%type<tclass> type_class new_type_class
499%type<decl> type_declarator type_declarator_name type_declaring_list
500
501%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
502%type<decl> typedef_name typedef_declaration typedef_expression
503
504%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
505%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
506
507%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
508
509%type<decl> type type_no_function
510%type<decl> type_parameter type_parameter_list type_initializer_opt
511
512%type<expr> type_parameters_opt type_list array_type_list
513
514%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
515%type<decl> type_specifier type_specifier_nobody
516
517%type<decl> variable_declarator variable_ptr variable_array variable_function
518%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
519
520%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
521
522// initializers
523%type<init>  initializer initializer_list_opt initializer_opt
524
525// designators
526%type<expr>  designator designator_list designation
527
528
529// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
530//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
531//   if ( C ) S1 else S2
532//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
533// Similar issues exit with the waitfor statement.
534
535// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
536// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
537%precedence THEN                // rule precedence for IF/WAITFOR statement
538%precedence ANDAND              // token precedence for start of WAND in WAITFOR statement
539%precedence WAND                // token precedence for start of WAND in WAITFOR statement
540%precedence OROR                // token precedence for start of WOR in WAITFOR statement
541%precedence WOR                 // token precedence for start of WOR in WAITFOR statement
542%precedence TIMEOUT             // token precedence for start of TIMEOUT in WAITFOR statement
543%precedence CATCH               // token precedence for start of TIMEOUT in WAITFOR statement
544%precedence RECOVER             // token precedence for start of TIMEOUT in WAITFOR statement
545%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
546%precedence FIXUP               // token precedence for start of TIMEOUT in WAITFOR statement
547%precedence FINALLY             // token precedence for start of TIMEOUT in WAITFOR statement
548%precedence ELSE                // token precedence for start of else clause in IF/WAITFOR statement
549
550
551// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
552//   forall( otype T ) struct Foo { T v; };
553//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
554//   Foo ( *fp )( int );
555//   `---'                                              matches start of TYPEGENname '('
556// must be:
557//   Foo( int ) ( *fp )( int );
558// The same problem occurs here:
559//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
560// must be:
561//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
562
563// Order of these lines matters (low-to-high precedence).
564%precedence TYPEGENname
565%precedence '}'
566%precedence '('
567
568// %precedence RESUME
569// %precedence '{'
570// %precedence ')'
571
572%locations                                                                                              // support location tracking for error messages
573
574%start translation_unit                                                                 // parse-tree root
575
576%%
577// ************************ Namespace Management ********************************
578
579// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
580// which are lexically identical.
581//
582//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
583//   foo f;           // to allow it to appear in this context
584//
585// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
586// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
587// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
588// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
589// must be distinguished by the lexical scanner.
590//
591// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
592// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
593// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
594// each context that introduces a name scope, a new level is created in the type table and that level is popped on
595// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
596// This requires distinguishing between type names that are local to the current declaration scope and those that
597// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
598//
599// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
600// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
601// around the list separator.
602//
603//  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
604//      push               pop   push                   pop
605
606push:
607                { typedefTable.enterScope(); }
608        ;
609
610pop:
611                { typedefTable.leaveScope(); }
612        ;
613
614// ************************ CONSTANTS ********************************
615
616constant:
617                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
618        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
619        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
620        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
621        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
622        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
623        ;
624
625quasi_keyword:                                                                                  // CFA
626        TIMEOUT
627        | WAND
628        | WOR
629        | CATCH
630        | RECOVER
631        | CATCHRESUME
632        | FIXUP
633        | FINALLY
634        ;
635
636identifier:
637        IDENTIFIER
638        | quasi_keyword
639        ;
640
641identifier_at:
642        identifier
643        | '@'                                                                                           // CFA
644                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
645        ;
646
647string_literal:
648        string_literal_list                                                     { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
649        ;
650
651string_literal_list:                                                                    // juxtaposed strings are concatenated
652        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
653        | string_literal_list STRINGliteral
654                {
655                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
656                        delete $2;                                                                      // allocated by lexer
657                        $$ = $1;                                                                        // conversion from tok to str
658                }
659        ;
660
661// ************************ EXPRESSIONS ********************************
662
663primary_expression:
664        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
665                { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
666        | quasi_keyword
667                { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
668        | TYPEDIMname                                                                           // CFA, generic length argument
669                // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
670                // { $$ = new ExpressionNode( build_varref( $1 ) ); }
671                { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
672        | tuple
673        | '(' comma_expression ')'
674                { $$ = $2; }
675        | '(' compound_statement ')'                                            // GCC, lambda expression
676                { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
677        | type_name '.' identifier                                                      // CFA, nested type
678                { $$ = new ExpressionNode( build_qualified_expr( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
679        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
680                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
681        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
682                {
683                        // add the missing control expression to the GenericExpr and return it
684                        $5->control = maybeMoveBuild( $3 );
685                        $$ = new ExpressionNode( $5 );
686                }
687        // | RESUME '(' comma_expression ')'
688        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
689        // | RESUME '(' comma_expression ')' compound_statement
690        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
691        | IDENTIFIER IDENTIFIER                                                         // invalid syntax rule
692                { IdentifierBeforeIdentifier( *$1.str, *$2.str, "n expression" ); $$ = nullptr; }
693        | IDENTIFIER type_qualifier                                                     // invalid syntax rule
694                { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
695        | IDENTIFIER storage_class                                                      // invalid syntax rule
696                { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
697        | IDENTIFIER basic_type_name                                            // invalid syntax rule
698                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
699        | IDENTIFIER TYPEDEFname                                                        // invalid syntax rule
700                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
701        | IDENTIFIER TYPEGENname                                                        // invalid syntax rule
702                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
703        ;
704
705generic_assoc_list:                                                                             // C11
706        generic_association
707        | generic_assoc_list ',' generic_association
708                {
709                        // steal the association node from the singleton and delete the wrapper
710                        assert( 1 == $3->associations.size() );
711                        $1->associations.push_back( $3->associations.front() );
712                        delete $3;
713                        $$ = $1;
714                }
715        ;
716
717generic_association:                                                                    // C11
718        type_no_function ':' assignment_expression
719                {
720                        // create a GenericExpr wrapper with one association pair
721                        $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
722                }
723        | DEFAULT ':' assignment_expression
724                { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
725        ;
726
727postfix_expression:
728        primary_expression
729        | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
730                // Historic, transitional: Disallow commas in subscripts.
731                // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
732                // Current: Commas in subscripts make tuples.
733                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
734        | postfix_expression '[' assignment_expression ']'
735                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
736                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
737                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
738                // equivalent to the old x[i,j].
739                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
740        | constant '[' assignment_expression ']'                        // 3[a], 'a'[a], 3.5[a]
741                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
742        | string_literal '[' assignment_expression ']'          // "abc"[3], 3["abc"]
743                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
744        | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
745                {
746                        Token fn;
747                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
748                        $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
749                }
750        | postfix_expression '(' argument_expression_list_opt ')'
751                { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
752        | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
753                // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
754                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg") ) ),
755                                                                                           (ExpressionNode *)($3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) )) ) ); }
756        | postfix_expression '`' identifier                                     // CFA, postfix call
757                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
758        | constant '`' identifier                                                       // CFA, postfix call
759                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
760        | string_literal '`' identifier                                         // CFA, postfix call
761                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
762        | postfix_expression '.' identifier
763                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
764        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
765                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
766        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
767                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
768        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
769                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
770        | postfix_expression '.' aggregate_control
771                { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
772        | postfix_expression ARROW identifier
773                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
774        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
775                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
776        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
777                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
778        | postfix_expression ICR
779                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
780        | postfix_expression DECR
781                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
782        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
783                { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
784        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
785                { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
786        | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
787                {
788                        Token fn;
789                        fn.str = new string( "^?{}" );                          // location undefined
790                        $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
791                }
792        ;
793
794argument_expression_list_opt:
795        // empty
796                { $$ = nullptr; }
797        | argument_expression_list
798        ;
799
800argument_expression_list:
801        argument_expression
802        | argument_expression_list_opt ',' argument_expression
803                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
804        ;
805
806argument_expression:
807        '@'                                                                                                     // CFA, default parameter
808                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
809                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
810        | assignment_expression
811        ;
812
813field_name_list:                                                                                // CFA, tuple field selector
814        field
815        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
816        ;
817
818field:                                                                                                  // CFA, tuple field selector
819        field_name
820        | FLOATING_DECIMALconstant field
821                { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
822        | FLOATING_DECIMALconstant '[' field_name_list ']'
823                { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
824        | field_name '.' field
825                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
826        | field_name '.' '[' field_name_list ']'
827                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
828        | field_name ARROW field
829                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
830        | field_name ARROW '[' field_name_list ']'
831                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
832        ;
833
834field_name:
835        INTEGERconstant fraction_constants_opt
836                { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
837        | FLOATINGconstant fraction_constants_opt
838                { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
839        | identifier_at fraction_constants_opt                          // CFA, allow anonymous fields
840                {
841                        $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
842                }
843        ;
844
845fraction_constants_opt:
846        // empty
847                { $$ = nullptr; }
848        | fraction_constants_opt FLOATING_FRACTIONconstant
849                {
850                        ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
851                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
852                }
853        ;
854
855unary_expression:
856        postfix_expression
857                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
858                // semantics checks, e.g., ++3, 3--, *3, &&3
859        | constant
860        | string_literal
861                { $$ = $1; }
862        | EXTENSION cast_expression                                                     // GCC
863                { $$ = $2->set_extension( true ); }
864                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
865                //              { * X; }         // dereference X
866                //              { * int X; } // CFA declaration of pointer to int
867        | ptrref_operator cast_expression                                       // CFA
868                {
869                        switch ( $1 ) {
870                        case OperKinds::AddressOf:
871                                $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
872                                break;
873                        case OperKinds::PointTo:
874                                $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
875                                break;
876                        case OperKinds::And:
877                                $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
878                                break;
879                        default:
880                                assert( false );
881                        }
882                }
883        | unary_operator cast_expression
884                { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
885        | ICR unary_expression
886                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
887        | DECR unary_expression
888                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
889        | SIZEOF unary_expression
890                { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
891        | SIZEOF '(' type_no_function ')'
892                { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
893        | ALIGNOF unary_expression                                                      // GCC, variable alignment
894                { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
895        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
896                { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
897        | OFFSETOF '(' type_no_function ',' identifier ')'
898                { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
899        | TYPEID '(' type_no_function ')'
900                {
901                        SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
902                        // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
903                }
904        ;
905
906ptrref_operator:
907        '*'                                                                                     { $$ = OperKinds::PointTo; }
908        | '&'                                                                           { $$ = OperKinds::AddressOf; }
909                // GCC, address of label must be handled by semantic check for ref,ref,label
910        | ANDAND                                                                        { $$ = OperKinds::And; }
911        ;
912
913unary_operator:
914        '+'                                                                                     { $$ = OperKinds::UnPlus; }
915        | '-'                                                                           { $$ = OperKinds::UnMinus; }
916        | '!'                                                                           { $$ = OperKinds::Neg; }
917        | '~'                                                                           { $$ = OperKinds::BitNeg; }
918        ;
919
920cast_expression:
921        unary_expression
922        | '(' type_no_function ')' cast_expression
923                { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
924        | '(' aggregate_control '&' ')' cast_expression         // CFA
925                { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
926        | '(' aggregate_control '*' ')' cast_expression         // CFA
927                { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
928        | '(' VIRTUAL ')' cast_expression                                       // CFA
929                { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), maybeMoveBuildType( nullptr ) ) ); }
930        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
931                { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
932        | '(' RETURN type_no_function ')' cast_expression       // CFA
933                { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
934        | '(' COERCE type_no_function ')' cast_expression       // CFA
935                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
936        | '(' qualifier_cast_list ')' cast_expression           // CFA
937                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
938//      | '(' type_no_function ')' tuple
939//              { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
940        ;
941
942qualifier_cast_list:
943        cast_modifier type_qualifier_name
944        | cast_modifier MUTEX
945        | qualifier_cast_list cast_modifier type_qualifier_name
946        | qualifier_cast_list cast_modifier MUTEX
947        ;
948
949cast_modifier:
950        '-'
951        | '+'
952        ;
953
954exponential_expression:
955        cast_expression
956        | exponential_expression '\\' cast_expression
957                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
958        ;
959
960multiplicative_expression:
961        exponential_expression
962        | multiplicative_expression '*' exponential_expression
963                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
964        | multiplicative_expression '/' exponential_expression
965                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
966        | multiplicative_expression '%' exponential_expression
967                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
968        ;
969
970additive_expression:
971        multiplicative_expression
972        | additive_expression '+' multiplicative_expression
973                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
974        | additive_expression '-' multiplicative_expression
975                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
976        ;
977
978shift_expression:
979        additive_expression
980        | shift_expression LS additive_expression
981                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
982        | shift_expression RS additive_expression
983                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
984        ;
985
986relational_expression:
987        shift_expression
988        | relational_expression '<' shift_expression
989                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
990        | relational_expression '>' shift_expression
991                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
992        | relational_expression LE shift_expression
993                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
994        | relational_expression GE shift_expression
995                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
996        ;
997
998equality_expression:
999        relational_expression
1000        | equality_expression EQ relational_expression
1001                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1002        | equality_expression NE relational_expression
1003                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1004        ;
1005
1006AND_expression:
1007        equality_expression
1008        | AND_expression '&' equality_expression
1009                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1010        ;
1011
1012exclusive_OR_expression:
1013        AND_expression
1014        | exclusive_OR_expression '^' AND_expression
1015                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1016        ;
1017
1018inclusive_OR_expression:
1019        exclusive_OR_expression
1020        | inclusive_OR_expression '|' exclusive_OR_expression
1021                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1022        ;
1023
1024logical_AND_expression:
1025        inclusive_OR_expression
1026        | logical_AND_expression ANDAND inclusive_OR_expression
1027                { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1028        ;
1029
1030logical_OR_expression:
1031        logical_AND_expression
1032        | logical_OR_expression OROR logical_AND_expression
1033                { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1034        ;
1035
1036conditional_expression:
1037        logical_OR_expression
1038        | logical_OR_expression '?' comma_expression ':' conditional_expression
1039                { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1040                // FIX ME: computes $1 twice
1041        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1042                { $$ = new ExpressionNode( build_cond( yylloc, $1, $1->clone(), $4 ) ); }
1043        ;
1044
1045constant_expression:
1046        conditional_expression
1047        ;
1048
1049assignment_expression:
1050                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1051        conditional_expression
1052        | unary_expression assignment_operator assignment_expression
1053                {
1054//                      if ( $2 == OperKinds::AtAssn ) {
1055//                              SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1056//                      } else {
1057                                $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1058//                      } // if
1059                }
1060        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1061                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1062        ;
1063
1064assignment_expression_opt:
1065        // empty
1066                { $$ = nullptr; }
1067        | assignment_expression
1068        ;
1069
1070assignment_operator:
1071        simple_assignment_operator
1072        | compound_assignment_operator
1073        ;
1074
1075simple_assignment_operator:
1076        '='                                                                                     { $$ = OperKinds::Assign; }
1077        | ATassign                                                                      { $$ = OperKinds::AtAssn; } // CFA
1078        ;
1079
1080compound_assignment_operator:
1081        EXPassign                                                                       { $$ = OperKinds::ExpAssn; }
1082        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
1083        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
1084        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
1085        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
1086        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
1087        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
1088        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
1089        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
1090        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
1091        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
1092        ;
1093
1094tuple:                                                                                                  // CFA, tuple
1095                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1096                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1097//      '[' ']'
1098//              { $$ = new ExpressionNode( build_tuple() ); }
1099//      | '[' push assignment_expression pop ']'
1100//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1101        '[' ',' tuple_expression_list ']'
1102                { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
1103        | '[' push assignment_expression pop ',' tuple_expression_list ']'
1104                { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $6 ) ) )); }
1105        ;
1106
1107tuple_expression_list:
1108        assignment_expression
1109        | '@'                                                                                           // CFA
1110                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1111        | tuple_expression_list ',' assignment_expression
1112                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1113        | tuple_expression_list ',' '@'
1114                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1115        ;
1116
1117comma_expression:
1118        assignment_expression
1119        | comma_expression ',' assignment_expression
1120                { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1121        ;
1122
1123comma_expression_opt:
1124        // empty
1125                { $$ = nullptr; }
1126        | comma_expression
1127        ;
1128
1129// ************************** STATEMENTS *******************************
1130
1131statement:
1132        labeled_statement
1133        | compound_statement
1134        | expression_statement
1135        | selection_statement
1136        | iteration_statement
1137        | jump_statement
1138        | with_statement
1139        | mutex_statement
1140        | waitfor_statement
1141        | waituntil_statement
1142        | exception_statement
1143        | enable_disable_statement
1144                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1145        | asm_statement
1146        | DIRECTIVE
1147                { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1148        ;
1149
1150labeled_statement:
1151                // labels cannot be identifiers 0 or 1
1152        identifier_or_type_name ':' attribute_list_opt statement
1153                { $$ = $4->add_label( yylloc, $1, $3 ); }
1154        | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1155                {
1156                        SemanticError( yylloc, ::toString( "syntx error, label \"", *$1.str, "\" must be associated with a statement, "
1157                                                                                           "where a declaration, case, or default is not a statement. "
1158                                                                                           "Move the label or terminate with a semi-colon." ) );
1159                        $$ = nullptr;
1160                }
1161        ;
1162
1163compound_statement:
1164        '{' '}'
1165                { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1166        | '{' push
1167          local_label_declaration_opt                                           // GCC, local labels appear at start of block
1168          statement_decl_list                                                           // C99, intermix declarations and statements
1169          pop '}'
1170                { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1171        ;
1172
1173statement_decl_list:                                                                    // C99
1174        statement_decl
1175        | statement_decl_list statement_decl
1176                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1177        ;
1178
1179statement_decl:
1180        declaration                                                                                     // CFA, new & old style declarations
1181                { $$ = new StatementNode( $1 ); }
1182        | EXTENSION declaration                                                         // GCC
1183                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1184        | function_definition
1185                { $$ = new StatementNode( $1 ); }
1186        | EXTENSION function_definition                                         // GCC
1187                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1188        | statement
1189        ;
1190
1191statement_list_nodecl:
1192        statement
1193        | statement_list_nodecl statement
1194                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1195        | statement_list_nodecl error                                           // invalid syntax rule
1196                { SemanticError( yylloc, "syntax error, declarations only allowed at the start of the switch body, i.e., after the '{'." ); $$ = nullptr; }
1197        ;
1198
1199expression_statement:
1200        comma_expression_opt ';'
1201                { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1202        ;
1203
1204selection_statement:
1205                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1206                        // the inherent S/R conflict with THEN/ELSE.
1207        push if_statement pop
1208                { $$ = $2; }
1209        | SWITCH '(' comma_expression ')' case_clause
1210                { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1211        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1212                {
1213                        StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1214                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1215                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1216                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1217                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1218                        // statement.
1219                        $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1220                }
1221        | SWITCH '(' comma_expression ')' '{' error '}'         // CFA, invalid syntax rule error
1222                { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1223        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1224                { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1225        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1226                {
1227                        StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1228                        $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1229                }
1230        | CHOOSE '(' comma_expression ')' '{' error '}'         // CFA, invalid syntax rule
1231                { SemanticError( yylloc, "syntax error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1232        ;
1233
1234if_statement:
1235        IF '(' conditional_declaration ')' statement            %prec THEN
1236                // explicitly deal with the shift/reduce conflict on if/else
1237                { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1238        | IF '(' conditional_declaration ')' statement ELSE statement
1239                { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1240        ;
1241
1242conditional_declaration:
1243        comma_expression
1244                { $$ = new CondCtl( nullptr, $1 ); }
1245        | c_declaration                                                                         // no semi-colon
1246                { $$ = new CondCtl( $1, nullptr ); }
1247        | cfa_declaration                                                                       // no semi-colon
1248                { $$ = new CondCtl( $1, nullptr ); }
1249        | declaration comma_expression                                          // semi-colon separated
1250                { $$ = new CondCtl( $1, $2 ); }
1251        ;
1252
1253// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1254// clause allows a list of values and subranges.
1255
1256case_value:                                                                                             // CFA
1257        constant_expression                                                     { $$ = $1; }
1258        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1259                { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1260        | subrange                                                                                      // CFA, subrange
1261        ;
1262
1263case_value_list:                                                                                // CFA
1264        case_value                                                                      { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1265                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1266        | case_value_list ',' case_value                        { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1267        ;
1268
1269case_label:                                                                                             // CFA
1270        CASE error                                                                                      // invalid syntax rule
1271                { SemanticError( yylloc, "syntax error, case list missing after case." ); $$ = nullptr; }
1272        | CASE case_value_list ':'                                      { $$ = $2; }
1273        | CASE case_value_list error                                            // invalid syntax rule
1274                { SemanticError( yylloc, "syntax error, colon missing after case list." ); $$ = nullptr; }
1275        | DEFAULT ':'                                                           { $$ = new ClauseNode( build_default( yylloc ) ); }
1276                // A semantic check is required to ensure only one default clause per switch/choose statement.
1277        | DEFAULT error                                                                         //  invalid syntax rule
1278                { SemanticError( yylloc, "syntax error, colon missing after default." ); $$ = nullptr; }
1279        ;
1280
1281case_label_list:                                                                                // CFA
1282        case_label
1283        | case_label_list case_label                            { $$ = $1->set_last( $2 ); }
1284        ;
1285
1286case_clause:                                                                                    // CFA
1287        case_label_list statement                                       { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1288        ;
1289
1290switch_clause_list_opt:                                                                 // CFA
1291        // empty
1292                { $$ = nullptr; }
1293        | switch_clause_list
1294        ;
1295
1296switch_clause_list:                                                                             // CFA
1297        case_label_list statement_list_nodecl
1298                { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1299        | switch_clause_list case_label_list statement_list_nodecl
1300                { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1301        ;
1302
1303iteration_statement:
1304        WHILE '(' ')' statement                                                         %prec THEN // CFA => while ( 1 )
1305                { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1306        | WHILE '(' ')' statement ELSE statement                        // CFA
1307                {
1308                        $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1309                        SemanticWarning( yylloc, Warning::SuperfluousElse );
1310                }
1311        | WHILE '(' conditional_declaration ')' statement       %prec THEN
1312                { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1313        | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1314                { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1315        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1316                { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1317        | DO statement WHILE '(' ')' ELSE statement                     // CFA
1318                {
1319                        $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1320                        SemanticWarning( yylloc, Warning::SuperfluousElse );
1321                }
1322        | DO statement WHILE '(' comma_expression ')' ';'
1323                { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1324        | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1325                { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1326        | FOR '(' ')' statement                                                         %prec THEN // CFA => for ( ;; )
1327                { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1328        | FOR '(' ')' statement ELSE statement                          // CFA
1329                {
1330                        $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1331                        SemanticWarning( yylloc, Warning::SuperfluousElse );
1332                }
1333        | FOR '(' for_control_expression_list ')' statement     %prec THEN
1334                { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1335        | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1336                { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1337        ;
1338
1339for_control_expression_list:
1340        for_control_expression
1341        | for_control_expression_list ':' for_control_expression
1342                // ForCtrl + ForCtrl:
1343                //    init + init => multiple declaration statements that are hoisted
1344                //    condition + condition => (expression) && (expression)
1345                //    change + change => (expression), (expression)
1346                {
1347                        $1->init->set_last( $3->init );
1348                        if ( $1->condition ) {
1349                                if ( $3->condition ) {
1350                                        $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1351                                } // if
1352                        } else $1->condition = $3->condition;
1353                        if ( $1->change ) {
1354                                if ( $3->change ) {
1355                                        $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1356                                } // if
1357                        } else $1->change = $3->change;
1358                        $$ = $1;
1359                }
1360        ;
1361
1362for_control_expression:
1363        ';' comma_expression_opt ';' comma_expression_opt
1364                { $$ = new ForCtrl( nullptr, $2, $4 ); }
1365        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1366                {
1367                        StatementNode * init = $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr;
1368                        $$ = new ForCtrl( init, $3, $5 );
1369                }
1370        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1371                { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1372
1373        | '@' ';' comma_expression                                                      // CFA, empty loop-index
1374                { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1375        | '@' ';' comma_expression ';' comma_expression         // CFA, empty loop-index
1376                { $$ = new ForCtrl( nullptr, $3, $5 ); }
1377
1378        | comma_expression                                                                      // CFA, anonymous loop-index
1379                { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1380        | downupdowneq comma_expression                                         // CFA, anonymous loop-index
1381                { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1382
1383        | comma_expression updowneq comma_expression            // CFA, anonymous loop-index
1384                { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1385        | '@' updowneq comma_expression                                         // CFA, anonymous loop-index
1386                {
1387                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1388                        else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1389                }
1390        | comma_expression updowneq '@'                                         // CFA, anonymous loop-index
1391                {
1392                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1393                        else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1394                }
1395        | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1396                { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1397        | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1398                {
1399                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1400                        else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1401                }
1402        | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1403                {
1404                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1405                        else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1406                }
1407        | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1408                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1409        | '@' updowneq '@'                                                                      // CFA, invalid syntax rule
1410                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1411        | '@' updowneq comma_expression '~' '@'                         // CFA, invalid syntax rule
1412                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1413        | comma_expression updowneq '@' '~' '@'                         // CFA, invalid syntax rule
1414                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1415        | '@' updowneq '@' '~' '@'                                                      // CFA, invalid syntax rule
1416                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1417
1418        | comma_expression ';' comma_expression                         // CFA
1419                { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1420        | comma_expression ';' downupdowneq comma_expression // CFA
1421                { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1422
1423        | comma_expression ';' comma_expression updowneq comma_expression // CFA
1424                { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1425        | comma_expression ';' '@' updowneq comma_expression // CFA
1426                {
1427                        if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1428                        else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1429                }
1430        | comma_expression ';' comma_expression updowneq '@' // CFA
1431                {
1432                        if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1433                        else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1434                        else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1435                }
1436        | comma_expression ';' '@' updowneq '@'                         // CFA, invalid syntax rule
1437                { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1438
1439        | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1440                { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1441        | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1442                {
1443                        if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1444                        else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1445                }
1446        | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1447                {
1448                        if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1449                        else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1450                        else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1451                }
1452        | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1453                { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1454        | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1455                {
1456                        if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1457                        else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1458                }
1459        | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1460                {
1461                        if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1462                        else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1463                        else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1464                }
1465        | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1466                { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1467
1468        | declaration comma_expression                                          // CFA
1469                { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1470        | declaration downupdowneq comma_expression                     // CFA
1471                { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1472
1473        | declaration comma_expression updowneq comma_expression // CFA
1474                { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1475        | declaration '@' updowneq comma_expression                     // CFA
1476                {
1477                        if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1478                        else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1479                }
1480        | declaration comma_expression updowneq '@'                     // CFA
1481                {
1482                        if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1483                        else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1484                        else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1485                }
1486
1487        | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1488                { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1489        | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1490                {
1491                        if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1492                        else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1493                }
1494        | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1495                {
1496                        if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1497                        else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1498                        else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1499                }
1500        | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1501                { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1502        | declaration '@' updowneq comma_expression '~' '@' // CFA
1503                {
1504                        if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1505                        else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1506                }
1507        | declaration comma_expression updowneq '@' '~' '@'     // CFA
1508                {
1509                        if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1510                        else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1511                        else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1512                }
1513        | declaration '@' updowneq '@' '~' '@'                          // CFA, invalid syntax rule
1514                { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1515
1516        | comma_expression ';' TYPEDEFname                                      // CFA, array type
1517                {
1518                        SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1519                        //$$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1520                }
1521        | comma_expression ';' downupdowneq TYPEDEFname         // CFA, array type
1522                {
1523                        if ( $3 == OperKinds::LEThan || $3 == OperKinds::GEThan ) {
1524                                SemanticError( yylloc, "syntax error, all enumeration ranges are equal (all values). Remove \"=~\"." ); $$ = nullptr;
1525                        }
1526                        SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1527                }
1528        ;
1529
1530downupdowneq:
1531        ErangeDown
1532                { $$ = OperKinds::GThan; }
1533        | ErangeUpEq
1534                { $$ = OperKinds::LEThan; }
1535        | ErangeDownEq
1536                { $$ = OperKinds::GEThan; }
1537        ;
1538
1539updown:
1540        '~'
1541                { $$ = OperKinds::LThan; }
1542        | ErangeDown
1543                { $$ = OperKinds::GThan; }
1544        ;
1545
1546updowneq:
1547        updown
1548        | ErangeUpEq
1549                { $$ = OperKinds::LEThan; }
1550        | ErangeDownEq
1551                { $$ = OperKinds::GEThan; }
1552        ;
1553
1554jump_statement:
1555        GOTO identifier_or_type_name ';'
1556                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1557        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1558                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1559                // whereas normal operator precedence yields goto (*i)+3;
1560                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1561                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1562        | fall_through_name ';'                                                         // CFA
1563                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1564        | fall_through_name identifier_or_type_name ';'         // CFA
1565                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1566        | fall_through_name DEFAULT ';'                                         // CFA
1567                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1568        | CONTINUE ';'
1569                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1570                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1571        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1572                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1573                // the target of the transfer appears only at the start of an iteration statement.
1574                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1575        | BREAK ';'
1576                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1577                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1578        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1579                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1580                // the target of the transfer appears only at the start of an iteration statement.
1581                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1582        | RETURN comma_expression_opt ';'
1583                { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1584        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1585                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1586        | SUSPEND ';'
1587                { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1588        | SUSPEND compound_statement
1589                { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1590        | SUSPEND COROUTINE ';'
1591                { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1592        | SUSPEND COROUTINE compound_statement
1593                { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1594        | SUSPEND GENERATOR ';'
1595                { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1596        | SUSPEND GENERATOR compound_statement
1597                { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1598        | THROW assignment_expression_opt ';'                           // handles rethrow
1599                { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1600        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1601                { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1602        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1603                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1604        ;
1605
1606fall_through_name:                                                                              // CFA
1607        FALLTHRU
1608        | FALLTHROUGH
1609        ;
1610
1611with_statement:
1612        WITH '(' tuple_expression_list ')' statement
1613                { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1614        ;
1615
1616// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1617mutex_statement:
1618        MUTEX '(' argument_expression_list_opt ')' statement
1619                {
1620                        if ( ! $3 ) { SemanticError( yylloc, "syntax error, mutex argument list cannot be empty." ); $$ = nullptr; }
1621                        $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1622                }
1623        ;
1624
1625when_clause:
1626        WHEN '(' comma_expression ')'                           { $$ = $3; }
1627        ;
1628
1629when_clause_opt:
1630        // empty
1631                { $$ = nullptr; }
1632        | when_clause
1633        ;
1634
1635cast_expression_list:
1636        cast_expression
1637        | cast_expression_list ',' cast_expression
1638                // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1639                { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1640        ;
1641
1642timeout:
1643        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1644        ;
1645
1646wor:
1647        OROR
1648        | WOR
1649
1650waitfor:
1651        WAITFOR '(' cast_expression ')'
1652                { $$ = $3; }
1653        | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1654                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1655        ;
1656
1657wor_waitfor_clause:
1658        when_clause_opt waitfor statement                                       %prec THEN
1659                // Called first: create header for WaitForStmt.
1660                { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1661        | wor_waitfor_clause wor when_clause_opt waitfor statement
1662                { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1663        | wor_waitfor_clause wor when_clause_opt ELSE statement
1664                { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1665        | wor_waitfor_clause wor when_clause_opt timeout statement      %prec THEN
1666                { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1667        // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1668        | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1669                { SemanticError( yylloc, "syntax error, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1670        | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1671                { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1672        ;
1673
1674waitfor_statement:
1675        wor_waitfor_clause                                                                      %prec THEN
1676                { $$ = new StatementNode( $1 ); }
1677        ;
1678
1679wand:
1680        ANDAND
1681        | WAND
1682        ;
1683
1684waituntil:
1685        WAITUNTIL '(' comma_expression ')'
1686                { $$ = $3; }
1687        ;
1688
1689waituntil_clause:
1690        when_clause_opt waituntil statement
1691                { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1692        | '(' wor_waituntil_clause ')'
1693                { $$ = $2; }
1694        ;
1695
1696wand_waituntil_clause:
1697        waituntil_clause                                                                        %prec THEN
1698                { $$ = $1; }
1699        | waituntil_clause wand wand_waituntil_clause
1700                { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1701        ;
1702
1703wor_waituntil_clause:
1704        wand_waituntil_clause
1705                { $$ = $1; }
1706        | wor_waituntil_clause wor wand_waituntil_clause
1707                { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1708        | wor_waituntil_clause wor when_clause_opt ELSE statement
1709                { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1710        ;
1711
1712waituntil_statement:
1713        wor_waituntil_clause                                                            %prec THEN
1714                { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1715        ;
1716
1717exception_statement:
1718        TRY compound_statement handler_clause                                   %prec THEN
1719                { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1720        | TRY compound_statement finally_clause
1721                { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1722        | TRY compound_statement handler_clause finally_clause
1723                { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1724        ;
1725
1726handler_clause:
1727        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1728                { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1729        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1730                { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1731        ;
1732
1733handler_predicate_opt:
1734        // empty
1735                { $$ = nullptr; }
1736        | ';' conditional_expression                            { $$ = $2; }
1737        ;
1738
1739handler_key:
1740        CATCH                                                                           { $$ = ast::Terminate; }
1741        | RECOVER                                                                       { $$ = ast::Terminate; }
1742        | CATCHRESUME                                                           { $$ = ast::Resume; }
1743        | FIXUP                                                                         { $$ = ast::Resume; }
1744        ;
1745
1746finally_clause:
1747        FINALLY compound_statement                                      { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1748        ;
1749
1750exception_declaration:
1751                // No SUE declaration in parameter list.
1752        type_specifier_nobody
1753        | type_specifier_nobody declarator
1754                { $$ = $2->addType( $1 ); }
1755        | type_specifier_nobody variable_abstract_declarator
1756                { $$ = $2->addType( $1 ); }
1757        | cfa_abstract_declarator_tuple identifier                      // CFA
1758                { $$ = $1->addName( $2 ); }
1759        | cfa_abstract_declarator_tuple                                         // CFA
1760        ;
1761
1762enable_disable_statement:
1763        enable_disable_key identifier_list compound_statement
1764        ;
1765
1766enable_disable_key:
1767        ENABLE
1768        | DISABLE
1769        ;
1770
1771asm_statement:
1772        ASM asm_volatile_opt '(' string_literal ')' ';'
1773                { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1774        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1775                { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1776        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1777                { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1778        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1779                { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1780        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1781                { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1782        ;
1783
1784asm_volatile_opt:                                                                               // GCC
1785        // empty
1786                { $$ = false; }
1787        | VOLATILE
1788                { $$ = true; }
1789        ;
1790
1791asm_operands_opt:                                                                               // GCC
1792        // empty
1793                { $$ = nullptr; }                                                               // use default argument
1794        | asm_operands_list
1795        ;
1796
1797asm_operands_list:                                                                              // GCC
1798        asm_operand
1799        | asm_operands_list ',' asm_operand
1800                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1801        ;
1802
1803asm_operand:                                                                                    // GCC
1804        string_literal '(' constant_expression ')'
1805                { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1806        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1807                {
1808                        $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1809                        delete $2.str;
1810                }
1811        ;
1812
1813asm_clobbers_list_opt:                                                                  // GCC
1814        // empty
1815                { $$ = nullptr; }                                                               // use default argument
1816        | string_literal
1817                { $$ = $1; }
1818        | asm_clobbers_list_opt ',' string_literal
1819                { $$ = (ExpressionNode *)( $1->set_last( $3 ) ); }
1820        ;
1821
1822label_list:
1823        identifier
1824                {
1825                        $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1826                        delete $1;                                                                      // allocated by lexer
1827                }
1828        | label_list ',' identifier
1829                {
1830                        $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1831                        delete $3;                                                                      // allocated by lexer
1832                }
1833        ;
1834
1835// ****************************** DECLARATIONS *********************************
1836
1837declaration_list_opt:                                                                   // used at beginning of switch statement
1838        // empty
1839                { $$ = nullptr; }
1840        | declaration_list
1841        ;
1842
1843declaration_list:
1844        declaration
1845        | declaration_list declaration
1846                { $$ = $1->appendList( $2 ); }
1847        ;
1848
1849KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1850        // empty
1851                { $$ = nullptr; }
1852        | KR_parameter_list
1853        ;
1854
1855KR_parameter_list:
1856        c_declaration ';'
1857                { $$ = $1; }
1858        | KR_parameter_list c_declaration ';'
1859                { $$ = $1->appendList( $2 ); }
1860        ;
1861
1862local_label_declaration_opt:                                                    // GCC, local label
1863        // empty
1864        | local_label_declaration_list
1865        ;
1866
1867local_label_declaration_list:                                                   // GCC, local label
1868        LABEL local_label_list ';'
1869        | local_label_declaration_list LABEL local_label_list ';'
1870        ;
1871
1872local_label_list:                                                                               // GCC, local label
1873        identifier_or_type_name
1874        | local_label_list ',' identifier_or_type_name
1875        ;
1876
1877declaration:                                                                                    // old & new style declarations
1878        c_declaration ';'
1879                {
1880                        // printf( "C_DECLARATION1 %p %s\n", $$, $$->name ? $$->name->c_str() : "(nil)" );
1881                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
1882                        //   printf( "\tattr %s\n", attr->name.c_str() );
1883                        // } // for
1884                }
1885        | cfa_declaration ';'                                                           // CFA
1886        | static_assert                                                                         // C11
1887        ;
1888
1889static_assert:
1890        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1891                { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1892        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1893                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
1894
1895// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1896// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1897// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1898// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1899// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1900// block, but cannot be mixed within a specific declaration.
1901//
1902//                      CFA                                     C
1903//              [10] int x;                     int x[10];              // array of 10 integers
1904//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1905
1906cfa_declaration:                                                                                // CFA
1907        cfa_variable_declaration
1908        | cfa_typedef_declaration
1909        | cfa_function_declaration
1910        | type_declaring_list
1911                { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1912        | trait_specifier
1913        ;
1914
1915cfa_variable_declaration:                                                               // CFA
1916        cfa_variable_specifier initializer_opt
1917                { $$ = $1->addInitializer( $2 ); }
1918        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1919                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1920                // them as a type_qualifier cannot appear in that context.
1921                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1922        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1923                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1924        ;
1925
1926cfa_variable_specifier:                                                                 // CFA
1927                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1928                // storage-class
1929        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1930                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1931        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1932                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1933        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1934                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1935        ;
1936
1937cfa_function_declaration:                                                               // CFA
1938        cfa_function_specifier
1939        | type_qualifier_list cfa_function_specifier
1940                { $$ = $2->addQualifiers( $1 ); }
1941        | declaration_qualifier_list cfa_function_specifier
1942                { $$ = $2->addQualifiers( $1 ); }
1943        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1944                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1945        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1946                {
1947                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1948                        DeclarationNode * ret = new DeclarationNode;
1949                        ret->type = maybeClone( $1->type->base );
1950                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1951                }
1952        ;
1953
1954cfa_function_specifier:                                                                 // CFA
1955//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1956//              {
1957//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, nullptr, true );
1958//              }
1959//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1960//              {
1961//                      typedefTable.setNextIdentifier( *$5 );
1962//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
1963//              }
1964//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1965//              {
1966//                      typedefTable.setNextIdentifier( *$5 );
1967//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
1968//              }
1969//      | '[' ']' typegen_name
1970                // identifier_or_type_name must be broken apart because of the sequence:
1971                //
1972                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1973                //   '[' ']' type_specifier
1974                //
1975                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1976                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1977        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1978                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1979                { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
1980        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1981                { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
1982        ;
1983
1984cfa_function_return:                                                                    // CFA
1985        '[' push cfa_parameter_list pop ']'
1986                { $$ = DeclarationNode::newTuple( $3 ); }
1987        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1988                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1989                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1990        ;
1991
1992cfa_typedef_declaration:                                                                // CFA
1993        TYPEDEF cfa_variable_specifier
1994                {
1995                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
1996                        $$ = $2->addTypedef();
1997                }
1998        | TYPEDEF cfa_function_specifier
1999                {
2000                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2001                        $$ = $2->addTypedef();
2002                }
2003        | cfa_typedef_declaration pop ',' push identifier
2004                {
2005                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "cfa_typedef_declaration 3" );
2006                        $$ = $1->appendList( $1->cloneType( $5 ) );
2007                }
2008        ;
2009
2010// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2011// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2012
2013typedef_declaration:
2014        TYPEDEF type_specifier declarator
2015                {
2016                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2017                        if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2018                                SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2019                        } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2020                }
2021        | typedef_declaration ',' declarator
2022                {
2023                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2024                        $$ = $1->appendList( $1->cloneBaseType( $3 )->addTypedef() );
2025                }
2026        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2027                { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2028        | type_specifier TYPEDEF declarator
2029                { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2030        | type_specifier TYPEDEF type_qualifier_list declarator
2031                { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2032        ;
2033
2034typedef_expression:
2035                // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2036        TYPEDEF identifier '=' assignment_expression
2037                {
2038                        SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2039                }
2040        | typedef_expression ',' identifier '=' assignment_expression
2041                {
2042                        SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2043                }
2044        ;
2045
2046c_declaration:
2047        declaration_specifier declaring_list
2048                { $$ = distAttr( $1, $2 ); }
2049        | typedef_declaration
2050        | typedef_expression                                                            // deprecated GCC, naming expression type
2051        | sue_declaration_specifier
2052                {
2053                        assert( $1->type );
2054                        if ( $1->type->qualifiers.any() ) {                     // CV qualifiers ?
2055                                SemanticError( yylloc, "syntax error, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2056                        }
2057                        // enums are never empty declarations because there must have at least one enumeration.
2058                        if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2059                                SemanticError( yylloc, "syntax error, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2060                        }
2061                }
2062        ;
2063
2064declaring_list:
2065                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2066                // storage-class
2067        variable_declarator asm_name_opt initializer_opt
2068                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2069        | variable_type_redeclarator asm_name_opt initializer_opt
2070                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2071
2072        | general_function_declarator asm_name_opt
2073                { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2074        | general_function_declarator asm_name_opt '=' VOID
2075                { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2076
2077        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2078                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2079        ;
2080
2081general_function_declarator:
2082        function_type_redeclarator
2083        | function_declarator
2084        ;
2085
2086declaration_specifier:                                                                  // type specifier + storage class
2087        basic_declaration_specifier
2088        | type_declaration_specifier
2089        | sue_declaration_specifier
2090        | sue_declaration_specifier invalid_types                       // invalid syntax rule
2091                {
2092                        SemanticError( yylloc, ::toString( "syntax error, expecting ';' at end of ",
2093                                $1->type->enumeration.name ? "enum" : ast::AggregateDecl::aggrString( $1->type->aggregate.kind ),
2094                                " declaration." ) );
2095                        $$ = nullptr;
2096                }
2097        ;
2098
2099invalid_types:
2100        aggregate_key
2101        | basic_type_name
2102        | indirect_type
2103        ;
2104
2105declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
2106                // Preclude SUE declarations in restricted scopes:
2107                //
2108                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2109                //
2110                // because it is impossible to call f due to name equivalence.
2111        basic_declaration_specifier
2112        | sue_declaration_specifier_nobody
2113        | type_declaration_specifier
2114        ;
2115
2116type_specifier:                                                                                 // type specifier
2117        basic_type_specifier
2118        | sue_type_specifier
2119        | type_type_specifier
2120        ;
2121
2122type_specifier_nobody:                                                                  // type specifier - {...}
2123                // Preclude SUE declarations in restricted scopes:
2124                //
2125                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2126                //
2127                // because it is impossible to call f due to name equivalence.
2128        basic_type_specifier
2129        | sue_type_specifier_nobody
2130        | type_type_specifier
2131        ;
2132
2133type_qualifier_list_opt:                                                                // GCC, used in asm_statement
2134        // empty
2135                { $$ = nullptr; }
2136        | type_qualifier_list
2137        ;
2138
2139type_qualifier_list:
2140                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2141                //
2142                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2143                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2144                // appeared only once.
2145        type_qualifier
2146        | type_qualifier_list type_qualifier
2147                { $$ = $1->addQualifiers( $2 ); }
2148        ;
2149
2150type_qualifier:
2151        type_qualifier_name
2152        | attribute                                                                                     // trick handles most atrribute locations
2153        ;
2154
2155type_qualifier_name:
2156        CONST
2157                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
2158        | RESTRICT
2159                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
2160        | VOLATILE
2161                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
2162        | ATOMIC
2163                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
2164        | forall
2165                { $$ = DeclarationNode::newForall( $1 ); }
2166        ;
2167
2168forall:
2169        FORALL '(' type_parameter_list ')'                                      // CFA
2170                { $$ = $3; }
2171        ;
2172
2173declaration_qualifier_list:
2174        storage_class_list
2175        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
2176                { $$ = $1->addQualifiers( $2 ); }
2177        | declaration_qualifier_list type_qualifier_list storage_class_list
2178                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2179        ;
2180
2181storage_class_list:
2182                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2183                // only one of each is specified, except for inline, which can appear with the others.
2184                //
2185                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2186                // specifiers in a declaration.
2187        storage_class
2188        | storage_class_list storage_class
2189                { $$ = $1->addQualifiers( $2 ); }
2190        ;
2191
2192storage_class:
2193        EXTERN
2194                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
2195        | STATIC
2196                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
2197        | AUTO
2198                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
2199        | REGISTER
2200                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
2201        | THREADLOCALGCC                                                                                // GCC
2202                { $$ = DeclarationNode::newStorageClass( Type::ThreadlocalGcc ); }
2203        | THREADLOCALC11                                                                                // C11
2204                { $$ = DeclarationNode::newStorageClass( Type::ThreadlocalC11 ); }
2205                // Put function specifiers here to simplify parsing rules, but separate them semantically.
2206        | INLINE                                                                                        // C99
2207                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
2208        | FORTRAN                                                                                       // C99
2209                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
2210        | NORETURN                                                                                      // C11
2211                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
2212        ;
2213
2214basic_type_name:
2215        VOID
2216                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2217        | BOOL                                                                                          // C99
2218                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
2219        | CHAR
2220                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
2221        | INT
2222                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
2223        | INT128
2224                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
2225        | UINT128
2226                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
2227        | FLOAT
2228                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
2229        | DOUBLE
2230                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
2231        | uuFLOAT80
2232                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
2233        | uuFLOAT128
2234                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
2235        | uFLOAT16
2236                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
2237        | uFLOAT32
2238                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
2239        | uFLOAT32X
2240                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
2241        | uFLOAT64
2242                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
2243        | uFLOAT64X
2244                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
2245        | uFLOAT128
2246                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
2247        | DECIMAL32
2248                { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2249        | DECIMAL64
2250                { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2251        | DECIMAL128
2252                { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2253        | COMPLEX                                                                                       // C99
2254                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
2255        | IMAGINARY                                                                                     // C99
2256                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
2257        | SIGNED
2258                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
2259        | UNSIGNED
2260                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
2261        | SHORT
2262                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
2263        | LONG
2264                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
2265        | VA_LIST                                                                                       // GCC, __builtin_va_list
2266                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
2267        | AUTO_TYPE
2268                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
2269        | vtable
2270        ;
2271
2272vtable_opt:
2273        // empty
2274                { $$ = nullptr; }
2275        | vtable
2276        ;
2277
2278vtable:
2279        VTABLE '(' type_name ')' default_opt
2280                { $$ = DeclarationNode::newVtableType( $3 ); }
2281                // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
2282        ;
2283
2284default_opt:
2285        // empty
2286                { $$ = nullptr; }
2287        | DEFAULT
2288                { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2289        ;
2290
2291basic_declaration_specifier:
2292                // A semantic check is necessary for conflicting storage classes.
2293        basic_type_specifier
2294        | declaration_qualifier_list basic_type_specifier
2295                { $$ = $2->addQualifiers( $1 ); }
2296        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
2297                { $$ = $1->addQualifiers( $2 ); }
2298        | basic_declaration_specifier storage_class type_qualifier_list
2299                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2300        | basic_declaration_specifier storage_class basic_type_specifier
2301                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2302        ;
2303
2304basic_type_specifier:
2305        direct_type
2306                // Cannot have type modifiers, e.g., short, long, etc.
2307        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2308                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2309        ;
2310
2311direct_type:
2312        basic_type_name
2313        | type_qualifier_list basic_type_name
2314                { $$ = $2->addQualifiers( $1 ); }
2315        | direct_type type_qualifier
2316                { $$ = $1->addQualifiers( $2 ); }
2317        | direct_type basic_type_name
2318                { $$ = $1->addType( $2 ); }
2319        ;
2320
2321indirect_type:
2322        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
2323                { $$ = $3; }
2324        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
2325                { $$ = DeclarationNode::newTypeof( $3 ); }
2326        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
2327                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2328        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
2329                { $$ = DeclarationNode::newTypeof( $3, true ); }
2330        | ZERO_T                                                                                        // CFA
2331                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
2332        | ONE_T                                                                                         // CFA
2333                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
2334        ;
2335
2336sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
2337        sue_type_specifier
2338                {
2339                        // printf( "sue_declaration_specifier %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2340                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2341                        //   printf( "\tattr %s\n", attr->name.c_str() );
2342                        // } // for
2343                }
2344        | declaration_qualifier_list sue_type_specifier
2345                { $$ = $2->addQualifiers( $1 ); }
2346        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
2347                { $$ = $1->addQualifiers( $2 ); }
2348        | sue_declaration_specifier storage_class type_qualifier_list
2349                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2350        ;
2351
2352sue_type_specifier:                                                                             // struct, union, enum + type specifier
2353        elaborated_type
2354                {
2355                        // printf( "sue_type_specifier %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2356                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2357                        //   printf( "\tattr %s\n", attr->name.c_str() );
2358                        // } // for
2359                }
2360        | type_qualifier_list
2361                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2362          elaborated_type
2363                { $$ = $3->addQualifiers( $1 ); }
2364        | sue_type_specifier type_qualifier
2365                {
2366                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2367                        $$ = $1->addQualifiers( $2 );
2368                }
2369        ;
2370
2371sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
2372        sue_type_specifier_nobody
2373        | declaration_qualifier_list sue_type_specifier_nobody
2374                { $$ = $2->addQualifiers( $1 ); }
2375        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
2376                { $$ = $1->addQualifiers( $2 ); }
2377        | sue_declaration_specifier_nobody storage_class type_qualifier_list
2378                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2379        ;
2380
2381sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
2382        elaborated_type_nobody
2383        | type_qualifier_list elaborated_type_nobody
2384                { $$ = $2->addQualifiers( $1 ); }
2385        | sue_type_specifier_nobody type_qualifier
2386                { $$ = $1->addQualifiers( $2 ); }
2387        ;
2388
2389type_declaration_specifier:
2390        type_type_specifier
2391        | declaration_qualifier_list type_type_specifier
2392                { $$ = $2->addQualifiers( $1 ); }
2393        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
2394                { $$ = $1->addQualifiers( $2 ); }
2395        | type_declaration_specifier storage_class type_qualifier_list
2396                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2397        ;
2398
2399type_type_specifier:                                                                    // typedef types
2400        type_name
2401        | type_qualifier_list type_name
2402                { $$ = $2->addQualifiers( $1 ); }
2403        | type_type_specifier type_qualifier
2404                { $$ = $1->addQualifiers( $2 ); }
2405        ;
2406
2407type_name:
2408        TYPEDEFname
2409                { $$ = DeclarationNode::newFromTypedef( $1 ); }
2410        | '.' TYPEDEFname
2411                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2412        | type_name '.' TYPEDEFname
2413                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2414        | typegen_name
2415        | '.' typegen_name
2416                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2417        | type_name '.' typegen_name
2418                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2419        ;
2420
2421typegen_name:                                                                                   // CFA
2422        TYPEGENname
2423                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2424        | TYPEGENname '(' ')'
2425                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2426        | TYPEGENname '(' type_list ')'
2427                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2428        ;
2429
2430elaborated_type:                                                                                // struct, union, enum
2431        aggregate_type
2432                {
2433                        // printf( "elaborated_type %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2434                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2435                        //   printf( "\tattr %s\n", attr->name.c_str() );
2436                        // } // for
2437                }
2438        | enum_type
2439        ;
2440
2441elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2442        aggregate_type_nobody
2443        | enum_type_nobody
2444        ;
2445
2446aggregate_type:                                                                                 // struct, union
2447        aggregate_key attribute_list_opt
2448                { forall = false; }                                                             // reset
2449          '{' field_declaration_list_opt '}' type_parameters_opt
2450                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2451        | aggregate_key attribute_list_opt identifier
2452                {
2453                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2454                        forall = false;                                                         // reset
2455                }
2456          '{' field_declaration_list_opt '}' type_parameters_opt
2457                {
2458                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2459                }
2460        | aggregate_key attribute_list_opt TYPEDEFname          // unqualified type name
2461                {
2462                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2463                        forall = false;                                                         // reset
2464                }
2465          '{' field_declaration_list_opt '}' type_parameters_opt
2466                {
2467                        DeclarationNode::newFromTypedef( $3 );
2468                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2469                }
2470        | aggregate_key attribute_list_opt TYPEGENname          // unqualified type name
2471                {
2472                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2473                        forall = false;                                                         // reset
2474                }
2475          '{' field_declaration_list_opt '}' type_parameters_opt
2476                {
2477                        DeclarationNode::newFromTypeGen( $3, nullptr );
2478                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2479                }
2480        | aggregate_type_nobody
2481        ;
2482
2483type_parameters_opt:
2484        // empty
2485                { $$ = nullptr; }                                                               %prec '}'
2486        | '(' type_list ')'
2487                { $$ = $2; }
2488        ;
2489
2490aggregate_type_nobody:                                                                  // struct, union - {...}
2491        aggregate_key attribute_list_opt identifier
2492                {
2493                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2494                        forall = false;                                                         // reset
2495                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2496                }
2497        | aggregate_key attribute_list_opt type_name
2498                {
2499                        forall = false;                                                         // reset
2500                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2501                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2502                        // delete newFromTypeGen.
2503                        if ( $3->type->kind == TypeData::SymbolicInst && ! $3->type->symbolic.isTypedef ) {
2504                                $$ = $3->addQualifiers( $2 );
2505                        } else {
2506                                $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2507                                $3->type->symbolic.name = nullptr;                      // copied to $$
2508                                $3->type->symbolic.actuals = nullptr;
2509                                delete $3;
2510                        }
2511                }
2512        ;
2513
2514aggregate_key:
2515        aggregate_data
2516        | aggregate_control
2517        ;
2518
2519aggregate_data:
2520        STRUCT vtable_opt
2521                { $$ = ast::AggregateDecl::Struct; }
2522        | UNION
2523                { $$ = ast::AggregateDecl::Union; }
2524        | EXCEPTION                                                                                     // CFA
2525                { $$ = ast::AggregateDecl::Exception; }
2526          //            { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = ast::AggregateDecl::NoAggregate; }
2527        ;
2528
2529aggregate_control:                                                                              // CFA
2530        MONITOR
2531                { $$ = ast::AggregateDecl::Monitor; }
2532        | MUTEX STRUCT
2533                { $$ = ast::AggregateDecl::Monitor; }
2534        | GENERATOR
2535                { $$ = ast::AggregateDecl::Generator; }
2536        | MUTEX GENERATOR
2537                {
2538                        SemanticError( yylloc, "monitor generator is currently unimplemented." );
2539                        $$ = ast::AggregateDecl::NoAggregate;
2540                }
2541        | COROUTINE
2542                { $$ = ast::AggregateDecl::Coroutine; }
2543        | MUTEX COROUTINE
2544                {
2545                        SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2546                        $$ = ast::AggregateDecl::NoAggregate;
2547                }
2548        | THREAD
2549                { $$ = ast::AggregateDecl::Thread; }
2550        | MUTEX THREAD
2551                {
2552                        SemanticError( yylloc, "monitor thread is currently unimplemented." );
2553                        $$ = ast::AggregateDecl::NoAggregate;
2554                }
2555        ;
2556
2557field_declaration_list_opt:
2558        // empty
2559                { $$ = nullptr; }
2560        | field_declaration_list_opt field_declaration
2561                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2562        ;
2563
2564field_declaration:
2565        type_specifier field_declaring_list_opt ';'
2566                {
2567                        // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2568                        $$ = fieldDecl( $1, $2 );
2569                        // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2570                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2571                        //   printf( "\tattr %s\n", attr->name.c_str() );
2572                        // } // for
2573                }
2574        | type_specifier field_declaring_list_opt '}'           // invalid syntax rule
2575                {
2576                        SemanticError( yylloc, ::toString( "syntax error, expecting ';' at end of previous declaration." ) );
2577                        $$ = nullptr;
2578                }
2579        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2580                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2581        | STATIC type_specifier field_declaring_list_opt ';' // CFA
2582                { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2583        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2584                {
2585                        if ( ! $3 ) {                                                           // field declarator ?
2586                                $3 = DeclarationNode::newName( nullptr );
2587                        } // if
2588                        $3->inLine = true;
2589                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2590                        distInl( $3 );
2591                }
2592        | INLINE aggregate_control ';'                                          // CFA
2593                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2594        | typedef_declaration ';'                                                       // CFA
2595        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2596        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2597                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2598        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2599                { $$ = $2; }                                                                    // mark all fields in list
2600        | cfa_typedef_declaration ';'                                           // CFA
2601        | static_assert                                                                         // C11
2602        ;
2603
2604field_declaring_list_opt:
2605        // empty
2606                { $$ = nullptr; }
2607        | field_declarator
2608        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2609                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2610        ;
2611
2612field_declarator:
2613        bit_subrange_size                                                                       // C special case, no field name
2614                { $$ = DeclarationNode::newBitfield( $1 ); }
2615        | variable_declarator bit_subrange_size_opt
2616                // A semantic check is required to ensure bit_subrange only appears on integral types.
2617                { $$ = $1->addBitfield( $2 ); }
2618        | variable_type_redeclarator bit_subrange_size_opt
2619                // A semantic check is required to ensure bit_subrange only appears on integral types.
2620                { $$ = $1->addBitfield( $2 ); }
2621        | function_type_redeclarator bit_subrange_size_opt
2622                // A semantic check is required to ensure bit_subrange only appears on integral types.
2623                { $$ = $1->addBitfield( $2 ); }
2624        ;
2625
2626field_abstract_list_opt:
2627        // empty
2628                { $$ = nullptr; }
2629        | field_abstract
2630        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2631                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2632        ;
2633
2634field_abstract:
2635                //      no bit fields
2636        variable_abstract_declarator
2637        ;
2638
2639cfa_field_declaring_list:                                                               // CFA, new style field declaration
2640        // bit-fields are handled by C declarations
2641        cfa_abstract_declarator_tuple identifier_or_type_name
2642                { $$ = $1->addName( $2 ); }
2643        | cfa_field_declaring_list ',' identifier_or_type_name
2644                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2645        ;
2646
2647cfa_field_abstract_list:                                                                // CFA, new style field declaration
2648        // bit-fields are handled by C declarations
2649        cfa_abstract_declarator_tuple
2650        | cfa_field_abstract_list ','
2651                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2652        ;
2653
2654bit_subrange_size_opt:
2655        // empty
2656                { $$ = nullptr; }
2657        | bit_subrange_size
2658        ;
2659
2660bit_subrange_size:
2661        ':' assignment_expression
2662                { $$ = $2; }
2663        ;
2664
2665enum_type:
2666        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2667                { $$ = DeclarationNode::newEnum( nullptr, $4, true, false )->addQualifiers( $2 ); }
2668        | ENUM attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2669                { SemanticError( yylloc, "syntax error, hiding '!' the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2670        | ENUM attribute_list_opt identifier
2671                { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2672          hide_opt '{' enumerator_list comma_opt '}'
2673                { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2674        | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2675                { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2676        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2677                {
2678                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.any() ) {
2679                                SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2680                        }
2681                        $$ = DeclarationNode::newEnum( nullptr, $7, true, true, $3 )->addQualifiers( $5 );
2682                }
2683        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // unqualified type name
2684                { SemanticError( yylloc, "syntax error, hiding '!' the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2685        | ENUM '(' ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2686                {
2687                        $$ = DeclarationNode::newEnum( nullptr, $6, true, true )->addQualifiers( $4 );
2688                }
2689        | ENUM '(' ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2690                { SemanticError( yylloc, "syntax error, hiding '!' the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2691        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2692                {
2693                        if ( $3 && ($3->storageClasses.any() || $3->type->qualifiers.val != 0 )) {
2694                                SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2695                        }
2696                        typedefTable.makeTypedef( *$6, "enum_type 2" );
2697                }
2698          hide_opt '{' enumerator_list comma_opt '}'
2699                {
2700                        $$ = DeclarationNode::newEnum( $6, $11, true, true, $3, $9 )->addQualifiers( $5 )->addQualifiers( $7 );
2701                }
2702        | ENUM '(' ')' attribute_list_opt identifier attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2703                {
2704                        $$ = DeclarationNode::newEnum( $5, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2705                }
2706        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2707                {
2708                        $$ = DeclarationNode::newEnum( $6->name, $10, true, true, $3, $8 )->addQualifiers( $5 )->addQualifiers( $7 );
2709                }
2710        | ENUM '(' ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2711                {
2712                        $$ = DeclarationNode::newEnum( $5->name, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2713                }
2714        | enum_type_nobody
2715        ;
2716
2717hide_opt:
2718        // empty
2719                { $$ = EnumHiding::Visible; }
2720        | '!'
2721                { $$ = EnumHiding::Hide; }
2722        ;
2723
2724enum_type_nobody:                                                                               // enum - {...}
2725        ENUM attribute_list_opt identifier
2726                {
2727                        typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2728                        $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2729                }
2730        | ENUM attribute_list_opt type_name
2731                {
2732                        typedefTable.makeTypedef( *$3->type->symbolic.name, "enum_type_nobody 2" );
2733                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2734                }
2735        ;
2736
2737enumerator_list:
2738        visible_hide_opt identifier_or_type_name enumerator_value_opt
2739                { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2740        | INLINE type_name
2741                { $$ = DeclarationNode::newEnumInLine( *$2->type->symbolic.name ); }
2742        | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2743                { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2744        | enumerator_list ',' INLINE type_name enumerator_value_opt
2745                { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( new string("inline"), nullptr ) ); }
2746        ;
2747
2748visible_hide_opt:
2749        hide_opt
2750        | '^'
2751                { $$ = EnumHiding::Visible; }
2752        ;
2753
2754enumerator_value_opt:
2755        // empty
2756                { $$ = nullptr; }
2757        | '=' constant_expression                                       { $$ = new InitializerNode( $2 ); }
2758        | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2759        // | simple_assignment_operator initializer
2760        //      { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2761        ;
2762
2763cfa_parameter_ellipsis_list_opt:                                                // CFA, abstract + real
2764        // empty
2765                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2766        | ELLIPSIS
2767                { $$ = nullptr; }
2768        | cfa_abstract_parameter_list
2769        | cfa_parameter_list
2770        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2771                { $$ = $1->appendList( $5 ); }
2772        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2773                { $$ = $1->addVarArgs(); }
2774        | cfa_parameter_list pop ',' push ELLIPSIS
2775                { $$ = $1->addVarArgs(); }
2776        ;
2777
2778cfa_parameter_list:                                                                             // CFA
2779                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2780                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2781        cfa_parameter_declaration
2782        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2783                { $$ = $1->appendList( $5 ); }
2784        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2785                { $$ = $1->appendList( $5 ); }
2786        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2787                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2788        ;
2789
2790cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2791        cfa_abstract_parameter_declaration
2792        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2793                { $$ = $1->appendList( $5 ); }
2794        ;
2795
2796parameter_type_list_opt:
2797        // empty
2798                { $$ = nullptr; }
2799        | ELLIPSIS
2800                { $$ = nullptr; }
2801        | parameter_list
2802        | parameter_list ',' ELLIPSIS
2803                { $$ = $1->addVarArgs(); }
2804        ;
2805
2806parameter_list:                                                                                 // abstract + real
2807        abstract_parameter_declaration
2808        | parameter_declaration
2809        | parameter_list ',' abstract_parameter_declaration
2810                { $$ = $1->appendList( $3 ); }
2811        | parameter_list ',' parameter_declaration
2812                { $$ = $1->appendList( $3 ); }
2813        ;
2814
2815// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2816// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2817
2818cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2819        parameter_declaration
2820        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2821                { $$ = $1->addName( $2 ); }
2822        | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2823                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2824                { $$ = $1->addName( $2 ); }
2825        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2826                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2827        | cfa_function_specifier
2828        ;
2829
2830cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2831        abstract_parameter_declaration
2832        | cfa_identifier_parameter_declarator_no_tuple
2833        | cfa_abstract_tuple
2834                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2835        | type_qualifier_list cfa_abstract_tuple
2836                { $$ = $2->addQualifiers( $1 ); }
2837        | cfa_abstract_function
2838        ;
2839
2840parameter_declaration:
2841                // No SUE declaration in parameter list.
2842        declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2843                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2844        | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2845                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2846        ;
2847
2848abstract_parameter_declaration:
2849        declaration_specifier_nobody default_initializer_opt
2850                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2851        | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2852                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2853        ;
2854
2855// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2856// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2857// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2858
2859identifier_list:                                                                                // K&R-style parameter list => no types
2860        identifier
2861                { $$ = DeclarationNode::newName( $1 ); }
2862        | identifier_list ',' identifier
2863                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2864        ;
2865
2866identifier_or_type_name:
2867        identifier
2868        | TYPEDEFname
2869        | TYPEGENname
2870        ;
2871
2872type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2873        cfa_abstract_declarator_tuple                                           // CFA
2874        | type_specifier                                                                        // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2875        | type_specifier abstract_declarator
2876                { $$ = $2->addType( $1 ); }
2877        ;
2878
2879type:                                                                                                   // typeof, assertion
2880        type_no_function
2881        | cfa_abstract_function                                                         // CFA
2882        ;
2883
2884initializer_opt:
2885        // empty
2886                { $$ = nullptr; }
2887        | simple_assignment_operator initializer        { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2888        | '=' VOID                                                                      { $$ = new InitializerNode( true ); }
2889        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2890        ;
2891
2892initializer:
2893        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2894        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2895        ;
2896
2897initializer_list_opt:
2898        // empty
2899                { $$ = nullptr; }
2900        | initializer
2901        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2902        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2903        | initializer_list_opt ',' designation initializer { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2904        ;
2905
2906// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2907// '=' to separator the designator from the initializer value, as in:
2908//
2909//              int x[10] = { [1] = 3 };
2910//
2911// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2912// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2913// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2914// shift/reduce conflicts
2915
2916designation:
2917        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2918        | identifier_at ':'                                                                     // GCC, field name
2919                { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
2920        ;
2921
2922designator_list:                                                                                // C99
2923        designator
2924        | designator_list designator
2925                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2926        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2927        ;
2928
2929designator:
2930        '.' identifier_at                                                                       // C99, field name
2931                { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
2932        | '[' push assignment_expression pop ']'                        // C99, single array element
2933                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2934                { $$ = $3; }
2935        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2936                { $$ = $3; }
2937        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2938                { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
2939        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2940                { $$ = $4; }
2941        ;
2942
2943// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2944// rather than an object-oriented type system. This required four groups of extensions:
2945//
2946// Overloading: function, data, and operator identifiers may be overloaded.
2947//
2948// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2949//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2950//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2951//
2952// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2953//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2954//
2955// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2956//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2957//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2958//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2959//     on type arguments of polymorphic functions.
2960
2961type_parameter_list:                                                                    // CFA
2962        type_parameter
2963        | type_parameter_list ',' type_parameter
2964                { $$ = $1->appendList( $3 ); }
2965        ;
2966
2967type_initializer_opt:                                                                   // CFA
2968        // empty
2969                { $$ = nullptr; }
2970        | '=' type
2971                { $$ = $2; }
2972        ;
2973
2974type_parameter:                                                                                 // CFA
2975        type_class identifier_or_type_name
2976                {
2977                        typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
2978                        if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2979                        if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2980                        if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2981                }
2982          type_initializer_opt assertion_list_opt
2983                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2984        | identifier_or_type_name new_type_class
2985                { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
2986          type_initializer_opt assertion_list_opt
2987                { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2988        | '[' identifier_or_type_name ']'
2989                {
2990                        typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
2991                        $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
2992                }
2993        // | type_specifier identifier_parameter_declarator
2994        | assertion_list
2995                { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2996        ;
2997
2998new_type_class:                                                                                 // CFA
2999        // empty
3000                { $$ = ast::TypeDecl::Otype; }
3001        | '&'
3002                { $$ = ast::TypeDecl::Dtype; }
3003        | '*'
3004                { $$ = ast::TypeDecl::DStype; }                                         // dtype + sized
3005        // | '(' '*' ')'
3006        //      { $$ = ast::TypeDecl::Ftype; }
3007        | ELLIPSIS
3008                { $$ = ast::TypeDecl::Ttype; }
3009        ;
3010
3011type_class:                                                                                             // CFA
3012        OTYPE
3013                { $$ = ast::TypeDecl::Otype; }
3014        | DTYPE
3015                { $$ = ast::TypeDecl::Dtype; }
3016        | FTYPE
3017                { $$ = ast::TypeDecl::Ftype; }
3018        | TTYPE
3019                { $$ = ast::TypeDecl::Ttype; }
3020        ;
3021
3022assertion_list_opt:                                                                             // CFA
3023        // empty
3024                { $$ = nullptr; }
3025        | assertion_list
3026        ;
3027
3028assertion_list:                                                                                 // CFA
3029        assertion
3030        | assertion_list assertion
3031                { $$ = $1->appendList( $2 ); }
3032        ;
3033
3034assertion:                                                                                              // CFA
3035        '|' identifier_or_type_name '(' type_list ')'
3036                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3037        | '|' '{' push trait_declaration_list pop '}'
3038                { $$ = $4; }
3039        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3040        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3041        ;
3042
3043type_list:                                                                                              // CFA
3044        type
3045                { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3046        | assignment_expression
3047        | type_list ',' type
3048                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3049        | type_list ',' assignment_expression
3050                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
3051        ;
3052
3053type_declaring_list:                                                                    // CFA
3054        OTYPE type_declarator
3055                { $$ = $2; }
3056        | storage_class_list OTYPE type_declarator
3057                { $$ = $3->addQualifiers( $1 ); }
3058        | type_declaring_list ',' type_declarator
3059                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
3060        ;
3061
3062type_declarator:                                                                                // CFA
3063        type_declarator_name assertion_list_opt
3064                { $$ = $1->addAssertions( $2 ); }
3065        | type_declarator_name assertion_list_opt '=' type
3066                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3067        ;
3068
3069type_declarator_name:                                                                   // CFA
3070        identifier_or_type_name
3071                {
3072                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3073                        $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3074                }
3075        | identifier_or_type_name '(' type_parameter_list ')'
3076                {
3077                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3078                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
3079                }
3080        ;
3081
3082trait_specifier:                                                                                // CFA
3083        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3084                {
3085                        SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3086                        $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3087                }
3088        | forall TRAIT identifier_or_type_name '{' '}'          // alternate
3089                { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3090        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3091                {
3092                        SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3093                        $$ = DeclarationNode::newTrait( $2, $4, $8 );
3094                }
3095        | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3096                { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3097        ;
3098
3099trait_declaration_list:                                                                 // CFA
3100        trait_declaration
3101        | trait_declaration_list pop push trait_declaration
3102                { $$ = $1->appendList( $4 ); }
3103        ;
3104
3105trait_declaration:                                                                              // CFA
3106        cfa_trait_declaring_list ';'
3107        | trait_declaring_list ';'
3108        ;
3109
3110cfa_trait_declaring_list:                                                               // CFA
3111        cfa_variable_specifier
3112        | cfa_function_specifier
3113        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3114                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
3115        ;
3116
3117trait_declaring_list:                                                                   // CFA
3118        type_specifier declarator
3119                { $$ = $2->addType( $1 ); }
3120        | trait_declaring_list pop ',' push declarator
3121                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
3122        ;
3123
3124// **************************** EXTERNAL DEFINITIONS *****************************
3125
3126translation_unit:
3127        // empty, input file
3128        | external_definition_list
3129                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
3130        ;
3131
3132external_definition_list:
3133        push external_definition pop
3134                { $$ = $2; }
3135        | external_definition_list push external_definition pop
3136                { $$ = $1 ? $1->appendList( $3 ) : $3; }
3137        ;
3138
3139external_definition_list_opt:
3140        // empty
3141                { $$ = nullptr; }
3142        | external_definition_list
3143        ;
3144
3145up:
3146                { typedefTable.up( forall ); forall = false; }
3147        ;
3148
3149down:
3150                { typedefTable.down(); }
3151        ;
3152
3153external_definition:
3154        DIRECTIVE
3155                { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3156        | declaration
3157                {
3158                        // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3159                        // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3160                        // disallowed at the moment.
3161                        if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static && $1->type && $1->type->kind == TypeData::AggregateInst ) {
3162                                if ( $1->type->aggInst.aggregate->kind == TypeData::Enum && $1->type->aggInst.aggregate->enumeration.anon ) {
3163                                        SemanticError( yylloc, "extern anonymous enumeration is currently unimplemented." ); $$ = nullptr;
3164                                } else if ( $1->type->aggInst.aggregate->aggregate.anon ) { // handles struct or union
3165                                        SemanticError( yylloc, "extern anonymous struct/union is currently unimplemented." ); $$ = nullptr;
3166                                }
3167                        }
3168                }
3169        | IDENTIFIER IDENTIFIER
3170                { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3171        | IDENTIFIER type_qualifier                                                     // invalid syntax rule
3172                { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3173        | IDENTIFIER storage_class                                                      // invalid syntax rule
3174                { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3175        | IDENTIFIER basic_type_name                                            // invalid syntax rule
3176                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3177        | IDENTIFIER TYPEDEFname                                                        // invalid syntax rule
3178                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3179        | IDENTIFIER TYPEGENname                                                        // invalid syntax rule
3180                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3181        | external_function_definition
3182        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
3183                {
3184                        distExt( $2 );                                                          // mark all fields in list
3185                        $$ = $2;
3186                }
3187        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
3188                { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3189        | EXTERN STRINGliteral
3190                {
3191                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
3192                        linkage = ast::Linkage::update( yylloc, linkage, $2 );
3193                }
3194          up external_definition down
3195                {
3196                        linkage = linkageStack.top();
3197                        linkageStack.pop();
3198                        $$ = $5;
3199                }
3200        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
3201                {
3202                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
3203                        linkage = ast::Linkage::update( yylloc, linkage, $2 );
3204                }
3205          '{' up external_definition_list_opt down '}'
3206                {
3207                        linkage = linkageStack.top();
3208                        linkageStack.pop();
3209                        $$ = $6;
3210                }
3211        // global distribution
3212        | type_qualifier_list
3213                {
3214                        if ( $1->type->qualifiers.any() ) {
3215                                SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3216                        }
3217                        if ( $1->type->forall ) forall = true;          // remember generic type
3218                }
3219          '{' up external_definition_list_opt down '}'          // CFA, namespace
3220                {
3221                        distQual( $5, $1 );
3222                        forall = false;
3223                        $$ = $5;
3224                }
3225        | declaration_qualifier_list
3226                {
3227                        if ( $1->type && $1->type->qualifiers.any() ) {
3228                                SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3229                        }
3230                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3231                }
3232          '{' up external_definition_list_opt down '}'          // CFA, namespace
3233                {
3234                        distQual( $5, $1 );
3235                        forall = false;
3236                        $$ = $5;
3237                }
3238        | declaration_qualifier_list type_qualifier_list
3239                {
3240                        if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3241                                SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3242                        }
3243                        if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3244                }
3245          '{' up external_definition_list_opt down '}'          // CFA, namespace
3246                {
3247                        distQual( $6, $1->addQualifiers( $2 ) );
3248                        forall = false;
3249                        $$ = $6;
3250                }
3251        ;
3252
3253external_function_definition:
3254        function_definition
3255                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3256                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3257                // Parsing is possible because function_definition does not appear in the context of an expression (nested
3258                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3259                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
3260        | function_declarator compound_statement
3261                { $$ = $1->addFunctionBody( $2 ); }
3262        | KR_function_declarator KR_parameter_list_opt compound_statement
3263                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3264        ;
3265
3266with_clause_opt:
3267        // empty
3268                { $$ = nullptr; forall = false; }
3269        | WITH '(' tuple_expression_list ')' attribute_list_opt
3270                {
3271                        $$ = $3; forall = false;
3272                        if ( $5 ) {
3273                                SemanticError( yylloc, "syntax error, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3274                                $$ = nullptr;
3275                        } // if
3276                }
3277        ;
3278
3279function_definition:
3280        cfa_function_declaration with_clause_opt compound_statement     // CFA
3281                {
3282                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
3283                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3284                        $1->get_last()->addFunctionBody( $3, $2 );
3285                        $$ = $1;
3286                }
3287        | declaration_specifier function_declarator with_clause_opt compound_statement
3288                {
3289                        rebindForall( $1, $2 );
3290                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3291                }
3292        | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3293                {
3294                        rebindForall( $1, $2 );
3295                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3296                }
3297                // handles default int return type, OBSOLESCENT (see 1)
3298        | type_qualifier_list function_declarator with_clause_opt compound_statement
3299                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3300                // handles default int return type, OBSOLESCENT (see 1)
3301        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3302                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3303                // handles default int return type, OBSOLESCENT (see 1)
3304        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3305                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3306
3307                // Old-style K&R function definition, OBSOLESCENT (see 4)
3308        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3309                {
3310                        rebindForall( $1, $2 );
3311                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3312                }
3313                // handles default int return type, OBSOLESCENT (see 1)
3314        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3315                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3316                // handles default int return type, OBSOLESCENT (see 1)
3317        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3318                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3319                // handles default int return type, OBSOLESCENT (see 1)
3320        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3321                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3322        ;
3323
3324declarator:
3325        variable_declarator
3326        | variable_type_redeclarator
3327        | function_declarator
3328        | function_type_redeclarator
3329        ;
3330
3331subrange:
3332        constant_expression '~' constant_expression                     // CFA, integer subrange
3333                { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3334        ;
3335
3336asm_name_opt:                                                                                   // GCC
3337        // empty
3338                { $$ = nullptr; }
3339        | ASM '(' string_literal ')' attribute_list_opt
3340                {
3341                        DeclarationNode * name = new DeclarationNode();
3342                        name->asmName = maybeMoveBuild( $3 );
3343                        $$ = name->addQualifiers( $5 );
3344                }
3345        ;
3346
3347attribute_list_opt:                                                                             // GCC
3348        // empty
3349                { $$ = nullptr; }
3350        | attribute_list
3351        ;
3352
3353attribute_list:                                                                                 // GCC
3354        attribute
3355        | attribute_list attribute
3356                { $$ = $2->addQualifiers( $1 ); }
3357        ;
3358
3359attribute:                                                                                              // GCC
3360        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3361                { $$ = $4; }
3362        ;
3363
3364attribute_name_list:                                                                    // GCC
3365        attribute_name
3366        | attribute_name_list ',' attribute_name
3367                { $$ = $3->addQualifiers( $1 ); }
3368        ;
3369
3370attribute_name:                                                                                 // GCC
3371        // empty
3372                { $$ = nullptr; }
3373        | attr_name
3374                { $$ = DeclarationNode::newAttribute( $1 ); }
3375        | attr_name '(' argument_expression_list_opt ')'
3376                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3377        ;
3378
3379attr_name:                                                                                              // GCC
3380        IDENTIFIER
3381        | quasi_keyword
3382        | TYPEDEFname
3383        | TYPEGENname
3384        | FALLTHROUGH
3385                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3386        | CONST
3387                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3388        ;
3389
3390// ============================================================================
3391// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3392// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3393// in:
3394//
3395//              int (*f())[10] { ... };
3396//              ... (*f())[3] += 1;             // definition mimics usage
3397//
3398// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3399// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3400// ============================================================================
3401
3402// ----------------------------------------------------------------------------
3403// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3404// to define a variable or function prototype, e.g.:
3405//
3406//              valid declaration               invalid definition
3407//              -----------------               ------------------
3408//              int f;                                  int f {}
3409//              int *f;                                 int *f {}
3410//              int f[10];                              int f[10] {}
3411//              int (*f)(int);                  int (*f)(int) {}
3412//
3413// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3414// variable_declarator and function_declarator.
3415// ----------------------------------------------------------------------------
3416
3417// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3418// declaring an array of functions versus a pointer to an array of functions.
3419
3420paren_identifier:
3421        identifier_at
3422                { $$ = DeclarationNode::newName( $1 ); }
3423        | '(' paren_identifier ')'                                                      // redundant parenthesis
3424                { $$ = $2; }
3425        ;
3426
3427variable_declarator:
3428        paren_identifier attribute_list_opt
3429                { $$ = $1->addQualifiers( $2 ); }
3430        | variable_ptr
3431        | variable_array attribute_list_opt
3432                { $$ = $1->addQualifiers( $2 ); }
3433        | variable_function attribute_list_opt
3434                { $$ = $1->addQualifiers( $2 ); }
3435        ;
3436
3437variable_ptr:
3438        ptrref_operator variable_declarator
3439                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3440        | ptrref_operator type_qualifier_list variable_declarator
3441                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3442        | '(' variable_ptr ')' attribute_list_opt                       // redundant parenthesis
3443                { $$ = $2->addQualifiers( $4 ); }
3444        | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3445                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3446        ;
3447
3448variable_array:
3449        paren_identifier array_dimension
3450                { $$ = $1->addArray( $2 ); }
3451        | '(' variable_ptr ')' array_dimension
3452                { $$ = $2->addArray( $4 ); }
3453        | '(' attribute_list variable_ptr ')' array_dimension
3454                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3455        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
3456                { $$ = $2->addArray( $4 ); }
3457        | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3458                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3459        | '(' variable_array ')'                                                        // redundant parenthesis
3460                { $$ = $2; }
3461        | '(' attribute_list variable_array ')'                         // redundant parenthesis
3462                { $$ = $3->addQualifiers( $2 ); }
3463        ;
3464
3465variable_function:
3466        '(' variable_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3467                { $$ = $2->addParamList( $5 ); }
3468        | '(' attribute_list variable_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3469                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3470        | '(' variable_function ')'                                                     // redundant parenthesis
3471                { $$ = $2; }
3472        | '(' attribute_list variable_function ')'                      // redundant parenthesis
3473                { $$ = $3->addQualifiers( $2 ); }
3474        ;
3475
3476// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3477// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3478// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3479
3480function_declarator:
3481        function_no_ptr attribute_list_opt
3482                { $$ = $1->addQualifiers( $2 ); }
3483        | function_ptr
3484        | function_array attribute_list_opt
3485                { $$ = $1->addQualifiers( $2 ); }
3486        ;
3487
3488function_no_ptr:
3489        paren_identifier '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3490                { $$ = $1->addParamList( $3 ); }
3491        | '(' function_ptr ')' '(' parameter_type_list_opt ')'
3492                { $$ = $2->addParamList( $5 ); }
3493        | '(' attribute_list function_ptr ')' '(' parameter_type_list_opt ')'
3494                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3495        | '(' function_no_ptr ')'                                                       // redundant parenthesis
3496                { $$ = $2; }
3497        | '(' attribute_list function_no_ptr ')'                        // redundant parenthesis
3498                { $$ = $3->addQualifiers( $2 ); }
3499        ;
3500
3501function_ptr:
3502        ptrref_operator function_declarator
3503                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3504        | ptrref_operator type_qualifier_list function_declarator
3505                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3506        | '(' function_ptr ')' attribute_list_opt
3507                { $$ = $2->addQualifiers( $4 ); }
3508        | '(' attribute_list function_ptr ')' attribute_list_opt
3509                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3510        ;
3511
3512function_array:
3513        '(' function_ptr ')' array_dimension
3514                { $$ = $2->addArray( $4 ); }
3515        | '(' attribute_list function_ptr ')' array_dimension
3516                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3517        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
3518                { $$ = $2->addArray( $4 ); }
3519        | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3520                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3521        | '(' function_array ')'                                                        // redundant parenthesis
3522                { $$ = $2; }
3523        | '(' attribute_list function_array ')'                         // redundant parenthesis
3524                { $$ = $3->addQualifiers( $2 ); }
3525        ;
3526
3527// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3528//
3529//   f( a, b, c ) int a, *b, c[]; {}
3530//
3531// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3532// returning arrays and functions versus pointers to arrays and functions.
3533
3534KR_function_declarator:
3535        KR_function_no_ptr
3536        | KR_function_ptr
3537        | KR_function_array
3538        ;
3539
3540KR_function_no_ptr:
3541        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
3542                { $$ = $1->addIdList( $3 ); }
3543        | '(' KR_function_ptr ')' '(' parameter_type_list_opt ')'
3544                { $$ = $2->addParamList( $5 ); }
3545        | '(' attribute_list KR_function_ptr ')' '(' parameter_type_list_opt ')'
3546                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3547        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
3548                { $$ = $2; }
3549        | '(' attribute_list KR_function_no_ptr ')'                     // redundant parenthesis
3550                { $$ = $3->addQualifiers( $2 ); }
3551        ;
3552
3553KR_function_ptr:
3554        ptrref_operator KR_function_declarator
3555                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3556        | ptrref_operator type_qualifier_list KR_function_declarator
3557                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3558        | '(' KR_function_ptr ')'
3559                { $$ = $2; }
3560        | '(' attribute_list KR_function_ptr ')'
3561                { $$ = $3->addQualifiers( $2 ); }
3562        ;
3563
3564KR_function_array:
3565        '(' KR_function_ptr ')' array_dimension
3566                { $$ = $2->addArray( $4 ); }
3567        | '(' attribute_list KR_function_ptr ')' array_dimension
3568                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3569        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
3570                { $$ = $2->addArray( $4 ); }
3571        | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3572                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3573        | '(' KR_function_array ')'                                                     // redundant parenthesis
3574                { $$ = $2; }
3575        | '(' attribute_list KR_function_array ')'                      // redundant parenthesis
3576                { $$ = $3->addQualifiers( $2 ); }
3577        ;
3578
3579// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3580//
3581//              typedef int foo;
3582//              {
3583//                 int foo; // redefine typedef name in new scope
3584//              }
3585
3586paren_type:
3587        typedef_name
3588                {
3589                        // hide type name in enclosing scope by variable name
3590                        typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3591                }
3592        | '(' paren_type ')'
3593                { $$ = $2; }
3594        ;
3595
3596variable_type_redeclarator:
3597        paren_type attribute_list_opt
3598                { $$ = $1->addQualifiers( $2 ); }
3599        | variable_type_ptr
3600        | variable_type_array attribute_list_opt
3601                { $$ = $1->addQualifiers( $2 ); }
3602        | variable_type_function attribute_list_opt
3603                { $$ = $1->addQualifiers( $2 ); }
3604        ;
3605
3606variable_type_ptr:
3607        ptrref_operator variable_type_redeclarator
3608                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3609        | ptrref_operator type_qualifier_list variable_type_redeclarator
3610                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3611        | '(' variable_type_ptr ')' attribute_list_opt          // redundant parenthesis
3612                { $$ = $2->addQualifiers( $4 ); }
3613        | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3614                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3615        ;
3616
3617variable_type_array:
3618        paren_type array_dimension
3619                { $$ = $1->addArray( $2 ); }
3620        | '(' variable_type_ptr ')' array_dimension
3621                { $$ = $2->addArray( $4 ); }
3622        | '(' attribute_list variable_type_ptr ')' array_dimension
3623                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3624        | '(' variable_type_array ')' multi_array_dimension     // redundant parenthesis
3625                { $$ = $2->addArray( $4 ); }
3626        | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3627                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3628        | '(' variable_type_array ')'                                           // redundant parenthesis
3629                { $$ = $2; }
3630        | '(' attribute_list variable_type_array ')'            // redundant parenthesis
3631                { $$ = $3->addQualifiers( $2 ); }
3632        ;
3633
3634variable_type_function:
3635        '(' variable_type_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3636                { $$ = $2->addParamList( $5 ); }
3637        | '(' attribute_list variable_type_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3638                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3639        | '(' variable_type_function ')'                                        // redundant parenthesis
3640                { $$ = $2; }
3641        | '(' attribute_list variable_type_function ')'         // redundant parenthesis
3642                { $$ = $3->addQualifiers( $2 ); }
3643        ;
3644
3645// This pattern parses a declaration for a function prototype that redefines a type name.  It precludes declaring an
3646// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3647// arrays and functions.
3648
3649function_type_redeclarator:
3650        function_type_no_ptr attribute_list_opt
3651                { $$ = $1->addQualifiers( $2 ); }
3652        | function_type_ptr
3653        | function_type_array attribute_list_opt
3654                { $$ = $1->addQualifiers( $2 ); }
3655        ;
3656
3657function_type_no_ptr:
3658        paren_type '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3659                { $$ = $1->addParamList( $3 ); }
3660        | '(' function_type_ptr ')' '(' parameter_type_list_opt ')'
3661                { $$ = $2->addParamList( $5 ); }
3662        | '(' attribute_list function_type_ptr ')' '(' parameter_type_list_opt ')'
3663                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3664        | '(' function_type_no_ptr ')'                                          // redundant parenthesis
3665                { $$ = $2; }
3666        | '(' attribute_list function_type_no_ptr ')'           // redundant parenthesis
3667                { $$ = $3->addQualifiers( $2 ); }
3668        ;
3669
3670function_type_ptr:
3671        ptrref_operator function_type_redeclarator
3672                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3673        | ptrref_operator type_qualifier_list function_type_redeclarator
3674                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3675        | '(' function_type_ptr ')' attribute_list_opt
3676                { $$ = $2->addQualifiers( $4 ); }
3677        | '(' attribute_list function_type_ptr ')' attribute_list_opt
3678                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3679        ;
3680
3681function_type_array:
3682        '(' function_type_ptr ')' array_dimension
3683                { $$ = $2->addArray( $4 ); }
3684        | '(' attribute_list function_type_ptr ')' array_dimension
3685                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3686        | '(' function_type_array ')' multi_array_dimension     // redundant parenthesis
3687                { $$ = $2->addArray( $4 ); }
3688        | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3689                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3690        | '(' function_type_array ')'                                           // redundant parenthesis
3691                { $$ = $2; }
3692        | '(' attribute_list function_type_array ')'            // redundant parenthesis
3693                { $$ = $3->addQualifiers( $2 ); }
3694        ;
3695
3696// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3697// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
3698// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3699// pointers to arrays and functions.
3700
3701identifier_parameter_declarator:
3702        paren_identifier attribute_list_opt
3703                { $$ = $1->addQualifiers( $2 ); }
3704        | '&' MUTEX paren_identifier attribute_list_opt
3705                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3706        | identifier_parameter_ptr
3707        | identifier_parameter_array attribute_list_opt
3708                { $$ = $1->addQualifiers( $2 ); }
3709        | identifier_parameter_function attribute_list_opt
3710                { $$ = $1->addQualifiers( $2 ); }
3711        ;
3712
3713identifier_parameter_ptr:
3714        ptrref_operator identifier_parameter_declarator
3715                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3716        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3717                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3718        | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3719                { $$ = $2->addQualifiers( $4 ); }
3720        ;
3721
3722identifier_parameter_array:
3723        paren_identifier array_parameter_dimension
3724                { $$ = $1->addArray( $2 ); }
3725        | '(' identifier_parameter_ptr ')' array_dimension
3726                { $$ = $2->addArray( $4 ); }
3727        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3728                { $$ = $2->addArray( $4 ); }
3729        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3730                { $$ = $2; }
3731        ;
3732
3733identifier_parameter_function:
3734        paren_identifier '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3735                { $$ = $1->addParamList( $3 ); }
3736        | '(' identifier_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3737                { $$ = $2->addParamList( $5 ); }
3738        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3739                { $$ = $2; }
3740        ;
3741
3742// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3743// e.g.:
3744//
3745//              typedef int foo;
3746//              forall( otype T ) struct foo;
3747//              int f( int foo ); // redefine typedef name in new scope
3748//
3749// and allows the C99 array options, which can only appear in a parameter list.
3750
3751type_parameter_redeclarator:
3752        typedef_name attribute_list_opt
3753                { $$ = $1->addQualifiers( $2 ); }
3754        | '&' MUTEX typedef_name attribute_list_opt
3755                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3756        | type_parameter_ptr
3757        | type_parameter_array attribute_list_opt
3758                { $$ = $1->addQualifiers( $2 ); }
3759        | type_parameter_function attribute_list_opt
3760                { $$ = $1->addQualifiers( $2 ); }
3761        ;
3762
3763typedef_name:
3764        TYPEDEFname
3765                { $$ = DeclarationNode::newName( $1 ); }
3766        | TYPEGENname
3767                { $$ = DeclarationNode::newName( $1 ); }
3768        ;
3769
3770type_parameter_ptr:
3771        ptrref_operator type_parameter_redeclarator
3772                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3773        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3774                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3775        | '(' type_parameter_ptr ')' attribute_list_opt         // redundant parenthesis
3776                { $$ = $2->addQualifiers( $4 ); }
3777        ;
3778
3779type_parameter_array:
3780        typedef_name array_parameter_dimension
3781                { $$ = $1->addArray( $2 ); }
3782        | '(' type_parameter_ptr ')' array_parameter_dimension
3783                { $$ = $2->addArray( $4 ); }
3784        ;
3785
3786type_parameter_function:
3787        typedef_name '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3788                { $$ = $1->addParamList( $3 ); }
3789        | '(' type_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3790                { $$ = $2->addParamList( $5 ); }
3791        ;
3792
3793// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3794// which the type applies, e.g.:
3795//
3796//              sizeof( int );
3797//              sizeof( int * );
3798//              sizeof( int [10] );
3799//              sizeof( int (*)() );
3800//              sizeof( int () );
3801//
3802// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3803// and functions versus pointers to arrays and functions.
3804
3805abstract_declarator:
3806        abstract_ptr
3807        | abstract_array attribute_list_opt
3808                { $$ = $1->addQualifiers( $2 ); }
3809        | abstract_function attribute_list_opt
3810                { $$ = $1->addQualifiers( $2 ); }
3811        ;
3812
3813abstract_ptr:
3814        ptrref_operator
3815                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3816        | ptrref_operator type_qualifier_list
3817                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3818        | ptrref_operator abstract_declarator
3819                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3820        | ptrref_operator type_qualifier_list abstract_declarator
3821                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3822        | '(' abstract_ptr ')' attribute_list_opt
3823                { $$ = $2->addQualifiers( $4 ); }
3824        ;
3825
3826abstract_array:
3827        array_dimension
3828        | '(' abstract_ptr ')' array_dimension
3829                { $$ = $2->addArray( $4 ); }
3830        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3831                { $$ = $2->addArray( $4 ); }
3832        | '(' abstract_array ')'                                                        // redundant parenthesis
3833                { $$ = $2; }
3834        ;
3835
3836abstract_function:
3837        '(' parameter_type_list_opt ')'                 // empty parameter list OBSOLESCENT (see 3)
3838                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3839        | '(' abstract_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3840                { $$ = $2->addParamList( $5 ); }
3841        | '(' abstract_function ')'                                                     // redundant parenthesis
3842                { $$ = $2; }
3843        ;
3844
3845array_dimension:
3846                // Only the first dimension can be empty.
3847        '[' ']'
3848                { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3849        | '[' ']' multi_array_dimension
3850                { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3851                // Cannot use constant_expression because of tuples => semantic check
3852        | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3853                { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3854                // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3855        | '[' push array_type_list pop ']'                                      // CFA
3856                { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3857        | '[' push INLINE enum_type_nobody pop']'
3858                {       
3859                        $$ = DeclarationNode::newInlineEnumeratedArray( $4, nullptr );
3860                }
3861        | multi_array_dimension
3862        ;
3863
3864array_type_list:
3865        basic_type_name
3866                { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3867        | type_name
3868                { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3869        | assignment_expression upupeq assignment_expression
3870        | array_type_list ',' basic_type_name
3871                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3872        | array_type_list ',' type_name
3873                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3874        | array_type_list ',' assignment_expression upupeq assignment_expression
3875        ;
3876
3877upupeq:
3878        '~'
3879                { $$ = OperKinds::LThan; }
3880        | ErangeUpEq
3881                { $$ = OperKinds::LEThan; }
3882        ;
3883
3884multi_array_dimension:
3885        '[' push assignment_expression pop ']'
3886                { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3887        | '[' push '*' pop ']'                                                          // C99
3888                { $$ = DeclarationNode::newVarArray( 0 ); }
3889        | multi_array_dimension '[' push assignment_expression pop ']'
3890                { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
3891        | multi_array_dimension '[' push '*' pop ']'            // C99
3892                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3893        ;
3894
3895// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3896// identifier to which the type applies, e.g.:
3897//
3898//              int f( int );                   // not handled here
3899//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3900//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3901//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3902//
3903// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3904// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3905// special meaning of parenthesis around a typedef name:
3906//
3907//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3908//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3909//              not as redundant parentheses around the identifier."
3910//
3911// For example:
3912//
3913//              typedef float T;
3914//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3915//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3916//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3917//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3918//
3919// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3920// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3921// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3922// functions.
3923
3924abstract_parameter_declarator_opt:
3925        // empty
3926                { $$ = nullptr; }
3927        | abstract_parameter_declarator
3928        ;
3929
3930abstract_parameter_declarator:
3931        abstract_parameter_ptr
3932        | '&' MUTEX attribute_list_opt
3933                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3934        | abstract_parameter_array attribute_list_opt
3935                { $$ = $1->addQualifiers( $2 ); }
3936        | abstract_parameter_function attribute_list_opt
3937                { $$ = $1->addQualifiers( $2 ); }
3938        ;
3939
3940abstract_parameter_ptr:
3941        ptrref_operator
3942                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3943        | ptrref_operator type_qualifier_list
3944                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3945        | ptrref_operator abstract_parameter_declarator
3946                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3947        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3948                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3949        | '(' abstract_parameter_ptr ')' attribute_list_opt     // redundant parenthesis
3950                { $$ = $2->addQualifiers( $4 ); }
3951        ;
3952
3953abstract_parameter_array:
3954        array_parameter_dimension
3955        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3956                { $$ = $2->addArray( $4 ); }
3957        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3958                { $$ = $2->addArray( $4 ); }
3959        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3960                { $$ = $2; }
3961        ;
3962
3963abstract_parameter_function:
3964        '(' parameter_type_list_opt ')'                 // empty parameter list OBSOLESCENT (see 3)
3965                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3966        | '(' abstract_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3967                { $$ = $2->addParamList( $5 ); }
3968        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3969                { $$ = $2; }
3970        ;
3971
3972array_parameter_dimension:
3973                // Only the first dimension can be empty or have qualifiers.
3974        array_parameter_1st_dimension
3975        | array_parameter_1st_dimension multi_array_dimension
3976                { $$ = $1->addArray( $2 ); }
3977        | multi_array_dimension
3978        ;
3979
3980// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3981//
3982//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3983//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3984
3985array_parameter_1st_dimension:
3986        '[' ']'
3987                { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3988                // multi_array_dimension handles the '[' '*' ']' case
3989        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3990                { $$ = DeclarationNode::newVarArray( $3 ); }
3991        | '[' push type_qualifier_list pop ']'
3992                { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
3993                // multi_array_dimension handles the '[' assignment_expression ']' case
3994        | '[' push type_qualifier_list assignment_expression pop ']'
3995                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3996        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3997                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3998        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3999                { $$ = DeclarationNode::newArray( $5, $3, true ); }
4000        ;
4001
4002// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4003//
4004//   struct S {
4005//       int;
4006//       int *;
4007//       int [10];
4008//       int (*)();
4009//   };
4010
4011variable_abstract_declarator:
4012        variable_abstract_ptr
4013        | variable_abstract_array attribute_list_opt
4014                { $$ = $1->addQualifiers( $2 ); }
4015        | variable_abstract_function attribute_list_opt
4016                { $$ = $1->addQualifiers( $2 ); }
4017        ;
4018
4019variable_abstract_ptr:
4020        ptrref_operator
4021                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4022        | ptrref_operator type_qualifier_list
4023                { $$ = DeclarationNode::newPointer( $2, $1 ); }
4024        | ptrref_operator variable_abstract_declarator
4025                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4026        | ptrref_operator type_qualifier_list variable_abstract_declarator
4027                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4028        | '(' variable_abstract_ptr ')' attribute_list_opt      // redundant parenthesis
4029                { $$ = $2->addQualifiers( $4 ); }
4030        ;
4031
4032variable_abstract_array:
4033        array_dimension
4034        | '(' variable_abstract_ptr ')' array_dimension
4035                { $$ = $2->addArray( $4 ); }
4036        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4037                { $$ = $2->addArray( $4 ); }
4038        | '(' variable_abstract_array ')'                                       // redundant parenthesis
4039                { $$ = $2; }
4040        ;
4041
4042variable_abstract_function:
4043        '(' variable_abstract_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
4044                { $$ = $2->addParamList( $5 ); }
4045        | '(' variable_abstract_function ')'                            // redundant parenthesis
4046                { $$ = $2; }
4047        ;
4048
4049// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4050// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4051
4052cfa_identifier_parameter_declarator_tuple:                              // CFA
4053        cfa_identifier_parameter_declarator_no_tuple
4054        | cfa_abstract_tuple
4055        | type_qualifier_list cfa_abstract_tuple
4056                { $$ = $2->addQualifiers( $1 ); }
4057        ;
4058
4059cfa_identifier_parameter_declarator_no_tuple:                   // CFA
4060        cfa_identifier_parameter_ptr
4061        | cfa_identifier_parameter_array
4062        ;
4063
4064cfa_identifier_parameter_ptr:                                                   // CFA
4065                // No SUE declaration in parameter list.
4066        ptrref_operator type_specifier_nobody
4067                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4068        | type_qualifier_list ptrref_operator type_specifier_nobody
4069                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4070        | ptrref_operator cfa_abstract_function
4071                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4072        | type_qualifier_list ptrref_operator cfa_abstract_function
4073                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4074        | ptrref_operator cfa_identifier_parameter_declarator_tuple
4075                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4076        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4077                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4078        ;
4079
4080cfa_identifier_parameter_array:                                                 // CFA
4081                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4082                // shift/reduce conflict with new-style empty (void) function return type.
4083        '[' ']' type_specifier_nobody
4084                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4085        | cfa_array_parameter_1st_dimension type_specifier_nobody
4086                { $$ = $2->addNewArray( $1 ); }
4087        | '[' ']' multi_array_dimension type_specifier_nobody
4088                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4089        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4090                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4091        | multi_array_dimension type_specifier_nobody
4092                { $$ = $2->addNewArray( $1 ); }
4093
4094        | '[' ']' cfa_identifier_parameter_ptr
4095                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4096        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4097                { $$ = $2->addNewArray( $1 ); }
4098        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4099                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4100        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4101                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4102        | multi_array_dimension cfa_identifier_parameter_ptr
4103                { $$ = $2->addNewArray( $1 ); }
4104        ;
4105
4106cfa_array_parameter_1st_dimension:
4107        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
4108                { $$ = DeclarationNode::newVarArray( $3 ); }
4109        | '[' push type_qualifier_list assignment_expression pop ']'
4110                { $$ = DeclarationNode::newArray( $4, $3, false ); }
4111        | '[' push declaration_qualifier_list assignment_expression pop ']'
4112                // declaration_qualifier_list must be used because of shift/reduce conflict with
4113                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4114                // appear in this context.
4115                { $$ = DeclarationNode::newArray( $4, $3, true ); }
4116        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4117                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4118        ;
4119
4120// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4121// identifier to which the type applies, e.g.:
4122//
4123//              [int] f( int );                         // abstract variable parameter; no parameter name specified
4124//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
4125//
4126// These rules need LR(3):
4127//
4128//              cfa_abstract_tuple identifier_or_type_name
4129//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
4130//
4131// since a function return type can be syntactically identical to a tuple type:
4132//
4133//              [int, int] t;
4134//              [int, int] f( int );
4135//
4136// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4137// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4138// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4139// duplicated when appearing with cfa_function_specifier.
4140
4141cfa_abstract_declarator_tuple:                                                  // CFA
4142        cfa_abstract_tuple
4143        | type_qualifier_list cfa_abstract_tuple
4144                { $$ = $2->addQualifiers( $1 ); }
4145        | cfa_abstract_declarator_no_tuple
4146        ;
4147
4148cfa_abstract_declarator_no_tuple:                                               // CFA
4149        cfa_abstract_ptr
4150        | cfa_abstract_array
4151        ;
4152
4153cfa_abstract_ptr:                                                                               // CFA
4154        ptrref_operator type_specifier
4155                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4156        | type_qualifier_list ptrref_operator type_specifier
4157                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4158        | ptrref_operator cfa_abstract_function
4159                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4160        | type_qualifier_list ptrref_operator cfa_abstract_function
4161                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4162        | ptrref_operator cfa_abstract_declarator_tuple
4163                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4164        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4165                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4166        ;
4167
4168cfa_abstract_array:                                                                             // CFA
4169                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4170                // empty (void) function return type.
4171        '[' ']' type_specifier
4172                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4173        | '[' ']' multi_array_dimension type_specifier
4174                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4175        | multi_array_dimension type_specifier
4176                { $$ = $2->addNewArray( $1 ); }
4177        | '[' ']' cfa_abstract_ptr
4178                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4179        | '[' ']' multi_array_dimension cfa_abstract_ptr
4180                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4181        | multi_array_dimension cfa_abstract_ptr
4182                { $$ = $2->addNewArray( $1 ); }
4183        ;
4184
4185cfa_abstract_tuple:                                                                             // CFA
4186        '[' push cfa_abstract_parameter_list pop ']'
4187                { $$ = DeclarationNode::newTuple( $3 ); }
4188        | '[' push type_specifier_nobody ELLIPSIS pop ']'
4189                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4190        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4191                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4192        ;
4193
4194cfa_abstract_function:                                                                  // CFA
4195//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
4196//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4197        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
4198                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4199        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
4200                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4201        ;
4202
4203// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4204//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4205//
4206// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4207//    the declaration specifiers in a declaration is an obsolescent feature."
4208//
4209// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4210//    prototype-format parameter type declarators) is an obsolescent feature."
4211//
4212// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4213//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4214
4215// ************************ MISCELLANEOUS ********************************
4216
4217comma_opt:                                                                                              // redundant comma
4218        // empty
4219        | ','
4220        ;
4221
4222default_initializer_opt:
4223        // empty
4224                { $$ = nullptr; }
4225        | '=' assignment_expression
4226                { $$ = $2; }
4227        ;
4228
4229%%
4230
4231// ----end of grammar----
4232
4233// Local Variables: //
4234// mode: c++ //
4235// tab-width: 4 //
4236// compile-command: "make install" //
4237// End: //
Note: See TracBrowser for help on using the repository browser.