source: src/Parser/parser.yy @ 9a705dc8

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerwith_gc
Last change on this file since 9a705dc8 was 9a705dc8, checked in by Rob Schluntz <rschlunt@…>, 4 years ago

Implement concurrency keyword casts

  • Property mode set to 100644
File size: 122.3 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Tue Apr 17 17:10:30 2018
13// Update Count     : 3144
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        //cur->addType( specifier );
102        for ( cur = dynamic_cast< DeclarationNode * >( cur->get_next() ); cur != nullptr; cur = dynamic_cast< DeclarationNode * >( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106//      delete cl;
107        return declList;
108} // distAttr
109
110void distExt( DeclarationNode * declaration ) {
111        // distribute EXTENSION across all declarations
112        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
113                iter->set_extension( true );
114        } // for
115} // distExt
116
117// There is an ambiguity for inline generic-routine return-types and generic routines.
118//   forall( otype T ) struct S { int i; } bar( T ) {}
119// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
120//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
121
122void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
123        if ( declSpec->type->kind == TypeData::Aggregate ) { // return is aggregate definition
124                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
125                declSpec->type->aggregate.params = nullptr;
126        } // if
127} // rebindForall
128
129NameExpr * build_postfix_name( const string * name ) {
130        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
131        delete name;
132        return new_name;
133} // build_postfix_name
134
135bool forall = false;                                                                    // aggregate have one or more forall qualifiers ?
136
137// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
138#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
139if ( N ) {                                                                                                                                              \
140        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
141        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
142        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
143        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
144        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
145} else {                                                                                                                                                \
146        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
147        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
148        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
149}
150%}
151
152%define parse.error verbose
153
154// Types declaration for productions
155%union
156{
157        Token tok;
158        ParseNode * pn;
159        ExpressionNode * en;
160        DeclarationNode * decl;
161        DeclarationNode::Aggregate aggKey;
162        DeclarationNode::TypeClass tclass;
163        StatementNode * sn;
164        WaitForStmt * wfs;
165        Expression * constant;
166        IfCtl * ifctl;
167        ForCtl * fctl;
168        LabelNode * label;
169        InitializerNode * in;
170        OperKinds op;
171        std::string * str;
172        bool flag;
173        CatchStmt::Kind catch_kind;
174}
175
176//************************* TERMINAL TOKENS ********************************
177
178// keywords
179%token TYPEDEF
180%token EXTERN STATIC AUTO REGISTER
181%token THREADLOCAL                                                                              // C11
182%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
183%token NORETURN                                                                                 // C11
184%token CONST VOLATILE
185%token RESTRICT                                                                                 // C99
186%token ATOMIC                                                                                   // C11
187%token FORALL MUTEX VIRTUAL                                                             // CFA
188%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
189%token BOOL COMPLEX IMAGINARY                                                   // C99
190%token INT128 FLOAT80 FLOAT128                                                  // GCC
191%token ZERO_T ONE_T                                                                             // CFA
192%token VALIST                                                                                   // GCC
193%token TYPEOF LABEL                                                                             // GCC
194%token ENUM STRUCT UNION
195%token EXCEPTION                                                                                // CFA
196%token COROUTINE MONITOR THREAD                                                 // CFA
197%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
198%token SIZEOF OFFSETOF
199%token ATTRIBUTE EXTENSION                                                              // GCC
200%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
201%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
202%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
203%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
204
205// names and constants: lexer differentiates between identifier and typedef names
206%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
207%token<tok> TIMEOUT                             WOR
208%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
209%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
210// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
211// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
212// converted into the tuple index (.)(1). e.g., 3.x
213%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
214
215// multi-character operators
216%token ARROW                                                                                    // ->
217%token ICR DECR                                                                                 // ++   --
218%token LS RS                                                                                    // <<   >>
219%token LE GE EQ NE                                                                              // <=   >=      ==      !=
220%token ANDAND OROR                                                                              // &&   ||
221%token ELLIPSIS                                                                                 // ...
222
223%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
224%token PLUSassign       MINUSassign                                                     // +=   -=
225%token LSassign         RSassign                                                        // <<=  >>=
226%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
227
228%token ATassign                                                                                 // @=
229
230%type<tok> identifier  no_attr_identifier
231%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
232%type<tok> quasi_keyword
233%type<constant> string_literal
234%type<str> string_literal_list
235
236// expressions
237%type<en> constant
238%type<en> tuple                                                 tuple_expression_list
239%type<op> ptrref_operator                               unary_operator                          assignment_operator
240%type<en> primary_expression                    postfix_expression                      unary_expression
241%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
242%type<en> shift_expression                              relational_expression           equality_expression
243%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
244%type<en> logical_AND_expression                logical_OR_expression
245%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
246%type<en> comma_expression                              comma_expression_opt
247%type<en> argument_expression_list              argument_expression                     default_initialize_opt
248%type<ifctl> if_control_expression
249%type<fctl> for_control_expression
250%type<en> subrange
251%type<decl> asm_name_opt
252%type<en> asm_operands_opt asm_operands_list asm_operand
253%type<label> label_list
254%type<en> asm_clobbers_list_opt
255%type<flag> asm_volatile_opt
256%type<en> handler_predicate_opt
257
258// statements
259%type<sn> statement                                             labeled_statement                       compound_statement
260%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
261%type<sn> selection_statement
262%type<sn> switch_clause_list_opt                switch_clause_list
263%type<en> case_value
264%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
265%type<sn> iteration_statement                   jump_statement
266%type<sn> expression_statement                  asm_statement
267%type<sn> with_statement
268%type<en> with_clause_opt
269%type<sn> exception_statement                   handler_clause                          finally_clause
270%type<catch_kind> handler_key
271%type<sn> mutex_statement
272%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
273%type<sn> waitfor_statement
274%type<wfs> waitfor_clause
275
276// declarations
277%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
278%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
279%type<decl> abstract_parameter_declaration
280
281%type<aggKey> aggregate_key
282%type<decl> aggregate_type aggregate_type_nobody
283
284%type<decl> assertion assertion_list_opt
285
286%type<en>   bit_subrange_size_opt bit_subrange_size
287
288%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
289
290%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
291
292%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
293%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
294
295%type<decl> elaborated_type elaborated_type_nobody
296
297%type<decl> enumerator_list enum_type enum_type_nobody
298%type<en> enumerator_value_opt
299
300%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
301
302%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
303%type<en> field field_list field_name fraction_constants
304
305%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
306
307%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
308%type<decl> identifier_list
309
310%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
311%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
312%type<decl> cfa_abstract_ptr cfa_abstract_tuple
313
314%type<decl> cfa_array_parameter_1st_dimension
315
316%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list
317%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
318
319%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
320%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
321
322%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_type_list_opt
323
324%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
325
326%type<decl> c_declaration static_assert
327%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
328%type<decl> KR_declaration_list KR_declaration_list_opt
329
330%type<decl> parameter_declaration parameter_list parameter_type_list_opt
331
332%type<decl> paren_identifier paren_type
333
334%type<decl> storage_class storage_class_list
335
336%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
337
338%type<tclass> type_class
339%type<decl> type_declarator type_declarator_name type_declaring_list
340
341%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
342%type<decl> typedef typedef_declaration typedef_expression
343
344%type<decl> variable_type_redeclarator type_ptr type_array type_function
345
346%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
347
348%type<decl> type type_no_function
349%type<decl> type_parameter type_parameter_list type_initializer_opt
350
351%type<en> type_list
352
353%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
354%type<decl> type_specifier type_specifier_nobody
355
356%type<decl> variable_declarator variable_ptr variable_array variable_function
357%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
358
359%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
360
361// initializers
362%type<in>  initializer initializer_list initializer_opt
363
364// designators
365%type<en>  designator designator_list designation
366
367
368// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
369//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
370//   if ( C ) S1 else S2
371//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
372// Similar issues exit with the waitfor statement.
373
374// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
375// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
376%precedence THEN        // rule precedence for IF/WAITFOR statement
377%precedence WOR         // token precedence for start of WOR in WAITFOR statement
378%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
379%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
380
381// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
382//   forall( otype T ) struct Foo { T v; };
383//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
384//   Foo ( *fp )( int );
385//   `---'                                              matches start of TYPEGENname '('
386// Must be:
387//   Foo( int ) ( *fp )( int );
388
389// Order of these lines matters (low-to-high precedence).
390%precedence TYPEGENname
391%precedence '('
392
393%locations                                                                                              // support location tracking for error messages
394
395%start translation_unit                                                                 // parse-tree root
396
397%%
398//************************* Namespace Management ********************************
399
400// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
401// "identifier", "TYPEDEFname", and "TYPEGENname" that are lexically identical.  While it is possible to write a purely
402// context-free grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.
403// Hence, this grammar uses the ANSI style.
404//
405// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
406// introduced through "forall" qualifiers), and by introducing "type generators" -- parameterized types.  This latter
407// type name creates a third class of identifiers that must be distinguished by the scanner.
408//
409// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
410// accesses a data structure (TypedefTable) to allow classification of an identifier that it has just read.  Semantic
411// actions during the parser update this data structure when the class of identifiers change.
412//
413// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its class in a
414// local scope; it must revert to its original class at the end of the block.  Since type names can be local to a
415// particular declaration, each declaration is itself a scope.  This requires distinguishing between type names that are
416// local to the current declaration scope and those that persist past the end of the declaration (i.e., names defined in
417// "typedef" or "otype" declarations).
418//
419// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and closing of
420// scopes.  Every push must have a matching pop, although it is regrettable the matching pairs do not always occur
421// within the same rule.  These non-terminals may appear in more contexts than strictly necessary from a semantic point
422// of view.  Unfortunately, these extra rules are necessary to prevent parsing conflicts -- the parser may not have
423// enough context and look-ahead information to decide whether a new scope is necessary, so the effect of these extra
424// rules is to open a new scope unconditionally.  As the grammar evolves, it may be neccesary to add or move around
425// "push" and "pop" nonterminals to resolve conflicts of this sort.
426
427push:
428                { typedefTable.enterScope(); }
429        ;
430
431pop:
432                { typedefTable.leaveScope(); }
433        ;
434
435//************************* CONSTANTS ********************************
436
437constant:
438                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
439        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
440        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
441        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
442        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
443        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
444        ;
445
446quasi_keyword:                                                                                  // CFA
447        TIMEOUT
448        | WOR
449        ;
450
451identifier:
452        IDENTIFIER
453        | ATTR_IDENTIFIER                                                                       // CFA
454        | quasi_keyword
455        ;
456
457no_attr_identifier:
458        IDENTIFIER
459        | quasi_keyword
460        ;
461
462string_literal:
463        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
464        ;
465
466string_literal_list:                                                                    // juxtaposed strings are concatenated
467        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
468        | string_literal_list STRINGliteral
469                {
470                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
471                        delete $2;                                                                      // allocated by lexer
472                        $$ = $1;                                                                        // conversion from tok to str
473                }
474        ;
475
476//************************* EXPRESSIONS ********************************
477
478primary_expression:
479        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
480                { $$ = new ExpressionNode( build_varref( $1 ) ); }
481        | quasi_keyword
482                { $$ = new ExpressionNode( build_varref( $1 ) ); }
483        | tuple
484        | '(' comma_expression ')'
485                { $$ = $2; }
486        | '(' compound_statement ')'                                            // GCC, lambda expression
487                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
488        | constant '`' IDENTIFIER                                                       // CFA, postfix call
489                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
490        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
491                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
492        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
493                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
494        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
495                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
496        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
497                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
498        | type_name '.' no_attr_identifier                                      // CFA, nested type
499                { SemanticError( yylloc, "Qualified names are currently unimplemented." ); $$ = nullptr; }
500        | type_name '.' '[' push field_list pop ']'                     // CFA, nested type / tuple field selector
501                { SemanticError( yylloc, "Qualified names are currently unimplemented." ); $$ = nullptr; }
502        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
503                { SemanticError( yylloc, "_Generic is currently unimplemented." ); $$ = nullptr; }
504        ;
505
506generic_assoc_list:                                                                             // C11
507        | generic_association
508        | generic_assoc_list ',' generic_association
509        ;
510
511generic_association:                                                                    // C11
512        type_no_function ':' assignment_expression
513        | DEFAULT ':' assignment_expression
514        ;
515
516postfix_expression:
517        primary_expression
518        | postfix_expression '[' push assignment_expression pop ']'
519                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
520                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
521                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
522                // equivalent to the old x[i,j].
523                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $4 ) ); }
524        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
525                {
526                        Token fn;
527                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
528                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
529                }
530        | postfix_expression '(' argument_expression_list ')'
531                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
532        | postfix_expression '.' no_attr_identifier
533                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
534        | postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
535                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
536        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
537                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
538        | postfix_expression ARROW no_attr_identifier
539                {
540                        $$ = new ExpressionNode( build_pfieldSel( $1, *$3 == "0" || *$3 == "1" ? build_constantInteger( *$3 ) : build_varref( $3 ) ) );
541                }
542        | postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
543                        { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
544        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
545                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
546        | postfix_expression ICR
547                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
548        | postfix_expression DECR
549                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
550        | '(' type_no_function ')' '{' initializer_list comma_opt '}' // C99, compound-literal
551                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
552        | '(' type_no_function ')' '@' '{' initializer_list comma_opt '}' // CFA, explicit C compound-literal
553                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
554        | '^' primary_expression '{' argument_expression_list '}' // CFA
555                {
556                        Token fn;
557                        fn.str = new string( "^?{}" );                          // location undefined
558                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
559                }
560        ;
561
562argument_expression_list:
563        argument_expression
564        | argument_expression_list ',' argument_expression
565                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
566        ;
567
568argument_expression:
569        // empty
570                { $$ = nullptr; }
571        // | '@'                                                                                                // use default argument
572        //      { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
573        | assignment_expression
574        ;
575
576field_list:                                                                                             // CFA, tuple field selector
577        field
578        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
579        ;
580
581field:                                                                                                  // CFA, tuple field selector
582        field_name
583        | FLOATING_DECIMALconstant field
584                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
585        | FLOATING_DECIMALconstant '[' push field_list pop ']'
586                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $4 ) ) ); }
587        | field_name '.' field
588                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
589        | field_name '.' '[' push field_list pop ']'
590                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
591        | field_name ARROW field
592                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
593        | field_name ARROW '[' push field_list pop ']'
594                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
595        ;
596
597field_name:
598        INTEGERconstant fraction_constants
599                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
600        | FLOATINGconstant fraction_constants
601                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
602        | no_attr_identifier fraction_constants
603                {
604                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
605                }
606        ;
607
608fraction_constants:
609        // empty
610                { $$ = nullptr; }
611        | fraction_constants FLOATING_FRACTIONconstant
612                {
613                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
614                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
615                }
616        ;
617
618unary_expression:
619        postfix_expression
620                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
621                // semantics checks, e.g., ++3, 3--, *3, &&3
622        | constant
623                { $$ = $1; }
624        | string_literal
625                { $$ = new ExpressionNode( $1 ); }
626        | EXTENSION cast_expression                                                     // GCC
627                { $$ = $2->set_extension( true ); }
628                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
629                //              { * X; }         // dereference X
630                //              { * int X; } // CFA declaration of pointer to int
631        | ptrref_operator cast_expression                                       // CFA
632                {
633                        switch ( $1 ) {
634                          case OperKinds::AddressOf:
635                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
636                                break;
637                          case OperKinds::PointTo:
638                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
639                                break;
640                          case OperKinds::And:
641                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
642                                break;
643                          default:
644                                assert( false );
645                        }
646                }
647        | unary_operator cast_expression
648                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
649        | ICR unary_expression
650                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
651        | DECR unary_expression
652                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
653        | SIZEOF unary_expression
654                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
655        | SIZEOF '(' type_no_function ')'
656                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
657        | ALIGNOF unary_expression                                                      // GCC, variable alignment
658                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
659        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
660                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
661        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
662                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
663        | ATTR_IDENTIFIER
664                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
665        | ATTR_IDENTIFIER '(' argument_expression ')'
666                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
667        | ATTR_IDENTIFIER '(' type ')'
668                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
669        ;
670
671ptrref_operator:
672        '*'                                                                                     { $$ = OperKinds::PointTo; }
673        | '&'                                                                           { $$ = OperKinds::AddressOf; }
674                // GCC, address of label must be handled by semantic check for ref,ref,label
675        | ANDAND                                                                        { $$ = OperKinds::And; }
676        ;
677
678unary_operator:
679        '+'                                                                                     { $$ = OperKinds::UnPlus; }
680        | '-'                                                                           { $$ = OperKinds::UnMinus; }
681        | '!'                                                                           { $$ = OperKinds::Neg; }
682        | '~'                                                                           { $$ = OperKinds::BitNeg; }
683        ;
684
685cast_expression:
686        unary_expression
687        | '(' type_no_function ')' cast_expression
688                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
689        | '(' COROUTINE '&' ')' cast_expression                         // CFA
690                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
691        | '(' THREAD '&' ')' cast_expression                            // CFA
692                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
693        | '(' MONITOR '&' ')' cast_expression                           // CFA
694                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
695                // VIRTUAL cannot be opt because of look ahead issues
696        | '(' VIRTUAL ')' cast_expression                                       // CFA
697                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
698        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
699                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
700//      | '(' type_no_function ')' tuple
701//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
702        ;
703
704exponential_expression:
705        cast_expression
706        | exponential_expression '\\' cast_expression
707                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
708        ;
709
710multiplicative_expression:
711        exponential_expression
712        | multiplicative_expression '*' exponential_expression
713                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
714        | multiplicative_expression '/' exponential_expression
715                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
716        | multiplicative_expression '%' exponential_expression
717                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
718        ;
719
720additive_expression:
721        multiplicative_expression
722        | additive_expression '+' multiplicative_expression
723                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
724        | additive_expression '-' multiplicative_expression
725                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
726        ;
727
728shift_expression:
729        additive_expression
730        | shift_expression LS additive_expression
731                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
732        | shift_expression RS additive_expression
733                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
734        ;
735
736relational_expression:
737        shift_expression
738        | relational_expression '<' shift_expression
739                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
740        | relational_expression '>' shift_expression
741                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
742        | relational_expression LE shift_expression
743                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
744        | relational_expression GE shift_expression
745                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
746        ;
747
748equality_expression:
749        relational_expression
750        | equality_expression EQ relational_expression
751                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
752        | equality_expression NE relational_expression
753                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
754        ;
755
756AND_expression:
757        equality_expression
758        | AND_expression '&' equality_expression
759                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
760        ;
761
762exclusive_OR_expression:
763        AND_expression
764        | exclusive_OR_expression '^' AND_expression
765                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
766        ;
767
768inclusive_OR_expression:
769        exclusive_OR_expression
770        | inclusive_OR_expression '|' exclusive_OR_expression
771                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
772        ;
773
774logical_AND_expression:
775        inclusive_OR_expression
776        | logical_AND_expression ANDAND inclusive_OR_expression
777                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
778        ;
779
780logical_OR_expression:
781        logical_AND_expression
782        | logical_OR_expression OROR logical_AND_expression
783                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
784        ;
785
786conditional_expression:
787        logical_OR_expression
788        | logical_OR_expression '?' comma_expression ':' conditional_expression
789                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
790                // FIX ME: computes $1 twice
791        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
792                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
793        ;
794
795constant_expression:
796        conditional_expression
797        ;
798
799assignment_expression:
800                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
801        conditional_expression
802        | unary_expression assignment_operator assignment_expression
803                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
804        | unary_expression '=' '{' initializer_list comma_opt '}'
805                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
806        ;
807
808assignment_expression_opt:
809        // empty
810                { $$ = nullptr; }
811        | assignment_expression
812        ;
813
814assignment_operator:
815        '='                                                                                     { $$ = OperKinds::Assign; }
816        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
817        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
818        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
819        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
820        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
821        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
822        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
823        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
824        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
825        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
826        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
827        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
828        ;
829
830tuple:                                                                                                  // CFA, tuple
831                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
832                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
833//      '[' ']'
834//              { $$ = new ExpressionNode( build_tuple() ); }
835//      '[' push assignment_expression pop ']'
836//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
837        '[' push ',' tuple_expression_list pop ']'
838                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
839        | '[' push assignment_expression ',' tuple_expression_list pop ']'
840                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
841        ;
842
843tuple_expression_list:
844        assignment_expression_opt
845        | tuple_expression_list ',' assignment_expression_opt
846                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
847        ;
848
849comma_expression:
850        assignment_expression
851        | comma_expression ',' assignment_expression
852                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
853        ;
854
855comma_expression_opt:
856        // empty
857                { $$ = nullptr; }
858        | comma_expression
859        ;
860
861//*************************** STATEMENTS *******************************
862
863statement:
864        labeled_statement
865        | compound_statement
866        | expression_statement                                          { $$ = $1; }
867        | selection_statement
868        | iteration_statement
869        | jump_statement
870        | with_statement
871        | mutex_statement
872        | waitfor_statement
873        | exception_statement
874        | enable_disable_statement
875                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
876        | asm_statement
877        ;
878
879labeled_statement:
880                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
881        identifier_or_type_name ':' attribute_list_opt statement
882                {
883                        $$ = $4->add_label( $1, $3 );
884                }
885        ;
886
887compound_statement:
888        '{' '}'
889                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
890        | '{'
891                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
892                // requires its own scope.
893          push push
894          local_label_declaration_opt                                           // GCC, local labels
895          statement_decl_list                                                           // C99, intermix declarations and statements
896          pop '}'
897                { $$ = new StatementNode( build_compound( $5 ) ); }
898        ;
899
900statement_decl_list:                                                                    // C99
901        statement_decl
902        | statement_decl_list push statement_decl
903                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
904        ;
905
906statement_decl:
907        declaration                                                                                     // CFA, new & old style declarations
908                { $$ = new StatementNode( $1 ); }
909        | EXTENSION declaration                                                         // GCC
910                {
911                        distExt( $2 );
912                        $$ = new StatementNode( $2 );
913                }
914        | function_definition
915                { $$ = new StatementNode( $1 ); }
916        | EXTENSION function_definition                                         // GCC
917                {
918                        distExt( $2 );
919                        $$ = new StatementNode( $2 );
920                }
921        | statement pop
922        ;
923
924statement_list_nodecl:
925        statement
926        | statement_list_nodecl statement
927                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
928        ;
929
930expression_statement:
931        comma_expression_opt ';'
932                { $$ = new StatementNode( build_expr( $1 ) ); }
933        ;
934
935selection_statement:
936        IF '(' push if_control_expression ')' statement         %prec THEN
937                // explicitly deal with the shift/reduce conflict on if/else
938                { $$ = new StatementNode( build_if( $4, $6, nullptr ) ); }
939        | IF '(' push if_control_expression ')' statement ELSE statement
940                { $$ = new StatementNode( build_if( $4, $6, $8 ) ); }
941        | SWITCH '(' comma_expression ')' case_clause
942                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
943        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
944                {
945                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
946                        // The semantics of the declaration list is changed to include associated initialization, which is performed
947                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
948                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
949                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
950                        // statement.
951                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
952                }
953        | CHOOSE '(' comma_expression ')' case_clause           // CFA
954                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
955        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
956                {
957                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
958                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
959                }
960        ;
961
962if_control_expression:
963        comma_expression pop
964                { $$ = new IfCtl( nullptr, $1 ); }
965        | c_declaration pop                                                                     // no semi-colon
966                { $$ = new IfCtl( $1, nullptr ); }
967        | cfa_declaration pop                                                           // no semi-colon
968                { $$ = new IfCtl( $1, nullptr ); }
969        | declaration comma_expression                                          // semi-colon separated
970                { $$ = new IfCtl( $1, $2 ); }
971        ;
972
973// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
974// clause allows a list of values and subranges.
975
976case_value:                                                                                             // CFA
977        constant_expression                                                     { $$ = $1; }
978        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
979                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
980        | subrange                                                                                      // CFA, subrange
981        ;
982
983case_value_list:                                                                                // CFA
984        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
985                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
986        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
987        ;
988
989case_label:                                                                                             // CFA
990        CASE case_value_list ':'                                        { $$ = $2; }
991        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
992                // A semantic check is required to ensure only one default clause per switch/choose statement.
993        ;
994
995//label_list_opt:
996//      // empty
997//      | identifier_or_type_name ':'
998//      | label_list_opt identifier_or_type_name ':'
999//      ;
1000
1001case_label_list:                                                                                // CFA
1002        case_label
1003        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1004        ;
1005
1006case_clause:                                                                                    // CFA
1007        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1008        ;
1009
1010switch_clause_list_opt:                                                                 // CFA
1011        // empty
1012                { $$ = nullptr; }
1013        | switch_clause_list
1014        ;
1015
1016switch_clause_list:                                                                             // CFA
1017        case_label_list statement_list_nodecl
1018                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1019        | switch_clause_list case_label_list statement_list_nodecl
1020                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1021        ;
1022
1023iteration_statement:
1024        WHILE '(' comma_expression ')' statement
1025                { $$ = new StatementNode( build_while( $3, $5 ) ); }
1026        | DO statement WHILE '(' comma_expression ')' ';'
1027                { $$ = new StatementNode( build_while( $5, $2, true ) ); }
1028        | FOR '(' push for_control_expression ')' statement
1029                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1030        ;
1031
1032for_control_expression:
1033        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
1034                { $$ = new ForCtl( $1, $4, $6 ); }
1035        | declaration comma_expression_opt ';' comma_expression_opt // C99
1036                { $$ = new ForCtl( $1, $2, $4 ); }
1037        ;
1038
1039jump_statement:
1040        GOTO identifier_or_type_name ';'
1041                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1042        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1043                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1044                // whereas normal operator precedence yields goto (*i)+3;
1045                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1046                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1047    | fall_through_name ';'                                                             // CFA
1048                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1049    | fall_through_name identifier_or_type_name ';'             // CFA
1050                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1051        | fall_through_name DEFAULT ';'                                         // CFA
1052                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1053        | CONTINUE ';'
1054                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1055                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1056        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1057                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1058                // the target of the transfer appears only at the start of an iteration statement.
1059                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1060        | BREAK ';'
1061                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1062                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1063        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1064                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1065                // the target of the transfer appears only at the start of an iteration statement.
1066                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1067        | RETURN comma_expression_opt ';'
1068                { $$ = new StatementNode( build_return( $2 ) ); }
1069        | RETURN '{' initializer_list comma_opt '}'
1070                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1071        | THROW assignment_expression_opt ';'                           // handles rethrow
1072                { $$ = new StatementNode( build_throw( $2 ) ); }
1073        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1074                { $$ = new StatementNode( build_resume( $2 ) ); }
1075        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1076                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1077        ;
1078
1079fall_through_name:                                                                              // CFA
1080        FALLTHRU
1081        | FALLTHROUGH
1082        ;
1083
1084with_statement:
1085        WITH '(' tuple_expression_list ')' statement
1086                {
1087                        $$ = new StatementNode( build_with( $3, $5 ) );
1088                }
1089        ;
1090
1091// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1092mutex_statement:
1093        MUTEX '(' argument_expression_list ')' statement
1094                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1095        ;
1096
1097when_clause:
1098        WHEN '(' comma_expression ')'                           { $$ = $3; }
1099        ;
1100
1101when_clause_opt:
1102        // empty
1103                { $$ = nullptr; }
1104        | when_clause
1105        ;
1106
1107waitfor:
1108        WAITFOR '(' identifier ')'
1109                {
1110                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1111                        delete $3;
1112                }
1113        | WAITFOR '(' identifier ',' argument_expression_list ')'
1114                {
1115                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1116                        $$->set_last( $5 );
1117                        delete $3;
1118                }
1119        ;
1120
1121timeout:
1122        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1123        ;
1124
1125waitfor_clause:
1126        when_clause_opt waitfor statement                                       %prec THEN
1127                { $$ = build_waitfor( $2, $3, $1 ); }
1128        | when_clause_opt waitfor statement WOR waitfor_clause
1129                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1130        | when_clause_opt timeout statement                                     %prec THEN
1131                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1132        | when_clause_opt ELSE statement
1133                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1134                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1135        | when_clause_opt timeout statement WOR when_clause ELSE statement
1136                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1137        ;
1138
1139waitfor_statement:
1140        when_clause_opt waitfor statement                                       %prec THEN
1141                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1142        | when_clause_opt waitfor statement WOR waitfor_clause
1143                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1144        ;
1145
1146exception_statement:
1147        TRY compound_statement handler_clause
1148                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1149        | TRY compound_statement finally_clause
1150                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1151        | TRY compound_statement handler_clause finally_clause
1152                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1153        ;
1154
1155handler_clause:
1156        handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1157                { $$ = new StatementNode( build_catch( $1, $5, $7, $9 ) ); }
1158        | handler_clause handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1159                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $6, $8, $10 ) ) ); }
1160        ;
1161
1162handler_predicate_opt:
1163        //empty
1164                { $$ = nullptr; }
1165        | ';' conditional_expression                            { $$ = $2; }
1166        ;
1167
1168handler_key:
1169        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1170        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1171        ;
1172
1173finally_clause:
1174        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1175        ;
1176
1177exception_declaration:
1178                // No SUE declaration in parameter list.
1179        type_specifier_nobody
1180        | type_specifier_nobody declarator
1181                {
1182                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1183                        $$ = $2->addType( $1 );
1184                }
1185        | type_specifier_nobody variable_abstract_declarator
1186                { $$ = $2->addType( $1 ); }
1187        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1188                {
1189                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1190                        $$ = $1->addName( $2 );
1191                }
1192        | cfa_abstract_declarator_tuple                                         // CFA
1193        ;
1194
1195enable_disable_statement:
1196        enable_disable_key identifier_list compound_statement
1197        ;
1198
1199enable_disable_key:
1200        ENABLE
1201        | DISABLE
1202        ;
1203
1204asm_statement:
1205        ASM asm_volatile_opt '(' string_literal ')' ';'
1206                { $$ = new StatementNode( build_asmstmt( $2, $4, 0 ) ); }
1207        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1208                { $$ = new StatementNode( build_asmstmt( $2, $4, $6 ) ); }
1209        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1210                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8 ) ); }
1211        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1212                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8, $10 ) ); }
1213        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1214                { $$ = new StatementNode( build_asmstmt( $2, $5, 0, $8, $10, $12 ) ); }
1215        ;
1216
1217asm_volatile_opt:                                                                               // GCC
1218        // empty
1219                { $$ = false; }
1220        | VOLATILE
1221                { $$ = true; }
1222        ;
1223
1224asm_operands_opt:                                                                               // GCC
1225        // empty
1226                { $$ = nullptr; }                                                               // use default argument
1227        | asm_operands_list
1228        ;
1229
1230asm_operands_list:                                                                              // GCC
1231        asm_operand
1232        | asm_operands_list ',' asm_operand
1233                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1234        ;
1235
1236asm_operand:                                                                                    // GCC
1237        string_literal '(' constant_expression ')'
1238                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1239        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1240                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1241        ;
1242
1243asm_clobbers_list_opt:                                                                  // GCC
1244        // empty
1245                { $$ = nullptr; }                                                               // use default argument
1246        | string_literal
1247                { $$ = new ExpressionNode( $1 ); }
1248        | asm_clobbers_list_opt ',' string_literal
1249                // set_last returns ParseNode *
1250                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1251        ;
1252
1253label_list:
1254        no_attr_identifier
1255                {
1256                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1257                        delete $1;                                                                      // allocated by lexer
1258                }
1259        | label_list ',' no_attr_identifier
1260                {
1261                        $$ = $1; $1->labels.push_back( *$3 );
1262                        delete $3;                                                                      // allocated by lexer
1263                }
1264        ;
1265
1266//******************************* DECLARATIONS *********************************
1267
1268declaration_list_opt:                                                                   // used at beginning of switch statement
1269        pop
1270                { $$ = nullptr; }
1271        | declaration_list
1272        ;
1273
1274declaration_list:
1275        declaration
1276        | declaration_list push declaration
1277                { $$ = $1->appendList( $3 ); }
1278        ;
1279
1280KR_declaration_list_opt:                                                                // used to declare parameter types in K&R style functions
1281        // empty
1282                { $$ = nullptr; }
1283        | KR_declaration_list
1284        ;
1285
1286KR_declaration_list:
1287        push c_declaration pop ';'
1288                { $$ = $2; }
1289        | KR_declaration_list push c_declaration pop ';'
1290                { $$ = $1->appendList( $3 ); }
1291        ;
1292
1293local_label_declaration_opt:                                                    // GCC, local label
1294        // empty
1295        | local_label_declaration_list
1296        ;
1297
1298local_label_declaration_list:                                                   // GCC, local label
1299        LABEL local_label_list ';'
1300        | local_label_declaration_list LABEL local_label_list ';'
1301        ;
1302
1303local_label_list:                                                                               // GCC, local label
1304        no_attr_identifier_or_type_name                         {}
1305        | local_label_list ',' no_attr_identifier_or_type_name {}
1306        ;
1307
1308declaration:                                                                                    // old & new style declarations
1309        c_declaration pop ';'
1310        | cfa_declaration pop ';'                                                       // CFA
1311        | static_assert
1312        ;
1313
1314static_assert:
1315        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1316                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1317
1318// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1319// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1320// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1321// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1322// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1323// block, but cannot be mixed within a specific declaration.
1324//
1325//                      CFA                                     C
1326//              [10] int x;                     int x[10];              // array of 10 integers
1327//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1328
1329cfa_declaration:                                                                                // CFA
1330        cfa_variable_declaration
1331        | cfa_typedef_declaration
1332        | cfa_function_declaration
1333        | type_declaring_list
1334        | trait_specifier
1335        ;
1336
1337cfa_variable_declaration:                                                               // CFA
1338        cfa_variable_specifier initializer_opt
1339                {
1340                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1341                        $$ = $1->addInitializer( $2 );
1342                }
1343        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1344                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1345                // them as a type_qualifier cannot appear in that context.
1346                {
1347                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1348                        $$ = $2->addQualifiers( $1 )->addInitializer( $3 );;
1349                }
1350        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1351                {
1352                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1353                        $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) );
1354                }
1355        ;
1356
1357cfa_variable_specifier:                                                                 // CFA
1358                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1359                // storage-class
1360        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1361                {
1362                        typedefTable.setNextIdentifier( *$2 );
1363                        $$ = $1->addName( $2 )->addAsmName( $3 );
1364                }
1365        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1366                {
1367                        typedefTable.setNextIdentifier( *$2 );
1368                        $$ = $1->addName( $2 )->addAsmName( $3 );
1369                }
1370        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1371                {
1372                        typedefTable.setNextIdentifier( *$3 );
1373                        $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 );
1374                }
1375        ;
1376
1377cfa_function_declaration:                                                               // CFA
1378        cfa_function_specifier
1379                {
1380                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1381                        $$ = $1;
1382                }
1383        | type_qualifier_list cfa_function_specifier
1384                {
1385                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1386                        $$ = $2->addQualifiers( $1 );
1387                }
1388        | declaration_qualifier_list cfa_function_specifier
1389                {
1390                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1391                        $$ = $2->addQualifiers( $1 );
1392                }
1393        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1394                {
1395                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1396                        $$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1397                }
1398        | cfa_function_declaration pop ',' push identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1399                {
1400                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1401                        DeclarationNode * ret = new DeclarationNode;
1402                        ret->type = maybeClone( $1->type->base );
1403                        $$ = $1->appendList( DeclarationNode::newFunction( $5, ret, $8, nullptr ) );
1404                }
1405        ;
1406
1407cfa_function_specifier:                                                                 // CFA
1408//      '[' ']' identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')' // S/R conflict
1409//              {
1410//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1411//              }
1412//      '[' ']' identifier '(' push cfa_parameter_type_list_opt pop ')'
1413//              {
1414//                      typedefTable.setNextIdentifier( *$5 );
1415//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1416//              }
1417//      | '[' ']' TYPEDEFname '(' push cfa_parameter_type_list_opt pop ')'
1418//              {
1419//                      typedefTable.setNextIdentifier( *$5 );
1420//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1421//              }
1422//      | '[' ']' typegen_name
1423                // identifier_or_type_name must be broken apart because of the sequence:
1424                //
1425                //   '[' ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
1426                //   '[' ']' type_specifier
1427                //
1428                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1429                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1430        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1431                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1432                {
1433                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0 );
1434                }
1435        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1436                {
1437                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0 );
1438                }
1439        ;
1440
1441cfa_function_return:                                                                    // CFA
1442        '[' push cfa_parameter_list pop ']'
1443                { $$ = DeclarationNode::newTuple( $3 ); }
1444        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1445                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the
1446                // ']'.
1447                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1448        ;
1449
1450cfa_typedef_declaration:                                                                // CFA
1451        TYPEDEF cfa_variable_specifier
1452                {
1453                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1454                        $$ = $2->addTypedef();
1455                }
1456        | TYPEDEF cfa_function_specifier
1457                {
1458                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1459                        $$ = $2->addTypedef();
1460                }
1461        | cfa_typedef_declaration pop ',' push no_attr_identifier
1462                {
1463                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1464                        $$ = $1->appendList( $1->cloneType( $5 ) );
1465                }
1466        ;
1467
1468// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1469// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1470
1471typedef_declaration:
1472        TYPEDEF type_specifier declarator
1473                {
1474                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1475                        $$ = $3->addType( $2 )->addTypedef();
1476                }
1477        | typedef_declaration pop ',' push declarator
1478                {
1479                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1480                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1481                }
1482        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1483                {
1484                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1485                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1486                }
1487        | type_specifier TYPEDEF declarator
1488                {
1489                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1490                        $$ = $3->addType( $1 )->addTypedef();
1491                }
1492        | type_specifier TYPEDEF type_qualifier_list declarator
1493                {
1494                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1495                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1496                }
1497        ;
1498
1499typedef_expression:
1500                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1501        TYPEDEF no_attr_identifier '=' assignment_expression
1502                {
1503                        typedefTable.addToEnclosingScope( *$2, TypedefTable::TD );
1504                        $$ = DeclarationNode::newName( 0 );                     // unimplemented
1505                }
1506        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1507                {
1508                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1509                        $$ = DeclarationNode::newName( 0 );                     // unimplemented
1510                }
1511        ;
1512
1513//c_declaration:
1514//      declaring_list pop ';'
1515//      | typedef_declaration pop ';'
1516//      | typedef_expression pop ';'                                            // GCC, naming expression type
1517//      | sue_declaration_specifier pop ';'
1518//      ;
1519//
1520//declaring_list:
1521//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1522//              // storage-class
1523//       declarator asm_name_opt initializer_opt
1524//              {
1525//                      typedefTable.addToEnclosingScope( TypedefTable::ID );
1526//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1527//              }
1528//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1529//              {
1530//                      typedefTable.addToEnclosingScope( TypedefTable::ID );
1531//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1532//              }
1533//      ;
1534
1535c_declaration:
1536        declaration_specifier declaring_list
1537                {
1538                        $$ = distAttr( $1, $2 );
1539                }
1540        | typedef_declaration
1541        | typedef_expression                                                            // GCC, naming expression type
1542        | sue_declaration_specifier
1543        ;
1544
1545declaring_list:
1546                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1547                // storage-class
1548        declarator asm_name_opt initializer_opt
1549                {
1550                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1551                        $$ = $1->addAsmName( $2 )->addInitializer( $3 );
1552                }
1553        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1554                {
1555                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1556                        $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) );
1557                }
1558        ;
1559
1560declaration_specifier:                                                                  // type specifier + storage class
1561        basic_declaration_specifier
1562        | sue_declaration_specifier
1563        | type_declaration_specifier
1564        ;
1565
1566declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1567                // Preclude SUE declarations in restricted scopes:
1568                //
1569                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1570                //
1571                // because it is impossible to call f due to name equivalence.
1572        basic_declaration_specifier
1573        | sue_declaration_specifier_nobody
1574        | type_declaration_specifier
1575        ;
1576
1577type_specifier:                                                                                 // type specifier
1578        basic_type_specifier
1579        | sue_type_specifier
1580        | type_type_specifier
1581        ;
1582
1583type_specifier_nobody:                                                                  // type specifier - {...}
1584                // Preclude SUE declarations in restricted scopes:
1585                //
1586                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1587                //
1588                // because it is impossible to call f due to name equivalence.
1589        basic_type_specifier
1590        | sue_type_specifier_nobody
1591        | type_type_specifier
1592        ;
1593
1594type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1595        // empty
1596                { $$ = nullptr; }
1597        | type_qualifier_list
1598        ;
1599
1600type_qualifier_list:
1601                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1602                //
1603                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1604                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1605                // appeared only once.
1606        type_qualifier
1607        | type_qualifier_list type_qualifier
1608                { $$ = $1->addQualifiers( $2 ); }
1609        ;
1610
1611type_qualifier:
1612        type_qualifier_name
1613        | attribute
1614        ;
1615
1616type_qualifier_name:
1617        CONST
1618                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1619        | RESTRICT
1620                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1621        | VOLATILE
1622                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1623        | ATOMIC
1624                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1625        | forall
1626        ;
1627
1628forall:
1629        FORALL '('
1630                {
1631                        typedefTable.enterScope();
1632                }
1633          type_parameter_list ')'                                                       // CFA
1634                {
1635                        typedefTable.leaveScope();
1636                        $$ = DeclarationNode::newForall( $4 );
1637                }
1638        ;
1639
1640declaration_qualifier_list:
1641        storage_class_list
1642        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1643                { $$ = $1->addQualifiers( $2 ); }
1644        | declaration_qualifier_list type_qualifier_list storage_class_list
1645                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1646        ;
1647
1648storage_class_list:
1649                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1650                // only one of each is specified, except for inline, which can appear with the others.
1651                //
1652                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1653                // specifiers in a declaration.
1654        storage_class
1655        | storage_class_list storage_class
1656                { $$ = $1->addQualifiers( $2 ); }
1657        ;
1658
1659storage_class:
1660        EXTERN
1661                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1662        | STATIC
1663                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1664        | AUTO
1665                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1666        | REGISTER
1667                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1668        | THREADLOCAL                                                                           // C11
1669                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1670                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1671        | INLINE                                                                                        // C99
1672                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1673        | FORTRAN                                                                                       // C99
1674                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1675        | NORETURN                                                                                      // C11
1676                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1677        ;
1678
1679basic_type_name:
1680        VOID
1681                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1682        | BOOL                                                                                          // C99
1683                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1684        | CHAR
1685                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1686        | INT
1687                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1688        | INT128
1689                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1690        | FLOAT
1691                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1692        | FLOAT80
1693                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float80 ); }
1694        | FLOAT128
1695                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float128 ); }
1696        | DOUBLE
1697                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1698        | COMPLEX                                                                                       // C99
1699                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1700        | IMAGINARY                                                                                     // C99
1701                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1702        | SIGNED
1703                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1704        | UNSIGNED
1705                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1706        | SHORT
1707                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1708        | LONG
1709                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1710        | VALIST                                                                                        // GCC, __builtin_va_list
1711                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1712        ;
1713
1714basic_declaration_specifier:
1715                // A semantic check is necessary for conflicting storage classes.
1716        basic_type_specifier
1717        | declaration_qualifier_list basic_type_specifier
1718                { $$ = $2->addQualifiers( $1 ); }
1719        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1720                { $$ = $1->addQualifiers( $2 ); }
1721        | basic_declaration_specifier storage_class type_qualifier_list
1722                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1723        | basic_declaration_specifier storage_class basic_type_specifier
1724                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1725        ;
1726
1727basic_type_specifier:
1728        direct_type
1729                // Cannot have type modifiers, e.g., short, long, etc.
1730        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1731                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1732        ;
1733
1734direct_type:
1735        basic_type_name
1736        | type_qualifier_list basic_type_name
1737                { $$ = $2->addQualifiers( $1 ); }
1738        | direct_type type_qualifier
1739                { $$ = $1->addQualifiers( $2 ); }
1740        | direct_type basic_type_name
1741                { $$ = $1->addType( $2 ); }
1742        ;
1743
1744indirect_type:
1745        TYPEOF '(' type ')'                                                                     // GCC: typeof(x) y;
1746                { $$ = $3; }
1747        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1748                { $$ = DeclarationNode::newTypeof( $3 ); }
1749        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type(x) y;
1750                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1751        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1752                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1753        | ZERO_T                                                                                        // CFA
1754                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1755        | ONE_T                                                                                         // CFA
1756                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1757        ;
1758
1759sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1760        sue_type_specifier
1761        | declaration_qualifier_list sue_type_specifier
1762                { $$ = $2->addQualifiers( $1 ); }
1763        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1764                { $$ = $1->addQualifiers( $2 ); }
1765        | sue_declaration_specifier storage_class type_qualifier_list
1766                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1767        ;
1768
1769sue_type_specifier:                                                                             // struct, union, enum + type specifier
1770        elaborated_type
1771        | type_qualifier_list
1772                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1773          elaborated_type
1774                { $$ = $3->addQualifiers( $1 ); }
1775        | sue_type_specifier type_qualifier
1776                { $$ = $1->addQualifiers( $2 ); }
1777        ;
1778
1779sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1780        sue_type_specifier_nobody
1781        | declaration_qualifier_list sue_type_specifier_nobody
1782                { $$ = $2->addQualifiers( $1 ); }
1783        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1784                { $$ = $1->addQualifiers( $2 ); }
1785        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1786                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1787        ;
1788
1789sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1790        elaborated_type_nobody
1791        | type_qualifier_list elaborated_type_nobody
1792                { $$ = $2->addQualifiers( $1 ); }
1793        | sue_type_specifier_nobody type_qualifier
1794                { $$ = $1->addQualifiers( $2 ); }
1795        ;
1796
1797type_declaration_specifier:
1798        type_type_specifier
1799        | declaration_qualifier_list type_type_specifier
1800                { $$ = $2->addQualifiers( $1 ); }
1801        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1802                { $$ = $1->addQualifiers( $2 ); }
1803        | type_declaration_specifier storage_class type_qualifier_list
1804                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1805        ;
1806
1807type_type_specifier:                                                                    // typedef types
1808        type_name
1809        | type_qualifier_list type_name
1810                { $$ = $2->addQualifiers( $1 ); }
1811        | type_type_specifier type_qualifier
1812                { $$ = $1->addQualifiers( $2 ); }
1813        ;
1814
1815type_name:
1816        TYPEDEFname
1817                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1818        | '.' TYPEDEFname
1819                { $$ = DeclarationNode::newFromTypedef( $2 ); } // FIX ME
1820        | type_name '.' TYPEDEFname
1821                { $$ = DeclarationNode::newFromTypedef( $3 ); } // FIX ME
1822        | typegen_name
1823        | '.' typegen_name
1824                { $$ = $2; }                                                                    // FIX ME
1825        | type_name '.' typegen_name
1826                { $$ = $3; }                                                                    // FIX ME
1827        ;
1828
1829typegen_name:                                                                                   // CFA
1830        TYPEGENname
1831                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1832        | TYPEGENname '(' ')'
1833                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1834        | TYPEGENname '(' type_list ')'
1835                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1836        ;
1837
1838elaborated_type:                                                                                // struct, union, enum
1839        aggregate_type
1840        | enum_type
1841        ;
1842
1843elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1844        aggregate_type_nobody
1845        | enum_type_nobody
1846        ;
1847
1848aggregate_type:                                                                                 // struct, union
1849        aggregate_key attribute_list_opt '{' field_declaration_list '}'
1850                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), nullptr, $4, true )->addQualifiers( $2 ); }
1851        | aggregate_key attribute_list_opt no_attr_identifier_or_type_name
1852                {
1853                        typedefTable.makeTypedef( *$3 );                        // create typedef
1854                        if ( forall ) typedefTable.changeKind( *$3, TypedefTable::TG ); // possibly update
1855                        forall = false;                                                         // reset
1856                }
1857          '{' field_declaration_list '}'
1858                { $$ = DeclarationNode::newAggregate( $1, $3, nullptr, $6, true )->addQualifiers( $2 ); }
1859        | aggregate_key attribute_list_opt '(' type_list ')' '{' field_declaration_list '}' // CFA
1860                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), $4, $7, false )->addQualifiers( $2 ); }
1861        | aggregate_type_nobody
1862        ;
1863
1864aggregate_type_nobody:                                                                  // struct, union - {...}
1865        aggregate_key attribute_list_opt no_attr_identifier
1866                {
1867                        typedefTable.makeTypedef( *$3 );
1868                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1869                }
1870        | aggregate_key attribute_list_opt TYPEDEFname
1871                {
1872                        typedefTable.makeTypedef( *$3 );
1873                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1874                }
1875        | aggregate_key attribute_list_opt typegen_name         // CFA
1876                {
1877                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
1878                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
1879                        // delete newFromTypeGen.
1880                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
1881                        $3->type->symbolic.name = nullptr;
1882                        $3->type->symbolic.actuals = nullptr;
1883                        delete $3;
1884                }
1885        ;
1886
1887aggregate_key:
1888        STRUCT
1889                { $$ = DeclarationNode::Struct; }
1890        | UNION
1891                { $$ = DeclarationNode::Union; }
1892        | EXCEPTION
1893                { $$ = DeclarationNode::Exception; }
1894        | COROUTINE
1895                { $$ = DeclarationNode::Coroutine; }
1896        | MONITOR
1897                { $$ = DeclarationNode::Monitor; }
1898        | THREAD
1899                { $$ = DeclarationNode::Thread; }
1900        ;
1901
1902field_declaration_list:
1903        // empty
1904                { $$ = nullptr; }
1905        | field_declaration_list field_declaration
1906                { $$ = $1 ? $1->appendList( $2 ) : $2; }
1907        ;
1908
1909field_declaration:
1910        cfa_field_declaring_list ';'                                            // CFA, new style field declaration
1911        | EXTENSION cfa_field_declaring_list ';'                        // GCC
1912                {
1913                        distExt( $2 );                                                          // mark all fields in list
1914                        $$ = $2;
1915                }
1916        | type_specifier field_declaring_list ';'
1917                {
1918                        $$ = distAttr( $1, $2 ); }
1919        | EXTENSION type_specifier field_declaring_list ';'     // GCC
1920                {
1921                        distExt( $3 );                                                          // mark all fields in list
1922                        $$ = distAttr( $2, $3 );
1923                }
1924        | static_assert
1925        ;
1926
1927cfa_field_declaring_list:                                                               // CFA, new style field declaration
1928        cfa_abstract_declarator_tuple                                           // CFA, no field name
1929        | cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
1930                { $$ = $1->addName( $2 ); }
1931        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
1932                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1933        | cfa_field_declaring_list ','                                          // CFA, no field name
1934                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1935        ;
1936
1937field_declaring_list:
1938        field_declarator
1939        | field_declaring_list ',' attribute_list_opt field_declarator
1940                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
1941        ;
1942
1943field_declarator:
1944        // empty
1945                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1946        // '@'
1947        //      { $$ = DeclarationNode::newName( new string( DeclarationNode::anonymous.newName() ) ); } // CFA, no field name
1948        | bit_subrange_size                                                                     // no field name
1949                { $$ = DeclarationNode::newBitfield( $1 ); }
1950        | variable_declarator bit_subrange_size_opt
1951                // A semantic check is required to ensure bit_subrange only appears on base type int.
1952                { $$ = $1->addBitfield( $2 ); }
1953        | variable_type_redeclarator bit_subrange_size_opt
1954                // A semantic check is required to ensure bit_subrange only appears on base type int.
1955                { $$ = $1->addBitfield( $2 ); }
1956        | variable_abstract_declarator                                          // CFA, no field name
1957        ;
1958
1959bit_subrange_size_opt:
1960        // empty
1961                { $$ = nullptr; }
1962        | bit_subrange_size
1963                { $$ = $1; }
1964        ;
1965
1966bit_subrange_size:
1967        ':' constant_expression
1968                { $$ = $2; }
1969        ;
1970
1971enum_type:                                                                                              // enum
1972        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
1973                { $$ = DeclarationNode::newEnum( new string( DeclarationNode::anonymous.newName() ), $4, true )->addQualifiers( $2 ); }
1974        | ENUM attribute_list_opt no_attr_identifier_or_type_name
1975                { typedefTable.makeTypedef( *$3 ); }
1976          '{' enumerator_list comma_opt '}'
1977                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
1978        | enum_type_nobody
1979        ;
1980
1981enum_type_nobody:                                                                               // enum - {...}
1982        ENUM attribute_list_opt no_attr_identifier_or_type_name
1983                {
1984                        typedefTable.makeTypedef( *$3 );
1985                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
1986                }
1987        ;
1988
1989enumerator_list:
1990        no_attr_identifier_or_type_name enumerator_value_opt
1991                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1992        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1993                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1994        ;
1995
1996enumerator_value_opt:
1997        // empty
1998                { $$ = nullptr; }
1999        | '=' constant_expression
2000                { $$ = $2; }
2001        ;
2002
2003cfa_parameter_type_list_opt:                                                    // CFA, abstract + real
2004        // empty
2005                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2006        | ELLIPSIS
2007                { $$ = nullptr; }
2008        | cfa_abstract_parameter_list
2009        | cfa_parameter_list
2010        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2011                { $$ = $1->appendList( $5 ); }
2012        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2013                { $$ = $1->addVarArgs(); }
2014        | cfa_parameter_list pop ',' push ELLIPSIS
2015                { $$ = $1->addVarArgs(); }
2016        ;
2017
2018cfa_parameter_list:                                                                             // CFA
2019                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2020                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2021        cfa_parameter_declaration
2022        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2023                { $$ = $1->appendList( $5 ); }
2024        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2025                { $$ = $1->appendList( $5 ); }
2026        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2027                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2028        ;
2029
2030cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2031        cfa_abstract_parameter_declaration
2032        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2033                { $$ = $1->appendList( $5 ); }
2034        ;
2035
2036parameter_type_list_opt:
2037        // empty
2038                { $$ = nullptr; }
2039        | ELLIPSIS
2040                { $$ = nullptr; }
2041        | parameter_list
2042        | parameter_list pop ',' push ELLIPSIS
2043                { $$ = $1->addVarArgs(); }
2044        ;
2045
2046parameter_list:                                                                                 // abstract + real
2047        abstract_parameter_declaration
2048        | parameter_declaration
2049        | parameter_list pop ',' push abstract_parameter_declaration
2050                { $$ = $1->appendList( $5 ); }
2051        | parameter_list pop ',' push parameter_declaration
2052                { $$ = $1->appendList( $5 ); }
2053        ;
2054
2055// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2056// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2057
2058cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2059        parameter_declaration
2060        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2061                { $$ = $1->addName( $2 ); }
2062        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2063                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2064                { $$ = $1->addName( $2 ); }
2065        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2066                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2067        | cfa_function_specifier
2068        ;
2069
2070cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2071        abstract_parameter_declaration
2072        | cfa_identifier_parameter_declarator_no_tuple
2073        | cfa_abstract_tuple
2074                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2075        | type_qualifier_list cfa_abstract_tuple
2076                { $$ = $2->addQualifiers( $1 ); }
2077        | cfa_abstract_function
2078        ;
2079
2080parameter_declaration:
2081                // No SUE declaration in parameter list.
2082        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2083                {
2084                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2085                        $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr );
2086                }
2087        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2088                {
2089                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2090                        $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr );
2091                }
2092        ;
2093
2094abstract_parameter_declaration:
2095        declaration_specifier_nobody default_initialize_opt
2096                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2097        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2098                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2099        ;
2100
2101// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2102// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2103// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2104
2105identifier_list:                                                                                // K&R-style parameter list => no types
2106        no_attr_identifier
2107                { $$ = DeclarationNode::newName( $1 ); }
2108        | identifier_list ',' no_attr_identifier
2109                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2110        ;
2111
2112identifier_or_type_name:
2113        identifier
2114        | TYPEDEFname
2115        | TYPEGENname
2116        ;
2117
2118no_attr_identifier_or_type_name:
2119        no_attr_identifier
2120        | TYPEDEFname
2121        | TYPEGENname
2122        ;
2123
2124type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2125        cfa_abstract_declarator_tuple                                           // CFA
2126        | type_specifier
2127        | type_specifier abstract_declarator
2128                { $$ = $2->addType( $1 ); }
2129        ;
2130
2131type:                                                                                                   // typeof, assertion
2132        type_no_function
2133        | cfa_abstract_function                                                         // CFA
2134        ;
2135
2136initializer_opt:
2137        // empty
2138                { $$ = nullptr; }
2139        | '=' initializer
2140                { $$ = $2; }
2141        | '=' VOID
2142                { $$ = nullptr; }
2143        | ATassign initializer
2144                { $$ = $2->set_maybeConstructed( false ); }
2145        ;
2146
2147initializer:
2148        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2149        | '{' initializer_list comma_opt '}'            { $$ = new InitializerNode( $2, true ); }
2150        ;
2151
2152initializer_list:
2153        // empty
2154                { $$ = nullptr; }
2155        | initializer
2156        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2157        | initializer_list ',' initializer                      { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2158        | initializer_list ',' designation initializer
2159                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2160        ;
2161
2162// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2163// '=' to separator the designator from the initializer value, as in:
2164//
2165//              int x[10] = { [1] = 3 };
2166//
2167// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2168// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2169// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2170// shift/reduce conflicts
2171
2172designation:
2173        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2174        | no_attr_identifier ':'                                                        // GCC, field name
2175                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2176        ;
2177
2178designator_list:                                                                                // C99
2179        designator
2180        | designator_list designator
2181                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2182        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2183        ;
2184
2185designator:
2186        '.' no_attr_identifier                                                          // C99, field name
2187                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2188        | '[' push assignment_expression pop ']'                        // C99, single array element
2189                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2190                { $$ = $3; }
2191        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2192                { $$ = $3; }
2193        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2194                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2195        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
2196                { $$ = $4; }
2197        ;
2198
2199// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2200// rather than an object-oriented type system. This required four groups of extensions:
2201//
2202// Overloading: function, data, and operator identifiers may be overloaded.
2203//
2204// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2205//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2206//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2207//
2208// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2209//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2210//
2211// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2212//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2213//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2214//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2215//     on type arguments of polymorphic functions.
2216
2217type_parameter_list:                                                                    // CFA
2218        type_parameter
2219                { $$ = $1; }
2220        | type_parameter_list ',' type_parameter
2221                { $$ = $1->appendList( $3 ); }
2222        ;
2223
2224type_initializer_opt:                                                                   // CFA
2225        // empty
2226                { $$ = nullptr; }
2227        | '=' type
2228                { $$ = $2; }
2229        ;
2230
2231type_parameter:                                                                                 // CFA
2232        type_class no_attr_identifier_or_type_name
2233                { typedefTable.addToEnclosingScope( *$2, TypedefTable::TD ); }
2234          type_initializer_opt assertion_list_opt
2235                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2236        | type_specifier identifier_parameter_declarator
2237        ;
2238
2239type_class:                                                                                             // CFA
2240        OTYPE
2241                { $$ = DeclarationNode::Otype; }
2242        | DTYPE
2243                { $$ = DeclarationNode::Dtype; }
2244        | FTYPE
2245                { $$ = DeclarationNode::Ftype; }
2246        | TTYPE
2247                { $$ = DeclarationNode::Ttype; }
2248        ;
2249
2250assertion_list_opt:                                                                             // CFA
2251        // empty
2252                { $$ = nullptr; }
2253        | assertion_list_opt assertion
2254                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2255        ;
2256
2257assertion:                                                                                              // CFA
2258        '|' no_attr_identifier_or_type_name '(' type_list ')'
2259                {
2260                        typedefTable.openTrait( *$2 );
2261                        $$ = DeclarationNode::newTraitUse( $2, $4 );
2262                }
2263        | '|' '{' push trait_declaration_list '}'
2264                { $$ = $4; }
2265        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_list ')'
2266                { $$ = nullptr; }
2267        ;
2268
2269type_list:                                                                                              // CFA
2270        type
2271                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2272        | assignment_expression
2273        | type_list ',' type
2274                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2275        | type_list ',' assignment_expression
2276                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2277        ;
2278
2279type_declaring_list:                                                                    // CFA
2280        OTYPE type_declarator
2281                { $$ = $2; }
2282        | storage_class_list OTYPE type_declarator
2283                { $$ = $3->addQualifiers( $1 ); }
2284        | type_declaring_list ',' type_declarator
2285                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2286        ;
2287
2288type_declarator:                                                                                // CFA
2289        type_declarator_name assertion_list_opt
2290                { $$ = $1->addAssertions( $2 ); }
2291        | type_declarator_name assertion_list_opt '=' type
2292                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2293        ;
2294
2295type_declarator_name:                                                                   // CFA
2296        no_attr_identifier_or_type_name
2297                {
2298                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TD );
2299                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2300                }
2301        | no_attr_identifier_or_type_name '(' push type_parameter_list pop ')'
2302                {
2303                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TG );
2304                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
2305                }
2306        ;
2307
2308trait_specifier:                                                                                // CFA
2309        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
2310                {
2311                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
2312                        $$ = DeclarationNode::newTrait( $2, $5, 0 );
2313                }
2314        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
2315                {
2316                        typedefTable.enterTrait( *$2 );
2317                        typedefTable.enterScope();
2318                }
2319          trait_declaration_list '}'
2320                {
2321                        typedefTable.leaveTrait();
2322                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
2323                        $$ = DeclarationNode::newTrait( $2, $5, $10 );
2324                }
2325        ;
2326
2327trait_declaration_list:                                                                 // CFA
2328        trait_declaration
2329        | trait_declaration_list push trait_declaration
2330                { $$ = $1->appendList( $3 ); }
2331        ;
2332
2333trait_declaration:                                                                              // CFA
2334        cfa_trait_declaring_list pop ';'
2335        | trait_declaring_list pop ';'
2336        ;
2337
2338cfa_trait_declaring_list:                                                               // CFA
2339        cfa_variable_specifier
2340                {
2341                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2342                        $$ = $1;
2343                }
2344        | cfa_function_specifier
2345                {
2346                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2347                        $$ = $1;
2348                }
2349        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2350                {
2351                        typedefTable.addToEnclosingScope2( *$5, TypedefTable::ID );
2352                        $$ = $1->appendList( $1->cloneType( $5 ) );
2353                }
2354        ;
2355
2356trait_declaring_list:                                                                   // CFA
2357        type_specifier declarator
2358                {
2359                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2360                        $$ = $2->addType( $1 );
2361                }
2362        | trait_declaring_list pop ',' push declarator
2363                {
2364                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2365                        $$ = $1->appendList( $1->cloneBaseType( $5 ) );
2366                }
2367        ;
2368
2369//***************************** EXTERNAL DEFINITIONS *****************************
2370
2371translation_unit:
2372        // empty
2373                {}                                                                                              // empty input file
2374        | external_definition_list
2375                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2376        ;
2377
2378external_definition_list:
2379        external_definition
2380        | external_definition_list push external_definition
2381                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2382        ;
2383
2384external_definition_list_opt:
2385        // empty
2386                { $$ = nullptr; }
2387        | external_definition_list
2388        ;
2389
2390external_definition:
2391        declaration
2392        | external_function_definition
2393        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2394                {
2395                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asmstmt( false, $3, 0 ) ) );
2396                }
2397        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2398                {
2399                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2400                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2401                }
2402          '{' external_definition_list_opt '}'
2403                {
2404                        linkage = linkageStack.top();
2405                        linkageStack.pop();
2406                        $$ = $5;
2407                }
2408        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2409                {
2410                        distExt( $2 );                                                          // mark all fields in list
2411                        $$ = $2;
2412                }
2413        | type_qualifier_list '{' external_definition_list '}'                  // CFA, namespace
2414        ;
2415
2416external_function_definition:
2417        function_definition
2418                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2419                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2420                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2421                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2422                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2423        | function_declarator compound_statement
2424                {
2425                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2426                        typedefTable.leaveScope();
2427                        $$ = $1->addFunctionBody( $2 );
2428                }
2429        | KR_function_declarator KR_declaration_list_opt compound_statement
2430                {
2431                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2432                        typedefTable.leaveScope();
2433                        $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 );
2434                }
2435        ;
2436
2437with_clause_opt:
2438        // empty
2439                { $$ = nullptr; }
2440        | WITH '(' tuple_expression_list ')'
2441                { $$ = $3; }
2442        ;
2443
2444function_definition:
2445        cfa_function_declaration with_clause_opt compound_statement     // CFA
2446                {
2447                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2448                        typedefTable.leaveScope();
2449                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2450                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2451                        $1->get_last()->addFunctionBody( $3, $2 );
2452                        $$ = $1;
2453                }
2454        | declaration_specifier function_declarator with_clause_opt compound_statement
2455                {
2456                        rebindForall( $1, $2 );
2457                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2458                        typedefTable.leaveScope();
2459                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2460                }
2461                // handles default int return type, OBSOLESCENT (see 1)
2462        | type_qualifier_list function_declarator with_clause_opt compound_statement
2463                {
2464                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2465                        typedefTable.leaveScope();
2466                        $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 );
2467                }
2468                // handles default int return type, OBSOLESCENT (see 1)
2469        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2470                {
2471                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2472                        typedefTable.leaveScope();
2473                        $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 );
2474                }
2475                // handles default int return type, OBSOLESCENT (see 1)
2476        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2477                {
2478                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2479                        typedefTable.leaveScope();
2480                        $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 );
2481                }
2482
2483                // Old-style K&R function definition, OBSOLESCENT (see 4)
2484        | declaration_specifier KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2485                {
2486                        rebindForall( $1, $2 );
2487                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2488                        typedefTable.leaveScope();
2489                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2490                }
2491                // handles default int return type, OBSOLESCENT (see 1)
2492        | type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2493                {
2494                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2495                        typedefTable.leaveScope();
2496                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 );
2497                }
2498                // handles default int return type, OBSOLESCENT (see 1)
2499        | declaration_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2500                {
2501                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2502                        typedefTable.leaveScope();
2503                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 );
2504                }
2505                // handles default int return type, OBSOLESCENT (see 1)
2506        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2507                {
2508                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2509                        typedefTable.leaveScope();
2510                        $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 );
2511                }
2512        ;
2513
2514declarator:
2515        variable_declarator
2516        | variable_type_redeclarator
2517        | function_declarator
2518        ;
2519
2520subrange:
2521        constant_expression '~' constant_expression                     // CFA, integer subrange
2522                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2523        ;
2524
2525asm_name_opt:                                                                                   // GCC
2526        // empty
2527                { $$ = nullptr; }
2528        | ASM '(' string_literal ')' attribute_list_opt
2529                {
2530                        DeclarationNode * name = new DeclarationNode();
2531                        name->asmName = $3;
2532                        $$ = name->addQualifiers( $5 );
2533                }
2534        ;
2535
2536attribute_list_opt:                                                                             // GCC
2537        // empty
2538                { $$ = nullptr; }
2539        | attribute_list
2540        ;
2541
2542attribute_list:                                                                                 // GCC
2543        attribute
2544        | attribute_list attribute
2545                { $$ = $2->addQualifiers( $1 ); }
2546        ;
2547
2548attribute:                                                                                              // GCC
2549        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2550                { $$ = $4; }
2551        ;
2552
2553attribute_name_list:                                                                    // GCC
2554        attribute_name
2555        | attribute_name_list ',' attribute_name
2556                { $$ = $3->addQualifiers( $1 ); }
2557        ;
2558
2559attribute_name:                                                                                 // GCC
2560        // empty
2561                { $$ = nullptr; }
2562        | attr_name
2563                { $$ = DeclarationNode::newAttribute( $1 ); }
2564        | attr_name '(' argument_expression_list ')'
2565                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2566        ;
2567
2568attr_name:                                                                                              // GCC
2569        IDENTIFIER
2570        | quasi_keyword
2571        | TYPEDEFname
2572        | TYPEGENname
2573        | FALLTHROUGH
2574                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2575        | CONST
2576                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2577        ;
2578
2579// ============================================================================
2580// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2581// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2582// in:
2583//
2584//              int (*f())[10] { ... };
2585//              ... (*f())[3] += 1;             // definition mimics usage
2586//
2587// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2588// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2589// ============================================================================
2590
2591// ----------------------------------------------------------------------------
2592// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2593// to define a variable or function prototype, e.g.:
2594//
2595//              valid declaration               invalid definition
2596//              -----------------               ------------------
2597//              int f;                                  int f {}
2598//              int *f;                                 int *f {}
2599//              int f[10];                              int f[10] {}
2600//              int (*f)(int);                  int (*f)(int) {}
2601//
2602// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2603// variable_declarator and function_declarator.
2604// ----------------------------------------------------------------------------
2605
2606// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2607// declaring an array of functions versus a pointer to an array of functions.
2608
2609variable_declarator:
2610        paren_identifier attribute_list_opt
2611                { $$ = $1->addQualifiers( $2 ); }
2612        | variable_ptr
2613        | variable_array attribute_list_opt
2614                { $$ = $1->addQualifiers( $2 ); }
2615        | variable_function attribute_list_opt
2616                { $$ = $1->addQualifiers( $2 ); }
2617        ;
2618
2619paren_identifier:
2620        identifier
2621                {
2622                        typedefTable.setNextIdentifier( *$1 );
2623                        $$ = DeclarationNode::newName( $1 );
2624                }
2625        | '(' paren_identifier ')'                                                      // redundant parenthesis
2626                { $$ = $2; }
2627        ;
2628
2629variable_ptr:
2630        ptrref_operator variable_declarator
2631                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2632        | ptrref_operator type_qualifier_list variable_declarator
2633                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2634        | '(' variable_ptr ')' attribute_list_opt
2635                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2636        ;
2637
2638variable_array:
2639        paren_identifier array_dimension
2640                { $$ = $1->addArray( $2 ); }
2641        | '(' variable_ptr ')' array_dimension
2642                { $$ = $2->addArray( $4 ); }
2643        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2644                { $$ = $2->addArray( $4 ); }
2645        | '(' variable_array ')'                                                        // redundant parenthesis
2646                { $$ = $2; }
2647        ;
2648
2649variable_function:
2650        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2651                { $$ = $2->addParamList( $6 ); }
2652        | '(' variable_function ')'                                                     // redundant parenthesis
2653                { $$ = $2; }
2654        ;
2655
2656// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2657// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2658// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2659
2660function_declarator:
2661        function_no_ptr attribute_list_opt
2662                { $$ = $1->addQualifiers( $2 ); }
2663        | function_ptr
2664        | function_array attribute_list_opt
2665                { $$ = $1->addQualifiers( $2 ); }
2666        ;
2667
2668function_no_ptr:
2669        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2670                { $$ = $1->addParamList( $4 ); }
2671        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2672                { $$ = $2->addParamList( $6 ); }
2673        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2674                { $$ = $2; }
2675        ;
2676
2677function_ptr:
2678        ptrref_operator function_declarator
2679                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2680        | ptrref_operator type_qualifier_list function_declarator
2681                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2682        | '(' function_ptr ')'
2683                { $$ = $2; }
2684        ;
2685
2686function_array:
2687        '(' function_ptr ')' array_dimension
2688                { $$ = $2->addArray( $4 ); }
2689        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2690                { $$ = $2->addArray( $4 ); }
2691        | '(' function_array ')'                                                        // redundant parenthesis
2692                { $$ = $2; }
2693        ;
2694
2695// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2696//
2697//   f( a, b, c ) int a, *b, c[]; {}
2698//
2699// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2700// returning arrays and functions versus pointers to arrays and functions.
2701
2702KR_function_declarator:
2703        KR_function_no_ptr
2704        | KR_function_ptr
2705        | KR_function_array
2706        ;
2707
2708KR_function_no_ptr:
2709        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2710                { $$ = $1->addIdList( $3 ); }
2711        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2712                { $$ = $2->addParamList( $6 ); }
2713        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2714                { $$ = $2; }
2715        ;
2716
2717KR_function_ptr:
2718        ptrref_operator KR_function_declarator
2719                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2720        | ptrref_operator type_qualifier_list KR_function_declarator
2721                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2722        | '(' KR_function_ptr ')'
2723                { $$ = $2; }
2724        ;
2725
2726KR_function_array:
2727        '(' KR_function_ptr ')' array_dimension
2728                { $$ = $2->addArray( $4 ); }
2729        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2730                { $$ = $2->addArray( $4 ); }
2731        | '(' KR_function_array ')'                                                     // redundant parenthesis
2732                { $$ = $2; }
2733        ;
2734
2735// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2736//
2737//              typedef int foo;
2738//              {
2739//                 int foo; // redefine typedef name in new scope
2740//              }
2741//
2742// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2743// and functions versus pointers to arrays and functions.
2744
2745variable_type_redeclarator:
2746        paren_type attribute_list_opt
2747                { $$ = $1->addQualifiers( $2 ); }
2748        | type_ptr
2749        | type_array attribute_list_opt
2750                { $$ = $1->addQualifiers( $2 ); }
2751        | type_function attribute_list_opt
2752                { $$ = $1->addQualifiers( $2 ); }
2753        ;
2754
2755paren_type:
2756        typedef
2757        | '(' paren_type ')'
2758                { $$ = $2; }
2759        ;
2760
2761type_ptr:
2762        ptrref_operator variable_type_redeclarator
2763                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2764        | ptrref_operator type_qualifier_list variable_type_redeclarator
2765                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2766        | '(' type_ptr ')' attribute_list_opt
2767                { $$ = $2->addQualifiers( $4 ); }
2768        ;
2769
2770type_array:
2771        paren_type array_dimension
2772                { $$ = $1->addArray( $2 ); }
2773        | '(' type_ptr ')' array_dimension
2774                { $$ = $2->addArray( $4 ); }
2775        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2776                { $$ = $2->addArray( $4 ); }
2777        | '(' type_array ')'                                                            // redundant parenthesis
2778                { $$ = $2; }
2779        ;
2780
2781type_function:
2782        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2783                { $$ = $1->addParamList( $4 ); }
2784        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2785                { $$ = $2->addParamList( $6 ); }
2786        | '(' type_function ')'                                                         // redundant parenthesis
2787                { $$ = $2; }
2788        ;
2789
2790// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2791// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2792// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2793// pointers to arrays and functions.
2794
2795identifier_parameter_declarator:
2796        paren_identifier attribute_list_opt
2797                { $$ = $1->addQualifiers( $2 ); }
2798        | '&' MUTEX paren_identifier attribute_list_opt
2799                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2800        | identifier_parameter_ptr
2801        | identifier_parameter_array attribute_list_opt
2802                { $$ = $1->addQualifiers( $2 ); }
2803        | identifier_parameter_function attribute_list_opt
2804                { $$ = $1->addQualifiers( $2 ); }
2805        ;
2806
2807identifier_parameter_ptr:
2808        ptrref_operator identifier_parameter_declarator
2809                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2810        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2811                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2812        | '(' identifier_parameter_ptr ')' attribute_list_opt
2813                { $$ = $2->addQualifiers( $4 ); }
2814        ;
2815
2816identifier_parameter_array:
2817        paren_identifier array_parameter_dimension
2818                { $$ = $1->addArray( $2 ); }
2819        | '(' identifier_parameter_ptr ')' array_dimension
2820                { $$ = $2->addArray( $4 ); }
2821        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2822                { $$ = $2->addArray( $4 ); }
2823        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2824                { $$ = $2; }
2825        ;
2826
2827identifier_parameter_function:
2828        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2829                { $$ = $1->addParamList( $4 ); }
2830        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2831                { $$ = $2->addParamList( $6 ); }
2832        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2833                { $$ = $2; }
2834        ;
2835
2836// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2837// e.g.:
2838//
2839//              typedef int foo;
2840//              forall( otype T ) struct foo;
2841//              int f( int foo ); // redefine typedef name in new scope
2842//
2843// and allows the C99 array options, which can only appear in a parameter list.
2844
2845type_parameter_redeclarator:
2846        typedef attribute_list_opt
2847                { $$ = $1->addQualifiers( $2 ); }
2848        | '&' MUTEX typedef attribute_list_opt
2849                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2850        | type_parameter_ptr
2851        | type_parameter_array attribute_list_opt
2852                { $$ = $1->addQualifiers( $2 ); }
2853        | type_parameter_function attribute_list_opt
2854                { $$ = $1->addQualifiers( $2 ); }
2855        ;
2856
2857typedef:
2858        TYPEDEFname
2859                {
2860                        typedefTable.setNextIdentifier( *$1 );
2861                        $$ = DeclarationNode::newName( $1 );
2862                }
2863        | TYPEGENname
2864                {
2865                        typedefTable.setNextIdentifier( *$1 );
2866                        $$ = DeclarationNode::newName( $1 );
2867                }
2868        ;
2869
2870type_parameter_ptr:
2871        ptrref_operator type_parameter_redeclarator
2872                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2873        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2874                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2875        | '(' type_parameter_ptr ')' attribute_list_opt
2876                { $$ = $2->addQualifiers( $4 ); }
2877        ;
2878
2879type_parameter_array:
2880        typedef array_parameter_dimension
2881                { $$ = $1->addArray( $2 ); }
2882        | '(' type_parameter_ptr ')' array_parameter_dimension
2883                { $$ = $2->addArray( $4 ); }
2884        ;
2885
2886type_parameter_function:
2887        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2888                { $$ = $1->addParamList( $4 ); }
2889        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2890                { $$ = $2->addParamList( $6 ); }
2891        ;
2892
2893// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2894// which the type applies, e.g.:
2895//
2896//              sizeof( int );
2897//              sizeof( int * );
2898//              sizeof( int [10] );
2899//              sizeof( int (*)() );
2900//              sizeof( int () );
2901//
2902// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2903// and functions versus pointers to arrays and functions.
2904
2905abstract_declarator:
2906        abstract_ptr
2907        | abstract_array attribute_list_opt
2908                { $$ = $1->addQualifiers( $2 ); }
2909        | abstract_function attribute_list_opt
2910                { $$ = $1->addQualifiers( $2 ); }
2911        ;
2912
2913abstract_ptr:
2914        ptrref_operator
2915                { $$ = DeclarationNode::newPointer( 0, $1 ); }
2916        | ptrref_operator type_qualifier_list
2917                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2918        | ptrref_operator abstract_declarator
2919                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2920        | ptrref_operator type_qualifier_list abstract_declarator
2921                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2922        | '(' abstract_ptr ')' attribute_list_opt
2923                { $$ = $2->addQualifiers( $4 ); }
2924        ;
2925
2926abstract_array:
2927        array_dimension
2928        | '(' abstract_ptr ')' array_dimension
2929                { $$ = $2->addArray( $4 ); }
2930        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2931                { $$ = $2->addArray( $4 ); }
2932        | '(' abstract_array ')'                                                        // redundant parenthesis
2933                { $$ = $2; }
2934        ;
2935
2936abstract_function:
2937        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2938                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2939        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2940                { $$ = $2->addParamList( $6 ); }
2941        | '(' abstract_function ')'                                                     // redundant parenthesis
2942                { $$ = $2; }
2943        ;
2944
2945array_dimension:
2946                // Only the first dimension can be empty.
2947        '[' ']'
2948                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2949        | '[' ']' multi_array_dimension
2950                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2951        | multi_array_dimension
2952        ;
2953
2954multi_array_dimension:
2955        '[' push assignment_expression pop ']'
2956                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2957        | '[' push '*' pop ']'                                                          // C99
2958                { $$ = DeclarationNode::newVarArray( 0 ); }
2959        | multi_array_dimension '[' push assignment_expression pop ']'
2960                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2961        | multi_array_dimension '[' push '*' pop ']'            // C99
2962                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2963        ;
2964
2965// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2966// identifier to which the type applies, e.g.:
2967//
2968//              int f( int );                   // not handled here
2969//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
2970//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
2971//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2972//
2973// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2974// and functions versus pointers to arrays and functions. In addition, the pattern handles the
2975// special meaning of parenthesis around a typedef name:
2976//
2977//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2978//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2979//              not as redundant parentheses around the identifier."
2980//
2981// For example:
2982//
2983//              typedef float T;
2984//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2985//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2986//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2987//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2988//
2989// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2990// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2991// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2992// functions.
2993
2994abstract_parameter_declarator:
2995        abstract_parameter_ptr
2996        | '&' MUTEX attribute_list_opt
2997                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
2998        | abstract_parameter_array attribute_list_opt
2999                { $$ = $1->addQualifiers( $2 ); }
3000        | abstract_parameter_function attribute_list_opt
3001                { $$ = $1->addQualifiers( $2 ); }
3002        ;
3003
3004abstract_parameter_ptr:
3005        ptrref_operator
3006                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3007        | ptrref_operator type_qualifier_list
3008                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3009        | ptrref_operator abstract_parameter_declarator
3010                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3011        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3012                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3013        | '(' abstract_parameter_ptr ')' attribute_list_opt
3014                { $$ = $2->addQualifiers( $4 ); }
3015        ;
3016
3017abstract_parameter_array:
3018        array_parameter_dimension
3019        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3020                { $$ = $2->addArray( $4 ); }
3021        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3022                { $$ = $2->addArray( $4 ); }
3023        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3024                { $$ = $2; }
3025        ;
3026
3027abstract_parameter_function:
3028        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3029                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3030        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3031                { $$ = $2->addParamList( $6 ); }
3032        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3033                { $$ = $2; }
3034        ;
3035
3036array_parameter_dimension:
3037                // Only the first dimension can be empty or have qualifiers.
3038        array_parameter_1st_dimension
3039        | array_parameter_1st_dimension multi_array_dimension
3040                { $$ = $1->addArray( $2 ); }
3041        | multi_array_dimension
3042        ;
3043
3044// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3045//
3046//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3047//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3048
3049array_parameter_1st_dimension:
3050        '[' ']'
3051                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3052        // multi_array_dimension handles the '[' '*' ']' case
3053        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3054                { $$ = DeclarationNode::newVarArray( $3 ); }
3055        | '[' push type_qualifier_list pop ']'
3056                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3057        // multi_array_dimension handles the '[' assignment_expression ']' case
3058        | '[' push type_qualifier_list assignment_expression pop ']'
3059                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3060        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3061                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3062        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3063                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3064        ;
3065
3066// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3067//
3068//              struct S {
3069//          int;
3070//          int *;
3071//          int [10];
3072//          int (*)();
3073//      };
3074
3075variable_abstract_declarator:
3076        variable_abstract_ptr
3077        | variable_abstract_array attribute_list_opt
3078                { $$ = $1->addQualifiers( $2 ); }
3079        | variable_abstract_function attribute_list_opt
3080                { $$ = $1->addQualifiers( $2 ); }
3081        ;
3082
3083variable_abstract_ptr:
3084        ptrref_operator
3085                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3086        | ptrref_operator type_qualifier_list
3087                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3088        | ptrref_operator variable_abstract_declarator
3089                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3090        | ptrref_operator type_qualifier_list variable_abstract_declarator
3091                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3092        | '(' variable_abstract_ptr ')' attribute_list_opt
3093                { $$ = $2->addQualifiers( $4 ); }
3094        ;
3095
3096variable_abstract_array:
3097        array_dimension
3098        | '(' variable_abstract_ptr ')' array_dimension
3099                { $$ = $2->addArray( $4 ); }
3100        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3101                { $$ = $2->addArray( $4 ); }
3102        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3103                { $$ = $2; }
3104        ;
3105
3106variable_abstract_function:
3107        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3108                { $$ = $2->addParamList( $6 ); }
3109        | '(' variable_abstract_function ')'                            // redundant parenthesis
3110                { $$ = $2; }
3111        ;
3112
3113// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3114// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3115
3116cfa_identifier_parameter_declarator_tuple:                              // CFA
3117        cfa_identifier_parameter_declarator_no_tuple
3118        | cfa_abstract_tuple
3119        | type_qualifier_list cfa_abstract_tuple
3120                { $$ = $2->addQualifiers( $1 ); }
3121        ;
3122
3123cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3124        cfa_identifier_parameter_ptr
3125        | cfa_identifier_parameter_array
3126        ;
3127
3128cfa_identifier_parameter_ptr:                                                   // CFA
3129                // No SUE declaration in parameter list.
3130        ptrref_operator type_specifier_nobody
3131                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3132        | type_qualifier_list ptrref_operator type_specifier_nobody
3133                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3134        | ptrref_operator cfa_abstract_function
3135                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3136        | type_qualifier_list ptrref_operator cfa_abstract_function
3137                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3138        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3139                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3140        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3141                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3142        ;
3143
3144cfa_identifier_parameter_array:                                                 // CFA
3145                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3146                // shift/reduce conflict with new-style empty (void) function return type.
3147        '[' ']' type_specifier_nobody
3148                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3149        | cfa_array_parameter_1st_dimension type_specifier_nobody
3150                { $$ = $2->addNewArray( $1 ); }
3151        | '[' ']' multi_array_dimension type_specifier_nobody
3152                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3153        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3154                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3155        | multi_array_dimension type_specifier_nobody
3156                { $$ = $2->addNewArray( $1 ); }
3157
3158        | '[' ']' cfa_identifier_parameter_ptr
3159                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3160        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3161                { $$ = $2->addNewArray( $1 ); }
3162        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3163                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3164        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3165                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3166        | multi_array_dimension cfa_identifier_parameter_ptr
3167                { $$ = $2->addNewArray( $1 ); }
3168        ;
3169
3170cfa_array_parameter_1st_dimension:
3171        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3172                { $$ = DeclarationNode::newVarArray( $3 ); }
3173        | '[' push type_qualifier_list assignment_expression pop ']'
3174                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3175        | '[' push declaration_qualifier_list assignment_expression pop ']'
3176                // declaration_qualifier_list must be used because of shift/reduce conflict with
3177                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3178                // appear in this context.
3179                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3180        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3181                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3182        ;
3183
3184// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3185// identifier to which the type applies, e.g.:
3186//
3187//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3188//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3189//
3190// These rules need LR(3):
3191//
3192//              cfa_abstract_tuple identifier_or_type_name
3193//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
3194//
3195// since a function return type can be syntactically identical to a tuple type:
3196//
3197//              [int, int] t;
3198//              [int, int] f( int );
3199//
3200// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3201// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3202// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3203// duplicated when appearing with cfa_function_specifier.
3204
3205cfa_abstract_declarator_tuple:                                                  // CFA
3206        cfa_abstract_tuple
3207        | type_qualifier_list cfa_abstract_tuple
3208                { $$ = $2->addQualifiers( $1 ); }
3209        | cfa_abstract_declarator_no_tuple
3210        ;
3211
3212cfa_abstract_declarator_no_tuple:                                               // CFA
3213        cfa_abstract_ptr
3214        | cfa_abstract_array
3215        ;
3216
3217cfa_abstract_ptr:                                                                               // CFA
3218        ptrref_operator type_specifier
3219                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3220        | type_qualifier_list ptrref_operator type_specifier
3221                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3222        | ptrref_operator cfa_abstract_function
3223                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3224        | type_qualifier_list ptrref_operator cfa_abstract_function
3225                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3226        | ptrref_operator cfa_abstract_declarator_tuple
3227                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3228        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3229                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3230        ;
3231
3232cfa_abstract_array:                                                                             // CFA
3233                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3234                // empty (void) function return type.
3235        '[' ']' type_specifier
3236                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3237        | '[' ']' multi_array_dimension type_specifier
3238                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3239        | multi_array_dimension type_specifier
3240                { $$ = $2->addNewArray( $1 ); }
3241        | '[' ']' cfa_abstract_ptr
3242                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3243        | '[' ']' multi_array_dimension cfa_abstract_ptr
3244                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3245        | multi_array_dimension cfa_abstract_ptr
3246                { $$ = $2->addNewArray( $1 ); }
3247        ;
3248
3249cfa_abstract_tuple:                                                                             // CFA
3250        '[' push cfa_abstract_parameter_list pop ']'
3251                { $$ = DeclarationNode::newTuple( $3 ); }
3252        ;
3253
3254cfa_abstract_function:                                                                  // CFA
3255//      '[' ']' '(' cfa_parameter_type_list_opt ')'
3256//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3257        cfa_abstract_tuple '(' push cfa_parameter_type_list_opt pop ')'
3258                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3259        | cfa_function_return '(' push cfa_parameter_type_list_opt pop ')'
3260                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3261        ;
3262
3263// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3264//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3265//
3266// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3267//    the declaration specifiers in a declaration is an obsolescent feature."
3268//
3269// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3270//    prototype-format parameter type declarators) is an obsolescent feature."
3271//
3272// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3273//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3274
3275//************************* MISCELLANEOUS ********************************
3276
3277comma_opt:                                                                                              // redundant comma
3278        // empty
3279        | ','
3280        ;
3281
3282default_initialize_opt:
3283        // empty
3284                { $$ = nullptr; }
3285        | '=' assignment_expression
3286                { $$ = $2; }
3287        ;
3288
3289%%
3290// ----end of grammar----
3291
3292// Local Variables: //
3293// mode: c++ //
3294// tab-width: 4 //
3295// compile-command: "make install" //
3296// End: //
Note: See TracBrowser for help on using the repository browser.