source: src/Parser/parser.yy @ 11ab0b4a

Last change on this file since 11ab0b4a was 11ab0b4a, checked in by Peter A. Buhr <pabuhr@…>, 7 months ago

add corun/cofor statement, update old cofor

  • Property mode set to 100644
File size: 175.1 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author           : Peter A. Buhr
10// Created On       : Sat Sep  1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Tue Oct  3 17:14:12 2023
13// Update Count     : 6396
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS.  While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks.  Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28//   designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule.  Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval )                                    // lexer loads this up each time
40#define YYDEBUG 1                                                                               // get the pretty debugging code to compile
41#define YYERROR_VERBOSE                                                                 // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "SynTree/Type.h"                               // for Type
51#include "DeclarationNode.h"                            // for DeclarationNode, ...
52#include "ExpressionNode.h"                             // for ExpressionNode, ...
53#include "InitializerNode.h"                            // for InitializerNode, ...
54#include "ParserTypes.h"
55#include "StatementNode.h"                              // for build_...
56#include "TypedefTable.h"
57#include "TypeData.h"
58#include "Common/SemanticError.h"                                               // error_str
59#include "Common/utility.h"                                                             // for maybeMoveBuild, maybeBuild, CodeLo...
60
61#include "SynTree/Attribute.h"                                                  // for Attribute
62
63// lex uses __null in a boolean context, it's fine.
64#ifdef __clang__
65#pragma GCC diagnostic ignored "-Wparentheses-equality"
66#endif
67
68extern DeclarationNode * parseTree;
69extern ast::Linkage::Spec linkage;
70extern TypedefTable typedefTable;
71
72stack<ast::Linkage::Spec> linkageStack;
73
74bool appendStr( string & to, string & from ) {
75        // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
76        //    "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
77        //    the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
78        //    easier to let the C compiler handle this case.
79        //
80        // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
81        //    without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
82        //    e.g., u"a" U"b" L"c" is disallowed.
83
84        if ( from[0] != '"' ) {                                                         // encoding ?
85                if ( to[0] != '"' ) {                                                   // encoding ?
86                        if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
87                                yyerror( "non-matching string encodings for string-literal concatenation" );
88                                return false;                                                   // parse error, must call YYERROR in action
89                        } else if ( from[1] == '8' ) {
90                                from.erase( 0, 1 );                                             // remove 2nd encoding
91                        } // if
92                } else {
93                        if ( from[1] == '8' ) {                                         // move encoding to start
94                                to = "u8" + to;
95                                from.erase( 0, 1 );                                             // remove 2nd encoding
96                        } else {
97                                to = from[0] + to;
98                        } // if
99                } // if
100                from.erase( 0, 1 );                                                             // remove 2nd encoding
101        } // if
102        to += " " + from;                                                                       // concatenated into single string
103        return true;
104} // appendStr
105
106DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
107        // distribute declaration_specifier across all declared variables, e.g., static, const, but not __attribute__.
108        assert( declList );
109        // printf( "distAttr1 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout );
110        DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec );
111        // printf( "distAttr2 cl %p\n", cl ); cl->type->print( std::cout );
112        // cl->type->aggregate.name = cl->type->aggInst.aggregate->aggregate.name;
113
114        for ( DeclarationNode * cur = dynamic_cast<DeclarationNode *>( declList->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
115                cl->cloneBaseType( cur );
116        } // for
117        declList->addType( cl );
118        // printf( "distAttr3 declList %p\n", declList ); declList->print( std::cout, 0 );
119        return declList;
120} // distAttr
121
122void distExt( DeclarationNode * declaration ) {
123        // distribute EXTENSION across all declarations
124        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
125                iter->set_extension( true );
126        } // for
127} // distExt
128
129void distInl( DeclarationNode * declaration ) {
130        // distribute INLINE across all declarations
131        for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
132                iter->set_inLine( true );
133        } // for
134} // distInl
135
136void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
137        // distribute qualifiers across all non-variable declarations in a distribution statemement
138        for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
139                // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
140                // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
141                // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
142                // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
143                DeclarationNode * clone = qualifiers->clone();
144                if ( qualifiers->type ) {                                               // forall clause ? (handles SC)
145                        if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
146                                swap( clone->type->forall, iter->type->aggregate.params );
147                                iter->addQualifiers( clone );
148                        } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
149                                // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
150                                DeclarationNode newnode;
151                                swap( newnode.type, iter->type->aggInst.aggregate );
152                                swap( clone->type->forall, newnode.type->aggregate.params );
153                                newnode.addQualifiers( clone );
154                                swap( newnode.type, iter->type->aggInst.aggregate );
155                        } else if ( iter->type->kind == TypeData::Function ) { // routines ?
156                                swap( clone->type->forall, iter->type->forall );
157                                iter->addQualifiers( clone );
158                        } // if
159                } else {                                                                                // just SC qualifiers
160                        iter->addQualifiers( clone );
161                } // if
162        } // for
163        delete qualifiers;
164} // distQual
165
166// There is an ambiguity for inline generic-routine return-types and generic routines.
167//   forall( otype T ) struct S { int i; } bar( T ) {}
168// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
169//   forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
170// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
171//   forall( otype T ) struct S { int T; };
172//   forall( otype W ) bar( W ) {}
173
174void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
175        if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
176                funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
177                declSpec->type->aggregate.params = nullptr;
178        } // if
179} // rebindForall
180
181string * build_postfix_name( string * name ) {
182        *name = string("__postfix_func_") + *name;
183        return name;
184} // build_postfix_name
185
186DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
187        if ( ! fieldList ) {                                                            // field declarator ?
188                if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
189                        stringstream ss;
190                        // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
191                        SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
192                        return nullptr;
193                } // if
194                // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
195                fieldList = DeclarationNode::newName( nullptr );
196        } // if
197//      return distAttr( typeSpec, fieldList );                         // mark all fields in list
198
199        // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
200        DeclarationNode * temp = distAttr( typeSpec, fieldList );                               // mark all fields in list
201        // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
202        return temp;
203} // fieldDecl
204
205#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
206#define NEW_ONE  new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
207#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
208#define MISSING_ANON_FIELD "syntax error, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
209#define MISSING_LOW "syntax error, missing low value for up-to range so index is uninitialized."
210#define MISSING_HIGH "syntax error, missing high value for down-to range so index is uninitialized."
211
212static ForCtrl * makeForCtrl(
213                const CodeLocation & location,
214                DeclarationNode * init,
215                enum OperKinds compop,
216                ExpressionNode * comp,
217                ExpressionNode * inc ) {
218        // Wrap both comp/inc if they are non-null.
219        if ( comp ) comp = new ExpressionNode( build_binary_val( location,
220                compop,
221                new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
222                comp ) );
223        if ( inc ) inc = new ExpressionNode( build_binary_val( location,
224                // choose += or -= for upto/downto
225                compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
226                new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
227                inc ) );
228        // The StatementNode call frees init->name, it must happen later.
229        return new ForCtrl( new StatementNode( init ), comp, inc );
230}
231
232ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
233        if ( index->initializer ) {
234                SemanticError( yylloc, "syntax error, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
235        } // if
236        if ( index->next ) {
237                SemanticError( yylloc, "syntax error, multiple loop indexes disallowed in for-loop declaration." );
238        } // if
239        DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
240        return makeForCtrl( location, initDecl, compop, comp, inc );
241} // forCtrl
242
243ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
244        ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
245        if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
246                type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicType::SignedInt ) ) );
247        } // if
248        DeclarationNode * initDecl = distAttr(
249                DeclarationNode::newTypeof( type, true ),
250                DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
251        );
252        return makeForCtrl( location, initDecl, compop, comp, inc );
253} // forCtrl
254
255ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
256        if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
257                return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
258        } else if ( auto commaExpr = dynamic_cast<ast::CommaExpr *>( index->expr.get() ) ) {
259                if ( auto identifier = commaExpr->arg1.as<ast::NameExpr>() ) {
260                        return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
261                } else {
262                        SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
263                } // if
264        } else {
265                SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed. ." ); return nullptr;
266        } // if
267} // forCtrl
268
269static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
270        SemanticError( yylloc, ::toString( "syntax error, adjacent identifiers \"", identifier1, "\" and \"", identifier2, "\" are not meaningful in a", kind, ".\n"
271                                   "Possible cause is misspelled type name or missing generic parameter." ) );
272} // IdentifierBeforeIdentifier
273
274static void IdentifierBeforeType( string & identifier, const char * kind ) {
275        SemanticError( yylloc, ::toString( "syntax error, identifier \"", identifier, "\" cannot appear before a ", kind, ".\n"
276                                   "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter." ) );
277} // IdentifierBeforeType
278
279bool forall = false;                                                                    // aggregate have one or more forall qualifiers ?
280
281// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
282#define YYLLOC_DEFAULT(Cur, Rhs, N)                                                                                             \
283if ( N ) {                                                                                                                                              \
284        (Cur).first_line   = YYRHSLOC( Rhs, 1 ).first_line;                                                     \
285        (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column;                                           \
286        (Cur).last_line    = YYRHSLOC( Rhs, N ).last_line;                                                      \
287        (Cur).last_column  = YYRHSLOC( Rhs, N ).last_column;                                            \
288        (Cur).filename     = YYRHSLOC( Rhs, 1 ).filename;                                                       \
289} else {                                                                                                                                                \
290        (Cur).first_line   = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line;            \
291        (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column;        \
292        (Cur).filename     = YYRHSLOC( Rhs, 0 ).filename;                                                       \
293}
294%}
295
296%define parse.error verbose
297
298// Types declaration for productions
299
300%union {
301        Token tok;
302        ExpressionNode * expr;
303        DeclarationNode * decl;
304        ast::AggregateDecl::Aggregate aggKey;
305        ast::TypeDecl::Kind tclass;
306        StatementNode * stmt;
307        ClauseNode * clause;
308        ast::WaitForStmt * wfs;
309    ast::WaitUntilStmt::ClauseNode * wucn;
310        CondCtl * ifctl;
311        ForCtrl * forctl;
312        LabelNode * labels;
313        InitializerNode * init;
314        OperKinds oper;
315        std::string * str;
316        bool is_volatile;
317        EnumHiding enum_hiding;
318        ast::ExceptionKind except_kind;
319        ast::GenericExpr * genexpr;
320}
321
322// ************************ TERMINAL TOKENS ********************************
323
324// keywords
325%token TYPEDEF
326%token EXTERN STATIC AUTO REGISTER
327%token THREADLOCALGCC THREADLOCALC11                                    // GCC, C11
328%token INLINE FORTRAN                                                                   // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
329%token NORETURN                                                                                 // C11
330%token CONST VOLATILE
331%token RESTRICT                                                                                 // C99
332%token ATOMIC                                                                                   // C11
333%token FORALL MUTEX VIRTUAL VTABLE COERCE                               // CFA
334%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
335%token BOOL COMPLEX IMAGINARY                                                   // C99
336%token INT128 UINT128 uuFLOAT80 uuFLOAT128                              // GCC
337%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
338%token DECIMAL32 DECIMAL64 DECIMAL128                                   // GCC
339%token ZERO_T ONE_T                                                                             // CFA
340%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE                   // GCC
341%token OFFSETOF BASETYPEOF TYPEID                                               // CFA
342%token ENUM STRUCT UNION
343%token EXCEPTION                                                                                // CFA
344%token GENERATOR COROUTINE MONITOR THREAD                               // CFA
345%token OTYPE FTYPE DTYPE TTYPE TRAIT                                    // CFA
346// %token RESUME                                                                                        // CFA
347%token LABEL                                                                                    // GCC
348%token SUSPEND                                                                                  // CFA
349%token ATTRIBUTE EXTENSION                                                              // GCC
350%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
351%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
352%token CORUN COFOR
353%token DISABLE ENABLE TRY THROW THROWRESUME AT                  // CFA
354%token ASM                                                                                              // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
355%token ALIGNAS ALIGNOF GENERIC STATICASSERT                             // C11
356
357// names and constants: lexer differentiates between identifier and typedef names
358%token<tok> IDENTIFIER          TYPEDIMname             TYPEDEFname             TYPEGENname
359%token<tok> TIMEOUT                     WAND    WOR                     CATCH                   RECOVER                 CATCHRESUME             FIXUP           FINALLY         // CFA
360%token<tok> INTEGERconstant     CHARACTERconstant       STRINGliteral
361%token<tok> DIRECTIVE
362// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
363// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
364// converted into the tuple index (.)(1). e.g., 3.x
365%token<tok>     FLOATING_DECIMALconstant        FLOATING_FRACTIONconstant       FLOATINGconstant
366
367// multi-character operators
368%token ARROW                                                                                    // ->
369%token ICR DECR                                                                                 // ++   --
370%token LS RS                                                                                    // <<   >>
371%token LE GE EQ NE                                                                              // <=   >=      ==      !=
372%token ANDAND OROR                                                                              // &&   ||
373%token ELLIPSIS                                                                                 // ...
374
375%token EXPassign        MULTassign      DIVassign       MODassign       // \=   *=      /=      %=
376%token PLUSassign       MINUSassign                                                     // +=   -=
377%token LSassign         RSassign                                                        // <<=  >>=
378%token ANDassign        ERassign        ORassign                                // &=   ^=      |=
379
380%token ErangeUpEq       ErangeDown      ErangeDownEq                    // ~=   -~      -~=
381%token ATassign                                                                                 // @=
382
383%type<tok> identifier                                   identifier_at                           identifier_or_type_name         attr_name
384%type<tok> quasi_keyword
385%type<expr> string_literal
386%type<str> string_literal_list
387
388%type<enum_hiding> hide_opt                             visible_hide_opt
389
390// expressions
391%type<expr> constant
392%type<expr> tuple                                               tuple_expression_list
393%type<oper> ptrref_operator                             unary_operator                          assignment_operator                     simple_assignment_operator      compound_assignment_operator
394%type<expr> primary_expression                  postfix_expression                      unary_expression
395%type<expr> cast_expression_list                cast_expression                         exponential_expression          multiplicative_expression       additive_expression
396%type<expr> shift_expression                    relational_expression           equality_expression
397%type<expr> AND_expression                              exclusive_OR_expression         inclusive_OR_expression
398%type<expr> logical_AND_expression              logical_OR_expression
399%type<expr> conditional_expression              constant_expression                     assignment_expression           assignment_expression_opt
400%type<expr> comma_expression                    comma_expression_opt
401%type<expr> argument_expression_list_opt argument_expression_list       argument_expression                     default_initializer_opt
402%type<ifctl> conditional_declaration
403%type<forctl> for_control_expression    for_control_expression_list
404%type<oper> upupeq updown updowneq downupdowneq
405%type<expr> subrange
406%type<decl> asm_name_opt
407%type<expr> asm_operands_opt                    asm_operands_list                       asm_operand
408%type<labels> label_list
409%type<expr> asm_clobbers_list_opt
410%type<is_volatile> asm_volatile_opt
411%type<expr> handler_predicate_opt
412%type<genexpr> generic_association              generic_assoc_list
413
414// statements
415%type<stmt> statement                                   labeled_statement                       compound_statement
416%type<stmt> statement_decl                              statement_decl_list                     statement_list_nodecl
417%type<stmt> selection_statement                 if_statement
418%type<clause> switch_clause_list_opt    switch_clause_list
419%type<expr> case_value
420%type<clause> case_clause                               case_value_list                         case_label      case_label_list
421%type<stmt> iteration_statement                 jump_statement
422%type<stmt> expression_statement                asm_statement
423%type<stmt> with_statement
424%type<expr> with_clause_opt
425%type<stmt> corun_statement                             cofor_statement
426%type<stmt> exception_statement
427%type<clause> handler_clause                    finally_clause
428%type<except_kind> handler_key
429%type<stmt> mutex_statement
430%type<expr> when_clause                                 when_clause_opt                         waitfor         waituntil               timeout
431%type<stmt> waitfor_statement                   waituntil_statement
432%type<wfs> wor_waitfor_clause
433%type<wucn> waituntil_clause                    wand_waituntil_clause       wor_waituntil_clause
434
435// declarations
436%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
437%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
438%type<decl> abstract_parameter_declaration
439
440%type<aggKey> aggregate_key aggregate_data aggregate_control
441%type<decl> aggregate_type aggregate_type_nobody
442
443%type<decl> assertion assertion_list assertion_list_opt
444
445%type<expr> bit_subrange_size_opt bit_subrange_size
446
447%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
448%type<decl> vtable vtable_opt default_opt
449
450%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
451
452%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
453%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
454
455%type<decl> elaborated_type elaborated_type_nobody
456
457%type<decl> enumerator_list enum_type enum_type_nobody
458%type<init> enumerator_value_opt
459
460%type<decl> external_definition external_definition_list external_definition_list_opt
461
462%type<decl> exception_declaration
463
464%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
465%type<expr> field field_name_list field_name fraction_constants_opt
466
467%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
468
469%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
470%type<decl> identifier_list
471
472%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
473%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
474%type<decl> cfa_abstract_ptr cfa_abstract_tuple
475
476%type<decl> cfa_array_parameter_1st_dimension
477
478%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
479%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
480
481%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
482%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
483
484%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
485
486%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
487
488%type<decl> c_declaration static_assert
489%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
490%type<decl> KR_parameter_list KR_parameter_list_opt
491
492%type<decl> parameter_declaration parameter_list parameter_type_list_opt
493
494%type<decl> paren_identifier paren_type
495
496%type<decl> storage_class storage_class_list
497
498%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
499
500%type<tclass> type_class new_type_class
501%type<decl> type_declarator type_declarator_name type_declaring_list
502
503%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
504%type<decl> typedef_name typedef_declaration typedef_expression
505
506%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
507%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
508
509%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
510
511%type<decl> type type_no_function
512%type<decl> type_parameter type_parameter_list type_initializer_opt
513
514%type<expr> type_parameters_opt type_list array_type_list
515
516%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
517%type<decl> type_specifier type_specifier_nobody
518
519%type<decl> variable_declarator variable_ptr variable_array variable_function
520%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
521
522%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
523
524// initializers
525%type<init>  initializer initializer_list_opt initializer_opt
526
527// designators
528%type<expr>  designator designator_list designation
529
530
531// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
532//   .---------.                                matches IF '(' comma_expression ')' statement . (reduce)
533//   if ( C ) S1 else S2
534//   `-----------------'                matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
535// Similar issues exit with the waitfor statement.
536
537// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
538// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
539%precedence THEN                // rule precedence for IF/WAITFOR statement
540%precedence ANDAND              // token precedence for start of WAND in WAITFOR statement
541%precedence WAND                // token precedence for start of WAND in WAITFOR statement
542%precedence OROR                // token precedence for start of WOR in WAITFOR statement
543%precedence WOR                 // token precedence for start of WOR in WAITFOR statement
544%precedence TIMEOUT             // token precedence for start of TIMEOUT in WAITFOR statement
545%precedence CATCH               // token precedence for start of TIMEOUT in WAITFOR statement
546%precedence RECOVER             // token precedence for start of TIMEOUT in WAITFOR statement
547%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
548%precedence FIXUP               // token precedence for start of TIMEOUT in WAITFOR statement
549%precedence FINALLY             // token precedence for start of TIMEOUT in WAITFOR statement
550%precedence ELSE                // token precedence for start of else clause in IF/WAITFOR statement
551
552
553// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
554//   forall( otype T ) struct Foo { T v; };
555//       .-----.                                matches pointer to function returning a generic (which is impossible without a type)
556//   Foo ( *fp )( int );
557//   `---'                                              matches start of TYPEGENname '('
558// must be:
559//   Foo( int ) ( *fp )( int );
560// The same problem occurs here:
561//   forall( otype T ) struct Foo { T v; } ( *fp )( int );
562// must be:
563//   forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
564
565// Order of these lines matters (low-to-high precedence).
566%precedence TYPEGENname
567%precedence '}'
568%precedence '('
569
570// %precedence RESUME
571// %precedence '{'
572// %precedence ')'
573
574%locations                                                                                              // support location tracking for error messages
575
576%start translation_unit                                                                 // parse-tree root
577
578%%
579// ************************ Namespace Management ********************************
580
581// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
582// which are lexically identical.
583//
584//   typedef int foo; // identifier foo must now be scanned as TYPEDEFname
585//   foo f;           // to allow it to appear in this context
586//
587// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
588// between syntactic and semantic constructs.  Cforall compounds this problem by introducing type names local to the
589// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
590// generators" -- parameterized types.  This latter type name creates a third class of identifiers, "TYPEGENname", which
591// must be distinguished by the lexical scanner.
592//
593// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
594// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
595// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
596// each context that introduces a name scope, a new level is created in the type table and that level is popped on
597// exiting the scope.  Since type names can be local to a particular declaration, each declaration is itself a scope.
598// This requires distinguishing between type names that are local to the current declaration scope and those that
599// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
600//
601// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
602// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
603// around the list separator.
604//
605//  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
606//      push               pop   push                   pop
607
608push:
609                { typedefTable.enterScope(); }
610        ;
611
612pop:
613                { typedefTable.leaveScope(); }
614        ;
615
616// ************************ CONSTANTS ********************************
617
618constant:
619                // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
620        INTEGERconstant                                                         { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
621        | FLOATING_DECIMALconstant                                      { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
622        | FLOATING_FRACTIONconstant                                     { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
623        | FLOATINGconstant                                                      { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
624        | CHARACTERconstant                                                     { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
625        ;
626
627quasi_keyword:                                                                                  // CFA
628        TIMEOUT
629        | WAND
630        | WOR
631        | CATCH
632        | RECOVER
633        | CATCHRESUME
634        | FIXUP
635        | FINALLY
636        ;
637
638identifier:
639        IDENTIFIER
640        | quasi_keyword
641        ;
642
643identifier_at:
644        identifier
645        | '@'                                                                                           // CFA
646                { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
647        ;
648
649string_literal:
650        string_literal_list                                                     { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
651        ;
652
653string_literal_list:                                                                    // juxtaposed strings are concatenated
654        STRINGliteral                                                           { $$ = $1; } // conversion from tok to str
655        | string_literal_list STRINGliteral
656                {
657                        if ( ! appendStr( *$1, *$2 ) ) YYERROR;         // append 2nd juxtaposed string to 1st
658                        delete $2;                                                                      // allocated by lexer
659                        $$ = $1;                                                                        // conversion from tok to str
660                }
661        ;
662
663// ************************ EXPRESSIONS ********************************
664
665primary_expression:
666        IDENTIFIER                                                                                      // typedef name cannot be used as a variable name
667                { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
668        | quasi_keyword
669                { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
670        | TYPEDIMname                                                                           // CFA, generic length argument
671                // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
672                // { $$ = new ExpressionNode( build_varref( $1 ) ); }
673                { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
674        | tuple
675        | '(' comma_expression ')'
676                { $$ = $2; }
677        | '(' compound_statement ')'                                            // GCC, lambda expression
678                { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
679        | type_name '.' identifier                                                      // CFA, nested type
680                { $$ = new ExpressionNode( build_qualified_expr( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
681        | type_name '.' '[' field_name_list ']'                         // CFA, nested type / tuple field selector
682                { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
683        | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
684                {
685                        // add the missing control expression to the GenericExpr and return it
686                        $5->control = maybeMoveBuild( $3 );
687                        $$ = new ExpressionNode( $5 );
688                }
689        // | RESUME '(' comma_expression ')'
690        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
691        // | RESUME '(' comma_expression ')' compound_statement
692        //      { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
693        | IDENTIFIER IDENTIFIER                                                         // invalid syntax rule
694                { IdentifierBeforeIdentifier( *$1.str, *$2.str, "n expression" ); $$ = nullptr; }
695        | IDENTIFIER type_qualifier                                                     // invalid syntax rule
696                { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
697        | IDENTIFIER storage_class                                                      // invalid syntax rule
698                { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
699        | IDENTIFIER basic_type_name                                            // invalid syntax rule
700                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
701        | IDENTIFIER TYPEDEFname                                                        // invalid syntax rule
702                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
703        | IDENTIFIER TYPEGENname                                                        // invalid syntax rule
704                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
705        ;
706
707generic_assoc_list:                                                                             // C11
708        generic_association
709        | generic_assoc_list ',' generic_association
710                {
711                        // steal the association node from the singleton and delete the wrapper
712                        assert( 1 == $3->associations.size() );
713                        $1->associations.push_back( $3->associations.front() );
714                        delete $3;
715                        $$ = $1;
716                }
717        ;
718
719generic_association:                                                                    // C11
720        type_no_function ':' assignment_expression
721                {
722                        // create a GenericExpr wrapper with one association pair
723                        $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
724                }
725        | DEFAULT ':' assignment_expression
726                { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
727        ;
728
729postfix_expression:
730        primary_expression
731        | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
732                // Historic, transitional: Disallow commas in subscripts.
733                // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
734                // Current: Commas in subscripts make tuples.
735                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
736        | postfix_expression '[' assignment_expression ']'
737                // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
738                // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
739                // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
740                // equivalent to the old x[i,j].
741                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
742        | constant '[' assignment_expression ']'                        // 3[a], 'a'[a], 3.5[a]
743                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
744        | string_literal '[' assignment_expression ']'          // "abc"[3], 3["abc"]
745                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
746        | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
747                {
748                        Token fn;
749                        fn.str = new std::string( "?{}" );                      // location undefined - use location of '{'?
750                        $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
751                }
752        | postfix_expression '(' argument_expression_list_opt ')'
753                { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
754        | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
755                // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
756                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg") ) ),
757                                                                                           (ExpressionNode *)($3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) )) ) ); }
758        | postfix_expression '`' identifier                                     // CFA, postfix call
759                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
760        | constant '`' identifier                                                       // CFA, postfix call
761                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
762        | string_literal '`' identifier                                         // CFA, postfix call
763                { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
764        | postfix_expression '.' identifier
765                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
766        | postfix_expression '.' INTEGERconstant                        // CFA, tuple index
767                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
768        | postfix_expression FLOATING_FRACTIONconstant          // CFA, tuple index
769                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
770        | postfix_expression '.' '[' field_name_list ']'        // CFA, tuple field selector
771                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
772        | postfix_expression '.' aggregate_control
773                { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
774        | postfix_expression ARROW identifier
775                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
776        | postfix_expression ARROW INTEGERconstant                      // CFA, tuple index
777                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
778        | postfix_expression ARROW '[' field_name_list ']'      // CFA, tuple field selector
779                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
780        | postfix_expression ICR
781                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
782        | postfix_expression DECR
783                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
784        | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
785                { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
786        | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
787                { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
788        | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
789                {
790                        Token fn;
791                        fn.str = new string( "^?{}" );                          // location undefined
792                        $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
793                }
794        ;
795
796argument_expression_list_opt:
797        // empty
798                { $$ = nullptr; }
799        | argument_expression_list
800        ;
801
802argument_expression_list:
803        argument_expression
804        | argument_expression_list_opt ',' argument_expression
805                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
806        ;
807
808argument_expression:
809        '@'                                                                                                     // CFA, default parameter
810                { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
811                // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
812        | assignment_expression
813        ;
814
815field_name_list:                                                                                // CFA, tuple field selector
816        field
817        | field_name_list ',' field                                     { $$ = (ExpressionNode *)($1->set_last( $3 )); }
818        ;
819
820field:                                                                                                  // CFA, tuple field selector
821        field_name
822        | FLOATING_DECIMALconstant field
823                { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
824        | FLOATING_DECIMALconstant '[' field_name_list ']'
825                { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
826        | field_name '.' field
827                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
828        | field_name '.' '[' field_name_list ']'
829                { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
830        | field_name ARROW field
831                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
832        | field_name ARROW '[' field_name_list ']'
833                { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
834        ;
835
836field_name:
837        INTEGERconstant fraction_constants_opt
838                { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
839        | FLOATINGconstant fraction_constants_opt
840                { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
841        | identifier_at fraction_constants_opt                          // CFA, allow anonymous fields
842                {
843                        $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
844                }
845        ;
846
847fraction_constants_opt:
848        // empty
849                { $$ = nullptr; }
850        | fraction_constants_opt FLOATING_FRACTIONconstant
851                {
852                        ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
853                        $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
854                }
855        ;
856
857unary_expression:
858        postfix_expression
859                // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
860                // semantics checks, e.g., ++3, 3--, *3, &&3
861        | constant
862        | string_literal
863                { $$ = $1; }
864        | EXTENSION cast_expression                                                     // GCC
865                { $$ = $2->set_extension( true ); }
866                // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
867                //              { * X; }         // dereference X
868                //              { * int X; } // CFA declaration of pointer to int
869        | ptrref_operator cast_expression                                       // CFA
870                {
871                        switch ( $1 ) {
872                        case OperKinds::AddressOf:
873                                $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
874                                break;
875                        case OperKinds::PointTo:
876                                $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
877                                break;
878                        case OperKinds::And:
879                                $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
880                                break;
881                        default:
882                                assert( false );
883                        }
884                }
885        | unary_operator cast_expression
886                { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
887        | ICR unary_expression
888                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
889        | DECR unary_expression
890                { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
891        | SIZEOF unary_expression
892                { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
893        | SIZEOF '(' type_no_function ')'
894                { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
895        | ALIGNOF unary_expression                                                      // GCC, variable alignment
896                { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
897        | ALIGNOF '(' type_no_function ')'                                      // GCC, type alignment
898                { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
899        | OFFSETOF '(' type_no_function ',' identifier ')'
900                { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
901        | TYPEID '(' type_no_function ')'
902                {
903                        SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
904                        // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
905                }
906        ;
907
908ptrref_operator:
909        '*'                                                                                     { $$ = OperKinds::PointTo; }
910        | '&'                                                                           { $$ = OperKinds::AddressOf; }
911                // GCC, address of label must be handled by semantic check for ref,ref,label
912        | ANDAND                                                                        { $$ = OperKinds::And; }
913        ;
914
915unary_operator:
916        '+'                                                                                     { $$ = OperKinds::UnPlus; }
917        | '-'                                                                           { $$ = OperKinds::UnMinus; }
918        | '!'                                                                           { $$ = OperKinds::Neg; }
919        | '~'                                                                           { $$ = OperKinds::BitNeg; }
920        ;
921
922cast_expression:
923        unary_expression
924        | '(' type_no_function ')' cast_expression
925                { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
926        | '(' aggregate_control '&' ')' cast_expression         // CFA
927                { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
928        | '(' aggregate_control '*' ')' cast_expression         // CFA
929                { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
930        | '(' VIRTUAL ')' cast_expression                                       // CFA
931                { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), maybeMoveBuildType( nullptr ) ) ); }
932        | '(' VIRTUAL type_no_function ')' cast_expression      // CFA
933                { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
934        | '(' RETURN type_no_function ')' cast_expression       // CFA
935                { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
936        | '(' COERCE type_no_function ')' cast_expression       // CFA
937                { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
938        | '(' qualifier_cast_list ')' cast_expression           // CFA
939                { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
940//      | '(' type_no_function ')' tuple
941//              { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
942        ;
943
944qualifier_cast_list:
945        cast_modifier type_qualifier_name
946        | cast_modifier MUTEX
947        | qualifier_cast_list cast_modifier type_qualifier_name
948        | qualifier_cast_list cast_modifier MUTEX
949        ;
950
951cast_modifier:
952        '-'
953        | '+'
954        ;
955
956exponential_expression:
957        cast_expression
958        | exponential_expression '\\' cast_expression
959                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
960        ;
961
962multiplicative_expression:
963        exponential_expression
964        | multiplicative_expression '*' exponential_expression
965                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
966        | multiplicative_expression '/' exponential_expression
967                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
968        | multiplicative_expression '%' exponential_expression
969                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
970        ;
971
972additive_expression:
973        multiplicative_expression
974        | additive_expression '+' multiplicative_expression
975                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
976        | additive_expression '-' multiplicative_expression
977                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
978        ;
979
980shift_expression:
981        additive_expression
982        | shift_expression LS additive_expression
983                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
984        | shift_expression RS additive_expression
985                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
986        ;
987
988relational_expression:
989        shift_expression
990        | relational_expression '<' shift_expression
991                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
992        | relational_expression '>' shift_expression
993                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
994        | relational_expression LE shift_expression
995                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
996        | relational_expression GE shift_expression
997                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
998        ;
999
1000equality_expression:
1001        relational_expression
1002        | equality_expression EQ relational_expression
1003                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1004        | equality_expression NE relational_expression
1005                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1006        ;
1007
1008AND_expression:
1009        equality_expression
1010        | AND_expression '&' equality_expression
1011                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1012        ;
1013
1014exclusive_OR_expression:
1015        AND_expression
1016        | exclusive_OR_expression '^' AND_expression
1017                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1018        ;
1019
1020inclusive_OR_expression:
1021        exclusive_OR_expression
1022        | inclusive_OR_expression '|' exclusive_OR_expression
1023                { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1024        ;
1025
1026logical_AND_expression:
1027        inclusive_OR_expression
1028        | logical_AND_expression ANDAND inclusive_OR_expression
1029                { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1030        ;
1031
1032logical_OR_expression:
1033        logical_AND_expression
1034        | logical_OR_expression OROR logical_AND_expression
1035                { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1036        ;
1037
1038conditional_expression:
1039        logical_OR_expression
1040        | logical_OR_expression '?' comma_expression ':' conditional_expression
1041                { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1042                // FIX ME: computes $1 twice
1043        | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1044                { $$ = new ExpressionNode( build_cond( yylloc, $1, $1->clone(), $4 ) ); }
1045        ;
1046
1047constant_expression:
1048        conditional_expression
1049        ;
1050
1051assignment_expression:
1052                // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1053        conditional_expression
1054        | unary_expression assignment_operator assignment_expression
1055                {
1056//                      if ( $2 == OperKinds::AtAssn ) {
1057//                              SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1058//                      } else {
1059                                $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1060//                      } // if
1061                }
1062        | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1063                { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1064        ;
1065
1066assignment_expression_opt:
1067        // empty
1068                { $$ = nullptr; }
1069        | assignment_expression
1070        ;
1071
1072assignment_operator:
1073        simple_assignment_operator
1074        | compound_assignment_operator
1075        ;
1076
1077simple_assignment_operator:
1078        '='                                                                                     { $$ = OperKinds::Assign; }
1079        | ATassign                                                                      { $$ = OperKinds::AtAssn; } // CFA
1080        ;
1081
1082compound_assignment_operator:
1083        EXPassign                                                                       { $$ = OperKinds::ExpAssn; }
1084        | MULTassign                                                            { $$ = OperKinds::MulAssn; }
1085        | DIVassign                                                                     { $$ = OperKinds::DivAssn; }
1086        | MODassign                                                                     { $$ = OperKinds::ModAssn; }
1087        | PLUSassign                                                            { $$ = OperKinds::PlusAssn; }
1088        | MINUSassign                                                           { $$ = OperKinds::MinusAssn; }
1089        | LSassign                                                                      { $$ = OperKinds::LSAssn; }
1090        | RSassign                                                                      { $$ = OperKinds::RSAssn; }
1091        | ANDassign                                                                     { $$ = OperKinds::AndAssn; }
1092        | ERassign                                                                      { $$ = OperKinds::ERAssn; }
1093        | ORassign                                                                      { $$ = OperKinds::OrAssn; }
1094        ;
1095
1096tuple:                                                                                                  // CFA, tuple
1097                // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1098                // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1099//      '[' ']'
1100//              { $$ = new ExpressionNode( build_tuple() ); }
1101//      | '[' push assignment_expression pop ']'
1102//              { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1103        '[' ',' tuple_expression_list ']'
1104                { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
1105        | '[' push assignment_expression pop ',' tuple_expression_list ']'
1106                { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $6 ) ) )); }
1107        ;
1108
1109tuple_expression_list:
1110        assignment_expression
1111        | '@'                                                                                           // CFA
1112                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1113        | tuple_expression_list ',' assignment_expression
1114                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1115        | tuple_expression_list ',' '@'
1116                { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1117        ;
1118
1119comma_expression:
1120        assignment_expression
1121        | comma_expression ',' assignment_expression
1122                { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1123        ;
1124
1125comma_expression_opt:
1126        // empty
1127                { $$ = nullptr; }
1128        | comma_expression
1129        ;
1130
1131// ************************** STATEMENTS *******************************
1132
1133statement:
1134        labeled_statement
1135        | compound_statement
1136        | expression_statement
1137        | selection_statement
1138        | iteration_statement
1139        | jump_statement
1140        | with_statement
1141        | mutex_statement
1142        | waitfor_statement
1143        | waituntil_statement
1144        | corun_statement
1145        | cofor_statement
1146        | exception_statement
1147        | enable_disable_statement
1148                { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1149        | asm_statement
1150        | DIRECTIVE
1151                { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1152        ;
1153
1154labeled_statement:
1155                // labels cannot be identifiers 0 or 1
1156        identifier_or_type_name ':' attribute_list_opt statement
1157                { $$ = $4->add_label( yylloc, $1, $3 ); }
1158        | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1159                {
1160                        SemanticError( yylloc, ::toString( "syntx error, label \"", *$1.str, "\" must be associated with a statement, "
1161                                                                                           "where a declaration, case, or default is not a statement. "
1162                                                                                           "Move the label or terminate with a semi-colon." ) );
1163                        $$ = nullptr;
1164                }
1165        ;
1166
1167compound_statement:
1168        '{' '}'
1169                { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1170        | '{' push
1171          local_label_declaration_opt                                           // GCC, local labels appear at start of block
1172          statement_decl_list                                                           // C99, intermix declarations and statements
1173          pop '}'
1174                { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1175        ;
1176
1177statement_decl_list:                                                                    // C99
1178        statement_decl
1179        | statement_decl_list statement_decl
1180                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1181        ;
1182
1183statement_decl:
1184        declaration                                                                                     // CFA, new & old style declarations
1185                { $$ = new StatementNode( $1 ); }
1186        | EXTENSION declaration                                                         // GCC
1187                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1188        | function_definition
1189                { $$ = new StatementNode( $1 ); }
1190        | EXTENSION function_definition                                         // GCC
1191                { distExt( $2 ); $$ = new StatementNode( $2 ); }
1192        | statement
1193        ;
1194
1195statement_list_nodecl:
1196        statement
1197        | statement_list_nodecl statement
1198                { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1199        | statement_list_nodecl error                                           // invalid syntax rule
1200                { SemanticError( yylloc, "syntax error, declarations only allowed at the start of the switch body, i.e., after the '{'." ); $$ = nullptr; }
1201        ;
1202
1203expression_statement:
1204        comma_expression_opt ';'
1205                { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1206        ;
1207
1208selection_statement:
1209                        // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1210                        // the inherent S/R conflict with THEN/ELSE.
1211        push if_statement pop
1212                { $$ = $2; }
1213        | SWITCH '(' comma_expression ')' case_clause
1214                { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1215        | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1216                {
1217                        StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1218                        // The semantics of the declaration list is changed to include associated initialization, which is performed
1219                        // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1220                        // statement around the switch.  Statements after the initial declaration list can never be executed, and
1221                        // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1222                        // statement.
1223                        $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1224                }
1225        | SWITCH '(' comma_expression ')' '{' error '}'         // CFA, invalid syntax rule error
1226                { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1227        | CHOOSE '(' comma_expression ')' case_clause           // CFA
1228                { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1229        | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1230                {
1231                        StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1232                        $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1233                }
1234        | CHOOSE '(' comma_expression ')' '{' error '}'         // CFA, invalid syntax rule
1235                { SemanticError( yylloc, "syntax error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1236        ;
1237
1238if_statement:
1239        IF '(' conditional_declaration ')' statement            %prec THEN
1240                // explicitly deal with the shift/reduce conflict on if/else
1241                { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1242        | IF '(' conditional_declaration ')' statement ELSE statement
1243                { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1244        ;
1245
1246conditional_declaration:
1247        comma_expression
1248                { $$ = new CondCtl( nullptr, $1 ); }
1249        | c_declaration                                                                         // no semi-colon
1250                { $$ = new CondCtl( $1, nullptr ); }
1251        | cfa_declaration                                                                       // no semi-colon
1252                { $$ = new CondCtl( $1, nullptr ); }
1253        | declaration comma_expression                                          // semi-colon separated
1254                { $$ = new CondCtl( $1, $2 ); }
1255        ;
1256
1257// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1258// clause allows a list of values and subranges.
1259
1260case_value:                                                                                             // CFA
1261        constant_expression                                                     { $$ = $1; }
1262        | constant_expression ELLIPSIS constant_expression      // GCC, subrange
1263                { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1264        | subrange                                                                                      // CFA, subrange
1265        ;
1266
1267case_value_list:                                                                                // CFA
1268        case_value                                                                      { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1269                // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1270        | case_value_list ',' case_value                        { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1271        ;
1272
1273case_label:                                                                                             // CFA
1274        CASE error                                                                                      // invalid syntax rule
1275                { SemanticError( yylloc, "syntax error, case list missing after case." ); $$ = nullptr; }
1276        | CASE case_value_list ':'                                      { $$ = $2; }
1277        | CASE case_value_list error                                            // invalid syntax rule
1278                { SemanticError( yylloc, "syntax error, colon missing after case list." ); $$ = nullptr; }
1279        | DEFAULT ':'                                                           { $$ = new ClauseNode( build_default( yylloc ) ); }
1280                // A semantic check is required to ensure only one default clause per switch/choose statement.
1281        | DEFAULT error                                                                         //  invalid syntax rule
1282                { SemanticError( yylloc, "syntax error, colon missing after default." ); $$ = nullptr; }
1283        ;
1284
1285case_label_list:                                                                                // CFA
1286        case_label
1287        | case_label_list case_label                            { $$ = $1->set_last( $2 ); }
1288        ;
1289
1290case_clause:                                                                                    // CFA
1291        case_label_list statement                                       { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1292        ;
1293
1294switch_clause_list_opt:                                                                 // CFA
1295        // empty
1296                { $$ = nullptr; }
1297        | switch_clause_list
1298        ;
1299
1300switch_clause_list:                                                                             // CFA
1301        case_label_list statement_list_nodecl
1302                { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1303        | switch_clause_list case_label_list statement_list_nodecl
1304                { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1305        ;
1306
1307iteration_statement:
1308        WHILE '(' ')' statement                                                         %prec THEN // CFA => while ( 1 )
1309                { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1310        | WHILE '(' ')' statement ELSE statement                        // CFA
1311                {
1312                        $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1313                        SemanticWarning( yylloc, Warning::SuperfluousElse );
1314                }
1315        | WHILE '(' conditional_declaration ')' statement       %prec THEN
1316                { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1317        | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1318                { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1319        | DO statement WHILE '(' ')' ';'                                        // CFA => do while( 1 )
1320                { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1321        | DO statement WHILE '(' ')' ELSE statement                     // CFA
1322                {
1323                        $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1324                        SemanticWarning( yylloc, Warning::SuperfluousElse );
1325                }
1326        | DO statement WHILE '(' comma_expression ')' ';'
1327                { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1328        | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1329                { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1330        | FOR '(' ')' statement                                                         %prec THEN // CFA => for ( ;; )
1331                { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1332        | FOR '(' ')' statement ELSE statement                          // CFA
1333                {
1334                        $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1335                        SemanticWarning( yylloc, Warning::SuperfluousElse );
1336                }
1337        | FOR '(' for_control_expression_list ')' statement     %prec THEN
1338                { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1339        | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1340                { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1341        ;
1342
1343for_control_expression_list:
1344        for_control_expression
1345        | for_control_expression_list ':' for_control_expression
1346                // ForCtrl + ForCtrl:
1347                //    init + init => multiple declaration statements that are hoisted
1348                //    condition + condition => (expression) && (expression)
1349                //    change + change => (expression), (expression)
1350                {
1351                        $1->init->set_last( $3->init );
1352                        if ( $1->condition ) {
1353                                if ( $3->condition ) {
1354                                        $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1355                                } // if
1356                        } else $1->condition = $3->condition;
1357                        if ( $1->change ) {
1358                                if ( $3->change ) {
1359                                        $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1360                                } // if
1361                        } else $1->change = $3->change;
1362                        $$ = $1;
1363                }
1364        ;
1365
1366for_control_expression:
1367        ';' comma_expression_opt ';' comma_expression_opt
1368                { $$ = new ForCtrl( nullptr, $2, $4 ); }
1369        | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1370                {
1371                        StatementNode * init = $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr;
1372                        $$ = new ForCtrl( init, $3, $5 );
1373                }
1374        | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1375                { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1376
1377        | '@' ';' comma_expression                                                      // CFA, empty loop-index
1378                { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1379        | '@' ';' comma_expression ';' comma_expression         // CFA, empty loop-index
1380                { $$ = new ForCtrl( nullptr, $3, $5 ); }
1381
1382        | comma_expression                                                                      // CFA, anonymous loop-index
1383                { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1384        | downupdowneq comma_expression                                         // CFA, anonymous loop-index
1385                { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1386
1387        | comma_expression updowneq comma_expression            // CFA, anonymous loop-index
1388                { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1389        | '@' updowneq comma_expression                                         // CFA, anonymous loop-index
1390                {
1391                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1392                        else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1393                }
1394        | comma_expression updowneq '@'                                         // CFA, anonymous loop-index
1395                {
1396                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1397                        else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1398                }
1399        | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1400                { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1401        | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1402                {
1403                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1404                        else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1405                }
1406        | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1407                {
1408                        if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1409                        else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1410                }
1411        | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1412                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1413        | '@' updowneq '@'                                                                      // CFA, invalid syntax rule
1414                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1415        | '@' updowneq comma_expression '~' '@'                         // CFA, invalid syntax rule
1416                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1417        | comma_expression updowneq '@' '~' '@'                         // CFA, invalid syntax rule
1418                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1419        | '@' updowneq '@' '~' '@'                                                      // CFA, invalid syntax rule
1420                { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1421
1422        | comma_expression ';' comma_expression                         // CFA
1423                { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1424        | comma_expression ';' downupdowneq comma_expression // CFA
1425                { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1426
1427        | comma_expression ';' comma_expression updowneq comma_expression // CFA
1428                { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1429        | comma_expression ';' '@' updowneq comma_expression // CFA
1430                {
1431                        if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1432                        else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1433                }
1434        | comma_expression ';' comma_expression updowneq '@' // CFA
1435                {
1436                        if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1437                        else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1438                        else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1439                }
1440        | comma_expression ';' '@' updowneq '@'                         // CFA, invalid syntax rule
1441                { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1442
1443        | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1444                { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1445        | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1446                {
1447                        if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1448                        else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1449                }
1450        | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1451                {
1452                        if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1453                        else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1454                        else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1455                }
1456        | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1457                { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1458        | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1459                {
1460                        if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1461                        else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1462                }
1463        | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1464                {
1465                        if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1466                        else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1467                        else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1468                }
1469        | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1470                { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1471
1472        | declaration comma_expression                                          // CFA
1473                { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1474        | declaration downupdowneq comma_expression                     // CFA
1475                { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1476
1477        | declaration comma_expression updowneq comma_expression // CFA
1478                { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1479        | declaration '@' updowneq comma_expression                     // CFA
1480                {
1481                        if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1482                        else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1483                }
1484        | declaration comma_expression updowneq '@'                     // CFA
1485                {
1486                        if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1487                        else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1488                        else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1489                }
1490
1491        | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1492                { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1493        | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1494                {
1495                        if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1496                        else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1497                }
1498        | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1499                {
1500                        if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1501                        else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1502                        else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1503                }
1504        | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1505                { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1506        | declaration '@' updowneq comma_expression '~' '@' // CFA
1507                {
1508                        if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1509                        else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1510                }
1511        | declaration comma_expression updowneq '@' '~' '@'     // CFA
1512                {
1513                        if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1514                        else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1515                        else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1516                }
1517        | declaration '@' updowneq '@' '~' '@'                          // CFA, invalid syntax rule
1518                { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1519
1520        | comma_expression ';' TYPEDEFname                                      // CFA, array type
1521                {
1522                        SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1523                        //$$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1524                }
1525        | comma_expression ';' downupdowneq TYPEDEFname         // CFA, array type
1526                {
1527                        if ( $3 == OperKinds::LEThan || $3 == OperKinds::GEThan ) {
1528                                SemanticError( yylloc, "syntax error, all enumeration ranges are equal (all values). Remove \"=~\"." ); $$ = nullptr;
1529                        }
1530                        SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1531                }
1532        ;
1533
1534downupdowneq:
1535        ErangeDown
1536                { $$ = OperKinds::GThan; }
1537        | ErangeUpEq
1538                { $$ = OperKinds::LEThan; }
1539        | ErangeDownEq
1540                { $$ = OperKinds::GEThan; }
1541        ;
1542
1543updown:
1544        '~'
1545                { $$ = OperKinds::LThan; }
1546        | ErangeDown
1547                { $$ = OperKinds::GThan; }
1548        ;
1549
1550updowneq:
1551        updown
1552        | ErangeUpEq
1553                { $$ = OperKinds::LEThan; }
1554        | ErangeDownEq
1555                { $$ = OperKinds::GEThan; }
1556        ;
1557
1558jump_statement:
1559        GOTO identifier_or_type_name ';'
1560                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1561        | GOTO '*' comma_expression ';'                                         // GCC, computed goto
1562                // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1563                // whereas normal operator precedence yields goto (*i)+3;
1564                { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1565                // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1566        | fall_through_name ';'                                                         // CFA
1567                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1568        | fall_through_name identifier_or_type_name ';'         // CFA
1569                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1570        | fall_through_name DEFAULT ';'                                         // CFA
1571                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1572        | CONTINUE ';'
1573                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1574                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1575        | CONTINUE identifier_or_type_name ';'                          // CFA, multi-level continue
1576                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1577                // the target of the transfer appears only at the start of an iteration statement.
1578                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1579        | BREAK ';'
1580                // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1581                { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1582        | BREAK identifier_or_type_name ';'                                     // CFA, multi-level exit
1583                // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1584                // the target of the transfer appears only at the start of an iteration statement.
1585                { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1586        | RETURN comma_expression_opt ';'
1587                { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1588        | RETURN '{' initializer_list_opt comma_opt '}' ';'
1589                { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1590        | SUSPEND ';'
1591                { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1592        | SUSPEND compound_statement
1593                { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1594        | SUSPEND COROUTINE ';'
1595                { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1596        | SUSPEND COROUTINE compound_statement
1597                { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1598        | SUSPEND GENERATOR ';'
1599                { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1600        | SUSPEND GENERATOR compound_statement
1601                { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1602        | THROW assignment_expression_opt ';'                           // handles rethrow
1603                { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1604        | THROWRESUME assignment_expression_opt ';'                     // handles reresume
1605                { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1606        | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1607                { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1608        ;
1609
1610fall_through_name:                                                                              // CFA
1611        FALLTHRU
1612        | FALLTHROUGH
1613        ;
1614
1615with_statement:
1616        WITH '(' tuple_expression_list ')' statement
1617                { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1618        ;
1619
1620// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1621mutex_statement:
1622        MUTEX '(' argument_expression_list_opt ')' statement
1623                {
1624                        if ( ! $3 ) { SemanticError( yylloc, "syntax error, mutex argument list cannot be empty." ); $$ = nullptr; }
1625                        $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1626                }
1627        ;
1628
1629when_clause:
1630        WHEN '(' comma_expression ')'                           { $$ = $3; }
1631        ;
1632
1633when_clause_opt:
1634        // empty
1635                { $$ = nullptr; }
1636        | when_clause
1637        ;
1638
1639cast_expression_list:
1640        cast_expression
1641        | cast_expression_list ',' cast_expression
1642                // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1643                { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1644        ;
1645
1646timeout:
1647        TIMEOUT '(' comma_expression ')'                        { $$ = $3; }
1648        ;
1649
1650wor:
1651        OROR
1652        | WOR
1653
1654waitfor:
1655        WAITFOR '(' cast_expression ')'
1656                { $$ = $3; }
1657        | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1658                { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1659        ;
1660
1661wor_waitfor_clause:
1662        when_clause_opt waitfor statement                                       %prec THEN
1663                // Called first: create header for WaitForStmt.
1664                { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1665        | wor_waitfor_clause wor when_clause_opt waitfor statement
1666                { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1667        | wor_waitfor_clause wor when_clause_opt ELSE statement
1668                { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1669        | wor_waitfor_clause wor when_clause_opt timeout statement      %prec THEN
1670                { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1671        // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1672        | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1673                { SemanticError( yylloc, "syntax error, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1674        | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1675                { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1676        ;
1677
1678waitfor_statement:
1679        wor_waitfor_clause                                                                      %prec THEN
1680                { $$ = new StatementNode( $1 ); }
1681        ;
1682
1683wand:
1684        ANDAND
1685        | WAND
1686        ;
1687
1688waituntil:
1689        WAITUNTIL '(' comma_expression ')'
1690                { $$ = $3; }
1691        ;
1692
1693waituntil_clause:
1694        when_clause_opt waituntil statement
1695                { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1696        | '(' wor_waituntil_clause ')'
1697                { $$ = $2; }
1698        ;
1699
1700wand_waituntil_clause:
1701        waituntil_clause                                                                        %prec THEN
1702                { $$ = $1; }
1703        | waituntil_clause wand wand_waituntil_clause
1704                { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1705        ;
1706
1707wor_waituntil_clause:
1708        wand_waituntil_clause
1709                { $$ = $1; }
1710        | wor_waituntil_clause wor wand_waituntil_clause
1711                { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1712        | wor_waituntil_clause wor when_clause_opt ELSE statement
1713                { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1714        ;
1715
1716waituntil_statement:
1717        wor_waituntil_clause                                                            %prec THEN
1718                { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1719        ;
1720
1721corun_statement:
1722        CORUN statement
1723                { SemanticError( yylloc, "corun statement is currently unimplemented." ); $$ = nullptr; }
1724        ;
1725
1726cofor_statement:
1727        COFOR '(' for_control_expression_list ')' statement
1728                { SemanticError( yylloc, "cofor statement is currently unimplemented." ); $$ = nullptr; }
1729        ;
1730
1731exception_statement:
1732        TRY compound_statement handler_clause                                   %prec THEN
1733                { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1734        | TRY compound_statement finally_clause
1735                { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1736        | TRY compound_statement handler_clause finally_clause
1737                { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1738        ;
1739
1740handler_clause:
1741        handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1742                { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1743        | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1744                { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1745        ;
1746
1747handler_predicate_opt:
1748        // empty
1749                { $$ = nullptr; }
1750        | ';' conditional_expression                            { $$ = $2; }
1751        ;
1752
1753handler_key:
1754        CATCH                                                                           { $$ = ast::Terminate; }
1755        | RECOVER                                                                       { $$ = ast::Terminate; }
1756        | CATCHRESUME                                                           { $$ = ast::Resume; }
1757        | FIXUP                                                                         { $$ = ast::Resume; }
1758        ;
1759
1760finally_clause:
1761        FINALLY compound_statement                                      { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1762        ;
1763
1764exception_declaration:
1765                // No SUE declaration in parameter list.
1766        type_specifier_nobody
1767        | type_specifier_nobody declarator
1768                { $$ = $2->addType( $1 ); }
1769        | type_specifier_nobody variable_abstract_declarator
1770                { $$ = $2->addType( $1 ); }
1771        | cfa_abstract_declarator_tuple identifier                      // CFA
1772                { $$ = $1->addName( $2 ); }
1773        | cfa_abstract_declarator_tuple                                         // CFA
1774        ;
1775
1776enable_disable_statement:
1777        enable_disable_key identifier_list compound_statement
1778        ;
1779
1780enable_disable_key:
1781        ENABLE
1782        | DISABLE
1783        ;
1784
1785asm_statement:
1786        ASM asm_volatile_opt '(' string_literal ')' ';'
1787                { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1788        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1789                { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1790        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1791                { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1792        | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1793                { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1794        | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1795                { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1796        ;
1797
1798asm_volatile_opt:                                                                               // GCC
1799        // empty
1800                { $$ = false; }
1801        | VOLATILE
1802                { $$ = true; }
1803        ;
1804
1805asm_operands_opt:                                                                               // GCC
1806        // empty
1807                { $$ = nullptr; }                                                               // use default argument
1808        | asm_operands_list
1809        ;
1810
1811asm_operands_list:                                                                              // GCC
1812        asm_operand
1813        | asm_operands_list ',' asm_operand
1814                { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1815        ;
1816
1817asm_operand:                                                                                    // GCC
1818        string_literal '(' constant_expression ')'
1819                { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1820        | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1821                {
1822                        $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1823                        delete $2.str;
1824                }
1825        ;
1826
1827asm_clobbers_list_opt:                                                                  // GCC
1828        // empty
1829                { $$ = nullptr; }                                                               // use default argument
1830        | string_literal
1831                { $$ = $1; }
1832        | asm_clobbers_list_opt ',' string_literal
1833                { $$ = (ExpressionNode *)( $1->set_last( $3 ) ); }
1834        ;
1835
1836label_list:
1837        identifier
1838                {
1839                        $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1840                        delete $1;                                                                      // allocated by lexer
1841                }
1842        | label_list ',' identifier
1843                {
1844                        $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1845                        delete $3;                                                                      // allocated by lexer
1846                }
1847        ;
1848
1849// ****************************** DECLARATIONS *********************************
1850
1851declaration_list_opt:                                                                   // used at beginning of switch statement
1852        // empty
1853                { $$ = nullptr; }
1854        | declaration_list
1855        ;
1856
1857declaration_list:
1858        declaration
1859        | declaration_list declaration
1860                { $$ = $1->appendList( $2 ); }
1861        ;
1862
1863KR_parameter_list_opt:                                                                  // used to declare parameter types in K&R style functions
1864        // empty
1865                { $$ = nullptr; }
1866        | KR_parameter_list
1867        ;
1868
1869KR_parameter_list:
1870        c_declaration ';'
1871                { $$ = $1; }
1872        | KR_parameter_list c_declaration ';'
1873                { $$ = $1->appendList( $2 ); }
1874        ;
1875
1876local_label_declaration_opt:                                                    // GCC, local label
1877        // empty
1878        | local_label_declaration_list
1879        ;
1880
1881local_label_declaration_list:                                                   // GCC, local label
1882        LABEL local_label_list ';'
1883        | local_label_declaration_list LABEL local_label_list ';'
1884        ;
1885
1886local_label_list:                                                                               // GCC, local label
1887        identifier_or_type_name
1888        | local_label_list ',' identifier_or_type_name
1889        ;
1890
1891declaration:                                                                                    // old & new style declarations
1892        c_declaration ';'
1893                {
1894                        // printf( "C_DECLARATION1 %p %s\n", $$, $$->name ? $$->name->c_str() : "(nil)" );
1895                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
1896                        //   printf( "\tattr %s\n", attr->name.c_str() );
1897                        // } // for
1898                }
1899        | cfa_declaration ';'                                                           // CFA
1900        | static_assert                                                                         // C11
1901        ;
1902
1903static_assert:
1904        STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1905                { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1906        | STATICASSERT '(' constant_expression ')' ';'          // CFA
1907                { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
1908
1909// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1910// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1911// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1912// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1913// the declaration list (as in Pascal).  ANSI C and the new CFA declarations may appear together in the same program
1914// block, but cannot be mixed within a specific declaration.
1915//
1916//                      CFA                                     C
1917//              [10] int x;                     int x[10];              // array of 10 integers
1918//              [10] * char y;          char *y[10];    // array of 10 pointers to char
1919
1920cfa_declaration:                                                                                // CFA
1921        cfa_variable_declaration
1922        | cfa_typedef_declaration
1923        | cfa_function_declaration
1924        | type_declaring_list
1925                { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1926        | trait_specifier
1927        ;
1928
1929cfa_variable_declaration:                                                               // CFA
1930        cfa_variable_specifier initializer_opt
1931                { $$ = $1->addInitializer( $2 ); }
1932        | declaration_qualifier_list cfa_variable_specifier initializer_opt
1933                // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1934                // them as a type_qualifier cannot appear in that context.
1935                { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1936        | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1937                { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1938        ;
1939
1940cfa_variable_specifier:                                                                 // CFA
1941                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1942                // storage-class
1943        cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1944                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1945        | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1946                { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1947        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1948                { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1949        ;
1950
1951cfa_function_declaration:                                                               // CFA
1952        cfa_function_specifier
1953        | type_qualifier_list cfa_function_specifier
1954                { $$ = $2->addQualifiers( $1 ); }
1955        | declaration_qualifier_list cfa_function_specifier
1956                { $$ = $2->addQualifiers( $1 ); }
1957        | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1958                { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1959        | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1960                {
1961                        // Append the return type at the start (left-hand-side) to each identifier in the list.
1962                        DeclarationNode * ret = new DeclarationNode;
1963                        ret->type = maybeClone( $1->type->base );
1964                        $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1965                }
1966        ;
1967
1968cfa_function_specifier:                                                                 // CFA
1969//      '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
1970//              {
1971//                      $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, nullptr, true );
1972//              }
1973//      '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
1974//              {
1975//                      typedefTable.setNextIdentifier( *$5 );
1976//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
1977//              }
1978//      | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
1979//              {
1980//                      typedefTable.setNextIdentifier( *$5 );
1981//                      $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
1982//              }
1983//      | '[' ']' typegen_name
1984                // identifier_or_type_name must be broken apart because of the sequence:
1985                //
1986                //   '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
1987                //   '[' ']' type_specifier
1988                //
1989                // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
1990                // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
1991        cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1992                // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
1993                { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
1994        | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
1995                { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
1996        ;
1997
1998cfa_function_return:                                                                    // CFA
1999        '[' push cfa_parameter_list pop ']'
2000                { $$ = DeclarationNode::newTuple( $3 ); }
2001        | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
2002                // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2003                { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
2004        ;
2005
2006cfa_typedef_declaration:                                                                // CFA
2007        TYPEDEF cfa_variable_specifier
2008                {
2009                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2010                        $$ = $2->addTypedef();
2011                }
2012        | TYPEDEF cfa_function_specifier
2013                {
2014                        typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2015                        $$ = $2->addTypedef();
2016                }
2017        | cfa_typedef_declaration pop ',' push identifier
2018                {
2019                        typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "cfa_typedef_declaration 3" );
2020                        $$ = $1->appendList( $1->cloneType( $5 ) );
2021                }
2022        ;
2023
2024// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2025// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2026
2027typedef_declaration:
2028        TYPEDEF type_specifier declarator
2029                {
2030                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2031                        if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2032                                SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2033                        } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2034                }
2035        | typedef_declaration ',' declarator
2036                {
2037                        typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2038                        $$ = $1->appendList( $1->cloneBaseType( $3 )->addTypedef() );
2039                }
2040        | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2041                { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2042        | type_specifier TYPEDEF declarator
2043                { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2044        | type_specifier TYPEDEF type_qualifier_list declarator
2045                { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2046        ;
2047
2048typedef_expression:
2049                // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2050        TYPEDEF identifier '=' assignment_expression
2051                {
2052                        SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2053                }
2054        | typedef_expression ',' identifier '=' assignment_expression
2055                {
2056                        SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2057                }
2058        ;
2059
2060c_declaration:
2061        declaration_specifier declaring_list
2062                { $$ = distAttr( $1, $2 ); }
2063        | typedef_declaration
2064        | typedef_expression                                                            // deprecated GCC, naming expression type
2065        | sue_declaration_specifier
2066                {
2067                        assert( $1->type );
2068                        if ( $1->type->qualifiers.any() ) {                     // CV qualifiers ?
2069                                SemanticError( yylloc, "syntax error, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2070                        }
2071                        // enums are never empty declarations because there must have at least one enumeration.
2072                        if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2073                                SemanticError( yylloc, "syntax error, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2074                        }
2075                }
2076        ;
2077
2078declaring_list:
2079                // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2080                // storage-class
2081        variable_declarator asm_name_opt initializer_opt
2082                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2083        | variable_type_redeclarator asm_name_opt initializer_opt
2084                { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2085
2086        | general_function_declarator asm_name_opt
2087                { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2088        | general_function_declarator asm_name_opt '=' VOID
2089                { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2090
2091        | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2092                { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2093        ;
2094
2095general_function_declarator:
2096        function_type_redeclarator
2097        | function_declarator
2098        ;
2099
2100declaration_specifier:                                                                  // type specifier + storage class
2101        basic_declaration_specifier
2102        | type_declaration_specifier
2103        | sue_declaration_specifier
2104        | sue_declaration_specifier invalid_types                       // invalid syntax rule
2105                {
2106                        SemanticError( yylloc, ::toString( "syntax error, expecting ';' at end of ",
2107                                $1->type->enumeration.name ? "enum" : ast::AggregateDecl::aggrString( $1->type->aggregate.kind ),
2108                                " declaration." ) );
2109                        $$ = nullptr;
2110                }
2111        ;
2112
2113invalid_types:
2114        aggregate_key
2115        | basic_type_name
2116        | indirect_type
2117        ;
2118
2119declaration_specifier_nobody:                                                   // type specifier + storage class - {...}
2120                // Preclude SUE declarations in restricted scopes:
2121                //
2122                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2123                //
2124                // because it is impossible to call f due to name equivalence.
2125        basic_declaration_specifier
2126        | sue_declaration_specifier_nobody
2127        | type_declaration_specifier
2128        ;
2129
2130type_specifier:                                                                                 // type specifier
2131        basic_type_specifier
2132        | sue_type_specifier
2133        | type_type_specifier
2134        ;
2135
2136type_specifier_nobody:                                                                  // type specifier - {...}
2137                // Preclude SUE declarations in restricted scopes:
2138                //
2139                //    int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2140                //
2141                // because it is impossible to call f due to name equivalence.
2142        basic_type_specifier
2143        | sue_type_specifier_nobody
2144        | type_type_specifier
2145        ;
2146
2147type_qualifier_list_opt:                                                                // GCC, used in asm_statement
2148        // empty
2149                { $$ = nullptr; }
2150        | type_qualifier_list
2151        ;
2152
2153type_qualifier_list:
2154                // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2155                //
2156                // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2157                // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2158                // appeared only once.
2159        type_qualifier
2160        | type_qualifier_list type_qualifier
2161                { $$ = $1->addQualifiers( $2 ); }
2162        ;
2163
2164type_qualifier:
2165        type_qualifier_name
2166        | attribute                                                                                     // trick handles most atrribute locations
2167        ;
2168
2169type_qualifier_name:
2170        CONST
2171                { $$ = DeclarationNode::newTypeQualifier( Type::Const ); }
2172        | RESTRICT
2173                { $$ = DeclarationNode::newTypeQualifier( Type::Restrict ); }
2174        | VOLATILE
2175                { $$ = DeclarationNode::newTypeQualifier( Type::Volatile ); }
2176        | ATOMIC
2177                { $$ = DeclarationNode::newTypeQualifier( Type::Atomic ); }
2178        | forall
2179                { $$ = DeclarationNode::newForall( $1 ); }
2180        ;
2181
2182forall:
2183        FORALL '(' type_parameter_list ')'                                      // CFA
2184                { $$ = $3; }
2185        ;
2186
2187declaration_qualifier_list:
2188        storage_class_list
2189        | type_qualifier_list storage_class_list                        // remaining OBSOLESCENT (see 2 )
2190                { $$ = $1->addQualifiers( $2 ); }
2191        | declaration_qualifier_list type_qualifier_list storage_class_list
2192                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2193        ;
2194
2195storage_class_list:
2196                // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2197                // only one of each is specified, except for inline, which can appear with the others.
2198                //
2199                // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2200                // specifiers in a declaration.
2201        storage_class
2202        | storage_class_list storage_class
2203                { $$ = $1->addQualifiers( $2 ); }
2204        ;
2205
2206storage_class:
2207        EXTERN
2208                { $$ = DeclarationNode::newStorageClass( Type::Extern ); }
2209        | STATIC
2210                { $$ = DeclarationNode::newStorageClass( Type::Static ); }
2211        | AUTO
2212                { $$ = DeclarationNode::newStorageClass( Type::Auto ); }
2213        | REGISTER
2214                { $$ = DeclarationNode::newStorageClass( Type::Register ); }
2215        | THREADLOCALGCC                                                                                // GCC
2216                { $$ = DeclarationNode::newStorageClass( Type::ThreadlocalGcc ); }
2217        | THREADLOCALC11                                                                                // C11
2218                { $$ = DeclarationNode::newStorageClass( Type::ThreadlocalC11 ); }
2219                // Put function specifiers here to simplify parsing rules, but separate them semantically.
2220        | INLINE                                                                                        // C99
2221                { $$ = DeclarationNode::newFuncSpecifier( Type::Inline ); }
2222        | FORTRAN                                                                                       // C99
2223                { $$ = DeclarationNode::newFuncSpecifier( Type::Fortran ); }
2224        | NORETURN                                                                                      // C11
2225                { $$ = DeclarationNode::newFuncSpecifier( Type::Noreturn ); }
2226        ;
2227
2228basic_type_name:
2229        VOID
2230                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2231        | BOOL                                                                                          // C99
2232                { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
2233        | CHAR
2234                { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
2235        | INT
2236                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
2237        | INT128
2238                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
2239        | UINT128
2240                { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
2241        | FLOAT
2242                { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
2243        | DOUBLE
2244                { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
2245        | uuFLOAT80
2246                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
2247        | uuFLOAT128
2248                { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
2249        | uFLOAT16
2250                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
2251        | uFLOAT32
2252                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
2253        | uFLOAT32X
2254                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
2255        | uFLOAT64
2256                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
2257        | uFLOAT64X
2258                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
2259        | uFLOAT128
2260                { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
2261        | DECIMAL32
2262                { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2263        | DECIMAL64
2264                { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2265        | DECIMAL128
2266                { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2267        | COMPLEX                                                                                       // C99
2268                { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
2269        | IMAGINARY                                                                                     // C99
2270                { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
2271        | SIGNED
2272                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
2273        | UNSIGNED
2274                { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
2275        | SHORT
2276                { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
2277        | LONG
2278                { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
2279        | VA_LIST                                                                                       // GCC, __builtin_va_list
2280                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
2281        | AUTO_TYPE
2282                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
2283        | vtable
2284        ;
2285
2286vtable_opt:
2287        // empty
2288                { $$ = nullptr; }
2289        | vtable
2290        ;
2291
2292vtable:
2293        VTABLE '(' type_name ')' default_opt
2294                { $$ = DeclarationNode::newVtableType( $3 ); }
2295                // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
2296        ;
2297
2298default_opt:
2299        // empty
2300                { $$ = nullptr; }
2301        | DEFAULT
2302                { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2303        ;
2304
2305basic_declaration_specifier:
2306                // A semantic check is necessary for conflicting storage classes.
2307        basic_type_specifier
2308        | declaration_qualifier_list basic_type_specifier
2309                { $$ = $2->addQualifiers( $1 ); }
2310        | basic_declaration_specifier storage_class                     // remaining OBSOLESCENT (see 2)
2311                { $$ = $1->addQualifiers( $2 ); }
2312        | basic_declaration_specifier storage_class type_qualifier_list
2313                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2314        | basic_declaration_specifier storage_class basic_type_specifier
2315                { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2316        ;
2317
2318basic_type_specifier:
2319        direct_type
2320                // Cannot have type modifiers, e.g., short, long, etc.
2321        | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2322                { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2323        ;
2324
2325direct_type:
2326        basic_type_name
2327        | type_qualifier_list basic_type_name
2328                { $$ = $2->addQualifiers( $1 ); }
2329        | direct_type type_qualifier
2330                { $$ = $1->addQualifiers( $2 ); }
2331        | direct_type basic_type_name
2332                { $$ = $1->addType( $2 ); }
2333        ;
2334
2335indirect_type:
2336        TYPEOF '(' type ')'                                                                     // GCC: typeof( x ) y;
2337                { $$ = $3; }
2338        | TYPEOF '(' comma_expression ')'                                       // GCC: typeof( a+b ) y;
2339                { $$ = DeclarationNode::newTypeof( $3 ); }
2340        | BASETYPEOF '(' type ')'                                                       // CFA: basetypeof( x ) y;
2341                { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2342        | BASETYPEOF '(' comma_expression ')'                           // CFA: basetypeof( a+b ) y;
2343                { $$ = DeclarationNode::newTypeof( $3, true ); }
2344        | ZERO_T                                                                                        // CFA
2345                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
2346        | ONE_T                                                                                         // CFA
2347                { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
2348        ;
2349
2350sue_declaration_specifier:                                                              // struct, union, enum + storage class + type specifier
2351        sue_type_specifier
2352                {
2353                        // printf( "sue_declaration_specifier %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2354                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2355                        //   printf( "\tattr %s\n", attr->name.c_str() );
2356                        // } // for
2357                }
2358        | declaration_qualifier_list sue_type_specifier
2359                { $$ = $2->addQualifiers( $1 ); }
2360        | sue_declaration_specifier storage_class                       // remaining OBSOLESCENT (see 2)
2361                { $$ = $1->addQualifiers( $2 ); }
2362        | sue_declaration_specifier storage_class type_qualifier_list
2363                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2364        ;
2365
2366sue_type_specifier:                                                                             // struct, union, enum + type specifier
2367        elaborated_type
2368                {
2369                        // printf( "sue_type_specifier %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2370                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2371                        //   printf( "\tattr %s\n", attr->name.c_str() );
2372                        // } // for
2373                }
2374        | type_qualifier_list
2375                { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2376          elaborated_type
2377                { $$ = $3->addQualifiers( $1 ); }
2378        | sue_type_specifier type_qualifier
2379                {
2380                        if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2381                        $$ = $1->addQualifiers( $2 );
2382                }
2383        ;
2384
2385sue_declaration_specifier_nobody:                                               // struct, union, enum - {...} + storage class + type specifier
2386        sue_type_specifier_nobody
2387        | declaration_qualifier_list sue_type_specifier_nobody
2388                { $$ = $2->addQualifiers( $1 ); }
2389        | sue_declaration_specifier_nobody storage_class        // remaining OBSOLESCENT (see 2)
2390                { $$ = $1->addQualifiers( $2 ); }
2391        | sue_declaration_specifier_nobody storage_class type_qualifier_list
2392                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2393        ;
2394
2395sue_type_specifier_nobody:                                                              // struct, union, enum - {...} + type specifier
2396        elaborated_type_nobody
2397        | type_qualifier_list elaborated_type_nobody
2398                { $$ = $2->addQualifiers( $1 ); }
2399        | sue_type_specifier_nobody type_qualifier
2400                { $$ = $1->addQualifiers( $2 ); }
2401        ;
2402
2403type_declaration_specifier:
2404        type_type_specifier
2405        | declaration_qualifier_list type_type_specifier
2406                { $$ = $2->addQualifiers( $1 ); }
2407        | type_declaration_specifier storage_class                      // remaining OBSOLESCENT (see 2)
2408                { $$ = $1->addQualifiers( $2 ); }
2409        | type_declaration_specifier storage_class type_qualifier_list
2410                { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2411        ;
2412
2413type_type_specifier:                                                                    // typedef types
2414        type_name
2415        | type_qualifier_list type_name
2416                { $$ = $2->addQualifiers( $1 ); }
2417        | type_type_specifier type_qualifier
2418                { $$ = $1->addQualifiers( $2 ); }
2419        ;
2420
2421type_name:
2422        TYPEDEFname
2423                { $$ = DeclarationNode::newFromTypedef( $1 ); }
2424        | '.' TYPEDEFname
2425                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2426        | type_name '.' TYPEDEFname
2427                { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2428        | typegen_name
2429        | '.' typegen_name
2430                { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2431        | type_name '.' typegen_name
2432                { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2433        ;
2434
2435typegen_name:                                                                                   // CFA
2436        TYPEGENname
2437                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2438        | TYPEGENname '(' ')'
2439                { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2440        | TYPEGENname '(' type_list ')'
2441                { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2442        ;
2443
2444elaborated_type:                                                                                // struct, union, enum
2445        aggregate_type
2446                {
2447                        // printf( "elaborated_type %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2448                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2449                        //   printf( "\tattr %s\n", attr->name.c_str() );
2450                        // } // for
2451                }
2452        | enum_type
2453        ;
2454
2455elaborated_type_nobody:                                                                 // struct, union, enum - {...}
2456        aggregate_type_nobody
2457        | enum_type_nobody
2458        ;
2459
2460aggregate_type:                                                                                 // struct, union
2461        aggregate_key attribute_list_opt
2462                { forall = false; }                                                             // reset
2463          '{' field_declaration_list_opt '}' type_parameters_opt
2464                { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2465        | aggregate_key attribute_list_opt identifier
2466                {
2467                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2468                        forall = false;                                                         // reset
2469                }
2470          '{' field_declaration_list_opt '}' type_parameters_opt
2471                {
2472                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2473                }
2474        | aggregate_key attribute_list_opt TYPEDEFname          // unqualified type name
2475                {
2476                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2477                        forall = false;                                                         // reset
2478                }
2479          '{' field_declaration_list_opt '}' type_parameters_opt
2480                {
2481                        DeclarationNode::newFromTypedef( $3 );
2482                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2483                }
2484        | aggregate_key attribute_list_opt TYPEGENname          // unqualified type name
2485                {
2486                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2487                        forall = false;                                                         // reset
2488                }
2489          '{' field_declaration_list_opt '}' type_parameters_opt
2490                {
2491                        DeclarationNode::newFromTypeGen( $3, nullptr );
2492                        $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2493                }
2494        | aggregate_type_nobody
2495        ;
2496
2497type_parameters_opt:
2498        // empty
2499                { $$ = nullptr; }                                                               %prec '}'
2500        | '(' type_list ')'
2501                { $$ = $2; }
2502        ;
2503
2504aggregate_type_nobody:                                                                  // struct, union - {...}
2505        aggregate_key attribute_list_opt identifier
2506                {
2507                        typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2508                        forall = false;                                                         // reset
2509                        $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2510                }
2511        | aggregate_key attribute_list_opt type_name
2512                {
2513                        forall = false;                                                         // reset
2514                        // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2515                        // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2516                        // delete newFromTypeGen.
2517                        if ( $3->type->kind == TypeData::SymbolicInst && ! $3->type->symbolic.isTypedef ) {
2518                                $$ = $3->addQualifiers( $2 );
2519                        } else {
2520                                $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2521                                $3->type->symbolic.name = nullptr;                      // copied to $$
2522                                $3->type->symbolic.actuals = nullptr;
2523                                delete $3;
2524                        }
2525                }
2526        ;
2527
2528aggregate_key:
2529        aggregate_data
2530        | aggregate_control
2531        ;
2532
2533aggregate_data:
2534        STRUCT vtable_opt
2535                { $$ = ast::AggregateDecl::Struct; }
2536        | UNION
2537                { $$ = ast::AggregateDecl::Union; }
2538        | EXCEPTION                                                                                     // CFA
2539                { $$ = ast::AggregateDecl::Exception; }
2540          //            { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = ast::AggregateDecl::NoAggregate; }
2541        ;
2542
2543aggregate_control:                                                                              // CFA
2544        MONITOR
2545                { $$ = ast::AggregateDecl::Monitor; }
2546        | MUTEX STRUCT
2547                { $$ = ast::AggregateDecl::Monitor; }
2548        | GENERATOR
2549                { $$ = ast::AggregateDecl::Generator; }
2550        | MUTEX GENERATOR
2551                {
2552                        SemanticError( yylloc, "monitor generator is currently unimplemented." );
2553                        $$ = ast::AggregateDecl::NoAggregate;
2554                }
2555        | COROUTINE
2556                { $$ = ast::AggregateDecl::Coroutine; }
2557        | MUTEX COROUTINE
2558                {
2559                        SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2560                        $$ = ast::AggregateDecl::NoAggregate;
2561                }
2562        | THREAD
2563                { $$ = ast::AggregateDecl::Thread; }
2564        | MUTEX THREAD
2565                {
2566                        SemanticError( yylloc, "monitor thread is currently unimplemented." );
2567                        $$ = ast::AggregateDecl::NoAggregate;
2568                }
2569        ;
2570
2571field_declaration_list_opt:
2572        // empty
2573                { $$ = nullptr; }
2574        | field_declaration_list_opt field_declaration
2575                { $$ = $1 ? $1->appendList( $2 ) : $2; }
2576        ;
2577
2578field_declaration:
2579        type_specifier field_declaring_list_opt ';'
2580                {
2581                        // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2582                        $$ = fieldDecl( $1, $2 );
2583                        // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2584                        // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2585                        //   printf( "\tattr %s\n", attr->name.c_str() );
2586                        // } // for
2587                }
2588        | type_specifier field_declaring_list_opt '}'           // invalid syntax rule
2589                {
2590                        SemanticError( yylloc, ::toString( "syntax error, expecting ';' at end of previous declaration." ) );
2591                        $$ = nullptr;
2592                }
2593        | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2594                { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2595        | STATIC type_specifier field_declaring_list_opt ';' // CFA
2596                { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2597        | INLINE type_specifier field_abstract_list_opt ';'     // CFA
2598                {
2599                        if ( ! $3 ) {                                                           // field declarator ?
2600                                $3 = DeclarationNode::newName( nullptr );
2601                        } // if
2602                        $3->inLine = true;
2603                        $$ = distAttr( $2, $3 );                                        // mark all fields in list
2604                        distInl( $3 );
2605                }
2606        | INLINE aggregate_control ';'                                          // CFA
2607                { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2608        | typedef_declaration ';'                                                       // CFA
2609        | cfa_field_declaring_list ';'                                          // CFA, new style field declaration
2610        | EXTENSION cfa_field_declaring_list ';'                        // GCC
2611                { distExt( $2 ); $$ = $2; }                                             // mark all fields in list
2612        | INLINE cfa_field_abstract_list ';'                            // CFA, new style field declaration
2613                { $$ = $2; }                                                                    // mark all fields in list
2614        | cfa_typedef_declaration ';'                                           // CFA
2615        | static_assert                                                                         // C11
2616        ;
2617
2618field_declaring_list_opt:
2619        // empty
2620                { $$ = nullptr; }
2621        | field_declarator
2622        | field_declaring_list_opt ',' attribute_list_opt field_declarator
2623                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2624        ;
2625
2626field_declarator:
2627        bit_subrange_size                                                                       // C special case, no field name
2628                { $$ = DeclarationNode::newBitfield( $1 ); }
2629        | variable_declarator bit_subrange_size_opt
2630                // A semantic check is required to ensure bit_subrange only appears on integral types.
2631                { $$ = $1->addBitfield( $2 ); }
2632        | variable_type_redeclarator bit_subrange_size_opt
2633                // A semantic check is required to ensure bit_subrange only appears on integral types.
2634                { $$ = $1->addBitfield( $2 ); }
2635        | function_type_redeclarator bit_subrange_size_opt
2636                // A semantic check is required to ensure bit_subrange only appears on integral types.
2637                { $$ = $1->addBitfield( $2 ); }
2638        ;
2639
2640field_abstract_list_opt:
2641        // empty
2642                { $$ = nullptr; }
2643        | field_abstract
2644        | field_abstract_list_opt ',' attribute_list_opt field_abstract
2645                { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2646        ;
2647
2648field_abstract:
2649                //      no bit fields
2650        variable_abstract_declarator
2651        ;
2652
2653cfa_field_declaring_list:                                                               // CFA, new style field declaration
2654        // bit-fields are handled by C declarations
2655        cfa_abstract_declarator_tuple identifier_or_type_name
2656                { $$ = $1->addName( $2 ); }
2657        | cfa_field_declaring_list ',' identifier_or_type_name
2658                { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2659        ;
2660
2661cfa_field_abstract_list:                                                                // CFA, new style field declaration
2662        // bit-fields are handled by C declarations
2663        cfa_abstract_declarator_tuple
2664        | cfa_field_abstract_list ','
2665                { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2666        ;
2667
2668bit_subrange_size_opt:
2669        // empty
2670                { $$ = nullptr; }
2671        | bit_subrange_size
2672        ;
2673
2674bit_subrange_size:
2675        ':' assignment_expression
2676                { $$ = $2; }
2677        ;
2678
2679enum_type:
2680        ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2681                { $$ = DeclarationNode::newEnum( nullptr, $4, true, false )->addQualifiers( $2 ); }
2682        | ENUM attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2683                { SemanticError( yylloc, "syntax error, hiding '!' the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2684        | ENUM attribute_list_opt identifier
2685                { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2686          hide_opt '{' enumerator_list comma_opt '}'
2687                { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2688        | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2689                { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2690        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2691                {
2692                        if ( $3->storageClasses.val != 0 || $3->type->qualifiers.any() ) {
2693                                SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2694                        }
2695                        $$ = DeclarationNode::newEnum( nullptr, $7, true, true, $3 )->addQualifiers( $5 );
2696                }
2697        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // unqualified type name
2698                { SemanticError( yylloc, "syntax error, hiding '!' the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2699        | ENUM '(' ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2700                {
2701                        $$ = DeclarationNode::newEnum( nullptr, $6, true, true )->addQualifiers( $4 );
2702                }
2703        | ENUM '(' ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2704                { SemanticError( yylloc, "syntax error, hiding '!' the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2705        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2706                {
2707                        if ( $3 && ($3->storageClasses.any() || $3->type->qualifiers.val != 0 )) {
2708                                SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2709                        }
2710                        typedefTable.makeTypedef( *$6, "enum_type 2" );
2711                }
2712          hide_opt '{' enumerator_list comma_opt '}'
2713                {
2714                        $$ = DeclarationNode::newEnum( $6, $11, true, true, $3, $9 )->addQualifiers( $5 )->addQualifiers( $7 );
2715                }
2716        | ENUM '(' ')' attribute_list_opt identifier attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2717                {
2718                        $$ = DeclarationNode::newEnum( $5, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2719                }
2720        | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2721                {
2722                        $$ = DeclarationNode::newEnum( $6->name, $10, true, true, $3, $8 )->addQualifiers( $5 )->addQualifiers( $7 );
2723                }
2724        | ENUM '(' ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2725                {
2726                        $$ = DeclarationNode::newEnum( $5->name, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2727                }
2728        | enum_type_nobody
2729        ;
2730
2731hide_opt:
2732        // empty
2733                { $$ = EnumHiding::Visible; }
2734        | '!'
2735                { $$ = EnumHiding::Hide; }
2736        ;
2737
2738enum_type_nobody:                                                                               // enum - {...}
2739        ENUM attribute_list_opt identifier
2740                {
2741                        typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2742                        $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2743                }
2744        | ENUM attribute_list_opt type_name
2745                {
2746                        typedefTable.makeTypedef( *$3->type->symbolic.name, "enum_type_nobody 2" );
2747                        $$ = DeclarationNode::newEnum( $3->type->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2748                }
2749        ;
2750
2751enumerator_list:
2752        visible_hide_opt identifier_or_type_name enumerator_value_opt
2753                { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2754        | INLINE type_name
2755                { $$ = DeclarationNode::newEnumInLine( *$2->type->symbolic.name ); }
2756        | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2757                { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2758        | enumerator_list ',' INLINE type_name enumerator_value_opt
2759                { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( new string("inline"), nullptr ) ); }
2760        ;
2761
2762visible_hide_opt:
2763        hide_opt
2764        | '^'
2765                { $$ = EnumHiding::Visible; }
2766        ;
2767
2768enumerator_value_opt:
2769        // empty
2770                { $$ = nullptr; }
2771        | '=' constant_expression                                       { $$ = new InitializerNode( $2 ); }
2772        | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2773        // | simple_assignment_operator initializer
2774        //      { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2775        ;
2776
2777cfa_parameter_ellipsis_list_opt:                                                // CFA, abstract + real
2778        // empty
2779                { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2780        | ELLIPSIS
2781                { $$ = nullptr; }
2782        | cfa_abstract_parameter_list
2783        | cfa_parameter_list
2784        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2785                { $$ = $1->appendList( $5 ); }
2786        | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2787                { $$ = $1->addVarArgs(); }
2788        | cfa_parameter_list pop ',' push ELLIPSIS
2789                { $$ = $1->addVarArgs(); }
2790        ;
2791
2792cfa_parameter_list:                                                                             // CFA
2793                // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2794                // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2795        cfa_parameter_declaration
2796        | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2797                { $$ = $1->appendList( $5 ); }
2798        | cfa_parameter_list pop ',' push cfa_parameter_declaration
2799                { $$ = $1->appendList( $5 ); }
2800        | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2801                { $$ = $1->appendList( $5 )->appendList( $9 ); }
2802        ;
2803
2804cfa_abstract_parameter_list:                                                    // CFA, new & old style abstract
2805        cfa_abstract_parameter_declaration
2806        | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2807                { $$ = $1->appendList( $5 ); }
2808        ;
2809
2810parameter_type_list_opt:
2811        // empty
2812                { $$ = nullptr; }
2813        | ELLIPSIS
2814                { $$ = nullptr; }
2815        | parameter_list
2816        | parameter_list ',' ELLIPSIS
2817                { $$ = $1->addVarArgs(); }
2818        ;
2819
2820parameter_list:                                                                                 // abstract + real
2821        abstract_parameter_declaration
2822        | parameter_declaration
2823        | parameter_list ',' abstract_parameter_declaration
2824                { $$ = $1->appendList( $3 ); }
2825        | parameter_list ',' parameter_declaration
2826                { $$ = $1->appendList( $3 ); }
2827        ;
2828
2829// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2830// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2831
2832cfa_parameter_declaration:                                                              // CFA, new & old style parameter declaration
2833        parameter_declaration
2834        | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2835                { $$ = $1->addName( $2 ); }
2836        | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2837                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2838                { $$ = $1->addName( $2 ); }
2839        | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2840                { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2841        | cfa_function_specifier
2842        ;
2843
2844cfa_abstract_parameter_declaration:                                             // CFA, new & old style parameter declaration
2845        abstract_parameter_declaration
2846        | cfa_identifier_parameter_declarator_no_tuple
2847        | cfa_abstract_tuple
2848                // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2849        | type_qualifier_list cfa_abstract_tuple
2850                { $$ = $2->addQualifiers( $1 ); }
2851        | cfa_abstract_function
2852        ;
2853
2854parameter_declaration:
2855                // No SUE declaration in parameter list.
2856        declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2857                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2858        | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2859                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2860        ;
2861
2862abstract_parameter_declaration:
2863        declaration_specifier_nobody default_initializer_opt
2864                { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2865        | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2866                { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2867        ;
2868
2869// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2870// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2871// identifiers.  The ANSI-style parameter-list can redefine a typedef name.
2872
2873identifier_list:                                                                                // K&R-style parameter list => no types
2874        identifier
2875                { $$ = DeclarationNode::newName( $1 ); }
2876        | identifier_list ',' identifier
2877                { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2878        ;
2879
2880identifier_or_type_name:
2881        identifier
2882        | TYPEDEFname
2883        | TYPEGENname
2884        ;
2885
2886type_no_function:                                                                               // sizeof, alignof, cast (constructor)
2887        cfa_abstract_declarator_tuple                                           // CFA
2888        | type_specifier                                                                        // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2889        | type_specifier abstract_declarator
2890                { $$ = $2->addType( $1 ); }
2891        ;
2892
2893type:                                                                                                   // typeof, assertion
2894        type_no_function
2895        | cfa_abstract_function                                                         // CFA
2896        ;
2897
2898initializer_opt:
2899        // empty
2900                { $$ = nullptr; }
2901        | simple_assignment_operator initializer        { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2902        | '=' VOID                                                                      { $$ = new InitializerNode( true ); }
2903        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2904        ;
2905
2906initializer:
2907        assignment_expression                                           { $$ = new InitializerNode( $1 ); }
2908        | '{' initializer_list_opt comma_opt '}'        { $$ = new InitializerNode( $2, true ); }
2909        ;
2910
2911initializer_list_opt:
2912        // empty
2913                { $$ = nullptr; }
2914        | initializer
2915        | designation initializer                                       { $$ = $2->set_designators( $1 ); }
2916        | initializer_list_opt ',' initializer          { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2917        | initializer_list_opt ',' designation initializer { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2918        ;
2919
2920// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2921// '=' to separator the designator from the initializer value, as in:
2922//
2923//              int x[10] = { [1] = 3 };
2924//
2925// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment.  To disambiguate this case, CFA
2926// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2927// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2928// shift/reduce conflicts
2929
2930designation:
2931        designator_list ':'                                                                     // C99, CFA uses ":" instead of "="
2932        | identifier_at ':'                                                                     // GCC, field name
2933                { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
2934        ;
2935
2936designator_list:                                                                                // C99
2937        designator
2938        | designator_list designator
2939                { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2940        //| designator_list designator                                          { $$ = new ExpressionNode( $1, $2 ); }
2941        ;
2942
2943designator:
2944        '.' identifier_at                                                                       // C99, field name
2945                { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
2946        | '[' push assignment_expression pop ']'                        // C99, single array element
2947                // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2948                { $$ = $3; }
2949        | '[' push subrange pop ']'                                                     // CFA, multiple array elements
2950                { $$ = $3; }
2951        | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2952                { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
2953        | '.' '[' push field_name_list pop ']'                          // CFA, tuple field selector
2954                { $$ = $4; }
2955        ;
2956
2957// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2958// rather than an object-oriented type system. This required four groups of extensions:
2959//
2960// Overloading: function, data, and operator identifiers may be overloaded.
2961//
2962// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2963//     and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2964//     definitions of new types. Type declarations with storage class "extern" provide opaque types.
2965//
2966// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2967//     site. A polymorphic function is not a template; it is a function, with an address and a type.
2968//
2969// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2970//     types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2971//     hierarchies. Unlike classes, they can define relationships between types.  Assertions declare that a type or
2972//     types provide the operations declared by a specification.  Assertions are normally used to declare requirements
2973//     on type arguments of polymorphic functions.
2974
2975type_parameter_list:                                                                    // CFA
2976        type_parameter
2977        | type_parameter_list ',' type_parameter
2978                { $$ = $1->appendList( $3 ); }
2979        ;
2980
2981type_initializer_opt:                                                                   // CFA
2982        // empty
2983                { $$ = nullptr; }
2984        | '=' type
2985                { $$ = $2; }
2986        ;
2987
2988type_parameter:                                                                                 // CFA
2989        type_class identifier_or_type_name
2990                {
2991                        typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
2992                        if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
2993                        if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
2994                        if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
2995                }
2996          type_initializer_opt assertion_list_opt
2997                { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
2998        | identifier_or_type_name new_type_class
2999                { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3000          type_initializer_opt assertion_list_opt
3001                { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3002        | '[' identifier_or_type_name ']'
3003                {
3004                        typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3005                        $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3006                }
3007        // | type_specifier identifier_parameter_declarator
3008        | assertion_list
3009                { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3010        ;
3011
3012new_type_class:                                                                                 // CFA
3013        // empty
3014                { $$ = ast::TypeDecl::Otype; }
3015        | '&'
3016                { $$ = ast::TypeDecl::Dtype; }
3017        | '*'
3018                { $$ = ast::TypeDecl::DStype; }                                         // dtype + sized
3019        // | '(' '*' ')'
3020        //      { $$ = ast::TypeDecl::Ftype; }
3021        | ELLIPSIS
3022                { $$ = ast::TypeDecl::Ttype; }
3023        ;
3024
3025type_class:                                                                                             // CFA
3026        OTYPE
3027                { $$ = ast::TypeDecl::Otype; }
3028        | DTYPE
3029                { $$ = ast::TypeDecl::Dtype; }
3030        | FTYPE
3031                { $$ = ast::TypeDecl::Ftype; }
3032        | TTYPE
3033                { $$ = ast::TypeDecl::Ttype; }
3034        ;
3035
3036assertion_list_opt:                                                                             // CFA
3037        // empty
3038                { $$ = nullptr; }
3039        | assertion_list
3040        ;
3041
3042assertion_list:                                                                                 // CFA
3043        assertion
3044        | assertion_list assertion
3045                { $$ = $1->appendList( $2 ); }
3046        ;
3047
3048assertion:                                                                                              // CFA
3049        '|' identifier_or_type_name '(' type_list ')'
3050                { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3051        | '|' '{' push trait_declaration_list pop '}'
3052                { $$ = $4; }
3053        // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3054        //      { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3055        ;
3056
3057type_list:                                                                                              // CFA
3058        type
3059                { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3060        | assignment_expression
3061        | type_list ',' type
3062                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3063        | type_list ',' assignment_expression
3064                { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
3065        ;
3066
3067type_declaring_list:                                                                    // CFA
3068        OTYPE type_declarator
3069                { $$ = $2; }
3070        | storage_class_list OTYPE type_declarator
3071                { $$ = $3->addQualifiers( $1 ); }
3072        | type_declaring_list ',' type_declarator
3073                { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
3074        ;
3075
3076type_declarator:                                                                                // CFA
3077        type_declarator_name assertion_list_opt
3078                { $$ = $1->addAssertions( $2 ); }
3079        | type_declarator_name assertion_list_opt '=' type
3080                { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3081        ;
3082
3083type_declarator_name:                                                                   // CFA
3084        identifier_or_type_name
3085                {
3086                        typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3087                        $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3088                }
3089        | identifier_or_type_name '(' type_parameter_list ')'
3090                {
3091                        typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3092                        $$ = DeclarationNode::newTypeDecl( $1, $3 );
3093                }
3094        ;
3095
3096trait_specifier:                                                                                // CFA
3097        TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3098                {
3099                        SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3100                        $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3101                }
3102        | forall TRAIT identifier_or_type_name '{' '}'          // alternate
3103                { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3104        | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3105                {
3106                        SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3107                        $$ = DeclarationNode::newTrait( $2, $4, $8 );
3108                }
3109        | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3110                { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3111        ;
3112
3113trait_declaration_list:                                                                 // CFA
3114        trait_declaration
3115        | trait_declaration_list pop push trait_declaration
3116                { $$ = $1->appendList( $4 ); }
3117        ;
3118
3119trait_declaration:                                                                              // CFA
3120        cfa_trait_declaring_list ';'
3121        | trait_declaring_list ';'
3122        ;
3123
3124cfa_trait_declaring_list:                                                               // CFA
3125        cfa_variable_specifier
3126        | cfa_function_specifier
3127        | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3128                { $$ = $1->appendList( $1->cloneType( $5 ) ); }
3129        ;
3130
3131trait_declaring_list:                                                                   // CFA
3132        type_specifier declarator
3133                { $$ = $2->addType( $1 ); }
3134        | trait_declaring_list pop ',' push declarator
3135                { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
3136        ;
3137
3138// **************************** EXTERNAL DEFINITIONS *****************************
3139
3140translation_unit:
3141        // empty, input file
3142        | external_definition_list
3143                { parseTree = parseTree ? parseTree->appendList( $1 ) : $1;     }
3144        ;
3145
3146external_definition_list:
3147        push external_definition pop
3148                { $$ = $2; }
3149        | external_definition_list push external_definition pop
3150                { $$ = $1 ? $1->appendList( $3 ) : $3; }
3151        ;
3152
3153external_definition_list_opt:
3154        // empty
3155                { $$ = nullptr; }
3156        | external_definition_list
3157        ;
3158
3159up:
3160                { typedefTable.up( forall ); forall = false; }
3161        ;
3162
3163down:
3164                { typedefTable.down(); }
3165        ;
3166
3167external_definition:
3168        DIRECTIVE
3169                { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3170        | declaration
3171                {
3172                        // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3173                        // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3174                        // disallowed at the moment.
3175                        if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static && $1->type && $1->type->kind == TypeData::AggregateInst ) {
3176                                if ( $1->type->aggInst.aggregate->kind == TypeData::Enum && $1->type->aggInst.aggregate->enumeration.anon ) {
3177                                        SemanticError( yylloc, "extern anonymous enumeration is currently unimplemented." ); $$ = nullptr;
3178                                } else if ( $1->type->aggInst.aggregate->aggregate.anon ) { // handles struct or union
3179                                        SemanticError( yylloc, "extern anonymous struct/union is currently unimplemented." ); $$ = nullptr;
3180                                }
3181                        }
3182                }
3183        | IDENTIFIER IDENTIFIER
3184                { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3185        | IDENTIFIER type_qualifier                                                     // invalid syntax rule
3186                { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3187        | IDENTIFIER storage_class                                                      // invalid syntax rule
3188                { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3189        | IDENTIFIER basic_type_name                                            // invalid syntax rule
3190                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3191        | IDENTIFIER TYPEDEFname                                                        // invalid syntax rule
3192                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3193        | IDENTIFIER TYPEGENname                                                        // invalid syntax rule
3194                { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3195        | external_function_definition
3196        | EXTENSION external_definition                                         // GCC, multiple __extension__ allowed, meaning unknown
3197                {
3198                        distExt( $2 );                                                          // mark all fields in list
3199                        $$ = $2;
3200                }
3201        | ASM '(' string_literal ')' ';'                                        // GCC, global assembler statement
3202                { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3203        | EXTERN STRINGliteral
3204                {
3205                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
3206                        linkage = ast::Linkage::update( yylloc, linkage, $2 );
3207                }
3208          up external_definition down
3209                {
3210                        linkage = linkageStack.top();
3211                        linkageStack.pop();
3212                        $$ = $5;
3213                }
3214        | EXTERN STRINGliteral                                                          // C++-style linkage specifier
3215                {
3216                        linkageStack.push( linkage );                           // handle nested extern "C"/"Cforall"
3217                        linkage = ast::Linkage::update( yylloc, linkage, $2 );
3218                }
3219          '{' up external_definition_list_opt down '}'
3220                {
3221                        linkage = linkageStack.top();
3222                        linkageStack.pop();
3223                        $$ = $6;
3224                }
3225        // global distribution
3226        | type_qualifier_list
3227                {
3228                        if ( $1->type->qualifiers.any() ) {
3229                                SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3230                        }
3231                        if ( $1->type->forall ) forall = true;          // remember generic type
3232                }
3233          '{' up external_definition_list_opt down '}'          // CFA, namespace
3234                {
3235                        distQual( $5, $1 );
3236                        forall = false;
3237                        $$ = $5;
3238                }
3239        | declaration_qualifier_list
3240                {
3241                        if ( $1->type && $1->type->qualifiers.any() ) {
3242                                SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3243                        }
3244                        if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3245                }
3246          '{' up external_definition_list_opt down '}'          // CFA, namespace
3247                {
3248                        distQual( $5, $1 );
3249                        forall = false;
3250                        $$ = $5;
3251                }
3252        | declaration_qualifier_list type_qualifier_list
3253                {
3254                        if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3255                                SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3256                        }
3257                        if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3258                }
3259          '{' up external_definition_list_opt down '}'          // CFA, namespace
3260                {
3261                        distQual( $6, $1->addQualifiers( $2 ) );
3262                        forall = false;
3263                        $$ = $6;
3264                }
3265        ;
3266
3267external_function_definition:
3268        function_definition
3269                // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3270                // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3271                // Parsing is possible because function_definition does not appear in the context of an expression (nested
3272                // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3273                // declaration must still have a type_specifier.  OBSOLESCENT (see 1)
3274        | function_declarator compound_statement
3275                { $$ = $1->addFunctionBody( $2 ); }
3276        | KR_function_declarator KR_parameter_list_opt compound_statement
3277                { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3278        ;
3279
3280with_clause_opt:
3281        // empty
3282                { $$ = nullptr; forall = false; }
3283        | WITH '(' tuple_expression_list ')' attribute_list_opt
3284                {
3285                        $$ = $3; forall = false;
3286                        if ( $5 ) {
3287                                SemanticError( yylloc, "syntax error, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3288                                $$ = nullptr;
3289                        } // if
3290                }
3291        ;
3292
3293function_definition:
3294        cfa_function_declaration with_clause_opt compound_statement     // CFA
3295                {
3296                        // Add the function body to the last identifier in the function definition list, i.e., foo3:
3297                        //   [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3298                        $1->get_last()->addFunctionBody( $3, $2 );
3299                        $$ = $1;
3300                }
3301        | declaration_specifier function_declarator with_clause_opt compound_statement
3302                {
3303                        rebindForall( $1, $2 );
3304                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3305                }
3306        | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3307                {
3308                        rebindForall( $1, $2 );
3309                        $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3310                }
3311                // handles default int return type, OBSOLESCENT (see 1)
3312        | type_qualifier_list function_declarator with_clause_opt compound_statement
3313                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3314                // handles default int return type, OBSOLESCENT (see 1)
3315        | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3316                { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3317                // handles default int return type, OBSOLESCENT (see 1)
3318        | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3319                { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3320
3321                // Old-style K&R function definition, OBSOLESCENT (see 4)
3322        | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3323                {
3324                        rebindForall( $1, $2 );
3325                        $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3326                }
3327                // handles default int return type, OBSOLESCENT (see 1)
3328        | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3329                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3330                // handles default int return type, OBSOLESCENT (see 1)
3331        | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3332                { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3333                // handles default int return type, OBSOLESCENT (see 1)
3334        | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3335                { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3336        ;
3337
3338declarator:
3339        variable_declarator
3340        | variable_type_redeclarator
3341        | function_declarator
3342        | function_type_redeclarator
3343        ;
3344
3345subrange:
3346        constant_expression '~' constant_expression                     // CFA, integer subrange
3347                { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3348        ;
3349
3350asm_name_opt:                                                                                   // GCC
3351        // empty
3352                { $$ = nullptr; }
3353        | ASM '(' string_literal ')' attribute_list_opt
3354                {
3355                        DeclarationNode * name = new DeclarationNode();
3356                        name->asmName = maybeMoveBuild( $3 );
3357                        $$ = name->addQualifiers( $5 );
3358                }
3359        ;
3360
3361attribute_list_opt:                                                                             // GCC
3362        // empty
3363                { $$ = nullptr; }
3364        | attribute_list
3365        ;
3366
3367attribute_list:                                                                                 // GCC
3368        attribute
3369        | attribute_list attribute
3370                { $$ = $2->addQualifiers( $1 ); }
3371        ;
3372
3373attribute:                                                                                              // GCC
3374        ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3375                { $$ = $4; }
3376        ;
3377
3378attribute_name_list:                                                                    // GCC
3379        attribute_name
3380        | attribute_name_list ',' attribute_name
3381                { $$ = $3->addQualifiers( $1 ); }
3382        ;
3383
3384attribute_name:                                                                                 // GCC
3385        // empty
3386                { $$ = nullptr; }
3387        | attr_name
3388                { $$ = DeclarationNode::newAttribute( $1 ); }
3389        | attr_name '(' argument_expression_list_opt ')'
3390                { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3391        ;
3392
3393attr_name:                                                                                              // GCC
3394        IDENTIFIER
3395        | quasi_keyword
3396        | TYPEDEFname
3397        | TYPEGENname
3398        | FALLTHROUGH
3399                { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3400        | CONST
3401                { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3402        ;
3403
3404// ============================================================================
3405// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3406// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3407// in:
3408//
3409//              int (*f())[10] { ... };
3410//              ... (*f())[3] += 1;             // definition mimics usage
3411//
3412// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3413// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3414// ============================================================================
3415
3416// ----------------------------------------------------------------------------
3417// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3418// to define a variable or function prototype, e.g.:
3419//
3420//              valid declaration               invalid definition
3421//              -----------------               ------------------
3422//              int f;                                  int f {}
3423//              int *f;                                 int *f {}
3424//              int f[10];                              int f[10] {}
3425//              int (*f)(int);                  int (*f)(int) {}
3426//
3427// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3428// variable_declarator and function_declarator.
3429// ----------------------------------------------------------------------------
3430
3431// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3432// declaring an array of functions versus a pointer to an array of functions.
3433
3434paren_identifier:
3435        identifier_at
3436                { $$ = DeclarationNode::newName( $1 ); }
3437        | '(' paren_identifier ')'                                                      // redundant parenthesis
3438                { $$ = $2; }
3439        ;
3440
3441variable_declarator:
3442        paren_identifier attribute_list_opt
3443                { $$ = $1->addQualifiers( $2 ); }
3444        | variable_ptr
3445        | variable_array attribute_list_opt
3446                { $$ = $1->addQualifiers( $2 ); }
3447        | variable_function attribute_list_opt
3448                { $$ = $1->addQualifiers( $2 ); }
3449        ;
3450
3451variable_ptr:
3452        ptrref_operator variable_declarator
3453                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3454        | ptrref_operator type_qualifier_list variable_declarator
3455                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3456        | '(' variable_ptr ')' attribute_list_opt                       // redundant parenthesis
3457                { $$ = $2->addQualifiers( $4 ); }
3458        | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3459                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3460        ;
3461
3462variable_array:
3463        paren_identifier array_dimension
3464                { $$ = $1->addArray( $2 ); }
3465        | '(' variable_ptr ')' array_dimension
3466                { $$ = $2->addArray( $4 ); }
3467        | '(' attribute_list variable_ptr ')' array_dimension
3468                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3469        | '(' variable_array ')' multi_array_dimension          // redundant parenthesis
3470                { $$ = $2->addArray( $4 ); }
3471        | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3472                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3473        | '(' variable_array ')'                                                        // redundant parenthesis
3474                { $$ = $2; }
3475        | '(' attribute_list variable_array ')'                         // redundant parenthesis
3476                { $$ = $3->addQualifiers( $2 ); }
3477        ;
3478
3479variable_function:
3480        '(' variable_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3481                { $$ = $2->addParamList( $5 ); }
3482        | '(' attribute_list variable_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3483                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3484        | '(' variable_function ')'                                                     // redundant parenthesis
3485                { $$ = $2; }
3486        | '(' attribute_list variable_function ')'                      // redundant parenthesis
3487                { $$ = $3->addQualifiers( $2 ); }
3488        ;
3489
3490// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3491// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3492// is the same scope.  The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3493
3494function_declarator:
3495        function_no_ptr attribute_list_opt
3496                { $$ = $1->addQualifiers( $2 ); }
3497        | function_ptr
3498        | function_array attribute_list_opt
3499                { $$ = $1->addQualifiers( $2 ); }
3500        ;
3501
3502function_no_ptr:
3503        paren_identifier '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3504                { $$ = $1->addParamList( $3 ); }
3505        | '(' function_ptr ')' '(' parameter_type_list_opt ')'
3506                { $$ = $2->addParamList( $5 ); }
3507        | '(' attribute_list function_ptr ')' '(' parameter_type_list_opt ')'
3508                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3509        | '(' function_no_ptr ')'                                                       // redundant parenthesis
3510                { $$ = $2; }
3511        | '(' attribute_list function_no_ptr ')'                        // redundant parenthesis
3512                { $$ = $3->addQualifiers( $2 ); }
3513        ;
3514
3515function_ptr:
3516        ptrref_operator function_declarator
3517                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3518        | ptrref_operator type_qualifier_list function_declarator
3519                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3520        | '(' function_ptr ')' attribute_list_opt
3521                { $$ = $2->addQualifiers( $4 ); }
3522        | '(' attribute_list function_ptr ')' attribute_list_opt
3523                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3524        ;
3525
3526function_array:
3527        '(' function_ptr ')' array_dimension
3528                { $$ = $2->addArray( $4 ); }
3529        | '(' attribute_list function_ptr ')' array_dimension
3530                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3531        | '(' function_array ')' multi_array_dimension          // redundant parenthesis
3532                { $$ = $2->addArray( $4 ); }
3533        | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3534                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3535        | '(' function_array ')'                                                        // redundant parenthesis
3536                { $$ = $2; }
3537        | '(' attribute_list function_array ')'                         // redundant parenthesis
3538                { $$ = $3->addQualifiers( $2 ); }
3539        ;
3540
3541// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3542//
3543//   f( a, b, c ) int a, *b, c[]; {}
3544//
3545// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3546// returning arrays and functions versus pointers to arrays and functions.
3547
3548KR_function_declarator:
3549        KR_function_no_ptr
3550        | KR_function_ptr
3551        | KR_function_array
3552        ;
3553
3554KR_function_no_ptr:
3555        paren_identifier '(' identifier_list ')'                        // function_declarator handles empty parameter
3556                { $$ = $1->addIdList( $3 ); }
3557        | '(' KR_function_ptr ')' '(' parameter_type_list_opt ')'
3558                { $$ = $2->addParamList( $5 ); }
3559        | '(' attribute_list KR_function_ptr ')' '(' parameter_type_list_opt ')'
3560                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3561        | '(' KR_function_no_ptr ')'                                            // redundant parenthesis
3562                { $$ = $2; }
3563        | '(' attribute_list KR_function_no_ptr ')'                     // redundant parenthesis
3564                { $$ = $3->addQualifiers( $2 ); }
3565        ;
3566
3567KR_function_ptr:
3568        ptrref_operator KR_function_declarator
3569                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3570        | ptrref_operator type_qualifier_list KR_function_declarator
3571                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3572        | '(' KR_function_ptr ')'
3573                { $$ = $2; }
3574        | '(' attribute_list KR_function_ptr ')'
3575                { $$ = $3->addQualifiers( $2 ); }
3576        ;
3577
3578KR_function_array:
3579        '(' KR_function_ptr ')' array_dimension
3580                { $$ = $2->addArray( $4 ); }
3581        | '(' attribute_list KR_function_ptr ')' array_dimension
3582                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3583        | '(' KR_function_array ')' multi_array_dimension       // redundant parenthesis
3584                { $$ = $2->addArray( $4 ); }
3585        | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3586                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3587        | '(' KR_function_array ')'                                                     // redundant parenthesis
3588                { $$ = $2; }
3589        | '(' attribute_list KR_function_array ')'                      // redundant parenthesis
3590                { $$ = $3->addQualifiers( $2 ); }
3591        ;
3592
3593// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3594//
3595//              typedef int foo;
3596//              {
3597//                 int foo; // redefine typedef name in new scope
3598//              }
3599
3600paren_type:
3601        typedef_name
3602                {
3603                        // hide type name in enclosing scope by variable name
3604                        typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3605                }
3606        | '(' paren_type ')'
3607                { $$ = $2; }
3608        ;
3609
3610variable_type_redeclarator:
3611        paren_type attribute_list_opt
3612                { $$ = $1->addQualifiers( $2 ); }
3613        | variable_type_ptr
3614        | variable_type_array attribute_list_opt
3615                { $$ = $1->addQualifiers( $2 ); }
3616        | variable_type_function attribute_list_opt
3617                { $$ = $1->addQualifiers( $2 ); }
3618        ;
3619
3620variable_type_ptr:
3621        ptrref_operator variable_type_redeclarator
3622                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3623        | ptrref_operator type_qualifier_list variable_type_redeclarator
3624                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3625        | '(' variable_type_ptr ')' attribute_list_opt          // redundant parenthesis
3626                { $$ = $2->addQualifiers( $4 ); }
3627        | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3628                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3629        ;
3630
3631variable_type_array:
3632        paren_type array_dimension
3633                { $$ = $1->addArray( $2 ); }
3634        | '(' variable_type_ptr ')' array_dimension
3635                { $$ = $2->addArray( $4 ); }
3636        | '(' attribute_list variable_type_ptr ')' array_dimension
3637                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3638        | '(' variable_type_array ')' multi_array_dimension     // redundant parenthesis
3639                { $$ = $2->addArray( $4 ); }
3640        | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3641                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3642        | '(' variable_type_array ')'                                           // redundant parenthesis
3643                { $$ = $2; }
3644        | '(' attribute_list variable_type_array ')'            // redundant parenthesis
3645                { $$ = $3->addQualifiers( $2 ); }
3646        ;
3647
3648variable_type_function:
3649        '(' variable_type_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3650                { $$ = $2->addParamList( $5 ); }
3651        | '(' attribute_list variable_type_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3652                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3653        | '(' variable_type_function ')'                                        // redundant parenthesis
3654                { $$ = $2; }
3655        | '(' attribute_list variable_type_function ')'         // redundant parenthesis
3656                { $$ = $3->addQualifiers( $2 ); }
3657        ;
3658
3659// This pattern parses a declaration for a function prototype that redefines a type name.  It precludes declaring an
3660// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3661// arrays and functions.
3662
3663function_type_redeclarator:
3664        function_type_no_ptr attribute_list_opt
3665                { $$ = $1->addQualifiers( $2 ); }
3666        | function_type_ptr
3667        | function_type_array attribute_list_opt
3668                { $$ = $1->addQualifiers( $2 ); }
3669        ;
3670
3671function_type_no_ptr:
3672        paren_type '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3673                { $$ = $1->addParamList( $3 ); }
3674        | '(' function_type_ptr ')' '(' parameter_type_list_opt ')'
3675                { $$ = $2->addParamList( $5 ); }
3676        | '(' attribute_list function_type_ptr ')' '(' parameter_type_list_opt ')'
3677                { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3678        | '(' function_type_no_ptr ')'                                          // redundant parenthesis
3679                { $$ = $2; }
3680        | '(' attribute_list function_type_no_ptr ')'           // redundant parenthesis
3681                { $$ = $3->addQualifiers( $2 ); }
3682        ;
3683
3684function_type_ptr:
3685        ptrref_operator function_type_redeclarator
3686                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3687        | ptrref_operator type_qualifier_list function_type_redeclarator
3688                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3689        | '(' function_type_ptr ')' attribute_list_opt
3690                { $$ = $2->addQualifiers( $4 ); }
3691        | '(' attribute_list function_type_ptr ')' attribute_list_opt
3692                { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3693        ;
3694
3695function_type_array:
3696        '(' function_type_ptr ')' array_dimension
3697                { $$ = $2->addArray( $4 ); }
3698        | '(' attribute_list function_type_ptr ')' array_dimension
3699                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3700        | '(' function_type_array ')' multi_array_dimension     // redundant parenthesis
3701                { $$ = $2->addArray( $4 ); }
3702        | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3703                { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3704        | '(' function_type_array ')'                                           // redundant parenthesis
3705                { $$ = $2; }
3706        | '(' attribute_list function_type_array ')'            // redundant parenthesis
3707                { $$ = $3->addQualifiers( $2 ); }
3708        ;
3709
3710// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3711// typedef name and allows the C99 array options, which can only appear in a parameter list.  The pattern precludes
3712// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3713// pointers to arrays and functions.
3714
3715identifier_parameter_declarator:
3716        paren_identifier attribute_list_opt
3717                { $$ = $1->addQualifiers( $2 ); }
3718        | '&' MUTEX paren_identifier attribute_list_opt
3719                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3720        | identifier_parameter_ptr
3721        | identifier_parameter_array attribute_list_opt
3722                { $$ = $1->addQualifiers( $2 ); }
3723        | identifier_parameter_function attribute_list_opt
3724                { $$ = $1->addQualifiers( $2 ); }
3725        ;
3726
3727identifier_parameter_ptr:
3728        ptrref_operator identifier_parameter_declarator
3729                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3730        | ptrref_operator type_qualifier_list identifier_parameter_declarator
3731                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3732        | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3733                { $$ = $2->addQualifiers( $4 ); }
3734        ;
3735
3736identifier_parameter_array:
3737        paren_identifier array_parameter_dimension
3738                { $$ = $1->addArray( $2 ); }
3739        | '(' identifier_parameter_ptr ')' array_dimension
3740                { $$ = $2->addArray( $4 ); }
3741        | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3742                { $$ = $2->addArray( $4 ); }
3743        | '(' identifier_parameter_array ')'                            // redundant parenthesis
3744                { $$ = $2; }
3745        ;
3746
3747identifier_parameter_function:
3748        paren_identifier '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3749                { $$ = $1->addParamList( $3 ); }
3750        | '(' identifier_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3751                { $$ = $2->addParamList( $5 ); }
3752        | '(' identifier_parameter_function ')'                         // redundant parenthesis
3753                { $$ = $2; }
3754        ;
3755
3756// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3757// e.g.:
3758//
3759//              typedef int foo;
3760//              forall( otype T ) struct foo;
3761//              int f( int foo ); // redefine typedef name in new scope
3762//
3763// and allows the C99 array options, which can only appear in a parameter list.
3764
3765type_parameter_redeclarator:
3766        typedef_name attribute_list_opt
3767                { $$ = $1->addQualifiers( $2 ); }
3768        | '&' MUTEX typedef_name attribute_list_opt
3769                { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3770        | type_parameter_ptr
3771        | type_parameter_array attribute_list_opt
3772                { $$ = $1->addQualifiers( $2 ); }
3773        | type_parameter_function attribute_list_opt
3774                { $$ = $1->addQualifiers( $2 ); }
3775        ;
3776
3777typedef_name:
3778        TYPEDEFname
3779                { $$ = DeclarationNode::newName( $1 ); }
3780        | TYPEGENname
3781                { $$ = DeclarationNode::newName( $1 ); }
3782        ;
3783
3784type_parameter_ptr:
3785        ptrref_operator type_parameter_redeclarator
3786                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3787        | ptrref_operator type_qualifier_list type_parameter_redeclarator
3788                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3789        | '(' type_parameter_ptr ')' attribute_list_opt         // redundant parenthesis
3790                { $$ = $2->addQualifiers( $4 ); }
3791        ;
3792
3793type_parameter_array:
3794        typedef_name array_parameter_dimension
3795                { $$ = $1->addArray( $2 ); }
3796        | '(' type_parameter_ptr ')' array_parameter_dimension
3797                { $$ = $2->addArray( $4 ); }
3798        ;
3799
3800type_parameter_function:
3801        typedef_name '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3802                { $$ = $1->addParamList( $3 ); }
3803        | '(' type_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3804                { $$ = $2->addParamList( $5 ); }
3805        ;
3806
3807// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3808// which the type applies, e.g.:
3809//
3810//              sizeof( int );
3811//              sizeof( int * );
3812//              sizeof( int [10] );
3813//              sizeof( int (*)() );
3814//              sizeof( int () );
3815//
3816// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3817// and functions versus pointers to arrays and functions.
3818
3819abstract_declarator:
3820        abstract_ptr
3821        | abstract_array attribute_list_opt
3822                { $$ = $1->addQualifiers( $2 ); }
3823        | abstract_function attribute_list_opt
3824                { $$ = $1->addQualifiers( $2 ); }
3825        ;
3826
3827abstract_ptr:
3828        ptrref_operator
3829                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3830        | ptrref_operator type_qualifier_list
3831                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3832        | ptrref_operator abstract_declarator
3833                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3834        | ptrref_operator type_qualifier_list abstract_declarator
3835                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3836        | '(' abstract_ptr ')' attribute_list_opt
3837                { $$ = $2->addQualifiers( $4 ); }
3838        ;
3839
3840abstract_array:
3841        array_dimension
3842        | '(' abstract_ptr ')' array_dimension
3843                { $$ = $2->addArray( $4 ); }
3844        | '(' abstract_array ')' multi_array_dimension          // redundant parenthesis
3845                { $$ = $2->addArray( $4 ); }
3846        | '(' abstract_array ')'                                                        // redundant parenthesis
3847                { $$ = $2; }
3848        ;
3849
3850abstract_function:
3851        '(' parameter_type_list_opt ')'                 // empty parameter list OBSOLESCENT (see 3)
3852                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3853        | '(' abstract_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3854                { $$ = $2->addParamList( $5 ); }
3855        | '(' abstract_function ')'                                                     // redundant parenthesis
3856                { $$ = $2; }
3857        ;
3858
3859array_dimension:
3860                // Only the first dimension can be empty.
3861        '[' ']'
3862                { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3863        | '[' ']' multi_array_dimension
3864                { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3865                // Cannot use constant_expression because of tuples => semantic check
3866        | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3867                { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3868                // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3869        | '[' push array_type_list pop ']'                                      // CFA
3870                { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3871        | multi_array_dimension
3872        ;
3873
3874array_type_list:
3875        basic_type_name
3876                { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3877        | type_name
3878                { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3879        | assignment_expression upupeq assignment_expression
3880        | array_type_list ',' basic_type_name
3881                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3882        | array_type_list ',' type_name
3883                { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3884        | array_type_list ',' assignment_expression upupeq assignment_expression
3885        ;
3886
3887upupeq:
3888        '~'
3889                { $$ = OperKinds::LThan; }
3890        | ErangeUpEq
3891                { $$ = OperKinds::LEThan; }
3892        ;
3893
3894multi_array_dimension:
3895        '[' push assignment_expression pop ']'
3896                { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3897        | '[' push '*' pop ']'                                                          // C99
3898                { $$ = DeclarationNode::newVarArray( 0 ); }
3899        | multi_array_dimension '[' push assignment_expression pop ']'
3900                { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
3901        | multi_array_dimension '[' push '*' pop ']'            // C99
3902                { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3903        ;
3904
3905// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3906// identifier to which the type applies, e.g.:
3907//
3908//              int f( int );                   // not handled here
3909//              int f( int * );                 // abstract function-prototype parameter; no parameter name specified
3910//              int f( int (*)() );             // abstract function-prototype parameter; no parameter name specified
3911//              int f( int (int) );             // abstract function-prototype parameter; no parameter name specified
3912//
3913// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3914// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3915// special meaning of parenthesis around a typedef name:
3916//
3917//              ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3918//              parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3919//              not as redundant parentheses around the identifier."
3920//
3921// For example:
3922//
3923//              typedef float T;
3924//              int f( int ( T [5] ) );                                 // see abstract_parameter_declarator
3925//              int g( int ( T ( int ) ) );                             // see abstract_parameter_declarator
3926//              int f( int f1( T a[5] ) );                              // see identifier_parameter_declarator
3927//              int g( int g1( T g2( int p ) ) );               // see identifier_parameter_declarator
3928//
3929// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3930// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3931// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3932// functions.
3933
3934abstract_parameter_declarator_opt:
3935        // empty
3936                { $$ = nullptr; }
3937        | abstract_parameter_declarator
3938        ;
3939
3940abstract_parameter_declarator:
3941        abstract_parameter_ptr
3942        | '&' MUTEX attribute_list_opt
3943                { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( Type::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3944        | abstract_parameter_array attribute_list_opt
3945                { $$ = $1->addQualifiers( $2 ); }
3946        | abstract_parameter_function attribute_list_opt
3947                { $$ = $1->addQualifiers( $2 ); }
3948        ;
3949
3950abstract_parameter_ptr:
3951        ptrref_operator
3952                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3953        | ptrref_operator type_qualifier_list
3954                { $$ = DeclarationNode::newPointer( $2, $1 ); }
3955        | ptrref_operator abstract_parameter_declarator
3956                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3957        | ptrref_operator type_qualifier_list abstract_parameter_declarator
3958                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3959        | '(' abstract_parameter_ptr ')' attribute_list_opt     // redundant parenthesis
3960                { $$ = $2->addQualifiers( $4 ); }
3961        ;
3962
3963abstract_parameter_array:
3964        array_parameter_dimension
3965        | '(' abstract_parameter_ptr ')' array_parameter_dimension
3966                { $$ = $2->addArray( $4 ); }
3967        | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3968                { $$ = $2->addArray( $4 ); }
3969        | '(' abstract_parameter_array ')'                                      // redundant parenthesis
3970                { $$ = $2; }
3971        ;
3972
3973abstract_parameter_function:
3974        '(' parameter_type_list_opt ')'                 // empty parameter list OBSOLESCENT (see 3)
3975                { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3976        | '(' abstract_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3977                { $$ = $2->addParamList( $5 ); }
3978        | '(' abstract_parameter_function ')'                           // redundant parenthesis
3979                { $$ = $2; }
3980        ;
3981
3982array_parameter_dimension:
3983                // Only the first dimension can be empty or have qualifiers.
3984        array_parameter_1st_dimension
3985        | array_parameter_1st_dimension multi_array_dimension
3986                { $$ = $1->addArray( $2 ); }
3987        | multi_array_dimension
3988        ;
3989
3990// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
3991//
3992//              ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
3993//              a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
3994
3995array_parameter_1st_dimension:
3996        '[' ']'
3997                { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3998                // multi_array_dimension handles the '[' '*' ']' case
3999        | '[' push type_qualifier_list '*' pop ']'                      // remaining C99
4000                { $$ = DeclarationNode::newVarArray( $3 ); }
4001        | '[' push type_qualifier_list pop ']'
4002                { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4003                // multi_array_dimension handles the '[' assignment_expression ']' case
4004        | '[' push type_qualifier_list assignment_expression pop ']'
4005                { $$ = DeclarationNode::newArray( $4, $3, false ); }
4006        | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4007                { $$ = DeclarationNode::newArray( $5, $4, true ); }
4008        | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4009                { $$ = DeclarationNode::newArray( $5, $3, true ); }
4010        ;
4011
4012// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4013//
4014//   struct S {
4015//       int;
4016//       int *;
4017//       int [10];
4018//       int (*)();
4019//   };
4020
4021variable_abstract_declarator:
4022        variable_abstract_ptr
4023        | variable_abstract_array attribute_list_opt
4024                { $$ = $1->addQualifiers( $2 ); }
4025        | variable_abstract_function attribute_list_opt
4026                { $$ = $1->addQualifiers( $2 ); }
4027        ;
4028
4029variable_abstract_ptr:
4030        ptrref_operator
4031                { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4032        | ptrref_operator type_qualifier_list
4033                { $$ = DeclarationNode::newPointer( $2, $1 ); }
4034        | ptrref_operator variable_abstract_declarator
4035                { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4036        | ptrref_operator type_qualifier_list variable_abstract_declarator
4037                { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4038        | '(' variable_abstract_ptr ')' attribute_list_opt      // redundant parenthesis
4039                { $$ = $2->addQualifiers( $4 ); }
4040        ;
4041
4042variable_abstract_array:
4043        array_dimension
4044        | '(' variable_abstract_ptr ')' array_dimension
4045                { $$ = $2->addArray( $4 ); }
4046        | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4047                { $$ = $2->addArray( $4 ); }
4048        | '(' variable_abstract_array ')'                                       // redundant parenthesis
4049                { $$ = $2; }
4050        ;
4051
4052variable_abstract_function:
4053        '(' variable_abstract_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
4054                { $$ = $2->addParamList( $5 ); }
4055        | '(' variable_abstract_function ')'                            // redundant parenthesis
4056                { $$ = $2; }
4057        ;
4058
4059// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4060// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4061
4062cfa_identifier_parameter_declarator_tuple:                              // CFA
4063        cfa_identifier_parameter_declarator_no_tuple
4064        | cfa_abstract_tuple
4065        | type_qualifier_list cfa_abstract_tuple
4066                { $$ = $2->addQualifiers( $1 ); }
4067        ;
4068
4069cfa_identifier_parameter_declarator_no_tuple:                   // CFA
4070        cfa_identifier_parameter_ptr
4071        | cfa_identifier_parameter_array
4072        ;
4073
4074cfa_identifier_parameter_ptr:                                                   // CFA
4075                // No SUE declaration in parameter list.
4076        ptrref_operator type_specifier_nobody
4077                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4078        | type_qualifier_list ptrref_operator type_specifier_nobody
4079                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4080        | ptrref_operator cfa_abstract_function
4081                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4082        | type_qualifier_list ptrref_operator cfa_abstract_function
4083                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4084        | ptrref_operator cfa_identifier_parameter_declarator_tuple
4085                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4086        | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4087                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4088        ;
4089
4090cfa_identifier_parameter_array:                                                 // CFA
4091                // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4092                // shift/reduce conflict with new-style empty (void) function return type.
4093        '[' ']' type_specifier_nobody
4094                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4095        | cfa_array_parameter_1st_dimension type_specifier_nobody
4096                { $$ = $2->addNewArray( $1 ); }
4097        | '[' ']' multi_array_dimension type_specifier_nobody
4098                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4099        | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4100                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4101        | multi_array_dimension type_specifier_nobody
4102                { $$ = $2->addNewArray( $1 ); }
4103
4104        | '[' ']' cfa_identifier_parameter_ptr
4105                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4106        | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4107                { $$ = $2->addNewArray( $1 ); }
4108        | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4109                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4110        | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4111                { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4112        | multi_array_dimension cfa_identifier_parameter_ptr
4113                { $$ = $2->addNewArray( $1 ); }
4114        ;
4115
4116cfa_array_parameter_1st_dimension:
4117        '[' push type_qualifier_list '*' pop ']'                        // remaining C99
4118                { $$ = DeclarationNode::newVarArray( $3 ); }
4119        | '[' push type_qualifier_list assignment_expression pop ']'
4120                { $$ = DeclarationNode::newArray( $4, $3, false ); }
4121        | '[' push declaration_qualifier_list assignment_expression pop ']'
4122                // declaration_qualifier_list must be used because of shift/reduce conflict with
4123                // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4124                // appear in this context.
4125                { $$ = DeclarationNode::newArray( $4, $3, true ); }
4126        | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4127                { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4128        ;
4129
4130// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4131// identifier to which the type applies, e.g.:
4132//
4133//              [int] f( int );                         // abstract variable parameter; no parameter name specified
4134//              [int] f( [int] (int) );         // abstract function-prototype parameter; no parameter name specified
4135//
4136// These rules need LR(3):
4137//
4138//              cfa_abstract_tuple identifier_or_type_name
4139//              '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
4140//
4141// since a function return type can be syntactically identical to a tuple type:
4142//
4143//              [int, int] t;
4144//              [int, int] f( int );
4145//
4146// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4147// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4148// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4149// duplicated when appearing with cfa_function_specifier.
4150
4151cfa_abstract_declarator_tuple:                                                  // CFA
4152        cfa_abstract_tuple
4153        | type_qualifier_list cfa_abstract_tuple
4154                { $$ = $2->addQualifiers( $1 ); }
4155        | cfa_abstract_declarator_no_tuple
4156        ;
4157
4158cfa_abstract_declarator_no_tuple:                                               // CFA
4159        cfa_abstract_ptr
4160        | cfa_abstract_array
4161        ;
4162
4163cfa_abstract_ptr:                                                                               // CFA
4164        ptrref_operator type_specifier
4165                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4166        | type_qualifier_list ptrref_operator type_specifier
4167                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4168        | ptrref_operator cfa_abstract_function
4169                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4170        | type_qualifier_list ptrref_operator cfa_abstract_function
4171                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4172        | ptrref_operator cfa_abstract_declarator_tuple
4173                { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4174        | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4175                { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4176        ;
4177
4178cfa_abstract_array:                                                                             // CFA
4179                // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4180                // empty (void) function return type.
4181        '[' ']' type_specifier
4182                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4183        | '[' ']' multi_array_dimension type_specifier
4184                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4185        | multi_array_dimension type_specifier
4186                { $$ = $2->addNewArray( $1 ); }
4187        | '[' ']' cfa_abstract_ptr
4188                { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4189        | '[' ']' multi_array_dimension cfa_abstract_ptr
4190                { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4191        | multi_array_dimension cfa_abstract_ptr
4192                { $$ = $2->addNewArray( $1 ); }
4193        ;
4194
4195cfa_abstract_tuple:                                                                             // CFA
4196        '[' push cfa_abstract_parameter_list pop ']'
4197                { $$ = DeclarationNode::newTuple( $3 ); }
4198        | '[' push type_specifier_nobody ELLIPSIS pop ']'
4199                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4200        | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4201                { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4202        ;
4203
4204cfa_abstract_function:                                                                  // CFA
4205//      '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
4206//              { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4207        cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
4208                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4209        | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
4210                { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4211        ;
4212
4213// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4214//    each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4215//
4216// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4217//    the declaration specifiers in a declaration is an obsolescent feature."
4218//
4219// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4220//    prototype-format parameter type declarators) is an obsolescent feature."
4221//
4222// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4223//    declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4224
4225// ************************ MISCELLANEOUS ********************************
4226
4227comma_opt:                                                                                              // redundant comma
4228        // empty
4229        | ','
4230        ;
4231
4232default_initializer_opt:
4233        // empty
4234                { $$ = nullptr; }
4235        | '=' assignment_expression
4236                { $$ = $2; }
4237        ;
4238
4239%%
4240
4241// ----end of grammar----
4242
4243// Local Variables: //
4244// mode: c++ //
4245// tab-width: 4 //
4246// compile-command: "make install" //
4247// End: //
Note: See TracBrowser for help on using the repository browser.