source: src/Parser/parser.yy @ 665f432

arm-ehjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-expr
Last change on this file since 665f432 was 665f432, checked in by Thierry Delisle <tdelisle@…>, 2 years ago

Fixed trac #149 where operand names in asm statements where incorrectly resolved (i.e., should not have been resolved)

  • Property mode set to 100644
File size: 135.1 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sun Aug  4 21:48:23 2019
13// Update Count     : 4364
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
102                cl->cloneBaseType( cur );
103        } // for
104        declList->addType( cl );
105        return declList;
106} // distAttr
107
108void distExt( DeclarationNode * declaration ) {
109        // distribute EXTENSION across all declarations
110        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
111                iter->set_extension( true );
112        } // for
113} // distExt
114
115void distInl( DeclarationNode * declaration ) {
116        // distribute EXTENSION across all declarations
117        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
118                iter->set_inLine( true );
119        } // for
120} // distInl
121
122void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
123        // distribute qualifiers across all non-variable declarations in a distribution statemement
124        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
125                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
126                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
127                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
128                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
129                DeclarationNode * clone = qualifiers->clone();
130                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
131                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
132                                swap( clone->type->forall, iter->type->aggregate.params );
133                                iter->addQualifiers( clone );
134                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
135                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
136                                DeclarationNode newnode;
137                                swap( newnode.type, iter->type->aggInst.aggregate );
138                                swap( clone->type->forall, newnode.type->aggregate.params );
139                                newnode.addQualifiers( clone );
140                                swap( newnode.type, iter->type->aggInst.aggregate );
141                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
142                                swap( clone->type->forall, iter->type->forall );
143                                iter->addQualifiers( clone );
144                        } // if
145                } else {                                                                                // just SC qualifiers
146                        iter->addQualifiers( clone );
147                } // if
148        } // for
149        delete qualifiers;
150} // distQual
151
152// There is an ambiguity for inline generic-routine return-types and generic routines.
153//   forall( otype T ) struct S { int i; } bar( T ) {}
154// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
155//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
156// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
157//   forall( otype T ) struct S { int T; };
158//   forall( otype W ) bar( W ) {}
159
160void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
161        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
162                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
163                declSpec->type->aggregate.params = nullptr;
164        } // if
165} // rebindForall
166
167NameExpr * build_postfix_name( const string * name ) {
168        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
169        delete name;
170        return new_name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210        } // if
211} // forCtrl
212
213
214bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
215
216// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
217#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
218if ( N ) {                                                                                                                                              \
219        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
220        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
221        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
222        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
223        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
224} else {                                                                                                                                                \
225        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
226        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
227        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
228}
229%}
230
231%define parse.error verbose
232
233// Types declaration for productions
234%union {
235        Token tok;
236        ParseNode * pn;
237        ExpressionNode * en;
238        DeclarationNode * decl;
239        DeclarationNode::Aggregate aggKey;
240        DeclarationNode::TypeClass tclass;
241        StatementNode * sn;
242        WaitForStmt * wfs;
243        Expression * constant;
244        IfCtrl * ifctl;
245        ForCtrl * fctl;
246        enum OperKinds compop;
247        LabelNode * label;
248        InitializerNode * in;
249        OperKinds op;
250        std::string * str;
251        bool flag;
252        CatchStmt::Kind catch_kind;
253        GenericExpr * genexpr;
254}
255
256//************************* TERMINAL TOKENS ********************************
257
258// keywords
259%token TYPEDEF
260%token EXTERN STATIC AUTO REGISTER
261%token THREADLOCAL                                                                              // C11
262%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
263%token NORETURN                                                                                 // C11
264%token CONST VOLATILE
265%token RESTRICT                                                                                 // C99
266%token ATOMIC                                                                                   // C11
267%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
268%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
269%token BOOL COMPLEX IMAGINARY                                                   // C99
270%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
271%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
272%token ZERO_T ONE_T                                                                             // CFA
273%token VALIST                                                                                   // GCC
274%token AUTO_TYPE                                                                                // GCC
275%token TYPEOF BASETYPEOF LABEL                                                  // GCC
276%token ENUM STRUCT UNION
277%token EXCEPTION                                                                                // CFA
278%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
279%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
280%token SIZEOF OFFSETOF
281// %token SUSPEND RESUME                                                                        // CFA
282%token ATTRIBUTE EXTENSION                                                              // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
290%token<tok> TIMEOUT                             WOR
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list              argument_expression                     default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en>   bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581        | constant '`' IDENTIFIER                                                       // CFA, postfix call
582                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
583        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
584                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
585        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
586                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
587        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
588                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
589        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
590                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
591        | type_name '.' identifier                                                      // CFA, nested type
592                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
593        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
594                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
595        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
596                {
597                        // add the missing control expression to the GenericExpr and return it
598                        $5->control = maybeMoveBuild<Expression>( $3 );
599                        $$ = new ExpressionNode( $5 );
600                }
601        // | RESUME '(' comma_expression ')'
602        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
603        // | RESUME '(' comma_expression ')' compound_statement
604        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
605        ;
606
607generic_assoc_list:                                                                             // C11
608        generic_association
609        | generic_assoc_list ',' generic_association
610                {
611                        // steal the association node from the singleton and delete the wrapper
612                        $1->associations.splice($1->associations.end(), $3->associations);
613                        delete $3;
614                        $$ = $1;
615                }
616        ;
617
618generic_association:                                                                    // C11
619        type_no_function ':' assignment_expression
620                {
621                        // create a GenericExpr wrapper with one association pair
622                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
623                }
624        | DEFAULT ':' assignment_expression
625                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
626        ;
627
628postfix_expression:
629        primary_expression
630        | postfix_expression '[' assignment_expression ']'
631                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
632                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
633                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
634                // equivalent to the old x[i,j].
635                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
636        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
637                {
638                        Token fn;
639                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
640                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
641                }
642        | postfix_expression '(' argument_expression_list ')'
643                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
644        | postfix_expression '.' identifier
645                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
646        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
647                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
648        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
649                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
650        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
651                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
652        | postfix_expression ARROW identifier
653                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
654        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
655                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
656        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
657                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
658        | postfix_expression ICR
659                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
660        | postfix_expression DECR
661                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
662        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
663                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
664        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
665                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
666        | '^' primary_expression '{' argument_expression_list '}' // CFA
667                {
668                        Token fn;
669                        fn.str = new string( "^?{}" );                          // location undefined
670                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
671                }
672        ;
673
674argument_expression_list:
675        // empty
676                { $$ = nullptr; }
677        | argument_expression
678        | argument_expression_list ',' argument_expression
679                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
680        ;
681
682argument_expression:
683        '@'                                                                                                     // CFA, default parameter
684                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
685                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
686        | assignment_expression
687        ;
688
689field_name_list:                                                                                // CFA, tuple field selector
690        field
691        | field_name_list ',' field                                     { $$ = (ExpressionNode *)$1->set_last( $3 ); }
692        ;
693
694field:                                                                                                  // CFA, tuple field selector
695        field_name
696        | FLOATING_DECIMALconstant field
697                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
698        | FLOATING_DECIMALconstant '[' field_name_list ']'
699                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
700        | field_name '.' field
701                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
702        | field_name '.' '[' field_name_list ']'
703                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
704        | field_name ARROW field
705                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
706        | field_name ARROW '[' field_name_list ']'
707                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
708        ;
709
710field_name:
711        INTEGERconstant fraction_constants_opt
712                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
713        | FLOATINGconstant fraction_constants_opt
714                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
715        | identifier fraction_constants_opt
716                {
717                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
718                }
719        ;
720
721fraction_constants_opt:
722        // empty
723                { $$ = nullptr; }
724        | fraction_constants_opt FLOATING_FRACTIONconstant
725                {
726                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
727                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
728                }
729        ;
730
731unary_expression:
732        postfix_expression
733                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
734                // semantics checks, e.g., ++3, 3--, *3, &&3
735        | constant
736        | string_literal
737                { $$ = new ExpressionNode( $1 ); }
738        | EXTENSION cast_expression                                                     // GCC
739                { $$ = $2->set_extension( true ); }
740                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
741                //              { * X; }         // dereference X
742                //              { * int X; } // CFA declaration of pointer to int
743        | ptrref_operator cast_expression                                       // CFA
744                {
745                        switch ( $1 ) {
746                          case OperKinds::AddressOf:
747                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
748                                break;
749                          case OperKinds::PointTo:
750                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
751                                break;
752                          case OperKinds::And:
753                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
754                                break;
755                          default:
756                                assert( false );
757                        }
758                }
759        | unary_operator cast_expression
760                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
761        | ICR unary_expression
762                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
763        | DECR unary_expression
764                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
765        | SIZEOF unary_expression
766                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
767        | SIZEOF '(' type_no_function ')'
768                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
769        | ALIGNOF unary_expression                                                      // GCC, variable alignment
770                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
771        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
772                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
773        | OFFSETOF '(' type_no_function ',' identifier ')'
774                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
775        ;
776
777ptrref_operator:
778        '*'                                                                                     { $$ = OperKinds::PointTo; }
779        | '&'                                                                           { $$ = OperKinds::AddressOf; }
780                // GCC, address of label must be handled by semantic check for ref,ref,label
781        | ANDAND                                                                        { $$ = OperKinds::And; }
782        ;
783
784unary_operator:
785        '+'                                                                                     { $$ = OperKinds::UnPlus; }
786        | '-'                                                                           { $$ = OperKinds::UnMinus; }
787        | '!'                                                                           { $$ = OperKinds::Neg; }
788        | '~'                                                                           { $$ = OperKinds::BitNeg; }
789        ;
790
791cast_expression:
792        unary_expression
793        | '(' type_no_function ')' cast_expression
794                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
795                // keyword cast cannot be grouped because of reduction in aggregate_key
796        | '(' GENERATOR '&' ')' cast_expression                         // CFA
797                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
798        | '(' COROUTINE '&' ')' cast_expression                         // CFA
799                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
800        | '(' THREAD '&' ')' cast_expression                            // CFA
801                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
802        | '(' MONITOR '&' ')' cast_expression                           // CFA
803                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
804                // VIRTUAL cannot be opt because of look ahead issues
805        | '(' VIRTUAL ')' cast_expression                                       // CFA
806                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
807        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
808                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
809        | '(' RETURN type_no_function ')' cast_expression       // CFA
810                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
811        | '(' COERCE type_no_function ')' cast_expression       // CFA
812                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
813        | '(' qualifier_cast_list ')' cast_expression           // CFA
814                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
815//      | '(' type_no_function ')' tuple
816//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
817        ;
818
819qualifier_cast_list:
820        cast_modifier type_qualifier_name
821        | cast_modifier MUTEX
822        | qualifier_cast_list cast_modifier type_qualifier_name
823        | qualifier_cast_list cast_modifier MUTEX
824        ;
825
826cast_modifier:
827        '-'
828        | '+'
829        ;
830
831exponential_expression:
832        cast_expression
833        | exponential_expression '\\' cast_expression
834                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
835        ;
836
837multiplicative_expression:
838        exponential_expression
839        | multiplicative_expression '*' exponential_expression
840                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
841        | multiplicative_expression '/' exponential_expression
842                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
843        | multiplicative_expression '%' exponential_expression
844                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
845        ;
846
847additive_expression:
848        multiplicative_expression
849        | additive_expression '+' multiplicative_expression
850                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
851        | additive_expression '-' multiplicative_expression
852                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
853        ;
854
855shift_expression:
856        additive_expression
857        | shift_expression LS additive_expression
858                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
859        | shift_expression RS additive_expression
860                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
861        ;
862
863relational_expression:
864        shift_expression
865        | relational_expression '<' shift_expression
866                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
867        | relational_expression '>' shift_expression
868                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
869        | relational_expression LE shift_expression
870                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
871        | relational_expression GE shift_expression
872                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
873        ;
874
875equality_expression:
876        relational_expression
877        | equality_expression EQ relational_expression
878                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
879        | equality_expression NE relational_expression
880                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
881        ;
882
883AND_expression:
884        equality_expression
885        | AND_expression '&' equality_expression
886                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
887        ;
888
889exclusive_OR_expression:
890        AND_expression
891        | exclusive_OR_expression '^' AND_expression
892                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
893        ;
894
895inclusive_OR_expression:
896        exclusive_OR_expression
897        | inclusive_OR_expression '|' exclusive_OR_expression
898                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
899        ;
900
901logical_AND_expression:
902        inclusive_OR_expression
903        | logical_AND_expression ANDAND inclusive_OR_expression
904                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
905        ;
906
907logical_OR_expression:
908        logical_AND_expression
909        | logical_OR_expression OROR logical_AND_expression
910                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
911        ;
912
913conditional_expression:
914        logical_OR_expression
915        | logical_OR_expression '?' comma_expression ':' conditional_expression
916                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
917                // FIX ME: computes $1 twice
918        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
919                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
920        ;
921
922constant_expression:
923        conditional_expression
924        ;
925
926assignment_expression:
927                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
928        conditional_expression
929        | unary_expression assignment_operator assignment_expression
930                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
931        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
932                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
933        ;
934
935assignment_expression_opt:
936        // empty
937                { $$ = nullptr; }
938        | assignment_expression
939        ;
940
941assignment_operator:
942        '='                                                                                     { $$ = OperKinds::Assign; }
943        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
944        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
945        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
946        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
947        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
948        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
949        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
950        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
951        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
952        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
953        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
954        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
955        ;
956
957tuple:                                                                                                  // CFA, tuple
958                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
959                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
960//      '[' ']'
961//              { $$ = new ExpressionNode( build_tuple() ); }
962//      | '[' push assignment_expression pop ']'
963//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
964        '[' ',' tuple_expression_list ']'
965                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
966        | '[' push assignment_expression pop ',' tuple_expression_list ']'
967                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $6 ) ) ); }
968        ;
969
970tuple_expression_list:
971        assignment_expression_opt
972        | tuple_expression_list ',' assignment_expression_opt
973                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
974        ;
975
976comma_expression:
977        assignment_expression
978        | comma_expression ',' assignment_expression
979                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
980        ;
981
982comma_expression_opt:
983        // empty
984                { $$ = nullptr; }
985        | comma_expression
986        ;
987
988//*************************** STATEMENTS *******************************
989
990statement:
991        labeled_statement
992        | compound_statement
993        | expression_statement
994        | selection_statement
995        | iteration_statement
996        | jump_statement
997        | with_statement
998        | mutex_statement
999        | waitfor_statement
1000        | exception_statement
1001        | enable_disable_statement
1002                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1003        | asm_statement
1004        | DIRECTIVE
1005                { $$ = new StatementNode( build_directive( $1 ) ); }
1006        ;
1007
1008labeled_statement:
1009                // labels cannot be identifiers 0 or 1
1010        identifier_or_type_name ':' attribute_list_opt statement
1011                { $$ = $4->add_label( $1, $3 ); }
1012        ;
1013
1014compound_statement:
1015        '{' '}'
1016                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1017        | '{' push
1018          local_label_declaration_opt                                           // GCC, local labels
1019          statement_decl_list                                                           // C99, intermix declarations and statements
1020          pop '}'
1021                { $$ = new StatementNode( build_compound( $4 ) ); }
1022        ;
1023
1024statement_decl_list:                                                                    // C99
1025        statement_decl
1026        | statement_decl_list statement_decl
1027                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1028        ;
1029
1030statement_decl:
1031        declaration                                                                                     // CFA, new & old style declarations
1032                { $$ = new StatementNode( $1 ); }
1033        | EXTENSION declaration                                                         // GCC
1034                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1035        | function_definition
1036                { $$ = new StatementNode( $1 ); }
1037        | EXTENSION function_definition                                         // GCC
1038                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1039        | statement
1040        ;
1041
1042statement_list_nodecl:
1043        statement
1044        | statement_list_nodecl statement
1045                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1046        ;
1047
1048expression_statement:
1049        comma_expression_opt ';'
1050                { $$ = new StatementNode( build_expr( $1 ) ); }
1051        ;
1052
1053selection_statement:
1054                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1055                        // the inherent S/R conflict with THEN/ELSE.
1056        push if_statement pop
1057                { $$ = $2; }
1058        | SWITCH '(' comma_expression ')' case_clause
1059                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1060        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1061                {
1062                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1063                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1064                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1065                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1066                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1067                        // statement.
1068                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1069                }
1070        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1071                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1072        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1073                {
1074                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1075                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1076                }
1077        ;
1078
1079if_statement:
1080        IF '(' if_control_expression ')' statement                      %prec THEN
1081                // explicitly deal with the shift/reduce conflict on if/else
1082                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1083        | IF '(' if_control_expression ')' statement ELSE statement
1084                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1085        ;
1086
1087if_control_expression:
1088        comma_expression
1089                { $$ = new IfCtrl( nullptr, $1 ); }
1090        | c_declaration                                                                         // no semi-colon
1091                { $$ = new IfCtrl( $1, nullptr ); }
1092        | cfa_declaration                                                                       // no semi-colon
1093                { $$ = new IfCtrl( $1, nullptr ); }
1094        | declaration comma_expression                                          // semi-colon separated
1095                { $$ = new IfCtrl( $1, $2 ); }
1096        ;
1097
1098// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1099// clause allows a list of values and subranges.
1100
1101case_value:                                                                                             // CFA
1102        constant_expression                                                     { $$ = $1; }
1103        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1104                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1105        | subrange                                                                                      // CFA, subrange
1106        ;
1107
1108case_value_list:                                                                                // CFA
1109        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1110                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1111        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1112        ;
1113
1114case_label:                                                                                             // CFA
1115        CASE case_value_list ':'                                        { $$ = $2; }
1116        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1117                // A semantic check is required to ensure only one default clause per switch/choose statement.
1118        ;
1119
1120//label_list_opt:
1121//      // empty
1122//      | identifier_or_type_name ':'
1123//      | label_list_opt identifier_or_type_name ':'
1124//      ;
1125
1126case_label_list:                                                                                // CFA
1127        case_label
1128        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1129        ;
1130
1131case_clause:                                                                                    // CFA
1132        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1133        ;
1134
1135switch_clause_list_opt:                                                                 // CFA
1136        // empty
1137                { $$ = nullptr; }
1138        | switch_clause_list
1139        ;
1140
1141switch_clause_list:                                                                             // CFA
1142        case_label_list statement_list_nodecl
1143                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1144        | switch_clause_list case_label_list statement_list_nodecl
1145                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1146        ;
1147
1148iteration_statement:
1149        WHILE '(' push if_control_expression ')' statement pop
1150                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1151        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1152                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1153        | DO statement WHILE '(' comma_expression ')' ';'
1154                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1155        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1156                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1157        | FOR '(' push for_control_expression_list ')' statement pop
1158                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1159        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1160                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1161        ;
1162
1163for_control_expression_list:
1164        for_control_expression
1165        | for_control_expression_list ':' for_control_expression
1166                // ForCtrl + ForCtrl:
1167                //    init + init => multiple declaration statements that are hoisted
1168                //    condition + condition => (expression) && (expression)
1169                //    change + change => (expression), (expression)
1170                {
1171                        $1->init->set_last( $3->init );
1172                        if ( $1->condition ) {
1173                                if ( $3->condition ) {
1174                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1175                                } // if
1176                        } else $1->condition = $3->condition;
1177                        if ( $1->change ) {
1178                                if ( $3->change ) {
1179                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1180                                } // if
1181                        } else $1->change = $3->change;
1182                        $$ = $1;
1183                }
1184        ;
1185
1186for_control_expression:
1187        ';' comma_expression_opt ';' comma_expression_opt
1188                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1189        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1190                { $$ = new ForCtrl( $1, $3, $5 ); }
1191        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1192                { $$ = new ForCtrl( $1, $2, $4 ); }
1193
1194        | comma_expression                                                                      // CFA
1195                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1196                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1197        | comma_expression inclexcl comma_expression            // CFA
1198                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1199        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1200                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1201        | comma_expression ';' comma_expression                         // CFA
1202                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1203                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1204        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1205                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1206        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1207                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1208
1209                // There is a S/R conflicit if ~ and -~ are factored out.
1210        | comma_expression ';' comma_expression '~' '@'         // CFA
1211                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1212        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1213                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1214        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1215                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1216        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1217                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1218        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1219                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1220        ;
1221
1222inclexcl:
1223        '~'
1224                { $$ = OperKinds::LThan; }
1225        | ErangeUpEq
1226                { $$ = OperKinds::LEThan; }
1227        | ErangeDown
1228                { $$ = OperKinds::GThan; }
1229        | ErangeDownEq
1230                { $$ = OperKinds::GEThan; }
1231        ;
1232
1233jump_statement:
1234        GOTO identifier_or_type_name ';'
1235                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1236        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1237                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1238                // whereas normal operator precedence yields goto (*i)+3;
1239                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1240                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1241    | fall_through_name ';'                                                             // CFA
1242                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1243    | fall_through_name identifier_or_type_name ';'             // CFA
1244                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1245        | fall_through_name DEFAULT ';'                                         // CFA
1246                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1247        | CONTINUE ';'
1248                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1249                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1250        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1251                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1252                // the target of the transfer appears only at the start of an iteration statement.
1253                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1254        | BREAK ';'
1255                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1256                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1257        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1258                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1259                // the target of the transfer appears only at the start of an iteration statement.
1260                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1261        | RETURN comma_expression_opt ';'
1262                { $$ = new StatementNode( build_return( $2 ) ); }
1263        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1264                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1265        // | SUSPEND ';'
1266        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1267        // | SUSPEND compound_statement ';'
1268        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1269        | THROW assignment_expression_opt ';'                           // handles rethrow
1270                { $$ = new StatementNode( build_throw( $2 ) ); }
1271        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1272                { $$ = new StatementNode( build_resume( $2 ) ); }
1273        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1274                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1275        ;
1276
1277fall_through_name:                                                                              // CFA
1278        FALLTHRU
1279        | FALLTHROUGH
1280        ;
1281
1282with_statement:
1283        WITH '(' tuple_expression_list ')' statement
1284                {
1285                        $$ = new StatementNode( build_with( $3, $5 ) );
1286                }
1287        ;
1288
1289// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1290mutex_statement:
1291        MUTEX '(' argument_expression_list ')' statement
1292                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1293        ;
1294
1295when_clause:
1296        WHEN '(' comma_expression ')'                           { $$ = $3; }
1297        ;
1298
1299when_clause_opt:
1300        // empty
1301                { $$ = nullptr; }
1302        | when_clause
1303        ;
1304
1305waitfor:
1306        WAITFOR '(' cast_expression ')'
1307                { $$ = $3; }
1308        | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1309                { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1310        ;
1311
1312timeout:
1313        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1314        ;
1315
1316waitfor_clause:
1317        when_clause_opt waitfor statement                                       %prec THEN
1318                { $$ = build_waitfor( $2, $3, $1 ); }
1319        | when_clause_opt waitfor statement WOR waitfor_clause
1320                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1321        | when_clause_opt timeout statement                                     %prec THEN
1322                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1323        | when_clause_opt ELSE statement
1324                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1325                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1326        | when_clause_opt timeout statement WOR ELSE statement
1327                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1328        | when_clause_opt timeout statement WOR when_clause ELSE statement
1329                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1330        ;
1331
1332waitfor_statement:
1333        when_clause_opt waitfor statement                                       %prec THEN
1334                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1335        | when_clause_opt waitfor statement WOR waitfor_clause
1336                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1337        ;
1338
1339exception_statement:
1340        TRY compound_statement handler_clause
1341                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1342        | TRY compound_statement finally_clause
1343                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1344        | TRY compound_statement handler_clause finally_clause
1345                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1346        ;
1347
1348handler_clause:
1349        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1350                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1351        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1352                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1353        ;
1354
1355handler_predicate_opt:
1356        // empty
1357                { $$ = nullptr; }
1358        | ';' conditional_expression                            { $$ = $2; }
1359        ;
1360
1361handler_key:
1362        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1363        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1364        ;
1365
1366finally_clause:
1367        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1368        ;
1369
1370exception_declaration:
1371                // No SUE declaration in parameter list.
1372        type_specifier_nobody
1373        | type_specifier_nobody declarator
1374                { $$ = $2->addType( $1 ); }
1375        | type_specifier_nobody variable_abstract_declarator
1376                { $$ = $2->addType( $1 ); }
1377        | cfa_abstract_declarator_tuple identifier                      // CFA
1378                { $$ = $1->addName( $2 ); }
1379        | cfa_abstract_declarator_tuple                                         // CFA
1380        ;
1381
1382enable_disable_statement:
1383        enable_disable_key identifier_list compound_statement
1384        ;
1385
1386enable_disable_key:
1387        ENABLE
1388        | DISABLE
1389        ;
1390
1391asm_statement:
1392        ASM asm_volatile_opt '(' string_literal ')' ';'
1393                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1394        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1395                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1396        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1397                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1398        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1399                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1400        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1401                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1402        ;
1403
1404asm_volatile_opt:                                                                               // GCC
1405        // empty
1406                { $$ = false; }
1407        | VOLATILE
1408                { $$ = true; }
1409        ;
1410
1411asm_operands_opt:                                                                               // GCC
1412        // empty
1413                { $$ = nullptr; }                                                               // use default argument
1414        | asm_operands_list
1415        ;
1416
1417asm_operands_list:                                                                              // GCC
1418        asm_operand
1419        | asm_operands_list ',' asm_operand
1420                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1421        ;
1422
1423asm_operand:                                                                                    // GCC
1424        string_literal '(' constant_expression ')'
1425                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1426        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1427                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1428        ;
1429
1430asm_clobbers_list_opt:                                                                  // GCC
1431        // empty
1432                { $$ = nullptr; }                                                               // use default argument
1433        | string_literal
1434                { $$ = new ExpressionNode( $1 ); }
1435        | asm_clobbers_list_opt ',' string_literal
1436                // set_last returns ParseNode *
1437                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1438        ;
1439
1440label_list:
1441        identifier
1442                {
1443                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1444                        delete $1;                                                                      // allocated by lexer
1445                }
1446        | label_list ',' identifier
1447                {
1448                        $$ = $1; $1->labels.push_back( *$3 );
1449                        delete $3;                                                                      // allocated by lexer
1450                }
1451        ;
1452
1453//******************************* DECLARATIONS *********************************
1454
1455declaration_list_opt:                                                                   // used at beginning of switch statement
1456        // empty
1457                { $$ = nullptr; }
1458        | declaration_list
1459        ;
1460
1461declaration_list:
1462        declaration
1463        | declaration_list declaration
1464                { $$ = $1->appendList( $2 ); }
1465        ;
1466
1467KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1468        // empty
1469                { $$ = nullptr; }
1470        | KR_parameter_list
1471        ;
1472
1473KR_parameter_list:
1474        push c_declaration pop ';'
1475                { $$ = $2; }
1476        | KR_parameter_list push c_declaration pop ';'
1477                { $$ = $1->appendList( $3 ); }
1478        ;
1479
1480local_label_declaration_opt:                                                    // GCC, local label
1481        // empty
1482        | local_label_declaration_list
1483        ;
1484
1485local_label_declaration_list:                                                   // GCC, local label
1486        LABEL local_label_list ';'
1487        | local_label_declaration_list LABEL local_label_list ';'
1488        ;
1489
1490local_label_list:                                                                               // GCC, local label
1491        identifier_or_type_name
1492        | local_label_list ',' identifier_or_type_name
1493        ;
1494
1495declaration:                                                                                    // old & new style declarations
1496        c_declaration ';'
1497        | cfa_declaration ';'                                                           // CFA
1498        | static_assert                                                                         // C11
1499        ;
1500
1501static_assert:
1502        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1503                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1504        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1505                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1506
1507// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1508// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1509// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1510// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1511// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1512// block, but cannot be mixed within a specific declaration.
1513//
1514//                      CFA                                     C
1515//              [10] int x;                     int x[10];              // array of 10 integers
1516//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1517
1518cfa_declaration:                                                                                // CFA
1519        cfa_variable_declaration
1520        | cfa_typedef_declaration
1521        | cfa_function_declaration
1522        | type_declaring_list
1523        | trait_specifier
1524        ;
1525
1526cfa_variable_declaration:                                                               // CFA
1527        cfa_variable_specifier initializer_opt
1528                { $$ = $1->addInitializer( $2 ); }
1529        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1530                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1531                // them as a type_qualifier cannot appear in that context.
1532                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1533        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1534                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1535        ;
1536
1537cfa_variable_specifier:                                                                 // CFA
1538                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1539                // storage-class
1540        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1541                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1542        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1543                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1544        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1545                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1546        ;
1547
1548cfa_function_declaration:                                                               // CFA
1549        cfa_function_specifier
1550        | type_qualifier_list cfa_function_specifier
1551                { $$ = $2->addQualifiers( $1 ); }
1552        | declaration_qualifier_list cfa_function_specifier
1553                { $$ = $2->addQualifiers( $1 ); }
1554        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1555                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1556        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1557                {
1558                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1559                        DeclarationNode * ret = new DeclarationNode;
1560                        ret->type = maybeClone( $1->type->base );
1561                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1562                }
1563        ;
1564
1565cfa_function_specifier:                                                                 // CFA
1566//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1567//              {
1568//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1569//              }
1570//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1571//              {
1572//                      typedefTable.setNextIdentifier( *$5 );
1573//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1574//              }
1575//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1576//              {
1577//                      typedefTable.setNextIdentifier( *$5 );
1578//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1579//              }
1580//      | '[' ']' typegen_name
1581                // identifier_or_type_name must be broken apart because of the sequence:
1582                //
1583                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1584                //   '[' ']' type_specifier
1585                //
1586                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1587                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1588        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1589                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1590                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1591        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1592                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1593        ;
1594
1595cfa_function_return:                                                                    // CFA
1596        '[' push cfa_parameter_list pop ']'
1597                { $$ = DeclarationNode::newTuple( $3 ); }
1598        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1599                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1600                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1601        ;
1602
1603cfa_typedef_declaration:                                                                // CFA
1604        TYPEDEF cfa_variable_specifier
1605                {
1606                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1607                        $$ = $2->addTypedef();
1608                }
1609        | TYPEDEF cfa_function_specifier
1610                {
1611                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1612                        $$ = $2->addTypedef();
1613                }
1614        | cfa_typedef_declaration pop ',' push identifier
1615                {
1616                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1617                        $$ = $1->appendList( $1->cloneType( $5 ) );
1618                }
1619        ;
1620
1621// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1622// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1623
1624typedef_declaration:
1625        TYPEDEF type_specifier declarator
1626                {
1627                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1628                        $$ = $3->addType( $2 )->addTypedef();
1629                }
1630        | typedef_declaration pop ',' push declarator
1631                {
1632                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1633                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1634                }
1635        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1636                {
1637                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1638                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1639                }
1640        | type_specifier TYPEDEF declarator
1641                {
1642                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1643                        $$ = $3->addType( $1 )->addTypedef();
1644                }
1645        | type_specifier TYPEDEF type_qualifier_list declarator
1646                {
1647                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1648                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1649                }
1650        ;
1651
1652typedef_expression:
1653                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1654        TYPEDEF identifier '=' assignment_expression
1655                {
1656                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1657                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1658                }
1659        | typedef_expression pop ',' push identifier '=' assignment_expression
1660                {
1661                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1662                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1663                }
1664        ;
1665
1666//c_declaration:
1667//      declaring_list pop ';'
1668//      | typedef_declaration pop ';'
1669//      | typedef_expression pop ';'                                            // GCC, naming expression type
1670//      | sue_declaration_specifier pop ';'
1671//      ;
1672//
1673//declaring_list:
1674//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1675//              // storage-class
1676//       declarator asm_name_opt initializer_opt
1677//              {
1678//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1679//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1680//              }
1681//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1682//              {
1683//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1684//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1685//              }
1686//      ;
1687
1688c_declaration:
1689        declaration_specifier declaring_list
1690                { $$ = distAttr( $1, $2 ); }
1691        | typedef_declaration
1692        | typedef_expression                                                            // GCC, naming expression type
1693        | sue_declaration_specifier
1694        ;
1695
1696declaring_list:
1697                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1698                // storage-class
1699        declarator asm_name_opt initializer_opt
1700                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1701        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1702                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1703        ;
1704
1705declaration_specifier:                                                                  // type specifier + storage class
1706        basic_declaration_specifier
1707        | sue_declaration_specifier
1708        | type_declaration_specifier
1709        ;
1710
1711declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1712                // Preclude SUE declarations in restricted scopes:
1713                //
1714                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1715                //
1716                // because it is impossible to call f due to name equivalence.
1717        basic_declaration_specifier
1718        | sue_declaration_specifier_nobody
1719        | type_declaration_specifier
1720        ;
1721
1722type_specifier:                                                                                 // type specifier
1723        basic_type_specifier
1724        | sue_type_specifier
1725        | type_type_specifier
1726        ;
1727
1728type_specifier_nobody:                                                                  // type specifier - {...}
1729                // Preclude SUE declarations in restricted scopes:
1730                //
1731                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1732                //
1733                // because it is impossible to call f due to name equivalence.
1734        basic_type_specifier
1735        | sue_type_specifier_nobody
1736        | type_type_specifier
1737        ;
1738
1739type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1740        // empty
1741                { $$ = nullptr; }
1742        | type_qualifier_list
1743        ;
1744
1745type_qualifier_list:
1746                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1747                //
1748                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1749                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1750                // appeared only once.
1751        type_qualifier
1752        | type_qualifier_list type_qualifier
1753                { $$ = $1->addQualifiers( $2 ); }
1754        ;
1755
1756type_qualifier:
1757        type_qualifier_name
1758        | attribute
1759        ;
1760
1761type_qualifier_name:
1762        CONST
1763                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1764        | RESTRICT
1765                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1766        | VOLATILE
1767                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1768        | ATOMIC
1769                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1770        | forall
1771        ;
1772
1773forall:
1774        FORALL '(' type_parameter_list ')'                                      // CFA
1775                { $$ = DeclarationNode::newForall( $3 ); }
1776        ;
1777
1778declaration_qualifier_list:
1779        storage_class_list
1780        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1781                { $$ = $1->addQualifiers( $2 ); }
1782        | declaration_qualifier_list type_qualifier_list storage_class_list
1783                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1784        ;
1785
1786storage_class_list:
1787                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1788                // only one of each is specified, except for inline, which can appear with the others.
1789                //
1790                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1791                // specifiers in a declaration.
1792        storage_class
1793        | storage_class_list storage_class
1794                { $$ = $1->addQualifiers( $2 ); }
1795        ;
1796
1797storage_class:
1798        EXTERN
1799                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1800        | STATIC
1801                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1802        | AUTO
1803                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1804        | REGISTER
1805                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1806        | THREADLOCAL                                                                           // C11
1807                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1808                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1809        | INLINE                                                                                        // C99
1810                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1811        | FORTRAN                                                                                       // C99
1812                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1813        | NORETURN                                                                                      // C11
1814                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1815        ;
1816
1817basic_type_name:
1818        VOID
1819                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1820        | BOOL                                                                                          // C99
1821                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1822        | CHAR
1823                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1824        | INT
1825                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1826        | INT128
1827                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1828        | UINT128
1829                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1830        | FLOAT
1831                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1832        | DOUBLE
1833                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1834        | uuFLOAT80
1835                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1836        | uuFLOAT128
1837                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1838        | uFLOAT16
1839                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1840        | uFLOAT32
1841                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1842        | uFLOAT32X
1843                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1844        | uFLOAT64
1845                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1846        | uFLOAT64X
1847                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1848        | uFLOAT128
1849                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1850        | COMPLEX                                                                                       // C99
1851                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1852        | IMAGINARY                                                                                     // C99
1853                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1854        | SIGNED
1855                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1856        | UNSIGNED
1857                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1858        | SHORT
1859                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1860        | LONG
1861                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1862        | VALIST                                                                                        // GCC, __builtin_va_list
1863                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1864        | AUTO_TYPE
1865                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1866        ;
1867
1868basic_declaration_specifier:
1869                // A semantic check is necessary for conflicting storage classes.
1870        basic_type_specifier
1871        | declaration_qualifier_list basic_type_specifier
1872                { $$ = $2->addQualifiers( $1 ); }
1873        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1874                { $$ = $1->addQualifiers( $2 ); }
1875        | basic_declaration_specifier storage_class type_qualifier_list
1876                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1877        | basic_declaration_specifier storage_class basic_type_specifier
1878                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1879        ;
1880
1881basic_type_specifier:
1882        direct_type
1883                // Cannot have type modifiers, e.g., short, long, etc.
1884        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1885                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1886        ;
1887
1888direct_type:
1889        basic_type_name
1890        | type_qualifier_list basic_type_name
1891                { $$ = $2->addQualifiers( $1 ); }
1892        | direct_type type_qualifier
1893                { $$ = $1->addQualifiers( $2 ); }
1894        | direct_type basic_type_name
1895                { $$ = $1->addType( $2 ); }
1896        ;
1897
1898indirect_type:
1899        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1900                { $$ = $3; }
1901        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1902                { $$ = DeclarationNode::newTypeof( $3 ); }
1903        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1904                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1905        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1906                { $$ = DeclarationNode::newTypeof( $3, true ); }
1907        | ZERO_T                                                                                        // CFA
1908                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1909        | ONE_T                                                                                         // CFA
1910                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1911        ;
1912
1913sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1914        sue_type_specifier
1915        | declaration_qualifier_list sue_type_specifier
1916                { $$ = $2->addQualifiers( $1 ); }
1917        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1918                { $$ = $1->addQualifiers( $2 ); }
1919        | sue_declaration_specifier storage_class type_qualifier_list
1920                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1921        ;
1922
1923sue_type_specifier:                                                                             // struct, union, enum + type specifier
1924        elaborated_type
1925        | type_qualifier_list
1926                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1927          elaborated_type
1928                { $$ = $3->addQualifiers( $1 ); }
1929        | sue_type_specifier type_qualifier
1930                {
1931                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1932                        $$ = $1->addQualifiers( $2 );
1933                }
1934        ;
1935
1936sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1937        sue_type_specifier_nobody
1938        | declaration_qualifier_list sue_type_specifier_nobody
1939                { $$ = $2->addQualifiers( $1 ); }
1940        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1941                { $$ = $1->addQualifiers( $2 ); }
1942        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1943                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1944        ;
1945
1946sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1947        elaborated_type_nobody
1948        | type_qualifier_list elaborated_type_nobody
1949                { $$ = $2->addQualifiers( $1 ); }
1950        | sue_type_specifier_nobody type_qualifier
1951                { $$ = $1->addQualifiers( $2 ); }
1952        ;
1953
1954type_declaration_specifier:
1955        type_type_specifier
1956        | declaration_qualifier_list type_type_specifier
1957                { $$ = $2->addQualifiers( $1 ); }
1958        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1959                { $$ = $1->addQualifiers( $2 ); }
1960        | type_declaration_specifier storage_class type_qualifier_list
1961                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1962        ;
1963
1964type_type_specifier:                                                                    // typedef types
1965        type_name
1966        | type_qualifier_list type_name
1967                { $$ = $2->addQualifiers( $1 ); }
1968        | type_type_specifier type_qualifier
1969                { $$ = $1->addQualifiers( $2 ); }
1970        ;
1971
1972type_name:
1973        TYPEDEFname
1974                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1975        | '.' TYPEDEFname
1976                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1977        | type_name '.' TYPEDEFname
1978                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1979        | typegen_name
1980        | '.' typegen_name
1981                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1982        | type_name '.' typegen_name
1983                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1984        ;
1985
1986typegen_name:                                                                                   // CFA
1987        TYPEGENname
1988                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1989        | TYPEGENname '(' ')'
1990                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1991        | TYPEGENname '(' type_list ')'
1992                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1993        ;
1994
1995elaborated_type:                                                                                // struct, union, enum
1996        aggregate_type
1997        | enum_type
1998        ;
1999
2000elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2001        aggregate_type_nobody
2002        | enum_type_nobody
2003        ;
2004
2005fred:
2006        // empty
2007                { yyy = false; }
2008        ;
2009
2010aggregate_type:                                                                                 // struct, union
2011        aggregate_key attribute_list_opt
2012                { forall = false; }                                                             // reset
2013          '{' field_declaration_list_opt '}' type_parameters_opt
2014                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2015        | aggregate_key attribute_list_opt identifier fred
2016                {
2017                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2018                        forall = false;                                                         // reset
2019                }
2020          '{' field_declaration_list_opt '}' type_parameters_opt
2021                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2022        | aggregate_key attribute_list_opt type_name fred
2023                {
2024                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2025                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2026                        forall = false;                                                         // reset
2027                }
2028          '{' field_declaration_list_opt '}' type_parameters_opt
2029                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2030        | aggregate_type_nobody
2031        ;
2032
2033type_parameters_opt:
2034        // empty
2035                { $$ = nullptr; }                                                               %prec '}'
2036        | '(' type_list ')'
2037                { $$ = $2; }
2038        ;
2039
2040aggregate_type_nobody:                                                                  // struct, union - {...}
2041        aggregate_key attribute_list_opt identifier fred
2042                {
2043                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2044                        forall = false;                                                         // reset
2045                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2046                }
2047        | aggregate_key attribute_list_opt type_name fred
2048                {
2049                        forall = false;                                                         // reset
2050                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2051                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2052                        // delete newFromTypeGen.
2053                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2054                        $3->type->symbolic.name = nullptr;
2055                        $3->type->symbolic.actuals = nullptr;
2056                        delete $3;
2057                }
2058        ;
2059
2060aggregate_key:
2061        STRUCT
2062                { yyy = true; $$ = DeclarationNode::Struct; }
2063        | UNION
2064                { yyy = true; $$ = DeclarationNode::Union; }
2065        | EXCEPTION
2066                { yyy = true; $$ = DeclarationNode::Exception; }
2067        | GENERATOR
2068                { yyy = true; $$ = DeclarationNode::Coroutine; }
2069        | COROUTINE
2070                { yyy = true; $$ = DeclarationNode::Coroutine; }
2071        | MONITOR
2072                { yyy = true; $$ = DeclarationNode::Monitor; }
2073        | THREAD
2074                { yyy = true; $$ = DeclarationNode::Thread; }
2075        ;
2076
2077field_declaration_list_opt:
2078        // empty
2079                { $$ = nullptr; }
2080        | field_declaration_list_opt field_declaration
2081                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2082        ;
2083
2084field_declaration:
2085        type_specifier field_declaring_list_opt ';'
2086                { $$ = fieldDecl( $1, $2 ); }
2087        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2088                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2089        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2090                {
2091                        if ( ! $3 ) {                                                           // field declarator ?
2092                                $3 = DeclarationNode::newName( nullptr );
2093                        } // if
2094                        $3->inLine = true;
2095                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2096                        distInl( $3 );
2097                }
2098        | typedef_declaration ';'                                                       // CFA
2099        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2100        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2101                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2102        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2103                { $$ = $2; }                                                                    // mark all fields in list
2104        | cfa_typedef_declaration ';'                                           // CFA
2105        | static_assert                                                                         // C11
2106        ;
2107
2108field_declaring_list_opt:
2109        // empty
2110                { $$ = nullptr; }
2111        | field_declarator
2112        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2113                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2114        ;
2115
2116field_declarator:
2117        bit_subrange_size                                                                       // C special case, no field name
2118                { $$ = DeclarationNode::newBitfield( $1 ); }
2119        | variable_declarator bit_subrange_size_opt
2120                // A semantic check is required to ensure bit_subrange only appears on integral types.
2121                { $$ = $1->addBitfield( $2 ); }
2122        | variable_type_redeclarator bit_subrange_size_opt
2123                // A semantic check is required to ensure bit_subrange only appears on integral types.
2124                { $$ = $1->addBitfield( $2 ); }
2125        ;
2126
2127field_abstract_list_opt:
2128        // empty
2129                { $$ = nullptr; }
2130        | field_abstract
2131        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2132                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2133        ;
2134
2135field_abstract:
2136                //      no bit fields
2137        variable_abstract_declarator
2138        ;
2139
2140cfa_field_declaring_list:                                                               // CFA, new style field declaration
2141        // bit-fields are handled by C declarations
2142        cfa_abstract_declarator_tuple identifier_or_type_name
2143                { $$ = $1->addName( $2 ); }
2144        | cfa_field_declaring_list ',' identifier_or_type_name
2145                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2146        ;
2147
2148cfa_field_abstract_list:                                                                // CFA, new style field declaration
2149        // bit-fields are handled by C declarations
2150        cfa_abstract_declarator_tuple
2151        | cfa_field_abstract_list ','
2152                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2153        ;
2154
2155bit_subrange_size_opt:
2156        // empty
2157                { $$ = nullptr; }
2158        | bit_subrange_size
2159        ;
2160
2161bit_subrange_size:
2162        ':' assignment_expression
2163                { $$ = $2; }
2164        ;
2165
2166enum_type:                                                                                              // enum
2167        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2168                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2169        | ENUM attribute_list_opt identifier
2170                { typedefTable.makeTypedef( *$3 ); }
2171          '{' enumerator_list comma_opt '}'
2172                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2173        | ENUM attribute_list_opt type_name
2174          '{' enumerator_list comma_opt '}'
2175                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2176        | enum_type_nobody
2177        ;
2178
2179enum_type_nobody:                                                                               // enum - {...}
2180        ENUM attribute_list_opt identifier
2181                {
2182                        typedefTable.makeTypedef( *$3 );
2183                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2184                }
2185        | ENUM attribute_list_opt type_name
2186                {
2187                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2188                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2189                }
2190        ;
2191
2192enumerator_list:
2193        identifier_or_type_name enumerator_value_opt
2194                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2195        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2196                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2197        ;
2198
2199enumerator_value_opt:
2200        // empty
2201                { $$ = nullptr; }
2202        | '=' constant_expression
2203                { $$ = $2; }
2204        ;
2205
2206cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2207        // empty
2208                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2209        | ELLIPSIS
2210                { $$ = nullptr; }
2211        | cfa_abstract_parameter_list
2212        | cfa_parameter_list
2213        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2214                { $$ = $1->appendList( $5 ); }
2215        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2216                { $$ = $1->addVarArgs(); }
2217        | cfa_parameter_list pop ',' push ELLIPSIS
2218                { $$ = $1->addVarArgs(); }
2219        ;
2220
2221cfa_parameter_list:                                                                             // CFA
2222                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2223                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2224        cfa_parameter_declaration
2225        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2226                { $$ = $1->appendList( $5 ); }
2227        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2228                { $$ = $1->appendList( $5 ); }
2229        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2230                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2231        ;
2232
2233cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2234        cfa_abstract_parameter_declaration
2235        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2236                { $$ = $1->appendList( $5 ); }
2237        ;
2238
2239parameter_type_list_opt:
2240        // empty
2241                { $$ = nullptr; }
2242        | ELLIPSIS
2243                { $$ = nullptr; }
2244        | parameter_list
2245        | parameter_list pop ',' push ELLIPSIS
2246                { $$ = $1->addVarArgs(); }
2247        ;
2248
2249parameter_list:                                                                                 // abstract + real
2250        abstract_parameter_declaration
2251        | parameter_declaration
2252        | parameter_list pop ',' push abstract_parameter_declaration
2253                { $$ = $1->appendList( $5 ); }
2254        | parameter_list pop ',' push parameter_declaration
2255                { $$ = $1->appendList( $5 ); }
2256        ;
2257
2258// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2259// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2260
2261cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2262        parameter_declaration
2263        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2264                { $$ = $1->addName( $2 ); }
2265        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2266                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2267                { $$ = $1->addName( $2 ); }
2268        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2269                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2270        | cfa_function_specifier
2271        ;
2272
2273cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2274        abstract_parameter_declaration
2275        | cfa_identifier_parameter_declarator_no_tuple
2276        | cfa_abstract_tuple
2277                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2278        | type_qualifier_list cfa_abstract_tuple
2279                { $$ = $2->addQualifiers( $1 ); }
2280        | cfa_abstract_function
2281        ;
2282
2283parameter_declaration:
2284                // No SUE declaration in parameter list.
2285        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2286                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2287        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2288                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2289        ;
2290
2291abstract_parameter_declaration:
2292        declaration_specifier_nobody default_initialize_opt
2293                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2294        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2295                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2296        ;
2297
2298// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2299// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2300// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2301
2302identifier_list:                                                                                // K&R-style parameter list => no types
2303        identifier
2304                { $$ = DeclarationNode::newName( $1 ); }
2305        | identifier_list ',' identifier
2306                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2307        ;
2308
2309identifier_or_type_name:
2310        identifier
2311        | TYPEDEFname
2312        | TYPEGENname
2313        ;
2314
2315type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2316        cfa_abstract_declarator_tuple                                           // CFA
2317        | type_specifier
2318        | type_specifier abstract_declarator
2319                { $$ = $2->addType( $1 ); }
2320        ;
2321
2322type:                                                                                                   // typeof, assertion
2323        type_no_function
2324        | cfa_abstract_function                                                         // CFA
2325        ;
2326
2327initializer_opt:
2328        // empty
2329                { $$ = nullptr; }
2330        | '=' initializer
2331                { $$ = $2; }
2332        | '=' VOID
2333                { $$ = new InitializerNode( true ); }
2334        | ATassign initializer
2335                { $$ = $2->set_maybeConstructed( false ); }
2336        ;
2337
2338initializer:
2339        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2340        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2341        ;
2342
2343initializer_list_opt:
2344        // empty
2345                { $$ = nullptr; }
2346        | initializer
2347        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2348        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2349        | initializer_list_opt ',' designation initializer
2350                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2351        ;
2352
2353// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2354// '=' to separator the designator from the initializer value, as in:
2355//
2356//              int x[10] = { [1] = 3 };
2357//
2358// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2359// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2360// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2361// shift/reduce conflicts
2362
2363designation:
2364        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2365        | identifier ':'                                                                        // GCC, field name
2366                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2367        ;
2368
2369designator_list:                                                                                // C99
2370        designator
2371        | designator_list designator
2372                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2373        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2374        ;
2375
2376designator:
2377        '.' identifier                                                                          // C99, field name
2378                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2379        | '[' push assignment_expression pop ']'                        // C99, single array element
2380                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2381                { $$ = $3; }
2382        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2383                { $$ = $3; }
2384        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2385                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2386        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2387                { $$ = $4; }
2388        ;
2389
2390// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2391// rather than an object-oriented type system. This required four groups of extensions:
2392//
2393// Overloading: function, data, and operator identifiers may be overloaded.
2394//
2395// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2396//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2397//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2398//
2399// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2400//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2401//
2402// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2403//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2404//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2405//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2406//     on type arguments of polymorphic functions.
2407
2408type_parameter_list:                                                                    // CFA
2409        type_parameter
2410        | type_parameter_list ',' type_parameter
2411                { $$ = $1->appendList( $3 ); }
2412        ;
2413
2414type_initializer_opt:                                                                   // CFA
2415        // empty
2416                { $$ = nullptr; }
2417        | '=' type
2418                { $$ = $2; }
2419        ;
2420
2421type_parameter:                                                                                 // CFA
2422        type_class identifier_or_type_name
2423                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2424          type_initializer_opt assertion_list_opt
2425                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2426        | type_specifier identifier_parameter_declarator
2427        | assertion_list
2428                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2429        ;
2430
2431type_class:                                                                                             // CFA
2432        OTYPE
2433                { $$ = DeclarationNode::Otype; }
2434        | DTYPE
2435                { $$ = DeclarationNode::Dtype; }
2436        | FTYPE
2437                { $$ = DeclarationNode::Ftype; }
2438        | TTYPE
2439                { $$ = DeclarationNode::Ttype; }
2440        ;
2441
2442assertion_list_opt:                                                                             // CFA
2443        // empty
2444                { $$ = nullptr; }
2445        | assertion_list
2446        ;
2447
2448assertion_list:                                                                                 // CFA
2449        assertion
2450        | assertion_list assertion
2451                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2452        ;
2453
2454assertion:                                                                                              // CFA
2455        '|' identifier_or_type_name '(' type_list ')'
2456                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2457        | '|' '{' push trait_declaration_list pop '}'
2458                { $$ = $4; }
2459        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2460        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2461        ;
2462
2463type_list:                                                                                              // CFA
2464        type
2465                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2466        | assignment_expression
2467                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2468        | type_list ',' type
2469                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2470        | type_list ',' assignment_expression
2471                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2472                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2473        ;
2474
2475type_declaring_list:                                                                    // CFA
2476        OTYPE type_declarator
2477                { $$ = $2; }
2478        | storage_class_list OTYPE type_declarator
2479                { $$ = $3->addQualifiers( $1 ); }
2480        | type_declaring_list ',' type_declarator
2481                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2482        ;
2483
2484type_declarator:                                                                                // CFA
2485        type_declarator_name assertion_list_opt
2486                { $$ = $1->addAssertions( $2 ); }
2487        | type_declarator_name assertion_list_opt '=' type
2488                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2489        ;
2490
2491type_declarator_name:                                                                   // CFA
2492        identifier_or_type_name
2493                {
2494                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2495                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2496                }
2497        | identifier_or_type_name '(' type_parameter_list ')'
2498                {
2499                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2500                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2501                }
2502        ;
2503
2504trait_specifier:                                                                                // CFA
2505        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2506                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2507        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2508                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2509        ;
2510
2511trait_declaration_list:                                                                 // CFA
2512        trait_declaration
2513        | trait_declaration_list pop push trait_declaration
2514                { $$ = $1->appendList( $4 ); }
2515        ;
2516
2517trait_declaration:                                                                              // CFA
2518        cfa_trait_declaring_list ';'
2519        | trait_declaring_list ';'
2520        ;
2521
2522cfa_trait_declaring_list:                                                               // CFA
2523        cfa_variable_specifier
2524        | cfa_function_specifier
2525        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2526                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2527        ;
2528
2529trait_declaring_list:                                                                   // CFA
2530        type_specifier declarator
2531                { $$ = $2->addType( $1 ); }
2532        | trait_declaring_list pop ',' push declarator
2533                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2534        ;
2535
2536//***************************** EXTERNAL DEFINITIONS *****************************
2537
2538translation_unit:
2539        // empty, input file
2540        | external_definition_list
2541                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2542        ;
2543
2544external_definition_list:
2545        push external_definition pop
2546                { $$ = $2; }
2547        | external_definition_list push external_definition pop
2548                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2549        ;
2550
2551external_definition_list_opt:
2552        // empty
2553                { $$ = nullptr; }
2554        | external_definition_list
2555        ;
2556
2557up:
2558                { typedefTable.up( forall ); forall = false; }
2559        ;
2560
2561down:
2562                { typedefTable.down(); }
2563        ;
2564
2565external_definition:
2566        declaration
2567        | external_function_definition
2568        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2569                {
2570                        distExt( $2 );                                                          // mark all fields in list
2571                        $$ = $2;
2572                }
2573        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2574                {
2575                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2576                }
2577        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2578                {
2579                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2580                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2581                }
2582          '{' up external_definition_list_opt down '}'
2583                {
2584                        linkage = linkageStack.top();
2585                        linkageStack.pop();
2586                        $$ = $6;
2587                }
2588        | type_qualifier_list
2589                {
2590                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2591                        if ( $1->type->forall ) forall = true;          // remember generic type
2592                }
2593          '{' up external_definition_list_opt down '}'          // CFA, namespace
2594                {
2595                        distQual( $5, $1 );
2596                        forall = false;
2597                        $$ = $5;
2598                }
2599        | declaration_qualifier_list
2600                {
2601                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2602                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2603                }
2604          '{' up external_definition_list_opt down '}'          // CFA, namespace
2605                {
2606                        distQual( $5, $1 );
2607                        forall = false;
2608                        $$ = $5;
2609                }
2610        | declaration_qualifier_list type_qualifier_list
2611                {
2612                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2613                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2614                }
2615          '{' up external_definition_list_opt down '}'          // CFA, namespace
2616                {
2617                        distQual( $6, $1->addQualifiers( $2 ) );
2618                        forall = false;
2619                        $$ = $6;
2620                }
2621        ;
2622
2623external_function_definition:
2624        function_definition
2625                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2626                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2627                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2628                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2629                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2630        | function_declarator compound_statement
2631                { $$ = $1->addFunctionBody( $2 ); }
2632        | KR_function_declarator KR_parameter_list_opt compound_statement
2633                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2634        ;
2635
2636with_clause_opt:
2637        // empty
2638                { $$ = nullptr; forall = false; }
2639        | WITH '(' tuple_expression_list ')'
2640                { $$ = $3; forall = false; }
2641        ;
2642
2643function_definition:
2644        cfa_function_declaration with_clause_opt compound_statement     // CFA
2645                {
2646                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2647                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2648                        $1->get_last()->addFunctionBody( $3, $2 );
2649                        $$ = $1;
2650                }
2651        | declaration_specifier function_declarator with_clause_opt compound_statement
2652                {
2653                        rebindForall( $1, $2 );
2654                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2655                }
2656        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2657                {
2658                        rebindForall( $1, $2 );
2659                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2660                }
2661                // handles default int return type, OBSOLESCENT (see 1)
2662        | type_qualifier_list function_declarator with_clause_opt compound_statement
2663                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2664                // handles default int return type, OBSOLESCENT (see 1)
2665        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2666                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2667                // handles default int return type, OBSOLESCENT (see 1)
2668        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2669                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2670
2671                // Old-style K&R function definition, OBSOLESCENT (see 4)
2672        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2673                {
2674                        rebindForall( $1, $2 );
2675                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2676                }
2677                // handles default int return type, OBSOLESCENT (see 1)
2678        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2679                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2680                // handles default int return type, OBSOLESCENT (see 1)
2681        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2682                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2683                // handles default int return type, OBSOLESCENT (see 1)
2684        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2685                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2686        ;
2687
2688declarator:
2689        variable_declarator
2690        | variable_type_redeclarator
2691        | function_declarator
2692        ;
2693
2694subrange:
2695        constant_expression '~' constant_expression                     // CFA, integer subrange
2696                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2697        ;
2698
2699asm_name_opt:                                                                                   // GCC
2700        // empty
2701                { $$ = nullptr; }
2702        | ASM '(' string_literal ')' attribute_list_opt
2703                {
2704                        DeclarationNode * name = new DeclarationNode();
2705                        name->asmName = $3;
2706                        $$ = name->addQualifiers( $5 );
2707                }
2708        ;
2709
2710attribute_list_opt:                                                                             // GCC
2711        // empty
2712                { $$ = nullptr; }
2713        | attribute_list
2714        ;
2715
2716attribute_list:                                                                                 // GCC
2717        attribute
2718        | attribute_list attribute
2719                { $$ = $2->addQualifiers( $1 ); }
2720        ;
2721
2722attribute:                                                                                              // GCC
2723        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2724                { $$ = $4; }
2725        ;
2726
2727attribute_name_list:                                                                    // GCC
2728        attribute_name
2729        | attribute_name_list ',' attribute_name
2730                { $$ = $3->addQualifiers( $1 ); }
2731        ;
2732
2733attribute_name:                                                                                 // GCC
2734        // empty
2735                { $$ = nullptr; }
2736        | attr_name
2737                { $$ = DeclarationNode::newAttribute( $1 ); }
2738        | attr_name '(' argument_expression_list ')'
2739                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2740        ;
2741
2742attr_name:                                                                                              // GCC
2743        IDENTIFIER
2744        | quasi_keyword
2745        | TYPEDEFname
2746        | TYPEGENname
2747        | FALLTHROUGH
2748                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2749        | CONST
2750                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2751        ;
2752
2753// ============================================================================
2754// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2755// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2756// in:
2757//
2758//              int (*f())[10] { ... };
2759//              ... (*f())[3] += 1;             // definition mimics usage
2760//
2761// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2762// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2763// ============================================================================
2764
2765// ----------------------------------------------------------------------------
2766// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2767// to define a variable or function prototype, e.g.:
2768//
2769//              valid declaration               invalid definition
2770//              -----------------               ------------------
2771//              int f;                                  int f {}
2772//              int *f;                                 int *f {}
2773//              int f[10];                              int f[10] {}
2774//              int (*f)(int);                  int (*f)(int) {}
2775//
2776// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2777// variable_declarator and function_declarator.
2778// ----------------------------------------------------------------------------
2779
2780// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2781// declaring an array of functions versus a pointer to an array of functions.
2782
2783variable_declarator:
2784        paren_identifier attribute_list_opt
2785                { $$ = $1->addQualifiers( $2 ); }
2786        | variable_ptr
2787        | variable_array attribute_list_opt
2788                { $$ = $1->addQualifiers( $2 ); }
2789        | variable_function attribute_list_opt
2790                { $$ = $1->addQualifiers( $2 ); }
2791        ;
2792
2793paren_identifier:
2794        identifier
2795                { $$ = DeclarationNode::newName( $1 ); }
2796        | '(' paren_identifier ')'                                                      // redundant parenthesis
2797                { $$ = $2; }
2798        ;
2799
2800variable_ptr:
2801        ptrref_operator variable_declarator
2802                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2803        | ptrref_operator type_qualifier_list variable_declarator
2804                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2805        | '(' variable_ptr ')' attribute_list_opt
2806                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2807        ;
2808
2809variable_array:
2810        paren_identifier array_dimension
2811                { $$ = $1->addArray( $2 ); }
2812        | '(' variable_ptr ')' array_dimension
2813                { $$ = $2->addArray( $4 ); }
2814        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2815                { $$ = $2->addArray( $4 ); }
2816        | '(' variable_array ')'                                                        // redundant parenthesis
2817                { $$ = $2; }
2818        ;
2819
2820variable_function:
2821        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2822                { $$ = $2->addParamList( $6 ); }
2823        | '(' variable_function ')'                                                     // redundant parenthesis
2824                { $$ = $2; }
2825        ;
2826
2827// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2828// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2829// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2830
2831function_declarator:
2832        function_no_ptr attribute_list_opt
2833                { $$ = $1->addQualifiers( $2 ); }
2834        | function_ptr
2835        | function_array attribute_list_opt
2836                { $$ = $1->addQualifiers( $2 ); }
2837        ;
2838
2839function_no_ptr:
2840        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2841                { $$ = $1->addParamList( $4 ); }
2842        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2843                { $$ = $2->addParamList( $6 ); }
2844        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2845                { $$ = $2; }
2846        ;
2847
2848function_ptr:
2849        ptrref_operator function_declarator
2850                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2851        | ptrref_operator type_qualifier_list function_declarator
2852                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2853        | '(' function_ptr ')'
2854                { $$ = $2; }
2855        ;
2856
2857function_array:
2858        '(' function_ptr ')' array_dimension
2859                { $$ = $2->addArray( $4 ); }
2860        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2861                { $$ = $2->addArray( $4 ); }
2862        | '(' function_array ')'                                                        // redundant parenthesis
2863                { $$ = $2; }
2864        ;
2865
2866// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2867//
2868//   f( a, b, c ) int a, *b, c[]; {}
2869//
2870// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2871// returning arrays and functions versus pointers to arrays and functions.
2872
2873KR_function_declarator:
2874        KR_function_no_ptr
2875        | KR_function_ptr
2876        | KR_function_array
2877        ;
2878
2879KR_function_no_ptr:
2880        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2881                { $$ = $1->addIdList( $3 ); }
2882        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2883                { $$ = $2->addParamList( $6 ); }
2884        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2885                { $$ = $2; }
2886        ;
2887
2888KR_function_ptr:
2889        ptrref_operator KR_function_declarator
2890                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2891        | ptrref_operator type_qualifier_list KR_function_declarator
2892                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2893        | '(' KR_function_ptr ')'
2894                { $$ = $2; }
2895        ;
2896
2897KR_function_array:
2898        '(' KR_function_ptr ')' array_dimension
2899                { $$ = $2->addArray( $4 ); }
2900        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2901                { $$ = $2->addArray( $4 ); }
2902        | '(' KR_function_array ')'                                                     // redundant parenthesis
2903                { $$ = $2; }
2904        ;
2905
2906// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2907//
2908//              typedef int foo;
2909//              {
2910//                 int foo; // redefine typedef name in new scope
2911//              }
2912//
2913// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2914// and functions versus pointers to arrays and functions.
2915
2916variable_type_redeclarator:
2917        paren_type attribute_list_opt
2918                { $$ = $1->addQualifiers( $2 ); }
2919        | type_ptr
2920        | type_array attribute_list_opt
2921                { $$ = $1->addQualifiers( $2 ); }
2922        | type_function attribute_list_opt
2923                { $$ = $1->addQualifiers( $2 ); }
2924        ;
2925
2926paren_type:
2927        typedef
2928                // hide type name in enclosing scope by variable name
2929                {
2930                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2931                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2932                        // } else {
2933                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2934                        // } // if
2935                }
2936        | '(' paren_type ')'
2937                { $$ = $2; }
2938        ;
2939
2940type_ptr:
2941        ptrref_operator variable_type_redeclarator
2942                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2943        | ptrref_operator type_qualifier_list variable_type_redeclarator
2944                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2945        | '(' type_ptr ')' attribute_list_opt
2946                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2947        ;
2948
2949type_array:
2950        paren_type array_dimension
2951                { $$ = $1->addArray( $2 ); }
2952        | '(' type_ptr ')' array_dimension
2953                { $$ = $2->addArray( $4 ); }
2954        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2955                { $$ = $2->addArray( $4 ); }
2956        | '(' type_array ')'                                                            // redundant parenthesis
2957                { $$ = $2; }
2958        ;
2959
2960type_function:
2961        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2962                { $$ = $1->addParamList( $4 ); }
2963        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2964                { $$ = $2->addParamList( $6 ); }
2965        | '(' type_function ')'                                                         // redundant parenthesis
2966                { $$ = $2; }
2967        ;
2968
2969// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2970// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2971// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2972// pointers to arrays and functions.
2973
2974identifier_parameter_declarator:
2975        paren_identifier attribute_list_opt
2976                { $$ = $1->addQualifiers( $2 ); }
2977        | '&' MUTEX paren_identifier attribute_list_opt
2978                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2979        | identifier_parameter_ptr
2980        | identifier_parameter_array attribute_list_opt
2981                { $$ = $1->addQualifiers( $2 ); }
2982        | identifier_parameter_function attribute_list_opt
2983                { $$ = $1->addQualifiers( $2 ); }
2984        ;
2985
2986identifier_parameter_ptr:
2987        ptrref_operator identifier_parameter_declarator
2988                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2989        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2990                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2991        | '(' identifier_parameter_ptr ')' attribute_list_opt
2992                { $$ = $2->addQualifiers( $4 ); }
2993        ;
2994
2995identifier_parameter_array:
2996        paren_identifier array_parameter_dimension
2997                { $$ = $1->addArray( $2 ); }
2998        | '(' identifier_parameter_ptr ')' array_dimension
2999                { $$ = $2->addArray( $4 ); }
3000        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3001                { $$ = $2->addArray( $4 ); }
3002        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3003                { $$ = $2; }
3004        ;
3005
3006identifier_parameter_function:
3007        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3008                { $$ = $1->addParamList( $4 ); }
3009        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3010                { $$ = $2->addParamList( $6 ); }
3011        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3012                { $$ = $2; }
3013        ;
3014
3015// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3016// e.g.:
3017//
3018//              typedef int foo;
3019//              forall( otype T ) struct foo;
3020//              int f( int foo ); // redefine typedef name in new scope
3021//
3022// and allows the C99 array options, which can only appear in a parameter list.
3023
3024type_parameter_redeclarator:
3025        typedef attribute_list_opt
3026                { $$ = $1->addQualifiers( $2 ); }
3027        | '&' MUTEX typedef attribute_list_opt
3028                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3029        | type_parameter_ptr
3030        | type_parameter_array attribute_list_opt
3031                { $$ = $1->addQualifiers( $2 ); }
3032        | type_parameter_function attribute_list_opt
3033                { $$ = $1->addQualifiers( $2 ); }
3034        ;
3035
3036typedef:
3037        TYPEDEFname
3038                { $$ = DeclarationNode::newName( $1 ); }
3039        | TYPEGENname
3040                { $$ = DeclarationNode::newName( $1 ); }
3041        ;
3042
3043type_parameter_ptr:
3044        ptrref_operator type_parameter_redeclarator
3045                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3046        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3047                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3048        | '(' type_parameter_ptr ')' attribute_list_opt
3049                { $$ = $2->addQualifiers( $4 ); }
3050        ;
3051
3052type_parameter_array:
3053        typedef array_parameter_dimension
3054                { $$ = $1->addArray( $2 ); }
3055        | '(' type_parameter_ptr ')' array_parameter_dimension
3056                { $$ = $2->addArray( $4 ); }
3057        ;
3058
3059type_parameter_function:
3060        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3061                { $$ = $1->addParamList( $4 ); }
3062        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3063                { $$ = $2->addParamList( $6 ); }
3064        ;
3065
3066// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3067// which the type applies, e.g.:
3068//
3069//              sizeof( int );
3070//              sizeof( int * );
3071//              sizeof( int [10] );
3072//              sizeof( int (*)() );
3073//              sizeof( int () );
3074//
3075// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3076// and functions versus pointers to arrays and functions.
3077
3078abstract_declarator:
3079        abstract_ptr
3080        | abstract_array attribute_list_opt
3081                { $$ = $1->addQualifiers( $2 ); }
3082        | abstract_function attribute_list_opt
3083                { $$ = $1->addQualifiers( $2 ); }
3084        ;
3085
3086abstract_ptr:
3087        ptrref_operator
3088                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3089        | ptrref_operator type_qualifier_list
3090                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3091        | ptrref_operator abstract_declarator
3092                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3093        | ptrref_operator type_qualifier_list abstract_declarator
3094                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3095        | '(' abstract_ptr ')' attribute_list_opt
3096                { $$ = $2->addQualifiers( $4 ); }
3097        ;
3098
3099abstract_array:
3100        array_dimension
3101        | '(' abstract_ptr ')' array_dimension
3102                { $$ = $2->addArray( $4 ); }
3103        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3104                { $$ = $2->addArray( $4 ); }
3105        | '(' abstract_array ')'                                                        // redundant parenthesis
3106                { $$ = $2; }
3107        ;
3108
3109abstract_function:
3110        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3111                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3112        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3113                { $$ = $2->addParamList( $6 ); }
3114        | '(' abstract_function ')'                                                     // redundant parenthesis
3115                { $$ = $2; }
3116        ;
3117
3118array_dimension:
3119                // Only the first dimension can be empty.
3120        '[' ']'
3121                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3122        | '[' ']' multi_array_dimension
3123                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3124        | multi_array_dimension
3125        ;
3126
3127multi_array_dimension:
3128        '[' push assignment_expression pop ']'
3129                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3130        | '[' push '*' pop ']'                                                          // C99
3131                { $$ = DeclarationNode::newVarArray( 0 ); }
3132        | multi_array_dimension '[' push assignment_expression pop ']'
3133                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3134        | multi_array_dimension '[' push '*' pop ']'            // C99
3135                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3136        ;
3137
3138// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3139// identifier to which the type applies, e.g.:
3140//
3141//              int f( int );                   // not handled here
3142//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3143//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3144//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3145//
3146// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3147// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3148// special meaning of parenthesis around a typedef name:
3149//
3150//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3151//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3152//              not as redundant parentheses around the identifier."
3153//
3154// For example:
3155//
3156//              typedef float T;
3157//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3158//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3159//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3160//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3161//
3162// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3163// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3164// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3165// functions.
3166
3167abstract_parameter_declarator:
3168        abstract_parameter_ptr
3169        | '&' MUTEX attribute_list_opt
3170                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3171        | abstract_parameter_array attribute_list_opt
3172                { $$ = $1->addQualifiers( $2 ); }
3173        | abstract_parameter_function attribute_list_opt
3174                { $$ = $1->addQualifiers( $2 ); }
3175        ;
3176
3177abstract_parameter_ptr:
3178        ptrref_operator
3179                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3180        | ptrref_operator type_qualifier_list
3181                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3182        | ptrref_operator abstract_parameter_declarator
3183                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3184        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3185                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3186        | '(' abstract_parameter_ptr ')' attribute_list_opt
3187                { $$ = $2->addQualifiers( $4 ); }
3188        ;
3189
3190abstract_parameter_array:
3191        array_parameter_dimension
3192        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3193                { $$ = $2->addArray( $4 ); }
3194        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3195                { $$ = $2->addArray( $4 ); }
3196        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3197                { $$ = $2; }
3198        ;
3199
3200abstract_parameter_function:
3201        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3202                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3203        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3204                { $$ = $2->addParamList( $6 ); }
3205        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3206                { $$ = $2; }
3207        ;
3208
3209array_parameter_dimension:
3210                // Only the first dimension can be empty or have qualifiers.
3211        array_parameter_1st_dimension
3212        | array_parameter_1st_dimension multi_array_dimension
3213                { $$ = $1->addArray( $2 ); }
3214        | multi_array_dimension
3215        ;
3216
3217// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3218//
3219//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3220//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3221
3222array_parameter_1st_dimension:
3223        '[' ']'
3224                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3225                // multi_array_dimension handles the '[' '*' ']' case
3226        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3227                { $$ = DeclarationNode::newVarArray( $3 ); }
3228        | '[' push type_qualifier_list pop ']'
3229                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3230                // multi_array_dimension handles the '[' assignment_expression ']' case
3231        | '[' push type_qualifier_list assignment_expression pop ']'
3232                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3233        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3234                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3235        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3236                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3237        ;
3238
3239// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3240//
3241//              struct S {
3242//          int;
3243//          int *;
3244//          int [10];
3245//          int (*)();
3246//      };
3247
3248variable_abstract_declarator:
3249        variable_abstract_ptr
3250        | variable_abstract_array attribute_list_opt
3251                { $$ = $1->addQualifiers( $2 ); }
3252        | variable_abstract_function attribute_list_opt
3253                { $$ = $1->addQualifiers( $2 ); }
3254        ;
3255
3256variable_abstract_ptr:
3257        ptrref_operator
3258                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3259        | ptrref_operator type_qualifier_list
3260                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3261        | ptrref_operator variable_abstract_declarator
3262                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3263        | ptrref_operator type_qualifier_list variable_abstract_declarator
3264                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3265        | '(' variable_abstract_ptr ')' attribute_list_opt
3266                { $$ = $2->addQualifiers( $4 ); }
3267        ;
3268
3269variable_abstract_array:
3270        array_dimension
3271        | '(' variable_abstract_ptr ')' array_dimension
3272                { $$ = $2->addArray( $4 ); }
3273        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3274                { $$ = $2->addArray( $4 ); }
3275        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3276                { $$ = $2; }
3277        ;
3278
3279variable_abstract_function:
3280        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3281                { $$ = $2->addParamList( $6 ); }
3282        | '(' variable_abstract_function ')'                            // redundant parenthesis
3283                { $$ = $2; }
3284        ;
3285
3286// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3287// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3288
3289cfa_identifier_parameter_declarator_tuple:                              // CFA
3290        cfa_identifier_parameter_declarator_no_tuple
3291        | cfa_abstract_tuple
3292        | type_qualifier_list cfa_abstract_tuple
3293                { $$ = $2->addQualifiers( $1 ); }
3294        ;
3295
3296cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3297        cfa_identifier_parameter_ptr
3298        | cfa_identifier_parameter_array
3299        ;
3300
3301cfa_identifier_parameter_ptr:                                                   // CFA
3302                // No SUE declaration in parameter list.
3303        ptrref_operator type_specifier_nobody
3304                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3305        | type_qualifier_list ptrref_operator type_specifier_nobody
3306                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3307        | ptrref_operator cfa_abstract_function
3308                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3309        | type_qualifier_list ptrref_operator cfa_abstract_function
3310                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3311        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3312                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3313        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3314                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3315        ;
3316
3317cfa_identifier_parameter_array:                                                 // CFA
3318                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3319                // shift/reduce conflict with new-style empty (void) function return type.
3320        '[' ']' type_specifier_nobody
3321                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3322        | cfa_array_parameter_1st_dimension type_specifier_nobody
3323                { $$ = $2->addNewArray( $1 ); }
3324        | '[' ']' multi_array_dimension type_specifier_nobody
3325                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3326        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3327                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3328        | multi_array_dimension type_specifier_nobody
3329                { $$ = $2->addNewArray( $1 ); }
3330
3331        | '[' ']' cfa_identifier_parameter_ptr
3332                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3333        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3334                { $$ = $2->addNewArray( $1 ); }
3335        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3336                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3337        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3338                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3339        | multi_array_dimension cfa_identifier_parameter_ptr
3340                { $$ = $2->addNewArray( $1 ); }
3341        ;
3342
3343cfa_array_parameter_1st_dimension:
3344        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3345                { $$ = DeclarationNode::newVarArray( $3 ); }
3346        | '[' push type_qualifier_list assignment_expression pop ']'
3347                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3348        | '[' push declaration_qualifier_list assignment_expression pop ']'
3349                // declaration_qualifier_list must be used because of shift/reduce conflict with
3350                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3351                // appear in this context.
3352                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3353        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3354                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3355        ;
3356
3357// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3358// identifier to which the type applies, e.g.:
3359//
3360//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3361//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3362//
3363// These rules need LR(3):
3364//
3365//              cfa_abstract_tuple identifier_or_type_name
3366//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3367//
3368// since a function return type can be syntactically identical to a tuple type:
3369//
3370//              [int, int] t;
3371//              [int, int] f( int );
3372//
3373// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3374// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3375// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3376// duplicated when appearing with cfa_function_specifier.
3377
3378cfa_abstract_declarator_tuple:                                                  // CFA
3379        cfa_abstract_tuple
3380        | type_qualifier_list cfa_abstract_tuple
3381                { $$ = $2->addQualifiers( $1 ); }
3382        | cfa_abstract_declarator_no_tuple
3383        ;
3384
3385cfa_abstract_declarator_no_tuple:                                               // CFA
3386        cfa_abstract_ptr
3387        | cfa_abstract_array
3388        ;
3389
3390cfa_abstract_ptr:                                                                               // CFA
3391        ptrref_operator type_specifier
3392                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3393        | type_qualifier_list ptrref_operator type_specifier
3394                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3395        | ptrref_operator cfa_abstract_function
3396                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3397        | type_qualifier_list ptrref_operator cfa_abstract_function
3398                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3399        | ptrref_operator cfa_abstract_declarator_tuple
3400                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3401        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3402                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3403        ;
3404
3405cfa_abstract_array:                                                                             // CFA
3406                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3407                // empty (void) function return type.
3408        '[' ']' type_specifier
3409                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3410        | '[' ']' multi_array_dimension type_specifier
3411                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3412        | multi_array_dimension type_specifier
3413                { $$ = $2->addNewArray( $1 ); }
3414        | '[' ']' cfa_abstract_ptr
3415                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3416        | '[' ']' multi_array_dimension cfa_abstract_ptr
3417                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3418        | multi_array_dimension cfa_abstract_ptr
3419                { $$ = $2->addNewArray( $1 ); }
3420        ;
3421
3422cfa_abstract_tuple:                                                                             // CFA
3423        '[' push cfa_abstract_parameter_list pop ']'
3424                { $$ = DeclarationNode::newTuple( $3 ); }
3425        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3426                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3427        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3428                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3429        ;
3430
3431cfa_abstract_function:                                                                  // CFA
3432//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3433//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3434        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3435                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3436        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3437                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3438        ;
3439
3440// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3441//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3442//
3443// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3444//    the declaration specifiers in a declaration is an obsolescent feature."
3445//
3446// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3447//    prototype-format parameter type declarators) is an obsolescent feature."
3448//
3449// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3450//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3451
3452//************************* MISCELLANEOUS ********************************
3453
3454comma_opt:                                                                                              // redundant comma
3455        // empty
3456        | ','
3457        ;
3458
3459default_initialize_opt:
3460        // empty
3461                { $$ = nullptr; }
3462        | '=' assignment_expression
3463                { $$ = $2; }
3464        ;
3465
3466%%
3467
3468// ----end of grammar----
3469
3470// Local Variables: //
3471// mode: c++ //
3472// tab-width: 4 //
3473// compile-command: "make install" //
3474// End: //
Note: See TracBrowser for help on using the repository browser.