source: src/Parser/parser.yy @ 4744074

arm-ehjacob/cs343-translationnew-ast-unique-expr
Last change on this file since 4744074 was 4744074, checked in by Peter A. Buhr <pabuhr@…>, 6 months ago

formatting

  • Property mode set to 100644
File size: 144.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Wed Apr 14 18:13:44 2021
13// Update Count     : 4983
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT( yylval )                                    // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack<LinkageSpec::Spec> linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169        *name = string("__postfix_func_") + *name;
170        return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189                type = new ExpressionNode( new CastExpr( maybeMoveBuild<Expression>(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
210        } // if
211} // forCtrl
212
213bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
217if ( N ) {                                                                                                                                              \
218        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
219        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
220        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
221        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
222        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
223} else {                                                                                                                                                \
224        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
225        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
226        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234        Token tok;
235        ParseNode * pn;
236        ExpressionNode * en;
237        DeclarationNode * decl;
238        AggregateDecl::Aggregate aggKey;
239        TypeDecl::Kind tclass;
240        StatementNode * sn;
241        WaitForStmt * wfs;
242        Expression * constant;
243        IfCtrl * ifctl;
244        ForCtrl * fctl;
245        enum OperKinds compop;
246        LabelNode * label;
247        InitializerNode * in;
248        OperKinds op;
249        std::string * str;
250        bool flag;
251        CatchStmt::Kind catch_kind;
252        GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL                                                                              // C11
261%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN                                                                                 // C11
263%token CONST VOLATILE
264%token RESTRICT                                                                                 // C99
265%token ATOMIC                                                                                   // C11
266%token FORALL MUTEX VIRTUAL VTABLE COERCE                               // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY                                                   // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T                                                                             // CFA
272%token SIZEOF TYPEOF VALIST AUTO_TYPE                                   // GCC
273%token OFFSETOF BASETYPEOF TYPEID                                               // CFA
274%token ENUM STRUCT UNION
275%token EXCEPTION                                                                                // CFA
276%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
277%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
278// %token RESUME                                                                                        // CFA
279%token LABEL                                                                                    // GCC
280%token SUSPEND                                                                                  // CFA
281%token ATTRIBUTE EXTENSION                                                              // GCC
282%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
283%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR    // CFA
284%token DISABLE ENABLE TRY THROW THROWRESUME AT                  // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER          QUOTED_IDENTIFIER       TYPEDEFname             TYPEGENname
290%token<tok> TIMEOUT                     WOR                                     CATCH                   RECOVER                 CATCHRESUME             FIXUP           FINALLY         // CFA
291%token<tok> INTEGERconstant     CHARACTERconstant       STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator                     simple_assignment_operator      compound_assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list_opt  argument_expression                     default_initializer_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en> bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375%type<decl> vtable vtable_opt default_opt
376
377%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
378
379%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
380%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
381
382%type<decl> elaborated_type elaborated_type_nobody
383
384%type<decl> enumerator_list enum_type enum_type_nobody
385%type<en> enumerator_value_opt
386
387%type<decl> external_definition external_definition_list external_definition_list_opt
388
389%type<decl> exception_declaration
390
391%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
392%type<en> field field_name_list field_name fraction_constants_opt
393
394%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
395
396%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
397%type<decl> identifier_list
398
399%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
400%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
401%type<decl> cfa_abstract_ptr cfa_abstract_tuple
402
403%type<decl> cfa_array_parameter_1st_dimension
404
405%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
406%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
407
408%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
409%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
410
411%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
412
413%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
414
415%type<decl> c_declaration static_assert
416%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
417%type<decl> KR_parameter_list KR_parameter_list_opt
418
419%type<decl> parameter_declaration parameter_list parameter_type_list_opt
420
421%type<decl> paren_identifier paren_type
422
423%type<decl> storage_class storage_class_list
424
425%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
426
427%type<tclass> type_class new_type_class
428%type<decl> type_declarator type_declarator_name type_declaring_list
429
430%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
431%type<decl> typedef_name typedef_declaration typedef_expression
432
433%type<decl> variable_type_redeclarator type_ptr type_array type_function
434
435%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
436
437%type<decl> type type_no_function
438%type<decl> type_parameter type_parameter_list type_initializer_opt
439
440%type<en> type_parameters_opt type_list
441
442%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
443%type<decl> type_specifier type_specifier_nobody
444
445%type<decl> variable_declarator variable_ptr variable_array variable_function
446%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
447
448%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
449
450// initializers
451%type<in>  initializer initializer_list_opt initializer_opt
452
453// designators
454%type<en>  designator designator_list designation
455
456
457// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
458//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
459//   if ( C ) S1 else S2
460//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
461// Similar issues exit with the waitfor statement.
462
463// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
464// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
465%precedence THEN                // rule precedence for IF/WAITFOR statement
466%precedence WOR                 // token precedence for start of WOR in WAITFOR statement
467%precedence TIMEOUT             // token precedence for start of TIMEOUT in WAITFOR statement
468%precedence CATCH               // token precedence for start of TIMEOUT in WAITFOR statement
469%precedence RECOVER             // token precedence for start of TIMEOUT in WAITFOR statement
470%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
471%precedence FIXUP               // token precedence for start of TIMEOUT in WAITFOR statement
472%precedence FINALLY             // token precedence for start of TIMEOUT in WAITFOR statement
473%precedence ELSE                // token precedence for start of else clause in IF/WAITFOR statement
474
475
476// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
477//   forall( otype T ) struct Foo { T v; };
478//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
479//   Foo ( *fp )( int );
480//   `---'                                              matches start of TYPEGENname '('
481// must be:
482//   Foo( int ) ( *fp )( int );
483// The same problem occurs here:
484//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
485// must be:
486//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
487
488// Order of these lines matters (low-to-high precedence).
489%precedence TYPEGENname
490%precedence '}'
491%precedence '('
492
493// %precedence RESUME
494// %precedence '{'
495// %precedence ')'
496
497%locations                                                                                              // support location tracking for error messages
498
499%start translation_unit                                                                 // parse-tree root
500
501%%
502//************************* Namespace Management ********************************
503
504// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
505// which are lexically identical.
506//
507//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
508//   foo f;           // to allow it to appear in this context
509//
510// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
511// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
512// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
513// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
514// must be distinguished by the lexical scanner.
515//
516// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
517// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
518// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
519// each context that introduces a name scope, a new level is created in the type table and that level is popped on
520// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
521// This requires distinguishing between type names that are local to the current declaration scope and those that
522// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
523//
524// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
525// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
526// around the list separator.
527//
528//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
529//      push               pop   push                   pop
530
531push:
532                { typedefTable.enterScope(); }
533        ;
534
535pop:
536                { typedefTable.leaveScope(); }
537        ;
538
539//************************* CONSTANTS ********************************
540
541constant:
542                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
543        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
544        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
545        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
546        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
547        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
548        ;
549
550quasi_keyword:                                                                                  // CFA
551        TIMEOUT
552        | WOR
553        | CATCH
554        | RECOVER
555        | CATCHRESUME
556        | FIXUP
557        | FINALLY
558        ;
559
560identifier:
561        IDENTIFIER
562        | quasi_keyword
563        | '@'                                                                                           // CFA
564                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
565        ;
566
567string_literal:
568        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
569        ;
570
571string_literal_list:                                                                    // juxtaposed strings are concatenated
572        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
573        | string_literal_list STRINGliteral
574                {
575                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
576                        delete $2;                                                                      // allocated by lexer
577                        $$ = $1;                                                                        // conversion from tok to str
578                }
579        ;
580
581//************************* EXPRESSIONS ********************************
582
583primary_expression:
584        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
585                { $$ = new ExpressionNode( build_varref( $1 ) ); }
586        | quasi_keyword
587                { $$ = new ExpressionNode( build_varref( $1 ) ); }
588        | tuple
589        | '(' comma_expression ')'
590                { $$ = $2; }
591        | '(' compound_statement ')'                                            // GCC, lambda expression
592                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast<CompoundStmt *>(maybeMoveBuild<Statement>($2) ) ) ); }
593        | type_name '.' identifier                                                      // CFA, nested type
594                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
595        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
596                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
597        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
598                {
599                        // add the missing control expression to the GenericExpr and return it
600                        $5->control = maybeMoveBuild<Expression>( $3 );
601                        $$ = new ExpressionNode( $5 );
602                }
603        // | RESUME '(' comma_expression ')'
604        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
605        // | RESUME '(' comma_expression ')' compound_statement
606        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
607        ;
608
609generic_assoc_list:                                                                             // C11
610        generic_association
611        | generic_assoc_list ',' generic_association
612                {
613                        // steal the association node from the singleton and delete the wrapper
614                        $1->associations.splice($1->associations.end(), $3->associations);
615                        delete $3;
616                        $$ = $1;
617                }
618        ;
619
620generic_association:                                                                    // C11
621        type_no_function ':' assignment_expression
622                {
623                        // create a GenericExpr wrapper with one association pair
624                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>( $3 ) } } );
625                }
626        | DEFAULT ':' assignment_expression
627                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>( $3 ) } } ); }
628        ;
629
630postfix_expression:
631        primary_expression
632        | postfix_expression '[' assignment_expression ',' comma_expression ']'
633                // { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, new ExpressionNode( build_binary_val( OperKinds::Index, $3, $5 ) ) ) ); }
634                { SemanticError( yylloc, "New array subscript is currently unimplemented." ); $$ = nullptr; }
635        | postfix_expression '[' assignment_expression ']'
636                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
637                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
638                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
639                // equivalent to the old x[i,j].
640                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
641        | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
642                {
643                        Token fn;
644                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
645                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
646                }
647        | postfix_expression '(' argument_expression_list_opt ')'
648                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
649        | postfix_expression '`' identifier                                     // CFA, postfix call
650                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
651        | constant '`' identifier                                                       // CFA, postfix call
652                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
653        | string_literal '`' identifier                                         // CFA, postfix call
654                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
655        | postfix_expression '.' identifier
656                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
657        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
658                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
659        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
660                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
661        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
662                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
663        | postfix_expression '.' aggregate_control
664                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
665        | postfix_expression ARROW identifier
666                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
667        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
668                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
669        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
670                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
671        | postfix_expression ICR
672                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
673        | postfix_expression DECR
674                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
675        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
676                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
677        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
678                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
679        | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
680                {
681                        Token fn;
682                        fn.str = new string( "^?{}" );                          // location undefined
683                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
684                }
685        ;
686
687argument_expression_list_opt:
688        // empty
689                { $$ = nullptr; }
690        | argument_expression
691        | argument_expression_list_opt ',' argument_expression
692                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
693        ;
694
695argument_expression:
696        '@'                                                                                                     // CFA, default parameter
697                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
698                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
699        | assignment_expression
700        ;
701
702field_name_list:                                                                                // CFA, tuple field selector
703        field
704        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
705        ;
706
707field:                                                                                                  // CFA, tuple field selector
708        field_name
709        | FLOATING_DECIMALconstant field
710                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
711        | FLOATING_DECIMALconstant '[' field_name_list ']'
712                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
713        | field_name '.' field
714                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
715        | field_name '.' '[' field_name_list ']'
716                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
717        | field_name ARROW field
718                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
719        | field_name ARROW '[' field_name_list ']'
720                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
721        ;
722
723field_name:
724        INTEGERconstant fraction_constants_opt
725                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
726        | FLOATINGconstant fraction_constants_opt
727                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
728        | identifier fraction_constants_opt
729                {
730                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
731                }
732        ;
733
734fraction_constants_opt:
735        // empty
736                { $$ = nullptr; }
737        | fraction_constants_opt FLOATING_FRACTIONconstant
738                {
739                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
740                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
741                }
742        ;
743
744unary_expression:
745        postfix_expression
746                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
747                // semantics checks, e.g., ++3, 3--, *3, &&3
748        | constant
749        | string_literal
750                { $$ = new ExpressionNode( $1 ); }
751        | EXTENSION cast_expression                                                     // GCC
752                { $$ = $2->set_extension( true ); }
753                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
754                //              { * X; }         // dereference X
755                //              { * int X; } // CFA declaration of pointer to int
756        | ptrref_operator cast_expression                                       // CFA
757                {
758                        switch ( $1 ) {
759                          case OperKinds::AddressOf:
760                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) );
761                                break;
762                          case OperKinds::PointTo:
763                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
764                                break;
765                          case OperKinds::And:
766                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) ) );
767                                break;
768                          default:
769                                assert( false );
770                        }
771                }
772        | unary_operator cast_expression
773                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
774        | ICR unary_expression
775                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
776        | DECR unary_expression
777                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
778        | SIZEOF unary_expression
779                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
780        | SIZEOF '(' type_no_function ')'
781                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
782        | ALIGNOF unary_expression                                                      // GCC, variable alignment
783                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
784        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
785                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
786        | OFFSETOF '(' type_no_function ',' identifier ')'
787                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
788        | TYPEID '(' type_no_function ')'
789                {
790                        SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
791                        // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
792                }
793        ;
794
795ptrref_operator:
796        '*'                                                                                     { $$ = OperKinds::PointTo; }
797        | '&'                                                                           { $$ = OperKinds::AddressOf; }
798                // GCC, address of label must be handled by semantic check for ref,ref,label
799        | ANDAND                                                                        { $$ = OperKinds::And; }
800        ;
801
802unary_operator:
803        '+'                                                                                     { $$ = OperKinds::UnPlus; }
804        | '-'                                                                           { $$ = OperKinds::UnMinus; }
805        | '!'                                                                           { $$ = OperKinds::Neg; }
806        | '~'                                                                           { $$ = OperKinds::BitNeg; }
807        ;
808
809cast_expression:
810        unary_expression
811        | '(' type_no_function ')' cast_expression
812                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
813        | '(' aggregate_control '&' ')' cast_expression         // CFA
814                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
815        | '(' VIRTUAL ')' cast_expression                                       // CFA
816                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $4 ), maybeMoveBuildType( nullptr ) ) ); }
817        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
818                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $5 ), maybeMoveBuildType( $3 ) ) ); }
819        | '(' RETURN type_no_function ')' cast_expression       // CFA
820                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
821        | '(' COERCE type_no_function ')' cast_expression       // CFA
822                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
823        | '(' qualifier_cast_list ')' cast_expression           // CFA
824                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
825//      | '(' type_no_function ')' tuple
826//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
827        ;
828
829qualifier_cast_list:
830        cast_modifier type_qualifier_name
831        | cast_modifier MUTEX
832        | qualifier_cast_list cast_modifier type_qualifier_name
833        | qualifier_cast_list cast_modifier MUTEX
834        ;
835
836cast_modifier:
837        '-'
838        | '+'
839        ;
840
841exponential_expression:
842        cast_expression
843        | exponential_expression '\\' cast_expression
844                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
845        ;
846
847multiplicative_expression:
848        exponential_expression
849        | multiplicative_expression '*' exponential_expression
850                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
851        | multiplicative_expression '/' exponential_expression
852                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
853        | multiplicative_expression '%' exponential_expression
854                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
855        ;
856
857additive_expression:
858        multiplicative_expression
859        | additive_expression '+' multiplicative_expression
860                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
861        | additive_expression '-' multiplicative_expression
862                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
863        ;
864
865shift_expression:
866        additive_expression
867        | shift_expression LS additive_expression
868                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
869        | shift_expression RS additive_expression
870                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
871        ;
872
873relational_expression:
874        shift_expression
875        | relational_expression '<' shift_expression
876                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
877        | relational_expression '>' shift_expression
878                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
879        | relational_expression LE shift_expression
880                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
881        | relational_expression GE shift_expression
882                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
883        ;
884
885equality_expression:
886        relational_expression
887        | equality_expression EQ relational_expression
888                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
889        | equality_expression NE relational_expression
890                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
891        ;
892
893AND_expression:
894        equality_expression
895        | AND_expression '&' equality_expression
896                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
897        ;
898
899exclusive_OR_expression:
900        AND_expression
901        | exclusive_OR_expression '^' AND_expression
902                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
903        ;
904
905inclusive_OR_expression:
906        exclusive_OR_expression
907        | inclusive_OR_expression '|' exclusive_OR_expression
908                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
909        ;
910
911logical_AND_expression:
912        inclusive_OR_expression
913        | logical_AND_expression ANDAND inclusive_OR_expression
914                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
915        ;
916
917logical_OR_expression:
918        logical_AND_expression
919        | logical_OR_expression OROR logical_AND_expression
920                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
921        ;
922
923conditional_expression:
924        logical_OR_expression
925        | logical_OR_expression '?' comma_expression ':' conditional_expression
926                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
927                // FIX ME: computes $1 twice
928        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
929                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
930        ;
931
932constant_expression:
933        conditional_expression
934        ;
935
936assignment_expression:
937                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
938        conditional_expression
939        | unary_expression assignment_operator assignment_expression
940                {
941//                      if ( $2 == OperKinds::AtAssn ) {
942//                              SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
943//                      } else {
944                                $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
945//                      } // if
946                }
947        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
948                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
949        ;
950
951assignment_expression_opt:
952        // empty
953                { $$ = nullptr; }
954        | assignment_expression
955        ;
956
957assignment_operator:
958        simple_assignment_operator
959        | compound_assignment_operator
960        ;
961
962simple_assignment_operator:
963        '='                                                                                     { $$ = OperKinds::Assign; }
964        | ATassign                                                                      { $$ = OperKinds::AtAssn; } // CFA
965        ;
966
967compound_assignment_operator:
968        EXPassign                                                                       { $$ = OperKinds::ExpAssn; }
969        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
970        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
971        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
972        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
973        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
974        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
975        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
976        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
977        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
978        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
979        ;
980
981tuple:                                                                                                  // CFA, tuple
982                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
983                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
984//      '[' ']'
985//              { $$ = new ExpressionNode( build_tuple() ); }
986//      | '[' push assignment_expression pop ']'
987//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
988        '[' ',' tuple_expression_list ']'
989                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
990        | '[' push assignment_expression pop ',' tuple_expression_list ']'
991                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
992        ;
993
994tuple_expression_list:
995        assignment_expression
996        | '@'                                                                                           // CFA
997                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
998        | tuple_expression_list ',' assignment_expression
999                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1000        | tuple_expression_list ',' '@'
1001                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1002        ;
1003
1004comma_expression:
1005        assignment_expression
1006        | comma_expression ',' assignment_expression
1007                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1008        ;
1009
1010comma_expression_opt:
1011        // empty
1012                { $$ = nullptr; }
1013        | comma_expression
1014        ;
1015
1016//*************************** STATEMENTS *******************************
1017
1018statement:
1019        labeled_statement
1020        | compound_statement
1021        | expression_statement
1022        | selection_statement
1023        | iteration_statement
1024        | jump_statement
1025        | with_statement
1026        | mutex_statement
1027        | waitfor_statement
1028        | exception_statement
1029        | enable_disable_statement
1030                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1031        | asm_statement
1032        | DIRECTIVE
1033                { $$ = new StatementNode( build_directive( $1 ) ); }
1034        ;
1035
1036labeled_statement:
1037                // labels cannot be identifiers 0 or 1
1038        identifier_or_type_name ':' attribute_list_opt statement
1039                { $$ = $4->add_label( $1, $3 ); }
1040        ;
1041
1042compound_statement:
1043        '{' '}'
1044                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1045        | '{' push
1046          local_label_declaration_opt                                           // GCC, local labels appear at start of block
1047          statement_decl_list                                                           // C99, intermix declarations and statements
1048          pop '}'
1049                { $$ = new StatementNode( build_compound( $4 ) ); }
1050        ;
1051
1052statement_decl_list:                                                                    // C99
1053        statement_decl
1054        | statement_decl_list statement_decl
1055                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1056        ;
1057
1058statement_decl:
1059        declaration                                                                                     // CFA, new & old style declarations
1060                { $$ = new StatementNode( $1 ); }
1061        | EXTENSION declaration                                                         // GCC
1062                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1063        | function_definition
1064                { $$ = new StatementNode( $1 ); }
1065        | EXTENSION function_definition                                         // GCC
1066                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1067        | statement
1068        ;
1069
1070statement_list_nodecl:
1071        statement
1072        | statement_list_nodecl statement
1073                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1074        ;
1075
1076expression_statement:
1077        comma_expression_opt ';'
1078                { $$ = new StatementNode( build_expr( $1 ) ); }
1079        ;
1080
1081selection_statement:
1082                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1083                        // the inherent S/R conflict with THEN/ELSE.
1084        push if_statement pop
1085                { $$ = $2; }
1086        | SWITCH '(' comma_expression ')' case_clause
1087                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1088        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1089                {
1090                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1091                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1092                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1093                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1094                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1095                        // statement.
1096                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1097                }
1098        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1099                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1100        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1101                {
1102                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1103                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1104                }
1105        ;
1106
1107if_statement:
1108        IF '(' if_control_expression ')' statement                      %prec THEN
1109                // explicitly deal with the shift/reduce conflict on if/else
1110                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1111        | IF '(' if_control_expression ')' statement ELSE statement
1112                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1113        ;
1114
1115if_control_expression:
1116        comma_expression
1117                { $$ = new IfCtrl( nullptr, $1 ); }
1118        | c_declaration                                                                         // no semi-colon
1119                { $$ = new IfCtrl( $1, nullptr ); }
1120        | cfa_declaration                                                                       // no semi-colon
1121                { $$ = new IfCtrl( $1, nullptr ); }
1122        | declaration comma_expression                                          // semi-colon separated
1123                { $$ = new IfCtrl( $1, $2 ); }
1124        ;
1125
1126// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1127// clause allows a list of values and subranges.
1128
1129case_value:                                                                                             // CFA
1130        constant_expression                                                     { $$ = $1; }
1131        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1132                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1133        | subrange                                                                                      // CFA, subrange
1134        ;
1135
1136case_value_list:                                                                                // CFA
1137        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1138                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1139        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1140        ;
1141
1142case_label:                                                                                             // CFA
1143        CASE case_value_list ':'                                        { $$ = $2; }
1144        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1145                // A semantic check is required to ensure only one default clause per switch/choose statement.
1146        ;
1147
1148//label_list_opt:
1149//      // empty
1150//      | identifier_or_type_name ':'
1151//      | label_list_opt identifier_or_type_name ':'
1152//      ;
1153
1154case_label_list:                                                                                // CFA
1155        case_label
1156        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1157        ;
1158
1159case_clause:                                                                                    // CFA
1160        case_label_list statement                                       { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1161        ;
1162
1163switch_clause_list_opt:                                                                 // CFA
1164        // empty
1165                { $$ = nullptr; }
1166        | switch_clause_list
1167        ;
1168
1169switch_clause_list:                                                                             // CFA
1170        case_label_list statement_list_nodecl
1171                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1172        | switch_clause_list case_label_list statement_list_nodecl
1173                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1174        ;
1175
1176iteration_statement:
1177        WHILE '(' push if_control_expression ')' statement pop
1178                { $$ = new StatementNode( build_while( $4, maybe_build_compound( $6 ) ) ); }
1179        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1180                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1181        | DO statement WHILE '(' comma_expression ')' ';'
1182                { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1183        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1184                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1185        | FOR '(' push for_control_expression_list ')' statement pop
1186                { $$ = new StatementNode( build_for( $4, maybe_build_compound( $6 ) ) ); }
1187        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1188                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1189        ;
1190
1191for_control_expression_list:
1192        for_control_expression
1193        | for_control_expression_list ':' for_control_expression
1194                // ForCtrl + ForCtrl:
1195                //    init + init => multiple declaration statements that are hoisted
1196                //    condition + condition => (expression) && (expression)
1197                //    change + change => (expression), (expression)
1198                {
1199                        $1->init->set_last( $3->init );
1200                        if ( $1->condition ) {
1201                                if ( $3->condition ) {
1202                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1203                                } // if
1204                        } else $1->condition = $3->condition;
1205                        if ( $1->change ) {
1206                                if ( $3->change ) {
1207                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1208                                } // if
1209                        } else $1->change = $3->change;
1210                        $$ = $1;
1211                }
1212        ;
1213
1214for_control_expression:
1215        ';' comma_expression_opt ';' comma_expression_opt
1216                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1217        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1218                { $$ = new ForCtrl( $1, $3, $5 ); }
1219        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1220                { $$ = new ForCtrl( $1, $2, $4 ); }
1221
1222        | comma_expression                                                                      // CFA
1223                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1224                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1225        | '=' comma_expression                                                          // CFA
1226                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1227                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1228        | comma_expression inclexcl comma_expression            // CFA
1229                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1230        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1231                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1232        | comma_expression ';'                                                          // CFA
1233                { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1234        | comma_expression ';' comma_expression                         // CFA
1235                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1236                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1237        | comma_expression ';' '=' comma_expression                     // CFA
1238                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1239                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1240        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1241                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1242        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1243                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1244
1245        | comma_expression ';' TYPEDEFname                                      // CFA, array type
1246                {
1247                        SemanticError( yylloc, "Array interator is currently unimplemented." ); $$ = nullptr;
1248                        $$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1249                }
1250
1251                // There is a S/R conflicit if ~ and -~ are factored out.
1252        | comma_expression ';' comma_expression '~' '@'         // CFA
1253                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1254        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1255                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1256        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1257                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1258        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1259                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1260        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1261                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1262        ;
1263
1264inclexcl:
1265        '~'
1266                { $$ = OperKinds::LThan; }
1267        | ErangeUpEq
1268                { $$ = OperKinds::LEThan; }
1269        | ErangeDown
1270                { $$ = OperKinds::GThan; }
1271        | ErangeDownEq
1272                { $$ = OperKinds::GEThan; }
1273        ;
1274
1275jump_statement:
1276        GOTO identifier_or_type_name ';'
1277                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1278        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1279                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1280                // whereas normal operator precedence yields goto (*i)+3;
1281                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1282                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1283        | fall_through_name ';'                                                         // CFA
1284                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1285        | fall_through_name identifier_or_type_name ';'         // CFA
1286                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1287        | fall_through_name DEFAULT ';'                                         // CFA
1288                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1289        | CONTINUE ';'
1290                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1291                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1292        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1293                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1294                // the target of the transfer appears only at the start of an iteration statement.
1295                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1296        | BREAK ';'
1297                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1298                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1299        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1300                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1301                // the target of the transfer appears only at the start of an iteration statement.
1302                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1303        | RETURN comma_expression_opt ';'
1304                { $$ = new StatementNode( build_return( $2 ) ); }
1305        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1306                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1307        | SUSPEND ';'
1308                { $$ = new StatementNode( build_suspend( nullptr ) ); }
1309        | SUSPEND compound_statement
1310                { $$ = new StatementNode( build_suspend( $2 ) ); }
1311        | SUSPEND COROUTINE ';'
1312                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1313        | SUSPEND COROUTINE compound_statement
1314                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1315        | SUSPEND GENERATOR ';'
1316                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1317        | SUSPEND GENERATOR compound_statement
1318                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1319        | THROW assignment_expression_opt ';'                           // handles rethrow
1320                { $$ = new StatementNode( build_throw( $2 ) ); }
1321        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1322                { $$ = new StatementNode( build_resume( $2 ) ); }
1323        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1324                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1325        ;
1326
1327fall_through_name:                                                                              // CFA
1328        FALLTHRU
1329        | FALLTHROUGH
1330        ;
1331
1332with_statement:
1333        WITH '(' tuple_expression_list ')' statement
1334                {
1335                        $$ = new StatementNode( build_with( $3, $5 ) );
1336                }
1337        ;
1338
1339// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1340mutex_statement:
1341        MUTEX '(' argument_expression_list_opt ')' statement
1342                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1343        ;
1344
1345when_clause:
1346        WHEN '(' comma_expression ')'                           { $$ = $3; }
1347        ;
1348
1349when_clause_opt:
1350        // empty
1351                { $$ = nullptr; }
1352        | when_clause
1353        ;
1354
1355waitfor:
1356        WAITFOR '(' cast_expression ')'
1357                { $$ = $3; }
1358//      | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1359//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1360        | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1361                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1362        ;
1363
1364cast_expression_list:
1365        cast_expression
1366        | cast_expression_list ',' cast_expression
1367                // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1368                { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1369        ;
1370
1371timeout:
1372        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1373        ;
1374
1375waitfor_clause:
1376        when_clause_opt waitfor statement                                       %prec THEN
1377                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1378        | when_clause_opt waitfor statement WOR waitfor_clause
1379                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1380        | when_clause_opt timeout statement                                     %prec THEN
1381                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1382        | when_clause_opt ELSE statement
1383                { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1384                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1385        | when_clause_opt timeout statement WOR ELSE statement
1386                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1387        | when_clause_opt timeout statement WOR when_clause ELSE statement
1388                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1389        ;
1390
1391waitfor_statement:
1392        when_clause_opt waitfor statement                                       %prec THEN
1393                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1394        | when_clause_opt waitfor statement WOR waitfor_clause
1395                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1396        ;
1397
1398exception_statement:
1399        TRY compound_statement handler_clause                                   %prec THEN
1400                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1401        | TRY compound_statement finally_clause
1402                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1403        | TRY compound_statement handler_clause finally_clause
1404                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1405        ;
1406
1407handler_clause:
1408        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1409                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1410        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1411                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1412        ;
1413
1414handler_predicate_opt:
1415        // empty
1416                { $$ = nullptr; }
1417        | ';' conditional_expression                            { $$ = $2; }
1418        ;
1419
1420handler_key:
1421        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1422        | RECOVER                                                                       { $$ = CatchStmt::Terminate; }
1423        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1424        | FIXUP                                                                         { $$ = CatchStmt::Resume; }
1425        ;
1426
1427finally_clause:
1428        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1429        ;
1430
1431exception_declaration:
1432                // No SUE declaration in parameter list.
1433        type_specifier_nobody
1434        | type_specifier_nobody declarator
1435                { $$ = $2->addType( $1 ); }
1436        | type_specifier_nobody variable_abstract_declarator
1437                { $$ = $2->addType( $1 ); }
1438        | cfa_abstract_declarator_tuple identifier                      // CFA
1439                { $$ = $1->addName( $2 ); }
1440        | cfa_abstract_declarator_tuple                                         // CFA
1441        ;
1442
1443enable_disable_statement:
1444        enable_disable_key identifier_list compound_statement
1445        ;
1446
1447enable_disable_key:
1448        ENABLE
1449        | DISABLE
1450        ;
1451
1452asm_statement:
1453        ASM asm_volatile_opt '(' string_literal ')' ';'
1454                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1455        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1456                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1457        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1458                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1459        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1460                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1461        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1462                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1463        ;
1464
1465asm_volatile_opt:                                                                               // GCC
1466        // empty
1467                { $$ = false; }
1468        | VOLATILE
1469                { $$ = true; }
1470        ;
1471
1472asm_operands_opt:                                                                               // GCC
1473        // empty
1474                { $$ = nullptr; }                                                               // use default argument
1475        | asm_operands_list
1476        ;
1477
1478asm_operands_list:                                                                              // GCC
1479        asm_operand
1480        | asm_operands_list ',' asm_operand
1481                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1482        ;
1483
1484asm_operand:                                                                                    // GCC
1485        string_literal '(' constant_expression ')'
1486                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild<Expression>( $3 ) ) ); }
1487        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1488                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild<Expression>( $6 ) ) ); }
1489        ;
1490
1491asm_clobbers_list_opt:                                                                  // GCC
1492        // empty
1493                { $$ = nullptr; }                                                               // use default argument
1494        | string_literal
1495                { $$ = new ExpressionNode( $1 ); }
1496        | asm_clobbers_list_opt ',' string_literal
1497                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1498        ;
1499
1500label_list:
1501        identifier
1502                {
1503                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1504                        delete $1;                                                                      // allocated by lexer
1505                }
1506        | label_list ',' identifier
1507                {
1508                        $$ = $1; $1->labels.push_back( *$3 );
1509                        delete $3;                                                                      // allocated by lexer
1510                }
1511        ;
1512
1513//******************************* DECLARATIONS *********************************
1514
1515declaration_list_opt:                                                                   // used at beginning of switch statement
1516        // empty
1517                { $$ = nullptr; }
1518        | declaration_list
1519        ;
1520
1521declaration_list:
1522        declaration
1523        | declaration_list declaration
1524                { $$ = $1->appendList( $2 ); }
1525        ;
1526
1527KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1528        // empty
1529                { $$ = nullptr; }
1530        | KR_parameter_list
1531        ;
1532
1533KR_parameter_list:
1534        push c_declaration pop ';'
1535                { $$ = $2; }
1536        | KR_parameter_list push c_declaration pop ';'
1537                { $$ = $1->appendList( $3 ); }
1538        ;
1539
1540local_label_declaration_opt:                                                    // GCC, local label
1541        // empty
1542        | local_label_declaration_list
1543        ;
1544
1545local_label_declaration_list:                                                   // GCC, local label
1546        LABEL local_label_list ';'
1547        | local_label_declaration_list LABEL local_label_list ';'
1548        ;
1549
1550local_label_list:                                                                               // GCC, local label
1551        identifier_or_type_name
1552        | local_label_list ',' identifier_or_type_name
1553        ;
1554
1555declaration:                                                                                    // old & new style declarations
1556        c_declaration ';'
1557        | cfa_declaration ';'                                                           // CFA
1558        | static_assert                                                                         // C11
1559        ;
1560
1561static_assert:
1562        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1563                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1564        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1565                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1566
1567// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1568// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1569// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1570// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1571// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1572// block, but cannot be mixed within a specific declaration.
1573//
1574//                      CFA                                     C
1575//              [10] int x;                     int x[10];              // array of 10 integers
1576//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1577
1578cfa_declaration:                                                                                // CFA
1579        cfa_variable_declaration
1580        | cfa_typedef_declaration
1581        | cfa_function_declaration
1582        | type_declaring_list
1583                { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1584        | trait_specifier
1585        ;
1586
1587cfa_variable_declaration:                                                               // CFA
1588        cfa_variable_specifier initializer_opt
1589                { $$ = $1->addInitializer( $2 ); }
1590        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1591                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1592                // them as a type_qualifier cannot appear in that context.
1593                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1594        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1595                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1596        ;
1597
1598cfa_variable_specifier:                                                                 // CFA
1599                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1600                // storage-class
1601        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1602                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1603        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1604                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1605        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1606                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1607        ;
1608
1609cfa_function_declaration:                                                               // CFA
1610        cfa_function_specifier
1611        | type_qualifier_list cfa_function_specifier
1612                { $$ = $2->addQualifiers( $1 ); }
1613        | declaration_qualifier_list cfa_function_specifier
1614                { $$ = $2->addQualifiers( $1 ); }
1615        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1616                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1617        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1618                {
1619                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1620                        DeclarationNode * ret = new DeclarationNode;
1621                        ret->type = maybeClone( $1->type->base );
1622                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1623                }
1624        ;
1625
1626cfa_function_specifier:                                                                 // CFA
1627//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1628//              {
1629//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1630//              }
1631//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1632//              {
1633//                      typedefTable.setNextIdentifier( *$5 );
1634//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1635//              }
1636//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1637//              {
1638//                      typedefTable.setNextIdentifier( *$5 );
1639//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1640//              }
1641//      | '[' ']' typegen_name
1642                // identifier_or_type_name must be broken apart because of the sequence:
1643                //
1644                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1645                //   '[' ']' type_specifier
1646                //
1647                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1648                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1649        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1650                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1651                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1652        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1653                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1654        ;
1655
1656cfa_function_return:                                                                    // CFA
1657        '[' push cfa_parameter_list pop ']'
1658                { $$ = DeclarationNode::newTuple( $3 ); }
1659        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1660                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1661                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1662        ;
1663
1664cfa_typedef_declaration:                                                                // CFA
1665        TYPEDEF cfa_variable_specifier
1666                {
1667                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1668                        $$ = $2->addTypedef();
1669                }
1670        | TYPEDEF cfa_function_specifier
1671                {
1672                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1673                        $$ = $2->addTypedef();
1674                }
1675        | cfa_typedef_declaration pop ',' push identifier
1676                {
1677                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1678                        $$ = $1->appendList( $1->cloneType( $5 ) );
1679                }
1680        ;
1681
1682// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1683// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1684
1685typedef_declaration:
1686        TYPEDEF type_specifier declarator
1687                {
1688                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1689                        $$ = $3->addType( $2 )->addTypedef();
1690                }
1691        | typedef_declaration pop ',' push declarator
1692                {
1693                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1694                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1695                }
1696        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1697                {
1698                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1699                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1700                }
1701        | type_specifier TYPEDEF declarator
1702                {
1703                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1704                        $$ = $3->addType( $1 )->addTypedef();
1705                }
1706        | type_specifier TYPEDEF type_qualifier_list declarator
1707                {
1708                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1709                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1710                }
1711        ;
1712
1713typedef_expression:
1714                // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1715        TYPEDEF identifier '=' assignment_expression
1716                {
1717                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1718                }
1719        | typedef_expression pop ',' push identifier '=' assignment_expression
1720                {
1721                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1722                }
1723        ;
1724
1725c_declaration:
1726        declaration_specifier declaring_list
1727                { $$ = distAttr( $1, $2 ); }
1728        | typedef_declaration
1729        | typedef_expression                                                            // deprecated GCC, naming expression type
1730        | sue_declaration_specifier
1731        ;
1732
1733declaring_list:
1734                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1735                // storage-class
1736        declarator asm_name_opt initializer_opt
1737                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1738        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1739                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1740        ;
1741
1742declaration_specifier:                                                                  // type specifier + storage class
1743        basic_declaration_specifier
1744        | sue_declaration_specifier
1745        | type_declaration_specifier
1746        ;
1747
1748declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1749                // Preclude SUE declarations in restricted scopes:
1750                //
1751                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1752                //
1753                // because it is impossible to call f due to name equivalence.
1754        basic_declaration_specifier
1755        | sue_declaration_specifier_nobody
1756        | type_declaration_specifier
1757        ;
1758
1759type_specifier:                                                                                 // type specifier
1760        basic_type_specifier
1761        | sue_type_specifier
1762        | type_type_specifier
1763        ;
1764
1765type_specifier_nobody:                                                                  // type specifier - {...}
1766                // Preclude SUE declarations in restricted scopes:
1767                //
1768                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1769                //
1770                // because it is impossible to call f due to name equivalence.
1771        basic_type_specifier
1772        | sue_type_specifier_nobody
1773        | type_type_specifier
1774        ;
1775
1776type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1777        // empty
1778                { $$ = nullptr; }
1779        | type_qualifier_list
1780        ;
1781
1782type_qualifier_list:
1783                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1784                //
1785                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1786                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1787                // appeared only once.
1788        type_qualifier
1789        | type_qualifier_list type_qualifier
1790                { $$ = $1->addQualifiers( $2 ); }
1791        ;
1792
1793type_qualifier:
1794        type_qualifier_name
1795        | attribute                                                                                     // trick handles most atrribute locations
1796        ;
1797
1798type_qualifier_name:
1799        CONST
1800                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1801        | RESTRICT
1802                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1803        | VOLATILE
1804                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1805        | ATOMIC
1806                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1807        | forall
1808        ;
1809
1810forall:
1811        FORALL '(' type_parameter_list ')'                                      // CFA
1812                { $$ = DeclarationNode::newForall( $3 ); }
1813        ;
1814
1815declaration_qualifier_list:
1816        storage_class_list
1817        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1818                { $$ = $1->addQualifiers( $2 ); }
1819        | declaration_qualifier_list type_qualifier_list storage_class_list
1820                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1821        ;
1822
1823storage_class_list:
1824                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1825                // only one of each is specified, except for inline, which can appear with the others.
1826                //
1827                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1828                // specifiers in a declaration.
1829        storage_class
1830        | storage_class_list storage_class
1831                { $$ = $1->addQualifiers( $2 ); }
1832        ;
1833
1834storage_class:
1835        EXTERN
1836                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1837        | STATIC
1838                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1839        | AUTO
1840                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1841        | REGISTER
1842                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1843        | THREADLOCAL                                                                           // C11
1844                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1845                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1846        | INLINE                                                                                        // C99
1847                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1848        | FORTRAN                                                                                       // C99
1849                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1850        | NORETURN                                                                                      // C11
1851                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1852        ;
1853
1854basic_type_name:
1855        VOID
1856                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1857        | BOOL                                                                                          // C99
1858                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1859        | CHAR
1860                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1861        | INT
1862                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1863        | INT128
1864                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1865        | UINT128
1866                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1867        | FLOAT
1868                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1869        | DOUBLE
1870                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1871        | uuFLOAT80
1872                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1873        | uuFLOAT128
1874                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1875        | uFLOAT16
1876                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1877        | uFLOAT32
1878                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1879        | uFLOAT32X
1880                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1881        | uFLOAT64
1882                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1883        | uFLOAT64X
1884                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1885        | uFLOAT128
1886                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1887        | COMPLEX                                                                                       // C99
1888                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1889        | IMAGINARY                                                                                     // C99
1890                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1891        | SIGNED
1892                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1893        | UNSIGNED
1894                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1895        | SHORT
1896                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1897        | LONG
1898                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1899        | VALIST                                                                                        // GCC, __builtin_va_list
1900                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1901        | AUTO_TYPE
1902                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1903        | vtable
1904        ;
1905
1906vtable_opt:
1907        // empty
1908                { $$ = nullptr; }
1909        | vtable;
1910        ;
1911
1912vtable:
1913        VTABLE '(' type_list ')' default_opt
1914                { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
1915        ;
1916
1917default_opt:
1918        // empty
1919                { $$ = nullptr; }
1920        | DEFAULT
1921                { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
1922        ;
1923
1924basic_declaration_specifier:
1925                // A semantic check is necessary for conflicting storage classes.
1926        basic_type_specifier
1927        | declaration_qualifier_list basic_type_specifier
1928                { $$ = $2->addQualifiers( $1 ); }
1929        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1930                { $$ = $1->addQualifiers( $2 ); }
1931        | basic_declaration_specifier storage_class type_qualifier_list
1932                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1933        | basic_declaration_specifier storage_class basic_type_specifier
1934                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1935        ;
1936
1937basic_type_specifier:
1938        direct_type
1939                // Cannot have type modifiers, e.g., short, long, etc.
1940        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1941                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1942        ;
1943
1944direct_type:
1945        basic_type_name
1946        | type_qualifier_list basic_type_name
1947                { $$ = $2->addQualifiers( $1 ); }
1948        | direct_type type_qualifier
1949                { $$ = $1->addQualifiers( $2 ); }
1950        | direct_type basic_type_name
1951                { $$ = $1->addType( $2 ); }
1952        ;
1953
1954indirect_type:
1955        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1956                { $$ = $3; }
1957        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1958                { $$ = DeclarationNode::newTypeof( $3 ); }
1959        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1960                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1961        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1962                { $$ = DeclarationNode::newTypeof( $3, true ); }
1963        | ZERO_T                                                                                        // CFA
1964                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1965        | ONE_T                                                                                         // CFA
1966                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1967        ;
1968
1969sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1970        sue_type_specifier
1971        | declaration_qualifier_list sue_type_specifier
1972                { $$ = $2->addQualifiers( $1 ); }
1973        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1974                { $$ = $1->addQualifiers( $2 ); }
1975        | sue_declaration_specifier storage_class type_qualifier_list
1976                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1977        ;
1978
1979sue_type_specifier:                                                                             // struct, union, enum + type specifier
1980        elaborated_type
1981        | type_qualifier_list
1982                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1983          elaborated_type
1984                { $$ = $3->addQualifiers( $1 ); }
1985        | sue_type_specifier type_qualifier
1986                {
1987                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1988                        $$ = $1->addQualifiers( $2 );
1989                }
1990        ;
1991
1992sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1993        sue_type_specifier_nobody
1994        | declaration_qualifier_list sue_type_specifier_nobody
1995                { $$ = $2->addQualifiers( $1 ); }
1996        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1997                { $$ = $1->addQualifiers( $2 ); }
1998        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1999                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2000        ;
2001
2002sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
2003        elaborated_type_nobody
2004        | type_qualifier_list elaborated_type_nobody
2005                { $$ = $2->addQualifiers( $1 ); }
2006        | sue_type_specifier_nobody type_qualifier
2007                { $$ = $1->addQualifiers( $2 ); }
2008        ;
2009
2010type_declaration_specifier:
2011        type_type_specifier
2012        | declaration_qualifier_list type_type_specifier
2013                { $$ = $2->addQualifiers( $1 ); }
2014        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
2015                { $$ = $1->addQualifiers( $2 ); }
2016        | type_declaration_specifier storage_class type_qualifier_list
2017                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2018        ;
2019
2020type_type_specifier:                                                                    // typedef types
2021        type_name
2022        | type_qualifier_list type_name
2023                { $$ = $2->addQualifiers( $1 ); }
2024        | type_type_specifier type_qualifier
2025                { $$ = $1->addQualifiers( $2 ); }
2026        ;
2027
2028type_name:
2029        TYPEDEFname
2030                { $$ = DeclarationNode::newFromTypedef( $1 ); }
2031        | '.' TYPEDEFname
2032                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2033        | type_name '.' TYPEDEFname
2034                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2035        | typegen_name
2036        | '.' typegen_name
2037                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2038        | type_name '.' typegen_name
2039                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2040        ;
2041
2042typegen_name:                                                                                   // CFA
2043        TYPEGENname
2044                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2045        | TYPEGENname '(' ')'
2046                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2047        | TYPEGENname '(' type_list ')'
2048                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2049        ;
2050
2051elaborated_type:                                                                                // struct, union, enum
2052        aggregate_type
2053        | enum_type
2054        ;
2055
2056elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2057        aggregate_type_nobody
2058        | enum_type_nobody
2059        ;
2060
2061aggregate_type:                                                                                 // struct, union
2062        aggregate_key attribute_list_opt
2063                { forall = false; }                                                             // reset
2064          '{' field_declaration_list_opt '}' type_parameters_opt
2065                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2066        | aggregate_key attribute_list_opt identifier
2067                {
2068                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2069                        forall = false;                                                         // reset
2070                }
2071          '{' field_declaration_list_opt '}' type_parameters_opt
2072                { $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 ); }
2073        | aggregate_key attribute_list_opt TYPEDEFname          // unqualified type name
2074                {
2075                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2076                        forall = false;                                                         // reset
2077                }
2078          '{' field_declaration_list_opt '}' type_parameters_opt
2079                {
2080                        DeclarationNode::newFromTypedef( $3 );
2081                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2082                }
2083        | aggregate_key attribute_list_opt TYPEGENname          // unqualified type name
2084                {
2085                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2086                        forall = false;                                                         // reset
2087                }
2088          '{' field_declaration_list_opt '}' type_parameters_opt
2089                {
2090                        DeclarationNode::newFromTypeGen( $3, nullptr );
2091                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2092                }
2093        | aggregate_type_nobody
2094        ;
2095
2096type_parameters_opt:
2097        // empty
2098                { $$ = nullptr; }                                                               %prec '}'
2099        | '(' type_list ')'
2100                { $$ = $2; }
2101        ;
2102
2103aggregate_type_nobody:                                                                  // struct, union - {...}
2104        aggregate_key attribute_list_opt identifier
2105                {
2106                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2107                        forall = false;                                                         // reset
2108                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2109                }
2110        | aggregate_key attribute_list_opt type_name
2111                {
2112                        forall = false;                                                         // reset
2113                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2114                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2115                        // delete newFromTypeGen.
2116                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2117                        $3->type->symbolic.name = nullptr;
2118                        $3->type->symbolic.actuals = nullptr;
2119                        delete $3;
2120                }
2121        ;
2122
2123aggregate_key:
2124        aggregate_data
2125        | aggregate_control
2126        ;
2127
2128aggregate_data:
2129        STRUCT vtable_opt
2130                { yyy = true; $$ = AggregateDecl::Struct; }
2131        | UNION
2132                { yyy = true; $$ = AggregateDecl::Union; }
2133        | EXCEPTION                                                                                     // CFA
2134                { yyy = true; $$ = AggregateDecl::Exception; }
2135          //            { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2136        ;
2137
2138aggregate_control:                                                                              // CFA
2139        MONITOR
2140                { yyy = true; $$ = AggregateDecl::Monitor; }
2141        | MUTEX STRUCT
2142                { yyy = true; $$ = AggregateDecl::Monitor; }
2143        | GENERATOR
2144                { yyy = true; $$ = AggregateDecl::Generator; }
2145        | MUTEX GENERATOR
2146                { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2147        | COROUTINE
2148                { yyy = true; $$ = AggregateDecl::Coroutine; }
2149        | MUTEX COROUTINE
2150                { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2151        | THREAD
2152                { yyy = true; $$ = AggregateDecl::Thread; }
2153        | MUTEX THREAD
2154                { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2155        ;
2156
2157field_declaration_list_opt:
2158        // empty
2159                { $$ = nullptr; }
2160        | field_declaration_list_opt field_declaration
2161                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2162        ;
2163
2164field_declaration:
2165        type_specifier field_declaring_list_opt ';'
2166                { $$ = fieldDecl( $1, $2 ); }
2167        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2168                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2169        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2170                {
2171                        if ( ! $3 ) {                                                           // field declarator ?
2172                                $3 = DeclarationNode::newName( nullptr );
2173                        } // if
2174                        $3->inLine = true;
2175                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2176                        distInl( $3 );
2177                }
2178        | INLINE aggregate_control ';'                                          // CFA
2179                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2180        | typedef_declaration ';'                                                       // CFA
2181        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2182        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2183                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2184        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2185                { $$ = $2; }                                                                    // mark all fields in list
2186        | cfa_typedef_declaration ';'                                           // CFA
2187        | static_assert                                                                         // C11
2188        ;
2189
2190field_declaring_list_opt:
2191        // empty
2192                { $$ = nullptr; }
2193        | field_declarator
2194        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2195                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2196        ;
2197
2198field_declarator:
2199        bit_subrange_size                                                                       // C special case, no field name
2200                { $$ = DeclarationNode::newBitfield( $1 ); }
2201        | variable_declarator bit_subrange_size_opt
2202                // A semantic check is required to ensure bit_subrange only appears on integral types.
2203                { $$ = $1->addBitfield( $2 ); }
2204        | variable_type_redeclarator bit_subrange_size_opt
2205                // A semantic check is required to ensure bit_subrange only appears on integral types.
2206                { $$ = $1->addBitfield( $2 ); }
2207        ;
2208
2209field_abstract_list_opt:
2210        // empty
2211                { $$ = nullptr; }
2212        | field_abstract
2213        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2214                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2215        ;
2216
2217field_abstract:
2218                //      no bit fields
2219        variable_abstract_declarator
2220        ;
2221
2222cfa_field_declaring_list:                                                               // CFA, new style field declaration
2223        // bit-fields are handled by C declarations
2224        cfa_abstract_declarator_tuple identifier_or_type_name
2225                { $$ = $1->addName( $2 ); }
2226        | cfa_field_declaring_list ',' identifier_or_type_name
2227                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2228        ;
2229
2230cfa_field_abstract_list:                                                                // CFA, new style field declaration
2231        // bit-fields are handled by C declarations
2232        cfa_abstract_declarator_tuple
2233        | cfa_field_abstract_list ','
2234                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2235        ;
2236
2237bit_subrange_size_opt:
2238        // empty
2239                { $$ = nullptr; }
2240        | bit_subrange_size
2241        ;
2242
2243bit_subrange_size:
2244        ':' assignment_expression
2245                { $$ = $2; }
2246        ;
2247
2248enum_type:                                                                                              // enum
2249        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2250                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2251        | ENUM attribute_list_opt identifier
2252                { typedefTable.makeTypedef( *$3 ); }
2253          '{' enumerator_list comma_opt '}'
2254                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2255        | ENUM attribute_list_opt typedef_name                          // unqualified type name
2256          '{' enumerator_list comma_opt '}'
2257                { $$ = DeclarationNode::newEnum( $3->name, $5, true )->addQualifiers( $2 ); }
2258        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2259                {
2260                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2261                        SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2262                }
2263        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2264                {
2265                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2266                        typedefTable.makeTypedef( *$6 );
2267                }
2268          '{' enumerator_list comma_opt '}'
2269                {
2270                        SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2271                }
2272        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt '{' enumerator_list comma_opt '}'
2273                {
2274                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2275                        typedefTable.makeTypedef( *$6->name );
2276                        SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2277                }
2278        | enum_type_nobody
2279        ;
2280
2281enum_type_nobody:                                                                               // enum - {...}
2282        ENUM attribute_list_opt identifier
2283                { typedefTable.makeTypedef( *$3 ); $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 ); }
2284        | ENUM attribute_list_opt type_name                                     // qualified type name
2285                { typedefTable.makeTypedef( *$3->type->symbolic.name ); $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 ); }
2286        ;
2287
2288enumerator_list:
2289        identifier_or_type_name enumerator_value_opt
2290                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2291        | INLINE type_name
2292                { $$ = DeclarationNode::newEnumConstant( new string("inline"), nullptr ); }
2293        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2294                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2295        | enumerator_list ',' INLINE type_name enumerator_value_opt
2296                { $$ = $1->appendList( DeclarationNode::newEnumConstant( new string("inline"), nullptr ) ); }
2297        ;
2298
2299enumerator_value_opt:
2300        // empty
2301                { $$ = nullptr; }
2302        // | '=' constant_expression
2303        //      { $$ = $2; }
2304        | simple_assignment_operator initializer
2305                { $$ = $2->get_expression(); }                                  // FIX ME: enum only deals with constant_expression
2306        ;
2307
2308cfa_parameter_ellipsis_list_opt:                                                // CFA, abstract + real
2309        // empty
2310                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2311        | ELLIPSIS
2312                { $$ = nullptr; }
2313        | cfa_abstract_parameter_list
2314        | cfa_parameter_list
2315        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2316                { $$ = $1->appendList( $5 ); }
2317        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2318                { $$ = $1->addVarArgs(); }
2319        | cfa_parameter_list pop ',' push ELLIPSIS
2320                { $$ = $1->addVarArgs(); }
2321        ;
2322
2323cfa_parameter_list:                                                                             // CFA
2324                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2325                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2326        cfa_parameter_declaration
2327        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2328                { $$ = $1->appendList( $5 ); }
2329        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2330                { $$ = $1->appendList( $5 ); }
2331        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2332                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2333        ;
2334
2335cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2336        cfa_abstract_parameter_declaration
2337        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2338                { $$ = $1->appendList( $5 ); }
2339        ;
2340
2341parameter_type_list_opt:
2342        // empty
2343                { $$ = nullptr; }
2344        | ELLIPSIS
2345                { $$ = nullptr; }
2346        | parameter_list
2347        | parameter_list pop ',' push ELLIPSIS
2348                { $$ = $1->addVarArgs(); }
2349        ;
2350
2351parameter_list:                                                                                 // abstract + real
2352        abstract_parameter_declaration
2353        | parameter_declaration
2354        | parameter_list pop ',' push abstract_parameter_declaration
2355                { $$ = $1->appendList( $5 ); }
2356        | parameter_list pop ',' push parameter_declaration
2357                { $$ = $1->appendList( $5 ); }
2358        ;
2359
2360// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2361// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2362
2363cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2364        parameter_declaration
2365        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2366                { $$ = $1->addName( $2 ); }
2367        | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2368                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2369                { $$ = $1->addName( $2 ); }
2370        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2371                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2372        | cfa_function_specifier
2373        ;
2374
2375cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2376        abstract_parameter_declaration
2377        | cfa_identifier_parameter_declarator_no_tuple
2378        | cfa_abstract_tuple
2379                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2380        | type_qualifier_list cfa_abstract_tuple
2381                { $$ = $2->addQualifiers( $1 ); }
2382        | cfa_abstract_function
2383        ;
2384
2385parameter_declaration:
2386                // No SUE declaration in parameter list.
2387        declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2388                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2389        | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2390                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2391        ;
2392
2393abstract_parameter_declaration:
2394        declaration_specifier_nobody default_initializer_opt
2395                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2396        | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2397                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2398        ;
2399
2400// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2401// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2402// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2403
2404identifier_list:                                                                                // K&R-style parameter list => no types
2405        identifier
2406                { $$ = DeclarationNode::newName( $1 ); }
2407        | identifier_list ',' identifier
2408                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2409        ;
2410
2411identifier_or_type_name:
2412        identifier
2413        | TYPEDEFname
2414        | TYPEGENname
2415        ;
2416
2417type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2418        cfa_abstract_declarator_tuple                                           // CFA
2419        | type_specifier
2420        | type_specifier abstract_declarator
2421                { $$ = $2->addType( $1 ); }
2422        ;
2423
2424type:                                                                                                   // typeof, assertion
2425        type_no_function
2426        | cfa_abstract_function                                                         // CFA
2427        ;
2428
2429initializer_opt:
2430        // empty
2431                { $$ = nullptr; }
2432        | simple_assignment_operator initializer        { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2433        | '=' VOID                                                                      { $$ = new InitializerNode( true ); }
2434        ;
2435
2436initializer:
2437        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2438        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2439        ;
2440
2441initializer_list_opt:
2442        // empty
2443                { $$ = nullptr; }
2444        | initializer
2445        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2446        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2447        | initializer_list_opt ',' designation initializer
2448                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2449        ;
2450
2451// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2452// '=' to separator the designator from the initializer value, as in:
2453//
2454//              int x[10] = { [1] = 3 };
2455//
2456// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2457// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2458// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2459// shift/reduce conflicts
2460
2461designation:
2462        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2463        | identifier ':'                                                                        // GCC, field name
2464                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2465        ;
2466
2467designator_list:                                                                                // C99
2468        designator
2469        | designator_list designator
2470                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2471        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2472        ;
2473
2474designator:
2475        '.' identifier                                                                          // C99, field name
2476                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2477        | '[' push assignment_expression pop ']'                        // C99, single array element
2478                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2479                { $$ = $3; }
2480        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2481                { $$ = $3; }
2482        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2483                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $3 ), maybeMoveBuild<Expression>( $5 ) ) ); }
2484        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2485                { $$ = $4; }
2486        ;
2487
2488// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2489// rather than an object-oriented type system. This required four groups of extensions:
2490//
2491// Overloading: function, data, and operator identifiers may be overloaded.
2492//
2493// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2494//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2495//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2496//
2497// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2498//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2499//
2500// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2501//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2502//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2503//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2504//     on type arguments of polymorphic functions.
2505
2506type_parameter_list:                                                                    // CFA
2507        type_parameter
2508        | type_parameter_list ',' type_parameter
2509                { $$ = $1->appendList( $3 ); }
2510        ;
2511
2512type_initializer_opt:                                                                   // CFA
2513        // empty
2514                { $$ = nullptr; }
2515        | '=' type
2516                { $$ = $2; }
2517        ;
2518
2519type_parameter:                                                                                 // CFA
2520        type_class identifier_or_type_name
2521                {
2522                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2523                        if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2524                        if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2525                        if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2526                }
2527          type_initializer_opt assertion_list_opt
2528                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2529        | identifier_or_type_name new_type_class
2530                { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2531          type_initializer_opt assertion_list_opt
2532                { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2533        | '[' identifier_or_type_name ']'
2534                {
2535                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2536                        $$ = DeclarationNode::newTypeParam( TypeDecl::ALtype, $2 );
2537                }
2538        // | type_specifier identifier_parameter_declarator
2539        | assertion_list
2540                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2541        ;
2542
2543new_type_class:                                                                                 // CFA
2544        // empty
2545                { $$ = TypeDecl::Otype; }
2546        | '&'
2547                { $$ = TypeDecl::Dtype; }
2548        | '*'
2549                { $$ = TypeDecl::DStype; }                                              // dtype + sized
2550        | ELLIPSIS
2551                { $$ = TypeDecl::Ttype; }
2552        ;
2553
2554type_class:                                                                                             // CFA
2555        OTYPE
2556                { $$ = TypeDecl::Otype; }
2557        | DTYPE
2558                { $$ = TypeDecl::Dtype; }
2559        | FTYPE
2560                { $$ = TypeDecl::Ftype; }
2561        | TTYPE
2562                { $$ = TypeDecl::Ttype; }
2563        ;
2564
2565assertion_list_opt:                                                                             // CFA
2566        // empty
2567                { $$ = nullptr; }
2568        | assertion_list
2569        ;
2570
2571assertion_list:                                                                                 // CFA
2572        assertion
2573        | assertion_list assertion
2574                { $$ = $1->appendList( $2 ); }
2575        ;
2576
2577assertion:                                                                                              // CFA
2578        '|' identifier_or_type_name '(' type_list ')'
2579                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2580        | '|' '{' push trait_declaration_list pop '}'
2581                { $$ = $4; }
2582        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2583        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2584        ;
2585
2586type_list:                                                                                              // CFA
2587        type
2588                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2589        | assignment_expression
2590                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2591        | type_list ',' type
2592                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2593        | type_list ',' assignment_expression
2594                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2595                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2596        ;
2597
2598type_declaring_list:                                                                    // CFA
2599        OTYPE type_declarator
2600                { $$ = $2; }
2601        | storage_class_list OTYPE type_declarator
2602                { $$ = $3->addQualifiers( $1 ); }
2603        | type_declaring_list ',' type_declarator
2604                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2605        ;
2606
2607type_declarator:                                                                                // CFA
2608        type_declarator_name assertion_list_opt
2609                { $$ = $1->addAssertions( $2 ); }
2610        | type_declarator_name assertion_list_opt '=' type
2611                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2612        ;
2613
2614type_declarator_name:                                                                   // CFA
2615        identifier_or_type_name
2616                {
2617                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2618                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2619                }
2620        | identifier_or_type_name '(' type_parameter_list ')'
2621                {
2622                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2623                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2624                }
2625        ;
2626
2627trait_specifier:                                                                                // CFA
2628        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2629                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2630        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2631                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2632        ;
2633
2634trait_declaration_list:                                                                 // CFA
2635        trait_declaration
2636        | trait_declaration_list pop push trait_declaration
2637                { $$ = $1->appendList( $4 ); }
2638        ;
2639
2640trait_declaration:                                                                              // CFA
2641        cfa_trait_declaring_list ';'
2642        | trait_declaring_list ';'
2643        ;
2644
2645cfa_trait_declaring_list:                                                               // CFA
2646        cfa_variable_specifier
2647        | cfa_function_specifier
2648        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2649                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2650        ;
2651
2652trait_declaring_list:                                                                   // CFA
2653        type_specifier declarator
2654                { $$ = $2->addType( $1 ); }
2655        | trait_declaring_list pop ',' push declarator
2656                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2657        ;
2658
2659//***************************** EXTERNAL DEFINITIONS *****************************
2660
2661translation_unit:
2662        // empty, input file
2663        | external_definition_list
2664                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2665        ;
2666
2667external_definition_list:
2668        push external_definition pop
2669                { $$ = $2; }
2670        | external_definition_list push external_definition pop
2671                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2672        ;
2673
2674external_definition_list_opt:
2675        // empty
2676                { $$ = nullptr; }
2677        | external_definition_list
2678        ;
2679
2680up:
2681                { typedefTable.up( forall ); forall = false; }
2682        ;
2683
2684down:
2685                { typedefTable.down(); }
2686        ;
2687
2688external_definition:
2689        DIRECTIVE
2690                { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( $1 ) ) ); }
2691        | declaration
2692        | external_function_definition
2693        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2694                {
2695                        distExt( $2 );                                                          // mark all fields in list
2696                        $$ = $2;
2697                }
2698        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2699                { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) ); }
2700        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2701                {
2702                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2703                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2704                }
2705          '{' up external_definition_list_opt down '}'
2706                {
2707                        linkage = linkageStack.top();
2708                        linkageStack.pop();
2709                        $$ = $6;
2710                }
2711        | type_qualifier_list
2712                {
2713                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2714                        if ( $1->type->forall ) forall = true;          // remember generic type
2715                }
2716          '{' up external_definition_list_opt down '}'          // CFA, namespace
2717                {
2718                        distQual( $5, $1 );
2719                        forall = false;
2720                        $$ = $5;
2721                }
2722        | declaration_qualifier_list
2723                {
2724                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2725                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2726                }
2727          '{' up external_definition_list_opt down '}'          // CFA, namespace
2728                {
2729                        distQual( $5, $1 );
2730                        forall = false;
2731                        $$ = $5;
2732                }
2733        | declaration_qualifier_list type_qualifier_list
2734                {
2735                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2736                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2737                }
2738          '{' up external_definition_list_opt down '}'          // CFA, namespace
2739                {
2740                        distQual( $6, $1->addQualifiers( $2 ) );
2741                        forall = false;
2742                        $$ = $6;
2743                }
2744        ;
2745
2746external_function_definition:
2747        function_definition
2748                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2749                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2750                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2751                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2752                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2753        | function_declarator compound_statement
2754                { $$ = $1->addFunctionBody( $2 ); }
2755        | KR_function_declarator KR_parameter_list_opt compound_statement
2756                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2757        ;
2758
2759with_clause_opt:
2760        // empty
2761                { $$ = nullptr; forall = false; }
2762        | WITH '(' tuple_expression_list ')'
2763                { $$ = $3; forall = false; }
2764        ;
2765
2766function_definition:
2767        cfa_function_declaration with_clause_opt compound_statement     // CFA
2768                {
2769                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2770                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2771                        $1->get_last()->addFunctionBody( $3, $2 );
2772                        $$ = $1;
2773                }
2774        | declaration_specifier function_declarator with_clause_opt compound_statement
2775                {
2776                        rebindForall( $1, $2 );
2777                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2778                }
2779        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2780                {
2781                        rebindForall( $1, $2 );
2782                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2783                }
2784                // handles default int return type, OBSOLESCENT (see 1)
2785        | type_qualifier_list function_declarator with_clause_opt compound_statement
2786                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2787                // handles default int return type, OBSOLESCENT (see 1)
2788        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2789                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2790                // handles default int return type, OBSOLESCENT (see 1)
2791        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2792                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2793
2794                // Old-style K&R function definition, OBSOLESCENT (see 4)
2795        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2796                {
2797                        rebindForall( $1, $2 );
2798                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2799                }
2800                // handles default int return type, OBSOLESCENT (see 1)
2801        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2802                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2803                // handles default int return type, OBSOLESCENT (see 1)
2804        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2805                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2806                // handles default int return type, OBSOLESCENT (see 1)
2807        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2808                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2809        ;
2810
2811declarator:
2812        variable_declarator
2813        | variable_type_redeclarator
2814        | function_declarator
2815        ;
2816
2817subrange:
2818        constant_expression '~' constant_expression                     // CFA, integer subrange
2819                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
2820        ;
2821
2822asm_name_opt:                                                                                   // GCC
2823        // empty
2824                { $$ = nullptr; }
2825        | ASM '(' string_literal ')' attribute_list_opt
2826                {
2827                        DeclarationNode * name = new DeclarationNode();
2828                        name->asmName = $3;
2829                        $$ = name->addQualifiers( $5 );
2830                }
2831        ;
2832
2833attribute_list_opt:                                                                             // GCC
2834        // empty
2835                { $$ = nullptr; }
2836        | attribute_list
2837        ;
2838
2839attribute_list:                                                                                 // GCC
2840        attribute
2841        | attribute_list attribute
2842                { $$ = $2->addQualifiers( $1 ); }
2843        ;
2844
2845attribute:                                                                                              // GCC
2846        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2847                { $$ = $4; }
2848        ;
2849
2850attribute_name_list:                                                                    // GCC
2851        attribute_name
2852        | attribute_name_list ',' attribute_name
2853                { $$ = $3->addQualifiers( $1 ); }
2854        ;
2855
2856attribute_name:                                                                                 // GCC
2857        // empty
2858                { $$ = nullptr; }
2859        | attr_name
2860                { $$ = DeclarationNode::newAttribute( $1 ); }
2861        | attr_name '(' argument_expression_list_opt ')'
2862                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2863        ;
2864
2865attr_name:                                                                                              // GCC
2866        IDENTIFIER
2867        | quasi_keyword
2868        | TYPEDEFname
2869        | TYPEGENname
2870        | FALLTHROUGH
2871                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2872        | CONST
2873                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2874        ;
2875
2876// ============================================================================
2877// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2878// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2879// in:
2880//
2881//              int (*f())[10] { ... };
2882//              ... (*f())[3] += 1;             // definition mimics usage
2883//
2884// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2885// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2886// ============================================================================
2887
2888// ----------------------------------------------------------------------------
2889// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2890// to define a variable or function prototype, e.g.:
2891//
2892//              valid declaration               invalid definition
2893//              -----------------               ------------------
2894//              int f;                                  int f {}
2895//              int *f;                                 int *f {}
2896//              int f[10];                              int f[10] {}
2897//              int (*f)(int);                  int (*f)(int) {}
2898//
2899// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2900// variable_declarator and function_declarator.
2901// ----------------------------------------------------------------------------
2902
2903// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2904// declaring an array of functions versus a pointer to an array of functions.
2905
2906paren_identifier:
2907        identifier
2908                { $$ = DeclarationNode::newName( $1 ); }
2909        | '(' paren_identifier ')'                                                      // redundant parenthesis
2910                { $$ = $2; }
2911        ;
2912
2913variable_declarator:
2914        paren_identifier attribute_list_opt
2915                { $$ = $1->addQualifiers( $2 ); }
2916        | variable_ptr
2917        | variable_array attribute_list_opt
2918                { $$ = $1->addQualifiers( $2 ); }
2919        | variable_function attribute_list_opt
2920                { $$ = $1->addQualifiers( $2 ); }
2921        ;
2922
2923variable_ptr:
2924        ptrref_operator variable_declarator
2925                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2926        | ptrref_operator type_qualifier_list variable_declarator
2927                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2928        | '(' variable_ptr ')' attribute_list_opt                       // redundant parenthesis
2929                { $$ = $2->addQualifiers( $4 ); }
2930        | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
2931                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
2932        ;
2933
2934variable_array:
2935        paren_identifier array_dimension
2936                { $$ = $1->addArray( $2 ); }
2937        | '(' variable_ptr ')' array_dimension
2938                { $$ = $2->addArray( $4 ); }
2939        | '(' attribute_list variable_ptr ')' array_dimension
2940                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
2941        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2942                { $$ = $2->addArray( $4 ); }
2943        | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
2944                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
2945        | '(' variable_array ')'                                                        // redundant parenthesis
2946                { $$ = $2; }
2947        | '(' attribute_list variable_array ')'                         // redundant parenthesis
2948                { $$ = $3->addQualifiers( $2 ); }
2949        ;
2950
2951variable_function:
2952        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2953                { $$ = $2->addParamList( $6 ); }
2954        | '(' attribute_list variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2955                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
2956        | '(' variable_function ')'                                                     // redundant parenthesis
2957                { $$ = $2; }
2958        | '(' attribute_list variable_function ')'                      // redundant parenthesis
2959                { $$ = $3->addQualifiers( $2 ); }
2960        ;
2961
2962// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2963// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2964// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2965
2966function_declarator:
2967        function_no_ptr attribute_list_opt
2968                { $$ = $1->addQualifiers( $2 ); }
2969        | function_ptr
2970        | function_array attribute_list_opt
2971                { $$ = $1->addQualifiers( $2 ); }
2972        ;
2973
2974function_no_ptr:
2975        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2976                { $$ = $1->addParamList( $4 ); }
2977        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2978                { $$ = $2->addParamList( $6 ); }
2979        | '(' attribute_list function_ptr ')' '(' push parameter_type_list_opt pop ')'
2980                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
2981        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2982                { $$ = $2; }
2983        | '(' attribute_list function_no_ptr ')'                        // redundant parenthesis
2984                { $$ = $3->addQualifiers( $2 ); }
2985        ;
2986
2987function_ptr:
2988        ptrref_operator function_declarator
2989                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2990        | ptrref_operator type_qualifier_list function_declarator
2991                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2992        | '(' function_ptr ')' attribute_list_opt
2993                { $$ = $2->addQualifiers( $4 ); }
2994        | '(' attribute_list function_ptr ')' attribute_list_opt
2995                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
2996        ;
2997
2998function_array:
2999        '(' function_ptr ')' array_dimension
3000                { $$ = $2->addArray( $4 ); }
3001        | '(' attribute_list function_ptr ')' array_dimension
3002                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3003        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
3004                { $$ = $2->addArray( $4 ); }
3005        | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3006                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3007        | '(' function_array ')'                                                        // redundant parenthesis
3008                { $$ = $2; }
3009        | '(' attribute_list function_array ')'                         // redundant parenthesis
3010                { $$ = $3->addQualifiers( $2 ); }
3011        ;
3012
3013// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3014//
3015//   f( a, b, c ) int a, *b, c[]; {}
3016//
3017// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3018// returning arrays and functions versus pointers to arrays and functions.
3019
3020KR_function_declarator:
3021        KR_function_no_ptr
3022        | KR_function_ptr
3023        | KR_function_array
3024        ;
3025
3026KR_function_no_ptr:
3027        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
3028                { $$ = $1->addIdList( $3 ); }
3029        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3030                { $$ = $2->addParamList( $6 ); }
3031        | '(' attribute_list KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3032                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3033        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
3034                { $$ = $2; }
3035        | '(' attribute_list KR_function_no_ptr ')'                     // redundant parenthesis
3036                { $$ = $3->addQualifiers( $2 ); }
3037        ;
3038
3039KR_function_ptr:
3040        ptrref_operator KR_function_declarator
3041                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3042        | ptrref_operator type_qualifier_list KR_function_declarator
3043                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3044        | '(' KR_function_ptr ')'
3045                { $$ = $2; }
3046        | '(' attribute_list KR_function_ptr ')'
3047                { $$ = $3->addQualifiers( $2 ); }
3048        ;
3049
3050KR_function_array:
3051        '(' KR_function_ptr ')' array_dimension
3052                { $$ = $2->addArray( $4 ); }
3053        | '(' attribute_list KR_function_ptr ')' array_dimension
3054                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3055        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
3056                { $$ = $2->addArray( $4 ); }
3057        | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3058                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3059        | '(' KR_function_array ')'                                                     // redundant parenthesis
3060                { $$ = $2; }
3061        | '(' attribute_list KR_function_array ')'                      // redundant parenthesis
3062                { $$ = $3->addQualifiers( $2 ); }
3063        ;
3064
3065// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
3066//
3067//              typedef int foo;
3068//              {
3069//                 int foo; // redefine typedef name in new scope
3070//              }
3071//
3072// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3073// and functions versus pointers to arrays and functions.
3074
3075paren_type:
3076        typedef_name
3077                {
3078                        // hide type name in enclosing scope by variable name
3079                        typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3080                }
3081        | '(' paren_type ')'
3082                { $$ = $2; }
3083        ;
3084
3085variable_type_redeclarator:
3086        paren_type attribute_list_opt
3087                { $$ = $1->addQualifiers( $2 ); }
3088        | type_ptr
3089        | type_array attribute_list_opt
3090                { $$ = $1->addQualifiers( $2 ); }
3091        | type_function attribute_list_opt
3092                { $$ = $1->addQualifiers( $2 ); }
3093        ;
3094
3095type_ptr:
3096        ptrref_operator variable_type_redeclarator
3097                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3098        | ptrref_operator type_qualifier_list variable_type_redeclarator
3099                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3100        | '(' type_ptr ')' attribute_list_opt                           // redundant parenthesis
3101                { $$ = $2->addQualifiers( $4 ); }
3102        | '(' attribute_list type_ptr ')' attribute_list_opt // redundant parenthesis
3103                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3104        ;
3105
3106type_array:
3107        paren_type array_dimension
3108                { $$ = $1->addArray( $2 ); }
3109        | '(' type_ptr ')' array_dimension
3110                { $$ = $2->addArray( $4 ); }
3111        | '(' attribute_list type_ptr ')' array_dimension
3112                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3113        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
3114                { $$ = $2->addArray( $4 ); }
3115        | '(' attribute_list type_array ')' multi_array_dimension // redundant parenthesis
3116                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3117        | '(' type_array ')'                                                            // redundant parenthesis
3118                { $$ = $2; }
3119        | '(' attribute_list type_array ')'                                     // redundant parenthesis
3120                { $$ = $3->addQualifiers( $2 ); }
3121        ;
3122
3123type_function:
3124        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3125                { $$ = $1->addParamList( $4 ); }
3126        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3127                { $$ = $2->addParamList( $6 ); }
3128        | '(' attribute_list type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3129                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3130        | '(' type_function ')'                                                         // redundant parenthesis
3131                { $$ = $2; }
3132        | '(' attribute_list type_function ')'                          // redundant parenthesis
3133                { $$ = $3->addQualifiers( $2 ); }
3134        ;
3135
3136// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3137// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
3138// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3139// pointers to arrays and functions.
3140
3141identifier_parameter_declarator:
3142        paren_identifier attribute_list_opt
3143                { $$ = $1->addQualifiers( $2 ); }
3144        | '&' MUTEX paren_identifier attribute_list_opt
3145                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3146        | identifier_parameter_ptr
3147        | identifier_parameter_array attribute_list_opt
3148                { $$ = $1->addQualifiers( $2 ); }
3149        | identifier_parameter_function attribute_list_opt
3150                { $$ = $1->addQualifiers( $2 ); }
3151        ;
3152
3153identifier_parameter_ptr:
3154        ptrref_operator identifier_parameter_declarator
3155                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3156        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3157                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3158        | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3159                { $$ = $2->addQualifiers( $4 ); }
3160        ;
3161
3162identifier_parameter_array:
3163        paren_identifier array_parameter_dimension
3164                { $$ = $1->addArray( $2 ); }
3165        | '(' identifier_parameter_ptr ')' array_dimension
3166                { $$ = $2->addArray( $4 ); }
3167        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3168                { $$ = $2->addArray( $4 ); }
3169        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3170                { $$ = $2; }
3171        ;
3172
3173identifier_parameter_function:
3174        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3175                { $$ = $1->addParamList( $4 ); }
3176        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3177                { $$ = $2->addParamList( $6 ); }
3178        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3179                { $$ = $2; }
3180        ;
3181
3182// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3183// e.g.:
3184//
3185//              typedef int foo;
3186//              forall( otype T ) struct foo;
3187//              int f( int foo ); // redefine typedef name in new scope
3188//
3189// and allows the C99 array options, which can only appear in a parameter list.
3190
3191type_parameter_redeclarator:
3192        typedef_name attribute_list_opt
3193                { $$ = $1->addQualifiers( $2 ); }
3194        | '&' MUTEX typedef_name attribute_list_opt
3195                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3196        | type_parameter_ptr
3197        | type_parameter_array attribute_list_opt
3198                { $$ = $1->addQualifiers( $2 ); }
3199        | type_parameter_function attribute_list_opt
3200                { $$ = $1->addQualifiers( $2 ); }
3201        ;
3202
3203typedef_name:
3204        TYPEDEFname
3205                { $$ = DeclarationNode::newName( $1 ); }
3206        | TYPEGENname
3207                { $$ = DeclarationNode::newName( $1 ); }
3208        ;
3209
3210type_parameter_ptr:
3211        ptrref_operator type_parameter_redeclarator
3212                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3213        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3214                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3215        | '(' type_parameter_ptr ')' attribute_list_opt         // redundant parenthesis
3216                { $$ = $2->addQualifiers( $4 ); }
3217        ;
3218
3219type_parameter_array:
3220        typedef_name array_parameter_dimension
3221                { $$ = $1->addArray( $2 ); }
3222        | '(' type_parameter_ptr ')' array_parameter_dimension
3223                { $$ = $2->addArray( $4 ); }
3224        ;
3225
3226type_parameter_function:
3227        typedef_name '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3228                { $$ = $1->addParamList( $4 ); }
3229        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3230                { $$ = $2->addParamList( $6 ); }
3231        ;
3232
3233// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3234// which the type applies, e.g.:
3235//
3236//              sizeof( int );
3237//              sizeof( int * );
3238//              sizeof( int [10] );
3239//              sizeof( int (*)() );
3240//              sizeof( int () );
3241//
3242// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3243// and functions versus pointers to arrays and functions.
3244
3245abstract_declarator:
3246        abstract_ptr
3247        | abstract_array attribute_list_opt
3248                { $$ = $1->addQualifiers( $2 ); }
3249        | abstract_function attribute_list_opt
3250                { $$ = $1->addQualifiers( $2 ); }
3251        ;
3252
3253abstract_ptr:
3254        ptrref_operator
3255                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3256        | ptrref_operator type_qualifier_list
3257                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3258        | ptrref_operator abstract_declarator
3259                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3260        | ptrref_operator type_qualifier_list abstract_declarator
3261                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3262        | '(' abstract_ptr ')' attribute_list_opt
3263                { $$ = $2->addQualifiers( $4 ); }
3264        ;
3265
3266abstract_array:
3267        array_dimension
3268        | '(' abstract_ptr ')' array_dimension
3269                { $$ = $2->addArray( $4 ); }
3270        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3271                { $$ = $2->addArray( $4 ); }
3272        | '(' abstract_array ')'                                                        // redundant parenthesis
3273                { $$ = $2; }
3274        ;
3275
3276abstract_function:
3277        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3278                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3279        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3280                { $$ = $2->addParamList( $6 ); }
3281        | '(' abstract_function ')'                                                     // redundant parenthesis
3282                { $$ = $2; }
3283        ;
3284
3285array_dimension:
3286                // Only the first dimension can be empty.
3287        '[' ']'
3288                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3289        | '[' ']' multi_array_dimension
3290                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3291        | '[' push assignment_expression pop ',' comma_expression ']'
3292                { $$ = DeclarationNode::newArray( $3, 0, false )->addArray( DeclarationNode::newArray( $6, 0, false ) ); }
3293                // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3294        | multi_array_dimension
3295        ;
3296
3297multi_array_dimension:
3298        '[' push assignment_expression pop ']'
3299                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3300        | '[' push '*' pop ']'                                                          // C99
3301                { $$ = DeclarationNode::newVarArray( 0 ); }
3302        | multi_array_dimension '[' push assignment_expression pop ']'
3303                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3304        | multi_array_dimension '[' push '*' pop ']'            // C99
3305                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3306        ;
3307
3308// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3309// identifier to which the type applies, e.g.:
3310//
3311//              int f( int );                   // not handled here
3312//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3313//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3314//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3315//
3316// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3317// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3318// special meaning of parenthesis around a typedef name:
3319//
3320//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3321//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3322//              not as redundant parentheses around the identifier."
3323//
3324// For example:
3325//
3326//              typedef float T;
3327//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3328//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3329//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3330//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3331//
3332// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3333// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3334// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3335// functions.
3336
3337abstract_parameter_declarator:
3338        abstract_parameter_ptr
3339        | '&' MUTEX attribute_list_opt
3340                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3341        | abstract_parameter_array attribute_list_opt
3342                { $$ = $1->addQualifiers( $2 ); }
3343        | abstract_parameter_function attribute_list_opt
3344                { $$ = $1->addQualifiers( $2 ); }
3345        ;
3346
3347abstract_parameter_ptr:
3348        ptrref_operator
3349                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3350        | ptrref_operator type_qualifier_list
3351                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3352        | ptrref_operator abstract_parameter_declarator
3353                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3354        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3355                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3356        | '(' abstract_parameter_ptr ')' attribute_list_opt     // redundant parenthesis
3357                { $$ = $2->addQualifiers( $4 ); }
3358        ;
3359
3360abstract_parameter_array:
3361        array_parameter_dimension
3362        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3363                { $$ = $2->addArray( $4 ); }
3364        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3365                { $$ = $2->addArray( $4 ); }
3366        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3367                { $$ = $2; }
3368        ;
3369
3370abstract_parameter_function:
3371        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3372                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3373        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3374                { $$ = $2->addParamList( $6 ); }
3375        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3376                { $$ = $2; }
3377        ;
3378
3379array_parameter_dimension:
3380                // Only the first dimension can be empty or have qualifiers.
3381        array_parameter_1st_dimension
3382        | array_parameter_1st_dimension multi_array_dimension
3383                { $$ = $1->addArray( $2 ); }
3384        | multi_array_dimension
3385        ;
3386
3387// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3388//
3389//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3390//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3391
3392array_parameter_1st_dimension:
3393        '[' ']'
3394                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3395                // multi_array_dimension handles the '[' '*' ']' case
3396        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3397                { $$ = DeclarationNode::newVarArray( $3 ); }
3398        | '[' push type_qualifier_list pop ']'
3399                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3400                // multi_array_dimension handles the '[' assignment_expression ']' case
3401        | '[' push type_qualifier_list assignment_expression pop ']'
3402                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3403        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3404                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3405        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3406                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3407        ;
3408
3409// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3410//
3411//              struct S {
3412//          int;
3413//          int *;
3414//          int [10];
3415//          int (*)();
3416//      };
3417
3418variable_abstract_declarator:
3419        variable_abstract_ptr
3420        | variable_abstract_array attribute_list_opt
3421                { $$ = $1->addQualifiers( $2 ); }
3422        | variable_abstract_function attribute_list_opt
3423                { $$ = $1->addQualifiers( $2 ); }
3424        ;
3425
3426variable_abstract_ptr:
3427        ptrref_operator
3428                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3429        | ptrref_operator type_qualifier_list
3430                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3431        | ptrref_operator variable_abstract_declarator
3432                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3433        | ptrref_operator type_qualifier_list variable_abstract_declarator
3434                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3435        | '(' variable_abstract_ptr ')' attribute_list_opt      // redundant parenthesis
3436                { $$ = $2->addQualifiers( $4 ); }
3437        ;
3438
3439variable_abstract_array:
3440        array_dimension
3441        | '(' variable_abstract_ptr ')' array_dimension
3442                { $$ = $2->addArray( $4 ); }
3443        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3444                { $$ = $2->addArray( $4 ); }
3445        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3446                { $$ = $2; }
3447        ;
3448
3449variable_abstract_function:
3450        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3451                { $$ = $2->addParamList( $6 ); }
3452        | '(' variable_abstract_function ')'                            // redundant parenthesis
3453                { $$ = $2; }
3454        ;
3455
3456// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3457// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3458
3459cfa_identifier_parameter_declarator_tuple:                              // CFA
3460        cfa_identifier_parameter_declarator_no_tuple
3461        | cfa_abstract_tuple
3462        | type_qualifier_list cfa_abstract_tuple
3463                { $$ = $2->addQualifiers( $1 ); }
3464        ;
3465
3466cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3467        cfa_identifier_parameter_ptr
3468        | cfa_identifier_parameter_array
3469        ;
3470
3471cfa_identifier_parameter_ptr:                                                   // CFA
3472                // No SUE declaration in parameter list.
3473        ptrref_operator type_specifier_nobody
3474                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3475        | type_qualifier_list ptrref_operator type_specifier_nobody
3476                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3477        | ptrref_operator cfa_abstract_function
3478                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3479        | type_qualifier_list ptrref_operator cfa_abstract_function
3480                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3481        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3482                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3483        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3484                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3485        ;
3486
3487cfa_identifier_parameter_array:                                                 // CFA
3488                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3489                // shift/reduce conflict with new-style empty (void) function return type.
3490        '[' ']' type_specifier_nobody
3491                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3492        | cfa_array_parameter_1st_dimension type_specifier_nobody
3493                { $$ = $2->addNewArray( $1 ); }
3494        | '[' ']' multi_array_dimension type_specifier_nobody
3495                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3496        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3497                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3498        | multi_array_dimension type_specifier_nobody
3499                { $$ = $2->addNewArray( $1 ); }
3500
3501        | '[' ']' cfa_identifier_parameter_ptr
3502                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3503        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3504                { $$ = $2->addNewArray( $1 ); }
3505        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3506                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3507        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3508                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3509        | multi_array_dimension cfa_identifier_parameter_ptr
3510                { $$ = $2->addNewArray( $1 ); }
3511        ;
3512
3513cfa_array_parameter_1st_dimension:
3514        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3515                { $$ = DeclarationNode::newVarArray( $3 ); }
3516        | '[' push type_qualifier_list assignment_expression pop ']'
3517                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3518        | '[' push declaration_qualifier_list assignment_expression pop ']'
3519                // declaration_qualifier_list must be used because of shift/reduce conflict with
3520                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3521                // appear in this context.
3522                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3523        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3524                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3525        ;
3526
3527// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3528// identifier to which the type applies, e.g.:
3529//
3530//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3531//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3532//
3533// These rules need LR(3):
3534//
3535//              cfa_abstract_tuple identifier_or_type_name
3536//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3537//
3538// since a function return type can be syntactically identical to a tuple type:
3539//
3540//              [int, int] t;
3541//              [int, int] f( int );
3542//
3543// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3544// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3545// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3546// duplicated when appearing with cfa_function_specifier.
3547
3548cfa_abstract_declarator_tuple:                                                  // CFA
3549        cfa_abstract_tuple
3550        | type_qualifier_list cfa_abstract_tuple
3551                { $$ = $2->addQualifiers( $1 ); }
3552        | cfa_abstract_declarator_no_tuple
3553        ;
3554
3555cfa_abstract_declarator_no_tuple:                                               // CFA
3556        cfa_abstract_ptr
3557        | cfa_abstract_array
3558        ;
3559
3560cfa_abstract_ptr:                                                                               // CFA
3561        ptrref_operator type_specifier
3562                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3563        | type_qualifier_list ptrref_operator type_specifier
3564                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3565        | ptrref_operator cfa_abstract_function
3566                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3567        | type_qualifier_list ptrref_operator cfa_abstract_function
3568                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3569        | ptrref_operator cfa_abstract_declarator_tuple
3570                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3571        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3572                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3573        ;
3574
3575cfa_abstract_array:                                                                             // CFA
3576                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3577                // empty (void) function return type.
3578        '[' ']' type_specifier
3579                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3580        | '[' ']' multi_array_dimension type_specifier
3581                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3582        | multi_array_dimension type_specifier
3583                { $$ = $2->addNewArray( $1 ); }
3584        | '[' ']' cfa_abstract_ptr
3585                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3586        | '[' ']' multi_array_dimension cfa_abstract_ptr
3587                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3588        | multi_array_dimension cfa_abstract_ptr
3589                { $$ = $2->addNewArray( $1 ); }
3590        ;
3591
3592cfa_abstract_tuple:                                                                             // CFA
3593        '[' push cfa_abstract_parameter_list pop ']'
3594                { $$ = DeclarationNode::newTuple( $3 ); }
3595        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3596                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3597        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3598                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3599        ;
3600
3601cfa_abstract_function:                                                                  // CFA
3602//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3603//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3604        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3605                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3606        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3607                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3608        ;
3609
3610// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3611//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3612//
3613// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3614//    the declaration specifiers in a declaration is an obsolescent feature."
3615//
3616// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3617//    prototype-format parameter type declarators) is an obsolescent feature."
3618//
3619// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3620//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3621
3622//************************* MISCELLANEOUS ********************************
3623
3624comma_opt:                                                                                              // redundant comma
3625        // empty
3626        | ','
3627        ;
3628
3629default_initializer_opt:
3630        // empty
3631                { $$ = nullptr; }
3632        | '=' assignment_expression
3633                { $$ = $2; }
3634        ;
3635
3636%%
3637
3638// ----end of grammar----
3639
3640// Local Variables: //
3641// mode: c++ //
3642// tab-width: 4 //
3643// compile-command: "make install" //
3644// End: //
Note: See TracBrowser for help on using the repository browser.