source: src/Parser/parser.yy @ 481115f

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerresolv-newwith_gc
Last change on this file since 481115f was 481115f, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

change semantics of CFA routine-prototype declaration

  • Property mode set to 100644
File size: 120.3 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Mon Nov 27 17:23:35 2017
13// Update Count     : 2992
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        //cur->addType( specifier );
102        for ( cur = dynamic_cast< DeclarationNode * >( cur->get_next() ); cur != nullptr; cur = dynamic_cast< DeclarationNode * >( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106//      delete cl;
107        return declList;
108} // distAttr
109
110void distExt( DeclarationNode * declaration ) {
111        // distribute EXTENSION across all declarations
112        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
113                iter->set_extension( true );
114        } // for
115} // distExt
116
117// There is an ambiguity for inline generic-routine return-types and generic routines.
118//   forall( otype T ) struct S { int i; } bar( T ) {}
119// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
120//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
121
122void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
123        if ( declSpec->type->kind == TypeData::Aggregate ) { // return is aggregate definition
124                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
125                declSpec->type->aggregate.params = nullptr;
126        } // if
127} // rebindForall
128
129bool forall = false;                                                                    // aggregate have one or more forall qualifiers ?
130
131// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
132#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
133if ( N ) {                                                                                                                                              \
134        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
135        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
136        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
137        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
138        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
139} else {                                                                                                                                                \
140        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
141        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
142        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
143}
144%}
145
146%define parse.error verbose
147
148// Types declaration for productions
149%union
150{
151        Token tok;
152        ParseNode * pn;
153        ExpressionNode * en;
154        DeclarationNode * decl;
155        DeclarationNode::Aggregate aggKey;
156        DeclarationNode::TypeClass tclass;
157        StatementNode * sn;
158        WaitForStmt * wfs;
159        Expression * constant;
160        IfCtl * ifctl;
161        ForCtl * fctl;
162        LabelNode * label;
163        InitializerNode * in;
164        OperKinds op;
165        std::string * str;
166        bool flag;
167        CatchStmt::Kind catch_kind;
168}
169
170//************************* TERMINAL TOKENS ********************************
171
172// keywords
173%token TYPEDEF
174%token EXTERN STATIC AUTO REGISTER
175%token THREADLOCAL                                                                              // C11
176%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
177%token NORETURN                                                                                 // C11
178%token CONST VOLATILE
179%token RESTRICT                                                                                 // C99
180%token ATOMIC                                                                                   // C11
181%token FORALL MUTEX VIRTUAL                                                             // CFA
182%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
183%token BOOL COMPLEX IMAGINARY                                                   // C99
184%token INT128 FLOAT80 FLOAT128                                                  // GCC
185%token ZERO_T ONE_T                                                                             // CFA
186%token VALIST                                                                                   // GCC
187%token TYPEOF LABEL                                                                             // GCC
188%token ENUM STRUCT UNION
189%token COROUTINE MONITOR THREAD                                                 // CFA
190%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
191%token SIZEOF OFFSETOF
192%token ATTRIBUTE EXTENSION                                                              // GCC
193%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
194%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
195%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
196%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
197
198// names and constants: lexer differentiates between identifier and typedef names
199%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
200%token<tok> TIMEOUT                             WOR
201%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
202%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
203// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
204// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
205// converted into the tuple index (.)(1). e.g., 3.x
206%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
207
208// multi-character operators
209%token ARROW                                                                                    // ->
210%token ICR DECR                                                                                 // ++   --
211%token LS RS                                                                                    // <<   >>
212%token LE GE EQ NE                                                                              // <=   >=      ==      !=
213%token ANDAND OROR                                                                              // &&   ||
214%token ELLIPSIS                                                                                 // ...
215
216%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
217%token PLUSassign       MINUSassign                                                     // +=   -=
218%token LSassign         RSassign                                                        // <<=  >>=
219%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
220
221%token ATassign                                                                                 // @=
222
223%type<tok> identifier  no_attr_identifier
224%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
225%type<tok> quasi_keyword
226%type<constant> string_literal
227%type<str> string_literal_list
228
229// expressions
230%type<en> constant
231%type<en> tuple                                                 tuple_expression_list
232%type<op> ptrref_operator                               unary_operator                          assignment_operator
233%type<en> primary_expression                    postfix_expression                      unary_expression
234%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
235%type<en> shift_expression                              relational_expression           equality_expression
236%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
237%type<en> logical_AND_expression                logical_OR_expression
238%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
239%type<en> comma_expression                              comma_expression_opt
240%type<en> argument_expression_list              argument_expression                     default_initialize_opt
241%type<ifctl> if_control_expression
242%type<fctl> for_control_expression
243%type<en> subrange
244%type<decl> asm_name_opt
245%type<en> asm_operands_opt asm_operands_list asm_operand
246%type<label> label_list
247%type<en> asm_clobbers_list_opt
248%type<flag> asm_volatile_opt
249%type<en> handler_predicate_opt
250
251// statements
252%type<sn> statement                                             labeled_statement                       compound_statement
253%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
254%type<sn> selection_statement
255%type<sn> switch_clause_list_opt                switch_clause_list                      choose_clause_list_opt          choose_clause_list
256%type<en> case_value
257%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
258%type<sn> fall_through                                  fall_through_opt
259%type<sn> iteration_statement                   jump_statement
260%type<sn> expression_statement                  asm_statement
261%type<sn> with_statement                                with_clause_opt
262%type<sn> exception_statement                   handler_clause                          finally_clause
263%type<catch_kind> handler_key
264%type<sn> mutex_statement
265%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
266%type<sn> waitfor_statement
267%type<wfs> waitfor_clause
268
269// declarations
270%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
271%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
272%type<decl> abstract_parameter_declaration
273
274%type<aggKey> aggregate_key
275%type<decl> aggregate_type aggregate_type_nobody
276
277%type<decl> assertion assertion_list_opt
278
279%type<en>   bit_subrange_size_opt bit_subrange_size
280
281%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
282
283%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
284
285%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
286%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
287
288%type<decl> elaborated_type elaborated_type_nobody
289
290%type<decl> enumerator_list enum_type enum_type_nobody
291%type<en> enumerator_value_opt
292
293%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
294
295%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
296%type<en> field field_list field_name fraction_constants
297
298%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
299
300%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
301%type<decl> identifier_list
302
303%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
304%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
305%type<decl> cfa_abstract_ptr cfa_abstract_tuple
306
307%type<decl> cfa_array_parameter_1st_dimension
308
309%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list
310%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
311
312%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
313%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
314
315%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_type_list cfa_parameter_type_list_opt
316
317%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
318
319%type<decl> c_declaration
320%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
321%type<decl> KR_declaration_list KR_declaration_list_opt
322
323%type<decl> parameter_declaration parameter_list parameter_type_list
324%type<decl> parameter_type_list_opt
325
326%type<decl> paren_identifier paren_type
327
328%type<decl> storage_class storage_class_list
329
330%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
331
332%type<tclass> type_class
333%type<decl> type_declarator type_declarator_name type_declaring_list
334
335%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
336%type<decl> typedef typedef_declaration typedef_expression
337
338%type<decl> variable_type_redeclarator type_ptr type_array type_function
339
340%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
341
342%type<decl> type type_no_function
343%type<decl> type_parameter type_parameter_list type_initializer_opt
344
345%type<en> type_list
346
347%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
348%type<decl> type_specifier type_specifier_nobody
349
350%type<decl> variable_declarator variable_ptr variable_array variable_function
351%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
352
353%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
354
355// initializers
356%type<in>  initializer initializer_list initializer_opt
357
358// designators
359%type<en>  designator designator_list designation
360
361
362// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
363//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
364//   if ( C ) S1 else S2
365//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
366// Similar issues exit with the waitfor statement.
367
368// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
369// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
370%precedence THEN        // rule precedence for IF/WAITFOR statement
371%precedence WOR         // token precedence for start of WOR in WAITFOR statement
372%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
373%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
374
375// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
376//   forall( otype T ) struct Foo { T v; };
377//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
378//   Foo ( *fp )( int );
379//   `---'                                              matches start of TYPEGENname '('
380// Must be:
381//   Foo( int ) ( *fp )( int );
382
383// Order of these lines matters (low-to-high precedence).
384%precedence TYPEGENname
385%precedence '('
386
387%locations                      // support location tracking for error messages
388
389%start translation_unit                                                                 // parse-tree root
390
391%%
392//************************* Namespace Management ********************************
393
394// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
395// "identifier", "TYPEDEFname", and "TYPEGENname" that are lexically identical.  While it is possible to write a purely
396// context-free grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.
397// Hence, this grammar uses the ANSI style.
398//
399// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
400// introduced through "forall" qualifiers), and by introducing "type generators" -- parameterized types.  This latter
401// type name creates a third class of identifiers that must be distinguished by the scanner.
402//
403// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
404// accesses a data structure (TypedefTable) to allow classification of an identifier that it has just read.  Semantic
405// actions during the parser update this data structure when the class of identifiers change.
406//
407// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its class in a
408// local scope; it must revert to its original class at the end of the block.  Since type names can be local to a
409// particular declaration, each declaration is itself a scope.  This requires distinguishing between type names that are
410// local to the current declaration scope and those that persist past the end of the declaration (i.e., names defined in
411// "typedef" or "otype" declarations).
412//
413// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and closing of
414// scopes.  Every push must have a matching pop, although it is regrettable the matching pairs do not always occur
415// within the same rule.  These non-terminals may appear in more contexts than strictly necessary from a semantic point
416// of view.  Unfortunately, these extra rules are necessary to prevent parsing conflicts -- the parser may not have
417// enough context and look-ahead information to decide whether a new scope is necessary, so the effect of these extra
418// rules is to open a new scope unconditionally.  As the grammar evolves, it may be neccesary to add or move around
419// "push" and "pop" nonterminals to resolve conflicts of this sort.
420
421push:
422                { typedefTable.enterScope(); }
423        ;
424
425pop:
426                { typedefTable.leaveScope(); }
427        ;
428
429//************************* CONSTANTS ********************************
430
431constant:
432                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
433        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
434        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
435        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
436        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
437        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
438        ;
439
440quasi_keyword:                                                                                  // CFA
441        TIMEOUT
442        | WOR
443        ;
444
445identifier:
446        IDENTIFIER
447        | ATTR_IDENTIFIER                                                                       // CFA
448        | quasi_keyword
449        ;
450
451no_attr_identifier:
452        IDENTIFIER
453        | quasi_keyword
454        ;
455
456string_literal:
457        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
458        ;
459
460string_literal_list:                                                                    // juxtaposed strings are concatenated
461        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
462        | string_literal_list STRINGliteral
463                {
464                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
465                        delete $2;                                                                      // allocated by lexer
466                        $$ = $1;                                                                        // conversion from tok to str
467                }
468        ;
469
470//************************* EXPRESSIONS ********************************
471
472primary_expression:
473        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
474                { $$ = new ExpressionNode( build_varref( $1 ) ); }
475        | quasi_keyword
476                { $$ = new ExpressionNode( build_varref( $1 ) ); }
477        | tuple
478        | '(' comma_expression ')'
479                { $$ = $2; }
480        | '(' compound_statement ')'                                            // GCC, lambda expression
481                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
482        | type_name '.' no_attr_identifier                                      // CFA, nested type
483                { throw SemanticError("Qualified names are currently unimplemented."); $$ = nullptr; }                                                          // FIX ME
484        | type_name '.' '[' push field_list pop ']'                     // CFA, nested type / tuple field selector
485                { throw SemanticError("Qualified names are currently unimplemented."); $$ = nullptr; }                                                          // FIX ME
486        ;
487
488postfix_expression:
489        primary_expression
490        | postfix_expression '[' push assignment_expression pop ']'
491                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
492                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
493                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
494                // equivalent to the old x[i,j].
495                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $4 ) ); }
496        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
497                {
498                        Token fn;
499                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
500                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
501                }
502        | postfix_expression '(' argument_expression_list ')'
503                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
504        | postfix_expression '.' no_attr_identifier
505                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
506        | postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
507                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
508        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
509                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
510        | postfix_expression ARROW no_attr_identifier
511                {
512                        $$ = new ExpressionNode( build_pfieldSel( $1, *$3 == "0" || *$3 == "1" ? build_constantInteger( *$3 ) : build_varref( $3 ) ) );
513                }
514        | postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
515                        { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
516        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
517                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
518        | postfix_expression ICR
519                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
520        | postfix_expression DECR
521                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
522        | '(' type_no_function ')' '{' initializer_list comma_opt '}' // C99, compound-literal
523                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
524        | '^' primary_expression '{' argument_expression_list '}' // CFA
525                {
526                        Token fn;
527                        fn.str = new string( "^?{}" );                          // location undefined
528                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
529                }
530        ;
531
532argument_expression_list:
533        argument_expression
534        | argument_expression_list ',' argument_expression
535                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
536        ;
537
538argument_expression:
539        // empty
540                { $$ = nullptr; }
541        // | '@'                                                                                                // use default argument
542        //      { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
543        | assignment_expression
544        ;
545
546field_list:                                                                                             // CFA, tuple field selector
547        field
548        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
549        ;
550
551field:                                                                                                  // CFA, tuple field selector
552        field_name
553        | FLOATING_DECIMALconstant field
554                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
555        | FLOATING_DECIMALconstant '[' push field_list pop ']'
556                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $4 ) ) ); }
557        | field_name '.' field
558                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
559        | field_name '.' '[' push field_list pop ']'
560                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $5 ) ) ); }
561        | field_name ARROW field
562                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
563        | field_name ARROW '[' push field_list pop ']'
564                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $5 ) ) ); }
565        ;
566
567field_name:
568        INTEGERconstant fraction_constants
569                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
570        | FLOATINGconstant fraction_constants
571                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
572        | no_attr_identifier fraction_constants
573                {
574                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
575                }
576        ;
577
578fraction_constants:
579        // empty
580                { $$ = nullptr; }
581        | fraction_constants FLOATING_FRACTIONconstant
582                {
583                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
584                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
585                }
586        ;
587
588unary_expression:
589        postfix_expression
590                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
591                // semantics checks, e.g., ++3, 3--, *3, &&3
592        | constant
593                { $$ = $1; }
594        | string_literal
595                { $$ = new ExpressionNode( $1 ); }
596        | EXTENSION cast_expression                                                     // GCC
597                { $$ = $2->set_extension( true ); }
598                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
599                //              { * X; }         // dereference X
600                //              { * int X; } // CFA declaration of pointer to int
601        | ptrref_operator cast_expression                                       // CFA
602                {
603                        switch ( $1 ) {
604                          case OperKinds::AddressOf:
605                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
606                                break;
607                          case OperKinds::PointTo:
608                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
609                                break;
610                          case OperKinds::And:
611                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
612                                break;
613                          default:
614                                assert( false );
615                        }
616                }
617        | unary_operator cast_expression
618                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
619        | ICR unary_expression
620                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
621        | DECR unary_expression
622                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
623        | SIZEOF unary_expression
624                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
625        | SIZEOF '(' type_no_function ')'
626                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
627        | ALIGNOF unary_expression                                                      // GCC, variable alignment
628                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
629        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
630                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
631        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
632                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
633        | ATTR_IDENTIFIER
634                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
635        | ATTR_IDENTIFIER '(' argument_expression ')'
636                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
637        | ATTR_IDENTIFIER '(' type ')'
638                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
639        ;
640
641ptrref_operator:
642        '*'                                                                                     { $$ = OperKinds::PointTo; }
643        | '&'                                                                           { $$ = OperKinds::AddressOf; }
644                // GCC, address of label must be handled by semantic check for ref,ref,label
645        | ANDAND                                                                        { $$ = OperKinds::And; }
646        ;
647
648unary_operator:
649        '+'                                                                                     { $$ = OperKinds::UnPlus; }
650        | '-'                                                                           { $$ = OperKinds::UnMinus; }
651        | '!'                                                                           { $$ = OperKinds::Neg; }
652        | '~'                                                                           { $$ = OperKinds::BitNeg; }
653        ;
654
655cast_expression:
656        unary_expression
657        | '(' type_no_function ')' cast_expression
658                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
659                // VIRTUAL cannot be opt because of look ahead issues
660        | '(' VIRTUAL ')' cast_expression
661                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
662        | '(' VIRTUAL type_no_function ')' cast_expression
663                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
664//      | '(' type_no_function ')' tuple
665//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
666        ;
667
668exponential_expression:
669        cast_expression
670        | exponential_expression '\\' cast_expression
671                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
672        ;
673
674multiplicative_expression:
675        exponential_expression
676        | multiplicative_expression '*' exponential_expression
677                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
678        | multiplicative_expression '/' exponential_expression
679                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
680        | multiplicative_expression '%' exponential_expression
681                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
682        ;
683
684additive_expression:
685        multiplicative_expression
686        | additive_expression '+' multiplicative_expression
687                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
688        | additive_expression '-' multiplicative_expression
689                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
690        ;
691
692shift_expression:
693        additive_expression
694        | shift_expression LS additive_expression
695                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
696        | shift_expression RS additive_expression
697                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
698        ;
699
700relational_expression:
701        shift_expression
702        | relational_expression '<' shift_expression
703                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
704        | relational_expression '>' shift_expression
705                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
706        | relational_expression LE shift_expression
707                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
708        | relational_expression GE shift_expression
709                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
710        ;
711
712equality_expression:
713        relational_expression
714        | equality_expression EQ relational_expression
715                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
716        | equality_expression NE relational_expression
717                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
718        ;
719
720AND_expression:
721        equality_expression
722        | AND_expression '&' equality_expression
723                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
724        ;
725
726exclusive_OR_expression:
727        AND_expression
728        | exclusive_OR_expression '^' AND_expression
729                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
730        ;
731
732inclusive_OR_expression:
733        exclusive_OR_expression
734        | inclusive_OR_expression '|' exclusive_OR_expression
735                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
736        ;
737
738logical_AND_expression:
739        inclusive_OR_expression
740        | logical_AND_expression ANDAND inclusive_OR_expression
741                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
742        ;
743
744logical_OR_expression:
745        logical_AND_expression
746        | logical_OR_expression OROR logical_AND_expression
747                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
748        ;
749
750conditional_expression:
751        logical_OR_expression
752        | logical_OR_expression '?' comma_expression ':' conditional_expression
753                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
754                // FIX ME: this hack computes $1 twice
755        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
756                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
757        ;
758
759constant_expression:
760        conditional_expression
761        ;
762
763assignment_expression:
764                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
765        conditional_expression
766        | unary_expression assignment_operator assignment_expression
767                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
768        ;
769
770assignment_expression_opt:
771        // empty
772                { $$ = nullptr; }
773        | assignment_expression
774        ;
775
776assignment_operator:
777        '='                                                                                     { $$ = OperKinds::Assign; }
778        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
779        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
780        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
781        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
782        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
783        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
784        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
785        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
786        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
787        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
788        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
789        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
790        ;
791
792tuple:                                                                                                  // CFA, tuple
793                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
794                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
795//      '[' ']'
796//              { $$ = new ExpressionNode( build_tuple() ); }
797//      '[' push assignment_expression pop ']'
798//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
799        '[' push ',' tuple_expression_list pop ']'
800                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
801        | '[' push assignment_expression ',' tuple_expression_list pop ']'
802                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
803        ;
804
805tuple_expression_list:
806        assignment_expression_opt
807        | tuple_expression_list ',' assignment_expression_opt
808                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
809        ;
810
811comma_expression:
812        assignment_expression
813        | comma_expression ',' assignment_expression
814                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
815        ;
816
817comma_expression_opt:
818        // empty
819                { $$ = nullptr; }
820        | comma_expression
821        ;
822
823//*************************** STATEMENTS *******************************
824
825statement:
826        labeled_statement
827        | compound_statement
828        | expression_statement                                          { $$ = $1; }
829        | selection_statement
830        | iteration_statement
831        | jump_statement
832        | with_statement
833        | mutex_statement
834        | waitfor_statement
835        | exception_statement
836        | asm_statement
837
838labeled_statement:
839                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
840        identifier_or_type_name ':' attribute_list_opt statement
841                {
842                        $$ = $4->add_label( $1, $3 );
843                }
844        ;
845
846compound_statement:
847        '{' '}'
848                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
849        | '{'
850                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
851                // requires its own scope.
852          push push
853          local_label_declaration_opt                                           // GCC, local labels
854          statement_decl_list                                                           // C99, intermix declarations and statements
855          pop '}'
856                { $$ = new StatementNode( build_compound( $5 ) ); }
857        ;
858
859statement_decl_list:                                                                    // C99
860        statement_decl
861        | statement_decl_list push statement_decl
862                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
863        ;
864
865statement_decl:
866        declaration                                                                                     // CFA, new & old style declarations
867                { $$ = new StatementNode( $1 ); }
868        | EXTENSION declaration                                                         // GCC
869                {
870                        distExt( $2 );
871                        $$ = new StatementNode( $2 );
872                }
873        | function_definition
874                { $$ = new StatementNode( $1 ); }
875        | EXTENSION function_definition                                         // GCC
876                {
877                        distExt( $2 );
878                        $$ = new StatementNode( $2 );
879                }
880        | statement pop
881        ;
882
883statement_list_nodecl:
884        statement
885        | statement_list_nodecl statement
886                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
887        ;
888
889expression_statement:
890        comma_expression_opt ';'
891                { $$ = new StatementNode( build_expr( $1 ) ); }
892        ;
893
894selection_statement:
895        IF '(' push if_control_expression ')' statement         %prec THEN
896                // explicitly deal with the shift/reduce conflict on if/else
897                { $$ = new StatementNode( build_if( $4, $6, nullptr ) ); }
898        | IF '(' push if_control_expression ')' statement ELSE statement
899                { $$ = new StatementNode( build_if( $4, $6, $8 ) ); }
900        | SWITCH '(' comma_expression ')' case_clause
901                { $$ = new StatementNode( build_switch( $3, $5 ) ); }
902        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
903                {
904                        StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
905                        // The semantics of the declaration list is changed to include associated initialization, which is performed
906                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
907                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
908                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
909                        // statement.
910                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
911                }
912        | CHOOSE '(' comma_expression ')' case_clause           // CFA
913                { $$ = new StatementNode( build_switch( $3, $5 ) ); }
914        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt choose_clause_list_opt '}' // CFA
915                {
916                        StatementNode *sw = new StatementNode( build_switch( $3, $8 ) );
917                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
918                }
919        ;
920
921if_control_expression:
922        comma_expression pop
923                { $$ = new IfCtl( nullptr, $1 ); }
924        | c_declaration pop                                                                     // no semi-colon
925                { $$ = new IfCtl( $1, nullptr ); }
926        | cfa_declaration pop                                                           // no semi-colon
927                { $$ = new IfCtl( $1, nullptr ); }
928        | declaration comma_expression                                          // semi-colon separated
929                { $$ = new IfCtl( $1, $2 ); }
930        ;
931
932// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
933// clause allows a list of values and subranges.
934
935case_value:                                                                                             // CFA
936        constant_expression                                                     { $$ = $1; }
937        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
938                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
939        | subrange                                                                                      // CFA, subrange
940        ;
941
942case_value_list:                                                                                // CFA
943        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
944                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
945        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
946        ;
947
948case_label:                                                                                             // CFA
949        CASE case_value_list ':'                                        { $$ = $2; }
950        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
951                // A semantic check is required to ensure only one default clause per switch/choose statement.
952        ;
953
954case_label_list:                                                                                // CFA
955        case_label
956        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
957        ;
958
959case_clause:                                                                                    // CFA
960        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
961        ;
962
963switch_clause_list_opt:                                                                 // CFA
964        // empty
965                { $$ = nullptr; }
966        | switch_clause_list
967        ;
968
969switch_clause_list:                                                                             // CFA
970        case_label_list statement_list_nodecl
971                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
972        | switch_clause_list case_label_list statement_list_nodecl
973                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
974        ;
975
976choose_clause_list_opt:                                                                 // CFA
977        // empty
978                { $$ = nullptr; }
979        | choose_clause_list
980        ;
981
982choose_clause_list:                                                                             // CFA
983        case_label_list fall_through
984                { $$ = $1->append_last_case( $2 ); }
985        | case_label_list statement_list_nodecl fall_through_opt
986                { $$ = $1->append_last_case( new StatementNode( build_compound( (StatementNode *)$2->set_last( $3 ) ) ) ); }
987        | choose_clause_list case_label_list fall_through
988                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( $3 ))); }
989        | choose_clause_list case_label_list statement_list_nodecl fall_through_opt
990                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( (StatementNode *)$3->set_last( $4 ) ) ) ) ) ); }
991        ;
992
993fall_through_opt:                                                                               // CFA
994        // empty
995                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); } // insert implicit break
996        | fall_through
997        ;
998
999fall_through_name:                                                                              // CFA
1000        FALLTHRU
1001        | FALLTHROUGH
1002        ;
1003
1004fall_through:                                                                                   // CFA
1005        fall_through_name
1006                { $$ = nullptr; }
1007        | fall_through_name ';'
1008                { $$ = nullptr; }
1009        ;
1010
1011iteration_statement:
1012        WHILE '(' comma_expression ')' statement
1013                { $$ = new StatementNode( build_while( $3, $5 ) ); }
1014        | DO statement WHILE '(' comma_expression ')' ';'
1015                { $$ = new StatementNode( build_while( $5, $2, true ) ); }
1016        | FOR '(' push for_control_expression ')' statement
1017                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1018        ;
1019
1020for_control_expression:
1021        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
1022                { $$ = new ForCtl( $1, $4, $6 ); }
1023        | declaration comma_expression_opt ';' comma_expression_opt // C99
1024                { $$ = new ForCtl( $1, $2, $4 ); }
1025        ;
1026
1027jump_statement:
1028        GOTO identifier_or_type_name ';'
1029                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1030        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1031                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1032                // whereas normal operator precedence yields goto (*i)+3;
1033                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1034        | CONTINUE ';'
1035                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1036                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1037        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1038                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1039                // the target of the transfer appears only at the start of an iteration statement.
1040                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1041        | BREAK ';'
1042                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1043                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1044        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1045                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1046                // the target of the transfer appears only at the start of an iteration statement.
1047                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1048        | RETURN comma_expression_opt ';'
1049                { $$ = new StatementNode( build_return( $2 ) ); }
1050        | THROW assignment_expression_opt ';'                           // handles rethrow
1051                { $$ = new StatementNode( build_throw( $2 ) ); }
1052        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1053                { $$ = new StatementNode( build_resume( $2 ) ); }
1054        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1055                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1056        ;
1057
1058with_statement:
1059        WITH '(' tuple_expression_list ')' statement
1060                { throw SemanticError("With clause is currently unimplemented."); $$ = nullptr; } // FIX ME
1061        ;
1062
1063// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1064mutex_statement:
1065        MUTEX '(' argument_expression_list ')' statement
1066                { throw SemanticError("Mutex statement is currently unimplemented."); $$ = nullptr; } // FIX ME
1067        ;
1068
1069when_clause:
1070        WHEN '(' comma_expression ')'
1071                { $$ = $3; }
1072        ;
1073
1074when_clause_opt:
1075        // empty
1076                { $$ = nullptr; }
1077        | when_clause
1078        ;
1079
1080waitfor:
1081        WAITFOR '(' identifier ')'
1082                {
1083                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1084                        delete $3;
1085                }
1086        | WAITFOR '(' identifier ',' argument_expression_list ')'
1087                {
1088                        $$ = new ExpressionNode( new NameExpr( *$3 ) );
1089                        $$->set_last( $5 );
1090                        delete $3;
1091                }
1092        ;
1093
1094timeout:
1095        TIMEOUT '(' comma_expression ')'
1096                { $$ = $3; }
1097        ;
1098
1099waitfor_clause:
1100        when_clause_opt waitfor statement                                       %prec THEN
1101                { $$ = build_waitfor( $2, $3, $1 ); }
1102        | when_clause_opt waitfor statement WOR waitfor_clause
1103                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1104        | when_clause_opt timeout statement                                     %prec THEN
1105                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1106        | when_clause_opt ELSE statement
1107                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1108                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1109        | when_clause_opt timeout statement WOR when_clause ELSE statement
1110                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1111        ;
1112
1113waitfor_statement:
1114        when_clause_opt waitfor statement                                       %prec THEN
1115                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1116        | when_clause_opt waitfor statement WOR waitfor_clause
1117                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1118        ;
1119
1120exception_statement:
1121        TRY compound_statement handler_clause
1122                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1123        | TRY compound_statement finally_clause
1124                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1125        | TRY compound_statement handler_clause finally_clause
1126                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1127        ;
1128
1129handler_clause:
1130        handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1131                { $$ = new StatementNode( build_catch( $1, $5, $7, $9 ) ); }
1132        | handler_clause handler_key '(' push push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1133                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $6, $8, $10 ) ) ); }
1134        ;
1135
1136handler_predicate_opt:
1137        //empty
1138                { $$ = nullptr; }
1139        | ';' conditional_expression
1140                { $$ = $2; }
1141        ;
1142
1143handler_key:
1144        CATCH
1145                { $$ = CatchStmt::Terminate; }
1146        | CATCHRESUME
1147                { $$ = CatchStmt::Resume; }
1148        ;
1149
1150finally_clause:
1151        FINALLY compound_statement
1152                {
1153                        $$ = new StatementNode( build_finally( $2 ) );
1154                }
1155        ;
1156
1157exception_declaration:
1158                // No SUE declaration in parameter list.
1159        type_specifier_nobody
1160        | type_specifier_nobody declarator
1161                {
1162                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1163                        $$ = $2->addType( $1 );
1164                }
1165        | type_specifier_nobody variable_abstract_declarator
1166                { $$ = $2->addType( $1 ); }
1167        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1168                {
1169                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1170                        $$ = $1->addName( $2 );
1171                }
1172        | cfa_abstract_declarator_tuple                                         // CFA
1173        ;
1174
1175asm_statement:
1176        ASM asm_volatile_opt '(' string_literal ')' ';'
1177                { $$ = new StatementNode( build_asmstmt( $2, $4, 0 ) ); }
1178        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1179                { $$ = new StatementNode( build_asmstmt( $2, $4, $6 ) ); }
1180        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1181                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8 ) ); }
1182        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1183                { $$ = new StatementNode( build_asmstmt( $2, $4, $6, $8, $10 ) ); }
1184        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1185                { $$ = new StatementNode( build_asmstmt( $2, $5, 0, $8, $10, $12 ) ); }
1186        ;
1187
1188asm_volatile_opt:                                                                               // GCC
1189        // empty
1190                { $$ = false; }
1191        | VOLATILE
1192                { $$ = true; }
1193        ;
1194
1195asm_operands_opt:                                                                               // GCC
1196        // empty
1197                { $$ = nullptr; }                                                               // use default argument
1198        | asm_operands_list
1199        ;
1200
1201asm_operands_list:                                                                              // GCC
1202        asm_operand
1203        | asm_operands_list ',' asm_operand
1204                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1205        ;
1206
1207asm_operand:                                                                                    // GCC
1208        string_literal '(' constant_expression ')'
1209                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1210        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1211                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1212        ;
1213
1214asm_clobbers_list_opt:                                                                  // GCC
1215        // empty
1216                { $$ = nullptr; }                                                               // use default argument
1217        | string_literal
1218                { $$ = new ExpressionNode( $1 ); }
1219        | asm_clobbers_list_opt ',' string_literal
1220                // set_last returns ParseNode *
1221                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1222        ;
1223
1224label_list:
1225        no_attr_identifier
1226                {
1227                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1228                        delete $1;                                                                      // allocated by lexer
1229                }
1230        | label_list ',' no_attr_identifier
1231                {
1232                        $$ = $1; $1->labels.push_back( *$3 );
1233                        delete $3;                                                                      // allocated by lexer
1234                }
1235        ;
1236
1237//******************************* DECLARATIONS *********************************
1238
1239declaration_list_opt:                                                                   // used at beginning of switch statement
1240        pop
1241                { $$ = nullptr; }
1242        | declaration_list
1243        ;
1244
1245declaration_list:
1246        declaration
1247        | declaration_list push declaration
1248                { $$ = $1->appendList( $3 ); }
1249        ;
1250
1251KR_declaration_list_opt:                                                                // used to declare parameter types in K&R style functions
1252        // empty
1253                { $$ = nullptr; }
1254        | KR_declaration_list
1255        ;
1256
1257KR_declaration_list:
1258        push c_declaration pop ';'
1259                { $$ = $2; }
1260        | KR_declaration_list push c_declaration pop ';'
1261                { $$ = $1->appendList( $3 ); }
1262        ;
1263
1264local_label_declaration_opt:                                                    // GCC, local label
1265        // empty
1266        | local_label_declaration_list
1267        ;
1268
1269local_label_declaration_list:                                                   // GCC, local label
1270        LABEL local_label_list ';'
1271        | local_label_declaration_list LABEL local_label_list ';'
1272        ;
1273
1274local_label_list:                                                                               // GCC, local label
1275        no_attr_identifier_or_type_name                         {}
1276        | local_label_list ',' no_attr_identifier_or_type_name {}
1277        ;
1278
1279declaration:                                                                                    // old & new style declarations
1280        c_declaration pop ';'
1281        | cfa_declaration pop ';'                                                       // CFA
1282        | STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1283                { throw SemanticError("Static assert is currently unimplemented."); $$ = nullptr; }     // FIX ME
1284        ;
1285
1286// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1287// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1288// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1289// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1290// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1291// block, but cannot be mixed within a specific declaration.
1292//
1293//                      CFA                                     C
1294//              [10] int x;                     int x[10];              // array of 10 integers
1295//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1296
1297cfa_declaration:                                                                                // CFA
1298        cfa_variable_declaration
1299        | cfa_typedef_declaration
1300        | cfa_function_declaration
1301        | type_declaring_list
1302        | trait_specifier
1303        ;
1304
1305cfa_variable_declaration:                                                               // CFA
1306        cfa_variable_specifier initializer_opt
1307                {
1308                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1309                        $$ = $1->addInitializer( $2 );
1310                }
1311        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1312                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1313                // them as a type_qualifier cannot appear in that context.
1314                {
1315                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1316                        $$ = $2->addQualifiers( $1 )->addInitializer( $3 );;
1317                }
1318        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1319                {
1320                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1321                        $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) );
1322                }
1323        ;
1324
1325cfa_variable_specifier:                                                                 // CFA
1326                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1327                // storage-class
1328        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1329                {
1330                        typedefTable.setNextIdentifier( *$2 );
1331                        $$ = $1->addName( $2 )->addAsmName( $3 );
1332                }
1333        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1334                {
1335                        typedefTable.setNextIdentifier( *$2 );
1336                        $$ = $1->addName( $2 )->addAsmName( $3 );
1337                }
1338        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1339                {
1340                        typedefTable.setNextIdentifier( *$3 );
1341                        $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 );
1342                }
1343        ;
1344
1345cfa_function_declaration:                                                               // CFA
1346        cfa_function_specifier
1347                {
1348                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1349                        $$ = $1;
1350                }
1351        | type_qualifier_list cfa_function_specifier
1352                {
1353                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1354                        $$ = $2->addQualifiers( $1 );
1355                }
1356        | declaration_qualifier_list cfa_function_specifier
1357                {
1358                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1359                        $$ = $2->addQualifiers( $1 );
1360                }
1361        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1362                {
1363                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1364                        $$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1365                }
1366        | cfa_function_declaration pop ',' push identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1367                {
1368                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1369                        DeclarationNode * ret = new DeclarationNode;
1370                        ret->type = maybeClone( $1->type->base );
1371                        $$ = $1->appendList( DeclarationNode::newFunction( $5, ret, $8, nullptr, true ) );
1372                }
1373        ;
1374
1375cfa_function_specifier:                                                                 // CFA
1376//      '[' ']' identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')' // S/R conflict
1377//              {
1378//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1379//              }
1380//      '[' ']' identifier '(' push cfa_parameter_type_list_opt pop ')'
1381//              {
1382//                      typedefTable.setNextIdentifier( *$5 );
1383//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1384//              }
1385//      | '[' ']' TYPEDEFname '(' push cfa_parameter_type_list_opt pop ')'
1386//              {
1387//                      typedefTable.setNextIdentifier( *$5 );
1388//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1389//              }
1390//      | '[' ']' typegen_name
1391                // identifier_or_type_name must be broken apart because of the sequence:
1392                //
1393                //   '[' ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
1394                //   '[' ']' type_specifier
1395                //
1396                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1397                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1398        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1399                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1400                {
1401                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1402                }
1403        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_type_list_opt pop ')'
1404                {
1405                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1406                }
1407        ;
1408
1409cfa_function_return:                                                                    // CFA
1410        '[' push cfa_parameter_list pop ']'
1411                { $$ = DeclarationNode::newTuple( $3 ); }
1412        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1413                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the
1414                // ']'.
1415                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1416        ;
1417
1418cfa_typedef_declaration:                                                                // CFA
1419        TYPEDEF cfa_variable_specifier
1420                {
1421                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1422                        $$ = $2->addTypedef();
1423                }
1424        | TYPEDEF cfa_function_specifier
1425                {
1426                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1427                        $$ = $2->addTypedef();
1428                }
1429        | cfa_typedef_declaration pop ',' push no_attr_identifier
1430                {
1431                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1432                        $$ = $1->appendList( $1->cloneType( $5 ) );
1433                }
1434        ;
1435
1436// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1437// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1438
1439typedef_declaration:
1440        TYPEDEF type_specifier declarator
1441                {
1442                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1443                        $$ = $3->addType( $2 )->addTypedef();
1444                }
1445        | typedef_declaration pop ',' push declarator
1446                {
1447                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1448                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1449                }
1450        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1451                {
1452                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1453                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1454                }
1455        | type_specifier TYPEDEF declarator
1456                {
1457                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1458                        $$ = $3->addType( $1 )->addTypedef();
1459                }
1460        | type_specifier TYPEDEF type_qualifier_list declarator
1461                {
1462                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1463                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1464                }
1465        ;
1466
1467typedef_expression:
1468                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1469        TYPEDEF no_attr_identifier '=' assignment_expression
1470                {
1471                        typedefTable.addToEnclosingScope( *$2, TypedefTable::TD );
1472                        $$ = DeclarationNode::newName( 0 );                     // unimplemented
1473                }
1474        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1475                {
1476                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1477                        $$ = DeclarationNode::newName( 0 );                     // unimplemented
1478                }
1479        ;
1480
1481//c_declaration:
1482//      declaring_list pop ';'
1483//      | typedef_declaration pop ';'
1484//      | typedef_expression pop ';'                                            // GCC, naming expression type
1485//      | sue_declaration_specifier pop ';'
1486//      ;
1487//
1488//declaring_list:
1489//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1490//              // storage-class
1491//       declarator asm_name_opt initializer_opt
1492//              {
1493//                      typedefTable.addToEnclosingScope( TypedefTable::ID );
1494//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1495//              }
1496//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1497//              {
1498//                      typedefTable.addToEnclosingScope( TypedefTable::ID );
1499//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1500//              }
1501//      ;
1502
1503c_declaration:
1504        declaration_specifier declaring_list
1505                {
1506                        $$ = distAttr( $1, $2 );
1507                }
1508        | typedef_declaration
1509        | typedef_expression                                                            // GCC, naming expression type
1510        | sue_declaration_specifier
1511        ;
1512
1513declaring_list:
1514                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1515                // storage-class
1516        declarator asm_name_opt initializer_opt
1517                {
1518                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1519                        $$ = $1->addAsmName( $2 )->addInitializer( $3 );
1520                }
1521        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1522                {
1523                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1524                        $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) );
1525                }
1526        ;
1527
1528declaration_specifier:                                                                  // type specifier + storage class
1529        basic_declaration_specifier
1530        | sue_declaration_specifier
1531        | type_declaration_specifier
1532        ;
1533
1534declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1535                // Preclude SUE declarations in restricted scopes:
1536                //
1537                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1538                //
1539                // because it is impossible to call f due to name equivalence.
1540        basic_declaration_specifier
1541        | sue_declaration_specifier_nobody
1542        | type_declaration_specifier
1543        ;
1544
1545type_specifier:                                                                                 // type specifier
1546        basic_type_specifier
1547        | sue_type_specifier
1548        | type_type_specifier
1549        ;
1550
1551type_specifier_nobody:                                                                  // type specifier - {...}
1552                // Preclude SUE declarations in restricted scopes:
1553                //
1554                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1555                //
1556                // because it is impossible to call f due to name equivalence.
1557        basic_type_specifier
1558        | sue_type_specifier_nobody
1559        | type_type_specifier
1560        ;
1561
1562type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1563        // empty
1564                { $$ = nullptr; }
1565        | type_qualifier_list
1566        ;
1567
1568type_qualifier_list:
1569                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1570                //
1571                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1572                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1573                // appeared only once.
1574        type_qualifier
1575        | type_qualifier_list type_qualifier
1576                { $$ = $1->addQualifiers( $2 ); }
1577        ;
1578
1579type_qualifier:
1580        type_qualifier_name
1581        | attribute
1582        ;
1583
1584type_qualifier_name:
1585        CONST
1586                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1587        | RESTRICT
1588                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1589        | VOLATILE
1590                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1591        | ATOMIC
1592                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1593        | forall
1594        ;
1595
1596forall:
1597        FORALL '('
1598                {
1599                        typedefTable.enterScope();
1600                }
1601          type_parameter_list ')'                                                       // CFA
1602                {
1603                        typedefTable.leaveScope();
1604                        $$ = DeclarationNode::newForall( $4 );
1605                }
1606        ;
1607
1608declaration_qualifier_list:
1609        storage_class_list
1610        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1611                { $$ = $1->addQualifiers( $2 ); }
1612        | declaration_qualifier_list type_qualifier_list storage_class_list
1613                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1614        ;
1615
1616storage_class_list:
1617                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1618                // only one of each is specified, except for inline, which can appear with the others.
1619                //
1620                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1621                // specifiers in a declaration.
1622        storage_class
1623        | storage_class_list storage_class
1624                { $$ = $1->addQualifiers( $2 ); }
1625        ;
1626
1627storage_class:
1628        EXTERN
1629                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1630        | STATIC
1631                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1632        | AUTO
1633                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1634        | REGISTER
1635                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1636        | THREADLOCAL                                                                           // C11
1637                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1638                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1639        | INLINE                                                                                        // C99
1640                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1641        | FORTRAN                                                                                       // C99
1642                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1643        | NORETURN                                                                                      // C11
1644                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1645        ;
1646
1647basic_type_name:
1648        VOID
1649                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1650        | BOOL                                                                                          // C99
1651                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1652        | CHAR
1653                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1654        | INT
1655                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1656        | INT128
1657                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1658        | FLOAT
1659                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1660        | FLOAT80
1661                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float80 ); }
1662        | FLOAT128
1663                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float128 ); }
1664        | DOUBLE
1665                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1666        | COMPLEX                                                                                       // C99
1667                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1668        | IMAGINARY                                                                                     // C99
1669                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1670        | SIGNED
1671                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1672        | UNSIGNED
1673                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1674        | SHORT
1675                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1676        | LONG
1677                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1678        | ZERO_T
1679                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1680        | ONE_T
1681                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1682        | VALIST                                                                                        // GCC, __builtin_va_list
1683                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1684        ;
1685
1686basic_declaration_specifier:
1687                // A semantic check is necessary for conflicting storage classes.
1688        basic_type_specifier
1689        | declaration_qualifier_list basic_type_specifier
1690                { $$ = $2->addQualifiers( $1 ); }
1691        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1692                { $$ = $1->addQualifiers( $2 ); }
1693        | basic_declaration_specifier storage_class type_qualifier_list
1694                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1695        | basic_declaration_specifier storage_class basic_type_specifier
1696                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1697        ;
1698
1699basic_type_specifier:
1700        direct_type
1701        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1702                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1703        ;
1704
1705direct_type:
1706                // A semantic check is necessary for conflicting type qualifiers.
1707        basic_type_name
1708        | type_qualifier_list basic_type_name
1709                { $$ = $2->addQualifiers( $1 ); }
1710        | direct_type type_qualifier
1711                { $$ = $1->addQualifiers( $2 ); }
1712        | direct_type basic_type_name
1713                { $$ = $1->addType( $2 ); }
1714        ;
1715
1716indirect_type:
1717        TYPEOF '(' type ')'                                                                     // GCC: typeof(x) y;
1718                { $$ = $3; }
1719        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1720                { $$ = DeclarationNode::newTypeof( $3 ); }
1721        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type(x) y;
1722                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1723        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1724                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1725        ;
1726
1727sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1728        sue_type_specifier
1729        | declaration_qualifier_list sue_type_specifier
1730                { $$ = $2->addQualifiers( $1 ); }
1731        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1732                { $$ = $1->addQualifiers( $2 ); }
1733        | sue_declaration_specifier storage_class type_qualifier_list
1734                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1735        ;
1736
1737sue_type_specifier:                                                                             // struct, union, enum + type specifier
1738        elaborated_type
1739        | type_qualifier_list
1740                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1741          elaborated_type
1742                { $$ = $3->addQualifiers( $1 ); }
1743        | sue_type_specifier type_qualifier
1744                { $$ = $1->addQualifiers( $2 ); }
1745        ;
1746
1747sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1748        sue_type_specifier_nobody
1749        | declaration_qualifier_list sue_type_specifier_nobody
1750                { $$ = $2->addQualifiers( $1 ); }
1751        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1752                { $$ = $1->addQualifiers( $2 ); }
1753        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1754                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1755        ;
1756
1757sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1758        elaborated_type_nobody
1759        | type_qualifier_list elaborated_type_nobody
1760                { $$ = $2->addQualifiers( $1 ); }
1761        | sue_type_specifier_nobody type_qualifier
1762                { $$ = $1->addQualifiers( $2 ); }
1763        ;
1764
1765type_declaration_specifier:
1766        type_type_specifier
1767        | declaration_qualifier_list type_type_specifier
1768                { $$ = $2->addQualifiers( $1 ); }
1769        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1770                { $$ = $1->addQualifiers( $2 ); }
1771        | type_declaration_specifier storage_class type_qualifier_list
1772                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1773        ;
1774
1775type_type_specifier:                                                                    // typedef types
1776        type_name
1777        | type_qualifier_list type_name
1778                { $$ = $2->addQualifiers( $1 ); }
1779        | type_type_specifier type_qualifier
1780                { $$ = $1->addQualifiers( $2 ); }
1781        ;
1782
1783type_name:
1784        TYPEDEFname
1785                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1786        | '.' TYPEDEFname
1787                { $$ = DeclarationNode::newFromTypedef( $2 ); } // FIX ME
1788        | type_name '.' TYPEDEFname
1789                { $$ = DeclarationNode::newFromTypedef( $3 ); } // FIX ME
1790        | typegen_name
1791        | '.' typegen_name
1792                { $$ = $2; }                                                                    // FIX ME
1793        | type_name '.' typegen_name
1794                { $$ = $3; }                                                                    // FIX ME
1795        ;
1796
1797typegen_name:                                                                                   // CFA
1798        TYPEGENname
1799                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1800        | TYPEGENname '(' ')'
1801                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1802        | TYPEGENname '(' type_list ')'
1803                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1804        ;
1805
1806elaborated_type:                                                                                // struct, union, enum
1807        aggregate_type
1808        | enum_type
1809        ;
1810
1811elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1812        aggregate_type_nobody
1813        | enum_type_nobody
1814        ;
1815
1816aggregate_type:                                                                                 // struct, union
1817        aggregate_key attribute_list_opt '{' field_declaration_list '}'
1818                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), nullptr, $4, true )->addQualifiers( $2 ); }
1819        | aggregate_key attribute_list_opt no_attr_identifier_or_type_name
1820                {
1821                        typedefTable.makeTypedef( *$3 );                        // create typedef
1822                        if ( forall ) typedefTable.changeKind( *$3, TypedefTable::TG ); // possibly update
1823                        forall = false;                                                         // reset
1824                }
1825          '{' field_declaration_list '}'
1826                { $$ = DeclarationNode::newAggregate( $1, $3, nullptr, $6, true )->addQualifiers( $2 ); }
1827        | aggregate_key attribute_list_opt '(' type_list ')' '{' field_declaration_list '}' // CFA
1828                { $$ = DeclarationNode::newAggregate( $1, new string( DeclarationNode::anonymous.newName() ), $4, $7, false )->addQualifiers( $2 ); }
1829        | aggregate_type_nobody
1830        ;
1831
1832aggregate_type_nobody:                                                                  // struct, union - {...}
1833        aggregate_key attribute_list_opt no_attr_identifier
1834                {
1835                        typedefTable.makeTypedef( *$3 );
1836                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1837                }
1838        | aggregate_key attribute_list_opt TYPEDEFname
1839                {
1840                        typedefTable.makeTypedef( *$3 );
1841                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1842                }
1843        | aggregate_key attribute_list_opt typegen_name         // CFA
1844                {
1845                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
1846                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
1847                        // delete newFromTypeGen.
1848                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
1849                        $3->type->symbolic.name = nullptr;
1850                        $3->type->symbolic.actuals = nullptr;
1851                        delete $3;
1852                }
1853        ;
1854
1855aggregate_key:
1856        STRUCT
1857                { $$ = DeclarationNode::Struct; }
1858        | UNION
1859                { $$ = DeclarationNode::Union; }
1860        | COROUTINE
1861                { $$ = DeclarationNode::Coroutine; }
1862        | MONITOR
1863                { $$ = DeclarationNode::Monitor; }
1864        | THREAD
1865                { $$ = DeclarationNode::Thread; }
1866        ;
1867
1868field_declaration_list:
1869        // empty
1870                { $$ = nullptr; }
1871        | field_declaration_list field_declaration
1872                { $$ = $1 ? $1->appendList( $2 ) : $2; }
1873        ;
1874
1875field_declaration:
1876        cfa_field_declaring_list ';'                                            // CFA, new style field declaration
1877        | EXTENSION cfa_field_declaring_list ';'                        // GCC
1878                {
1879                        distExt( $2 );                                                          // mark all fields in list
1880                        $$ = $2;
1881                }
1882        | type_specifier field_declaring_list ';'
1883                {
1884                        $$ = distAttr( $1, $2 ); }
1885        | EXTENSION type_specifier field_declaring_list ';'     // GCC
1886                {
1887                        distExt( $3 );                                                          // mark all fields in list
1888                        $$ = distAttr( $2, $3 );
1889                }
1890        ;
1891
1892cfa_field_declaring_list:                                                               // CFA, new style field declaration
1893        cfa_abstract_declarator_tuple                                           // CFA, no field name
1894        | cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
1895                { $$ = $1->addName( $2 ); }
1896        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
1897                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1898        | cfa_field_declaring_list ','                                          // CFA, no field name
1899                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1900        ;
1901
1902field_declaring_list:
1903        field_declarator
1904        | field_declaring_list ',' attribute_list_opt field_declarator
1905                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
1906        ;
1907
1908field_declarator:
1909        // empty
1910                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1911        // '@'
1912        //      { $$ = DeclarationNode::newName( new string( DeclarationNode::anonymous.newName() ) ); } // CFA, no field name
1913        | bit_subrange_size                                                                     // no field name
1914                { $$ = DeclarationNode::newBitfield( $1 ); }
1915        | variable_declarator bit_subrange_size_opt
1916                // A semantic check is required to ensure bit_subrange only appears on base type int.
1917                { $$ = $1->addBitfield( $2 ); }
1918        | variable_type_redeclarator bit_subrange_size_opt
1919                // A semantic check is required to ensure bit_subrange only appears on base type int.
1920                { $$ = $1->addBitfield( $2 ); }
1921        | variable_abstract_declarator                                          // CFA, no field name
1922        ;
1923
1924bit_subrange_size_opt:
1925        // empty
1926                { $$ = nullptr; }
1927        | bit_subrange_size
1928                { $$ = $1; }
1929        ;
1930
1931bit_subrange_size:
1932        ':' constant_expression
1933                { $$ = $2; }
1934        ;
1935
1936enum_type:                                                                                              // enum
1937        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
1938                { $$ = DeclarationNode::newEnum( new string( DeclarationNode::anonymous.newName() ), $4, true )->addQualifiers( $2 ); }
1939        | ENUM attribute_list_opt no_attr_identifier_or_type_name
1940                { typedefTable.makeTypedef( *$3 ); }
1941          '{' enumerator_list comma_opt '}'
1942                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
1943        | enum_type_nobody
1944        ;
1945
1946enum_type_nobody:                                                                               // enum - {...}
1947        ENUM attribute_list_opt no_attr_identifier_or_type_name
1948                {
1949                        typedefTable.makeTypedef( *$3 );
1950                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
1951                }
1952        ;
1953
1954enumerator_list:
1955        no_attr_identifier_or_type_name enumerator_value_opt
1956                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1957        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1958                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1959        ;
1960
1961enumerator_value_opt:
1962        // empty
1963                { $$ = nullptr; }
1964        | '=' constant_expression
1965                { $$ = $2; }
1966        ;
1967
1968// Minimum of one parameter after which ellipsis is allowed only at the end.
1969
1970cfa_parameter_type_list_opt:                                                    // CFA
1971        // empty
1972                { $$ = nullptr; }
1973        | cfa_parameter_type_list
1974        ;
1975
1976cfa_parameter_type_list:                                                                // CFA, abstract + real
1977        cfa_abstract_parameter_list
1978        | cfa_parameter_list
1979        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
1980                { $$ = $1->appendList( $5 ); }
1981        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
1982                { $$ = $1->addVarArgs(); }
1983        | cfa_parameter_list pop ',' push ELLIPSIS
1984                { $$ = $1->addVarArgs(); }
1985        ;
1986
1987cfa_parameter_list:                                                                             // CFA
1988                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
1989                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
1990        cfa_parameter_declaration
1991        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
1992                { $$ = $1->appendList( $5 ); }
1993        | cfa_parameter_list pop ',' push cfa_parameter_declaration
1994                { $$ = $1->appendList( $5 ); }
1995        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
1996                { $$ = $1->appendList( $5 )->appendList( $9 ); }
1997        ;
1998
1999cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2000        cfa_abstract_parameter_declaration
2001        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2002                { $$ = $1->appendList( $5 ); }
2003        ;
2004
2005parameter_type_list_opt:
2006        // empty
2007                { $$ = nullptr; }
2008        | parameter_type_list
2009        ;
2010
2011parameter_type_list:
2012        parameter_list
2013        | parameter_list pop ',' push ELLIPSIS
2014                { $$ = $1->addVarArgs(); }
2015        ;
2016
2017parameter_list:                                                                                 // abstract + real
2018        abstract_parameter_declaration
2019        | parameter_declaration
2020        | parameter_list pop ',' push abstract_parameter_declaration
2021                { $$ = $1->appendList( $5 ); }
2022        | parameter_list pop ',' push parameter_declaration
2023                { $$ = $1->appendList( $5 ); }
2024        ;
2025
2026// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2027// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2028
2029cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2030        parameter_declaration
2031        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2032                { $$ = $1->addName( $2 ); }
2033        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2034                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2035                { $$ = $1->addName( $2 ); }
2036        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2037                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2038        | cfa_function_specifier
2039        ;
2040
2041cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2042        abstract_parameter_declaration
2043        | cfa_identifier_parameter_declarator_no_tuple
2044        | cfa_abstract_tuple
2045                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2046        | type_qualifier_list cfa_abstract_tuple
2047                { $$ = $2->addQualifiers( $1 ); }
2048        | cfa_abstract_function
2049        ;
2050
2051parameter_declaration:
2052                // No SUE declaration in parameter list.
2053        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2054                {
2055                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2056                        $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr );
2057                }
2058        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2059                {
2060                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2061                        $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr );
2062                }
2063        ;
2064
2065abstract_parameter_declaration:
2066        declaration_specifier_nobody default_initialize_opt
2067                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2068        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2069                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2070        ;
2071
2072// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2073// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2074// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2075
2076identifier_list:                                                                                // K&R-style parameter list => no types
2077        no_attr_identifier
2078                { $$ = DeclarationNode::newName( $1 ); }
2079        | identifier_list ',' no_attr_identifier
2080                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2081        ;
2082
2083identifier_or_type_name:
2084        identifier
2085        | TYPEDEFname
2086        | TYPEGENname
2087        ;
2088
2089no_attr_identifier_or_type_name:
2090        no_attr_identifier
2091        | TYPEDEFname
2092        | TYPEGENname
2093        ;
2094
2095type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2096        cfa_abstract_declarator_tuple                                           // CFA
2097        | type_specifier
2098        | type_specifier abstract_declarator
2099                { $$ = $2->addType( $1 ); }
2100        ;
2101
2102type:                                                                                                   // typeof, assertion
2103        type_no_function
2104        | cfa_abstract_function                                                         // CFA
2105        ;
2106
2107initializer_opt:
2108        // empty
2109                { $$ = nullptr; }
2110        | '=' initializer
2111                { $$ = $2; }
2112        | '=' VOID
2113                { $$ = nullptr; }
2114        | ATassign initializer
2115                { $$ = $2->set_maybeConstructed( false ); }
2116        ;
2117
2118initializer:
2119        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2120        | '{' initializer_list comma_opt '}'            { $$ = new InitializerNode( $2, true ); }
2121        ;
2122
2123initializer_list:
2124        // empty
2125                { $$ = nullptr; }
2126        | initializer
2127        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2128        | initializer_list ',' initializer                      { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2129        | initializer_list ',' designation initializer
2130                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2131        ;
2132
2133// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2134// '=' to separator the designator from the initializer value, as in:
2135//
2136//              int x[10] = { [1] = 3 };
2137//
2138// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2139// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2140// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2141// shift/reduce conflicts
2142
2143designation:
2144        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2145        | no_attr_identifier ':'                                                        // GCC, field name
2146                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2147        ;
2148
2149designator_list:                                                                                // C99
2150        designator
2151        | designator_list designator
2152                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2153        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2154        ;
2155
2156designator:
2157        '.' no_attr_identifier                                                          // C99, field name
2158                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2159        | '[' push assignment_expression pop ']'                        // C99, single array element
2160                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2161                { $$ = $3; }
2162        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2163                { $$ = $3; }
2164        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2165                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2166        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
2167                { $$ = $4; }
2168        ;
2169
2170// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2171// rather than an object-oriented type system. This required four groups of extensions:
2172//
2173// Overloading: function, data, and operator identifiers may be overloaded.
2174//
2175// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2176//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2177//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2178//
2179// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2180//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2181//
2182// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2183//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2184//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2185//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2186//     on type arguments of polymorphic functions.
2187
2188type_parameter_list:                                                                    // CFA
2189        type_parameter
2190                { $$ = $1; }
2191        | type_parameter_list ',' type_parameter
2192                { $$ = $1->appendList( $3 ); }
2193        ;
2194
2195type_initializer_opt:                                                                   // CFA
2196        // empty
2197                { $$ = nullptr; }
2198        | '=' type
2199                { $$ = $2; }
2200        ;
2201
2202type_parameter:                                                                                 // CFA
2203        type_class no_attr_identifier_or_type_name
2204                { typedefTable.addToEnclosingScope( *$2, TypedefTable::TD ); }
2205          type_initializer_opt assertion_list_opt
2206                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2207        | type_specifier identifier_parameter_declarator
2208        ;
2209
2210type_class:                                                                                             // CFA
2211        OTYPE
2212                { $$ = DeclarationNode::Otype; }
2213        | DTYPE
2214                { $$ = DeclarationNode::Dtype; }
2215        | FTYPE
2216                { $$ = DeclarationNode::Ftype; }
2217        | TTYPE
2218                { $$ = DeclarationNode::Ttype; }
2219        ;
2220
2221assertion_list_opt:                                                                             // CFA
2222        // empty
2223                { $$ = nullptr; }
2224        | assertion_list_opt assertion
2225                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2226        ;
2227
2228assertion:                                                                                              // CFA
2229        '|' no_attr_identifier_or_type_name '(' type_list ')'
2230                {
2231                        typedefTable.openTrait( *$2 );
2232                        $$ = DeclarationNode::newTraitUse( $2, $4 );
2233                }
2234        | '|' '{' push trait_declaration_list '}'
2235                { $$ = $4; }
2236        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_list ')'
2237                { $$ = nullptr; }
2238        ;
2239
2240type_list:                                                                                              // CFA
2241        type
2242                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2243        | assignment_expression
2244        | type_list ',' type
2245                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2246        | type_list ',' assignment_expression
2247                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2248        ;
2249
2250type_declaring_list:                                                                    // CFA
2251        OTYPE type_declarator
2252                { $$ = $2; }
2253        | storage_class_list OTYPE type_declarator
2254                { $$ = $3->addQualifiers( $1 ); }
2255        | type_declaring_list ',' type_declarator
2256                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2257        ;
2258
2259type_declarator:                                                                                // CFA
2260        type_declarator_name assertion_list_opt
2261                { $$ = $1->addAssertions( $2 ); }
2262        | type_declarator_name assertion_list_opt '=' type
2263                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2264        ;
2265
2266type_declarator_name:                                                                   // CFA
2267        no_attr_identifier_or_type_name
2268                {
2269                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TD );
2270                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2271                }
2272        | no_attr_identifier_or_type_name '(' push type_parameter_list pop ')'
2273                {
2274                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TG );
2275                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
2276                }
2277        ;
2278
2279trait_specifier:                                                                                // CFA
2280        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
2281                {
2282                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
2283                        $$ = DeclarationNode::newTrait( $2, $5, 0 );
2284                }
2285        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
2286                {
2287                        typedefTable.enterTrait( *$2 );
2288                        typedefTable.enterScope();
2289                }
2290          trait_declaration_list '}'
2291                {
2292                        typedefTable.leaveTrait();
2293                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
2294                        $$ = DeclarationNode::newTrait( $2, $5, $10 );
2295                }
2296        ;
2297
2298trait_declaration_list:                                                                 // CFA
2299        trait_declaration
2300        | trait_declaration_list push trait_declaration
2301                { $$ = $1->appendList( $3 ); }
2302        ;
2303
2304trait_declaration:                                                                              // CFA
2305        cfa_trait_declaring_list pop ';'
2306        | trait_declaring_list pop ';'
2307        ;
2308
2309cfa_trait_declaring_list:                                                               // CFA
2310        cfa_variable_specifier
2311                {
2312                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2313                        $$ = $1;
2314                }
2315        | cfa_function_specifier
2316                {
2317                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2318                        $$ = $1;
2319                }
2320        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2321                {
2322                        typedefTable.addToEnclosingScope2( *$5, TypedefTable::ID );
2323                        $$ = $1->appendList( $1->cloneType( $5 ) );
2324                }
2325        ;
2326
2327trait_declaring_list:                                                                   // CFA
2328        type_specifier declarator
2329                {
2330                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2331                        $$ = $2->addType( $1 );
2332                }
2333        | trait_declaring_list pop ',' push declarator
2334                {
2335                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
2336                        $$ = $1->appendList( $1->cloneBaseType( $5 ) );
2337                }
2338        ;
2339
2340//***************************** EXTERNAL DEFINITIONS *****************************
2341
2342translation_unit:
2343        // empty
2344                {}                                                                                              // empty input file
2345        | external_definition_list
2346                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2347        ;
2348
2349external_definition_list:
2350        external_definition
2351        | external_definition_list push external_definition
2352                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2353        ;
2354
2355external_definition_list_opt:
2356        // empty
2357                { $$ = nullptr; }
2358        | external_definition_list
2359        ;
2360
2361external_definition:
2362        declaration
2363        | external_function_definition
2364        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2365                {
2366                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asmstmt( false, $3, 0 ) ) );
2367                }
2368        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2369                {
2370                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2371                        linkage = LinkageSpec::linkageUpdate( linkage, $2 );
2372                }
2373          '{' external_definition_list_opt '}'
2374                {
2375                        linkage = linkageStack.top();
2376                        linkageStack.pop();
2377                        $$ = $5;
2378                }
2379        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2380                {
2381                        distExt( $2 );                                                          // mark all fields in list
2382                        $$ = $2;
2383                }
2384        | forall '{' external_definition_list '}'                       // CFA, namespace
2385        ;
2386
2387external_function_definition:
2388        function_definition
2389                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2390                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2391                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2392                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2393                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2394        | function_declarator compound_statement
2395                {
2396                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2397                        typedefTable.leaveScope();
2398                        $$ = $1->addFunctionBody( $2 );
2399                }
2400        | KR_function_declarator KR_declaration_list_opt compound_statement
2401                {
2402                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2403                        typedefTable.leaveScope();
2404                        $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 );
2405                }
2406        ;
2407
2408with_clause_opt:
2409        // empty
2410                { $$ = nullptr; }
2411        | WITH '(' tuple_expression_list ')'
2412                { throw SemanticError("With clause is currently unimplemented."); $$ = nullptr; } // FIX ME
2413        ;
2414
2415function_definition:
2416        cfa_function_declaration with_clause_opt compound_statement     // CFA
2417                {
2418                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2419                        typedefTable.leaveScope();
2420                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2421                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2422                        $1->get_last()->addFunctionBody( $3 );
2423                        $$ = $1;
2424                }
2425        | declaration_specifier function_declarator with_clause_opt compound_statement
2426                {
2427                        rebindForall( $1, $2 );
2428                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2429                        typedefTable.leaveScope();
2430                        $$ = $2->addFunctionBody( $4 )->addType( $1 );
2431                }
2432                // handles default int return type, OBSOLESCENT (see 1)
2433        | type_qualifier_list function_declarator with_clause_opt compound_statement
2434                {
2435                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2436                        typedefTable.leaveScope();
2437                        $$ = $2->addFunctionBody( $4 )->addQualifiers( $1 );
2438                }
2439                // handles default int return type, OBSOLESCENT (see 1)
2440        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2441                {
2442                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2443                        typedefTable.leaveScope();
2444                        $$ = $2->addFunctionBody( $4 )->addQualifiers( $1 );
2445                }
2446                // handles default int return type, OBSOLESCENT (see 1)
2447        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2448                {
2449                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2450                        typedefTable.leaveScope();
2451                        $$ = $3->addFunctionBody( $5 )->addQualifiers( $2 )->addQualifiers( $1 );
2452                }
2453
2454                // Old-style K&R function definition, OBSOLESCENT (see 4)
2455        | declaration_specifier KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2456                {
2457                        rebindForall( $1, $2 );
2458                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2459                        typedefTable.leaveScope();
2460                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5 )->addType( $1 );
2461                }
2462                // handles default int return type, OBSOLESCENT (see 1)
2463        | type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2464                {
2465                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2466                        typedefTable.leaveScope();
2467                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5 )->addQualifiers( $1 );
2468                }
2469                // handles default int return type, OBSOLESCENT (see 1)
2470        | declaration_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2471                {
2472                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2473                        typedefTable.leaveScope();
2474                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5 )->addQualifiers( $1 );
2475                }
2476                // handles default int return type, OBSOLESCENT (see 1)
2477        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_declaration_list_opt with_clause_opt compound_statement
2478                {
2479                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2480                        typedefTable.leaveScope();
2481                        $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6 )->addQualifiers( $2 )->addQualifiers( $1 );
2482                }
2483        ;
2484
2485declarator:
2486        variable_declarator
2487        | variable_type_redeclarator
2488        | function_declarator
2489        ;
2490
2491subrange:
2492        constant_expression '~' constant_expression                     // CFA, integer subrange
2493                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2494        ;
2495
2496asm_name_opt:                                                                                   // GCC
2497        // empty
2498                { $$ = nullptr; }
2499        | ASM '(' string_literal ')' attribute_list_opt
2500                {
2501                        DeclarationNode * name = new DeclarationNode();
2502                        name->asmName = $3;
2503                        $$ = name->addQualifiers( $5 );
2504                }
2505        ;
2506
2507attribute_list_opt:                                                                             // GCC
2508        // empty
2509                { $$ = nullptr; }
2510        | attribute_list
2511        ;
2512
2513attribute_list:                                                                                 // GCC
2514        attribute
2515        | attribute_list attribute
2516                { $$ = $2->addQualifiers( $1 ); }
2517        ;
2518
2519attribute:                                                                                              // GCC
2520        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2521                { $$ = $4; }
2522        ;
2523
2524attribute_name_list:                                                                    // GCC
2525        attribute_name
2526        | attribute_name_list ',' attribute_name
2527                { $$ = $3->addQualifiers( $1 ); }
2528        ;
2529
2530attribute_name:                                                                                 // GCC
2531        // empty
2532                { $$ = nullptr; }
2533        | attr_name
2534                { $$ = DeclarationNode::newAttribute( $1 ); }
2535        | attr_name '(' argument_expression_list ')'
2536                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2537        ;
2538
2539attr_name:                                                                                              // GCC
2540        IDENTIFIER
2541        | quasi_keyword
2542        | TYPEDEFname
2543        | TYPEGENname
2544        | FALLTHROUGH
2545                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2546        | CONST
2547                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2548        ;
2549
2550// ============================================================================
2551// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2552// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2553// in:
2554//
2555//              int (*f())[10] { ... };
2556//              ... (*f())[3] += 1;             // definition mimics usage
2557//
2558// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2559// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2560// ============================================================================
2561
2562// ----------------------------------------------------------------------------
2563// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2564// to define a variable or function prototype, e.g.:
2565//
2566//              valid declaration               invalid definition
2567//              -----------------               ------------------
2568//              int f;                                  int f {}
2569//              int *f;                                 int *f {}
2570//              int f[10];                              int f[10] {}
2571//              int (*f)(int);                  int (*f)(int) {}
2572//
2573// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2574// variable_declarator and function_declarator.
2575// ----------------------------------------------------------------------------
2576
2577// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2578// declaring an array of functions versus a pointer to an array of functions.
2579
2580variable_declarator:
2581        paren_identifier attribute_list_opt
2582                { $$ = $1->addQualifiers( $2 ); }
2583        | variable_ptr
2584        | variable_array attribute_list_opt
2585                { $$ = $1->addQualifiers( $2 ); }
2586        | variable_function attribute_list_opt
2587                { $$ = $1->addQualifiers( $2 ); }
2588        ;
2589
2590paren_identifier:
2591        identifier
2592                {
2593                        typedefTable.setNextIdentifier( *$1 );
2594                        $$ = DeclarationNode::newName( $1 );
2595                }
2596        | '(' paren_identifier ')'                                                      // redundant parenthesis
2597                { $$ = $2; }
2598        ;
2599
2600variable_ptr:
2601        ptrref_operator variable_declarator
2602                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2603        | ptrref_operator type_qualifier_list variable_declarator
2604                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2605        | '(' variable_ptr ')' attribute_list_opt
2606                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2607        ;
2608
2609variable_array:
2610        paren_identifier array_dimension
2611                { $$ = $1->addArray( $2 ); }
2612        | '(' variable_ptr ')' array_dimension
2613                { $$ = $2->addArray( $4 ); }
2614        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2615                { $$ = $2->addArray( $4 ); }
2616        | '(' variable_array ')'                                                        // redundant parenthesis
2617                { $$ = $2; }
2618        ;
2619
2620variable_function:
2621        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2622                { $$ = $2->addParamList( $6 ); }
2623        | '(' variable_function ')'                                                     // redundant parenthesis
2624                { $$ = $2; }
2625        ;
2626
2627// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2628// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2629// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2630
2631function_declarator:
2632        function_no_ptr attribute_list_opt
2633                { $$ = $1->addQualifiers( $2 ); }
2634        | function_ptr
2635        | function_array attribute_list_opt
2636                { $$ = $1->addQualifiers( $2 ); }
2637        ;
2638
2639function_no_ptr:
2640        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2641                { $$ = $1->addParamList( $4 ); }
2642        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2643                { $$ = $2->addParamList( $6 ); }
2644        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2645                { $$ = $2; }
2646        ;
2647
2648function_ptr:
2649        ptrref_operator function_declarator
2650                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2651        | ptrref_operator type_qualifier_list function_declarator
2652                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2653        | '(' function_ptr ')'
2654                { $$ = $2; }
2655        ;
2656
2657function_array:
2658        '(' function_ptr ')' array_dimension
2659                { $$ = $2->addArray( $4 ); }
2660        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2661                { $$ = $2->addArray( $4 ); }
2662        | '(' function_array ')'                                                        // redundant parenthesis
2663                { $$ = $2; }
2664        ;
2665
2666// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2667//
2668//   f( a, b, c ) int a, *b, c[]; {}
2669//
2670// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2671// returning arrays and functions versus pointers to arrays and functions.
2672
2673KR_function_declarator:
2674        KR_function_no_ptr
2675        | KR_function_ptr
2676        | KR_function_array
2677        ;
2678
2679KR_function_no_ptr:
2680        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2681                { $$ = $1->addIdList( $3 ); }
2682        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2683                { $$ = $2->addParamList( $6 ); }
2684        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2685                { $$ = $2; }
2686        ;
2687
2688KR_function_ptr:
2689        ptrref_operator KR_function_declarator
2690                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2691        | ptrref_operator type_qualifier_list KR_function_declarator
2692                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2693        | '(' KR_function_ptr ')'
2694                { $$ = $2; }
2695        ;
2696
2697KR_function_array:
2698        '(' KR_function_ptr ')' array_dimension
2699                { $$ = $2->addArray( $4 ); }
2700        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2701                { $$ = $2->addArray( $4 ); }
2702        | '(' KR_function_array ')'                                                     // redundant parenthesis
2703                { $$ = $2; }
2704        ;
2705
2706// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2707//
2708//              typedef int foo;
2709//              {
2710//                 int foo; // redefine typedef name in new scope
2711//              }
2712//
2713// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2714// and functions versus pointers to arrays and functions.
2715
2716variable_type_redeclarator:
2717        paren_type attribute_list_opt
2718                { $$ = $1->addQualifiers( $2 ); }
2719        | type_ptr
2720        | type_array attribute_list_opt
2721                { $$ = $1->addQualifiers( $2 ); }
2722        | type_function attribute_list_opt
2723                { $$ = $1->addQualifiers( $2 ); }
2724        ;
2725
2726paren_type:
2727        typedef
2728        | '(' paren_type ')'
2729                { $$ = $2; }
2730        ;
2731
2732type_ptr:
2733        ptrref_operator variable_type_redeclarator
2734                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2735        | ptrref_operator type_qualifier_list variable_type_redeclarator
2736                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2737        | '(' type_ptr ')' attribute_list_opt
2738                { $$ = $2->addQualifiers( $4 ); }
2739        ;
2740
2741type_array:
2742        paren_type array_dimension
2743                { $$ = $1->addArray( $2 ); }
2744        | '(' type_ptr ')' array_dimension
2745                { $$ = $2->addArray( $4 ); }
2746        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2747                { $$ = $2->addArray( $4 ); }
2748        | '(' type_array ')'                                                            // redundant parenthesis
2749                { $$ = $2; }
2750        ;
2751
2752type_function:
2753        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2754                { $$ = $1->addParamList( $4 ); }
2755        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2756                { $$ = $2->addParamList( $6 ); }
2757        | '(' type_function ')'                                                         // redundant parenthesis
2758                { $$ = $2; }
2759        ;
2760
2761// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2762// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2763// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2764// pointers to arrays and functions.
2765
2766identifier_parameter_declarator:
2767        paren_identifier attribute_list_opt
2768                { $$ = $1->addQualifiers( $2 ); }
2769        | '&' MUTEX paren_identifier attribute_list_opt
2770                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2771        | identifier_parameter_ptr
2772        | identifier_parameter_array attribute_list_opt
2773                { $$ = $1->addQualifiers( $2 ); }
2774        | identifier_parameter_function attribute_list_opt
2775                { $$ = $1->addQualifiers( $2 ); }
2776        ;
2777
2778identifier_parameter_ptr:
2779        ptrref_operator identifier_parameter_declarator
2780                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2781        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2782                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2783        | '(' identifier_parameter_ptr ')' attribute_list_opt
2784                { $$ = $2->addQualifiers( $4 ); }
2785        ;
2786
2787identifier_parameter_array:
2788        paren_identifier array_parameter_dimension
2789                { $$ = $1->addArray( $2 ); }
2790        | '(' identifier_parameter_ptr ')' array_dimension
2791                { $$ = $2->addArray( $4 ); }
2792        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2793                { $$ = $2->addArray( $4 ); }
2794        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2795                { $$ = $2; }
2796        ;
2797
2798identifier_parameter_function:
2799        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2800                { $$ = $1->addParamList( $4 ); }
2801        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2802                { $$ = $2->addParamList( $6 ); }
2803        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2804                { $$ = $2; }
2805        ;
2806
2807// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2808// e.g.:
2809//
2810//              typedef int foo;
2811//              forall( otype T ) struct foo;
2812//              int f( int foo ); // redefine typedef name in new scope
2813//
2814// and allows the C99 array options, which can only appear in a parameter list.
2815
2816type_parameter_redeclarator:
2817        typedef attribute_list_opt
2818                { $$ = $1->addQualifiers( $2 ); }
2819        | '&' MUTEX typedef attribute_list_opt
2820                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2821        | type_parameter_ptr
2822        | type_parameter_array attribute_list_opt
2823                { $$ = $1->addQualifiers( $2 ); }
2824        | type_parameter_function attribute_list_opt
2825                { $$ = $1->addQualifiers( $2 ); }
2826        ;
2827
2828typedef:
2829        TYPEDEFname
2830                {
2831                        typedefTable.setNextIdentifier( *$1 );
2832                        $$ = DeclarationNode::newName( $1 );
2833                }
2834        | TYPEGENname
2835                {
2836                        typedefTable.setNextIdentifier( *$1 );
2837                        $$ = DeclarationNode::newName( $1 );
2838                }
2839        ;
2840
2841type_parameter_ptr:
2842        ptrref_operator type_parameter_redeclarator
2843                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2844        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2845                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2846        | '(' type_parameter_ptr ')' attribute_list_opt
2847                { $$ = $2->addQualifiers( $4 ); }
2848        ;
2849
2850type_parameter_array:
2851        typedef array_parameter_dimension
2852                { $$ = $1->addArray( $2 ); }
2853        | '(' type_parameter_ptr ')' array_parameter_dimension
2854                { $$ = $2->addArray( $4 ); }
2855        ;
2856
2857type_parameter_function:
2858        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2859                { $$ = $1->addParamList( $4 ); }
2860        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2861                { $$ = $2->addParamList( $6 ); }
2862        ;
2863
2864// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2865// which the type applies, e.g.:
2866//
2867//              sizeof( int );
2868//              sizeof( int * );
2869//              sizeof( int [10] );
2870//              sizeof( int (*)() );
2871//              sizeof( int () );
2872//
2873// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2874// and functions versus pointers to arrays and functions.
2875
2876abstract_declarator:
2877        abstract_ptr
2878        | abstract_array attribute_list_opt
2879                { $$ = $1->addQualifiers( $2 ); }
2880        | abstract_function attribute_list_opt
2881                { $$ = $1->addQualifiers( $2 ); }
2882        ;
2883
2884abstract_ptr:
2885        ptrref_operator
2886                { $$ = DeclarationNode::newPointer( 0, $1 ); }
2887        | ptrref_operator type_qualifier_list
2888                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2889        | ptrref_operator abstract_declarator
2890                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2891        | ptrref_operator type_qualifier_list abstract_declarator
2892                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2893        | '(' abstract_ptr ')' attribute_list_opt
2894                { $$ = $2->addQualifiers( $4 ); }
2895        ;
2896
2897abstract_array:
2898        array_dimension
2899        | '(' abstract_ptr ')' array_dimension
2900                { $$ = $2->addArray( $4 ); }
2901        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2902                { $$ = $2->addArray( $4 ); }
2903        | '(' abstract_array ')'                                                        // redundant parenthesis
2904                { $$ = $2; }
2905        ;
2906
2907abstract_function:
2908        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2909                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
2910        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2911                { $$ = $2->addParamList( $6 ); }
2912        | '(' abstract_function ')'                                                     // redundant parenthesis
2913                { $$ = $2; }
2914        ;
2915
2916array_dimension:
2917                // Only the first dimension can be empty.
2918        '[' ']'
2919                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2920        | '[' ']' multi_array_dimension
2921                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2922        | multi_array_dimension
2923        ;
2924
2925multi_array_dimension:
2926        '[' push assignment_expression pop ']'
2927                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2928        | '[' push '*' pop ']'                                                          // C99
2929                { $$ = DeclarationNode::newVarArray( 0 ); }
2930        | multi_array_dimension '[' push assignment_expression pop ']'
2931                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2932        | multi_array_dimension '[' push '*' pop ']'            // C99
2933                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2934        ;
2935
2936// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2937// identifier to which the type applies, e.g.:
2938//
2939//              int f( int );                   // not handled here
2940//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
2941//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
2942//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2943//
2944// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2945// and functions versus pointers to arrays and functions. In addition, the pattern handles the
2946// special meaning of parenthesis around a typedef name:
2947//
2948//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2949//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2950//              not as redundant parentheses around the identifier."
2951//
2952// For example:
2953//
2954//              typedef float T;
2955//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2956//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2957//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2958//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2959//
2960// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2961// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2962// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2963// functions.
2964
2965abstract_parameter_declarator:
2966        abstract_parameter_ptr
2967        | '&' MUTEX attribute_list_opt
2968                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
2969        | abstract_parameter_array attribute_list_opt
2970                { $$ = $1->addQualifiers( $2 ); }
2971        | abstract_parameter_function attribute_list_opt
2972                { $$ = $1->addQualifiers( $2 ); }
2973        ;
2974
2975abstract_parameter_ptr:
2976        ptrref_operator
2977                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
2978        | ptrref_operator type_qualifier_list
2979                { $$ = DeclarationNode::newPointer( $2, $1 ); }
2980        | ptrref_operator abstract_parameter_declarator
2981                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
2982        | ptrref_operator type_qualifier_list abstract_parameter_declarator
2983                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2984        | '(' abstract_parameter_ptr ')' attribute_list_opt
2985                { $$ = $2->addQualifiers( $4 ); }
2986        ;
2987
2988abstract_parameter_array:
2989        array_parameter_dimension
2990        | '(' abstract_parameter_ptr ')' array_parameter_dimension
2991                { $$ = $2->addArray( $4 ); }
2992        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2993                { $$ = $2->addArray( $4 ); }
2994        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
2995                { $$ = $2; }
2996        ;
2997
2998abstract_parameter_function:
2999        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3000                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3001        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3002                { $$ = $2->addParamList( $6 ); }
3003        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3004                { $$ = $2; }
3005        ;
3006
3007array_parameter_dimension:
3008                // Only the first dimension can be empty or have qualifiers.
3009        array_parameter_1st_dimension
3010        | array_parameter_1st_dimension multi_array_dimension
3011                { $$ = $1->addArray( $2 ); }
3012        | multi_array_dimension
3013        ;
3014
3015// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3016//
3017//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3018//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3019
3020array_parameter_1st_dimension:
3021        '[' ']'
3022                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3023        // multi_array_dimension handles the '[' '*' ']' case
3024        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3025                { $$ = DeclarationNode::newVarArray( $3 ); }
3026        | '[' push type_qualifier_list pop ']'
3027                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3028        // multi_array_dimension handles the '[' assignment_expression ']' case
3029        | '[' push type_qualifier_list assignment_expression pop ']'
3030                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3031        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3032                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3033        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3034                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3035        ;
3036
3037// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3038//
3039//              struct S {
3040//          int;
3041//          int *;
3042//          int [10];
3043//          int (*)();
3044//      };
3045
3046variable_abstract_declarator:
3047        variable_abstract_ptr
3048        | variable_abstract_array attribute_list_opt
3049                { $$ = $1->addQualifiers( $2 ); }
3050        | variable_abstract_function attribute_list_opt
3051                { $$ = $1->addQualifiers( $2 ); }
3052        ;
3053
3054variable_abstract_ptr:
3055        ptrref_operator
3056                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3057        | ptrref_operator type_qualifier_list
3058                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3059        | ptrref_operator variable_abstract_declarator
3060                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3061        | ptrref_operator type_qualifier_list variable_abstract_declarator
3062                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3063        | '(' variable_abstract_ptr ')' attribute_list_opt
3064                { $$ = $2->addQualifiers( $4 ); }
3065        ;
3066
3067variable_abstract_array:
3068        array_dimension
3069        | '(' variable_abstract_ptr ')' array_dimension
3070                { $$ = $2->addArray( $4 ); }
3071        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3072                { $$ = $2->addArray( $4 ); }
3073        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3074                { $$ = $2; }
3075        ;
3076
3077variable_abstract_function:
3078        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3079                { $$ = $2->addParamList( $6 ); }
3080        | '(' variable_abstract_function ')'                            // redundant parenthesis
3081                { $$ = $2; }
3082        ;
3083
3084// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3085// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3086
3087cfa_identifier_parameter_declarator_tuple:                              // CFA
3088        cfa_identifier_parameter_declarator_no_tuple
3089        | cfa_abstract_tuple
3090        | type_qualifier_list cfa_abstract_tuple
3091                { $$ = $2->addQualifiers( $1 ); }
3092        ;
3093
3094cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3095        cfa_identifier_parameter_ptr
3096        | cfa_identifier_parameter_array
3097        ;
3098
3099cfa_identifier_parameter_ptr:                                                   // CFA
3100                // No SUE declaration in parameter list.
3101        ptrref_operator type_specifier_nobody
3102                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3103        | type_qualifier_list ptrref_operator type_specifier_nobody
3104                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3105        | ptrref_operator cfa_abstract_function
3106                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3107        | type_qualifier_list ptrref_operator cfa_abstract_function
3108                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3109        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3110                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3111        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3112                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3113        ;
3114
3115cfa_identifier_parameter_array:                                                 // CFA
3116                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3117                // shift/reduce conflict with new-style empty (void) function return type.
3118        '[' ']' type_specifier_nobody
3119                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3120        | cfa_array_parameter_1st_dimension type_specifier_nobody
3121                { $$ = $2->addNewArray( $1 ); }
3122        | '[' ']' multi_array_dimension type_specifier_nobody
3123                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3124        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3125                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3126        | multi_array_dimension type_specifier_nobody
3127                { $$ = $2->addNewArray( $1 ); }
3128
3129        | '[' ']' cfa_identifier_parameter_ptr
3130                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3131        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3132                { $$ = $2->addNewArray( $1 ); }
3133        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3134                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3135        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3136                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3137        | multi_array_dimension cfa_identifier_parameter_ptr
3138                { $$ = $2->addNewArray( $1 ); }
3139        ;
3140
3141cfa_array_parameter_1st_dimension:
3142        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3143                { $$ = DeclarationNode::newVarArray( $3 ); }
3144        | '[' push type_qualifier_list assignment_expression pop ']'
3145                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3146        | '[' push declaration_qualifier_list assignment_expression pop ']'
3147                // declaration_qualifier_list must be used because of shift/reduce conflict with
3148                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3149                // appear in this context.
3150                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3151        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3152                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3153        ;
3154
3155// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3156// identifier to which the type applies, e.g.:
3157//
3158//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3159//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3160//
3161// These rules need LR(3):
3162//
3163//              cfa_abstract_tuple identifier_or_type_name
3164//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_type_list_opt ')'
3165//
3166// since a function return type can be syntactically identical to a tuple type:
3167//
3168//              [int, int] t;
3169//              [int, int] f( int );
3170//
3171// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3172// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3173// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3174// duplicated when appearing with cfa_function_specifier.
3175
3176cfa_abstract_declarator_tuple:                                                  // CFA
3177        cfa_abstract_tuple
3178        | type_qualifier_list cfa_abstract_tuple
3179                { $$ = $2->addQualifiers( $1 ); }
3180        | cfa_abstract_declarator_no_tuple
3181        ;
3182
3183cfa_abstract_declarator_no_tuple:                                               // CFA
3184        cfa_abstract_ptr
3185        | cfa_abstract_array
3186        ;
3187
3188cfa_abstract_ptr:                                                                               // CFA
3189        ptrref_operator type_specifier
3190                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3191        | type_qualifier_list ptrref_operator type_specifier
3192                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3193        | ptrref_operator cfa_abstract_function
3194                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3195        | type_qualifier_list ptrref_operator cfa_abstract_function
3196                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3197        | ptrref_operator cfa_abstract_declarator_tuple
3198                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3199        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3200                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3201        ;
3202
3203cfa_abstract_array:                                                                             // CFA
3204                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3205                // empty (void) function return type.
3206        '[' ']' type_specifier
3207                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3208        | '[' ']' multi_array_dimension type_specifier
3209                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3210        | multi_array_dimension type_specifier
3211                { $$ = $2->addNewArray( $1 ); }
3212        | '[' ']' cfa_abstract_ptr
3213                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3214        | '[' ']' multi_array_dimension cfa_abstract_ptr
3215                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3216        | multi_array_dimension cfa_abstract_ptr
3217                { $$ = $2->addNewArray( $1 ); }
3218        ;
3219
3220cfa_abstract_tuple:                                                                             // CFA
3221        '[' push cfa_abstract_parameter_list pop ']'
3222                { $$ = DeclarationNode::newTuple( $3 ); }
3223        ;
3224
3225cfa_abstract_function:                                                                  // CFA
3226//      '[' ']' '(' cfa_parameter_type_list_opt ')'
3227//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3228        cfa_abstract_tuple '(' push cfa_parameter_type_list_opt pop ')'
3229                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3230        | cfa_function_return '(' push cfa_parameter_type_list_opt pop ')'
3231                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3232        ;
3233
3234// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3235//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3236//
3237// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3238//    the declaration specifiers in a declaration is an obsolescent feature."
3239//
3240// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3241//    prototype-format parameter type declarators) is an obsolescent feature."
3242//
3243// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3244//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3245
3246//************************* MISCELLANEOUS ********************************
3247
3248comma_opt:                                                                                              // redundant comma
3249        // empty
3250        | ','
3251        ;
3252
3253default_initialize_opt:
3254        // empty
3255                { $$ = nullptr; }
3256        | '=' assignment_expression
3257                { $$ = $2; }
3258        ;
3259
3260%%
3261// ----end of grammar----
3262
3263// Local Variables: //
3264// mode: c++ //
3265// tab-width: 4 //
3266// compile-command: "make install" //
3267// End: //
Note: See TracBrowser for help on using the repository browser.