source: src/Parser/parser.yy @ 58dd019

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerresolv-newwith_gc
Last change on this file since 58dd019 was 58dd019, checked in by Peter A. Buhr <pabuhr@…>, 5 years ago

add asm_name clause to declarations

  • Property mode set to 100644
File size: 105.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// cfa.y --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Tue Dec 13 14:14:52 2016
13// Update Count     : 2081
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45
46#undef __GNUC_MINOR__
47
48#include <cstdio>
49#include <stack>
50#include "lex.h"
51#include "parser.h"
52#include "ParseNode.h"
53#include "TypedefTable.h"
54#include "TypeData.h"
55#include "LinkageSpec.h"
56using namespace std;
57
58extern DeclarationNode * parseTree;
59extern LinkageSpec::Spec linkage;
60extern TypedefTable typedefTable;
61
62stack< LinkageSpec::Spec > linkageStack;
63
64void appendStr( string *to, string *from ) {
65        // "abc" "def" "ghi" => "abcdefghi", remove new text from quotes and insert before last quote in old string.
66        to->insert( to->length() - 1, from->substr( 1, from->length() - 2 ) );
67} // appendStr
68%}
69
70//************************* TERMINAL TOKENS ********************************
71
72// keywords
73%token TYPEDEF
74%token AUTO EXTERN REGISTER STATIC
75%token INLINE                                                                                   // C99
76%token FORTRAN                                                                                  // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
77%token CONST VOLATILE
78%token RESTRICT                                                                                 // C99
79%token FORALL LVALUE                                                                    // CFA
80%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED ZERO_T ONE_T
81%token VALIST                                                                                   // GCC
82%token BOOL COMPLEX IMAGINARY                                                   // C99
83%token TYPEOF LABEL                                                                             // GCC
84%token ENUM STRUCT UNION
85%token OTYPE FTYPE DTYPE TRAIT                                                  // CFA
86%token SIZEOF OFFSETOF
87%token ATTRIBUTE EXTENSION                                                              // GCC
88%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
89%token CHOOSE DISABLE ENABLE FALLTHRU TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT        // CFA
90%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
91%token ALIGNAS ALIGNOF ATOMIC GENERIC NORETURN STATICASSERT THREADLOCAL // C11
92
93// names and constants: lexer differentiates between identifier and typedef names
94%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
95%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
96%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
97// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
98// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
99// converted into the tuple index (.)(1). e.g., 3.x
100%token<tok>     REALDECIMALconstant     REALFRACTIONconstant    FLOATINGconstant
101%token<tok> ZERO                                ONE                                             // CFA
102
103// multi-character operators
104%token ARROW                                                                                    // ->
105%token ICR DECR                                                                                 // ++   --
106%token LS RS                                                                                    // <<   >>
107%token LE GE EQ NE                                                                              // <=   >=      ==      !=
108%token ANDAND OROR                                                                              // &&   ||
109%token ELLIPSIS                                                                                 // ...
110
111%token MULTassign       DIVassign       MODassign                               // *=   /=      %=/
112%token PLUSassign       MINUSassign                                                     // +=   -=
113%token LSassign         RSassign                                                        // <<=  >>=
114%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
115
116%token ATassign                                                                                 // @=
117
118// Types declaration
119%union
120{
121        Token tok;
122        ParseNode *pn;
123        ExpressionNode *en;
124        DeclarationNode *decl;
125        DeclarationNode::Aggregate aggKey;
126        DeclarationNode::TypeClass tclass;
127        StatementNode *sn;
128        ConstantExpr *constant;
129        ForCtl *fctl;
130        LabelNode *label;
131        InitializerNode *in;
132        OperKinds op;
133        std::string *str;
134        bool flag;
135}
136
137%type<tok> identifier  no_01_identifier  no_attr_identifier zero_one
138%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  no_01_identifier_or_type_name
139%type<constant> string_literal
140%type<str> string_literal_list
141
142// expressions
143%type<en> constant
144%type<en> tuple                                                 tuple_expression_list
145%type<op> ptrref_operator                               unary_operator                          assignment_operator
146%type<en> primary_expression                    postfix_expression                      unary_expression
147%type<en> cast_expression                               multiplicative_expression       additive_expression                     shift_expression
148%type<en> relational_expression                 equality_expression                     AND_expression                          exclusive_OR_expression
149%type<en> inclusive_OR_expression               logical_AND_expression          logical_OR_expression           conditional_expression
150%type<en> constant_expression                   assignment_expression           assignment_expression_opt
151%type<en> comma_expression                              comma_expression_opt
152%type<en> argument_expression_list              argument_expression                     assignment_opt
153%type<fctl> for_control_expression
154%type<en> subrange
155%type<constant> asm_name_opt
156%type<en> asm_operands_opt asm_operands_list asm_operand
157%type<label> label_list
158%type<en> asm_clobbers_list_opt
159%type<flag> asm_volatile_opt
160
161// statements
162%type<sn> labeled_statement                             compound_statement                      expression_statement            selection_statement
163%type<sn> iteration_statement                   jump_statement                          exception_statement                     asm_statement
164%type<sn> fall_through_opt                              fall_through
165%type<sn> statement                                             statement_list
166%type<sn> block_item_list                               block_item
167%type<sn> case_clause
168%type<en> case_value
169%type<sn> case_value_list                               case_label                                      case_label_list
170%type<sn> switch_clause_list_opt                switch_clause_list                      choose_clause_list_opt          choose_clause_list
171%type<sn> handler_list                                  handler_clause                          finally_clause
172
173// declarations
174%type<decl> abstract_array abstract_declarator abstract_function abstract_parameter_array
175%type<decl> abstract_parameter_declaration abstract_parameter_declarator abstract_parameter_function
176%type<decl> abstract_parameter_ptr abstract_ptr
177
178%type<aggKey> aggregate_key
179%type<decl>  aggregate_name
180
181%type<decl> array_dimension array_parameter_1st_dimension array_parameter_dimension multi_array_dimension
182
183%type<decl> assertion assertion_list_opt
184
185%type<en>   bit_subrange_size_opt bit_subrange_size
186
187%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type_name indirect_type_name
188
189%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
190
191%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
192%type<decl> declaration_specifier declarator declaring_list
193
194%type<decl> elaborated_type_name
195
196%type<decl> enumerator_list enum_name
197%type<en> enumerator_value_opt
198
199%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
200
201%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
202%type<en> field field_list field_name fraction_constants
203
204%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
205
206%type<decl> identifier_parameter_array identifier_parameter_declarator identifier_parameter_function
207%type<decl> identifier_parameter_ptr identifier_list
208
209%type<decl> new_abstract_array new_abstract_declarator_no_tuple new_abstract_declarator_tuple
210%type<decl> new_abstract_function new_abstract_parameter_declaration new_abstract_parameter_list
211%type<decl> new_abstract_ptr new_abstract_tuple
212
213%type<decl> new_array_parameter_1st_dimension
214
215%type<decl> new_trait_declaring_list new_declaration new_field_declaring_list
216%type<decl> new_function_declaration new_function_return new_function_specifier
217
218%type<decl> new_identifier_parameter_array new_identifier_parameter_declarator_no_tuple
219%type<decl> new_identifier_parameter_declarator_tuple new_identifier_parameter_ptr
220
221%type<decl> new_parameter_declaration new_parameter_list new_parameter_type_list new_parameter_type_list_opt
222
223%type<decl> new_typedef_declaration new_variable_declaration new_variable_specifier
224
225%type<decl> old_declaration old_declaration_list old_declaration_list_opt old_function_array
226%type<decl> old_function_declarator old_function_no_ptr old_function_ptr
227
228%type<decl> parameter_declaration parameter_list parameter_type_list
229%type<decl> parameter_type_list_opt
230
231%type<decl> paren_identifier paren_type
232
233%type<decl> storage_class storage_class_list
234
235%type<decl> sue_declaration_specifier sue_type_specifier
236
237%type<tclass> type_class
238%type<decl> type_declarator type_declarator_name type_declaring_list
239
240%type<decl> typedef type_array typedef_declaration typedef_declaration_specifier typedef_expression
241%type<decl> type_function type_parameter_array type_parameter_function type_parameter_ptr
242%type<decl> type_parameter_redeclarator type_ptr variable_type_redeclarator typedef_type_specifier
243%type<decl> typegen_declaration_specifier typegen_type_specifier typegen_name
244
245%type<decl> type_name type_name_no_function
246%type<decl> type_parameter type_parameter_list
247
248%type<en> type_name_list
249
250%type<decl> type_qualifier type_qualifier_name type_qualifier_list type_qualifier_list_opt type_specifier
251
252%type<decl> variable_abstract_array variable_abstract_declarator variable_abstract_function
253%type<decl> variable_abstract_ptr variable_array variable_declarator variable_function variable_ptr
254
255%type<decl> attribute_list_opt attribute_list attribute
256
257// initializers
258%type<in>  initializer initializer_list initializer_opt
259
260// designators
261%type<en>  designator designator_list designation
262
263
264// Handle single shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string
265// is ambiguous:
266// .---------.                          matches IF '(' comma_expression ')' statement
267// if ( C ) S1 else S2
268// `-----------------'          matches IF '(' comma_expression ')' statement ELSE statement */
269
270%nonassoc THEN  // rule precedence for IF '(' comma_expression ')' statement
271%nonassoc ELSE  // token precedence for start of else clause in IF statement
272
273%start translation_unit                                                                 // parse-tree root
274
275%%
276//************************* Namespace Management ********************************
277
278// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
279// "identifier" and "TYPEDEFname" that are lexically identical.  While it is possible to write a purely context-free
280// grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.  Hence, this
281// grammar uses the ANSI style.
282//
283// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
284// introduced through "forall" qualifiers), and by introducing "type generators" -- parameterized types.  This latter
285// type name creates a third class of identifiers that must be distinguished by the scanner.
286//
287// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
288// accesses a data structure (TypedefTable) to allow classification of an identifier that it has just read.  Semantic
289// actions during the parser update this data structure when the class of identifiers change.
290//
291// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its class in a
292// local scope; it must revert to its original class at the end of the block.  Since type names can be local to a
293// particular declaration, each declaration is itself a scope.  This requires distinguishing between type names that are
294// local to the current declaration scope and those that persist past the end of the declaration (i.e., names defined in
295// "typedef" or "otype" declarations).
296//
297// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and closing of
298// scopes.  Every push must have a matching pop, although it is regrettable the matching pairs do not always occur
299// within the same rule.  These non-terminals may appear in more contexts than strictly necessary from a semantic point
300// of view.  Unfortunately, these extra rules are necessary to prevent parsing conflicts -- the parser may not have
301// enough context and look-ahead information to decide whether a new scope is necessary, so the effect of these extra
302// rules is to open a new scope unconditionally.  As the grammar evolves, it may be neccesary to add or move around
303// "push" and "pop" nonterminals to resolve conflicts of this sort.
304
305push:
306                { typedefTable.enterScope(); }
307        ;
308
309pop:
310                { typedefTable.leaveScope(); }
311        ;
312
313//************************* CONSTANTS ********************************
314
315constant:
316                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
317        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
318        | REALDECIMALconstant                                           { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
319        | REALFRACTIONconstant                                          { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
320        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
321        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
322        ;
323
324identifier:
325        IDENTIFIER
326        | ATTR_IDENTIFIER                                                                       // CFA
327        | zero_one                                                                                      // CFA
328        ;
329
330no_01_identifier:
331        IDENTIFIER
332        | ATTR_IDENTIFIER                                                                       // CFA
333        ;
334
335no_attr_identifier:
336        IDENTIFIER
337        | zero_one                                                                                      // CFA
338        ;
339
340zero_one:                                                                                               // CFA
341        ZERO
342        | ONE
343        ;
344
345string_literal:
346        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
347        ;
348
349string_literal_list:                                                                    // juxtaposed strings are concatenated
350        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
351        | string_literal_list STRINGliteral
352                {
353                        appendStr( $1, $2 );                                            // append 2nd juxtaposed string to 1st
354                        delete $2;                                                                      // allocated by lexer
355                        $$ = $1;                                                                        // conversion from tok to str
356                }
357        ;
358
359//************************* EXPRESSIONS ********************************
360
361primary_expression:
362        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
363                { $$ = new ExpressionNode( build_varref( $1 ) ); }
364        | zero_one
365                { $$ = new ExpressionNode( build_constantZeroOne( *$1 ) ); }
366        | tuple
367        | '(' comma_expression ')'
368                { $$ = $2; }
369        | '(' compound_statement ')'                                            // GCC, lambda expression
370                { $$ = new ExpressionNode( build_valexpr( $2 ) ); }
371        ;
372
373postfix_expression:
374        primary_expression
375        | postfix_expression '[' push assignment_expression pop ']'
376                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
377                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
378                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
379                // equivalent to the old x[i,j].
380                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $4 ) ); }
381        | postfix_expression '(' argument_expression_list ')'
382                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
383        | postfix_expression '.' no_attr_identifier
384                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
385        | postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
386                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
387        | postfix_expression REALFRACTIONconstant                       // CFA, tuple index
388                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_REALFRACTIONconstant( *$2 ) ) ); }
389        | postfix_expression ARROW no_attr_identifier
390                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
391        | postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
392                        { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
393        | postfix_expression ICR
394                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
395        | postfix_expression DECR
396                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
397        | '(' type_name_no_function ')' '{' initializer_list comma_opt '}' // C99
398                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
399        | postfix_expression '{' argument_expression_list '}' // CFA
400                {
401                        Token fn;
402                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
403                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
404                }
405        ;
406
407argument_expression_list:
408        argument_expression
409        | argument_expression_list ',' argument_expression
410                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
411        ;
412
413argument_expression:
414        // empty
415                { $$ = nullptr; }                                                               // use default argument
416        | assignment_expression
417        ;
418
419field_list:                                                                                             // CFA, tuple field selector
420        field
421        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
422        ;
423
424field:                                                                                                  // CFA, tuple field selector
425        field_name
426        | REALDECIMALconstant field
427                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_REALDECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
428        | REALDECIMALconstant '[' push field_list pop ']'
429                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_REALDECIMALconstant( *$1 ) ), build_tuple( $4 ) ) ); }
430        | field_name '.' field
431                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
432        | field_name '.' '[' push field_list pop ']'
433                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
434        | field_name ARROW field
435                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
436        | field_name ARROW '[' push field_list pop ']'
437                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
438        ;
439
440field_name:
441        INTEGERconstant fraction_constants
442                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
443        | FLOATINGconstant fraction_constants
444                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
445        | no_attr_identifier fraction_constants
446                {
447                        if( (*$1) == "0" || (*$1) == "1" ) {
448                                $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantZeroOne( *$1 ), $2 ) );
449                        } else {
450                                $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
451                        }
452                }
453        ;
454
455fraction_constants:
456        // empty
457                { $$ = nullptr; }
458        | fraction_constants REALFRACTIONconstant
459                {
460                        Expression * constant = build_field_name_REALFRACTIONconstant( *$2 );
461                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
462                }
463        ;
464
465unary_expression:
466        postfix_expression
467                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
468                // semantics checks, e.g., ++3, 3--, *3, &&3
469        | constant
470                { $$ = $1; }
471        | string_literal
472                { $$ = new ExpressionNode( $1 ); }
473        | EXTENSION cast_expression                                                     // GCC
474                { $$ = $2->set_extension( true ); }
475                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
476                //              { * X; }         // dereference X
477                //              { * int X; } // CFA declaration of pointer to int
478        | ptrref_operator cast_expression                                       // CFA
479                {
480                        switch ( $1 ) {
481                          case OperKinds::AddressOf:
482                                $$ = new ExpressionNode( build_addressOf( $2 ) );
483                                break;
484                          case OperKinds::PointTo:
485                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
486                                break;
487                          default:
488                                assert( false );
489                        }
490                }
491        | unary_operator cast_expression
492                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
493        | ICR unary_expression
494                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
495        | DECR unary_expression
496                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
497        | SIZEOF unary_expression
498                { $$ = new ExpressionNode( build_sizeOfexpr( $2 ) ); }
499        | SIZEOF '(' type_name_no_function ')'
500                { $$ = new ExpressionNode( build_sizeOftype( $3 ) ); }
501        | ALIGNOF unary_expression                                                      // GCC, variable alignment
502                { $$ = new ExpressionNode( build_alignOfexpr( $2 ) ); }
503        | ALIGNOF '(' type_name_no_function ')'                         // GCC, type alignment
504                { $$ = new ExpressionNode( build_alignOftype( $3 ) ); }
505        | OFFSETOF '(' type_name_no_function ',' no_attr_identifier ')'
506                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
507        | ATTR_IDENTIFIER
508                { $$ = new ExpressionNode( build_attrexpr( build_varref( $1 ), nullptr ) ); }
509        | ATTR_IDENTIFIER '(' argument_expression ')'
510                { $$ = new ExpressionNode( build_attrexpr( build_varref( $1 ), $3 ) ); }
511        | ATTR_IDENTIFIER '(' type_name ')'
512                { $$ = new ExpressionNode( build_attrtype( build_varref( $1 ), $3 ) ); }
513//      | ANDAND IDENTIFIER                                                                     // GCC, address of label
514//              { $$ = new ExpressionNode( new OperatorNode( OperKinds::LabelAddress ), new ExpressionNode( build_varref( $2, true ) ); }
515        ;
516
517ptrref_operator:
518        '*'                                                                                     { $$ = OperKinds::PointTo; }
519        | '&'                                                                           { $$ = OperKinds::AddressOf; }
520                // GCC, address of label must be handled by semantic check for ref,ref,label
521//      | ANDAND                                                                        { $$ = OperKinds::And; }
522        ;
523
524unary_operator:
525        '+'                                                                                     { $$ = OperKinds::UnPlus; }
526        | '-'                                                                           { $$ = OperKinds::UnMinus; }
527        | '!'                                                                           { $$ = OperKinds::Neg; }
528        | '~'                                                                           { $$ = OperKinds::BitNeg; }
529        ;
530
531cast_expression:
532        unary_expression
533        | '(' type_name_no_function ')' cast_expression
534                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
535//      | '(' type_name_no_function ')' tuple
536//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
537        ;
538
539multiplicative_expression:
540        cast_expression
541        | multiplicative_expression '*' cast_expression
542                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
543        | multiplicative_expression '/' cast_expression
544                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
545        | multiplicative_expression '%' cast_expression
546                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
547        ;
548
549additive_expression:
550        multiplicative_expression
551        | additive_expression '+' multiplicative_expression
552                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
553        | additive_expression '-' multiplicative_expression
554                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
555        ;
556
557shift_expression:
558        additive_expression
559        | shift_expression LS additive_expression
560                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
561        | shift_expression RS additive_expression
562                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
563        ;
564
565relational_expression:
566        shift_expression
567        | relational_expression '<' shift_expression
568                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
569        | relational_expression '>' shift_expression
570                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
571        | relational_expression LE shift_expression
572                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
573        | relational_expression GE shift_expression
574                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
575        ;
576
577equality_expression:
578        relational_expression
579        | equality_expression EQ relational_expression
580                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
581        | equality_expression NE relational_expression
582                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
583        ;
584
585AND_expression:
586        equality_expression
587        | AND_expression '&' equality_expression
588                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
589        ;
590
591exclusive_OR_expression:
592        AND_expression
593        | exclusive_OR_expression '^' AND_expression
594                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
595        ;
596
597inclusive_OR_expression:
598        exclusive_OR_expression
599        | inclusive_OR_expression '|' exclusive_OR_expression
600                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
601        ;
602
603logical_AND_expression:
604        inclusive_OR_expression
605        | logical_AND_expression ANDAND inclusive_OR_expression
606                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
607        ;
608
609logical_OR_expression:
610        logical_AND_expression
611        | logical_OR_expression OROR logical_AND_expression
612                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
613        ;
614
615conditional_expression:
616        logical_OR_expression
617        | logical_OR_expression '?' comma_expression ':' conditional_expression
618                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
619                // FIX ME: this hack computes $1 twice
620        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
621                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
622//      | logical_OR_expression '?' comma_expression ':' tuple // CFA, tuple expression
623//              { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
624        ;
625
626constant_expression:
627        conditional_expression
628        ;
629
630assignment_expression:
631                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
632        conditional_expression
633        | unary_expression assignment_operator assignment_expression
634                { $$ = new ExpressionNode( build_binary_ptr( $2, $1, $3 ) ); }
635//      | tuple assignment_opt                                                          // CFA, tuple expression
636//              { $$ = ( $2 == 0 ) ? $1 : new ExpressionNode( build_binary_ptr( OperKinds::Assign, $1, $2 ) ); }
637        ;
638
639assignment_expression_opt:
640        // empty
641                { $$ = nullptr; }
642        | assignment_expression
643        ;
644
645assignment_operator:
646        '='                                                                                     { $$ = OperKinds::Assign; }
647        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
648        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
649        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
650        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
651        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
652        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
653        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
654        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
655        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
656        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
657        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
658        ;
659
660tuple:                                                                                                  // CFA, tuple
661                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
662                // comma_expression in new_identifier_parameter_array and new_abstract_array
663//      '[' ']'
664//              { $$ = new ExpressionNode( build_tuple() ); }
665//      '[' push assignment_expression pop ']'
666//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
667        '[' push ',' tuple_expression_list pop ']'
668                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
669        | '[' push assignment_expression ',' tuple_expression_list pop ']'
670                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
671        ;
672
673tuple_expression_list:
674        assignment_expression_opt
675        | tuple_expression_list ',' assignment_expression_opt
676                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
677        ;
678
679comma_expression:
680        assignment_expression
681        | comma_expression ',' assignment_expression
682                { $$ = new ExpressionNode( build_comma( $1, $3 ) ); }
683        ;
684
685comma_expression_opt:
686        // empty
687                { $$ = nullptr; }
688        | comma_expression
689        ;
690
691//*************************** STATEMENTS *******************************
692
693statement:
694        labeled_statement
695        | compound_statement
696        | expression_statement                                          { $$ = $1; }
697        | selection_statement
698        | iteration_statement
699        | jump_statement
700        | exception_statement
701        | asm_statement
702        | '^' postfix_expression '{' argument_expression_list '}' ';' // CFA
703                {
704                        Token fn;
705                        fn.str = new string( "^?{}" );                          // location undefined
706                        $$ = new StatementNode( build_expr( new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) ) ) );
707                }
708        ;
709
710labeled_statement:
711                // labels cannot be identifiers 0 or 1
712        IDENTIFIER ':' attribute_list_opt statement
713                {
714                        $$ = $4->add_label( $1 );
715                }
716        ;
717
718compound_statement:
719        '{' '}'
720                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
721        | '{'
722                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
723                // requires its own scope.
724          push push
725          local_label_declaration_opt                                           // GCC, local labels
726          block_item_list pop '}'                                                       // C99, intermix declarations and statements
727                { $$ = new StatementNode( build_compound( $5 ) ); }
728        ;
729
730block_item_list:                                                                                // C99
731        block_item
732        | block_item_list push block_item
733                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
734        ;
735
736block_item:
737        declaration                                                                                     // CFA, new & old style declarations
738                { $$ = new StatementNode( $1 ); }
739        | EXTENSION declaration                                                         // GCC
740                {       // mark all fields in list
741                        for ( DeclarationNode *iter = $2; iter != nullptr; iter = (DeclarationNode *)iter->get_next() )
742                                iter->set_extension( true );
743                        $$ = new StatementNode( $2 );
744                }
745        | function_definition
746                { $$ = new StatementNode( $1 ); }
747        | statement pop
748        ;
749
750statement_list:
751        statement
752        | statement_list statement
753                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
754        ;
755
756expression_statement:
757        comma_expression_opt ';'
758                { $$ = new StatementNode( build_expr( $1 ) ); }
759        ;
760
761selection_statement:
762        IF '(' comma_expression ')' statement                           %prec THEN
763                // explicitly deal with the shift/reduce conflict on if/else
764                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
765        | IF '(' comma_expression ')' statement ELSE statement
766                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
767        | SWITCH '(' comma_expression ')' case_clause           // CFA
768                { $$ = new StatementNode( build_switch( $3, $5 ) ); }
769        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
770                {
771                        StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
772                        // The semantics of the declaration list is changed to include associated initialization, which is performed
773                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
774                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
775                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
776                        // statement.
777                        $$ = $7 != 0 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
778                }
779        | CHOOSE '(' comma_expression ')' case_clause           // CFA
780                { $$ = new StatementNode( build_switch( $3, $5 ) ); }
781        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt choose_clause_list_opt '}' // CFA
782                {
783                        StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
784                        $$ = $7 != 0 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
785                }
786        ;
787
788// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
789// clause allows a list of values and subranges.
790
791case_value:                                                                                             // CFA
792        constant_expression                                                     { $$ = $1; }
793        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
794                { $$ = new ExpressionNode( build_range( $1, $3 ) ); }
795        | subrange                                                                                      // CFA, subrange
796        ;
797
798case_value_list:                                                                                // CFA
799        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
800                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
801        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
802        ;
803
804case_label:                                                                                             // CFA
805        CASE case_value_list ':'                                        { $$ = $2; }
806        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
807                // A semantic check is required to ensure only one default clause per switch/choose statement.
808        ;
809
810case_label_list:                                                                                // CFA
811        case_label
812        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
813        ;
814
815case_clause:                                                                                    // CFA
816        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
817        ;
818
819switch_clause_list_opt:                                                                 // CFA
820        // empty
821                { $$ = nullptr; }
822        | switch_clause_list
823        ;
824
825switch_clause_list:                                                                             // CFA
826        case_label_list statement_list
827                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
828        | switch_clause_list case_label_list statement_list
829                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
830        ;
831
832choose_clause_list_opt:                                                                 // CFA
833        // empty
834                { $$ = nullptr; }
835        | choose_clause_list
836        ;
837
838choose_clause_list:                                                                             // CFA
839        case_label_list fall_through
840                { $$ = $1->append_last_case( $2 ); }
841        | case_label_list statement_list fall_through_opt
842                { $$ = $1->append_last_case( new StatementNode( build_compound( (StatementNode *)$2->set_last( $3 ) ) ) ); }
843        | choose_clause_list case_label_list fall_through
844                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( $3 ))); }
845        | choose_clause_list case_label_list statement_list fall_through_opt
846                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( (StatementNode *)$3->set_last( $4 ) ) ) ) ) ); }
847        ;
848
849fall_through_opt:                                                                               // CFA
850        // empty
851                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); } // insert implicit break
852        | fall_through
853        ;
854
855fall_through:                                                                                   // CFA
856        FALLTHRU
857                { $$ = nullptr; }
858        | FALLTHRU ';'
859                { $$ = nullptr; }
860        ;
861
862iteration_statement:
863        WHILE '(' comma_expression ')' statement
864                { $$ = new StatementNode( build_while( $3, $5 ) ); }
865        | DO statement WHILE '(' comma_expression ')' ';'
866                { $$ = new StatementNode( build_while( $5, $2, true ) ); }
867        | FOR '(' push for_control_expression ')' statement
868                { $$ = new StatementNode( build_for( $4, $6 ) ); }
869        ;
870
871for_control_expression:
872        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
873                { $$ = new ForCtl( $1, $4, $6 ); }
874        | declaration comma_expression_opt ';' comma_expression_opt // C99
875                { $$ = new ForCtl( $1, $2, $4 ); }
876        ;
877
878jump_statement:
879        GOTO IDENTIFIER ';'
880                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
881        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
882                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
883                // whereas normal operator precedence yields goto (*i)+3;
884                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
885        | CONTINUE ';'
886                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
887                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
888        | CONTINUE IDENTIFIER ';'                                                       // CFA, multi-level continue
889                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
890                // the target of the transfer appears only at the start of an iteration statement.
891                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
892        | BREAK ';'
893                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
894                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
895        | BREAK IDENTIFIER ';'                                                          // CFA, multi-level exit
896                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
897                // the target of the transfer appears only at the start of an iteration statement.
898                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
899        | RETURN comma_expression_opt ';'
900                { $$ = new StatementNode( build_return( $2 ) ); }
901        | THROW assignment_expression_opt ';'                           // handles rethrow
902                { $$ = new StatementNode( build_throw( $2 ) ); }
903        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
904                { $$ = new StatementNode( build_throw( $2 ) ); }
905        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
906                { $$ = new StatementNode( build_throw( $2 ) ); }
907        ;
908
909exception_statement:
910        TRY compound_statement handler_list
911                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
912        | TRY compound_statement finally_clause
913                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
914        | TRY compound_statement handler_list finally_clause
915                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
916        ;
917
918handler_list:
919        handler_clause
920                // ISO/IEC 9899:1999 Section 15.3(6 ) If present, a "..." handler shall be the last handler for its try block.
921        | CATCH '(' ELLIPSIS ')' compound_statement
922                { $$ = new StatementNode( build_catch( 0, $5, true ) ); }
923        | handler_clause CATCH '(' ELLIPSIS ')' compound_statement
924                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( 0, $6, true ) ) ); }
925        | CATCHRESUME '(' ELLIPSIS ')' compound_statement
926                { $$ = new StatementNode( build_catch( 0, $5, true ) ); }
927        | handler_clause CATCHRESUME '(' ELLIPSIS ')' compound_statement
928                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( 0, $6, true ) ) ); }
929        ;
930
931handler_clause:
932        CATCH '(' push push exception_declaration pop ')' compound_statement pop
933                { $$ = new StatementNode( build_catch( $5, $8 ) ); }
934        | handler_clause CATCH '(' push push exception_declaration pop ')' compound_statement pop
935                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $6, $9 ) ) ); }
936        | CATCHRESUME '(' push push exception_declaration pop ')' compound_statement pop
937                { $$ = new StatementNode( build_catch( $5, $8 ) ); }
938        | handler_clause CATCHRESUME '(' push push exception_declaration pop ')' compound_statement pop
939                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $6, $9 ) ) ); }
940        ;
941
942finally_clause:
943        FINALLY compound_statement
944                {
945                        $$ = new StatementNode( build_finally( $2 ) );
946                }
947        ;
948
949exception_declaration:
950                // A semantic check is required to ensure type_specifier does not create a new type, e.g.:
951                //
952                //              catch ( struct { int i; } x ) ...
953                //
954                // This new type cannot catch any thrown type because of name equivalence among types.
955        type_specifier
956        | type_specifier declarator
957                {
958                        typedefTable.addToEnclosingScope( TypedefTable::ID );
959                        $$ = $2->addType( $1 );
960                }
961        | type_specifier variable_abstract_declarator
962                { $$ = $2->addType( $1 ); }
963        | new_abstract_declarator_tuple no_attr_identifier      // CFA
964                {
965                        typedefTable.addToEnclosingScope( TypedefTable::ID );
966                        $$ = $1->addName( $2 );
967                }
968        | new_abstract_declarator_tuple                                         // CFA
969        ;
970
971asm_statement:
972        ASM asm_volatile_opt '(' string_literal ')' ';'
973                { $$ = new StatementNode( build_asmstmt( $2, $4, 0 ) ); }
974        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
975                { $$ = new StatementNode( build_asmstmt( $2, $4, $6 ) ); }
976        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
977                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8 ) ); }
978        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
979                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8, $10 ) ); }
980        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
981                { $$ = new StatementNode( build_asmstmt( $2, $5, 0, $8, $10, $12 ) ); }
982        ;
983
984asm_volatile_opt:                                                                               // GCC
985        // empty
986                { $$ = false; }
987        | VOLATILE
988                { $$ = true; }
989        ;
990
991asm_operands_opt:                                                                               // GCC
992        // empty
993                { $$ = nullptr; }                                                               // use default argument
994        | asm_operands_list
995        ;
996
997asm_operands_list:                                                                              // GCC
998        asm_operand
999        | asm_operands_list ',' asm_operand
1000                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1001        ;
1002
1003asm_operand:                                                                                    // GCC
1004        string_literal '(' constant_expression ')'
1005                { $$ = new ExpressionNode( build_asmexpr( 0, $1, $3 ) ); }
1006        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1007                { $$ = new ExpressionNode( build_asmexpr( $2, $4, $6 ) ); }
1008        ;
1009
1010asm_clobbers_list_opt:                                                                  // GCC
1011        // empty
1012                { $$ = nullptr; }                                                               // use default argument
1013        | string_literal
1014                { $$ = new ExpressionNode( $1 ); }
1015        | asm_clobbers_list_opt ',' string_literal
1016                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1017        ;
1018
1019label_list:
1020        no_attr_identifier
1021                {
1022                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1023                        delete $1;                                                                      // allocated by lexer
1024                }
1025        | label_list ',' no_attr_identifier
1026                {
1027                        $$ = $1; $1->labels.push_back( *$3 );
1028                        delete $3;                                                                      // allocated by lexer
1029                }
1030        ;
1031
1032//******************************* DECLARATIONS *********************************
1033
1034declaration_list_opt:                                                                   // used at beginning of switch statement
1035        pop
1036                { $$ = nullptr; }
1037        | declaration_list
1038        ;
1039
1040declaration_list:
1041        declaration
1042        | declaration_list push declaration
1043                { $$ = $1->appendList( $3 ); }
1044        ;
1045
1046old_declaration_list_opt:                                                               // used to declare parameter types in K&R style functions
1047        pop
1048                { $$ = nullptr; }
1049        | old_declaration_list
1050        ;
1051
1052old_declaration_list:
1053        old_declaration
1054        | old_declaration_list push old_declaration
1055                { $$ = $1->appendList( $3 ); }
1056        ;
1057
1058local_label_declaration_opt:                                                    // GCC, local label
1059        // empty
1060        | local_label_declaration_list
1061        ;
1062
1063local_label_declaration_list:                                                   // GCC, local label
1064        LABEL local_label_list ';'
1065        | local_label_declaration_list LABEL local_label_list ';'
1066        ;
1067
1068local_label_list:                                                                               // GCC, local label
1069        no_attr_identifier_or_type_name                         {}
1070        | local_label_list ',' no_attr_identifier_or_type_name {}
1071        ;
1072
1073declaration:                                                                                    // CFA, new & old style declarations
1074        new_declaration
1075        | old_declaration
1076        ;
1077
1078// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1079// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1080// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1081// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1082// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1083// block, but cannot be mixed within a specific declaration.
1084//
1085//                      CFA                                     C
1086//              [10] int x;                     int x[10];              // array of 10 integers
1087//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1088
1089new_declaration:                                                                                // CFA
1090        new_variable_declaration pop ';'
1091        | new_typedef_declaration pop ';'
1092        | new_function_declaration pop ';'
1093        | type_declaring_list pop ';'
1094        | trait_specifier pop ';'
1095        ;
1096
1097new_variable_declaration:                                                               // CFA
1098        new_variable_specifier initializer_opt
1099                {
1100                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1101                        $$ = $1->addInitializer( $2 );
1102                }
1103        | declaration_qualifier_list new_variable_specifier initializer_opt
1104                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1105                // them as a type_qualifier cannot appear in that context.
1106                {
1107                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1108                        $$ = $2->addQualifiers( $1 )->addInitializer( $3 );;
1109                }
1110        | new_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1111                {
1112                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1113                        $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) );
1114                }
1115        ;
1116
1117new_variable_specifier:                                                                 // CFA
1118                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1119                // storage-class
1120        new_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1121                {
1122                        typedefTable.setNextIdentifier( *$2 );
1123                        $$ = $1->addName( $2 )->addAsmName( $3 );
1124                }
1125        | new_abstract_tuple identifier_or_type_name asm_name_opt
1126                {
1127                        typedefTable.setNextIdentifier( *$2 );
1128                        $$ = $1->addName( $2 )->addAsmName( $3 );
1129                }
1130        | type_qualifier_list new_abstract_tuple identifier_or_type_name asm_name_opt
1131                {
1132                        typedefTable.setNextIdentifier( *$3 );
1133                        $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 );
1134                }
1135        ;
1136
1137new_function_declaration:                                                               // CFA
1138        new_function_specifier
1139                {
1140                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1141                        $$ = $1;
1142                }
1143        | type_qualifier_list new_function_specifier
1144                {
1145                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1146                        $$ = $2->addQualifiers( $1 );
1147                }
1148        | declaration_qualifier_list new_function_specifier
1149                {
1150                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1151                        $$ = $2->addQualifiers( $1 );
1152                }
1153        | declaration_qualifier_list type_qualifier_list new_function_specifier
1154                {
1155                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1156                        $$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1157                }
1158        | new_function_declaration pop ',' push identifier_or_type_name
1159                {
1160                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1161                        $$ = $1->appendList( $1->cloneType( $5 ) );
1162                }
1163        ;
1164
1165new_function_specifier:                                                                 // CFA
1166//      '[' ']' identifier_or_type_name '(' push new_parameter_type_list_opt pop ')' // S/R conflict
1167//              {
1168//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1169//              }
1170//      '[' ']' identifier '(' push new_parameter_type_list_opt pop ')'
1171//              {
1172//                      typedefTable.setNextIdentifier( *$5 );
1173//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1174//              }
1175//      | '[' ']' TYPEDEFname '(' push new_parameter_type_list_opt pop ')'
1176//              {
1177//                      typedefTable.setNextIdentifier( *$5 );
1178//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1179//              }
1180//      | '[' ']' typegen_name
1181                // identifier_or_type_name must be broken apart because of the sequence:
1182                //
1183                //   '[' ']' identifier_or_type_name '(' new_parameter_type_list_opt ')'
1184                //   '[' ']' type_specifier
1185                //
1186                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1187                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1188        new_abstract_tuple identifier_or_type_name '(' push new_parameter_type_list_opt pop ')'
1189                // To obtain LR(1 ), this rule must be factored out from function return type (see new_abstract_declarator).
1190                {
1191                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1192                }
1193        | new_function_return identifier_or_type_name '(' push new_parameter_type_list_opt pop ')'
1194                {
1195                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1196                }
1197        ;
1198
1199new_function_return:                                                                    // CFA
1200        '[' push new_parameter_list pop ']'
1201                { $$ = DeclarationNode::newTuple( $3 ); }
1202        | '[' push new_parameter_list pop ',' push new_abstract_parameter_list pop ']'
1203                // To obtain LR(1 ), the last new_abstract_parameter_list is added into this flattened rule to lookahead to the
1204                // ']'.
1205                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1206        ;
1207
1208new_typedef_declaration:                                                                // CFA
1209        TYPEDEF new_variable_specifier
1210                {
1211                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1212                        $$ = $2->addTypedef();
1213                }
1214        | TYPEDEF new_function_specifier
1215                {
1216                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1217                        $$ = $2->addTypedef();
1218                }
1219        | new_typedef_declaration pop ',' push no_attr_identifier
1220                {
1221                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1222                        $$ = $1->appendList( $1->cloneType( $5 ) );
1223                }
1224        ;
1225
1226// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1227// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1228
1229typedef_declaration:
1230        TYPEDEF type_specifier declarator
1231                {
1232                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1233                        $$ = $3->addType( $2 )->addTypedef();
1234                }
1235        | typedef_declaration pop ',' push declarator
1236                {
1237                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1238                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1239                }
1240        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1241                {
1242                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1243                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1244                }
1245        | type_specifier TYPEDEF declarator
1246                {
1247                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1248                        $$ = $3->addType( $1 )->addTypedef();
1249                }
1250        | type_specifier TYPEDEF type_qualifier_list declarator
1251                {
1252                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1253                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1254                }
1255        ;
1256
1257typedef_expression:
1258                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1259        TYPEDEF no_attr_identifier '=' assignment_expression
1260                {
1261                        typedefTable.addToEnclosingScope( *$2, TypedefTable::TD );
1262                        $$ = DeclarationNode::newName( 0 ); // XXX
1263                }
1264        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1265                {
1266                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1267                        $$ = DeclarationNode::newName( 0 ); // XXX
1268                }
1269        ;
1270
1271old_declaration:
1272        declaring_list pop ';'
1273        | typedef_declaration pop ';'
1274        | typedef_expression pop ';'                                            // GCC, naming expression type
1275        | sue_declaration_specifier pop ';'
1276        ;
1277
1278declaring_list:
1279                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1280                // storage-class
1281        declaration_specifier declarator asm_name_opt initializer_opt
1282                {
1283                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1284                        $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1285                }
1286        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1287                {
1288                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1289                        $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1290                }
1291        ;
1292
1293declaration_specifier:                                                                  // type specifier + storage class
1294        basic_declaration_specifier
1295        | sue_declaration_specifier
1296        | typedef_declaration_specifier
1297        | typegen_declaration_specifier
1298        ;
1299
1300type_specifier:                                                                                 // declaration specifier - storage class
1301        basic_type_specifier
1302        | sue_type_specifier
1303        | typedef_type_specifier
1304        | typegen_type_specifier
1305        ;
1306
1307type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1308        // empty
1309                { $$ = nullptr; }
1310        | type_qualifier_list
1311        ;
1312
1313type_qualifier_list:
1314                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1315                //
1316                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1317                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1318                // appeared only once.
1319        type_qualifier
1320        | type_qualifier_list type_qualifier
1321                { $$ = $1->addQualifiers( $2 ); }
1322        ;
1323
1324type_qualifier:
1325        type_qualifier_name
1326        | attribute
1327                //{ $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
1328        ;
1329
1330type_qualifier_name:
1331        CONST
1332                { $$ = DeclarationNode::newQualifier( DeclarationNode::Const ); }
1333        | RESTRICT
1334                { $$ = DeclarationNode::newQualifier( DeclarationNode::Restrict ); }
1335        | VOLATILE
1336                { $$ = DeclarationNode::newQualifier( DeclarationNode::Volatile ); }
1337        | LVALUE                                                                                        // CFA
1338                { $$ = DeclarationNode::newQualifier( DeclarationNode::Lvalue ); }
1339        | ATOMIC
1340                { $$ = DeclarationNode::newQualifier( DeclarationNode::Atomic ); }
1341        | FORALL '('
1342                {
1343                        typedefTable.enterScope();
1344                }
1345          type_parameter_list ')'                                                       // CFA
1346                {
1347                        typedefTable.leaveScope();
1348                        $$ = DeclarationNode::newForall( $4 );
1349                }
1350        ;
1351
1352declaration_qualifier_list:
1353        storage_class_list
1354        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1355                { $$ = $1->addQualifiers( $2 ); }
1356        | declaration_qualifier_list type_qualifier_list storage_class_list
1357                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1358        ;
1359
1360storage_class_list:
1361                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1362                // only one of each is specified, except for inline, which can appear with the others.
1363                //
1364                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1365                // specifiers in a declaration.
1366        storage_class
1367        | storage_class_list storage_class
1368                { $$ = $1->addQualifiers( $2 ); }
1369        ;
1370
1371storage_class:
1372        EXTERN
1373                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Extern ); }
1374        | STATIC
1375                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Static ); }
1376        | AUTO
1377                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Auto ); }
1378        | REGISTER
1379                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Register ); }
1380        | INLINE                                                                                        // C99
1381                //{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Inline ); }
1382                { $$ = new DeclarationNode; $$->isInline = true; }
1383        | FORTRAN                                                                                       // C99
1384                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Fortran ); }
1385        | NORETURN                                                                                      // C11
1386                //{ $$ = DeclarationNode::newStorageClass( DeclarationNode::Noreturn ); }
1387                { $$ = new DeclarationNode; $$->isNoreturn = true; }
1388        | THREADLOCAL                                                                           // C11
1389                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Threadlocal ); }
1390        ;
1391
1392basic_type_name:
1393        CHAR
1394                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1395        | DOUBLE
1396                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1397        | FLOAT
1398                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1399        | INT
1400                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1401        | LONG
1402                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1403        | SHORT
1404                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1405        | SIGNED
1406                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1407        | UNSIGNED
1408                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1409        | VOID
1410                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1411        | BOOL                                                                                          // C99
1412                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1413        | COMPLEX                                                                                       // C99
1414                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1415        | IMAGINARY                                                                                     // C99
1416                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1417        | VALIST                                                                                        // GCC, __builtin_va_list
1418                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1419        | ZERO_T
1420                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1421        | ONE_T
1422                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1423        ;
1424
1425basic_declaration_specifier:
1426                // A semantic check is necessary for conflicting storage classes.
1427        basic_type_specifier
1428        | declaration_qualifier_list basic_type_specifier
1429                { $$ = $2->addQualifiers( $1 ); }
1430        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1431                { $$ = $1->addQualifiers( $2 ); }
1432        | basic_declaration_specifier storage_class type_qualifier_list
1433                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1434        | basic_declaration_specifier storage_class basic_type_specifier
1435                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1436        ;
1437
1438basic_type_specifier:
1439        direct_type_name
1440        | type_qualifier_list_opt indirect_type_name type_qualifier_list_opt
1441                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1442        ;
1443
1444direct_type_name:
1445                // A semantic check is necessary for conflicting type qualifiers.
1446        basic_type_name
1447        | type_qualifier_list basic_type_name
1448                { $$ = $2->addQualifiers( $1 ); }
1449        | direct_type_name type_qualifier
1450                { $$ = $1->addQualifiers( $2 ); }
1451        | direct_type_name basic_type_name
1452                { $$ = $1->addType( $2 ); }
1453        ;
1454
1455indirect_type_name:
1456        TYPEOF '(' type_name ')'                                                        // GCC: typeof(x) y;
1457                { $$ = $3; }
1458        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1459                { $$ = DeclarationNode::newTypeof( $3 ); }
1460        | ATTR_TYPEGENname '(' type_name ')'                            // CFA: e.g., @type(x) y;
1461                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1462        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1463                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1464        ;
1465
1466sue_declaration_specifier:
1467        sue_type_specifier
1468        | declaration_qualifier_list sue_type_specifier
1469                { $$ = $2->addQualifiers( $1 ); }
1470        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1471                { $$ = $1->addQualifiers( $2 ); }
1472        | sue_declaration_specifier storage_class type_qualifier_list
1473                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1474        ;
1475
1476sue_type_specifier:
1477        elaborated_type_name                                                            // struct, union, enum
1478        | type_qualifier_list elaborated_type_name
1479                { $$ = $2->addQualifiers( $1 ); }
1480        | sue_type_specifier type_qualifier
1481                { $$ = $1->addQualifiers( $2 ); }
1482        ;
1483
1484typedef_declaration_specifier:
1485        typedef_type_specifier
1486        | declaration_qualifier_list typedef_type_specifier
1487                { $$ = $2->addQualifiers( $1 ); }
1488        | typedef_declaration_specifier storage_class           // remaining OBSOLESCENT (see 2)
1489                { $$ = $1->addQualifiers( $2 ); }
1490        | typedef_declaration_specifier storage_class type_qualifier_list
1491                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1492        ;
1493
1494typedef_type_specifier:                                                                 // typedef types
1495        TYPEDEFname
1496                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1497        | type_qualifier_list TYPEDEFname
1498                { $$ = DeclarationNode::newFromTypedef( $2 )->addQualifiers( $1 ); }
1499        | typedef_type_specifier type_qualifier
1500                { $$ = $1->addQualifiers( $2 ); }
1501        ;
1502
1503elaborated_type_name:
1504        aggregate_name
1505        | enum_name
1506        ;
1507
1508aggregate_name:
1509        aggregate_key '{' field_declaration_list '}'
1510                { $$ = DeclarationNode::newAggregate( $1, nullptr, nullptr, $3, true ); }
1511        | aggregate_key no_attr_identifier_or_type_name
1512                {
1513                        typedefTable.makeTypedef( *$2 );
1514                        $$ = DeclarationNode::newAggregate( $1, $2, nullptr, nullptr, false );
1515                }
1516        | aggregate_key no_attr_identifier_or_type_name
1517                { typedefTable.makeTypedef( *$2 ); }
1518                '{' field_declaration_list '}'
1519                { $$ = DeclarationNode::newAggregate( $1, $2, nullptr, $5, true ); }
1520        | aggregate_key '(' type_name_list ')' '{' field_declaration_list '}' // CFA
1521                { $$ = DeclarationNode::newAggregate( $1, nullptr, $3, $6, false ); }
1522        | aggregate_key typegen_name                                            // CFA, S/R conflict
1523                { $$ = $2; }
1524        ;
1525
1526aggregate_key:
1527        STRUCT attribute_list_opt
1528                { $$ = DeclarationNode::Struct; }
1529        | UNION attribute_list_opt
1530                { $$ = DeclarationNode::Union; }
1531        ;
1532
1533field_declaration_list:
1534        // empty
1535                { $$ = nullptr; }
1536        | field_declaration_list field_declaration
1537                { $$ = $1 != 0 ? $1->appendList( $2 ) : $2; }
1538        ;
1539
1540field_declaration:
1541        new_field_declaring_list ';'                                            // CFA, new style field declaration
1542        | EXTENSION new_field_declaring_list ';'                        // GCC
1543                { $$ = $2->set_extension( true ); }
1544        | field_declaring_list ';'
1545        | EXTENSION field_declaring_list ';'                            // GCC
1546                {       // mark all fields in list
1547                        for ( DeclarationNode *iter = $2; iter != nullptr; iter = (DeclarationNode *)iter->get_next() )
1548                                iter->set_extension( true );
1549                        $$ = $2;
1550                }
1551        ;
1552
1553new_field_declaring_list:                                                               // CFA, new style field declaration
1554        new_abstract_declarator_tuple                                           // CFA, no field name
1555        | new_abstract_declarator_tuple no_attr_identifier_or_type_name
1556                { $$ = $1->addName( $2 ); }
1557        | new_field_declaring_list ',' no_attr_identifier_or_type_name
1558                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1559        | new_field_declaring_list ','                                          // CFA, no field name
1560                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1561        ;
1562
1563field_declaring_list:
1564        type_specifier field_declarator
1565                { $$ = $2->addType( $1 ); }
1566        | field_declaring_list ',' attribute_list_opt field_declarator
1567                { $$ = $1->appendList( $1->cloneBaseType( $4 ) ); }
1568        ;
1569
1570field_declarator:
1571        // empty
1572                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1573        | bit_subrange_size                                                                     // no field name
1574                { $$ = DeclarationNode::newBitfield( $1 ); }
1575        | variable_declarator bit_subrange_size_opt
1576                // A semantic check is required to ensure bit_subrange only appears on base type int.
1577                { $$ = $1->addBitfield( $2 ); }
1578        | variable_type_redeclarator bit_subrange_size_opt
1579                // A semantic check is required to ensure bit_subrange only appears on base type int.
1580                { $$ = $1->addBitfield( $2 ); }
1581        | variable_abstract_declarator                                          // CFA, no field name
1582        ;
1583
1584bit_subrange_size_opt:
1585        // empty
1586                { $$ = nullptr; }
1587        | bit_subrange_size
1588                { $$ = $1; }
1589        ;
1590
1591bit_subrange_size:
1592        ':' constant_expression
1593                { $$ = $2; }
1594        ;
1595
1596enum_key:
1597        ENUM attribute_list_opt
1598        ;
1599
1600enum_name:
1601        enum_key '{' enumerator_list comma_opt '}'
1602                { $$ = DeclarationNode::newEnum( nullptr, $3 ); }
1603        | enum_key no_attr_identifier_or_type_name
1604                {
1605                        typedefTable.makeTypedef( *$2 );
1606                        $$ = DeclarationNode::newEnum( $2, 0 );
1607                }
1608        | enum_key no_attr_identifier_or_type_name
1609                { typedefTable.makeTypedef( *$2 ); }
1610                '{' enumerator_list comma_opt '}'
1611                { $$ = DeclarationNode::newEnum( $2, $5 ); }
1612        ;
1613
1614enumerator_list:
1615        no_attr_identifier_or_type_name enumerator_value_opt
1616                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1617        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1618                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1619        ;
1620
1621enumerator_value_opt:
1622        // empty
1623                { $$ = nullptr; }
1624        | '=' constant_expression
1625                { $$ = $2; }
1626        ;
1627
1628// Minimum of one parameter after which ellipsis is allowed only at the end.
1629
1630new_parameter_type_list_opt:                                                    // CFA
1631        // empty
1632                { $$ = nullptr; }
1633        | new_parameter_type_list
1634        ;
1635
1636new_parameter_type_list:                                                                // CFA, abstract + real
1637        new_abstract_parameter_list
1638        | new_parameter_list
1639        | new_parameter_list pop ',' push new_abstract_parameter_list
1640                { $$ = $1->appendList( $5 ); }
1641        | new_abstract_parameter_list pop ',' push ELLIPSIS
1642                { $$ = $1->addVarArgs(); }
1643        | new_parameter_list pop ',' push ELLIPSIS
1644                { $$ = $1->addVarArgs(); }
1645        ;
1646
1647new_parameter_list:                                                                             // CFA
1648                // To obtain LR(1) between new_parameter_list and new_abstract_tuple, the last new_abstract_parameter_list is
1649                // factored out from new_parameter_list, flattening the rules to get lookahead to the ']'.
1650        new_parameter_declaration
1651        | new_abstract_parameter_list pop ',' push new_parameter_declaration
1652                { $$ = $1->appendList( $5 ); }
1653        | new_parameter_list pop ',' push new_parameter_declaration
1654                { $$ = $1->appendList( $5 ); }
1655        | new_parameter_list pop ',' push new_abstract_parameter_list pop ',' push new_parameter_declaration
1656                { $$ = $1->appendList( $5 )->appendList( $9 ); }
1657        ;
1658
1659new_abstract_parameter_list:                                                    // CFA, new & old style abstract
1660        new_abstract_parameter_declaration
1661        | new_abstract_parameter_list pop ',' push new_abstract_parameter_declaration
1662                { $$ = $1->appendList( $5 ); }
1663        ;
1664
1665parameter_type_list_opt:
1666        // empty
1667                { $$ = nullptr; }
1668        | parameter_type_list
1669        ;
1670
1671parameter_type_list:
1672        parameter_list
1673        | parameter_list pop ',' push ELLIPSIS
1674                { $$ = $1->addVarArgs(); }
1675        ;
1676
1677parameter_list:                                                                                 // abstract + real
1678        abstract_parameter_declaration
1679        | parameter_declaration
1680        | parameter_list pop ',' push abstract_parameter_declaration
1681                { $$ = $1->appendList( $5 ); }
1682        | parameter_list pop ',' push parameter_declaration
1683                { $$ = $1->appendList( $5 ); }
1684        ;
1685
1686// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
1687// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
1688
1689new_parameter_declaration:                                                              // CFA, new & old style parameter declaration
1690        parameter_declaration
1691        | new_identifier_parameter_declarator_no_tuple identifier_or_type_name assignment_opt
1692                { $$ = $1->addName( $2 ); }
1693        | new_abstract_tuple identifier_or_type_name assignment_opt
1694                // To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1695                { $$ = $1->addName( $2 ); }
1696        | type_qualifier_list new_abstract_tuple identifier_or_type_name assignment_opt
1697                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
1698        | new_function_specifier
1699        ;
1700
1701new_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
1702        abstract_parameter_declaration
1703        | new_identifier_parameter_declarator_no_tuple
1704        | new_abstract_tuple
1705                // To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1706        | type_qualifier_list new_abstract_tuple
1707                { $$ = $2->addQualifiers( $1 ); }
1708        | new_abstract_function
1709        ;
1710
1711parameter_declaration:
1712        declaration_specifier identifier_parameter_declarator assignment_opt
1713                {
1714                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1715                        $$ = $2->addType( $1 )->addInitializer( new InitializerNode( $3 ) );
1716                }
1717        | declaration_specifier type_parameter_redeclarator assignment_opt
1718                {
1719                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1720                        $$ = $2->addType( $1 )->addInitializer( new InitializerNode( $3 ) );
1721                }
1722        ;
1723
1724abstract_parameter_declaration:
1725        declaration_specifier
1726        | declaration_specifier abstract_parameter_declarator
1727                { $$ = $2->addType( $1 ); }
1728        ;
1729
1730// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
1731// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
1732// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
1733
1734identifier_list:                                                                                // K&R-style parameter list => no types
1735        no_attr_identifier
1736                { $$ = DeclarationNode::newName( $1 ); }
1737        | identifier_list ',' no_attr_identifier
1738                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
1739        ;
1740
1741identifier_or_type_name:
1742        identifier
1743        | TYPEDEFname
1744        | TYPEGENname
1745        ;
1746
1747no_01_identifier_or_type_name:
1748        no_01_identifier
1749        | TYPEDEFname
1750        | TYPEGENname
1751        ;
1752
1753no_attr_identifier_or_type_name:
1754        no_attr_identifier
1755        | TYPEDEFname
1756        | TYPEGENname
1757        ;
1758
1759type_name_no_function:                                                                  // sizeof, alignof, cast (constructor)
1760        new_abstract_declarator_tuple                                           // CFA
1761        | type_specifier
1762        | type_specifier variable_abstract_declarator
1763                { $$ = $2->addType( $1 ); }
1764        ;
1765
1766type_name:                                                                                              // typeof, assertion
1767        new_abstract_declarator_tuple                                           // CFA
1768        | new_abstract_function                                                         // CFA
1769        | type_specifier
1770        | type_specifier abstract_declarator
1771                { $$ = $2->addType( $1 ); }
1772        ;
1773
1774initializer_opt:
1775        // empty
1776                { $$ = nullptr; }
1777        | '=' initializer
1778                { $$ = $2; }
1779        | ATassign initializer
1780                { $$ = $2->set_maybeConstructed( false ); }
1781        ;
1782
1783initializer:
1784        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
1785        | '{' initializer_list comma_opt '}'            { $$ = new InitializerNode( $2, true ); }
1786        ;
1787
1788initializer_list:
1789        // empty
1790                { $$ = nullptr; }
1791        | initializer
1792        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
1793        | initializer_list ',' initializer                      { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
1794        | initializer_list ',' designation initializer
1795                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
1796        ;
1797
1798// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
1799// '=' to separator the designator from the initializer value, as in:
1800//
1801//              int x[10] = { [1] = 3 };
1802//
1803// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
1804// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
1805// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
1806// shift/reduce conflicts
1807
1808designation:
1809        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
1810        | no_attr_identifier_or_type_name ':'                           // GCC, field name
1811                { $$ = new ExpressionNode( build_varref( $1 ) ); }
1812        ;
1813
1814designator_list:                                                                                // C99
1815        designator
1816        | designator_list designator
1817                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
1818        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
1819        ;
1820
1821designator:
1822        '.' no_attr_identifier_or_type_name                                     // C99, field name
1823                { $$ = new ExpressionNode( build_varref( $2 ) ); }
1824        | '[' push assignment_expression pop ']'                        // C99, single array element
1825                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
1826                { $$ = $3; }
1827        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
1828                { $$ = $3; }
1829        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
1830                { $$ = new ExpressionNode( build_range( $3, $5 ) ); }
1831        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
1832                { $$ = $4; }
1833        ;
1834
1835// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
1836// rather than an object-oriented type system. This required four groups of extensions:
1837//
1838// Overloading: function, data, and operator identifiers may be overloaded.
1839//
1840// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
1841//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
1842//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
1843//
1844// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
1845//     site. A polymorphic function is not a template; it is a function, with an address and a type.
1846//
1847// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
1848//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
1849//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
1850//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
1851//     on type arguments of polymorphic functions.
1852
1853typegen_declaration_specifier:                                                  // CFA
1854        typegen_type_specifier
1855        | declaration_qualifier_list typegen_type_specifier
1856                { $$ = $2->addQualifiers( $1 ); }
1857        | typegen_declaration_specifier storage_class           // remaining OBSOLESCENT (see 2)
1858                { $$ = $1->addQualifiers( $2 ); }
1859        | typegen_declaration_specifier storage_class type_qualifier_list
1860                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1861        ;
1862
1863typegen_type_specifier:                                                                 // CFA
1864        typegen_name
1865        | type_qualifier_list typegen_name
1866                { $$ = $2->addQualifiers( $1 ); }
1867        | typegen_type_specifier type_qualifier
1868                { $$ = $1->addQualifiers( $2 ); }
1869        ;
1870
1871typegen_name:                                                                                   // CFA
1872        TYPEGENname '(' type_name_list ')'
1873                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1874        ;
1875
1876type_parameter_list:                                                                    // CFA
1877        type_parameter assignment_opt
1878        | type_parameter_list ',' type_parameter assignment_opt
1879                { $$ = $1->appendList( $3 ); }
1880        ;
1881
1882type_parameter:                                                                                 // CFA
1883        type_class no_attr_identifier_or_type_name
1884                { typedefTable.addToEnclosingScope( *$2, TypedefTable::TD ); }
1885          assertion_list_opt
1886                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addAssertions( $4 ); }
1887        | type_specifier identifier_parameter_declarator
1888        ;
1889
1890type_class:                                                                                             // CFA
1891        OTYPE
1892                { $$ = DeclarationNode::Otype; }
1893        | DTYPE
1894                { $$ = DeclarationNode::Ftype; }
1895        | FTYPE
1896                { $$ = DeclarationNode::Dtype; }
1897        ;
1898
1899assertion_list_opt:                                                                             // CFA
1900        // empty
1901                { $$ = nullptr; }
1902        | assertion_list_opt assertion
1903                { $$ = $1 != 0 ? $1->appendList( $2 ) : $2; }
1904        ;
1905
1906assertion:                                                                                              // CFA
1907        '|' no_attr_identifier_or_type_name '(' type_name_list ')'
1908                {
1909                        typedefTable.openTrait( *$2 );
1910                        $$ = DeclarationNode::newTraitUse( $2, $4 );
1911                }
1912        | '|' '{' push trait_declaration_list '}'
1913                { $$ = $4; }
1914        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_name_list ')'
1915                { $$ = nullptr; }
1916        ;
1917
1918type_name_list:                                                                                 // CFA
1919        type_name
1920                { $$ = new ExpressionNode( build_typevalue( $1 ) ); }
1921        | assignment_expression
1922        | type_name_list ',' type_name
1923                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( build_typevalue( $3 ) ) ) ); }
1924        | type_name_list ',' assignment_expression
1925                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
1926        ;
1927
1928type_declaring_list:                                                                    // CFA
1929        OTYPE type_declarator
1930                { $$ = $2; }
1931        | storage_class_list OTYPE type_declarator
1932                { $$ = $3->addQualifiers( $1 ); }
1933        | type_declaring_list ',' type_declarator
1934                { $$ = $1->appendList( $3->copyStorageClasses( $1 ) ); }
1935        ;
1936
1937type_declarator:                                                                                // CFA
1938        type_declarator_name assertion_list_opt
1939                { $$ = $1->addAssertions( $2 ); }
1940        | type_declarator_name assertion_list_opt '=' type_name
1941                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
1942        ;
1943
1944type_declarator_name:                                                                   // CFA
1945        no_attr_identifier_or_type_name
1946                {
1947                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TD );
1948                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
1949                }
1950        | no_01_identifier_or_type_name '(' push type_parameter_list pop ')'
1951                {
1952                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TG );
1953                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
1954                }
1955        ;
1956
1957trait_specifier:                                                                                // CFA
1958        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
1959                {
1960                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
1961                        $$ = DeclarationNode::newTrait( $2, $5, 0 );
1962                }
1963        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
1964                {
1965                        typedefTable.enterTrait( *$2 );
1966                        typedefTable.enterScope();
1967                }
1968          trait_declaration_list '}'
1969                {
1970                        typedefTable.leaveTrait();
1971                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
1972                        $$ = DeclarationNode::newTrait( $2, $5, $10 );
1973                }
1974        ;
1975
1976trait_declaration_list:                                                         // CFA
1977        trait_declaration
1978        | trait_declaration_list push trait_declaration
1979                { $$ = $1->appendList( $3 ); }
1980        ;
1981
1982trait_declaration:                                                                      // CFA
1983        new_trait_declaring_list pop ';'
1984        | trait_declaring_list pop ';'
1985        ;
1986
1987new_trait_declaring_list:                                                               // CFA
1988        new_variable_specifier
1989                {
1990                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
1991                        $$ = $1;
1992                }
1993        | new_function_specifier
1994                {
1995                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
1996                        $$ = $1;
1997                }
1998        | new_trait_declaring_list pop ',' push identifier_or_type_name
1999                {
2000                        typedefTable.addToEnclosingScope2( *$5, TypedefTable::ID );
2001                        $$ = $1->appendList( $1->cloneType( $5 ) );
2002                }
2003        ;
2004
2005trait_declaring_list:                                                                   // CFA
2006        type_specifier declarator
2007                {
2008                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2009                        $$ = $2->addType( $1 );
2010                }
2011        | trait_declaring_list pop ',' push declarator
2012                {
2013                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2014                        $$ = $1->appendList( $1->cloneBaseType( $5 ) );
2015                }
2016        ;
2017
2018//***************************** EXTERNAL DEFINITIONS *****************************
2019
2020translation_unit:
2021        // empty
2022                {}                                                                                              // empty input file
2023        | external_definition_list
2024                { parseTree = parseTree != nullptr ? parseTree->appendList( $1 ) : $1;  }
2025        ;
2026
2027external_definition_list:
2028        external_definition
2029        | external_definition_list push external_definition
2030                { $$ = $1 != nullptr ? $1->appendList( $3 ) : $3; }
2031        ;
2032
2033external_definition_list_opt:
2034        // empty
2035                { $$ = nullptr; }
2036        | external_definition_list
2037        ;
2038
2039external_definition:
2040        declaration
2041        | external_function_definition
2042        | asm_statement                                                                         // GCC, global assembler statement
2043                {}
2044        | EXTERN STRINGliteral
2045                {
2046                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2047                        linkage = LinkageSpec::linkageCheck( $2 );
2048                }
2049          '{' external_definition_list_opt '}'                          // C++-style linkage specifier
2050                {
2051                        linkage = linkageStack.top();
2052                        linkageStack.pop();
2053                        $$ = $5;
2054                }
2055        | EXTENSION external_definition
2056                {       // mark all fields in list
2057                        for ( DeclarationNode *iter = $2; iter != nullptr; iter = (DeclarationNode *)iter->get_next() )
2058                                iter->set_extension( true );
2059                        $$ = $2;
2060                }
2061        ;
2062
2063external_function_definition:
2064        function_definition
2065                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2066                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2067                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2068                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2069                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2070        | function_declarator compound_statement
2071                {
2072                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2073                        typedefTable.leaveScope();
2074                        $$ = $1->addFunctionBody( $2 );
2075                }
2076        | old_function_declarator push old_declaration_list_opt compound_statement
2077                {
2078                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2079                        typedefTable.leaveScope();
2080                        $$ = $1->addOldDeclList( $3 )->addFunctionBody( $4 );
2081                }
2082        ;
2083
2084function_definition:
2085        new_function_declaration compound_statement                     // CFA
2086                {
2087                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2088                        typedefTable.leaveScope();
2089                        $$ = $1->addFunctionBody( $2 );
2090                }
2091        | declaration_specifier function_declarator compound_statement
2092                {
2093                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2094                        typedefTable.leaveScope();
2095                        $$ = $2->addFunctionBody( $3 )->addType( $1 );
2096                }
2097        | type_qualifier_list function_declarator compound_statement
2098                {
2099                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2100                        typedefTable.leaveScope();
2101                        $$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
2102                }
2103        | declaration_qualifier_list function_declarator compound_statement
2104                {
2105                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2106                        typedefTable.leaveScope();
2107                        $$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
2108                }
2109        | declaration_qualifier_list type_qualifier_list function_declarator compound_statement
2110                {
2111                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2112                        typedefTable.leaveScope();
2113                        $$ = $3->addFunctionBody( $4 )->addQualifiers( $2 )->addQualifiers( $1 );
2114                }
2115
2116                // Old-style K&R function definition, OBSOLESCENT (see 4)
2117        | declaration_specifier old_function_declarator push old_declaration_list_opt compound_statement
2118                {
2119                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2120                        typedefTable.leaveScope();
2121                        $$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addType( $1 );
2122                }
2123        | type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2124                {
2125                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2126                        typedefTable.leaveScope();
2127                        $$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
2128                }
2129
2130                // Old-style K&R function definition with "implicit int" type_specifier, OBSOLESCENT (see 4)
2131        | declaration_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2132                {
2133                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2134                        typedefTable.leaveScope();
2135                        $$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
2136                }
2137        | declaration_qualifier_list type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2138                {
2139                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2140                        typedefTable.leaveScope();
2141                        $$ = $3->addOldDeclList( $5 )->addFunctionBody( $6 )->addQualifiers( $2 )->addQualifiers( $1 );
2142                }
2143        ;
2144
2145declarator:
2146        variable_declarator
2147        | variable_type_redeclarator
2148        | function_declarator
2149        ;
2150
2151subrange:
2152        constant_expression '~' constant_expression                     // CFA, integer subrange
2153                { $$ = new ExpressionNode( build_range( $1, $3 ) ); }
2154        ;
2155
2156asm_name_opt:                                                                                   // GCC
2157        // empty
2158                { $$ = nullptr; }
2159        | ASM '(' string_literal ')' attribute_list_opt
2160                { $$ = $3; }
2161        ;
2162
2163attribute_list_opt:                                                                             // GCC
2164        // empty
2165                { $$ = nullptr; }
2166        | attribute_list
2167        ;
2168
2169attribute_list:                                                                                 // GCC
2170        attribute
2171        | attribute_list attribute
2172                { $$ = $2->addQualifiers( $1 ); }
2173        ;
2174
2175attribute:                                                                                              // GCC
2176        ATTRIBUTE '(' '(' attribute_parameter_list ')' ')'
2177        //              { $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
2178                { $$ = nullptr; }
2179        ;
2180
2181attribute_parameter_list:                                                               // GCC
2182        attrib
2183        | attribute_parameter_list ',' attrib
2184        ;
2185
2186attrib:                                                                                                 // GCC
2187        // empty
2188        | any_word
2189        | any_word '(' comma_expression_opt ')' { delete $3; } // FIX ME: unimplemented
2190        ;
2191
2192any_word:                                                                                               // GCC
2193        identifier_or_type_name { delete $1; }                          // FIX ME: unimplemented
2194        | storage_class { delete $1; }                                          // FIX ME: unimplemented
2195        | basic_type_name { delete $1; }                                        // FIX ME: unimplemented
2196        | type_qualifier { delete $1; }                                         // FIX ME: unimplemented
2197        ;
2198
2199// ============================================================================
2200// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2201// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2202// in:
2203//
2204//              int (*f())[10] { ... };
2205//              ... (*f())[3] += 1;             // definition mimics usage
2206//
2207// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2208// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2209// ============================================================================
2210
2211// ----------------------------------------------------------------------------
2212// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2213// to define a variable or function prototype, e.g.:
2214//
2215//              valid declaration               invalid definition
2216//              -----------------               ------------------
2217//              int f;                                  int f {}
2218//              int *f;                                 int *f {}
2219//              int f[10];                              int f[10] {}
2220//              int (*f)(int);                  int (*f)(int) {}
2221//
2222// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2223// variable_declarator and function_declarator.
2224// ----------------------------------------------------------------------------
2225
2226// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2227// declaring an array of functions versus a pointer to an array of functions.
2228
2229variable_declarator:
2230        paren_identifier attribute_list_opt
2231                { $$ = $1->addQualifiers( $2 ); }
2232        | variable_ptr
2233        | variable_array attribute_list_opt
2234                { $$ = $1->addQualifiers( $2 ); }
2235        | variable_function attribute_list_opt
2236                { $$ = $1->addQualifiers( $2 ); }
2237        ;
2238
2239paren_identifier:
2240        identifier
2241                {
2242                        typedefTable.setNextIdentifier( *$1 );
2243                        $$ = DeclarationNode::newName( $1 );
2244                }
2245        | '(' paren_identifier ')'                                                      // redundant parenthesis
2246                { $$ = $2; }
2247        ;
2248
2249variable_ptr:
2250        ptrref_operator variable_declarator
2251                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2252        | ptrref_operator type_qualifier_list variable_declarator
2253                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2254        | '(' variable_ptr ')'
2255                { $$ = $2; }
2256        ;
2257
2258variable_array:
2259        paren_identifier array_dimension
2260                { $$ = $1->addArray( $2 ); }
2261        | '(' variable_ptr ')' array_dimension
2262                { $$ = $2->addArray( $4 ); }
2263        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2264                { $$ = $2->addArray( $4 ); }
2265        | '(' variable_array ')'                                                        // redundant parenthesis
2266                { $$ = $2; }
2267        ;
2268
2269variable_function:
2270        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2271                { $$ = $2->addParamList( $6 ); }
2272        | '(' variable_function ')'                                                     // redundant parenthesis
2273                { $$ = $2; }
2274        ;
2275
2276// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2277// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2278// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2279
2280function_declarator:
2281        function_no_ptr attribute_list_opt
2282                { $$ = $1->addQualifiers( $2 ); }
2283        | function_ptr
2284        | function_array attribute_list_opt
2285                { $$ = $1->addQualifiers( $2 ); }
2286        ;
2287
2288function_no_ptr:
2289        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2290                { $$ = $1->addParamList( $4 ); }
2291        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2292                { $$ = $2->addParamList( $6 ); }
2293        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2294                { $$ = $2; }
2295        ;
2296
2297function_ptr:
2298        ptrref_operator function_declarator
2299                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2300        | ptrref_operator type_qualifier_list function_declarator
2301                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2302        | '(' function_ptr ')'
2303                { $$ = $2; }
2304        ;
2305
2306function_array:
2307        '(' function_ptr ')' array_dimension
2308                { $$ = $2->addArray( $4 ); }
2309        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2310                { $$ = $2->addArray( $4 ); }
2311        | '(' function_array ')'                                                        // redundant parenthesis
2312                { $$ = $2; }
2313        ;
2314
2315// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4) that is not redefining a typedef name
2316// (see function_declarator for additional comments). The pattern precludes returning arrays and functions versus
2317// pointers to arrays and functions.
2318
2319old_function_declarator:
2320        old_function_no_ptr
2321        | old_function_ptr
2322        | old_function_array
2323        ;
2324
2325old_function_no_ptr:
2326        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2327                { $$ = $1->addIdList( $3 ); }
2328        | '(' old_function_ptr ')' '(' identifier_list ')'
2329                { $$ = $2->addIdList( $5 ); }
2330        | '(' old_function_no_ptr ')'                                           // redundant parenthesis
2331                { $$ = $2; }
2332        ;
2333
2334old_function_ptr:
2335        ptrref_operator old_function_declarator
2336                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2337        | ptrref_operator type_qualifier_list old_function_declarator
2338                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2339        | '(' old_function_ptr ')'
2340                { $$ = $2; }
2341        ;
2342
2343old_function_array:
2344        '(' old_function_ptr ')' array_dimension
2345                { $$ = $2->addArray( $4 ); }
2346        | '(' old_function_array ')' multi_array_dimension      // redundant parenthesis
2347                { $$ = $2->addArray( $4 ); }
2348        | '(' old_function_array ')'                                            // redundant parenthesis
2349                { $$ = $2; }
2350        ;
2351
2352// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2353//
2354//              typedef int foo;
2355//              {
2356//                 int foo; // redefine typedef name in new scope
2357//              }
2358//
2359// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2360// and functions versus pointers to arrays and functions.
2361
2362variable_type_redeclarator:
2363        paren_type attribute_list_opt
2364                { $$ = $1->addQualifiers( $2 ); }
2365        | type_ptr
2366        | type_array attribute_list_opt
2367                { $$ = $1->addQualifiers( $2 ); }
2368        | type_function attribute_list_opt
2369                { $$ = $1->addQualifiers( $2 ); }
2370        ;
2371
2372paren_type:
2373        typedef
2374        | '(' paren_type ')'
2375                { $$ = $2; }
2376        ;
2377
2378type_ptr:
2379        ptrref_operator variable_type_redeclarator
2380                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2381        | ptrref_operator type_qualifier_list variable_type_redeclarator
2382                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2383        | '(' type_ptr ')'
2384                { $$ = $2; }
2385        ;
2386
2387type_array:
2388        paren_type array_dimension
2389                { $$ = $1->addArray( $2 ); }
2390        | '(' type_ptr ')' array_dimension
2391                { $$ = $2->addArray( $4 ); }
2392        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2393                { $$ = $2->addArray( $4 ); }
2394        | '(' type_array ')'                                                            // redundant parenthesis
2395                { $$ = $2; }
2396        ;
2397
2398type_function:
2399        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2400                { $$ = $1->addParamList( $4 ); }
2401        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2402                { $$ = $2->addParamList( $6 ); }
2403        | '(' type_function ')'                                                         // redundant parenthesis
2404                { $$ = $2; }
2405        ;
2406
2407// This pattern parses a declaration for a parameter variable or function prototype that is not redefining a typedef
2408// name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes declaring an
2409// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
2410// arrays and functions.
2411
2412identifier_parameter_declarator:
2413        paren_identifier attribute_list_opt
2414                { $$ = $1->addQualifiers( $2 ); }
2415        | identifier_parameter_ptr
2416        | identifier_parameter_array attribute_list_opt
2417                { $$ = $1->addQualifiers( $2 ); }
2418        | identifier_parameter_function attribute_list_opt
2419                { $$ = $1->addQualifiers( $2 ); }
2420        ;
2421
2422identifier_parameter_ptr:
2423        ptrref_operator identifier_parameter_declarator
2424                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2425        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2426                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2427        | '(' identifier_parameter_ptr ')'
2428                { $$ = $2; }
2429        ;
2430
2431identifier_parameter_array:
2432        paren_identifier array_parameter_dimension
2433                { $$ = $1->addArray( $2 ); }
2434        | '(' identifier_parameter_ptr ')' array_dimension
2435                { $$ = $2->addArray( $4 ); }
2436        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2437                { $$ = $2->addArray( $4 ); }
2438        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2439                { $$ = $2; }
2440        ;
2441
2442identifier_parameter_function:
2443        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2444                { $$ = $1->addParamList( $4 ); }
2445        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2446                { $$ = $2->addParamList( $6 ); }
2447        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2448                { $$ = $2; }
2449        ;
2450
2451// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2452// e.g.:
2453//
2454//              typedef int foo;
2455//              int f( int foo ); // redefine typedef name in new scope
2456//
2457// and allows the C99 array options, which can only appear in a parameter list.  In addition, the pattern handles the
2458// special meaning of parenthesis around a typedef name:
2459//
2460//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2461//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2462//              not as redundant parentheses around the identifier."
2463//
2464// For example:
2465//
2466//              typedef float T;
2467//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2468//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2469//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2470//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2471//
2472// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2473// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2474// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2475// functions.
2476
2477type_parameter_redeclarator:
2478        typedef attribute_list_opt
2479                { $$ = $1->addQualifiers( $2 ); }
2480        | type_parameter_ptr
2481        | type_parameter_array attribute_list_opt
2482                { $$ = $1->addQualifiers( $2 ); }
2483        | type_parameter_function attribute_list_opt
2484                { $$ = $1->addQualifiers( $2 ); }
2485        ;
2486
2487typedef:
2488        TYPEDEFname
2489                {
2490                        typedefTable.setNextIdentifier( *$1 );
2491                        $$ = DeclarationNode::newName( $1 );
2492                }
2493        | TYPEGENname
2494                {
2495                        typedefTable.setNextIdentifier( *$1 );
2496                        $$ = DeclarationNode::newName( $1 );
2497                }
2498        ;
2499
2500type_parameter_ptr:
2501        ptrref_operator type_parameter_redeclarator
2502                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2503        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2504                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2505        | '(' type_parameter_ptr ')'
2506                { $$ = $2; }
2507        ;
2508
2509type_parameter_array:
2510        typedef array_parameter_dimension
2511                { $$ = $1->addArray( $2 ); }
2512        | '(' type_parameter_ptr ')' array_parameter_dimension
2513                { $$ = $2->addArray( $4 ); }
2514        ;
2515
2516type_parameter_function:
2517        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2518                { $$ = $1->addParamList( $4 ); }
2519        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2520                { $$ = $2->addParamList( $6 ); }
2521        ;
2522
2523// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2524// which the type applies, e.g.:
2525//
2526//              sizeof( int );
2527//              sizeof( int [10] );
2528//
2529// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2530// and functions versus pointers to arrays and functions.
2531
2532abstract_declarator:
2533        abstract_ptr
2534        | abstract_array attribute_list_opt
2535                { $$ = $1->addQualifiers( $2 ); }
2536        | abstract_function attribute_list_opt
2537                { $$ = $1->addQualifiers( $2 ); }
2538        ;
2539
2540abstract_ptr:
2541        ptrref_operator
2542                { $$ = DeclarationNode::newPointer( 0 ); }
2543        | ptrref_operator type_qualifier_list
2544                { $$ = DeclarationNode::newPointer( $2 ); }
2545        | ptrref_operator abstract_declarator
2546                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2547        | ptrref_operator type_qualifier_list abstract_declarator
2548                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2549        | '(' abstract_ptr ')'
2550                { $$ = $2; }
2551        ;
2552
2553abstract_array:
2554        array_dimension
2555        | '(' abstract_ptr ')' array_dimension
2556                { $$ = $2->addArray( $4 ); }
2557        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2558                { $$ = $2->addArray( $4 ); }
2559        | '(' abstract_array ')'                                                        // redundant parenthesis
2560                { $$ = $2; }
2561        ;
2562
2563abstract_function:
2564        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2565                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2566        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2567                { $$ = $2->addParamList( $6 ); }
2568        | '(' abstract_function ')'                                                     // redundant parenthesis
2569                { $$ = $2; }
2570        ;
2571
2572array_dimension:
2573                // Only the first dimension can be empty.
2574        '[' ']'
2575                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2576        | '[' ']' multi_array_dimension
2577                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2578        | multi_array_dimension
2579        ;
2580
2581multi_array_dimension:
2582        '[' push assignment_expression pop ']'
2583                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2584        | '[' push '*' pop ']'                                                          // C99
2585                { $$ = DeclarationNode::newVarArray( 0 ); }
2586        | multi_array_dimension '[' push assignment_expression pop ']'
2587                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2588        | multi_array_dimension '[' push '*' pop ']'            // C99
2589                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2590        ;
2591
2592// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2593// identifier to which the type applies, e.g.:
2594//
2595//              int f( int );                   // abstract variable parameter; no parameter name specified
2596//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2597//
2598// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2599// and functions versus pointers to arrays and functions.
2600
2601abstract_parameter_declarator:
2602        abstract_parameter_ptr
2603        | abstract_parameter_array attribute_list_opt
2604                { $$ = $1->addQualifiers( $2 ); }
2605        | abstract_parameter_function attribute_list_opt
2606                { $$ = $1->addQualifiers( $2 ); }
2607        ;
2608
2609abstract_parameter_ptr:
2610        ptrref_operator
2611                { $$ = DeclarationNode::newPointer( 0 ); }
2612        | ptrref_operator type_qualifier_list
2613                { $$ = DeclarationNode::newPointer( $2 ); }
2614        | ptrref_operator abstract_parameter_declarator
2615                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2616        | ptrref_operator type_qualifier_list abstract_parameter_declarator
2617                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2618        | '(' abstract_parameter_ptr ')'
2619                { $$ = $2; }
2620        ;
2621
2622abstract_parameter_array:
2623        array_parameter_dimension
2624        | '(' abstract_parameter_ptr ')' array_parameter_dimension
2625                { $$ = $2->addArray( $4 ); }
2626        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2627                { $$ = $2->addArray( $4 ); }
2628        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
2629                { $$ = $2; }
2630        ;
2631
2632abstract_parameter_function:
2633        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2634                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2635        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2636                { $$ = $2->addParamList( $6 ); }
2637        | '(' abstract_parameter_function ')'                           // redundant parenthesis
2638                { $$ = $2; }
2639        ;
2640
2641array_parameter_dimension:
2642                // Only the first dimension can be empty or have qualifiers.
2643        array_parameter_1st_dimension
2644        | array_parameter_1st_dimension multi_array_dimension
2645                { $$ = $1->addArray( $2 ); }
2646        | multi_array_dimension
2647        ;
2648
2649// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
2650//
2651//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
2652//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
2653
2654array_parameter_1st_dimension:
2655        '[' ']'
2656                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2657        // multi_array_dimension handles the '[' '*' ']' case
2658        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
2659                { $$ = DeclarationNode::newVarArray( $3 ); }
2660        | '[' push type_qualifier_list pop ']'
2661                { $$ = DeclarationNode::newArray( 0, $3, false ); }
2662        // multi_array_dimension handles the '[' assignment_expression ']' case
2663        | '[' push type_qualifier_list assignment_expression pop ']'
2664                { $$ = DeclarationNode::newArray( $4, $3, false ); }
2665        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
2666                { $$ = DeclarationNode::newArray( $5, $4, true ); }
2667        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
2668                { $$ = DeclarationNode::newArray( $5, $3, true ); }
2669        ;
2670
2671// This pattern parses a declaration of an abstract variable, i.e., there is no identifier to which the type applies,
2672// e.g.:
2673//
2674//              sizeof( int ); // abstract variable; no identifier name specified
2675//
2676// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2677// and functions versus pointers to arrays and functions.
2678
2679variable_abstract_declarator:
2680        variable_abstract_ptr
2681        | variable_abstract_array attribute_list_opt
2682                { $$ = $1->addQualifiers( $2 ); }
2683        | variable_abstract_function attribute_list_opt
2684                { $$ = $1->addQualifiers( $2 ); }
2685        ;
2686
2687variable_abstract_ptr:
2688        ptrref_operator
2689                { $$ = DeclarationNode::newPointer( 0 ); }
2690        | ptrref_operator type_qualifier_list
2691                { $$ = DeclarationNode::newPointer( $2 ); }
2692        | ptrref_operator variable_abstract_declarator
2693                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2694        | ptrref_operator type_qualifier_list variable_abstract_declarator
2695                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2696        | '(' variable_abstract_ptr ')'
2697                { $$ = $2; }
2698        ;
2699
2700variable_abstract_array:
2701        array_dimension
2702        | '(' variable_abstract_ptr ')' array_dimension
2703                { $$ = $2->addArray( $4 ); }
2704        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
2705                { $$ = $2->addArray( $4 ); }
2706        | '(' variable_abstract_array ')'                                       // redundant parenthesis
2707                { $$ = $2; }
2708        ;
2709
2710variable_abstract_function:
2711        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2712                { $$ = $2->addParamList( $6 ); }
2713        | '(' variable_abstract_function ')'                            // redundant parenthesis
2714                { $$ = $2; }
2715        ;
2716
2717// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
2718// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
2719
2720new_identifier_parameter_declarator_tuple:                              // CFA
2721        new_identifier_parameter_declarator_no_tuple
2722        | new_abstract_tuple
2723        | type_qualifier_list new_abstract_tuple
2724                { $$ = $2->addQualifiers( $1 ); }
2725        ;
2726
2727new_identifier_parameter_declarator_no_tuple:                   // CFA
2728        new_identifier_parameter_ptr
2729        | new_identifier_parameter_array
2730        ;
2731
2732new_identifier_parameter_ptr:                                                   // CFA
2733        ptrref_operator type_specifier
2734                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2735        | type_qualifier_list ptrref_operator type_specifier
2736                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2737        | ptrref_operator new_abstract_function
2738                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2739        | type_qualifier_list ptrref_operator new_abstract_function
2740                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2741        | ptrref_operator new_identifier_parameter_declarator_tuple
2742                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2743        | type_qualifier_list ptrref_operator new_identifier_parameter_declarator_tuple
2744                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2745        ;
2746
2747new_identifier_parameter_array:                                                 // CFA
2748                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
2749                // shift/reduce conflict with new-style empty (void) function return type.
2750        '[' ']' type_specifier
2751                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2752        | new_array_parameter_1st_dimension type_specifier
2753                { $$ = $2->addNewArray( $1 ); }
2754        | '[' ']' multi_array_dimension type_specifier
2755                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2756        | new_array_parameter_1st_dimension multi_array_dimension type_specifier
2757                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2758        | multi_array_dimension type_specifier
2759                { $$ = $2->addNewArray( $1 ); }
2760
2761        | '[' ']' new_identifier_parameter_ptr
2762                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2763        | new_array_parameter_1st_dimension new_identifier_parameter_ptr
2764                { $$ = $2->addNewArray( $1 ); }
2765        | '[' ']' multi_array_dimension new_identifier_parameter_ptr
2766                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2767        | new_array_parameter_1st_dimension multi_array_dimension new_identifier_parameter_ptr
2768                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2769        | multi_array_dimension new_identifier_parameter_ptr
2770                { $$ = $2->addNewArray( $1 ); }
2771        ;
2772
2773new_array_parameter_1st_dimension:
2774        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
2775                { $$ = DeclarationNode::newVarArray( $3 ); }
2776        | '[' push type_qualifier_list assignment_expression pop ']'
2777                { $$ = DeclarationNode::newArray( $4, $3, false ); }
2778        | '[' push declaration_qualifier_list assignment_expression pop ']'
2779                // declaration_qualifier_list must be used because of shift/reduce conflict with
2780                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
2781                // appear in this context.
2782                { $$ = DeclarationNode::newArray( $4, $3, true ); }
2783        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
2784                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
2785        ;
2786
2787// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
2788// identifier to which the type applies, e.g.:
2789//
2790//              [int] f( int );                         // abstract variable parameter; no parameter name specified
2791//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
2792//
2793// These rules need LR(3):
2794//
2795//              new_abstract_tuple identifier_or_type_name
2796//              '[' new_parameter_list ']' identifier_or_type_name '(' new_parameter_type_list_opt ')'
2797//
2798// since a function return type can be syntactically identical to a tuple type:
2799//
2800//              [int, int] t;
2801//              [int, int] f( int );
2802//
2803// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
2804// new_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
2805// lookahead. To accomplish this, new_abstract_declarator has an entry point without tuple, and tuple declarations are
2806// duplicated when appearing with new_function_specifier.
2807
2808new_abstract_declarator_tuple:                                                  // CFA
2809        new_abstract_tuple
2810        | type_qualifier_list new_abstract_tuple
2811                { $$ = $2->addQualifiers( $1 ); }
2812        | new_abstract_declarator_no_tuple
2813        ;
2814
2815new_abstract_declarator_no_tuple:                                               // CFA
2816        new_abstract_ptr
2817        | new_abstract_array
2818        ;
2819
2820new_abstract_ptr:                                                                               // CFA
2821        ptrref_operator type_specifier
2822                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2823        | type_qualifier_list ptrref_operator type_specifier
2824                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2825        | ptrref_operator new_abstract_function
2826                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2827        | type_qualifier_list ptrref_operator new_abstract_function
2828                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2829        | ptrref_operator new_abstract_declarator_tuple
2830                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2831        | type_qualifier_list ptrref_operator new_abstract_declarator_tuple
2832                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2833        ;
2834
2835new_abstract_array:                                                                             // CFA
2836                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
2837                // empty (void) function return type.
2838        '[' ']' type_specifier
2839                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
2840        | '[' ']' multi_array_dimension type_specifier
2841                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
2842        | multi_array_dimension type_specifier
2843                { $$ = $2->addNewArray( $1 ); }
2844        | '[' ']' new_abstract_ptr
2845                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
2846        | '[' ']' multi_array_dimension new_abstract_ptr
2847                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
2848        | multi_array_dimension new_abstract_ptr
2849                { $$ = $2->addNewArray( $1 ); }
2850        ;
2851
2852new_abstract_tuple:                                                                             // CFA
2853        '[' push new_abstract_parameter_list pop ']'
2854                { $$ = DeclarationNode::newTuple( $3 ); }
2855        ;
2856
2857new_abstract_function:                                                                  // CFA
2858//      '[' ']' '(' new_parameter_type_list_opt ')'
2859//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
2860        new_abstract_tuple '(' push new_parameter_type_list_opt pop ')'
2861                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
2862        | new_function_return '(' push new_parameter_type_list_opt pop ')'
2863                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
2864        ;
2865
2866// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
2867//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
2868//
2869// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
2870//    the declaration specifiers in a declaration is an obsolescent feature."
2871//
2872// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
2873//    prototype-format parameter type declarators) is an obsolescent feature."
2874//
2875// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
2876//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
2877
2878//************************* MISCELLANEOUS ********************************
2879
2880comma_opt:                                                                                              // redundant comma
2881        // empty
2882        | ','
2883        ;
2884
2885assignment_opt:
2886        // empty
2887                { $$ = nullptr; }
2888        | '=' assignment_expression
2889                { $$ = $2; }
2890        ;
2891
2892%%
2893// ----end of grammar----
2894
2895extern char *yytext;
2896
2897void yyerror( const char * ) {
2898        cout << "Error ";
2899        if ( yyfilename ) {
2900                cout << "in file " << yyfilename << " ";
2901        } // if
2902        cout << "at line " << yylineno << " reading token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << "\"" << endl;
2903}
2904
2905// Local Variables: //
2906// mode: c++ //
2907// tab-width: 4 //
2908// compile-command: "make install" //
2909// End: //
Note: See TracBrowser for help on using the repository browser.