source: src/Parser/parser.yy @ 4a063df

arm-ehjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-expr
Last change on this file since 4a063df was 4a063df, checked in by Peter A. Buhr <pabuhr@…>, 21 months ago

formatting, change waitfor to support a list of functions, separated by a colon, from a list of monitors

  • Property mode set to 100644
File size: 135.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Fri Jan 17 14:54:55 2020
13// Update Count     : 4426
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack< LinkageSpec::Spec > linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168NameExpr * build_postfix_name( const string * name ) {
169        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
170        delete name;
171        return new_name;
172} // build_postfix_name
173
174DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
175        if ( ! fieldList ) {                                                            // field declarator ?
176                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
177                        stringstream ss;
178                        typeSpec->type->print( ss );
179                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
180                        return nullptr;
181                } // if
182                fieldList = DeclarationNode::newName( nullptr );
183        } // if
184        return distAttr( typeSpec, fieldList );                         // mark all fields in list
185} // fieldDecl
186
187ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
188        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
189        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
190        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
191        } // if
192        return new ForCtrl(
193                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
194                // NULL comp/inc => leave blank
195                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
196                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
197                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
198} // forCtrl
199
200ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
201        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
202                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
203        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
204                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
205                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
206                } else {
207                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
208                } // if
209        } else {
210                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
211        } // if
212} // forCtrl
213
214bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
215
216// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
217#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
218if ( N ) {                                                                                                                                              \
219        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
220        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
221        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
222        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
223        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
224} else {                                                                                                                                                \
225        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
226        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
227        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
228}
229%}
230
231%define parse.error verbose
232
233// Types declaration for productions
234%union {
235        Token tok;
236        ParseNode * pn;
237        ExpressionNode * en;
238        DeclarationNode * decl;
239        AggregateDecl::Aggregate aggKey;
240        TypeDecl::Kind tclass;
241        StatementNode * sn;
242        WaitForStmt * wfs;
243        Expression * constant;
244        IfCtrl * ifctl;
245        ForCtrl * fctl;
246        enum OperKinds compop;
247        LabelNode * label;
248        InitializerNode * in;
249        OperKinds op;
250        std::string * str;
251        bool flag;
252        CatchStmt::Kind catch_kind;
253        GenericExpr * genexpr;
254}
255
256//************************* TERMINAL TOKENS ********************************
257
258// keywords
259%token TYPEDEF
260%token EXTERN STATIC AUTO REGISTER
261%token THREADLOCAL                                                                              // C11
262%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
263%token NORETURN                                                                                 // C11
264%token CONST VOLATILE
265%token RESTRICT                                                                                 // C99
266%token ATOMIC                                                                                   // C11
267%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
268%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
269%token BOOL COMPLEX IMAGINARY                                                   // C99
270%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
271%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
272%token ZERO_T ONE_T                                                                             // CFA
273%token VALIST                                                                                   // GCC
274%token AUTO_TYPE                                                                                // GCC
275%token TYPEOF BASETYPEOF LABEL                                                  // GCC
276%token ENUM STRUCT UNION
277%token EXCEPTION                                                                                // CFA
278%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
279%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
280%token SIZEOF OFFSETOF
281// %token SUSPEND RESUME                                                                        // CFA
282%token ATTRIBUTE EXTENSION                                                              // GCC
283%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
284%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
290%token<tok> TIMEOUT                             WOR
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list              argument_expression                     default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en>   bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581        | constant '`' IDENTIFIER                                                       // CFA, postfix call
582                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
583        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
584                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
585        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
586                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
587        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
588                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
589        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
590                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
591        | type_name '.' identifier                                                      // CFA, nested type
592                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
593        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
594                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
595        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
596                {
597                        // add the missing control expression to the GenericExpr and return it
598                        $5->control = maybeMoveBuild<Expression>( $3 );
599                        $$ = new ExpressionNode( $5 );
600                }
601        // | RESUME '(' comma_expression ')'
602        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
603        // | RESUME '(' comma_expression ')' compound_statement
604        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
605        ;
606
607generic_assoc_list:                                                                             // C11
608        generic_association
609        | generic_assoc_list ',' generic_association
610                {
611                        // steal the association node from the singleton and delete the wrapper
612                        $1->associations.splice($1->associations.end(), $3->associations);
613                        delete $3;
614                        $$ = $1;
615                }
616        ;
617
618generic_association:                                                                    // C11
619        type_no_function ':' assignment_expression
620                {
621                        // create a GenericExpr wrapper with one association pair
622                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
623                }
624        | DEFAULT ':' assignment_expression
625                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
626        ;
627
628postfix_expression:
629        primary_expression
630        | postfix_expression '[' assignment_expression ']'
631                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
632                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
633                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
634                // equivalent to the old x[i,j].
635                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
636        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
637                {
638                        Token fn;
639                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
640                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
641                }
642        | postfix_expression '(' argument_expression_list ')'
643                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
644        | postfix_expression '.' identifier
645                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
646        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
647                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
648        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
649                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
650        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
651                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
652        | postfix_expression '.' aggregate_control
653                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
654        | postfix_expression ARROW identifier
655                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
656        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
657                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
658        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
659                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
660        | postfix_expression ICR
661                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
662        | postfix_expression DECR
663                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
664        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
665                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
666        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
667                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
668        | '^' primary_expression '{' argument_expression_list '}' // CFA
669                {
670                        Token fn;
671                        fn.str = new string( "^?{}" );                          // location undefined
672                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
673                }
674        ;
675
676argument_expression_list:
677        // empty
678                { $$ = nullptr; }
679        | argument_expression
680        | argument_expression_list ',' argument_expression
681                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
682        ;
683
684argument_expression:
685        '@'                                                                                                     // CFA, default parameter
686                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
687                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
688        | assignment_expression
689        ;
690
691field_name_list:                                                                                // CFA, tuple field selector
692        field
693        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
694        ;
695
696field:                                                                                                  // CFA, tuple field selector
697        field_name
698        | FLOATING_DECIMALconstant field
699                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
700        | FLOATING_DECIMALconstant '[' field_name_list ']'
701                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
702        | field_name '.' field
703                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
704        | field_name '.' '[' field_name_list ']'
705                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
706        | field_name ARROW field
707                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
708        | field_name ARROW '[' field_name_list ']'
709                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
710        ;
711
712field_name:
713        INTEGERconstant fraction_constants_opt
714                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
715        | FLOATINGconstant fraction_constants_opt
716                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
717        | identifier fraction_constants_opt
718                {
719                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
720                }
721        ;
722
723fraction_constants_opt:
724        // empty
725                { $$ = nullptr; }
726        | fraction_constants_opt FLOATING_FRACTIONconstant
727                {
728                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
729                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
730                }
731        ;
732
733unary_expression:
734        postfix_expression
735                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
736                // semantics checks, e.g., ++3, 3--, *3, &&3
737        | constant
738        | string_literal
739                { $$ = new ExpressionNode( $1 ); }
740        | EXTENSION cast_expression                                                     // GCC
741                { $$ = $2->set_extension( true ); }
742                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
743                //              { * X; }         // dereference X
744                //              { * int X; } // CFA declaration of pointer to int
745        | ptrref_operator cast_expression                                       // CFA
746                {
747                        switch ( $1 ) {
748                          case OperKinds::AddressOf:
749                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
750                                break;
751                          case OperKinds::PointTo:
752                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
753                                break;
754                          case OperKinds::And:
755                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
756                                break;
757                          default:
758                                assert( false );
759                        }
760                }
761        | unary_operator cast_expression
762                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
763        | ICR unary_expression
764                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
765        | DECR unary_expression
766                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
767        | SIZEOF unary_expression
768                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
769        | SIZEOF '(' type_no_function ')'
770                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
771        | ALIGNOF unary_expression                                                      // GCC, variable alignment
772                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
773        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
774                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
775        | OFFSETOF '(' type_no_function ',' identifier ')'
776                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
777        ;
778
779ptrref_operator:
780        '*'                                                                                     { $$ = OperKinds::PointTo; }
781        | '&'                                                                           { $$ = OperKinds::AddressOf; }
782                // GCC, address of label must be handled by semantic check for ref,ref,label
783        | ANDAND                                                                        { $$ = OperKinds::And; }
784        ;
785
786unary_operator:
787        '+'                                                                                     { $$ = OperKinds::UnPlus; }
788        | '-'                                                                           { $$ = OperKinds::UnMinus; }
789        | '!'                                                                           { $$ = OperKinds::Neg; }
790        | '~'                                                                           { $$ = OperKinds::BitNeg; }
791        ;
792
793cast_expression:
794        unary_expression
795        | '(' type_no_function ')' cast_expression
796                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
797        | '(' aggregate_control '&' ')' cast_expression         // CFA
798                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
799                // VIRTUAL cannot be opt because of look ahead issues
800        | '(' VIRTUAL ')' cast_expression                                       // CFA
801                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
802        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
803                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
804        | '(' RETURN type_no_function ')' cast_expression       // CFA
805                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
806        | '(' COERCE type_no_function ')' cast_expression       // CFA
807                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
808        | '(' qualifier_cast_list ')' cast_expression           // CFA
809                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
810//      | '(' type_no_function ')' tuple
811//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
812        ;
813
814qualifier_cast_list:
815        cast_modifier type_qualifier_name
816        | cast_modifier MUTEX
817        | qualifier_cast_list cast_modifier type_qualifier_name
818        | qualifier_cast_list cast_modifier MUTEX
819        ;
820
821cast_modifier:
822        '-'
823        | '+'
824        ;
825
826exponential_expression:
827        cast_expression
828        | exponential_expression '\\' cast_expression
829                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
830        ;
831
832multiplicative_expression:
833        exponential_expression
834        | multiplicative_expression '*' exponential_expression
835                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
836        | multiplicative_expression '/' exponential_expression
837                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
838        | multiplicative_expression '%' exponential_expression
839                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
840        ;
841
842additive_expression:
843        multiplicative_expression
844        | additive_expression '+' multiplicative_expression
845                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
846        | additive_expression '-' multiplicative_expression
847                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
848        ;
849
850shift_expression:
851        additive_expression
852        | shift_expression LS additive_expression
853                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
854        | shift_expression RS additive_expression
855                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
856        ;
857
858relational_expression:
859        shift_expression
860        | relational_expression '<' shift_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
862        | relational_expression '>' shift_expression
863                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
864        | relational_expression LE shift_expression
865                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
866        | relational_expression GE shift_expression
867                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
868        ;
869
870equality_expression:
871        relational_expression
872        | equality_expression EQ relational_expression
873                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
874        | equality_expression NE relational_expression
875                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
876        ;
877
878AND_expression:
879        equality_expression
880        | AND_expression '&' equality_expression
881                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
882        ;
883
884exclusive_OR_expression:
885        AND_expression
886        | exclusive_OR_expression '^' AND_expression
887                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
888        ;
889
890inclusive_OR_expression:
891        exclusive_OR_expression
892        | inclusive_OR_expression '|' exclusive_OR_expression
893                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
894        ;
895
896logical_AND_expression:
897        inclusive_OR_expression
898        | logical_AND_expression ANDAND inclusive_OR_expression
899                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
900        ;
901
902logical_OR_expression:
903        logical_AND_expression
904        | logical_OR_expression OROR logical_AND_expression
905                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
906        ;
907
908conditional_expression:
909        logical_OR_expression
910        | logical_OR_expression '?' comma_expression ':' conditional_expression
911                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
912                // FIX ME: computes $1 twice
913        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
914                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
915        ;
916
917constant_expression:
918        conditional_expression
919        ;
920
921assignment_expression:
922                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
923        conditional_expression
924        | unary_expression assignment_operator assignment_expression
925                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
926        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
927                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
928        ;
929
930assignment_expression_opt:
931        // empty
932                { $$ = nullptr; }
933        | assignment_expression
934        ;
935
936assignment_operator:
937        '='                                                                                     { $$ = OperKinds::Assign; }
938        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
939        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
940        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
941        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
942        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
943        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
944        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
945        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
946        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
947        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
948        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
949        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
950        ;
951
952tuple:                                                                                                  // CFA, tuple
953                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
954                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
955//      '[' ']'
956//              { $$ = new ExpressionNode( build_tuple() ); }
957//      | '[' push assignment_expression pop ']'
958//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
959        '[' ',' tuple_expression_list ']'
960                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
961        | '[' push assignment_expression pop ',' tuple_expression_list ']'
962                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
963        ;
964
965tuple_expression_list:
966        assignment_expression_opt
967        | tuple_expression_list ',' assignment_expression_opt
968                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
969        ;
970
971comma_expression:
972        assignment_expression
973        | comma_expression ',' assignment_expression
974                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
975        ;
976
977comma_expression_opt:
978        // empty
979                { $$ = nullptr; }
980        | comma_expression
981        ;
982
983//*************************** STATEMENTS *******************************
984
985statement:
986        labeled_statement
987        | compound_statement
988        | expression_statement
989        | selection_statement
990        | iteration_statement
991        | jump_statement
992        | with_statement
993        | mutex_statement
994        | waitfor_statement
995        | exception_statement
996        | enable_disable_statement
997                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
998        | asm_statement
999        | DIRECTIVE
1000                { $$ = new StatementNode( build_directive( $1 ) ); }
1001        ;
1002
1003labeled_statement:
1004                // labels cannot be identifiers 0 or 1
1005        identifier_or_type_name ':' attribute_list_opt statement
1006                { $$ = $4->add_label( $1, $3 ); }
1007        ;
1008
1009compound_statement:
1010        '{' '}'
1011                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1012        | '{' push
1013          local_label_declaration_opt                                           // GCC, local labels
1014          statement_decl_list                                                           // C99, intermix declarations and statements
1015          pop '}'
1016                { $$ = new StatementNode( build_compound( $4 ) ); }
1017        ;
1018
1019statement_decl_list:                                                                    // C99
1020        statement_decl
1021        | statement_decl_list statement_decl
1022                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1023        ;
1024
1025statement_decl:
1026        declaration                                                                                     // CFA, new & old style declarations
1027                { $$ = new StatementNode( $1 ); }
1028        | EXTENSION declaration                                                         // GCC
1029                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1030        | function_definition
1031                { $$ = new StatementNode( $1 ); }
1032        | EXTENSION function_definition                                         // GCC
1033                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1034        | statement
1035        ;
1036
1037statement_list_nodecl:
1038        statement
1039        | statement_list_nodecl statement
1040                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1041        ;
1042
1043expression_statement:
1044        comma_expression_opt ';'
1045                { $$ = new StatementNode( build_expr( $1 ) ); }
1046        ;
1047
1048selection_statement:
1049                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1050                        // the inherent S/R conflict with THEN/ELSE.
1051        push if_statement pop
1052                { $$ = $2; }
1053        | SWITCH '(' comma_expression ')' case_clause
1054                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1055        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1056                {
1057                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1058                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1059                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1060                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1061                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1062                        // statement.
1063                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1064                }
1065        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1066                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1067        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1068                {
1069                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1070                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1071                }
1072        ;
1073
1074if_statement:
1075        IF '(' if_control_expression ')' statement                      %prec THEN
1076                // explicitly deal with the shift/reduce conflict on if/else
1077                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1078        | IF '(' if_control_expression ')' statement ELSE statement
1079                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1080        ;
1081
1082if_control_expression:
1083        comma_expression
1084                { $$ = new IfCtrl( nullptr, $1 ); }
1085        | c_declaration                                                                         // no semi-colon
1086                { $$ = new IfCtrl( $1, nullptr ); }
1087        | cfa_declaration                                                                       // no semi-colon
1088                { $$ = new IfCtrl( $1, nullptr ); }
1089        | declaration comma_expression                                          // semi-colon separated
1090                { $$ = new IfCtrl( $1, $2 ); }
1091        ;
1092
1093// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1094// clause allows a list of values and subranges.
1095
1096case_value:                                                                                             // CFA
1097        constant_expression                                                     { $$ = $1; }
1098        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1099                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1100        | subrange                                                                                      // CFA, subrange
1101        ;
1102
1103case_value_list:                                                                                // CFA
1104        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1105                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1106        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1107        ;
1108
1109case_label:                                                                                             // CFA
1110        CASE case_value_list ':'                                        { $$ = $2; }
1111        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1112                // A semantic check is required to ensure only one default clause per switch/choose statement.
1113        ;
1114
1115//label_list_opt:
1116//      // empty
1117//      | identifier_or_type_name ':'
1118//      | label_list_opt identifier_or_type_name ':'
1119//      ;
1120
1121case_label_list:                                                                                // CFA
1122        case_label
1123        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1124        ;
1125
1126case_clause:                                                                                    // CFA
1127        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1128        ;
1129
1130switch_clause_list_opt:                                                                 // CFA
1131        // empty
1132                { $$ = nullptr; }
1133        | switch_clause_list
1134        ;
1135
1136switch_clause_list:                                                                             // CFA
1137        case_label_list statement_list_nodecl
1138                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1139        | switch_clause_list case_label_list statement_list_nodecl
1140                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1141        ;
1142
1143iteration_statement:
1144        WHILE '(' push if_control_expression ')' statement pop
1145                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1146        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1147                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1148        | DO statement WHILE '(' comma_expression ')' ';'
1149                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1150        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1151                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1152        | FOR '(' push for_control_expression_list ')' statement pop
1153                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1154        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1155                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1156        ;
1157
1158for_control_expression_list:
1159        for_control_expression
1160        | for_control_expression_list ':' for_control_expression
1161                // ForCtrl + ForCtrl:
1162                //    init + init => multiple declaration statements that are hoisted
1163                //    condition + condition => (expression) && (expression)
1164                //    change + change => (expression), (expression)
1165                {
1166                        $1->init->set_last( $3->init );
1167                        if ( $1->condition ) {
1168                                if ( $3->condition ) {
1169                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1170                                } // if
1171                        } else $1->condition = $3->condition;
1172                        if ( $1->change ) {
1173                                if ( $3->change ) {
1174                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1175                                } // if
1176                        } else $1->change = $3->change;
1177                        $$ = $1;
1178                }
1179        ;
1180
1181for_control_expression:
1182        ';' comma_expression_opt ';' comma_expression_opt
1183                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1184        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1185                { $$ = new ForCtrl( $1, $3, $5 ); }
1186        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1187                { $$ = new ForCtrl( $1, $2, $4 ); }
1188
1189        | comma_expression                                                                      // CFA
1190                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1191                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1192        | '=' comma_expression                                                                  // CFA
1193                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1194                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1195        | comma_expression inclexcl comma_expression            // CFA
1196                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1197        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1198                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1199        | comma_expression ';' comma_expression                         // CFA
1200                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1201                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1202        | comma_expression ';' '=' comma_expression                             // CFA
1203                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1204                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1205        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1206                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1207        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1208                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1209
1210                // There is a S/R conflicit if ~ and -~ are factored out.
1211        | comma_expression ';' comma_expression '~' '@'         // CFA
1212                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1213        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1214                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1215        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1216                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1217        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1218                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1219        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1220                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1221        ;
1222
1223inclexcl:
1224        '~'
1225                { $$ = OperKinds::LThan; }
1226        | ErangeUpEq
1227                { $$ = OperKinds::LEThan; }
1228        | ErangeDown
1229                { $$ = OperKinds::GThan; }
1230        | ErangeDownEq
1231                { $$ = OperKinds::GEThan; }
1232        ;
1233
1234jump_statement:
1235        GOTO identifier_or_type_name ';'
1236                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1237        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1238                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1239                // whereas normal operator precedence yields goto (*i)+3;
1240                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1241                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1242    | fall_through_name ';'                                                             // CFA
1243                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1244    | fall_through_name identifier_or_type_name ';'             // CFA
1245                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1246        | fall_through_name DEFAULT ';'                                         // CFA
1247                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1248        | CONTINUE ';'
1249                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1250                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1251        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1252                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1253                // the target of the transfer appears only at the start of an iteration statement.
1254                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1255        | BREAK ';'
1256                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1257                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1258        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1259                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1260                // the target of the transfer appears only at the start of an iteration statement.
1261                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1262        | RETURN comma_expression_opt ';'
1263                { $$ = new StatementNode( build_return( $2 ) ); }
1264        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1265                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1266        // | SUSPEND ';'
1267        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1268        // | SUSPEND compound_statement ';'
1269        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1270        | THROW assignment_expression_opt ';'                           // handles rethrow
1271                { $$ = new StatementNode( build_throw( $2 ) ); }
1272        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1273                { $$ = new StatementNode( build_resume( $2 ) ); }
1274        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1275                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1276        ;
1277
1278fall_through_name:                                                                              // CFA
1279        FALLTHRU
1280        | FALLTHROUGH
1281        ;
1282
1283with_statement:
1284        WITH '(' tuple_expression_list ')' statement
1285                {
1286                        $$ = new StatementNode( build_with( $3, $5 ) );
1287                }
1288        ;
1289
1290// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1291mutex_statement:
1292        MUTEX '(' argument_expression_list ')' statement
1293                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1294        ;
1295
1296when_clause:
1297        WHEN '(' comma_expression ')'                           { $$ = $3; }
1298        ;
1299
1300when_clause_opt:
1301        // empty
1302                { $$ = nullptr; }
1303        | when_clause
1304        ;
1305
1306waitfor:
1307        WAITFOR '(' cast_expression ')'
1308                { $$ = $3; }
1309//      | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1310//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1311        | WAITFOR '(' cast_expression_list ':' argument_expression_list ')'
1312                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1313        ;
1314
1315cast_expression_list:
1316        cast_expression
1317        | cast_expression_list ',' cast_expression
1318                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1319        ;
1320
1321timeout:
1322        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1323        ;
1324
1325waitfor_clause:
1326        when_clause_opt waitfor statement                                       %prec THEN
1327                { $$ = build_waitfor( $2, $3, $1 ); }
1328        | when_clause_opt waitfor statement WOR waitfor_clause
1329                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1330        | when_clause_opt timeout statement                                     %prec THEN
1331                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1332        | when_clause_opt ELSE statement
1333                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1334                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1335        | when_clause_opt timeout statement WOR ELSE statement
1336                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1337        | when_clause_opt timeout statement WOR when_clause ELSE statement
1338                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1339        ;
1340
1341waitfor_statement:
1342        when_clause_opt waitfor statement                                       %prec THEN
1343                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1344        | when_clause_opt waitfor statement WOR waitfor_clause
1345                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1346        ;
1347
1348exception_statement:
1349        TRY compound_statement handler_clause
1350                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1351        | TRY compound_statement finally_clause
1352                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1353        | TRY compound_statement handler_clause finally_clause
1354                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1355        ;
1356
1357handler_clause:
1358        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1359                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1360        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1361                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1362        ;
1363
1364handler_predicate_opt:
1365        // empty
1366                { $$ = nullptr; }
1367        | ';' conditional_expression                            { $$ = $2; }
1368        ;
1369
1370handler_key:
1371        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1372        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1373        ;
1374
1375finally_clause:
1376        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1377        ;
1378
1379exception_declaration:
1380                // No SUE declaration in parameter list.
1381        type_specifier_nobody
1382        | type_specifier_nobody declarator
1383                { $$ = $2->addType( $1 ); }
1384        | type_specifier_nobody variable_abstract_declarator
1385                { $$ = $2->addType( $1 ); }
1386        | cfa_abstract_declarator_tuple identifier                      // CFA
1387                { $$ = $1->addName( $2 ); }
1388        | cfa_abstract_declarator_tuple                                         // CFA
1389        ;
1390
1391enable_disable_statement:
1392        enable_disable_key identifier_list compound_statement
1393        ;
1394
1395enable_disable_key:
1396        ENABLE
1397        | DISABLE
1398        ;
1399
1400asm_statement:
1401        ASM asm_volatile_opt '(' string_literal ')' ';'
1402                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1403        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1404                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1405        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1406                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1407        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1408                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1409        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1410                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1411        ;
1412
1413asm_volatile_opt:                                                                               // GCC
1414        // empty
1415                { $$ = false; }
1416        | VOLATILE
1417                { $$ = true; }
1418        ;
1419
1420asm_operands_opt:                                                                               // GCC
1421        // empty
1422                { $$ = nullptr; }                                                               // use default argument
1423        | asm_operands_list
1424        ;
1425
1426asm_operands_list:                                                                              // GCC
1427        asm_operand
1428        | asm_operands_list ',' asm_operand
1429                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1430        ;
1431
1432asm_operand:                                                                                    // GCC
1433        string_literal '(' constant_expression ')'
1434                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1435        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1436                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1437        ;
1438
1439asm_clobbers_list_opt:                                                                  // GCC
1440        // empty
1441                { $$ = nullptr; }                                                               // use default argument
1442        | string_literal
1443                { $$ = new ExpressionNode( $1 ); }
1444        | asm_clobbers_list_opt ',' string_literal
1445                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1446        ;
1447
1448label_list:
1449        identifier
1450                {
1451                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1452                        delete $1;                                                                      // allocated by lexer
1453                }
1454        | label_list ',' identifier
1455                {
1456                        $$ = $1; $1->labels.push_back( *$3 );
1457                        delete $3;                                                                      // allocated by lexer
1458                }
1459        ;
1460
1461//******************************* DECLARATIONS *********************************
1462
1463declaration_list_opt:                                                                   // used at beginning of switch statement
1464        // empty
1465                { $$ = nullptr; }
1466        | declaration_list
1467        ;
1468
1469declaration_list:
1470        declaration
1471        | declaration_list declaration
1472                { $$ = $1->appendList( $2 ); }
1473        ;
1474
1475KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1476        // empty
1477                { $$ = nullptr; }
1478        | KR_parameter_list
1479        ;
1480
1481KR_parameter_list:
1482        push c_declaration pop ';'
1483                { $$ = $2; }
1484        | KR_parameter_list push c_declaration pop ';'
1485                { $$ = $1->appendList( $3 ); }
1486        ;
1487
1488local_label_declaration_opt:                                                    // GCC, local label
1489        // empty
1490        | local_label_declaration_list
1491        ;
1492
1493local_label_declaration_list:                                                   // GCC, local label
1494        LABEL local_label_list ';'
1495        | local_label_declaration_list LABEL local_label_list ';'
1496        ;
1497
1498local_label_list:                                                                               // GCC, local label
1499        identifier_or_type_name
1500        | local_label_list ',' identifier_or_type_name
1501        ;
1502
1503declaration:                                                                                    // old & new style declarations
1504        c_declaration ';'
1505        | cfa_declaration ';'                                                           // CFA
1506        | static_assert                                                                         // C11
1507        ;
1508
1509static_assert:
1510        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1511                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1512        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1513                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1514
1515// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1516// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1517// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1518// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1519// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1520// block, but cannot be mixed within a specific declaration.
1521//
1522//                      CFA                                     C
1523//              [10] int x;                     int x[10];              // array of 10 integers
1524//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1525
1526cfa_declaration:                                                                                // CFA
1527        cfa_variable_declaration
1528        | cfa_typedef_declaration
1529        | cfa_function_declaration
1530        | type_declaring_list
1531        | trait_specifier
1532        ;
1533
1534cfa_variable_declaration:                                                               // CFA
1535        cfa_variable_specifier initializer_opt
1536                { $$ = $1->addInitializer( $2 ); }
1537        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1538                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1539                // them as a type_qualifier cannot appear in that context.
1540                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1541        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1542                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1543        ;
1544
1545cfa_variable_specifier:                                                                 // CFA
1546                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1547                // storage-class
1548        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1549                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1550        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1551                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1552        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1553                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1554        ;
1555
1556cfa_function_declaration:                                                               // CFA
1557        cfa_function_specifier
1558        | type_qualifier_list cfa_function_specifier
1559                { $$ = $2->addQualifiers( $1 ); }
1560        | declaration_qualifier_list cfa_function_specifier
1561                { $$ = $2->addQualifiers( $1 ); }
1562        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1563                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1564        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1565                {
1566                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1567                        DeclarationNode * ret = new DeclarationNode;
1568                        ret->type = maybeClone( $1->type->base );
1569                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1570                }
1571        ;
1572
1573cfa_function_specifier:                                                                 // CFA
1574//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1575//              {
1576//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1577//              }
1578//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1579//              {
1580//                      typedefTable.setNextIdentifier( *$5 );
1581//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1582//              }
1583//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1584//              {
1585//                      typedefTable.setNextIdentifier( *$5 );
1586//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1587//              }
1588//      | '[' ']' typegen_name
1589                // identifier_or_type_name must be broken apart because of the sequence:
1590                //
1591                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1592                //   '[' ']' type_specifier
1593                //
1594                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1595                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1596        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1597                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1598                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1599        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1600                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1601        ;
1602
1603cfa_function_return:                                                                    // CFA
1604        '[' push cfa_parameter_list pop ']'
1605                { $$ = DeclarationNode::newTuple( $3 ); }
1606        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1607                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1608                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1609        ;
1610
1611cfa_typedef_declaration:                                                                // CFA
1612        TYPEDEF cfa_variable_specifier
1613                {
1614                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1615                        $$ = $2->addTypedef();
1616                }
1617        | TYPEDEF cfa_function_specifier
1618                {
1619                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1620                        $$ = $2->addTypedef();
1621                }
1622        | cfa_typedef_declaration pop ',' push identifier
1623                {
1624                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1625                        $$ = $1->appendList( $1->cloneType( $5 ) );
1626                }
1627        ;
1628
1629// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1630// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1631
1632typedef_declaration:
1633        TYPEDEF type_specifier declarator
1634                {
1635                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1636                        $$ = $3->addType( $2 )->addTypedef();
1637                }
1638        | typedef_declaration pop ',' push declarator
1639                {
1640                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1641                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1642                }
1643        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1644                {
1645                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1646                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1647                }
1648        | type_specifier TYPEDEF declarator
1649                {
1650                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1651                        $$ = $3->addType( $1 )->addTypedef();
1652                }
1653        | type_specifier TYPEDEF type_qualifier_list declarator
1654                {
1655                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1656                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1657                }
1658        ;
1659
1660typedef_expression:
1661                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1662        TYPEDEF identifier '=' assignment_expression
1663                {
1664                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1665                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1666                }
1667        | typedef_expression pop ',' push identifier '=' assignment_expression
1668                {
1669                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1670                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1671                }
1672        ;
1673
1674//c_declaration:
1675//      declaring_list pop ';'
1676//      | typedef_declaration pop ';'
1677//      | typedef_expression pop ';'                                            // GCC, naming expression type
1678//      | sue_declaration_specifier pop ';'
1679//      ;
1680//
1681//declaring_list:
1682//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1683//              // storage-class
1684//       declarator asm_name_opt initializer_opt
1685//              {
1686//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1687//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1688//              }
1689//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1690//              {
1691//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1692//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1693//              }
1694//      ;
1695
1696c_declaration:
1697        declaration_specifier declaring_list
1698                { $$ = distAttr( $1, $2 ); }
1699        | typedef_declaration
1700        | typedef_expression                                                            // GCC, naming expression type
1701        | sue_declaration_specifier
1702        ;
1703
1704declaring_list:
1705                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1706                // storage-class
1707        declarator asm_name_opt initializer_opt
1708                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1709        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1710                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1711        ;
1712
1713declaration_specifier:                                                                  // type specifier + storage class
1714        basic_declaration_specifier
1715        | sue_declaration_specifier
1716        | type_declaration_specifier
1717        ;
1718
1719declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1720                // Preclude SUE declarations in restricted scopes:
1721                //
1722                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1723                //
1724                // because it is impossible to call f due to name equivalence.
1725        basic_declaration_specifier
1726        | sue_declaration_specifier_nobody
1727        | type_declaration_specifier
1728        ;
1729
1730type_specifier:                                                                                 // type specifier
1731        basic_type_specifier
1732        | sue_type_specifier
1733        | type_type_specifier
1734        ;
1735
1736type_specifier_nobody:                                                                  // type specifier - {...}
1737                // Preclude SUE declarations in restricted scopes:
1738                //
1739                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1740                //
1741                // because it is impossible to call f due to name equivalence.
1742        basic_type_specifier
1743        | sue_type_specifier_nobody
1744        | type_type_specifier
1745        ;
1746
1747type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1748        // empty
1749                { $$ = nullptr; }
1750        | type_qualifier_list
1751        ;
1752
1753type_qualifier_list:
1754                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1755                //
1756                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1757                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1758                // appeared only once.
1759        type_qualifier
1760        | type_qualifier_list type_qualifier
1761                { $$ = $1->addQualifiers( $2 ); }
1762        ;
1763
1764type_qualifier:
1765        type_qualifier_name
1766        | attribute
1767        ;
1768
1769type_qualifier_name:
1770        CONST
1771                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1772        | RESTRICT
1773                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1774        | VOLATILE
1775                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1776        | ATOMIC
1777                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1778        | forall
1779        ;
1780
1781forall:
1782        FORALL '(' type_parameter_list ')'                                      // CFA
1783                { $$ = DeclarationNode::newForall( $3 ); }
1784        ;
1785
1786declaration_qualifier_list:
1787        storage_class_list
1788        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1789                { $$ = $1->addQualifiers( $2 ); }
1790        | declaration_qualifier_list type_qualifier_list storage_class_list
1791                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1792        ;
1793
1794storage_class_list:
1795                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1796                // only one of each is specified, except for inline, which can appear with the others.
1797                //
1798                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1799                // specifiers in a declaration.
1800        storage_class
1801        | storage_class_list storage_class
1802                { $$ = $1->addQualifiers( $2 ); }
1803        ;
1804
1805storage_class:
1806        EXTERN
1807                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1808        | STATIC
1809                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1810        | AUTO
1811                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1812        | REGISTER
1813                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1814        | THREADLOCAL                                                                           // C11
1815                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1816                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1817        | INLINE                                                                                        // C99
1818                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1819        | FORTRAN                                                                                       // C99
1820                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1821        | NORETURN                                                                                      // C11
1822                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1823        ;
1824
1825basic_type_name:
1826        VOID
1827                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1828        | BOOL                                                                                          // C99
1829                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1830        | CHAR
1831                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1832        | INT
1833                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1834        | INT128
1835                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1836        | UINT128
1837                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1838        | FLOAT
1839                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1840        | DOUBLE
1841                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1842        | uuFLOAT80
1843                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1844        | uuFLOAT128
1845                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1846        | uFLOAT16
1847                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1848        | uFLOAT32
1849                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1850        | uFLOAT32X
1851                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1852        | uFLOAT64
1853                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1854        | uFLOAT64X
1855                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1856        | uFLOAT128
1857                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1858        | COMPLEX                                                                                       // C99
1859                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1860        | IMAGINARY                                                                                     // C99
1861                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1862        | SIGNED
1863                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1864        | UNSIGNED
1865                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1866        | SHORT
1867                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1868        | LONG
1869                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1870        | VALIST                                                                                        // GCC, __builtin_va_list
1871                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1872        | AUTO_TYPE
1873                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1874        ;
1875
1876basic_declaration_specifier:
1877                // A semantic check is necessary for conflicting storage classes.
1878        basic_type_specifier
1879        | declaration_qualifier_list basic_type_specifier
1880                { $$ = $2->addQualifiers( $1 ); }
1881        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1882                { $$ = $1->addQualifiers( $2 ); }
1883        | basic_declaration_specifier storage_class type_qualifier_list
1884                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1885        | basic_declaration_specifier storage_class basic_type_specifier
1886                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1887        ;
1888
1889basic_type_specifier:
1890        direct_type
1891                // Cannot have type modifiers, e.g., short, long, etc.
1892        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1893                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1894        ;
1895
1896direct_type:
1897        basic_type_name
1898        | type_qualifier_list basic_type_name
1899                { $$ = $2->addQualifiers( $1 ); }
1900        | direct_type type_qualifier
1901                { $$ = $1->addQualifiers( $2 ); }
1902        | direct_type basic_type_name
1903                { $$ = $1->addType( $2 ); }
1904        ;
1905
1906indirect_type:
1907        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1908                { $$ = $3; }
1909        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1910                { $$ = DeclarationNode::newTypeof( $3 ); }
1911        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1912                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1913        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1914                { $$ = DeclarationNode::newTypeof( $3, true ); }
1915        | ZERO_T                                                                                        // CFA
1916                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1917        | ONE_T                                                                                         // CFA
1918                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1919        ;
1920
1921sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1922        sue_type_specifier
1923        | declaration_qualifier_list sue_type_specifier
1924                { $$ = $2->addQualifiers( $1 ); }
1925        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1926                { $$ = $1->addQualifiers( $2 ); }
1927        | sue_declaration_specifier storage_class type_qualifier_list
1928                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1929        ;
1930
1931sue_type_specifier:                                                                             // struct, union, enum + type specifier
1932        elaborated_type
1933        | type_qualifier_list
1934                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1935          elaborated_type
1936                { $$ = $3->addQualifiers( $1 ); }
1937        | sue_type_specifier type_qualifier
1938                {
1939                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1940                        $$ = $1->addQualifiers( $2 );
1941                }
1942        ;
1943
1944sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1945        sue_type_specifier_nobody
1946        | declaration_qualifier_list sue_type_specifier_nobody
1947                { $$ = $2->addQualifiers( $1 ); }
1948        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1949                { $$ = $1->addQualifiers( $2 ); }
1950        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1951                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1952        ;
1953
1954sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1955        elaborated_type_nobody
1956        | type_qualifier_list elaborated_type_nobody
1957                { $$ = $2->addQualifiers( $1 ); }
1958        | sue_type_specifier_nobody type_qualifier
1959                { $$ = $1->addQualifiers( $2 ); }
1960        ;
1961
1962type_declaration_specifier:
1963        type_type_specifier
1964        | declaration_qualifier_list type_type_specifier
1965                { $$ = $2->addQualifiers( $1 ); }
1966        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1967                { $$ = $1->addQualifiers( $2 ); }
1968        | type_declaration_specifier storage_class type_qualifier_list
1969                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1970        ;
1971
1972type_type_specifier:                                                                    // typedef types
1973        type_name
1974        | type_qualifier_list type_name
1975                { $$ = $2->addQualifiers( $1 ); }
1976        | type_type_specifier type_qualifier
1977                { $$ = $1->addQualifiers( $2 ); }
1978        ;
1979
1980type_name:
1981        TYPEDEFname
1982                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1983        | '.' TYPEDEFname
1984                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1985        | type_name '.' TYPEDEFname
1986                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1987        | typegen_name
1988        | '.' typegen_name
1989                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1990        | type_name '.' typegen_name
1991                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1992        ;
1993
1994typegen_name:                                                                                   // CFA
1995        TYPEGENname
1996                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1997        | TYPEGENname '(' ')'
1998                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1999        | TYPEGENname '(' type_list ')'
2000                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2001        ;
2002
2003elaborated_type:                                                                                // struct, union, enum
2004        aggregate_type
2005        | enum_type
2006        ;
2007
2008elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2009        aggregate_type_nobody
2010        | enum_type_nobody
2011        ;
2012
2013fred:
2014        // empty
2015                { yyy = false; }
2016        ;
2017
2018aggregate_type:                                                                                 // struct, union
2019        aggregate_key attribute_list_opt
2020                { forall = false; }                                                             // reset
2021          '{' field_declaration_list_opt '}' type_parameters_opt
2022                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2023        | aggregate_key attribute_list_opt identifier fred
2024                {
2025                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2026                        forall = false;                                                         // reset
2027                }
2028          '{' field_declaration_list_opt '}' type_parameters_opt
2029                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2030        | aggregate_key attribute_list_opt type_name fred
2031                {
2032                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2033                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2034                        forall = false;                                                         // reset
2035                }
2036          '{' field_declaration_list_opt '}' type_parameters_opt
2037                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2038        | aggregate_type_nobody
2039        ;
2040
2041type_parameters_opt:
2042        // empty
2043                { $$ = nullptr; }                                                               %prec '}'
2044        | '(' type_list ')'
2045                { $$ = $2; }
2046        ;
2047
2048aggregate_type_nobody:                                                                  // struct, union - {...}
2049        aggregate_key attribute_list_opt identifier fred
2050                {
2051                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2052                        forall = false;                                                         // reset
2053                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2054                }
2055        | aggregate_key attribute_list_opt type_name fred
2056                {
2057                        forall = false;                                                         // reset
2058                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2059                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2060                        // delete newFromTypeGen.
2061                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2062                        $3->type->symbolic.name = nullptr;
2063                        $3->type->symbolic.actuals = nullptr;
2064                        delete $3;
2065                }
2066        ;
2067
2068aggregate_key:
2069        aggregate_data
2070        | aggregate_control
2071        ;
2072
2073aggregate_data:
2074        STRUCT
2075                { yyy = true; $$ = AggregateDecl::Struct; }
2076        | UNION
2077                { yyy = true; $$ = AggregateDecl::Union; }
2078        | EXCEPTION                                                                                     // CFA
2079                { yyy = true; $$ = AggregateDecl::Exception; }
2080        ;
2081
2082aggregate_control:                                                                              // CFA
2083        GENERATOR
2084                { yyy = true; $$ = AggregateDecl::Coroutine; }
2085        | COROUTINE
2086                { yyy = true; $$ = AggregateDecl::Coroutine; }
2087        | MONITOR
2088                { yyy = true; $$ = AggregateDecl::Monitor; }
2089        | THREAD
2090                { yyy = true; $$ = AggregateDecl::Thread; }
2091        ;
2092
2093field_declaration_list_opt:
2094        // empty
2095                { $$ = nullptr; }
2096        | field_declaration_list_opt field_declaration
2097                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2098        ;
2099
2100field_declaration:
2101        type_specifier field_declaring_list_opt ';'
2102                { $$ = fieldDecl( $1, $2 ); }
2103        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2104                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2105        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2106                {
2107                        if ( ! $3 ) {                                                           // field declarator ?
2108                                $3 = DeclarationNode::newName( nullptr );
2109                        } // if
2110                        $3->inLine = true;
2111                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2112                        distInl( $3 );
2113                }
2114        | INLINE aggregate_control ';'                                          // CFA
2115                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2116        | typedef_declaration ';'                                                       // CFA
2117        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2118        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2119                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2120        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2121                { $$ = $2; }                                                                    // mark all fields in list
2122        | cfa_typedef_declaration ';'                                           // CFA
2123        | static_assert                                                                         // C11
2124        ;
2125
2126field_declaring_list_opt:
2127        // empty
2128                { $$ = nullptr; }
2129        | field_declarator
2130        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2131                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2132        ;
2133
2134field_declarator:
2135        bit_subrange_size                                                                       // C special case, no field name
2136                { $$ = DeclarationNode::newBitfield( $1 ); }
2137        | variable_declarator bit_subrange_size_opt
2138                // A semantic check is required to ensure bit_subrange only appears on integral types.
2139                { $$ = $1->addBitfield( $2 ); }
2140        | variable_type_redeclarator bit_subrange_size_opt
2141                // A semantic check is required to ensure bit_subrange only appears on integral types.
2142                { $$ = $1->addBitfield( $2 ); }
2143        ;
2144
2145field_abstract_list_opt:
2146        // empty
2147                { $$ = nullptr; }
2148        | field_abstract
2149        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2150                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2151        ;
2152
2153field_abstract:
2154                //      no bit fields
2155        variable_abstract_declarator
2156        ;
2157
2158cfa_field_declaring_list:                                                               // CFA, new style field declaration
2159        // bit-fields are handled by C declarations
2160        cfa_abstract_declarator_tuple identifier_or_type_name
2161                { $$ = $1->addName( $2 ); }
2162        | cfa_field_declaring_list ',' identifier_or_type_name
2163                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2164        ;
2165
2166cfa_field_abstract_list:                                                                // CFA, new style field declaration
2167        // bit-fields are handled by C declarations
2168        cfa_abstract_declarator_tuple
2169        | cfa_field_abstract_list ','
2170                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2171        ;
2172
2173bit_subrange_size_opt:
2174        // empty
2175                { $$ = nullptr; }
2176        | bit_subrange_size
2177        ;
2178
2179bit_subrange_size:
2180        ':' assignment_expression
2181                { $$ = $2; }
2182        ;
2183
2184enum_type:                                                                                              // enum
2185        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2186                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2187        | ENUM attribute_list_opt identifier
2188                { typedefTable.makeTypedef( *$3 ); }
2189          '{' enumerator_list comma_opt '}'
2190                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2191        | ENUM attribute_list_opt type_name
2192          '{' enumerator_list comma_opt '}'
2193                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2194        | enum_type_nobody
2195        ;
2196
2197enum_type_nobody:                                                                               // enum - {...}
2198        ENUM attribute_list_opt identifier
2199                {
2200                        typedefTable.makeTypedef( *$3 );
2201                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2202                }
2203        | ENUM attribute_list_opt type_name
2204                {
2205                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2206                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2207                }
2208        ;
2209
2210enumerator_list:
2211        identifier_or_type_name enumerator_value_opt
2212                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2213        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2214                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2215        ;
2216
2217enumerator_value_opt:
2218        // empty
2219                { $$ = nullptr; }
2220        | '=' constant_expression
2221                { $$ = $2; }
2222        ;
2223
2224cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2225        // empty
2226                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2227        | ELLIPSIS
2228                { $$ = nullptr; }
2229        | cfa_abstract_parameter_list
2230        | cfa_parameter_list
2231        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2232                { $$ = $1->appendList( $5 ); }
2233        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2234                { $$ = $1->addVarArgs(); }
2235        | cfa_parameter_list pop ',' push ELLIPSIS
2236                { $$ = $1->addVarArgs(); }
2237        ;
2238
2239cfa_parameter_list:                                                                             // CFA
2240                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2241                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2242        cfa_parameter_declaration
2243        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2244                { $$ = $1->appendList( $5 ); }
2245        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2246                { $$ = $1->appendList( $5 ); }
2247        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2248                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2249        ;
2250
2251cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2252        cfa_abstract_parameter_declaration
2253        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2254                { $$ = $1->appendList( $5 ); }
2255        ;
2256
2257parameter_type_list_opt:
2258        // empty
2259                { $$ = nullptr; }
2260        | ELLIPSIS
2261                { $$ = nullptr; }
2262        | parameter_list
2263        | parameter_list pop ',' push ELLIPSIS
2264                { $$ = $1->addVarArgs(); }
2265        ;
2266
2267parameter_list:                                                                                 // abstract + real
2268        abstract_parameter_declaration
2269        | parameter_declaration
2270        | parameter_list pop ',' push abstract_parameter_declaration
2271                { $$ = $1->appendList( $5 ); }
2272        | parameter_list pop ',' push parameter_declaration
2273                { $$ = $1->appendList( $5 ); }
2274        ;
2275
2276// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2277// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2278
2279cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2280        parameter_declaration
2281        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2282                { $$ = $1->addName( $2 ); }
2283        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2284                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2285                { $$ = $1->addName( $2 ); }
2286        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2287                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2288        | cfa_function_specifier
2289        ;
2290
2291cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2292        abstract_parameter_declaration
2293        | cfa_identifier_parameter_declarator_no_tuple
2294        | cfa_abstract_tuple
2295                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2296        | type_qualifier_list cfa_abstract_tuple
2297                { $$ = $2->addQualifiers( $1 ); }
2298        | cfa_abstract_function
2299        ;
2300
2301parameter_declaration:
2302                // No SUE declaration in parameter list.
2303        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2304                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2305        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2306                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2307        ;
2308
2309abstract_parameter_declaration:
2310        declaration_specifier_nobody default_initialize_opt
2311                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2312        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2313                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2314        ;
2315
2316// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2317// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2318// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2319
2320identifier_list:                                                                                // K&R-style parameter list => no types
2321        identifier
2322                { $$ = DeclarationNode::newName( $1 ); }
2323        | identifier_list ',' identifier
2324                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2325        ;
2326
2327identifier_or_type_name:
2328        identifier
2329        | TYPEDEFname
2330        | TYPEGENname
2331        ;
2332
2333type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2334        cfa_abstract_declarator_tuple                                           // CFA
2335        | type_specifier
2336        | type_specifier abstract_declarator
2337                { $$ = $2->addType( $1 ); }
2338        ;
2339
2340type:                                                                                                   // typeof, assertion
2341        type_no_function
2342        | cfa_abstract_function                                                         // CFA
2343        ;
2344
2345initializer_opt:
2346        // empty
2347                { $$ = nullptr; }
2348        | '=' initializer
2349                { $$ = $2; }
2350        | '=' VOID
2351                { $$ = new InitializerNode( true ); }
2352        | ATassign initializer
2353                { $$ = $2->set_maybeConstructed( false ); }
2354        ;
2355
2356initializer:
2357        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2358        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2359        ;
2360
2361initializer_list_opt:
2362        // empty
2363                { $$ = nullptr; }
2364        | initializer
2365        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2366        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2367        | initializer_list_opt ',' designation initializer
2368                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2369        ;
2370
2371// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2372// '=' to separator the designator from the initializer value, as in:
2373//
2374//              int x[10] = { [1] = 3 };
2375//
2376// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2377// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2378// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2379// shift/reduce conflicts
2380
2381designation:
2382        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2383        | identifier ':'                                                                        // GCC, field name
2384                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2385        ;
2386
2387designator_list:                                                                                // C99
2388        designator
2389        | designator_list designator
2390                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2391        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2392        ;
2393
2394designator:
2395        '.' identifier                                                                          // C99, field name
2396                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2397        | '[' push assignment_expression pop ']'                        // C99, single array element
2398                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2399                { $$ = $3; }
2400        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2401                { $$ = $3; }
2402        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2403                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2404        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2405                { $$ = $4; }
2406        ;
2407
2408// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2409// rather than an object-oriented type system. This required four groups of extensions:
2410//
2411// Overloading: function, data, and operator identifiers may be overloaded.
2412//
2413// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2414//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2415//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2416//
2417// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2418//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2419//
2420// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2421//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2422//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2423//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2424//     on type arguments of polymorphic functions.
2425
2426type_parameter_list:                                                                    // CFA
2427        type_parameter
2428        | type_parameter_list ',' type_parameter
2429                { $$ = $1->appendList( $3 ); }
2430        ;
2431
2432type_initializer_opt:                                                                   // CFA
2433        // empty
2434                { $$ = nullptr; }
2435        | '=' type
2436                { $$ = $2; }
2437        ;
2438
2439type_parameter:                                                                                 // CFA
2440        type_class identifier_or_type_name
2441                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2442          type_initializer_opt assertion_list_opt
2443                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2444        | type_specifier identifier_parameter_declarator
2445        | assertion_list
2446                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2447        ;
2448
2449type_class:                                                                                             // CFA
2450        OTYPE
2451                { $$ = TypeDecl::Otype; }
2452        | DTYPE
2453                { $$ = TypeDecl::Dtype; }
2454        | FTYPE
2455                { $$ = TypeDecl::Ftype; }
2456        | TTYPE
2457                { $$ = TypeDecl::Ttype; }
2458        ;
2459
2460assertion_list_opt:                                                                             // CFA
2461        // empty
2462                { $$ = nullptr; }
2463        | assertion_list
2464        ;
2465
2466assertion_list:                                                                                 // CFA
2467        assertion
2468        | assertion_list assertion
2469                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2470        ;
2471
2472assertion:                                                                                              // CFA
2473        '|' identifier_or_type_name '(' type_list ')'
2474                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2475        | '|' '{' push trait_declaration_list pop '}'
2476                { $$ = $4; }
2477        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2478        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2479        ;
2480
2481type_list:                                                                                              // CFA
2482        type
2483                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2484        | assignment_expression
2485                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2486        | type_list ',' type
2487                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2488        | type_list ',' assignment_expression
2489                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2490                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2491        ;
2492
2493type_declaring_list:                                                                    // CFA
2494        OTYPE type_declarator
2495                { $$ = $2; }
2496        | storage_class_list OTYPE type_declarator
2497                { $$ = $3->addQualifiers( $1 ); }
2498        | type_declaring_list ',' type_declarator
2499                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2500        ;
2501
2502type_declarator:                                                                                // CFA
2503        type_declarator_name assertion_list_opt
2504                { $$ = $1->addAssertions( $2 ); }
2505        | type_declarator_name assertion_list_opt '=' type
2506                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2507        ;
2508
2509type_declarator_name:                                                                   // CFA
2510        identifier_or_type_name
2511                {
2512                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2513                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2514                }
2515        | identifier_or_type_name '(' type_parameter_list ')'
2516                {
2517                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2518                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2519                }
2520        ;
2521
2522trait_specifier:                                                                                // CFA
2523        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2524                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2525        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2526                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2527        ;
2528
2529trait_declaration_list:                                                                 // CFA
2530        trait_declaration
2531        | trait_declaration_list pop push trait_declaration
2532                { $$ = $1->appendList( $4 ); }
2533        ;
2534
2535trait_declaration:                                                                              // CFA
2536        cfa_trait_declaring_list ';'
2537        | trait_declaring_list ';'
2538        ;
2539
2540cfa_trait_declaring_list:                                                               // CFA
2541        cfa_variable_specifier
2542        | cfa_function_specifier
2543        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2544                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2545        ;
2546
2547trait_declaring_list:                                                                   // CFA
2548        type_specifier declarator
2549                { $$ = $2->addType( $1 ); }
2550        | trait_declaring_list pop ',' push declarator
2551                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2552        ;
2553
2554//***************************** EXTERNAL DEFINITIONS *****************************
2555
2556translation_unit:
2557        // empty, input file
2558        | external_definition_list
2559                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2560        ;
2561
2562external_definition_list:
2563        push external_definition pop
2564                { $$ = $2; }
2565        | external_definition_list push external_definition pop
2566                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2567        ;
2568
2569external_definition_list_opt:
2570        // empty
2571                { $$ = nullptr; }
2572        | external_definition_list
2573        ;
2574
2575up:
2576                { typedefTable.up( forall ); forall = false; }
2577        ;
2578
2579down:
2580                { typedefTable.down(); }
2581        ;
2582
2583external_definition:
2584        declaration
2585        | external_function_definition
2586        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2587                {
2588                        distExt( $2 );                                                          // mark all fields in list
2589                        $$ = $2;
2590                }
2591        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2592                {
2593                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2594                }
2595        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2596                {
2597                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2598                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2599                }
2600          '{' up external_definition_list_opt down '}'
2601                {
2602                        linkage = linkageStack.top();
2603                        linkageStack.pop();
2604                        $$ = $6;
2605                }
2606        | type_qualifier_list
2607                {
2608                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2609                        if ( $1->type->forall ) forall = true;          // remember generic type
2610                }
2611          '{' up external_definition_list_opt down '}'          // CFA, namespace
2612                {
2613                        distQual( $5, $1 );
2614                        forall = false;
2615                        $$ = $5;
2616                }
2617        | declaration_qualifier_list
2618                {
2619                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2620                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2621                }
2622          '{' up external_definition_list_opt down '}'          // CFA, namespace
2623                {
2624                        distQual( $5, $1 );
2625                        forall = false;
2626                        $$ = $5;
2627                }
2628        | declaration_qualifier_list type_qualifier_list
2629                {
2630                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2631                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2632                }
2633          '{' up external_definition_list_opt down '}'          // CFA, namespace
2634                {
2635                        distQual( $6, $1->addQualifiers( $2 ) );
2636                        forall = false;
2637                        $$ = $6;
2638                }
2639        ;
2640
2641external_function_definition:
2642        function_definition
2643                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2644                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2645                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2646                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2647                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2648        | function_declarator compound_statement
2649                { $$ = $1->addFunctionBody( $2 ); }
2650        | KR_function_declarator KR_parameter_list_opt compound_statement
2651                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2652        ;
2653
2654with_clause_opt:
2655        // empty
2656                { $$ = nullptr; forall = false; }
2657        | WITH '(' tuple_expression_list ')'
2658                { $$ = $3; forall = false; }
2659        ;
2660
2661function_definition:
2662        cfa_function_declaration with_clause_opt compound_statement     // CFA
2663                {
2664                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2665                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2666                        $1->get_last()->addFunctionBody( $3, $2 );
2667                        $$ = $1;
2668                }
2669        | declaration_specifier function_declarator with_clause_opt compound_statement
2670                {
2671                        rebindForall( $1, $2 );
2672                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2673                }
2674        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2675                {
2676                        rebindForall( $1, $2 );
2677                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2678                }
2679                // handles default int return type, OBSOLESCENT (see 1)
2680        | type_qualifier_list function_declarator with_clause_opt compound_statement
2681                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2682                // handles default int return type, OBSOLESCENT (see 1)
2683        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2684                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2685                // handles default int return type, OBSOLESCENT (see 1)
2686        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2687                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2688
2689                // Old-style K&R function definition, OBSOLESCENT (see 4)
2690        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2691                {
2692                        rebindForall( $1, $2 );
2693                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2694                }
2695                // handles default int return type, OBSOLESCENT (see 1)
2696        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2697                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2698                // handles default int return type, OBSOLESCENT (see 1)
2699        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2700                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2701                // handles default int return type, OBSOLESCENT (see 1)
2702        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2703                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2704        ;
2705
2706declarator:
2707        variable_declarator
2708        | variable_type_redeclarator
2709        | function_declarator
2710        ;
2711
2712subrange:
2713        constant_expression '~' constant_expression                     // CFA, integer subrange
2714                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2715        ;
2716
2717asm_name_opt:                                                                                   // GCC
2718        // empty
2719                { $$ = nullptr; }
2720        | ASM '(' string_literal ')' attribute_list_opt
2721                {
2722                        DeclarationNode * name = new DeclarationNode();
2723                        name->asmName = $3;
2724                        $$ = name->addQualifiers( $5 );
2725                }
2726        ;
2727
2728attribute_list_opt:                                                                             // GCC
2729        // empty
2730                { $$ = nullptr; }
2731        | attribute_list
2732        ;
2733
2734attribute_list:                                                                                 // GCC
2735        attribute
2736        | attribute_list attribute
2737                { $$ = $2->addQualifiers( $1 ); }
2738        ;
2739
2740attribute:                                                                                              // GCC
2741        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2742                { $$ = $4; }
2743        ;
2744
2745attribute_name_list:                                                                    // GCC
2746        attribute_name
2747        | attribute_name_list ',' attribute_name
2748                { $$ = $3->addQualifiers( $1 ); }
2749        ;
2750
2751attribute_name:                                                                                 // GCC
2752        // empty
2753                { $$ = nullptr; }
2754        | attr_name
2755                { $$ = DeclarationNode::newAttribute( $1 ); }
2756        | attr_name '(' argument_expression_list ')'
2757                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2758        ;
2759
2760attr_name:                                                                                              // GCC
2761        IDENTIFIER
2762        | quasi_keyword
2763        | TYPEDEFname
2764        | TYPEGENname
2765        | FALLTHROUGH
2766                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2767        | CONST
2768                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2769        ;
2770
2771// ============================================================================
2772// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2773// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2774// in:
2775//
2776//              int (*f())[10] { ... };
2777//              ... (*f())[3] += 1;             // definition mimics usage
2778//
2779// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2780// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2781// ============================================================================
2782
2783// ----------------------------------------------------------------------------
2784// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2785// to define a variable or function prototype, e.g.:
2786//
2787//              valid declaration               invalid definition
2788//              -----------------               ------------------
2789//              int f;                                  int f {}
2790//              int *f;                                 int *f {}
2791//              int f[10];                              int f[10] {}
2792//              int (*f)(int);                  int (*f)(int) {}
2793//
2794// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2795// variable_declarator and function_declarator.
2796// ----------------------------------------------------------------------------
2797
2798// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2799// declaring an array of functions versus a pointer to an array of functions.
2800
2801variable_declarator:
2802        paren_identifier attribute_list_opt
2803                { $$ = $1->addQualifiers( $2 ); }
2804        | variable_ptr
2805        | variable_array attribute_list_opt
2806                { $$ = $1->addQualifiers( $2 ); }
2807        | variable_function attribute_list_opt
2808                { $$ = $1->addQualifiers( $2 ); }
2809        ;
2810
2811paren_identifier:
2812        identifier
2813                { $$ = DeclarationNode::newName( $1 ); }
2814        | '(' paren_identifier ')'                                                      // redundant parenthesis
2815                { $$ = $2; }
2816        ;
2817
2818variable_ptr:
2819        ptrref_operator variable_declarator
2820                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2821        | ptrref_operator type_qualifier_list variable_declarator
2822                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2823        | '(' variable_ptr ')' attribute_list_opt
2824                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2825        ;
2826
2827variable_array:
2828        paren_identifier array_dimension
2829                { $$ = $1->addArray( $2 ); }
2830        | '(' variable_ptr ')' array_dimension
2831                { $$ = $2->addArray( $4 ); }
2832        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2833                { $$ = $2->addArray( $4 ); }
2834        | '(' variable_array ')'                                                        // redundant parenthesis
2835                { $$ = $2; }
2836        ;
2837
2838variable_function:
2839        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2840                { $$ = $2->addParamList( $6 ); }
2841        | '(' variable_function ')'                                                     // redundant parenthesis
2842                { $$ = $2; }
2843        ;
2844
2845// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2846// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2847// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2848
2849function_declarator:
2850        function_no_ptr attribute_list_opt
2851                { $$ = $1->addQualifiers( $2 ); }
2852        | function_ptr
2853        | function_array attribute_list_opt
2854                { $$ = $1->addQualifiers( $2 ); }
2855        ;
2856
2857function_no_ptr:
2858        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2859                { $$ = $1->addParamList( $4 ); }
2860        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2861                { $$ = $2->addParamList( $6 ); }
2862        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2863                { $$ = $2; }
2864        ;
2865
2866function_ptr:
2867        ptrref_operator function_declarator
2868                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2869        | ptrref_operator type_qualifier_list function_declarator
2870                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2871        | '(' function_ptr ')'
2872                { $$ = $2; }
2873        ;
2874
2875function_array:
2876        '(' function_ptr ')' array_dimension
2877                { $$ = $2->addArray( $4 ); }
2878        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2879                { $$ = $2->addArray( $4 ); }
2880        | '(' function_array ')'                                                        // redundant parenthesis
2881                { $$ = $2; }
2882        ;
2883
2884// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2885//
2886//   f( a, b, c ) int a, *b, c[]; {}
2887//
2888// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2889// returning arrays and functions versus pointers to arrays and functions.
2890
2891KR_function_declarator:
2892        KR_function_no_ptr
2893        | KR_function_ptr
2894        | KR_function_array
2895        ;
2896
2897KR_function_no_ptr:
2898        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2899                { $$ = $1->addIdList( $3 ); }
2900        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2901                { $$ = $2->addParamList( $6 ); }
2902        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2903                { $$ = $2; }
2904        ;
2905
2906KR_function_ptr:
2907        ptrref_operator KR_function_declarator
2908                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2909        | ptrref_operator type_qualifier_list KR_function_declarator
2910                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2911        | '(' KR_function_ptr ')'
2912                { $$ = $2; }
2913        ;
2914
2915KR_function_array:
2916        '(' KR_function_ptr ')' array_dimension
2917                { $$ = $2->addArray( $4 ); }
2918        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2919                { $$ = $2->addArray( $4 ); }
2920        | '(' KR_function_array ')'                                                     // redundant parenthesis
2921                { $$ = $2; }
2922        ;
2923
2924// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2925//
2926//              typedef int foo;
2927//              {
2928//                 int foo; // redefine typedef name in new scope
2929//              }
2930//
2931// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2932// and functions versus pointers to arrays and functions.
2933
2934variable_type_redeclarator:
2935        paren_type attribute_list_opt
2936                { $$ = $1->addQualifiers( $2 ); }
2937        | type_ptr
2938        | type_array attribute_list_opt
2939                { $$ = $1->addQualifiers( $2 ); }
2940        | type_function attribute_list_opt
2941                { $$ = $1->addQualifiers( $2 ); }
2942        ;
2943
2944paren_type:
2945        typedef
2946                // hide type name in enclosing scope by variable name
2947                {
2948                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2949                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2950                        // } else {
2951                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2952                        // } // if
2953                }
2954        | '(' paren_type ')'
2955                { $$ = $2; }
2956        ;
2957
2958type_ptr:
2959        ptrref_operator variable_type_redeclarator
2960                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2961        | ptrref_operator type_qualifier_list variable_type_redeclarator
2962                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2963        | '(' type_ptr ')' attribute_list_opt
2964                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2965        ;
2966
2967type_array:
2968        paren_type array_dimension
2969                { $$ = $1->addArray( $2 ); }
2970        | '(' type_ptr ')' array_dimension
2971                { $$ = $2->addArray( $4 ); }
2972        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2973                { $$ = $2->addArray( $4 ); }
2974        | '(' type_array ')'                                                            // redundant parenthesis
2975                { $$ = $2; }
2976        ;
2977
2978type_function:
2979        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2980                { $$ = $1->addParamList( $4 ); }
2981        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2982                { $$ = $2->addParamList( $6 ); }
2983        | '(' type_function ')'                                                         // redundant parenthesis
2984                { $$ = $2; }
2985        ;
2986
2987// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2988// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2989// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2990// pointers to arrays and functions.
2991
2992identifier_parameter_declarator:
2993        paren_identifier attribute_list_opt
2994                { $$ = $1->addQualifiers( $2 ); }
2995        | '&' MUTEX paren_identifier attribute_list_opt
2996                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2997        | identifier_parameter_ptr
2998        | identifier_parameter_array attribute_list_opt
2999                { $$ = $1->addQualifiers( $2 ); }
3000        | identifier_parameter_function attribute_list_opt
3001                { $$ = $1->addQualifiers( $2 ); }
3002        ;
3003
3004identifier_parameter_ptr:
3005        ptrref_operator identifier_parameter_declarator
3006                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3007        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3008                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3009        | '(' identifier_parameter_ptr ')' attribute_list_opt
3010                { $$ = $2->addQualifiers( $4 ); }
3011        ;
3012
3013identifier_parameter_array:
3014        paren_identifier array_parameter_dimension
3015                { $$ = $1->addArray( $2 ); }
3016        | '(' identifier_parameter_ptr ')' array_dimension
3017                { $$ = $2->addArray( $4 ); }
3018        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3019                { $$ = $2->addArray( $4 ); }
3020        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3021                { $$ = $2; }
3022        ;
3023
3024identifier_parameter_function:
3025        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3026                { $$ = $1->addParamList( $4 ); }
3027        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3028                { $$ = $2->addParamList( $6 ); }
3029        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3030                { $$ = $2; }
3031        ;
3032
3033// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3034// e.g.:
3035//
3036//              typedef int foo;
3037//              forall( otype T ) struct foo;
3038//              int f( int foo ); // redefine typedef name in new scope
3039//
3040// and allows the C99 array options, which can only appear in a parameter list.
3041
3042type_parameter_redeclarator:
3043        typedef attribute_list_opt
3044                { $$ = $1->addQualifiers( $2 ); }
3045        | '&' MUTEX typedef attribute_list_opt
3046                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3047        | type_parameter_ptr
3048        | type_parameter_array attribute_list_opt
3049                { $$ = $1->addQualifiers( $2 ); }
3050        | type_parameter_function attribute_list_opt
3051                { $$ = $1->addQualifiers( $2 ); }
3052        ;
3053
3054typedef:
3055        TYPEDEFname
3056                { $$ = DeclarationNode::newName( $1 ); }
3057        | TYPEGENname
3058                { $$ = DeclarationNode::newName( $1 ); }
3059        ;
3060
3061type_parameter_ptr:
3062        ptrref_operator type_parameter_redeclarator
3063                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3064        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3065                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3066        | '(' type_parameter_ptr ')' attribute_list_opt
3067                { $$ = $2->addQualifiers( $4 ); }
3068        ;
3069
3070type_parameter_array:
3071        typedef array_parameter_dimension
3072                { $$ = $1->addArray( $2 ); }
3073        | '(' type_parameter_ptr ')' array_parameter_dimension
3074                { $$ = $2->addArray( $4 ); }
3075        ;
3076
3077type_parameter_function:
3078        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3079                { $$ = $1->addParamList( $4 ); }
3080        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3081                { $$ = $2->addParamList( $6 ); }
3082        ;
3083
3084// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3085// which the type applies, e.g.:
3086//
3087//              sizeof( int );
3088//              sizeof( int * );
3089//              sizeof( int [10] );
3090//              sizeof( int (*)() );
3091//              sizeof( int () );
3092//
3093// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3094// and functions versus pointers to arrays and functions.
3095
3096abstract_declarator:
3097        abstract_ptr
3098        | abstract_array attribute_list_opt
3099                { $$ = $1->addQualifiers( $2 ); }
3100        | abstract_function attribute_list_opt
3101                { $$ = $1->addQualifiers( $2 ); }
3102        ;
3103
3104abstract_ptr:
3105        ptrref_operator
3106                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3107        | ptrref_operator type_qualifier_list
3108                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3109        | ptrref_operator abstract_declarator
3110                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3111        | ptrref_operator type_qualifier_list abstract_declarator
3112                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3113        | '(' abstract_ptr ')' attribute_list_opt
3114                { $$ = $2->addQualifiers( $4 ); }
3115        ;
3116
3117abstract_array:
3118        array_dimension
3119        | '(' abstract_ptr ')' array_dimension
3120                { $$ = $2->addArray( $4 ); }
3121        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3122                { $$ = $2->addArray( $4 ); }
3123        | '(' abstract_array ')'                                                        // redundant parenthesis
3124                { $$ = $2; }
3125        ;
3126
3127abstract_function:
3128        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3129                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3130        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3131                { $$ = $2->addParamList( $6 ); }
3132        | '(' abstract_function ')'                                                     // redundant parenthesis
3133                { $$ = $2; }
3134        ;
3135
3136array_dimension:
3137                // Only the first dimension can be empty.
3138        '[' ']'
3139                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3140        | '[' ']' multi_array_dimension
3141                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3142        | multi_array_dimension
3143        ;
3144
3145multi_array_dimension:
3146        '[' push assignment_expression pop ']'
3147                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3148        | '[' push '*' pop ']'                                                          // C99
3149                { $$ = DeclarationNode::newVarArray( 0 ); }
3150        | multi_array_dimension '[' push assignment_expression pop ']'
3151                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3152        | multi_array_dimension '[' push '*' pop ']'            // C99
3153                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3154        ;
3155
3156// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3157// identifier to which the type applies, e.g.:
3158//
3159//              int f( int );                   // not handled here
3160//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3161//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3162//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3163//
3164// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3165// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3166// special meaning of parenthesis around a typedef name:
3167//
3168//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3169//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3170//              not as redundant parentheses around the identifier."
3171//
3172// For example:
3173//
3174//              typedef float T;
3175//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3176//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3177//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3178//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3179//
3180// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3181// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3182// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3183// functions.
3184
3185abstract_parameter_declarator:
3186        abstract_parameter_ptr
3187        | '&' MUTEX attribute_list_opt
3188                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3189        | abstract_parameter_array attribute_list_opt
3190                { $$ = $1->addQualifiers( $2 ); }
3191        | abstract_parameter_function attribute_list_opt
3192                { $$ = $1->addQualifiers( $2 ); }
3193        ;
3194
3195abstract_parameter_ptr:
3196        ptrref_operator
3197                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3198        | ptrref_operator type_qualifier_list
3199                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3200        | ptrref_operator abstract_parameter_declarator
3201                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3202        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3203                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3204        | '(' abstract_parameter_ptr ')' attribute_list_opt
3205                { $$ = $2->addQualifiers( $4 ); }
3206        ;
3207
3208abstract_parameter_array:
3209        array_parameter_dimension
3210        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3211                { $$ = $2->addArray( $4 ); }
3212        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3213                { $$ = $2->addArray( $4 ); }
3214        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3215                { $$ = $2; }
3216        ;
3217
3218abstract_parameter_function:
3219        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3220                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3221        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3222                { $$ = $2->addParamList( $6 ); }
3223        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3224                { $$ = $2; }
3225        ;
3226
3227array_parameter_dimension:
3228                // Only the first dimension can be empty or have qualifiers.
3229        array_parameter_1st_dimension
3230        | array_parameter_1st_dimension multi_array_dimension
3231                { $$ = $1->addArray( $2 ); }
3232        | multi_array_dimension
3233        ;
3234
3235// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3236//
3237//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3238//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3239
3240array_parameter_1st_dimension:
3241        '[' ']'
3242                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3243                // multi_array_dimension handles the '[' '*' ']' case
3244        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3245                { $$ = DeclarationNode::newVarArray( $3 ); }
3246        | '[' push type_qualifier_list pop ']'
3247                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3248                // multi_array_dimension handles the '[' assignment_expression ']' case
3249        | '[' push type_qualifier_list assignment_expression pop ']'
3250                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3251        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3252                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3253        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3254                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3255        ;
3256
3257// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3258//
3259//              struct S {
3260//          int;
3261//          int *;
3262//          int [10];
3263//          int (*)();
3264//      };
3265
3266variable_abstract_declarator:
3267        variable_abstract_ptr
3268        | variable_abstract_array attribute_list_opt
3269                { $$ = $1->addQualifiers( $2 ); }
3270        | variable_abstract_function attribute_list_opt
3271                { $$ = $1->addQualifiers( $2 ); }
3272        ;
3273
3274variable_abstract_ptr:
3275        ptrref_operator
3276                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3277        | ptrref_operator type_qualifier_list
3278                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3279        | ptrref_operator variable_abstract_declarator
3280                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3281        | ptrref_operator type_qualifier_list variable_abstract_declarator
3282                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3283        | '(' variable_abstract_ptr ')' attribute_list_opt
3284                { $$ = $2->addQualifiers( $4 ); }
3285        ;
3286
3287variable_abstract_array:
3288        array_dimension
3289        | '(' variable_abstract_ptr ')' array_dimension
3290                { $$ = $2->addArray( $4 ); }
3291        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3292                { $$ = $2->addArray( $4 ); }
3293        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3294                { $$ = $2; }
3295        ;
3296
3297variable_abstract_function:
3298        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3299                { $$ = $2->addParamList( $6 ); }
3300        | '(' variable_abstract_function ')'                            // redundant parenthesis
3301                { $$ = $2; }
3302        ;
3303
3304// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3305// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3306
3307cfa_identifier_parameter_declarator_tuple:                              // CFA
3308        cfa_identifier_parameter_declarator_no_tuple
3309        | cfa_abstract_tuple
3310        | type_qualifier_list cfa_abstract_tuple
3311                { $$ = $2->addQualifiers( $1 ); }
3312        ;
3313
3314cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3315        cfa_identifier_parameter_ptr
3316        | cfa_identifier_parameter_array
3317        ;
3318
3319cfa_identifier_parameter_ptr:                                                   // CFA
3320                // No SUE declaration in parameter list.
3321        ptrref_operator type_specifier_nobody
3322                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3323        | type_qualifier_list ptrref_operator type_specifier_nobody
3324                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3325        | ptrref_operator cfa_abstract_function
3326                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3327        | type_qualifier_list ptrref_operator cfa_abstract_function
3328                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3329        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3330                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3331        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3332                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3333        ;
3334
3335cfa_identifier_parameter_array:                                                 // CFA
3336                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3337                // shift/reduce conflict with new-style empty (void) function return type.
3338        '[' ']' type_specifier_nobody
3339                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3340        | cfa_array_parameter_1st_dimension type_specifier_nobody
3341                { $$ = $2->addNewArray( $1 ); }
3342        | '[' ']' multi_array_dimension type_specifier_nobody
3343                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3344        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3345                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3346        | multi_array_dimension type_specifier_nobody
3347                { $$ = $2->addNewArray( $1 ); }
3348
3349        | '[' ']' cfa_identifier_parameter_ptr
3350                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3351        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3352                { $$ = $2->addNewArray( $1 ); }
3353        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3354                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3355        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3356                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3357        | multi_array_dimension cfa_identifier_parameter_ptr
3358                { $$ = $2->addNewArray( $1 ); }
3359        ;
3360
3361cfa_array_parameter_1st_dimension:
3362        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3363                { $$ = DeclarationNode::newVarArray( $3 ); }
3364        | '[' push type_qualifier_list assignment_expression pop ']'
3365                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3366        | '[' push declaration_qualifier_list assignment_expression pop ']'
3367                // declaration_qualifier_list must be used because of shift/reduce conflict with
3368                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3369                // appear in this context.
3370                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3371        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3372                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3373        ;
3374
3375// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3376// identifier to which the type applies, e.g.:
3377//
3378//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3379//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3380//
3381// These rules need LR(3):
3382//
3383//              cfa_abstract_tuple identifier_or_type_name
3384//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3385//
3386// since a function return type can be syntactically identical to a tuple type:
3387//
3388//              [int, int] t;
3389//              [int, int] f( int );
3390//
3391// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3392// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3393// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3394// duplicated when appearing with cfa_function_specifier.
3395
3396cfa_abstract_declarator_tuple:                                                  // CFA
3397        cfa_abstract_tuple
3398        | type_qualifier_list cfa_abstract_tuple
3399                { $$ = $2->addQualifiers( $1 ); }
3400        | cfa_abstract_declarator_no_tuple
3401        ;
3402
3403cfa_abstract_declarator_no_tuple:                                               // CFA
3404        cfa_abstract_ptr
3405        | cfa_abstract_array
3406        ;
3407
3408cfa_abstract_ptr:                                                                               // CFA
3409        ptrref_operator type_specifier
3410                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3411        | type_qualifier_list ptrref_operator type_specifier
3412                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3413        | ptrref_operator cfa_abstract_function
3414                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3415        | type_qualifier_list ptrref_operator cfa_abstract_function
3416                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3417        | ptrref_operator cfa_abstract_declarator_tuple
3418                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3419        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3420                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3421        ;
3422
3423cfa_abstract_array:                                                                             // CFA
3424                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3425                // empty (void) function return type.
3426        '[' ']' type_specifier
3427                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3428        | '[' ']' multi_array_dimension type_specifier
3429                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3430        | multi_array_dimension type_specifier
3431                { $$ = $2->addNewArray( $1 ); }
3432        | '[' ']' cfa_abstract_ptr
3433                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3434        | '[' ']' multi_array_dimension cfa_abstract_ptr
3435                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3436        | multi_array_dimension cfa_abstract_ptr
3437                { $$ = $2->addNewArray( $1 ); }
3438        ;
3439
3440cfa_abstract_tuple:                                                                             // CFA
3441        '[' push cfa_abstract_parameter_list pop ']'
3442                { $$ = DeclarationNode::newTuple( $3 ); }
3443        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3444                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3445        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3446                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3447        ;
3448
3449cfa_abstract_function:                                                                  // CFA
3450//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3451//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3452        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3453                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3454        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3455                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3456        ;
3457
3458// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3459//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3460//
3461// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3462//    the declaration specifiers in a declaration is an obsolescent feature."
3463//
3464// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3465//    prototype-format parameter type declarators) is an obsolescent feature."
3466//
3467// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3468//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3469
3470//************************* MISCELLANEOUS ********************************
3471
3472comma_opt:                                                                                              // redundant comma
3473        // empty
3474        | ','
3475        ;
3476
3477default_initialize_opt:
3478        // empty
3479                { $$ = nullptr; }
3480        | '=' assignment_expression
3481                { $$ = $2; }
3482        ;
3483
3484%%
3485
3486// ----end of grammar----
3487
3488// Local Variables: //
3489// mode: c++ //
3490// tab-width: 4 //
3491// compile-command: "make install" //
3492// End: //
Note: See TracBrowser for help on using the repository browser.