source: src/Parser/parser.yy@ 55ba259e

stuck-waitfor-destruct
Last change on this file since 55ba259e was 55ba259e, checked in by Peter A. Buhr <pabuhr@…>, 2 years ago

clarify for-control for enumerations
  • Property mode set to 100644
File size: 177.7 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Jun 26 09:37:28 2024
13// Update Count : 6700
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "DeclarationNode.hpp" // for DeclarationNode, ...
51#include "ExpressionNode.hpp" // for ExpressionNode, ...
52#include "InitializerNode.hpp" // for InitializerNode, ...
53#include "ParserTypes.hpp"
54#include "StatementNode.hpp" // for build_...
55#include "TypedefTable.hpp"
56#include "TypeData.hpp"
57#include "AST/Type.hpp" // for BasicType, BasicKind
58#include "Common/SemanticError.hpp" // error_str
59#include "Common/Utility.hpp" // for maybeMoveBuild, maybeBuild, CodeLo...
60
61// lex uses __null in a boolean context, it's fine.
62#ifdef __clang__
63#pragma GCC diagnostic ignored "-Wparentheses-equality"
64#endif
65
66extern DeclarationNode * parseTree;
67extern ast::Linkage::Spec linkage;
68extern TypedefTable typedefTable;
69
70stack<ast::Linkage::Spec> linkageStack;
71
72bool appendStr( string & to, string & from ) {
73 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
74 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
75 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
76 // easier to let the C compiler handle this case.
77 //
78 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
79 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
80 // e.g., u"a" U"b" L"c" is disallowed.
81
82 if ( from[0] != '"' ) { // encoding ?
83 if ( to[0] != '"' ) { // encoding ?
84 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
85 yyerror( "non-matching string encodings for string-literal concatenation" );
86 return false; // parse error, must call YYERROR in action
87 } else if ( from[1] == '8' ) {
88 from.erase( 0, 1 ); // remove 2nd encoding
89 } // if
90 } else {
91 if ( from[1] == '8' ) { // move encoding to start
92 to = "u8" + to;
93 from.erase( 0, 1 ); // remove 2nd encoding
94 } else {
95 to = from[0] + to;
96 } // if
97 } // if
98 from.erase( 0, 1 ); // remove 2nd encoding
99 } // if
100 to += " " + from; // concatenated into single string
101 return true;
102} // appendStr
103
104DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
105 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
106 assert( declList );
107
108 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
109 // variables in the declaration list, e.g.,
110 //
111 // struct __attribute__(( aligned(128) )) S { ...
112 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
113 // struct S v4;
114 //
115 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
116 //
117 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
118 // to the declaration list.
119 //
120 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
121 //
122 // v1 => 128
123
124 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
125
126 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
127 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
128
129 // Start at second variable in declaration list and clone the type specifiers for each variable.
130 for ( DeclarationNode * cur = declList->next ; cur != nullptr; cur = cur->next ) {
131 cl->cloneBaseType( cur, copyattr ); // cur is modified
132 } // for
133
134 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
135 // extractType to recover the type for the aggregate instances.
136 declList->addType( cl, copyattr ); // cl IS DELETED!!!
137 return declList;
138} // distAttr
139
140void distExt( DeclarationNode * declaration ) {
141 // distribute EXTENSION across all declarations
142 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
143 iter->set_extension( true );
144 } // for
145} // distExt
146
147void distInl( DeclarationNode * declaration ) {
148 // distribute INLINE across all declarations
149 for ( DeclarationNode *iter = declaration ; iter != nullptr ; iter = iter->next ) {
150 iter->set_inLine( true );
151 } // for
152} // distInl
153
154void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
155 // distribute qualifiers across all non-variable declarations in a distribution statemement
156 for ( DeclarationNode * iter = declaration ; iter != nullptr ; iter = iter->next ) {
157 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
158 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
159 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
160 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
161 DeclarationNode * clone = qualifiers->clone();
162 if ( qualifiers->type ) { // forall clause ? (handles SC)
163 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
164 swap( clone->type->forall, iter->type->aggregate.params );
165 iter->addQualifiers( clone );
166 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
167 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
168 DeclarationNode newnode;
169 swap( newnode.type, iter->type->aggInst.aggregate );
170 swap( clone->type->forall, newnode.type->aggregate.params );
171 newnode.addQualifiers( clone );
172 swap( newnode.type, iter->type->aggInst.aggregate );
173 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
174 swap( clone->type->forall, iter->type->forall );
175 iter->addQualifiers( clone );
176 } // if
177 } else { // just SC qualifiers
178 iter->addQualifiers( clone );
179 } // if
180 } // for
181 delete qualifiers;
182} // distQual
183
184// There is an ambiguity for inline generic-routine return-types and generic routines.
185// forall( otype T ) struct S { int i; } bar( T ) {}
186// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
187// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
188// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
189// forall( otype T ) struct S { int T; };
190// forall( otype W ) bar( W ) {}
191
192void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
193 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
194 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
195 declSpec->type->aggregate.params = nullptr;
196 } // if
197} // rebindForall
198
199string * build_postfix_name( string * name ) {
200 *name = string("__postfix_func_") + *name;
201 return name;
202} // build_postfix_name
203
204DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
205 if ( nullptr == fieldList ) {
206 if ( !( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) {
207 stringstream ss;
208 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
209 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
210 return nullptr;
211 } // if
212 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
213 fieldList = DeclarationNode::newName( nullptr );
214 } // if
215
216 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
217 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
218 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
219 return temp;
220} // fieldDecl
221
222#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
223#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
224#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
225#define MISSING_ANON_FIELD "illegal syntax, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
226#define MISSING_LOW "illegal syntax, missing low value for up-to range so index is uninitialized."
227#define MISSING_HIGH "illegal syntax, missing high value for down-to range so index is uninitialized."
228
229static ForCtrl * makeForCtrl( const CodeLocation & location, DeclarationNode * init, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
230 // Wrap both comp/inc if they are non-null.
231 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
232 compop,
233 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
234 comp ) );
235 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
236 // choose += or -= for upto/downto
237 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
238 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
239 inc ) );
240 // The StatementNode call frees init->name, it must happen later.
241 return new ForCtrl( new StatementNode( init ), comp, inc );
242}
243
244ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
245 if ( index->initializer ) {
246 SemanticError( yylloc, "illegal syntax, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
247 } // if
248 if ( index->next ) {
249 SemanticError( yylloc, "illegal syntax, multiple loop indexes disallowed in for-loop declaration." );
250 } // if
251 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
252 return makeForCtrl( location, initDecl, compop, comp, inc );
253} // forCtrl
254
255ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
256 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
257 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
258 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicKind::SignedInt ) ) );
259 } // if
260 DeclarationNode * initDecl = distAttr(
261 DeclarationNode::newTypeof( type, true ),
262 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
263 );
264 return makeForCtrl( location, initDecl, compop, comp, inc );
265} // forCtrl
266
267#define MISSING_LOOP_INDEX "illegal syntax, only a single identifier or declaration allowed in initialization, e.g., for ( i; ... ) or for ( int i; ... ). Expression disallowed."
268
269ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
270 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
271 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
272 } else {
273 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
274 } // if
275} // forCtrl
276
277ForCtrl * enumRangeCtrl( ExpressionNode * index_expr, __attribute__((unused)) OperKinds compop, ExpressionNode * range_over_expr ) {
278 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index_expr->expr.get()) ) {
279 DeclarationNode * indexDecl = DeclarationNode::newName( new std::string(identifier->name) );
280 assert( range_over_expr );
281 return new ForCtrl( new StatementNode( indexDecl ), range_over_expr );
282 } else {
283 SemanticError( yylloc, MISSING_LOOP_INDEX ); return nullptr;
284 } // if
285} // enumRangeCtrl
286
287static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
288 SemanticError( yylloc, "illegal syntax, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
289 "Possible cause is misspelled type name or missing generic parameter.",
290 identifier1.c_str(), identifier2.c_str(), kind );
291} // IdentifierBeforeIdentifier
292
293static void IdentifierBeforeType( string & identifier, const char * kind ) {
294 SemanticError( yylloc, "illegal syntax, identifier \"%s\" cannot appear before a %s.\n"
295 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
296 identifier.c_str(), kind );
297} // IdentifierBeforeType
298
299bool forall = false; // aggregate have one or more forall qualifiers ?
300
301// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
302#define YYLLOC_DEFAULT(Cur, Rhs, N) \
303if ( N ) { \
304 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
305 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
306 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
307 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
308 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
309} else { \
310 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
311 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
312 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
313}
314%}
315
316%define parse.error verbose
317
318// Types declaration for productions
319
320%union {
321 // A raw token can be used.
322 Token tok;
323
324 // The general node types hold some generic node or list of nodes.
325 DeclarationNode * decl;
326 InitializerNode * init;
327 ExpressionNode * expr;
328 StatementNode * stmt;
329 ClauseNode * clause;
330 TypeData * type;
331
332 // Special "nodes" containing compound information.
333 CondCtl * ifctl;
334 ForCtrl * forctl;
335 LabelNode * labels;
336
337 // Various flags and single values that become fields later.
338 ast::AggregateDecl::Aggregate aggKey;
339 ast::TypeDecl::Kind tclass;
340 OperKinds oper;
341 bool is_volatile;
342 EnumHiding enum_hiding;
343 ast::ExceptionKind except_kind;
344 // String passes ownership with it.
345 std::string * str;
346
347 // Narrower node types are used to avoid constant unwrapping.
348 ast::WaitForStmt * wfs;
349 ast::WaitUntilStmt::ClauseNode * wucn;
350 ast::GenericExpr * genexpr;
351}
352
353// ************************ TERMINAL TOKENS ********************************
354
355// keywords
356%token TYPEDEF
357%token EXTERN STATIC AUTO REGISTER
358%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
359%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
360%token NORETURN // C11
361%token CONST VOLATILE
362%token RESTRICT // C99
363%token ATOMIC // C11
364%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
365%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
366%token BOOL COMPLEX IMAGINARY // C99
367%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
368%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
369%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
370%token ZERO_T ONE_T // CFA
371%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE COUNTOF // GCC
372%token OFFSETOF BASETYPEOF TYPEID // CFA
373%token ENUM STRUCT UNION
374%token EXCEPTION // CFA
375%token GENERATOR COROUTINE MONITOR THREAD // CFA
376%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
377// %token RESUME // CFA
378%token LABEL // GCC
379%token SUSPEND // CFA
380%token ATTRIBUTE EXTENSION // GCC
381%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
382%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
383%token CORUN COFOR
384%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
385%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
386%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
387
388// names and constants: lexer differentiates between identifier and typedef names
389%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
390%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
391%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
392%token<tok> DIRECTIVE
393// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
394// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
395// converted into the tuple index (.)(1). e.g., 3.x
396%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
397
398// multi-character operators
399%token ARROW // ->
400%token ICR DECR // ++ --
401%token LS RS // << >>
402%token LE GE EQ NE // <= >= == !=
403%token ANDAND OROR // && ||
404%token ATTR ELLIPSIS // @@ ...
405
406%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
407%token PLUSassign MINUSassign // += -=
408%token LSassign RSassign // <<= >>=
409%token ANDassign ERassign ORassign // &= ^= |=
410
411%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
412%token ATassign // @=
413
414%type<tok> identifier identifier_at identifier_or_type_name attr_name
415%type<tok> quasi_keyword
416%type<expr> string_literal
417%type<str> string_literal_list
418
419%type<enum_hiding> hide_opt visible_hide_opt
420
421// expressions
422%type<expr> constant
423%type<expr> tuple tuple_expression_list
424%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
425%type<expr> primary_expression postfix_expression unary_expression
426%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
427%type<expr> shift_expression relational_expression equality_expression
428%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
429%type<expr> logical_AND_expression logical_OR_expression
430%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
431%type<expr> comma_expression comma_expression_opt
432%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
433%type<ifctl> conditional_declaration
434%type<forctl> for_control_expression for_control_expression_list
435%type<oper> upupeq updown updowneq downupdowneq
436%type<expr> subrange
437%type<decl> asm_name_opt
438%type<expr> asm_operands_opt asm_operands_list asm_operand
439%type<labels> label_list
440%type<expr> asm_clobbers_list_opt
441%type<is_volatile> asm_volatile_opt
442%type<expr> handler_predicate_opt
443%type<genexpr> generic_association generic_assoc_list
444
445// statements
446%type<stmt> statement labeled_statement compound_statement
447%type<stmt> statement_decl statement_decl_list statement_list_nodecl
448%type<stmt> selection_statement
449%type<clause> switch_clause_list_opt switch_clause_list
450%type<expr> case_value
451%type<clause> case_clause case_value_list case_label case_label_list
452%type<stmt> iteration_statement jump_statement
453%type<stmt> expression_statement asm_statement
454%type<stmt> with_statement
455%type<expr> with_clause_opt
456%type<stmt> corun_statement cofor_statement
457%type<stmt> exception_statement
458%type<clause> handler_clause finally_clause
459%type<except_kind> handler_key
460%type<stmt> mutex_statement
461%type<expr> when_clause when_clause_opt waitfor waituntil timeout
462%type<stmt> waitfor_statement waituntil_statement
463%type<wfs> wor_waitfor_clause
464%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
465
466// declarations
467%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
468%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
469%type<decl> abstract_parameter_declaration
470
471%type<aggKey> aggregate_key aggregate_data aggregate_control
472%type<decl> aggregate_type aggregate_type_nobody
473
474%type<decl> assertion assertion_list assertion_list_opt
475
476%type<expr> bit_subrange_size_opt bit_subrange_size
477
478%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
479%type<type> basic_type_name_type
480%type<type> vtable vtable_opt default_opt
481
482%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
483
484%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
485%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
486
487%type<decl> elaborated_type elaborated_type_nobody
488
489%type<decl> enumerator_list enum_type enum_type_nobody enum_key enumerator_type
490%type<init> enumerator_value_opt
491
492%type<decl> external_definition external_definition_list external_definition_list_opt
493
494%type<decl> exception_declaration
495
496%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
497%type<expr> field field_name_list field_name fraction_constants_opt
498
499%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
500
501%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
502%type<decl> identifier_list
503
504%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
505%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
506%type<decl> cfa_abstract_ptr cfa_abstract_tuple
507
508%type<decl> cfa_array_parameter_1st_dimension
509
510%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
511%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
512
513%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
514%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
515
516%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_list_ellipsis_opt
517
518%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
519
520%type<decl> c_declaration static_assert
521%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
522%type<decl> KR_parameter_list KR_parameter_list_opt
523
524%type<decl> parameter_declaration parameter_list parameter_list_ellipsis_opt
525
526%type<decl> paren_identifier paren_type
527
528%type<decl> storage_class storage_class_list
529
530%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
531
532%type<tclass> type_class new_type_class
533%type<decl> type_declarator type_declarator_name type_declaring_list
534
535%type<decl> type_declaration_specifier type_type_specifier
536%type<type> type_name typegen_name
537%type<decl> typedef_name typedef_declaration typedef_expression
538
539%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
540%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
541
542%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
543
544%type<decl> type type_no_function
545%type<decl> type_parameter type_parameter_list type_initializer_opt
546
547%type<expr> type_parameters_opt type_list array_type_list // array_dimension_list
548
549%type<decl> type_qualifier forall type_qualifier_list_opt type_qualifier_list
550%type<type> type_qualifier_name
551%type<decl> type_specifier type_specifier_nobody
552
553%type<decl> variable_declarator variable_ptr variable_array variable_function
554%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
555
556%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
557
558// initializers
559%type<init> initializer initializer_list_opt initializer_opt
560
561// designators
562%type<expr> designator designator_list designation
563
564
565// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
566// .---------. matches IF '(' comma_expression ')' statement . (reduce)
567// if ( C ) S1 else S2
568// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
569// Similar issues exit with the waitfor statement.
570
571// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
572// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
573%precedence THEN // rule precedence for IF/WAITFOR statement
574%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
575%precedence WAND // token precedence for start of WAND in WAITFOR statement
576%precedence OROR // token precedence for start of WOR in WAITFOR statement
577%precedence WOR // token precedence for start of WOR in WAITFOR statement
578%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
579%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
580%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
581%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
582%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
583%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
584%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
585
586
587// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
588// forall( otype T ) struct Foo { T v; };
589// .-----. matches pointer to function returning a generic (which is impossible without a type)
590// Foo ( *fp )( int );
591// `---' matches start of TYPEGENname '('
592// must be:
593// Foo( int ) ( *fp )( int );
594// The same problem occurs here:
595// forall( otype T ) struct Foo { T v; } ( *fp )( int );
596// must be:
597// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
598
599// Order of these lines matters (low-to-high precedence).
600%precedence TYPEGENname
601%precedence '}'
602%precedence '('
603
604// %precedence RESUME
605// %precedence '{'
606// %precedence ')'
607
608%locations // support location tracking for error messages
609
610%start translation_unit // parse-tree root
611
612%%
613// ************************ Namespace Management ********************************
614
615// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
616// which are lexically identical.
617//
618// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
619// foo f; // to allow it to appear in this context
620//
621// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
622// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
623// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
624// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
625// must be distinguished by the lexical scanner.
626//
627// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
628// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
629// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
630// each context that introduces a name scope, a new level is created in the type table and that level is popped on
631// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
632// This requires distinguishing between type names that are local to the current declaration scope and those that
633// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
634//
635// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
636// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
637// around the list separator.
638//
639// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
640// push pop push pop
641
642push:
643 { typedefTable.enterScope(); }
644 ;
645
646pop:
647 { typedefTable.leaveScope(); }
648 ;
649
650// ************************ CONSTANTS ********************************
651
652constant:
653 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
654 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
655 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
656 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
657 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
658 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
659 ;
660
661quasi_keyword: // CFA
662 TIMEOUT
663 | WAND
664 | WOR
665 | CATCH
666 | RECOVER
667 | CATCHRESUME
668 | FIXUP
669 | FINALLY
670 ;
671
672identifier:
673 IDENTIFIER
674 | quasi_keyword
675 ;
676
677identifier_at:
678 identifier
679 | '@' // CFA
680 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
681 ;
682
683identifier_or_type_name:
684 identifier
685 | TYPEDEFname
686 | TYPEGENname
687 ;
688
689string_literal:
690 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
691 ;
692
693string_literal_list: // juxtaposed strings are concatenated
694 STRINGliteral { $$ = $1; } // conversion from tok to str
695 | string_literal_list STRINGliteral
696 {
697 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
698 delete $2; // allocated by lexer
699 $$ = $1; // conversion from tok to str
700 }
701 ;
702
703// ************************ EXPRESSIONS ********************************
704
705primary_expression:
706 IDENTIFIER // typedef name cannot be used as a variable name
707 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
708 | quasi_keyword
709 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
710 | TYPEDIMname // CFA, generic length argument
711 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
712 | tuple
713 | '(' comma_expression ')'
714 { $$ = $2; }
715 | '(' compound_statement ')' // GCC, lambda expression
716 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
717 | type_name '.' identifier // CFA, nested type
718 { $$ = new ExpressionNode( build_qualified_expr( yylloc, DeclarationNode::newFromTypeData( $1 ), build_varref( yylloc, $3 ) ) ); }
719 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
720 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
721 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
722 {
723 // add the missing control expression to the GenericExpr and return it
724 $5->control = maybeMoveBuild( $3 );
725 $$ = new ExpressionNode( $5 );
726 }
727 // | RESUME '(' comma_expression ')'
728 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
729 // | RESUME '(' comma_expression ')' compound_statement
730 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
731 | IDENTIFIER IDENTIFIER // invalid syntax rule
732 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
733 | IDENTIFIER type_qualifier // invalid syntax rule
734 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
735 | IDENTIFIER storage_class // invalid syntax rule
736 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
737 | IDENTIFIER basic_type_name // invalid syntax rule
738 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
739 | IDENTIFIER TYPEDEFname // invalid syntax rule
740 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
741 | IDENTIFIER TYPEGENname // invalid syntax rule
742 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
743 ;
744
745generic_assoc_list: // C11
746 generic_association
747 | generic_assoc_list ',' generic_association
748 {
749 // steal the association node from the singleton and delete the wrapper
750 assert( 1 == $3->associations.size() );
751 $1->associations.push_back( $3->associations.front() );
752 delete $3;
753 $$ = $1;
754 }
755 ;
756
757generic_association: // C11
758 type_no_function ':' assignment_expression
759 {
760 // create a GenericExpr wrapper with one association pair
761 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
762 }
763 | DEFAULT ':' assignment_expression
764 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
765 ;
766
767postfix_expression:
768 primary_expression
769 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
770 // Historic, transitional: Disallow commas in subscripts.
771 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
772 // Current: Commas in subscripts make tuples.
773 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, $3->set_last( $5 ) ) ) ) ); }
774 | postfix_expression '[' assignment_expression ']'
775 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
776 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
777 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
778 // equivalent to the old x[i,j].
779 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
780 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
781 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
782 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
783 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
784 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
785 {
786 Token fn;
787 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
788 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $1->set_last( $3 ) ) ) );
789 }
790 | postfix_expression '(' argument_expression_list_opt ')'
791 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
792 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
793 // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
794 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg" ) ) ),
795 $3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) ) ) ); }
796 | postfix_expression '`' identifier // CFA, postfix call
797 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
798 | constant '`' identifier // CFA, postfix call
799 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
800 | string_literal '`' identifier // CFA, postfix call
801 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
802
803 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
804 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
805 // them. For example:
806 //
807 // struct S;
808 // forall(T) struct T;
809 // union U;
810 // enum E { S, T, E };
811 // struct Z { int S, T, Z, E, U; };
812 // void fred () {
813 // Z z;
814 // z.S; // lexer returns S is TYPEDEFname
815 // z.T; // lexer returns T is TYPEGENname
816 // z.Z; // lexer returns Z is TYPEDEFname
817 // z.U; // lexer returns U is TYPEDEFname
818 // z.E; // lexer returns E is TYPEDEFname
819 // }
820 | postfix_expression '.' identifier_or_type_name
821 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
822
823 | postfix_expression '.' INTEGERconstant // CFA, tuple index
824 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
825 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
826 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
827 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
828 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
829 | postfix_expression '.' aggregate_control
830 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
831 | postfix_expression ARROW identifier
832 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
833 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
834 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
835 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
836 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
837 | postfix_expression ICR
838 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
839 | postfix_expression DECR
840 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
841 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
842 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
843 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
844 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
845 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
846 {
847 Token fn;
848 fn.str = new string( "^?{}" ); // location undefined
849 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), $2->set_last( $4 ) ) );
850 }
851 ;
852
853argument_expression_list_opt:
854 // empty
855 { $$ = nullptr; }
856 | argument_expression_list
857 ;
858
859argument_expression_list:
860 argument_expression
861 | argument_expression_list_opt ',' argument_expression
862 { $$ = $1->set_last( $3 ); }
863 ;
864
865argument_expression:
866 '@' // CFA, default parameter
867 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
868 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
869 | assignment_expression
870 ;
871
872field_name_list: // CFA, tuple field selector
873 field
874 | field_name_list ',' field { $$ = $1->set_last( $3 ); }
875 ;
876
877field: // CFA, tuple field selector
878 field_name
879 | FLOATING_DECIMALconstant field
880 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
881 | FLOATING_DECIMALconstant '[' field_name_list ']'
882 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
883 | field_name '.' field
884 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
885 | field_name '.' '[' field_name_list ']'
886 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
887 | field_name ARROW field
888 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
889 | field_name ARROW '[' field_name_list ']'
890 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
891 ;
892
893field_name:
894 INTEGERconstant fraction_constants_opt
895 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
896 | FLOATINGconstant fraction_constants_opt
897 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
898 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
899 {
900 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
901 }
902 ;
903
904fraction_constants_opt:
905 // empty
906 { $$ = nullptr; }
907 | fraction_constants_opt FLOATING_FRACTIONconstant
908 {
909 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
910 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
911 }
912 ;
913
914unary_expression:
915 postfix_expression
916 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
917 // semantics checks, e.g., ++3, 3--, *3, &&3
918 | constant
919 | string_literal
920 { $$ = $1; }
921 | EXTENSION cast_expression // GCC
922 { $$ = $2->set_extension( true ); }
923 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
924 // { * X; } // dereference X
925 // { * int X; } // CFA declaration of pointer to int
926 | ptrref_operator cast_expression // CFA
927 {
928 switch ( $1 ) {
929 case OperKinds::AddressOf:
930 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
931 break;
932 case OperKinds::PointTo:
933 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
934 break;
935 case OperKinds::And:
936 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
937 break;
938 default:
939 assert( false );
940 }
941 }
942 | unary_operator cast_expression
943 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
944 | ICR unary_expression
945 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
946 | DECR unary_expression
947 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
948 | SIZEOF unary_expression
949 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
950 | SIZEOF '(' type_no_function ')'
951 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
952 | ALIGNOF unary_expression // GCC, variable alignment
953 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
954 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
955 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
956
957 // Cannot use rule "type", which includes cfa_abstract_function, for sizeof/alignof, because of S/R problems on
958 // look ahead, so the cfa_abstract_function is factored out.
959 | SIZEOF '(' cfa_abstract_function ')'
960 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
961 | ALIGNOF '(' cfa_abstract_function ')' // GCC, type alignment
962 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
963
964 | OFFSETOF '(' type_no_function ',' identifier ')'
965 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
966 | TYPEID '(' type ')'
967 {
968 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
969 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
970 }
971 | COUNTOF '(' type_no_function ')'
972 { $$ = new ExpressionNode( new ast::CountExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
973 | COUNTOF unary_expression
974 { SemanticError( yylloc, "countof for expressions is currently unimplemented. "); $$ = nullptr; }
975 ;
976
977ptrref_operator:
978 '*' { $$ = OperKinds::PointTo; }
979 | '&' { $$ = OperKinds::AddressOf; }
980 // GCC, address of label must be handled by semantic check for ref,ref,label
981 | ANDAND { $$ = OperKinds::And; }
982 ;
983
984unary_operator:
985 '+' { $$ = OperKinds::UnPlus; }
986 | '-' { $$ = OperKinds::UnMinus; }
987 | '!' { $$ = OperKinds::Neg; }
988 | '~' { $$ = OperKinds::BitNeg; }
989 ;
990
991cast_expression:
992 unary_expression
993 | '(' type_no_function ')' cast_expression
994 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
995 | '(' aggregate_control '&' ')' cast_expression // CFA
996 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
997 | '(' aggregate_control '*' ')' cast_expression // CFA
998 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
999 | '(' VIRTUAL ')' cast_expression // CFA
1000 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), nullptr ) ); }
1001 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
1002 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
1003 | '(' RETURN type_no_function ')' cast_expression // CFA
1004 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
1005 | '(' COERCE type_no_function ')' cast_expression // CFA
1006 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
1007 | '(' qualifier_cast_list ')' cast_expression // CFA
1008 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
1009// | '(' type_no_function ')' tuple
1010// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
1011 ;
1012
1013qualifier_cast_list:
1014 cast_modifier type_qualifier_name
1015 | cast_modifier MUTEX
1016 | qualifier_cast_list cast_modifier type_qualifier_name
1017 | qualifier_cast_list cast_modifier MUTEX
1018 ;
1019
1020cast_modifier:
1021 '-'
1022 | '+'
1023 ;
1024
1025exponential_expression:
1026 cast_expression
1027 | exponential_expression '\\' cast_expression
1028 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1029 ;
1030
1031multiplicative_expression:
1032 exponential_expression
1033 | multiplicative_expression '*' exponential_expression
1034 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1035 | multiplicative_expression '/' exponential_expression
1036 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1037 | multiplicative_expression '%' exponential_expression
1038 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1039 ;
1040
1041additive_expression:
1042 multiplicative_expression
1043 | additive_expression '+' multiplicative_expression
1044 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1045 | additive_expression '-' multiplicative_expression
1046 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1047 ;
1048
1049shift_expression:
1050 additive_expression
1051 | shift_expression LS additive_expression
1052 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1053 | shift_expression RS additive_expression
1054 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1055 ;
1056
1057relational_expression:
1058 shift_expression
1059 | relational_expression '<' shift_expression
1060 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1061 | relational_expression '>' shift_expression
1062 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1063 | relational_expression LE shift_expression
1064 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1065 | relational_expression GE shift_expression
1066 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1067 ;
1068
1069equality_expression:
1070 relational_expression
1071 | equality_expression EQ relational_expression
1072 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1073 | equality_expression NE relational_expression
1074 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1075 ;
1076
1077AND_expression:
1078 equality_expression
1079 | AND_expression '&' equality_expression
1080 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1081 ;
1082
1083exclusive_OR_expression:
1084 AND_expression
1085 | exclusive_OR_expression '^' AND_expression
1086 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1087 ;
1088
1089inclusive_OR_expression:
1090 exclusive_OR_expression
1091 | inclusive_OR_expression '|' exclusive_OR_expression
1092 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1093 ;
1094
1095logical_AND_expression:
1096 inclusive_OR_expression
1097 | logical_AND_expression ANDAND inclusive_OR_expression
1098 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1099 ;
1100
1101logical_OR_expression:
1102 logical_AND_expression
1103 | logical_OR_expression OROR logical_AND_expression
1104 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1105 ;
1106
1107conditional_expression:
1108 logical_OR_expression
1109 | logical_OR_expression '?' comma_expression ':' conditional_expression
1110 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1111 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1112 { $$ = new ExpressionNode( build_cond( yylloc, $1, nullptr, $4 ) ); }
1113 ;
1114
1115constant_expression:
1116 conditional_expression
1117 ;
1118
1119assignment_expression:
1120 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1121 conditional_expression
1122 | unary_expression assignment_operator assignment_expression
1123 {
1124// if ( $2 == OperKinds::AtAssn ) {
1125// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1126// } else {
1127 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1128// } // if
1129 }
1130 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1131 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1132 ;
1133
1134assignment_expression_opt:
1135 // empty
1136 { $$ = nullptr; }
1137 | assignment_expression
1138 ;
1139
1140assignment_operator:
1141 simple_assignment_operator
1142 | compound_assignment_operator
1143 ;
1144
1145simple_assignment_operator:
1146 '=' { $$ = OperKinds::Assign; }
1147 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1148 ;
1149
1150compound_assignment_operator:
1151 EXPassign { $$ = OperKinds::ExpAssn; }
1152 | MULTassign { $$ = OperKinds::MulAssn; }
1153 | DIVassign { $$ = OperKinds::DivAssn; }
1154 | MODassign { $$ = OperKinds::ModAssn; }
1155 | PLUSassign { $$ = OperKinds::PlusAssn; }
1156 | MINUSassign { $$ = OperKinds::MinusAssn; }
1157 | LSassign { $$ = OperKinds::LSAssn; }
1158 | RSassign { $$ = OperKinds::RSAssn; }
1159 | ANDassign { $$ = OperKinds::AndAssn; }
1160 | ERassign { $$ = OperKinds::ERAssn; }
1161 | ORassign { $$ = OperKinds::OrAssn; }
1162 ;
1163
1164tuple: // CFA, tuple
1165 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1166 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1167// '[' ']'
1168// { $$ = new ExpressionNode( build_tuple() ); }
1169// | '[' push assignment_expression pop ']'
1170// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1171 '[' ',' tuple_expression_list ']'
1172 { $$ = new ExpressionNode( build_tuple( yylloc, (new ExpressionNode( nullptr ))->set_last( $3 ) ) ); }
1173 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1174 { $$ = new ExpressionNode( build_tuple( yylloc, $3->set_last( $6 ) ) ); }
1175 ;
1176
1177tuple_expression_list:
1178 assignment_expression
1179 | '@' // CFA
1180 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1181 | tuple_expression_list ',' assignment_expression
1182 { $$ = $1->set_last( $3 ); }
1183 | tuple_expression_list ',' '@'
1184 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1185 ;
1186
1187comma_expression:
1188 assignment_expression
1189 | comma_expression ',' assignment_expression
1190 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1191 ;
1192
1193comma_expression_opt:
1194 // empty
1195 { $$ = nullptr; }
1196 | comma_expression
1197 ;
1198
1199// ************************** STATEMENTS *******************************
1200
1201statement:
1202 labeled_statement
1203 | compound_statement
1204 | expression_statement
1205 | selection_statement
1206 | iteration_statement
1207 | jump_statement
1208 | with_statement
1209 | mutex_statement
1210 | waitfor_statement
1211 | waituntil_statement
1212 | corun_statement
1213 | cofor_statement
1214 | exception_statement
1215 | enable_disable_statement
1216 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1217 | asm_statement
1218 | DIRECTIVE
1219 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1220 ;
1221
1222labeled_statement:
1223 // labels cannot be identifiers 0 or 1
1224 identifier_or_type_name ':' attribute_list_opt statement
1225 { $$ = $4->add_label( yylloc, $1, $3 ); }
1226 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1227 {
1228 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1229 "where a declaration, case, or default is not a statement.\n"
1230 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1231 $$ = nullptr;
1232 }
1233 ;
1234
1235compound_statement:
1236 '{' '}'
1237 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1238 | '{' push
1239 local_label_declaration_opt // GCC, local labels appear at start of block
1240 statement_decl_list // C99, intermix declarations and statements
1241 pop '}'
1242 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1243 ;
1244
1245statement_decl_list: // C99
1246 statement_decl
1247 | statement_decl_list statement_decl
1248 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1249 ;
1250
1251statement_decl:
1252 declaration // CFA, new & old style declarations
1253 { $$ = new StatementNode( $1 ); }
1254 | EXTENSION declaration // GCC
1255 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1256 | function_definition
1257 { $$ = new StatementNode( $1 ); }
1258 | EXTENSION function_definition // GCC
1259 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1260 | statement
1261 ;
1262
1263statement_list_nodecl:
1264 statement
1265 | statement_list_nodecl statement
1266 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1267 | statement_list_nodecl error // invalid syntax rule
1268 { SemanticError( yylloc, "illegal syntax, declarations only allowed at the start of the switch body,"
1269 " i.e., after the '{'." ); $$ = nullptr; }
1270 ;
1271
1272expression_statement:
1273 comma_expression_opt ';'
1274 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1275 ;
1276
1277// "if", "switch", and "choose" require parenthesis around the conditional. See the following ambiguities without
1278// parenthesis:
1279//
1280// if x + y + z; => if ( x ) + y + z or if ( x + y ) + z
1281//
1282// switch O { }
1283//
1284// O{} => object-constructor for conditional, switch body ???
1285// O{} => O for conditional followed by switch body
1286//
1287// C++ has this problem, as it has the same constructor syntax.
1288//
1289// switch sizeof ( T ) { }
1290//
1291// sizeof ( T ) => sizeof of T for conditional followed by switch body
1292// sizeof ( T ) => sizeof of compound literal (T){ }, closing parenthesis ???
1293//
1294// Note the two grammar rules for sizeof (alignof)
1295//
1296// | SIZEOF unary_expression
1297// | SIZEOF '(' type_no_function ')'
1298//
1299// where the first DOES NOT require parenthesis! And C++ inherits this problem from C.
1300
1301selection_statement:
1302 IF '(' conditional_declaration ')' statement %prec THEN
1303 // explicitly deal with the shift/reduce conflict on if/else
1304 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1305 | IF '(' conditional_declaration ')' statement ELSE statement
1306 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1307 | SWITCH '(' comma_expression ')' case_clause
1308 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1309 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1310 {
1311 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1312 // The semantics of the declaration list is changed to include associated initialization, which is performed
1313 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1314 // statement around the switch. Statements after the initial declaration list can never be executed, and
1315 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1316 // statement.
1317 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1318 }
1319 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1320 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1321 | CHOOSE '(' comma_expression ')' case_clause // CFA
1322 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1323 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1324 {
1325 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1326 $$ = $7 ? new StatementNode( build_compound( yylloc, (new StatementNode( $7 ))->set_last( sw ) ) ) : sw;
1327 }
1328 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1329 { SemanticError( yylloc, "illegal syntax, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1330 ;
1331
1332conditional_declaration:
1333 comma_expression
1334 { $$ = new CondCtl( nullptr, $1 ); }
1335 | c_declaration // no semi-colon
1336 { $$ = new CondCtl( $1, nullptr ); }
1337 | cfa_declaration // no semi-colon
1338 { $$ = new CondCtl( $1, nullptr ); }
1339 | declaration comma_expression // semi-colon separated
1340 { $$ = new CondCtl( $1, $2 ); }
1341 ;
1342
1343// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1344// clause allows a list of values and subranges.
1345
1346case_value: // CFA
1347 constant_expression { $$ = $1; }
1348 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1349 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1350 | subrange // CFA, subrange
1351 ;
1352
1353case_value_list: // CFA
1354 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1355 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1356 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1357 ;
1358
1359case_label: // CFA
1360 CASE error // invalid syntax rule
1361 { SemanticError( yylloc, "illegal syntax, case list missing after case." ); $$ = nullptr; }
1362 | CASE case_value_list ':' { $$ = $2; }
1363 | CASE case_value_list error // invalid syntax rule
1364 { SemanticError( yylloc, "illegal syntax, colon missing after case list." ); $$ = nullptr; }
1365 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1366 // A semantic check is required to ensure only one default clause per switch/choose statement.
1367 | DEFAULT error // invalid syntax rule
1368 { SemanticError( yylloc, "illegal syntax, colon missing after default." ); $$ = nullptr; }
1369 ;
1370
1371case_label_list: // CFA
1372 case_label
1373 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1374 ;
1375
1376case_clause: // CFA
1377 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1378 ;
1379
1380switch_clause_list_opt: // CFA
1381 // empty
1382 { $$ = nullptr; }
1383 | switch_clause_list
1384 ;
1385
1386switch_clause_list: // CFA
1387 case_label_list statement_list_nodecl
1388 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1389 | switch_clause_list case_label_list statement_list_nodecl
1390 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1391 ;
1392
1393iteration_statement:
1394 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1395 { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1396 | WHILE '(' ')' statement ELSE statement // CFA
1397 {
1398 $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1399 SemanticWarning( yylloc, Warning::SuperfluousElse );
1400 }
1401 | WHILE '(' conditional_declaration ')' statement %prec THEN
1402 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1403 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1404 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1405 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1406 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1407 | DO statement WHILE '(' ')' ELSE statement // CFA
1408 {
1409 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1410 SemanticWarning( yylloc, Warning::SuperfluousElse );
1411 }
1412 | DO statement WHILE '(' comma_expression ')' ';'
1413 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1414 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1415 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1416 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1417 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1418 | FOR '(' ')' statement ELSE statement // CFA
1419 {
1420 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1421 SemanticWarning( yylloc, Warning::SuperfluousElse );
1422 }
1423 | FOR '(' for_control_expression_list ')' statement %prec THEN
1424 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1425 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1426 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1427 ;
1428
1429for_control_expression_list:
1430 for_control_expression
1431 | for_control_expression_list ':' for_control_expression
1432 // ForCtrl + ForCtrl:
1433 // init + init => multiple declaration statements that are hoisted
1434 // condition + condition => (expression) && (expression)
1435 // change + change => (expression), (expression)
1436 {
1437 $1->init->set_last( $3->init );
1438 if ( $1->condition ) {
1439 if ( $3->condition ) {
1440 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1441 } // if
1442 } else $1->condition = $3->condition;
1443 if ( $1->change ) {
1444 if ( $3->change ) {
1445 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1446 } // if
1447 } else $1->change = $3->change;
1448 $$ = $1;
1449 }
1450 ;
1451
1452for_control_expression:
1453 ';' comma_expression_opt ';' comma_expression_opt
1454 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1455 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1456 {
1457 $$ = new ForCtrl( $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr, $3, $5 );
1458 }
1459 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1460 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1461
1462 | '@' ';' comma_expression // CFA, empty loop-index
1463 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1464 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1465 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1466
1467 | comma_expression // CFA, anonymous loop-index
1468 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1469 | downupdowneq comma_expression // CFA, anonymous loop-index
1470 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1471
1472 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1473 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1474 | '@' updowneq comma_expression // CFA, anonymous loop-index
1475 {
1476 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1477 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1478 }
1479 | comma_expression updowneq '@' // CFA, anonymous loop-index
1480 {
1481 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1482 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1483 }
1484 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1485 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1486 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1487 {
1488 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1489 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1490 }
1491 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1492 {
1493 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1494 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1495 }
1496 | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1497 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1498 | '@' updowneq '@' // CFA, invalid syntax rule
1499 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1500 | '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1501 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1502 | comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1503 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1504 | '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1505 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1506
1507 // These rules accept a comma_expression for the initialization, when only an identifier is correct. Being
1508 // permissive allows for a better error message from forCtrl.
1509 | comma_expression ';' comma_expression // CFA
1510 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1511 | comma_expression ';' downupdowneq comma_expression // CFA
1512 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1513
1514 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1515 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1516 | comma_expression ';' '@' updowneq comma_expression // CFA
1517 {
1518 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1519 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1520 }
1521 | comma_expression ';' comma_expression updowneq '@' // CFA
1522 {
1523 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1524 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1525 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1526 }
1527 | comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1528 { SemanticError( yylloc, "illegal syntax, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1529
1530 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1531 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1532 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1533 {
1534 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1535 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1536 }
1537 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1538 {
1539 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1540 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1541 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1542 }
1543 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1544 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1545 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1546 {
1547 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1548 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1549 }
1550 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1551 {
1552 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1553 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1554 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1555 }
1556 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1557 { SemanticError( yylloc, "illegal syntax, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1558
1559 | declaration comma_expression // CFA
1560 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1561 | declaration downupdowneq comma_expression // CFA
1562 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1563
1564 | declaration comma_expression updowneq comma_expression // CFA
1565 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1566 | declaration '@' updowneq comma_expression // CFA
1567 {
1568 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1569 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1570 }
1571 | declaration comma_expression updowneq '@' // CFA
1572 {
1573 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1574 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1575 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1576 }
1577
1578 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1579 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1580 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1581 {
1582 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1583 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1584 }
1585 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1586 {
1587 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1588 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1589 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1590 }
1591 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1592 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1593 | declaration '@' updowneq comma_expression '~' '@' // CFA
1594 {
1595 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1596 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1597 }
1598 | declaration comma_expression updowneq '@' '~' '@' // CFA
1599 {
1600 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1601 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "illegal syntax, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1602 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1603 }
1604 | declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1605 { SemanticError( yylloc, "illegal syntax, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1606
1607 | comma_expression ';' enum_key // CFA, enum type
1608 {
1609 $$ = enumRangeCtrl( $1, OperKinds::LEThan, new ExpressionNode( new ast::TypeExpr( yylloc, $3->buildType() ) ) );
1610 }
1611 | comma_expression ';' downupdowneq enum_key // CFA, enum type, reverse direction
1612 {
1613 if ( $3 == OperKinds::GThan ) {
1614 SemanticError( yylloc, "all enumeration ranges are equal (all values). Add an equal, e.g., ~=, -~=." ); $$ = nullptr;
1615 $3 = OperKinds::GEThan;
1616 } // if
1617 $$ = enumRangeCtrl( $1, $3, new ExpressionNode( new ast::TypeExpr( yylloc, $4->buildType() ) ) );
1618 }
1619 ;
1620
1621enum_key:
1622 type_name
1623 { $$ = DeclarationNode::newEnum( $1->symbolic.name, nullptr, false, false ); }
1624 | ENUM identifier
1625 { $$ = DeclarationNode::newEnum( $2, nullptr, false, false ); }
1626 | ENUM type_name
1627 { $$ = DeclarationNode::newEnum( $2->symbolic.name, nullptr, false, false ); }
1628 ;
1629
1630// This rule exists to handle the ambiguity with unary operator '~'. The rule is the same as updowneq minus the '~'.
1631// Specifically, "for ( ~5 )" means the complement of 5, not loop 0..4. Hence, in this case "for ( ~= 5 )", i.e., 0..5,
1632// it is not possible to just remove the '='. The entire '~=' must be removed.
1633downupdowneq:
1634 ErangeDown
1635 { $$ = OperKinds::GThan; }
1636 | ErangeUpEq
1637 { $$ = OperKinds::LEThan; }
1638 | ErangeDownEq
1639 { $$ = OperKinds::GEThan; }
1640 ;
1641
1642updown:
1643 '~'
1644 { $$ = OperKinds::LThan; }
1645 | ErangeDown
1646 { $$ = OperKinds::GThan; }
1647 ;
1648
1649updowneq:
1650 updown
1651 | ErangeUpEq
1652 { $$ = OperKinds::LEThan; }
1653 | ErangeDownEq
1654 { $$ = OperKinds::GEThan; }
1655 ;
1656
1657jump_statement:
1658 GOTO identifier_or_type_name ';'
1659 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1660 | GOTO '*' comma_expression ';' // GCC, computed goto
1661 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1662 // whereas normal operator precedence yields goto (*i)+3;
1663 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1664 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1665 | fall_through_name ';' // CFA
1666 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1667 | fall_through_name identifier_or_type_name ';' // CFA
1668 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1669 | fall_through_name DEFAULT ';' // CFA
1670 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1671 | CONTINUE ';'
1672 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1673 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1674 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1675 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1676 // the target of the transfer appears only at the start of an iteration statement.
1677 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1678 | BREAK ';'
1679 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1680 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1681 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1682 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1683 // the target of the transfer appears only at the start of an iteration statement.
1684 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1685 | RETURN comma_expression_opt ';'
1686 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1687 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1688 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1689 | SUSPEND ';'
1690 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1691 | SUSPEND compound_statement
1692 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1693 | SUSPEND COROUTINE ';'
1694 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1695 | SUSPEND COROUTINE compound_statement
1696 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1697 | SUSPEND GENERATOR ';'
1698 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1699 | SUSPEND GENERATOR compound_statement
1700 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1701 | THROW assignment_expression_opt ';' // handles rethrow
1702 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1703 | THROWRESUME assignment_expression_opt ';' // handles reresume
1704 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1705 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1706 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1707 ;
1708
1709fall_through_name: // CFA
1710 FALLTHRU
1711 | FALLTHROUGH
1712 ;
1713
1714with_statement:
1715 WITH '(' type_list ')' statement // support scoped enumeration
1716 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1717 ;
1718
1719// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1720mutex_statement:
1721 MUTEX '(' argument_expression_list_opt ')' statement
1722 {
1723 if ( ! $3 ) { SemanticError( yylloc, "illegal syntax, mutex argument list cannot be empty." ); $$ = nullptr; }
1724 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1725 }
1726 ;
1727
1728when_clause:
1729 WHEN '(' comma_expression ')' { $$ = $3; }
1730 ;
1731
1732when_clause_opt:
1733 // empty
1734 { $$ = nullptr; }
1735 | when_clause
1736 ;
1737
1738cast_expression_list:
1739 cast_expression
1740 | cast_expression_list ',' cast_expression
1741 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1742 ;
1743
1744timeout:
1745 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1746 ;
1747
1748wor:
1749 OROR
1750 | WOR
1751
1752waitfor:
1753 WAITFOR '(' cast_expression ')'
1754 { $$ = $3; }
1755 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1756 { $$ = $3->set_last( $5 ); }
1757 ;
1758
1759wor_waitfor_clause:
1760 when_clause_opt waitfor statement %prec THEN
1761 // Called first: create header for WaitForStmt.
1762 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1763 | wor_waitfor_clause wor when_clause_opt waitfor statement
1764 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1765 | wor_waitfor_clause wor when_clause_opt ELSE statement
1766 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1767 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1768 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1769 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1770 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1771 { SemanticError( yylloc, "illegal syntax, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1772 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1773 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1774 ;
1775
1776waitfor_statement:
1777 wor_waitfor_clause %prec THEN
1778 { $$ = new StatementNode( $1 ); }
1779 ;
1780
1781wand:
1782 ANDAND
1783 | WAND
1784 ;
1785
1786waituntil:
1787 WAITUNTIL '(' comma_expression ')'
1788 { $$ = $3; }
1789 ;
1790
1791waituntil_clause:
1792 when_clause_opt waituntil statement
1793 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1794 | '(' wor_waituntil_clause ')'
1795 { $$ = $2; }
1796 ;
1797
1798wand_waituntil_clause:
1799 waituntil_clause %prec THEN
1800 { $$ = $1; }
1801 | waituntil_clause wand wand_waituntil_clause
1802 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1803 ;
1804
1805wor_waituntil_clause:
1806 wand_waituntil_clause
1807 { $$ = $1; }
1808 | wor_waituntil_clause wor wand_waituntil_clause
1809 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1810 | wor_waituntil_clause wor when_clause_opt ELSE statement
1811 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1812 ;
1813
1814waituntil_statement:
1815 wor_waituntil_clause %prec THEN
1816 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1817 ;
1818
1819corun_statement:
1820 CORUN statement
1821 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1822 ;
1823
1824cofor_statement:
1825 COFOR '(' for_control_expression_list ')' statement
1826 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1827 ;
1828
1829exception_statement:
1830 TRY compound_statement handler_clause %prec THEN
1831 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1832 | TRY compound_statement finally_clause
1833 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1834 | TRY compound_statement handler_clause finally_clause
1835 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1836 ;
1837
1838handler_clause:
1839 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1840 { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1841 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1842 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1843 ;
1844
1845handler_predicate_opt:
1846 // empty
1847 { $$ = nullptr; }
1848 | ';' conditional_expression { $$ = $2; }
1849 ;
1850
1851handler_key:
1852 CATCH { $$ = ast::Terminate; }
1853 | RECOVER { $$ = ast::Terminate; }
1854 | CATCHRESUME { $$ = ast::Resume; }
1855 | FIXUP { $$ = ast::Resume; }
1856 ;
1857
1858finally_clause:
1859 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1860 ;
1861
1862exception_declaration:
1863 // No SUE declaration in parameter list.
1864 type_specifier_nobody
1865 | type_specifier_nobody declarator
1866 { $$ = $2->addType( $1 ); }
1867 | type_specifier_nobody variable_abstract_declarator
1868 { $$ = $2->addType( $1 ); }
1869 | cfa_abstract_declarator_tuple identifier // CFA
1870 { $$ = $1->addName( $2 ); }
1871 | cfa_abstract_declarator_tuple // CFA
1872 ;
1873
1874enable_disable_statement:
1875 enable_disable_key identifier_list compound_statement
1876 ;
1877
1878enable_disable_key:
1879 ENABLE
1880 | DISABLE
1881 ;
1882
1883asm_statement:
1884 ASM asm_volatile_opt '(' string_literal ')' ';'
1885 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1886 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1887 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1888 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1889 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1890 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1891 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1892 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1893 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1894 ;
1895
1896asm_volatile_opt: // GCC
1897 // empty
1898 { $$ = false; }
1899 | VOLATILE
1900 { $$ = true; }
1901 ;
1902
1903asm_operands_opt: // GCC
1904 // empty
1905 { $$ = nullptr; } // use default argument
1906 | asm_operands_list
1907 ;
1908
1909asm_operands_list: // GCC
1910 asm_operand
1911 | asm_operands_list ',' asm_operand
1912 { $$ = $1->set_last( $3 ); }
1913 ;
1914
1915asm_operand: // GCC
1916 string_literal '(' constant_expression ')'
1917 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1918 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1919 {
1920 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1921 delete $2.str;
1922 }
1923 ;
1924
1925asm_clobbers_list_opt: // GCC
1926 // empty
1927 { $$ = nullptr; } // use default argument
1928 | string_literal
1929 { $$ = $1; }
1930 | asm_clobbers_list_opt ',' string_literal
1931 { $$ = $1->set_last( $3 ); }
1932 ;
1933
1934label_list:
1935 identifier
1936 {
1937 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1938 delete $1; // allocated by lexer
1939 }
1940 | label_list ',' identifier
1941 {
1942 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1943 delete $3; // allocated by lexer
1944 }
1945 ;
1946
1947// ****************************** DECLARATIONS *********************************
1948
1949declaration_list_opt: // used at beginning of switch statement
1950 // empty
1951 { $$ = nullptr; }
1952 | declaration_list
1953 ;
1954
1955declaration_list:
1956 declaration
1957 | declaration_list declaration
1958 { $$ = $1->set_last( $2 ); }
1959 ;
1960
1961KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1962 // empty
1963 { $$ = nullptr; }
1964 | KR_parameter_list
1965 ;
1966
1967KR_parameter_list:
1968 c_declaration ';'
1969 { $$ = $1; }
1970 | KR_parameter_list c_declaration ';'
1971 { $$ = $1->set_last( $2 ); }
1972 ;
1973
1974local_label_declaration_opt: // GCC, local label
1975 // empty
1976 | local_label_declaration_list
1977 ;
1978
1979local_label_declaration_list: // GCC, local label
1980 LABEL local_label_list ';'
1981 | local_label_declaration_list LABEL local_label_list ';'
1982 ;
1983
1984local_label_list: // GCC, local label
1985 identifier_or_type_name
1986 | local_label_list ',' identifier_or_type_name
1987 ;
1988
1989declaration: // old & new style declarations
1990 c_declaration ';'
1991 | cfa_declaration ';' // CFA
1992 | static_assert // C11
1993 ;
1994
1995static_assert:
1996 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1997 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1998 | STATICASSERT '(' constant_expression ')' ';' // CFA
1999 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
2000
2001// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
2002// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
2003// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
2004// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
2005// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
2006// block, but cannot be mixed within a specific declaration.
2007//
2008// CFA C
2009// [10] int x; int x[10]; // array of 10 integers
2010// [10] * char y; char *y[10]; // array of 10 pointers to char
2011
2012cfa_declaration: // CFA
2013 cfa_variable_declaration
2014 | cfa_typedef_declaration
2015 | cfa_function_declaration
2016 | type_declaring_list
2017 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
2018 | trait_specifier
2019 ;
2020
2021cfa_variable_declaration: // CFA
2022 cfa_variable_specifier initializer_opt
2023 { $$ = $1->addInitializer( $2 ); }
2024 | declaration_qualifier_list cfa_variable_specifier initializer_opt
2025 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
2026 // them as a type_qualifier cannot appear in that context.
2027 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
2028 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
2029 { $$ = $1->set_last( $1->cloneType( $5 )->addInitializer( $6 ) ); }
2030 ;
2031
2032cfa_variable_specifier: // CFA
2033 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2034 // storage-class
2035 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
2036 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2037 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
2038 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
2039 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
2040 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
2041
2042 // [ int s, int t ]; // declare s and t
2043 // [ int, int ] f();
2044 // [] g( int );
2045 // [ int x, int y ] = f(); // declare x and y, initialize each from f
2046 // g( x + y );
2047 | cfa_function_return asm_name_opt
2048 { SemanticError( yylloc, "tuple-element declarations is currently unimplemented." ); $$ = nullptr; }
2049 | type_qualifier_list cfa_function_return asm_name_opt
2050 { SemanticError( yylloc, "tuple variable declaration is currently unimplemented." ); $$ = nullptr; }
2051 ;
2052
2053cfa_function_declaration: // CFA
2054 cfa_function_specifier
2055 | type_qualifier_list cfa_function_specifier
2056 { $$ = $2->addQualifiers( $1 ); }
2057 | declaration_qualifier_list cfa_function_specifier
2058 { $$ = $2->addQualifiers( $1 ); }
2059 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
2060 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
2061 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')'
2062 {
2063 // Append the return type at the start (left-hand-side) to each identifier in the list.
2064 DeclarationNode * ret = new DeclarationNode;
2065 ret->type = maybeCopy( $1->type->base );
2066 $$ = $1->set_last( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
2067 }
2068 ;
2069
2070cfa_function_specifier: // CFA
2071 '[' ']' identifier '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2072 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2073 | '[' ']' TYPEDEFname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2074 { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2075 // | '[' ']' TYPEGENname '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2076 // { $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( nullptr ), $6, nullptr )->addQualifiers( $9 ); }
2077
2078 // identifier_or_type_name must be broken apart because of the sequence:
2079 //
2080 // '[' ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
2081 // '[' ']' type_specifier
2082 //
2083 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2084 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2085 | cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2086 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2087 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2088 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_list_ellipsis_opt pop ')' attribute_list_opt
2089 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2090 ;
2091
2092cfa_function_return: // CFA
2093 '[' push cfa_parameter_list pop ']'
2094 { $$ = DeclarationNode::newTuple( $3 ); }
2095 | '[' push cfa_parameter_list ',' cfa_abstract_parameter_list pop ']'
2096 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2097 { $$ = DeclarationNode::newTuple( $3->set_last( $5 ) ); }
2098 ;
2099
2100cfa_typedef_declaration: // CFA
2101 TYPEDEF cfa_variable_specifier
2102 {
2103 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2104 $$ = $2->addTypedef();
2105 }
2106 | TYPEDEF cfa_function_specifier
2107 {
2108 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2109 $$ = $2->addTypedef();
2110 }
2111 | cfa_typedef_declaration ',' identifier
2112 {
2113 typedefTable.addToEnclosingScope( *$3, TYPEDEFname, "cfa_typedef_declaration 3" );
2114 $$ = $1->set_last( $1->cloneType( $3 ) );
2115 }
2116 ;
2117
2118// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2119// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2120
2121typedef_declaration:
2122 TYPEDEF type_specifier declarator
2123 {
2124 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2125 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2126 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2127 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2128 }
2129 | typedef_declaration ',' declarator
2130 {
2131 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2132 $$ = $1->set_last( $1->cloneBaseType( $3 )->addTypedef() );
2133 }
2134 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2135 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2136 | type_specifier TYPEDEF declarator
2137 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2138 | type_specifier TYPEDEF type_qualifier_list declarator
2139 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2140 ;
2141
2142typedef_expression:
2143 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2144 TYPEDEF identifier '=' assignment_expression
2145 {
2146 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2147 }
2148 | typedef_expression ',' identifier '=' assignment_expression
2149 {
2150 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2151 }
2152 ;
2153
2154c_declaration:
2155 declaration_specifier declaring_list
2156 { $$ = distAttr( $1, $2 ); }
2157 | typedef_declaration
2158 | typedef_expression // deprecated GCC, naming expression type
2159 | sue_declaration_specifier
2160 {
2161 assert( $1->type );
2162 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2163 SemanticError( yylloc, "illegal syntax, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2164 }
2165 // enums are never empty declarations because there must have at least one enumeration.
2166 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2167 SemanticError( yylloc, "illegal syntax, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2168 }
2169 }
2170 ;
2171
2172declaring_list:
2173 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2174 // storage-class
2175 variable_declarator asm_name_opt initializer_opt
2176 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2177 | variable_type_redeclarator asm_name_opt initializer_opt
2178 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2179
2180 | general_function_declarator asm_name_opt
2181 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2182 | general_function_declarator asm_name_opt '=' VOID
2183 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2184
2185 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2186 { $$ = $1->set_last( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2187 ;
2188
2189general_function_declarator:
2190 function_type_redeclarator
2191 | function_declarator
2192 ;
2193
2194declaration_specifier: // type specifier + storage class
2195 basic_declaration_specifier
2196 | type_declaration_specifier
2197 | sue_declaration_specifier
2198 | sue_declaration_specifier invalid_types // invalid syntax rule
2199 {
2200 SemanticError( yylloc, "illegal syntax, expecting ';' at end of \"%s\" declaration.",
2201 ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2202 $$ = nullptr;
2203 }
2204 ;
2205
2206invalid_types:
2207 aggregate_key
2208 | basic_type_name
2209 | indirect_type
2210 ;
2211
2212declaration_specifier_nobody: // type specifier + storage class - {...}
2213 // Preclude SUE declarations in restricted scopes:
2214 //
2215 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2216 //
2217 // because it is impossible to call f due to name equivalence.
2218 basic_declaration_specifier
2219 | sue_declaration_specifier_nobody
2220 | type_declaration_specifier
2221 ;
2222
2223type_specifier: // type specifier
2224 basic_type_specifier
2225 | sue_type_specifier
2226 | type_type_specifier
2227 ;
2228
2229type_specifier_nobody: // type specifier - {...}
2230 // Preclude SUE declarations in restricted scopes:
2231 //
2232 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2233 //
2234 // because it is impossible to call f due to name equivalence.
2235 basic_type_specifier
2236 | sue_type_specifier_nobody
2237 | type_type_specifier
2238 ;
2239
2240type_qualifier_list_opt: // GCC, used in asm_statement
2241 // empty
2242 { $$ = nullptr; }
2243 | type_qualifier_list
2244 ;
2245
2246type_qualifier_list:
2247 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2248 //
2249 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2250 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2251 // appeared only once.
2252 type_qualifier
2253 | type_qualifier_list type_qualifier
2254 { $$ = $1->addQualifiers( $2 ); }
2255 ;
2256
2257type_qualifier:
2258 type_qualifier_name
2259 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2260 | attribute // trick handles most attribute locations
2261 ;
2262
2263type_qualifier_name:
2264 CONST
2265 { $$ = build_type_qualifier( ast::CV::Const ); }
2266 | RESTRICT
2267 { $$ = build_type_qualifier( ast::CV::Restrict ); }
2268 | VOLATILE
2269 { $$ = build_type_qualifier( ast::CV::Volatile ); }
2270 | ATOMIC
2271 { $$ = build_type_qualifier( ast::CV::Atomic ); }
2272
2273 // forall is a CV qualifier because it can appear in places where SC qualifiers are disallowed.
2274 //
2275 // void foo( forall( T ) T (*)( T ) ); // forward declaration
2276 // void bar( static int ); // static disallowed (gcc/CFA)
2277 | forall
2278 { $$ = build_forall( $1 ); }
2279 ;
2280
2281forall:
2282 FORALL '(' type_parameter_list ')' // CFA
2283 { $$ = $3; }
2284 ;
2285
2286declaration_qualifier_list:
2287 storage_class_list
2288 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2289 { $$ = $1->addQualifiers( $2 ); }
2290 | declaration_qualifier_list type_qualifier_list storage_class_list
2291 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2292 ;
2293
2294storage_class_list:
2295 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2296 // only one of each is specified, except for inline, which can appear with the others.
2297 //
2298 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2299 // specifiers in a declaration.
2300 storage_class
2301 | storage_class_list storage_class
2302 { $$ = $1->addQualifiers( $2 ); }
2303 ;
2304
2305storage_class:
2306 EXTERN
2307 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2308 | STATIC
2309 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2310 | AUTO
2311 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2312 | REGISTER
2313 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2314 | THREADLOCALGCC // GCC
2315 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2316 | THREADLOCALC11 // C11
2317 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2318 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2319 | INLINE // C99
2320 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2321 | FORTRAN // C99
2322 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2323 | NORETURN // C11
2324 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2325 ;
2326
2327basic_type_name:
2328 basic_type_name_type
2329 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2330 ;
2331
2332// Just an intermediate value for conversion.
2333basic_type_name_type:
2334 VOID
2335 { $$ = build_basic_type( TypeData::Void ); }
2336 | BOOL // C99
2337 { $$ = build_basic_type( TypeData::Bool ); }
2338 | CHAR
2339 { $$ = build_basic_type( TypeData::Char ); }
2340 | INT
2341 { $$ = build_basic_type( TypeData::Int ); }
2342 | INT128
2343 { $$ = build_basic_type( TypeData::Int128 ); }
2344 | UINT128
2345 { $$ = addType( build_basic_type( TypeData::Int128 ), build_signedness( TypeData::Unsigned ) ); }
2346 | FLOAT
2347 { $$ = build_basic_type( TypeData::Float ); }
2348 | DOUBLE
2349 { $$ = build_basic_type( TypeData::Double ); }
2350 | uuFLOAT80
2351 { $$ = build_basic_type( TypeData::uuFloat80 ); }
2352 | uuFLOAT128
2353 { $$ = build_basic_type( TypeData::uuFloat128 ); }
2354 | uFLOAT16
2355 { $$ = build_basic_type( TypeData::uFloat16 ); }
2356 | uFLOAT32
2357 { $$ = build_basic_type( TypeData::uFloat32 ); }
2358 | uFLOAT32X
2359 { $$ = build_basic_type( TypeData::uFloat32x ); }
2360 | uFLOAT64
2361 { $$ = build_basic_type( TypeData::uFloat64 ); }
2362 | uFLOAT64X
2363 { $$ = build_basic_type( TypeData::uFloat64x ); }
2364 | uFLOAT128
2365 { $$ = build_basic_type( TypeData::uFloat128 ); }
2366 | DECIMAL32
2367 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2368 | DECIMAL64
2369 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2370 | DECIMAL128
2371 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2372 | COMPLEX // C99
2373 { $$ = build_complex_type( TypeData::Complex ); }
2374 | IMAGINARY // C99
2375 { $$ = build_complex_type( TypeData::Imaginary ); }
2376 | SIGNED
2377 { $$ = build_signedness( TypeData::Signed ); }
2378 | UNSIGNED
2379 { $$ = build_signedness( TypeData::Unsigned ); }
2380 | SHORT
2381 { $$ = build_length( TypeData::Short ); }
2382 | LONG
2383 { $$ = build_length( TypeData::Long ); }
2384 | VA_LIST // GCC, __builtin_va_list
2385 { $$ = build_builtin_type( TypeData::Valist ); }
2386 | AUTO_TYPE
2387 { $$ = build_builtin_type( TypeData::AutoType ); }
2388 | vtable
2389 ;
2390
2391vtable_opt:
2392 // empty
2393 { $$ = nullptr; }
2394 | vtable
2395 ;
2396
2397vtable:
2398 VTABLE '(' type_name ')' default_opt
2399 { $$ = build_vtable_type( $3 ); }
2400 ;
2401
2402default_opt:
2403 // empty
2404 { $$ = nullptr; }
2405 | DEFAULT
2406 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2407 ;
2408
2409basic_declaration_specifier:
2410 // A semantic check is necessary for conflicting storage classes.
2411 basic_type_specifier
2412 | declaration_qualifier_list basic_type_specifier
2413 { $$ = $2->addQualifiers( $1 ); }
2414 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2415 { $$ = $1->addQualifiers( $2 ); }
2416 | basic_declaration_specifier storage_class type_qualifier_list
2417 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2418 | basic_declaration_specifier storage_class basic_type_specifier
2419 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2420 ;
2421
2422basic_type_specifier:
2423 direct_type
2424 // Cannot have type modifiers, e.g., short, long, etc.
2425 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2426 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2427 ;
2428
2429direct_type:
2430 basic_type_name
2431 | type_qualifier_list basic_type_name
2432 { $$ = $2->addQualifiers( $1 ); }
2433 | direct_type type_qualifier
2434 { $$ = $1->addQualifiers( $2 ); }
2435 | direct_type basic_type_name
2436 { $$ = $1->addType( $2 ); }
2437 ;
2438
2439indirect_type:
2440 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2441 { $$ = $3; }
2442 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2443 { $$ = DeclarationNode::newTypeof( $3 ); }
2444 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2445 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2446 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2447 { $$ = DeclarationNode::newTypeof( $3, true ); }
2448 | ZERO_T // CFA
2449 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::Zero ) ); }
2450 | ONE_T // CFA
2451 { $$ = DeclarationNode::newFromTypeData( build_builtin_type( TypeData::One ) ); }
2452 ;
2453
2454sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2455 sue_type_specifier
2456 | declaration_qualifier_list sue_type_specifier
2457 { $$ = $2->addQualifiers( $1 ); }
2458 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2459 { $$ = $1->addQualifiers( $2 ); }
2460 | sue_declaration_specifier storage_class type_qualifier_list
2461 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2462 ;
2463
2464sue_type_specifier: // struct, union, enum + type specifier
2465 elaborated_type
2466 | type_qualifier_list
2467 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2468 elaborated_type
2469 { $$ = $3->addQualifiers( $1 ); }
2470 | sue_type_specifier type_qualifier
2471 {
2472 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2473 $$ = $1->addQualifiers( $2 );
2474 }
2475 ;
2476
2477sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2478 sue_type_specifier_nobody
2479 | declaration_qualifier_list sue_type_specifier_nobody
2480 { $$ = $2->addQualifiers( $1 ); }
2481 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2482 { $$ = $1->addQualifiers( $2 ); }
2483 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2484 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2485 ;
2486
2487sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2488 elaborated_type_nobody
2489 | type_qualifier_list elaborated_type_nobody
2490 { $$ = $2->addQualifiers( $1 ); }
2491 | sue_type_specifier_nobody type_qualifier
2492 { $$ = $1->addQualifiers( $2 ); }
2493 ;
2494
2495type_declaration_specifier:
2496 type_type_specifier
2497 | declaration_qualifier_list type_type_specifier
2498 { $$ = $2->addQualifiers( $1 ); }
2499 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2500 { $$ = $1->addQualifiers( $2 ); }
2501 | type_declaration_specifier storage_class type_qualifier_list
2502 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2503 ;
2504
2505type_type_specifier: // typedef types
2506 type_name
2507 { $$ = DeclarationNode::newFromTypeData( $1 ); }
2508 | type_qualifier_list type_name
2509 { $$ = DeclarationNode::newFromTypeData( $2 )->addQualifiers( $1 ); }
2510 | type_type_specifier type_qualifier
2511 { $$ = $1->addQualifiers( $2 ); }
2512 ;
2513
2514type_name:
2515 TYPEDEFname
2516 { $$ = build_typedef( $1 ); }
2517 | '.' TYPEDEFname
2518 { $$ = build_qualified_type( build_global_scope(), build_typedef( $2 ) ); }
2519 | type_name '.' TYPEDEFname
2520 { $$ = build_qualified_type( $1, build_typedef( $3 ) ); }
2521 | typegen_name
2522 | '.' typegen_name
2523 { $$ = build_qualified_type( build_global_scope(), $2 ); }
2524 | type_name '.' typegen_name
2525 { $$ = build_qualified_type( $1, $3 ); }
2526 ;
2527
2528typegen_name: // CFA
2529 TYPEGENname
2530 { $$ = build_type_gen( $1, nullptr ); }
2531 | TYPEGENname '(' ')'
2532 { $$ = build_type_gen( $1, nullptr ); }
2533 | TYPEGENname '(' type_list ')'
2534 { $$ = build_type_gen( $1, $3 ); }
2535 ;
2536
2537elaborated_type: // struct, union, enum
2538 aggregate_type
2539 | enum_type
2540 ;
2541
2542elaborated_type_nobody: // struct, union, enum - {...}
2543 aggregate_type_nobody
2544 | enum_type_nobody
2545 ;
2546
2547// ************************** AGGREGATE *******************************
2548
2549aggregate_type: // struct, union
2550 aggregate_key attribute_list_opt
2551 { forall = false; } // reset
2552 '{' field_declaration_list_opt '}' type_parameters_opt
2553 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2554 | aggregate_key attribute_list_opt identifier
2555 {
2556 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2557 forall = false; // reset
2558 }
2559 '{' field_declaration_list_opt '}' type_parameters_opt
2560 {
2561 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2562 }
2563 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2564 {
2565 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2566 forall = false; // reset
2567 }
2568 '{' field_declaration_list_opt '}' type_parameters_opt
2569 {
2570 DeclarationNode::newFromTypeData( build_typedef( $3 ) );
2571 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2572 }
2573 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2574 {
2575 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2576 forall = false; // reset
2577 }
2578 '{' field_declaration_list_opt '}' type_parameters_opt
2579 {
2580 DeclarationNode::newFromTypeData( build_type_gen( $3, nullptr ) );
2581 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2582 }
2583 | aggregate_type_nobody
2584 ;
2585
2586type_parameters_opt:
2587 // empty
2588 { $$ = nullptr; } %prec '}'
2589 | '(' type_list ')'
2590 { $$ = $2; }
2591 ;
2592
2593aggregate_type_nobody: // struct, union - {...}
2594 aggregate_key attribute_list_opt identifier
2595 {
2596 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2597 forall = false; // reset
2598 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2599 }
2600 | aggregate_key attribute_list_opt type_name
2601 {
2602 forall = false; // reset
2603 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2604 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2605 // delete newFromTypeGen.
2606 if ( $3->kind == TypeData::SymbolicInst && ! $3->symbolic.isTypedef ) {
2607 $$ = DeclarationNode::newFromTypeData( $3 )->addQualifiers( $2 );
2608 } else {
2609 $$ = DeclarationNode::newAggregate( $1, $3->symbolic.name, $3->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2610 $3->symbolic.name = nullptr; // copied to $$
2611 $3->symbolic.actuals = nullptr;
2612 delete $3;
2613 }
2614 }
2615 ;
2616
2617aggregate_key:
2618 aggregate_data
2619 | aggregate_control
2620 ;
2621
2622aggregate_data:
2623 STRUCT vtable_opt
2624 { $$ = ast::AggregateDecl::Struct; }
2625 | UNION
2626 { $$ = ast::AggregateDecl::Union; }
2627 | EXCEPTION // CFA
2628 { $$ = ast::AggregateDecl::Exception; }
2629 ;
2630
2631aggregate_control: // CFA
2632 MONITOR
2633 { $$ = ast::AggregateDecl::Monitor; }
2634 | MUTEX STRUCT
2635 { $$ = ast::AggregateDecl::Monitor; }
2636 | GENERATOR
2637 { $$ = ast::AggregateDecl::Generator; }
2638 | MUTEX GENERATOR
2639 {
2640 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2641 $$ = ast::AggregateDecl::NoAggregate;
2642 }
2643 | COROUTINE
2644 { $$ = ast::AggregateDecl::Coroutine; }
2645 | MUTEX COROUTINE
2646 {
2647 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2648 $$ = ast::AggregateDecl::NoAggregate;
2649 }
2650 | THREAD
2651 { $$ = ast::AggregateDecl::Thread; }
2652 | MUTEX THREAD
2653 {
2654 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2655 $$ = ast::AggregateDecl::NoAggregate;
2656 }
2657 ;
2658
2659field_declaration_list_opt:
2660 // empty
2661 { $$ = nullptr; }
2662 | field_declaration_list_opt field_declaration
2663 { $$ = $1 ? $1->set_last( $2 ) : $2; }
2664 ;
2665
2666field_declaration:
2667 type_specifier field_declaring_list_opt ';'
2668 {
2669 // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2670 $$ = fieldDecl( $1, $2 );
2671 // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2672 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2673 // printf( "\tattr %s\n", attr->name.c_str() );
2674 // } // for
2675 }
2676 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2677 {
2678 SemanticError( yylloc, "illegal syntax, expecting ';' at end of previous declaration." );
2679 $$ = nullptr;
2680 }
2681 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2682 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2683 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2684 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2685 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2686 {
2687 if ( ! $3 ) { // field declarator ?
2688 $3 = DeclarationNode::newName( nullptr );
2689 } // if
2690 $3->inLine = true;
2691 $$ = distAttr( $2, $3 ); // mark all fields in list
2692 distInl( $3 );
2693 }
2694 | INLINE aggregate_control ';' // CFA
2695 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2696 | typedef_declaration ';' // CFA
2697 | cfa_field_declaring_list ';' // CFA, new style field declaration
2698 | EXTENSION cfa_field_declaring_list ';' // GCC
2699 { distExt( $2 ); $$ = $2; } // mark all fields in list
2700 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2701 { $$ = $2; } // mark all fields in list
2702 | cfa_typedef_declaration ';' // CFA
2703 | static_assert // C11
2704 ;
2705
2706field_declaring_list_opt:
2707 // empty
2708 { $$ = nullptr; }
2709 | field_declarator
2710 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2711 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2712 ;
2713
2714field_declarator:
2715 bit_subrange_size // C special case, no field name
2716 { $$ = DeclarationNode::newBitfield( $1 ); }
2717 | variable_declarator bit_subrange_size_opt
2718 // A semantic check is required to ensure bit_subrange only appears on integral types.
2719 { $$ = $1->addBitfield( $2 ); }
2720 | variable_type_redeclarator bit_subrange_size_opt
2721 // A semantic check is required to ensure bit_subrange only appears on integral types.
2722 { $$ = $1->addBitfield( $2 ); }
2723 | function_type_redeclarator bit_subrange_size_opt
2724 // A semantic check is required to ensure bit_subrange only appears on integral types.
2725 { $$ = $1->addBitfield( $2 ); }
2726 ;
2727
2728field_abstract_list_opt:
2729 // empty
2730 { $$ = nullptr; }
2731 | field_abstract
2732 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2733 { $$ = $1->set_last( $4->addQualifiers( $3 ) ); }
2734 ;
2735
2736field_abstract:
2737 // no bit fields
2738 variable_abstract_declarator
2739 ;
2740
2741cfa_field_declaring_list: // CFA, new style field declaration
2742 // bit-fields are handled by C declarations
2743 cfa_abstract_declarator_tuple identifier_or_type_name
2744 { $$ = $1->addName( $2 ); }
2745 | cfa_field_declaring_list ',' identifier_or_type_name
2746 { $$ = $1->set_last( $1->cloneType( $3 ) ); }
2747 ;
2748
2749cfa_field_abstract_list: // CFA, new style field declaration
2750 // bit-fields are handled by C declarations
2751 cfa_abstract_declarator_tuple
2752 | cfa_field_abstract_list ','
2753 { $$ = $1->set_last( $1->cloneType( 0 ) ); }
2754 ;
2755
2756bit_subrange_size_opt:
2757 // empty
2758 { $$ = nullptr; }
2759 | bit_subrange_size
2760 ;
2761
2762bit_subrange_size:
2763 ':' assignment_expression
2764 { $$ = $2; }
2765 ;
2766
2767// ************************** ENUMERATION *******************************
2768
2769enum_type:
2770 // anonymous, no type name
2771 ENUM attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2772 {
2773 if ( $3 == EnumHiding::Hide ) {
2774 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2775 } // if
2776 $$ = DeclarationNode::newEnum( nullptr, $5, true, false )->addQualifiers( $2 );
2777 }
2778 | ENUM enumerator_type attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2779 {
2780 if ( $2 && ($2->storageClasses.val != 0 || $2->type->qualifiers.any()) ) {
2781 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2782 }
2783 if ( $4 == EnumHiding::Hide ) {
2784 SemanticError( yylloc, "illegal syntax, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr;
2785 } // if
2786 $$ = DeclarationNode::newEnum( nullptr, $6, true, true, $2 )->addQualifiers( $3 );
2787 }
2788
2789 // named type
2790 | ENUM attribute_list_opt identifier
2791 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2792 hide_opt '{' enumerator_list comma_opt '}'
2793 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2794 | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2795 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2796 | ENUM enumerator_type attribute_list_opt identifier attribute_list_opt
2797 {
2798 if ( $2 && ($2->storageClasses.any() || $2->type->qualifiers.val != 0) ) {
2799 SemanticError( yylloc, "illegal syntax, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2800 }
2801 typedefTable.makeTypedef( *$4, "enum_type 2" );
2802 }
2803 hide_opt '{' enumerator_list comma_opt '}'
2804 { $$ = DeclarationNode::newEnum( $4, $9, true, true, $2, $7 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2805 | ENUM enumerator_type attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2806 { $$ = DeclarationNode::newEnum( $4->name, $8, true, true, $2, $6 )->addQualifiers( $3 )->addQualifiers( $5 ); }
2807
2808 // forward declaration
2809 | enum_type_nobody
2810 ;
2811
2812enumerator_type:
2813 '(' ')' // pure enumeration
2814 { $$ = nullptr; }
2815 | '(' cfa_abstract_parameter_declaration ')' // typed enumeration
2816 { $$ = $2; }
2817 ;
2818
2819hide_opt:
2820 // empty
2821 { $$ = EnumHiding::Visible; }
2822 | '!'
2823 { $$ = EnumHiding::Hide; }
2824 ;
2825
2826enum_type_nobody: // enum - {...}
2827 ENUM attribute_list_opt identifier
2828 {
2829 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2830 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2831 }
2832 | ENUM attribute_list_opt type_name
2833 {
2834 typedefTable.makeTypedef( *$3->symbolic.name, "enum_type_nobody 2" );
2835 $$ = DeclarationNode::newEnum( $3->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2836 }
2837 ;
2838
2839enumerator_list:
2840 visible_hide_opt identifier_or_type_name enumerator_value_opt
2841 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2842 | INLINE type_name
2843 {
2844 $$ = DeclarationNode::newEnumInLine( $2->symbolic.name );
2845 $2->symbolic.name = nullptr;
2846 delete $2;
2847 }
2848 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2849 { $$ = $1->set_last( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2850 | enumerator_list ',' INLINE type_name
2851 { $$ = $1->set_last( DeclarationNode::newEnumInLine( $4->symbolic.name ) ); }
2852 ;
2853
2854visible_hide_opt:
2855 hide_opt
2856 | '^'
2857 { $$ = EnumHiding::Visible; }
2858 ;
2859
2860enumerator_value_opt:
2861 // empty
2862 { $$ = nullptr; }
2863 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2864 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2865 // | simple_assignment_operator initializer
2866 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2867 ;
2868
2869// ************************** FUNCTION PARAMETERS *******************************
2870
2871parameter_list_ellipsis_opt:
2872 // empty
2873 { $$ = nullptr; }
2874 | ELLIPSIS
2875 { $$ = nullptr; }
2876 | parameter_list
2877 | parameter_list ',' ELLIPSIS
2878 { $$ = $1->addVarArgs(); }
2879 ;
2880
2881parameter_list: // abstract + real
2882 parameter_declaration
2883 | abstract_parameter_declaration
2884 | parameter_list ',' parameter_declaration
2885 { $$ = $1->set_last( $3 ); }
2886 | parameter_list ',' abstract_parameter_declaration
2887 { $$ = $1->set_last( $3 ); }
2888 ;
2889
2890cfa_parameter_list_ellipsis_opt: // CFA, abstract + real
2891 // empty
2892 { $$ = DeclarationNode::newFromTypeData( build_basic_type( TypeData::Void ) ); }
2893 | ELLIPSIS
2894 { $$ = nullptr; }
2895 | cfa_parameter_list
2896 | cfa_abstract_parameter_list
2897 | cfa_parameter_list ',' cfa_abstract_parameter_list
2898 { $$ = $1->set_last( $3 ); }
2899 | cfa_parameter_list ',' ELLIPSIS
2900 { $$ = $1->addVarArgs(); }
2901 | cfa_abstract_parameter_list ',' ELLIPSIS
2902 { $$ = $1->addVarArgs(); }
2903 ;
2904
2905cfa_parameter_list: // CFA
2906 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2907 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2908 cfa_parameter_declaration
2909 | cfa_abstract_parameter_list ',' cfa_parameter_declaration
2910 { $$ = $1->set_last( $3 ); }
2911 | cfa_parameter_list ',' cfa_parameter_declaration
2912 { $$ = $1->set_last( $3 ); }
2913 | cfa_parameter_list ',' cfa_abstract_parameter_list ',' cfa_parameter_declaration
2914 { $$ = $1->set_last( $3 )->set_last( $5 ); }
2915 ;
2916
2917cfa_abstract_parameter_list: // CFA, new & old style abstract
2918 cfa_abstract_parameter_declaration
2919 | cfa_abstract_parameter_list ',' cfa_abstract_parameter_declaration
2920 { $$ = $1->set_last( $3 ); }
2921 ;
2922
2923// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2924// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2925
2926parameter_declaration:
2927 // No SUE declaration in parameter list.
2928 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2929 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2930 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2931 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2932 ;
2933
2934abstract_parameter_declaration:
2935 declaration_specifier_nobody default_initializer_opt
2936 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2937 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2938 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2939 ;
2940
2941cfa_parameter_declaration: // CFA, new & old style parameter declaration
2942 parameter_declaration
2943 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2944 { $$ = $1->addName( $2 ); }
2945 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2946 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2947 { $$ = $1->addName( $2 ); }
2948 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2949 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2950 | cfa_function_specifier // int f( "int fp()" );
2951 ;
2952
2953cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2954 abstract_parameter_declaration
2955 | cfa_identifier_parameter_declarator_no_tuple
2956 | cfa_abstract_tuple
2957 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2958 | type_qualifier_list cfa_abstract_tuple
2959 { $$ = $2->addQualifiers( $1 ); }
2960 | cfa_abstract_function // int f( "int ()" );
2961 ;
2962
2963// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2964// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2965// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2966
2967identifier_list: // K&R-style parameter list => no types
2968 identifier
2969 { $$ = DeclarationNode::newName( $1 ); }
2970 | identifier_list ',' identifier
2971 { $$ = $1->set_last( DeclarationNode::newName( $3 ) ); }
2972 ;
2973
2974type_no_function: // sizeof, alignof, cast (constructor)
2975 cfa_abstract_declarator_tuple // CFA
2976 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2977 | type_specifier abstract_declarator
2978 { $$ = $2->addType( $1 ); }
2979 ;
2980
2981type: // typeof, assertion
2982 type_no_function
2983 | cfa_abstract_function // CFA
2984 ;
2985
2986initializer_opt:
2987 // empty
2988 { $$ = nullptr; }
2989 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2990 | '=' VOID { $$ = new InitializerNode( true ); }
2991 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2992 ;
2993
2994initializer:
2995 assignment_expression { $$ = new InitializerNode( $1 ); }
2996 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2997 ;
2998
2999initializer_list_opt:
3000 // empty
3001 { $$ = nullptr; }
3002 | initializer
3003 | designation initializer { $$ = $2->set_designators( $1 ); }
3004 | initializer_list_opt ',' initializer { $$ = $1->set_last( $3 ); }
3005 | initializer_list_opt ',' designation initializer { $$ = $1->set_last( $4->set_designators( $3 ) ); }
3006 ;
3007
3008// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
3009// '=' to separator the designator from the initializer value, as in:
3010//
3011// int x[10] = { [1] = 3 };
3012//
3013// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
3014// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
3015// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
3016// shift/reduce conflicts
3017
3018designation:
3019 designator_list ':' // C99, CFA uses ":" instead of "="
3020 | identifier_at ':' // GCC, field name
3021 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
3022 ;
3023
3024designator_list: // C99
3025 designator
3026 | designator_list designator
3027 { $$ = $1->set_last( $2 ); }
3028 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
3029 ;
3030
3031designator:
3032 '.' identifier_at // C99, field name
3033 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
3034 | '[' push assignment_expression pop ']' // C99, single array element
3035 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
3036 { $$ = $3; }
3037 | '[' push subrange pop ']' // CFA, multiple array elements
3038 { $$ = $3; }
3039 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
3040 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
3041 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
3042 { $$ = $4; }
3043 ;
3044
3045// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
3046// rather than an object-oriented type system. This required four groups of extensions:
3047//
3048// Overloading: function, data, and operator identifiers may be overloaded.
3049//
3050// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
3051// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
3052// definitions of new types. Type declarations with storage class "extern" provide opaque types.
3053//
3054// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
3055// site. A polymorphic function is not a template; it is a function, with an address and a type.
3056//
3057// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
3058// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
3059// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
3060// types provide the operations declared by a specification. Assertions are normally used to declare requirements
3061// on type arguments of polymorphic functions.
3062
3063type_parameter_list: // CFA
3064 type_parameter
3065 | type_parameter_list ',' type_parameter
3066 { $$ = $1->set_last( $3 ); }
3067 ;
3068
3069type_initializer_opt: // CFA
3070 // empty
3071 { $$ = nullptr; }
3072 | '=' type
3073 { $$ = $2; }
3074 ;
3075
3076type_parameter: // CFA
3077 type_class identifier_or_type_name
3078 {
3079 typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3080 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3081 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3082 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3083 }
3084 type_initializer_opt assertion_list_opt
3085 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3086 | identifier_or_type_name new_type_class
3087 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3088 type_initializer_opt assertion_list_opt
3089 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3090 | '[' identifier_or_type_name ']'
3091 {
3092 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3093 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3094 }
3095 // | type_specifier identifier_parameter_declarator
3096 | assertion_list
3097 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3098 | ENUM '(' identifier_or_type_name ')' identifier_or_type_name new_type_class type_initializer_opt assertion_list_opt
3099 {
3100 typedefTable.addToScope( *$3, TYPEDIMname, "type_parameter 4" );
3101 typedefTable.addToScope( *$5, TYPEDIMname, "type_parameter 5" );
3102 $$ = DeclarationNode::newTypeParam( $6, $5 )->addTypeInitializer( $7 )->addAssertions( $8 );
3103 }
3104 ;
3105
3106new_type_class: // CFA
3107 // empty
3108 { $$ = ast::TypeDecl::Otype; }
3109 | '&'
3110 { $$ = ast::TypeDecl::Dtype; }
3111 | '*'
3112 { $$ = ast::TypeDecl::DStype; } // Dtype + sized
3113 // | '(' '*' ')' // Gregor made me do it
3114 // { $$ = ast::TypeDecl::Ftype; }
3115 | ELLIPSIS
3116 { $$ = ast::TypeDecl::Ttype; }
3117 ;
3118
3119type_class: // CFA
3120 OTYPE
3121 { $$ = ast::TypeDecl::Otype; }
3122 | DTYPE
3123 { $$ = ast::TypeDecl::Dtype; }
3124 | FTYPE
3125 { $$ = ast::TypeDecl::Ftype; }
3126 | TTYPE
3127 { $$ = ast::TypeDecl::Ttype; }
3128 ;
3129
3130assertion_list_opt: // CFA
3131 // empty
3132 { $$ = nullptr; }
3133 | assertion_list
3134 ;
3135
3136assertion_list: // CFA
3137 assertion
3138 | assertion_list assertion
3139 { $$ = $1->set_last( $2 ); }
3140 ;
3141
3142assertion: // CFA
3143 '|' identifier_or_type_name '(' type_list ')'
3144 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3145 | '|' '{' push trait_declaration_list pop '}'
3146 { $$ = $4; }
3147 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3148 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3149 ;
3150
3151type_list: // CFA
3152 type
3153 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3154 | assignment_expression
3155 | type_list ',' type
3156 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3157 | type_list ',' assignment_expression
3158 { $$ = $1->set_last( $3 ); }
3159 ;
3160
3161type_declaring_list: // CFA
3162 OTYPE type_declarator
3163 { $$ = $2; }
3164 | storage_class_list OTYPE type_declarator
3165 { $$ = $3->addQualifiers( $1 ); }
3166 | type_declaring_list ',' type_declarator
3167 { $$ = $1->set_last( $3->copySpecifiers( $1 ) ); }
3168 ;
3169
3170type_declarator: // CFA
3171 type_declarator_name assertion_list_opt
3172 { $$ = $1->addAssertions( $2 ); }
3173 | type_declarator_name assertion_list_opt '=' type
3174 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3175 ;
3176
3177type_declarator_name: // CFA
3178 identifier_or_type_name
3179 {
3180 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3181 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3182 }
3183 | identifier_or_type_name '(' type_parameter_list ')'
3184 {
3185 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3186 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3187 }
3188 ;
3189
3190trait_specifier: // CFA
3191 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3192 {
3193 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3194 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3195 }
3196 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3197 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3198 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3199 {
3200 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3201 $$ = DeclarationNode::newTrait( $2, $4, $8 );
3202 }
3203 | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3204 { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3205 ;
3206
3207trait_declaration_list: // CFA
3208 trait_declaration
3209 | trait_declaration_list pop push trait_declaration
3210 { $$ = $1->set_last( $4 ); }
3211 ;
3212
3213trait_declaration: // CFA
3214 cfa_trait_declaring_list ';'
3215 | trait_declaring_list ';'
3216 ;
3217
3218cfa_trait_declaring_list: // CFA
3219 cfa_variable_specifier
3220 | cfa_function_specifier
3221 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3222 { $$ = $1->set_last( $1->cloneType( $5 ) ); }
3223 ;
3224
3225trait_declaring_list: // CFA
3226 type_specifier declarator
3227 { $$ = $2->addType( $1 ); }
3228 | trait_declaring_list pop ',' push declarator
3229 { $$ = $1->set_last( $1->cloneBaseType( $5 ) ); }
3230 ;
3231
3232// **************************** EXTERNAL DEFINITIONS *****************************
3233
3234translation_unit:
3235 // empty, input file
3236 | external_definition_list
3237 { parseTree = parseTree ? parseTree->set_last( $1 ) : $1; }
3238 ;
3239
3240external_definition_list:
3241 push external_definition pop
3242 { $$ = $2; }
3243 | external_definition_list push external_definition pop
3244 { $$ = $1 ? $1->set_last( $3 ) : $3; }
3245 ;
3246
3247external_definition_list_opt:
3248 // empty
3249 { $$ = nullptr; }
3250 | external_definition_list
3251 ;
3252
3253up:
3254 { typedefTable.up( forall ); forall = false; }
3255 ;
3256
3257down:
3258 { typedefTable.down(); }
3259 ;
3260
3261external_definition:
3262 DIRECTIVE
3263 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3264 | declaration
3265 {
3266 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3267 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3268 // disallowed at the moment.
3269 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3270 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3271 if ( $1->type->aggInst.aggregate->aggregate.anon ) {
3272 SemanticError( yylloc, "extern anonymous aggregate is currently unimplemented." ); $$ = nullptr;
3273 }
3274 }
3275 }
3276 | IDENTIFIER IDENTIFIER
3277 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3278 | IDENTIFIER type_qualifier // invalid syntax rule
3279 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3280 | IDENTIFIER storage_class // invalid syntax rule
3281 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3282 | IDENTIFIER basic_type_name // invalid syntax rule
3283 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3284 | IDENTIFIER TYPEDEFname // invalid syntax rule
3285 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3286 | IDENTIFIER TYPEGENname // invalid syntax rule
3287 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3288 | external_function_definition
3289 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3290 {
3291 distExt( $2 ); // mark all fields in list
3292 $$ = $2;
3293 }
3294 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3295 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3296 | EXTERN STRINGliteral
3297 {
3298 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3299 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3300 }
3301 up external_definition down
3302 {
3303 linkage = linkageStack.top();
3304 linkageStack.pop();
3305 $$ = $5;
3306 }
3307 | EXTERN STRINGliteral // C++-style linkage specifier
3308 {
3309 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3310 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3311 }
3312 '{' up external_definition_list_opt down '}'
3313 {
3314 linkage = linkageStack.top();
3315 linkageStack.pop();
3316 $$ = $6;
3317 }
3318 // global distribution
3319 | type_qualifier_list
3320 {
3321 if ( $1->type->qualifiers.any() ) {
3322 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3323 }
3324 if ( $1->type->forall ) forall = true; // remember generic type
3325 }
3326 '{' up external_definition_list_opt down '}' // CFA, namespace
3327 {
3328 distQual( $5, $1 );
3329 forall = false;
3330 $$ = $5;
3331 }
3332 | declaration_qualifier_list
3333 {
3334 if ( $1->type && $1->type->qualifiers.any() ) {
3335 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3336 }
3337 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3338 }
3339 '{' up external_definition_list_opt down '}' // CFA, namespace
3340 {
3341 distQual( $5, $1 );
3342 forall = false;
3343 $$ = $5;
3344 }
3345 | declaration_qualifier_list type_qualifier_list
3346 {
3347 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3348 SemanticError( yylloc, "illegal syntax, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3349 }
3350 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3351 }
3352 '{' up external_definition_list_opt down '}' // CFA, namespace
3353 {
3354 distQual( $6, $1->addQualifiers( $2 ) );
3355 forall = false;
3356 $$ = $6;
3357 }
3358 ;
3359
3360external_function_definition:
3361 function_definition
3362 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3363 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3364 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3365 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3366 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3367 | function_declarator compound_statement
3368 { $$ = $1->addFunctionBody( $2 ); }
3369 | KR_function_declarator KR_parameter_list_opt compound_statement
3370 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3371 ;
3372
3373with_clause_opt:
3374 // empty
3375 { $$ = nullptr; forall = false; }
3376 | WITH '(' type_list ')' attribute_list_opt // support scoped enumeration
3377 {
3378 $$ = $3; forall = false;
3379 if ( $5 ) {
3380 SemanticError( yylloc, "illegal syntax, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3381 $$ = nullptr;
3382 } // if
3383 }
3384 ;
3385
3386function_definition:
3387 cfa_function_declaration with_clause_opt compound_statement // CFA
3388 {
3389 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3390 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3391 $1->get_last()->addFunctionBody( $3, $2 );
3392 $$ = $1;
3393 }
3394 | declaration_specifier function_declarator with_clause_opt compound_statement
3395 {
3396 rebindForall( $1, $2 );
3397 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3398 }
3399 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3400 {
3401 rebindForall( $1, $2 );
3402 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3403 }
3404 // handles default int return type, OBSOLESCENT (see 1)
3405 | type_qualifier_list function_declarator with_clause_opt compound_statement
3406 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3407 // handles default int return type, OBSOLESCENT (see 1)
3408 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3409 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3410 // handles default int return type, OBSOLESCENT (see 1)
3411 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3412 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3413
3414 // Old-style K&R function definition, OBSOLESCENT (see 4)
3415 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3416 {
3417 rebindForall( $1, $2 );
3418 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3419 }
3420 // handles default int return type, OBSOLESCENT (see 1)
3421 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3422 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3423 // handles default int return type, OBSOLESCENT (see 1)
3424 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3425 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3426 // handles default int return type, OBSOLESCENT (see 1)
3427 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3428 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3429 ;
3430
3431declarator:
3432 variable_declarator
3433 | variable_type_redeclarator
3434 | function_declarator
3435 | function_type_redeclarator
3436 ;
3437
3438subrange:
3439 constant_expression '~' constant_expression // CFA, integer subrange
3440 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3441 ;
3442
3443// **************************** ASM *****************************
3444
3445asm_name_opt: // GCC
3446 // empty
3447 { $$ = nullptr; }
3448 | ASM '(' string_literal ')' attribute_list_opt
3449 {
3450 DeclarationNode * name = new DeclarationNode();
3451 name->asmName = maybeMoveBuild( $3 );
3452 $$ = name->addQualifiers( $5 );
3453 }
3454 ;
3455
3456// **************************** ATTRIBUTE *****************************
3457
3458attribute_list_opt: // GCC
3459 // empty
3460 { $$ = nullptr; }
3461 | attribute_list
3462 ;
3463
3464attribute_list: // GCC
3465 attribute
3466 | attribute_list attribute
3467 { $$ = $2->addQualifiers( $1 ); }
3468 ;
3469
3470attribute: // GCC
3471 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3472 { $$ = $4; }
3473 | ATTRIBUTE '(' attribute_name_list ')' // CFA
3474 { $$ = $3; }
3475 | ATTR '(' attribute_name_list ')' // CFA
3476 { $$ = $3; }
3477 ;
3478
3479attribute_name_list: // GCC
3480 attribute_name
3481 | attribute_name_list ',' attribute_name
3482 { $$ = $3->addQualifiers( $1 ); }
3483 ;
3484
3485attribute_name: // GCC
3486 // empty
3487 { $$ = nullptr; }
3488 | attr_name
3489 { $$ = DeclarationNode::newAttribute( $1 ); }
3490 | attr_name '(' argument_expression_list_opt ')'
3491 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3492 ;
3493
3494attr_name: // GCC
3495 identifier_or_type_name
3496 | FALLTHROUGH
3497 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3498 | CONST
3499 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3500 ;
3501
3502// ============================================================================
3503// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3504// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3505// in:
3506//
3507// int (*f())[10] { ... };
3508// ... (*f())[3] += 1; // definition mimics usage
3509//
3510// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3511// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3512// ============================================================================
3513
3514// ----------------------------------------------------------------------------
3515// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3516// to define a variable or function prototype, e.g.:
3517//
3518// valid declaration invalid definition
3519// ----------------- ------------------
3520// int f; int f {}
3521// int *f; int *f {}
3522// int f[10]; int f[10] {}
3523// int (*f)(int); int (*f)(int) {}
3524//
3525// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3526// variable_declarator and function_declarator.
3527// ----------------------------------------------------------------------------
3528
3529// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3530// declaring an array of functions versus a pointer to an array of functions.
3531
3532paren_identifier:
3533 identifier_at
3534 { $$ = DeclarationNode::newName( $1 ); }
3535 | '(' paren_identifier ')' // redundant parenthesis
3536 { $$ = $2; }
3537 ;
3538
3539variable_declarator:
3540 paren_identifier attribute_list_opt
3541 { $$ = $1->addQualifiers( $2 ); }
3542 | variable_ptr
3543 | variable_array attribute_list_opt
3544 { $$ = $1->addQualifiers( $2 ); }
3545 | variable_function attribute_list_opt
3546 { $$ = $1->addQualifiers( $2 ); }
3547 ;
3548
3549variable_ptr:
3550 ptrref_operator variable_declarator
3551 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3552 | ptrref_operator type_qualifier_list variable_declarator
3553 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3554 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3555 { $$ = $2->addQualifiers( $4 ); }
3556 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3557 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3558 ;
3559
3560variable_array:
3561 paren_identifier array_dimension
3562 { $$ = $1->addArray( $2 ); }
3563 | '(' variable_ptr ')' array_dimension
3564 { $$ = $2->addArray( $4 ); }
3565 | '(' attribute_list variable_ptr ')' array_dimension
3566 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3567 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3568 { $$ = $2->addArray( $4 ); }
3569 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3570 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3571 | '(' variable_array ')' // redundant parenthesis
3572 { $$ = $2; }
3573 | '(' attribute_list variable_array ')' // redundant parenthesis
3574 { $$ = $3->addQualifiers( $2 ); }
3575 ;
3576
3577variable_function:
3578 '(' variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3579 { $$ = $2->addParamList( $5 ); }
3580 | '(' attribute_list variable_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3581 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3582 | '(' variable_function ')' // redundant parenthesis
3583 { $$ = $2; }
3584 | '(' attribute_list variable_function ')' // redundant parenthesis
3585 { $$ = $3->addQualifiers( $2 ); }
3586 ;
3587
3588// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3589// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3590// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3591
3592function_declarator:
3593 function_no_ptr attribute_list_opt
3594 { $$ = $1->addQualifiers( $2 ); }
3595 | function_ptr
3596 | function_array attribute_list_opt
3597 { $$ = $1->addQualifiers( $2 ); }
3598 ;
3599
3600function_no_ptr:
3601 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3602 { $$ = $1->addParamList( $3 ); }
3603 | '(' function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3604 { $$ = $2->addParamList( $5 ); }
3605 | '(' attribute_list function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3606 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3607 | '(' function_no_ptr ')' // redundant parenthesis
3608 { $$ = $2; }
3609 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3610 { $$ = $3->addQualifiers( $2 ); }
3611 ;
3612
3613function_ptr:
3614 ptrref_operator function_declarator
3615 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3616 | ptrref_operator type_qualifier_list function_declarator
3617 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3618 | '(' function_ptr ')' attribute_list_opt
3619 { $$ = $2->addQualifiers( $4 ); }
3620 | '(' attribute_list function_ptr ')' attribute_list_opt
3621 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3622 ;
3623
3624function_array:
3625 '(' function_ptr ')' array_dimension
3626 { $$ = $2->addArray( $4 ); }
3627 | '(' attribute_list function_ptr ')' array_dimension
3628 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3629 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3630 { $$ = $2->addArray( $4 ); }
3631 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3632 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3633 | '(' function_array ')' // redundant parenthesis
3634 { $$ = $2; }
3635 | '(' attribute_list function_array ')' // redundant parenthesis
3636 { $$ = $3->addQualifiers( $2 ); }
3637 ;
3638
3639// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3640//
3641// f( a, b, c ) int a, *b, c[]; {}
3642//
3643// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3644// returning arrays and functions versus pointers to arrays and functions.
3645
3646KR_function_declarator:
3647 KR_function_no_ptr
3648 | KR_function_ptr
3649 | KR_function_array
3650 ;
3651
3652KR_function_no_ptr:
3653 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3654 { $$ = $1->addIdList( $3 ); }
3655 | '(' KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3656 { $$ = $2->addParamList( $5 ); }
3657 | '(' attribute_list KR_function_ptr ')' '(' parameter_list_ellipsis_opt ')'
3658 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3659 | '(' KR_function_no_ptr ')' // redundant parenthesis
3660 { $$ = $2; }
3661 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3662 { $$ = $3->addQualifiers( $2 ); }
3663 ;
3664
3665KR_function_ptr:
3666 ptrref_operator KR_function_declarator
3667 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3668 | ptrref_operator type_qualifier_list KR_function_declarator
3669 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3670 | '(' KR_function_ptr ')'
3671 { $$ = $2; }
3672 | '(' attribute_list KR_function_ptr ')'
3673 { $$ = $3->addQualifiers( $2 ); }
3674 ;
3675
3676KR_function_array:
3677 '(' KR_function_ptr ')' array_dimension
3678 { $$ = $2->addArray( $4 ); }
3679 | '(' attribute_list KR_function_ptr ')' array_dimension
3680 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3681 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3682 { $$ = $2->addArray( $4 ); }
3683 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3684 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3685 | '(' KR_function_array ')' // redundant parenthesis
3686 { $$ = $2; }
3687 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3688 { $$ = $3->addQualifiers( $2 ); }
3689 ;
3690
3691// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3692//
3693// typedef int foo;
3694// {
3695// int foo; // redefine typedef name in new scope
3696// }
3697
3698paren_type:
3699 typedef_name
3700 {
3701 // hide type name in enclosing scope by variable name
3702 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3703 }
3704 | '(' paren_type ')'
3705 { $$ = $2; }
3706 ;
3707
3708variable_type_redeclarator:
3709 paren_type attribute_list_opt
3710 { $$ = $1->addQualifiers( $2 ); }
3711 | variable_type_ptr
3712 | variable_type_array attribute_list_opt
3713 { $$ = $1->addQualifiers( $2 ); }
3714 | variable_type_function attribute_list_opt
3715 { $$ = $1->addQualifiers( $2 ); }
3716 ;
3717
3718variable_type_ptr:
3719 ptrref_operator variable_type_redeclarator
3720 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3721 | ptrref_operator type_qualifier_list variable_type_redeclarator
3722 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3723 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3724 { $$ = $2->addQualifiers( $4 ); }
3725 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3726 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3727 ;
3728
3729variable_type_array:
3730 paren_type array_dimension
3731 { $$ = $1->addArray( $2 ); }
3732 | '(' variable_type_ptr ')' array_dimension
3733 { $$ = $2->addArray( $4 ); }
3734 | '(' attribute_list variable_type_ptr ')' array_dimension
3735 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3736 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3737 { $$ = $2->addArray( $4 ); }
3738 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3739 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3740 | '(' variable_type_array ')' // redundant parenthesis
3741 { $$ = $2; }
3742 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3743 { $$ = $3->addQualifiers( $2 ); }
3744 ;
3745
3746variable_type_function:
3747 '(' variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3748 { $$ = $2->addParamList( $5 ); }
3749 | '(' attribute_list variable_type_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3750 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3751 | '(' variable_type_function ')' // redundant parenthesis
3752 { $$ = $2; }
3753 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3754 { $$ = $3->addQualifiers( $2 ); }
3755 ;
3756
3757// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3758// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3759// arrays and functions.
3760
3761function_type_redeclarator:
3762 function_type_no_ptr attribute_list_opt
3763 { $$ = $1->addQualifiers( $2 ); }
3764 | function_type_ptr
3765 | function_type_array attribute_list_opt
3766 { $$ = $1->addQualifiers( $2 ); }
3767 ;
3768
3769function_type_no_ptr:
3770 paren_type '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3771 { $$ = $1->addParamList( $3 ); }
3772 | '(' function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3773 { $$ = $2->addParamList( $5 ); }
3774 | '(' attribute_list function_type_ptr ')' '(' parameter_list_ellipsis_opt ')'
3775 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3776 | '(' function_type_no_ptr ')' // redundant parenthesis
3777 { $$ = $2; }
3778 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3779 { $$ = $3->addQualifiers( $2 ); }
3780 ;
3781
3782function_type_ptr:
3783 ptrref_operator function_type_redeclarator
3784 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3785 | ptrref_operator type_qualifier_list function_type_redeclarator
3786 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3787 | '(' function_type_ptr ')' attribute_list_opt
3788 { $$ = $2->addQualifiers( $4 ); }
3789 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3790 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3791 ;
3792
3793function_type_array:
3794 '(' function_type_ptr ')' array_dimension
3795 { $$ = $2->addArray( $4 ); }
3796 | '(' attribute_list function_type_ptr ')' array_dimension
3797 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3798 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3799 { $$ = $2->addArray( $4 ); }
3800 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3801 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3802 | '(' function_type_array ')' // redundant parenthesis
3803 { $$ = $2; }
3804 | '(' attribute_list function_type_array ')' // redundant parenthesis
3805 { $$ = $3->addQualifiers( $2 ); }
3806 ;
3807
3808// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3809// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3810// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3811// pointers to arrays and functions.
3812
3813identifier_parameter_declarator:
3814 paren_identifier attribute_list_opt
3815 { $$ = $1->addQualifiers( $2 ); }
3816 | '&' MUTEX paren_identifier attribute_list_opt
3817 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3818 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3819 | identifier_parameter_ptr
3820 | identifier_parameter_array attribute_list_opt
3821 { $$ = $1->addQualifiers( $2 ); }
3822 | identifier_parameter_function attribute_list_opt
3823 { $$ = $1->addQualifiers( $2 ); }
3824 ;
3825
3826identifier_parameter_ptr:
3827 ptrref_operator identifier_parameter_declarator
3828 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3829 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3830 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3831 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3832 { $$ = $2->addQualifiers( $4 ); }
3833 ;
3834
3835identifier_parameter_array:
3836 paren_identifier array_parameter_dimension
3837 { $$ = $1->addArray( $2 ); }
3838 | '(' identifier_parameter_ptr ')' array_dimension
3839 { $$ = $2->addArray( $4 ); }
3840 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3841 { $$ = $2->addArray( $4 ); }
3842 | '(' identifier_parameter_array ')' // redundant parenthesis
3843 { $$ = $2; }
3844 ;
3845
3846identifier_parameter_function:
3847 paren_identifier '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3848 { $$ = $1->addParamList( $3 ); }
3849 | '(' identifier_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3850 { $$ = $2->addParamList( $5 ); }
3851 | '(' identifier_parameter_function ')' // redundant parenthesis
3852 { $$ = $2; }
3853 ;
3854
3855// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3856// e.g.:
3857//
3858// typedef int foo;
3859// forall( otype T ) struct foo;
3860// int f( int foo ); // redefine typedef name in new scope
3861//
3862// and allows the C99 array options, which can only appear in a parameter list.
3863
3864type_parameter_redeclarator:
3865 typedef_name attribute_list_opt
3866 { $$ = $1->addQualifiers( $2 ); }
3867 | '&' MUTEX typedef_name attribute_list_opt
3868 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
3869 OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3870 | type_parameter_ptr
3871 | type_parameter_array attribute_list_opt
3872 { $$ = $1->addQualifiers( $2 ); }
3873 | type_parameter_function attribute_list_opt
3874 { $$ = $1->addQualifiers( $2 ); }
3875 ;
3876
3877typedef_name:
3878 TYPEDEFname
3879 { $$ = DeclarationNode::newName( $1 ); }
3880 | TYPEGENname
3881 { $$ = DeclarationNode::newName( $1 ); }
3882 ;
3883
3884type_parameter_ptr:
3885 ptrref_operator type_parameter_redeclarator
3886 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3887 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3888 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3889 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3890 { $$ = $2->addQualifiers( $4 ); }
3891 ;
3892
3893type_parameter_array:
3894 typedef_name array_parameter_dimension
3895 { $$ = $1->addArray( $2 ); }
3896 | '(' type_parameter_ptr ')' array_parameter_dimension
3897 { $$ = $2->addArray( $4 ); }
3898 ;
3899
3900type_parameter_function:
3901 typedef_name '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3902 { $$ = $1->addParamList( $3 ); }
3903 | '(' type_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3904 { $$ = $2->addParamList( $5 ); }
3905 ;
3906
3907// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3908// which the type applies, e.g.:
3909//
3910// sizeof( int );
3911// sizeof( int * );
3912// sizeof( int [10] );
3913// sizeof( int (*)() );
3914// sizeof( int () );
3915//
3916// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3917// and functions versus pointers to arrays and functions.
3918
3919abstract_declarator:
3920 abstract_ptr
3921 | abstract_array attribute_list_opt
3922 { $$ = $1->addQualifiers( $2 ); }
3923 | abstract_function attribute_list_opt
3924 { $$ = $1->addQualifiers( $2 ); }
3925 ;
3926
3927abstract_ptr:
3928 ptrref_operator
3929 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3930 | ptrref_operator type_qualifier_list
3931 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3932 | ptrref_operator abstract_declarator
3933 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3934 | ptrref_operator type_qualifier_list abstract_declarator
3935 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3936 | '(' abstract_ptr ')' attribute_list_opt
3937 { $$ = $2->addQualifiers( $4 ); }
3938 ;
3939
3940abstract_array:
3941 array_dimension
3942 | '(' abstract_ptr ')' array_dimension
3943 { $$ = $2->addArray( $4 ); }
3944 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3945 { $$ = $2->addArray( $4 ); }
3946 | '(' abstract_array ')' // redundant parenthesis
3947 { $$ = $2; }
3948 ;
3949
3950abstract_function:
3951 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3952 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3953 | '(' abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
3954 { $$ = $2->addParamList( $5 ); }
3955 | '(' abstract_function ')' // redundant parenthesis
3956 { $$ = $2; }
3957 ;
3958
3959array_dimension:
3960 // Only the first dimension can be empty.
3961 '[' ']'
3962 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3963 | '[' ']' multi_array_dimension
3964 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3965 // Cannot use constant_expression because of tuples => semantic check
3966 | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3967 { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3968 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3969
3970 // If needed, the following parses and does not use comma_expression, so the array structure can be built.
3971 // | '[' push assignment_expression pop ',' push array_dimension_list pop ']' // CFA
3972
3973 | '[' push array_type_list pop ']' // CFA
3974 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3975 | multi_array_dimension
3976 ;
3977
3978// array_dimension_list:
3979// assignment_expression
3980// | array_dimension_list ',' assignment_expression
3981// ;
3982
3983array_type_list:
3984 basic_type_name
3985 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3986 | type_name
3987 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3988 | assignment_expression upupeq assignment_expression
3989 | array_type_list ',' basic_type_name
3990 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3991 | array_type_list ',' type_name
3992 { $$ = $1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) ); }
3993 | array_type_list ',' assignment_expression upupeq assignment_expression
3994 ;
3995
3996upupeq:
3997 '~'
3998 { $$ = OperKinds::LThan; }
3999 | ErangeUpEq
4000 { $$ = OperKinds::LEThan; }
4001 ;
4002
4003multi_array_dimension:
4004 '[' push assignment_expression pop ']'
4005 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
4006 | '[' push '*' pop ']' // C99
4007 { $$ = DeclarationNode::newVarArray( 0 ); }
4008 | multi_array_dimension '[' push assignment_expression pop ']'
4009 { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
4010 | multi_array_dimension '[' push '*' pop ']' // C99
4011 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
4012 ;
4013
4014// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
4015// identifier to which the type applies, e.g.:
4016//
4017// int f( int ); // not handled here
4018// int f( int * ); // abstract function-prototype parameter; no parameter name specified
4019// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
4020// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
4021//
4022// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
4023// and functions versus pointers to arrays and functions. In addition, the pattern handles the special meaning of
4024// parenthesis around a typedef name:
4025//
4026// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
4027// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
4028// not as redundant parentheses around the identifier."
4029//
4030// For example:
4031//
4032// typedef float T;
4033// int f( int ( T [5] ) ); // see abstract_parameter_declarator
4034// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
4035// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
4036// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
4037//
4038// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
4039// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
4040// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
4041// functions.
4042
4043abstract_parameter_declarator_opt:
4044 // empty
4045 { $$ = nullptr; }
4046 | abstract_parameter_declarator
4047 ;
4048
4049abstract_parameter_declarator:
4050 abstract_parameter_ptr
4051 | '&' MUTEX attribute_list_opt
4052 { $$ = DeclarationNode::newPointer( DeclarationNode::newFromTypeData( build_type_qualifier( ast::CV::Mutex ) ),
4053 OperKinds::AddressOf )->addQualifiers( $3 ); }
4054 | abstract_parameter_array attribute_list_opt
4055 { $$ = $1->addQualifiers( $2 ); }
4056 | abstract_parameter_function attribute_list_opt
4057 { $$ = $1->addQualifiers( $2 ); }
4058 ;
4059
4060abstract_parameter_ptr:
4061 ptrref_operator
4062 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4063 | ptrref_operator type_qualifier_list
4064 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4065 | ptrref_operator abstract_parameter_declarator
4066 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4067 | ptrref_operator type_qualifier_list abstract_parameter_declarator
4068 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4069 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
4070 { $$ = $2->addQualifiers( $4 ); }
4071 ;
4072
4073abstract_parameter_array:
4074 array_parameter_dimension
4075 | '(' abstract_parameter_ptr ')' array_parameter_dimension
4076 { $$ = $2->addArray( $4 ); }
4077 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
4078 { $$ = $2->addArray( $4 ); }
4079 | '(' abstract_parameter_array ')' // redundant parenthesis
4080 { $$ = $2; }
4081 ;
4082
4083abstract_parameter_function:
4084 '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4085 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
4086 | '(' abstract_parameter_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4087 { $$ = $2->addParamList( $5 ); }
4088 | '(' abstract_parameter_function ')' // redundant parenthesis
4089 { $$ = $2; }
4090 ;
4091
4092array_parameter_dimension:
4093 // Only the first dimension can be empty or have qualifiers.
4094 array_parameter_1st_dimension
4095 | array_parameter_1st_dimension multi_array_dimension
4096 { $$ = $1->addArray( $2 ); }
4097 | multi_array_dimension
4098 ;
4099
4100// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4101//
4102// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4103// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4104
4105array_parameter_1st_dimension:
4106 '[' ']'
4107 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4108 // multi_array_dimension handles the '[' '*' ']' case
4109 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4110 { $$ = DeclarationNode::newVarArray( $3 ); }
4111 | '[' push type_qualifier_list pop ']'
4112 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4113 // multi_array_dimension handles the '[' assignment_expression ']' case
4114 | '[' push type_qualifier_list assignment_expression pop ']'
4115 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4116 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4117 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4118 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4119 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4120 ;
4121
4122// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4123//
4124// struct S {
4125// int;
4126// int *;
4127// int [10];
4128// int (*)();
4129// };
4130
4131variable_abstract_declarator:
4132 variable_abstract_ptr
4133 | variable_abstract_array attribute_list_opt
4134 { $$ = $1->addQualifiers( $2 ); }
4135 | variable_abstract_function attribute_list_opt
4136 { $$ = $1->addQualifiers( $2 ); }
4137 ;
4138
4139variable_abstract_ptr:
4140 ptrref_operator
4141 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4142 | ptrref_operator type_qualifier_list
4143 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4144 | ptrref_operator variable_abstract_declarator
4145 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4146 | ptrref_operator type_qualifier_list variable_abstract_declarator
4147 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4148 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4149 { $$ = $2->addQualifiers( $4 ); }
4150 ;
4151
4152variable_abstract_array:
4153 array_dimension
4154 | '(' variable_abstract_ptr ')' array_dimension
4155 { $$ = $2->addArray( $4 ); }
4156 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4157 { $$ = $2->addArray( $4 ); }
4158 | '(' variable_abstract_array ')' // redundant parenthesis
4159 { $$ = $2; }
4160 ;
4161
4162variable_abstract_function:
4163 '(' variable_abstract_ptr ')' '(' parameter_list_ellipsis_opt ')' // empty parameter list OBSOLESCENT (see 3)
4164 { $$ = $2->addParamList( $5 ); }
4165 | '(' variable_abstract_function ')' // redundant parenthesis
4166 { $$ = $2; }
4167 ;
4168
4169// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4170// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4171
4172cfa_identifier_parameter_declarator_tuple: // CFA
4173 cfa_identifier_parameter_declarator_no_tuple
4174 | cfa_abstract_tuple
4175 | type_qualifier_list cfa_abstract_tuple
4176 { $$ = $2->addQualifiers( $1 ); }
4177 ;
4178
4179cfa_identifier_parameter_declarator_no_tuple: // CFA
4180 cfa_identifier_parameter_ptr
4181 | cfa_identifier_parameter_array
4182 ;
4183
4184cfa_identifier_parameter_ptr: // CFA
4185 // No SUE declaration in parameter list.
4186 ptrref_operator type_specifier_nobody
4187 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4188 | type_qualifier_list ptrref_operator type_specifier_nobody
4189 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4190 | ptrref_operator cfa_abstract_function
4191 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4192 | type_qualifier_list ptrref_operator cfa_abstract_function
4193 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4194 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4195 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4196 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4197 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4198 ;
4199
4200cfa_identifier_parameter_array: // CFA
4201 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4202 // shift/reduce conflict with new-style empty (void) function return type.
4203 '[' ']' type_specifier_nobody
4204 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4205 | cfa_array_parameter_1st_dimension type_specifier_nobody
4206 { $$ = $2->addNewArray( $1 ); }
4207 | '[' ']' multi_array_dimension type_specifier_nobody
4208 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4209 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4210 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4211 | multi_array_dimension type_specifier_nobody
4212 { $$ = $2->addNewArray( $1 ); }
4213
4214 | '[' ']' cfa_identifier_parameter_ptr
4215 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4216 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4217 { $$ = $2->addNewArray( $1 ); }
4218 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4219 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4220 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4221 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4222 | multi_array_dimension cfa_identifier_parameter_ptr
4223 { $$ = $2->addNewArray( $1 ); }
4224 ;
4225
4226cfa_array_parameter_1st_dimension:
4227 '[' push type_qualifier_list '*' pop ']' // remaining C99
4228 { $$ = DeclarationNode::newVarArray( $3 ); }
4229 | '[' push type_qualifier_list assignment_expression pop ']'
4230 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4231 | '[' push declaration_qualifier_list assignment_expression pop ']'
4232 // declaration_qualifier_list must be used because of shift/reduce conflict with
4233 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4234 // appear in this context.
4235 { $$ = DeclarationNode::newArray( $4, $3, true ); }
4236 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4237 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4238 ;
4239
4240// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4241// identifier to which the type applies, e.g.:
4242//
4243// [int] f( int ); // abstract variable parameter; no parameter name specified
4244// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4245//
4246// These rules need LR(3):
4247//
4248// cfa_abstract_tuple identifier_or_type_name
4249// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_list_ellipsis_opt ')'
4250//
4251// since a function return type can be syntactically identical to a tuple type:
4252//
4253// [int, int] t;
4254// [int, int] f( int );
4255//
4256// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4257// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4258// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4259// duplicated when appearing with cfa_function_specifier.
4260
4261cfa_abstract_declarator_tuple: // CFA
4262 cfa_abstract_tuple
4263 | type_qualifier_list cfa_abstract_tuple
4264 { $$ = $2->addQualifiers( $1 ); }
4265 | cfa_abstract_declarator_no_tuple
4266 ;
4267
4268cfa_abstract_declarator_no_tuple: // CFA
4269 cfa_abstract_ptr
4270 | cfa_abstract_array
4271 ;
4272
4273cfa_abstract_ptr: // CFA
4274 ptrref_operator type_specifier
4275 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4276 | type_qualifier_list ptrref_operator type_specifier
4277 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4278 | ptrref_operator cfa_abstract_function
4279 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4280 | type_qualifier_list ptrref_operator cfa_abstract_function
4281 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4282 | ptrref_operator cfa_abstract_declarator_tuple
4283 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4284 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4285 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4286 ;
4287
4288cfa_abstract_array: // CFA
4289 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4290 // empty (void) function return type.
4291 '[' ']' type_specifier
4292 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4293 | '[' ']' multi_array_dimension type_specifier
4294 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4295 | multi_array_dimension type_specifier
4296 { $$ = $2->addNewArray( $1 ); }
4297 | '[' ']' cfa_abstract_ptr
4298 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4299 | '[' ']' multi_array_dimension cfa_abstract_ptr
4300 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4301 | multi_array_dimension cfa_abstract_ptr
4302 { $$ = $2->addNewArray( $1 ); }
4303 ;
4304
4305cfa_abstract_tuple: // CFA
4306 '[' push cfa_abstract_parameter_list pop ']'
4307 { $$ = DeclarationNode::newTuple( $3 ); }
4308 | '[' push type_specifier_nobody ELLIPSIS pop ']'
4309 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4310 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4311 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4312 ;
4313
4314cfa_abstract_function: // CFA
4315 '[' ']' '(' cfa_parameter_list_ellipsis_opt ')'
4316 { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4317 | cfa_abstract_tuple '(' push cfa_parameter_list_ellipsis_opt pop ')'
4318 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4319 | cfa_function_return '(' push cfa_parameter_list_ellipsis_opt pop ')'
4320 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4321 ;
4322
4323// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4324// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4325//
4326// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4327// the declaration specifiers in a declaration is an obsolescent feature."
4328//
4329// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4330// prototype-format parameter type declarators) is an obsolescent feature."
4331//
4332// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4333// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4334
4335// ************************ MISCELLANEOUS ********************************
4336
4337comma_opt: // redundant comma
4338 // empty
4339 | ','
4340 ;
4341
4342default_initializer_opt:
4343 // empty
4344 { $$ = nullptr; }
4345 | '=' assignment_expression
4346 { $$ = $2; }
4347 ;
4348
4349%%
4350
4351// ----end of grammar----
4352
4353// Local Variables: //
4354// mode: c++ //
4355// tab-width: 4 //
4356// compile-command: "bison -Wcounterexamples parser.yy" //
4357// End: //
Note: See TracBrowser for help on using the repository browser.