source: src/Parser/parser.yy @ 948fdef

arm-ehjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-expr
Last change on this file since 948fdef was 948fdef, checked in by Peter A. Buhr <pabuhr@…>, 21 months ago

change backquotes identifiers to xxx syntax, change priority of postfix function call

  • Property mode set to 100644
File size: 135.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sat Feb  1 10:04:40 2020
13// Update Count     : 4440
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168NameExpr * build_postfix_name( const string * name ) {
169        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
170        delete name;
171        return new_name;
172} // build_postfix_name
173
174DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
175        if ( ! fieldList ) {                                                            // field declarator ?
176                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
177                        stringstream ss;
178                        typeSpec->type->print( ss );
179                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
180                        return nullptr;
181                } // if
182                fieldList = DeclarationNode::newName( nullptr );
183        } // if
184        return distAttr( typeSpec, fieldList );                         // mark all fields in list
185} // fieldDecl
186
187ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
188        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
189        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
190        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
191        } // if
192        return new ForCtrl(
193                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
194                // NULL comp/inc => leave blank
195                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
196                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
197                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
198} // forCtrl
199
200ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
201        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
202                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
203        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
204                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
205                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
206                } else {
207                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
208                } // if
209        } else {
210                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
211        } // if
212} // forCtrl
213
214bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
215
216// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
217#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
218if ( N ) {                                                                                                                                              \
219        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
220        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
221        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
222        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
223        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
224} else {                                                                                                                                                \
225        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
226        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
227        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
228}
229%}
230
231%define parse.error verbose
232
233// Types declaration for productions
234%union {
235        Token tok;
236        ParseNode * pn;
237        ExpressionNode * en;
238        DeclarationNode * decl;
239        AggregateDecl::Aggregate aggKey;
240        TypeDecl::Kind tclass;
241        StatementNode * sn;
242        WaitForStmt * wfs;
243        Expression * constant;
244        IfCtrl * ifctl;
245        ForCtrl * fctl;
246        enum OperKinds compop;
247        LabelNode * label;
248        InitializerNode * in;
249        OperKinds op;
250        std::string * str;
251        bool flag;
252        CatchStmt::Kind catch_kind;
253        GenericExpr * genexpr;
254}
255
256//************************* TERMINAL TOKENS ********************************
257
258// keywords
259%token TYPEDEF
260%token EXTERN STATIC AUTO REGISTER
261%token THREADLOCAL                                                                              // C11
262%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
263%token NORETURN                                                                                 // C11
264%token CONST VOLATILE
265%token RESTRICT                                                                                 // C99
266%token ATOMIC                                                                                   // C11
267%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
268%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
269%token BOOL COMPLEX IMAGINARY                                                   // C99
270%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
271%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
272%token ZERO_T ONE_T                                                                             // CFA
273%token VALIST                                                                                   // GCC
274%token AUTO_TYPE                                                                                // GCC
275%token TYPEOF BASETYPEOF LABEL                                                  // GCC
276%token ENUM STRUCT UNION
277%token EXCEPTION                                                                                // CFA
278%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
279%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
280%token SIZEOF OFFSETOF
281// %token SUSPEND RESUME                                                                        // CFA
282%token ATTRIBUTE EXTENSION                                                              // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
290%token<tok> TIMEOUT                             WOR
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list              argument_expression                     default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en>   bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581        | type_name '.' identifier                                                      // CFA, nested type
582                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
583        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
584                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
585        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
586                {
587                        // add the missing control expression to the GenericExpr and return it
588                        $5->control = maybeMoveBuild<Expression>( $3 );
589                        $$ = new ExpressionNode( $5 );
590                }
591        // | RESUME '(' comma_expression ')'
592        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
593        // | RESUME '(' comma_expression ')' compound_statement
594        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
595        ;
596
597generic_assoc_list:                                                                             // C11
598        generic_association
599        | generic_assoc_list ',' generic_association
600                {
601                        // steal the association node from the singleton and delete the wrapper
602                        $1->associations.splice($1->associations.end(), $3->associations);
603                        delete $3;
604                        $$ = $1;
605                }
606        ;
607
608generic_association:                                                                    // C11
609        type_no_function ':' assignment_expression
610                {
611                        // create a GenericExpr wrapper with one association pair
612                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
613                }
614        | DEFAULT ':' assignment_expression
615                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
616        ;
617
618postfix_expression:
619        primary_expression
620        | postfix_expression '[' assignment_expression ']'
621                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
622                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
623                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
624                // equivalent to the old x[i,j].
625                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
626        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
627                {
628                        Token fn;
629                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
630                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
631                }
632        | postfix_expression '(' argument_expression_list ')'
633                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
634        | postfix_expression '`' identifier                                     // CFA, postfix call
635                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
636        | constant '`' identifier                                                       // CFA, postfix call
637                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
638        | string_literal '`' identifier                                         // CFA, postfix call
639                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
640        | postfix_expression '.' identifier
641                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
642        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
643                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
644        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
645                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
646        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
647                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
648        | postfix_expression '.' aggregate_control
649                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
650        | postfix_expression ARROW identifier
651                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
652        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
653                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
654        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
655                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
656        | postfix_expression ICR
657                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
658        | postfix_expression DECR
659                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
660        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
661                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
662        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
663                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
664        | '^' primary_expression '{' argument_expression_list '}' // CFA, destructor call
665                {
666                        Token fn;
667                        fn.str = new string( "^?{}" );                          // location undefined
668                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
669                }
670        ;
671
672argument_expression_list:
673        // empty
674                { $$ = nullptr; }
675        | argument_expression
676        | argument_expression_list ',' argument_expression
677                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
678        ;
679
680argument_expression:
681        '@'                                                                                                     // CFA, default parameter
682                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
683                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
684        | assignment_expression
685        ;
686
687field_name_list:                                                                                // CFA, tuple field selector
688        field
689        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
690        ;
691
692field:                                                                                                  // CFA, tuple field selector
693        field_name
694        | FLOATING_DECIMALconstant field
695                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
696        | FLOATING_DECIMALconstant '[' field_name_list ']'
697                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
698        | field_name '.' field
699                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
700        | field_name '.' '[' field_name_list ']'
701                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
702        | field_name ARROW field
703                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704        | field_name ARROW '[' field_name_list ']'
705                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
706        ;
707
708field_name:
709        INTEGERconstant fraction_constants_opt
710                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
711        | FLOATINGconstant fraction_constants_opt
712                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
713        | identifier fraction_constants_opt
714                {
715                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
716                }
717        ;
718
719fraction_constants_opt:
720        // empty
721                { $$ = nullptr; }
722        | fraction_constants_opt FLOATING_FRACTIONconstant
723                {
724                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
725                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
726                }
727        ;
728
729unary_expression:
730        postfix_expression
731                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
732                // semantics checks, e.g., ++3, 3--, *3, &&3
733        | constant
734        | string_literal
735                { $$ = new ExpressionNode( $1 ); }
736        | EXTENSION cast_expression                                                     // GCC
737                { $$ = $2->set_extension( true ); }
738                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
739                //              { * X; }         // dereference X
740                //              { * int X; } // CFA declaration of pointer to int
741        | ptrref_operator cast_expression                                       // CFA
742                {
743                        switch ( $1 ) {
744                          case OperKinds::AddressOf:
745                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
746                                break;
747                          case OperKinds::PointTo:
748                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
749                                break;
750                          case OperKinds::And:
751                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
752                                break;
753                          default:
754                                assert( false );
755                        }
756                }
757        | unary_operator cast_expression
758                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
759        | ICR unary_expression
760                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
761        | DECR unary_expression
762                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
763        | SIZEOF unary_expression
764                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
765        | SIZEOF '(' type_no_function ')'
766                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
767        | ALIGNOF unary_expression                                                      // GCC, variable alignment
768                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
770                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
771        | OFFSETOF '(' type_no_function ',' identifier ')'
772                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
773        ;
774
775ptrref_operator:
776        '*'                                                                                     { $$ = OperKinds::PointTo; }
777        | '&'                                                                           { $$ = OperKinds::AddressOf; }
778                // GCC, address of label must be handled by semantic check for ref,ref,label
779        | ANDAND                                                                        { $$ = OperKinds::And; }
780        ;
781
782unary_operator:
783        '+'                                                                                     { $$ = OperKinds::UnPlus; }
784        | '-'                                                                           { $$ = OperKinds::UnMinus; }
785        | '!'                                                                           { $$ = OperKinds::Neg; }
786        | '~'                                                                           { $$ = OperKinds::BitNeg; }
787        ;
788
789cast_expression:
790        unary_expression
791        | '(' type_no_function ')' cast_expression
792                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
793        | '(' aggregate_control '&' ')' cast_expression         // CFA
794                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
795                // VIRTUAL cannot be opt because of look ahead issues
796        | '(' VIRTUAL ')' cast_expression                                       // CFA
797                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
798        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
799                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
800        | '(' RETURN type_no_function ')' cast_expression       // CFA
801                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
802        | '(' COERCE type_no_function ')' cast_expression       // CFA
803                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
804        | '(' qualifier_cast_list ')' cast_expression           // CFA
805                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
806//      | '(' type_no_function ')' tuple
807//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
808        ;
809
810qualifier_cast_list:
811        cast_modifier type_qualifier_name
812        | cast_modifier MUTEX
813        | qualifier_cast_list cast_modifier type_qualifier_name
814        | qualifier_cast_list cast_modifier MUTEX
815        ;
816
817cast_modifier:
818        '-'
819        | '+'
820        ;
821
822exponential_expression:
823        cast_expression
824        | exponential_expression '\\' cast_expression
825                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
826        ;
827
828multiplicative_expression:
829        exponential_expression
830        | multiplicative_expression '*' exponential_expression
831                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
832        | multiplicative_expression '/' exponential_expression
833                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
834        | multiplicative_expression '%' exponential_expression
835                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
836        ;
837
838additive_expression:
839        multiplicative_expression
840        | additive_expression '+' multiplicative_expression
841                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
842        | additive_expression '-' multiplicative_expression
843                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
844        ;
845
846shift_expression:
847        additive_expression
848        | shift_expression LS additive_expression
849                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
850        | shift_expression RS additive_expression
851                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
852        ;
853
854relational_expression:
855        shift_expression
856        | relational_expression '<' shift_expression
857                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
858        | relational_expression '>' shift_expression
859                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
860        | relational_expression LE shift_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
862        | relational_expression GE shift_expression
863                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
864        ;
865
866equality_expression:
867        relational_expression
868        | equality_expression EQ relational_expression
869                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
870        | equality_expression NE relational_expression
871                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
872        ;
873
874AND_expression:
875        equality_expression
876        | AND_expression '&' equality_expression
877                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
878        ;
879
880exclusive_OR_expression:
881        AND_expression
882        | exclusive_OR_expression '^' AND_expression
883                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
884        ;
885
886inclusive_OR_expression:
887        exclusive_OR_expression
888        | inclusive_OR_expression '|' exclusive_OR_expression
889                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
890        ;
891
892logical_AND_expression:
893        inclusive_OR_expression
894        | logical_AND_expression ANDAND inclusive_OR_expression
895                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
896        ;
897
898logical_OR_expression:
899        logical_AND_expression
900        | logical_OR_expression OROR logical_AND_expression
901                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
902        ;
903
904conditional_expression:
905        logical_OR_expression
906        | logical_OR_expression '?' comma_expression ':' conditional_expression
907                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
908                // FIX ME: computes $1 twice
909        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
910                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
911        ;
912
913constant_expression:
914        conditional_expression
915        ;
916
917assignment_expression:
918                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
919        conditional_expression
920        | unary_expression assignment_operator assignment_expression
921                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
922        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
923                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
924        ;
925
926assignment_expression_opt:
927        // empty
928                { $$ = nullptr; }
929        | assignment_expression
930        ;
931
932assignment_operator:
933        '='                                                                                     { $$ = OperKinds::Assign; }
934        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
935        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
936        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
937        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
938        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
939        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
940        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
941        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
942        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
943        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
944        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
945        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
946        ;
947
948tuple:                                                                                                  // CFA, tuple
949                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
950                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
951//      '[' ']'
952//              { $$ = new ExpressionNode( build_tuple() ); }
953//      | '[' push assignment_expression pop ']'
954//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
955        '[' ',' tuple_expression_list ']'
956                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
957        | '[' push assignment_expression pop ',' tuple_expression_list ']'
958                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
959        ;
960
961tuple_expression_list:
962        assignment_expression_opt
963        | tuple_expression_list ',' assignment_expression_opt
964                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
965        ;
966
967comma_expression:
968        assignment_expression
969        | comma_expression ',' assignment_expression
970                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
971        ;
972
973comma_expression_opt:
974        // empty
975                { $$ = nullptr; }
976        | comma_expression
977        ;
978
979//*************************** STATEMENTS *******************************
980
981statement:
982        labeled_statement
983        | compound_statement
984        | expression_statement
985        | selection_statement
986        | iteration_statement
987        | jump_statement
988        | with_statement
989        | mutex_statement
990        | waitfor_statement
991        | exception_statement
992        | enable_disable_statement
993                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
994        | asm_statement
995        | DIRECTIVE
996                { $$ = new StatementNode( build_directive( $1 ) ); }
997        ;
998
999labeled_statement:
1000                // labels cannot be identifiers 0 or 1
1001        identifier_or_type_name ':' attribute_list_opt statement
1002                { $$ = $4->add_label( $1, $3 ); }
1003        ;
1004
1005compound_statement:
1006        '{' '}'
1007                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1008        | '{' push
1009          local_label_declaration_opt                                           // GCC, local labels
1010          statement_decl_list                                                           // C99, intermix declarations and statements
1011          pop '}'
1012                { $$ = new StatementNode( build_compound( $4 ) ); }
1013        ;
1014
1015statement_decl_list:                                                                    // C99
1016        statement_decl
1017        | statement_decl_list statement_decl
1018                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1019        ;
1020
1021statement_decl:
1022        declaration                                                                                     // CFA, new & old style declarations
1023                { $$ = new StatementNode( $1 ); }
1024        | EXTENSION declaration                                                         // GCC
1025                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1026        | function_definition
1027                { $$ = new StatementNode( $1 ); }
1028        | EXTENSION function_definition                                         // GCC
1029                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1030        | statement
1031        ;
1032
1033statement_list_nodecl:
1034        statement
1035        | statement_list_nodecl statement
1036                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1037        ;
1038
1039expression_statement:
1040        comma_expression_opt ';'
1041                { $$ = new StatementNode( build_expr( $1 ) ); }
1042        ;
1043
1044selection_statement:
1045                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1046                        // the inherent S/R conflict with THEN/ELSE.
1047        push if_statement pop
1048                { $$ = $2; }
1049        | SWITCH '(' comma_expression ')' case_clause
1050                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1051        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1052                {
1053                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1054                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1055                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1056                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1057                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1058                        // statement.
1059                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1060                }
1061        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1062                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1063        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1064                {
1065                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1066                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1067                }
1068        ;
1069
1070if_statement:
1071        IF '(' if_control_expression ')' statement                      %prec THEN
1072                // explicitly deal with the shift/reduce conflict on if/else
1073                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1074        | IF '(' if_control_expression ')' statement ELSE statement
1075                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1076        ;
1077
1078if_control_expression:
1079        comma_expression
1080                { $$ = new IfCtrl( nullptr, $1 ); }
1081        | c_declaration                                                                         // no semi-colon
1082                { $$ = new IfCtrl( $1, nullptr ); }
1083        | cfa_declaration                                                                       // no semi-colon
1084                { $$ = new IfCtrl( $1, nullptr ); }
1085        | declaration comma_expression                                          // semi-colon separated
1086                { $$ = new IfCtrl( $1, $2 ); }
1087        ;
1088
1089// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1090// clause allows a list of values and subranges.
1091
1092case_value:                                                                                             // CFA
1093        constant_expression                                                     { $$ = $1; }
1094        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1095                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1096        | subrange                                                                                      // CFA, subrange
1097        ;
1098
1099case_value_list:                                                                                // CFA
1100        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1101                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1102        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1103        ;
1104
1105case_label:                                                                                             // CFA
1106        CASE case_value_list ':'                                        { $$ = $2; }
1107        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1108                // A semantic check is required to ensure only one default clause per switch/choose statement.
1109        ;
1110
1111//label_list_opt:
1112//      // empty
1113//      | identifier_or_type_name ':'
1114//      | label_list_opt identifier_or_type_name ':'
1115//      ;
1116
1117case_label_list:                                                                                // CFA
1118        case_label
1119        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1120        ;
1121
1122case_clause:                                                                                    // CFA
1123        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1124        ;
1125
1126switch_clause_list_opt:                                                                 // CFA
1127        // empty
1128                { $$ = nullptr; }
1129        | switch_clause_list
1130        ;
1131
1132switch_clause_list:                                                                             // CFA
1133        case_label_list statement_list_nodecl
1134                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1135        | switch_clause_list case_label_list statement_list_nodecl
1136                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1137        ;
1138
1139iteration_statement:
1140        WHILE '(' push if_control_expression ')' statement pop
1141                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1142        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1143                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1144        | DO statement WHILE '(' comma_expression ')' ';'
1145                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1146        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1147                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1148        | FOR '(' push for_control_expression_list ')' statement pop
1149                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1150        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1151                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1152        ;
1153
1154for_control_expression_list:
1155        for_control_expression
1156        | for_control_expression_list ':' for_control_expression
1157                // ForCtrl + ForCtrl:
1158                //    init + init => multiple declaration statements that are hoisted
1159                //    condition + condition => (expression) && (expression)
1160                //    change + change => (expression), (expression)
1161                {
1162                        $1->init->set_last( $3->init );
1163                        if ( $1->condition ) {
1164                                if ( $3->condition ) {
1165                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1166                                } // if
1167                        } else $1->condition = $3->condition;
1168                        if ( $1->change ) {
1169                                if ( $3->change ) {
1170                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1171                                } // if
1172                        } else $1->change = $3->change;
1173                        $$ = $1;
1174                }
1175        ;
1176
1177for_control_expression:
1178        ';' comma_expression_opt ';' comma_expression_opt
1179                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1180        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1181                { $$ = new ForCtrl( $1, $3, $5 ); }
1182        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1183                { $$ = new ForCtrl( $1, $2, $4 ); }
1184
1185        | comma_expression                                                                      // CFA
1186                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1187                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1188        | '=' comma_expression                                                                  // CFA
1189                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1190                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1191        | comma_expression inclexcl comma_expression            // CFA
1192                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1193        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1194                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1195        | comma_expression ';' comma_expression                         // CFA
1196                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1197                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1198        | comma_expression ';' '=' comma_expression                             // CFA
1199                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1200                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1201        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1202                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1203        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1204                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1205
1206                // There is a S/R conflicit if ~ and -~ are factored out.
1207        | comma_expression ';' comma_expression '~' '@'         // CFA
1208                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1209        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1210                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1211        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1212                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1213        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1214                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1215        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1216                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1217        ;
1218
1219inclexcl:
1220        '~'
1221                { $$ = OperKinds::LThan; }
1222        | ErangeUpEq
1223                { $$ = OperKinds::LEThan; }
1224        | ErangeDown
1225                { $$ = OperKinds::GThan; }
1226        | ErangeDownEq
1227                { $$ = OperKinds::GEThan; }
1228        ;
1229
1230jump_statement:
1231        GOTO identifier_or_type_name ';'
1232                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1233        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1234                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1235                // whereas normal operator precedence yields goto (*i)+3;
1236                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1237                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1238    | fall_through_name ';'                                                             // CFA
1239                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1240    | fall_through_name identifier_or_type_name ';'             // CFA
1241                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1242        | fall_through_name DEFAULT ';'                                         // CFA
1243                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1244        | CONTINUE ';'
1245                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1246                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1247        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1248                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1249                // the target of the transfer appears only at the start of an iteration statement.
1250                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1251        | BREAK ';'
1252                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1253                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1254        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1255                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1256                // the target of the transfer appears only at the start of an iteration statement.
1257                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1258        | RETURN comma_expression_opt ';'
1259                { $$ = new StatementNode( build_return( $2 ) ); }
1260        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1261                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1262        // | SUSPEND ';'
1263        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1264        // | SUSPEND compound_statement ';'
1265        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1266        | THROW assignment_expression_opt ';'                           // handles rethrow
1267                { $$ = new StatementNode( build_throw( $2 ) ); }
1268        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1269                { $$ = new StatementNode( build_resume( $2 ) ); }
1270        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1271                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1272        ;
1273
1274fall_through_name:                                                                              // CFA
1275        FALLTHRU
1276        | FALLTHROUGH
1277        ;
1278
1279with_statement:
1280        WITH '(' tuple_expression_list ')' statement
1281                {
1282                        $$ = new StatementNode( build_with( $3, $5 ) );
1283                }
1284        ;
1285
1286// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1287mutex_statement:
1288        MUTEX '(' argument_expression_list ')' statement
1289                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1290        ;
1291
1292when_clause:
1293        WHEN '(' comma_expression ')'                           { $$ = $3; }
1294        ;
1295
1296when_clause_opt:
1297        // empty
1298                { $$ = nullptr; }
1299        | when_clause
1300        ;
1301
1302waitfor:
1303        WAITFOR '(' cast_expression ')'
1304                { $$ = $3; }
1305//      | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1306//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1307        | WAITFOR '(' cast_expression_list ':' argument_expression_list ')'
1308                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1309        ;
1310
1311cast_expression_list:
1312        cast_expression
1313        | cast_expression_list ',' cast_expression
1314                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1315        ;
1316
1317timeout:
1318        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1319        ;
1320
1321waitfor_clause:
1322        when_clause_opt waitfor statement                                       %prec THEN
1323                { $$ = build_waitfor( $2, $3, $1 ); }
1324        | when_clause_opt waitfor statement WOR waitfor_clause
1325                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1326        | when_clause_opt timeout statement                                     %prec THEN
1327                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1328        | when_clause_opt ELSE statement
1329                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1330                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1331        | when_clause_opt timeout statement WOR ELSE statement
1332                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1333        | when_clause_opt timeout statement WOR when_clause ELSE statement
1334                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1335        ;
1336
1337waitfor_statement:
1338        when_clause_opt waitfor statement                                       %prec THEN
1339                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1340        | when_clause_opt waitfor statement WOR waitfor_clause
1341                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1342        ;
1343
1344exception_statement:
1345        TRY compound_statement handler_clause
1346                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1347        | TRY compound_statement finally_clause
1348                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1349        | TRY compound_statement handler_clause finally_clause
1350                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1351        ;
1352
1353handler_clause:
1354        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1355                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1356        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1357                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1358        ;
1359
1360handler_predicate_opt:
1361        // empty
1362                { $$ = nullptr; }
1363        | ';' conditional_expression                            { $$ = $2; }
1364        ;
1365
1366handler_key:
1367        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1368        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1369        ;
1370
1371finally_clause:
1372        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1373        ;
1374
1375exception_declaration:
1376                // No SUE declaration in parameter list.
1377        type_specifier_nobody
1378        | type_specifier_nobody declarator
1379                { $$ = $2->addType( $1 ); }
1380        | type_specifier_nobody variable_abstract_declarator
1381                { $$ = $2->addType( $1 ); }
1382        | cfa_abstract_declarator_tuple identifier                      // CFA
1383                { $$ = $1->addName( $2 ); }
1384        | cfa_abstract_declarator_tuple                                         // CFA
1385        ;
1386
1387enable_disable_statement:
1388        enable_disable_key identifier_list compound_statement
1389        ;
1390
1391enable_disable_key:
1392        ENABLE
1393        | DISABLE
1394        ;
1395
1396asm_statement:
1397        ASM asm_volatile_opt '(' string_literal ')' ';'
1398                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1399        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1400                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1401        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1402                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1403        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1404                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1405        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1406                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1407        ;
1408
1409asm_volatile_opt:                                                                               // GCC
1410        // empty
1411                { $$ = false; }
1412        | VOLATILE
1413                { $$ = true; }
1414        ;
1415
1416asm_operands_opt:                                                                               // GCC
1417        // empty
1418                { $$ = nullptr; }                                                               // use default argument
1419        | asm_operands_list
1420        ;
1421
1422asm_operands_list:                                                                              // GCC
1423        asm_operand
1424        | asm_operands_list ',' asm_operand
1425                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1426        ;
1427
1428asm_operand:                                                                                    // GCC
1429        string_literal '(' constant_expression ')'
1430                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1431        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1432                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1433        ;
1434
1435asm_clobbers_list_opt:                                                                  // GCC
1436        // empty
1437                { $$ = nullptr; }                                                               // use default argument
1438        | string_literal
1439                { $$ = new ExpressionNode( $1 ); }
1440        | asm_clobbers_list_opt ',' string_literal
1441                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1442        ;
1443
1444label_list:
1445        identifier
1446                {
1447                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1448                        delete $1;                                                                      // allocated by lexer
1449                }
1450        | label_list ',' identifier
1451                {
1452                        $$ = $1; $1->labels.push_back( *$3 );
1453                        delete $3;                                                                      // allocated by lexer
1454                }
1455        ;
1456
1457//******************************* DECLARATIONS *********************************
1458
1459declaration_list_opt:                                                                   // used at beginning of switch statement
1460        // empty
1461                { $$ = nullptr; }
1462        | declaration_list
1463        ;
1464
1465declaration_list:
1466        declaration
1467        | declaration_list declaration
1468                { $$ = $1->appendList( $2 ); }
1469        ;
1470
1471KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1472        // empty
1473                { $$ = nullptr; }
1474        | KR_parameter_list
1475        ;
1476
1477KR_parameter_list:
1478        push c_declaration pop ';'
1479                { $$ = $2; }
1480        | KR_parameter_list push c_declaration pop ';'
1481                { $$ = $1->appendList( $3 ); }
1482        ;
1483
1484local_label_declaration_opt:                                                    // GCC, local label
1485        // empty
1486        | local_label_declaration_list
1487        ;
1488
1489local_label_declaration_list:                                                   // GCC, local label
1490        LABEL local_label_list ';'
1491        | local_label_declaration_list LABEL local_label_list ';'
1492        ;
1493
1494local_label_list:                                                                               // GCC, local label
1495        identifier_or_type_name
1496        | local_label_list ',' identifier_or_type_name
1497        ;
1498
1499declaration:                                                                                    // old & new style declarations
1500        c_declaration ';'
1501        | cfa_declaration ';'                                                           // CFA
1502        | static_assert                                                                         // C11
1503        ;
1504
1505static_assert:
1506        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1507                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1508        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1509                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1510
1511// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1512// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1513// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1514// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1515// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1516// block, but cannot be mixed within a specific declaration.
1517//
1518//                      CFA                                     C
1519//              [10] int x;                     int x[10];              // array of 10 integers
1520//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1521
1522cfa_declaration:                                                                                // CFA
1523        cfa_variable_declaration
1524        | cfa_typedef_declaration
1525        | cfa_function_declaration
1526        | type_declaring_list
1527        | trait_specifier
1528        ;
1529
1530cfa_variable_declaration:                                                               // CFA
1531        cfa_variable_specifier initializer_opt
1532                { $$ = $1->addInitializer( $2 ); }
1533        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1534                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1535                // them as a type_qualifier cannot appear in that context.
1536                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1537        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1538                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1539        ;
1540
1541cfa_variable_specifier:                                                                 // CFA
1542                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1543                // storage-class
1544        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1545                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1546        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1547                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1548        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1549                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1550        ;
1551
1552cfa_function_declaration:                                                               // CFA
1553        cfa_function_specifier
1554        | type_qualifier_list cfa_function_specifier
1555                { $$ = $2->addQualifiers( $1 ); }
1556        | declaration_qualifier_list cfa_function_specifier
1557                { $$ = $2->addQualifiers( $1 ); }
1558        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1559                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1560        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1561                {
1562                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1563                        DeclarationNode * ret = new DeclarationNode;
1564                        ret->type = maybeClone( $1->type->base );
1565                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1566                }
1567        ;
1568
1569cfa_function_specifier:                                                                 // CFA
1570//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1571//              {
1572//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1573//              }
1574//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1575//              {
1576//                      typedefTable.setNextIdentifier( *$5 );
1577//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1578//              }
1579//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1580//              {
1581//                      typedefTable.setNextIdentifier( *$5 );
1582//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1583//              }
1584//      | '[' ']' typegen_name
1585                // identifier_or_type_name must be broken apart because of the sequence:
1586                //
1587                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1588                //   '[' ']' type_specifier
1589                //
1590                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1591                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1592        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1593                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1594                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1595        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1596                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1597        ;
1598
1599cfa_function_return:                                                                    // CFA
1600        '[' push cfa_parameter_list pop ']'
1601                { $$ = DeclarationNode::newTuple( $3 ); }
1602        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1603                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1604                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1605        ;
1606
1607cfa_typedef_declaration:                                                                // CFA
1608        TYPEDEF cfa_variable_specifier
1609                {
1610                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1611                        $$ = $2->addTypedef();
1612                }
1613        | TYPEDEF cfa_function_specifier
1614                {
1615                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1616                        $$ = $2->addTypedef();
1617                }
1618        | cfa_typedef_declaration pop ',' push identifier
1619                {
1620                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1621                        $$ = $1->appendList( $1->cloneType( $5 ) );
1622                }
1623        ;
1624
1625// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1626// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1627
1628typedef_declaration:
1629        TYPEDEF type_specifier declarator
1630                {
1631                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1632                        $$ = $3->addType( $2 )->addTypedef();
1633                }
1634        | typedef_declaration pop ',' push declarator
1635                {
1636                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1637                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1638                }
1639        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1640                {
1641                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1642                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1643                }
1644        | type_specifier TYPEDEF declarator
1645                {
1646                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1647                        $$ = $3->addType( $1 )->addTypedef();
1648                }
1649        | type_specifier TYPEDEF type_qualifier_list declarator
1650                {
1651                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1652                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1653                }
1654        ;
1655
1656typedef_expression:
1657                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1658        TYPEDEF identifier '=' assignment_expression
1659                {
1660                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1661                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1662                }
1663        | typedef_expression pop ',' push identifier '=' assignment_expression
1664                {
1665                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1666                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1667                }
1668        ;
1669
1670//c_declaration:
1671//      declaring_list pop ';'
1672//      | typedef_declaration pop ';'
1673//      | typedef_expression pop ';'                                            // GCC, naming expression type
1674//      | sue_declaration_specifier pop ';'
1675//      ;
1676//
1677//declaring_list:
1678//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1679//              // storage-class
1680//       declarator asm_name_opt initializer_opt
1681//              {
1682//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1683//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1684//              }
1685//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1686//              {
1687//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1688//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1689//              }
1690//      ;
1691
1692c_declaration:
1693        declaration_specifier declaring_list
1694                { $$ = distAttr( $1, $2 ); }
1695        | typedef_declaration
1696        | typedef_expression                                                            // GCC, naming expression type
1697        | sue_declaration_specifier
1698        ;
1699
1700declaring_list:
1701                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1702                // storage-class
1703        declarator asm_name_opt initializer_opt
1704                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1705        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1706                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1707        ;
1708
1709declaration_specifier:                                                                  // type specifier + storage class
1710        basic_declaration_specifier
1711        | sue_declaration_specifier
1712        | type_declaration_specifier
1713        ;
1714
1715declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1716                // Preclude SUE declarations in restricted scopes:
1717                //
1718                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1719                //
1720                // because it is impossible to call f due to name equivalence.
1721        basic_declaration_specifier
1722        | sue_declaration_specifier_nobody
1723        | type_declaration_specifier
1724        ;
1725
1726type_specifier:                                                                                 // type specifier
1727        basic_type_specifier
1728        | sue_type_specifier
1729        | type_type_specifier
1730        ;
1731
1732type_specifier_nobody:                                                                  // type specifier - {...}
1733                // Preclude SUE declarations in restricted scopes:
1734                //
1735                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1736                //
1737                // because it is impossible to call f due to name equivalence.
1738        basic_type_specifier
1739        | sue_type_specifier_nobody
1740        | type_type_specifier
1741        ;
1742
1743type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1744        // empty
1745                { $$ = nullptr; }
1746        | type_qualifier_list
1747        ;
1748
1749type_qualifier_list:
1750                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1751                //
1752                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1753                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1754                // appeared only once.
1755        type_qualifier
1756        | type_qualifier_list type_qualifier
1757                { $$ = $1->addQualifiers( $2 ); }
1758        ;
1759
1760type_qualifier:
1761        type_qualifier_name
1762        | attribute
1763        ;
1764
1765type_qualifier_name:
1766        CONST
1767                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1768        | RESTRICT
1769                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1770        | VOLATILE
1771                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1772        | ATOMIC
1773                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1774        | forall
1775        ;
1776
1777forall:
1778        FORALL '(' type_parameter_list ')'                                      // CFA
1779                { $$ = DeclarationNode::newForall( $3 ); }
1780        ;
1781
1782declaration_qualifier_list:
1783        storage_class_list
1784        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1785                { $$ = $1->addQualifiers( $2 ); }
1786        | declaration_qualifier_list type_qualifier_list storage_class_list
1787                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1788        ;
1789
1790storage_class_list:
1791                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1792                // only one of each is specified, except for inline, which can appear with the others.
1793                //
1794                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1795                // specifiers in a declaration.
1796        storage_class
1797        | storage_class_list storage_class
1798                { $$ = $1->addQualifiers( $2 ); }
1799        ;
1800
1801storage_class:
1802        EXTERN
1803                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1804        | STATIC
1805                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1806        | AUTO
1807                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1808        | REGISTER
1809                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1810        | THREADLOCAL                                                                           // C11
1811                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1812                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1813        | INLINE                                                                                        // C99
1814                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1815        | FORTRAN                                                                                       // C99
1816                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1817        | NORETURN                                                                                      // C11
1818                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1819        ;
1820
1821basic_type_name:
1822        VOID
1823                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1824        | BOOL                                                                                          // C99
1825                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1826        | CHAR
1827                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1828        | INT
1829                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1830        | INT128
1831                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1832        | UINT128
1833                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1834        | FLOAT
1835                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1836        | DOUBLE
1837                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1838        | uuFLOAT80
1839                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1840        | uuFLOAT128
1841                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1842        | uFLOAT16
1843                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1844        | uFLOAT32
1845                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1846        | uFLOAT32X
1847                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1848        | uFLOAT64
1849                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1850        | uFLOAT64X
1851                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1852        | uFLOAT128
1853                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1854        | COMPLEX                                                                                       // C99
1855                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1856        | IMAGINARY                                                                                     // C99
1857                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1858        | SIGNED
1859                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1860        | UNSIGNED
1861                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1862        | SHORT
1863                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1864        | LONG
1865                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1866        | VALIST                                                                                        // GCC, __builtin_va_list
1867                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1868        | AUTO_TYPE
1869                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1870        ;
1871
1872basic_declaration_specifier:
1873                // A semantic check is necessary for conflicting storage classes.
1874        basic_type_specifier
1875        | declaration_qualifier_list basic_type_specifier
1876                { $$ = $2->addQualifiers( $1 ); }
1877        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1878                { $$ = $1->addQualifiers( $2 ); }
1879        | basic_declaration_specifier storage_class type_qualifier_list
1880                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1881        | basic_declaration_specifier storage_class basic_type_specifier
1882                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1883        ;
1884
1885basic_type_specifier:
1886        direct_type
1887                // Cannot have type modifiers, e.g., short, long, etc.
1888        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1889                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1890        ;
1891
1892direct_type:
1893        basic_type_name
1894        | type_qualifier_list basic_type_name
1895                { $$ = $2->addQualifiers( $1 ); }
1896        | direct_type type_qualifier
1897                { $$ = $1->addQualifiers( $2 ); }
1898        | direct_type basic_type_name
1899                { $$ = $1->addType( $2 ); }
1900        ;
1901
1902indirect_type:
1903        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1904                { $$ = $3; }
1905        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1906                { $$ = DeclarationNode::newTypeof( $3 ); }
1907        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1908                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1909        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1910                { $$ = DeclarationNode::newTypeof( $3, true ); }
1911        | ZERO_T                                                                                        // CFA
1912                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1913        | ONE_T                                                                                         // CFA
1914                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1915        ;
1916
1917sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1918        sue_type_specifier
1919        | declaration_qualifier_list sue_type_specifier
1920                { $$ = $2->addQualifiers( $1 ); }
1921        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1922                { $$ = $1->addQualifiers( $2 ); }
1923        | sue_declaration_specifier storage_class type_qualifier_list
1924                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1925        ;
1926
1927sue_type_specifier:                                                                             // struct, union, enum + type specifier
1928        elaborated_type
1929        | type_qualifier_list
1930                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1931          elaborated_type
1932                { $$ = $3->addQualifiers( $1 ); }
1933        | sue_type_specifier type_qualifier
1934                {
1935                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1936                        $$ = $1->addQualifiers( $2 );
1937                }
1938        ;
1939
1940sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1941        sue_type_specifier_nobody
1942        | declaration_qualifier_list sue_type_specifier_nobody
1943                { $$ = $2->addQualifiers( $1 ); }
1944        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1945                { $$ = $1->addQualifiers( $2 ); }
1946        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1947                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1948        ;
1949
1950sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1951        elaborated_type_nobody
1952        | type_qualifier_list elaborated_type_nobody
1953                { $$ = $2->addQualifiers( $1 ); }
1954        | sue_type_specifier_nobody type_qualifier
1955                { $$ = $1->addQualifiers( $2 ); }
1956        ;
1957
1958type_declaration_specifier:
1959        type_type_specifier
1960        | declaration_qualifier_list type_type_specifier
1961                { $$ = $2->addQualifiers( $1 ); }
1962        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1963                { $$ = $1->addQualifiers( $2 ); }
1964        | type_declaration_specifier storage_class type_qualifier_list
1965                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1966        ;
1967
1968type_type_specifier:                                                                    // typedef types
1969        type_name
1970        | type_qualifier_list type_name
1971                { $$ = $2->addQualifiers( $1 ); }
1972        | type_type_specifier type_qualifier
1973                { $$ = $1->addQualifiers( $2 ); }
1974        ;
1975
1976type_name:
1977        TYPEDEFname
1978                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1979        | '.' TYPEDEFname
1980                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1981        | type_name '.' TYPEDEFname
1982                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1983        | typegen_name
1984        | '.' typegen_name
1985                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1986        | type_name '.' typegen_name
1987                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1988        ;
1989
1990typegen_name:                                                                                   // CFA
1991        TYPEGENname
1992                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1993        | TYPEGENname '(' ')'
1994                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1995        | TYPEGENname '(' type_list ')'
1996                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1997        ;
1998
1999elaborated_type:                                                                                // struct, union, enum
2000        aggregate_type
2001        | enum_type
2002        ;
2003
2004elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2005        aggregate_type_nobody
2006        | enum_type_nobody
2007        ;
2008
2009fred:
2010        // empty
2011                { yyy = false; }
2012        ;
2013
2014aggregate_type:                                                                                 // struct, union
2015        aggregate_key attribute_list_opt
2016                { forall = false; }                                                             // reset
2017          '{' field_declaration_list_opt '}' type_parameters_opt
2018                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2019        | aggregate_key attribute_list_opt identifier fred
2020                {
2021                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2022                        forall = false;                                                         // reset
2023                }
2024          '{' field_declaration_list_opt '}' type_parameters_opt
2025                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2026        | aggregate_key attribute_list_opt type_name fred
2027                {
2028                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2029                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2030                        forall = false;                                                         // reset
2031                }
2032          '{' field_declaration_list_opt '}' type_parameters_opt
2033                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2034        | aggregate_type_nobody
2035        ;
2036
2037type_parameters_opt:
2038        // empty
2039                { $$ = nullptr; }                                                               %prec '}'
2040        | '(' type_list ')'
2041                { $$ = $2; }
2042        ;
2043
2044aggregate_type_nobody:                                                                  // struct, union - {...}
2045        aggregate_key attribute_list_opt identifier fred
2046                {
2047                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2048                        forall = false;                                                         // reset
2049                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2050                }
2051        | aggregate_key attribute_list_opt type_name fred
2052                {
2053                        forall = false;                                                         // reset
2054                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2055                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2056                        // delete newFromTypeGen.
2057                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2058                        $3->type->symbolic.name = nullptr;
2059                        $3->type->symbolic.actuals = nullptr;
2060                        delete $3;
2061                }
2062        ;
2063
2064aggregate_key:
2065        aggregate_data
2066        | aggregate_control
2067        ;
2068
2069aggregate_data:
2070        STRUCT
2071                { yyy = true; $$ = AggregateDecl::Struct; }
2072        | UNION
2073                { yyy = true; $$ = AggregateDecl::Union; }
2074        | EXCEPTION                                                                                     // CFA
2075                { yyy = true; $$ = AggregateDecl::Exception; }
2076        ;
2077
2078aggregate_control:                                                                              // CFA
2079        GENERATOR
2080                { yyy = true; $$ = AggregateDecl::Coroutine; }
2081        | COROUTINE
2082                { yyy = true; $$ = AggregateDecl::Coroutine; }
2083        | MONITOR
2084                { yyy = true; $$ = AggregateDecl::Monitor; }
2085        | THREAD
2086                { yyy = true; $$ = AggregateDecl::Thread; }
2087        ;
2088
2089field_declaration_list_opt:
2090        // empty
2091                { $$ = nullptr; }
2092        | field_declaration_list_opt field_declaration
2093                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2094        ;
2095
2096field_declaration:
2097        type_specifier field_declaring_list_opt ';'
2098                { $$ = fieldDecl( $1, $2 ); }
2099        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2100                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2101        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2102                {
2103                        if ( ! $3 ) {                                                           // field declarator ?
2104                                $3 = DeclarationNode::newName( nullptr );
2105                        } // if
2106                        $3->inLine = true;
2107                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2108                        distInl( $3 );
2109                }
2110        | INLINE aggregate_control ';'                                          // CFA
2111                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2112        | typedef_declaration ';'                                                       // CFA
2113        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2114        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2115                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2116        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2117                { $$ = $2; }                                                                    // mark all fields in list
2118        | cfa_typedef_declaration ';'                                           // CFA
2119        | static_assert                                                                         // C11
2120        ;
2121
2122field_declaring_list_opt:
2123        // empty
2124                { $$ = nullptr; }
2125        | field_declarator
2126        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2127                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2128        ;
2129
2130field_declarator:
2131        bit_subrange_size                                                                       // C special case, no field name
2132                { $$ = DeclarationNode::newBitfield( $1 ); }
2133        | variable_declarator bit_subrange_size_opt
2134                // A semantic check is required to ensure bit_subrange only appears on integral types.
2135                { $$ = $1->addBitfield( $2 ); }
2136        | variable_type_redeclarator bit_subrange_size_opt
2137                // A semantic check is required to ensure bit_subrange only appears on integral types.
2138                { $$ = $1->addBitfield( $2 ); }
2139        ;
2140
2141field_abstract_list_opt:
2142        // empty
2143                { $$ = nullptr; }
2144        | field_abstract
2145        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2146                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2147        ;
2148
2149field_abstract:
2150                //      no bit fields
2151        variable_abstract_declarator
2152        ;
2153
2154cfa_field_declaring_list:                                                               // CFA, new style field declaration
2155        // bit-fields are handled by C declarations
2156        cfa_abstract_declarator_tuple identifier_or_type_name
2157                { $$ = $1->addName( $2 ); }
2158        | cfa_field_declaring_list ',' identifier_or_type_name
2159                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2160        ;
2161
2162cfa_field_abstract_list:                                                                // CFA, new style field declaration
2163        // bit-fields are handled by C declarations
2164        cfa_abstract_declarator_tuple
2165        | cfa_field_abstract_list ','
2166                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2167        ;
2168
2169bit_subrange_size_opt:
2170        // empty
2171                { $$ = nullptr; }
2172        | bit_subrange_size
2173        ;
2174
2175bit_subrange_size:
2176        ':' assignment_expression
2177                { $$ = $2; }
2178        ;
2179
2180enum_type:                                                                                              // enum
2181        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2182                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2183        | ENUM attribute_list_opt identifier
2184                { typedefTable.makeTypedef( *$3 ); }
2185          '{' enumerator_list comma_opt '}'
2186                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2187        | ENUM attribute_list_opt type_name
2188          '{' enumerator_list comma_opt '}'
2189                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2190        | enum_type_nobody
2191        ;
2192
2193enum_type_nobody:                                                                               // enum - {...}
2194        ENUM attribute_list_opt identifier
2195                {
2196                        typedefTable.makeTypedef( *$3 );
2197                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2198                }
2199        | ENUM attribute_list_opt type_name
2200                {
2201                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2202                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2203                }
2204        ;
2205
2206enumerator_list:
2207        identifier_or_type_name enumerator_value_opt
2208                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2209        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2210                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2211        ;
2212
2213enumerator_value_opt:
2214        // empty
2215                { $$ = nullptr; }
2216        | '=' constant_expression
2217                { $$ = $2; }
2218        ;
2219
2220cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2221        // empty
2222                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2223        | ELLIPSIS
2224                { $$ = nullptr; }
2225        | cfa_abstract_parameter_list
2226        | cfa_parameter_list
2227        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2228                { $$ = $1->appendList( $5 ); }
2229        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2230                { $$ = $1->addVarArgs(); }
2231        | cfa_parameter_list pop ',' push ELLIPSIS
2232                { $$ = $1->addVarArgs(); }
2233        ;
2234
2235cfa_parameter_list:                                                                             // CFA
2236                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2237                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2238        cfa_parameter_declaration
2239        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2240                { $$ = $1->appendList( $5 ); }
2241        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2242                { $$ = $1->appendList( $5 ); }
2243        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2244                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2245        ;
2246
2247cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2248        cfa_abstract_parameter_declaration
2249        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2250                { $$ = $1->appendList( $5 ); }
2251        ;
2252
2253parameter_type_list_opt:
2254        // empty
2255                { $$ = nullptr; }
2256        | ELLIPSIS
2257                { $$ = nullptr; }
2258        | parameter_list
2259        | parameter_list pop ',' push ELLIPSIS
2260                { $$ = $1->addVarArgs(); }
2261        ;
2262
2263parameter_list:                                                                                 // abstract + real
2264        abstract_parameter_declaration
2265        | parameter_declaration
2266        | parameter_list pop ',' push abstract_parameter_declaration
2267                { $$ = $1->appendList( $5 ); }
2268        | parameter_list pop ',' push parameter_declaration
2269                { $$ = $1->appendList( $5 ); }
2270        ;
2271
2272// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2273// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2274
2275cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2276        parameter_declaration
2277        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2278                { $$ = $1->addName( $2 ); }
2279        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2280                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2281                { $$ = $1->addName( $2 ); }
2282        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2283                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2284        | cfa_function_specifier
2285        ;
2286
2287cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2288        abstract_parameter_declaration
2289        | cfa_identifier_parameter_declarator_no_tuple
2290        | cfa_abstract_tuple
2291                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2292        | type_qualifier_list cfa_abstract_tuple
2293                { $$ = $2->addQualifiers( $1 ); }
2294        | cfa_abstract_function
2295        ;
2296
2297parameter_declaration:
2298                // No SUE declaration in parameter list.
2299        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2300                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2301        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2302                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2303        ;
2304
2305abstract_parameter_declaration:
2306        declaration_specifier_nobody default_initialize_opt
2307                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2308        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2309                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2310        ;
2311
2312// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2313// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2314// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2315
2316identifier_list:                                                                                // K&R-style parameter list => no types
2317        identifier
2318                { $$ = DeclarationNode::newName( $1 ); }
2319        | identifier_list ',' identifier
2320                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2321        ;
2322
2323identifier_or_type_name:
2324        identifier
2325        | TYPEDEFname
2326        | TYPEGENname
2327        ;
2328
2329type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2330        cfa_abstract_declarator_tuple                                           // CFA
2331        | type_specifier
2332        | type_specifier abstract_declarator
2333                { $$ = $2->addType( $1 ); }
2334        ;
2335
2336type:                                                                                                   // typeof, assertion
2337        type_no_function
2338        | cfa_abstract_function                                                         // CFA
2339        ;
2340
2341initializer_opt:
2342        // empty
2343                { $$ = nullptr; }
2344        | '=' initializer
2345                { $$ = $2; }
2346        | '=' VOID
2347                { $$ = new InitializerNode( true ); }
2348        | ATassign initializer
2349                { $$ = $2->set_maybeConstructed( false ); }
2350        ;
2351
2352initializer:
2353        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2354        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2355        ;
2356
2357initializer_list_opt:
2358        // empty
2359                { $$ = nullptr; }
2360        | initializer
2361        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2362        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2363        | initializer_list_opt ',' designation initializer
2364                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2365        ;
2366
2367// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2368// '=' to separator the designator from the initializer value, as in:
2369//
2370//              int x[10] = { [1] = 3 };
2371//
2372// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2373// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2374// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2375// shift/reduce conflicts
2376
2377designation:
2378        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2379        | identifier ':'                                                                        // GCC, field name
2380                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2381        ;
2382
2383designator_list:                                                                                // C99
2384        designator
2385        | designator_list designator
2386                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2387        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2388        ;
2389
2390designator:
2391        '.' identifier                                                                          // C99, field name
2392                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2393        | '[' push assignment_expression pop ']'                        // C99, single array element
2394                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2395                { $$ = $3; }
2396        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2397                { $$ = $3; }
2398        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2399                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2400        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2401                { $$ = $4; }
2402        ;
2403
2404// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2405// rather than an object-oriented type system. This required four groups of extensions:
2406//
2407// Overloading: function, data, and operator identifiers may be overloaded.
2408//
2409// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2410//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2411//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2412//
2413// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2414//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2415//
2416// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2417//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2418//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2419//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2420//     on type arguments of polymorphic functions.
2421
2422type_parameter_list:                                                                    // CFA
2423        type_parameter
2424        | type_parameter_list ',' type_parameter
2425                { $$ = $1->appendList( $3 ); }
2426        ;
2427
2428type_initializer_opt:                                                                   // CFA
2429        // empty
2430                { $$ = nullptr; }
2431        | '=' type
2432                { $$ = $2; }
2433        ;
2434
2435type_parameter:                                                                                 // CFA
2436        type_class identifier_or_type_name
2437                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2438          type_initializer_opt assertion_list_opt
2439                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2440        | type_specifier identifier_parameter_declarator
2441        | assertion_list
2442                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2443        ;
2444
2445type_class:                                                                                             // CFA
2446        OTYPE
2447                { $$ = TypeDecl::Otype; }
2448        | DTYPE
2449                { $$ = TypeDecl::Dtype; }
2450        | FTYPE
2451                { $$ = TypeDecl::Ftype; }
2452        | TTYPE
2453                { $$ = TypeDecl::Ttype; }
2454        ;
2455
2456assertion_list_opt:                                                                             // CFA
2457        // empty
2458                { $$ = nullptr; }
2459        | assertion_list
2460        ;
2461
2462assertion_list:                                                                                 // CFA
2463        assertion
2464        | assertion_list assertion
2465                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2466        ;
2467
2468assertion:                                                                                              // CFA
2469        '|' identifier_or_type_name '(' type_list ')'
2470                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2471        | '|' '{' push trait_declaration_list pop '}'
2472                { $$ = $4; }
2473        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2474        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2475        ;
2476
2477type_list:                                                                                              // CFA
2478        type
2479                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2480        | assignment_expression
2481                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2482        | type_list ',' type
2483                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2484        | type_list ',' assignment_expression
2485                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2486                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2487        ;
2488
2489type_declaring_list:                                                                    // CFA
2490        OTYPE type_declarator
2491                { $$ = $2; }
2492        | storage_class_list OTYPE type_declarator
2493                { $$ = $3->addQualifiers( $1 ); }
2494        | type_declaring_list ',' type_declarator
2495                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2496        ;
2497
2498type_declarator:                                                                                // CFA
2499        type_declarator_name assertion_list_opt
2500                { $$ = $1->addAssertions( $2 ); }
2501        | type_declarator_name assertion_list_opt '=' type
2502                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2503        ;
2504
2505type_declarator_name:                                                                   // CFA
2506        identifier_or_type_name
2507                {
2508                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2509                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2510                }
2511        | identifier_or_type_name '(' type_parameter_list ')'
2512                {
2513                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2514                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2515                }
2516        ;
2517
2518trait_specifier:                                                                                // CFA
2519        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2520                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2521        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2522                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2523        ;
2524
2525trait_declaration_list:                                                                 // CFA
2526        trait_declaration
2527        | trait_declaration_list pop push trait_declaration
2528                { $$ = $1->appendList( $4 ); }
2529        ;
2530
2531trait_declaration:                                                                              // CFA
2532        cfa_trait_declaring_list ';'
2533        | trait_declaring_list ';'
2534        ;
2535
2536cfa_trait_declaring_list:                                                               // CFA
2537        cfa_variable_specifier
2538        | cfa_function_specifier
2539        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2540                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2541        ;
2542
2543trait_declaring_list:                                                                   // CFA
2544        type_specifier declarator
2545                { $$ = $2->addType( $1 ); }
2546        | trait_declaring_list pop ',' push declarator
2547                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2548        ;
2549
2550//***************************** EXTERNAL DEFINITIONS *****************************
2551
2552translation_unit:
2553        // empty, input file
2554        | external_definition_list
2555                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2556        ;
2557
2558external_definition_list:
2559        push external_definition pop
2560                { $$ = $2; }
2561        | external_definition_list push external_definition pop
2562                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2563        ;
2564
2565external_definition_list_opt:
2566        // empty
2567                { $$ = nullptr; }
2568        | external_definition_list
2569        ;
2570
2571up:
2572                { typedefTable.up( forall ); forall = false; }
2573        ;
2574
2575down:
2576                { typedefTable.down(); }
2577        ;
2578
2579external_definition:
2580        declaration
2581        | external_function_definition
2582        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2583                {
2584                        distExt( $2 );                                                          // mark all fields in list
2585                        $$ = $2;
2586                }
2587        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2588                {
2589                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2590                }
2591        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2592                {
2593                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2594                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2595                }
2596          '{' up external_definition_list_opt down '}'
2597                {
2598                        linkage = linkageStack.top();
2599                        linkageStack.pop();
2600                        $$ = $6;
2601                }
2602        | type_qualifier_list
2603                {
2604                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2605                        if ( $1->type->forall ) forall = true;          // remember generic type
2606                }
2607          '{' up external_definition_list_opt down '}'          // CFA, namespace
2608                {
2609                        distQual( $5, $1 );
2610                        forall = false;
2611                        $$ = $5;
2612                }
2613        | declaration_qualifier_list
2614                {
2615                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2616                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2617                }
2618          '{' up external_definition_list_opt down '}'          // CFA, namespace
2619                {
2620                        distQual( $5, $1 );
2621                        forall = false;
2622                        $$ = $5;
2623                }
2624        | declaration_qualifier_list type_qualifier_list
2625                {
2626                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2627                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2628                }
2629          '{' up external_definition_list_opt down '}'          // CFA, namespace
2630                {
2631                        distQual( $6, $1->addQualifiers( $2 ) );
2632                        forall = false;
2633                        $$ = $6;
2634                }
2635        ;
2636
2637external_function_definition:
2638        function_definition
2639                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2640                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2641                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2642                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2643                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2644        | function_declarator compound_statement
2645                { $$ = $1->addFunctionBody( $2 ); }
2646        | KR_function_declarator KR_parameter_list_opt compound_statement
2647                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2648        ;
2649
2650with_clause_opt:
2651        // empty
2652                { $$ = nullptr; forall = false; }
2653        | WITH '(' tuple_expression_list ')'
2654                { $$ = $3; forall = false; }
2655        ;
2656
2657function_definition:
2658        cfa_function_declaration with_clause_opt compound_statement     // CFA
2659                {
2660                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2661                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2662                        $1->get_last()->addFunctionBody( $3, $2 );
2663                        $$ = $1;
2664                }
2665        | declaration_specifier function_declarator with_clause_opt compound_statement
2666                {
2667                        rebindForall( $1, $2 );
2668                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2669                }
2670        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2671                {
2672                        rebindForall( $1, $2 );
2673                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2674                }
2675                // handles default int return type, OBSOLESCENT (see 1)
2676        | type_qualifier_list function_declarator with_clause_opt compound_statement
2677                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2678                // handles default int return type, OBSOLESCENT (see 1)
2679        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2680                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2681                // handles default int return type, OBSOLESCENT (see 1)
2682        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2683                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2684
2685                // Old-style K&R function definition, OBSOLESCENT (see 4)
2686        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2687                {
2688                        rebindForall( $1, $2 );
2689                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2690                }
2691                // handles default int return type, OBSOLESCENT (see 1)
2692        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2693                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2694                // handles default int return type, OBSOLESCENT (see 1)
2695        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2696                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2697                // handles default int return type, OBSOLESCENT (see 1)
2698        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2699                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2700        ;
2701
2702declarator:
2703        variable_declarator
2704        | variable_type_redeclarator
2705        | function_declarator
2706        ;
2707
2708subrange:
2709        constant_expression '~' constant_expression                     // CFA, integer subrange
2710                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2711        ;
2712
2713asm_name_opt:                                                                                   // GCC
2714        // empty
2715                { $$ = nullptr; }
2716        | ASM '(' string_literal ')' attribute_list_opt
2717                {
2718                        DeclarationNode * name = new DeclarationNode();
2719                        name->asmName = $3;
2720                        $$ = name->addQualifiers( $5 );
2721                }
2722        ;
2723
2724attribute_list_opt:                                                                             // GCC
2725        // empty
2726                { $$ = nullptr; }
2727        | attribute_list
2728        ;
2729
2730attribute_list:                                                                                 // GCC
2731        attribute
2732        | attribute_list attribute
2733                { $$ = $2->addQualifiers( $1 ); }
2734        ;
2735
2736attribute:                                                                                              // GCC
2737        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2738                { $$ = $4; }
2739        ;
2740
2741attribute_name_list:                                                                    // GCC
2742        attribute_name
2743        | attribute_name_list ',' attribute_name
2744                { $$ = $3->addQualifiers( $1 ); }
2745        ;
2746
2747attribute_name:                                                                                 // GCC
2748        // empty
2749                { $$ = nullptr; }
2750        | attr_name
2751                { $$ = DeclarationNode::newAttribute( $1 ); }
2752        | attr_name '(' argument_expression_list ')'
2753                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2754        ;
2755
2756attr_name:                                                                                              // GCC
2757        IDENTIFIER
2758        | quasi_keyword
2759        | TYPEDEFname
2760        | TYPEGENname
2761        | FALLTHROUGH
2762                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2763        | CONST
2764                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2765        ;
2766
2767// ============================================================================
2768// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2769// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2770// in:
2771//
2772//              int (*f())[10] { ... };
2773//              ... (*f())[3] += 1;             // definition mimics usage
2774//
2775// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2776// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2777// ============================================================================
2778
2779// ----------------------------------------------------------------------------
2780// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2781// to define a variable or function prototype, e.g.:
2782//
2783//              valid declaration               invalid definition
2784//              -----------------               ------------------
2785//              int f;                                  int f {}
2786//              int *f;                                 int *f {}
2787//              int f[10];                              int f[10] {}
2788//              int (*f)(int);                  int (*f)(int) {}
2789//
2790// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2791// variable_declarator and function_declarator.
2792// ----------------------------------------------------------------------------
2793
2794// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2795// declaring an array of functions versus a pointer to an array of functions.
2796
2797variable_declarator:
2798        paren_identifier attribute_list_opt
2799                { $$ = $1->addQualifiers( $2 ); }
2800        | variable_ptr
2801        | variable_array attribute_list_opt
2802                { $$ = $1->addQualifiers( $2 ); }
2803        | variable_function attribute_list_opt
2804                { $$ = $1->addQualifiers( $2 ); }
2805        ;
2806
2807paren_identifier:
2808        identifier
2809                { $$ = DeclarationNode::newName( $1 ); }
2810        | '(' paren_identifier ')'                                                      // redundant parenthesis
2811                { $$ = $2; }
2812        ;
2813
2814variable_ptr:
2815        ptrref_operator variable_declarator
2816                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2817        | ptrref_operator type_qualifier_list variable_declarator
2818                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2819        | '(' variable_ptr ')' attribute_list_opt
2820                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2821        ;
2822
2823variable_array:
2824        paren_identifier array_dimension
2825                { $$ = $1->addArray( $2 ); }
2826        | '(' variable_ptr ')' array_dimension
2827                { $$ = $2->addArray( $4 ); }
2828        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2829                { $$ = $2->addArray( $4 ); }
2830        | '(' variable_array ')'                                                        // redundant parenthesis
2831                { $$ = $2; }
2832        ;
2833
2834variable_function:
2835        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2836                { $$ = $2->addParamList( $6 ); }
2837        | '(' variable_function ')'                                                     // redundant parenthesis
2838                { $$ = $2; }
2839        ;
2840
2841// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2842// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2843// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2844
2845function_declarator:
2846        function_no_ptr attribute_list_opt
2847                { $$ = $1->addQualifiers( $2 ); }
2848        | function_ptr
2849        | function_array attribute_list_opt
2850                { $$ = $1->addQualifiers( $2 ); }
2851        ;
2852
2853function_no_ptr:
2854        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2855                { $$ = $1->addParamList( $4 ); }
2856        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2857                { $$ = $2->addParamList( $6 ); }
2858        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2859                { $$ = $2; }
2860        ;
2861
2862function_ptr:
2863        ptrref_operator function_declarator
2864                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2865        | ptrref_operator type_qualifier_list function_declarator
2866                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2867        | '(' function_ptr ')'
2868                { $$ = $2; }
2869        ;
2870
2871function_array:
2872        '(' function_ptr ')' array_dimension
2873                { $$ = $2->addArray( $4 ); }
2874        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2875                { $$ = $2->addArray( $4 ); }
2876        | '(' function_array ')'                                                        // redundant parenthesis
2877                { $$ = $2; }
2878        ;
2879
2880// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2881//
2882//   f( a, b, c ) int a, *b, c[]; {}
2883//
2884// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2885// returning arrays and functions versus pointers to arrays and functions.
2886
2887KR_function_declarator:
2888        KR_function_no_ptr
2889        | KR_function_ptr
2890        | KR_function_array
2891        ;
2892
2893KR_function_no_ptr:
2894        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2895                { $$ = $1->addIdList( $3 ); }
2896        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2897                { $$ = $2->addParamList( $6 ); }
2898        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2899                { $$ = $2; }
2900        ;
2901
2902KR_function_ptr:
2903        ptrref_operator KR_function_declarator
2904                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2905        | ptrref_operator type_qualifier_list KR_function_declarator
2906                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2907        | '(' KR_function_ptr ')'
2908                { $$ = $2; }
2909        ;
2910
2911KR_function_array:
2912        '(' KR_function_ptr ')' array_dimension
2913                { $$ = $2->addArray( $4 ); }
2914        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2915                { $$ = $2->addArray( $4 ); }
2916        | '(' KR_function_array ')'                                                     // redundant parenthesis
2917                { $$ = $2; }
2918        ;
2919
2920// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2921//
2922//              typedef int foo;
2923//              {
2924//                 int foo; // redefine typedef name in new scope
2925//              }
2926//
2927// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2928// and functions versus pointers to arrays and functions.
2929
2930variable_type_redeclarator:
2931        paren_type attribute_list_opt
2932                { $$ = $1->addQualifiers( $2 ); }
2933        | type_ptr
2934        | type_array attribute_list_opt
2935                { $$ = $1->addQualifiers( $2 ); }
2936        | type_function attribute_list_opt
2937                { $$ = $1->addQualifiers( $2 ); }
2938        ;
2939
2940paren_type:
2941        typedef
2942                // hide type name in enclosing scope by variable name
2943                {
2944                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2945                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2946                        // } else {
2947                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2948                        // } // if
2949                }
2950        | '(' paren_type ')'
2951                { $$ = $2; }
2952        ;
2953
2954type_ptr:
2955        ptrref_operator variable_type_redeclarator
2956                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2957        | ptrref_operator type_qualifier_list variable_type_redeclarator
2958                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2959        | '(' type_ptr ')' attribute_list_opt
2960                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2961        ;
2962
2963type_array:
2964        paren_type array_dimension
2965                { $$ = $1->addArray( $2 ); }
2966        | '(' type_ptr ')' array_dimension
2967                { $$ = $2->addArray( $4 ); }
2968        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2969                { $$ = $2->addArray( $4 ); }
2970        | '(' type_array ')'                                                            // redundant parenthesis
2971                { $$ = $2; }
2972        ;
2973
2974type_function:
2975        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2976                { $$ = $1->addParamList( $4 ); }
2977        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2978                { $$ = $2->addParamList( $6 ); }
2979        | '(' type_function ')'                                                         // redundant parenthesis
2980                { $$ = $2; }
2981        ;
2982
2983// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2984// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2985// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2986// pointers to arrays and functions.
2987
2988identifier_parameter_declarator:
2989        paren_identifier attribute_list_opt
2990                { $$ = $1->addQualifiers( $2 ); }
2991        | '&' MUTEX paren_identifier attribute_list_opt
2992                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2993        | identifier_parameter_ptr
2994        | identifier_parameter_array attribute_list_opt
2995                { $$ = $1->addQualifiers( $2 ); }
2996        | identifier_parameter_function attribute_list_opt
2997                { $$ = $1->addQualifiers( $2 ); }
2998        ;
2999
3000identifier_parameter_ptr:
3001        ptrref_operator identifier_parameter_declarator
3002                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3003        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3004                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3005        | '(' identifier_parameter_ptr ')' attribute_list_opt
3006                { $$ = $2->addQualifiers( $4 ); }
3007        ;
3008
3009identifier_parameter_array:
3010        paren_identifier array_parameter_dimension
3011                { $$ = $1->addArray( $2 ); }
3012        | '(' identifier_parameter_ptr ')' array_dimension
3013                { $$ = $2->addArray( $4 ); }
3014        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3015                { $$ = $2->addArray( $4 ); }
3016        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3017                { $$ = $2; }
3018        ;
3019
3020identifier_parameter_function:
3021        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3022                { $$ = $1->addParamList( $4 ); }
3023        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3024                { $$ = $2->addParamList( $6 ); }
3025        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3026                { $$ = $2; }
3027        ;
3028
3029// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3030// e.g.:
3031//
3032//              typedef int foo;
3033//              forall( otype T ) struct foo;
3034//              int f( int foo ); // redefine typedef name in new scope
3035//
3036// and allows the C99 array options, which can only appear in a parameter list.
3037
3038type_parameter_redeclarator:
3039        typedef attribute_list_opt
3040                { $$ = $1->addQualifiers( $2 ); }
3041        | '&' MUTEX typedef attribute_list_opt
3042                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3043        | type_parameter_ptr
3044        | type_parameter_array attribute_list_opt
3045                { $$ = $1->addQualifiers( $2 ); }
3046        | type_parameter_function attribute_list_opt
3047                { $$ = $1->addQualifiers( $2 ); }
3048        ;
3049
3050typedef:
3051        TYPEDEFname
3052                { $$ = DeclarationNode::newName( $1 ); }
3053        | TYPEGENname
3054                { $$ = DeclarationNode::newName( $1 ); }
3055        ;
3056
3057type_parameter_ptr:
3058        ptrref_operator type_parameter_redeclarator
3059                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3060        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3061                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3062        | '(' type_parameter_ptr ')' attribute_list_opt
3063                { $$ = $2->addQualifiers( $4 ); }
3064        ;
3065
3066type_parameter_array:
3067        typedef array_parameter_dimension
3068                { $$ = $1->addArray( $2 ); }
3069        | '(' type_parameter_ptr ')' array_parameter_dimension
3070                { $$ = $2->addArray( $4 ); }
3071        ;
3072
3073type_parameter_function:
3074        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3075                { $$ = $1->addParamList( $4 ); }
3076        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3077                { $$ = $2->addParamList( $6 ); }
3078        ;
3079
3080// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3081// which the type applies, e.g.:
3082//
3083//              sizeof( int );
3084//              sizeof( int * );
3085//              sizeof( int [10] );
3086//              sizeof( int (*)() );
3087//              sizeof( int () );
3088//
3089// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3090// and functions versus pointers to arrays and functions.
3091
3092abstract_declarator:
3093        abstract_ptr
3094        | abstract_array attribute_list_opt
3095                { $$ = $1->addQualifiers( $2 ); }
3096        | abstract_function attribute_list_opt
3097                { $$ = $1->addQualifiers( $2 ); }
3098        ;
3099
3100abstract_ptr:
3101        ptrref_operator
3102                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3103        | ptrref_operator type_qualifier_list
3104                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3105        | ptrref_operator abstract_declarator
3106                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3107        | ptrref_operator type_qualifier_list abstract_declarator
3108                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3109        | '(' abstract_ptr ')' attribute_list_opt
3110                { $$ = $2->addQualifiers( $4 ); }
3111        ;
3112
3113abstract_array:
3114        array_dimension
3115        | '(' abstract_ptr ')' array_dimension
3116                { $$ = $2->addArray( $4 ); }
3117        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3118                { $$ = $2->addArray( $4 ); }
3119        | '(' abstract_array ')'                                                        // redundant parenthesis
3120                { $$ = $2; }
3121        ;
3122
3123abstract_function:
3124        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3125                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3126        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3127                { $$ = $2->addParamList( $6 ); }
3128        | '(' abstract_function ')'                                                     // redundant parenthesis
3129                { $$ = $2; }
3130        ;
3131
3132array_dimension:
3133                // Only the first dimension can be empty.
3134        '[' ']'
3135                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3136        | '[' ']' multi_array_dimension
3137                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3138        | multi_array_dimension
3139        ;
3140
3141multi_array_dimension:
3142        '[' push assignment_expression pop ']'
3143                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3144        | '[' push '*' pop ']'                                                          // C99
3145                { $$ = DeclarationNode::newVarArray( 0 ); }
3146        | multi_array_dimension '[' push assignment_expression pop ']'
3147                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3148        | multi_array_dimension '[' push '*' pop ']'            // C99
3149                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3150        ;
3151
3152// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3153// identifier to which the type applies, e.g.:
3154//
3155//              int f( int );                   // not handled here
3156//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3157//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3158//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3159//
3160// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3161// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3162// special meaning of parenthesis around a typedef name:
3163//
3164//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3165//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3166//              not as redundant parentheses around the identifier."
3167//
3168// For example:
3169//
3170//              typedef float T;
3171//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3172//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3173//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3174//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3175//
3176// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3177// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3178// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3179// functions.
3180
3181abstract_parameter_declarator:
3182        abstract_parameter_ptr
3183        | '&' MUTEX attribute_list_opt
3184                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3185        | abstract_parameter_array attribute_list_opt
3186                { $$ = $1->addQualifiers( $2 ); }
3187        | abstract_parameter_function attribute_list_opt
3188                { $$ = $1->addQualifiers( $2 ); }
3189        ;
3190
3191abstract_parameter_ptr:
3192        ptrref_operator
3193                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3194        | ptrref_operator type_qualifier_list
3195                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3196        | ptrref_operator abstract_parameter_declarator
3197                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3198        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3199                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3200        | '(' abstract_parameter_ptr ')' attribute_list_opt
3201                { $$ = $2->addQualifiers( $4 ); }
3202        ;
3203
3204abstract_parameter_array:
3205        array_parameter_dimension
3206        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3207                { $$ = $2->addArray( $4 ); }
3208        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3209                { $$ = $2->addArray( $4 ); }
3210        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3211                { $$ = $2; }
3212        ;
3213
3214abstract_parameter_function:
3215        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3216                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3217        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3218                { $$ = $2->addParamList( $6 ); }
3219        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3220                { $$ = $2; }
3221        ;
3222
3223array_parameter_dimension:
3224                // Only the first dimension can be empty or have qualifiers.
3225        array_parameter_1st_dimension
3226        | array_parameter_1st_dimension multi_array_dimension
3227                { $$ = $1->addArray( $2 ); }
3228        | multi_array_dimension
3229        ;
3230
3231// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3232//
3233//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3234//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3235
3236array_parameter_1st_dimension:
3237        '[' ']'
3238                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3239                // multi_array_dimension handles the '[' '*' ']' case
3240        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3241                { $$ = DeclarationNode::newVarArray( $3 ); }
3242        | '[' push type_qualifier_list pop ']'
3243                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3244                // multi_array_dimension handles the '[' assignment_expression ']' case
3245        | '[' push type_qualifier_list assignment_expression pop ']'
3246                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3247        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3248                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3249        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3250                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3251        ;
3252
3253// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3254//
3255//              struct S {
3256//          int;
3257//          int *;
3258//          int [10];
3259//          int (*)();
3260//      };
3261
3262variable_abstract_declarator:
3263        variable_abstract_ptr
3264        | variable_abstract_array attribute_list_opt
3265                { $$ = $1->addQualifiers( $2 ); }
3266        | variable_abstract_function attribute_list_opt
3267                { $$ = $1->addQualifiers( $2 ); }
3268        ;
3269
3270variable_abstract_ptr:
3271        ptrref_operator
3272                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3273        | ptrref_operator type_qualifier_list
3274                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3275        | ptrref_operator variable_abstract_declarator
3276                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3277        | ptrref_operator type_qualifier_list variable_abstract_declarator
3278                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3279        | '(' variable_abstract_ptr ')' attribute_list_opt
3280                { $$ = $2->addQualifiers( $4 ); }
3281        ;
3282
3283variable_abstract_array:
3284        array_dimension
3285        | '(' variable_abstract_ptr ')' array_dimension
3286                { $$ = $2->addArray( $4 ); }
3287        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3288                { $$ = $2->addArray( $4 ); }
3289        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3290                { $$ = $2; }
3291        ;
3292
3293variable_abstract_function:
3294        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3295                { $$ = $2->addParamList( $6 ); }
3296        | '(' variable_abstract_function ')'                            // redundant parenthesis
3297                { $$ = $2; }
3298        ;
3299
3300// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3301// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3302
3303cfa_identifier_parameter_declarator_tuple:                              // CFA
3304        cfa_identifier_parameter_declarator_no_tuple
3305        | cfa_abstract_tuple
3306        | type_qualifier_list cfa_abstract_tuple
3307                { $$ = $2->addQualifiers( $1 ); }
3308        ;
3309
3310cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3311        cfa_identifier_parameter_ptr
3312        | cfa_identifier_parameter_array
3313        ;
3314
3315cfa_identifier_parameter_ptr:                                                   // CFA
3316                // No SUE declaration in parameter list.
3317        ptrref_operator type_specifier_nobody
3318                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3319        | type_qualifier_list ptrref_operator type_specifier_nobody
3320                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3321        | ptrref_operator cfa_abstract_function
3322                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3323        | type_qualifier_list ptrref_operator cfa_abstract_function
3324                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3325        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3326                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3327        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3328                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3329        ;
3330
3331cfa_identifier_parameter_array:                                                 // CFA
3332                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3333                // shift/reduce conflict with new-style empty (void) function return type.
3334        '[' ']' type_specifier_nobody
3335                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3336        | cfa_array_parameter_1st_dimension type_specifier_nobody
3337                { $$ = $2->addNewArray( $1 ); }
3338        | '[' ']' multi_array_dimension type_specifier_nobody
3339                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3340        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3341                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3342        | multi_array_dimension type_specifier_nobody
3343                { $$ = $2->addNewArray( $1 ); }
3344
3345        | '[' ']' cfa_identifier_parameter_ptr
3346                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3347        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3348                { $$ = $2->addNewArray( $1 ); }
3349        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3350                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3351        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3352                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3353        | multi_array_dimension cfa_identifier_parameter_ptr
3354                { $$ = $2->addNewArray( $1 ); }
3355        ;
3356
3357cfa_array_parameter_1st_dimension:
3358        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3359                { $$ = DeclarationNode::newVarArray( $3 ); }
3360        | '[' push type_qualifier_list assignment_expression pop ']'
3361                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3362        | '[' push declaration_qualifier_list assignment_expression pop ']'
3363                // declaration_qualifier_list must be used because of shift/reduce conflict with
3364                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3365                // appear in this context.
3366                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3367        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3368                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3369        ;
3370
3371// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3372// identifier to which the type applies, e.g.:
3373//
3374//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3375//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3376//
3377// These rules need LR(3):
3378//
3379//              cfa_abstract_tuple identifier_or_type_name
3380//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3381//
3382// since a function return type can be syntactically identical to a tuple type:
3383//
3384//              [int, int] t;
3385//              [int, int] f( int );
3386//
3387// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3388// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3389// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3390// duplicated when appearing with cfa_function_specifier.
3391
3392cfa_abstract_declarator_tuple:                                                  // CFA
3393        cfa_abstract_tuple
3394        | type_qualifier_list cfa_abstract_tuple
3395                { $$ = $2->addQualifiers( $1 ); }
3396        | cfa_abstract_declarator_no_tuple
3397        ;
3398
3399cfa_abstract_declarator_no_tuple:                                               // CFA
3400        cfa_abstract_ptr
3401        | cfa_abstract_array
3402        ;
3403
3404cfa_abstract_ptr:                                                                               // CFA
3405        ptrref_operator type_specifier
3406                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3407        | type_qualifier_list ptrref_operator type_specifier
3408                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3409        | ptrref_operator cfa_abstract_function
3410                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3411        | type_qualifier_list ptrref_operator cfa_abstract_function
3412                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3413        | ptrref_operator cfa_abstract_declarator_tuple
3414                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3415        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3416                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3417        ;
3418
3419cfa_abstract_array:                                                                             // CFA
3420                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3421                // empty (void) function return type.
3422        '[' ']' type_specifier
3423                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3424        | '[' ']' multi_array_dimension type_specifier
3425                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3426        | multi_array_dimension type_specifier
3427                { $$ = $2->addNewArray( $1 ); }
3428        | '[' ']' cfa_abstract_ptr
3429                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3430        | '[' ']' multi_array_dimension cfa_abstract_ptr
3431                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3432        | multi_array_dimension cfa_abstract_ptr
3433                { $$ = $2->addNewArray( $1 ); }
3434        ;
3435
3436cfa_abstract_tuple:                                                                             // CFA
3437        '[' push cfa_abstract_parameter_list pop ']'
3438                { $$ = DeclarationNode::newTuple( $3 ); }
3439        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3440                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3441        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3442                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3443        ;
3444
3445cfa_abstract_function:                                                                  // CFA
3446//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3447//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3448        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3449                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3450        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3451                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3452        ;
3453
3454// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3455//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3456//
3457// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3458//    the declaration specifiers in a declaration is an obsolescent feature."
3459//
3460// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3461//    prototype-format parameter type declarators) is an obsolescent feature."
3462//
3463// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3464//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3465
3466//************************* MISCELLANEOUS ********************************
3467
3468comma_opt:                                                                                              // redundant comma
3469        // empty
3470        | ','
3471        ;
3472
3473default_initialize_opt:
3474        // empty
3475                { $$ = nullptr; }
3476        | '=' assignment_expression
3477                { $$ = $2; }
3478        ;
3479
3480%%
3481
3482// ----end of grammar----
3483
3484// Local Variables: //
3485// mode: c++ //
3486// tab-width: 4 //
3487// compile-command: "make install" //
3488// End: //
Note: See TracBrowser for help on using the repository browser.