source: src/Parser/parser.yy @ 24711a3

arm-ehjacob/cs343-translationnew-ast-unique-expr
Last change on this file since 24711a3 was 24711a3, checked in by Peter A. Buhr <pabuhr@…>, 6 months ago

parse aggregate_control *, remove spurious yyy variable

  • Property mode set to 100644
File size: 144.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Mon Apr 26 18:41:54 2021
13// Update Count     : 4990
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT( yylval )                                    // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "SynTree/Declaration.h"
54#include "ParseNode.h"
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "SynTree/LinkageSpec.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61extern DeclarationNode * parseTree;
62extern LinkageSpec::Spec linkage;
63extern TypedefTable typedefTable;
64
65stack<LinkageSpec::Spec> linkageStack;
66
67bool appendStr( string & to, string & from ) {
68        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
69        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
70        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
71        //    easier to let the C compiler handle this case.
72        //
73        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
74        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
75        //    i.e., u"a" U"b" L"c" is disallowed.
76
77        if ( from[0] != '"' ) {                                                         // encoding ?
78                if ( to[0] != '"' ) {                                                   // encoding ?
79                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
80                                yyerror( "non-matching string encodings for string-literal concatenation" );
81                                return false;                                                   // parse error, must call YYERROR in action
82                        } else if ( from[1] == '8' ) {
83                                from.erase( 0, 1 );                                             // remove 2nd encoding
84                        } // if
85                } else {
86                        if ( from[1] == '8' ) {                                         // move encoding to start
87                                to = "u8" + to;
88                                from.erase( 0, 1 );                                             // remove 2nd encoding
89                        } else {
90                                to = from[0] + to;
91                        } // if
92                } // if
93                from.erase( 0, 1 );                                                             // remove 2nd encoding
94        } // if
95        to += " " + from;                                                                       // concatenated into single string
96        return true;
97} // appendStr
98
99DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
100        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
101        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
102        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
103                cl->cloneBaseType( cur );
104        } // for
105        declList->addType( cl );
106        return declList;
107} // distAttr
108
109void distExt( DeclarationNode * declaration ) {
110        // distribute EXTENSION across all declarations
111        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
112                iter->set_extension( true );
113        } // for
114} // distExt
115
116void distInl( DeclarationNode * declaration ) {
117        // distribute EXTENSION across all declarations
118        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
119                iter->set_inLine( true );
120        } // for
121} // distInl
122
123void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
124        // distribute qualifiers across all non-variable declarations in a distribution statemement
125        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
126                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
127                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
128                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
129                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
130                DeclarationNode * clone = qualifiers->clone();
131                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
132                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
133                                swap( clone->type->forall, iter->type->aggregate.params );
134                                iter->addQualifiers( clone );
135                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
136                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
137                                DeclarationNode newnode;
138                                swap( newnode.type, iter->type->aggInst.aggregate );
139                                swap( clone->type->forall, newnode.type->aggregate.params );
140                                newnode.addQualifiers( clone );
141                                swap( newnode.type, iter->type->aggInst.aggregate );
142                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
143                                swap( clone->type->forall, iter->type->forall );
144                                iter->addQualifiers( clone );
145                        } // if
146                } else {                                                                                // just SC qualifiers
147                        iter->addQualifiers( clone );
148                } // if
149        } // for
150        delete qualifiers;
151} // distQual
152
153// There is an ambiguity for inline generic-routine return-types and generic routines.
154//   forall( otype T ) struct S { int i; } bar( T ) {}
155// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
156//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
157// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
158//   forall( otype T ) struct S { int T; };
159//   forall( otype W ) bar( W ) {}
160
161void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
162        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
163                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
164                declSpec->type->aggregate.params = nullptr;
165        } // if
166} // rebindForall
167
168string * build_postfix_name( string * name ) {
169        *name = string("__postfix_func_") + *name;
170        return name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189                type = new ExpressionNode( new CastExpr( maybeMoveBuild<Expression>(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed." ); return nullptr;
210        } // if
211} // forCtrl
212
213bool forall = false;                                                                    // aggregate have one or more forall qualifiers ?
214
215// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
216#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
217if ( N ) {                                                                                                                                              \
218        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
219        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
220        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
221        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
222        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
223} else {                                                                                                                                                \
224        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
225        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
226        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
227}
228%}
229
230%define parse.error verbose
231
232// Types declaration for productions
233%union {
234        Token tok;
235        ParseNode * pn;
236        ExpressionNode * en;
237        DeclarationNode * decl;
238        AggregateDecl::Aggregate aggKey;
239        TypeDecl::Kind tclass;
240        StatementNode * sn;
241        WaitForStmt * wfs;
242        Expression * constant;
243        IfCtrl * ifctl;
244        ForCtrl * fctl;
245        enum OperKinds compop;
246        LabelNode * label;
247        InitializerNode * in;
248        OperKinds op;
249        std::string * str;
250        bool flag;
251        CatchStmt::Kind catch_kind;
252        GenericExpr * genexpr;
253}
254
255//************************* TERMINAL TOKENS ********************************
256
257// keywords
258%token TYPEDEF
259%token EXTERN STATIC AUTO REGISTER
260%token THREADLOCAL                                                                              // C11
261%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
262%token NORETURN                                                                                 // C11
263%token CONST VOLATILE
264%token RESTRICT                                                                                 // C99
265%token ATOMIC                                                                                   // C11
266%token FORALL MUTEX VIRTUAL VTABLE COERCE                               // CFA
267%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
268%token BOOL COMPLEX IMAGINARY                                                   // C99
269%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
270%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
271%token ZERO_T ONE_T                                                                             // CFA
272%token SIZEOF TYPEOF VALIST AUTO_TYPE                                   // GCC
273%token OFFSETOF BASETYPEOF TYPEID                                               // CFA
274%token ENUM STRUCT UNION
275%token EXCEPTION                                                                                // CFA
276%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
277%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
278// %token RESUME                                                                                        // CFA
279%token LABEL                                                                                    // GCC
280%token SUSPEND                                                                                  // CFA
281%token ATTRIBUTE EXTENSION                                                              // GCC
282%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
283%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR    // CFA
284%token DISABLE ENABLE TRY THROW THROWRESUME AT                  // CFA
285%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
286%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
287
288// names and constants: lexer differentiates between identifier and typedef names
289%token<tok> IDENTIFIER          QUOTED_IDENTIFIER       TYPEDEFname             TYPEGENname
290%token<tok> TIMEOUT                     WOR                                     CATCH                   RECOVER                 CATCHRESUME             FIXUP           FINALLY         // CFA
291%token<tok> INTEGERconstant     CHARACTERconstant       STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier
315%type<tok> identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator                     simple_assignment_operator      compound_assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression_list                  cast_expression                         exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list_opt  argument_expression                     default_initializer_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key aggregate_data aggregate_control
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en> bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375%type<decl> vtable vtable_opt default_opt
376
377%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
378
379%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
380%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
381
382%type<decl> elaborated_type elaborated_type_nobody
383
384%type<decl> enumerator_list enum_type enum_type_nobody
385%type<en> enumerator_value_opt
386
387%type<decl> external_definition external_definition_list external_definition_list_opt
388
389%type<decl> exception_declaration
390
391%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
392%type<en> field field_name_list field_name fraction_constants_opt
393
394%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
395
396%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
397%type<decl> identifier_list
398
399%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
400%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
401%type<decl> cfa_abstract_ptr cfa_abstract_tuple
402
403%type<decl> cfa_array_parameter_1st_dimension
404
405%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
406%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
407
408%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
409%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
410
411%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
412
413%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
414
415%type<decl> c_declaration static_assert
416%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
417%type<decl> KR_parameter_list KR_parameter_list_opt
418
419%type<decl> parameter_declaration parameter_list parameter_type_list_opt
420
421%type<decl> paren_identifier paren_type
422
423%type<decl> storage_class storage_class_list
424
425%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
426
427%type<tclass> type_class new_type_class
428%type<decl> type_declarator type_declarator_name type_declaring_list
429
430%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
431%type<decl> typedef_name typedef_declaration typedef_expression
432
433%type<decl> variable_type_redeclarator type_ptr type_array type_function
434
435%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
436
437%type<decl> type type_no_function
438%type<decl> type_parameter type_parameter_list type_initializer_opt
439
440%type<en> type_parameters_opt type_list
441
442%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
443%type<decl> type_specifier type_specifier_nobody
444
445%type<decl> variable_declarator variable_ptr variable_array variable_function
446%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
447
448%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
449
450// initializers
451%type<in>  initializer initializer_list_opt initializer_opt
452
453// designators
454%type<en>  designator designator_list designation
455
456
457// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
458//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
459//   if ( C ) S1 else S2
460//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
461// Similar issues exit with the waitfor statement.
462
463// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
464// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
465%precedence THEN                // rule precedence for IF/WAITFOR statement
466%precedence WOR                 // token precedence for start of WOR in WAITFOR statement
467%precedence TIMEOUT             // token precedence for start of TIMEOUT in WAITFOR statement
468%precedence CATCH               // token precedence for start of TIMEOUT in WAITFOR statement
469%precedence RECOVER             // token precedence for start of TIMEOUT in WAITFOR statement
470%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
471%precedence FIXUP               // token precedence for start of TIMEOUT in WAITFOR statement
472%precedence FINALLY             // token precedence for start of TIMEOUT in WAITFOR statement
473%precedence ELSE                // token precedence for start of else clause in IF/WAITFOR statement
474
475
476// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
477//   forall( otype T ) struct Foo { T v; };
478//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
479//   Foo ( *fp )( int );
480//   `---'                                              matches start of TYPEGENname '('
481// must be:
482//   Foo( int ) ( *fp )( int );
483// The same problem occurs here:
484//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
485// must be:
486//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
487
488// Order of these lines matters (low-to-high precedence).
489%precedence TYPEGENname
490%precedence '}'
491%precedence '('
492
493// %precedence RESUME
494// %precedence '{'
495// %precedence ')'
496
497%locations                                                                                              // support location tracking for error messages
498
499%start translation_unit                                                                 // parse-tree root
500
501%%
502//************************* Namespace Management ********************************
503
504// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
505// which are lexically identical.
506//
507//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
508//   foo f;           // to allow it to appear in this context
509//
510// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
511// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
512// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
513// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
514// must be distinguished by the lexical scanner.
515//
516// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
517// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
518// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
519// each context that introduces a name scope, a new level is created in the type table and that level is popped on
520// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
521// This requires distinguishing between type names that are local to the current declaration scope and those that
522// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
523//
524// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
525// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
526// around the list separator.
527//
528//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
529//      push               pop   push                   pop
530
531push:
532                { typedefTable.enterScope(); }
533        ;
534
535pop:
536                { typedefTable.leaveScope(); }
537        ;
538
539//************************* CONSTANTS ********************************
540
541constant:
542                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
543        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
544        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
545        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
546        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
547        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
548        ;
549
550quasi_keyword:                                                                                  // CFA
551        TIMEOUT
552        | WOR
553        | CATCH
554        | RECOVER
555        | CATCHRESUME
556        | FIXUP
557        | FINALLY
558        ;
559
560identifier:
561        IDENTIFIER
562        | quasi_keyword
563        | '@'                                                                                           // CFA
564                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
565        ;
566
567string_literal:
568        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
569        ;
570
571string_literal_list:                                                                    // juxtaposed strings are concatenated
572        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
573        | string_literal_list STRINGliteral
574                {
575                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
576                        delete $2;                                                                      // allocated by lexer
577                        $$ = $1;                                                                        // conversion from tok to str
578                }
579        ;
580
581//************************* EXPRESSIONS ********************************
582
583primary_expression:
584        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
585                { $$ = new ExpressionNode( build_varref( $1 ) ); }
586        | quasi_keyword
587                { $$ = new ExpressionNode( build_varref( $1 ) ); }
588        | tuple
589        | '(' comma_expression ')'
590                { $$ = $2; }
591        | '(' compound_statement ')'                                            // GCC, lambda expression
592                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast<CompoundStmt *>(maybeMoveBuild<Statement>($2) ) ) ); }
593        | type_name '.' identifier                                                      // CFA, nested type
594                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
595        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
596                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
597        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
598                {
599                        // add the missing control expression to the GenericExpr and return it
600                        $5->control = maybeMoveBuild<Expression>( $3 );
601                        $$ = new ExpressionNode( $5 );
602                }
603        // | RESUME '(' comma_expression ')'
604        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
605        // | RESUME '(' comma_expression ')' compound_statement
606        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
607        ;
608
609generic_assoc_list:                                                                             // C11
610        generic_association
611        | generic_assoc_list ',' generic_association
612                {
613                        // steal the association node from the singleton and delete the wrapper
614                        $1->associations.splice($1->associations.end(), $3->associations);
615                        delete $3;
616                        $$ = $1;
617                }
618        ;
619
620generic_association:                                                                    // C11
621        type_no_function ':' assignment_expression
622                {
623                        // create a GenericExpr wrapper with one association pair
624                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>( $3 ) } } );
625                }
626        | DEFAULT ':' assignment_expression
627                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>( $3 ) } } ); }
628        ;
629
630postfix_expression:
631        primary_expression
632        | postfix_expression '[' assignment_expression ',' comma_expression ']'
633                // { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, new ExpressionNode( build_binary_val( OperKinds::Index, $3, $5 ) ) ) ); }
634                { SemanticError( yylloc, "New array subscript is currently unimplemented." ); $$ = nullptr; }
635        | postfix_expression '[' assignment_expression ']'
636                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
637                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
638                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
639                // equivalent to the old x[i,j].
640                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
641        | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
642                {
643                        Token fn;
644                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
645                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
646                }
647        | postfix_expression '(' argument_expression_list_opt ')'
648                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
649        | postfix_expression '`' identifier                                     // CFA, postfix call
650                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
651        | constant '`' identifier                                                       // CFA, postfix call
652                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), $1 ) ); }
653        | string_literal '`' identifier                                         // CFA, postfix call
654                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( build_postfix_name( $3 ) ) ), new ExpressionNode( $1 ) ) ); }
655        | postfix_expression '.' identifier
656                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
657        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
658                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
659        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
660                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
661        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
662                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
663        | postfix_expression '.' aggregate_control
664                { $$ = new ExpressionNode( build_keyword_cast( $3, $1 ) ); }
665        | postfix_expression ARROW identifier
666                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
667        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
668                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
669        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
670                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
671        | postfix_expression ICR
672                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
673        | postfix_expression DECR
674                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
675        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
676                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
677        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
678                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
679        | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
680                {
681                        Token fn;
682                        fn.str = new string( "^?{}" );                          // location undefined
683                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
684                }
685        ;
686
687argument_expression_list_opt:
688        // empty
689                { $$ = nullptr; }
690        | argument_expression
691        | argument_expression_list_opt ',' argument_expression
692                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
693        ;
694
695argument_expression:
696        '@'                                                                                                     // CFA, default parameter
697                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
698                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
699        | assignment_expression
700        ;
701
702field_name_list:                                                                                // CFA, tuple field selector
703        field
704        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
705        ;
706
707field:                                                                                                  // CFA, tuple field selector
708        field_name
709        | FLOATING_DECIMALconstant field
710                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
711        | FLOATING_DECIMALconstant '[' field_name_list ']'
712                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
713        | field_name '.' field
714                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
715        | field_name '.' '[' field_name_list ']'
716                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
717        | field_name ARROW field
718                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
719        | field_name ARROW '[' field_name_list ']'
720                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
721        ;
722
723field_name:
724        INTEGERconstant fraction_constants_opt
725                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
726        | FLOATINGconstant fraction_constants_opt
727                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
728        | identifier fraction_constants_opt
729                {
730                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
731                }
732        ;
733
734fraction_constants_opt:
735        // empty
736                { $$ = nullptr; }
737        | fraction_constants_opt FLOATING_FRACTIONconstant
738                {
739                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
740                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
741                }
742        ;
743
744unary_expression:
745        postfix_expression
746                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
747                // semantics checks, e.g., ++3, 3--, *3, &&3
748        | constant
749        | string_literal
750                { $$ = new ExpressionNode( $1 ); }
751        | EXTENSION cast_expression                                                     // GCC
752                { $$ = $2->set_extension( true ); }
753                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
754                //              { * X; }         // dereference X
755                //              { * int X; } // CFA declaration of pointer to int
756        | ptrref_operator cast_expression                                       // CFA
757                {
758                        switch ( $1 ) {
759                          case OperKinds::AddressOf:
760                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) );
761                                break;
762                          case OperKinds::PointTo:
763                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
764                                break;
765                          case OperKinds::And:
766                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild<Expression>( $2 ) ) ) );
767                                break;
768                          default:
769                                assert( false );
770                        }
771                }
772        | unary_operator cast_expression
773                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
774        | ICR unary_expression
775                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
776        | DECR unary_expression
777                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
778        | SIZEOF unary_expression
779                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
780        | SIZEOF '(' type_no_function ')'
781                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
782        | ALIGNOF unary_expression                                                      // GCC, variable alignment
783                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild<Expression>( $2 ) ) ); }
784        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
785                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
786        | OFFSETOF '(' type_no_function ',' identifier ')'
787                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
788        | TYPEID '(' type_no_function ')'
789                {
790                        SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
791                        // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
792                }
793        ;
794
795ptrref_operator:
796        '*'                                                                                     { $$ = OperKinds::PointTo; }
797        | '&'                                                                           { $$ = OperKinds::AddressOf; }
798                // GCC, address of label must be handled by semantic check for ref,ref,label
799        | ANDAND                                                                        { $$ = OperKinds::And; }
800        ;
801
802unary_operator:
803        '+'                                                                                     { $$ = OperKinds::UnPlus; }
804        | '-'                                                                           { $$ = OperKinds::UnMinus; }
805        | '!'                                                                           { $$ = OperKinds::Neg; }
806        | '~'                                                                           { $$ = OperKinds::BitNeg; }
807        ;
808
809cast_expression:
810        unary_expression
811        | '(' type_no_function ')' cast_expression
812                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
813        | '(' aggregate_control '&' ')' cast_expression         // CFA
814                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
815        | '(' aggregate_control '*' ')' cast_expression         // CFA
816                { $$ = new ExpressionNode( build_keyword_cast( $2, $5 ) ); }
817        | '(' VIRTUAL ')' cast_expression                                       // CFA
818                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $4 ), maybeMoveBuildType( nullptr ) ) ); }
819        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
820                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild<Expression>( $5 ), maybeMoveBuildType( $3 ) ) ); }
821        | '(' RETURN type_no_function ')' cast_expression       // CFA
822                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
823        | '(' COERCE type_no_function ')' cast_expression       // CFA
824                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
825        | '(' qualifier_cast_list ')' cast_expression           // CFA
826                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
827//      | '(' type_no_function ')' tuple
828//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
829        ;
830
831qualifier_cast_list:
832        cast_modifier type_qualifier_name
833        | cast_modifier MUTEX
834        | qualifier_cast_list cast_modifier type_qualifier_name
835        | qualifier_cast_list cast_modifier MUTEX
836        ;
837
838cast_modifier:
839        '-'
840        | '+'
841        ;
842
843exponential_expression:
844        cast_expression
845        | exponential_expression '\\' cast_expression
846                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
847        ;
848
849multiplicative_expression:
850        exponential_expression
851        | multiplicative_expression '*' exponential_expression
852                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
853        | multiplicative_expression '/' exponential_expression
854                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
855        | multiplicative_expression '%' exponential_expression
856                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
857        ;
858
859additive_expression:
860        multiplicative_expression
861        | additive_expression '+' multiplicative_expression
862                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
863        | additive_expression '-' multiplicative_expression
864                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
865        ;
866
867shift_expression:
868        additive_expression
869        | shift_expression LS additive_expression
870                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
871        | shift_expression RS additive_expression
872                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
873        ;
874
875relational_expression:
876        shift_expression
877        | relational_expression '<' shift_expression
878                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
879        | relational_expression '>' shift_expression
880                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
881        | relational_expression LE shift_expression
882                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
883        | relational_expression GE shift_expression
884                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
885        ;
886
887equality_expression:
888        relational_expression
889        | equality_expression EQ relational_expression
890                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
891        | equality_expression NE relational_expression
892                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
893        ;
894
895AND_expression:
896        equality_expression
897        | AND_expression '&' equality_expression
898                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
899        ;
900
901exclusive_OR_expression:
902        AND_expression
903        | exclusive_OR_expression '^' AND_expression
904                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
905        ;
906
907inclusive_OR_expression:
908        exclusive_OR_expression
909        | inclusive_OR_expression '|' exclusive_OR_expression
910                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
911        ;
912
913logical_AND_expression:
914        inclusive_OR_expression
915        | logical_AND_expression ANDAND inclusive_OR_expression
916                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
917        ;
918
919logical_OR_expression:
920        logical_AND_expression
921        | logical_OR_expression OROR logical_AND_expression
922                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
923        ;
924
925conditional_expression:
926        logical_OR_expression
927        | logical_OR_expression '?' comma_expression ':' conditional_expression
928                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
929                // FIX ME: computes $1 twice
930        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
931                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
932        ;
933
934constant_expression:
935        conditional_expression
936        ;
937
938assignment_expression:
939                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
940        conditional_expression
941        | unary_expression assignment_operator assignment_expression
942                {
943//                      if ( $2 == OperKinds::AtAssn ) {
944//                              SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
945//                      } else {
946                                $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) );
947//                      } // if
948                }
949        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
950                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
951        ;
952
953assignment_expression_opt:
954        // empty
955                { $$ = nullptr; }
956        | assignment_expression
957        ;
958
959assignment_operator:
960        simple_assignment_operator
961        | compound_assignment_operator
962        ;
963
964simple_assignment_operator:
965        '='                                                                                     { $$ = OperKinds::Assign; }
966        | ATassign                                                                      { $$ = OperKinds::AtAssn; } // CFA
967        ;
968
969compound_assignment_operator:
970        EXPassign                                                                       { $$ = OperKinds::ExpAssn; }
971        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
972        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
973        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
974        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
975        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
976        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
977        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
978        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
979        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
980        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
981        ;
982
983tuple:                                                                                                  // CFA, tuple
984                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
985                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
986//      '[' ']'
987//              { $$ = new ExpressionNode( build_tuple() ); }
988//      | '[' push assignment_expression pop ']'
989//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
990        '[' ',' tuple_expression_list ']'
991                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
992        | '[' push assignment_expression pop ',' tuple_expression_list ']'
993                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)($3->set_last( $6 ) ) )); }
994        ;
995
996tuple_expression_list:
997        assignment_expression
998        | '@'                                                                                           // CFA
999                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1000        | tuple_expression_list ',' assignment_expression
1001                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1002        | tuple_expression_list ',' '@'
1003                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1004        ;
1005
1006comma_expression:
1007        assignment_expression
1008        | comma_expression ',' assignment_expression
1009                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1010        ;
1011
1012comma_expression_opt:
1013        // empty
1014                { $$ = nullptr; }
1015        | comma_expression
1016        ;
1017
1018//*************************** STATEMENTS *******************************
1019
1020statement:
1021        labeled_statement
1022        | compound_statement
1023        | expression_statement
1024        | selection_statement
1025        | iteration_statement
1026        | jump_statement
1027        | with_statement
1028        | mutex_statement
1029        | waitfor_statement
1030        | exception_statement
1031        | enable_disable_statement
1032                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1033        | asm_statement
1034        | DIRECTIVE
1035                { $$ = new StatementNode( build_directive( $1 ) ); }
1036        ;
1037
1038labeled_statement:
1039                // labels cannot be identifiers 0 or 1
1040        identifier_or_type_name ':' attribute_list_opt statement
1041                { $$ = $4->add_label( $1, $3 ); }
1042        ;
1043
1044compound_statement:
1045        '{' '}'
1046                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1047        | '{' push
1048          local_label_declaration_opt                                           // GCC, local labels appear at start of block
1049          statement_decl_list                                                           // C99, intermix declarations and statements
1050          pop '}'
1051                { $$ = new StatementNode( build_compound( $4 ) ); }
1052        ;
1053
1054statement_decl_list:                                                                    // C99
1055        statement_decl
1056        | statement_decl_list statement_decl
1057                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1058        ;
1059
1060statement_decl:
1061        declaration                                                                                     // CFA, new & old style declarations
1062                { $$ = new StatementNode( $1 ); }
1063        | EXTENSION declaration                                                         // GCC
1064                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1065        | function_definition
1066                { $$ = new StatementNode( $1 ); }
1067        | EXTENSION function_definition                                         // GCC
1068                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1069        | statement
1070        ;
1071
1072statement_list_nodecl:
1073        statement
1074        | statement_list_nodecl statement
1075                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1076        ;
1077
1078expression_statement:
1079        comma_expression_opt ';'
1080                { $$ = new StatementNode( build_expr( $1 ) ); }
1081        ;
1082
1083selection_statement:
1084                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1085                        // the inherent S/R conflict with THEN/ELSE.
1086        push if_statement pop
1087                { $$ = $2; }
1088        | SWITCH '(' comma_expression ')' case_clause
1089                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1090        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1091                {
1092                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1093                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1094                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1095                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1096                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1097                        // statement.
1098                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1099                }
1100        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1101                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1102        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1103                {
1104                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1105                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1106                }
1107        ;
1108
1109if_statement:
1110        IF '(' if_control_expression ')' statement                      %prec THEN
1111                // explicitly deal with the shift/reduce conflict on if/else
1112                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), nullptr ) ); }
1113        | IF '(' if_control_expression ')' statement ELSE statement
1114                { $$ = new StatementNode( build_if( $3, maybe_build_compound( $5 ), maybe_build_compound( $7 ) ) ); }
1115        ;
1116
1117if_control_expression:
1118        comma_expression
1119                { $$ = new IfCtrl( nullptr, $1 ); }
1120        | c_declaration                                                                         // no semi-colon
1121                { $$ = new IfCtrl( $1, nullptr ); }
1122        | cfa_declaration                                                                       // no semi-colon
1123                { $$ = new IfCtrl( $1, nullptr ); }
1124        | declaration comma_expression                                          // semi-colon separated
1125                { $$ = new IfCtrl( $1, $2 ); }
1126        ;
1127
1128// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1129// clause allows a list of values and subranges.
1130
1131case_value:                                                                                             // CFA
1132        constant_expression                                                     { $$ = $1; }
1133        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1134                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
1135        | subrange                                                                                      // CFA, subrange
1136        ;
1137
1138case_value_list:                                                                                // CFA
1139        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1140                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1141        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1142        ;
1143
1144case_label:                                                                                             // CFA
1145        CASE case_value_list ':'                                        { $$ = $2; }
1146        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1147                // A semantic check is required to ensure only one default clause per switch/choose statement.
1148        ;
1149
1150//label_list_opt:
1151//      // empty
1152//      | identifier_or_type_name ':'
1153//      | label_list_opt identifier_or_type_name ':'
1154//      ;
1155
1156case_label_list:                                                                                // CFA
1157        case_label
1158        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1159        ;
1160
1161case_clause:                                                                                    // CFA
1162        case_label_list statement                                       { $$ = $1->append_last_case( maybe_build_compound( $2 ) ); }
1163        ;
1164
1165switch_clause_list_opt:                                                                 // CFA
1166        // empty
1167                { $$ = nullptr; }
1168        | switch_clause_list
1169        ;
1170
1171switch_clause_list:                                                                             // CFA
1172        case_label_list statement_list_nodecl
1173                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1174        | switch_clause_list case_label_list statement_list_nodecl
1175                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1176        ;
1177
1178iteration_statement:
1179        WHILE '(' push if_control_expression ')' statement pop
1180                { $$ = new StatementNode( build_while( $4, maybe_build_compound( $6 ) ) ); }
1181        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1182                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), maybe_build_compound( $4 ) ) ); }
1183        | DO statement WHILE '(' comma_expression ')' ';'
1184                { $$ = new StatementNode( build_do_while( $5, maybe_build_compound( $2 ) ) ); }
1185        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1186                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), maybe_build_compound( $2 ) ) ); }
1187        | FOR '(' push for_control_expression_list ')' statement pop
1188                { $$ = new StatementNode( build_for( $4, maybe_build_compound( $6 ) ) ); }
1189        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1190                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), maybe_build_compound( $4 ) ) ); }
1191        ;
1192
1193for_control_expression_list:
1194        for_control_expression
1195        | for_control_expression_list ':' for_control_expression
1196                // ForCtrl + ForCtrl:
1197                //    init + init => multiple declaration statements that are hoisted
1198                //    condition + condition => (expression) && (expression)
1199                //    change + change => (expression), (expression)
1200                {
1201                        $1->init->set_last( $3->init );
1202                        if ( $1->condition ) {
1203                                if ( $3->condition ) {
1204                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1205                                } // if
1206                        } else $1->condition = $3->condition;
1207                        if ( $1->change ) {
1208                                if ( $3->change ) {
1209                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1210                                } // if
1211                        } else $1->change = $3->change;
1212                        $$ = $1;
1213                }
1214        ;
1215
1216for_control_expression:
1217        ';' comma_expression_opt ';' comma_expression_opt
1218                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1219        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1220                { $$ = new ForCtrl( $1, $3, $5 ); }
1221        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1222                { $$ = new ForCtrl( $1, $2, $4 ); }
1223
1224        | comma_expression                                                                      // CFA
1225                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1226                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1227        | '=' comma_expression                                                          // CFA
1228                { $$ = forCtrl( $2, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1229                                                OperKinds::LEThan, $2->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1230        | comma_expression inclexcl comma_expression            // CFA
1231                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1232        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1233                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1234        | comma_expression ';'                                                          // CFA
1235                { $$ = forCtrl( new ExpressionNode( build_constantInteger( *new string( "0u" ) ) ), $1, nullptr, OperKinds::LThan, nullptr, nullptr ); }
1236        | comma_expression ';' comma_expression                         // CFA
1237                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1238                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1239        | comma_expression ';' '=' comma_expression                     // CFA
1240                { $$ = forCtrl( $4, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1241                                                OperKinds::LEThan, $4->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1242        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1243                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1244        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1245                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1246
1247        | comma_expression ';' TYPEDEFname                                      // CFA, array type
1248                {
1249                        SemanticError( yylloc, "Array interator is currently unimplemented." ); $$ = nullptr;
1250                        $$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1251                }
1252
1253                // There is a S/R conflicit if ~ and -~ are factored out.
1254        | comma_expression ';' comma_expression '~' '@'         // CFA
1255                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1256        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1257                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1258        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1259                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1260        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1261                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1262        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1263                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1264        ;
1265
1266inclexcl:
1267        '~'
1268                { $$ = OperKinds::LThan; }
1269        | ErangeUpEq
1270                { $$ = OperKinds::LEThan; }
1271        | ErangeDown
1272                { $$ = OperKinds::GThan; }
1273        | ErangeDownEq
1274                { $$ = OperKinds::GEThan; }
1275        ;
1276
1277jump_statement:
1278        GOTO identifier_or_type_name ';'
1279                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1280        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1281                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1282                // whereas normal operator precedence yields goto (*i)+3;
1283                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1284                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1285        | fall_through_name ';'                                                         // CFA
1286                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1287        | fall_through_name identifier_or_type_name ';'         // CFA
1288                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1289        | fall_through_name DEFAULT ';'                                         // CFA
1290                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1291        | CONTINUE ';'
1292                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1293                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1294        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1295                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1296                // the target of the transfer appears only at the start of an iteration statement.
1297                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1298        | BREAK ';'
1299                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1300                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1301        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1302                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1303                // the target of the transfer appears only at the start of an iteration statement.
1304                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1305        | RETURN comma_expression_opt ';'
1306                { $$ = new StatementNode( build_return( $2 ) ); }
1307        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1308                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1309        | SUSPEND ';'
1310                { $$ = new StatementNode( build_suspend( nullptr ) ); }
1311        | SUSPEND compound_statement
1312                { $$ = new StatementNode( build_suspend( $2 ) ); }
1313        | SUSPEND COROUTINE ';'
1314                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Coroutine ) ); }
1315        | SUSPEND COROUTINE compound_statement
1316                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Coroutine ) ); }
1317        | SUSPEND GENERATOR ';'
1318                { $$ = new StatementNode( build_suspend( nullptr, SuspendStmt::Generator ) ); }
1319        | SUSPEND GENERATOR compound_statement
1320                { $$ = new StatementNode( build_suspend( $3, SuspendStmt::Generator ) ); }
1321        | THROW assignment_expression_opt ';'                           // handles rethrow
1322                { $$ = new StatementNode( build_throw( $2 ) ); }
1323        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1324                { $$ = new StatementNode( build_resume( $2 ) ); }
1325        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1326                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1327        ;
1328
1329fall_through_name:                                                                              // CFA
1330        FALLTHRU
1331        | FALLTHROUGH
1332        ;
1333
1334with_statement:
1335        WITH '(' tuple_expression_list ')' statement
1336                {
1337                        $$ = new StatementNode( build_with( $3, $5 ) );
1338                }
1339        ;
1340
1341// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1342mutex_statement:
1343        MUTEX '(' argument_expression_list_opt ')' statement
1344                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1345        ;
1346
1347when_clause:
1348        WHEN '(' comma_expression ')'                           { $$ = $3; }
1349        ;
1350
1351when_clause_opt:
1352        // empty
1353                { $$ = nullptr; }
1354        | when_clause
1355        ;
1356
1357waitfor:
1358        WAITFOR '(' cast_expression ')'
1359                { $$ = $3; }
1360//      | WAITFOR '(' cast_expression ',' argument_expression_list_opt ')'
1361//              { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1362        | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1363                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1364        ;
1365
1366cast_expression_list:
1367        cast_expression
1368        | cast_expression_list ',' cast_expression
1369                // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1370                { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1371        ;
1372
1373timeout:
1374        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1375        ;
1376
1377waitfor_clause:
1378        when_clause_opt waitfor statement                                       %prec THEN
1379                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1 ); }
1380        | when_clause_opt waitfor statement WOR waitfor_clause
1381                { $$ = build_waitfor( $2, maybe_build_compound( $3 ), $1, $5 ); }
1382        | when_clause_opt timeout statement                                     %prec THEN
1383                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1 ); }
1384        | when_clause_opt ELSE statement
1385                { $$ = build_waitfor_timeout( nullptr, maybe_build_compound( $3 ), $1 ); }
1386                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1387        | when_clause_opt timeout statement WOR ELSE statement
1388                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1389        | when_clause_opt timeout statement WOR when_clause ELSE statement
1390                { $$ = build_waitfor_timeout( $2, maybe_build_compound( $3 ), $1, maybe_build_compound( $7 ), $5 ); }
1391        ;
1392
1393waitfor_statement:
1394        when_clause_opt waitfor statement                                       %prec THEN
1395                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1396        | when_clause_opt waitfor statement WOR waitfor_clause
1397                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1398        ;
1399
1400exception_statement:
1401        TRY compound_statement handler_clause                                   %prec THEN
1402                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1403        | TRY compound_statement finally_clause
1404                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1405        | TRY compound_statement handler_clause finally_clause
1406                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1407        ;
1408
1409handler_clause:
1410        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1411                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1412        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1413                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1414        ;
1415
1416handler_predicate_opt:
1417        // empty
1418                { $$ = nullptr; }
1419        | ';' conditional_expression                            { $$ = $2; }
1420        ;
1421
1422handler_key:
1423        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1424        | RECOVER                                                                       { $$ = CatchStmt::Terminate; }
1425        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1426        | FIXUP                                                                         { $$ = CatchStmt::Resume; }
1427        ;
1428
1429finally_clause:
1430        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1431        ;
1432
1433exception_declaration:
1434                // No SUE declaration in parameter list.
1435        type_specifier_nobody
1436        | type_specifier_nobody declarator
1437                { $$ = $2->addType( $1 ); }
1438        | type_specifier_nobody variable_abstract_declarator
1439                { $$ = $2->addType( $1 ); }
1440        | cfa_abstract_declarator_tuple identifier                      // CFA
1441                { $$ = $1->addName( $2 ); }
1442        | cfa_abstract_declarator_tuple                                         // CFA
1443        ;
1444
1445enable_disable_statement:
1446        enable_disable_key identifier_list compound_statement
1447        ;
1448
1449enable_disable_key:
1450        ENABLE
1451        | DISABLE
1452        ;
1453
1454asm_statement:
1455        ASM asm_volatile_opt '(' string_literal ')' ';'
1456                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1457        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1458                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1459        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1460                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1461        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1462                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1463        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1464                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1465        ;
1466
1467asm_volatile_opt:                                                                               // GCC
1468        // empty
1469                { $$ = false; }
1470        | VOLATILE
1471                { $$ = true; }
1472        ;
1473
1474asm_operands_opt:                                                                               // GCC
1475        // empty
1476                { $$ = nullptr; }                                                               // use default argument
1477        | asm_operands_list
1478        ;
1479
1480asm_operands_list:                                                                              // GCC
1481        asm_operand
1482        | asm_operands_list ',' asm_operand
1483                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1484        ;
1485
1486asm_operand:                                                                                    // GCC
1487        string_literal '(' constant_expression ')'
1488                { $$ = new ExpressionNode( new AsmExpr( nullptr, $1, maybeMoveBuild<Expression>( $3 ) ) ); }
1489        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1490                { $$ = new ExpressionNode( new AsmExpr( $2, $4, maybeMoveBuild<Expression>( $6 ) ) ); }
1491        ;
1492
1493asm_clobbers_list_opt:                                                                  // GCC
1494        // empty
1495                { $$ = nullptr; }                                                               // use default argument
1496        | string_literal
1497                { $$ = new ExpressionNode( $1 ); }
1498        | asm_clobbers_list_opt ',' string_literal
1499                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( $3 ) )); }
1500        ;
1501
1502label_list:
1503        identifier
1504                {
1505                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1506                        delete $1;                                                                      // allocated by lexer
1507                }
1508        | label_list ',' identifier
1509                {
1510                        $$ = $1; $1->labels.push_back( *$3 );
1511                        delete $3;                                                                      // allocated by lexer
1512                }
1513        ;
1514
1515//******************************* DECLARATIONS *********************************
1516
1517declaration_list_opt:                                                                   // used at beginning of switch statement
1518        // empty
1519                { $$ = nullptr; }
1520        | declaration_list
1521        ;
1522
1523declaration_list:
1524        declaration
1525        | declaration_list declaration
1526                { $$ = $1->appendList( $2 ); }
1527        ;
1528
1529KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1530        // empty
1531                { $$ = nullptr; }
1532        | KR_parameter_list
1533        ;
1534
1535KR_parameter_list:
1536        push c_declaration pop ';'
1537                { $$ = $2; }
1538        | KR_parameter_list push c_declaration pop ';'
1539                { $$ = $1->appendList( $3 ); }
1540        ;
1541
1542local_label_declaration_opt:                                                    // GCC, local label
1543        // empty
1544        | local_label_declaration_list
1545        ;
1546
1547local_label_declaration_list:                                                   // GCC, local label
1548        LABEL local_label_list ';'
1549        | local_label_declaration_list LABEL local_label_list ';'
1550        ;
1551
1552local_label_list:                                                                               // GCC, local label
1553        identifier_or_type_name
1554        | local_label_list ',' identifier_or_type_name
1555        ;
1556
1557declaration:                                                                                    // old & new style declarations
1558        c_declaration ';'
1559        | cfa_declaration ';'                                                           // CFA
1560        | static_assert                                                                         // C11
1561        ;
1562
1563static_assert:
1564        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1565                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1566        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1567                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1568
1569// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1570// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1571// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1572// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1573// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1574// block, but cannot be mixed within a specific declaration.
1575//
1576//                      CFA                                     C
1577//              [10] int x;                     int x[10];              // array of 10 integers
1578//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1579
1580cfa_declaration:                                                                                // CFA
1581        cfa_variable_declaration
1582        | cfa_typedef_declaration
1583        | cfa_function_declaration
1584        | type_declaring_list
1585                { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1586        | trait_specifier
1587        ;
1588
1589cfa_variable_declaration:                                                               // CFA
1590        cfa_variable_specifier initializer_opt
1591                { $$ = $1->addInitializer( $2 ); }
1592        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1593                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1594                // them as a type_qualifier cannot appear in that context.
1595                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1596        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1597                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1598        ;
1599
1600cfa_variable_specifier:                                                                 // CFA
1601                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1602                // storage-class
1603        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1604                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1605        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1606                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1607        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1608                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1609        ;
1610
1611cfa_function_declaration:                                                               // CFA
1612        cfa_function_specifier
1613        | type_qualifier_list cfa_function_specifier
1614                { $$ = $2->addQualifiers( $1 ); }
1615        | declaration_qualifier_list cfa_function_specifier
1616                { $$ = $2->addQualifiers( $1 ); }
1617        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1618                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1619        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1620                {
1621                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1622                        DeclarationNode * ret = new DeclarationNode;
1623                        ret->type = maybeClone( $1->type->base );
1624                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1625                }
1626        ;
1627
1628cfa_function_specifier:                                                                 // CFA
1629//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1630//              {
1631//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1632//              }
1633//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1634//              {
1635//                      typedefTable.setNextIdentifier( *$5 );
1636//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1637//              }
1638//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1639//              {
1640//                      typedefTable.setNextIdentifier( *$5 );
1641//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1642//              }
1643//      | '[' ']' typegen_name
1644                // identifier_or_type_name must be broken apart because of the sequence:
1645                //
1646                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1647                //   '[' ']' type_specifier
1648                //
1649                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1650                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1651        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1652                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1653                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1654        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1655                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 )->addQualifiers( $8 ); }
1656        ;
1657
1658cfa_function_return:                                                                    // CFA
1659        '[' push cfa_parameter_list pop ']'
1660                { $$ = DeclarationNode::newTuple( $3 ); }
1661        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1662                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1663                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1664        ;
1665
1666cfa_typedef_declaration:                                                                // CFA
1667        TYPEDEF cfa_variable_specifier
1668                {
1669                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1670                        $$ = $2->addTypedef();
1671                }
1672        | TYPEDEF cfa_function_specifier
1673                {
1674                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1675                        $$ = $2->addTypedef();
1676                }
1677        | cfa_typedef_declaration pop ',' push identifier
1678                {
1679                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1680                        $$ = $1->appendList( $1->cloneType( $5 ) );
1681                }
1682        ;
1683
1684// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1685// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1686
1687typedef_declaration:
1688        TYPEDEF type_specifier declarator
1689                {
1690                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1691                        $$ = $3->addType( $2 )->addTypedef();
1692                }
1693        | typedef_declaration pop ',' push declarator
1694                {
1695                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1696                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1697                }
1698        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1699                {
1700                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1701                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1702                }
1703        | type_specifier TYPEDEF declarator
1704                {
1705                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1706                        $$ = $3->addType( $1 )->addTypedef();
1707                }
1708        | type_specifier TYPEDEF type_qualifier_list declarator
1709                {
1710                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1711                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1712                }
1713        ;
1714
1715typedef_expression:
1716                // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1717        TYPEDEF identifier '=' assignment_expression
1718                {
1719                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1720                }
1721        | typedef_expression pop ',' push identifier '=' assignment_expression
1722                {
1723                        SemanticError( yylloc, "Typedef expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
1724                }
1725        ;
1726
1727c_declaration:
1728        declaration_specifier declaring_list
1729                { $$ = distAttr( $1, $2 ); }
1730        | typedef_declaration
1731        | typedef_expression                                                            // deprecated GCC, naming expression type
1732        | sue_declaration_specifier
1733        ;
1734
1735declaring_list:
1736                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1737                // storage-class
1738        declarator asm_name_opt initializer_opt
1739                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1740        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1741                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1742        ;
1743
1744declaration_specifier:                                                                  // type specifier + storage class
1745        basic_declaration_specifier
1746        | sue_declaration_specifier
1747        | type_declaration_specifier
1748        ;
1749
1750declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1751                // Preclude SUE declarations in restricted scopes:
1752                //
1753                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1754                //
1755                // because it is impossible to call f due to name equivalence.
1756        basic_declaration_specifier
1757        | sue_declaration_specifier_nobody
1758        | type_declaration_specifier
1759        ;
1760
1761type_specifier:                                                                                 // type specifier
1762        basic_type_specifier
1763        | sue_type_specifier
1764        | type_type_specifier
1765        ;
1766
1767type_specifier_nobody:                                                                  // type specifier - {...}
1768                // Preclude SUE declarations in restricted scopes:
1769                //
1770                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1771                //
1772                // because it is impossible to call f due to name equivalence.
1773        basic_type_specifier
1774        | sue_type_specifier_nobody
1775        | type_type_specifier
1776        ;
1777
1778type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1779        // empty
1780                { $$ = nullptr; }
1781        | type_qualifier_list
1782        ;
1783
1784type_qualifier_list:
1785                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1786                //
1787                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1788                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1789                // appeared only once.
1790        type_qualifier
1791        | type_qualifier_list type_qualifier
1792                { $$ = $1->addQualifiers( $2 ); }
1793        ;
1794
1795type_qualifier:
1796        type_qualifier_name
1797        | attribute                                                                                     // trick handles most atrribute locations
1798        ;
1799
1800type_qualifier_name:
1801        CONST
1802                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1803        | RESTRICT
1804                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1805        | VOLATILE
1806                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1807        | ATOMIC
1808                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1809        | forall
1810        ;
1811
1812forall:
1813        FORALL '(' type_parameter_list ')'                                      // CFA
1814                { $$ = DeclarationNode::newForall( $3 ); }
1815        ;
1816
1817declaration_qualifier_list:
1818        storage_class_list
1819        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1820                { $$ = $1->addQualifiers( $2 ); }
1821        | declaration_qualifier_list type_qualifier_list storage_class_list
1822                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1823        ;
1824
1825storage_class_list:
1826                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1827                // only one of each is specified, except for inline, which can appear with the others.
1828                //
1829                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1830                // specifiers in a declaration.
1831        storage_class
1832        | storage_class_list storage_class
1833                { $$ = $1->addQualifiers( $2 ); }
1834        ;
1835
1836storage_class:
1837        EXTERN
1838                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1839        | STATIC
1840                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1841        | AUTO
1842                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1843        | REGISTER
1844                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1845        | THREADLOCAL                                                                           // C11
1846                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1847                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1848        | INLINE                                                                                        // C99
1849                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1850        | FORTRAN                                                                                       // C99
1851                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1852        | NORETURN                                                                                      // C11
1853                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1854        ;
1855
1856basic_type_name:
1857        VOID
1858                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1859        | BOOL                                                                                          // C99
1860                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1861        | CHAR
1862                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1863        | INT
1864                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1865        | INT128
1866                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1867        | UINT128
1868                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
1869        | FLOAT
1870                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1871        | DOUBLE
1872                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1873        | uuFLOAT80
1874                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1875        | uuFLOAT128
1876                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1877        | uFLOAT16
1878                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1879        | uFLOAT32
1880                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1881        | uFLOAT32X
1882                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1883        | uFLOAT64
1884                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1885        | uFLOAT64X
1886                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1887        | uFLOAT128
1888                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1889        | COMPLEX                                                                                       // C99
1890                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1891        | IMAGINARY                                                                                     // C99
1892                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1893        | SIGNED
1894                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1895        | UNSIGNED
1896                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1897        | SHORT
1898                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1899        | LONG
1900                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1901        | VALIST                                                                                        // GCC, __builtin_va_list
1902                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1903        | AUTO_TYPE
1904                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
1905        | vtable
1906        ;
1907
1908vtable_opt:
1909        // empty
1910                { $$ = nullptr; }
1911        | vtable;
1912        ;
1913
1914vtable:
1915        VTABLE '(' type_list ')' default_opt
1916                { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
1917        ;
1918
1919default_opt:
1920        // empty
1921                { $$ = nullptr; }
1922        | DEFAULT
1923                { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
1924        ;
1925
1926basic_declaration_specifier:
1927                // A semantic check is necessary for conflicting storage classes.
1928        basic_type_specifier
1929        | declaration_qualifier_list basic_type_specifier
1930                { $$ = $2->addQualifiers( $1 ); }
1931        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1932                { $$ = $1->addQualifiers( $2 ); }
1933        | basic_declaration_specifier storage_class type_qualifier_list
1934                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1935        | basic_declaration_specifier storage_class basic_type_specifier
1936                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1937        ;
1938
1939basic_type_specifier:
1940        direct_type
1941                // Cannot have type modifiers, e.g., short, long, etc.
1942        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1943                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1944        ;
1945
1946direct_type:
1947        basic_type_name
1948        | type_qualifier_list basic_type_name
1949                { $$ = $2->addQualifiers( $1 ); }
1950        | direct_type type_qualifier
1951                { $$ = $1->addQualifiers( $2 ); }
1952        | direct_type basic_type_name
1953                { $$ = $1->addType( $2 ); }
1954        ;
1955
1956indirect_type:
1957        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1958                { $$ = $3; }
1959        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1960                { $$ = DeclarationNode::newTypeof( $3 ); }
1961        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1962                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1963        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1964                { $$ = DeclarationNode::newTypeof( $3, true ); }
1965        | ZERO_T                                                                                        // CFA
1966                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1967        | ONE_T                                                                                         // CFA
1968                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1969        ;
1970
1971sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1972        sue_type_specifier
1973        | declaration_qualifier_list sue_type_specifier
1974                { $$ = $2->addQualifiers( $1 ); }
1975        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1976                { $$ = $1->addQualifiers( $2 ); }
1977        | sue_declaration_specifier storage_class type_qualifier_list
1978                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1979        ;
1980
1981sue_type_specifier:                                                                             // struct, union, enum + type specifier
1982        elaborated_type
1983        | type_qualifier_list
1984                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1985          elaborated_type
1986                { $$ = $3->addQualifiers( $1 ); }
1987        | sue_type_specifier type_qualifier
1988                {
1989                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1990                        $$ = $1->addQualifiers( $2 );
1991                }
1992        ;
1993
1994sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1995        sue_type_specifier_nobody
1996        | declaration_qualifier_list sue_type_specifier_nobody
1997                { $$ = $2->addQualifiers( $1 ); }
1998        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1999                { $$ = $1->addQualifiers( $2 ); }
2000        | sue_declaration_specifier_nobody storage_class type_qualifier_list
2001                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2002        ;
2003
2004sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
2005        elaborated_type_nobody
2006        | type_qualifier_list elaborated_type_nobody
2007                { $$ = $2->addQualifiers( $1 ); }
2008        | sue_type_specifier_nobody type_qualifier
2009                { $$ = $1->addQualifiers( $2 ); }
2010        ;
2011
2012type_declaration_specifier:
2013        type_type_specifier
2014        | declaration_qualifier_list type_type_specifier
2015                { $$ = $2->addQualifiers( $1 ); }
2016        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
2017                { $$ = $1->addQualifiers( $2 ); }
2018        | type_declaration_specifier storage_class type_qualifier_list
2019                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2020        ;
2021
2022type_type_specifier:                                                                    // typedef types
2023        type_name
2024        | type_qualifier_list type_name
2025                { $$ = $2->addQualifiers( $1 ); }
2026        | type_type_specifier type_qualifier
2027                { $$ = $1->addQualifiers( $2 ); }
2028        ;
2029
2030type_name:
2031        TYPEDEFname
2032                { $$ = DeclarationNode::newFromTypedef( $1 ); }
2033        | '.' TYPEDEFname
2034                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2035        | type_name '.' TYPEDEFname
2036                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2037        | typegen_name
2038        | '.' typegen_name
2039                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2040        | type_name '.' typegen_name
2041                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2042        ;
2043
2044typegen_name:                                                                                   // CFA
2045        TYPEGENname
2046                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2047        | TYPEGENname '(' ')'
2048                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2049        | TYPEGENname '(' type_list ')'
2050                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2051        ;
2052
2053elaborated_type:                                                                                // struct, union, enum
2054        aggregate_type
2055        | enum_type
2056        ;
2057
2058elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2059        aggregate_type_nobody
2060        | enum_type_nobody
2061        ;
2062
2063aggregate_type:                                                                                 // struct, union
2064        aggregate_key attribute_list_opt
2065                { forall = false; }                                                             // reset
2066          '{' field_declaration_list_opt '}' type_parameters_opt
2067                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2068        | aggregate_key attribute_list_opt identifier
2069                {
2070                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2071                        forall = false;                                                         // reset
2072                }
2073          '{' field_declaration_list_opt '}' type_parameters_opt
2074                { $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 ); }
2075        | aggregate_key attribute_list_opt TYPEDEFname          // unqualified type name
2076                {
2077                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2078                        forall = false;                                                         // reset
2079                }
2080          '{' field_declaration_list_opt '}' type_parameters_opt
2081                {
2082                        DeclarationNode::newFromTypedef( $3 );
2083                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2084                }
2085        | aggregate_key attribute_list_opt TYPEGENname          // unqualified type name
2086                {
2087                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2088                        forall = false;                                                         // reset
2089                }
2090          '{' field_declaration_list_opt '}' type_parameters_opt
2091                {
2092                        DeclarationNode::newFromTypeGen( $3, nullptr );
2093                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2094                }
2095        | aggregate_type_nobody
2096        ;
2097
2098type_parameters_opt:
2099        // empty
2100                { $$ = nullptr; }                                                               %prec '}'
2101        | '(' type_list ')'
2102                { $$ = $2; }
2103        ;
2104
2105aggregate_type_nobody:                                                                  // struct, union - {...}
2106        aggregate_key attribute_list_opt identifier
2107                {
2108                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2109                        forall = false;                                                         // reset
2110                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2111                }
2112        | aggregate_key attribute_list_opt type_name
2113                {
2114                        forall = false;                                                         // reset
2115                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2116                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2117                        // delete newFromTypeGen.
2118                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2119                        $3->type->symbolic.name = nullptr;
2120                        $3->type->symbolic.actuals = nullptr;
2121                        delete $3;
2122                }
2123        ;
2124
2125aggregate_key:
2126        aggregate_data
2127        | aggregate_control
2128        ;
2129
2130aggregate_data:
2131        STRUCT vtable_opt
2132                { $$ = AggregateDecl::Struct; }
2133        | UNION
2134                { $$ = AggregateDecl::Union; }
2135        | EXCEPTION                                                                                     // CFA
2136                { $$ = AggregateDecl::Exception; }
2137          //            { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2138        ;
2139
2140aggregate_control:                                                                              // CFA
2141        MONITOR
2142                { $$ = AggregateDecl::Monitor; }
2143        | MUTEX STRUCT
2144                { $$ = AggregateDecl::Monitor; }
2145        | GENERATOR
2146                { $$ = AggregateDecl::Generator; }
2147        | MUTEX GENERATOR
2148                { SemanticError( yylloc, "monitor generator is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2149        | COROUTINE
2150                { $$ = AggregateDecl::Coroutine; }
2151        | MUTEX COROUTINE
2152                { SemanticError( yylloc, "monitor coroutine is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2153        | THREAD
2154                { $$ = AggregateDecl::Thread; }
2155        | MUTEX THREAD
2156                { SemanticError( yylloc, "monitor thread is currently unimplemented." ); $$ = AggregateDecl::NoAggregate; }
2157        ;
2158
2159field_declaration_list_opt:
2160        // empty
2161                { $$ = nullptr; }
2162        | field_declaration_list_opt field_declaration
2163                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2164        ;
2165
2166field_declaration:
2167        type_specifier field_declaring_list_opt ';'
2168                { $$ = fieldDecl( $1, $2 ); }
2169        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2170                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2171        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2172                {
2173                        if ( ! $3 ) {                                                           // field declarator ?
2174                                $3 = DeclarationNode::newName( nullptr );
2175                        } // if
2176                        $3->inLine = true;
2177                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2178                        distInl( $3 );
2179                }
2180        | INLINE aggregate_control ';'                                          // CFA
2181                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2182        | typedef_declaration ';'                                                       // CFA
2183        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2184        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2185                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2186        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2187                { $$ = $2; }                                                                    // mark all fields in list
2188        | cfa_typedef_declaration ';'                                           // CFA
2189        | static_assert                                                                         // C11
2190        ;
2191
2192field_declaring_list_opt:
2193        // empty
2194                { $$ = nullptr; }
2195        | field_declarator
2196        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2197                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2198        ;
2199
2200field_declarator:
2201        bit_subrange_size                                                                       // C special case, no field name
2202                { $$ = DeclarationNode::newBitfield( $1 ); }
2203        | variable_declarator bit_subrange_size_opt
2204                // A semantic check is required to ensure bit_subrange only appears on integral types.
2205                { $$ = $1->addBitfield( $2 ); }
2206        | variable_type_redeclarator bit_subrange_size_opt
2207                // A semantic check is required to ensure bit_subrange only appears on integral types.
2208                { $$ = $1->addBitfield( $2 ); }
2209        ;
2210
2211field_abstract_list_opt:
2212        // empty
2213                { $$ = nullptr; }
2214        | field_abstract
2215        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2216                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2217        ;
2218
2219field_abstract:
2220                //      no bit fields
2221        variable_abstract_declarator
2222        ;
2223
2224cfa_field_declaring_list:                                                               // CFA, new style field declaration
2225        // bit-fields are handled by C declarations
2226        cfa_abstract_declarator_tuple identifier_or_type_name
2227                { $$ = $1->addName( $2 ); }
2228        | cfa_field_declaring_list ',' identifier_or_type_name
2229                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2230        ;
2231
2232cfa_field_abstract_list:                                                                // CFA, new style field declaration
2233        // bit-fields are handled by C declarations
2234        cfa_abstract_declarator_tuple
2235        | cfa_field_abstract_list ','
2236                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2237        ;
2238
2239bit_subrange_size_opt:
2240        // empty
2241                { $$ = nullptr; }
2242        | bit_subrange_size
2243        ;
2244
2245bit_subrange_size:
2246        ':' assignment_expression
2247                { $$ = $2; }
2248        ;
2249
2250enum_type:                                                                                              // enum
2251        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2252                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2253        | ENUM attribute_list_opt identifier
2254                { typedefTable.makeTypedef( *$3 ); }
2255          '{' enumerator_list comma_opt '}'
2256                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2257        | ENUM attribute_list_opt typedef_name                          // unqualified type name
2258          '{' enumerator_list comma_opt '}'
2259                { $$ = DeclarationNode::newEnum( $3->name, $5, true )->addQualifiers( $2 ); }
2260        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2261                {
2262                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2263                        SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2264                }
2265        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2266                {
2267                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2268                        typedefTable.makeTypedef( *$6 );
2269                }
2270          '{' enumerator_list comma_opt '}'
2271                {
2272                        SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2273                }
2274        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt '{' enumerator_list comma_opt '}'
2275                {
2276                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.val != 0 ) { SemanticError( yylloc, "storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." ); }
2277                        typedefTable.makeTypedef( *$6->name );
2278                        SemanticError( yylloc, "Typed enumeration is currently unimplemented." ); $$ = nullptr;
2279                }
2280        | enum_type_nobody
2281        ;
2282
2283enum_type_nobody:                                                                               // enum - {...}
2284        ENUM attribute_list_opt identifier
2285                { typedefTable.makeTypedef( *$3 ); $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 ); }
2286        | ENUM attribute_list_opt type_name                                     // qualified type name
2287                { typedefTable.makeTypedef( *$3->type->symbolic.name ); $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 ); }
2288        ;
2289
2290enumerator_list:
2291        identifier_or_type_name enumerator_value_opt
2292                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2293        | INLINE type_name
2294                { $$ = DeclarationNode::newEnumConstant( new string("inline"), nullptr ); }
2295        | enumerator_list ',' identifier_or_type_name enumerator_value_opt
2296                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2297        | enumerator_list ',' INLINE type_name enumerator_value_opt
2298                { $$ = $1->appendList( DeclarationNode::newEnumConstant( new string("inline"), nullptr ) ); }
2299        ;
2300
2301enumerator_value_opt:
2302        // empty
2303                { $$ = nullptr; }
2304        // | '=' constant_expression
2305        //      { $$ = $2; }
2306        | simple_assignment_operator initializer
2307                { $$ = $2->get_expression(); }                                  // FIX ME: enum only deals with constant_expression
2308        ;
2309
2310cfa_parameter_ellipsis_list_opt:                                                // CFA, abstract + real
2311        // empty
2312                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2313        | ELLIPSIS
2314                { $$ = nullptr; }
2315        | cfa_abstract_parameter_list
2316        | cfa_parameter_list
2317        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2318                { $$ = $1->appendList( $5 ); }
2319        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2320                { $$ = $1->addVarArgs(); }
2321        | cfa_parameter_list pop ',' push ELLIPSIS
2322                { $$ = $1->addVarArgs(); }
2323        ;
2324
2325cfa_parameter_list:                                                                             // CFA
2326                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2327                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2328        cfa_parameter_declaration
2329        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2330                { $$ = $1->appendList( $5 ); }
2331        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2332                { $$ = $1->appendList( $5 ); }
2333        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2334                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2335        ;
2336
2337cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2338        cfa_abstract_parameter_declaration
2339        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2340                { $$ = $1->appendList( $5 ); }
2341        ;
2342
2343parameter_type_list_opt:
2344        // empty
2345                { $$ = nullptr; }
2346        | ELLIPSIS
2347                { $$ = nullptr; }
2348        | parameter_list
2349        | parameter_list pop ',' push ELLIPSIS
2350                { $$ = $1->addVarArgs(); }
2351        ;
2352
2353parameter_list:                                                                                 // abstract + real
2354        abstract_parameter_declaration
2355        | parameter_declaration
2356        | parameter_list pop ',' push abstract_parameter_declaration
2357                { $$ = $1->appendList( $5 ); }
2358        | parameter_list pop ',' push parameter_declaration
2359                { $$ = $1->appendList( $5 ); }
2360        ;
2361
2362// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2363// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2364
2365cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2366        parameter_declaration
2367        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2368                { $$ = $1->addName( $2 ); }
2369        | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2370                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2371                { $$ = $1->addName( $2 ); }
2372        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2373                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2374        | cfa_function_specifier
2375        ;
2376
2377cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2378        abstract_parameter_declaration
2379        | cfa_identifier_parameter_declarator_no_tuple
2380        | cfa_abstract_tuple
2381                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2382        | type_qualifier_list cfa_abstract_tuple
2383                { $$ = $2->addQualifiers( $1 ); }
2384        | cfa_abstract_function
2385        ;
2386
2387parameter_declaration:
2388                // No SUE declaration in parameter list.
2389        declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2390                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2391        | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2392                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2393        ;
2394
2395abstract_parameter_declaration:
2396        declaration_specifier_nobody default_initializer_opt
2397                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2398        | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2399                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2400        ;
2401
2402// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2403// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2404// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2405
2406identifier_list:                                                                                // K&R-style parameter list => no types
2407        identifier
2408                { $$ = DeclarationNode::newName( $1 ); }
2409        | identifier_list ',' identifier
2410                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2411        ;
2412
2413identifier_or_type_name:
2414        identifier
2415        | TYPEDEFname
2416        | TYPEGENname
2417        ;
2418
2419type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2420        cfa_abstract_declarator_tuple                                           // CFA
2421        | type_specifier
2422        | type_specifier abstract_declarator
2423                { $$ = $2->addType( $1 ); }
2424        ;
2425
2426type:                                                                                                   // typeof, assertion
2427        type_no_function
2428        | cfa_abstract_function                                                         // CFA
2429        ;
2430
2431initializer_opt:
2432        // empty
2433                { $$ = nullptr; }
2434        | simple_assignment_operator initializer        { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2435        | '=' VOID                                                                      { $$ = new InitializerNode( true ); }
2436        ;
2437
2438initializer:
2439        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2440        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2441        ;
2442
2443initializer_list_opt:
2444        // empty
2445                { $$ = nullptr; }
2446        | initializer
2447        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2448        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2449        | initializer_list_opt ',' designation initializer
2450                { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2451        ;
2452
2453// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2454// '=' to separator the designator from the initializer value, as in:
2455//
2456//              int x[10] = { [1] = 3 };
2457//
2458// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2459// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2460// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2461// shift/reduce conflicts
2462
2463designation:
2464        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2465        | identifier ':'                                                                        // GCC, field name
2466                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2467        ;
2468
2469designator_list:                                                                                // C99
2470        designator
2471        | designator_list designator
2472                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2473        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2474        ;
2475
2476designator:
2477        '.' identifier                                                                          // C99, field name
2478                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2479        | '[' push assignment_expression pop ']'                        // C99, single array element
2480                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2481                { $$ = $3; }
2482        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2483                { $$ = $3; }
2484        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2485                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $3 ), maybeMoveBuild<Expression>( $5 ) ) ); }
2486        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2487                { $$ = $4; }
2488        ;
2489
2490// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2491// rather than an object-oriented type system. This required four groups of extensions:
2492//
2493// Overloading: function, data, and operator identifiers may be overloaded.
2494//
2495// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2496//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2497//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2498//
2499// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2500//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2501//
2502// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2503//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2504//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2505//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2506//     on type arguments of polymorphic functions.
2507
2508type_parameter_list:                                                                    // CFA
2509        type_parameter
2510        | type_parameter_list ',' type_parameter
2511                { $$ = $1->appendList( $3 ); }
2512        ;
2513
2514type_initializer_opt:                                                                   // CFA
2515        // empty
2516                { $$ = nullptr; }
2517        | '=' type
2518                { $$ = $2; }
2519        ;
2520
2521type_parameter:                                                                                 // CFA
2522        type_class identifier_or_type_name
2523                {
2524                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2525                        if ( $1 == TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2526                        if ( $1 == TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2527                        if ( $1 == TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2528                }
2529          type_initializer_opt assertion_list_opt
2530                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2531        | identifier_or_type_name new_type_class
2532                { typedefTable.addToScope( *$1, TYPEDEFname, "9" ); }
2533          type_initializer_opt assertion_list_opt
2534                { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2535        | '[' identifier_or_type_name ']'
2536                {
2537                        typedefTable.addToScope( *$2, TYPEDEFname, "9" );
2538                        $$ = DeclarationNode::newTypeParam( TypeDecl::ALtype, $2 );
2539                }
2540        // | type_specifier identifier_parameter_declarator
2541        | assertion_list
2542                { $$ = DeclarationNode::newTypeParam( TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2543        ;
2544
2545new_type_class:                                                                                 // CFA
2546        // empty
2547                { $$ = TypeDecl::Otype; }
2548        | '&'
2549                { $$ = TypeDecl::Dtype; }
2550        | '*'
2551                { $$ = TypeDecl::DStype; }                                              // dtype + sized
2552        | ELLIPSIS
2553                { $$ = TypeDecl::Ttype; }
2554        ;
2555
2556type_class:                                                                                             // CFA
2557        OTYPE
2558                { $$ = TypeDecl::Otype; }
2559        | DTYPE
2560                { $$ = TypeDecl::Dtype; }
2561        | FTYPE
2562                { $$ = TypeDecl::Ftype; }
2563        | TTYPE
2564                { $$ = TypeDecl::Ttype; }
2565        ;
2566
2567assertion_list_opt:                                                                             // CFA
2568        // empty
2569                { $$ = nullptr; }
2570        | assertion_list
2571        ;
2572
2573assertion_list:                                                                                 // CFA
2574        assertion
2575        | assertion_list assertion
2576                { $$ = $1->appendList( $2 ); }
2577        ;
2578
2579assertion:                                                                                              // CFA
2580        '|' identifier_or_type_name '(' type_list ')'
2581                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2582        | '|' '{' push trait_declaration_list pop '}'
2583                { $$ = $4; }
2584        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2585        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2586        ;
2587
2588type_list:                                                                                              // CFA
2589        type
2590                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2591        | assignment_expression
2592                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2593        | type_list ',' type
2594                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) )); }
2595        | type_list ',' assignment_expression
2596                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2597                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2598        ;
2599
2600type_declaring_list:                                                                    // CFA
2601        OTYPE type_declarator
2602                { $$ = $2; }
2603        | storage_class_list OTYPE type_declarator
2604                { $$ = $3->addQualifiers( $1 ); }
2605        | type_declaring_list ',' type_declarator
2606                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2607        ;
2608
2609type_declarator:                                                                                // CFA
2610        type_declarator_name assertion_list_opt
2611                { $$ = $1->addAssertions( $2 ); }
2612        | type_declarator_name assertion_list_opt '=' type
2613                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2614        ;
2615
2616type_declarator_name:                                                                   // CFA
2617        identifier_or_type_name
2618                {
2619                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2620                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2621                }
2622        | identifier_or_type_name '(' type_parameter_list ')'
2623                {
2624                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2625                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2626                }
2627        ;
2628
2629trait_specifier:                                                                                // CFA
2630        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2631                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2632        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2633                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2634        ;
2635
2636trait_declaration_list:                                                                 // CFA
2637        trait_declaration
2638        | trait_declaration_list pop push trait_declaration
2639                { $$ = $1->appendList( $4 ); }
2640        ;
2641
2642trait_declaration:                                                                              // CFA
2643        cfa_trait_declaring_list ';'
2644        | trait_declaring_list ';'
2645        ;
2646
2647cfa_trait_declaring_list:                                                               // CFA
2648        cfa_variable_specifier
2649        | cfa_function_specifier
2650        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2651                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2652        ;
2653
2654trait_declaring_list:                                                                   // CFA
2655        type_specifier declarator
2656                { $$ = $2->addType( $1 ); }
2657        | trait_declaring_list pop ',' push declarator
2658                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2659        ;
2660
2661//***************************** EXTERNAL DEFINITIONS *****************************
2662
2663translation_unit:
2664        // empty, input file
2665        | external_definition_list
2666                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2667        ;
2668
2669external_definition_list:
2670        push external_definition pop
2671                { $$ = $2; }
2672        | external_definition_list push external_definition pop
2673                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2674        ;
2675
2676external_definition_list_opt:
2677        // empty
2678                { $$ = nullptr; }
2679        | external_definition_list
2680        ;
2681
2682up:
2683                { typedefTable.up( forall ); forall = false; }
2684        ;
2685
2686down:
2687                { typedefTable.down(); }
2688        ;
2689
2690external_definition:
2691        DIRECTIVE
2692                { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( $1 ) ) ); }
2693        | declaration
2694        | external_function_definition
2695        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2696                {
2697                        distExt( $2 );                                                          // mark all fields in list
2698                        $$ = $2;
2699                }
2700        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2701                { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) ); }
2702        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2703                {
2704                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2705                        linkage = LinkageSpec::update( yylloc, linkage, $2 );
2706                }
2707          '{' up external_definition_list_opt down '}'
2708                {
2709                        linkage = linkageStack.top();
2710                        linkageStack.pop();
2711                        $$ = $6;
2712                }
2713        | type_qualifier_list
2714                {
2715                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2716                        if ( $1->type->forall ) forall = true;          // remember generic type
2717                }
2718          '{' up external_definition_list_opt down '}'          // CFA, namespace
2719                {
2720                        distQual( $5, $1 );
2721                        forall = false;
2722                        $$ = $5;
2723                }
2724        | declaration_qualifier_list
2725                {
2726                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2727                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2728                }
2729          '{' up external_definition_list_opt down '}'          // CFA, namespace
2730                {
2731                        distQual( $5, $1 );
2732                        forall = false;
2733                        $$ = $5;
2734                }
2735        | declaration_qualifier_list type_qualifier_list
2736                {
2737                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2738                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2739                }
2740          '{' up external_definition_list_opt down '}'          // CFA, namespace
2741                {
2742                        distQual( $6, $1->addQualifiers( $2 ) );
2743                        forall = false;
2744                        $$ = $6;
2745                }
2746        ;
2747
2748external_function_definition:
2749        function_definition
2750                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2751                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2752                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2753                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2754                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2755        | function_declarator compound_statement
2756                { $$ = $1->addFunctionBody( $2 ); }
2757        | KR_function_declarator KR_parameter_list_opt compound_statement
2758                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2759        ;
2760
2761with_clause_opt:
2762        // empty
2763                { $$ = nullptr; forall = false; }
2764        | WITH '(' tuple_expression_list ')'
2765                { $$ = $3; forall = false; }
2766        ;
2767
2768function_definition:
2769        cfa_function_declaration with_clause_opt compound_statement     // CFA
2770                {
2771                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2772                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2773                        $1->get_last()->addFunctionBody( $3, $2 );
2774                        $$ = $1;
2775                }
2776        | declaration_specifier function_declarator with_clause_opt compound_statement
2777                {
2778                        rebindForall( $1, $2 );
2779                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2780                }
2781        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2782                {
2783                        rebindForall( $1, $2 );
2784                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2785                }
2786                // handles default int return type, OBSOLESCENT (see 1)
2787        | type_qualifier_list function_declarator with_clause_opt compound_statement
2788                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2789                // handles default int return type, OBSOLESCENT (see 1)
2790        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2791                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2792                // handles default int return type, OBSOLESCENT (see 1)
2793        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2794                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2795
2796                // Old-style K&R function definition, OBSOLESCENT (see 4)
2797        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2798                {
2799                        rebindForall( $1, $2 );
2800                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2801                }
2802                // handles default int return type, OBSOLESCENT (see 1)
2803        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2804                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2805                // handles default int return type, OBSOLESCENT (see 1)
2806        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2807                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2808                // handles default int return type, OBSOLESCENT (see 1)
2809        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2810                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2811        ;
2812
2813declarator:
2814        variable_declarator
2815        | variable_type_redeclarator
2816        | function_declarator
2817        ;
2818
2819subrange:
2820        constant_expression '~' constant_expression                     // CFA, integer subrange
2821                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild<Expression>( $1 ), maybeMoveBuild<Expression>( $3 ) ) ); }
2822        ;
2823
2824asm_name_opt:                                                                                   // GCC
2825        // empty
2826                { $$ = nullptr; }
2827        | ASM '(' string_literal ')' attribute_list_opt
2828                {
2829                        DeclarationNode * name = new DeclarationNode();
2830                        name->asmName = $3;
2831                        $$ = name->addQualifiers( $5 );
2832                }
2833        ;
2834
2835attribute_list_opt:                                                                             // GCC
2836        // empty
2837                { $$ = nullptr; }
2838        | attribute_list
2839        ;
2840
2841attribute_list:                                                                                 // GCC
2842        attribute
2843        | attribute_list attribute
2844                { $$ = $2->addQualifiers( $1 ); }
2845        ;
2846
2847attribute:                                                                                              // GCC
2848        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2849                { $$ = $4; }
2850        ;
2851
2852attribute_name_list:                                                                    // GCC
2853        attribute_name
2854        | attribute_name_list ',' attribute_name
2855                { $$ = $3->addQualifiers( $1 ); }
2856        ;
2857
2858attribute_name:                                                                                 // GCC
2859        // empty
2860                { $$ = nullptr; }
2861        | attr_name
2862                { $$ = DeclarationNode::newAttribute( $1 ); }
2863        | attr_name '(' argument_expression_list_opt ')'
2864                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2865        ;
2866
2867attr_name:                                                                                              // GCC
2868        IDENTIFIER
2869        | quasi_keyword
2870        | TYPEDEFname
2871        | TYPEGENname
2872        | FALLTHROUGH
2873                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2874        | CONST
2875                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2876        ;
2877
2878// ============================================================================
2879// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2880// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2881// in:
2882//
2883//              int (*f())[10] { ... };
2884//              ... (*f())[3] += 1;             // definition mimics usage
2885//
2886// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2887// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2888// ============================================================================
2889
2890// ----------------------------------------------------------------------------
2891// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2892// to define a variable or function prototype, e.g.:
2893//
2894//              valid declaration               invalid definition
2895//              -----------------               ------------------
2896//              int f;                                  int f {}
2897//              int *f;                                 int *f {}
2898//              int f[10];                              int f[10] {}
2899//              int (*f)(int);                  int (*f)(int) {}
2900//
2901// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2902// variable_declarator and function_declarator.
2903// ----------------------------------------------------------------------------
2904
2905// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2906// declaring an array of functions versus a pointer to an array of functions.
2907
2908paren_identifier:
2909        identifier
2910                { $$ = DeclarationNode::newName( $1 ); }
2911        | '(' paren_identifier ')'                                                      // redundant parenthesis
2912                { $$ = $2; }
2913        ;
2914
2915variable_declarator:
2916        paren_identifier attribute_list_opt
2917                { $$ = $1->addQualifiers( $2 ); }
2918        | variable_ptr
2919        | variable_array attribute_list_opt
2920                { $$ = $1->addQualifiers( $2 ); }
2921        | variable_function attribute_list_opt
2922                { $$ = $1->addQualifiers( $2 ); }
2923        ;
2924
2925variable_ptr:
2926        ptrref_operator variable_declarator
2927                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2928        | ptrref_operator type_qualifier_list variable_declarator
2929                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2930        | '(' variable_ptr ')' attribute_list_opt                       // redundant parenthesis
2931                { $$ = $2->addQualifiers( $4 ); }
2932        | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
2933                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
2934        ;
2935
2936variable_array:
2937        paren_identifier array_dimension
2938                { $$ = $1->addArray( $2 ); }
2939        | '(' variable_ptr ')' array_dimension
2940                { $$ = $2->addArray( $4 ); }
2941        | '(' attribute_list variable_ptr ')' array_dimension
2942                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
2943        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2944                { $$ = $2->addArray( $4 ); }
2945        | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
2946                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
2947        | '(' variable_array ')'                                                        // redundant parenthesis
2948                { $$ = $2; }
2949        | '(' attribute_list variable_array ')'                         // redundant parenthesis
2950                { $$ = $3->addQualifiers( $2 ); }
2951        ;
2952
2953variable_function:
2954        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2955                { $$ = $2->addParamList( $6 ); }
2956        | '(' attribute_list variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2957                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
2958        | '(' variable_function ')'                                                     // redundant parenthesis
2959                { $$ = $2; }
2960        | '(' attribute_list variable_function ')'                      // redundant parenthesis
2961                { $$ = $3->addQualifiers( $2 ); }
2962        ;
2963
2964// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2965// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2966// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2967
2968function_declarator:
2969        function_no_ptr attribute_list_opt
2970                { $$ = $1->addQualifiers( $2 ); }
2971        | function_ptr
2972        | function_array attribute_list_opt
2973                { $$ = $1->addQualifiers( $2 ); }
2974        ;
2975
2976function_no_ptr:
2977        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2978                { $$ = $1->addParamList( $4 ); }
2979        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2980                { $$ = $2->addParamList( $6 ); }
2981        | '(' attribute_list function_ptr ')' '(' push parameter_type_list_opt pop ')'
2982                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
2983        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2984                { $$ = $2; }
2985        | '(' attribute_list function_no_ptr ')'                        // redundant parenthesis
2986                { $$ = $3->addQualifiers( $2 ); }
2987        ;
2988
2989function_ptr:
2990        ptrref_operator function_declarator
2991                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2992        | ptrref_operator type_qualifier_list function_declarator
2993                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2994        | '(' function_ptr ')' attribute_list_opt
2995                { $$ = $2->addQualifiers( $4 ); }
2996        | '(' attribute_list function_ptr ')' attribute_list_opt
2997                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
2998        ;
2999
3000function_array:
3001        '(' function_ptr ')' array_dimension
3002                { $$ = $2->addArray( $4 ); }
3003        | '(' attribute_list function_ptr ')' array_dimension
3004                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3005        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
3006                { $$ = $2->addArray( $4 ); }
3007        | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3008                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3009        | '(' function_array ')'                                                        // redundant parenthesis
3010                { $$ = $2; }
3011        | '(' attribute_list function_array ')'                         // redundant parenthesis
3012                { $$ = $3->addQualifiers( $2 ); }
3013        ;
3014
3015// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3016//
3017//   f( a, b, c ) int a, *b, c[]; {}
3018//
3019// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3020// returning arrays and functions versus pointers to arrays and functions.
3021
3022KR_function_declarator:
3023        KR_function_no_ptr
3024        | KR_function_ptr
3025        | KR_function_array
3026        ;
3027
3028KR_function_no_ptr:
3029        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
3030                { $$ = $1->addIdList( $3 ); }
3031        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3032                { $$ = $2->addParamList( $6 ); }
3033        | '(' attribute_list KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
3034                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3035        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
3036                { $$ = $2; }
3037        | '(' attribute_list KR_function_no_ptr ')'                     // redundant parenthesis
3038                { $$ = $3->addQualifiers( $2 ); }
3039        ;
3040
3041KR_function_ptr:
3042        ptrref_operator KR_function_declarator
3043                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3044        | ptrref_operator type_qualifier_list KR_function_declarator
3045                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3046        | '(' KR_function_ptr ')'
3047                { $$ = $2; }
3048        | '(' attribute_list KR_function_ptr ')'
3049                { $$ = $3->addQualifiers( $2 ); }
3050        ;
3051
3052KR_function_array:
3053        '(' KR_function_ptr ')' array_dimension
3054                { $$ = $2->addArray( $4 ); }
3055        | '(' attribute_list KR_function_ptr ')' array_dimension
3056                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3057        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
3058                { $$ = $2->addArray( $4 ); }
3059        | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3060                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3061        | '(' KR_function_array ')'                                                     // redundant parenthesis
3062                { $$ = $2; }
3063        | '(' attribute_list KR_function_array ')'                      // redundant parenthesis
3064                { $$ = $3->addQualifiers( $2 ); }
3065        ;
3066
3067// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
3068//
3069//              typedef int foo;
3070//              {
3071//                 int foo; // redefine typedef name in new scope
3072//              }
3073//
3074// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3075// and functions versus pointers to arrays and functions.
3076
3077paren_type:
3078        typedef_name
3079                {
3080                        // hide type name in enclosing scope by variable name
3081                        typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
3082                }
3083        | '(' paren_type ')'
3084                { $$ = $2; }
3085        ;
3086
3087variable_type_redeclarator:
3088        paren_type attribute_list_opt
3089                { $$ = $1->addQualifiers( $2 ); }
3090        | type_ptr
3091        | type_array attribute_list_opt
3092                { $$ = $1->addQualifiers( $2 ); }
3093        | type_function attribute_list_opt
3094                { $$ = $1->addQualifiers( $2 ); }
3095        ;
3096
3097type_ptr:
3098        ptrref_operator variable_type_redeclarator
3099                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3100        | ptrref_operator type_qualifier_list variable_type_redeclarator
3101                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3102        | '(' type_ptr ')' attribute_list_opt                           // redundant parenthesis
3103                { $$ = $2->addQualifiers( $4 ); }
3104        | '(' attribute_list type_ptr ')' attribute_list_opt // redundant parenthesis
3105                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3106        ;
3107
3108type_array:
3109        paren_type array_dimension
3110                { $$ = $1->addArray( $2 ); }
3111        | '(' type_ptr ')' array_dimension
3112                { $$ = $2->addArray( $4 ); }
3113        | '(' attribute_list type_ptr ')' array_dimension
3114                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3115        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
3116                { $$ = $2->addArray( $4 ); }
3117        | '(' attribute_list type_array ')' multi_array_dimension // redundant parenthesis
3118                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3119        | '(' type_array ')'                                                            // redundant parenthesis
3120                { $$ = $2; }
3121        | '(' attribute_list type_array ')'                                     // redundant parenthesis
3122                { $$ = $3->addQualifiers( $2 ); }
3123        ;
3124
3125type_function:
3126        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3127                { $$ = $1->addParamList( $4 ); }
3128        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3129                { $$ = $2->addParamList( $6 ); }
3130        | '(' attribute_list type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3131                { $$ = $3->addQualifiers( $2 )->addParamList( $7 ); }
3132        | '(' type_function ')'                                                         // redundant parenthesis
3133                { $$ = $2; }
3134        | '(' attribute_list type_function ')'                          // redundant parenthesis
3135                { $$ = $3->addQualifiers( $2 ); }
3136        ;
3137
3138// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3139// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
3140// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3141// pointers to arrays and functions.
3142
3143identifier_parameter_declarator:
3144        paren_identifier attribute_list_opt
3145                { $$ = $1->addQualifiers( $2 ); }
3146        | '&' MUTEX paren_identifier attribute_list_opt
3147                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3148        | identifier_parameter_ptr
3149        | identifier_parameter_array attribute_list_opt
3150                { $$ = $1->addQualifiers( $2 ); }
3151        | identifier_parameter_function attribute_list_opt
3152                { $$ = $1->addQualifiers( $2 ); }
3153        ;
3154
3155identifier_parameter_ptr:
3156        ptrref_operator identifier_parameter_declarator
3157                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3158        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3159                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3160        | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3161                { $$ = $2->addQualifiers( $4 ); }
3162        ;
3163
3164identifier_parameter_array:
3165        paren_identifier array_parameter_dimension
3166                { $$ = $1->addArray( $2 ); }
3167        | '(' identifier_parameter_ptr ')' array_dimension
3168                { $$ = $2->addArray( $4 ); }
3169        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3170                { $$ = $2->addArray( $4 ); }
3171        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3172                { $$ = $2; }
3173        ;
3174
3175identifier_parameter_function:
3176        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3177                { $$ = $1->addParamList( $4 ); }
3178        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3179                { $$ = $2->addParamList( $6 ); }
3180        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3181                { $$ = $2; }
3182        ;
3183
3184// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3185// e.g.:
3186//
3187//              typedef int foo;
3188//              forall( otype T ) struct foo;
3189//              int f( int foo ); // redefine typedef name in new scope
3190//
3191// and allows the C99 array options, which can only appear in a parameter list.
3192
3193type_parameter_redeclarator:
3194        typedef_name attribute_list_opt
3195                { $$ = $1->addQualifiers( $2 ); }
3196        | '&' MUTEX typedef_name attribute_list_opt
3197                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3198        | type_parameter_ptr
3199        | type_parameter_array attribute_list_opt
3200                { $$ = $1->addQualifiers( $2 ); }
3201        | type_parameter_function attribute_list_opt
3202                { $$ = $1->addQualifiers( $2 ); }
3203        ;
3204
3205typedef_name:
3206        TYPEDEFname
3207                { $$ = DeclarationNode::newName( $1 ); }
3208        | TYPEGENname
3209                { $$ = DeclarationNode::newName( $1 ); }
3210        ;
3211
3212type_parameter_ptr:
3213        ptrref_operator type_parameter_redeclarator
3214                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3215        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3216                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3217        | '(' type_parameter_ptr ')' attribute_list_opt         // redundant parenthesis
3218                { $$ = $2->addQualifiers( $4 ); }
3219        ;
3220
3221type_parameter_array:
3222        typedef_name array_parameter_dimension
3223                { $$ = $1->addArray( $2 ); }
3224        | '(' type_parameter_ptr ')' array_parameter_dimension
3225                { $$ = $2->addArray( $4 ); }
3226        ;
3227
3228type_parameter_function:
3229        typedef_name '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3230                { $$ = $1->addParamList( $4 ); }
3231        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3232                { $$ = $2->addParamList( $6 ); }
3233        ;
3234
3235// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3236// which the type applies, e.g.:
3237//
3238//              sizeof( int );
3239//              sizeof( int * );
3240//              sizeof( int [10] );
3241//              sizeof( int (*)() );
3242//              sizeof( int () );
3243//
3244// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3245// and functions versus pointers to arrays and functions.
3246
3247abstract_declarator:
3248        abstract_ptr
3249        | abstract_array attribute_list_opt
3250                { $$ = $1->addQualifiers( $2 ); }
3251        | abstract_function attribute_list_opt
3252                { $$ = $1->addQualifiers( $2 ); }
3253        ;
3254
3255abstract_ptr:
3256        ptrref_operator
3257                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3258        | ptrref_operator type_qualifier_list
3259                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3260        | ptrref_operator abstract_declarator
3261                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3262        | ptrref_operator type_qualifier_list abstract_declarator
3263                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3264        | '(' abstract_ptr ')' attribute_list_opt
3265                { $$ = $2->addQualifiers( $4 ); }
3266        ;
3267
3268abstract_array:
3269        array_dimension
3270        | '(' abstract_ptr ')' array_dimension
3271                { $$ = $2->addArray( $4 ); }
3272        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3273                { $$ = $2->addArray( $4 ); }
3274        | '(' abstract_array ')'                                                        // redundant parenthesis
3275                { $$ = $2; }
3276        ;
3277
3278abstract_function:
3279        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3280                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3281        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3282                { $$ = $2->addParamList( $6 ); }
3283        | '(' abstract_function ')'                                                     // redundant parenthesis
3284                { $$ = $2; }
3285        ;
3286
3287array_dimension:
3288                // Only the first dimension can be empty.
3289        '[' ']'
3290                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3291        | '[' ']' multi_array_dimension
3292                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3293        | '[' push assignment_expression pop ',' comma_expression ']'
3294                { $$ = DeclarationNode::newArray( $3, 0, false )->addArray( DeclarationNode::newArray( $6, 0, false ) ); }
3295                // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3296        | multi_array_dimension
3297        ;
3298
3299multi_array_dimension:
3300        '[' push assignment_expression pop ']'
3301                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3302        | '[' push '*' pop ']'                                                          // C99
3303                { $$ = DeclarationNode::newVarArray( 0 ); }
3304        | multi_array_dimension '[' push assignment_expression pop ']'
3305                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3306        | multi_array_dimension '[' push '*' pop ']'            // C99
3307                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3308        ;
3309
3310// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3311// identifier to which the type applies, e.g.:
3312//
3313//              int f( int );                   // not handled here
3314//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3315//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3316//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3317//
3318// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3319// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3320// special meaning of parenthesis around a typedef name:
3321//
3322//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3323//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3324//              not as redundant parentheses around the identifier."
3325//
3326// For example:
3327//
3328//              typedef float T;
3329//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3330//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3331//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3332//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3333//
3334// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3335// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3336// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3337// functions.
3338
3339abstract_parameter_declarator:
3340        abstract_parameter_ptr
3341        | '&' MUTEX attribute_list_opt
3342                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3343        | abstract_parameter_array attribute_list_opt
3344                { $$ = $1->addQualifiers( $2 ); }
3345        | abstract_parameter_function attribute_list_opt
3346                { $$ = $1->addQualifiers( $2 ); }
3347        ;
3348
3349abstract_parameter_ptr:
3350        ptrref_operator
3351                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3352        | ptrref_operator type_qualifier_list
3353                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3354        | ptrref_operator abstract_parameter_declarator
3355                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3356        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3357                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3358        | '(' abstract_parameter_ptr ')' attribute_list_opt     // redundant parenthesis
3359                { $$ = $2->addQualifiers( $4 ); }
3360        ;
3361
3362abstract_parameter_array:
3363        array_parameter_dimension
3364        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3365                { $$ = $2->addArray( $4 ); }
3366        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3367                { $$ = $2->addArray( $4 ); }
3368        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3369                { $$ = $2; }
3370        ;
3371
3372abstract_parameter_function:
3373        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3374                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3375        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3376                { $$ = $2->addParamList( $6 ); }
3377        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3378                { $$ = $2; }
3379        ;
3380
3381array_parameter_dimension:
3382                // Only the first dimension can be empty or have qualifiers.
3383        array_parameter_1st_dimension
3384        | array_parameter_1st_dimension multi_array_dimension
3385                { $$ = $1->addArray( $2 ); }
3386        | multi_array_dimension
3387        ;
3388
3389// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3390//
3391//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3392//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3393
3394array_parameter_1st_dimension:
3395        '[' ']'
3396                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3397                // multi_array_dimension handles the '[' '*' ']' case
3398        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3399                { $$ = DeclarationNode::newVarArray( $3 ); }
3400        | '[' push type_qualifier_list pop ']'
3401                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3402                // multi_array_dimension handles the '[' assignment_expression ']' case
3403        | '[' push type_qualifier_list assignment_expression pop ']'
3404                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3405        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3406                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3407        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3408                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3409        ;
3410
3411// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3412//
3413//              struct S {
3414//          int;
3415//          int *;
3416//          int [10];
3417//          int (*)();
3418//      };
3419
3420variable_abstract_declarator:
3421        variable_abstract_ptr
3422        | variable_abstract_array attribute_list_opt
3423                { $$ = $1->addQualifiers( $2 ); }
3424        | variable_abstract_function attribute_list_opt
3425                { $$ = $1->addQualifiers( $2 ); }
3426        ;
3427
3428variable_abstract_ptr:
3429        ptrref_operator
3430                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3431        | ptrref_operator type_qualifier_list
3432                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3433        | ptrref_operator variable_abstract_declarator
3434                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3435        | ptrref_operator type_qualifier_list variable_abstract_declarator
3436                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3437        | '(' variable_abstract_ptr ')' attribute_list_opt      // redundant parenthesis
3438                { $$ = $2->addQualifiers( $4 ); }
3439        ;
3440
3441variable_abstract_array:
3442        array_dimension
3443        | '(' variable_abstract_ptr ')' array_dimension
3444                { $$ = $2->addArray( $4 ); }
3445        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3446                { $$ = $2->addArray( $4 ); }
3447        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3448                { $$ = $2; }
3449        ;
3450
3451variable_abstract_function:
3452        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3453                { $$ = $2->addParamList( $6 ); }
3454        | '(' variable_abstract_function ')'                            // redundant parenthesis
3455                { $$ = $2; }
3456        ;
3457
3458// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3459// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3460
3461cfa_identifier_parameter_declarator_tuple:                              // CFA
3462        cfa_identifier_parameter_declarator_no_tuple
3463        | cfa_abstract_tuple
3464        | type_qualifier_list cfa_abstract_tuple
3465                { $$ = $2->addQualifiers( $1 ); }
3466        ;
3467
3468cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3469        cfa_identifier_parameter_ptr
3470        | cfa_identifier_parameter_array
3471        ;
3472
3473cfa_identifier_parameter_ptr:                                                   // CFA
3474                // No SUE declaration in parameter list.
3475        ptrref_operator type_specifier_nobody
3476                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3477        | type_qualifier_list ptrref_operator type_specifier_nobody
3478                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3479        | ptrref_operator cfa_abstract_function
3480                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3481        | type_qualifier_list ptrref_operator cfa_abstract_function
3482                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3483        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3484                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3485        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3486                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3487        ;
3488
3489cfa_identifier_parameter_array:                                                 // CFA
3490                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3491                // shift/reduce conflict with new-style empty (void) function return type.
3492        '[' ']' type_specifier_nobody
3493                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3494        | cfa_array_parameter_1st_dimension type_specifier_nobody
3495                { $$ = $2->addNewArray( $1 ); }
3496        | '[' ']' multi_array_dimension type_specifier_nobody
3497                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3498        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3499                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3500        | multi_array_dimension type_specifier_nobody
3501                { $$ = $2->addNewArray( $1 ); }
3502
3503        | '[' ']' cfa_identifier_parameter_ptr
3504                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3505        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3506                { $$ = $2->addNewArray( $1 ); }
3507        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3508                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3509        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3510                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3511        | multi_array_dimension cfa_identifier_parameter_ptr
3512                { $$ = $2->addNewArray( $1 ); }
3513        ;
3514
3515cfa_array_parameter_1st_dimension:
3516        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3517                { $$ = DeclarationNode::newVarArray( $3 ); }
3518        | '[' push type_qualifier_list assignment_expression pop ']'
3519                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3520        | '[' push declaration_qualifier_list assignment_expression pop ']'
3521                // declaration_qualifier_list must be used because of shift/reduce conflict with
3522                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3523                // appear in this context.
3524                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3525        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3526                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3527        ;
3528
3529// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3530// identifier to which the type applies, e.g.:
3531//
3532//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3533//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3534//
3535// These rules need LR(3):
3536//
3537//              cfa_abstract_tuple identifier_or_type_name
3538//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3539//
3540// since a function return type can be syntactically identical to a tuple type:
3541//
3542//              [int, int] t;
3543//              [int, int] f( int );
3544//
3545// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3546// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3547// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3548// duplicated when appearing with cfa_function_specifier.
3549
3550cfa_abstract_declarator_tuple:                                                  // CFA
3551        cfa_abstract_tuple
3552        | type_qualifier_list cfa_abstract_tuple
3553                { $$ = $2->addQualifiers( $1 ); }
3554        | cfa_abstract_declarator_no_tuple
3555        ;
3556
3557cfa_abstract_declarator_no_tuple:                                               // CFA
3558        cfa_abstract_ptr
3559        | cfa_abstract_array
3560        ;
3561
3562cfa_abstract_ptr:                                                                               // CFA
3563        ptrref_operator type_specifier
3564                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3565        | type_qualifier_list ptrref_operator type_specifier
3566                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3567        | ptrref_operator cfa_abstract_function
3568                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3569        | type_qualifier_list ptrref_operator cfa_abstract_function
3570                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3571        | ptrref_operator cfa_abstract_declarator_tuple
3572                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3573        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3574                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3575        ;
3576
3577cfa_abstract_array:                                                                             // CFA
3578                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3579                // empty (void) function return type.
3580        '[' ']' type_specifier
3581                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3582        | '[' ']' multi_array_dimension type_specifier
3583                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3584        | multi_array_dimension type_specifier
3585                { $$ = $2->addNewArray( $1 ); }
3586        | '[' ']' cfa_abstract_ptr
3587                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3588        | '[' ']' multi_array_dimension cfa_abstract_ptr
3589                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3590        | multi_array_dimension cfa_abstract_ptr
3591                { $$ = $2->addNewArray( $1 ); }
3592        ;
3593
3594cfa_abstract_tuple:                                                                             // CFA
3595        '[' push cfa_abstract_parameter_list pop ']'
3596                { $$ = DeclarationNode::newTuple( $3 ); }
3597        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3598                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3599        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3600                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3601        ;
3602
3603cfa_abstract_function:                                                                  // CFA
3604//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3605//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3606        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3607                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3608        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3609                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3610        ;
3611
3612// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3613//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3614//
3615// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3616//    the declaration specifiers in a declaration is an obsolescent feature."
3617//
3618// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3619//    prototype-format parameter type declarators) is an obsolescent feature."
3620//
3621// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3622//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3623
3624//************************* MISCELLANEOUS ********************************
3625
3626comma_opt:                                                                                              // redundant comma
3627        // empty
3628        | ','
3629        ;
3630
3631default_initializer_opt:
3632        // empty
3633                { $$ = nullptr; }
3634        | '=' assignment_expression
3635                { $$ = $2; }
3636        ;
3637
3638%%
3639
3640// ----end of grammar----
3641
3642// Local Variables: //
3643// mode: c++ //
3644// tab-width: 4 //
3645// compile-command: "make install" //
3646// End: //
Note: See TracBrowser for help on using the repository browser.