source: src/Parser/parser.yy @ 6a99803

arm-ehjacob/cs343-translationnew-ast-unique-expr
Last change on this file since 6a99803 was 6a99803, checked in by Peter A. Buhr <pabuhr@…>, 8 months ago

add parsing for new array declaration and subscript

  • Property mode set to 100644
File size: 139.2 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Feb  3 18:30:12 2021
13// Update Count     : 4700
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT( yylval )                                    // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack<LinkageSpec::Spec> linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169        *name = string("__postfix_func_") + *name;
170        return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189                type = new ExpressionNode( new CastExpr( maybeMoveBuild<Expression>(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
210        } // if
211} // forCtrl
212
213bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
217if ( N ) {                                                                                                                                              \
218        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
219        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
220        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
221        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
222        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
223} else {                                                                                                                                                \
224        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
225        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
226        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234        Token tok;
235        ParseNode * pn;
236        ExpressionNode * en;
237        DeclarationNode * decl;
238        AggregateDecl::Aggregate aggKey;
239        TypeDecl::Kind tclass;
240        StatementNode * sn;
241        WaitForStmt * wfs;
242        Expression * constant;
243        IfCtrl * ifctl;
244        ForCtrl * fctl;
245        enum OperKinds compop;
246        LabelNode * label;
247        InitializerNode * in;
248        OperKinds op;
249        std::string * str;
250        bool flag;
251        CatchStmt::Kind catch_kind;
252        GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL                                                                              // C11
261%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN                                                                                 // C11
263%token CONST VOLATILE
264%token RESTRICT                                                                                 // C99
265%token ATOMIC                                                                                   // C11
266%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY                                                   // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T                                                                             // CFA
272%token VALIST                                                                                   // GCC
273%token AUTO_TYPE                                                                                // GCC
274%token TYPEOF BASETYPEOF LABEL                                                  // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION                                                                                // CFA
277%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
279%token SIZEOF OFFSETOF
280// %token RESUME                                                                                        // CFA
281%token SUSPEND                                                                                  // CFA
282%token ATTRIBUTE EXTENSION                                                              // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
290%token<tok> TIMEOUT                             WOR
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list_opt  argument_expression                     default_initializer_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en> bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class new_type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody enum_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_opt attribute attribute_name_list attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast<CompoundStmt *>(maybeMoveBuild<Statement>($2) ) ) ); }
581        | type_name '.' identifier                                                      // CFA, nested type
582                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
583        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
584                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
585        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
586                {
587                        // add the missing control expression to the GenericExpr and return it
588                        $5->control = maybeMoveBuild<Expression>( $3 );
589                        $$ = new ExpressionNode( $5 );
590                }
591        // | RESUME '(' comma_expression ')'
592        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
593        // | RESUME '(' comma_expression ')' compound_statement
594        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
595        ;
596
597generic_assoc_list:                                                                             // C11
598        generic_association
599        | generic_assoc_list ',' generic_association
600                {
601                        // steal the association node from the singleton and delete the wrapper
602                        $1->associations.splice($1->associations.end(), $3->associations);
603                        delete $3;
604                        $$ = $1;
605                }
606        ;
607
608generic_association:                                                                    // C11
609        type_no_function ':' assignment_expression
610                {
611                        // create a GenericExpr wrapper with one association pair
612                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>( $3 ) } } );
613                }
614        | DEFAULT ':' assignment_expression
615                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>( $3 ) } } ); }
616        ;
617
618postfix_expression:
619        primary_expression
620        | postfix_expression '[' assignment_expression ',' comma_expression ']'
621                // { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, new ExpressionNode( build_binary_val( OperKinds::Index, $3, $5 ) ) ) ); }
622                { SemanticError( yylloc, "New array subscript is currently unimplemented." ); $$ = nullptr; }
623        | postfix_expression '[' assignment_expression ']'
624                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
625                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
626                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
627                // equivalent to the old x[i,j].
628                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
629        | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
630                {
631                        Token fn;
632                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
633                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
634                }
635        | postfix_expression '(' argument_expression_list_opt ')'
636                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
637        | postfix_expression '`' identifier                                     // CFA, postfix call
638                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
639        | constant '`' identifier                                                       // CFA, postfix call
640                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
641        | string_literal '`' identifier                                         // CFA, postfix call
642                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
643        | postfix_expression '.' identifier
644                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
645        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
646                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
647        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
648                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
649        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
650                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
651        | postfix_expression '.' aggregate_control
652                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
653        | postfix_expression ARROW identifier
654                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
655        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
656                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
657        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
658                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
659        | postfix_expression ICR
660                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
661        | postfix_expression DECR
662                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
663        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
664                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
665        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
666                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
667        | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
668                {
669                        Token fn;
670                        fn.str = new string( "^?{}" );                          // location undefined
671                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
672                }
673        ;
674
675argument_expression_list_opt:
676        // empty
677                { $$ = nullptr; }
678        | argument_expression
679        | argument_expression_list_opt ',' argument_expression
680                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
681        ;
682
683argument_expression:
684        '@'                                                                                                     // CFA, default parameter
685                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
686                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
687        | assignment_expression
688        ;
689
690field_name_list:                                                                                // CFA, tuple field selector
691        field
692        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
693        ;
694
695field:                                                                                                  // CFA, tuple field selector
696        field_name
697        | FLOATING_DECIMALconstant field
698                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
699        | FLOATING_DECIMALconstant '[' field_name_list ']'
700                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
701        | field_name '.' field
702                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
703        | field_name '.' '[' field_name_list ']'
704                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
705        | field_name ARROW field
706                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
707        | field_name ARROW '[' field_name_list ']'
708                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
709        ;
710
711field_name:
712        INTEGERconstant fraction_constants_opt
713                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
714        | FLOATINGconstant fraction_constants_opt
715                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
716        | identifier fraction_constants_opt
717                {
718                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
719                }
720        ;
721
722fraction_constants_opt:
723        // empty
724                { $$ = nullptr; }
725        | fraction_constants_opt FLOATING_FRACTIONconstant
726                {
727                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
728                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
729                }
730        ;
731
732unary_expression:
733        postfix_expression
734                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
735                // semantics checks, e.g., ++3, 3--, *3, &&3
736        | constant
737        | string_literal
738                { $$ = new ExpressionNode( $1 ); }
739        | EXTENSION cast_expression                                                     // GCC
740                { $$ = $2->set_extension( true ); }
741                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
742                //              { * X; }         // dereference X
743                //              { * int X; } // CFA declaration of pointer to int
744        | ptrref_operator cast_expression                                       // CFA
745                {
746                        switch ( $1 ) {
747                          case OperKinds::AddressOf:
748                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) );
749                                break;
750                          case OperKinds::PointTo:
751                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
752                                break;
753                          case OperKinds::And:
754                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) ) );
755                                break;
756                          default:
757                                assert( false );
758                        }
759                }
760        | unary_operator cast_expression
761                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
762        | ICR unary_expression
763                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
764        | DECR unary_expression
765                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
766        | SIZEOF unary_expression
767                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
768        | SIZEOF '(' type_no_function ')'
769                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
770        | ALIGNOF unary_expression                                                      // GCC, variable alignment
771                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
772        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
773                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
774        | OFFSETOF '(' type_no_function ',' identifier ')'
775                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
776        ;
777
778ptrref_operator:
779        '*'                                                                                     { $$ = OperKinds::PointTo; }
780        | '&'                                                                           { $$ = OperKinds::AddressOf; }
781                // GCC, address of label must be handled by semantic check for ref,ref,label
782        | ANDAND                                                                        { $$ = OperKinds::And; }
783        ;
784
785unary_operator:
786        '+'                                                                                     { $$ = OperKinds::UnPlus; }
787        | '-'                                                                           { $$ = OperKinds::UnMinus; }
788        | '!'                                                                           { $$ = OperKinds::Neg; }
789        | '~'                                                                           { $$ = OperKinds::BitNeg; }
790        ;
791
792cast_expression:
793        unary_expression
794        | '(' type_no_function ')' cast_expression
795                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
796        | '(' aggregate_control '&' ')' cast_expression         // CFA
797                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
798        | '(' VIRTUAL ')' cast_expression                                       // CFA
799                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $4 ), maybeMoveBuildType( nullptr ) ) ); }
800        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
801                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $5 ), maybeMoveBuildType( $3 ) ) ); }
802        | '(' RETURN type_no_function ')' cast_expression       // CFA
803                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
804        | '(' COERCE type_no_function ')' cast_expression       // CFA
805                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
806        | '(' qualifier_cast_list ')' cast_expression           // CFA
807                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
808//      | '(' type_no_function ')' tuple
809//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
810        ;
811
812qualifier_cast_list:
813        cast_modifier type_qualifier_name
814        | cast_modifier MUTEX
815        | qualifier_cast_list cast_modifier type_qualifier_name
816        | qualifier_cast_list cast_modifier MUTEX
817        ;
818
819cast_modifier:
820        '-'
821        | '+'
822        ;
823
824exponential_expression:
825        cast_expression
826        | exponential_expression '\\' cast_expression
827                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
828        ;
829
830multiplicative_expression:
831        exponential_expression
832        | multiplicative_expression '*' exponential_expression
833                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
834        | multiplicative_expression '/' exponential_expression
835                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
836        | multiplicative_expression '%' exponential_expression
837                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
838        ;
839
840additive_expression:
841        multiplicative_expression
842        | additive_expression '+' multiplicative_expression
843                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
844        | additive_expression '-' multiplicative_expression
845                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
846        ;
847
848shift_expression:
849        additive_expression
850        | shift_expression LS additive_expression
851                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
852        | shift_expression RS additive_expression
853                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
854        ;
855
856relational_expression:
857        shift_expression
858        | relational_expression '<' shift_expression
859                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
860        | relational_expression '>' shift_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
862        | relational_expression LE shift_expression
863                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
864        | relational_expression GE shift_expression
865                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
866        ;
867
868equality_expression:
869        relational_expression
870        | equality_expression EQ relational_expression
871                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
872        | equality_expression NE relational_expression
873                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
874        ;
875
876AND_expression:
877        equality_expression
878        | AND_expression '&' equality_expression
879                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
880        ;
881
882exclusive_OR_expression:
883        AND_expression
884        | exclusive_OR_expression '^' AND_expression
885                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
886        ;
887
888inclusive_OR_expression:
889        exclusive_OR_expression
890        | inclusive_OR_expression '|' exclusive_OR_expression
891                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
892        ;
893
894logical_AND_expression:
895        inclusive_OR_expression
896        | logical_AND_expression ANDAND inclusive_OR_expression
897                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
898        ;
899
900logical_OR_expression:
901        logical_AND_expression
902        | logical_OR_expression OROR logical_AND_expression
903                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
904        ;
905
906conditional_expression:
907        logical_OR_expression
908        | logical_OR_expression '?' comma_expression ':' conditional_expression
909                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
910                // FIX ME: computes $1 twice
911        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
912                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
913        ;
914
915constant_expression:
916        conditional_expression
917        ;
918
919assignment_expression:
920                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
921        conditional_expression
922        | unary_expression assignment_operator assignment_expression
923                {
924//                      if ( $2 == OperKinds::AtAssn ) {
925//                              SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
926//                      } else {
927                                $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
928//                      } // if
929                }
930        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
931                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
932        ;
933
934assignment_expression_opt:
935        // empty
936                { $$ = nullptr; }
937        | assignment_expression
938        ;
939
940assignment_operator:
941        '='                                                                                     { $$ = OperKinds::Assign; }
942        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
943        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
944        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
945        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
946        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
947        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
948        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
949        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
950        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
951        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
952        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
953        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
954        ;
955
956tuple:                                                                                                  // CFA, tuple
957                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
958                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
959//      '[' ']'
960//              { $$ = new ExpressionNode( build_tuple() ); }
961//      | '[' push assignment_expression pop ']'
962//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
963        '[' ',' tuple_expression_list ']'
964                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
965        | '[' push assignment_expression pop ',' tuple_expression_list ']'
966                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
967        ;
968
969tuple_expression_list:
970        assignment_expression
971        | '@'                                                                                           // CFA
972                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
973        | tuple_expression_list ',' assignment_expression
974                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
975        | tuple_expression_list ',' '@'
976                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
977        ;
978
979comma_expression:
980        assignment_expression
981        | comma_expression ',' assignment_expression
982                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
983        ;
984
985comma_expression_opt:
986        // empty
987                { $$ = nullptr; }
988        | comma_expression
989        ;
990
991//*************************** STATEMENTS *******************************
992
993statement:
994        labeled_statement
995        | compound_statement
996        | expression_statement
997        | selection_statement
998        | iteration_statement
999        | jump_statement
1000        | with_statement
1001        | mutex_statement
1002        | waitfor_statement
1003        | exception_statement
1004        | enable_disable_statement
1005                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1006        | asm_statement
1007        | DIRECTIVE
1008                { $$ = new StatementNode( build_directive( $1 ) ); }
1009        ;
1010
1011labeled_statement:
1012                // labels cannot be identifiers 0 or 1
1013        identifier_or_type_name ':' attribute_list_opt statement
1014                { $$ = $4->add_label( $1, $3 ); }
1015        ;
1016
1017compound_statement:
1018        '{' '}'
1019                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1020        | '{' push
1021          local_label_declaration_opt                                           // GCC, local labels
1022          statement_decl_list                                                           // C99, intermix declarations and statements
1023          pop '}'
1024                { $$ = new StatementNode( build_compound( $4 ) ); }
1025        ;
1026
1027statement_decl_list:                                                                    // C99
1028        statement_decl
1029        | statement_decl_list statement_decl
1030                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1031        ;
1032
1033statement_decl:
1034        declaration                                                                                     // CFA, new & old style declarations
1035                { $$ = new StatementNode( $1 ); }
1036        | EXTENSION declaration                                                         // GCC
1037                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1038        | function_definition
1039                { $$ = new StatementNode( $1 ); }
1040        | EXTENSION function_definition                                         // GCC
1041                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1042        | statement
1043        ;
1044
1045statement_list_nodecl:
1046        statement
1047        | statement_list_nodecl statement
1048                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1049        ;
1050
1051expression_statement:
1052        comma_expression_opt ';'
1053                { $$ = new StatementNode( build_expr( $1 ) ); }
1054        ;
1055
1056selection_statement:
1057                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1058                        // the inherent S/R conflict with THEN/ELSE.
1059        push if_statement pop
1060                { $$ = $2; }
1061        | SWITCH '(' comma_expression ')' case_clause
1062                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1063        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1064                {
1065                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1066                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1067                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1068                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1069                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1070                        // statement.
1071                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1072                }
1073        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1074                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1075        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1076                {
1077                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1078                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1079                }
1080        ;
1081
1082if_statement:
1083        IF '(' if_control_expression ')' statement                      %prec THEN
1084                // explicitly deal with the shift/reduce conflict on if/else
1085                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1086        | IF '(' if_control_expression ')' statement ELSE statement
1087                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1088        ;
1089
1090if_control_expression:
1091        comma_expression
1092                { $$ = new IfCtrl( nullptr, $1 ); }
1093        | c_declaration                                                                         // no semi-colon
1094                { $$ = new IfCtrl( $1, nullptr ); }
1095        | cfa_declaration                                                                       // no semi-colon
1096                { $$ = new IfCtrl( $1, nullptr ); }
1097        | declaration comma_expression                                          // semi-colon separated
1098                { $$ = new IfCtrl( $1, $2 ); }
1099        ;
1100
1101// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1102// clause allows a list of values and subranges.
1103
1104case_value:                                                                                             // CFA
1105        constant_expression                                                     { $$ = $1; }
1106        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1107                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1108        | subrange                                                                                      // CFA, subrange
1109        ;
1110
1111case_value_list:                                                                                // CFA
1112        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1113                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1114        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1115        ;
1116
1117case_label:                                                                                             // CFA
1118        CASE case_value_list ':'                                        { $$ = $2; }
1119        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1120                // A semantic check is required to ensure only one default clause per switch/choose statement.
1121        ;
1122
1123//label_list_opt:
1124//      // empty
1125//      | identifier_or_type_name ':'
1126//      | label_list_opt identifier_or_type_name ':'
1127//      ;
1128
1129case_label_list:                                                                                // CFA
1130        case_label
1131        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1132        ;
1133
1134case_clause:                                                                                    // CFA
1135        case_label_list statement                                       { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1136        ;
1137
1138switch_clause_list_opt:                                                                 // CFA
1139        // empty
1140                { $$ = nullptr; }
1141        | switch_clause_list
1142        ;
1143
1144switch_clause_list:                                                                             // CFA
1145        case_label_list statement_list_nodecl
1146                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1147        | switch_clause_list case_label_list statement_list_nodecl
1148                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1149        ;
1150
1151iteration_statement:
1152        WHILE '(' push if_control_expression ')' statement pop
1153                { $$ = new StatementNode( build_while( $4, maybe_build_compound( $6 ) ) ); }
1154        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1155                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1156        | DO statement WHILE '(' comma_expression ')' ';'
1157                { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1158        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1159                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1160        | FOR '(' push for_control_expression_list ')' statement pop
1161                { $$ = new StatementNode( build_for( $4, maybe_build_compound( $6 ) ) ); }
1162        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1163                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1164        ;
1165
1166for_control_expression_list:
1167        for_control_expression
1168        | for_control_expression_list ':' for_control_expression
1169                // ForCtrl + ForCtrl:
1170                //    init + init => multiple declaration statements that are hoisted
1171                //    condition + condition => (expression) && (expression)
1172                //    change + change => (expression), (expression)
1173                {
1174                        $1->init->set_last( $3->init );
1175                        if ( $1->condition ) {
1176                                if ( $3->condition ) {
1177                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1178                                } // if
1179                        } else $1->condition = $3->condition;
1180                        if ( $1->change ) {
1181                                if ( $3->change ) {
1182                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1183                                } // if
1184                        } else $1->change = $3->change;
1185                        $$ = $1;
1186                }
1187        ;
1188
1189for_control_expression:
1190        ';' comma_expression_opt ';' comma_expression_opt
1191                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1192        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1193                { $$ = new ForCtrl( $1, $3, $5 ); }
1194        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1195                { $$ = new ForCtrl( $1, $2, $4 ); }
1196
1197        | comma_expression                                                                      // CFA
1198                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1199                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1200        | '=' comma_expression                                                          // CFA
1201                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1202                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1203        | comma_expression inclexcl comma_expression            // CFA
1204                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1205        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1206                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1207        | comma_expression ';'                                                          // CFA
1208                { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1209        | comma_expression ';' comma_expression                         // CFA
1210                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1211                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1212        | comma_expression ';' '=' comma_expression                     // CFA
1213                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1214                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1215        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1216                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1217        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1218                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1219
1220                // There is a S/R conflicit if ~ and -~ are factored out.
1221        | comma_expression ';' comma_expression '~' '@'         // CFA
1222                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1223        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1224                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1225        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1226                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1227        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1228                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1229        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1230                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1231        ;
1232
1233inclexcl:
1234        '~'
1235                { $$ = OperKinds::LThan; }
1236        | ErangeUpEq
1237                { $$ = OperKinds::LEThan; }
1238        | ErangeDown
1239                { $$ = OperKinds::GThan; }
1240        | ErangeDownEq
1241                { $$ = OperKinds::GEThan; }
1242        ;
1243
1244jump_statement:
1245        GOTO identifier_or_type_name ';'
1246                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1247        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1248                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1249                // whereas normal operator precedence yields goto (*i)+3;
1250                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1251                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1252        | fall_through_name ';'                                                         // CFA
1253                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1254        | fall_through_name identifier_or_type_name ';'         // CFA
1255                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1256        | fall_through_name DEFAULT ';'                                         // CFA
1257                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1258        | CONTINUE ';'
1259                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1260                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1261        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1262                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1263                // the target of the transfer appears only at the start of an iteration statement.
1264                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1265        | BREAK ';'
1266                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1267                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1268        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1269                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1270                // the target of the transfer appears only at the start of an iteration statement.
1271                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1272        | RETURN comma_expression_opt ';'
1273                { $$ = new StatementNode( build_return( $2 ) ); }
1274        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1275                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1276        | SUSPEND ';'
1277                { $$ = new StatementNode( build_suspend( nullptr ) ); }
1278        | SUSPEND compound_statement
1279                { $$ = new StatementNode( build_suspend( $2 ) ); }
1280        | SUSPEND COROUTINE ';'
1281                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1282        | SUSPEND COROUTINE compound_statement
1283                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1284        | SUSPEND GENERATOR ';'
1285                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1286        | SUSPEND GENERATOR compound_statement
1287                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1288        | THROW assignment_expression_opt ';'                           // handles rethrow
1289                { $$ = new StatementNode( build_throw( $2 ) ); }
1290        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1291                { $$ = new StatementNode( build_resume( $2 ) ); }
1292        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1293                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1294        ;
1295
1296fall_through_name:                                                                              // CFA
1297        FALLTHRU
1298        | FALLTHROUGH
1299        ;
1300
1301with_statement:
1302        WITH '(' tuple_expression_list ')' statement
1303                {
1304                        $$ = new StatementNode( build_with( $3, $5 ) );
1305                }
1306        ;
1307
1308// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1309mutex_statement:
1310        MUTEX '(' argument_expression_list_opt ')' statement
1311                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1312        ;
1313
1314when_clause:
1315        WHEN '(' comma_expression ')'                           { $$ = $3; }
1316        ;
1317
1318when_clause_opt:
1319        // empty
1320                { $$ = nullptr; }
1321        | when_clause
1322        ;
1323
1324waitfor:
1325        WAITFOR '(' cast_expression ')'
1326                { $$ = $3; }
1327//      | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1328//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1329        | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1330                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1331        ;
1332
1333cast_expression_list:
1334        cast_expression
1335        | cast_expression_list ',' cast_expression
1336                // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1337                { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1338        ;
1339
1340timeout:
1341        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1342        ;
1343
1344waitfor_clause:
1345        when_clause_opt waitfor statement                                       %prec THEN
1346                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1347        | when_clause_opt waitfor statement WOR waitfor_clause
1348                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1349        | when_clause_opt timeout statement                                     %prec THEN
1350                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1351        | when_clause_opt ELSE statement
1352                { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1353                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1354        | when_clause_opt timeout statement WOR ELSE statement
1355                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1356        | when_clause_opt timeout statement WOR when_clause ELSE statement
1357                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1358        ;
1359
1360waitfor_statement:
1361        when_clause_opt waitfor statement                                       %prec THEN
1362                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1363        | when_clause_opt waitfor statement WOR waitfor_clause
1364                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1365        ;
1366
1367exception_statement:
1368        TRY compound_statement handler_clause
1369                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1370        | TRY compound_statement finally_clause
1371                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1372        | TRY compound_statement handler_clause finally_clause
1373                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1374        ;
1375
1376handler_clause:
1377        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1378                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1379        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1380                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1381        ;
1382
1383handler_predicate_opt:
1384        // empty
1385                { $$ = nullptr; }
1386        | ';' conditional_expression                            { $$ = $2; }
1387        ;
1388
1389handler_key:
1390        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1391        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1392        ;
1393
1394finally_clause:
1395        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1396        ;
1397
1398exception_declaration:
1399                // No SUE declaration in parameter list.
1400        type_specifier_nobody
1401        | type_specifier_nobody declarator
1402                { $$ = $2->addType( $1 ); }
1403        | type_specifier_nobody variable_abstract_declarator
1404                { $$ = $2->addType( $1 ); }
1405        | cfa_abstract_declarator_tuple identifier                      // CFA
1406                { $$ = $1->addName( $2 ); }
1407        | cfa_abstract_declarator_tuple                                         // CFA
1408        ;
1409
1410enable_disable_statement:
1411        enable_disable_key identifier_list compound_statement
1412        ;
1413
1414enable_disable_key:
1415        ENABLE
1416        | DISABLE
1417        ;
1418
1419asm_statement:
1420        ASM asm_volatile_opt '(' string_literal ')' ';'
1421                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1422        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1423                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1424        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1425                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1426        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1427                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1428        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1429                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1430        ;
1431
1432asm_volatile_opt:                                                                               // GCC
1433        // empty
1434                { $$ = false; }
1435        | VOLATILE
1436                { $$ = true; }
1437        ;
1438
1439asm_operands_opt:                                                                               // GCC
1440        // empty
1441                { $$ = nullptr; }                                                               // use default argument
1442        | asm_operands_list
1443        ;
1444
1445asm_operands_list:                                                                              // GCC
1446        asm_operand
1447        | asm_operands_list ',' asm_operand
1448                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1449        ;
1450
1451asm_operand:                                                                                    // GCC
1452        string_literal '(' constant_expression ')'
1453                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild<Expression>( $3 ) ) ); }
1454        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1455                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild<Expression>( $6 ) ) ); }
1456        ;
1457
1458asm_clobbers_list_opt:                                                                  // GCC
1459        // empty
1460                { $$ = nullptr; }                                                               // use default argument
1461        | string_literal
1462                { $$ = new ExpressionNode( $1 ); }
1463        | asm_clobbers_list_opt ',' string_literal
1464                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1465        ;
1466
1467label_list:
1468        identifier
1469                {
1470                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1471                        delete $1;                                                                      // allocated by lexer
1472                }
1473        | label_list ',' identifier
1474                {
1475                        $$ = $1; $1->labels.push_back( *$3 );
1476                        delete $3;                                                                      // allocated by lexer
1477                }
1478        ;
1479
1480//******************************* DECLARATIONS *********************************
1481
1482declaration_list_opt:                                                                   // used at beginning of switch statement
1483        // empty
1484                { $$ = nullptr; }
1485        | declaration_list
1486        ;
1487
1488declaration_list:
1489        declaration
1490        | declaration_list declaration
1491                { $$ = $1->appendList( $2 ); }
1492        ;
1493
1494KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1495        // empty
1496                { $$ = nullptr; }
1497        | KR_parameter_list
1498        ;
1499
1500KR_parameter_list:
1501        push c_declaration pop ';'
1502                { $$ = $2; }
1503        | KR_parameter_list push c_declaration pop ';'
1504                { $$ = $1->appendList( $3 ); }
1505        ;
1506
1507local_label_declaration_opt:                                                    // GCC, local label
1508        // empty
1509        | local_label_declaration_list
1510        ;
1511
1512local_label_declaration_list:                                                   // GCC, local label
1513        LABEL local_label_list ';'
1514        | local_label_declaration_list LABEL local_label_list ';'
1515        ;
1516
1517local_label_list:                                                                               // GCC, local label
1518        identifier_or_type_name
1519        | local_label_list ',' identifier_or_type_name
1520        ;
1521
1522declaration:                                                                                    // old & new style declarations
1523        c_declaration ';'
1524        | cfa_declaration ';'                                                           // CFA
1525        | static_assert                                                                         // C11
1526        ;
1527
1528static_assert:
1529        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1530                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1531        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1532                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1533
1534// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1535// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1536// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1537// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1538// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1539// block, but cannot be mixed within a specific declaration.
1540//
1541//                      CFA                                     C
1542//              [10] int x;                     int x[10];              // array of 10 integers
1543//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1544
1545cfa_declaration:                                                                                // CFA
1546        cfa_variable_declaration
1547        | cfa_typedef_declaration
1548        | cfa_function_declaration
1549        | type_declaring_list
1550                { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1551        | trait_specifier
1552        ;
1553
1554cfa_variable_declaration:                                                               // CFA
1555        cfa_variable_specifier initializer_opt
1556                { $$ = $1->addInitializer( $2 ); }
1557        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1558                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1559                // them as a type_qualifier cannot appear in that context.
1560                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1561        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1562                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1563        ;
1564
1565cfa_variable_specifier:                                                                 // CFA
1566                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1567                // storage-class
1568        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1569                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1570        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1571                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1572        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1573                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1574        ;
1575
1576cfa_function_declaration:                                                               // CFA
1577        cfa_function_specifier
1578        | type_qualifier_list cfa_function_specifier
1579                { $$ = $2->addQualifiers( $1 ); }
1580        | declaration_qualifier_list cfa_function_specifier
1581                { $$ = $2->addQualifiers( $1 ); }
1582        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1583                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1584        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1585                {
1586                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1587                        DeclarationNode * ret = new DeclarationNode;
1588                        ret->type = maybeClone( $1->type->base );
1589                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1590                }
1591        ;
1592
1593cfa_function_specifier:                                                                 // CFA
1594//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1595//              {
1596//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1597//              }
1598//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1599//              {
1600//                      typedefTable.setNextIdentifier( *$5 );
1601//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1602//              }
1603//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1604//              {
1605//                      typedefTable.setNextIdentifier( *$5 );
1606//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1607//              }
1608//      | '[' ']' typegen_name
1609                // identifier_or_type_name must be broken apart because of the sequence:
1610                //
1611                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1612                //   '[' ']' type_specifier
1613                //
1614                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1615                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1616        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1617                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1618                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1619        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1620                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1621        ;
1622
1623cfa_function_return:                                                                    // CFA
1624        '[' push cfa_parameter_list pop ']'
1625                { $$ = DeclarationNode::newTuple( $3 ); }
1626        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1627                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1628                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1629        ;
1630
1631cfa_typedef_declaration:                                                                // CFA
1632        TYPEDEF cfa_variable_specifier
1633                {
1634                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1635                        $$ = $2->addTypedef();
1636                }
1637        | TYPEDEF cfa_function_specifier
1638                {
1639                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1640                        $$ = $2->addTypedef();
1641                }
1642        | cfa_typedef_declaration pop ',' push identifier
1643                {
1644                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1645                        $$ = $1->appendList( $1->cloneType( $5 ) );
1646                }
1647        ;
1648
1649// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1650// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1651
1652typedef_declaration:
1653        TYPEDEF type_specifier declarator
1654                {
1655                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1656                        $$ = $3->addType( $2 )->addTypedef();
1657                }
1658        | typedef_declaration pop ',' push declarator
1659                {
1660                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1661                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1662                }
1663        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1664                {
1665                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1666                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1667                }
1668        | type_specifier TYPEDEF declarator
1669                {
1670                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1671                        $$ = $3->addType( $1 )->addTypedef();
1672                }
1673        | type_specifier TYPEDEF type_qualifier_list declarator
1674                {
1675                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1676                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1677                }
1678        ;
1679
1680typedef_expression:
1681                // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1682        TYPEDEF identifier '=' assignment_expression
1683                {
1684                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1685                }
1686        | typedef_expression pop ',' push identifier '=' assignment_expression
1687                {
1688                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1689                }
1690        ;
1691
1692c_declaration:
1693        declaration_specifier declaring_list
1694                { $$ = distAttr( $1, $2 ); }
1695        | typedef_declaration
1696        | typedef_expression                                                            // deprecated GCC, naming expression type
1697        | sue_declaration_specifier
1698        ;
1699
1700declaring_list:
1701                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1702                // storage-class
1703        declarator asm_name_opt initializer_opt
1704                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1705        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1706                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1707        ;
1708
1709declaration_specifier:                                                                  // type specifier + storage class
1710        basic_declaration_specifier
1711        | sue_declaration_specifier
1712        | type_declaration_specifier
1713        ;
1714
1715declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1716                // Preclude SUE declarations in restricted scopes:
1717                //
1718                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1719                //
1720                // because it is impossible to call f due to name equivalence.
1721        basic_declaration_specifier
1722        | sue_declaration_specifier_nobody
1723        | type_declaration_specifier
1724        ;
1725
1726type_specifier:                                                                                 // type specifier
1727        basic_type_specifier
1728        | sue_type_specifier
1729        | type_type_specifier
1730        ;
1731
1732type_specifier_nobody:                                                                  // type specifier - {...}
1733                // Preclude SUE declarations in restricted scopes:
1734                //
1735                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1736                //
1737                // because it is impossible to call f due to name equivalence.
1738        basic_type_specifier
1739        | sue_type_specifier_nobody
1740        | type_type_specifier
1741        ;
1742
1743enum_specifier_nobody:                                                                  // type specifier - {...}
1744                // Preclude SUE declarations in restricted scopes (see type_specifier_nobody)
1745        basic_type_specifier
1746        | sue_type_specifier_nobody
1747        ;
1748
1749type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1750        // empty
1751                { $$ = nullptr; }
1752        | type_qualifier_list
1753        ;
1754
1755type_qualifier_list:
1756                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1757                //
1758                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1759                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1760                // appeared only once.
1761        type_qualifier
1762        | type_qualifier_list type_qualifier
1763                { $$ = $1->addQualifiers( $2 ); }
1764        ;
1765
1766type_qualifier:
1767        type_qualifier_name
1768        | attribute
1769        ;
1770
1771type_qualifier_name:
1772        CONST
1773                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1774        | RESTRICT
1775                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1776        | VOLATILE
1777                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1778        | ATOMIC
1779                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1780        | forall
1781        ;
1782
1783forall:
1784        FORALL '(' type_parameter_list ')'                                      // CFA
1785                { $$ = DeclarationNode::newForall( $3 ); }
1786        ;
1787
1788declaration_qualifier_list:
1789        storage_class_list
1790        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1791                { $$ = $1->addQualifiers( $2 ); }
1792        | declaration_qualifier_list type_qualifier_list storage_class_list
1793                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1794        ;
1795
1796storage_class_list:
1797                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1798                // only one of each is specified, except for inline, which can appear with the others.
1799                //
1800                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1801                // specifiers in a declaration.
1802        storage_class
1803        | storage_class_list storage_class
1804                { $$ = $1->addQualifiers( $2 ); }
1805        ;
1806
1807storage_class:
1808        EXTERN
1809                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1810        | STATIC
1811                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1812        | AUTO
1813                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1814        | REGISTER
1815                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1816        | THREADLOCAL                                                                           // C11
1817                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1818                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1819        | INLINE                                                                                        // C99
1820                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1821        | FORTRAN                                                                                       // C99
1822                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1823        | NORETURN                                                                                      // C11
1824                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1825        ;
1826
1827basic_type_name:
1828        VOID
1829                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1830        | BOOL                                                                                          // C99
1831                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1832        | CHAR
1833                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1834        | INT
1835                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1836        | INT128
1837                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1838        | UINT128
1839                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1840        | FLOAT
1841                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1842        | DOUBLE
1843                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1844        | uuFLOAT80
1845                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1846        | uuFLOAT128
1847                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1848        | uFLOAT16
1849                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1850        | uFLOAT32
1851                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1852        | uFLOAT32X
1853                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1854        | uFLOAT64
1855                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1856        | uFLOAT64X
1857                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1858        | uFLOAT128
1859                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1860        | COMPLEX                                                                                       // C99
1861                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1862        | IMAGINARY                                                                                     // C99
1863                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1864        | SIGNED
1865                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1866        | UNSIGNED
1867                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1868        | SHORT
1869                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1870        | LONG
1871                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1872        | VALIST                                                                                        // GCC, __builtin_va_list
1873                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1874        | AUTO_TYPE
1875                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1876        ;
1877
1878basic_declaration_specifier:
1879                // A semantic check is necessary for conflicting storage classes.
1880        basic_type_specifier
1881        | declaration_qualifier_list basic_type_specifier
1882                { $$ = $2->addQualifiers( $1 ); }
1883        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1884                { $$ = $1->addQualifiers( $2 ); }
1885        | basic_declaration_specifier storage_class type_qualifier_list
1886                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1887        | basic_declaration_specifier storage_class basic_type_specifier
1888                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1889        ;
1890
1891basic_type_specifier:
1892        direct_type
1893                // Cannot have type modifiers, e.g., short, long, etc.
1894        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1895                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1896        ;
1897
1898direct_type:
1899        basic_type_name
1900        | type_qualifier_list basic_type_name
1901                { $$ = $2->addQualifiers( $1 ); }
1902        | direct_type type_qualifier
1903                { $$ = $1->addQualifiers( $2 ); }
1904        | direct_type basic_type_name
1905                { $$ = $1->addType( $2 ); }
1906        ;
1907
1908indirect_type:
1909        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1910                { $$ = $3; }
1911        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1912                { $$ = DeclarationNode::newTypeof( $3 ); }
1913        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1914                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1915        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1916                { $$ = DeclarationNode::newTypeof( $3, true ); }
1917        | ZERO_T                                                                                        // CFA
1918                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1919        | ONE_T                                                                                         // CFA
1920                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1921        ;
1922
1923sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1924        sue_type_specifier
1925        | declaration_qualifier_list sue_type_specifier
1926                { $$ = $2->addQualifiers( $1 ); }
1927        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1928                { $$ = $1->addQualifiers( $2 ); }
1929        | sue_declaration_specifier storage_class type_qualifier_list
1930                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1931        ;
1932
1933sue_type_specifier:                                                                             // struct, union, enum + type specifier
1934        elaborated_type
1935        | type_qualifier_list
1936                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1937          elaborated_type
1938                { $$ = $3->addQualifiers( $1 ); }
1939        | sue_type_specifier type_qualifier
1940                {
1941                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1942                        $$ = $1->addQualifiers( $2 );
1943                }
1944        ;
1945
1946sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1947        sue_type_specifier_nobody
1948        | declaration_qualifier_list sue_type_specifier_nobody
1949                { $$ = $2->addQualifiers( $1 ); }
1950        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1951                { $$ = $1->addQualifiers( $2 ); }
1952        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1953                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1954        ;
1955
1956sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1957        elaborated_type_nobody
1958        | type_qualifier_list elaborated_type_nobody
1959                { $$ = $2->addQualifiers( $1 ); }
1960        | sue_type_specifier_nobody type_qualifier
1961                { $$ = $1->addQualifiers( $2 ); }
1962        ;
1963
1964type_declaration_specifier:
1965        type_type_specifier
1966        | declaration_qualifier_list type_type_specifier
1967                { $$ = $2->addQualifiers( $1 ); }
1968        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1969                { $$ = $1->addQualifiers( $2 ); }
1970        | type_declaration_specifier storage_class type_qualifier_list
1971                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1972        ;
1973
1974type_type_specifier:                                                                    // typedef types
1975        type_name
1976        | type_qualifier_list type_name
1977                { $$ = $2->addQualifiers( $1 ); }
1978        | type_type_specifier type_qualifier
1979                { $$ = $1->addQualifiers( $2 ); }
1980        ;
1981
1982type_name:
1983        TYPEDEFname
1984                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1985        | '.' TYPEDEFname
1986                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1987        | type_name '.' TYPEDEFname
1988                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1989        | typegen_name
1990        | '.' typegen_name
1991                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1992        | type_name '.' typegen_name
1993                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1994        ;
1995
1996typegen_name:                                                                                   // CFA
1997        TYPEGENname
1998                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1999        | TYPEGENname '(' ')'
2000                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2001        | TYPEGENname '(' type_list ')'
2002                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2003        ;
2004
2005elaborated_type:                                                                                // struct, union, enum
2006        aggregate_type
2007        | enum_type
2008        ;
2009
2010elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2011        aggregate_type_nobody
2012        | enum_type_nobody
2013        ;
2014
2015aggregate_type:                                                                                 // struct, union
2016        aggregate_key attribute_list_opt
2017                { forall = false; }                                                             // reset
2018          '{' field_declaration_list_opt '}' type_parameters_opt
2019                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2020        | aggregate_key attribute_list_opt identifier
2021                {
2022                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2023                        forall = false;                                                         // reset
2024                }
2025          '{' field_declaration_list_opt '}' type_parameters_opt
2026                { $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 ); }
2027        | aggregate_key attribute_list_opt type_name
2028                {
2029                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2030                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2031                        forall = false;                                                         // reset
2032                }
2033          '{' field_declaration_list_opt '}' type_parameters_opt
2034                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $8, $6, true )->addQualifiers( $2 ); }
2035        | aggregate_type_nobody
2036        ;
2037
2038type_parameters_opt:
2039        // empty
2040                { $$ = nullptr; }                                                               %prec '}'
2041        | '(' type_list ')'
2042                { $$ = $2; }
2043        ;
2044
2045aggregate_type_nobody:                                                                  // struct, union - {...}
2046        aggregate_key attribute_list_opt identifier
2047                {
2048                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2049                        forall = false;                                                         // reset
2050                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2051                }
2052        | aggregate_key attribute_list_opt type_name
2053                {
2054                        forall = false;                                                         // reset
2055                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2056                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2057                        // delete newFromTypeGen.
2058                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2059                        $3->type->symbolic.name = nullptr;
2060                        $3->type->symbolic.actuals = nullptr;
2061                        delete $3;
2062                }
2063        ;
2064
2065aggregate_key:
2066        aggregate_data
2067        | aggregate_control
2068        ;
2069
2070aggregate_data:
2071        STRUCT
2072                { yyy = true; $$ = AggregateDecl::Struct; }
2073        | UNION
2074                { yyy = true; $$ = AggregateDecl::Union; }
2075        | EXCEPTION                                                                                     // CFA
2076                // { yyy = true; $$ = AggregateDecl::Exception; }
2077                { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2078        ;
2079
2080aggregate_control:                                                                              // CFA
2081        MONITOR
2082                { yyy = true; $$ = AggregateDecl::Monitor; }
2083        | MUTEX STRUCT
2084                { yyy = true; $$ = AggregateDecl::Monitor; }
2085        | GENERATOR
2086                { yyy = true; $$ = AggregateDecl::Generator; }
2087        | MUTEX GENERATOR
2088                { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2089        | COROUTINE
2090                { yyy = true; $$ = AggregateDecl::Coroutine; }
2091        | MUTEX COROUTINE
2092                { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2093        | THREAD
2094                { yyy = true; $$ = AggregateDecl::Thread; }
2095        | MUTEX THREAD
2096                { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2097        ;
2098
2099field_declaration_list_opt:
2100        // empty
2101                { $$ = nullptr; }
2102        | field_declaration_list_opt field_declaration
2103                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2104        ;
2105
2106field_declaration:
2107        type_specifier field_declaring_list_opt ';'
2108                { $$ = fieldDecl( $1, $2 ); }
2109        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2110                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2111        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2112                {
2113                        if ( ! $3 ) {                                                           // field declarator ?
2114                                $3 = DeclarationNode::newName( nullptr );
2115                        } // if
2116                        $3->inLine = true;
2117                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2118                        distInl( $3 );
2119                }
2120        | INLINE aggregate_control ';'                                          // CFA
2121                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2122        | typedef_declaration ';'                                                       // CFA
2123        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2124        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2125                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2126        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2127                { $$ = $2; }                                                                    // mark all fields in list
2128        | cfa_typedef_declaration ';'                                           // CFA
2129        | static_assert                                                                         // C11
2130        ;
2131
2132field_declaring_list_opt:
2133        // empty
2134                { $$ = nullptr; }
2135        | field_declarator
2136        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2137                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2138        ;
2139
2140field_declarator:
2141        bit_subrange_size                                                                       // C special case, no field name
2142                { $$ = DeclarationNode::newBitfield( $1 ); }
2143        | variable_declarator bit_subrange_size_opt
2144                // A semantic check is required to ensure bit_subrange only appears on integral types.
2145                { $$ = $1->addBitfield( $2 ); }
2146        | variable_type_redeclarator bit_subrange_size_opt
2147                // A semantic check is required to ensure bit_subrange only appears on integral types.
2148                { $$ = $1->addBitfield( $2 ); }
2149        ;
2150
2151field_abstract_list_opt:
2152        // empty
2153                { $$ = nullptr; }
2154        | field_abstract
2155        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2156                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2157        ;
2158
2159field_abstract:
2160                //      no bit fields
2161        variable_abstract_declarator
2162        ;
2163
2164cfa_field_declaring_list:                                                               // CFA, new style field declaration
2165        // bit-fields are handled by C declarations
2166        cfa_abstract_declarator_tuple identifier_or_type_name
2167                { $$ = $1->addName( $2 ); }
2168        | cfa_field_declaring_list ',' identifier_or_type_name
2169                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2170        ;
2171
2172cfa_field_abstract_list:                                                                // CFA, new style field declaration
2173        // bit-fields are handled by C declarations
2174        cfa_abstract_declarator_tuple
2175        | cfa_field_abstract_list ','
2176                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2177        ;
2178
2179bit_subrange_size_opt:
2180        // empty
2181                { $$ = nullptr; }
2182        | bit_subrange_size
2183        ;
2184
2185bit_subrange_size:
2186        ':' assignment_expression
2187                { $$ = $2; }
2188        ;
2189
2190// Cannot use attribute_list_opt because of ambiguity with enum_specifier_nobody, which already parses attribute.
2191// Hence, only a single attribute is allowed after the "ENUM".
2192enum_type:                                                                                              // enum
2193        ENUM attribute_opt '{' enumerator_list comma_opt '}'
2194                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2195        | ENUM attribute_opt identifier
2196                { typedefTable.makeTypedef( *$3 ); }
2197          '{' enumerator_list comma_opt '}'
2198                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2199        | ENUM attribute_opt typedef                                            // enum cannot be generic
2200          '{' enumerator_list comma_opt '}'
2201                { $$ = DeclarationNode::newEnum( $3->name, $5, true )->addQualifiers( $2 ); }
2202        | ENUM enum_specifier_nobody '{' enumerator_list comma_opt '}'
2203                // { $$ = DeclarationNode::newEnum( nullptr, $4, true ); }
2204                { SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr; }
2205        | ENUM enum_specifier_nobody declarator '{' enumerator_list comma_opt '}'
2206                // {
2207                //      typedefTable.makeTypedef( *$3->name );
2208                //      $$ = DeclarationNode::newEnum( nullptr, $5, true );
2209                // }
2210                { SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr; }
2211        | enum_type_nobody
2212        ;
2213
2214enum_type_nobody:                                                                               // enum - {...}
2215        ENUM attribute_opt identifier
2216                {
2217                        typedefTable.makeTypedef( *$3 );
2218                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2219                }
2220        | ENUM attribute_opt type_name                                          // enum cannot be generic
2221                {
2222                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2223                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2224                }
2225        ;
2226
2227enumerator_list:
2228        identifier_or_type_name enumerator_value_opt
2229                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2230        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2231                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2232        ;
2233
2234enumerator_value_opt:
2235        // empty
2236                { $$ = nullptr; }
2237        // | '=' constant_expression
2238        //      { $$ = $2; }
2239        | '=' initializer
2240                { $$ = $2->get_expression(); }                                  // FIX ME: enum only deals with constant_expression
2241        ;
2242
2243cfa_parameter_ellipsis_list_opt:                                                // CFA, abstract + real
2244        // empty
2245                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2246        | ELLIPSIS
2247                { $$ = nullptr; }
2248        | cfa_abstract_parameter_list
2249        | cfa_parameter_list
2250        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2251                { $$ = $1->appendList( $5 ); }
2252        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2253                { $$ = $1->addVarArgs(); }
2254        | cfa_parameter_list pop ',' push ELLIPSIS
2255                { $$ = $1->addVarArgs(); }
2256        ;
2257
2258cfa_parameter_list:                                                                             // CFA
2259                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2260                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2261        cfa_parameter_declaration
2262        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2263                { $$ = $1->appendList( $5 ); }
2264        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2265                { $$ = $1->appendList( $5 ); }
2266        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2267                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2268        ;
2269
2270cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2271        cfa_abstract_parameter_declaration
2272        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2273                { $$ = $1->appendList( $5 ); }
2274        ;
2275
2276parameter_type_list_opt:
2277        // empty
2278                { $$ = nullptr; }
2279        | ELLIPSIS
2280                { $$ = nullptr; }
2281        | parameter_list
2282        | parameter_list pop ',' push ELLIPSIS
2283                { $$ = $1->addVarArgs(); }
2284        ;
2285
2286parameter_list:                                                                                 // abstract + real
2287        abstract_parameter_declaration
2288        | parameter_declaration
2289        | parameter_list pop ',' push abstract_parameter_declaration
2290                { $$ = $1->appendList( $5 ); }
2291        | parameter_list pop ',' push parameter_declaration
2292                { $$ = $1->appendList( $5 ); }
2293        ;
2294
2295// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2296// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2297
2298cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2299        parameter_declaration
2300        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2301                { $$ = $1->addName( $2 ); }
2302        | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2303                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2304                { $$ = $1->addName( $2 ); }
2305        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2306                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2307        | cfa_function_specifier
2308        ;
2309
2310cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2311        abstract_parameter_declaration
2312        | cfa_identifier_parameter_declarator_no_tuple
2313        | cfa_abstract_tuple
2314                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2315        | type_qualifier_list cfa_abstract_tuple
2316                { $$ = $2->addQualifiers( $1 ); }
2317        | cfa_abstract_function
2318        ;
2319
2320parameter_declaration:
2321                // No SUE declaration in parameter list.
2322        declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2323                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2324        | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2325                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2326        ;
2327
2328abstract_parameter_declaration:
2329        declaration_specifier_nobody default_initializer_opt
2330                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2331        | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2332                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2333        ;
2334
2335// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2336// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2337// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2338
2339identifier_list:                                                                                // K&R-style parameter list => no types
2340        identifier
2341                { $$ = DeclarationNode::newName( $1 ); }
2342        | identifier_list ',' identifier
2343                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2344        ;
2345
2346identifier_or_type_name:
2347        identifier
2348        | TYPEDEFname
2349        | TYPEGENname
2350        ;
2351
2352type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2353        cfa_abstract_declarator_tuple                                           // CFA
2354        | type_specifier
2355        | type_specifier abstract_declarator
2356                { $$ = $2->addType( $1 ); }
2357        ;
2358
2359type:                                                                                                   // typeof, assertion
2360        type_no_function
2361        | cfa_abstract_function                                                         // CFA
2362        ;
2363
2364initializer_opt:
2365        // empty
2366                { $$ = nullptr; }
2367        | '=' initializer
2368                { $$ = $2; }
2369        | '=' VOID
2370                { $$ = new InitializerNode( true ); }
2371        | ATassign initializer
2372                { $$ = $2->set_maybeConstructed( false ); }
2373        ;
2374
2375initializer:
2376        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2377        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2378        ;
2379
2380initializer_list_opt:
2381        // empty
2382                { $$ = nullptr; }
2383        | initializer
2384        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2385        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2386        | initializer_list_opt ',' designation initializer
2387                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2388        ;
2389
2390// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2391// '=' to separator the designator from the initializer value, as in:
2392//
2393//              int x[10] = { [1] = 3 };
2394//
2395// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2396// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2397// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2398// shift/reduce conflicts
2399
2400designation:
2401        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2402        | identifier ':'                                                                        // GCC, field name
2403                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2404        ;
2405
2406designator_list:                                                                                // C99
2407        designator
2408        | designator_list designator
2409                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2410        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2411        ;
2412
2413designator:
2414        '.' identifier                                                                          // C99, field name
2415                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2416        | '[' push assignment_expression pop ']'                        // C99, single array element
2417                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2418                { $$ = $3; }
2419        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2420                { $$ = $3; }
2421        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2422                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $3 ), maybeMoveBuild<Expression>( $5 ) ) ); }
2423        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2424                { $$ = $4; }
2425        ;
2426
2427// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2428// rather than an object-oriented type system. This required four groups of extensions:
2429//
2430// Overloading: function, data, and operator identifiers may be overloaded.
2431//
2432// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2433//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2434//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2435//
2436// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2437//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2438//
2439// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2440//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2441//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2442//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2443//     on type arguments of polymorphic functions.
2444
2445type_parameter_list:                                                                    // CFA
2446        type_parameter
2447        | type_parameter_list ',' type_parameter
2448                { $$ = $1->appendList( $3 ); }
2449        ;
2450
2451type_initializer_opt:                                                                   // CFA
2452        // empty
2453                { $$ = nullptr; }
2454        | '=' type
2455                { $$ = $2; }
2456        ;
2457
2458type_parameter:                                                                                 // CFA
2459        type_class identifier_or_type_name
2460                {
2461                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2462                        if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2463                        if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2464                        if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2465                }
2466          type_initializer_opt assertion_list_opt
2467                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2468        | identifier_or_type_name new_type_class
2469                { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2470          type_initializer_opt assertion_list_opt
2471                { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2472        | '[' identifier_or_type_name ']'
2473                {
2474                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2475                        $$ = DeclarationNode::newTypeParam( TypeDecl::ALtype, $2 );
2476                }
2477        // | type_specifier identifier_parameter_declarator
2478        | assertion_list
2479                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2480        ;
2481
2482new_type_class:                                                                                 // CFA
2483        // empty
2484                { $$ = TypeDecl::Otype; }
2485        | '&'
2486                { $$ = TypeDecl::Dtype; }
2487        | '*'
2488                { $$ = TypeDecl::DStype; }                                              // dtype + sized
2489        | ELLIPSIS
2490                { $$ = TypeDecl::Ttype; }
2491        ;
2492
2493type_class:                                                                                             // CFA
2494        OTYPE
2495                { $$ = TypeDecl::Otype; }
2496        | DTYPE
2497                { $$ = TypeDecl::Dtype; }
2498        | FTYPE
2499                { $$ = TypeDecl::Ftype; }
2500        | TTYPE
2501                { $$ = TypeDecl::Ttype; }
2502        ;
2503
2504assertion_list_opt:                                                                             // CFA
2505        // empty
2506                { $$ = nullptr; }
2507        | assertion_list
2508        ;
2509
2510assertion_list:                                                                                 // CFA
2511        assertion
2512        | assertion_list assertion
2513                { $$ = $1->appendList( $2 ); }
2514        ;
2515
2516assertion:                                                                                              // CFA
2517        '|' identifier_or_type_name '(' type_list ')'
2518                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2519        | '|' '{' push trait_declaration_list pop '}'
2520                { $$ = $4; }
2521        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2522        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2523        ;
2524
2525type_list:                                                                                              // CFA
2526        type
2527                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2528        | assignment_expression
2529                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2530        | type_list ',' type
2531                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2532        | type_list ',' assignment_expression
2533                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2534                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2535        ;
2536
2537type_declaring_list:                                                                    // CFA
2538        OTYPE type_declarator
2539                { $$ = $2; }
2540        | storage_class_list OTYPE type_declarator
2541                { $$ = $3->addQualifiers( $1 ); }
2542        | type_declaring_list ',' type_declarator
2543                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2544        ;
2545
2546type_declarator:                                                                                // CFA
2547        type_declarator_name assertion_list_opt
2548                { $$ = $1->addAssertions( $2 ); }
2549        | type_declarator_name assertion_list_opt '=' type
2550                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2551        ;
2552
2553type_declarator_name:                                                                   // CFA
2554        identifier_or_type_name
2555                {
2556                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2557                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2558                }
2559        | identifier_or_type_name '(' type_parameter_list ')'
2560                {
2561                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2562                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2563                }
2564        ;
2565
2566trait_specifier:                                                                                // CFA
2567        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2568                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2569        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2570                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2571        ;
2572
2573trait_declaration_list:                                                                 // CFA
2574        trait_declaration
2575        | trait_declaration_list pop push trait_declaration
2576                { $$ = $1->appendList( $4 ); }
2577        ;
2578
2579trait_declaration:                                                                              // CFA
2580        cfa_trait_declaring_list ';'
2581        | trait_declaring_list ';'
2582        ;
2583
2584cfa_trait_declaring_list:                                                               // CFA
2585        cfa_variable_specifier
2586        | cfa_function_specifier
2587        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2588                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2589        ;
2590
2591trait_declaring_list:                                                                   // CFA
2592        type_specifier declarator
2593                { $$ = $2->addType( $1 ); }
2594        | trait_declaring_list pop ',' push declarator
2595                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2596        ;
2597
2598//***************************** EXTERNAL DEFINITIONS *****************************
2599
2600translation_unit:
2601        // empty, input file
2602        | external_definition_list
2603                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2604        ;
2605
2606external_definition_list:
2607        push external_definition pop
2608                { $$ = $2; }
2609        | external_definition_list push external_definition pop
2610                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2611        ;
2612
2613external_definition_list_opt:
2614        // empty
2615                { $$ = nullptr; }
2616        | external_definition_list
2617        ;
2618
2619up:
2620                { typedefTable.up( forall ); forall = false; }
2621        ;
2622
2623down:
2624                { typedefTable.down(); }
2625        ;
2626
2627external_definition:
2628        declaration
2629        | external_function_definition
2630        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2631                {
2632                        distExt( $2 );                                                          // mark all fields in list
2633                        $$ = $2;
2634                }
2635        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2636                {
2637                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2638                }
2639        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2640                {
2641                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2642                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2643                }
2644          '{' up external_definition_list_opt down '}'
2645                {
2646                        linkage = linkageStack.top();
2647                        linkageStack.pop();
2648                        $$ = $6;
2649                }
2650        | type_qualifier_list
2651                {
2652                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2653                        if ( $1->type->forall ) forall = true;          // remember generic type
2654                }
2655          '{' up external_definition_list_opt down '}'          // CFA, namespace
2656                {
2657                        distQual( $5, $1 );
2658                        forall = false;
2659                        $$ = $5;
2660                }
2661        | declaration_qualifier_list
2662                {
2663                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2664                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2665                }
2666          '{' up external_definition_list_opt down '}'          // CFA, namespace
2667                {
2668                        distQual( $5, $1 );
2669                        forall = false;
2670                        $$ = $5;
2671                }
2672        | declaration_qualifier_list type_qualifier_list
2673                {
2674                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2675                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2676                }
2677          '{' up external_definition_list_opt down '}'          // CFA, namespace
2678                {
2679                        distQual( $6, $1->addQualifiers( $2 ) );
2680                        forall = false;
2681                        $$ = $6;
2682                }
2683        ;
2684
2685external_function_definition:
2686        function_definition
2687                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2688                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2689                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2690                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2691                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2692        | function_declarator compound_statement
2693                { $$ = $1->addFunctionBody( $2 ); }
2694        | KR_function_declarator KR_parameter_list_opt compound_statement
2695                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2696        ;
2697
2698with_clause_opt:
2699        // empty
2700                { $$ = nullptr; forall = false; }
2701        | WITH '(' tuple_expression_list ')'
2702                { $$ = $3; forall = false; }
2703        ;
2704
2705function_definition:
2706        cfa_function_declaration with_clause_opt compound_statement     // CFA
2707                {
2708                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2709                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2710                        $1->get_last()->addFunctionBody( $3, $2 );
2711                        $$ = $1;
2712                }
2713        | declaration_specifier function_declarator with_clause_opt compound_statement
2714                {
2715                        rebindForall( $1, $2 );
2716                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2717                }
2718        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2719                {
2720                        rebindForall( $1, $2 );
2721                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2722                }
2723                // handles default int return type, OBSOLESCENT (see 1)
2724        | type_qualifier_list function_declarator with_clause_opt compound_statement
2725                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2726                // handles default int return type, OBSOLESCENT (see 1)
2727        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2728                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2729                // handles default int return type, OBSOLESCENT (see 1)
2730        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2731                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2732
2733                // Old-style K&R function definition, OBSOLESCENT (see 4)
2734        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2735                {
2736                        rebindForall( $1, $2 );
2737                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2738                }
2739                // handles default int return type, OBSOLESCENT (see 1)
2740        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2741                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2742                // handles default int return type, OBSOLESCENT (see 1)
2743        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2744                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2745                // handles default int return type, OBSOLESCENT (see 1)
2746        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2747                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2748        ;
2749
2750declarator:
2751        variable_declarator
2752        | variable_type_redeclarator
2753        | function_declarator
2754        ;
2755
2756subrange:
2757        constant_expression '~' constant_expression                     // CFA, integer subrange
2758                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
2759        ;
2760
2761asm_name_opt:                                                                                   // GCC
2762        // empty
2763                { $$ = nullptr; }
2764        | ASM '(' string_literal ')' attribute_list_opt
2765                {
2766                        DeclarationNode * name = new DeclarationNode();
2767                        name->asmName = $3;
2768                        $$ = name->addQualifiers( $5 );
2769                }
2770        ;
2771
2772attribute_list_opt:                                                                             // GCC
2773        // empty
2774                { $$ = nullptr; }
2775        | attribute_list
2776        ;
2777
2778attribute_list:                                                                                 // GCC
2779        attribute
2780        | attribute_list attribute
2781                { $$ = $2->addQualifiers( $1 ); }
2782        ;
2783
2784attribute_opt:
2785        // empty
2786                { $$ = nullptr; }
2787        | attribute
2788        ;
2789
2790attribute:                                                                                              // GCC
2791        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2792                { $$ = $4; }
2793        ;
2794
2795attribute_name_list:                                                                    // GCC
2796        attribute_name
2797        | attribute_name_list ',' attribute_name
2798                { $$ = $3->addQualifiers( $1 ); }
2799        ;
2800
2801attribute_name:                                                                                 // GCC
2802        // empty
2803                { $$ = nullptr; }
2804        | attr_name
2805                { $$ = DeclarationNode::newAttribute( $1 ); }
2806        | attr_name '(' argument_expression_list_opt ')'
2807                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2808        ;
2809
2810attr_name:                                                                                              // GCC
2811        IDENTIFIER
2812        | quasi_keyword
2813        | TYPEDEFname
2814        | TYPEGENname
2815        | FALLTHROUGH
2816                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2817        | CONST
2818                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2819        ;
2820
2821// ============================================================================
2822// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2823// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2824// in:
2825//
2826//              int (*f())[10] { ... };
2827//              ... (*f())[3] += 1;             // definition mimics usage
2828//
2829// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2830// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2831// ============================================================================
2832
2833// ----------------------------------------------------------------------------
2834// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2835// to define a variable or function prototype, e.g.:
2836//
2837//              valid declaration               invalid definition
2838//              -----------------               ------------------
2839//              int f;                                  int f {}
2840//              int *f;                                 int *f {}
2841//              int f[10];                              int f[10] {}
2842//              int (*f)(int);                  int (*f)(int) {}
2843//
2844// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2845// variable_declarator and function_declarator.
2846// ----------------------------------------------------------------------------
2847
2848// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2849// declaring an array of functions versus a pointer to an array of functions.
2850
2851variable_declarator:
2852        paren_identifier attribute_list_opt
2853                { $$ = $1->addQualifiers( $2 ); }
2854        | variable_ptr
2855        | variable_array attribute_list_opt
2856                { $$ = $1->addQualifiers( $2 ); }
2857        | variable_function attribute_list_opt
2858                { $$ = $1->addQualifiers( $2 ); }
2859        ;
2860
2861paren_identifier:
2862        identifier
2863                { $$ = DeclarationNode::newName( $1 ); }
2864        | '(' paren_identifier ')'                                                      // redundant parenthesis
2865                { $$ = $2; }
2866        ;
2867
2868variable_ptr:
2869        ptrref_operator variable_declarator
2870                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2871        | ptrref_operator type_qualifier_list variable_declarator
2872                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2873        | '(' variable_ptr ')' attribute_list_opt
2874                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2875        ;
2876
2877variable_array:
2878        paren_identifier array_dimension
2879                { $$ = $1->addArray( $2 ); }
2880        | '(' variable_ptr ')' array_dimension
2881                { $$ = $2->addArray( $4 ); }
2882        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2883                { $$ = $2->addArray( $4 ); }
2884        | '(' variable_array ')'                                                        // redundant parenthesis
2885                { $$ = $2; }
2886        ;
2887
2888variable_function:
2889        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2890                { $$ = $2->addParamList( $6 ); }
2891        | '(' variable_function ')'                                                     // redundant parenthesis
2892                { $$ = $2; }
2893        ;
2894
2895// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2896// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2897// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2898
2899function_declarator:
2900        function_no_ptr attribute_list_opt
2901                { $$ = $1->addQualifiers( $2 ); }
2902        | function_ptr
2903        | function_array attribute_list_opt
2904                { $$ = $1->addQualifiers( $2 ); }
2905        ;
2906
2907function_no_ptr:
2908        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2909                { $$ = $1->addParamList( $4 ); }
2910        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2911                { $$ = $2->addParamList( $6 ); }
2912        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2913                { $$ = $2; }
2914        ;
2915
2916function_ptr:
2917        ptrref_operator function_declarator
2918                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2919        | ptrref_operator type_qualifier_list function_declarator
2920                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2921        | '(' function_ptr ')'
2922                { $$ = $2; }
2923        ;
2924
2925function_array:
2926        '(' function_ptr ')' array_dimension
2927                { $$ = $2->addArray( $4 ); }
2928        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2929                { $$ = $2->addArray( $4 ); }
2930        | '(' function_array ')'                                                        // redundant parenthesis
2931                { $$ = $2; }
2932        ;
2933
2934// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2935//
2936//   f( a, b, c ) int a, *b, c[]; {}
2937//
2938// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2939// returning arrays and functions versus pointers to arrays and functions.
2940
2941KR_function_declarator:
2942        KR_function_no_ptr
2943        | KR_function_ptr
2944        | KR_function_array
2945        ;
2946
2947KR_function_no_ptr:
2948        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2949                { $$ = $1->addIdList( $3 ); }
2950        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2951                { $$ = $2->addParamList( $6 ); }
2952        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2953                { $$ = $2; }
2954        ;
2955
2956KR_function_ptr:
2957        ptrref_operator KR_function_declarator
2958                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2959        | ptrref_operator type_qualifier_list KR_function_declarator
2960                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2961        | '(' KR_function_ptr ')'
2962                { $$ = $2; }
2963        ;
2964
2965KR_function_array:
2966        '(' KR_function_ptr ')' array_dimension
2967                { $$ = $2->addArray( $4 ); }
2968        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2969                { $$ = $2->addArray( $4 ); }
2970        | '(' KR_function_array ')'                                                     // redundant parenthesis
2971                { $$ = $2; }
2972        ;
2973
2974// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2975//
2976//              typedef int foo;
2977//              {
2978//                 int foo; // redefine typedef name in new scope
2979//              }
2980//
2981// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2982// and functions versus pointers to arrays and functions.
2983
2984variable_type_redeclarator:
2985        paren_type attribute_list_opt
2986                { $$ = $1->addQualifiers( $2 ); }
2987        | type_ptr
2988        | type_array attribute_list_opt
2989                { $$ = $1->addQualifiers( $2 ); }
2990        | type_function attribute_list_opt
2991                { $$ = $1->addQualifiers( $2 ); }
2992        ;
2993
2994paren_type:
2995        typedef
2996                // hide type name in enclosing scope by variable name
2997                {
2998                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2999                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3000                        // } else {
3001                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
3002                        // } // if
3003                }
3004        | '(' paren_type ')'
3005                { $$ = $2; }
3006        ;
3007
3008type_ptr:
3009        ptrref_operator variable_type_redeclarator
3010                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3011        | ptrref_operator type_qualifier_list variable_type_redeclarator
3012                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3013        | '(' type_ptr ')' attribute_list_opt
3014                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
3015        ;
3016
3017type_array:
3018        paren_type array_dimension
3019                { $$ = $1->addArray( $2 ); }
3020        | '(' type_ptr ')' array_dimension
3021                { $$ = $2->addArray( $4 ); }
3022        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
3023                { $$ = $2->addArray( $4 ); }
3024        | '(' type_array ')'                                                            // redundant parenthesis
3025                { $$ = $2; }
3026        ;
3027
3028type_function:
3029        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3030                { $$ = $1->addParamList( $4 ); }
3031        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3032                { $$ = $2->addParamList( $6 ); }
3033        | '(' type_function ')'                                                         // redundant parenthesis
3034                { $$ = $2; }
3035        ;
3036
3037// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3038// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
3039// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3040// pointers to arrays and functions.
3041
3042identifier_parameter_declarator:
3043        paren_identifier attribute_list_opt
3044                { $$ = $1->addQualifiers( $2 ); }
3045        | '&' MUTEX paren_identifier attribute_list_opt
3046                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3047        | identifier_parameter_ptr
3048        | identifier_parameter_array attribute_list_opt
3049                { $$ = $1->addQualifiers( $2 ); }
3050        | identifier_parameter_function attribute_list_opt
3051                { $$ = $1->addQualifiers( $2 ); }
3052        ;
3053
3054identifier_parameter_ptr:
3055        ptrref_operator identifier_parameter_declarator
3056                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3057        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3058                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3059        | '(' identifier_parameter_ptr ')' attribute_list_opt
3060                { $$ = $2->addQualifiers( $4 ); }
3061        ;
3062
3063identifier_parameter_array:
3064        paren_identifier array_parameter_dimension
3065                { $$ = $1->addArray( $2 ); }
3066        | '(' identifier_parameter_ptr ')' array_dimension
3067                { $$ = $2->addArray( $4 ); }
3068        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3069                { $$ = $2->addArray( $4 ); }
3070        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3071                { $$ = $2; }
3072        ;
3073
3074identifier_parameter_function:
3075        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3076                { $$ = $1->addParamList( $4 ); }
3077        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3078                { $$ = $2->addParamList( $6 ); }
3079        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3080                { $$ = $2; }
3081        ;
3082
3083// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3084// e.g.:
3085//
3086//              typedef int foo;
3087//              forall( otype T ) struct foo;
3088//              int f( int foo ); // redefine typedef name in new scope
3089//
3090// and allows the C99 array options, which can only appear in a parameter list.
3091
3092type_parameter_redeclarator:
3093        typedef attribute_list_opt
3094                { $$ = $1->addQualifiers( $2 ); }
3095        | '&' MUTEX typedef attribute_list_opt
3096                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3097        | type_parameter_ptr
3098        | type_parameter_array attribute_list_opt
3099                { $$ = $1->addQualifiers( $2 ); }
3100        | type_parameter_function attribute_list_opt
3101                { $$ = $1->addQualifiers( $2 ); }
3102        ;
3103
3104typedef:
3105        TYPEDEFname
3106                { $$ = DeclarationNode::newName( $1 ); }
3107        | TYPEGENname
3108                { $$ = DeclarationNode::newName( $1 ); }
3109        ;
3110
3111type_parameter_ptr:
3112        ptrref_operator type_parameter_redeclarator
3113                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3114        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3115                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3116        | '(' type_parameter_ptr ')' attribute_list_opt
3117                { $$ = $2->addQualifiers( $4 ); }
3118        ;
3119
3120type_parameter_array:
3121        typedef array_parameter_dimension
3122                { $$ = $1->addArray( $2 ); }
3123        | '(' type_parameter_ptr ')' array_parameter_dimension
3124                { $$ = $2->addArray( $4 ); }
3125        ;
3126
3127type_parameter_function:
3128        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3129                { $$ = $1->addParamList( $4 ); }
3130        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3131                { $$ = $2->addParamList( $6 ); }
3132        ;
3133
3134// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3135// which the type applies, e.g.:
3136//
3137//              sizeof( int );
3138//              sizeof( int * );
3139//              sizeof( int [10] );
3140//              sizeof( int (*)() );
3141//              sizeof( int () );
3142//
3143// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3144// and functions versus pointers to arrays and functions.
3145
3146abstract_declarator:
3147        abstract_ptr
3148        | abstract_array attribute_list_opt
3149                { $$ = $1->addQualifiers( $2 ); }
3150        | abstract_function attribute_list_opt
3151                { $$ = $1->addQualifiers( $2 ); }
3152        ;
3153
3154abstract_ptr:
3155        ptrref_operator
3156                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3157        | ptrref_operator type_qualifier_list
3158                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3159        | ptrref_operator abstract_declarator
3160                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3161        | ptrref_operator type_qualifier_list abstract_declarator
3162                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3163        | '(' abstract_ptr ')' attribute_list_opt
3164                { $$ = $2->addQualifiers( $4 ); }
3165        ;
3166
3167abstract_array:
3168        array_dimension
3169        | '(' abstract_ptr ')' array_dimension
3170                { $$ = $2->addArray( $4 ); }
3171        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3172                { $$ = $2->addArray( $4 ); }
3173        | '(' abstract_array ')'                                                        // redundant parenthesis
3174                { $$ = $2; }
3175        ;
3176
3177abstract_function:
3178        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3179                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3180        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3181                { $$ = $2->addParamList( $6 ); }
3182        | '(' abstract_function ')'                                                     // redundant parenthesis
3183                { $$ = $2; }
3184        ;
3185
3186array_dimension:
3187                // Only the first dimension can be empty.
3188        '[' ']'
3189                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3190        | '[' ']' multi_array_dimension
3191                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3192        | '[' push assignment_expression pop ',' comma_expression ']'
3193                { $$ = DeclarationNode::newArray( $3, 0, false )->addArray( DeclarationNode::newArray( $6, 0, false ) ); }
3194                // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3195        | multi_array_dimension
3196        ;
3197
3198multi_array_dimension:
3199        '[' push assignment_expression pop ']'
3200                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3201        | '[' push '*' pop ']'                                                          // C99
3202                { $$ = DeclarationNode::newVarArray( 0 ); }
3203        | multi_array_dimension '[' push assignment_expression pop ']'
3204                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3205        | multi_array_dimension '[' push '*' pop ']'            // C99
3206                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3207        ;
3208
3209// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3210// identifier to which the type applies, e.g.:
3211//
3212//              int f( int );                   // not handled here
3213//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3214//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3215//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3216//
3217// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3218// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3219// special meaning of parenthesis around a typedef name:
3220//
3221//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3222//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3223//              not as redundant parentheses around the identifier."
3224//
3225// For example:
3226//
3227//              typedef float T;
3228//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3229//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3230//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3231//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3232//
3233// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3234// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3235// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3236// functions.
3237
3238abstract_parameter_declarator:
3239        abstract_parameter_ptr
3240        | '&' MUTEX attribute_list_opt
3241                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3242        | abstract_parameter_array attribute_list_opt
3243                { $$ = $1->addQualifiers( $2 ); }
3244        | abstract_parameter_function attribute_list_opt
3245                { $$ = $1->addQualifiers( $2 ); }
3246        ;
3247
3248abstract_parameter_ptr:
3249        ptrref_operator
3250                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3251        | ptrref_operator type_qualifier_list
3252                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3253        | ptrref_operator abstract_parameter_declarator
3254                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3255        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3256                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3257        | '(' abstract_parameter_ptr ')' attribute_list_opt
3258                { $$ = $2->addQualifiers( $4 ); }
3259        ;
3260
3261abstract_parameter_array:
3262        array_parameter_dimension
3263        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3264                { $$ = $2->addArray( $4 ); }
3265        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3266                { $$ = $2->addArray( $4 ); }
3267        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3268                { $$ = $2; }
3269        ;
3270
3271abstract_parameter_function:
3272        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3273                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3274        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3275                { $$ = $2->addParamList( $6 ); }
3276        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3277                { $$ = $2; }
3278        ;
3279
3280array_parameter_dimension:
3281                // Only the first dimension can be empty or have qualifiers.
3282        array_parameter_1st_dimension
3283        | array_parameter_1st_dimension multi_array_dimension
3284                { $$ = $1->addArray( $2 ); }
3285        | multi_array_dimension
3286        ;
3287
3288// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3289//
3290//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3291//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3292
3293array_parameter_1st_dimension:
3294        '[' ']'
3295                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3296                // multi_array_dimension handles the '[' '*' ']' case
3297        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3298                { $$ = DeclarationNode::newVarArray( $3 ); }
3299        | '[' push type_qualifier_list pop ']'
3300                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3301                // multi_array_dimension handles the '[' assignment_expression ']' case
3302        | '[' push type_qualifier_list assignment_expression pop ']'
3303                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3304        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3305                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3306        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3307                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3308        ;
3309
3310// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3311//
3312//              struct S {
3313//          int;
3314//          int *;
3315//          int [10];
3316//          int (*)();
3317//      };
3318
3319variable_abstract_declarator:
3320        variable_abstract_ptr
3321        | variable_abstract_array attribute_list_opt
3322                { $$ = $1->addQualifiers( $2 ); }
3323        | variable_abstract_function attribute_list_opt
3324                { $$ = $1->addQualifiers( $2 ); }
3325        ;
3326
3327variable_abstract_ptr:
3328        ptrref_operator
3329                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3330        | ptrref_operator type_qualifier_list
3331                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3332        | ptrref_operator variable_abstract_declarator
3333                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3334        | ptrref_operator type_qualifier_list variable_abstract_declarator
3335                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3336        | '(' variable_abstract_ptr ')' attribute_list_opt
3337                { $$ = $2->addQualifiers( $4 ); }
3338        ;
3339
3340variable_abstract_array:
3341        array_dimension
3342        | '(' variable_abstract_ptr ')' array_dimension
3343                { $$ = $2->addArray( $4 ); }
3344        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3345                { $$ = $2->addArray( $4 ); }
3346        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3347                { $$ = $2; }
3348        ;
3349
3350variable_abstract_function:
3351        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3352                { $$ = $2->addParamList( $6 ); }
3353        | '(' variable_abstract_function ')'                            // redundant parenthesis
3354                { $$ = $2; }
3355        ;
3356
3357// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3358// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3359
3360cfa_identifier_parameter_declarator_tuple:                              // CFA
3361        cfa_identifier_parameter_declarator_no_tuple
3362        | cfa_abstract_tuple
3363        | type_qualifier_list cfa_abstract_tuple
3364                { $$ = $2->addQualifiers( $1 ); }
3365        ;
3366
3367cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3368        cfa_identifier_parameter_ptr
3369        | cfa_identifier_parameter_array
3370        ;
3371
3372cfa_identifier_parameter_ptr:                                                   // CFA
3373                // No SUE declaration in parameter list.
3374        ptrref_operator type_specifier_nobody
3375                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3376        | type_qualifier_list ptrref_operator type_specifier_nobody
3377                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3378        | ptrref_operator cfa_abstract_function
3379                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3380        | type_qualifier_list ptrref_operator cfa_abstract_function
3381                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3382        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3383                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3384        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3385                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3386        ;
3387
3388cfa_identifier_parameter_array:                                                 // CFA
3389                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3390                // shift/reduce conflict with new-style empty (void) function return type.
3391        '[' ']' type_specifier_nobody
3392                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3393        | cfa_array_parameter_1st_dimension type_specifier_nobody
3394                { $$ = $2->addNewArray( $1 ); }
3395        | '[' ']' multi_array_dimension type_specifier_nobody
3396                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3397        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3398                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3399        | multi_array_dimension type_specifier_nobody
3400                { $$ = $2->addNewArray( $1 ); }
3401
3402        | '[' ']' cfa_identifier_parameter_ptr
3403                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3404        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3405                { $$ = $2->addNewArray( $1 ); }
3406        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3407                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3408        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3409                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3410        | multi_array_dimension cfa_identifier_parameter_ptr
3411                { $$ = $2->addNewArray( $1 ); }
3412        ;
3413
3414cfa_array_parameter_1st_dimension:
3415        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3416                { $$ = DeclarationNode::newVarArray( $3 ); }
3417        | '[' push type_qualifier_list assignment_expression pop ']'
3418                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3419        | '[' push declaration_qualifier_list assignment_expression pop ']'
3420                // declaration_qualifier_list must be used because of shift/reduce conflict with
3421                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3422                // appear in this context.
3423                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3424        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3425                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3426        ;
3427
3428// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3429// identifier to which the type applies, e.g.:
3430//
3431//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3432//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3433//
3434// These rules need LR(3):
3435//
3436//              cfa_abstract_tuple identifier_or_type_name
3437//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3438//
3439// since a function return type can be syntactically identical to a tuple type:
3440//
3441//              [int, int] t;
3442//              [int, int] f( int );
3443//
3444// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3445// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3446// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3447// duplicated when appearing with cfa_function_specifier.
3448
3449cfa_abstract_declarator_tuple:                                                  // CFA
3450        cfa_abstract_tuple
3451        | type_qualifier_list cfa_abstract_tuple
3452                { $$ = $2->addQualifiers( $1 ); }
3453        | cfa_abstract_declarator_no_tuple
3454        ;
3455
3456cfa_abstract_declarator_no_tuple:                                               // CFA
3457        cfa_abstract_ptr
3458        | cfa_abstract_array
3459        ;
3460
3461cfa_abstract_ptr:                                                                               // CFA
3462        ptrref_operator type_specifier
3463                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3464        | type_qualifier_list ptrref_operator type_specifier
3465                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3466        | ptrref_operator cfa_abstract_function
3467                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3468        | type_qualifier_list ptrref_operator cfa_abstract_function
3469                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3470        | ptrref_operator cfa_abstract_declarator_tuple
3471                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3472        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3473                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3474        ;
3475
3476cfa_abstract_array:                                                                             // CFA
3477                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3478                // empty (void) function return type.
3479        '[' ']' type_specifier
3480                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3481        | '[' ']' multi_array_dimension type_specifier
3482                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3483        | multi_array_dimension type_specifier
3484                { $$ = $2->addNewArray( $1 ); }
3485        | '[' ']' cfa_abstract_ptr
3486                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3487        | '[' ']' multi_array_dimension cfa_abstract_ptr
3488                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3489        | multi_array_dimension cfa_abstract_ptr
3490                { $$ = $2->addNewArray( $1 ); }
3491        ;
3492
3493cfa_abstract_tuple:                                                                             // CFA
3494        '[' push cfa_abstract_parameter_list pop ']'
3495                { $$ = DeclarationNode::newTuple( $3 ); }
3496        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3497                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3498        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3499                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3500        ;
3501
3502cfa_abstract_function:                                                                  // CFA
3503//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3504//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3505        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3506                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3507        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3508                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3509        ;
3510
3511// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3512//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3513//
3514// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3515//    the declaration specifiers in a declaration is an obsolescent feature."
3516//
3517// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3518//    prototype-format parameter type declarators) is an obsolescent feature."
3519//
3520// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3521//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3522
3523//************************* MISCELLANEOUS ********************************
3524
3525comma_opt:                                                                                              // redundant comma
3526        // empty
3527        | ','
3528        ;
3529
3530default_initializer_opt:
3531        // empty
3532                { $$ = nullptr; }
3533        | '=' assignment_expression
3534                { $$ = $2; }
3535        ;
3536
3537%%
3538
3539// ----end of grammar----
3540
3541// Local Variables: //
3542// mode: c++ //
3543// tab-width: 4 //
3544// compile-command: "make install" //
3545// End: //
Note: See TracBrowser for help on using the repository browser.