source: src/Parser/parser.yy @ 1201d54

ADTarm-ehast-experimentalenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprpthread-emulationqualifiedEnum
Last change on this file since 1201d54 was 757ffed, checked in by Peter A. Buhr <pabuhr@…>, 5 years ago

remove empty arguments in call to mean use default parameter value, use @ instead

  • Property mode set to 100644
File size: 136.1 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Sun Jul 14 07:54:30 2019
13// Update Count     : 4355
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// 1. designation with '=' (use ':' instead)
29//
30// Most of the syntactic extensions from ANSI90 to ANSI11 C are marked with the comment "C99/C11". This grammar also has
31// two levels of extensions. The first extensions cover most of the GCC C extensions, except for:
32//
33// 1. designation with and without '=' (use ':' instead)
34// 2. attributes not allowed in parenthesis of declarator
35//
36// All of the syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall
37// (CFA), which fixes several of C's outstanding problems and extends C with many modern language concepts. All of the
38// syntactic extensions for CFA C are marked with the comment "CFA". As noted above, there is one unreconcileable
39// parsing problem between C99 and CFA with respect to designators; this is discussed in detail before the "designation"
40// grammar rule.
41
42%{
43#define YYDEBUG_LEXER_TEXT (yylval)                                             // lexer loads this up each time
44#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
45#define YYERROR_VERBOSE                                                                 // more information in syntax errors
46
47#undef __GNUC_MINOR__
48
49#include <cstdio>
50#include <stack>
51using namespace std;
52
53#include "ParseNode.h"
54#include "TypedefTable.h"
55#include "TypeData.h"
56#include "LinkageSpec.h"
57#include "Common/SemanticError.h"                                               // error_str
58#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
59
60extern DeclarationNode * parseTree;
61extern LinkageSpec::Spec linkage;
62extern TypedefTable typedefTable;
63
64stack< LinkageSpec::Spec > linkageStack;
65
66bool appendStr( string & to, string & from ) {
67        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
68        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
69        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
70        //    easier to let the C compiler handle this case.
71        //
72        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
73        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
74        //    i.e., u"a" U"b" L"c" is disallowed.
75
76        if ( from[0] != '"' ) {                                                         // encoding ?
77                if ( to[0] != '"' ) {                                                   // encoding ?
78                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
79                                yyerror( "non-matching string encodings for string-literal concatenation" );
80                                return false;                                                   // parse error, must call YYERROR in action
81                        } else if ( from[1] == '8' ) {
82                                from.erase( 0, 1 );                                             // remove 2nd encoding
83                        } // if
84                } else {
85                        if ( from[1] == '8' ) {                                         // move encoding to start
86                                to = "u8" + to;
87                                from.erase( 0, 1 );                                             // remove 2nd encoding
88                        } else {
89                                to = from[0] + to;
90                        } // if
91                } // if
92                from.erase( 0, 1 );                                                             // remove 2nd encoding
93        } // if
94        to += " " + from;                                                                       // concatenated into single string
95        return true;
96} // appendStr
97
98DeclarationNode * distAttr( DeclarationNode * specifier, DeclarationNode * declList ) {
99        // distribute declaration_specifier across all declared variables, e.g., static, const, __attribute__.
100        DeclarationNode * cur = declList, * cl = (new DeclarationNode)->addType( specifier );
101        for ( cur = dynamic_cast<DeclarationNode *>( cur->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
102                cl->cloneBaseType( cur );
103        } // for
104        declList->addType( cl );
105        return declList;
106} // distAttr
107
108void distExt( DeclarationNode * declaration ) {
109        // distribute EXTENSION across all declarations
110        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
111                iter->set_extension( true );
112        } // for
113} // distExt
114
115void distInl( DeclarationNode * declaration ) {
116        // distribute EXTENSION across all declarations
117        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
118                iter->set_inLine( true );
119        } // for
120} // distInl
121
122void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
123        // distribute qualifiers across all non-variable declarations in a distribution statemement
124        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
125                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
126                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
127                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
128                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
129                DeclarationNode * clone = qualifiers->clone();
130                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
131                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
132                                swap( clone->type->forall, iter->type->aggregate.params );
133                                iter->addQualifiers( clone );
134                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
135                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
136                                DeclarationNode newnode;
137                                swap( newnode.type, iter->type->aggInst.aggregate );
138                                swap( clone->type->forall, newnode.type->aggregate.params );
139                                newnode.addQualifiers( clone );
140                                swap( newnode.type, iter->type->aggInst.aggregate );
141                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
142                                swap( clone->type->forall, iter->type->forall );
143                                iter->addQualifiers( clone );
144                        } // if
145                } else {                                                                                // just SC qualifiers
146                        iter->addQualifiers( clone );
147                } // if
148        } // for
149        delete qualifiers;
150} // distQual
151
152// There is an ambiguity for inline generic-routine return-types and generic routines.
153//   forall( otype T ) struct S { int i; } bar( T ) {}
154// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
155//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
156// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
157//   forall( otype T ) struct S { int T; };
158//   forall( otype W ) bar( W ) {}
159
160void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
161        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
162                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
163                declSpec->type->aggregate.params = nullptr;
164        } // if
165} // rebindForall
166
167NameExpr * build_postfix_name( const string * name ) {
168        NameExpr * new_name = build_varref( new string( "?`" + *name ) );
169        delete name;
170        return new_name;
171} // build_postfix_name
172
173DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
174        if ( ! fieldList ) {                                                            // field declarator ?
175                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
176                        stringstream ss;
177                        typeSpec->type->print( ss );
178                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
179                        return nullptr;
180                } // if
181                fieldList = DeclarationNode::newName( nullptr );
182        } // if
183        return distAttr( typeSpec, fieldList );                         // mark all fields in list
184} // fieldDecl
185
186ForCtrl * forCtrl( ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
187        ConstantExpr * constant = dynamic_cast<ConstantExpr *>(type->expr.get());
188        if ( constant && (constant->get_constant()->get_value() == "0" || constant->get_constant()->get_value() == "1") ) {
189        type = new ExpressionNode( new CastExpr( maybeMoveBuild< Expression >(type), new BasicType( Type::Qualifiers(), BasicType::SignedInt ) ) );
190        } // if
191        return new ForCtrl(
192                distAttr( DeclarationNode::newTypeof( type, true ), DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) ) ),
193                // NULL comp/inc => leave blank
194                comp ? new ExpressionNode( build_binary_val( compop, new ExpressionNode( build_varref( new string( *index ) ) ), comp ) ) : 0,
195                inc ? new ExpressionNode( build_binary_val( compop == OperKinds::LThan || compop == OperKinds::LEThan ? // choose += or -= for upto/downto
196                                                        OperKinds::PlusAssn : OperKinds::MinusAssn, new ExpressionNode( build_varref( new string( *index ) ) ), inc ) ) : 0 );
197} // forCtrl
198
199ForCtrl * forCtrl( ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
200        if ( NameExpr * identifier = dynamic_cast<NameExpr *>(index->expr.get()) ) {
201                return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
202        } else if ( CommaExpr * commaExpr = dynamic_cast<CommaExpr *>(index->expr.get()) ) {
203                if ( NameExpr * identifier = dynamic_cast<NameExpr *>(commaExpr->arg1 ) ) {
204                        return forCtrl( type, new string( identifier->name ), start, compop, comp, inc );
205                } else {
206                        SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
207                } // if
208        } else {
209                SemanticError( yylloc, "Expression disallowed. Only loop-index name allowed" ); return nullptr;
210        } // if
211} // forCtrl
212
213
214bool forall = false, yyy = false;                                               // aggregate have one or more forall qualifiers ?
215
216// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
217#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
218if ( N ) {                                                                                                                                              \
219        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
220        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
221        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
222        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
223        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
224} else {                                                                                                                                                \
225        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
226        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
227        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
228}
229%}
230
231%define parse.error verbose
232
233// Types declaration for productions
234%union {
235        Token tok;
236        ParseNode * pn;
237        ExpressionNode * en;
238        DeclarationNode * decl;
239        DeclarationNode::Aggregate aggKey;
240        DeclarationNode::TypeClass tclass;
241        StatementNode * sn;
242        WaitForStmt * wfs;
243        Expression * constant;
244        IfCtrl * ifctl;
245        ForCtrl * fctl;
246        enum OperKinds compop;
247        LabelNode * label;
248        InitializerNode * in;
249        OperKinds op;
250        std::string * str;
251        bool flag;
252        CatchStmt::Kind catch_kind;
253        GenericExpr * genexpr;
254}
255
256//************************* TERMINAL TOKENS ********************************
257
258// keywords
259%token TYPEDEF
260%token EXTERN STATIC AUTO REGISTER
261%token THREADLOCAL                                                                              // C11
262%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
263%token NORETURN                                                                                 // C11
264%token CONST VOLATILE
265%token RESTRICT                                                                                 // C99
266%token ATOMIC                                                                                   // C11
267%token FORALL MUTEX VIRTUAL COERCE                                              // CFA
268%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
269%token BOOL COMPLEX IMAGINARY                                                   // C99
270%token INT128 uuFLOAT80 uuFLOAT128                                              // GCC
271%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
272%token ZERO_T ONE_T                                                                             // CFA
273%token VALIST                                                                                   // GCC
274%token TYPEOF BASETYPEOF LABEL                                                  // GCC
275%token ENUM STRUCT UNION
276%token EXCEPTION                                                                                // CFA
277%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
278%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
279%token SIZEOF OFFSETOF
280// %token SUSPEND RESUME                                                                        // CFA
281%token ATTRIBUTE EXTENSION                                                              // GCC
282%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
283%token CHOOSE DISABLE ENABLE FALLTHRU FALLTHROUGH TRY CATCH CATCHRESUME FINALLY THROW THROWRESUME AT WITH WHEN WAITFOR // CFA
284%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
285%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
286
287// names and constants: lexer differentiates between identifier and typedef names
288%token<tok> IDENTIFIER                  QUOTED_IDENTIFIER               TYPEDEFname                             TYPEGENname
289%token<tok> TIMEOUT                             WOR
290%token<tok> ATTR_IDENTIFIER             ATTR_TYPEDEFname                ATTR_TYPEGENname
291%token<tok> INTEGERconstant             CHARACTERconstant               STRINGliteral
292%token<tok> DIRECTIVE
293// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
294// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
295// converted into the tuple index (.)(1). e.g., 3.x
296%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
297
298// multi-character operators
299%token ARROW                                                                                    // ->
300%token ICR DECR                                                                                 // ++   --
301%token LS RS                                                                                    // <<   >>
302%token LE GE EQ NE                                                                              // <=   >=      ==      !=
303%token ANDAND OROR                                                                              // &&   ||
304%token ELLIPSIS                                                                                 // ...
305
306%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
307%token PLUSassign       MINUSassign                                                     // +=   -=
308%token LSassign         RSassign                                                        // <<=  >>=
309%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
310
311%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
312%token ATassign                                                                                 // @=
313
314%type<tok> identifier  no_attr_identifier
315%type<tok> identifier_or_type_name  no_attr_identifier_or_type_name  attr_name
316%type<tok> quasi_keyword
317%type<constant> string_literal
318%type<str> string_literal_list
319
320// expressions
321%type<en> constant
322%type<en> tuple                                                 tuple_expression_list
323%type<op> ptrref_operator                               unary_operator                          assignment_operator
324%type<en> primary_expression                    postfix_expression                      unary_expression
325%type<en> cast_expression                               exponential_expression          multiplicative_expression       additive_expression
326%type<en> shift_expression                              relational_expression           equality_expression
327%type<en> AND_expression                                exclusive_OR_expression         inclusive_OR_expression
328%type<en> logical_AND_expression                logical_OR_expression
329%type<en> conditional_expression                constant_expression                     assignment_expression           assignment_expression_opt
330%type<en> comma_expression                              comma_expression_opt
331%type<en> argument_expression_list              argument_expression                     default_initialize_opt
332%type<ifctl> if_control_expression
333%type<fctl> for_control_expression              for_control_expression_list
334%type<compop> inclexcl
335%type<en> subrange
336%type<decl> asm_name_opt
337%type<en> asm_operands_opt                              asm_operands_list                       asm_operand
338%type<label> label_list
339%type<en> asm_clobbers_list_opt
340%type<flag> asm_volatile_opt
341%type<en> handler_predicate_opt
342%type<genexpr> generic_association              generic_assoc_list
343
344// statements
345%type<sn> statement                                             labeled_statement                       compound_statement
346%type<sn> statement_decl                                statement_decl_list                     statement_list_nodecl
347%type<sn> selection_statement                   if_statement
348%type<sn> switch_clause_list_opt                switch_clause_list
349%type<en> case_value
350%type<sn> case_clause                                   case_value_list                         case_label                                      case_label_list
351%type<sn> iteration_statement                   jump_statement
352%type<sn> expression_statement                  asm_statement
353%type<sn> with_statement
354%type<en> with_clause_opt
355%type<sn> exception_statement                   handler_clause                          finally_clause
356%type<catch_kind> handler_key
357%type<sn> mutex_statement
358%type<en> when_clause                                   when_clause_opt                         waitfor                                         timeout
359%type<sn> waitfor_statement
360%type<wfs> waitfor_clause
361
362// declarations
363%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
364%type<decl> abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
365%type<decl> abstract_parameter_declaration
366
367%type<aggKey> aggregate_key
368%type<decl> aggregate_type aggregate_type_nobody
369
370%type<decl> assertion assertion_list assertion_list_opt
371
372%type<en>   bit_subrange_size_opt bit_subrange_size
373
374%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
375
376%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
377
378%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
379%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
380
381%type<decl> elaborated_type elaborated_type_nobody
382
383%type<decl> enumerator_list enum_type enum_type_nobody
384%type<en> enumerator_value_opt
385
386%type<decl> external_definition external_definition_list external_definition_list_opt
387
388%type<decl> exception_declaration
389
390%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
391%type<en> field field_name_list field_name fraction_constants_opt
392
393%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
394
395%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
396%type<decl> identifier_list
397
398%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
399%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
400%type<decl> cfa_abstract_ptr cfa_abstract_tuple
401
402%type<decl> cfa_array_parameter_1st_dimension
403
404%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
405%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
406
407%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
408%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
409
410%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
411
412%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
413
414%type<decl> c_declaration static_assert
415%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
416%type<decl> KR_parameter_list KR_parameter_list_opt
417
418%type<decl> parameter_declaration parameter_list parameter_type_list_opt
419
420%type<decl> paren_identifier paren_type
421
422%type<decl> storage_class storage_class_list
423
424%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
425
426%type<tclass> type_class
427%type<decl> type_declarator type_declarator_name type_declaring_list
428
429%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
430%type<decl> typedef typedef_declaration typedef_expression
431
432%type<decl> variable_type_redeclarator type_ptr type_array type_function
433
434%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
435
436%type<decl> type type_no_function
437%type<decl> type_parameter type_parameter_list type_initializer_opt
438
439%type<en> type_parameters_opt type_list
440
441%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
442%type<decl> type_specifier type_specifier_nobody
443
444%type<decl> variable_declarator variable_ptr variable_array variable_function
445%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
446
447%type<decl> attribute_list_opt attribute_list attribute_name_list attribute attribute_name
448
449// initializers
450%type<in>  initializer initializer_list_opt initializer_opt
451
452// designators
453%type<en>  designator designator_list designation
454
455
456// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
457//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
458//   if ( C ) S1 else S2
459//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
460// Similar issues exit with the waitfor statement.
461
462// Order of these lines matters (low-to-high precedence). THEN is left associative over WOR/TIMEOUT/ELSE, WOR is left
463// associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
464%precedence THEN        // rule precedence for IF/WAITFOR statement
465%precedence WOR         // token precedence for start of WOR in WAITFOR statement
466%precedence TIMEOUT     // token precedence for start of TIMEOUT in WAITFOR statement
467%precedence ELSE        // token precedence for start of else clause in IF/WAITFOR statement
468
469// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
470//   forall( otype T ) struct Foo { T v; };
471//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
472//   Foo ( *fp )( int );
473//   `---'                                              matches start of TYPEGENname '('
474// must be:
475//   Foo( int ) ( *fp )( int );
476// The same problem occurs here:
477//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
478// must be:
479//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
480
481// Order of these lines matters (low-to-high precedence).
482%precedence TYPEGENname
483%precedence '}'
484%precedence '('
485
486// %precedence RESUME
487// %precedence '{'
488// %precedence ')'
489
490%locations                                                                                              // support location tracking for error messages
491
492%start translation_unit                                                                 // parse-tree root
493
494%%
495//************************* Namespace Management ********************************
496
497// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
498// which are lexically identical.
499//
500//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
501//   foo f;           // to allow it to appear in this context
502//
503// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
504// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
505// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
506// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
507// must be distinguished by the lexical scanner.
508//
509// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
510// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
511// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
512// each context that introduces a name scope, a new level is created in the type table and that level is popped on
513// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
514// This requires distinguishing between type names that are local to the current declaration scope and those that
515// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
516//
517// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
518// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
519// around the list separator.
520//
521//  int f( forall(T) T (*f1) T , forall( S ) S (*f2)( S ) );
522//      push               pop   push                   pop
523
524push:
525                { typedefTable.enterScope(); }
526        ;
527
528pop:
529                { typedefTable.leaveScope(); }
530        ;
531
532//************************* CONSTANTS ********************************
533
534constant:
535                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
536        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( *$1 ) ); }
537        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
538        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
539        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( *$1 ) ); }
540        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( *$1 ) ); }
541        ;
542
543quasi_keyword:                                                                                  // CFA
544        TIMEOUT
545        | WOR
546        ;
547
548no_attr_identifier:
549        IDENTIFIER
550        | quasi_keyword
551        | '@'                                                                                           // CFA
552                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
553        ;
554
555identifier:
556        no_attr_identifier
557        | ATTR_IDENTIFIER                                                                       // CFA
558        ;
559
560string_literal:
561        string_literal_list                                                     { $$ = build_constantStr( *$1 ); }
562        ;
563
564string_literal_list:                                                                    // juxtaposed strings are concatenated
565        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
566        | string_literal_list STRINGliteral
567                {
568                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
569                        delete $2;                                                                      // allocated by lexer
570                        $$ = $1;                                                                        // conversion from tok to str
571                }
572        ;
573
574//************************* EXPRESSIONS ********************************
575
576primary_expression:
577        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
578                { $$ = new ExpressionNode( build_varref( $1 ) ); }
579        | quasi_keyword
580                { $$ = new ExpressionNode( build_varref( $1 ) ); }
581        | tuple
582        | '(' comma_expression ')'
583                { $$ = $2; }
584        | '(' compound_statement ')'                                            // GCC, lambda expression
585                { $$ = new ExpressionNode( new StmtExpr( dynamic_cast< CompoundStmt * >(maybeMoveBuild< Statement >($2) ) ) ); }
586        | constant '`' IDENTIFIER                                                       // CFA, postfix call
587                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
588        | string_literal '`' IDENTIFIER                                         // CFA, postfix call
589                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( $1 ) ) ); }
590        | IDENTIFIER '`' IDENTIFIER                                                     // CFA, postfix call
591                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), new ExpressionNode( build_varref( $1 ) ) ) ); }
592        | tuple '`' IDENTIFIER                                                          // CFA, postfix call
593                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $3 ) ), $1 ) ); }
594        | '(' comma_expression ')' '`' IDENTIFIER                       // CFA, postfix call
595                { $$ = new ExpressionNode( build_func( new ExpressionNode( build_postfix_name( $5 ) ), $2 ) ); }
596        | type_name '.' no_attr_identifier                                      // CFA, nested type
597                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
598        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
599                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
600        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
601                {
602                        // add the missing control expression to the GenericExpr and return it
603                        $5->control = maybeMoveBuild<Expression>( $3 );
604                        $$ = new ExpressionNode( $5 );
605                }
606        // | RESUME '(' comma_expression ')'
607        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
608        // | RESUME '(' comma_expression ')' compound_statement
609        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
610        ;
611
612generic_assoc_list:                                                                             // C11
613        generic_association
614        | generic_assoc_list ',' generic_association
615                {
616                        // steal the association node from the singleton and delete the wrapper
617                        $1->associations.splice($1->associations.end(), $3->associations);
618                        delete $3;
619                        $$ = $1;
620                }
621        ;
622
623generic_association:                                                                    // C11
624        type_no_function ':' assignment_expression
625                {
626                        // create a GenericExpr wrapper with one association pair
627                        $$ = new GenericExpr( nullptr, { { maybeMoveBuildType($1), maybeMoveBuild<Expression>($3) } } );
628                }
629        | DEFAULT ':' assignment_expression
630                { $$ = new GenericExpr( nullptr, { { maybeMoveBuild<Expression>($3) } } ); }
631        ;
632
633postfix_expression:
634        primary_expression
635        | postfix_expression '[' assignment_expression ']'
636                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
637                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
638                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
639                // equivalent to the old x[i,j].
640                { $$ = new ExpressionNode( build_binary_val( OperKinds::Index, $1, $3 ) ); }
641        | postfix_expression '{' argument_expression_list '}' // CFA, constructor call
642                {
643                        Token fn;
644                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
645                        $$ = new ExpressionNode( new ConstructorExpr( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
646                }
647        | postfix_expression '(' argument_expression_list ')'
648                { $$ = new ExpressionNode( build_func( $1, $3 ) ); }
649        | postfix_expression '.' no_attr_identifier
650                { $$ = new ExpressionNode( build_fieldSel( $1, build_varref( $3 ) ) ); }
651        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
652                { $$ = new ExpressionNode( build_fieldSel( $1, build_constantInteger( *$3 ) ) ); }
653        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
654                { $$ = new ExpressionNode( build_fieldSel( $1, build_field_name_FLOATING_FRACTIONconstant( *$2 ) ) ); }
655        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
656                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
657        | postfix_expression ARROW no_attr_identifier
658                { $$ = new ExpressionNode( build_pfieldSel( $1, build_varref( $3 ) ) ); }
659        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
660                { $$ = new ExpressionNode( build_pfieldSel( $1, build_constantInteger( *$3 ) ) ); }
661        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
662                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
663        | postfix_expression ICR
664                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::IncrPost, $1 ) ); }
665        | postfix_expression DECR
666                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::DecrPost, $1 ) ); }
667        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
668                { $$ = new ExpressionNode( build_compoundLiteral( $2, new InitializerNode( $5, true ) ) ); }
669        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
670                { $$ = new ExpressionNode( build_compoundLiteral( $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
671        | '^' primary_expression '{' argument_expression_list '}' // CFA
672                {
673                        Token fn;
674                        fn.str = new string( "^?{}" );                          // location undefined
675                        $$ = new ExpressionNode( build_func( new ExpressionNode( build_varref( fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
676                }
677        ;
678
679argument_expression_list:
680        // empty
681                { $$ = nullptr; }
682        | argument_expression
683        | argument_expression_list ',' argument_expression
684                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
685        ;
686
687argument_expression:
688        '@'                                                                                                     // CFA, default parameter
689                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
690                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
691        | assignment_expression
692        ;
693
694field_name_list:                                                                                // CFA, tuple field selector
695        field
696        | field_name_list ',' field                                     { $$ = (ExpressionNode *)$1->set_last( $3 ); }
697        ;
698
699field:                                                                                                  // CFA, tuple field selector
700        field_name
701        | FLOATING_DECIMALconstant field
702                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), maybeMoveBuild<Expression>( $2 ) ) ); }
703        | FLOATING_DECIMALconstant '[' field_name_list ']'
704                { $$ = new ExpressionNode( build_fieldSel( new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( *$1 ) ), build_tuple( $3 ) ) ); }
705        | field_name '.' field
706                { $$ = new ExpressionNode( build_fieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
707        | field_name '.' '[' field_name_list ']'
708                { $$ = new ExpressionNode( build_fieldSel( $1, build_tuple( $4 ) ) ); }
709        | field_name ARROW field
710                { $$ = new ExpressionNode( build_pfieldSel( $1, maybeMoveBuild<Expression>( $3 ) ) ); }
711        | field_name ARROW '[' field_name_list ']'
712                { $$ = new ExpressionNode( build_pfieldSel( $1, build_tuple( $4 ) ) ); }
713        ;
714
715field_name:
716        INTEGERconstant fraction_constants_opt
717                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_constantInteger( *$1 ), $2 ) ); }
718        | FLOATINGconstant fraction_constants_opt
719                { $$ = new ExpressionNode( build_field_name_fraction_constants( build_field_name_FLOATINGconstant( *$1 ), $2 ) ); }
720        | no_attr_identifier fraction_constants_opt
721                {
722                        $$ = new ExpressionNode( build_field_name_fraction_constants( build_varref( $1 ), $2 ) );
723                }
724        ;
725
726fraction_constants_opt:
727        // empty
728                { $$ = nullptr; }
729        | fraction_constants_opt FLOATING_FRACTIONconstant
730                {
731                        Expression * constant = build_field_name_FLOATING_FRACTIONconstant( *$2 );
732                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( $1,  constant ) ) : new ExpressionNode( constant );
733                }
734        ;
735
736unary_expression:
737        postfix_expression
738                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
739                // semantics checks, e.g., ++3, 3--, *3, &&3
740        | constant
741        | string_literal
742                { $$ = new ExpressionNode( $1 ); }
743        | EXTENSION cast_expression                                                     // GCC
744                { $$ = $2->set_extension( true ); }
745                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
746                //              { * X; }         // dereference X
747                //              { * int X; } // CFA declaration of pointer to int
748        | ptrref_operator cast_expression                                       // CFA
749                {
750                        switch ( $1 ) {
751                          case OperKinds::AddressOf:
752                                $$ = new ExpressionNode( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) );
753                                break;
754                          case OperKinds::PointTo:
755                                $$ = new ExpressionNode( build_unary_val( $1, $2 ) );
756                                break;
757                          case OperKinds::And:
758                                $$ = new ExpressionNode( new AddressExpr( new AddressExpr( maybeMoveBuild< Expression >( $2 ) ) ) );
759                                break;
760                          default:
761                                assert( false );
762                        }
763                }
764        | unary_operator cast_expression
765                { $$ = new ExpressionNode( build_unary_val( $1, $2 ) ); }
766        | ICR unary_expression
767                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Incr, $2 ) ); }
768        | DECR unary_expression
769                { $$ = new ExpressionNode( build_unary_ptr( OperKinds::Decr, $2 ) ); }
770        | SIZEOF unary_expression
771                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
772        | SIZEOF '(' type_no_function ')'
773                { $$ = new ExpressionNode( new SizeofExpr( maybeMoveBuildType( $3 ) ) ); }
774        | ALIGNOF unary_expression                                                      // GCC, variable alignment
775                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuild< Expression >( $2 ) ) ); }
776        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
777                { $$ = new ExpressionNode( new AlignofExpr( maybeMoveBuildType( $3 ) ) ); }
778        | OFFSETOF '(' type_no_function ',' no_attr_identifier ')'
779                { $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) ); }
780        | ATTR_IDENTIFIER
781                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ) ) ); }
782        | ATTR_IDENTIFIER '(' argument_expression ')'
783                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
784        | ATTR_IDENTIFIER '(' type ')'
785                { $$ = new ExpressionNode( new AttrExpr( build_varref( $1 ), maybeMoveBuildType( $3 ) ) ); }
786        ;
787
788ptrref_operator:
789        '*'                                                                                     { $$ = OperKinds::PointTo; }
790        | '&'                                                                           { $$ = OperKinds::AddressOf; }
791                // GCC, address of label must be handled by semantic check for ref,ref,label
792        | ANDAND                                                                        { $$ = OperKinds::And; }
793        ;
794
795unary_operator:
796        '+'                                                                                     { $$ = OperKinds::UnPlus; }
797        | '-'                                                                           { $$ = OperKinds::UnMinus; }
798        | '!'                                                                           { $$ = OperKinds::Neg; }
799        | '~'                                                                           { $$ = OperKinds::BitNeg; }
800        ;
801
802cast_expression:
803        unary_expression
804        | '(' type_no_function ')' cast_expression
805                { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
806                // keyword cast cannot be grouped because of reduction in aggregate_key
807        | '(' GENERATOR '&' ')' cast_expression                         // CFA
808                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
809        | '(' COROUTINE '&' ')' cast_expression                         // CFA
810                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Coroutine, $5 ) ); }
811        | '(' THREAD '&' ')' cast_expression                            // CFA
812                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Thread, $5 ) ); }
813        | '(' MONITOR '&' ')' cast_expression                           // CFA
814                { $$ = new ExpressionNode( build_keyword_cast( KeywordCastExpr::Monitor, $5 ) ); }
815                // VIRTUAL cannot be opt because of look ahead issues
816        | '(' VIRTUAL ')' cast_expression                                       // CFA
817                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $4 ), maybeMoveBuildType( nullptr ) ) ); }
818        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
819                { $$ = new ExpressionNode( new VirtualCastExpr( maybeMoveBuild< Expression >( $5 ), maybeMoveBuildType( $3 ) ) ); }
820        | '(' RETURN type_no_function ')' cast_expression       // CFA
821                { SemanticError( yylloc, "Return cast is currently unimplemented." ); $$ = nullptr; }
822        | '(' COERCE type_no_function ')' cast_expression       // CFA
823                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
824        | '(' qualifier_cast_list ')' cast_expression           // CFA
825                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
826//      | '(' type_no_function ')' tuple
827//              { $$ = new ExpressionNode( build_cast( $2, $4 ) ); }
828        ;
829
830qualifier_cast_list:
831        cast_modifier type_qualifier_name
832        | cast_modifier MUTEX
833        | qualifier_cast_list cast_modifier type_qualifier_name
834        | qualifier_cast_list cast_modifier MUTEX
835        ;
836
837cast_modifier:
838        '-'
839        | '+'
840        ;
841
842exponential_expression:
843        cast_expression
844        | exponential_expression '\\' cast_expression
845                { $$ = new ExpressionNode( build_binary_val( OperKinds::Exp, $1, $3 ) ); }
846        ;
847
848multiplicative_expression:
849        exponential_expression
850        | multiplicative_expression '*' exponential_expression
851                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mul, $1, $3 ) ); }
852        | multiplicative_expression '/' exponential_expression
853                { $$ = new ExpressionNode( build_binary_val( OperKinds::Div, $1, $3 ) ); }
854        | multiplicative_expression '%' exponential_expression
855                { $$ = new ExpressionNode( build_binary_val( OperKinds::Mod, $1, $3 ) ); }
856        ;
857
858additive_expression:
859        multiplicative_expression
860        | additive_expression '+' multiplicative_expression
861                { $$ = new ExpressionNode( build_binary_val( OperKinds::Plus, $1, $3 ) ); }
862        | additive_expression '-' multiplicative_expression
863                { $$ = new ExpressionNode( build_binary_val( OperKinds::Minus, $1, $3 ) ); }
864        ;
865
866shift_expression:
867        additive_expression
868        | shift_expression LS additive_expression
869                { $$ = new ExpressionNode( build_binary_val( OperKinds::LShift, $1, $3 ) ); }
870        | shift_expression RS additive_expression
871                { $$ = new ExpressionNode( build_binary_val( OperKinds::RShift, $1, $3 ) ); }
872        ;
873
874relational_expression:
875        shift_expression
876        | relational_expression '<' shift_expression
877                { $$ = new ExpressionNode( build_binary_val( OperKinds::LThan, $1, $3 ) ); }
878        | relational_expression '>' shift_expression
879                { $$ = new ExpressionNode( build_binary_val( OperKinds::GThan, $1, $3 ) ); }
880        | relational_expression LE shift_expression
881                { $$ = new ExpressionNode( build_binary_val( OperKinds::LEThan, $1, $3 ) ); }
882        | relational_expression GE shift_expression
883                { $$ = new ExpressionNode( build_binary_val( OperKinds::GEThan, $1, $3 ) ); }
884        ;
885
886equality_expression:
887        relational_expression
888        | equality_expression EQ relational_expression
889                { $$ = new ExpressionNode( build_binary_val( OperKinds::Eq, $1, $3 ) ); }
890        | equality_expression NE relational_expression
891                { $$ = new ExpressionNode( build_binary_val( OperKinds::Neq, $1, $3 ) ); }
892        ;
893
894AND_expression:
895        equality_expression
896        | AND_expression '&' equality_expression
897                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitAnd, $1, $3 ) ); }
898        ;
899
900exclusive_OR_expression:
901        AND_expression
902        | exclusive_OR_expression '^' AND_expression
903                { $$ = new ExpressionNode( build_binary_val( OperKinds::Xor, $1, $3 ) ); }
904        ;
905
906inclusive_OR_expression:
907        exclusive_OR_expression
908        | inclusive_OR_expression '|' exclusive_OR_expression
909                { $$ = new ExpressionNode( build_binary_val( OperKinds::BitOr, $1, $3 ) ); }
910        ;
911
912logical_AND_expression:
913        inclusive_OR_expression
914        | logical_AND_expression ANDAND inclusive_OR_expression
915                { $$ = new ExpressionNode( build_and_or( $1, $3, true ) ); }
916        ;
917
918logical_OR_expression:
919        logical_AND_expression
920        | logical_OR_expression OROR logical_AND_expression
921                { $$ = new ExpressionNode( build_and_or( $1, $3, false ) ); }
922        ;
923
924conditional_expression:
925        logical_OR_expression
926        | logical_OR_expression '?' comma_expression ':' conditional_expression
927                { $$ = new ExpressionNode( build_cond( $1, $3, $5 ) ); }
928                // FIX ME: computes $1 twice
929        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
930                { $$ = new ExpressionNode( build_cond( $1, $1, $4 ) ); }
931        ;
932
933constant_expression:
934        conditional_expression
935        ;
936
937assignment_expression:
938                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
939        conditional_expression
940        | unary_expression assignment_operator assignment_expression
941                { $$ = new ExpressionNode( build_binary_val( $2, $1, $3 ) ); }
942        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
943                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
944        ;
945
946assignment_expression_opt:
947        // empty
948                { $$ = nullptr; }
949        | assignment_expression
950        ;
951
952assignment_operator:
953        '='                                                                                     { $$ = OperKinds::Assign; }
954        | ATassign                                                                      { $$ = OperKinds::AtAssn; }
955        | EXPassign                                                                     { $$ = OperKinds::ExpAssn; }
956        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
957        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
958        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
959        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
960        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
961        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
962        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
963        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
964        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
965        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
966        ;
967
968tuple:                                                                                                  // CFA, tuple
969                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
970                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
971//      '[' ']'
972//              { $$ = new ExpressionNode( build_tuple() ); }
973//      | '[' push assignment_expression pop ']'
974//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
975        '[' ',' tuple_expression_list ']'
976                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
977        | '[' push assignment_expression pop ',' tuple_expression_list ']'
978                { $$ = new ExpressionNode( build_tuple( (ExpressionNode *)$3->set_last( $6 ) ) ); }
979        ;
980
981tuple_expression_list:
982        assignment_expression_opt
983        | tuple_expression_list ',' assignment_expression_opt
984                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
985        ;
986
987comma_expression:
988        assignment_expression
989        | comma_expression ',' assignment_expression
990                { $$ = new ExpressionNode( new CommaExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
991        ;
992
993comma_expression_opt:
994        // empty
995                { $$ = nullptr; }
996        | comma_expression
997        ;
998
999//*************************** STATEMENTS *******************************
1000
1001statement:
1002        labeled_statement
1003        | compound_statement
1004        | expression_statement
1005        | selection_statement
1006        | iteration_statement
1007        | jump_statement
1008        | with_statement
1009        | mutex_statement
1010        | waitfor_statement
1011        | exception_statement
1012        | enable_disable_statement
1013                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1014        | asm_statement
1015        | DIRECTIVE
1016                { $$ = new StatementNode( build_directive( $1 ) ); }
1017        ;
1018
1019labeled_statement:
1020                // labels cannot be identifiers 0 or 1 or ATTR_IDENTIFIER
1021        identifier_or_type_name ':' attribute_list_opt statement
1022                { $$ = $4->add_label( $1, $3 ); }
1023        ;
1024
1025compound_statement:
1026        '{' '}'
1027                { $$ = new StatementNode( build_compound( (StatementNode *)0 ) ); }
1028        | '{' push
1029          local_label_declaration_opt                                           // GCC, local labels
1030          statement_decl_list                                                           // C99, intermix declarations and statements
1031          pop '}'
1032                { $$ = new StatementNode( build_compound( $4 ) ); }
1033        ;
1034
1035statement_decl_list:                                                                    // C99
1036        statement_decl
1037        | statement_decl_list statement_decl
1038                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1039        ;
1040
1041statement_decl:
1042        declaration                                                                                     // CFA, new & old style declarations
1043                { $$ = new StatementNode( $1 ); }
1044        | EXTENSION declaration                                                         // GCC
1045                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1046        | function_definition
1047                { $$ = new StatementNode( $1 ); }
1048        | EXTENSION function_definition                                         // GCC
1049                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1050        | statement
1051        ;
1052
1053statement_list_nodecl:
1054        statement
1055        | statement_list_nodecl statement
1056                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1057        ;
1058
1059expression_statement:
1060        comma_expression_opt ';'
1061                { $$ = new StatementNode( build_expr( $1 ) ); }
1062        ;
1063
1064selection_statement:
1065                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1066                        // the inherent S/R conflict with THEN/ELSE.
1067        push if_statement pop
1068                { $$ = $2; }
1069        | SWITCH '(' comma_expression ')' case_clause
1070                { $$ = new StatementNode( build_switch( true, $3, $5 ) ); }
1071        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1072                {
1073                        StatementNode *sw = new StatementNode( build_switch( true, $3, $8 ) );
1074                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1075                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1076                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1077                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1078                        // statement.
1079                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1080                }
1081        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1082                { $$ = new StatementNode( build_switch( false, $3, $5 ) ); }
1083        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1084                {
1085                        StatementNode *sw = new StatementNode( build_switch( false, $3, $8 ) );
1086                        $$ = $7 ? new StatementNode( build_compound( (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1087                }
1088        ;
1089
1090if_statement:
1091        IF '(' if_control_expression ')' statement                      %prec THEN
1092                // explicitly deal with the shift/reduce conflict on if/else
1093                { $$ = new StatementNode( build_if( $3, $5, nullptr ) ); }
1094        | IF '(' if_control_expression ')' statement ELSE statement
1095                { $$ = new StatementNode( build_if( $3, $5, $7 ) ); }
1096        ;
1097
1098if_control_expression:
1099        comma_expression
1100                { $$ = new IfCtrl( nullptr, $1 ); }
1101        | c_declaration                                                                         // no semi-colon
1102                { $$ = new IfCtrl( $1, nullptr ); }
1103        | cfa_declaration                                                                       // no semi-colon
1104                { $$ = new IfCtrl( $1, nullptr ); }
1105        | declaration comma_expression                                          // semi-colon separated
1106                { $$ = new IfCtrl( $1, $2 ); }
1107        ;
1108
1109// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1110// clause allows a list of values and subranges.
1111
1112case_value:                                                                                             // CFA
1113        constant_expression                                                     { $$ = $1; }
1114        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1115                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
1116        | subrange                                                                                      // CFA, subrange
1117        ;
1118
1119case_value_list:                                                                                // CFA
1120        case_value                                                                      { $$ = new StatementNode( build_case( $1 ) ); }
1121                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1122        | case_value_list ',' case_value                        { $$ = (StatementNode *)($1->set_last( new StatementNode( build_case( $3 ) ) ) ); }
1123        ;
1124
1125case_label:                                                                                             // CFA
1126        CASE case_value_list ':'                                        { $$ = $2; }
1127        | DEFAULT ':'                                                           { $$ = new StatementNode( build_default() ); }
1128                // A semantic check is required to ensure only one default clause per switch/choose statement.
1129        ;
1130
1131//label_list_opt:
1132//      // empty
1133//      | identifier_or_type_name ':'
1134//      | label_list_opt identifier_or_type_name ':'
1135//      ;
1136
1137case_label_list:                                                                                // CFA
1138        case_label
1139        | case_label_list case_label                            { $$ = (StatementNode *)( $1->set_last( $2 )); }
1140        ;
1141
1142case_clause:                                                                                    // CFA
1143        case_label_list statement                                       { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1144        ;
1145
1146switch_clause_list_opt:                                                                 // CFA
1147        // empty
1148                { $$ = nullptr; }
1149        | switch_clause_list
1150        ;
1151
1152switch_clause_list:                                                                             // CFA
1153        case_label_list statement_list_nodecl
1154                { $$ = $1->append_last_case( new StatementNode( build_compound( $2 ) ) ); }
1155        | switch_clause_list case_label_list statement_list_nodecl
1156                { $$ = (StatementNode *)( $1->set_last( $2->append_last_case( new StatementNode( build_compound( $3 ) ) ) ) ); }
1157        ;
1158
1159iteration_statement:
1160        WHILE '(' push if_control_expression ')' statement pop
1161                { $$ = new StatementNode( build_while( $4, $6 ) ); }
1162        | WHILE '(' ')' statement                                                       // CFA => while ( 1 )
1163                { $$ = new StatementNode( build_while( new IfCtrl( nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ), $4 ) ); }
1164        | DO statement WHILE '(' comma_expression ')' ';'
1165                { $$ = new StatementNode( build_do_while( $5, $2 ) ); }
1166        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1167                { $$ = new StatementNode( build_do_while( new ExpressionNode( build_constantInteger( *new string( "1" ) ) ), $2 ) ); }
1168        | FOR '(' push for_control_expression_list ')' statement pop
1169                { $$ = new StatementNode( build_for( $4, $6 ) ); }
1170        | FOR '(' ')' statement                                                         // CFA => for ( ;; )
1171                { $$ = new StatementNode( build_for( new ForCtrl( (ExpressionNode * )nullptr, (ExpressionNode * )nullptr, (ExpressionNode * )nullptr ), $4 ) ); }
1172        ;
1173
1174for_control_expression_list:
1175        for_control_expression
1176        | for_control_expression_list ':' for_control_expression
1177                // ForCtrl + ForCtrl:
1178                //    init + init => multiple declaration statements that are hoisted
1179                //    condition + condition => (expression) && (expression)
1180                //    change + change => (expression), (expression)
1181                {
1182                        $1->init->set_last( $3->init );
1183                        if ( $1->condition ) {
1184                                if ( $3->condition ) {
1185                                        $1->condition->expr.reset( new LogicalExpr( $1->condition->expr.release(), $3->condition->expr.release(), true ) );
1186                                } // if
1187                        } else $1->condition = $3->condition;
1188                        if ( $1->change ) {
1189                                if ( $3->change ) {
1190                                        $1->change->expr.reset( new CommaExpr( $1->change->expr.release(), $3->change->expr.release() ) );
1191                                } // if
1192                        } else $1->change = $3->change;
1193                        $$ = $1;
1194                }
1195        ;
1196
1197for_control_expression:
1198        ';' comma_expression_opt ';' comma_expression_opt
1199                { $$ = new ForCtrl( (ExpressionNode * )nullptr, $2, $4 ); }
1200        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1201                { $$ = new ForCtrl( $1, $3, $5 ); }
1202        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1203                { $$ = new ForCtrl( $1, $2, $4 ); }
1204
1205        | comma_expression                                                                      // CFA
1206                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1207                                                OperKinds::LThan, $1->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1208        | comma_expression inclexcl comma_expression            // CFA
1209                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1210        | comma_expression inclexcl comma_expression '~' comma_expression // CFA
1211                { $$ = forCtrl( $1, new string( DeclarationNode::anonymous.newName() ), $1->clone(), $2, $3, $5 ); }
1212        | comma_expression ';' comma_expression                         // CFA
1213                { $$ = forCtrl( $3, $1, new ExpressionNode( build_constantInteger( *new string( "0" ) ) ),
1214                                                OperKinds::LThan, $3->clone(), new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1215        | comma_expression ';' comma_expression inclexcl comma_expression // CFA
1216                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1217        | comma_expression ';' comma_expression inclexcl comma_expression '~' comma_expression // CFA
1218                { $$ = forCtrl( $3, $1, $3->clone(), $4, $5, $7 ); }
1219
1220                // There is a S/R conflicit if ~ and -~ are factored out.
1221        | comma_expression ';' comma_expression '~' '@'         // CFA
1222                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1223        | comma_expression ';' comma_expression ErangeDown '@' // CFA
1224                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, new ExpressionNode( build_constantInteger( *new string( "1" ) ) ) ); }
1225        | comma_expression ';' comma_expression '~' '@' '~' comma_expression // CFA
1226                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, $7 ); }
1227        | comma_expression ';' comma_expression ErangeDown '@' '~' comma_expression // CFA
1228                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::GThan, nullptr, $7 ); }
1229        | comma_expression ';' comma_expression '~' '@' '~' '@' // CFA
1230                { $$ = forCtrl( $3, $1, $3->clone(), OperKinds::LThan, nullptr, nullptr ); }
1231        ;
1232
1233inclexcl:
1234        '~'
1235                { $$ = OperKinds::LThan; }
1236        | ErangeUpEq
1237                { $$ = OperKinds::LEThan; }
1238        | ErangeDown
1239                { $$ = OperKinds::GThan; }
1240        | ErangeDownEq
1241                { $$ = OperKinds::GEThan; }
1242        ;
1243
1244jump_statement:
1245        GOTO identifier_or_type_name ';'
1246                { $$ = new StatementNode( build_branch( $2, BranchStmt::Goto ) ); }
1247        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1248                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1249                // whereas normal operator precedence yields goto (*i)+3;
1250                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1251                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1252    | fall_through_name ';'                                                             // CFA
1253                { $$ = new StatementNode( build_branch( BranchStmt::FallThrough ) ); }
1254    | fall_through_name identifier_or_type_name ';'             // CFA
1255                { $$ = new StatementNode( build_branch( $2, BranchStmt::FallThrough ) ); }
1256        | fall_through_name DEFAULT ';'                                         // CFA
1257                { $$ = new StatementNode( build_branch( BranchStmt::FallThroughDefault ) ); }
1258        | CONTINUE ';'
1259                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1260                { $$ = new StatementNode( build_branch( BranchStmt::Continue ) ); }
1261        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1262                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1263                // the target of the transfer appears only at the start of an iteration statement.
1264                { $$ = new StatementNode( build_branch( $2, BranchStmt::Continue ) ); }
1265        | BREAK ';'
1266                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1267                { $$ = new StatementNode( build_branch( BranchStmt::Break ) ); }
1268        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1269                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1270                // the target of the transfer appears only at the start of an iteration statement.
1271                { $$ = new StatementNode( build_branch( $2, BranchStmt::Break ) ); }
1272        | RETURN comma_expression_opt ';'
1273                { $$ = new StatementNode( build_return( $2 ) ); }
1274        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1275                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1276        // | SUSPEND ';'
1277        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1278        // | SUSPEND compound_statement ';'
1279        //      { SemanticError( yylloc, "Suspend expression is currently unimplemented." ); $$ = nullptr; }
1280        | THROW assignment_expression_opt ';'                           // handles rethrow
1281                { $$ = new StatementNode( build_throw( $2 ) ); }
1282        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1283                { $$ = new StatementNode( build_resume( $2 ) ); }
1284        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1285                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1286        ;
1287
1288fall_through_name:                                                                              // CFA
1289        FALLTHRU
1290        | FALLTHROUGH
1291        ;
1292
1293with_statement:
1294        WITH '(' tuple_expression_list ')' statement
1295                {
1296                        $$ = new StatementNode( build_with( $3, $5 ) );
1297                }
1298        ;
1299
1300// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so change syntax to "with mutex".
1301mutex_statement:
1302        MUTEX '(' argument_expression_list ')' statement
1303                { SemanticError( yylloc, "Mutex statement is currently unimplemented." ); $$ = nullptr; }
1304        ;
1305
1306when_clause:
1307        WHEN '(' comma_expression ')'                           { $$ = $3; }
1308        ;
1309
1310when_clause_opt:
1311        // empty
1312                { $$ = nullptr; }
1313        | when_clause
1314        ;
1315
1316waitfor:
1317        WAITFOR '(' cast_expression ')'
1318                { $$ = $3; }
1319        | WAITFOR '(' cast_expression ',' argument_expression_list ')'
1320                { $$ = (ExpressionNode *)$3->set_last( $5 ); }
1321        ;
1322
1323timeout:
1324        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1325        ;
1326
1327waitfor_clause:
1328        when_clause_opt waitfor statement                                       %prec THEN
1329                { $$ = build_waitfor( $2, $3, $1 ); }
1330        | when_clause_opt waitfor statement WOR waitfor_clause
1331                { $$ = build_waitfor( $2, $3, $1, $5 ); }
1332        | when_clause_opt timeout statement                                     %prec THEN
1333                { $$ = build_waitfor_timeout( $2, $3, $1 ); }
1334        | when_clause_opt ELSE statement
1335                { $$ = build_waitfor_timeout( nullptr, $3, $1 ); }
1336                // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1337        | when_clause_opt timeout statement WOR ELSE statement
1338                { SemanticError( yylloc, "else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1339        | when_clause_opt timeout statement WOR when_clause ELSE statement
1340                { $$ = build_waitfor_timeout( $2, $3, $1, $7, $5 ); }
1341        ;
1342
1343waitfor_statement:
1344        when_clause_opt waitfor statement                                       %prec THEN
1345                { $$ = new StatementNode( build_waitfor( $2, $3, $1 ) ); }
1346        | when_clause_opt waitfor statement WOR waitfor_clause
1347                { $$ = new StatementNode( build_waitfor( $2, $3, $1, $5 ) ); }
1348        ;
1349
1350exception_statement:
1351        TRY compound_statement handler_clause
1352                { $$ = new StatementNode( build_try( $2, $3, 0 ) ); }
1353        | TRY compound_statement finally_clause
1354                { $$ = new StatementNode( build_try( $2, 0, $3 ) ); }
1355        | TRY compound_statement handler_clause finally_clause
1356                { $$ = new StatementNode( build_try( $2, $3, $4 ) ); }
1357        ;
1358
1359handler_clause:
1360        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1361                { $$ = new StatementNode( build_catch( $1, $4, $6, $8 ) ); }
1362        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1363                { $$ = (StatementNode *)$1->set_last( new StatementNode( build_catch( $2, $5, $7, $9 ) ) ); }
1364        ;
1365
1366handler_predicate_opt:
1367        // empty
1368                { $$ = nullptr; }
1369        | ';' conditional_expression                            { $$ = $2; }
1370        ;
1371
1372handler_key:
1373        CATCH                                                                           { $$ = CatchStmt::Terminate; }
1374        | CATCHRESUME                                                           { $$ = CatchStmt::Resume; }
1375        ;
1376
1377finally_clause:
1378        FINALLY compound_statement                                      { $$ = new StatementNode( build_finally( $2 ) ); }
1379        ;
1380
1381exception_declaration:
1382                // No SUE declaration in parameter list.
1383        type_specifier_nobody
1384        | type_specifier_nobody declarator
1385                { $$ = $2->addType( $1 ); }
1386        | type_specifier_nobody variable_abstract_declarator
1387                { $$ = $2->addType( $1 ); }
1388        | cfa_abstract_declarator_tuple no_attr_identifier      // CFA
1389                { $$ = $1->addName( $2 ); }
1390        | cfa_abstract_declarator_tuple                                         // CFA
1391        ;
1392
1393enable_disable_statement:
1394        enable_disable_key identifier_list compound_statement
1395        ;
1396
1397enable_disable_key:
1398        ENABLE
1399        | DISABLE
1400        ;
1401
1402asm_statement:
1403        ASM asm_volatile_opt '(' string_literal ')' ';'
1404                { $$ = new StatementNode( build_asm( $2, $4, 0 ) ); }
1405        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1406                { $$ = new StatementNode( build_asm( $2, $4, $6 ) ); }
1407        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1408                { $$ = new StatementNode( build_asm( $2, $4, $6, $8 ) ); }
1409        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1410                { $$ = new StatementNode( build_asm( $2, $4, $6, $8, $10 ) ); }
1411        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1412                { $$ = new StatementNode( build_asm( $2, $5, 0, $8, $10, $12 ) ); }
1413        ;
1414
1415asm_volatile_opt:                                                                               // GCC
1416        // empty
1417                { $$ = false; }
1418        | VOLATILE
1419                { $$ = true; }
1420        ;
1421
1422asm_operands_opt:                                                                               // GCC
1423        // empty
1424                { $$ = nullptr; }                                                               // use default argument
1425        | asm_operands_list
1426        ;
1427
1428asm_operands_list:                                                                              // GCC
1429        asm_operand
1430        | asm_operands_list ',' asm_operand
1431                { $$ = (ExpressionNode *)$1->set_last( $3 ); }
1432        ;
1433
1434asm_operand:                                                                                    // GCC
1435        string_literal '(' constant_expression ')'
1436                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( (ExpressionNode *)nullptr ), $1, maybeMoveBuild< Expression >( $3 ) ) ); }
1437        | '[' constant_expression ']' string_literal '(' constant_expression ')'
1438                { $$ = new ExpressionNode( new AsmExpr( maybeMoveBuild< Expression >( $2 ), $4, maybeMoveBuild< Expression >( $6 ) ) ); }
1439        ;
1440
1441asm_clobbers_list_opt:                                                                  // GCC
1442        // empty
1443                { $$ = nullptr; }                                                               // use default argument
1444        | string_literal
1445                { $$ = new ExpressionNode( $1 ); }
1446        | asm_clobbers_list_opt ',' string_literal
1447                // set_last returns ParseNode *
1448                { $$ = (ExpressionNode *)$1->set_last( new ExpressionNode( $3 ) ); }
1449        ;
1450
1451label_list:
1452        no_attr_identifier
1453                {
1454                        $$ = new LabelNode(); $$->labels.push_back( *$1 );
1455                        delete $1;                                                                      // allocated by lexer
1456                }
1457        | label_list ',' no_attr_identifier
1458                {
1459                        $$ = $1; $1->labels.push_back( *$3 );
1460                        delete $3;                                                                      // allocated by lexer
1461                }
1462        ;
1463
1464//******************************* DECLARATIONS *********************************
1465
1466declaration_list_opt:                                                                   // used at beginning of switch statement
1467        // empty
1468                { $$ = nullptr; }
1469        | declaration_list
1470        ;
1471
1472declaration_list:
1473        declaration
1474        | declaration_list declaration
1475                { $$ = $1->appendList( $2 ); }
1476        ;
1477
1478KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1479        // empty
1480                { $$ = nullptr; }
1481        | KR_parameter_list
1482        ;
1483
1484KR_parameter_list:
1485        push c_declaration pop ';'
1486                { $$ = $2; }
1487        | KR_parameter_list push c_declaration pop ';'
1488                { $$ = $1->appendList( $3 ); }
1489        ;
1490
1491local_label_declaration_opt:                                                    // GCC, local label
1492        // empty
1493        | local_label_declaration_list
1494        ;
1495
1496local_label_declaration_list:                                                   // GCC, local label
1497        LABEL local_label_list ';'
1498        | local_label_declaration_list LABEL local_label_list ';'
1499        ;
1500
1501local_label_list:                                                                               // GCC, local label
1502        no_attr_identifier_or_type_name
1503        | local_label_list ',' no_attr_identifier_or_type_name
1504        ;
1505
1506declaration:                                                                                    // old & new style declarations
1507        c_declaration ';'
1508        | cfa_declaration ';'                                                           // CFA
1509        | static_assert                                                                         // C11
1510        ;
1511
1512static_assert:
1513        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1514                { $$ = DeclarationNode::newStaticAssert( $3, $5 ); }
1515        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1516                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( *new string( "\"\"" ) ) ); }
1517
1518// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1519// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1520// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1521// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1522// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1523// block, but cannot be mixed within a specific declaration.
1524//
1525//                      CFA                                     C
1526//              [10] int x;                     int x[10];              // array of 10 integers
1527//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1528
1529cfa_declaration:                                                                                // CFA
1530        cfa_variable_declaration
1531        | cfa_typedef_declaration
1532        | cfa_function_declaration
1533        | type_declaring_list
1534        | trait_specifier
1535        ;
1536
1537cfa_variable_declaration:                                                               // CFA
1538        cfa_variable_specifier initializer_opt
1539                { $$ = $1->addInitializer( $2 ); }
1540        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1541                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1542                // them as a type_qualifier cannot appear in that context.
1543                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1544        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1545                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1546        ;
1547
1548cfa_variable_specifier:                                                                 // CFA
1549                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1550                // storage-class
1551        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1552                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1553        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1554                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1555        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1556                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1557        ;
1558
1559cfa_function_declaration:                                                               // CFA
1560        cfa_function_specifier
1561        | type_qualifier_list cfa_function_specifier
1562                { $$ = $2->addQualifiers( $1 ); }
1563        | declaration_qualifier_list cfa_function_specifier
1564                { $$ = $2->addQualifiers( $1 ); }
1565        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1566                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1567        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1568                {
1569                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1570                        DeclarationNode * ret = new DeclarationNode;
1571                        ret->type = maybeClone( $1->type->base );
1572                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1573                }
1574        ;
1575
1576cfa_function_specifier:                                                                 // CFA
1577//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1578//              {
1579//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, 0, true );
1580//              }
1581//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1582//              {
1583//                      typedefTable.setNextIdentifier( *$5 );
1584//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1585//              }
1586//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1587//              {
1588//                      typedefTable.setNextIdentifier( *$5 );
1589//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, 0, true );
1590//              }
1591//      | '[' ']' typegen_name
1592                // identifier_or_type_name must be broken apart because of the sequence:
1593                //
1594                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1595                //   '[' ']' type_specifier
1596                //
1597                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1598                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1599        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1600                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1601                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1602        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1603                { $$ = DeclarationNode::newFunction( $2, $1, $5, 0 ); }
1604        ;
1605
1606cfa_function_return:                                                                    // CFA
1607        '[' push cfa_parameter_list pop ']'
1608                { $$ = DeclarationNode::newTuple( $3 ); }
1609        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
1610                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
1611                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
1612        ;
1613
1614cfa_typedef_declaration:                                                                // CFA
1615        TYPEDEF cfa_variable_specifier
1616                {
1617                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "1" );
1618                        $$ = $2->addTypedef();
1619                }
1620        | TYPEDEF cfa_function_specifier
1621                {
1622                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "2" );
1623                        $$ = $2->addTypedef();
1624                }
1625        | cfa_typedef_declaration pop ',' push no_attr_identifier
1626                {
1627                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "3" );
1628                        $$ = $1->appendList( $1->cloneType( $5 ) );
1629                }
1630        ;
1631
1632// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
1633// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
1634
1635typedef_declaration:
1636        TYPEDEF type_specifier declarator
1637                {
1638                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "4" );
1639                        $$ = $3->addType( $2 )->addTypedef();
1640                }
1641        | typedef_declaration pop ',' push declarator
1642                {
1643                        typedefTable.addToEnclosingScope( *$5->name, TYPEDEFname, "5" );
1644                        $$ = $1->appendList( $1->cloneBaseType( $5 )->addTypedef() );
1645                }
1646        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
1647                {
1648                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "6" );
1649                        $$ = $4->addType( $3 )->addQualifiers( $1 )->addTypedef();
1650                }
1651        | type_specifier TYPEDEF declarator
1652                {
1653                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "7" );
1654                        $$ = $3->addType( $1 )->addTypedef();
1655                }
1656        | type_specifier TYPEDEF type_qualifier_list declarator
1657                {
1658                        typedefTable.addToEnclosingScope( *$4->name, TYPEDEFname, "8" );
1659                        $$ = $4->addQualifiers( $1 )->addTypedef()->addType( $1 );
1660                }
1661        ;
1662
1663typedef_expression:
1664                // GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
1665        TYPEDEF no_attr_identifier '=' assignment_expression
1666                {
1667                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1668                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1669                }
1670        | typedef_expression pop ',' push no_attr_identifier '=' assignment_expression
1671                {
1672                        // $$ = DeclarationNode::newName( 0 );                  // unimplemented
1673                        SemanticError( yylloc, "Typedef expression is currently unimplemented." ); $$ = nullptr;
1674                }
1675        ;
1676
1677//c_declaration:
1678//      declaring_list pop ';'
1679//      | typedef_declaration pop ';'
1680//      | typedef_expression pop ';'                                            // GCC, naming expression type
1681//      | sue_declaration_specifier pop ';'
1682//      ;
1683//
1684//declaring_list:
1685//              // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1686//              // storage-class
1687//       declarator asm_name_opt initializer_opt
1688//              {
1689//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1690//                      $$ = ( $2->addType( $1 ))->addAsmName( $3 )->addInitializer( $4 );
1691//              }
1692//      | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1693//              {
1694//                      typedefTable.addToEnclosingScope( IDENTIFIER );
1695//                      $$ = $1->appendList( $1->cloneBaseType( $4->addAsmName( $5 )->addInitializer( $6 ) ) );
1696//              }
1697//      ;
1698
1699c_declaration:
1700        declaration_specifier declaring_list
1701                { $$ = distAttr( $1, $2 ); }
1702        | typedef_declaration
1703        | typedef_expression                                                            // GCC, naming expression type
1704        | sue_declaration_specifier
1705        ;
1706
1707declaring_list:
1708                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1709                // storage-class
1710        declarator asm_name_opt initializer_opt
1711                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
1712        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
1713                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
1714        ;
1715
1716declaration_specifier:                                                                  // type specifier + storage class
1717        basic_declaration_specifier
1718        | sue_declaration_specifier
1719        | type_declaration_specifier
1720        ;
1721
1722declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
1723                // Preclude SUE declarations in restricted scopes:
1724                //
1725                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1726                //
1727                // because it is impossible to call f due to name equivalence.
1728        basic_declaration_specifier
1729        | sue_declaration_specifier_nobody
1730        | type_declaration_specifier
1731        ;
1732
1733type_specifier:                                                                                 // type specifier
1734        basic_type_specifier
1735        | sue_type_specifier
1736        | type_type_specifier
1737        ;
1738
1739type_specifier_nobody:                                                                  // type specifier - {...}
1740                // Preclude SUE declarations in restricted scopes:
1741                //
1742                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
1743                //
1744                // because it is impossible to call f due to name equivalence.
1745        basic_type_specifier
1746        | sue_type_specifier_nobody
1747        | type_type_specifier
1748        ;
1749
1750type_qualifier_list_opt:                                                                // GCC, used in asm_statement
1751        // empty
1752                { $$ = nullptr; }
1753        | type_qualifier_list
1754        ;
1755
1756type_qualifier_list:
1757                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
1758                //
1759                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
1760                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
1761                // appeared only once.
1762        type_qualifier
1763        | type_qualifier_list type_qualifier
1764                { $$ = $1->addQualifiers( $2 ); }
1765        ;
1766
1767type_qualifier:
1768        type_qualifier_name
1769        | attribute
1770        ;
1771
1772type_qualifier_name:
1773        CONST
1774                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
1775        | RESTRICT
1776                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
1777        | VOLATILE
1778                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
1779        | ATOMIC
1780                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
1781        | forall
1782        ;
1783
1784forall:
1785        FORALL '(' type_parameter_list ')'                                      // CFA
1786                { $$ = DeclarationNode::newForall( $3 ); }
1787        ;
1788
1789declaration_qualifier_list:
1790        storage_class_list
1791        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
1792                { $$ = $1->addQualifiers( $2 ); }
1793        | declaration_qualifier_list type_qualifier_list storage_class_list
1794                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1795        ;
1796
1797storage_class_list:
1798                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
1799                // only one of each is specified, except for inline, which can appear with the others.
1800                //
1801                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
1802                // specifiers in a declaration.
1803        storage_class
1804        | storage_class_list storage_class
1805                { $$ = $1->addQualifiers( $2 ); }
1806        ;
1807
1808storage_class:
1809        EXTERN
1810                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
1811        | STATIC
1812                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
1813        | AUTO
1814                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
1815        | REGISTER
1816                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
1817        | THREADLOCAL                                                                           // C11
1818                { $$ = DeclarationNode::newStorageClass( Type::Threadlocal ); }
1819                // Put function specifiers here to simplify parsing rules, but separate them semantically.
1820        | INLINE                                                                                        // C99
1821                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
1822        | FORTRAN                                                                                       // C99
1823                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
1824        | NORETURN                                                                                      // C11
1825                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
1826        ;
1827
1828basic_type_name:
1829        VOID
1830                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
1831        | BOOL                                                                                          // C99
1832                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
1833        | CHAR
1834                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
1835        | INT
1836                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
1837        | INT128
1838                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
1839        | FLOAT
1840                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
1841        | DOUBLE
1842                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
1843        | uuFLOAT80
1844                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
1845        | uuFLOAT128
1846                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
1847        | uFLOAT16
1848                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
1849        | uFLOAT32
1850                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
1851        | uFLOAT32X
1852                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
1853        | uFLOAT64
1854                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
1855        | uFLOAT64X
1856                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
1857        | uFLOAT128
1858                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
1859        | COMPLEX                                                                                       // C99
1860                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
1861        | IMAGINARY                                                                                     // C99
1862                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
1863        | SIGNED
1864                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
1865        | UNSIGNED
1866                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
1867        | SHORT
1868                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
1869        | LONG
1870                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
1871        | VALIST                                                                                        // GCC, __builtin_va_list
1872                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
1873        ;
1874
1875basic_declaration_specifier:
1876                // A semantic check is necessary for conflicting storage classes.
1877        basic_type_specifier
1878        | declaration_qualifier_list basic_type_specifier
1879                { $$ = $2->addQualifiers( $1 ); }
1880        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
1881                { $$ = $1->addQualifiers( $2 ); }
1882        | basic_declaration_specifier storage_class type_qualifier_list
1883                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1884        | basic_declaration_specifier storage_class basic_type_specifier
1885                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
1886        ;
1887
1888basic_type_specifier:
1889        direct_type
1890                // Cannot have type modifiers, e.g., short, long, etc.
1891        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
1892                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
1893        ;
1894
1895direct_type:
1896        basic_type_name
1897        | type_qualifier_list basic_type_name
1898                { $$ = $2->addQualifiers( $1 ); }
1899        | direct_type type_qualifier
1900                { $$ = $1->addQualifiers( $2 ); }
1901        | direct_type basic_type_name
1902                { $$ = $1->addType( $2 ); }
1903        ;
1904
1905indirect_type:
1906        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
1907                { $$ = $3; }
1908        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
1909                { $$ = DeclarationNode::newTypeof( $3 ); }
1910        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
1911                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ), true ); }
1912        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
1913                { $$ = DeclarationNode::newTypeof( $3, true ); }
1914        | ATTR_TYPEGENname '(' type ')'                                         // CFA: e.g., @type( x ) y;
1915                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1916        | ATTR_TYPEGENname '(' comma_expression ')'                     // CFA: e.g., @type( a+b ) y;
1917                { $$ = DeclarationNode::newAttr( $1, $3 ); }
1918        | ZERO_T                                                                                        // CFA
1919                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
1920        | ONE_T                                                                                         // CFA
1921                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
1922        ;
1923
1924sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
1925        sue_type_specifier
1926        | declaration_qualifier_list sue_type_specifier
1927                { $$ = $2->addQualifiers( $1 ); }
1928        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
1929                { $$ = $1->addQualifiers( $2 ); }
1930        | sue_declaration_specifier storage_class type_qualifier_list
1931                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1932        ;
1933
1934sue_type_specifier:                                                                             // struct, union, enum + type specifier
1935        elaborated_type
1936        | type_qualifier_list
1937                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
1938          elaborated_type
1939                { $$ = $3->addQualifiers( $1 ); }
1940        | sue_type_specifier type_qualifier
1941                {
1942                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
1943                        $$ = $1->addQualifiers( $2 );
1944                }
1945        ;
1946
1947sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
1948        sue_type_specifier_nobody
1949        | declaration_qualifier_list sue_type_specifier_nobody
1950                { $$ = $2->addQualifiers( $1 ); }
1951        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
1952                { $$ = $1->addQualifiers( $2 ); }
1953        | sue_declaration_specifier_nobody storage_class type_qualifier_list
1954                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1955        ;
1956
1957sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
1958        elaborated_type_nobody
1959        | type_qualifier_list elaborated_type_nobody
1960                { $$ = $2->addQualifiers( $1 ); }
1961        | sue_type_specifier_nobody type_qualifier
1962                { $$ = $1->addQualifiers( $2 ); }
1963        ;
1964
1965type_declaration_specifier:
1966        type_type_specifier
1967        | declaration_qualifier_list type_type_specifier
1968                { $$ = $2->addQualifiers( $1 ); }
1969        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
1970                { $$ = $1->addQualifiers( $2 ); }
1971        | type_declaration_specifier storage_class type_qualifier_list
1972                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
1973        ;
1974
1975type_type_specifier:                                                                    // typedef types
1976        type_name
1977        | type_qualifier_list type_name
1978                { $$ = $2->addQualifiers( $1 ); }
1979        | type_type_specifier type_qualifier
1980                { $$ = $1->addQualifiers( $2 ); }
1981        ;
1982
1983type_name:
1984        TYPEDEFname
1985                { $$ = DeclarationNode::newFromTypedef( $1 ); }
1986        | '.' TYPEDEFname
1987                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
1988        | type_name '.' TYPEDEFname
1989                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
1990        | typegen_name
1991        | '.' typegen_name
1992                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
1993        | type_name '.' typegen_name
1994                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
1995        ;
1996
1997typegen_name:                                                                                   // CFA
1998        TYPEGENname
1999                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2000        | TYPEGENname '(' ')'
2001                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2002        | TYPEGENname '(' type_list ')'
2003                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2004        ;
2005
2006elaborated_type:                                                                                // struct, union, enum
2007        aggregate_type
2008        | enum_type
2009        ;
2010
2011elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2012        aggregate_type_nobody
2013        | enum_type_nobody
2014        ;
2015
2016fred:
2017        // empty
2018                { yyy = false; }
2019        ;
2020
2021aggregate_type:                                                                                 // struct, union
2022        aggregate_key attribute_list_opt
2023                { forall = false; }                                                             // reset
2024          '{' field_declaration_list_opt '}' type_parameters_opt
2025                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2026        | aggregate_key attribute_list_opt no_attr_identifier fred
2027                {
2028                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2029                        forall = false;                                                         // reset
2030                }
2031          '{' field_declaration_list_opt '}' type_parameters_opt
2032                { $$ = DeclarationNode::newAggregate( $1, $3, $9, $7, true )->addQualifiers( $2 ); }
2033        | aggregate_key attribute_list_opt type_name fred
2034                {
2035                        // for type_name can be a qualified type name S.T, in which case only the last name in the chain needs a typedef (other names in the chain should already have one)
2036                        typedefTable.makeTypedef( *$3->type->leafName(), forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname ); // create typedef
2037                        forall = false;                                                         // reset
2038                }
2039          '{' field_declaration_list_opt '}' type_parameters_opt
2040                { $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $9, $7, true )->addQualifiers( $2 ); }
2041        | aggregate_type_nobody
2042        ;
2043
2044type_parameters_opt:
2045        // empty
2046                { $$ = nullptr; }                                                               %prec '}'
2047        | '(' type_list ')'
2048                { $$ = $2; }
2049        ;
2050
2051aggregate_type_nobody:                                                                  // struct, union - {...}
2052        aggregate_key attribute_list_opt no_attr_identifier fred
2053                {
2054                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname );
2055                        forall = false;                                                         // reset
2056                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2057                }
2058        | aggregate_key attribute_list_opt type_name fred
2059                {
2060                        forall = false;                                                         // reset
2061                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2062                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2063                        // delete newFromTypeGen.
2064                        $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2065                        $3->type->symbolic.name = nullptr;
2066                        $3->type->symbolic.actuals = nullptr;
2067                        delete $3;
2068                }
2069        ;
2070
2071aggregate_key:
2072        STRUCT
2073                { yyy = true; $$ = DeclarationNode::Struct; }
2074        | UNION
2075                { yyy = true; $$ = DeclarationNode::Union; }
2076        | EXCEPTION
2077                { yyy = true; $$ = DeclarationNode::Exception; }
2078        | GENERATOR
2079                { yyy = true; $$ = DeclarationNode::Coroutine; }
2080        | COROUTINE
2081                { yyy = true; $$ = DeclarationNode::Coroutine; }
2082        | MONITOR
2083                { yyy = true; $$ = DeclarationNode::Monitor; }
2084        | THREAD
2085                { yyy = true; $$ = DeclarationNode::Thread; }
2086        ;
2087
2088field_declaration_list_opt:
2089        // empty
2090                { $$ = nullptr; }
2091        | field_declaration_list_opt field_declaration
2092                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2093        ;
2094
2095field_declaration:
2096        type_specifier field_declaring_list_opt ';'
2097                { $$ = fieldDecl( $1, $2 ); }
2098        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2099                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2100        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2101                {
2102                        if ( ! $3 ) {                                                           // field declarator ?
2103                                $3 = DeclarationNode::newName( nullptr );
2104                        } // if
2105                        $3->inLine = true;
2106                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2107                        distInl( $3 );
2108                }
2109        | typedef_declaration ';'                                                       // CFA
2110        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2111        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2112                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2113        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2114                { $$ = $2; }                                                                    // mark all fields in list
2115        | cfa_typedef_declaration ';'                                           // CFA
2116        | static_assert                                                                         // C11
2117        ;
2118
2119field_declaring_list_opt:
2120        // empty
2121                { $$ = nullptr; }
2122        | field_declarator
2123        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2124                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2125        ;
2126
2127field_declarator:
2128        bit_subrange_size                                                                       // C special case, no field name
2129                { $$ = DeclarationNode::newBitfield( $1 ); }
2130        | variable_declarator bit_subrange_size_opt
2131                // A semantic check is required to ensure bit_subrange only appears on integral types.
2132                { $$ = $1->addBitfield( $2 ); }
2133        | variable_type_redeclarator bit_subrange_size_opt
2134                // A semantic check is required to ensure bit_subrange only appears on integral types.
2135                { $$ = $1->addBitfield( $2 ); }
2136        ;
2137
2138field_abstract_list_opt:
2139        // empty
2140                { $$ = nullptr; }
2141        | field_abstract
2142        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2143                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2144        ;
2145
2146field_abstract:
2147                //      no bit fields
2148        variable_abstract_declarator
2149        ;
2150
2151cfa_field_declaring_list:                                                               // CFA, new style field declaration
2152        // bit-fields are handled by C declarations
2153        cfa_abstract_declarator_tuple no_attr_identifier_or_type_name
2154                { $$ = $1->addName( $2 ); }
2155        | cfa_field_declaring_list ',' no_attr_identifier_or_type_name
2156                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2157        ;
2158
2159cfa_field_abstract_list:                                                                // CFA, new style field declaration
2160        // bit-fields are handled by C declarations
2161        cfa_abstract_declarator_tuple
2162        | cfa_field_abstract_list ','
2163                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2164        ;
2165
2166bit_subrange_size_opt:
2167        // empty
2168                { $$ = nullptr; }
2169        | bit_subrange_size
2170        ;
2171
2172bit_subrange_size:
2173        ':' assignment_expression
2174                { $$ = $2; }
2175        ;
2176
2177enum_type:                                                                                              // enum
2178        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2179                { $$ = DeclarationNode::newEnum( nullptr, $4, true )->addQualifiers( $2 ); }
2180        | ENUM attribute_list_opt no_attr_identifier
2181                { typedefTable.makeTypedef( *$3 ); }
2182          '{' enumerator_list comma_opt '}'
2183                { $$ = DeclarationNode::newEnum( $3, $6, true )->addQualifiers( $2 ); }
2184        | ENUM attribute_list_opt type_name
2185          '{' enumerator_list comma_opt '}'
2186                { $$ = DeclarationNode::newEnum( $3->type->symbolic.name, $5, true )->addQualifiers( $2 ); }
2187        | enum_type_nobody
2188        ;
2189
2190enum_type_nobody:                                                                               // enum - {...}
2191        ENUM attribute_list_opt no_attr_identifier
2192                {
2193                        typedefTable.makeTypedef( *$3 );
2194                        $$ = DeclarationNode::newEnum( $3, 0, false )->addQualifiers( $2 );
2195                }
2196        | ENUM attribute_list_opt type_name
2197                {
2198                        typedefTable.makeTypedef( *$3->type->symbolic.name );
2199                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, 0, false )->addQualifiers( $2 );
2200                }
2201        ;
2202
2203enumerator_list:
2204        no_attr_identifier_or_type_name enumerator_value_opt
2205                { $$ = DeclarationNode::newEnumConstant( $1, $2 ); }
2206        | enumerator_list ',' no_attr_identifier_or_type_name enumerator_value_opt
2207                { $$ = $1->appendList( DeclarationNode::newEnumConstant( $3, $4 ) ); }
2208        ;
2209
2210enumerator_value_opt:
2211        // empty
2212                { $$ = nullptr; }
2213        | '=' constant_expression
2214                { $$ = $2; }
2215        ;
2216
2217cfa_parameter_ellipsis_list_opt:                                                        // CFA, abstract + real
2218        // empty
2219                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2220        | ELLIPSIS
2221                { $$ = nullptr; }
2222        | cfa_abstract_parameter_list
2223        | cfa_parameter_list
2224        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2225                { $$ = $1->appendList( $5 ); }
2226        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2227                { $$ = $1->addVarArgs(); }
2228        | cfa_parameter_list pop ',' push ELLIPSIS
2229                { $$ = $1->addVarArgs(); }
2230        ;
2231
2232cfa_parameter_list:                                                                             // CFA
2233                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2234                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2235        cfa_parameter_declaration
2236        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2237                { $$ = $1->appendList( $5 ); }
2238        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2239                { $$ = $1->appendList( $5 ); }
2240        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2241                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2242        ;
2243
2244cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2245        cfa_abstract_parameter_declaration
2246        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2247                { $$ = $1->appendList( $5 ); }
2248        ;
2249
2250parameter_type_list_opt:
2251        // empty
2252                { $$ = nullptr; }
2253        | ELLIPSIS
2254                { $$ = nullptr; }
2255        | parameter_list
2256        | parameter_list pop ',' push ELLIPSIS
2257                { $$ = $1->addVarArgs(); }
2258        ;
2259
2260parameter_list:                                                                                 // abstract + real
2261        abstract_parameter_declaration
2262        | parameter_declaration
2263        | parameter_list pop ',' push abstract_parameter_declaration
2264                { $$ = $1->appendList( $5 ); }
2265        | parameter_list pop ',' push parameter_declaration
2266                { $$ = $1->appendList( $5 ); }
2267        ;
2268
2269// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2270// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2271
2272cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2273        parameter_declaration
2274        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initialize_opt
2275                { $$ = $1->addName( $2 ); }
2276        | cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2277                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2278                { $$ = $1->addName( $2 ); }
2279        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initialize_opt
2280                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2281        | cfa_function_specifier
2282        ;
2283
2284cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2285        abstract_parameter_declaration
2286        | cfa_identifier_parameter_declarator_no_tuple
2287        | cfa_abstract_tuple
2288                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2289        | type_qualifier_list cfa_abstract_tuple
2290                { $$ = $2->addQualifiers( $1 ); }
2291        | cfa_abstract_function
2292        ;
2293
2294parameter_declaration:
2295                // No SUE declaration in parameter list.
2296        declaration_specifier_nobody identifier_parameter_declarator default_initialize_opt
2297                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2298        | declaration_specifier_nobody type_parameter_redeclarator default_initialize_opt
2299                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2300        ;
2301
2302abstract_parameter_declaration:
2303        declaration_specifier_nobody default_initialize_opt
2304                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2305        | declaration_specifier_nobody abstract_parameter_declarator default_initialize_opt
2306                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2307        ;
2308
2309// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2310// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2311// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2312
2313identifier_list:                                                                                // K&R-style parameter list => no types
2314        no_attr_identifier
2315                { $$ = DeclarationNode::newName( $1 ); }
2316        | identifier_list ',' no_attr_identifier
2317                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2318        ;
2319
2320identifier_or_type_name:
2321        identifier
2322        | TYPEDEFname
2323        | TYPEGENname
2324        ;
2325
2326no_attr_identifier_or_type_name:
2327        no_attr_identifier
2328        | TYPEDEFname
2329        | TYPEGENname
2330        ;
2331
2332type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2333        cfa_abstract_declarator_tuple                                           // CFA
2334        | type_specifier
2335        | type_specifier abstract_declarator
2336                { $$ = $2->addType( $1 ); }
2337        ;
2338
2339type:                                                                                                   // typeof, assertion
2340        type_no_function
2341        | cfa_abstract_function                                                         // CFA
2342        ;
2343
2344initializer_opt:
2345        // empty
2346                { $$ = nullptr; }
2347        | '=' initializer
2348                { $$ = $2; }
2349        | '=' VOID
2350                { $$ = new InitializerNode( true ); }
2351        | ATassign initializer
2352                { $$ = $2->set_maybeConstructed( false ); }
2353        ;
2354
2355initializer:
2356        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2357        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2358        ;
2359
2360initializer_list_opt:
2361        // empty
2362                { $$ = nullptr; }
2363        | initializer
2364        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2365        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2366        | initializer_list_opt ',' designation initializer
2367                { $$ = (InitializerNode *)( $1->set_last( $4->set_designators( $3 ) ) ); }
2368        ;
2369
2370// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2371// '=' to separator the designator from the initializer value, as in:
2372//
2373//              int x[10] = { [1] = 3 };
2374//
2375// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2376// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2377// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2378// shift/reduce conflicts
2379
2380designation:
2381        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2382        | no_attr_identifier ':'                                                        // GCC, field name
2383                { $$ = new ExpressionNode( build_varref( $1 ) ); }
2384        ;
2385
2386designator_list:                                                                                // C99
2387        designator
2388        | designator_list designator
2389                { $$ = (ExpressionNode *)( $1->set_last( $2 ) ); }
2390        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2391        ;
2392
2393designator:
2394        '.' no_attr_identifier                                                          // C99, field name
2395                { $$ = new ExpressionNode( build_varref( $2 ) ); }
2396        | '[' push assignment_expression pop ']'                        // C99, single array element
2397                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2398                { $$ = $3; }
2399        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2400                { $$ = $3; }
2401        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2402                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $3 ), maybeMoveBuild< Expression >( $5 ) ) ); }
2403        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2404                { $$ = $4; }
2405        ;
2406
2407// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2408// rather than an object-oriented type system. This required four groups of extensions:
2409//
2410// Overloading: function, data, and operator identifiers may be overloaded.
2411//
2412// Type declarations: "type" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2413//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2414//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2415//
2416// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2417//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2418//
2419// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2420//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2421//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2422//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2423//     on type arguments of polymorphic functions.
2424
2425type_parameter_list:                                                                    // CFA
2426        type_parameter
2427        | type_parameter_list ',' type_parameter
2428                { $$ = $1->appendList( $3 ); }
2429        ;
2430
2431type_initializer_opt:                                                                   // CFA
2432        // empty
2433                { $$ = nullptr; }
2434        | '=' type
2435                { $$ = $2; }
2436        ;
2437
2438type_parameter:                                                                                 // CFA
2439        type_class no_attr_identifier_or_type_name
2440                { typedefTable.addToScope( *$2, TYPEDEFname, "9" ); }
2441          type_initializer_opt assertion_list_opt
2442                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2443        | type_specifier identifier_parameter_declarator
2444        | assertion_list
2445                { $$ = DeclarationNode::newTypeParam( DeclarationNode::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
2446        ;
2447
2448type_class:                                                                                             // CFA
2449        OTYPE
2450                { $$ = DeclarationNode::Otype; }
2451        | DTYPE
2452                { $$ = DeclarationNode::Dtype; }
2453        | FTYPE
2454                { $$ = DeclarationNode::Ftype; }
2455        | TTYPE
2456                { $$ = DeclarationNode::Ttype; }
2457        ;
2458
2459assertion_list_opt:                                                                             // CFA
2460        // empty
2461                { $$ = nullptr; }
2462        | assertion_list
2463        ;
2464
2465assertion_list:                                                                                 // CFA
2466        assertion
2467        | assertion_list assertion
2468                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2469        ;
2470
2471assertion:                                                                                              // CFA
2472        '|' no_attr_identifier_or_type_name '(' type_list ')'
2473                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
2474        | '|' '{' push trait_declaration_list pop '}'
2475                { $$ = $4; }
2476        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
2477        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
2478        ;
2479
2480type_list:                                                                                              // CFA
2481        type
2482                { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( $1 ) ) ); }
2483        | assignment_expression
2484                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $1->build()) ); $$ = nullptr; }
2485        | type_list ',' type
2486                { $$ = (ExpressionNode *)( $1->set_last( new ExpressionNode( new TypeExpr( maybeMoveBuildType( $3 ) ) ) ) ); }
2487        | type_list ',' assignment_expression
2488                { SemanticError( yylloc, toString("Expression generic parameters are currently unimplemented: ", $3->build()) ); $$ = nullptr; }
2489                // { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
2490        ;
2491
2492type_declaring_list:                                                                    // CFA
2493        OTYPE type_declarator
2494                { $$ = $2; }
2495        | storage_class_list OTYPE type_declarator
2496                { $$ = $3->addQualifiers( $1 ); }
2497        | type_declaring_list ',' type_declarator
2498                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
2499        ;
2500
2501type_declarator:                                                                                // CFA
2502        type_declarator_name assertion_list_opt
2503                { $$ = $1->addAssertions( $2 ); }
2504        | type_declarator_name assertion_list_opt '=' type
2505                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
2506        ;
2507
2508type_declarator_name:                                                                   // CFA
2509        no_attr_identifier_or_type_name
2510                {
2511                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "10" );
2512                        $$ = DeclarationNode::newTypeDecl( $1, 0 );
2513                }
2514        | no_attr_identifier_or_type_name '(' type_parameter_list ')'
2515                {
2516                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "11" );
2517                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
2518                }
2519        ;
2520
2521trait_specifier:                                                                                // CFA
2522        TRAIT no_attr_identifier_or_type_name '(' type_parameter_list ')' '{' '}'
2523                { $$ = DeclarationNode::newTrait( $2, $4, 0 ); }
2524        | TRAIT no_attr_identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
2525                { $$ = DeclarationNode::newTrait( $2, $4, $8 ); }
2526        ;
2527
2528trait_declaration_list:                                                                 // CFA
2529        trait_declaration
2530        | trait_declaration_list pop push trait_declaration
2531                { $$ = $1->appendList( $4 ); }
2532        ;
2533
2534trait_declaration:                                                                              // CFA
2535        cfa_trait_declaring_list ';'
2536        | trait_declaring_list ';'
2537        ;
2538
2539cfa_trait_declaring_list:                                                               // CFA
2540        cfa_variable_specifier
2541        | cfa_function_specifier
2542        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
2543                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
2544        ;
2545
2546trait_declaring_list:                                                                   // CFA
2547        type_specifier declarator
2548                { $$ = $2->addType( $1 ); }
2549        | trait_declaring_list pop ',' push declarator
2550                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
2551        ;
2552
2553//***************************** EXTERNAL DEFINITIONS *****************************
2554
2555translation_unit:
2556        // empty, input file
2557        | external_definition_list
2558                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
2559        ;
2560
2561external_definition_list:
2562        push external_definition pop
2563                { $$ = $2; }
2564        | external_definition_list push external_definition pop
2565                { $$ = $1 ? $1->appendList( $3 ) : $3; }
2566        ;
2567
2568external_definition_list_opt:
2569        // empty
2570                { $$ = nullptr; }
2571        | external_definition_list
2572        ;
2573
2574up:
2575                { typedefTable.up( forall ); forall = false; }
2576        ;
2577
2578down:
2579                { typedefTable.down(); }
2580        ;
2581
2582external_definition:
2583        declaration
2584        | external_function_definition
2585        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
2586                {
2587                        distExt( $2 );                                                          // mark all fields in list
2588                        $$ = $2;
2589                }
2590        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
2591                {
2592                        $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( false, $3, 0 ) ) );
2593                }
2594        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
2595                {
2596                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
2597                        linkage = LinkageSpec::linkageUpdate( yylloc, linkage, $2 );
2598                }
2599          '{' up external_definition_list_opt down '}'
2600                {
2601                        linkage = linkageStack.top();
2602                        linkageStack.pop();
2603                        $$ = $6;
2604                }
2605        | type_qualifier_list
2606                {
2607                        if ( $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2608                        if ( $1->type->forall ) forall = true;          // remember generic type
2609                }
2610          '{' up external_definition_list_opt down '}'          // CFA, namespace
2611                {
2612                        distQual( $5, $1 );
2613                        forall = false;
2614                        $$ = $5;
2615                }
2616        | declaration_qualifier_list
2617                {
2618                        if ( $1->type && $1->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2619                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
2620                }
2621          '{' up external_definition_list_opt down '}'          // CFA, namespace
2622                {
2623                        distQual( $5, $1 );
2624                        forall = false;
2625                        $$ = $5;
2626                }
2627        | declaration_qualifier_list type_qualifier_list
2628                {
2629                        if ( ($1->type && $1->type->qualifiers.val) || $2->type->qualifiers.val ) { SemanticError( yylloc, "CV qualifiers cannot be distributed; only storage-class and forall qualifiers." ); }
2630                        if ( ($1->type && $1->type->forall) || $2->type->forall ) forall = true; // remember generic type
2631                }
2632          '{' up external_definition_list_opt down '}'          // CFA, namespace
2633                {
2634                        distQual( $6, $1->addQualifiers( $2 ) );
2635                        forall = false;
2636                        $$ = $6;
2637                }
2638        ;
2639
2640external_function_definition:
2641        function_definition
2642                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
2643                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
2644                // Parsing is possible because function_definition does not appear in the context of an expression (nested
2645                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
2646                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
2647        | function_declarator compound_statement
2648                { $$ = $1->addFunctionBody( $2 ); }
2649        | KR_function_declarator KR_parameter_list_opt compound_statement
2650                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
2651        ;
2652
2653with_clause_opt:
2654        // empty
2655                { $$ = nullptr; forall = false; }
2656        | WITH '(' tuple_expression_list ')'
2657                { $$ = $3; forall = false; }
2658        ;
2659
2660function_definition:
2661        cfa_function_declaration with_clause_opt compound_statement     // CFA
2662                {
2663                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
2664                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
2665                        $1->get_last()->addFunctionBody( $3, $2 );
2666                        $$ = $1;
2667                }
2668        | declaration_specifier function_declarator with_clause_opt compound_statement
2669                {
2670                        rebindForall( $1, $2 );
2671                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2672                }
2673        | declaration_specifier variable_type_redeclarator with_clause_opt compound_statement
2674                {
2675                        rebindForall( $1, $2 );
2676                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
2677                }
2678                // handles default int return type, OBSOLESCENT (see 1)
2679        | type_qualifier_list function_declarator with_clause_opt compound_statement
2680                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2681                // handles default int return type, OBSOLESCENT (see 1)
2682        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
2683                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
2684                // handles default int return type, OBSOLESCENT (see 1)
2685        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
2686                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2687
2688                // Old-style K&R function definition, OBSOLESCENT (see 4)
2689        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2690                {
2691                        rebindForall( $1, $2 );
2692                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
2693                }
2694                // handles default int return type, OBSOLESCENT (see 1)
2695        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2696                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2697                // handles default int return type, OBSOLESCENT (see 1)
2698        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2699                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
2700                // handles default int return type, OBSOLESCENT (see 1)
2701        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
2702                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
2703        ;
2704
2705declarator:
2706        variable_declarator
2707        | variable_type_redeclarator
2708        | function_declarator
2709        ;
2710
2711subrange:
2712        constant_expression '~' constant_expression                     // CFA, integer subrange
2713                { $$ = new ExpressionNode( new RangeExpr( maybeMoveBuild< Expression >( $1 ), maybeMoveBuild< Expression >( $3 ) ) ); }
2714        ;
2715
2716asm_name_opt:                                                                                   // GCC
2717        // empty
2718                { $$ = nullptr; }
2719        | ASM '(' string_literal ')' attribute_list_opt
2720                {
2721                        DeclarationNode * name = new DeclarationNode();
2722                        name->asmName = $3;
2723                        $$ = name->addQualifiers( $5 );
2724                }
2725        ;
2726
2727attribute_list_opt:                                                                             // GCC
2728        // empty
2729                { $$ = nullptr; }
2730        | attribute_list
2731        ;
2732
2733attribute_list:                                                                                 // GCC
2734        attribute
2735        | attribute_list attribute
2736                { $$ = $2->addQualifiers( $1 ); }
2737        ;
2738
2739attribute:                                                                                              // GCC
2740        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
2741                { $$ = $4; }
2742        ;
2743
2744attribute_name_list:                                                                    // GCC
2745        attribute_name
2746        | attribute_name_list ',' attribute_name
2747                { $$ = $3->addQualifiers( $1 ); }
2748        ;
2749
2750attribute_name:                                                                                 // GCC
2751        // empty
2752                { $$ = nullptr; }
2753        | attr_name
2754                { $$ = DeclarationNode::newAttribute( $1 ); }
2755        | attr_name '(' argument_expression_list ')'
2756                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
2757        ;
2758
2759attr_name:                                                                                              // GCC
2760        IDENTIFIER
2761        | quasi_keyword
2762        | TYPEDEFname
2763        | TYPEGENname
2764        | FALLTHROUGH
2765                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
2766        | CONST
2767                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
2768        ;
2769
2770// ============================================================================
2771// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
2772// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
2773// in:
2774//
2775//              int (*f())[10] { ... };
2776//              ... (*f())[3] += 1;             // definition mimics usage
2777//
2778// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
2779// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
2780// ============================================================================
2781
2782// ----------------------------------------------------------------------------
2783// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
2784// to define a variable or function prototype, e.g.:
2785//
2786//              valid declaration               invalid definition
2787//              -----------------               ------------------
2788//              int f;                                  int f {}
2789//              int *f;                                 int *f {}
2790//              int f[10];                              int f[10] {}
2791//              int (*f)(int);                  int (*f)(int) {}
2792//
2793// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
2794// variable_declarator and function_declarator.
2795// ----------------------------------------------------------------------------
2796
2797// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
2798// declaring an array of functions versus a pointer to an array of functions.
2799
2800variable_declarator:
2801        paren_identifier attribute_list_opt
2802                { $$ = $1->addQualifiers( $2 ); }
2803        | variable_ptr
2804        | variable_array attribute_list_opt
2805                { $$ = $1->addQualifiers( $2 ); }
2806        | variable_function attribute_list_opt
2807                { $$ = $1->addQualifiers( $2 ); }
2808        ;
2809
2810paren_identifier:
2811        identifier
2812                { $$ = DeclarationNode::newName( $1 ); }
2813        | '(' paren_identifier ')'                                                      // redundant parenthesis
2814                { $$ = $2; }
2815        ;
2816
2817variable_ptr:
2818        ptrref_operator variable_declarator
2819                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2820        | ptrref_operator type_qualifier_list variable_declarator
2821                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2822        | '(' variable_ptr ')' attribute_list_opt
2823                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2824        ;
2825
2826variable_array:
2827        paren_identifier array_dimension
2828                { $$ = $1->addArray( $2 ); }
2829        | '(' variable_ptr ')' array_dimension
2830                { $$ = $2->addArray( $4 ); }
2831        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
2832                { $$ = $2->addArray( $4 ); }
2833        | '(' variable_array ')'                                                        // redundant parenthesis
2834                { $$ = $2; }
2835        ;
2836
2837variable_function:
2838        '(' variable_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2839                { $$ = $2->addParamList( $6 ); }
2840        | '(' variable_function ')'                                                     // redundant parenthesis
2841                { $$ = $2; }
2842        ;
2843
2844// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
2845// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
2846// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
2847
2848function_declarator:
2849        function_no_ptr attribute_list_opt
2850                { $$ = $1->addQualifiers( $2 ); }
2851        | function_ptr
2852        | function_array attribute_list_opt
2853                { $$ = $1->addQualifiers( $2 ); }
2854        ;
2855
2856function_no_ptr:
2857        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2858                { $$ = $1->addParamList( $4 ); }
2859        | '(' function_ptr ')' '(' push parameter_type_list_opt pop ')'
2860                { $$ = $2->addParamList( $6 ); }
2861        | '(' function_no_ptr ')'                                                       // redundant parenthesis
2862                { $$ = $2; }
2863        ;
2864
2865function_ptr:
2866        ptrref_operator function_declarator
2867                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2868        | ptrref_operator type_qualifier_list function_declarator
2869                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2870        | '(' function_ptr ')'
2871                { $$ = $2; }
2872        ;
2873
2874function_array:
2875        '(' function_ptr ')' array_dimension
2876                { $$ = $2->addArray( $4 ); }
2877        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
2878                { $$ = $2->addArray( $4 ); }
2879        | '(' function_array ')'                                                        // redundant parenthesis
2880                { $$ = $2; }
2881        ;
2882
2883// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
2884//
2885//   f( a, b, c ) int a, *b, c[]; {}
2886//
2887// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
2888// returning arrays and functions versus pointers to arrays and functions.
2889
2890KR_function_declarator:
2891        KR_function_no_ptr
2892        | KR_function_ptr
2893        | KR_function_array
2894        ;
2895
2896KR_function_no_ptr:
2897        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
2898                { $$ = $1->addIdList( $3 ); }
2899        | '(' KR_function_ptr ')' '(' push parameter_type_list_opt pop ')'
2900                { $$ = $2->addParamList( $6 ); }
2901        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
2902                { $$ = $2; }
2903        ;
2904
2905KR_function_ptr:
2906        ptrref_operator KR_function_declarator
2907                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2908        | ptrref_operator type_qualifier_list KR_function_declarator
2909                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2910        | '(' KR_function_ptr ')'
2911                { $$ = $2; }
2912        ;
2913
2914KR_function_array:
2915        '(' KR_function_ptr ')' array_dimension
2916                { $$ = $2->addArray( $4 ); }
2917        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
2918                { $$ = $2->addArray( $4 ); }
2919        | '(' KR_function_array ')'                                                     // redundant parenthesis
2920                { $$ = $2; }
2921        ;
2922
2923// This pattern parses a declaration for a variable or function prototype that redefines a type name, e.g.:
2924//
2925//              typedef int foo;
2926//              {
2927//                 int foo; // redefine typedef name in new scope
2928//              }
2929//
2930// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
2931// and functions versus pointers to arrays and functions.
2932
2933variable_type_redeclarator:
2934        paren_type attribute_list_opt
2935                { $$ = $1->addQualifiers( $2 ); }
2936        | type_ptr
2937        | type_array attribute_list_opt
2938                { $$ = $1->addQualifiers( $2 ); }
2939        | type_function attribute_list_opt
2940                { $$ = $1->addQualifiers( $2 ); }
2941        ;
2942
2943paren_type:
2944        typedef
2945                // hide type name in enclosing scope by variable name
2946                {
2947                        // if ( ! typedefTable.existsCurr( *$1->name ) ) {
2948                                typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "ID" );
2949                        // } else {
2950                        //      SemanticError( yylloc, string("'") + *$1->name + "' redeclared as different kind of symbol." ); $$ = nullptr;
2951                        // } // if
2952                }
2953        | '(' paren_type ')'
2954                { $$ = $2; }
2955        ;
2956
2957type_ptr:
2958        ptrref_operator variable_type_redeclarator
2959                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
2960        | ptrref_operator type_qualifier_list variable_type_redeclarator
2961                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
2962        | '(' type_ptr ')' attribute_list_opt
2963                { $$ = $2->addQualifiers( $4 ); }                               // redundant parenthesis
2964        ;
2965
2966type_array:
2967        paren_type array_dimension
2968                { $$ = $1->addArray( $2 ); }
2969        | '(' type_ptr ')' array_dimension
2970                { $$ = $2->addArray( $4 ); }
2971        | '(' type_array ')' multi_array_dimension                      // redundant parenthesis
2972                { $$ = $2->addArray( $4 ); }
2973        | '(' type_array ')'                                                            // redundant parenthesis
2974                { $$ = $2; }
2975        ;
2976
2977type_function:
2978        paren_type '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2979                { $$ = $1->addParamList( $4 ); }
2980        | '(' type_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
2981                { $$ = $2->addParamList( $6 ); }
2982        | '(' type_function ')'                                                         // redundant parenthesis
2983                { $$ = $2; }
2984        ;
2985
2986// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
2987// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
2988// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
2989// pointers to arrays and functions.
2990
2991identifier_parameter_declarator:
2992        paren_identifier attribute_list_opt
2993                { $$ = $1->addQualifiers( $2 ); }
2994        | '&' MUTEX paren_identifier attribute_list_opt
2995                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
2996        | identifier_parameter_ptr
2997        | identifier_parameter_array attribute_list_opt
2998                { $$ = $1->addQualifiers( $2 ); }
2999        | identifier_parameter_function attribute_list_opt
3000                { $$ = $1->addQualifiers( $2 ); }
3001        ;
3002
3003identifier_parameter_ptr:
3004        ptrref_operator identifier_parameter_declarator
3005                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3006        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3007                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3008        | '(' identifier_parameter_ptr ')' attribute_list_opt
3009                { $$ = $2->addQualifiers( $4 ); }
3010        ;
3011
3012identifier_parameter_array:
3013        paren_identifier array_parameter_dimension
3014                { $$ = $1->addArray( $2 ); }
3015        | '(' identifier_parameter_ptr ')' array_dimension
3016                { $$ = $2->addArray( $4 ); }
3017        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3018                { $$ = $2->addArray( $4 ); }
3019        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3020                { $$ = $2; }
3021        ;
3022
3023identifier_parameter_function:
3024        paren_identifier '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3025                { $$ = $1->addParamList( $4 ); }
3026        | '(' identifier_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3027                { $$ = $2->addParamList( $6 ); }
3028        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3029                { $$ = $2; }
3030        ;
3031
3032// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3033// e.g.:
3034//
3035//              typedef int foo;
3036//              forall( otype T ) struct foo;
3037//              int f( int foo ); // redefine typedef name in new scope
3038//
3039// and allows the C99 array options, which can only appear in a parameter list.
3040
3041type_parameter_redeclarator:
3042        typedef attribute_list_opt
3043                { $$ = $1->addQualifiers( $2 ); }
3044        | '&' MUTEX typedef attribute_list_opt
3045                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3046        | type_parameter_ptr
3047        | type_parameter_array attribute_list_opt
3048                { $$ = $1->addQualifiers( $2 ); }
3049        | type_parameter_function attribute_list_opt
3050                { $$ = $1->addQualifiers( $2 ); }
3051        ;
3052
3053typedef:
3054        TYPEDEFname
3055                { $$ = DeclarationNode::newName( $1 ); }
3056        | TYPEGENname
3057                { $$ = DeclarationNode::newName( $1 ); }
3058        ;
3059
3060type_parameter_ptr:
3061        ptrref_operator type_parameter_redeclarator
3062                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3063        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3064                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3065        | '(' type_parameter_ptr ')' attribute_list_opt
3066                { $$ = $2->addQualifiers( $4 ); }
3067        ;
3068
3069type_parameter_array:
3070        typedef array_parameter_dimension
3071                { $$ = $1->addArray( $2 ); }
3072        | '(' type_parameter_ptr ')' array_parameter_dimension
3073                { $$ = $2->addArray( $4 ); }
3074        ;
3075
3076type_parameter_function:
3077        typedef '(' push parameter_type_list_opt pop ')'        // empty parameter list OBSOLESCENT (see 3)
3078                { $$ = $1->addParamList( $4 ); }
3079        | '(' type_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3080                { $$ = $2->addParamList( $6 ); }
3081        ;
3082
3083// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3084// which the type applies, e.g.:
3085//
3086//              sizeof( int );
3087//              sizeof( int * );
3088//              sizeof( int [10] );
3089//              sizeof( int (*)() );
3090//              sizeof( int () );
3091//
3092// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3093// and functions versus pointers to arrays and functions.
3094
3095abstract_declarator:
3096        abstract_ptr
3097        | abstract_array attribute_list_opt
3098                { $$ = $1->addQualifiers( $2 ); }
3099        | abstract_function attribute_list_opt
3100                { $$ = $1->addQualifiers( $2 ); }
3101        ;
3102
3103abstract_ptr:
3104        ptrref_operator
3105                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3106        | ptrref_operator type_qualifier_list
3107                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3108        | ptrref_operator abstract_declarator
3109                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3110        | ptrref_operator type_qualifier_list abstract_declarator
3111                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3112        | '(' abstract_ptr ')' attribute_list_opt
3113                { $$ = $2->addQualifiers( $4 ); }
3114        ;
3115
3116abstract_array:
3117        array_dimension
3118        | '(' abstract_ptr ')' array_dimension
3119                { $$ = $2->addArray( $4 ); }
3120        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3121                { $$ = $2->addArray( $4 ); }
3122        | '(' abstract_array ')'                                                        // redundant parenthesis
3123                { $$ = $2; }
3124        ;
3125
3126abstract_function:
3127        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3128                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3129        | '(' abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3130                { $$ = $2->addParamList( $6 ); }
3131        | '(' abstract_function ')'                                                     // redundant parenthesis
3132                { $$ = $2; }
3133        ;
3134
3135array_dimension:
3136                // Only the first dimension can be empty.
3137        '[' ']'
3138                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3139        | '[' ']' multi_array_dimension
3140                { $$ = DeclarationNode::newArray( 0, 0, false )->addArray( $3 ); }
3141        | multi_array_dimension
3142        ;
3143
3144multi_array_dimension:
3145        '[' push assignment_expression pop ']'
3146                { $$ = DeclarationNode::newArray( $3, 0, false ); }
3147        | '[' push '*' pop ']'                                                          // C99
3148                { $$ = DeclarationNode::newVarArray( 0 ); }
3149        | multi_array_dimension '[' push assignment_expression pop ']'
3150                { $$ = $1->addArray( DeclarationNode::newArray( $4, 0, false ) ); }
3151        | multi_array_dimension '[' push '*' pop ']'            // C99
3152                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3153        ;
3154
3155// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3156// identifier to which the type applies, e.g.:
3157//
3158//              int f( int );                   // not handled here
3159//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3160//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3161//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3162//
3163// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3164// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3165// special meaning of parenthesis around a typedef name:
3166//
3167//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3168//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3169//              not as redundant parentheses around the identifier."
3170//
3171// For example:
3172//
3173//              typedef float T;
3174//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3175//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3176//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3177//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3178//
3179// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3180// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3181// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3182// functions.
3183
3184abstract_parameter_declarator:
3185        abstract_parameter_ptr
3186        | '&' MUTEX attribute_list_opt
3187                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3188        | abstract_parameter_array attribute_list_opt
3189                { $$ = $1->addQualifiers( $2 ); }
3190        | abstract_parameter_function attribute_list_opt
3191                { $$ = $1->addQualifiers( $2 ); }
3192        ;
3193
3194abstract_parameter_ptr:
3195        ptrref_operator
3196                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3197        | ptrref_operator type_qualifier_list
3198                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3199        | ptrref_operator abstract_parameter_declarator
3200                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3201        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3202                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3203        | '(' abstract_parameter_ptr ')' attribute_list_opt
3204                { $$ = $2->addQualifiers( $4 ); }
3205        ;
3206
3207abstract_parameter_array:
3208        array_parameter_dimension
3209        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3210                { $$ = $2->addArray( $4 ); }
3211        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3212                { $$ = $2->addArray( $4 ); }
3213        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3214                { $$ = $2; }
3215        ;
3216
3217abstract_parameter_function:
3218        '(' push parameter_type_list_opt pop ')'                        // empty parameter list OBSOLESCENT (see 3)
3219                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $3, nullptr ); }
3220        | '(' abstract_parameter_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3221                { $$ = $2->addParamList( $6 ); }
3222        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3223                { $$ = $2; }
3224        ;
3225
3226array_parameter_dimension:
3227                // Only the first dimension can be empty or have qualifiers.
3228        array_parameter_1st_dimension
3229        | array_parameter_1st_dimension multi_array_dimension
3230                { $$ = $1->addArray( $2 ); }
3231        | multi_array_dimension
3232        ;
3233
3234// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3235//
3236//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3237//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3238
3239array_parameter_1st_dimension:
3240        '[' ']'
3241                { $$ = DeclarationNode::newArray( 0, 0, false ); }
3242                // multi_array_dimension handles the '[' '*' ']' case
3243        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
3244                { $$ = DeclarationNode::newVarArray( $3 ); }
3245        | '[' push type_qualifier_list pop ']'
3246                { $$ = DeclarationNode::newArray( 0, $3, false ); }
3247                // multi_array_dimension handles the '[' assignment_expression ']' case
3248        | '[' push type_qualifier_list assignment_expression pop ']'
3249                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3250        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
3251                { $$ = DeclarationNode::newArray( $5, $4, true ); }
3252        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
3253                { $$ = DeclarationNode::newArray( $5, $3, true ); }
3254        ;
3255
3256// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
3257//
3258//              struct S {
3259//          int;
3260//          int *;
3261//          int [10];
3262//          int (*)();
3263//      };
3264
3265variable_abstract_declarator:
3266        variable_abstract_ptr
3267        | variable_abstract_array attribute_list_opt
3268                { $$ = $1->addQualifiers( $2 ); }
3269        | variable_abstract_function attribute_list_opt
3270                { $$ = $1->addQualifiers( $2 ); }
3271        ;
3272
3273variable_abstract_ptr:
3274        ptrref_operator
3275                { $$ = DeclarationNode::newPointer( 0, $1 ); }
3276        | ptrref_operator type_qualifier_list
3277                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3278        | ptrref_operator variable_abstract_declarator
3279                { $$ = $2->addPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3280        | ptrref_operator type_qualifier_list variable_abstract_declarator
3281                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3282        | '(' variable_abstract_ptr ')' attribute_list_opt
3283                { $$ = $2->addQualifiers( $4 ); }
3284        ;
3285
3286variable_abstract_array:
3287        array_dimension
3288        | '(' variable_abstract_ptr ')' array_dimension
3289                { $$ = $2->addArray( $4 ); }
3290        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
3291                { $$ = $2->addArray( $4 ); }
3292        | '(' variable_abstract_array ')'                                       // redundant parenthesis
3293                { $$ = $2; }
3294        ;
3295
3296variable_abstract_function:
3297        '(' variable_abstract_ptr ')' '(' push parameter_type_list_opt pop ')' // empty parameter list OBSOLESCENT (see 3)
3298                { $$ = $2->addParamList( $6 ); }
3299        | '(' variable_abstract_function ')'                            // redundant parenthesis
3300                { $$ = $2; }
3301        ;
3302
3303// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
3304// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
3305
3306cfa_identifier_parameter_declarator_tuple:                              // CFA
3307        cfa_identifier_parameter_declarator_no_tuple
3308        | cfa_abstract_tuple
3309        | type_qualifier_list cfa_abstract_tuple
3310                { $$ = $2->addQualifiers( $1 ); }
3311        ;
3312
3313cfa_identifier_parameter_declarator_no_tuple:                   // CFA
3314        cfa_identifier_parameter_ptr
3315        | cfa_identifier_parameter_array
3316        ;
3317
3318cfa_identifier_parameter_ptr:                                                   // CFA
3319                // No SUE declaration in parameter list.
3320        ptrref_operator type_specifier_nobody
3321                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3322        | type_qualifier_list ptrref_operator type_specifier_nobody
3323                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3324        | ptrref_operator cfa_abstract_function
3325                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3326        | type_qualifier_list ptrref_operator cfa_abstract_function
3327                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3328        | ptrref_operator cfa_identifier_parameter_declarator_tuple
3329                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3330        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
3331                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3332        ;
3333
3334cfa_identifier_parameter_array:                                                 // CFA
3335                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
3336                // shift/reduce conflict with new-style empty (void) function return type.
3337        '[' ']' type_specifier_nobody
3338                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3339        | cfa_array_parameter_1st_dimension type_specifier_nobody
3340                { $$ = $2->addNewArray( $1 ); }
3341        | '[' ']' multi_array_dimension type_specifier_nobody
3342                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3343        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
3344                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3345        | multi_array_dimension type_specifier_nobody
3346                { $$ = $2->addNewArray( $1 ); }
3347
3348        | '[' ']' cfa_identifier_parameter_ptr
3349                { $$ = $3->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3350        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
3351                { $$ = $2->addNewArray( $1 ); }
3352        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
3353                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( 0, 0, false ) ); }
3354        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
3355                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
3356        | multi_array_dimension cfa_identifier_parameter_ptr
3357                { $$ = $2->addNewArray( $1 ); }
3358        ;
3359
3360cfa_array_parameter_1st_dimension:
3361        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
3362                { $$ = DeclarationNode::newVarArray( $3 ); }
3363        | '[' push type_qualifier_list assignment_expression pop ']'
3364                { $$ = DeclarationNode::newArray( $4, $3, false ); }
3365        | '[' push declaration_qualifier_list assignment_expression pop ']'
3366                // declaration_qualifier_list must be used because of shift/reduce conflict with
3367                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
3368                // appear in this context.
3369                { $$ = DeclarationNode::newArray( $4, $3, true ); }
3370        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
3371                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
3372        ;
3373
3374// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
3375// identifier to which the type applies, e.g.:
3376//
3377//              [int] f( int );                         // abstract variable parameter; no parameter name specified
3378//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
3379//
3380// These rules need LR(3):
3381//
3382//              cfa_abstract_tuple identifier_or_type_name
3383//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
3384//
3385// since a function return type can be syntactically identical to a tuple type:
3386//
3387//              [int, int] t;
3388//              [int, int] f( int );
3389//
3390// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
3391// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
3392// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
3393// duplicated when appearing with cfa_function_specifier.
3394
3395cfa_abstract_declarator_tuple:                                                  // CFA
3396        cfa_abstract_tuple
3397        | type_qualifier_list cfa_abstract_tuple
3398                { $$ = $2->addQualifiers( $1 ); }
3399        | cfa_abstract_declarator_no_tuple
3400        ;
3401
3402cfa_abstract_declarator_no_tuple:                                               // CFA
3403        cfa_abstract_ptr
3404        | cfa_abstract_array
3405        ;
3406
3407cfa_abstract_ptr:                                                                               // CFA
3408        ptrref_operator type_specifier
3409                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3410        | type_qualifier_list ptrref_operator type_specifier
3411                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3412        | ptrref_operator cfa_abstract_function
3413                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3414        | type_qualifier_list ptrref_operator cfa_abstract_function
3415                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3416        | ptrref_operator cfa_abstract_declarator_tuple
3417                { $$ = $2->addNewPointer( DeclarationNode::newPointer( 0, $1 ) ); }
3418        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
3419                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
3420        ;
3421
3422cfa_abstract_array:                                                                             // CFA
3423                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
3424                // empty (void) function return type.
3425        '[' ']' type_specifier
3426                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3427        | '[' ']' multi_array_dimension type_specifier
3428                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3429        | multi_array_dimension type_specifier
3430                { $$ = $2->addNewArray( $1 ); }
3431        | '[' ']' cfa_abstract_ptr
3432                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3433        | '[' ']' multi_array_dimension cfa_abstract_ptr
3434                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
3435        | multi_array_dimension cfa_abstract_ptr
3436                { $$ = $2->addNewArray( $1 ); }
3437        ;
3438
3439cfa_abstract_tuple:                                                                             // CFA
3440        '[' push cfa_abstract_parameter_list pop ']'
3441                { $$ = DeclarationNode::newTuple( $3 ); }
3442        | '[' push type_specifier_nobody ELLIPSIS pop ']'
3443                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3444        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
3445                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
3446        ;
3447
3448cfa_abstract_function:                                                                  // CFA
3449//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
3450//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
3451        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
3452                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3453        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
3454                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
3455        ;
3456
3457// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
3458//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
3459//
3460// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
3461//    the declaration specifiers in a declaration is an obsolescent feature."
3462//
3463// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
3464//    prototype-format parameter type declarators) is an obsolescent feature."
3465//
3466// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
3467//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
3468
3469//************************* MISCELLANEOUS ********************************
3470
3471comma_opt:                                                                                              // redundant comma
3472        // empty
3473        | ','
3474        ;
3475
3476default_initialize_opt:
3477        // empty
3478                { $$ = nullptr; }
3479        | '=' assignment_expression
3480                { $$ = $2; }
3481        ;
3482
3483%%
3484
3485// ----end of grammar----
3486
3487// Local Variables: //
3488// mode: c++ //
3489// tab-width: 4 //
3490// compile-command: "make install" //
3491// End: //
Note: See TracBrowser for help on using the repository browser.