source: src/Parser/parser.yy @ 1d4580a

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newwith_gc
Last change on this file since 1d4580a was 1d4580a, checked in by Peter A. Buhr <pabuhr@…>, 8 years ago

more refactoring of parser code

  • Property mode set to 100644
File size: 102.8 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// cfa.y --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sat Aug 13 18:59:02 2016
13// Update Count     : 1877
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45extern char *yytext;
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51#include "lex.h"
52#include "parser.h"
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57
58DeclarationNode *theTree = 0;                                                   // the resulting parse tree
59LinkageSpec::Type linkage = LinkageSpec::Cforall;
60std::stack< LinkageSpec::Type > linkageStack;
61TypedefTable typedefTable;
62
63void appendStr( std::string &to, std::string *from ) {
64        // "abc" "def" "ghi" => "abcdefghi", remove new text from quotes and insert before last quote in old string.
65        to.insert( to.length() - 1, from->substr( 1, from->length() - 2 ) );
66} // appendStr
67%}
68
69//************************* TERMINAL TOKENS ********************************
70
71// keywords
72%token TYPEDEF
73%token AUTO EXTERN REGISTER STATIC
74%token INLINE                                                                                   // C99
75%token FORTRAN                                                                                  // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
76%token CONST VOLATILE
77%token RESTRICT                                                                                 // C99
78%token FORALL LVALUE                                                                    // CFA
79%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
80%token VALIST                                                                                   // GCC
81%token BOOL COMPLEX IMAGINARY                                                   // C99
82%token TYPEOF LABEL                                                                             // GCC
83%token ENUM STRUCT UNION
84%token OTYPE FTYPE DTYPE TRAIT                                                  // CFA
85%token SIZEOF OFFSETOF
86%token ATTRIBUTE EXTENSION                                                              // GCC
87%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
88%token CHOOSE DISABLE ENABLE FALLTHRU TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT        // CFA
89%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
90%token ALIGNAS ALIGNOF ATOMIC GENERIC NORETURN STATICASSERT THREADLOCAL // C11
91
92// names and constants: lexer differentiates between identifier and typedef names
93%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
94%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
95%token<tok> INTEGERconstant             FLOATINGconstant                CHARACTERconstant               STRINGliteral
96%token<tok> ZERO                                ONE                                             // CFA
97
98// multi-character operators
99%token ARROW                                                                                    // ->
100%token ICR DECR                                                                                 // ++   --
101%token LS RS                                                                                    // <<   >>
102%token LE GE EQ NE                                                                              // <=   >=      ==      !=
103%token ANDAND OROR                                                                              // &&   ||
104%token ELLIPSIS                                                                                 // ...
105
106%token MULTassign       DIVassign       MODassign                               // *=   /=      %=/
107%token PLUSassign       MINUSassign                                                     // +=   -=
108%token LSassign         RSassign                                                        // <<=  >>=
109%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
110
111%token ATassign                                                                                 // @=
112
113// Types declaration
114%union
115{
116        Token tok;
117        ParseNode *pn;
118        ExpressionNode *en;
119        DeclarationNode *decl;
120        DeclarationNode::Aggregate aggKey;
121        DeclarationNode::TypeClass tclass;
122        StatementNode *sn;
123        ConstantExpr *constant;
124        ForCtl *fctl;
125        LabelNode *label;
126        InitializerNode *in;
127        OperKinds op;
128        bool flag;
129}
130
131%type<tok> identifier  no_01_identifier  no_attr_identifier zero_one
132%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  no_01_identifier_or_type_name
133%type<constant> string_literal_list
134
135// expressions
136%type<en> constant
137%type<en> tuple                                                 tuple_expression_list
138%type<op> ptrref_operator                               unary_operator                          assignment_operator
139%type<en> primary_expression                    postfix_expression                      unary_expression
140%type<en> cast_expression                               multiplicative_expression       additive_expression                     shift_expression
141%type<en> relational_expression                 equality_expression                     AND_expression                          exclusive_OR_expression
142%type<en> inclusive_OR_expression               logical_AND_expression          logical_OR_expression           conditional_expression
143%type<en> constant_expression                   assignment_expression           assignment_expression_opt
144%type<en> comma_expression                              comma_expression_opt
145//%type<en> argument_expression_list            argument_expression                     for_control_expression          assignment_opt
146%type<en> argument_expression_list              argument_expression                     assignment_opt
147%type<fctl> for_control_expression
148%type<en> subrange
149%type<en> asm_operands_opt asm_operands_list asm_operand
150%type<label> label_list
151%type<en> asm_clobbers_list_opt
152%type<flag> asm_volatile_opt
153
154// statements
155%type<sn> labeled_statement                             compound_statement                      expression_statement            selection_statement
156%type<sn> iteration_statement                   jump_statement                          exception_statement                     asm_statement
157%type<sn> fall_through_opt                              fall_through
158%type<sn> statement                                             statement_list
159%type<sn> block_item_list                               block_item
160%type<sn> case_clause
161%type<en> case_value
162%type<sn> case_value_list                               case_label                                      case_label_list
163%type<sn> switch_clause_list_opt                switch_clause_list                      choose_clause_list_opt          choose_clause_list
164%type<sn> handler_list                                  handler_clause                          finally_clause
165
166// declarations
167%type<decl> abstract_array abstract_declarator abstract_function abstract_parameter_array
168%type<decl> abstract_parameter_declaration abstract_parameter_declarator abstract_parameter_function
169%type<decl> abstract_parameter_ptr abstract_ptr
170
171%type<aggKey> aggregate_key
172%type<decl>  aggregate_name
173
174%type<decl> array_dimension array_parameter_1st_dimension array_parameter_dimension multi_array_dimension
175
176%type<decl> assertion assertion_list_opt
177
178%type<en>   bit_subrange_size_opt bit_subrange_size
179
180%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type_name indirect_type_name
181
182%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
183
184%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
185%type<decl> declaration_specifier declarator declaring_list
186
187%type<decl> elaborated_type_name
188
189%type<decl> enumerator_list enum_name
190%type<en> enumerator_value_opt
191
192%type<decl> exception_declaration external_definition external_definition_list external_definition_list_opt
193
194%type<decl> field_declaration field_declaration_list field_declarator field_declaring_list
195%type<en> field field_list
196
197%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
198
199%type<decl> identifier_parameter_array identifier_parameter_declarator identifier_parameter_function
200%type<decl> identifier_parameter_ptr identifier_list
201
202%type<decl> new_abstract_array new_abstract_declarator_no_tuple new_abstract_declarator_tuple
203%type<decl> new_abstract_function new_abstract_parameter_declaration new_abstract_parameter_list
204%type<decl> new_abstract_ptr new_abstract_tuple
205
206%type<decl> new_array_parameter_1st_dimension
207
208%type<decl> new_trait_declaring_list new_declaration new_field_declaring_list
209%type<decl> new_function_declaration new_function_return new_function_specifier
210
211%type<decl> new_identifier_parameter_array new_identifier_parameter_declarator_no_tuple
212%type<decl> new_identifier_parameter_declarator_tuple new_identifier_parameter_ptr
213
214%type<decl> new_parameter_declaration new_parameter_list new_parameter_type_list new_parameter_type_list_opt
215
216%type<decl> new_typedef_declaration new_variable_declaration new_variable_specifier
217
218%type<decl> old_declaration old_declaration_list old_declaration_list_opt old_function_array
219%type<decl> old_function_declarator old_function_no_ptr old_function_ptr
220
221%type<decl> parameter_declaration parameter_list parameter_type_list
222%type<decl> parameter_type_list_opt
223
224%type<decl> paren_identifier paren_type
225
226%type<decl> storage_class storage_class_name storage_class_list
227
228%type<decl> sue_declaration_specifier sue_type_specifier
229
230%type<tclass> type_class
231%type<decl> type_declarator type_declarator_name type_declaring_list
232
233%type<decl> typedef type_array typedef_declaration typedef_declaration_specifier typedef_expression
234%type<decl> type_function type_parameter_array type_parameter_function type_parameter_ptr
235%type<decl> type_parameter_redeclarator type_ptr variable_type_redeclarator typedef_type_specifier
236%type<decl> typegen_declaration_specifier typegen_type_specifier typegen_name
237
238%type<decl> type_name type_name_no_function
239%type<decl> type_parameter type_parameter_list
240
241%type<en> type_name_list
242
243%type<decl> type_qualifier type_qualifier_name type_qualifier_list type_qualifier_list_opt type_specifier
244
245%type<decl> variable_abstract_array variable_abstract_declarator variable_abstract_function
246%type<decl> variable_abstract_ptr variable_array variable_declarator variable_function variable_ptr
247
248%type<decl> attribute_list_opt attribute_list attribute
249
250// initializers
251%type<in>  initializer initializer_list initializer_opt
252
253// designators
254%type<en>  designator designator_list designation
255
256
257// Handle single shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string
258// is ambiguous:
259// .---------.                          matches IF '(' comma_expression ')' statement
260// if ( C ) S1 else S2
261// `-----------------'          matches IF '(' comma_expression ')' statement ELSE statement */
262
263%nonassoc THEN  // rule precedence for IF '(' comma_expression ')' statement
264%nonassoc ELSE  // token precedence for start of else clause in IF statement
265
266%start translation_unit                                                                 // parse-tree root
267
268%%
269//************************* Namespace Management ********************************
270
271// The grammar in the ANSI C standard is not strictly context-free, since it relies upon the distinct terminal symbols
272// "identifier" and "TYPEDEFname" that are lexically identical.  While it is possible to write a purely context-free
273// grammar, such a grammar would obscure the relationship between syntactic and semantic constructs.  Hence, this
274// grammar uses the ANSI style.
275//
276// Cforall compounds this problem by introducing type names local to the scope of a declaration (for instance, those
277// introduced through "forall" qualifiers), and by introducing "type generators" -- parametrized types.  This latter
278// type name creates a third class of identifiers that must be distinguished by the scanner.
279//
280// Since the scanner cannot distinguish among the different classes of identifiers without some context information, it
281// accesses a data structure (the TypedefTable) to allow classification of an identifier that it has just read.
282// Semantic actions during the parser update this data structure when the class of identifiers change.
283//
284// Because the Cforall language is block-scoped, there is the possibility that an identifier can change its class in a
285// local scope; it must revert to its original class at the end of the block.  Since type names can be local to a
286// particular declaration, each declaration is itself a scope.  This requires distinguishing between type names that are
287// local to the current declaration scope and those that persist past the end of the declaration (i.e., names defined in
288// "typedef" or "type" declarations).
289//
290// The non-terminals "push" and "pop" derive the empty string; their only use is to denote the opening and closing of
291// scopes.  Every push must have a matching pop, although it is regrettable the matching pairs do not always occur
292// within the same rule.  These non-terminals may appear in more contexts than strictly necessary from a semantic point
293// of view.  Unfortunately, these extra rules are necessary to prevent parsing conflicts -- the parser may not have
294// enough context and look-ahead information to decide whether a new scope is necessary, so the effect of these extra
295// rules is to open a new scope unconditionally.  As the grammar evolves, it may be neccesary to add or move around
296// "push" and "pop" nonterminals to resolve conflicts of this sort.
297
298push:
299                {
300                        typedefTable.enterScope();
301                }
302        ;
303
304pop:
305                {
306                        typedefTable.leaveScope();
307                }
308        ;
309
310//************************* CONSTANTS ********************************
311
312constant:
313                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
314INTEGERconstant                                                                 { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
315        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
316        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
317        ;
318
319identifier:
320        IDENTIFIER
321        | ATTR_IDENTIFIER                                                                       // CFA
322        | zero_one                                                                                      // CFA
323        ;
324
325no_01_identifier:
326        IDENTIFIER
327        | ATTR_IDENTIFIER                                                                       // CFA
328        ;
329
330no_attr_identifier:
331        IDENTIFIER
332        | zero_one                                                                                      // CFA
333        ;
334
335zero_one:                                                                                               // CFA
336        ZERO
337        | ONE
338        ;
339
340string_literal_list:                                                                    // juxtaposed strings are concatenated
341        STRINGliteral                                                           { $$ = build_constantStr( *$1 ); }
342        | string_literal_list STRINGliteral
343                {
344                        appendStr( $1->get_constant()->get_value(), $2 );
345                        delete $2;                                                                      // allocated by lexer
346                        $$ = $1;
347                }
348        ;
349
350//************************* EXPRESSIONS ********************************
351
352primary_expression:
353        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
354                { $$ = new ExpressionNode( build_varref( $1 ) ); }
355        | zero_one
356                { $$ = new ExpressionNode( build_varref( $1 ) ); }
357        | '(' comma_expression ')'
358                { $$ = $2; }
359        | '(' compound_statement ')'                                            // GCC, lambda expression
360        { $$ = new ExpressionNode( build_valexpr( $2 ) ); }
361        ;
362
363postfix_expression:
364        primary_expression
365        | postfix_expression '[' push assignment_expression pop ']'
366                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
367                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
368                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
369                // equivalent to the old x[i,j].
370                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $4 ) ); }
371        | postfix_expression '(' argument_expression_list ')'
372                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
373        // ambiguity with .0 so space required after field-selection, e.g.
374                //   struct S { int 0, 1; } s; s. 0 = 0; s. 1 = 1;
375        | postfix_expression '.' no_attr_identifier
376                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
377        | postfix_expression '.' '[' push field_list pop ']' // CFA, tuple field selector
378        | postfix_expression ARROW no_attr_identifier
379                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
380        | postfix_expression ARROW '[' push field_list pop ']' // CFA, tuple field selector
381        | postfix_expression ICR
382                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
383        | postfix_expression DECR
384                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
385        | '(' type_name_no_function ')' '{' initializer_list comma_opt '}' // C99
386                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
387        | postfix_expression '{' argument_expression_list '}' // CFA
388                {
389                        Token fn;
390                        fn.str = new std::string( "?{}" ); // location undefined
391                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) );
392                }
393        ;
394
395argument_expression_list:
396        argument_expression
397        | argument_expression_list ',' argument_expression
398                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
399        ;
400
401argument_expression:
402        // empty
403                { $$ = 0; }                                                                             // use default argument
404        | assignment_expression
405        ;
406
407field_list:                                                                                             // CFA, tuple field selector
408        field
409        | field_list ',' field                                          { $$ = (ExpressionNode *)$1->set_last( $3 ); }
410        ;
411
412field:                                                                                                  // CFA, tuple field selector
413        no_attr_identifier
414                { $$ = new ExpressionNode( build_varref( $1 ) ); }
415        // ambiguity with .0 so space required after field-selection, e.g.
416                //   struct S { int 0, 1; } s; s. 0 = 0; s. 1 = 1;
417        | no_attr_identifier '.' field
418                { $$ = new ExpressionNode( build_fieldSel( $3, build_varref( $1 ) ) ); }
419        | no_attr_identifier '.' '[' push field_list pop ']'
420                { $$ = new ExpressionNode( build_fieldSel( $5, build_varref( $1 ) ) ); }
421        | no_attr_identifier ARROW field
422                { $$ = new ExpressionNode( build_pfieldSel( $3, build_varref( $1 ) ) ); }
423        | no_attr_identifier ARROW '[' push field_list pop ']'
424                { $$ = new ExpressionNode( build_pfieldSel( $5, build_varref( $1 ) ) ); }
425        ;
426
427unary_expression:
428        postfix_expression
429                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
430                // semantics checks, e.g., ++3, 3--, *3, &&3
431        | constant
432                { $$ = $1; }
433        | string_literal_list
434                { $$ = new ExpressionNode( $1 ); }
435        | EXTENSION cast_expression                                                     // GCC
436                { $$ = $2->set_extension( true ); }
437                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
438                //              { * X; }         // dereference X
439                //              { * int X; } // CFA declaration of pointer to int
440        | ptrref_operator cast_expression                                       // CFA
441                {
442                        switch ( $1 ) {
443                          case OperKinds::AddressOf:
444                                $$ = new ExpressionNode( build_addressOf( $2 ) );
445                                break;
446                          case OperKinds::PointTo:
447                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
448                                break;
449                          default:
450                                assert( false );
451                        }
452                }
453        | unary_operator cast_expression
454                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
455        | ICR unary_expression
456                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
457        | DECR unary_expression
458                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
459        | SIZEOF unary_expression
460                { $$ = new ExpressionNode( build_sizeOfexpr( $2 ) ); }
461        | SIZEOF '(' type_name_no_function ')'
462                { $$ = new ExpressionNode( build_sizeOftype( $3 ) ); }
463        | ALIGNOF unary_expression                                                      // GCC, variable alignment
464                { $$ = new ExpressionNode( build_alignOfexpr( $2 ) ); }
465        | ALIGNOF '(' type_name_no_function ')'                         // GCC, type alignment
466                { $$ = new ExpressionNode( build_alignOftype( $3 ) ); }
467        | OFFSETOF '(' type_name_no_function ',' no_attr_identifier ')'
468                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
469        | ATTR_IDENTIFIER
470                { $$ = new ExpressionNode( build_attrexpr( build_varref( $1 ), nullptr ) ); }
471        | ATTR_IDENTIFIER '(' argument_expression ')'
472                { $$ = new ExpressionNode( build_attrexpr( build_varref( $1 ), $3 ) ); }
473        | ATTR_IDENTIFIER '(' type_name ')'
474                { $$ = new ExpressionNode( build_attrtype( build_varref( $1 ), $3 ) ); }
475//      | ANDAND IDENTIFIER                                                                     // GCC, address of label
476//              { $$ = new ExpressionNode( new OperatorNode( OperKinds::LabelAddress ), new ExpressionNode( build_varref( $2, true ) ); }
477        ;
478
479ptrref_operator:
480        '*'                                                                                     { $$ = OperKinds::PointTo; }
481        | '&'                                                                           { $$ = OperKinds::AddressOf; }
482                // GCC, address of label must be handled by semantic check for ref,ref,label
483//      | ANDAND                                                                        { $$ = OperKinds::And; }
484        ;
485
486unary_operator:
487        '+'                                                                                     { $$ = OperKinds::UnPlus; }
488        | '-'                                                                           { $$ = OperKinds::UnMinus; }
489        | '!'                                                                           { $$ = OperKinds::Neg; }
490        | '~'                                                                           { $$ = OperKinds::BitNeg; }
491        ;
492
493cast_expression:
494        unary_expression
495        | '(' type_name_no_function ')' cast_expression
496                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
497        | '(' type_name_no_function ')' tuple
498                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
499        ;
500
501multiplicative_expression:
502        cast_expression
503        | multiplicative_expression '*' cast_expression
504                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
505        | multiplicative_expression '/' cast_expression
506                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
507        | multiplicative_expression '%' cast_expression
508                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
509        ;
510
511additive_expression:
512        multiplicative_expression
513        | additive_expression '+' multiplicative_expression
514                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
515        | additive_expression '-' multiplicative_expression
516                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
517        ;
518
519shift_expression:
520        additive_expression
521        | shift_expression LS additive_expression
522                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
523        | shift_expression RS additive_expression
524                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
525        ;
526
527relational_expression:
528        shift_expression
529        | relational_expression '<' shift_expression
530                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
531        | relational_expression '>' shift_expression
532                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
533        | relational_expression LE shift_expression
534                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
535        | relational_expression GE shift_expression
536                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
537        ;
538
539equality_expression:
540        relational_expression
541        | equality_expression EQ relational_expression
542                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
543        | equality_expression NE relational_expression
544                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
545        ;
546
547AND_expression:
548        equality_expression
549        | AND_expression '&' equality_expression
550                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
551        ;
552
553exclusive_OR_expression:
554        AND_expression
555        | exclusive_OR_expression '^' AND_expression
556                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
557        ;
558
559inclusive_OR_expression:
560        exclusive_OR_expression
561        | inclusive_OR_expression '|' exclusive_OR_expression
562                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
563        ;
564
565logical_AND_expression:
566        inclusive_OR_expression
567        | logical_AND_expression ANDAND inclusive_OR_expression
568                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
569        ;
570
571logical_OR_expression:
572        logical_AND_expression
573        | logical_OR_expression OROR logical_AND_expression
574                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
575        ;
576
577conditional_expression:
578        logical_OR_expression
579        | logical_OR_expression '?' comma_expression ':' conditional_expression
580                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
581                // FIX ME: this hack computes $1 twice
582        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
583                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
584        | logical_OR_expression '?' comma_expression ':' tuple // CFA, tuple expression
585                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
586        ;
587
588constant_expression:
589        conditional_expression
590        ;
591
592assignment_expression:
593                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
594        conditional_expression
595        | unary_expression assignment_operator assignment_expression
596                { $$ = new ExpressionNode( build_binary_ptr( $2, $1, $3 ) ); }
597        | tuple assignment_opt                                                          // CFA, tuple expression
598                { $$ = ( $2 == 0 ) ? $1 : new ExpressionNode( build_binary_ptr( OperKinds::Assign, $1, $2 ) ); }
599        ;
600
601assignment_expression_opt:
602        // empty
603                { $$ = nullptr; }
604        | assignment_expression
605        ;
606
607assignment_operator:
608        '='                                                                                     { $$ = OperKinds::Assign; }
609        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
610        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
611        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
612        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
613        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
614        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
615        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
616        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
617        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
618        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
619        ;
620
621tuple:                                                                                                  // CFA, tuple
622                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
623                // comma_expression in new_identifier_parameter_array and new_abstract_array
624        '[' ']'
625                { $$ = new ExpressionNode( build_tuple() ); }
626        | '[' push assignment_expression pop ']'
627                { $$ = new ExpressionNode( build_tuple( $3 ) ); }
628        | '[' push ',' tuple_expression_list pop ']'
629                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $4 ) ) ); }
630        | '[' push assignment_expression ',' tuple_expression_list pop ']'
631                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $5 ) ) ); }
632        ;
633
634tuple_expression_list:
635        assignment_expression_opt
636        | tuple_expression_list ',' assignment_expression_opt
637                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
638        ;
639
640comma_expression:
641        assignment_expression
642        | comma_expression ',' assignment_expression
643                { $$ = new ExpressionNode( build_comma( $1, $3 ) ); }
644        ;
645
646comma_expression_opt:
647        // empty
648                { $$ = 0; }
649        | comma_expression
650        ;
651
652//*************************** STATEMENTS *******************************
653
654statement:
655        labeled_statement
656        | compound_statement
657        | expression_statement                                          { $$ = $1; }
658        | selection_statement
659        | iteration_statement
660        | jump_statement
661        | exception_statement
662        | asm_statement
663        | '^' postfix_expression '{' argument_expression_list '}' ';' // CFA
664                {
665                        Token fn;
666                        fn.str = new std::string( "^?{}" ); // location undefined
667                        $$ = new StatementNode2( build_expr( new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) ) ) );
668                }
669        ;
670
671labeled_statement:
672                // labels cannot be identifiers 0 or 1
673        IDENTIFIER ':' attribute_list_opt statement
674                {
675                        $$ = $4->add_label( $1 );
676                }
677        ;
678
679compound_statement:
680        '{' '}'
681                { $$ = new CompoundStmtNode( (StatementNode *)0 ); }
682        | '{'
683                // Two scopes are necessary because the block itself has a scope, but every declaration within the block also
684                // requires its own scope
685          push push
686          local_label_declaration_opt                                           // GCC, local labels
687          block_item_list pop '}'                                                       // C99, intermix declarations and statements
688                { $$ = new CompoundStmtNode( $5 ); }
689        ;
690
691block_item_list:                                                                                // C99
692        block_item
693        | block_item_list push block_item
694                { if ( $1 != 0 ) { $1->set_last( $3 ); $$ = $1; } }
695        ;
696
697block_item:
698        declaration                                                                                     // CFA, new & old style declarations
699                { $$ = new StatementNode2( $1 ); }
700        | EXTENSION declaration                                                         // GCC
701                {       // mark all fields in list
702                        for ( DeclarationNode *iter = $2; iter != NULL; iter = (DeclarationNode *)iter->get_next() )
703                                iter->set_extension( true );
704                        $$ = new StatementNode2( $2 );
705                }
706        | function_definition
707                { $$ = new StatementNode2( $1 ); }
708        | statement pop
709        ;
710
711statement_list:
712        statement
713        | statement_list statement
714                { if ( $1 != 0 ) { $1->set_last( $2 ); $$ = $1; } }
715        ;
716
717expression_statement:
718        comma_expression_opt ';'
719                { $$ = new StatementNode2( build_expr( $1 ) ); }
720        ;
721
722selection_statement:
723        IF '(' comma_expression ')' statement                           %prec THEN
724                // explicitly deal with the shift/reduce conflict on if/else
725                { $$ = new StatementNode2( build_if( $3, $5, nullptr ) ); }
726        | IF '(' comma_expression ')' statement ELSE statement
727                { $$ = new StatementNode2( build_if( $3, $5, $7 ) ); }
728        | SWITCH '(' comma_expression ')' case_clause           // CFA
729                { $$ = new StatementNode2( build_switch( $3, $5 ) ); }
730        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt '}' // CFA
731                {
732                        StatementNode *sw = new StatementNode2( build_switch( $3, $8 ) );
733                        // The semantics of the declaration list is changed to include associated initialization, which is performed
734                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
735                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
736                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
737                        // statement.
738                        $$ = $7 != 0 ? new CompoundStmtNode( (StatementNode *)((new StatementNode2( $7 ))->set_last( sw )) ) : sw;
739                }
740        | CHOOSE '(' comma_expression ')' case_clause           // CFA
741                { $$ = new StatementNode2( build_switch( $3, $5 ) ); }
742        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt choose_clause_list_opt '}' // CFA
743                {
744                        StatementNode *sw = new StatementNode2( build_switch( $3, $8 ) );
745                        $$ = $7 != 0 ? new CompoundStmtNode( (StatementNode *)((new StatementNode2( $7 ))->set_last( sw )) ) : sw;
746                }
747        ;
748
749// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
750// clause allows a list of values and subranges.
751
752case_value:                                                                                             // CFA
753        constant_expression                                                     { $$ = $1; }
754        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
755                { $$ = new ExpressionNode( build_range( $1, $3 ) ); }
756        | subrange                                                                                      // CFA, subrange
757        ;
758
759case_value_list:                                                                                // CFA
760        case_value                                                                      { $$ = new StatementNode2( build_case( $1 ) ); }
761                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
762        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode2( build_case( $3 ) ) ) ); }
763        ;
764
765case_label:                                                                                             // CFA
766        CASE case_value_list ':'                                        { $$ = $2; }
767        | DEFAULT ':'                                                           { $$ = new StatementNode2( build_default() ); }
768                // A semantic check is required to ensure only one default clause per switch/choose statement.
769        ;
770
771case_label_list:                                                                                // CFA
772        case_label
773        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
774        ;
775
776case_clause:                                                                                    // CFA
777        case_label_list statement                                       { $$ = $1->append_last_case( new CompoundStmtNode( $2 ) ); }
778        ;
779
780switch_clause_list_opt:                                                                 // CFA
781        // empty
782                { $$ = 0; }
783        | switch_clause_list
784        ;
785
786switch_clause_list:                                                                             // CFA
787        case_label_list statement_list
788                { $$ = $1->append_last_case( new CompoundStmtNode( $2 ) ); }
789        | switch_clause_list case_label_list statement_list
790                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new CompoundStmtNode( $3 ) ) ) ); }
791        ;
792
793choose_clause_list_opt:                                                                 // CFA
794        // empty
795                { $$ = 0; }
796        | choose_clause_list
797        ;
798
799choose_clause_list:                                                                             // CFA
800        case_label_list fall_through
801                { $$ = $1->append_last_case( $2 ); }
802        | case_label_list statement_list fall_through_opt
803                { $$ = $1->append_last_case( new CompoundStmtNode( (StatementNode *)mkList( (*$2, *$3 ) ) ) ); }
804        | choose_clause_list case_label_list fall_through
805                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( $3 ))); }
806        | choose_clause_list case_label_list statement_list fall_through_opt
807                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new CompoundStmtNode( (StatementNode *)mkList( (*$3, *$4 ) ) ) ) ) ); }
808        ;
809
810fall_through_opt:                                                                               // CFA
811        // empty
812                { $$ = new StatementNode2( build_branch( "", BranchStmt::Break ) ); } // insert implicit break
813        | fall_through
814        ;
815
816fall_through:                                                                                   // CFA
817        FALLTHRU
818                { $$ = 0; }
819        | FALLTHRU ';'
820                { $$ = 0; }
821        ;
822
823iteration_statement:
824        WHILE '(' comma_expression ')' statement
825                { $$ = new StatementNode2( build_while( $3, $5 ) ); }
826        | DO statement WHILE '(' comma_expression ')' ';'
827                { $$ = new StatementNode2( build_while( $5, $2 ) ); }
828        | FOR '(' push for_control_expression ')' statement
829                { $$ = new StatementNode2( build_for( $4, $6 ) ); }
830        ;
831
832for_control_expression:
833        comma_expression_opt pop ';' comma_expression_opt ';' comma_expression_opt
834                { $$ = new ForCtl( $1, $4, $6 ); }
835        | declaration comma_expression_opt ';' comma_expression_opt // C99
836                { $$ = new ForCtl( $1, $2, $4 ); }
837        ;
838
839jump_statement:
840        GOTO IDENTIFIER ';'
841                { $$ = new StatementNode2( build_branch( *$2, BranchStmt::Goto ) ); }
842        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
843                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
844                // whereas normal operator precedence yields goto (*i)+3;
845                { $$ = new StatementNode2( build_computedgoto( $3 ) ); }
846        | CONTINUE ';'
847                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
848                { $$ = new StatementNode2( build_branch( "", BranchStmt::Continue ) ); }
849        | CONTINUE IDENTIFIER ';'                                                       // CFA, multi-level continue
850                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
851                // the target of the transfer appears only at the start of an iteration statement.
852                { $$ = new StatementNode2( build_branch( *$2, BranchStmt::Continue ) ); delete $2; }
853        | BREAK ';'
854                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
855                { $$ = new StatementNode2( build_branch( "", BranchStmt::Break ) ); }
856        | BREAK IDENTIFIER ';'                                                          // CFA, multi-level exit
857                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
858                // the target of the transfer appears only at the start of an iteration statement.
859                { $$ = new StatementNode2( build_branch( *$2, BranchStmt::Break ) ); delete $2; }
860        | RETURN comma_expression_opt ';'
861                { $$ = new StatementNode2( build_return( $2 ) ); }
862        | THROW assignment_expression_opt ';'                           // handles rethrow
863                { $$ = new StatementNode2( build_throw( $2 ) ); }
864        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
865                { $$ = new StatementNode2( build_throw( $2 ) ); }
866        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
867                { $$ = new StatementNode2( build_throw( $2 ) ); }
868        ;
869
870exception_statement:
871        TRY compound_statement handler_list
872                { $$ = new StatementNode2( build_try( $2, $3, 0 ) ); }
873        | TRY compound_statement finally_clause
874                { $$ = new StatementNode2( build_try( $2, 0, $3 ) ); }
875        | TRY compound_statement handler_list finally_clause
876                { $$ = new StatementNode2( build_try( $2, $3, $4 ) ); }
877        ;
878
879handler_list:
880        handler_clause
881                // ISO/IEC 9899:1999 Section 15.3(6 ) If present, a "..." handler shall be the last handler for its try block.
882        | CATCH '(' ELLIPSIS ')' compound_statement
883                { $$ = new StatementNode2( build_catch( 0, $5, true ) ); }
884        | handler_clause CATCH '(' ELLIPSIS ')' compound_statement
885                { $$ = (StatementNode *)$1->set_last( new StatementNode2( build_catch( 0, $6, true ) ) ); }
886        | CATCHRESUME '(' ELLIPSIS ')' compound_statement
887                { $$ = new StatementNode2( build_catch( 0, $5, true ) ); }
888        | handler_clause CATCHRESUME '(' ELLIPSIS ')' compound_statement
889                { $$ = (StatementNode *)$1->set_last( new StatementNode2( build_catch( 0, $6, true ) ) ); }
890        ;
891
892handler_clause:
893        CATCH '(' push push exception_declaration pop ')' compound_statement pop
894                { $$ = new StatementNode2( build_catch( $5, $8 ) ); }
895        | handler_clause CATCH '(' push push exception_declaration pop ')' compound_statement pop
896        { $$ = (StatementNode *)$1->set_last( new StatementNode2( build_catch( $6, $9 ) ) ); }
897        | CATCHRESUME '(' push push exception_declaration pop ')' compound_statement pop
898                { $$ = new StatementNode2( build_catch( $5, $8 ) ); }
899        | handler_clause CATCHRESUME '(' push push exception_declaration pop ')' compound_statement pop
900                { $$ = (StatementNode *)$1->set_last( new StatementNode2( build_catch( $6, $9 ) ) ); }
901        ;
902
903finally_clause:
904        FINALLY compound_statement
905                {
906                        $$ = new StatementNode2( build_finally( $2 ) );
907                }
908        ;
909
910exception_declaration:
911                // A semantic check is required to ensure type_specifier does not create a new type, e.g.:
912                //
913                //              catch ( struct { int i; } x ) ...
914                //
915                // This new type cannot catch any thrown type because of name equivalence among types.
916        type_specifier
917        | type_specifier declarator
918                {
919                        typedefTable.addToEnclosingScope( TypedefTable::ID );
920                        $$ = $2->addType( $1 );
921                }
922        | type_specifier variable_abstract_declarator
923                { $$ = $2->addType( $1 ); }
924        | new_abstract_declarator_tuple no_attr_identifier      // CFA
925                {
926                        typedefTable.addToEnclosingScope( TypedefTable::ID );
927                        $$ = $1->addName( $2 );
928                }
929        | new_abstract_declarator_tuple                                         // CFA
930        ;
931
932asm_statement:
933        ASM asm_volatile_opt '(' string_literal_list ')' ';'
934                { $$ = new AsmStmtNode( StatementNode::Asm, $2, $4, 0 ); }
935        | ASM asm_volatile_opt '(' string_literal_list ':' asm_operands_opt ')' ';' // remaining GCC
936                { $$ = new AsmStmtNode( StatementNode::Asm, $2, $4, $6 ); }
937        | ASM asm_volatile_opt '(' string_literal_list ':' asm_operands_opt ':' asm_operands_opt ')' ';'
938                { $$ = new AsmStmtNode( StatementNode::Asm, $2, $4, $6, $8 ); }
939        | ASM asm_volatile_opt '(' string_literal_list ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
940                { $$ = new AsmStmtNode( StatementNode::Asm, $2, $4, $6, $8, $10 ); }
941        | ASM asm_volatile_opt GOTO '(' string_literal_list ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
942                { $$ = new AsmStmtNode( StatementNode::Asm, $2, $5, 0, $8, $10, $12 ); }
943        ;
944
945asm_volatile_opt:                                                                               // GCC
946        // empty
947                { $$ = false; }
948        | VOLATILE
949                { $$ = true; }
950        ;
951
952asm_operands_opt:                                                                               // GCC
953        // empty
954                { $$ = 0; }                                                                             // use default argument
955        | asm_operands_list
956        ;
957
958asm_operands_list:                                                                              // GCC
959        asm_operand
960        | asm_operands_list ',' asm_operand
961                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
962        ;
963
964asm_operand:                                                                                    // GCC
965        string_literal_list '(' constant_expression ')'
966                { $$ = new ExpressionNode( build_asm( 0, $1, $3 ) ); }
967        | '[' constant_expression ']' string_literal_list '(' constant_expression ')'
968        { $$ = new ExpressionNode( build_asm( $2, $4, $6 ) ); }
969        ;
970
971asm_clobbers_list_opt:                                                                  // GCC
972        // empty
973                { $$ = 0; }                                                                             // use default argument
974        | string_literal_list
975                { $$ = new ExpressionNode( $1 ); }
976        | asm_clobbers_list_opt ',' string_literal_list
977        { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
978        ;
979
980label_list:
981        no_attr_identifier
982                { $$ = new LabelNode(); $$->append_label( $1 ); }
983        | label_list ',' no_attr_identifier
984                { $$ = $1; $1->append_label( $3 ); }
985        ;
986
987//******************************* DECLARATIONS *********************************
988
989declaration_list_opt:                                                                   // used at beginning of switch statement
990        pop
991                { $$ = 0; }
992        | declaration_list
993        ;
994
995declaration_list:
996        declaration
997        | declaration_list push declaration
998                { $$ = $1->appendList( $3 ); }
999        ;
1000
1001old_declaration_list_opt:                                                               // used to declare parameter types in K&R style functions
1002        pop
1003                { $$ = 0; }
1004        | old_declaration_list
1005        ;
1006
1007old_declaration_list:
1008        old_declaration
1009        | old_declaration_list push old_declaration
1010                { $$ = $1->appendList( $3 ); }
1011        ;
1012
1013local_label_declaration_opt:                                                    // GCC, local label
1014        // empty
1015        | local_label_declaration_list
1016        ;
1017
1018local_label_declaration_list:                                                   // GCC, local label
1019        LABEL local_label_list ';'
1020        | local_label_declaration_list LABEL local_label_list ';'
1021        ;
1022
1023local_label_list:                                                                               // GCC, local label
1024        no_attr_identifier_or_type_name                         {}
1025        | local_label_list ',' no_attr_identifier_or_type_name {}
1026        ;
1027
1028declaration:                                                                                    // CFA, new & old style declarations
1029        new_declaration
1030        | old_declaration
1031        ;
1032
1033// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1034// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1035// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1036// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1037// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1038// block, but cannot be mixed within a specific declaration.
1039//
1040//                      CFA                                     C
1041//              [10] int x;                     int x[10];              // array of 10 integers
1042//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1043
1044new_declaration:                                                                                // CFA
1045        new_variable_declaration pop ';'
1046        | new_typedef_declaration pop ';'
1047        | new_function_declaration pop ';'
1048        | type_declaring_list pop ';'
1049        | trait_specifier pop ';'
1050        ;
1051
1052new_variable_declaration:                                                               // CFA
1053        new_variable_specifier initializer_opt
1054                {
1055                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1056                        $$ = $1->addInitializer( $2 );
1057                }
1058        | declaration_qualifier_list new_variable_specifier initializer_opt
1059                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1060                // them as a type_qualifier cannot appear in that context.
1061                {
1062                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1063                        $$ = $2->addQualifiers( $1 )->addInitializer( $3 );;
1064                }
1065        | new_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1066                {
1067                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1068                        $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) );
1069                }
1070        ;
1071
1072new_variable_specifier:                                                                 // CFA
1073                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1074                // storage-class
1075        new_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1076                {
1077                        typedefTable.setNextIdentifier( *$2 );
1078                        $$ = $1->addName( $2 );
1079                }
1080        | new_abstract_tuple identifier_or_type_name asm_name_opt
1081                {
1082                        typedefTable.setNextIdentifier( *$2 );
1083                        $$ = $1->addName( $2 );
1084                }
1085        | type_qualifier_list new_abstract_tuple identifier_or_type_name asm_name_opt
1086                {
1087                        typedefTable.setNextIdentifier( *$3 );
1088                        $$ = $2->addQualifiers( $1 )->addName( $3 );
1089                }
1090        ;
1091
1092new_function_declaration:                                                               // CFA
1093        new_function_specifier
1094                {
1095                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1096                        $$ = $1;
1097                }
1098        | type_qualifier_list new_function_specifier
1099                {
1100                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1101                        $$ = $2->addQualifiers( $1 );
1102                }
1103        | declaration_qualifier_list new_function_specifier
1104                {
1105                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1106                        $$ = $2->addQualifiers( $1 );
1107                }
1108        | declaration_qualifier_list type_qualifier_list new_function_specifier
1109                {
1110                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1111                        $$ = $3->addQualifiers( $1 )->addQualifiers( $2 );
1112                }
1113        | new_function_declaration pop ',' push identifier_or_type_name
1114                {
1115                        typedefTable.addToEnclosingScope( *$5, TypedefTable::ID );
1116                        $$ = $1->appendList( $1->cloneType( $5 ) );
1117                }
1118        ;
1119
1120new_function_specifier:                                                                 // CFA
1121        '[' ']' identifier_or_type_name '(' push new_parameter_type_list_opt pop ')' // S/R conflict
1122                {
1123                        $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1124                }
1125//      '[' ']' identifier '(' push new_parameter_type_list_opt pop ')'
1126//              {
1127//                      typedefTable.setNextIdentifier( *$5 );
1128//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1129//              }
1130//      | '[' ']' TYPEDEFname '(' push new_parameter_type_list_opt pop ')'
1131//              {
1132//                      typedefTable.setNextIdentifier( *$5 );
1133//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1134//              }
1135//      | '[' ']' typegen_name
1136                // identifier_or_type_name must be broken apart because of the sequence:
1137                //
1138                //   '[' ']' identifier_or_type_name '(' new_parameter_type_list_opt ')'
1139                //   '[' ']' type_specifier
1140                //
1141                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1142                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1143        | new_abstract_tuple identifier_or_type_name '(' push new_parameter_type_list_opt pop ')'
1144                // To obtain LR(1 ), this rule must be factored out from function return type (see new_abstract_declarator).
1145                {
1146                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1147                }
1148        | new_function_return identifier_or_type_name '(' push new_parameter_type_list_opt pop ')'
1149                {
1150                        $$ = DeclarationNode::newFunction( $2, $1, $5, 0, true );
1151                }
1152        ;
1153
1154new_function_return:                                                                    // CFA
1155        '[' push new_parameter_list pop ']'
1156                { $$ = DeclarationNode::newTuple( $3 ); }
1157        | '[' push new_parameter_list pop ',' push new_abstract_parameter_list pop ']'
1158                // To obtain LR(1 ), the last new_abstract_parameter_list is added into this flattened rule to lookahead to the
1159                // ']'.
1160                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1161        ;
1162
1163new_typedef_declaration:                                                                // CFA
1164        TYPEDEF new_variable_specifier
1165                {
1166                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1167                        $$ = $2->addTypedef();
1168                }
1169        | TYPEDEF new_function_specifier
1170                {
1171                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1172                        $$ = $2->addTypedef();
1173                }
1174        | new_typedef_declaration pop ',' push no_attr_identifier
1175                {
1176                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1177                        $$ = $1->appendList( $1->cloneType( $5 ) );
1178                }
1179        ;
1180
1181// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1182// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1183
1184typedef_declaration:
1185        TYPEDEF type_specifier declarator
1186                {
1187                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1188                        $$ = $3->addType( $2 )->addTypedef();
1189                }
1190        | typedef_declaration pop ',' push declarator
1191                {
1192                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1193                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1194                }
1195        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1196                {
1197                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1198                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1199                }
1200        | type_specifier TYPEDEF declarator
1201                {
1202                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1203                        $$ = $3->addType( $1 )->addTypedef();
1204                }
1205        | type_specifier TYPEDEF type_qualifier_list declarator
1206                {
1207                        typedefTable.addToEnclosingScope( TypedefTable::TD );
1208                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1209                }
1210        ;
1211
1212typedef_expression:
1213                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1214        TYPEDEF no_attr_identifier '=' assignment_expression
1215                {
1216                        typedefTable.addToEnclosingScope( *$2, TypedefTable::TD );
1217                        $$ = DeclarationNode::newName( 0 ); // XXX
1218                }
1219        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1220                {
1221                        typedefTable.addToEnclosingScope( *$5, TypedefTable::TD );
1222                        $$ = DeclarationNode::newName( 0 ); // XXX
1223                }
1224        ;
1225
1226old_declaration:
1227        declaring_list pop ';'
1228        | typedef_declaration pop ';'
1229        | typedef_expression pop ';'                                            // GCC, naming expression type
1230        | sue_declaration_specifier pop ';'
1231        ;
1232
1233declaring_list:
1234                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1235                // storage-class
1236        declaration_specifier declarator asm_name_opt initializer_opt
1237                {
1238                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1239                        $$ = ( $2->addType( $1 ))->addInitializer( $4 );
1240                }
1241        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1242                {
1243                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1244                        $$ = $1->appendList( $1->cloneBaseType( $4->addInitializer( $6 ) ) );
1245                }
1246        ;
1247
1248declaration_specifier:                                                                  // type specifier + storage class
1249        basic_declaration_specifier
1250        | sue_declaration_specifier
1251        | typedef_declaration_specifier
1252        | typegen_declaration_specifier
1253        ;
1254
1255type_specifier:                                                                                 // declaration specifier - storage class
1256        basic_type_specifier
1257        | sue_type_specifier
1258        | typedef_type_specifier
1259        | typegen_type_specifier
1260        ;
1261
1262type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1263        // empty
1264                { $$ = 0; }
1265        | type_qualifier_list
1266        ;
1267
1268type_qualifier_list:
1269                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1270                //
1271                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1272                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1273                // appeared only once.
1274        type_qualifier
1275        | type_qualifier_list type_qualifier
1276                { $$ = $1->addQualifiers( $2 ); }
1277        ;
1278
1279type_qualifier:
1280        type_qualifier_name
1281        | attribute
1282        //{ $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
1283        ;
1284
1285type_qualifier_name:
1286        CONST
1287                { $$ = DeclarationNode::newQualifier( DeclarationNode::Const ); }
1288        | RESTRICT
1289                { $$ = DeclarationNode::newQualifier( DeclarationNode::Restrict ); }
1290        | VOLATILE
1291                { $$ = DeclarationNode::newQualifier( DeclarationNode::Volatile ); }
1292        | LVALUE                                                                                        // CFA
1293                { $$ = DeclarationNode::newQualifier( DeclarationNode::Lvalue ); }
1294        | ATOMIC
1295                { $$ = DeclarationNode::newQualifier( DeclarationNode::Atomic ); }
1296        | FORALL '('
1297                {
1298                        typedefTable.enterScope();
1299                }
1300          type_parameter_list ')'                                                       // CFA
1301                {
1302                        typedefTable.leaveScope();
1303                        $$ = DeclarationNode::newForall( $4 );
1304                }
1305        ;
1306
1307declaration_qualifier_list:
1308        storage_class_list
1309        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1310                { $$ = $1->addQualifiers( $2 ); }
1311        | declaration_qualifier_list type_qualifier_list storage_class_list
1312                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1313        ;
1314
1315storage_class_list:
1316                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1317                // only one of each is specified, except for inline, which can appear with the others.
1318                //
1319                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1320                // specifiers in a declaration.
1321        storage_class
1322        | storage_class_list storage_class
1323                { $$ = $1->addQualifiers( $2 ); }
1324        ;
1325
1326storage_class:
1327        storage_class_name
1328        ;
1329
1330storage_class_name:
1331        EXTERN
1332                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Extern ); }
1333        | STATIC
1334                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Static ); }
1335        | AUTO
1336                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Auto ); }
1337        | REGISTER
1338                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Register ); }
1339        | INLINE                                                                                        // C99
1340                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Inline ); }
1341        | FORTRAN                                                                                       // C99
1342                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Fortran ); }
1343        | NORETURN                                                                                      // C11
1344                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Noreturn ); }
1345        | THREADLOCAL                                                                           // C11
1346                { $$ = DeclarationNode::newStorageClass( DeclarationNode::Threadlocal ); }
1347        ;
1348
1349basic_type_name:
1350        CHAR
1351                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1352        | DOUBLE
1353                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1354        | FLOAT
1355                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1356        | INT
1357                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1358        | LONG
1359                { $$ = DeclarationNode::newModifier( DeclarationNode::Long ); }
1360        | SHORT
1361                { $$ = DeclarationNode::newModifier( DeclarationNode::Short ); }
1362        | SIGNED
1363                { $$ = DeclarationNode::newModifier( DeclarationNode::Signed ); }
1364        | UNSIGNED
1365                { $$ = DeclarationNode::newModifier( DeclarationNode::Unsigned ); }
1366        | VOID
1367                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1368        | BOOL                                                                                          // C99
1369                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1370        | COMPLEX                                                                                       // C99
1371                { $$ = DeclarationNode::newBasicType( DeclarationNode::Complex ); }
1372        | IMAGINARY                                                                                     // C99
1373                { $$ = DeclarationNode::newBasicType( DeclarationNode::Imaginary ); }
1374        | VALIST                                                                                        // GCC, __builtin_va_list
1375                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1376        ;
1377
1378basic_declaration_specifier:
1379                // A semantic check is necessary for conflicting storage classes.
1380        basic_type_specifier
1381        | declaration_qualifier_list basic_type_specifier
1382                { $$ = $2->addQualifiers( $1 ); }
1383        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1384                { $$ = $1->addQualifiers( $2 ); }
1385        | basic_declaration_specifier storage_class type_qualifier_list
1386                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1387        | basic_declaration_specifier storage_class basic_type_specifier
1388                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1389        ;
1390
1391basic_type_specifier:
1392        direct_type_name
1393        | type_qualifier_list_opt indirect_type_name type_qualifier_list_opt
1394                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1395        ;
1396
1397direct_type_name:
1398                // A semantic check is necessary for conflicting type qualifiers.
1399        basic_type_name
1400        | type_qualifier_list basic_type_name
1401                { $$ = $2->addQualifiers( $1 ); }
1402        | direct_type_name type_qualifier
1403                { $$ = $1->addQualifiers( $2 ); }
1404        | direct_type_name basic_type_name
1405                { $$ = $1->addType( $2 ); }
1406        ;
1407
1408indirect_type_name:
1409        TYPEOF '(' type_name ')'                                                        // GCC: typeof(x) y;
1410                { $$ = $3; }
1411        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof(a+b) y;
1412                { $$ = DeclarationNode::newTypeof( $3 ); }
1413        | ATTR_TYPEGENname '(' type_name ')'                            // CFA: e.g., @type(x) y;
1414                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1415        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type(a+b) y;
1416                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1417        ;
1418
1419sue_declaration_specifier:
1420        sue_type_specifier
1421        | declaration_qualifier_list sue_type_specifier
1422                { $$ = $2->addQualifiers( $1 ); }
1423        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1424                { $$ = $1->addQualifiers( $2 ); }
1425        | sue_declaration_specifier storage_class type_qualifier_list
1426                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1427        ;
1428
1429sue_type_specifier:
1430        elaborated_type_name                                                            // struct, union, enum
1431        | type_qualifier_list elaborated_type_name
1432                { $$ = $2->addQualifiers( $1 ); }
1433        | sue_type_specifier type_qualifier
1434                { $$ = $1->addQualifiers( $2 ); }
1435        ;
1436
1437typedef_declaration_specifier:
1438        typedef_type_specifier
1439        | declaration_qualifier_list typedef_type_specifier
1440                { $$ = $2->addQualifiers( $1 ); }
1441        | typedef_declaration_specifier storage_class           // remaining OBSOLESCENT (see 2)
1442                { $$ = $1->addQualifiers( $2 ); }
1443        | typedef_declaration_specifier storage_class type_qualifier_list
1444                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1445        ;
1446
1447typedef_type_specifier:                                                                 // typedef types
1448        TYPEDEFname
1449                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1450        | type_qualifier_list TYPEDEFname
1451                { $$ = DeclarationNode::newFromTypedef( $2 )->addQualifiers( $1 ); }
1452        | typedef_type_specifier type_qualifier
1453                { $$ = $1->addQualifiers( $2 ); }
1454        ;
1455
1456elaborated_type_name:
1457        aggregate_name
1458        | enum_name
1459        ;
1460
1461aggregate_name:
1462        aggregate_key '{' field_declaration_list '}'
1463                { $$ = DeclarationNode::newAggregate( $1, 0, 0, $3, true ); }
1464        | aggregate_key no_attr_identifier_or_type_name
1465                {
1466                        typedefTable.makeTypedef( *$2 );
1467                        $$ = DeclarationNode::newAggregate( $1, $2, 0, 0, false );
1468                }
1469        | aggregate_key no_attr_identifier_or_type_name
1470                { typedefTable.makeTypedef( *$2 ); }
1471                '{' field_declaration_list '}'
1472                { $$ = DeclarationNode::newAggregate( $1, $2, 0, $5, true ); }
1473        | aggregate_key '(' type_name_list ')' '{' field_declaration_list '}' // CFA
1474                { $$ = DeclarationNode::newAggregate( $1, 0, $3, $6, false ); }
1475        | aggregate_key typegen_name                                            // CFA, S/R conflict
1476                { $$ = $2; }
1477        ;
1478
1479aggregate_key:
1480        STRUCT attribute_list_opt
1481                { $$ = DeclarationNode::Struct; }
1482        | UNION attribute_list_opt
1483                { $$ = DeclarationNode::Union; }
1484        ;
1485
1486field_declaration_list:
1487        // empty
1488                { $$ = 0; }
1489        | field_declaration_list field_declaration
1490                { $$ = $1 != 0 ? $1->appendList( $2 ) : $2; }
1491        ;
1492
1493field_declaration:
1494        new_field_declaring_list ';'                                            // CFA, new style field declaration
1495        | EXTENSION new_field_declaring_list ';'                        // GCC
1496                { $$ = $2->set_extension( true ); }
1497        | field_declaring_list ';'
1498        | EXTENSION field_declaring_list ';'                            // GCC
1499                {       // mark all fields in list
1500                        for ( DeclarationNode *iter = $2; iter != NULL; iter = (DeclarationNode *)iter->get_next() )
1501                                iter->set_extension( true );
1502                        $$ = $2;
1503                }
1504        ;
1505
1506new_field_declaring_list:                                                               // CFA, new style field declaration
1507        new_abstract_declarator_tuple                                           // CFA, no field name
1508        | new_abstract_declarator_tuple no_attr_identifier_or_type_name
1509                { $$ = $1->addName( $2 ); }
1510        | new_field_declaring_list ',' no_attr_identifier_or_type_name
1511                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
1512        | new_field_declaring_list ','                                          // CFA, no field name
1513                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
1514        ;
1515
1516field_declaring_list:
1517        type_specifier field_declarator
1518                { $$ = $2->addType( $1 ); }
1519        | field_declaring_list ',' attribute_list_opt field_declarator
1520                { $$ = $1->appendList( $1->cloneBaseType( $4 ) ); }
1521        ;
1522
1523field_declarator:
1524        // empty
1525                { $$ = DeclarationNode::newName( 0 ); /* XXX */ } // CFA, no field name
1526        | bit_subrange_size                                                                     // no field name
1527                { $$ = DeclarationNode::newBitfield( $1 ); }
1528        | variable_declarator bit_subrange_size_opt
1529                // A semantic check is required to ensure bit_subrange only appears on base type int.
1530                { $$ = $1->addBitfield( $2 ); }
1531        | variable_type_redeclarator bit_subrange_size_opt
1532                // A semantic check is required to ensure bit_subrange only appears on base type int.
1533                { $$ = $1->addBitfield( $2 ); }
1534        | variable_abstract_declarator                                          // CFA, no field name
1535        ;
1536
1537bit_subrange_size_opt:
1538        // empty
1539                { $$ = 0; }
1540        | bit_subrange_size
1541                { $$ = $1; }
1542        ;
1543
1544bit_subrange_size:
1545        ':' constant_expression
1546                { $$ = $2; }
1547        ;
1548
1549enum_key:
1550        ENUM attribute_list_opt
1551        ;
1552
1553enum_name:
1554        enum_key '{' enumerator_list comma_opt '}'
1555                { $$ = DeclarationNode::newEnum( 0, $3 ); }
1556        | enum_key no_attr_identifier_or_type_name
1557                {
1558                        typedefTable.makeTypedef( *$2 );
1559                        $$ = DeclarationNode::newEnum( $2, 0 );
1560                }
1561        | enum_key no_attr_identifier_or_type_name
1562                { typedefTable.makeTypedef( *$2 ); }
1563                '{' enumerator_list comma_opt '}'
1564                { $$ = DeclarationNode::newEnum( $2, $5 ); }
1565        ;
1566
1567enumerator_list:
1568        no_attr_identifier_or_type_name enumerator_value_opt
1569                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
1570        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
1571                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
1572        ;
1573
1574enumerator_value_opt:
1575        // empty
1576                { $$ = 0; }
1577        | '=' constant_expression
1578                { $$ = $2; }
1579        ;
1580
1581// Minimum of one parameter after which ellipsis is allowed only at the end.
1582
1583new_parameter_type_list_opt:                                                    // CFA
1584        // empty
1585                { $$ = 0; }
1586        | new_parameter_type_list
1587        ;
1588
1589new_parameter_type_list:                                                                // CFA, abstract + real
1590        new_abstract_parameter_list
1591        | new_parameter_list
1592        | new_parameter_list pop ',' push new_abstract_parameter_list
1593                { $$ = $1->appendList( $5 ); }
1594        | new_abstract_parameter_list pop ',' push ELLIPSIS
1595                { $$ = $1->addVarArgs(); }
1596        | new_parameter_list pop ',' push ELLIPSIS
1597                { $$ = $1->addVarArgs(); }
1598        ;
1599
1600new_parameter_list:                                                                             // CFA
1601                // To obtain LR(1) between new_parameter_list and new_abstract_tuple, the last new_abstract_parameter_list is
1602                // factored out from new_parameter_list, flattening the rules to get lookahead to the ']'.
1603        new_parameter_declaration
1604        | new_abstract_parameter_list pop ',' push new_parameter_declaration
1605                { $$ = $1->appendList( $5 ); }
1606        | new_parameter_list pop ',' push new_parameter_declaration
1607                { $$ = $1->appendList( $5 ); }
1608        | new_parameter_list pop ',' push new_abstract_parameter_list pop ',' push new_parameter_declaration
1609                { $$ = $1->appendList( $5 )->appendList( $9 ); }
1610        ;
1611
1612new_abstract_parameter_list:                                                    // CFA, new & old style abstract
1613        new_abstract_parameter_declaration
1614        | new_abstract_parameter_list pop ',' push new_abstract_parameter_declaration
1615                { $$ = $1->appendList( $5 ); }
1616        ;
1617
1618parameter_type_list_opt:
1619        // empty
1620                { $$ = 0; }
1621        | parameter_type_list
1622        ;
1623
1624parameter_type_list:
1625        parameter_list
1626        | parameter_list pop ',' push ELLIPSIS
1627                { $$ = $1->addVarArgs(); }
1628        ;
1629
1630parameter_list:                                                                                 // abstract + real
1631        abstract_parameter_declaration
1632        | parameter_declaration
1633        | parameter_list pop ',' push abstract_parameter_declaration
1634                { $$ = $1->appendList( $5 ); }
1635        | parameter_list pop ',' push parameter_declaration
1636                { $$ = $1->appendList( $5 ); }
1637        ;
1638
1639// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
1640// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
1641
1642new_parameter_declaration:                                                              // CFA, new & old style parameter declaration
1643        parameter_declaration
1644        | new_identifier_parameter_declarator_no_tuple identifier_or_type_name assignment_opt
1645                { $$ = $1->addName( $2 ); }
1646        | new_abstract_tuple identifier_or_type_name assignment_opt
1647                // To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1648                { $$ = $1->addName( $2 ); }
1649        | type_qualifier_list new_abstract_tuple identifier_or_type_name assignment_opt
1650                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
1651        | new_function_specifier
1652        ;
1653
1654new_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
1655        abstract_parameter_declaration
1656        | new_identifier_parameter_declarator_no_tuple
1657        | new_abstract_tuple
1658                // To obtain LR(1), these rules must be duplicated here (see new_abstract_declarator).
1659        | type_qualifier_list new_abstract_tuple
1660                { $$ = $2->addQualifiers( $1 ); }
1661        | new_abstract_function
1662        ;
1663
1664parameter_declaration:
1665        declaration_specifier identifier_parameter_declarator assignment_opt
1666                {
1667                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1668                        $$ = $2->addType( $1 )->addInitializer( new InitializerNode( $3 ) );
1669                }
1670        | declaration_specifier type_parameter_redeclarator assignment_opt
1671                {
1672                        typedefTable.addToEnclosingScope( TypedefTable::ID );
1673                        $$ = $2->addType( $1 )->addInitializer( new InitializerNode( $3 ) );
1674                }
1675        ;
1676
1677abstract_parameter_declaration:
1678        declaration_specifier
1679        | declaration_specifier abstract_parameter_declarator
1680                { $$ = $2->addType( $1 ); }
1681        ;
1682
1683// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
1684// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
1685// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
1686
1687identifier_list:                                                                                // K&R-style parameter list => no types
1688        no_attr_identifier
1689                { $$ = DeclarationNode::newName( $1 ); }
1690        | identifier_list ',' no_attr_identifier
1691                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
1692        ;
1693
1694identifier_or_type_name:
1695        identifier
1696        | TYPEDEFname
1697        | TYPEGENname
1698        ;
1699
1700no_01_identifier_or_type_name:
1701        no_01_identifier
1702        | TYPEDEFname
1703        | TYPEGENname
1704        ;
1705
1706no_attr_identifier_or_type_name:
1707        no_attr_identifier
1708        | TYPEDEFname
1709        | TYPEGENname
1710        ;
1711
1712type_name_no_function:                                                                  // sizeof, alignof, cast (constructor)
1713        new_abstract_declarator_tuple                                           // CFA
1714        | type_specifier
1715        | type_specifier variable_abstract_declarator
1716                { $$ = $2->addType( $1 ); }
1717        ;
1718
1719type_name:                                                                                              // typeof, assertion
1720        new_abstract_declarator_tuple                                           // CFA
1721        | new_abstract_function                                                         // CFA
1722        | type_specifier
1723        | type_specifier abstract_declarator
1724                { $$ = $2->addType( $1 ); }
1725        ;
1726
1727initializer_opt:
1728        // empty
1729                { $$ = 0; }
1730        | '=' initializer
1731                { $$ = $2; }
1732        | ATassign initializer
1733                { $$ = $2->set_maybeConstructed( false ); }
1734        ;
1735
1736initializer:
1737        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
1738        | '{' initializer_list comma_opt '}'            { $$ = new InitializerNode( $2, true ); }
1739        ;
1740
1741initializer_list:
1742        // empty
1743                { $$ = 0; }
1744        | initializer
1745        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
1746        | initializer_list ',' initializer                      { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
1747        | initializer_list ',' designation initializer
1748                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
1749        ;
1750
1751// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
1752// '=' to separator the designator from the initializer value, as in:
1753//
1754//              int x[10] = { [1] = 3 };
1755//
1756// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
1757// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
1758// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
1759// shift/reduce conflicts
1760
1761designation:
1762        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
1763        | no_attr_identifier_or_type_name ':'                           // GCC, field name
1764                { $$ = new ExpressionNode( build_varref( $1 ) ); }
1765        ;
1766
1767designator_list:                                                                                // C99
1768        designator
1769        | designator_list designator
1770                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
1771        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
1772        ;
1773
1774designator:
1775        '.' no_attr_identifier_or_type_name                                     // C99, field name
1776                { $$ = new ExpressionNode( build_varref( $2 ) ); }
1777        | '[' push assignment_expression pop ']'                        // C99, single array element
1778                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
1779                { $$ = $3; }
1780        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
1781                { $$ = $3; }
1782        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
1783                { $$ = new ExpressionNode( build_range( $3, $5 ) ); }
1784        | '.' '[' push field_list pop ']'                                       // CFA, tuple field selector
1785                { $$ = $4; }
1786        ;
1787
1788// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
1789// rather than an object-oriented type system. This required four groups of extensions:
1790//
1791// Overloading: function, data, and operator identifiers may be overloaded.
1792//
1793// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
1794//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
1795//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
1796//
1797// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
1798//     site. A polymorphic function is not a template; it is a function, with an address and a type.
1799//
1800// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
1801//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
1802//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
1803//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
1804//     on type arguments of polymorphic functions.
1805
1806typegen_declaration_specifier:                                                  // CFA
1807        typegen_type_specifier
1808        | declaration_qualifier_list typegen_type_specifier
1809                { $$ = $2->addQualifiers( $1 ); }
1810        | typegen_declaration_specifier storage_class           // remaining OBSOLESCENT (see 2)
1811                { $$ = $1->addQualifiers( $2 ); }
1812        | typegen_declaration_specifier storage_class type_qualifier_list
1813                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1814        ;
1815
1816typegen_type_specifier:                                                                 // CFA
1817        typegen_name
1818        | type_qualifier_list typegen_name
1819                { $$ = $2->addQualifiers( $1 ); }
1820        | typegen_type_specifier type_qualifier
1821                { $$ = $1->addQualifiers( $2 ); }
1822        ;
1823
1824typegen_name:                                                                                   // CFA
1825        TYPEGENname '(' type_name_list ')'
1826                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1827        ;
1828
1829type_parameter_list:                                                                    // CFA
1830        type_parameter assignment_opt
1831        | type_parameter_list ',' type_parameter assignment_opt
1832                { $$ = $1->appendList( $3 ); }
1833        ;
1834
1835type_parameter:                                                                                 // CFA
1836        type_class no_attr_identifier_or_type_name
1837                { typedefTable.addToEnclosingScope( *$2, TypedefTable::TD ); }
1838          assertion_list_opt
1839                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addAssertions( $4 ); }
1840        | type_specifier identifier_parameter_declarator
1841        ;
1842
1843type_class:                                                                                             // CFA
1844        OTYPE
1845                { $$ = DeclarationNode::Type; }
1846        | DTYPE
1847                { $$ = DeclarationNode::Ftype; }
1848        | FTYPE
1849                { $$ = DeclarationNode::Dtype; }
1850        ;
1851
1852assertion_list_opt:                                                                             // CFA
1853        // empty
1854                { $$ = 0; }
1855        | assertion_list_opt assertion
1856                { $$ = $1 != 0 ? $1->appendList( $2 ) : $2; }
1857        ;
1858
1859assertion:                                                                                              // CFA
1860        '|' no_attr_identifier_or_type_name '(' type_name_list ')'
1861                {
1862                        typedefTable.openTrait( *$2 );
1863                        $$ = DeclarationNode::newTraitUse( $2, $4 );
1864                }
1865        | '|' '{' push trait_declaration_list '}'
1866                { $$ = $4; }
1867        | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list '}' '(' type_name_list ')'
1868                { $$ = 0; }
1869        ;
1870
1871type_name_list:                                                                                 // CFA
1872        type_name
1873                { $$ = new ExpressionNode( build_typevalue( $1 ) ); }
1874        | assignment_expression
1875        | type_name_list ',' type_name
1876                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( build_typevalue( $3 ) ) ) ); }
1877        | type_name_list ',' assignment_expression
1878                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
1879        ;
1880
1881type_declaring_list:                                                                    // CFA
1882        OTYPE type_declarator
1883                { $$ = $2; }
1884        | storage_class_list OTYPE type_declarator
1885                { $$ = $3->addQualifiers( $1 ); }
1886        | type_declaring_list ',' type_declarator
1887                { $$ = $1->appendList( $3->copyStorageClasses( $1 ) ); }
1888        ;
1889
1890type_declarator:                                                                                // CFA
1891        type_declarator_name assertion_list_opt
1892                { $$ = $1->addAssertions( $2 ); }
1893        | type_declarator_name assertion_list_opt '=' type_name
1894                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
1895        ;
1896
1897type_declarator_name:                                                                   // CFA
1898        no_attr_identifier_or_type_name
1899                {
1900                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TD );
1901                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
1902                }
1903        | no_01_identifier_or_type_name '(' push type_parameter_list pop ')'
1904                {
1905                        typedefTable.addToEnclosingScope( *$1, TypedefTable::TG );
1906                        $$ = DeclarationNode::newTypeDecl( $1, $4 );
1907                }
1908        ;
1909
1910trait_specifier:                                                                                // CFA
1911        TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{' '}'
1912                {
1913                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
1914                        $$ = DeclarationNode::newTrait( $2, $5, 0 );
1915                }
1916        | TRAIT no_attr_identifier_or_type_name '(' push type_parameter_list pop ')' '{'
1917                {
1918                        typedefTable.enterTrait( *$2 );
1919                        typedefTable.enterScope();
1920                }
1921          trait_declaration_list '}'
1922                {
1923                        typedefTable.leaveTrait();
1924                        typedefTable.addToEnclosingScope( *$2, TypedefTable::ID );
1925                        $$ = DeclarationNode::newTrait( $2, $5, $10 );
1926                }
1927        ;
1928
1929trait_declaration_list:                                                         // CFA
1930        trait_declaration
1931        | trait_declaration_list push trait_declaration
1932                { $$ = $1->appendList( $3 ); }
1933        ;
1934
1935trait_declaration:                                                                      // CFA
1936        new_trait_declaring_list pop ';'
1937        | trait_declaring_list pop ';'
1938        ;
1939
1940new_trait_declaring_list:                                                               // CFA
1941        new_variable_specifier
1942                {
1943                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
1944                        $$ = $1;
1945                }
1946        | new_function_specifier
1947                {
1948                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
1949                        $$ = $1;
1950                }
1951        | new_trait_declaring_list pop ',' push identifier_or_type_name
1952                {
1953                        typedefTable.addToEnclosingScope2( *$5, TypedefTable::ID );
1954                        $$ = $1->appendList( $1->cloneType( $5 ) );
1955                }
1956        ;
1957
1958trait_declaring_list:                                                                   // CFA
1959        type_specifier declarator
1960                {
1961                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
1962                        $$ = $2->addType( $1 );
1963                }
1964        | trait_declaring_list pop ',' push declarator
1965                {
1966                        typedefTable.addToEnclosingScope2( TypedefTable::ID );
1967                        $$ = $1->appendList( $1->cloneBaseType( $5 ) );
1968                }
1969        ;
1970
1971//***************************** EXTERNAL DEFINITIONS *****************************
1972
1973translation_unit:
1974        // empty
1975                {}                                                                                              // empty input file
1976        | external_definition_list
1977                {
1978                        if ( theTree ) {
1979                                theTree->appendList( $1 );
1980                        } else {
1981                                theTree = $1;
1982                        }
1983                }
1984        ;
1985
1986external_definition_list:
1987        external_definition
1988        | external_definition_list push external_definition
1989                { $$ = ( $1 != NULL ) ? $1->appendList( $3 ) : $3; }
1990        ;
1991
1992external_definition_list_opt:
1993        // empty
1994                { $$ = 0; }
1995        | external_definition_list
1996        ;
1997
1998external_definition:
1999        declaration
2000        | external_function_definition
2001        | asm_statement                                                                         // GCC, global assembler statement
2002                {}
2003        | EXTERN STRINGliteral
2004                {
2005                        linkageStack.push( linkage );
2006                        linkage = LinkageSpec::fromString( *$2 );
2007                }
2008          '{' external_definition_list_opt '}'                          // C++-style linkage specifier
2009                {
2010                        linkage = linkageStack.top();
2011                        linkageStack.pop();
2012                        $$ = $5;
2013                }
2014        | EXTENSION external_definition
2015                {       // mark all fields in list
2016                        for ( DeclarationNode *iter = $2; iter != NULL; iter = (DeclarationNode *)iter->get_next() )
2017                                iter->set_extension( true );
2018                        $$ = $2;
2019                }
2020        ;
2021
2022external_function_definition:
2023        function_definition
2024                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2025                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2026                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2027                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2028                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2029        | function_declarator compound_statement
2030                {
2031                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2032                        typedefTable.leaveScope();
2033                        $$ = $1->addFunctionBody( $2 );
2034                }
2035        | old_function_declarator push old_declaration_list_opt compound_statement
2036                {
2037                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2038                        typedefTable.leaveScope();
2039                        $$ = $1->addOldDeclList( $3 )->addFunctionBody( $4 );
2040                }
2041        ;
2042
2043function_definition:
2044        new_function_declaration compound_statement                     // CFA
2045                {
2046                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2047                        typedefTable.leaveScope();
2048                        $$ = $1->addFunctionBody( $2 );
2049                }
2050        | declaration_specifier function_declarator compound_statement
2051                {
2052                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2053                        typedefTable.leaveScope();
2054                        $$ = $2->addFunctionBody( $3 )->addType( $1 );
2055                }
2056        | type_qualifier_list function_declarator compound_statement
2057                {
2058                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2059                        typedefTable.leaveScope();
2060                        $$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
2061                }
2062        | declaration_qualifier_list function_declarator compound_statement
2063                {
2064                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2065                        typedefTable.leaveScope();
2066                        $$ = $2->addFunctionBody( $3 )->addQualifiers( $1 );
2067                }
2068        | declaration_qualifier_list type_qualifier_list function_declarator compound_statement
2069                {
2070                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2071                        typedefTable.leaveScope();
2072                        $$ = $3->addFunctionBody( $4 )->addQualifiers( $2 )->addQualifiers( $1 );
2073                }
2074
2075                // Old-style K&R function definition, OBSOLESCENT (see 4)
2076        | declaration_specifier old_function_declarator push old_declaration_list_opt compound_statement
2077                {
2078                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2079                        typedefTable.leaveScope();
2080                        $$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addType( $1 );
2081                }
2082        | type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2083                {
2084                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2085                        typedefTable.leaveScope();
2086                        $$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
2087                }
2088
2089                // Old-style K&R function definition with "implicit int" type_specifier, OBSOLESCENT (see 4)
2090        | declaration_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2091                {
2092                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2093                        typedefTable.leaveScope();
2094                        $$ = $2->addOldDeclList( $4 )->addFunctionBody( $5 )->addQualifiers( $1 );
2095                }
2096        | declaration_qualifier_list type_qualifier_list old_function_declarator push old_declaration_list_opt compound_statement
2097                {
2098                        typedefTable.addToEnclosingScope( TypedefTable::ID );
2099                        typedefTable.leaveScope();
2100                        $$ = $3->addOldDeclList( $5 )->addFunctionBody( $6 )->addQualifiers( $2 )->addQualifiers( $1 );
2101                }
2102        ;
2103
2104declarator:
2105        variable_declarator
2106        | variable_type_redeclarator
2107        | function_declarator
2108        ;
2109
2110subrange:
2111        constant_expression '~' constant_expression                     // CFA, integer subrange
2112                { $$ = new ExpressionNode( build_range( $1, $3 ) ); }
2113        ;
2114
2115asm_name_opt:                                                                                   // GCC
2116        // empty
2117        | ASM '(' string_literal_list ')' attribute_list_opt
2118        ;
2119
2120attribute_list_opt:                                                                             // GCC
2121        // empty
2122                { $$ = 0; }
2123        | attribute_list
2124        ;
2125
2126attribute_list:                                                                                 // GCC
2127        attribute
2128        | attribute_list attribute
2129                { $$ = $2->addQualifiers( $1 ); }
2130        ;
2131
2132attribute:                                                                                              // GCC
2133        ATTRIBUTE '(' '(' attribute_parameter_list ')' ')'
2134        //              { $$ = DeclarationNode::newQualifier( DeclarationNode::Attribute ); }
2135                { $$ = 0; }
2136        ;
2137
2138attribute_parameter_list:                                                               // GCC
2139        attrib
2140        | attribute_parameter_list ',' attrib
2141        ;
2142
2143attrib:                                                                                                 // GCC
2144        // empty
2145        | any_word
2146        | any_word '(' comma_expression_opt ')'
2147        ;
2148
2149any_word:                                                                                               // GCC
2150        identifier_or_type_name {}
2151        | storage_class_name {}
2152        | basic_type_name {}
2153        | type_qualifier {}
2154        ;
2155
2156// ============================================================================
2157// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2158// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2159// in:
2160//
2161//              int (*f())[10] { ... };
2162//              ... (*f())[3] += 1;             // definition mimics usage
2163//
2164// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2165// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2166// ============================================================================
2167
2168// ----------------------------------------------------------------------------
2169// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2170// to define a variable or function prototype, e.g.:
2171//
2172//              valid declaration               invalid definition
2173//              -----------------               ------------------
2174//              int f;                                  int f {}
2175//              int *f;                                 int *f {}
2176//              int f[10];                              int f[10] {}
2177//              int (*f)(int);                  int (*f)(int) {}
2178//
2179// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2180// variable_declarator and function_declarator.
2181// ----------------------------------------------------------------------------
2182
2183// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2184// declaring an array of functions versus a pointer to an array of functions.
2185
2186variable_declarator:
2187        paren_identifier attribute_list_opt
2188                { $$ = $1->addQualifiers( $2 ); }
2189        | variable_ptr
2190        | variable_array attribute_list_opt
2191                { $$ = $1->addQualifiers( $2 ); }
2192        | variable_function attribute_list_opt
2193                { $$ = $1->addQualifiers( $2 ); }
2194        ;
2195
2196paren_identifier:
2197        identifier
2198                {
2199                        typedefTable.setNextIdentifier( *$1 );
2200                        $$ = DeclarationNode::newName( $1 );
2201                }
2202        | '(' paren_identifier ')'                                                      // redundant parenthesis
2203                { $$ = $2; }
2204        ;
2205
2206variable_ptr:
2207        ptrref_operator variable_declarator
2208                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2209        | ptrref_operator type_qualifier_list variable_declarator
2210                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2211        | '(' variable_ptr ')'
2212                { $$ = $2; }
2213        ;
2214
2215variable_array:
2216        paren_identifier array_dimension
2217                { $$ = $1->addArray( $2 ); }
2218        | '(' variable_ptr ')' array_dimension
2219                { $$ = $2->addArray( $4 ); }
2220        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2221                { $$ = $2->addArray( $4 ); }
2222        | '(' variable_array ')'                                                        // redundant parenthesis
2223                { $$ = $2; }
2224        ;
2225
2226variable_function:
2227        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2228                { $$ = $2->addParamList( $6 ); }
2229        | '(' variable_function ')'                                                     // redundant parenthesis
2230                { $$ = $2; }
2231        ;
2232
2233// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2234// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2235// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2236
2237function_declarator:
2238        function_no_ptr attribute_list_opt
2239                { $$ = $1->addQualifiers( $2 ); }
2240        | function_ptr
2241        | function_array attribute_list_opt
2242                { $$ = $1->addQualifiers( $2 ); }
2243        ;
2244
2245function_no_ptr:
2246        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2247                { $$ = $1->addParamList( $4 ); }
2248        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2249                { $$ = $2->addParamList( $6 ); }
2250        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2251                { $$ = $2; }
2252        ;
2253
2254function_ptr:
2255        ptrref_operator function_declarator
2256                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2257        | ptrref_operator type_qualifier_list function_declarator
2258                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2259        | '(' function_ptr ')'
2260                { $$ = $2; }
2261        ;
2262
2263function_array:
2264        '(' function_ptr ')' array_dimension
2265                { $$ = $2->addArray( $4 ); }
2266        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2267                { $$ = $2->addArray( $4 ); }
2268        | '(' function_array ')'                                                        // redundant parenthesis
2269                { $$ = $2; }
2270        ;
2271
2272// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4) that is not redefining a typedef name
2273// (see function_declarator for additional comments). The pattern precludes returning arrays and functions versus
2274// pointers to arrays and functions.
2275
2276old_function_declarator:
2277        old_function_no_ptr
2278        | old_function_ptr
2279        | old_function_array
2280        ;
2281
2282old_function_no_ptr:
2283        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2284                { $$ = $1->addIdList( $3 ); }
2285        | '(' old_function_ptr ')' '(' identifier_list ')'
2286                { $$ = $2->addIdList( $5 ); }
2287        | '(' old_function_no_ptr ')'                                           // redundant parenthesis
2288                { $$ = $2; }
2289        ;
2290
2291old_function_ptr:
2292        ptrref_operator old_function_declarator
2293                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2294        | ptrref_operator type_qualifier_list old_function_declarator
2295                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2296        | '(' old_function_ptr ')'
2297                { $$ = $2; }
2298        ;
2299
2300old_function_array:
2301        '(' old_function_ptr ')' array_dimension
2302                { $$ = $2->addArray( $4 ); }
2303        | '(' old_function_array ')' multi_array_dimension      // redundant parenthesis
2304                { $$ = $2->addArray( $4 ); }
2305        | '(' old_function_array ')'                                            // redundant parenthesis
2306                { $$ = $2; }
2307        ;
2308
2309// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2310//
2311//              typedef int foo;
2312//              {
2313//                 int foo; // redefine typedef name in new scope
2314//              }
2315//
2316// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2317// and functions versus pointers to arrays and functions.
2318
2319variable_type_redeclarator:
2320        paren_type attribute_list_opt
2321                { $$ = $1->addQualifiers( $2 ); }
2322        | type_ptr
2323        | type_array attribute_list_opt
2324                { $$ = $1->addQualifiers( $2 ); }
2325        | type_function attribute_list_opt
2326                { $$ = $1->addQualifiers( $2 ); }
2327        ;
2328
2329paren_type:
2330        typedef
2331        | '(' paren_type ')'
2332                { $$ = $2; }
2333        ;
2334
2335type_ptr:
2336        ptrref_operator variable_type_redeclarator
2337                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2338        | ptrref_operator type_qualifier_list variable_type_redeclarator
2339                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2340        | '(' type_ptr ')'
2341                { $$ = $2; }
2342        ;
2343
2344type_array:
2345        paren_type array_dimension
2346                { $$ = $1->addArray( $2 ); }
2347        | '(' type_ptr ')' array_dimension
2348                { $$ = $2->addArray( $4 ); }
2349        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2350                { $$ = $2->addArray( $4 ); }
2351        | '(' type_array ')'                                                            // redundant parenthesis
2352                { $$ = $2; }
2353        ;
2354
2355type_function:
2356        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2357                { $$ = $1->addParamList( $4 ); }
2358        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2359                { $$ = $2->addParamList( $6 ); }
2360        | '(' type_function ')'                                                         // redundant parenthesis
2361                { $$ = $2; }
2362        ;
2363
2364// This pattern parses a declaration for a parameter variable or function prototype that is not redefining a typedef
2365// name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes declaring an
2366// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
2367// arrays and functions.
2368
2369identifier_parameter_declarator:
2370        paren_identifier attribute_list_opt
2371                { $$ = $1->addQualifiers( $2 ); }
2372        | identifier_parameter_ptr
2373        | identifier_parameter_array attribute_list_opt
2374                { $$ = $1->addQualifiers( $2 ); }
2375        | identifier_parameter_function attribute_list_opt
2376                { $$ = $1->addQualifiers( $2 ); }
2377        ;
2378
2379identifier_parameter_ptr:
2380        ptrref_operator identifier_parameter_declarator
2381                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2382        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2383                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2384        | '(' identifier_parameter_ptr ')'
2385                { $$ = $2; }
2386        ;
2387
2388identifier_parameter_array:
2389        paren_identifier array_parameter_dimension
2390                { $$ = $1->addArray( $2 ); }
2391        | '(' identifier_parameter_ptr ')' array_dimension
2392                { $$ = $2->addArray( $4 ); }
2393        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2394                { $$ = $2->addArray( $4 ); }
2395        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2396                { $$ = $2; }
2397        ;
2398
2399identifier_parameter_function:
2400        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2401                { $$ = $1->addParamList( $4 ); }
2402        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2403                { $$ = $2->addParamList( $6 ); }
2404        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2405                { $$ = $2; }
2406        ;
2407
2408// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2409// e.g.:
2410//
2411//              typedef int foo;
2412//              int f( int foo ); // redefine typedef name in new scope
2413//
2414// and allows the C99 array options, which can only appear in a parameter list.  In addition, the pattern handles the
2415// special meaning of parenthesis around a typedef name:
2416//
2417//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
2418//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
2419//              not as redundant parentheses around the identifier."
2420//
2421// For example:
2422//
2423//              typedef float T;
2424//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
2425//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
2426//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
2427//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
2428//
2429// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
2430// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
2431// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
2432// functions.
2433
2434type_parameter_redeclarator:
2435        typedef attribute_list_opt
2436                { $$ = $1->addQualifiers( $2 ); }
2437        | type_parameter_ptr
2438        | type_parameter_array attribute_list_opt
2439                { $$ = $1->addQualifiers( $2 ); }
2440        | type_parameter_function attribute_list_opt
2441                { $$ = $1->addQualifiers( $2 ); }
2442        ;
2443
2444typedef:
2445        TYPEDEFname
2446                {
2447                        typedefTable.setNextIdentifier( *$1 );
2448                        $$ = DeclarationNode::newName( $1 );
2449                }
2450        | TYPEGENname
2451                {
2452                        typedefTable.setNextIdentifier( *$1 );
2453                        $$ = DeclarationNode::newName( $1 );
2454                }
2455        ;
2456
2457type_parameter_ptr:
2458        ptrref_operator type_parameter_redeclarator
2459                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2460        | ptrref_operator type_qualifier_list type_parameter_redeclarator
2461                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2462        | '(' type_parameter_ptr ')'
2463                { $$ = $2; }
2464        ;
2465
2466type_parameter_array:
2467        typedef array_parameter_dimension
2468                { $$ = $1->addArray( $2 ); }
2469        | '(' type_parameter_ptr ')' array_parameter_dimension
2470                { $$ = $2->addArray( $4 ); }
2471        ;
2472
2473type_parameter_function:
2474        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
2475                { $$ = $1->addParamList( $4 ); }
2476        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2477                { $$ = $2->addParamList( $6 ); }
2478        ;
2479
2480// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
2481// which the type applies, e.g.:
2482//
2483//              sizeof( int );
2484//              sizeof( int [10] );
2485//
2486// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2487// and functions versus pointers to arrays and functions.
2488
2489abstract_declarator:
2490        abstract_ptr
2491        | abstract_array attribute_list_opt
2492                { $$ = $1->addQualifiers( $2 ); }
2493        | abstract_function attribute_list_opt
2494                { $$ = $1->addQualifiers( $2 ); }
2495        ;
2496
2497abstract_ptr:
2498        ptrref_operator
2499                { $$ = DeclarationNode::newPointer( 0 ); }
2500        | ptrref_operator type_qualifier_list
2501                { $$ = DeclarationNode::newPointer( $2 ); }
2502        | ptrref_operator abstract_declarator
2503                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2504        | ptrref_operator type_qualifier_list abstract_declarator
2505                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2506        | '(' abstract_ptr ')'
2507                { $$ = $2; }
2508        ;
2509
2510abstract_array:
2511        array_dimension
2512        | '(' abstract_ptr ')' array_dimension
2513                { $$ = $2->addArray( $4 ); }
2514        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
2515                { $$ = $2->addArray( $4 ); }
2516        | '(' abstract_array ')'                                                        // redundant parenthesis
2517                { $$ = $2; }
2518        ;
2519
2520abstract_function:
2521        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2522                { $$ = DeclarationNode::newFunction( 0, 0, $3, 0 ); }
2523        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2524                { $$ = $2->addParamList( $6 ); }
2525        | '(' abstract_function ')'                                                     // redundant parenthesis
2526                { $$ = $2; }
2527        ;
2528
2529array_dimension:
2530                // Only the first dimension can be empty.
2531        '[' ']'
2532                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2533        | '[' ']' multi_array_dimension
2534                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
2535        | multi_array_dimension
2536        ;
2537
2538multi_array_dimension:
2539        '[' push assignment_expression pop ']'
2540                { $$ = DeclarationNode::newArray( $3, 0, false ); }
2541        | '[' push '*' pop ']'                                                          // C99
2542                { $$ = DeclarationNode::newVarArray( 0 ); }
2543        | multi_array_dimension '[' push assignment_expression pop ']'
2544                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
2545        | multi_array_dimension '[' push '*' pop ']'            // C99
2546                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
2547        ;
2548
2549// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
2550// identifier to which the type applies, e.g.:
2551//
2552//              int f( int );                   // abstract variable parameter; no parameter name specified
2553//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
2554//
2555// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2556// and functions versus pointers to arrays and functions.
2557
2558abstract_parameter_declarator:
2559        abstract_parameter_ptr
2560        | abstract_parameter_array attribute_list_opt
2561                { $$ = $1->addQualifiers( $2 ); }
2562        | abstract_parameter_function attribute_list_opt
2563                { $$ = $1->addQualifiers( $2 ); }
2564        ;
2565
2566abstract_parameter_ptr:
2567        ptrref_operator
2568                { $$ = DeclarationNode::newPointer( 0 ); }
2569        | ptrref_operator type_qualifier_list
2570                { $$ = DeclarationNode::newPointer( $2 ); }
2571        | ptrref_operator abstract_parameter_declarator
2572                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2573        | ptrref_operator type_qualifier_list abstract_parameter_declarator
2574                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2575        | '(' abstract_parameter_ptr ')'
2576                { $$ = $2; }
2577        ;
2578
2579abstract_parameter_array:
2580        array_parameter_dimension
2581        | '(' abstract_parameter_ptr ')' array_parameter_dimension
2582                { $$ = $2->addArray( $4 ); }
2583        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
2584                { $$ = $2->addArray( $4 ); }
2585        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
2586                { $$ = $2; }
2587        ;
2588
2589abstract_parameter_function:
2590        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
2591                { $$ = DeclarationNode::newFunction( 0, 0, $3, 0 ); }
2592        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2593                { $$ = $2->addParamList( $6 ); }
2594        | '(' abstract_parameter_function ')'                           // redundant parenthesis
2595                { $$ = $2; }
2596        ;
2597
2598array_parameter_dimension:
2599                // Only the first dimension can be empty or have qualifiers.
2600        array_parameter_1st_dimension
2601        | array_parameter_1st_dimension multi_array_dimension
2602                { $$ = $1->addArray( $2 ); }
2603        | multi_array_dimension
2604        ;
2605
2606// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
2607//
2608//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
2609//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
2610
2611array_parameter_1st_dimension:
2612        '[' ']'
2613                { $$ = DeclarationNode::newArray( 0, 0, false ); }
2614        // multi_array_dimension handles the '[' '*' ']' case
2615        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
2616                { $$ = DeclarationNode::newVarArray( $3 ); }
2617        | '[' push type_qualifier_list pop ']'
2618                { $$ = DeclarationNode::newArray( 0, $3, false ); }
2619        // multi_array_dimension handles the '[' assignment_expression ']' case
2620        | '[' push type_qualifier_list assignment_expression pop ']'
2621                { $$ = DeclarationNode::newArray( $4, $3, false ); }
2622        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
2623                { $$ = DeclarationNode::newArray( $5, $4, true ); }
2624        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
2625                { $$ = DeclarationNode::newArray( $5, $3, true ); }
2626        ;
2627
2628// This pattern parses a declaration of an abstract variable, i.e., there is no identifier to which the type applies,
2629// e.g.:
2630//
2631//              sizeof( int ); // abstract variable; no identifier name specified
2632//
2633// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2634// and functions versus pointers to arrays and functions.
2635
2636variable_abstract_declarator:
2637        variable_abstract_ptr
2638        | variable_abstract_array attribute_list_opt
2639                { $$ = $1->addQualifiers( $2 ); }
2640        | variable_abstract_function attribute_list_opt
2641                { $$ = $1->addQualifiers( $2 ); }
2642        ;
2643
2644variable_abstract_ptr:
2645        ptrref_operator
2646                { $$ = DeclarationNode::newPointer( 0 ); }
2647        | ptrref_operator type_qualifier_list
2648                { $$ = DeclarationNode::newPointer( $2 ); }
2649        | ptrref_operator variable_abstract_declarator
2650                { $$ = $2->addPointer( DeclarationNode::newPointer( 0 ) ); }
2651        | ptrref_operator type_qualifier_list variable_abstract_declarator
2652                { $$ = $3->addPointer( DeclarationNode::newPointer( $2 ) ); }
2653        | '(' variable_abstract_ptr ')'
2654                { $$ = $2; }
2655        ;
2656
2657variable_abstract_array:
2658        array_dimension
2659        | '(' variable_abstract_ptr ')' array_dimension
2660                { $$ = $2->addArray( $4 ); }
2661        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
2662                { $$ = $2->addArray( $4 ); }
2663        | '(' variable_abstract_array ')'                                       // redundant parenthesis
2664                { $$ = $2; }
2665        ;
2666
2667variable_abstract_function:
2668        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2669                { $$ = $2->addParamList( $6 ); }
2670        | '(' variable_abstract_function ')'                            // redundant parenthesis
2671                { $$ = $2; }
2672        ;
2673
2674// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
2675// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
2676
2677new_identifier_parameter_declarator_tuple:                              // CFA
2678        new_identifier_parameter_declarator_no_tuple
2679        | new_abstract_tuple
2680        | type_qualifier_list new_abstract_tuple
2681                { $$ = $2->addQualifiers( $1 ); }
2682        ;
2683
2684new_identifier_parameter_declarator_no_tuple:                   // CFA
2685        new_identifier_parameter_ptr
2686        | new_identifier_parameter_array
2687        ;
2688
2689new_identifier_parameter_ptr:                                                   // CFA
2690        ptrref_operator type_specifier
2691                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2692        | type_qualifier_list ptrref_operator type_specifier
2693                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2694        | ptrref_operator new_abstract_function
2695                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2696        | type_qualifier_list ptrref_operator new_abstract_function
2697                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2698        | ptrref_operator new_identifier_parameter_declarator_tuple
2699                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2700        | type_qualifier_list ptrref_operator new_identifier_parameter_declarator_tuple
2701                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2702        ;
2703
2704new_identifier_parameter_array:                                                 // CFA
2705                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
2706                // shift/reduce conflict with new-style empty (void) function return type.
2707        '[' ']' type_specifier
2708                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2709        | new_array_parameter_1st_dimension type_specifier
2710                { $$ = $2->addNewArray( $1 ); }
2711        | '[' ']' multi_array_dimension type_specifier
2712                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2713        | new_array_parameter_1st_dimension multi_array_dimension type_specifier
2714                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2715        | multi_array_dimension type_specifier
2716                { $$ = $2->addNewArray( $1 ); }
2717        | '[' ']' new_identifier_parameter_ptr
2718                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2719        | new_array_parameter_1st_dimension new_identifier_parameter_ptr
2720                { $$ = $2->addNewArray( $1 ); }
2721        | '[' ']' multi_array_dimension new_identifier_parameter_ptr
2722                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2723        | new_array_parameter_1st_dimension multi_array_dimension new_identifier_parameter_ptr
2724                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
2725        | multi_array_dimension new_identifier_parameter_ptr
2726                { $$ = $2->addNewArray( $1 ); }
2727        ;
2728
2729new_array_parameter_1st_dimension:
2730        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
2731                { $$ = DeclarationNode::newVarArray( $3 ); }
2732        | '[' push type_qualifier_list assignment_expression pop ']'
2733                { $$ = DeclarationNode::newArray( $4, $3, false ); }
2734        | '[' push declaration_qualifier_list assignment_expression pop ']'
2735                // declaration_qualifier_list must be used because of shift/reduce conflict with
2736                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
2737                // appear in this context.
2738                { $$ = DeclarationNode::newArray( $4, $3, true ); }
2739        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
2740                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
2741        ;
2742
2743// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
2744// identifier to which the type applies, e.g.:
2745//
2746//              [int] f( int );                         // abstract variable parameter; no parameter name specified
2747//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
2748//
2749// These rules need LR(3):
2750//
2751//              new_abstract_tuple identifier_or_type_name
2752//              '[' new_parameter_list ']' identifier_or_type_name '(' new_parameter_type_list_opt ')'
2753//
2754// since a function return type can be syntactically identical to a tuple type:
2755//
2756//              [int, int] t;
2757//              [int, int] f( int );
2758//
2759// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
2760// new_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
2761// lookahead. To accomplish this, new_abstract_declarator has an entry point without tuple, and tuple declarations are
2762// duplicated when appearing with new_function_specifier.
2763
2764new_abstract_declarator_tuple:                                                  // CFA
2765        new_abstract_tuple
2766        | type_qualifier_list new_abstract_tuple
2767                { $$ = $2->addQualifiers( $1 ); }
2768        | new_abstract_declarator_no_tuple
2769        ;
2770
2771new_abstract_declarator_no_tuple:                                               // CFA
2772        new_abstract_ptr
2773        | new_abstract_array
2774        ;
2775
2776new_abstract_ptr:                                                                               // CFA
2777        ptrref_operator type_specifier
2778                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2779        | type_qualifier_list ptrref_operator type_specifier
2780                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2781        | ptrref_operator new_abstract_function
2782                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2783        | type_qualifier_list ptrref_operator new_abstract_function
2784                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2785        | ptrref_operator new_abstract_declarator_tuple
2786                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0 ) ); }
2787        | type_qualifier_list ptrref_operator new_abstract_declarator_tuple
2788                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1 ) ); }
2789        ;
2790
2791new_abstract_array:                                                                             // CFA
2792                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
2793                // empty (void) function return type.
2794        '[' ']' type_specifier
2795                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2796        | '[' ']' multi_array_dimension type_specifier
2797                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2798        | multi_array_dimension type_specifier
2799                { $$ = $2->addNewArray( $1 ); }
2800        | '[' ']' new_abstract_ptr
2801                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2802        | '[' ']' multi_array_dimension new_abstract_ptr
2803                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
2804        | multi_array_dimension new_abstract_ptr
2805                { $$ = $2->addNewArray( $1 ); }
2806        ;
2807
2808new_abstract_tuple:                                                                             // CFA
2809        '[' push new_abstract_parameter_list pop ']'
2810                { $$ = DeclarationNode::newTuple( $3 ); }
2811        ;
2812
2813new_abstract_function:                                                                  // CFA
2814        '[' ']' '(' new_parameter_type_list_opt ')'
2815                { $$ = DeclarationNode::newFunction( 0, DeclarationNode::newTuple( 0 ), $4, 0 ); }
2816        | new_abstract_tuple '(' push new_parameter_type_list_opt pop ')'
2817                { $$ = DeclarationNode::newFunction( 0, $1, $4, 0 ); }
2818        | new_function_return '(' push new_parameter_type_list_opt pop ')'
2819                { $$ = DeclarationNode::newFunction( 0, $1, $4, 0 ); }
2820        ;
2821
2822// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
2823//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
2824//
2825// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
2826//    the declaration specifiers in a declaration is an obsolescent feature."
2827//
2828// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
2829//    prototype-format parameter type declarators) is an obsolescent feature."
2830//
2831// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
2832//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
2833
2834//************************* MISCELLANEOUS ********************************
2835
2836comma_opt:                                                                                              // redundant comma
2837        // empty
2838        | ','
2839        ;
2840
2841assignment_opt:
2842        // empty
2843                { $$ = 0; }
2844        | '=' assignment_expression
2845                { $$ = $2; }
2846        ;
2847
2848%%
2849// ----end of grammar----
2850
2851void yyerror( const char * ) {
2852        std::cout << "Error ";
2853        if ( yyfilename ) {
2854                std::cout << "in file " << yyfilename << " ";
2855        } // if
2856        std::cout << "at line " << yylineno << " reading token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << "\"" << std::endl;
2857}
2858
2859// Local Variables: //
2860// mode: c++ //
2861// tab-width: 4 //
2862// compile-command: "make install" //
2863// End: //
Note: See TracBrowser for help on using the repository browser.