source: src/Parser/parser.yy @ 1b54b54

aaron-thesisarm-ehcleanup-dtorsjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprpersistent-indexer
Last change on this file since 1b54b54 was 1b54b54, checked in by Peter A. Buhr <pabuhr@…>, 3 years ago

add decrement to new for control, add tests for it

  • Property mode set to 100644
File size: 133.4 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Thu Feb 21 08:45:07 2019
13// Update Count     : 4232
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
102                cl->cloneBaseType( cur );
103        } // for
104        declList->addType( cl );
105        return declList;
106} // distAttr
107
108void distExt( DeclarationNode * declaration ) {
109        // distribute EXTENSION across all declarations
110        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
111                iter->set_extension( true );
112        } // for
113} // distExt
114
115void distInl( DeclarationNode * declaration ) {
116        // distribute EXTENSION across all declarations
117        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
118                iter->set_inLine( true );
119        } // for
120} // distInl
121
122void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
123        // distribute qualifiers across all non-variable declarations in a distribution statemement
124        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
125                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
126                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
127                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
128                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
129                DeclarationNode * clone = qualifiers->clone();
130                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
131                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
132                                swap( clone->type->forall, iter->type->aggregate.params );
133                                iter->addQualifiers( clone );
134                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
135                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
136                                DeclarationNode newnode;
137                                swap( newnode.type, iter->type->aggInst.aggregate );
138                                swap( clone->type->forall, newnode.type->aggregate.params );
139                                newnode.addQualifiers( clone );
140                                swap( newnode.type, iter->type->aggInst.aggregate );
141                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
142                                swap( clone->type->forall, iter->type->forall );
143                                iter->addQualifiers( clone );
144                        } // if
145                } else {                                                                                // just SC qualifiers
146                        iter->addQualifiers( clone );
147                } // if
148        } // for
149        delete qualifiers;
150} // distQual
151
152// There is an ambiguity for inline generic-routine return-types and generic routines.
153//   forall( otype T ) struct S { int i; } bar( T ) {}
154// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
155//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
156// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
157//   forall( otype T ) struct S { int T; };
158//   forall( otype W ) bar( W ) {}
159
160void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
161        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
162                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
163                declSpec->type->aggregate.params = nullptr;
164        } // if
165} // rebindForall
166
167NameExpr * build_postfix_name( const string * name ) {
168        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
169        delete name;
170        return new_name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && typeSpec->type->kind == TypeData::Aggregate ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->get_expr());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->get_expr()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->get_expr()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210        } // if
211} // forCtrl
212
213
214bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
215
216// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
217#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
218if ( N ) {                                                                                                                                              \
219        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
220        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
221        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
222        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
223        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
224} else {                                                                                                                                                \
225        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
226        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
227        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
228}
229%}
230
231%define parse.error verbose
232
233// Types declaration for productions
234%union {
235        Token tok;
236        ParseNode * pn;
237        ExpressionNode * en;
238        DeclarationNode * decl;
239        DeclarationNode::Aggregate aggKey;
240        DeclarationNode::TypeClass tclass;
241        StatementNode * sn;
242        WaitForStmt * wfs;
243        Expression * constant;
244        IfCtrl * ifctl;
245        ForCtrl * fctl;
246        enum OperKinds compop;
247        LabelNode * label;
248        InitializerNode * in;
249        OperKinds op;
250        std::string * str;
251        bool flag;
252        CatchStmt::Kind catch_kind;
253        GenericExpr * genexpr;
254}
255
256//************************* TERMINAL TOKENS ********************************
257
258// keywords
259%token TYPEDEF
260%token EXTERN STATIC AUTO REGISTER
261%token THREADLOCAL                                                                              // C11
262%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
263%token NORETURN                                                                                 // C11
264%token CONST VOLATILE
265%token RESTRICT                                                                                 // C99
266%token ATOMIC                                                                                   // C11
267%token FORALL MUTEX VIRTUAL                                                             // CFA
268%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
269%token BOOL COMPLEX IMAGINARY                                                   // C99
270%token INT128 uuFLOAT80 uuFLOAT128                                              // GCC
271%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
272%token ZERO_T ONE_T                                                                             // CFA
273%token VALIST                                                                                   // GCC
274%token TYPEOF BASETYPEOF LABEL                                                  // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION                                                                                // CFA
277%token COROUTINE MONITOR THREAD                                                 // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
279%token SIZEOF OFFSETOF
280%token ATTRIBUTE EXTENSION                                                              // GCC
281%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
282%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
283%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
284%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
285
286// names and constants: lexer differentiates between identifier and typedef names
287%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
288%token<tok> TIMEOUT                             WOR
289%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
290%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
291%token<tok> DIRECTIVE
292// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
293// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
294// converted into the tuple index (.)(1). e.g., 3.x
295%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
296
297// multi-character operators
298%token ARROW                                                                                    // ->
299%token ICR DECR                                                                                 // ++   --
300%token LS RS                                                                                    // <<   >>
301%token LE GE EQ NE                                                                              // <=   >=      ==      !=
302%token ANDAND OROR                                                                              // &&   ||
303%token ELLIPSIS                                                                                 // ...
304
305%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
306%token PLUSassign       MINUSassign                                                     // +=   -=
307%token LSassign         RSassign                                                        // <<=  >>=
308%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
309
310%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
311%token ATassign                                                                                 // @=
312
313%type<tok> identifier  no_attr_identifier
314%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
315%type<tok> quasi_keyword
316%type<constant> string_literal
317%type<str> string_literal_list
318
319// expressions
320%type<en> constant
321%type<en> tuple                                                 tuple_expression_list
322%type<op> ptrref_operator                               unary_operator                          assignment_operator
323%type<en> primary_expression                    postfix_expression                      unary_expression
324%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
325%type<en> shift_expression                              relational_expression           equality_expression
326%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
327%type<en> logical_AND_expression                logical_OR_expression
328%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
329%type<en> comma_expression                              comma_expression_opt
330%type<en> argument_expression_list              argument_expression                     default_initialize_opt
331%type<ifctl> if_control_expression
332%type<fctl> for_control_expression              for_control_expression_list
333%type<compop> inclexcl
334%type<en> subrange
335%type<decl> asm_name_opt
336%type<en> asm_operands_opt asm_operands_list asm_operand
337%type<label> label_list
338%type<en> asm_clobbers_list_opt
339%type<flag> asm_volatile_opt
340%type<en> handler_predicate_opt
341%type<genexpr> generic_association generic_assoc_list
342
343// statements
344%type<sn> statement                                             labeled_statement                       compound_statement
345%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
346%type<sn> selection_statement                   if_statement
347%type<sn> switch_clause_list_opt                switch_clause_list
348%type<en> case_value
349%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
350%type<sn> iteration_statement                   jump_statement
351%type<sn> expression_statement                  asm_statement
352%type<sn> with_statement
353%type<en> with_clause_opt
354%type<sn> exception_statement                   handler_clause                          finally_clause
355%type<catch_kind> handler_key
356%type<sn> mutex_statement
357%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
358%type<sn> waitfor_statement
359%type<wfs> waitfor_clause
360
361// declarations
362%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
363%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
364%type<decl> abstract_parameter_declaration
365
366%type<aggKey> aggregate_key
367%type<decl> aggregate_type aggregate_type_nobody
368
369%type<decl> assertion assertion_list assertion_list_opt
370
371%type<en>   bit_subrange_size_opt bit_subrange_size
372
373%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
374
375%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
376
377%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
378%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
379
380%type<decl> elaborated_type elaborated_type_nobody
381
382%type<decl> enumerator_list enum_type enum_type_nobody
383%type<en> enumerator_value_opt
384
385%type<decl> external_definition external_definition_list external_definition_list_opt
386
387%type<decl> exception_declaration
388
389%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
390%type<en> field field_name_list field_name fraction_constants_opt
391
392%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
393
394%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
395%type<decl> identifier_list
396
397%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
398%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
399%type<decl> cfa_abstract_ptr cfa_abstract_tuple
400
401%type<decl> cfa_array_parameter_1st_dimension
402
403%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
404%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
405
406%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
407%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
408
409%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
410
411%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
412
413%type<decl> c_declaration static_assert
414%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
415%type<decl> KR_parameter_list KR_parameter_list_opt
416
417%type<decl> parameter_declaration parameter_list parameter_type_list_opt
418
419%type<decl> paren_identifier paren_type
420
421%type<decl> storage_class storage_class_list
422
423%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
424
425%type<tclass> type_class
426%type<decl> type_declarator type_declarator_name type_declaring_list
427
428%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
429%type<decl> typedef typedef_declaration typedef_expression
430
431%type<decl> variable_type_redeclarator type_ptr type_array type_function
432
433%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
434
435%type<decl> type type_no_function
436%type<decl> type_parameter type_parameter_list type_initializer_opt
437
438%type<en> type_parameters_opt type_list
439
440%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
441%type<decl> type_specifier type_specifier_nobody
442
443%type<decl> variable_declarator variable_ptr variable_array variable_function
444%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
445
446%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
447
448// initializers
449%type<in>  initializer initializer_list_opt initializer_opt
450
451// designators
452%type<en>  designator designator_list designation
453
454
455// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
456//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
457//   if ( C ) S1 else S2
458//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
459// Similar issues exit with the waitfor statement.
460
461// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
462// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
463%precedence THEN        // rule precedence for IF/WAITFOR statement
464%precedence WOR         // token precedence for start of WOR in WAITFOR statement
465%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
466%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
467
468// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
469//   forall( otype T ) struct Foo { T v; };
470//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
471//   Foo ( *fp )( int );
472//   `---'                                              matches start of TYPEGENname '('
473// must be:
474//   Foo( int ) ( *fp )( int );
475// The same problem occurs here:
476//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
477// must be:
478//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
479
480// Order of these lines matters (low-to-high precedence).
481%precedence TYPEGENname
482%precedence '}'
483%precedence '('
484
485%locations                                                                                              // support location tracking for error messages
486
487%start translation_unit                                                                 // parse-tree root
488
489%%
490//************************* Namespace Management ********************************
491
492// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
493// which are lexically identical.
494//
495//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
496//   foo f;           // to allow it to appear in this context
497//
498// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
499// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
500// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
501// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
502// must be distinguished by the lexical scanner.
503//
504// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
505// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
506// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
507// each context that introduces a name scope, a new level is created in the type table and that level is popped on
508// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
509// This requires distinguishing between type names that are local to the current declaration scope and those that
510// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
511//
512// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
513// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
514// around the list separator.
515//
516//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
517//      push               pop   push                   pop
518
519push:
520                { typedefTable.enterScope(); }
521        ;
522
523pop:
524                { typedefTable.leaveScope(); }
525        ;
526
527//************************* CONSTANTS ********************************
528
529constant:
530                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
531        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
532        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
533        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
534        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
535        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
536        ;
537
538quasi_keyword:                                                                                  // CFA
539        TIMEOUT
540        | WOR
541        ;
542
543no_attr_identifier:
544        IDENTIFIER
545        | quasi_keyword
546        | '@'                                                                                           // CFA
547                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
548        ;
549
550identifier:
551        no_attr_identifier
552        | ATTR_IDENTIFIER                                                                       // CFA
553        ;
554
555string_literal:
556        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
557        ;
558
559string_literal_list:                                                                    // juxtaposed strings are concatenated
560        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
561        | string_literal_list STRINGliteral
562                {
563                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
564                        delete $2;                                                                      // allocated by lexer
565                        $$ = $1;                                                                        // conversion from tok to str
566                }
567        ;
568
569//************************* EXPRESSIONS ********************************
570
571primary_expression:
572        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
573                { $$ = new ExpressionNode( build_varref( $1 ) ); }
574        | quasi_keyword
575                { $$ = new ExpressionNode( build_varref( $1 ) ); }
576        | tuple
577        | '(' comma_expression ')'
578                { $$ = $2; }
579        | '(' compound_statement ')'                                            // GCC, lambda expression
580                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
581        | constant '`' IDENTIFIER                                                       // CFA, postfix call
582                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
583        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
584                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
585        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
586                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
587        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
588                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
589        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
590                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
591        | type_name '.' no_attr_identifier                                      // CFA, nested type
592                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
593        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
594                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
595        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
596                {
597                        // add the missing control expression to the GenericExpr and return it
598                        $5->control = maybeMoveBuild<Expression>( $3 );
599                        $$ = new ExpressionNode( $5 );
600                }
601        ;
602
603generic_assoc_list:                                                                             // C11
604        generic_association
605        | generic_assoc_list ',' generic_association
606                {
607                        // steal the association node from the singleton and delete the wrapper
608                        $1->associations.splice($1->associations.end(), $3->associations);
609                        delete $3;
610                        $$ = $1;
611                }
612        ;
613
614generic_association:                                                                    // C11
615        type_no_function ':' assignment_expression
616                {
617                        // create a GenericExpr wrapper with one association pair
618                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
619                }
620        | DEFAULT ':' assignment_expression
621                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
622        ;
623
624postfix_expression:
625        primary_expression
626        | postfix_expression '[' assignment_expression ']'
627                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
628                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
629                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
630                // equivalent to the old x[i,j].
631                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
632        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
633                {
634                        Token fn;
635                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
636                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
637                }
638        | postfix_expression '(' argument_expression_list ')'
639                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
640        | postfix_expression '.' no_attr_identifier
641                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
642        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
643                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
644        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
645                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
646        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
647                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
648        | postfix_expression ARROW no_attr_identifier
649                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
650        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
651                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
652        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
653                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
654        | postfix_expression ICR
655                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
656        | postfix_expression DECR
657                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
658        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
659                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
660        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
661                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
662        | '^' primary_expression '{' argument_expression_list '}' // CFA
663                {
664                        Token fn;
665                        fn.str = new string( "^?{}" );                          // location undefined
666                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
667                }
668        ;
669
670argument_expression_list:
671        argument_expression
672        | argument_expression_list ',' argument_expression
673                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
674        ;
675
676argument_expression:
677        // empty
678                { $$ = nullptr; }
679        | '?'                                                                                           // CFA, default parameter
680                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
681                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
682        | assignment_expression
683        ;
684
685field_name_list:                                                                                // CFA, tuple field selector
686        field
687        | field_name_list ',' field                                     { $$ = (ExpressionNode *)$1->set_last( $3 ); }
688        ;
689
690field:                                                                                                  // CFA, tuple field selector
691        field_name
692        | FLOATING_DECIMALconstant field
693                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
694        | FLOATING_DECIMALconstant '[' field_name_list ']'
695                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
696        | field_name '.' field
697                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
698        | field_name '.' '[' field_name_list ']'
699                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
700        | field_name ARROW field
701                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
702        | field_name ARROW '[' field_name_list ']'
703                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
704        ;
705
706field_name:
707        INTEGERconstant fraction_constants_opt
708                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
709        | FLOATINGconstant fraction_constants_opt
710                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
711        | no_attr_identifier fraction_constants_opt
712                {
713                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
714                }
715        ;
716
717fraction_constants_opt:
718        // empty
719                { $$ = nullptr; }
720        | fraction_constants_opt FLOATING_FRACTIONconstant
721                {
722                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
723                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
724                }
725        ;
726
727unary_expression:
728        postfix_expression
729                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
730                // semantics checks, e.g., ++3, 3--, *3, &&3
731        | constant
732        | string_literal
733                { $$ = new ExpressionNode( $1 ); }
734        | EXTENSION cast_expression                                                     // GCC
735                { $$ = $2->set_extension( true ); }
736                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
737                //              { * X; }         // dereference X
738                //              { * int X; } // CFA declaration of pointer to int
739        | ptrref_operator cast_expression                                       // CFA
740                {
741                        switch ( $1 ) {
742                          case OperKinds::AddressOf:
743                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
744                                break;
745                          case OperKinds::PointTo:
746                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
747                                break;
748                          case OperKinds::And:
749                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
750                                break;
751                          default:
752                                assert( false );
753                        }
754                }
755        | unary_operator cast_expression
756                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
757        | ICR unary_expression
758                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
759        | DECR unary_expression
760                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
761        | SIZEOF unary_expression
762                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
763        | SIZEOF '(' type_no_function ')'
764                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
765        | ALIGNOF unary_expression                                                      // GCC, variable alignment
766                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
767        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
768                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
769        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
770                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
771        | ATTR_IDENTIFIER
772                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
773        | ATTR_IDENTIFIER '(' argument_expression ')'
774                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
775        | ATTR_IDENTIFIER '(' type ')'
776                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
777        ;
778
779ptrref_operator:
780        '*'                                                                                     { $$ = OperKinds::PointTo; }
781        | '&'                                                                           { $$ = OperKinds::AddressOf; }
782                // GCC, address of label must be handled by semantic check for ref,ref,label
783        | ANDAND                                                                        { $$ = OperKinds::And; }
784        ;
785
786unary_operator:
787        '+'                                                                                     { $$ = OperKinds::UnPlus; }
788        | '-'                                                                           { $$ = OperKinds::UnMinus; }
789        | '!'                                                                           { $$ = OperKinds::Neg; }
790        | '~'                                                                           { $$ = OperKinds::BitNeg; }
791        ;
792
793cast_expression:
794        unary_expression
795        | '(' type_no_function ')' cast_expression
796                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
797        | '(' COROUTINE '&' ')' cast_expression                         // CFA
798                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
799        | '(' THREAD '&' ')' cast_expression                            // CFA
800                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
801        | '(' MONITOR '&' ')' cast_expression                           // CFA
802                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
803                // VIRTUAL cannot be opt because of look ahead issues
804        | '(' VIRTUAL ')' cast_expression                                       // CFA
805                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
806        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
807                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
808//      | '(' type_no_function ')' tuple
809//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
810        ;
811
812exponential_expression:
813        cast_expression
814        | exponential_expression '\\' cast_expression
815                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
816        ;
817
818multiplicative_expression:
819        exponential_expression
820        | multiplicative_expression '*' exponential_expression
821                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
822        | multiplicative_expression '/' exponential_expression
823                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
824        | multiplicative_expression '%' exponential_expression
825                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
826        ;
827
828additive_expression:
829        multiplicative_expression
830        | additive_expression '+' multiplicative_expression
831                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
832        | additive_expression '-' multiplicative_expression
833                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
834        ;
835
836shift_expression:
837        additive_expression
838        | shift_expression LS additive_expression
839                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
840        | shift_expression RS additive_expression
841                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
842        ;
843
844relational_expression:
845        shift_expression
846        | relational_expression '<' shift_expression
847                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
848        | relational_expression '>' shift_expression
849                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
850        | relational_expression LE shift_expression
851                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
852        | relational_expression GE shift_expression
853                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
854        ;
855
856equality_expression:
857        relational_expression
858        | equality_expression EQ relational_expression
859                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
860        | equality_expression NE relational_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
862        ;
863
864AND_expression:
865        equality_expression
866        | AND_expression '&' equality_expression
867                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
868        ;
869
870exclusive_OR_expression:
871        AND_expression
872        | exclusive_OR_expression '^' AND_expression
873                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
874        ;
875
876inclusive_OR_expression:
877        exclusive_OR_expression
878        | inclusive_OR_expression '|' exclusive_OR_expression
879                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
880        ;
881
882logical_AND_expression:
883        inclusive_OR_expression
884        | logical_AND_expression ANDAND inclusive_OR_expression
885                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
886        ;
887
888logical_OR_expression:
889        logical_AND_expression
890        | logical_OR_expression OROR logical_AND_expression
891                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
892        ;
893
894conditional_expression:
895        logical_OR_expression
896        | logical_OR_expression '?' comma_expression ':' conditional_expression
897                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
898                // FIX ME: computes $1 twice
899        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
900                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
901        ;
902
903constant_expression:
904        conditional_expression
905        ;
906
907assignment_expression:
908                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
909        conditional_expression
910        | unary_expression assignment_operator assignment_expression
911                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
912        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
913                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
914        ;
915
916assignment_expression_opt:
917        // empty
918                { $$ = nullptr; }
919        | assignment_expression
920        ;
921
922assignment_operator:
923        '='                                                                                     { $$ = OperKinds::Assign; }
924        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
925        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
926        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
927        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
928        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
929        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
930        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
931        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
932        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
933        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
934        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
935        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
936        ;
937
938tuple:                                                                                                  // CFA, tuple
939                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
940                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
941//      '[' ']'
942//              { $$ = new ExpressionNode( build_tuple() ); }
943//      | '[' push assignment_expression pop ']'
944//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
945        '[' ',' tuple_expression_list ']'
946                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
947        | '[' push assignment_expression pop ',' tuple_expression_list ']'
948                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $6 ) ) ); }
949        ;
950
951tuple_expression_list:
952        assignment_expression_opt
953        | tuple_expression_list ',' assignment_expression_opt
954                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
955        ;
956
957comma_expression:
958        assignment_expression
959        | comma_expression ',' assignment_expression
960                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
961        ;
962
963comma_expression_opt:
964        // empty
965                { $$ = nullptr; }
966        | comma_expression
967        ;
968
969//*************************** STATEMENTS *******************************
970
971statement:
972        labeled_statement
973        | compound_statement
974        | expression_statement
975        | selection_statement
976        | iteration_statement
977        | jump_statement
978        | with_statement
979        | mutex_statement
980        | waitfor_statement
981        | exception_statement
982        | enable_disable_statement
983                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
984        | asm_statement
985        | DIRECTIVE
986                { $$ = new StatementNode( build_directive( $1 ) ); }
987        ;
988
989labeled_statement:
990                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
991        identifier_or_type_name ':' attribute_list_opt statement
992                { $$ = $4->add_label( $1, $3 ); }
993        ;
994
995compound_statement:
996        '{' '}'
997                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
998        | '{' push
999          local_label_declaration_opt                                           // GCC, local labels
1000          statement_decl_list                                                           // C99, intermix declarations and statements
1001          pop '}'
1002                { $$ = new StatementNode( build_compound( $4 ) ); }
1003        ;
1004
1005statement_decl_list:                                                                    // C99
1006        statement_decl
1007        | statement_decl_list statement_decl
1008                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1009        ;
1010
1011statement_decl:
1012        declaration                                                                                     // CFA, new & old style declarations
1013                { $$ = new StatementNode( $1 ); }
1014        | EXTENSION declaration                                                         // GCC
1015                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1016        | function_definition
1017                { $$ = new StatementNode( $1 ); }
1018        | EXTENSION function_definition                                         // GCC
1019                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1020        | statement
1021        ;
1022
1023statement_list_nodecl:
1024        statement
1025        | statement_list_nodecl statement
1026                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1027        ;
1028
1029expression_statement:
1030        comma_expression_opt ';'
1031                { $$ = new StatementNode( build_expr( $1 ) ); }
1032        ;
1033
1034selection_statement:
1035                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1036                        // the inherent S/R conflict with THEN/ELSE.
1037        push if_statement pop
1038                { $$ = $2; }
1039        | SWITCH '(' comma_expression ')' case_clause
1040                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1041        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1042                {
1043                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1044                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1045                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1046                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1047                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1048                        // statement.
1049                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1050                }
1051        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1052                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1053        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1054                {
1055                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1056                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1057                }
1058        ;
1059
1060if_statement:
1061        IF '(' if_control_expression ')' statement                      %prec THEN
1062                // explicitly deal with the shift/reduce conflict on if/else
1063                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1064        | IF '(' if_control_expression ')' statement ELSE statement
1065                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1066        ;
1067
1068if_control_expression:
1069        comma_expression
1070                { $$ = new IfCtrl( nullptr, $1 ); }
1071        | c_declaration                                                                         // no semi-colon
1072                { $$ = new IfCtrl( $1, nullptr ); }
1073        | cfa_declaration                                                                       // no semi-colon
1074                { $$ = new IfCtrl( $1, nullptr ); }
1075        | declaration comma_expression                                          // semi-colon separated
1076                { $$ = new IfCtrl( $1, $2 ); }
1077        ;
1078
1079// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1080// clause allows a list of values and subranges.
1081
1082case_value:                                                                                             // CFA
1083        constant_expression                                                     { $$ = $1; }
1084        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1085                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1086        | subrange                                                                                      // CFA, subrange
1087        ;
1088
1089case_value_list:                                                                                // CFA
1090        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1091                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1092        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1093        ;
1094
1095case_label:                                                                                             // CFA
1096        CASE case_value_list ':'                                        { $$ = $2; }
1097        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1098                // A semantic check is required to ensure only one default clause per switch/choose statement.
1099        ;
1100
1101//label_list_opt:
1102//      // empty
1103//      | identifier_or_type_name ':'
1104//      | label_list_opt identifier_or_type_name ':'
1105//      ;
1106
1107case_label_list:                                                                                // CFA
1108        case_label
1109        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1110        ;
1111
1112case_clause:                                                                                    // CFA
1113        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1114        ;
1115
1116switch_clause_list_opt:                                                                 // CFA
1117        // empty
1118                { $$ = nullptr; }
1119        | switch_clause_list
1120        ;
1121
1122switch_clause_list:                                                                             // CFA
1123        case_label_list statement_list_nodecl
1124                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1125        | switch_clause_list case_label_list statement_list_nodecl
1126                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1127        ;
1128
1129iteration_statement:
1130        WHILE '(' push if_control_expression ')' statement pop
1131                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1132        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1133                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1134        | DO statement WHILE '(' comma_expression ')' ';'
1135                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1136        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1137                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1138        | FOR '(' push for_control_expression_list ')' statement pop
1139                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1140        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1141                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1142        ;
1143
1144for_control_expression_list:
1145        for_control_expression
1146        | for_control_expression_list ':' for_control_expression
1147                { $$ = $3; }
1148        ;
1149
1150for_control_expression:
1151        ';' comma_expression_opt ';' comma_expression_opt
1152                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1153        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1154                { $$ = new ForCtrl( $1, $3, $5 ); }
1155        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1156                { $$ = new ForCtrl( $1, $2, $4 ); }
1157        | comma_expression                                                                      // CFA
1158                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1159                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1160        | comma_expression inclexcl comma_expression            // CFA
1161                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1162        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1163                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1164        | comma_expression ';' comma_expression                         // CFA
1165                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1166                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1167        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1168                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1169        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1170                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1171        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1172                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1173        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1174                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1175        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1176                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1177        ;
1178
1179inclexcl:
1180        '~'
1181                { $$ = OperKinds::LThan; }
1182        | ErangeUpEq
1183                { $$ = OperKinds::LEThan; }
1184        | ErangeDown
1185                { $$ = OperKinds::GThan; }
1186        | ErangeDownEq
1187                { $$ = OperKinds::GEThan; }
1188        ;
1189
1190jump_statement:
1191        GOTO identifier_or_type_name ';'
1192                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1193        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1194                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1195                // whereas normal operator precedence yields goto (*i)+3;
1196                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1197                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1198    | fall_through_name ';'                                                             // CFA
1199                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1200    | fall_through_name identifier_or_type_name ';'             // CFA
1201                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1202        | fall_through_name DEFAULT ';'                                         // CFA
1203                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1204        | CONTINUE ';'
1205                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1206                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1207        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1208                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1209                // the target of the transfer appears only at the start of an iteration statement.
1210                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1211        | BREAK ';'
1212                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1213                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1214        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1215                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1216                // the target of the transfer appears only at the start of an iteration statement.
1217                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1218        | RETURN comma_expression_opt ';'
1219                { $$ = new StatementNode( build_return( $2 ) ); }
1220        | RETURN '{' initializer_list_opt comma_opt '}'
1221                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1222        | THROW assignment_expression_opt ';'                           // handles rethrow
1223                { $$ = new StatementNode( build_throw( $2 ) ); }
1224        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1225                { $$ = new StatementNode( build_resume( $2 ) ); }
1226        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1227                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1228        ;
1229
1230fall_through_name:                                                                              // CFA
1231        FALLTHRU
1232        | FALLTHROUGH
1233        ;
1234
1235with_statement:
1236        WITH '(' tuple_expression_list ')' statement
1237                {
1238                        $$ = new StatementNode( build_with( $3, $5 ) );
1239                }
1240        ;
1241
1242// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1243mutex_statement:
1244        MUTEX '(' argument_expression_list ')' statement
1245                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1246        ;
1247
1248when_clause:
1249        WHEN '(' comma_expression ')'                           { $$ = $3; }
1250        ;
1251
1252when_clause_opt:
1253        // empty
1254                { $$ = nullptr; }
1255        | when_clause
1256        ;
1257
1258waitfor:
1259        WAITFOR '(' cast_expression ')'
1260                { $$ = $3; }
1261        | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1262                { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1263        ;
1264
1265timeout:
1266        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1267        ;
1268
1269waitfor_clause:
1270        when_clause_opt waitfor statement                                       %prec THEN
1271                { $$ = build_waitfor( $2, $3, $1 ); }
1272        | when_clause_opt waitfor statement WOR waitfor_clause
1273                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1274        | when_clause_opt timeout statement                                     %prec THEN
1275                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1276        | when_clause_opt ELSE statement
1277                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1278                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1279        | when_clause_opt timeout statement WOR ELSE statement
1280                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1281        | when_clause_opt timeout statement WOR when_clause ELSE statement
1282                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1283        ;
1284
1285waitfor_statement:
1286        when_clause_opt waitfor statement                                       %prec THEN
1287                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1288        | when_clause_opt waitfor statement WOR waitfor_clause
1289                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1290        ;
1291
1292exception_statement:
1293        TRY compound_statement handler_clause
1294                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1295        | TRY compound_statement finally_clause
1296                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1297        | TRY compound_statement handler_clause finally_clause
1298                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1299        ;
1300
1301handler_clause:
1302        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1303                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1304        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement pop
1305                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1306        ;
1307
1308handler_predicate_opt:
1309        // empty
1310                { $$ = nullptr; }
1311        | ';' conditional_expression                            { $$ = $2; }
1312        ;
1313
1314handler_key:
1315        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1316        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1317        ;
1318
1319finally_clause:
1320        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1321        ;
1322
1323exception_declaration:
1324                // No SUE declaration in parameter list.
1325        type_specifier_nobody
1326        | type_specifier_nobody declarator
1327                { $$ = $2->addType( $1 ); }
1328        | type_specifier_nobody variable_abstract_declarator
1329                { $$ = $2->addType( $1 ); }
1330        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1331                { $$ = $1->addName( $2 ); }
1332        | cfa_abstract_declarator_tuple                                         // CFA
1333        ;
1334
1335enable_disable_statement:
1336        enable_disable_key identifier_list compound_statement
1337        ;
1338
1339enable_disable_key:
1340        ENABLE
1341        | DISABLE
1342        ;
1343
1344asm_statement:
1345        ASM asm_volatile_opt '(' string_literal ')' ';'
1346                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1347        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1348                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1349        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1350                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1351        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1352                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1353        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1354                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1355        ;
1356
1357asm_volatile_opt:                                                                               // GCC
1358        // empty
1359                { $$ = false; }
1360        | VOLATILE
1361                { $$ = true; }
1362        ;
1363
1364asm_operands_opt:                                                                               // GCC
1365        // empty
1366                { $$ = nullptr; }                                                               // use default argument
1367        | asm_operands_list
1368        ;
1369
1370asm_operands_list:                                                                              // GCC
1371        asm_operand
1372        | asm_operands_list ',' asm_operand
1373                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1374        ;
1375
1376asm_operand:                                                                                    // GCC
1377        string_literal '(' constant_expression ')'
1378                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1379        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1380                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1381        ;
1382
1383asm_clobbers_list_opt:                                                                  // GCC
1384        // empty
1385                { $$ = nullptr; }                                                               // use default argument
1386        | string_literal
1387                { $$ = new ExpressionNode( $1 ); }
1388        | asm_clobbers_list_opt ',' string_literal
1389                // set_last returns ParseNode *
1390                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1391        ;
1392
1393label_list:
1394        no_attr_identifier
1395                {
1396                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1397                        delete $1;                                                                      // allocated by lexer
1398                }
1399        | label_list ',' no_attr_identifier
1400                {
1401                        $$ = $1; $1->labels.push_back( *$3 );
1402                        delete $3;                                                                      // allocated by lexer
1403                }
1404        ;
1405
1406//******************************* DECLARATIONS *********************************
1407
1408declaration_list_opt:                                                                   // used at beginning of switch statement
1409        // empty
1410                { $$ = nullptr; }
1411        | declaration_list
1412        ;
1413
1414declaration_list:
1415        declaration
1416        | declaration_list declaration
1417                { $$ = $1->appendList( $2 ); }
1418        ;
1419
1420KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1421        // empty
1422                { $$ = nullptr; }
1423        | KR_parameter_list
1424        ;
1425
1426KR_parameter_list:
1427        push c_declaration pop ';'
1428                { $$ = $2; }
1429        | KR_parameter_list push c_declaration pop ';'
1430                { $$ = $1->appendList( $3 ); }
1431        ;
1432
1433local_label_declaration_opt:                                                    // GCC, local label
1434        // empty
1435        | local_label_declaration_list
1436        ;
1437
1438local_label_declaration_list:                                                   // GCC, local label
1439        LABEL local_label_list ';'
1440        | local_label_declaration_list LABEL local_label_list ';'
1441        ;
1442
1443local_label_list:                                                                               // GCC, local label
1444        no_attr_identifier_or_type_name
1445        | local_label_list ',' no_attr_identifier_or_type_name
1446        ;
1447
1448declaration:                                                                                    // old & new style declarations
1449        c_declaration ';'
1450        | cfa_declaration ';'                                                           // CFA
1451        | static_assert                                                                         // C11
1452        ;
1453
1454static_assert:
1455        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1456                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1457        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1458                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1459
1460// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1461// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1462// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1463// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1464// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1465// block, but cannot be mixed within a specific declaration.
1466//
1467//                      CFA                                     C
1468//              [10] int x;                     int x[10];              // array of 10 integers
1469//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1470
1471cfa_declaration:                                                                                // CFA
1472        cfa_variable_declaration
1473        | cfa_typedef_declaration
1474        | cfa_function_declaration
1475        | type_declaring_list
1476        | trait_specifier
1477        ;
1478
1479cfa_variable_declaration:                                                               // CFA
1480        cfa_variable_specifier initializer_opt
1481                { $$ = $1->addInitializer( $2 ); }
1482        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1483                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1484                // them as a type_qualifier cannot appear in that context.
1485                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1486        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1487                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1488        ;
1489
1490cfa_variable_specifier:                                                                 // CFA
1491                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1492                // storage-class
1493        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1494                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1495        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1496                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1497        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1498                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1499        ;
1500
1501cfa_function_declaration:                                                               // CFA
1502        cfa_function_specifier
1503        | type_qualifier_list cfa_function_specifier
1504                { $$ = $2->addQualifiers( $1 ); }
1505        | declaration_qualifier_list cfa_function_specifier
1506                { $$ = $2->addQualifiers( $1 ); }
1507        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1508                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1509        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1510                {
1511                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1512                        DeclarationNode * ret = new DeclarationNode;
1513                        ret->type = maybeClone( $1->type->base );
1514                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1515                }
1516        ;
1517
1518cfa_function_specifier:                                                                 // CFA
1519//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1520//              {
1521//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1522//              }
1523//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1524//              {
1525//                      typedefTable.setNextIdentifier( *$5 );
1526//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1527//              }
1528//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1529//              {
1530//                      typedefTable.setNextIdentifier( *$5 );
1531//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1532//              }
1533//      | '[' ']' typegen_name
1534                // identifier_or_type_name must be broken apart because of the sequence:
1535                //
1536                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1537                //   '[' ']' type_specifier
1538                //
1539                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1540                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1541        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1542                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1543                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1544        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1545                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1546        ;
1547
1548cfa_function_return:                                                                    // CFA
1549        '[' push cfa_parameter_list pop ']'
1550                { $$ = DeclarationNode::newTuple( $3 ); }
1551        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1552                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1553                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1554        ;
1555
1556cfa_typedef_declaration:                                                                // CFA
1557        TYPEDEF cfa_variable_specifier
1558                {
1559                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1560                        $$ = $2->addTypedef();
1561                }
1562        | TYPEDEF cfa_function_specifier
1563                {
1564                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1565                        $$ = $2->addTypedef();
1566                }
1567        | cfa_typedef_declaration pop ',' push no_attr_identifier
1568                {
1569                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1570                        $$ = $1->appendList( $1->cloneType( $5 ) );
1571                }
1572        ;
1573
1574// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1575// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1576
1577typedef_declaration:
1578        TYPEDEF type_specifier declarator
1579                {
1580                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1581                        $$ = $3->addType( $2 )->addTypedef();
1582                }
1583        | typedef_declaration pop ',' push declarator
1584                {
1585                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1586                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1587                }
1588        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1589                {
1590                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1591                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1592                }
1593        | type_specifier TYPEDEF declarator
1594                {
1595                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1596                        $$ = $3->addType( $1 )->addTypedef();
1597                }
1598        | type_specifier TYPEDEF type_qualifier_list declarator
1599                {
1600                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1601                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1602                }
1603        ;
1604
1605typedef_expression:
1606                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1607        TYPEDEF no_attr_identifier '=' assignment_expression
1608                {
1609                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1610                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1611                }
1612        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1613                {
1614                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1615                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1616                }
1617        ;
1618
1619//c_declaration:
1620//      declaring_list pop ';'
1621//      | typedef_declaration pop ';'
1622//      | typedef_expression pop ';'                                            // GCC, naming expression type
1623//      | sue_declaration_specifier pop ';'
1624//      ;
1625//
1626//declaring_list:
1627//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1628//              // storage-class
1629//       declarator asm_name_opt initializer_opt
1630//              {
1631//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1632//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1633//              }
1634//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1635//              {
1636//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1637//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1638//              }
1639//      ;
1640
1641c_declaration:
1642        declaration_specifier declaring_list
1643                { $$ = distAttr( $1, $2 ); }
1644        | typedef_declaration
1645        | typedef_expression                                                            // GCC, naming expression type
1646        | sue_declaration_specifier
1647        ;
1648
1649declaring_list:
1650                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1651                // storage-class
1652        declarator asm_name_opt initializer_opt
1653                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1654        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1655                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1656        ;
1657
1658declaration_specifier:                                                                  // type specifier + storage class
1659        basic_declaration_specifier
1660        | sue_declaration_specifier
1661        | type_declaration_specifier
1662        ;
1663
1664declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1665                // Preclude SUE declarations in restricted scopes:
1666                //
1667                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1668                //
1669                // because it is impossible to call f due to name equivalence.
1670        basic_declaration_specifier
1671        | sue_declaration_specifier_nobody
1672        | type_declaration_specifier
1673        ;
1674
1675type_specifier:                                                                                 // type specifier
1676        basic_type_specifier
1677        | sue_type_specifier
1678        | type_type_specifier
1679        ;
1680
1681type_specifier_nobody:                                                                  // type specifier - {...}
1682                // Preclude SUE declarations in restricted scopes:
1683                //
1684                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1685                //
1686                // because it is impossible to call f due to name equivalence.
1687        basic_type_specifier
1688        | sue_type_specifier_nobody
1689        | type_type_specifier
1690        ;
1691
1692type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1693        // empty
1694                { $$ = nullptr; }
1695        | type_qualifier_list
1696        ;
1697
1698type_qualifier_list:
1699                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1700                //
1701                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1702                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1703                // appeared only once.
1704        type_qualifier
1705        | type_qualifier_list type_qualifier
1706                { $$ = $1->addQualifiers( $2 ); }
1707        ;
1708
1709type_qualifier:
1710        type_qualifier_name
1711        | attribute
1712        ;
1713
1714type_qualifier_name:
1715        CONST
1716                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1717        | RESTRICT
1718                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1719        | VOLATILE
1720                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1721        | ATOMIC
1722                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1723        | forall
1724        ;
1725
1726forall:
1727        FORALL '(' type_parameter_list ')'                                      // CFA
1728                { $$ = DeclarationNode::newForall( $3 ); }
1729        ;
1730
1731declaration_qualifier_list:
1732        storage_class_list
1733        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1734                { $$ = $1->addQualifiers( $2 ); }
1735        | declaration_qualifier_list type_qualifier_list storage_class_list
1736                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1737        ;
1738
1739storage_class_list:
1740                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1741                // only one of each is specified, except for inline, which can appear with the others.
1742                //
1743                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1744                // specifiers in a declaration.
1745        storage_class
1746        | storage_class_list storage_class
1747                { $$ = $1->addQualifiers( $2 ); }
1748        ;
1749
1750storage_class:
1751        EXTERN
1752                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1753        | STATIC
1754                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1755        | AUTO
1756                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1757        | REGISTER
1758                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1759        | THREADLOCAL                                                                           // C11
1760                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1761                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1762        | INLINE                                                                                        // C99
1763                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1764        | FORTRAN                                                                                       // C99
1765                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1766        | NORETURN                                                                                      // C11
1767                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1768        ;
1769
1770basic_type_name:
1771        VOID
1772                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1773        | BOOL                                                                                          // C99
1774                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1775        | CHAR
1776                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1777        | INT
1778                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1779        | INT128
1780                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1781        | FLOAT
1782                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1783        | DOUBLE
1784                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1785        | uuFLOAT80
1786                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1787        | uuFLOAT128
1788                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1789        | uFLOAT16
1790                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1791        | uFLOAT32
1792                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1793        | uFLOAT32X
1794                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1795        | uFLOAT64
1796                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1797        | uFLOAT64X
1798                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1799        | uFLOAT128
1800                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1801        | COMPLEX                                                                                       // C99
1802                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1803        | IMAGINARY                                                                                     // C99
1804                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1805        | SIGNED
1806                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1807        | UNSIGNED
1808                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1809        | SHORT
1810                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1811        | LONG
1812                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1813        | VALIST                                                                                        // GCC, __builtin_va_list
1814                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1815        ;
1816
1817basic_declaration_specifier:
1818                // A semantic check is necessary for conflicting storage classes.
1819        basic_type_specifier
1820        | declaration_qualifier_list basic_type_specifier
1821                { $$ = $2->addQualifiers( $1 ); }
1822        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1823                { $$ = $1->addQualifiers( $2 ); }
1824        | basic_declaration_specifier storage_class type_qualifier_list
1825                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1826        | basic_declaration_specifier storage_class basic_type_specifier
1827                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1828        ;
1829
1830basic_type_specifier:
1831        direct_type
1832                // Cannot have type modifiers, e.g., short, long, etc.
1833        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1834                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1835        ;
1836
1837direct_type:
1838        basic_type_name
1839        | type_qualifier_list basic_type_name
1840                { $$ = $2->addQualifiers( $1 ); }
1841        | direct_type type_qualifier
1842                { $$ = $1->addQualifiers( $2 ); }
1843        | direct_type basic_type_name
1844                { $$ = $1->addType( $2 ); }
1845        ;
1846
1847indirect_type:
1848        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1849                { $$ = $3; }
1850        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1851                { $$ = DeclarationNode::newTypeof( $3 ); }
1852        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1853                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1854        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1855                { $$ = DeclarationNode::newTypeof( $3, true ); }
1856        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type( x ) y;
1857                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1858        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type( a+b ) y;
1859                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1860        | ZERO_T                                                                                        // CFA
1861                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1862        | ONE_T                                                                                         // CFA
1863                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1864        ;
1865
1866sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1867        sue_type_specifier
1868        | declaration_qualifier_list sue_type_specifier
1869                { $$ = $2->addQualifiers( $1 ); }
1870        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1871                { $$ = $1->addQualifiers( $2 ); }
1872        | sue_declaration_specifier storage_class type_qualifier_list
1873                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1874        ;
1875
1876sue_type_specifier:                                                                             // struct, union, enum + type specifier
1877        elaborated_type
1878        | type_qualifier_list
1879                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1880          elaborated_type
1881                { $$ = $3->addQualifiers( $1 ); }
1882        | sue_type_specifier type_qualifier
1883                {
1884                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1885                        $$ = $1->addQualifiers( $2 );
1886                }
1887        ;
1888
1889sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1890        sue_type_specifier_nobody
1891        | declaration_qualifier_list sue_type_specifier_nobody
1892                { $$ = $2->addQualifiers( $1 ); }
1893        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1894                { $$ = $1->addQualifiers( $2 ); }
1895        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1896                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1897        ;
1898
1899sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1900        elaborated_type_nobody
1901        | type_qualifier_list elaborated_type_nobody
1902                { $$ = $2->addQualifiers( $1 ); }
1903        | sue_type_specifier_nobody type_qualifier
1904                { $$ = $1->addQualifiers( $2 ); }
1905        ;
1906
1907type_declaration_specifier:
1908        type_type_specifier
1909        | declaration_qualifier_list type_type_specifier
1910                { $$ = $2->addQualifiers( $1 ); }
1911        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1912                { $$ = $1->addQualifiers( $2 ); }
1913        | type_declaration_specifier storage_class type_qualifier_list
1914                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1915        ;
1916
1917type_type_specifier:                                                                    // typedef types
1918        type_name
1919        | type_qualifier_list type_name
1920                { $$ = $2->addQualifiers( $1 ); }
1921        | type_type_specifier type_qualifier
1922                { $$ = $1->addQualifiers( $2 ); }
1923        ;
1924
1925type_name:
1926        TYPEDEFname
1927                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1928        | '.' TYPEDEFname
1929                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1930        | type_name '.' TYPEDEFname
1931                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1932        | typegen_name
1933        | '.' typegen_name
1934                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1935        | type_name '.' typegen_name
1936                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1937        ;
1938
1939typegen_name:                                                                                   // CFA
1940        TYPEGENname
1941                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1942        | TYPEGENname '(' ')'
1943                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
1944        | TYPEGENname '(' type_list ')'
1945                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
1946        ;
1947
1948elaborated_type:                                                                                // struct, union, enum
1949        aggregate_type
1950        | enum_type
1951        ;
1952
1953elaborated_type_nobody:                                                                 // struct, union, enum - {...}
1954        aggregate_type_nobody
1955        | enum_type_nobody
1956        ;
1957
1958fred:
1959        // empty
1960                { yyy = false; }
1961        ;
1962
1963aggregate_type:                                                                                 // struct, union
1964        aggregate_key attribute_list_opt
1965                { forall = false; }                                                             // reset
1966          '{' field_declaration_list_opt '}' type_parameters_opt
1967                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
1968        | aggregate_key attribute_list_opt no_attr_identifier fred
1969                {
1970                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
1971                        forall = false;                                                         // reset
1972                }
1973          '{' field_declaration_list_opt '}' type_parameters_opt
1974                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
1975        | aggregate_key attribute_list_opt type_name fred
1976                {
1977                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
1978                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
1979                        forall = false;                                                         // reset
1980                }
1981          '{' field_declaration_list_opt '}' type_parameters_opt
1982                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
1983        | aggregate_type_nobody
1984        ;
1985
1986type_parameters_opt:
1987        // empty
1988                { $$ = nullptr; }                                                               %prec '}'
1989        | '(' type_list ')'
1990                { $$ = $2; }
1991        ;
1992
1993aggregate_type_nobody:                                                                  // struct, union - {...}
1994        aggregate_key attribute_list_opt no_attr_identifier fred
1995                {
1996                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
1997                        forall = false;                                                         // reset
1998                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
1999                }
2000        | aggregate_key attribute_list_opt type_name fred
2001                {
2002                        forall = false;                                                         // reset
2003                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2004                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2005                        // delete newFromTypeGen.
2006                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2007                        $3->type->symbolic.name = nullptr;
2008                        $3->type->symbolic.actuals = nullptr;
2009                        delete $3;
2010                }
2011        ;
2012
2013aggregate_key:
2014        STRUCT
2015                { yyy = true; $$ = DeclarationNode::Struct; }
2016        | UNION
2017                { yyy = true; $$ = DeclarationNode::Union; }
2018        | EXCEPTION
2019                { yyy = true; $$ = DeclarationNode::Exception; }
2020        | COROUTINE
2021                { yyy = true; $$ = DeclarationNode::Coroutine; }
2022        | MONITOR
2023                { yyy = true; $$ = DeclarationNode::Monitor; }
2024        | THREAD
2025                { yyy = true; $$ = DeclarationNode::Thread; }
2026        ;
2027
2028field_declaration_list_opt:
2029        // empty
2030                { $$ = nullptr; }
2031        | field_declaration_list_opt field_declaration
2032                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2033        ;
2034
2035field_declaration:
2036        type_specifier field_declaring_list_opt ';'
2037                { $$ = fieldDecl( $1, $2 ); }
2038        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2039                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2040        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2041                {
2042                        if ( ! $3 ) {                                                           // field declarator ?
2043                                $3 = DeclarationNode::newName( nullptr );
2044                        } // if
2045                        $3->inLine = true;
2046                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2047                        distInl( $3 );
2048                }
2049        | typedef_declaration ';'                                                       // CFA
2050        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2051        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2052                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2053        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2054                { $$ = $2; }                                                                    // mark all fields in list
2055        | cfa_typedef_declaration ';'                                           // CFA
2056        | static_assert                                                                         // C11
2057        ;
2058
2059field_declaring_list_opt:
2060        // empty
2061                { $$ = nullptr; }
2062        | field_declarator
2063        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2064                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2065        ;
2066
2067field_declarator:
2068        bit_subrange_size                                                                       // C special case, no field name
2069                { $$ = DeclarationNode::newBitfield( $1 ); }
2070        | variable_declarator bit_subrange_size_opt
2071                // A semantic check is required to ensure bit_subrange only appears on integral types.
2072                { $$ = $1->addBitfield( $2 ); }
2073        | variable_type_redeclarator bit_subrange_size_opt
2074                // A semantic check is required to ensure bit_subrange only appears on integral types.
2075                { $$ = $1->addBitfield( $2 ); }
2076        ;
2077
2078field_abstract_list_opt:
2079        // empty
2080                { $$ = nullptr; }
2081        | field_abstract
2082        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2083                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2084        ;
2085
2086field_abstract:
2087                //      no bit fields
2088        variable_abstract_declarator
2089        ;
2090
2091cfa_field_declaring_list:                                                               // CFA, new style field declaration
2092        // bit-fields are handled by C declarations
2093        cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
2094                { $$ = $1->addName( $2 ); }
2095        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
2096                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2097        ;
2098
2099cfa_field_abstract_list:                                                                // CFA, new style field declaration
2100        // bit-fields are handled by C declarations
2101        cfa_abstract_declarator_tuple
2102        | cfa_field_abstract_list ','
2103                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2104        ;
2105
2106bit_subrange_size_opt:
2107        // empty
2108                { $$ = nullptr; }
2109        | bit_subrange_size
2110        ;
2111
2112bit_subrange_size:
2113        ':' constant_expression
2114                { $$ = $2; }
2115        ;
2116
2117enum_type:                                                                                              // enum
2118        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2119                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2120        | ENUM attribute_list_opt no_attr_identifier
2121                { typedefTable.makeTypedef( *$3 ); }
2122          '{' enumerator_list comma_opt '}'
2123                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2124        | ENUM attribute_list_opt type_name
2125          '{' enumerator_list comma_opt '}'
2126                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2127        | enum_type_nobody
2128        ;
2129
2130enum_type_nobody:                                                                               // enum - {...}
2131        ENUM attribute_list_opt no_attr_identifier
2132                {
2133                        typedefTable.makeTypedef( *$3 );
2134                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2135                }
2136        | ENUM attribute_list_opt type_name
2137                {
2138                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2139                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2140                }
2141        ;
2142
2143enumerator_list:
2144        no_attr_identifier_or_type_name enumerator_value_opt
2145                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2146        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
2147                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2148        ;
2149
2150enumerator_value_opt:
2151        // empty
2152                { $$ = nullptr; }
2153        | '=' constant_expression
2154                { $$ = $2; }
2155        ;
2156
2157cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2158        // empty
2159                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2160        | ELLIPSIS
2161                { $$ = nullptr; }
2162        | cfa_abstract_parameter_list
2163        | cfa_parameter_list
2164        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2165                { $$ = $1->appendList( $5 ); }
2166        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2167                { $$ = $1->addVarArgs(); }
2168        | cfa_parameter_list pop ',' push ELLIPSIS
2169                { $$ = $1->addVarArgs(); }
2170        ;
2171
2172cfa_parameter_list:                                                                             // CFA
2173                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2174                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2175        cfa_parameter_declaration
2176        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2177                { $$ = $1->appendList( $5 ); }
2178        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2179                { $$ = $1->appendList( $5 ); }
2180        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2181                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2182        ;
2183
2184cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2185        cfa_abstract_parameter_declaration
2186        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2187                { $$ = $1->appendList( $5 ); }
2188        ;
2189
2190parameter_type_list_opt:
2191        // empty
2192                { $$ = nullptr; }
2193        | ELLIPSIS
2194                { $$ = nullptr; }
2195        | parameter_list
2196        | parameter_list pop ',' push ELLIPSIS
2197                { $$ = $1->addVarArgs(); }
2198        ;
2199
2200parameter_list:                                                                                 // abstract + real
2201        abstract_parameter_declaration
2202        | parameter_declaration
2203        | parameter_list pop ',' push abstract_parameter_declaration
2204                { $$ = $1->appendList( $5 ); }
2205        | parameter_list pop ',' push parameter_declaration
2206                { $$ = $1->appendList( $5 ); }
2207        ;
2208
2209// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2210// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2211
2212cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2213        parameter_declaration
2214        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2215                { $$ = $1->addName( $2 ); }
2216        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2217                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2218                { $$ = $1->addName( $2 ); }
2219        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2220                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2221        | cfa_function_specifier
2222        ;
2223
2224cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2225        abstract_parameter_declaration
2226        | cfa_identifier_parameter_declarator_no_tuple
2227        | cfa_abstract_tuple
2228                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2229        | type_qualifier_list cfa_abstract_tuple
2230                { $$ = $2->addQualifiers( $1 ); }
2231        | cfa_abstract_function
2232        ;
2233
2234parameter_declaration:
2235                // No SUE declaration in parameter list.
2236        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2237                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2238        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2239                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2240        ;
2241
2242abstract_parameter_declaration:
2243        declaration_specifier_nobody default_initialize_opt
2244                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2245        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2246                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2247        ;
2248
2249// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2250// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2251// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2252
2253identifier_list:                                                                                // K&R-style parameter list => no types
2254        no_attr_identifier
2255                { $$ = DeclarationNode::newName( $1 ); }
2256        | identifier_list ',' no_attr_identifier
2257                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2258        ;
2259
2260identifier_or_type_name:
2261        identifier
2262        | TYPEDEFname
2263        | TYPEGENname
2264        ;
2265
2266no_attr_identifier_or_type_name:
2267        no_attr_identifier
2268        | TYPEDEFname
2269        | TYPEGENname
2270        ;
2271
2272type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2273        cfa_abstract_declarator_tuple                                           // CFA
2274        | type_specifier
2275        | type_specifier abstract_declarator
2276                { $$ = $2->addType( $1 ); }
2277        ;
2278
2279type:                                                                                                   // typeof, assertion
2280        type_no_function
2281        | cfa_abstract_function                                                         // CFA
2282        ;
2283
2284initializer_opt:
2285        // empty
2286                { $$ = nullptr; }
2287        | '=' initializer
2288                { $$ = $2; }
2289        | '=' VOID
2290                { $$ = new InitializerNode( true ); }
2291        | ATassign initializer
2292                { $$ = $2->set_maybeConstructed( false ); }
2293        ;
2294
2295initializer:
2296        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2297        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2298        ;
2299
2300initializer_list_opt:
2301        // empty
2302                { $$ = nullptr; }
2303        | initializer
2304        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2305        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2306        | initializer_list_opt ',' designation initializer
2307                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2308        ;
2309
2310// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2311// '=' to separator the designator from the initializer value, as in:
2312//
2313//              int x[10] = { [1] = 3 };
2314//
2315// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2316// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2317// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2318// shift/reduce conflicts
2319
2320designation:
2321        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2322        | no_attr_identifier ':'                                                        // GCC, field name
2323                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2324        ;
2325
2326designator_list:                                                                                // C99
2327        designator
2328        | designator_list designator
2329                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2330        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2331        ;
2332
2333designator:
2334        '.' no_attr_identifier                                                          // C99, field name
2335                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2336        | '[' push assignment_expression pop ']'                        // C99, single array element
2337                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2338                { $$ = $3; }
2339        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2340                { $$ = $3; }
2341        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2342                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2343        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2344                { $$ = $4; }
2345        ;
2346
2347// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2348// rather than an object-oriented type system. This required four groups of extensions:
2349//
2350// Overloading: function, data, and operator identifiers may be overloaded.
2351//
2352// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2353//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2354//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2355//
2356// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2357//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2358//
2359// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2360//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2361//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2362//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2363//     on type arguments of polymorphic functions.
2364
2365type_parameter_list:                                                                    // CFA
2366        type_parameter
2367        | type_parameter_list ',' type_parameter
2368                { $$ = $1->appendList( $3 ); }
2369        ;
2370
2371type_initializer_opt:                                                                   // CFA
2372        // empty
2373                { $$ = nullptr; }
2374        | '=' type
2375                { $$ = $2; }
2376        ;
2377
2378type_parameter:                                                                                 // CFA
2379        type_class no_attr_identifier_or_type_name
2380                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2381          type_initializer_opt assertion_list_opt
2382                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2383        | type_specifier identifier_parameter_declarator
2384        | assertion_list
2385                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2386        ;
2387
2388type_class:                                                                                             // CFA
2389        OTYPE
2390                { $$ = DeclarationNode::Otype; }
2391        | DTYPE
2392                { $$ = DeclarationNode::Dtype; }
2393        | FTYPE
2394                { $$ = DeclarationNode::Ftype; }
2395        | TTYPE
2396                { $$ = DeclarationNode::Ttype; }
2397        ;
2398
2399assertion_list_opt:                                                                             // CFA
2400        // empty
2401                { $$ = nullptr; }
2402        | assertion_list
2403        ;
2404
2405assertion_list:                                                                                 // CFA
2406        assertion
2407        | assertion_list assertion
2408                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2409        ;
2410
2411assertion:                                                                                              // CFA
2412        '|' no_attr_identifier_or_type_name '(' type_list ')'
2413                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2414        | '|' '{' push trait_declaration_list pop '}'
2415                { $$ = $4; }
2416        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2417        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2418        ;
2419
2420type_list:                                                                                              // CFA
2421        type
2422                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2423        | assignment_expression
2424                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2425        | type_list ',' type
2426                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2427        | type_list ',' assignment_expression
2428                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2429                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2430        ;
2431
2432type_declaring_list:                                                                    // CFA
2433        OTYPE type_declarator
2434                { $$ = $2; }
2435        | storage_class_list OTYPE type_declarator
2436                { $$ = $3->addQualifiers( $1 ); }
2437        | type_declaring_list ',' type_declarator
2438                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2439        ;
2440
2441type_declarator:                                                                                // CFA
2442        type_declarator_name assertion_list_opt
2443                { $$ = $1->addAssertions( $2 ); }
2444        | type_declarator_name assertion_list_opt '=' type
2445                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2446        ;
2447
2448type_declarator_name:                                                                   // CFA
2449        no_attr_identifier_or_type_name
2450                {
2451                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2452                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2453                }
2454        | no_attr_identifier_or_type_name '(' type_parameter_list ')'
2455                {
2456                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2457                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2458                }
2459        ;
2460
2461trait_specifier:                                                                                // CFA
2462        TRAIT no_attr_identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2463                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2464        | TRAIT no_attr_identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2465                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2466        ;
2467
2468trait_declaration_list:                                                                 // CFA
2469        trait_declaration
2470        | trait_declaration_list pop push trait_declaration
2471                { $$ = $1->appendList( $4 ); }
2472        ;
2473
2474trait_declaration:                                                                              // CFA
2475        cfa_trait_declaring_list ';'
2476        | trait_declaring_list ';'
2477        ;
2478
2479cfa_trait_declaring_list:                                                               // CFA
2480        cfa_variable_specifier
2481        | cfa_function_specifier
2482        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2483                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2484        ;
2485
2486trait_declaring_list:                                                                   // CFA
2487        type_specifier declarator
2488                { $$ = $2->addType( $1 ); }
2489        | trait_declaring_list pop ',' push declarator
2490                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2491        ;
2492
2493//***************************** EXTERNAL DEFINITIONS *****************************
2494
2495translation_unit:
2496        // empty, input file
2497        | external_definition_list
2498                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2499        ;
2500
2501external_definition_list:
2502        push external_definition pop
2503                { $$ = $2; }
2504        | external_definition_list push external_definition pop
2505                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2506        ;
2507
2508external_definition_list_opt:
2509        // empty
2510                { $$ = nullptr; }
2511        | external_definition_list
2512        ;
2513
2514up:
2515                { typedefTable.up( forall ); forall = false; }
2516        ;
2517
2518down:
2519                { typedefTable.down(); }
2520        ;
2521
2522external_definition:
2523        declaration
2524        | external_function_definition
2525        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2526                {
2527                        distExt( $2 );                                                          // mark all fields in list
2528                        $$ = $2;
2529                }
2530        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2531                {
2532                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2533                }
2534        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2535                {
2536                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2537                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2538                }
2539          '{' up external_definition_list_opt down '}'
2540                {
2541                        linkage = linkageStack.top();
2542                        linkageStack.pop();
2543                        $$ = $6;
2544                }
2545        | type_qualifier_list
2546                {
2547                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2548                        if ( $1->type->forall ) forall = true;          // remember generic type
2549                }
2550          '{' up external_definition_list_opt down '}'          // CFA, namespace
2551                {
2552                        distQual( $5, $1 );
2553                        forall = false;
2554                        $$ = $5;
2555                }
2556        | declaration_qualifier_list
2557                {
2558                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2559                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2560                }
2561          '{' up external_definition_list_opt down '}'          // CFA, namespace
2562                {
2563                        distQual( $5, $1 );
2564                        forall = false;
2565                        $$ = $5;
2566                }
2567        | declaration_qualifier_list type_qualifier_list
2568                {
2569                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2570                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2571                }
2572          '{' up external_definition_list_opt down '}'          // CFA, namespace
2573                {
2574                        distQual( $6, $1->addQualifiers( $2 ) );
2575                        forall = false;
2576                        $$ = $6;
2577                }
2578        ;
2579
2580external_function_definition:
2581        function_definition
2582                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2583                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2584                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2585                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2586                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2587        | function_declarator compound_statement
2588                { $$ = $1->addFunctionBody( $2 ); }
2589        | KR_function_declarator KR_parameter_list_opt compound_statement
2590                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2591        ;
2592
2593with_clause_opt:
2594        // empty
2595                { $$ = nullptr; forall = false; }
2596        | WITH '(' tuple_expression_list ')'
2597                { $$ = $3; forall = false; }
2598        ;
2599
2600function_definition:
2601        cfa_function_declaration with_clause_opt compound_statement     // CFA
2602                {
2603                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2604                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2605                        $1->get_last()->addFunctionBody( $3, $2 );
2606                        $$ = $1;
2607                }
2608        | declaration_specifier function_declarator with_clause_opt compound_statement
2609                {
2610                        rebindForall( $1, $2 );
2611                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2612                }
2613        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2614                {
2615                        rebindForall( $1, $2 );
2616                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2617                }
2618                // handles default int return type, OBSOLESCENT (see 1)
2619        | type_qualifier_list function_declarator with_clause_opt compound_statement
2620                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2621                // handles default int return type, OBSOLESCENT (see 1)
2622        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2623                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2624                // handles default int return type, OBSOLESCENT (see 1)
2625        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2626                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2627
2628                // Old-style K&R function definition, OBSOLESCENT (see 4)
2629        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2630                {
2631                        rebindForall( $1, $2 );
2632                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2633                }
2634                // handles default int return type, OBSOLESCENT (see 1)
2635        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2636                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2637                // handles default int return type, OBSOLESCENT (see 1)
2638        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2639                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2640                // handles default int return type, OBSOLESCENT (see 1)
2641        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2642                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2643        ;
2644
2645declarator:
2646        variable_declarator
2647        | variable_type_redeclarator
2648        | function_declarator
2649        ;
2650
2651subrange:
2652        constant_expression '~' constant_expression                     // CFA, integer subrange
2653                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2654        ;
2655
2656asm_name_opt:                                                                                   // GCC
2657        // empty
2658                { $$ = nullptr; }
2659        | ASM '(' string_literal ')' attribute_list_opt
2660                {
2661                        DeclarationNode * name = new DeclarationNode();
2662                        name->asmName = $3;
2663                        $$ = name->addQualifiers( $5 );
2664                }
2665        ;
2666
2667attribute_list_opt:                                                                             // GCC
2668        // empty
2669                { $$ = nullptr; }
2670        | attribute_list
2671        ;
2672
2673attribute_list:                                                                                 // GCC
2674        attribute
2675        | attribute_list attribute
2676                { $$ = $2->addQualifiers( $1 ); }
2677        ;
2678
2679attribute:                                                                                              // GCC
2680        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2681                { $$ = $4; }
2682        ;
2683
2684attribute_name_list:                                                                    // GCC
2685        attribute_name
2686        | attribute_name_list ',' attribute_name
2687                { $$ = $3->addQualifiers( $1 ); }
2688        ;
2689
2690attribute_name:                                                                                 // GCC
2691        // empty
2692                { $$ = nullptr; }
2693        | attr_name
2694                { $$ = DeclarationNode::newAttribute( $1 ); }
2695        | attr_name '(' argument_expression_list ')'
2696                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2697        ;
2698
2699attr_name:                                                                                              // GCC
2700        IDENTIFIER
2701        | quasi_keyword
2702        | TYPEDEFname
2703        | TYPEGENname
2704        | FALLTHROUGH
2705                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2706        | CONST
2707                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2708        ;
2709
2710// ============================================================================
2711// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2712// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2713// in:
2714//
2715//              int (*f())[10] { ... };
2716//              ... (*f())[3] += 1;             // definition mimics usage
2717//
2718// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2719// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2720// ============================================================================
2721
2722// ----------------------------------------------------------------------------
2723// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2724// to define a variable or function prototype, e.g.:
2725//
2726//              valid declaration               invalid definition
2727//              -----------------               ------------------
2728//              int f;                                  int f {}
2729//              int *f;                                 int *f {}
2730//              int f[10];                              int f[10] {}
2731//              int (*f)(int);                  int (*f)(int) {}
2732//
2733// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2734// variable_declarator and function_declarator.
2735// ----------------------------------------------------------------------------
2736
2737// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2738// declaring an array of functions versus a pointer to an array of functions.
2739
2740variable_declarator:
2741        paren_identifier attribute_list_opt
2742                { $$ = $1->addQualifiers( $2 ); }
2743        | variable_ptr
2744        | variable_array attribute_list_opt
2745                { $$ = $1->addQualifiers( $2 ); }
2746        | variable_function attribute_list_opt
2747                { $$ = $1->addQualifiers( $2 ); }
2748        ;
2749
2750paren_identifier:
2751        identifier
2752                { $$ = DeclarationNode::newName( $1 ); }
2753        | '(' paren_identifier ')'                                                      // redundant parenthesis
2754                { $$ = $2; }
2755        ;
2756
2757variable_ptr:
2758        ptrref_operator variable_declarator
2759                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2760        | ptrref_operator type_qualifier_list variable_declarator
2761                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2762        | '(' variable_ptr ')' attribute_list_opt
2763                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2764        ;
2765
2766variable_array:
2767        paren_identifier array_dimension
2768                { $$ = $1->addArray( $2 ); }
2769        | '(' variable_ptr ')' array_dimension
2770                { $$ = $2->addArray( $4 ); }
2771        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2772                { $$ = $2->addArray( $4 ); }
2773        | '(' variable_array ')'                                                        // redundant parenthesis
2774                { $$ = $2; }
2775        ;
2776
2777variable_function:
2778        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2779                { $$ = $2->addParamList( $6 ); }
2780        | '(' variable_function ')'                                                     // redundant parenthesis
2781                { $$ = $2; }
2782        ;
2783
2784// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2785// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2786// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2787
2788function_declarator:
2789        function_no_ptr attribute_list_opt
2790                { $$ = $1->addQualifiers( $2 ); }
2791        | function_ptr
2792        | function_array attribute_list_opt
2793                { $$ = $1->addQualifiers( $2 ); }
2794        ;
2795
2796function_no_ptr:
2797        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2798                { $$ = $1->addParamList( $4 ); }
2799        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2800                { $$ = $2->addParamList( $6 ); }
2801        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2802                { $$ = $2; }
2803        ;
2804
2805function_ptr:
2806        ptrref_operator function_declarator
2807                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2808        | ptrref_operator type_qualifier_list function_declarator
2809                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2810        | '(' function_ptr ')'
2811                { $$ = $2; }
2812        ;
2813
2814function_array:
2815        '(' function_ptr ')' array_dimension
2816                { $$ = $2->addArray( $4 ); }
2817        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2818                { $$ = $2->addArray( $4 ); }
2819        | '(' function_array ')'                                                        // redundant parenthesis
2820                { $$ = $2; }
2821        ;
2822
2823// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2824//
2825//   f( a, b, c ) int a, *b, c[]; {}
2826//
2827// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2828// returning arrays and functions versus pointers to arrays and functions.
2829
2830KR_function_declarator:
2831        KR_function_no_ptr
2832        | KR_function_ptr
2833        | KR_function_array
2834        ;
2835
2836KR_function_no_ptr:
2837        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2838                { $$ = $1->addIdList( $3 ); }
2839        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2840                { $$ = $2->addParamList( $6 ); }
2841        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2842                { $$ = $2; }
2843        ;
2844
2845KR_function_ptr:
2846        ptrref_operator KR_function_declarator
2847                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2848        | ptrref_operator type_qualifier_list KR_function_declarator
2849                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2850        | '(' KR_function_ptr ')'
2851                { $$ = $2; }
2852        ;
2853
2854KR_function_array:
2855        '(' KR_function_ptr ')' array_dimension
2856                { $$ = $2->addArray( $4 ); }
2857        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2858                { $$ = $2->addArray( $4 ); }
2859        | '(' KR_function_array ')'                                                     // redundant parenthesis
2860                { $$ = $2; }
2861        ;
2862
2863// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2864//
2865//              typedef int foo;
2866//              {
2867//                 int foo; // redefine typedef name in new scope
2868//              }
2869//
2870// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2871// and functions versus pointers to arrays and functions.
2872
2873variable_type_redeclarator:
2874        paren_type attribute_list_opt
2875                { $$ = $1->addQualifiers( $2 ); }
2876        | type_ptr
2877        | type_array attribute_list_opt
2878                { $$ = $1->addQualifiers( $2 ); }
2879        | type_function attribute_list_opt
2880                { $$ = $1->addQualifiers( $2 ); }
2881        ;
2882
2883paren_type:
2884        typedef
2885                // hide type name in enclosing scope by variable name
2886                {
2887                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2888                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2889                        // } else {
2890                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2891                        // } // if
2892                }
2893        | '(' paren_type ')'
2894                { $$ = $2; }
2895        ;
2896
2897type_ptr:
2898        ptrref_operator variable_type_redeclarator
2899                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2900        | ptrref_operator type_qualifier_list variable_type_redeclarator
2901                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2902        | '(' type_ptr ')' attribute_list_opt
2903                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2904        ;
2905
2906type_array:
2907        paren_type array_dimension
2908                { $$ = $1->addArray( $2 ); }
2909        | '(' type_ptr ')' array_dimension
2910                { $$ = $2->addArray( $4 ); }
2911        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2912                { $$ = $2->addArray( $4 ); }
2913        | '(' type_array ')'                                                            // redundant parenthesis
2914                { $$ = $2; }
2915        ;
2916
2917type_function:
2918        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2919                { $$ = $1->addParamList( $4 ); }
2920        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2921                { $$ = $2->addParamList( $6 ); }
2922        | '(' type_function ')'                                                         // redundant parenthesis
2923                { $$ = $2; }
2924        ;
2925
2926// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2927// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2928// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2929// pointers to arrays and functions.
2930
2931identifier_parameter_declarator:
2932        paren_identifier attribute_list_opt
2933                { $$ = $1->addQualifiers( $2 ); }
2934        | '&' MUTEX paren_identifier attribute_list_opt
2935                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2936        | identifier_parameter_ptr
2937        | identifier_parameter_array attribute_list_opt
2938                { $$ = $1->addQualifiers( $2 ); }
2939        | identifier_parameter_function attribute_list_opt
2940                { $$ = $1->addQualifiers( $2 ); }
2941        ;
2942
2943identifier_parameter_ptr:
2944        ptrref_operator identifier_parameter_declarator
2945                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2946        | ptrref_operator type_qualifier_list identifier_parameter_declarator
2947                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2948        | '(' identifier_parameter_ptr ')' attribute_list_opt
2949                { $$ = $2->addQualifiers( $4 ); }
2950        ;
2951
2952identifier_parameter_array:
2953        paren_identifier array_parameter_dimension
2954                { $$ = $1->addArray( $2 ); }
2955        | '(' identifier_parameter_ptr ')' array_dimension
2956                { $$ = $2->addArray( $4 ); }
2957        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
2958                { $$ = $2->addArray( $4 ); }
2959        | '(' identifier_parameter_array ')'                            // redundant parenthesis
2960                { $$ = $2; }
2961        ;
2962
2963identifier_parameter_function:
2964        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2965                { $$ = $1->addParamList( $4 ); }
2966        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2967                { $$ = $2->addParamList( $6 ); }
2968        | '(' identifier_parameter_function ')'                         // redundant parenthesis
2969                { $$ = $2; }
2970        ;
2971
2972// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
2973// e.g.:
2974//
2975//              typedef int foo;
2976//              forall( otype T ) struct foo;
2977//              int f( int foo ); // redefine typedef name in new scope
2978//
2979// and allows the C99 array options, which can only appear in a parameter list.
2980
2981type_parameter_redeclarator:
2982        typedef attribute_list_opt
2983                { $$ = $1->addQualifiers( $2 ); }
2984        | '&' MUTEX typedef attribute_list_opt
2985                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2986        | type_parameter_ptr
2987        | type_parameter_array attribute_list_opt
2988                { $$ = $1->addQualifiers( $2 ); }
2989        | type_parameter_function attribute_list_opt
2990                { $$ = $1->addQualifiers( $2 ); }
2991        ;
2992
2993typedef:
2994        TYPEDEFname
2995                { $$ = DeclarationNode::newName( $1 ); }
2996        | TYPEGENname
2997                { $$ = DeclarationNode::newName( $1 ); }
2998        ;
2999
3000type_parameter_ptr:
3001        ptrref_operator type_parameter_redeclarator
3002                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3003        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3004                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3005        | '(' type_parameter_ptr ')' attribute_list_opt
3006                { $$ = $2->addQualifiers( $4 ); }
3007        ;
3008
3009type_parameter_array:
3010        typedef array_parameter_dimension
3011                { $$ = $1->addArray( $2 ); }
3012        | '(' type_parameter_ptr ')' array_parameter_dimension
3013                { $$ = $2->addArray( $4 ); }
3014        ;
3015
3016type_parameter_function:
3017        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3018                { $$ = $1->addParamList( $4 ); }
3019        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3020                { $$ = $2->addParamList( $6 ); }
3021        ;
3022
3023// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3024// which the type applies, e.g.:
3025//
3026//              sizeof( int );
3027//              sizeof( int * );
3028//              sizeof( int [10] );
3029//              sizeof( int (*)() );
3030//              sizeof( int () );
3031//
3032// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3033// and functions versus pointers to arrays and functions.
3034
3035abstract_declarator:
3036        abstract_ptr
3037        | abstract_array attribute_list_opt
3038                { $$ = $1->addQualifiers( $2 ); }
3039        | abstract_function attribute_list_opt
3040                { $$ = $1->addQualifiers( $2 ); }
3041        ;
3042
3043abstract_ptr:
3044        ptrref_operator
3045                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3046        | ptrref_operator type_qualifier_list
3047                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3048        | ptrref_operator abstract_declarator
3049                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3050        | ptrref_operator type_qualifier_list abstract_declarator
3051                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3052        | '(' abstract_ptr ')' attribute_list_opt
3053                { $$ = $2->addQualifiers( $4 ); }
3054        ;
3055
3056abstract_array:
3057        array_dimension
3058        | '(' abstract_ptr ')' array_dimension
3059                { $$ = $2->addArray( $4 ); }
3060        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3061                { $$ = $2->addArray( $4 ); }
3062        | '(' abstract_array ')'                                                        // redundant parenthesis
3063                { $$ = $2; }
3064        ;
3065
3066abstract_function:
3067        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3068                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3069        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3070                { $$ = $2->addParamList( $6 ); }
3071        | '(' abstract_function ')'                                                     // redundant parenthesis
3072                { $$ = $2; }
3073        ;
3074
3075array_dimension:
3076                // Only the first dimension can be empty.
3077        '[' ']'
3078                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3079        | '[' ']' multi_array_dimension
3080                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3081        | multi_array_dimension
3082        ;
3083
3084multi_array_dimension:
3085        '[' push assignment_expression pop ']'
3086                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3087        | '[' push '*' pop ']'                                                          // C99
3088                { $$ = DeclarationNode::newVarArray( 0 ); }
3089        | multi_array_dimension '[' push assignment_expression pop ']'
3090                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3091        | multi_array_dimension '[' push '*' pop ']'            // C99
3092                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3093        ;
3094
3095// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3096// identifier to which the type applies, e.g.:
3097//
3098//              int f( int );                   // not handled here
3099//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3100//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3101//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3102//
3103// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3104// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3105// special meaning of parenthesis around a typedef name:
3106//
3107//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3108//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3109//              not as redundant parentheses around the identifier."
3110//
3111// For example:
3112//
3113//              typedef float T;
3114//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3115//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3116//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3117//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3118//
3119// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3120// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3121// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3122// functions.
3123
3124abstract_parameter_declarator:
3125        abstract_parameter_ptr
3126        | '&' MUTEX attribute_list_opt
3127                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3128        | abstract_parameter_array attribute_list_opt
3129                { $$ = $1->addQualifiers( $2 ); }
3130        | abstract_parameter_function attribute_list_opt
3131                { $$ = $1->addQualifiers( $2 ); }
3132        ;
3133
3134abstract_parameter_ptr:
3135        ptrref_operator
3136                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3137        | ptrref_operator type_qualifier_list
3138                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3139        | ptrref_operator abstract_parameter_declarator
3140                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3141        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3142                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3143        | '(' abstract_parameter_ptr ')' attribute_list_opt
3144                { $$ = $2->addQualifiers( $4 ); }
3145        ;
3146
3147abstract_parameter_array:
3148        array_parameter_dimension
3149        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3150                { $$ = $2->addArray( $4 ); }
3151        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3152                { $$ = $2->addArray( $4 ); }
3153        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3154                { $$ = $2; }
3155        ;
3156
3157abstract_parameter_function:
3158        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3159                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3160        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3161                { $$ = $2->addParamList( $6 ); }
3162        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3163                { $$ = $2; }
3164        ;
3165
3166array_parameter_dimension:
3167                // Only the first dimension can be empty or have qualifiers.
3168        array_parameter_1st_dimension
3169        | array_parameter_1st_dimension multi_array_dimension
3170                { $$ = $1->addArray( $2 ); }
3171        | multi_array_dimension
3172        ;
3173
3174// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3175//
3176//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3177//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3178
3179array_parameter_1st_dimension:
3180        '[' ']'
3181                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3182                // multi_array_dimension handles the '[' '*' ']' case
3183        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3184                { $$ = DeclarationNode::newVarArray( $3 ); }
3185        | '[' push type_qualifier_list pop ']'
3186                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3187                // multi_array_dimension handles the '[' assignment_expression ']' case
3188        | '[' push type_qualifier_list assignment_expression pop ']'
3189                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3190        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3191                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3192        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3193                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3194        ;
3195
3196// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3197//
3198//              struct S {
3199//          int;
3200//          int *;
3201//          int [10];
3202//          int (*)();
3203//      };
3204
3205variable_abstract_declarator:
3206        variable_abstract_ptr
3207        | variable_abstract_array attribute_list_opt
3208                { $$ = $1->addQualifiers( $2 ); }
3209        | variable_abstract_function attribute_list_opt
3210                { $$ = $1->addQualifiers( $2 ); }
3211        ;
3212
3213variable_abstract_ptr:
3214        ptrref_operator
3215                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3216        | ptrref_operator type_qualifier_list
3217                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3218        | ptrref_operator variable_abstract_declarator
3219                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3220        | ptrref_operator type_qualifier_list variable_abstract_declarator
3221                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3222        | '(' variable_abstract_ptr ')' attribute_list_opt
3223                { $$ = $2->addQualifiers( $4 ); }
3224        ;
3225
3226variable_abstract_array:
3227        array_dimension
3228        | '(' variable_abstract_ptr ')' array_dimension
3229                { $$ = $2->addArray( $4 ); }
3230        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3231                { $$ = $2->addArray( $4 ); }
3232        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3233                { $$ = $2; }
3234        ;
3235
3236variable_abstract_function:
3237        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3238                { $$ = $2->addParamList( $6 ); }
3239        | '(' variable_abstract_function ')'                            // redundant parenthesis
3240                { $$ = $2; }
3241        ;
3242
3243// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3244// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3245
3246cfa_identifier_parameter_declarator_tuple:                              // CFA
3247        cfa_identifier_parameter_declarator_no_tuple
3248        | cfa_abstract_tuple
3249        | type_qualifier_list cfa_abstract_tuple
3250                { $$ = $2->addQualifiers( $1 ); }
3251        ;
3252
3253cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3254        cfa_identifier_parameter_ptr
3255        | cfa_identifier_parameter_array
3256        ;
3257
3258cfa_identifier_parameter_ptr:                                                   // CFA
3259                // No SUE declaration in parameter list.
3260        ptrref_operator type_specifier_nobody
3261                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3262        | type_qualifier_list ptrref_operator type_specifier_nobody
3263                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3264        | ptrref_operator cfa_abstract_function
3265                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3266        | type_qualifier_list ptrref_operator cfa_abstract_function
3267                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3268        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3269                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3270        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3271                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3272        ;
3273
3274cfa_identifier_parameter_array:                                                 // CFA
3275                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3276                // shift/reduce conflict with new-style empty (void) function return type.
3277        '[' ']' type_specifier_nobody
3278                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3279        | cfa_array_parameter_1st_dimension type_specifier_nobody
3280                { $$ = $2->addNewArray( $1 ); }
3281        | '[' ']' multi_array_dimension type_specifier_nobody
3282                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3283        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3284                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3285        | multi_array_dimension type_specifier_nobody
3286                { $$ = $2->addNewArray( $1 ); }
3287
3288        | '[' ']' cfa_identifier_parameter_ptr
3289                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3290        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3291                { $$ = $2->addNewArray( $1 ); }
3292        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3293                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3294        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3295                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3296        | multi_array_dimension cfa_identifier_parameter_ptr
3297                { $$ = $2->addNewArray( $1 ); }
3298        ;
3299
3300cfa_array_parameter_1st_dimension:
3301        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3302                { $$ = DeclarationNode::newVarArray( $3 ); }
3303        | '[' push type_qualifier_list assignment_expression pop ']'
3304                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3305        | '[' push declaration_qualifier_list assignment_expression pop ']'
3306                // declaration_qualifier_list must be used because of shift/reduce conflict with
3307                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3308                // appear in this context.
3309                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3310        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3311                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3312        ;
3313
3314// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3315// identifier to which the type applies, e.g.:
3316//
3317//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3318//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3319//
3320// These rules need LR(3):
3321//
3322//              cfa_abstract_tuple identifier_or_type_name
3323//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3324//
3325// since a function return type can be syntactically identical to a tuple type:
3326//
3327//              [int, int] t;
3328//              [int, int] f( int );
3329//
3330// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3331// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3332// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3333// duplicated when appearing with cfa_function_specifier.
3334
3335cfa_abstract_declarator_tuple:                                                  // CFA
3336        cfa_abstract_tuple
3337        | type_qualifier_list cfa_abstract_tuple
3338                { $$ = $2->addQualifiers( $1 ); }
3339        | cfa_abstract_declarator_no_tuple
3340        ;
3341
3342cfa_abstract_declarator_no_tuple:                                               // CFA
3343        cfa_abstract_ptr
3344        | cfa_abstract_array
3345        ;
3346
3347cfa_abstract_ptr:                                                                               // CFA
3348        ptrref_operator type_specifier
3349                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3350        | type_qualifier_list ptrref_operator type_specifier
3351                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3352        | ptrref_operator cfa_abstract_function
3353                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3354        | type_qualifier_list ptrref_operator cfa_abstract_function
3355                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3356        | ptrref_operator cfa_abstract_declarator_tuple
3357                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3358        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3359                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3360        ;
3361
3362cfa_abstract_array:                                                                             // CFA
3363                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3364                // empty (void) function return type.
3365        '[' ']' type_specifier
3366                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3367        | '[' ']' multi_array_dimension type_specifier
3368                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3369        | multi_array_dimension type_specifier
3370                { $$ = $2->addNewArray( $1 ); }
3371        | '[' ']' cfa_abstract_ptr
3372                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3373        | '[' ']' multi_array_dimension cfa_abstract_ptr
3374                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3375        | multi_array_dimension cfa_abstract_ptr
3376                { $$ = $2->addNewArray( $1 ); }
3377        ;
3378
3379cfa_abstract_tuple:                                                                             // CFA
3380        '[' push cfa_abstract_parameter_list pop ']'
3381                { $$ = DeclarationNode::newTuple( $3 ); }
3382        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3383                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3384        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3385                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3386        ;
3387
3388cfa_abstract_function:                                                                  // CFA
3389//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3390//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3391        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3392                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3393        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3394                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3395        ;
3396
3397// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3398//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3399//
3400// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3401//    the declaration specifiers in a declaration is an obsolescent feature."
3402//
3403// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3404//    prototype-format parameter type declarators) is an obsolescent feature."
3405//
3406// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3407//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3408
3409//************************* MISCELLANEOUS ********************************
3410
3411comma_opt:                                                                                              // redundant comma
3412        // empty
3413        | ','
3414        ;
3415
3416default_initialize_opt:
3417        // empty
3418                { $$ = nullptr; }
3419        | '=' assignment_expression
3420                { $$ = $2; }
3421        ;
3422
3423%%
3424
3425// ----end of grammar----
3426
3427// Local Variables: //
3428// mode: c++ //
3429// tab-width: 4 //
3430// compile-command: "make install" //
3431// End: //
Note: See TracBrowser for help on using the repository browser.