source: src/Parser/parser.yy @ 60a8062

arm-ehjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-expr
Last change on this file since 60a8062 was 60a8062, checked in by Peter A. Buhr <pabuhr@…>, 22 months ago

rewrite most of OperatorTable? and change caller modules to use new interface

  • Property mode set to 100644
File size: 135.5 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sun Feb 16 08:22:14 2020
13// Update Count     : 4461
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169        *name = string("__postfix_func_") + *name;
170        return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210        } // if
211} // forCtrl
212
213bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
217if ( N ) {                                                                                                                                              \
218        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
219        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
220        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
221        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
222        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
223} else {                                                                                                                                                \
224        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
225        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
226        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234        Token tok;
235        ParseNode * pn;
236        ExpressionNode * en;
237        DeclarationNode * decl;
238        AggregateDecl::Aggregate aggKey;
239        TypeDecl::Kind tclass;
240        StatementNode * sn;
241        WaitForStmt * wfs;
242        Expression * constant;
243        IfCtrl * ifctl;
244        ForCtrl * fctl;
245        enum OperKinds compop;
246        LabelNode * label;
247        InitializerNode * in;
248        OperKinds op;
249        std::string * str;
250        bool flag;
251        CatchStmt::Kind catch_kind;
252        GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL                                                                              // C11
261%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN                                                                                 // C11
263%token CONST VOLATILE
264%token RESTRICT                                                                                 // C99
265%token ATOMIC                                                                                   // C11
266%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY                                                   // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T                                                                             // CFA
272%token VALIST                                                                                   // GCC
273%token AUTO_TYPE                                                                                // GCC
274%token TYPEOF BASETYPEOF LABEL                                                  // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION                                                                                // CFA
277%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
279%token SIZEOF OFFSETOF
280// %token SUSPEND RESUME                                                                        // CFA
281%token ATTRIBUTE EXTENSION                                                              // GCC
282%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
283%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
284%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
285%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
286
287// names and constants: lexer differentiates between identifier and typedef names
288%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
289%token<tok> TIMEOUT                             WOR
290%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
291%token<tok> DIRECTIVE
292// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
293// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
294// converted into the tuple index (.)(1). e.g., 3.x
295%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
296
297// multi-character operators
298%token ARROW                                                                                    // ->
299%token ICR DECR                                                                                 // ++   --
300%token LS RS                                                                                    // <<   >>
301%token LE GE EQ NE                                                                              // <=   >=      ==      !=
302%token ANDAND OROR                                                                              // &&   ||
303%token ELLIPSIS                                                                                 // ...
304
305%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
306%token PLUSassign       MINUSassign                                                     // +=   -=
307%token LSassign         RSassign                                                        // <<=  >>=
308%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
309
310%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
311%token ATassign                                                                                 // @=
312
313%type<tok> identifier
314%type<tok> identifier_or_type_name  attr_name
315%type<tok> quasi_keyword
316%type<constant> string_literal
317%type<str> string_literal_list
318
319// expressions
320%type<en> constant
321%type<en> tuple                                                 tuple_expression_list
322%type<op> ptrref_operator                               unary_operator                          assignment_operator
323%type<en> primary_expression                    postfix_expression                      unary_expression
324%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
325%type<en> shift_expression                              relational_expression           equality_expression
326%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
327%type<en> logical_AND_expression                logical_OR_expression
328%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
329%type<en> comma_expression                              comma_expression_opt
330%type<en> argument_expression_list              argument_expression                     default_initialize_opt
331%type<ifctl> if_control_expression
332%type<fctl> for_control_expression              for_control_expression_list
333%type<compop> inclexcl
334%type<en> subrange
335%type<decl> asm_name_opt
336%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
337%type<label> label_list
338%type<en> asm_clobbers_list_opt
339%type<flag> asm_volatile_opt
340%type<en> handler_predicate_opt
341%type<genexpr> generic_association              generic_assoc_list
342
343// statements
344%type<sn> statement                                             labeled_statement                       compound_statement
345%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
346%type<sn> selection_statement                   if_statement
347%type<sn> switch_clause_list_opt                switch_clause_list
348%type<en> case_value
349%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
350%type<sn> iteration_statement                   jump_statement
351%type<sn> expression_statement                  asm_statement
352%type<sn> with_statement
353%type<en> with_clause_opt
354%type<sn> exception_statement                   handler_clause                          finally_clause
355%type<catch_kind> handler_key
356%type<sn> mutex_statement
357%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
358%type<sn> waitfor_statement
359%type<wfs> waitfor_clause
360
361// declarations
362%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
363%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
364%type<decl> abstract_parameter_declaration
365
366%type<aggKey> aggregate_key aggregate_data aggregate_control
367%type<decl> aggregate_type aggregate_type_nobody
368
369%type<decl> assertion assertion_list assertion_list_opt
370
371%type<en>   bit_subrange_size_opt bit_subrange_size
372
373%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
374
375%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
376
377%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
378%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
379
380%type<decl> elaborated_type elaborated_type_nobody
381
382%type<decl> enumerator_list enum_type enum_type_nobody
383%type<en> enumerator_value_opt
384
385%type<decl> external_definition external_definition_list external_definition_list_opt
386
387%type<decl> exception_declaration
388
389%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
390%type<en> field field_name_list field_name fraction_constants_opt
391
392%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
393
394%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
395%type<decl> identifier_list
396
397%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
398%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
399%type<decl> cfa_abstract_ptr cfa_abstract_tuple
400
401%type<decl> cfa_array_parameter_1st_dimension
402
403%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
404%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
405
406%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
407%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
408
409%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
410
411%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
412
413%type<decl> c_declaration static_assert
414%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
415%type<decl> KR_parameter_list KR_parameter_list_opt
416
417%type<decl> parameter_declaration parameter_list parameter_type_list_opt
418
419%type<decl> paren_identifier paren_type
420
421%type<decl> storage_class storage_class_list
422
423%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
424
425%type<tclass> type_class
426%type<decl> type_declarator type_declarator_name type_declaring_list
427
428%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
429%type<decl> typedef typedef_declaration typedef_expression
430
431%type<decl> variable_type_redeclarator type_ptr type_array type_function
432
433%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
434
435%type<decl> type type_no_function
436%type<decl> type_parameter type_parameter_list type_initializer_opt
437
438%type<en> type_parameters_opt type_list
439
440%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
441%type<decl> type_specifier type_specifier_nobody
442
443%type<decl> variable_declarator variable_ptr variable_array variable_function
444%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
445
446%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
447
448// initializers
449%type<in>  initializer initializer_list_opt initializer_opt
450
451// designators
452%type<en>  designator designator_list designation
453
454
455// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
456//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
457//   if ( C ) S1 else S2
458//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
459// Similar issues exit with the waitfor statement.
460
461// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
462// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
463%precedence THEN        // rule precedence for IF/WAITFOR statement
464%precedence WOR         // token precedence for start of WOR in WAITFOR statement
465%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
466%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
467
468// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
469//   forall( otype T ) struct Foo { T v; };
470//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
471//   Foo ( *fp )( int );
472//   `---'                                              matches start of TYPEGENname '('
473// must be:
474//   Foo( int ) ( *fp )( int );
475// The same problem occurs here:
476//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
477// must be:
478//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
479
480// Order of these lines matters (low-to-high precedence).
481%precedence TYPEGENname
482%precedence '}'
483%precedence '('
484
485// %precedence RESUME
486// %precedence '{'
487// %precedence ')'
488
489%locations                                                                                              // support location tracking for error messages
490
491%start translation_unit                                                                 // parse-tree root
492
493%%
494//************************* Namespace Management ********************************
495
496// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
497// which are lexically identical.
498//
499//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
500//   foo f;           // to allow it to appear in this context
501//
502// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
503// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
504// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
505// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
506// must be distinguished by the lexical scanner.
507//
508// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
509// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
510// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
511// each context that introduces a name scope, a new level is created in the type table and that level is popped on
512// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
513// This requires distinguishing between type names that are local to the current declaration scope and those that
514// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
515//
516// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
517// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
518// around the list separator.
519//
520//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
521//      push               pop   push                   pop
522
523push:
524                { typedefTable.enterScope(); }
525        ;
526
527pop:
528                { typedefTable.leaveScope(); }
529        ;
530
531//************************* CONSTANTS ********************************
532
533constant:
534                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
535        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
536        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
537        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
540        ;
541
542quasi_keyword:                                                                                  // CFA
543        TIMEOUT
544        | WOR
545        ;
546
547identifier:
548        IDENTIFIER
549        | quasi_keyword
550        | '@'                                                                                           // CFA
551                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
552        ;
553
554string_literal:
555        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
556        ;
557
558string_literal_list:                                                                    // juxtaposed strings are concatenated
559        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
560        | string_literal_list STRINGliteral
561                {
562                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
563                        delete $2;                                                                      // allocated by lexer
564                        $$ = $1;                                                                        // conversion from tok to str
565                }
566        ;
567
568//************************* EXPRESSIONS ********************************
569
570primary_expression:
571        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
572                { $$ = new ExpressionNode( build_varref( $1 ) ); }
573        | quasi_keyword
574                { $$ = new ExpressionNode( build_varref( $1 ) ); }
575        | tuple
576        | '(' comma_expression ')'
577                { $$ = $2; }
578        | '(' compound_statement ')'                                            // GCC, lambda expression
579                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
580        | type_name '.' identifier                                                      // CFA, nested type
581                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
582        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
583                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
584        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
585                {
586                        // add the missing control expression to the GenericExpr and return it
587                        $5->control = maybeMoveBuild<Expression>( $3 );
588                        $$ = new ExpressionNode( $5 );
589                }
590        // | RESUME '(' comma_expression ')'
591        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
592        // | RESUME '(' comma_expression ')' compound_statement
593        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
594        ;
595
596generic_assoc_list:                                                                             // C11
597        generic_association
598        | generic_assoc_list ',' generic_association
599                {
600                        // steal the association node from the singleton and delete the wrapper
601                        $1->associations.splice($1->associations.end(), $3->associations);
602                        delete $3;
603                        $$ = $1;
604                }
605        ;
606
607generic_association:                                                                    // C11
608        type_no_function ':' assignment_expression
609                {
610                        // create a GenericExpr wrapper with one association pair
611                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
612                }
613        | DEFAULT ':' assignment_expression
614                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
615        ;
616
617postfix_expression:
618        primary_expression
619        | postfix_expression '[' assignment_expression ']'
620                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
621                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
622                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
623                // equivalent to the old x[i,j].
624                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
625        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
626                {
627                        Token fn;
628                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
629                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
630                }
631        | postfix_expression '(' argument_expression_list ')'
632                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
633        | postfix_expression '`' identifier                                     // CFA, postfix call
634                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
635        | constant '`' identifier                                                       // CFA, postfix call
636                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
637        | string_literal '`' identifier                                         // CFA, postfix call
638                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
639        | postfix_expression '.' identifier
640                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
641        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
642                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
643        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
644                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
645        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
646                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
647        | postfix_expression '.' aggregate_control
648                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
649        | postfix_expression ARROW identifier
650                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
651        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
652                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
653        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
654                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
655        | postfix_expression ICR
656                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
657        | postfix_expression DECR
658                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
659        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
660                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
661        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
662                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
663        | '^' primary_expression '{' argument_expression_list '}' // CFA, destructor call
664                {
665                        Token fn;
666                        fn.str = new string( "^?{}" );                          // location undefined
667                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
668                }
669        ;
670
671argument_expression_list:
672        // empty
673                { $$ = nullptr; }
674        | argument_expression
675        | argument_expression_list ',' argument_expression
676                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
677        ;
678
679argument_expression:
680        '@'                                                                                                     // CFA, default parameter
681                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
682                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
683        | assignment_expression
684        ;
685
686field_name_list:                                                                                // CFA, tuple field selector
687        field
688        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
689        ;
690
691field:                                                                                                  // CFA, tuple field selector
692        field_name
693        | FLOATING_DECIMALconstant field
694                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
695        | FLOATING_DECIMALconstant '[' field_name_list ']'
696                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
697        | field_name '.' field
698                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
699        | field_name '.' '[' field_name_list ']'
700                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
701        | field_name ARROW field
702                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
703        | field_name ARROW '[' field_name_list ']'
704                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
705        ;
706
707field_name:
708        INTEGERconstant fraction_constants_opt
709                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
710        | FLOATINGconstant fraction_constants_opt
711                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
712        | identifier fraction_constants_opt
713                {
714                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
715                }
716        ;
717
718fraction_constants_opt:
719        // empty
720                { $$ = nullptr; }
721        | fraction_constants_opt FLOATING_FRACTIONconstant
722                {
723                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
724                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
725                }
726        ;
727
728unary_expression:
729        postfix_expression
730                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
731                // semantics checks, e.g., ++3, 3--, *3, &&3
732        | constant
733        | string_literal
734                { $$ = new ExpressionNode( $1 ); }
735        | EXTENSION cast_expression                                                     // GCC
736                { $$ = $2->set_extension( true ); }
737                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
738                //              { * X; }         // dereference X
739                //              { * int X; } // CFA declaration of pointer to int
740        | ptrref_operator cast_expression                                       // CFA
741                {
742                        switch ( $1 ) {
743                          case OperKinds::AddressOf:
744                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
745                                break;
746                          case OperKinds::PointTo:
747                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
748                                break;
749                          case OperKinds::And:
750                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
751                                break;
752                          default:
753                                assert( false );
754                        }
755                }
756        | unary_operator cast_expression
757                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
758        | ICR unary_expression
759                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
760        | DECR unary_expression
761                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
762        | SIZEOF unary_expression
763                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
764        | SIZEOF '(' type_no_function ')'
765                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
766        | ALIGNOF unary_expression                                                      // GCC, variable alignment
767                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
768        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
769                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
770        | OFFSETOF '(' type_no_function ',' identifier ')'
771                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
772        ;
773
774ptrref_operator:
775        '*'                                                                                     { $$ = OperKinds::PointTo; }
776        | '&'                                                                           { $$ = OperKinds::AddressOf; }
777                // GCC, address of label must be handled by semantic check for ref,ref,label
778        | ANDAND                                                                        { $$ = OperKinds::And; }
779        ;
780
781unary_operator:
782        '+'                                                                                     { $$ = OperKinds::UnPlus; }
783        | '-'                                                                           { $$ = OperKinds::UnMinus; }
784        | '!'                                                                           { $$ = OperKinds::Neg; }
785        | '~'                                                                           { $$ = OperKinds::BitNeg; }
786        ;
787
788cast_expression:
789        unary_expression
790        | '(' type_no_function ')' cast_expression
791                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
792        | '(' aggregate_control '&' ')' cast_expression         // CFA
793                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
794                // VIRTUAL cannot be opt because of look ahead issues
795        | '(' VIRTUAL ')' cast_expression                                       // CFA
796                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
797        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
798                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
799        | '(' RETURN type_no_function ')' cast_expression       // CFA
800                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
801        | '(' COERCE type_no_function ')' cast_expression       // CFA
802                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
803        | '(' qualifier_cast_list ')' cast_expression           // CFA
804                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
805//      | '(' type_no_function ')' tuple
806//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
807        ;
808
809qualifier_cast_list:
810        cast_modifier type_qualifier_name
811        | cast_modifier MUTEX
812        | qualifier_cast_list cast_modifier type_qualifier_name
813        | qualifier_cast_list cast_modifier MUTEX
814        ;
815
816cast_modifier:
817        '-'
818        | '+'
819        ;
820
821exponential_expression:
822        cast_expression
823        | exponential_expression '\\' cast_expression
824                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
825        ;
826
827multiplicative_expression:
828        exponential_expression
829        | multiplicative_expression '*' exponential_expression
830                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
831        | multiplicative_expression '/' exponential_expression
832                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
833        | multiplicative_expression '%' exponential_expression
834                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
835        ;
836
837additive_expression:
838        multiplicative_expression
839        | additive_expression '+' multiplicative_expression
840                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
841        | additive_expression '-' multiplicative_expression
842                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
843        ;
844
845shift_expression:
846        additive_expression
847        | shift_expression LS additive_expression
848                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
849        | shift_expression RS additive_expression
850                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
851        ;
852
853relational_expression:
854        shift_expression
855        | relational_expression '<' shift_expression
856                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
857        | relational_expression '>' shift_expression
858                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
859        | relational_expression LE shift_expression
860                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
861        | relational_expression GE shift_expression
862                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
863        ;
864
865equality_expression:
866        relational_expression
867        | equality_expression EQ relational_expression
868                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
869        | equality_expression NE relational_expression
870                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
871        ;
872
873AND_expression:
874        equality_expression
875        | AND_expression '&' equality_expression
876                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
877        ;
878
879exclusive_OR_expression:
880        AND_expression
881        | exclusive_OR_expression '^' AND_expression
882                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
883        ;
884
885inclusive_OR_expression:
886        exclusive_OR_expression
887        | inclusive_OR_expression '|' exclusive_OR_expression
888                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
889        ;
890
891logical_AND_expression:
892        inclusive_OR_expression
893        | logical_AND_expression ANDAND inclusive_OR_expression
894                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
895        ;
896
897logical_OR_expression:
898        logical_AND_expression
899        | logical_OR_expression OROR logical_AND_expression
900                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
901        ;
902
903conditional_expression:
904        logical_OR_expression
905        | logical_OR_expression '?' comma_expression ':' conditional_expression
906                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
907                // FIX ME: computes $1 twice
908        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
909                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
910        ;
911
912constant_expression:
913        conditional_expression
914        ;
915
916assignment_expression:
917                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
918        conditional_expression
919        | unary_expression assignment_operator assignment_expression
920                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
921        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
922                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
923        ;
924
925assignment_expression_opt:
926        // empty
927                { $$ = nullptr; }
928        | assignment_expression
929        ;
930
931assignment_operator:
932        '='                                                                                     { $$ = OperKinds::Assign; }
933        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
934        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
935        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
936        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
937        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
938        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
939        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
940        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
941        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
942        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
943        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
944        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
945        ;
946
947tuple:                                                                                                  // CFA, tuple
948                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
949                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
950//      '[' ']'
951//              { $$ = new ExpressionNode( build_tuple() ); }
952//      | '[' push assignment_expression pop ']'
953//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
954        '[' ',' tuple_expression_list ']'
955                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
956        | '[' push assignment_expression pop ',' tuple_expression_list ']'
957                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
958        ;
959
960tuple_expression_list:
961        assignment_expression_opt
962        | tuple_expression_list ',' assignment_expression_opt
963                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
964        ;
965
966comma_expression:
967        assignment_expression
968        | comma_expression ',' assignment_expression
969                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
970        ;
971
972comma_expression_opt:
973        // empty
974                { $$ = nullptr; }
975        | comma_expression
976        ;
977
978//*************************** STATEMENTS *******************************
979
980statement:
981        labeled_statement
982        | compound_statement
983        | expression_statement
984        | selection_statement
985        | iteration_statement
986        | jump_statement
987        | with_statement
988        | mutex_statement
989        | waitfor_statement
990        | exception_statement
991        | enable_disable_statement
992                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
993        | asm_statement
994        | DIRECTIVE
995                { $$ = new StatementNode( build_directive( $1 ) ); }
996        ;
997
998labeled_statement:
999                // labels cannot be identifiers 0 or 1
1000        identifier_or_type_name ':' attribute_list_opt statement
1001                { $$ = $4->add_label( $1, $3 ); }
1002        ;
1003
1004compound_statement:
1005        '{' '}'
1006                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1007        | '{' push
1008          local_label_declaration_opt                                           // GCC, local labels
1009          statement_decl_list                                                           // C99, intermix declarations and statements
1010          pop '}'
1011                { $$ = new StatementNode( build_compound( $4 ) ); }
1012        ;
1013
1014statement_decl_list:                                                                    // C99
1015        statement_decl
1016        | statement_decl_list statement_decl
1017                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1018        ;
1019
1020statement_decl:
1021        declaration                                                                                     // CFA, new & old style declarations
1022                { $$ = new StatementNode( $1 ); }
1023        | EXTENSION declaration                                                         // GCC
1024                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1025        | function_definition
1026                { $$ = new StatementNode( $1 ); }
1027        | EXTENSION function_definition                                         // GCC
1028                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1029        | statement
1030        ;
1031
1032statement_list_nodecl:
1033        statement
1034        | statement_list_nodecl statement
1035                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1036        ;
1037
1038expression_statement:
1039        comma_expression_opt ';'
1040                { $$ = new StatementNode( build_expr( $1 ) ); }
1041        ;
1042
1043selection_statement:
1044                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1045                        // the inherent S/R conflict with THEN/ELSE.
1046        push if_statement pop
1047                { $$ = $2; }
1048        | SWITCH '(' comma_expression ')' case_clause
1049                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1050        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1051                {
1052                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1053                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1054                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1055                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1056                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1057                        // statement.
1058                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1059                }
1060        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1061                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1062        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1063                {
1064                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1065                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1066                }
1067        ;
1068
1069if_statement:
1070        IF '(' if_control_expression ')' statement                      %prec THEN
1071                // explicitly deal with the shift/reduce conflict on if/else
1072                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1073        | IF '(' if_control_expression ')' statement ELSE statement
1074                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1075        ;
1076
1077if_control_expression:
1078        comma_expression
1079                { $$ = new IfCtrl( nullptr, $1 ); }
1080        | c_declaration                                                                         // no semi-colon
1081                { $$ = new IfCtrl( $1, nullptr ); }
1082        | cfa_declaration                                                                       // no semi-colon
1083                { $$ = new IfCtrl( $1, nullptr ); }
1084        | declaration comma_expression                                          // semi-colon separated
1085                { $$ = new IfCtrl( $1, $2 ); }
1086        ;
1087
1088// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1089// clause allows a list of values and subranges.
1090
1091case_value:                                                                                             // CFA
1092        constant_expression                                                     { $$ = $1; }
1093        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1094                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1095        | subrange                                                                                      // CFA, subrange
1096        ;
1097
1098case_value_list:                                                                                // CFA
1099        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1100                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1101        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1102        ;
1103
1104case_label:                                                                                             // CFA
1105        CASE case_value_list ':'                                        { $$ = $2; }
1106        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1107                // A semantic check is required to ensure only one default clause per switch/choose statement.
1108        ;
1109
1110//label_list_opt:
1111//      // empty
1112//      | identifier_or_type_name ':'
1113//      | label_list_opt identifier_or_type_name ':'
1114//      ;
1115
1116case_label_list:                                                                                // CFA
1117        case_label
1118        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1119        ;
1120
1121case_clause:                                                                                    // CFA
1122        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1123        ;
1124
1125switch_clause_list_opt:                                                                 // CFA
1126        // empty
1127                { $$ = nullptr; }
1128        | switch_clause_list
1129        ;
1130
1131switch_clause_list:                                                                             // CFA
1132        case_label_list statement_list_nodecl
1133                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1134        | switch_clause_list case_label_list statement_list_nodecl
1135                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1136        ;
1137
1138iteration_statement:
1139        WHILE '(' push if_control_expression ')' statement pop
1140                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1141        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1142                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1143        | DO statement WHILE '(' comma_expression ')' ';'
1144                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1145        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1146                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1147        | FOR '(' push for_control_expression_list ')' statement pop
1148                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1149        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1150                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1151        ;
1152
1153for_control_expression_list:
1154        for_control_expression
1155        | for_control_expression_list ':' for_control_expression
1156                // ForCtrl + ForCtrl:
1157                //    init + init => multiple declaration statements that are hoisted
1158                //    condition + condition => (expression) && (expression)
1159                //    change + change => (expression), (expression)
1160                {
1161                        $1->init->set_last( $3->init );
1162                        if ( $1->condition ) {
1163                                if ( $3->condition ) {
1164                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1165                                } // if
1166                        } else $1->condition = $3->condition;
1167                        if ( $1->change ) {
1168                                if ( $3->change ) {
1169                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1170                                } // if
1171                        } else $1->change = $3->change;
1172                        $$ = $1;
1173                }
1174        ;
1175
1176for_control_expression:
1177        ';' comma_expression_opt ';' comma_expression_opt
1178                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1179        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1180                { $$ = new ForCtrl( $1, $3, $5 ); }
1181        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1182                { $$ = new ForCtrl( $1, $2, $4 ); }
1183
1184        | comma_expression                                                                      // CFA
1185                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1186                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1187        | '=' comma_expression                                                                  // CFA
1188                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1189                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1190        | comma_expression inclexcl comma_expression            // CFA
1191                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1192        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1193                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1194        | comma_expression ';' comma_expression                         // CFA
1195                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1196                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1197        | comma_expression ';' '=' comma_expression                             // CFA
1198                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1199                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1200        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1201                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1202        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1203                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1204
1205                // There is a S/R conflicit if ~ and -~ are factored out.
1206        | comma_expression ';' comma_expression '~' '@'         // CFA
1207                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1208        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1209                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1210        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1211                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1212        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1213                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1214        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1215                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1216        ;
1217
1218inclexcl:
1219        '~'
1220                { $$ = OperKinds::LThan; }
1221        | ErangeUpEq
1222                { $$ = OperKinds::LEThan; }
1223        | ErangeDown
1224                { $$ = OperKinds::GThan; }
1225        | ErangeDownEq
1226                { $$ = OperKinds::GEThan; }
1227        ;
1228
1229jump_statement:
1230        GOTO identifier_or_type_name ';'
1231                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1232        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1233                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1234                // whereas normal operator precedence yields goto (*i)+3;
1235                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1236                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1237    | fall_through_name ';'                                                             // CFA
1238                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1239    | fall_through_name identifier_or_type_name ';'             // CFA
1240                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1241        | fall_through_name DEFAULT ';'                                         // CFA
1242                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1243        | CONTINUE ';'
1244                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1245                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1246        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1247                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1248                // the target of the transfer appears only at the start of an iteration statement.
1249                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1250        | BREAK ';'
1251                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1252                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1253        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1254                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1255                // the target of the transfer appears only at the start of an iteration statement.
1256                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1257        | RETURN comma_expression_opt ';'
1258                { $$ = new StatementNode( build_return( $2 ) ); }
1259        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1260                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1261        // | SUSPEND ';'
1262        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1263        // | SUSPEND compound_statement ';'
1264        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1265        | THROW assignment_expression_opt ';'                           // handles rethrow
1266                { $$ = new StatementNode( build_throw( $2 ) ); }
1267        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1268                { $$ = new StatementNode( build_resume( $2 ) ); }
1269        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1270                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1271        ;
1272
1273fall_through_name:                                                                              // CFA
1274        FALLTHRU
1275        | FALLTHROUGH
1276        ;
1277
1278with_statement:
1279        WITH '(' tuple_expression_list ')' statement
1280                {
1281                        $$ = new StatementNode( build_with( $3, $5 ) );
1282                }
1283        ;
1284
1285// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1286mutex_statement:
1287        MUTEX '(' argument_expression_list ')' statement
1288                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1289        ;
1290
1291when_clause:
1292        WHEN '(' comma_expression ')'                           { $$ = $3; }
1293        ;
1294
1295when_clause_opt:
1296        // empty
1297                { $$ = nullptr; }
1298        | when_clause
1299        ;
1300
1301waitfor:
1302        WAITFOR '(' cast_expression ')'
1303                { $$ = $3; }
1304//      | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1305//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1306        | WAITFOR '(' cast_expression_list ':' argument_expression_list ')'
1307                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1308        ;
1309
1310cast_expression_list:
1311        cast_expression
1312        | cast_expression_list ',' cast_expression
1313                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1314        ;
1315
1316timeout:
1317        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1318        ;
1319
1320waitfor_clause:
1321        when_clause_opt waitfor statement                                       %prec THEN
1322                { $$ = build_waitfor( $2, $3, $1 ); }
1323        | when_clause_opt waitfor statement WOR waitfor_clause
1324                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1325        | when_clause_opt timeout statement                                     %prec THEN
1326                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1327        | when_clause_opt ELSE statement
1328                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1329                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1330        | when_clause_opt timeout statement WOR ELSE statement
1331                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1332        | when_clause_opt timeout statement WOR when_clause ELSE statement
1333                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1334        ;
1335
1336waitfor_statement:
1337        when_clause_opt waitfor statement                                       %prec THEN
1338                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1339        | when_clause_opt waitfor statement WOR waitfor_clause
1340                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1341        ;
1342
1343exception_statement:
1344        TRY compound_statement handler_clause
1345                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1346        | TRY compound_statement finally_clause
1347                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1348        | TRY compound_statement handler_clause finally_clause
1349                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1350        ;
1351
1352handler_clause:
1353        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1354                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1355        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1356                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1357        ;
1358
1359handler_predicate_opt:
1360        // empty
1361                { $$ = nullptr; }
1362        | ';' conditional_expression                            { $$ = $2; }
1363        ;
1364
1365handler_key:
1366        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1367        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1368        ;
1369
1370finally_clause:
1371        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1372        ;
1373
1374exception_declaration:
1375                // No SUE declaration in parameter list.
1376        type_specifier_nobody
1377        | type_specifier_nobody declarator
1378                { $$ = $2->addType( $1 ); }
1379        | type_specifier_nobody variable_abstract_declarator
1380                { $$ = $2->addType( $1 ); }
1381        | cfa_abstract_declarator_tuple identifier                      // CFA
1382                { $$ = $1->addName( $2 ); }
1383        | cfa_abstract_declarator_tuple                                         // CFA
1384        ;
1385
1386enable_disable_statement:
1387        enable_disable_key identifier_list compound_statement
1388        ;
1389
1390enable_disable_key:
1391        ENABLE
1392        | DISABLE
1393        ;
1394
1395asm_statement:
1396        ASM asm_volatile_opt '(' string_literal ')' ';'
1397                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1398        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1399                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1400        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1401                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1402        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1403                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1404        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1405                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1406        ;
1407
1408asm_volatile_opt:                                                                               // GCC
1409        // empty
1410                { $$ = false; }
1411        | VOLATILE
1412                { $$ = true; }
1413        ;
1414
1415asm_operands_opt:                                                                               // GCC
1416        // empty
1417                { $$ = nullptr; }                                                               // use default argument
1418        | asm_operands_list
1419        ;
1420
1421asm_operands_list:                                                                              // GCC
1422        asm_operand
1423        | asm_operands_list ',' asm_operand
1424                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1425        ;
1426
1427asm_operand:                                                                                    // GCC
1428        string_literal '(' constant_expression ')'
1429                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1430        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1431                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1432        ;
1433
1434asm_clobbers_list_opt:                                                                  // GCC
1435        // empty
1436                { $$ = nullptr; }                                                               // use default argument
1437        | string_literal
1438                { $$ = new ExpressionNode( $1 ); }
1439        | asm_clobbers_list_opt ',' string_literal
1440                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1441        ;
1442
1443label_list:
1444        identifier
1445                {
1446                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1447                        delete $1;                                                                      // allocated by lexer
1448                }
1449        | label_list ',' identifier
1450                {
1451                        $$ = $1; $1->labels.push_back( *$3 );
1452                        delete $3;                                                                      // allocated by lexer
1453                }
1454        ;
1455
1456//******************************* DECLARATIONS *********************************
1457
1458declaration_list_opt:                                                                   // used at beginning of switch statement
1459        // empty
1460                { $$ = nullptr; }
1461        | declaration_list
1462        ;
1463
1464declaration_list:
1465        declaration
1466        | declaration_list declaration
1467                { $$ = $1->appendList( $2 ); }
1468        ;
1469
1470KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1471        // empty
1472                { $$ = nullptr; }
1473        | KR_parameter_list
1474        ;
1475
1476KR_parameter_list:
1477        push c_declaration pop ';'
1478                { $$ = $2; }
1479        | KR_parameter_list push c_declaration pop ';'
1480                { $$ = $1->appendList( $3 ); }
1481        ;
1482
1483local_label_declaration_opt:                                                    // GCC, local label
1484        // empty
1485        | local_label_declaration_list
1486        ;
1487
1488local_label_declaration_list:                                                   // GCC, local label
1489        LABEL local_label_list ';'
1490        | local_label_declaration_list LABEL local_label_list ';'
1491        ;
1492
1493local_label_list:                                                                               // GCC, local label
1494        identifier_or_type_name
1495        | local_label_list ',' identifier_or_type_name
1496        ;
1497
1498declaration:                                                                                    // old & new style declarations
1499        c_declaration ';'
1500        | cfa_declaration ';'                                                           // CFA
1501        | static_assert                                                                         // C11
1502        ;
1503
1504static_assert:
1505        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1506                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1507        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1508                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1509
1510// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1511// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1512// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1513// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1514// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1515// block, but cannot be mixed within a specific declaration.
1516//
1517//                      CFA                                     C
1518//              [10] int x;                     int x[10];              // array of 10 integers
1519//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1520
1521cfa_declaration:                                                                                // CFA
1522        cfa_variable_declaration
1523        | cfa_typedef_declaration
1524        | cfa_function_declaration
1525        | type_declaring_list
1526        | trait_specifier
1527        ;
1528
1529cfa_variable_declaration:                                                               // CFA
1530        cfa_variable_specifier initializer_opt
1531                { $$ = $1->addInitializer( $2 ); }
1532        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1533                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1534                // them as a type_qualifier cannot appear in that context.
1535                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1536        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1537                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1538        ;
1539
1540cfa_variable_specifier:                                                                 // CFA
1541                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1542                // storage-class
1543        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1544                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1545        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1546                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1547        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1548                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1549        ;
1550
1551cfa_function_declaration:                                                               // CFA
1552        cfa_function_specifier
1553        | type_qualifier_list cfa_function_specifier
1554                { $$ = $2->addQualifiers( $1 ); }
1555        | declaration_qualifier_list cfa_function_specifier
1556                { $$ = $2->addQualifiers( $1 ); }
1557        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1558                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1559        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1560                {
1561                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1562                        DeclarationNode * ret = new DeclarationNode;
1563                        ret->type = maybeClone( $1->type->base );
1564                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1565                }
1566        ;
1567
1568cfa_function_specifier:                                                                 // CFA
1569//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1570//              {
1571//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1572//              }
1573//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1574//              {
1575//                      typedefTable.setNextIdentifier( *$5 );
1576//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1577//              }
1578//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1579//              {
1580//                      typedefTable.setNextIdentifier( *$5 );
1581//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1582//              }
1583//      | '[' ']' typegen_name
1584                // identifier_or_type_name must be broken apart because of the sequence:
1585                //
1586                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1587                //   '[' ']' type_specifier
1588                //
1589                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1590                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1591        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1592                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1593                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1594        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1595                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1596        ;
1597
1598cfa_function_return:                                                                    // CFA
1599        '[' push cfa_parameter_list pop ']'
1600                { $$ = DeclarationNode::newTuple( $3 ); }
1601        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1602                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1603                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1604        ;
1605
1606cfa_typedef_declaration:                                                                // CFA
1607        TYPEDEF cfa_variable_specifier
1608                {
1609                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1610                        $$ = $2->addTypedef();
1611                }
1612        | TYPEDEF cfa_function_specifier
1613                {
1614                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1615                        $$ = $2->addTypedef();
1616                }
1617        | cfa_typedef_declaration pop ',' push identifier
1618                {
1619                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1620                        $$ = $1->appendList( $1->cloneType( $5 ) );
1621                }
1622        ;
1623
1624// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1625// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1626
1627typedef_declaration:
1628        TYPEDEF type_specifier declarator
1629                {
1630                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1631                        $$ = $3->addType( $2 )->addTypedef();
1632                }
1633        | typedef_declaration pop ',' push declarator
1634                {
1635                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1636                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1637                }
1638        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1639                {
1640                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1641                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1642                }
1643        | type_specifier TYPEDEF declarator
1644                {
1645                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1646                        $$ = $3->addType( $1 )->addTypedef();
1647                }
1648        | type_specifier TYPEDEF type_qualifier_list declarator
1649                {
1650                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1651                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1652                }
1653        ;
1654
1655typedef_expression:
1656                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1657        TYPEDEF identifier '=' assignment_expression
1658                {
1659                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1660                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1661                }
1662        | typedef_expression pop ',' push identifier '=' assignment_expression
1663                {
1664                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1665                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1666                }
1667        ;
1668
1669//c_declaration:
1670//      declaring_list pop ';'
1671//      | typedef_declaration pop ';'
1672//      | typedef_expression pop ';'                                            // GCC, naming expression type
1673//      | sue_declaration_specifier pop ';'
1674//      ;
1675//
1676//declaring_list:
1677//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1678//              // storage-class
1679//       declarator asm_name_opt initializer_opt
1680//              {
1681//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1682//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1683//              }
1684//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1685//              {
1686//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1687//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1688//              }
1689//      ;
1690
1691c_declaration:
1692        declaration_specifier declaring_list
1693                { $$ = distAttr( $1, $2 ); }
1694        | typedef_declaration
1695        | typedef_expression                                                            // GCC, naming expression type
1696        | sue_declaration_specifier
1697        ;
1698
1699declaring_list:
1700                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1701                // storage-class
1702        declarator asm_name_opt initializer_opt
1703                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1704        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1705                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1706        ;
1707
1708declaration_specifier:                                                                  // type specifier + storage class
1709        basic_declaration_specifier
1710        | sue_declaration_specifier
1711        | type_declaration_specifier
1712        ;
1713
1714declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1715                // Preclude SUE declarations in restricted scopes:
1716                //
1717                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1718                //
1719                // because it is impossible to call f due to name equivalence.
1720        basic_declaration_specifier
1721        | sue_declaration_specifier_nobody
1722        | type_declaration_specifier
1723        ;
1724
1725type_specifier:                                                                                 // type specifier
1726        basic_type_specifier
1727        | sue_type_specifier
1728        | type_type_specifier
1729        ;
1730
1731type_specifier_nobody:                                                                  // type specifier - {...}
1732                // Preclude SUE declarations in restricted scopes:
1733                //
1734                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1735                //
1736                // because it is impossible to call f due to name equivalence.
1737        basic_type_specifier
1738        | sue_type_specifier_nobody
1739        | type_type_specifier
1740        ;
1741
1742type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1743        // empty
1744                { $$ = nullptr; }
1745        | type_qualifier_list
1746        ;
1747
1748type_qualifier_list:
1749                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1750                //
1751                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1752                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1753                // appeared only once.
1754        type_qualifier
1755        | type_qualifier_list type_qualifier
1756                { $$ = $1->addQualifiers( $2 ); }
1757        ;
1758
1759type_qualifier:
1760        type_qualifier_name
1761        | attribute
1762        ;
1763
1764type_qualifier_name:
1765        CONST
1766                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1767        | RESTRICT
1768                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1769        | VOLATILE
1770                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1771        | ATOMIC
1772                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1773        | forall
1774        ;
1775
1776forall:
1777        FORALL '(' type_parameter_list ')'                                      // CFA
1778                { $$ = DeclarationNode::newForall( $3 ); }
1779        ;
1780
1781declaration_qualifier_list:
1782        storage_class_list
1783        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1784                { $$ = $1->addQualifiers( $2 ); }
1785        | declaration_qualifier_list type_qualifier_list storage_class_list
1786                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1787        ;
1788
1789storage_class_list:
1790                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1791                // only one of each is specified, except for inline, which can appear with the others.
1792                //
1793                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1794                // specifiers in a declaration.
1795        storage_class
1796        | storage_class_list storage_class
1797                { $$ = $1->addQualifiers( $2 ); }
1798        ;
1799
1800storage_class:
1801        EXTERN
1802                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1803        | STATIC
1804                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1805        | AUTO
1806                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1807        | REGISTER
1808                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1809        | THREADLOCAL                                                                           // C11
1810                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1811                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1812        | INLINE                                                                                        // C99
1813                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1814        | FORTRAN                                                                                       // C99
1815                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1816        | NORETURN                                                                                      // C11
1817                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1818        ;
1819
1820basic_type_name:
1821        VOID
1822                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1823        | BOOL                                                                                          // C99
1824                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1825        | CHAR
1826                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1827        | INT
1828                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1829        | INT128
1830                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1831        | UINT128
1832                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1833        | FLOAT
1834                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1835        | DOUBLE
1836                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1837        | uuFLOAT80
1838                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1839        | uuFLOAT128
1840                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1841        | uFLOAT16
1842                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1843        | uFLOAT32
1844                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1845        | uFLOAT32X
1846                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1847        | uFLOAT64
1848                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1849        | uFLOAT64X
1850                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1851        | uFLOAT128
1852                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1853        | COMPLEX                                                                                       // C99
1854                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1855        | IMAGINARY                                                                                     // C99
1856                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1857        | SIGNED
1858                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1859        | UNSIGNED
1860                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1861        | SHORT
1862                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1863        | LONG
1864                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1865        | VALIST                                                                                        // GCC, __builtin_va_list
1866                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1867        | AUTO_TYPE
1868                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1869        ;
1870
1871basic_declaration_specifier:
1872                // A semantic check is necessary for conflicting storage classes.
1873        basic_type_specifier
1874        | declaration_qualifier_list basic_type_specifier
1875                { $$ = $2->addQualifiers( $1 ); }
1876        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1877                { $$ = $1->addQualifiers( $2 ); }
1878        | basic_declaration_specifier storage_class type_qualifier_list
1879                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1880        | basic_declaration_specifier storage_class basic_type_specifier
1881                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1882        ;
1883
1884basic_type_specifier:
1885        direct_type
1886                // Cannot have type modifiers, e.g., short, long, etc.
1887        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1888                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1889        ;
1890
1891direct_type:
1892        basic_type_name
1893        | type_qualifier_list basic_type_name
1894                { $$ = $2->addQualifiers( $1 ); }
1895        | direct_type type_qualifier
1896                { $$ = $1->addQualifiers( $2 ); }
1897        | direct_type basic_type_name
1898                { $$ = $1->addType( $2 ); }
1899        ;
1900
1901indirect_type:
1902        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1903                { $$ = $3; }
1904        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1905                { $$ = DeclarationNode::newTypeof( $3 ); }
1906        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1907                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1908        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1909                { $$ = DeclarationNode::newTypeof( $3, true ); }
1910        | ZERO_T                                                                                        // CFA
1911                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1912        | ONE_T                                                                                         // CFA
1913                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1914        ;
1915
1916sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1917        sue_type_specifier
1918        | declaration_qualifier_list sue_type_specifier
1919                { $$ = $2->addQualifiers( $1 ); }
1920        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1921                { $$ = $1->addQualifiers( $2 ); }
1922        | sue_declaration_specifier storage_class type_qualifier_list
1923                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1924        ;
1925
1926sue_type_specifier:                                                                             // struct, union, enum + type specifier
1927        elaborated_type
1928        | type_qualifier_list
1929                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1930          elaborated_type
1931                { $$ = $3->addQualifiers( $1 ); }
1932        | sue_type_specifier type_qualifier
1933                {
1934                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1935                        $$ = $1->addQualifiers( $2 );
1936                }
1937        ;
1938
1939sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1940        sue_type_specifier_nobody
1941        | declaration_qualifier_list sue_type_specifier_nobody
1942                { $$ = $2->addQualifiers( $1 ); }
1943        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1944                { $$ = $1->addQualifiers( $2 ); }
1945        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1946                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1947        ;
1948
1949sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1950        elaborated_type_nobody
1951        | type_qualifier_list elaborated_type_nobody
1952                { $$ = $2->addQualifiers( $1 ); }
1953        | sue_type_specifier_nobody type_qualifier
1954                { $$ = $1->addQualifiers( $2 ); }
1955        ;
1956
1957type_declaration_specifier:
1958        type_type_specifier
1959        | declaration_qualifier_list type_type_specifier
1960                { $$ = $2->addQualifiers( $1 ); }
1961        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1962                { $$ = $1->addQualifiers( $2 ); }
1963        | type_declaration_specifier storage_class type_qualifier_list
1964                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1965        ;
1966
1967type_type_specifier:                                                                    // typedef types
1968        type_name
1969        | type_qualifier_list type_name
1970                { $$ = $2->addQualifiers( $1 ); }
1971        | type_type_specifier type_qualifier
1972                { $$ = $1->addQualifiers( $2 ); }
1973        ;
1974
1975type_name:
1976        TYPEDEFname
1977                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1978        | '.' TYPEDEFname
1979                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1980        | type_name '.' TYPEDEFname
1981                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1982        | typegen_name
1983        | '.' typegen_name
1984                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1985        | type_name '.' typegen_name
1986                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1987        ;
1988
1989typegen_name:                                                                                   // CFA
1990        TYPEGENname
1991                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1992        | TYPEGENname '(' ')'
1993                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1994        | TYPEGENname '(' type_list ')'
1995                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1996        ;
1997
1998elaborated_type:                                                                                // struct, union, enum
1999        aggregate_type
2000        | enum_type
2001        ;
2002
2003elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2004        aggregate_type_nobody
2005        | enum_type_nobody
2006        ;
2007
2008fred:
2009        // empty
2010                { yyy = false; }
2011        ;
2012
2013aggregate_type:                                                                                 // struct, union
2014        aggregate_key attribute_list_opt
2015                { forall = false; }                                                             // reset
2016          '{' field_declaration_list_opt '}' type_parameters_opt
2017                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2018        | aggregate_key attribute_list_opt identifier fred
2019                {
2020                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2021                        forall = false;                                                         // reset
2022                }
2023          '{' field_declaration_list_opt '}' type_parameters_opt
2024                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2025        | aggregate_key attribute_list_opt type_name fred
2026                {
2027                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2028                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2029                        forall = false;                                                         // reset
2030                }
2031          '{' field_declaration_list_opt '}' type_parameters_opt
2032                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2033        | aggregate_type_nobody
2034        ;
2035
2036type_parameters_opt:
2037        // empty
2038                { $$ = nullptr; }                                                               %prec '}'
2039        | '(' type_list ')'
2040                { $$ = $2; }
2041        ;
2042
2043aggregate_type_nobody:                                                                  // struct, union - {...}
2044        aggregate_key attribute_list_opt identifier fred
2045                {
2046                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2047                        forall = false;                                                         // reset
2048                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2049                }
2050        | aggregate_key attribute_list_opt type_name fred
2051                {
2052                        forall = false;                                                         // reset
2053                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2054                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2055                        // delete newFromTypeGen.
2056                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2057                        $3->type->symbolic.name = nullptr;
2058                        $3->type->symbolic.actuals = nullptr;
2059                        delete $3;
2060                }
2061        ;
2062
2063aggregate_key:
2064        aggregate_data
2065        | aggregate_control
2066        ;
2067
2068aggregate_data:
2069        STRUCT
2070                { yyy = true; $$ = AggregateDecl::Struct; }
2071        | UNION
2072                { yyy = true; $$ = AggregateDecl::Union; }
2073        | EXCEPTION                                                                                     // CFA
2074                { yyy = true; $$ = AggregateDecl::Exception; }
2075        ;
2076
2077aggregate_control:                                                                              // CFA
2078        GENERATOR
2079                { yyy = true; $$ = AggregateDecl::Coroutine; }
2080        | COROUTINE
2081                { yyy = true; $$ = AggregateDecl::Coroutine; }
2082        | MONITOR
2083                { yyy = true; $$ = AggregateDecl::Monitor; }
2084        | THREAD
2085                { yyy = true; $$ = AggregateDecl::Thread; }
2086        ;
2087
2088field_declaration_list_opt:
2089        // empty
2090                { $$ = nullptr; }
2091        | field_declaration_list_opt field_declaration
2092                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2093        ;
2094
2095field_declaration:
2096        type_specifier field_declaring_list_opt ';'
2097                { $$ = fieldDecl( $1, $2 ); }
2098        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2099                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2100        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2101                {
2102                        if ( ! $3 ) {                                                           // field declarator ?
2103                                $3 = DeclarationNode::newName( nullptr );
2104                        } // if
2105                        $3->inLine = true;
2106                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2107                        distInl( $3 );
2108                }
2109        | INLINE aggregate_control ';'                                          // CFA
2110                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2111        | typedef_declaration ';'                                                       // CFA
2112        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2113        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2114                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2115        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2116                { $$ = $2; }                                                                    // mark all fields in list
2117        | cfa_typedef_declaration ';'                                           // CFA
2118        | static_assert                                                                         // C11
2119        ;
2120
2121field_declaring_list_opt:
2122        // empty
2123                { $$ = nullptr; }
2124        | field_declarator
2125        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2126                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2127        ;
2128
2129field_declarator:
2130        bit_subrange_size                                                                       // C special case, no field name
2131                { $$ = DeclarationNode::newBitfield( $1 ); }
2132        | variable_declarator bit_subrange_size_opt
2133                // A semantic check is required to ensure bit_subrange only appears on integral types.
2134                { $$ = $1->addBitfield( $2 ); }
2135        | variable_type_redeclarator bit_subrange_size_opt
2136                // A semantic check is required to ensure bit_subrange only appears on integral types.
2137                { $$ = $1->addBitfield( $2 ); }
2138        ;
2139
2140field_abstract_list_opt:
2141        // empty
2142                { $$ = nullptr; }
2143        | field_abstract
2144        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2145                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2146        ;
2147
2148field_abstract:
2149                //      no bit fields
2150        variable_abstract_declarator
2151        ;
2152
2153cfa_field_declaring_list:                                                               // CFA, new style field declaration
2154        // bit-fields are handled by C declarations
2155        cfa_abstract_declarator_tuple identifier_or_type_name
2156                { $$ = $1->addName( $2 ); }
2157        | cfa_field_declaring_list ',' identifier_or_type_name
2158                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2159        ;
2160
2161cfa_field_abstract_list:                                                                // CFA, new style field declaration
2162        // bit-fields are handled by C declarations
2163        cfa_abstract_declarator_tuple
2164        | cfa_field_abstract_list ','
2165                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2166        ;
2167
2168bit_subrange_size_opt:
2169        // empty
2170                { $$ = nullptr; }
2171        | bit_subrange_size
2172        ;
2173
2174bit_subrange_size:
2175        ':' assignment_expression
2176                { $$ = $2; }
2177        ;
2178
2179enum_type:                                                                                              // enum
2180        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2181                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2182        | ENUM attribute_list_opt identifier
2183                { typedefTable.makeTypedef( *$3 ); }
2184          '{' enumerator_list comma_opt '}'
2185                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2186        | ENUM attribute_list_opt type_name
2187          '{' enumerator_list comma_opt '}'
2188                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2189        | enum_type_nobody
2190        ;
2191
2192enum_type_nobody:                                                                               // enum - {...}
2193        ENUM attribute_list_opt identifier
2194                {
2195                        typedefTable.makeTypedef( *$3 );
2196                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2197                }
2198        | ENUM attribute_list_opt type_name
2199                {
2200                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2201                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2202                }
2203        ;
2204
2205enumerator_list:
2206        identifier_or_type_name enumerator_value_opt
2207                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2208        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2209                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2210        ;
2211
2212enumerator_value_opt:
2213        // empty
2214                { $$ = nullptr; }
2215        | '=' constant_expression
2216                { $$ = $2; }
2217        ;
2218
2219cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2220        // empty
2221                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2222        | ELLIPSIS
2223                { $$ = nullptr; }
2224        | cfa_abstract_parameter_list
2225        | cfa_parameter_list
2226        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2227                { $$ = $1->appendList( $5 ); }
2228        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2229                { $$ = $1->addVarArgs(); }
2230        | cfa_parameter_list pop ',' push ELLIPSIS
2231                { $$ = $1->addVarArgs(); }
2232        ;
2233
2234cfa_parameter_list:                                                                             // CFA
2235                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2236                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2237        cfa_parameter_declaration
2238        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2239                { $$ = $1->appendList( $5 ); }
2240        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2241                { $$ = $1->appendList( $5 ); }
2242        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2243                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2244        ;
2245
2246cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2247        cfa_abstract_parameter_declaration
2248        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2249                { $$ = $1->appendList( $5 ); }
2250        ;
2251
2252parameter_type_list_opt:
2253        // empty
2254                { $$ = nullptr; }
2255        | ELLIPSIS
2256                { $$ = nullptr; }
2257        | parameter_list
2258        | parameter_list pop ',' push ELLIPSIS
2259                { $$ = $1->addVarArgs(); }
2260        ;
2261
2262parameter_list:                                                                                 // abstract + real
2263        abstract_parameter_declaration
2264        | parameter_declaration
2265        | parameter_list pop ',' push abstract_parameter_declaration
2266                { $$ = $1->appendList( $5 ); }
2267        | parameter_list pop ',' push parameter_declaration
2268                { $$ = $1->appendList( $5 ); }
2269        ;
2270
2271// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2272// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2273
2274cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2275        parameter_declaration
2276        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2277                { $$ = $1->addName( $2 ); }
2278        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2279                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2280                { $$ = $1->addName( $2 ); }
2281        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2282                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2283        | cfa_function_specifier
2284        ;
2285
2286cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2287        abstract_parameter_declaration
2288        | cfa_identifier_parameter_declarator_no_tuple
2289        | cfa_abstract_tuple
2290                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2291        | type_qualifier_list cfa_abstract_tuple
2292                { $$ = $2->addQualifiers( $1 ); }
2293        | cfa_abstract_function
2294        ;
2295
2296parameter_declaration:
2297                // No SUE declaration in parameter list.
2298        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2299                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2300        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2301                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2302        ;
2303
2304abstract_parameter_declaration:
2305        declaration_specifier_nobody default_initialize_opt
2306                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2307        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2308                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2309        ;
2310
2311// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2312// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2313// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2314
2315identifier_list:                                                                                // K&R-style parameter list => no types
2316        identifier
2317                { $$ = DeclarationNode::newName( $1 ); }
2318        | identifier_list ',' identifier
2319                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2320        ;
2321
2322identifier_or_type_name:
2323        identifier
2324        | TYPEDEFname
2325        | TYPEGENname
2326        ;
2327
2328type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2329        cfa_abstract_declarator_tuple                                           // CFA
2330        | type_specifier
2331        | type_specifier abstract_declarator
2332                { $$ = $2->addType( $1 ); }
2333        ;
2334
2335type:                                                                                                   // typeof, assertion
2336        type_no_function
2337        | cfa_abstract_function                                                         // CFA
2338        ;
2339
2340initializer_opt:
2341        // empty
2342                { $$ = nullptr; }
2343        | '=' initializer
2344                { $$ = $2; }
2345        | '=' VOID
2346                { $$ = new InitializerNode( true ); }
2347        | ATassign initializer
2348                { $$ = $2->set_maybeConstructed( false ); }
2349        ;
2350
2351initializer:
2352        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2353        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2354        ;
2355
2356initializer_list_opt:
2357        // empty
2358                { $$ = nullptr; }
2359        | initializer
2360        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2361        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2362        | initializer_list_opt ',' designation initializer
2363                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2364        ;
2365
2366// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2367// '=' to separator the designator from the initializer value, as in:
2368//
2369//              int x[10] = { [1] = 3 };
2370//
2371// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2372// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2373// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2374// shift/reduce conflicts
2375
2376designation:
2377        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2378        | identifier ':'                                                                        // GCC, field name
2379                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2380        ;
2381
2382designator_list:                                                                                // C99
2383        designator
2384        | designator_list designator
2385                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2386        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2387        ;
2388
2389designator:
2390        '.' identifier                                                                          // C99, field name
2391                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2392        | '[' push assignment_expression pop ']'                        // C99, single array element
2393                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2394                { $$ = $3; }
2395        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2396                { $$ = $3; }
2397        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2398                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2399        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2400                { $$ = $4; }
2401        ;
2402
2403// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2404// rather than an object-oriented type system. This required four groups of extensions:
2405//
2406// Overloading: function, data, and operator identifiers may be overloaded.
2407//
2408// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2409//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2410//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2411//
2412// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2413//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2414//
2415// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2416//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2417//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2418//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2419//     on type arguments of polymorphic functions.
2420
2421type_parameter_list:                                                                    // CFA
2422        type_parameter
2423        | type_parameter_list ',' type_parameter
2424                { $$ = $1->appendList( $3 ); }
2425        ;
2426
2427type_initializer_opt:                                                                   // CFA
2428        // empty
2429                { $$ = nullptr; }
2430        | '=' type
2431                { $$ = $2; }
2432        ;
2433
2434type_parameter:                                                                                 // CFA
2435        type_class identifier_or_type_name
2436                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2437          type_initializer_opt assertion_list_opt
2438                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2439        | type_specifier identifier_parameter_declarator
2440        | assertion_list
2441                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2442        ;
2443
2444type_class:                                                                                             // CFA
2445        OTYPE
2446                { $$ = TypeDecl::Otype; }
2447        | DTYPE
2448                { $$ = TypeDecl::Dtype; }
2449        | FTYPE
2450                { $$ = TypeDecl::Ftype; }
2451        | TTYPE
2452                { $$ = TypeDecl::Ttype; }
2453        ;
2454
2455assertion_list_opt:                                                                             // CFA
2456        // empty
2457                { $$ = nullptr; }
2458        | assertion_list
2459        ;
2460
2461assertion_list:                                                                                 // CFA
2462        assertion
2463        | assertion_list assertion
2464                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2465        ;
2466
2467assertion:                                                                                              // CFA
2468        '|' identifier_or_type_name '(' type_list ')'
2469                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2470        | '|' '{' push trait_declaration_list pop '}'
2471                { $$ = $4; }
2472        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2473        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2474        ;
2475
2476type_list:                                                                                              // CFA
2477        type
2478                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2479        | assignment_expression
2480                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2481        | type_list ',' type
2482                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2483        | type_list ',' assignment_expression
2484                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2485                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2486        ;
2487
2488type_declaring_list:                                                                    // CFA
2489        OTYPE type_declarator
2490                { $$ = $2; }
2491        | storage_class_list OTYPE type_declarator
2492                { $$ = $3->addQualifiers( $1 ); }
2493        | type_declaring_list ',' type_declarator
2494                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2495        ;
2496
2497type_declarator:                                                                                // CFA
2498        type_declarator_name assertion_list_opt
2499                { $$ = $1->addAssertions( $2 ); }
2500        | type_declarator_name assertion_list_opt '=' type
2501                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2502        ;
2503
2504type_declarator_name:                                                                   // CFA
2505        identifier_or_type_name
2506                {
2507                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2508                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2509                }
2510        | identifier_or_type_name '(' type_parameter_list ')'
2511                {
2512                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2513                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2514                }
2515        ;
2516
2517trait_specifier:                                                                                // CFA
2518        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2519                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2520        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2521                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2522        ;
2523
2524trait_declaration_list:                                                                 // CFA
2525        trait_declaration
2526        | trait_declaration_list pop push trait_declaration
2527                { $$ = $1->appendList( $4 ); }
2528        ;
2529
2530trait_declaration:                                                                              // CFA
2531        cfa_trait_declaring_list ';'
2532        | trait_declaring_list ';'
2533        ;
2534
2535cfa_trait_declaring_list:                                                               // CFA
2536        cfa_variable_specifier
2537        | cfa_function_specifier
2538        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2539                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2540        ;
2541
2542trait_declaring_list:                                                                   // CFA
2543        type_specifier declarator
2544                { $$ = $2->addType( $1 ); }
2545        | trait_declaring_list pop ',' push declarator
2546                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2547        ;
2548
2549//***************************** EXTERNAL DEFINITIONS *****************************
2550
2551translation_unit:
2552        // empty, input file
2553        | external_definition_list
2554                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2555        ;
2556
2557external_definition_list:
2558        push external_definition pop
2559                { $$ = $2; }
2560        | external_definition_list push external_definition pop
2561                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2562        ;
2563
2564external_definition_list_opt:
2565        // empty
2566                { $$ = nullptr; }
2567        | external_definition_list
2568        ;
2569
2570up:
2571                { typedefTable.up( forall ); forall = false; }
2572        ;
2573
2574down:
2575                { typedefTable.down(); }
2576        ;
2577
2578external_definition:
2579        declaration
2580        | external_function_definition
2581        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2582                {
2583                        distExt( $2 );                                                          // mark all fields in list
2584                        $$ = $2;
2585                }
2586        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2587                {
2588                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2589                }
2590        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2591                {
2592                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2593                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2594                }
2595          '{' up external_definition_list_opt down '}'
2596                {
2597                        linkage = linkageStack.top();
2598                        linkageStack.pop();
2599                        $$ = $6;
2600                }
2601        | type_qualifier_list
2602                {
2603                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2604                        if ( $1->type->forall ) forall = true;          // remember generic type
2605                }
2606          '{' up external_definition_list_opt down '}'          // CFA, namespace
2607                {
2608                        distQual( $5, $1 );
2609                        forall = false;
2610                        $$ = $5;
2611                }
2612        | declaration_qualifier_list
2613                {
2614                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2615                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2616                }
2617          '{' up external_definition_list_opt down '}'          // CFA, namespace
2618                {
2619                        distQual( $5, $1 );
2620                        forall = false;
2621                        $$ = $5;
2622                }
2623        | declaration_qualifier_list type_qualifier_list
2624                {
2625                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2626                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2627                }
2628          '{' up external_definition_list_opt down '}'          // CFA, namespace
2629                {
2630                        distQual( $6, $1->addQualifiers( $2 ) );
2631                        forall = false;
2632                        $$ = $6;
2633                }
2634        ;
2635
2636external_function_definition:
2637        function_definition
2638                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2639                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2640                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2641                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2642                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2643        | function_declarator compound_statement
2644                { $$ = $1->addFunctionBody( $2 ); }
2645        | KR_function_declarator KR_parameter_list_opt compound_statement
2646                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2647        ;
2648
2649with_clause_opt:
2650        // empty
2651                { $$ = nullptr; forall = false; }
2652        | WITH '(' tuple_expression_list ')'
2653                { $$ = $3; forall = false; }
2654        ;
2655
2656function_definition:
2657        cfa_function_declaration with_clause_opt compound_statement     // CFA
2658                {
2659                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2660                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2661                        $1->get_last()->addFunctionBody( $3, $2 );
2662                        $$ = $1;
2663                }
2664        | declaration_specifier function_declarator with_clause_opt compound_statement
2665                {
2666                        rebindForall( $1, $2 );
2667                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2668                }
2669        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2670                {
2671                        rebindForall( $1, $2 );
2672                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2673                }
2674                // handles default int return type, OBSOLESCENT (see 1)
2675        | type_qualifier_list function_declarator with_clause_opt compound_statement
2676                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2677                // handles default int return type, OBSOLESCENT (see 1)
2678        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2679                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2680                // handles default int return type, OBSOLESCENT (see 1)
2681        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2682                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2683
2684                // Old-style K&R function definition, OBSOLESCENT (see 4)
2685        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2686                {
2687                        rebindForall( $1, $2 );
2688                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2689                }
2690                // handles default int return type, OBSOLESCENT (see 1)
2691        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2692                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2693                // handles default int return type, OBSOLESCENT (see 1)
2694        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2695                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2696                // handles default int return type, OBSOLESCENT (see 1)
2697        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2698                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2699        ;
2700
2701declarator:
2702        variable_declarator
2703        | variable_type_redeclarator
2704        | function_declarator
2705        ;
2706
2707subrange:
2708        constant_expression '~' constant_expression                     // CFA, integer subrange
2709                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2710        ;
2711
2712asm_name_opt:                                                                                   // GCC
2713        // empty
2714                { $$ = nullptr; }
2715        | ASM '(' string_literal ')' attribute_list_opt
2716                {
2717                        DeclarationNode * name = new DeclarationNode();
2718                        name->asmName = $3;
2719                        $$ = name->addQualifiers( $5 );
2720                }
2721        ;
2722
2723attribute_list_opt:                                                                             // GCC
2724        // empty
2725                { $$ = nullptr; }
2726        | attribute_list
2727        ;
2728
2729attribute_list:                                                                                 // GCC
2730        attribute
2731        | attribute_list attribute
2732                { $$ = $2->addQualifiers( $1 ); }
2733        ;
2734
2735attribute:                                                                                              // GCC
2736        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2737                { $$ = $4; }
2738        ;
2739
2740attribute_name_list:                                                                    // GCC
2741        attribute_name
2742        | attribute_name_list ',' attribute_name
2743                { $$ = $3->addQualifiers( $1 ); }
2744        ;
2745
2746attribute_name:                                                                                 // GCC
2747        // empty
2748                { $$ = nullptr; }
2749        | attr_name
2750                { $$ = DeclarationNode::newAttribute( $1 ); }
2751        | attr_name '(' argument_expression_list ')'
2752                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2753        ;
2754
2755attr_name:                                                                                              // GCC
2756        IDENTIFIER
2757        | quasi_keyword
2758        | TYPEDEFname
2759        | TYPEGENname
2760        | FALLTHROUGH
2761                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2762        | CONST
2763                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2764        ;
2765
2766// ============================================================================
2767// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2768// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2769// in:
2770//
2771//              int (*f())[10] { ... };
2772//              ... (*f())[3] += 1;             // definition mimics usage
2773//
2774// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2775// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2776// ============================================================================
2777
2778// ----------------------------------------------------------------------------
2779// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2780// to define a variable or function prototype, e.g.:
2781//
2782//              valid declaration               invalid definition
2783//              -----------------               ------------------
2784//              int f;                                  int f {}
2785//              int *f;                                 int *f {}
2786//              int f[10];                              int f[10] {}
2787//              int (*f)(int);                  int (*f)(int) {}
2788//
2789// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2790// variable_declarator and function_declarator.
2791// ----------------------------------------------------------------------------
2792
2793// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2794// declaring an array of functions versus a pointer to an array of functions.
2795
2796variable_declarator:
2797        paren_identifier attribute_list_opt
2798                { $$ = $1->addQualifiers( $2 ); }
2799        | variable_ptr
2800        | variable_array attribute_list_opt
2801                { $$ = $1->addQualifiers( $2 ); }
2802        | variable_function attribute_list_opt
2803                { $$ = $1->addQualifiers( $2 ); }
2804        ;
2805
2806paren_identifier:
2807        identifier
2808                { $$ = DeclarationNode::newName( $1 ); }
2809        | '(' paren_identifier ')'                                                      // redundant parenthesis
2810                { $$ = $2; }
2811        ;
2812
2813variable_ptr:
2814        ptrref_operator variable_declarator
2815                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2816        | ptrref_operator type_qualifier_list variable_declarator
2817                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2818        | '(' variable_ptr ')' attribute_list_opt
2819                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2820        ;
2821
2822variable_array:
2823        paren_identifier array_dimension
2824                { $$ = $1->addArray( $2 ); }
2825        | '(' variable_ptr ')' array_dimension
2826                { $$ = $2->addArray( $4 ); }
2827        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2828                { $$ = $2->addArray( $4 ); }
2829        | '(' variable_array ')'                                                        // redundant parenthesis
2830                { $$ = $2; }
2831        ;
2832
2833variable_function:
2834        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2835                { $$ = $2->addParamList( $6 ); }
2836        | '(' variable_function ')'                                                     // redundant parenthesis
2837                { $$ = $2; }
2838        ;
2839
2840// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2841// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2842// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2843
2844function_declarator:
2845        function_no_ptr attribute_list_opt
2846                { $$ = $1->addQualifiers( $2 ); }
2847        | function_ptr
2848        | function_array attribute_list_opt
2849                { $$ = $1->addQualifiers( $2 ); }
2850        ;
2851
2852function_no_ptr:
2853        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2854                { $$ = $1->addParamList( $4 ); }
2855        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2856                { $$ = $2->addParamList( $6 ); }
2857        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2858                { $$ = $2; }
2859        ;
2860
2861function_ptr:
2862        ptrref_operator function_declarator
2863                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2864        | ptrref_operator type_qualifier_list function_declarator
2865                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2866        | '(' function_ptr ')'
2867                { $$ = $2; }
2868        ;
2869
2870function_array:
2871        '(' function_ptr ')' array_dimension
2872                { $$ = $2->addArray( $4 ); }
2873        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2874                { $$ = $2->addArray( $4 ); }
2875        | '(' function_array ')'                                                        // redundant parenthesis
2876                { $$ = $2; }
2877        ;
2878
2879// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2880//
2881//   f( a, b, c ) int a, *b, c[]; {}
2882//
2883// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2884// returning arrays and functions versus pointers to arrays and functions.
2885
2886KR_function_declarator:
2887        KR_function_no_ptr
2888        | KR_function_ptr
2889        | KR_function_array
2890        ;
2891
2892KR_function_no_ptr:
2893        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2894                { $$ = $1->addIdList( $3 ); }
2895        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2896                { $$ = $2->addParamList( $6 ); }
2897        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2898                { $$ = $2; }
2899        ;
2900
2901KR_function_ptr:
2902        ptrref_operator KR_function_declarator
2903                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2904        | ptrref_operator type_qualifier_list KR_function_declarator
2905                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2906        | '(' KR_function_ptr ')'
2907                { $$ = $2; }
2908        ;
2909
2910KR_function_array:
2911        '(' KR_function_ptr ')' array_dimension
2912                { $$ = $2->addArray( $4 ); }
2913        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2914                { $$ = $2->addArray( $4 ); }
2915        | '(' KR_function_array ')'                                                     // redundant parenthesis
2916                { $$ = $2; }
2917        ;
2918
2919// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2920//
2921//              typedef int foo;
2922//              {
2923//                 int foo; // redefine typedef name in new scope
2924//              }
2925//
2926// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2927// and functions versus pointers to arrays and functions.
2928
2929variable_type_redeclarator:
2930        paren_type attribute_list_opt
2931                { $$ = $1->addQualifiers( $2 ); }
2932        | type_ptr
2933        | type_array attribute_list_opt
2934                { $$ = $1->addQualifiers( $2 ); }
2935        | type_function attribute_list_opt
2936                { $$ = $1->addQualifiers( $2 ); }
2937        ;
2938
2939paren_type:
2940        typedef
2941                // hide type name in enclosing scope by variable name
2942                {
2943                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2944                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2945                        // } else {
2946                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2947                        // } // if
2948                }
2949        | '(' paren_type ')'
2950                { $$ = $2; }
2951        ;
2952
2953type_ptr:
2954        ptrref_operator variable_type_redeclarator
2955                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2956        | ptrref_operator type_qualifier_list variable_type_redeclarator
2957                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2958        | '(' type_ptr ')' attribute_list_opt
2959                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2960        ;
2961
2962type_array:
2963        paren_type array_dimension
2964                { $$ = $1->addArray( $2 ); }
2965        | '(' type_ptr ')' array_dimension
2966                { $$ = $2->addArray( $4 ); }
2967        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2968                { $$ = $2->addArray( $4 ); }
2969        | '(' type_array ')'                                                            // redundant parenthesis
2970                { $$ = $2; }
2971        ;
2972
2973type_function:
2974        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2975                { $$ = $1->addParamList( $4 ); }
2976        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2977                { $$ = $2->addParamList( $6 ); }
2978        | '(' type_function ')'                                                         // redundant parenthesis
2979                { $$ = $2; }
2980        ;
2981
2982// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2983// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2984// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2985// pointers to arrays and functions.
2986
2987identifier_parameter_declarator:
2988        paren_identifier attribute_list_opt
2989                { $$ = $1->addQualifiers( $2 ); }
2990        | '&' MUTEX paren_identifier attribute_list_opt
2991                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2992        | identifier_parameter_ptr
2993        | identifier_parameter_array attribute_list_opt
2994                { $$ = $1->addQualifiers( $2 ); }
2995        | identifier_parameter_function attribute_list_opt
2996                { $$ = $1->addQualifiers( $2 ); }
2997        ;
2998
2999identifier_parameter_ptr:
3000        ptrref_operator identifier_parameter_declarator
3001                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3002        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3003                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3004        | '(' identifier_parameter_ptr ')' attribute_list_opt
3005                { $$ = $2->addQualifiers( $4 ); }
3006        ;
3007
3008identifier_parameter_array:
3009        paren_identifier array_parameter_dimension
3010                { $$ = $1->addArray( $2 ); }
3011        | '(' identifier_parameter_ptr ')' array_dimension
3012                { $$ = $2->addArray( $4 ); }
3013        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3014                { $$ = $2->addArray( $4 ); }
3015        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3016                { $$ = $2; }
3017        ;
3018
3019identifier_parameter_function:
3020        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3021                { $$ = $1->addParamList( $4 ); }
3022        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3023                { $$ = $2->addParamList( $6 ); }
3024        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3025                { $$ = $2; }
3026        ;
3027
3028// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3029// e.g.:
3030//
3031//              typedef int foo;
3032//              forall( otype T ) struct foo;
3033//              int f( int foo ); // redefine typedef name in new scope
3034//
3035// and allows the C99 array options, which can only appear in a parameter list.
3036
3037type_parameter_redeclarator:
3038        typedef attribute_list_opt
3039                { $$ = $1->addQualifiers( $2 ); }
3040        | '&' MUTEX typedef attribute_list_opt
3041                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3042        | type_parameter_ptr
3043        | type_parameter_array attribute_list_opt
3044                { $$ = $1->addQualifiers( $2 ); }
3045        | type_parameter_function attribute_list_opt
3046                { $$ = $1->addQualifiers( $2 ); }
3047        ;
3048
3049typedef:
3050        TYPEDEFname
3051                { $$ = DeclarationNode::newName( $1 ); }
3052        | TYPEGENname
3053                { $$ = DeclarationNode::newName( $1 ); }
3054        ;
3055
3056type_parameter_ptr:
3057        ptrref_operator type_parameter_redeclarator
3058                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3059        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3060                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3061        | '(' type_parameter_ptr ')' attribute_list_opt
3062                { $$ = $2->addQualifiers( $4 ); }
3063        ;
3064
3065type_parameter_array:
3066        typedef array_parameter_dimension
3067                { $$ = $1->addArray( $2 ); }
3068        | '(' type_parameter_ptr ')' array_parameter_dimension
3069                { $$ = $2->addArray( $4 ); }
3070        ;
3071
3072type_parameter_function:
3073        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3074                { $$ = $1->addParamList( $4 ); }
3075        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3076                { $$ = $2->addParamList( $6 ); }
3077        ;
3078
3079// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3080// which the type applies, e.g.:
3081//
3082//              sizeof( int );
3083//              sizeof( int * );
3084//              sizeof( int [10] );
3085//              sizeof( int (*)() );
3086//              sizeof( int () );
3087//
3088// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3089// and functions versus pointers to arrays and functions.
3090
3091abstract_declarator:
3092        abstract_ptr
3093        | abstract_array attribute_list_opt
3094                { $$ = $1->addQualifiers( $2 ); }
3095        | abstract_function attribute_list_opt
3096                { $$ = $1->addQualifiers( $2 ); }
3097        ;
3098
3099abstract_ptr:
3100        ptrref_operator
3101                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3102        | ptrref_operator type_qualifier_list
3103                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3104        | ptrref_operator abstract_declarator
3105                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3106        | ptrref_operator type_qualifier_list abstract_declarator
3107                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3108        | '(' abstract_ptr ')' attribute_list_opt
3109                { $$ = $2->addQualifiers( $4 ); }
3110        ;
3111
3112abstract_array:
3113        array_dimension
3114        | '(' abstract_ptr ')' array_dimension
3115                { $$ = $2->addArray( $4 ); }
3116        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3117                { $$ = $2->addArray( $4 ); }
3118        | '(' abstract_array ')'                                                        // redundant parenthesis
3119                { $$ = $2; }
3120        ;
3121
3122abstract_function:
3123        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3124                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3125        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3126                { $$ = $2->addParamList( $6 ); }
3127        | '(' abstract_function ')'                                                     // redundant parenthesis
3128                { $$ = $2; }
3129        ;
3130
3131array_dimension:
3132                // Only the first dimension can be empty.
3133        '[' ']'
3134                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3135        | '[' ']' multi_array_dimension
3136                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3137        | multi_array_dimension
3138        ;
3139
3140multi_array_dimension:
3141        '[' push assignment_expression pop ']'
3142                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3143        | '[' push '*' pop ']'                                                          // C99
3144                { $$ = DeclarationNode::newVarArray( 0 ); }
3145        | multi_array_dimension '[' push assignment_expression pop ']'
3146                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3147        | multi_array_dimension '[' push '*' pop ']'            // C99
3148                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3149        ;
3150
3151// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3152// identifier to which the type applies, e.g.:
3153//
3154//              int f( int );                   // not handled here
3155//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3156//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3157//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3158//
3159// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3160// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3161// special meaning of parenthesis around a typedef name:
3162//
3163//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3164//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3165//              not as redundant parentheses around the identifier."
3166//
3167// For example:
3168//
3169//              typedef float T;
3170//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3171//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3172//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3173//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3174//
3175// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3176// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3177// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3178// functions.
3179
3180abstract_parameter_declarator:
3181        abstract_parameter_ptr
3182        | '&' MUTEX attribute_list_opt
3183                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3184        | abstract_parameter_array attribute_list_opt
3185                { $$ = $1->addQualifiers( $2 ); }
3186        | abstract_parameter_function attribute_list_opt
3187                { $$ = $1->addQualifiers( $2 ); }
3188        ;
3189
3190abstract_parameter_ptr:
3191        ptrref_operator
3192                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3193        | ptrref_operator type_qualifier_list
3194                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3195        | ptrref_operator abstract_parameter_declarator
3196                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3197        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3198                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3199        | '(' abstract_parameter_ptr ')' attribute_list_opt
3200                { $$ = $2->addQualifiers( $4 ); }
3201        ;
3202
3203abstract_parameter_array:
3204        array_parameter_dimension
3205        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3206                { $$ = $2->addArray( $4 ); }
3207        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3208                { $$ = $2->addArray( $4 ); }
3209        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3210                { $$ = $2; }
3211        ;
3212
3213abstract_parameter_function:
3214        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3215                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3216        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3217                { $$ = $2->addParamList( $6 ); }
3218        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3219                { $$ = $2; }
3220        ;
3221
3222array_parameter_dimension:
3223                // Only the first dimension can be empty or have qualifiers.
3224        array_parameter_1st_dimension
3225        | array_parameter_1st_dimension multi_array_dimension
3226                { $$ = $1->addArray( $2 ); }
3227        | multi_array_dimension
3228        ;
3229
3230// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3231//
3232//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3233//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3234
3235array_parameter_1st_dimension:
3236        '[' ']'
3237                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3238                // multi_array_dimension handles the '[' '*' ']' case
3239        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3240                { $$ = DeclarationNode::newVarArray( $3 ); }
3241        | '[' push type_qualifier_list pop ']'
3242                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3243                // multi_array_dimension handles the '[' assignment_expression ']' case
3244        | '[' push type_qualifier_list assignment_expression pop ']'
3245                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3246        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3247                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3248        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3249                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3250        ;
3251
3252// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3253//
3254//              struct S {
3255//          int;
3256//          int *;
3257//          int [10];
3258//          int (*)();
3259//      };
3260
3261variable_abstract_declarator:
3262        variable_abstract_ptr
3263        | variable_abstract_array attribute_list_opt
3264                { $$ = $1->addQualifiers( $2 ); }
3265        | variable_abstract_function attribute_list_opt
3266                { $$ = $1->addQualifiers( $2 ); }
3267        ;
3268
3269variable_abstract_ptr:
3270        ptrref_operator
3271                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3272        | ptrref_operator type_qualifier_list
3273                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3274        | ptrref_operator variable_abstract_declarator
3275                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3276        | ptrref_operator type_qualifier_list variable_abstract_declarator
3277                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3278        | '(' variable_abstract_ptr ')' attribute_list_opt
3279                { $$ = $2->addQualifiers( $4 ); }
3280        ;
3281
3282variable_abstract_array:
3283        array_dimension
3284        | '(' variable_abstract_ptr ')' array_dimension
3285                { $$ = $2->addArray( $4 ); }
3286        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3287                { $$ = $2->addArray( $4 ); }
3288        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3289                { $$ = $2; }
3290        ;
3291
3292variable_abstract_function:
3293        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3294                { $$ = $2->addParamList( $6 ); }
3295        | '(' variable_abstract_function ')'                            // redundant parenthesis
3296                { $$ = $2; }
3297        ;
3298
3299// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3300// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3301
3302cfa_identifier_parameter_declarator_tuple:                              // CFA
3303        cfa_identifier_parameter_declarator_no_tuple
3304        | cfa_abstract_tuple
3305        | type_qualifier_list cfa_abstract_tuple
3306                { $$ = $2->addQualifiers( $1 ); }
3307        ;
3308
3309cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3310        cfa_identifier_parameter_ptr
3311        | cfa_identifier_parameter_array
3312        ;
3313
3314cfa_identifier_parameter_ptr:                                                   // CFA
3315                // No SUE declaration in parameter list.
3316        ptrref_operator type_specifier_nobody
3317                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3318        | type_qualifier_list ptrref_operator type_specifier_nobody
3319                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3320        | ptrref_operator cfa_abstract_function
3321                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3322        | type_qualifier_list ptrref_operator cfa_abstract_function
3323                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3324        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3325                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3326        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3327                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3328        ;
3329
3330cfa_identifier_parameter_array:                                                 // CFA
3331                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3332                // shift/reduce conflict with new-style empty (void) function return type.
3333        '[' ']' type_specifier_nobody
3334                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3335        | cfa_array_parameter_1st_dimension type_specifier_nobody
3336                { $$ = $2->addNewArray( $1 ); }
3337        | '[' ']' multi_array_dimension type_specifier_nobody
3338                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3339        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3340                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3341        | multi_array_dimension type_specifier_nobody
3342                { $$ = $2->addNewArray( $1 ); }
3343
3344        | '[' ']' cfa_identifier_parameter_ptr
3345                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3346        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3347                { $$ = $2->addNewArray( $1 ); }
3348        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3349                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3350        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3351                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3352        | multi_array_dimension cfa_identifier_parameter_ptr
3353                { $$ = $2->addNewArray( $1 ); }
3354        ;
3355
3356cfa_array_parameter_1st_dimension:
3357        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3358                { $$ = DeclarationNode::newVarArray( $3 ); }
3359        | '[' push type_qualifier_list assignment_expression pop ']'
3360                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3361        | '[' push declaration_qualifier_list assignment_expression pop ']'
3362                // declaration_qualifier_list must be used because of shift/reduce conflict with
3363                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3364                // appear in this context.
3365                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3366        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3367                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3368        ;
3369
3370// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3371// identifier to which the type applies, e.g.:
3372//
3373//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3374//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3375//
3376// These rules need LR(3):
3377//
3378//              cfa_abstract_tuple identifier_or_type_name
3379//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3380//
3381// since a function return type can be syntactically identical to a tuple type:
3382//
3383//              [int, int] t;
3384//              [int, int] f( int );
3385//
3386// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3387// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3388// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3389// duplicated when appearing with cfa_function_specifier.
3390
3391cfa_abstract_declarator_tuple:                                                  // CFA
3392        cfa_abstract_tuple
3393        | type_qualifier_list cfa_abstract_tuple
3394                { $$ = $2->addQualifiers( $1 ); }
3395        | cfa_abstract_declarator_no_tuple
3396        ;
3397
3398cfa_abstract_declarator_no_tuple:                                               // CFA
3399        cfa_abstract_ptr
3400        | cfa_abstract_array
3401        ;
3402
3403cfa_abstract_ptr:                                                                               // CFA
3404        ptrref_operator type_specifier
3405                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3406        | type_qualifier_list ptrref_operator type_specifier
3407                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3408        | ptrref_operator cfa_abstract_function
3409                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3410        | type_qualifier_list ptrref_operator cfa_abstract_function
3411                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3412        | ptrref_operator cfa_abstract_declarator_tuple
3413                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3414        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3415                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3416        ;
3417
3418cfa_abstract_array:                                                                             // CFA
3419                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3420                // empty (void) function return type.
3421        '[' ']' type_specifier
3422                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3423        | '[' ']' multi_array_dimension type_specifier
3424                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3425        | multi_array_dimension type_specifier
3426                { $$ = $2->addNewArray( $1 ); }
3427        | '[' ']' cfa_abstract_ptr
3428                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3429        | '[' ']' multi_array_dimension cfa_abstract_ptr
3430                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3431        | multi_array_dimension cfa_abstract_ptr
3432                { $$ = $2->addNewArray( $1 ); }
3433        ;
3434
3435cfa_abstract_tuple:                                                                             // CFA
3436        '[' push cfa_abstract_parameter_list pop ']'
3437                { $$ = DeclarationNode::newTuple( $3 ); }
3438        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3439                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3440        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3441                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3442        ;
3443
3444cfa_abstract_function:                                                                  // CFA
3445//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3446//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3447        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3448                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3449        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3450                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3451        ;
3452
3453// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3454//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3455//
3456// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3457//    the declaration specifiers in a declaration is an obsolescent feature."
3458//
3459// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3460//    prototype-format parameter type declarators) is an obsolescent feature."
3461//
3462// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3463//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3464
3465//************************* MISCELLANEOUS ********************************
3466
3467comma_opt:                                                                                              // redundant comma
3468        // empty
3469        | ','
3470        ;
3471
3472default_initialize_opt:
3473        // empty
3474                { $$ = nullptr; }
3475        | '=' assignment_expression
3476                { $$ = $2; }
3477        ;
3478
3479%%
3480
3481// ----end of grammar----
3482
3483// Local Variables: //
3484// mode: c++ //
3485// tab-width: 4 //
3486// compile-command: "make install" //
3487// End: //
Note: See TracBrowser for help on using the repository browser.