source: src/Parser/parser.yy@ 4eb3a7c5

Last change on this file since 4eb3a7c5 was 4eb3a7c5, checked in by Peter A. Buhr <pabuhr@…>, 22 months ago

first attempt at correct distribution of attributes for aggregates
  • Property mode set to 100644
File size: 175.7 KB
Line 
1//
2// Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3//
4// The contents of this file are covered under the licence agreement in the
5// file "LICENCE" distributed with Cforall.
6//
7// parser.yy --
8//
9// Author : Peter A. Buhr
10// Created On : Sat Sep 1 20:22:55 2001
11// Last Modified By : Peter A. Buhr
12// Last Modified On : Fri Feb 23 18:25:46 2024
13// Update Count : 6484
14//
15
16// This grammar is based on the ANSI99/11 C grammar, specifically parts of EXPRESSION and STATEMENTS, and on the C
17// grammar by James A. Roskind, specifically parts of DECLARATIONS and EXTERNAL DEFINITIONS. While parts have been
18// copied, important changes have been made in all sections; these changes are sufficient to constitute a new grammar.
19// In particular, this grammar attempts to be more syntactically precise, i.e., it parses less incorrect language syntax
20// that must be subsequently rejected by semantic checks. Nevertheless, there are still several semantic checks
21// required and many are noted in the grammar. Finally, the grammar is extended with GCC and CFA language extensions.
22
23// Acknowledgments to Richard Bilson, Glen Ditchfield, and Rodolfo Gabriel Esteves who all helped when I got stuck with
24// the grammar.
25
26// The root language for this grammar is ANSI99/11 C. All of ANSI99/11 is parsed, except for:
27//
28// designation with '=' (use ':' instead)
29//
30// This incompatibility is discussed in detail before the "designation" grammar rule. Most of the syntactic extensions
31// from ANSI90 to ANSI11 C are marked with the comment "C99/C11".
32
33// This grammar also has two levels of extensions. The first extensions cover most of the GCC C extensions. All of the
34// syntactic extensions for GCC C are marked with the comment "GCC". The second extensions are for Cforall (CFA), which
35// fixes several of C's outstanding problems and extends C with many modern language concepts. All of the syntactic
36// extensions for CFA C are marked with the comment "CFA".
37
38%{
39#define YYDEBUG_LEXER_TEXT( yylval ) // lexer loads this up each time
40#define YYDEBUG 1 // get the pretty debugging code to compile
41#define YYERROR_VERBOSE // more information in syntax errors
42
43#undef __GNUC_MINOR__
44
45#include <cstdio>
46#include <sstream>
47#include <stack>
48using namespace std;
49
50#include "DeclarationNode.h" // for DeclarationNode, ...
51#include "ExpressionNode.h" // for ExpressionNode, ...
52#include "InitializerNode.h" // for InitializerNode, ...
53#include "ParserTypes.h"
54#include "StatementNode.h" // for build_...
55#include "TypedefTable.h"
56#include "TypeData.h"
57#include "Common/SemanticError.h" // error_str
58#include "Common/utility.h" // for maybeMoveBuild, maybeBuild, CodeLo...
59
60// lex uses __null in a boolean context, it's fine.
61#ifdef __clang__
62#pragma GCC diagnostic ignored "-Wparentheses-equality"
63#endif
64
65extern DeclarationNode * parseTree;
66extern ast::Linkage::Spec linkage;
67extern TypedefTable typedefTable;
68
69stack<ast::Linkage::Spec> linkageStack;
70
71bool appendStr( string & to, string & from ) {
72 // 1. Multiple strings are concatenated into a single string but not combined internally. The reason is that
73 // "\x12" "3" is treated as 2 characters versus 1 because "escape sequences are converted into single members of
74 // the execution character set just prior to adjacent string literal concatenation" (C11, Section 6.4.5-8). It is
75 // easier to let the C compiler handle this case.
76 //
77 // 2. String encodings are transformed into canonical form (one encoding at start) so the encoding can be found
78 // without searching the string, e.g.: "abc" L"def" L"ghi" => L"abc" "def" "ghi". Multiple encodings must match,
79 // e.g., u"a" U"b" L"c" is disallowed.
80
81 if ( from[0] != '"' ) { // encoding ?
82 if ( to[0] != '"' ) { // encoding ?
83 if ( to[0] != from[0] || to[1] != from[1] ) { // different encodings ?
84 yyerror( "non-matching string encodings for string-literal concatenation" );
85 return false; // parse error, must call YYERROR in action
86 } else if ( from[1] == '8' ) {
87 from.erase( 0, 1 ); // remove 2nd encoding
88 } // if
89 } else {
90 if ( from[1] == '8' ) { // move encoding to start
91 to = "u8" + to;
92 from.erase( 0, 1 ); // remove 2nd encoding
93 } else {
94 to = from[0] + to;
95 } // if
96 } // if
97 from.erase( 0, 1 ); // remove 2nd encoding
98 } // if
99 to += " " + from; // concatenated into single string
100 return true;
101} // appendStr
102
103DeclarationNode * distAttr( DeclarationNode * typeSpec, DeclarationNode * declList ) {
104 // Distribute type specifier across all declared variables, e.g., static, const, __attribute__.
105 assert( declList );
106
107 // Do not distribute attributes for aggregates because the attributes surrounding the aggregate belong it not the
108 // variables in the declaration list, e.g.,
109 //
110 // struct __attribute__(( aligned(128) )) S { ...
111 // } v1 __attribute__(( aligned(64) )), v2 __attribute__(( aligned(32) )), v3;
112 // struct S v4;
113 //
114 // v1 => 64, v2 =>32, v3 => 128, v2 => 128
115 //
116 // Anonymous aggregates are a special case because there is no aggregate to bind the attribute to; hence it floats
117 // to the declaration list.
118 //
119 // struct __attribute__(( aligned(128) )) /*anonymous */ { ... } v1;
120 //
121 // v1 => 128
122
123 bool copyattr = ! (typeSpec->type && typeSpec->type->kind == TypeData::Aggregate && ! typeSpec->type->aggregate.anon );
124
125 // addType copies the type information for the aggregate instances from typeSpec into cl's aggInst.aggregate.
126 DeclarationNode * cl = (new DeclarationNode)->addType( typeSpec ); // typeSpec IS DELETED!!!
127
128 // Start at second variable in declaration list and clone the type specifiers for each variable..
129 for ( DeclarationNode * cur = dynamic_cast<DeclarationNode *>( declList->get_next() ); cur != nullptr; cur = dynamic_cast<DeclarationNode *>( cur->get_next() ) ) {
130 cl->cloneBaseType( cur, copyattr ); // cur is modified
131 } // for
132
133 // Add first variable in declaration list with hidden type information in aggInst.aggregate, which is used by
134 // extractType to recover the type for the aggregate instances.
135 declList->addType( cl, copyattr ); // cl IS DELETED!!!
136 return declList;
137} // distAttr
138
139void distExt( DeclarationNode * declaration ) {
140 // distribute EXTENSION across all declarations
141 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
142 iter->set_extension( true );
143 } // for
144} // distExt
145
146void distInl( DeclarationNode * declaration ) {
147 // distribute INLINE across all declarations
148 for ( DeclarationNode *iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
149 iter->set_inLine( true );
150 } // for
151} // distInl
152
153void distQual( DeclarationNode * declaration, DeclarationNode * qualifiers ) {
154 // distribute qualifiers across all non-variable declarations in a distribution statemement
155 for ( DeclarationNode * iter = declaration; iter != nullptr; iter = (DeclarationNode *)iter->get_next() ) {
156 // SKULLDUGGERY: Distributions are parsed inside out, so qualifiers are added to declarations inside out. Since
157 // addQualifiers appends to the back of the list, the forall clauses are in the wrong order (right to left). To
158 // get the qualifiers in the correct order and still use addQualifiers (otherwise, 90% of addQualifiers has to
159 // be copied to add to front), the appropriate forall pointers are interchanged before calling addQualifiers.
160 DeclarationNode * clone = qualifiers->clone();
161 if ( qualifiers->type ) { // forall clause ? (handles SC)
162 if ( iter->type->kind == TypeData::Aggregate ) { // struct/union ?
163 swap( clone->type->forall, iter->type->aggregate.params );
164 iter->addQualifiers( clone );
165 } else if ( iter->type->kind == TypeData::AggregateInst && iter->type->aggInst.aggregate->aggregate.body ) { // struct/union ?
166 // Create temporary node to hold aggregate, call addQualifiers as above, then put nodes back together.
167 DeclarationNode newnode;
168 swap( newnode.type, iter->type->aggInst.aggregate );
169 swap( clone->type->forall, newnode.type->aggregate.params );
170 newnode.addQualifiers( clone );
171 swap( newnode.type, iter->type->aggInst.aggregate );
172 } else if ( iter->type->kind == TypeData::Function ) { // routines ?
173 swap( clone->type->forall, iter->type->forall );
174 iter->addQualifiers( clone );
175 } // if
176 } else { // just SC qualifiers
177 iter->addQualifiers( clone );
178 } // if
179 } // for
180 delete qualifiers;
181} // distQual
182
183// There is an ambiguity for inline generic-routine return-types and generic routines.
184// forall( otype T ) struct S { int i; } bar( T ) {}
185// Does the forall bind to the struct or the routine, and how would it be possible to explicitly specify the binding.
186// forall( otype T ) struct S { int T; } forall( otype W ) bar( W ) {}
187// Currently, the forall is associated with the routine, and the generic type has to be separately defined:
188// forall( otype T ) struct S { int T; };
189// forall( otype W ) bar( W ) {}
190
191void rebindForall( DeclarationNode * declSpec, DeclarationNode * funcDecl ) {
192 if ( declSpec->type->kind == TypeData::Aggregate ) { // ignore aggregate definition
193 funcDecl->type->forall = declSpec->type->aggregate.params; // move forall from aggregate to function type
194 declSpec->type->aggregate.params = nullptr;
195 } // if
196} // rebindForall
197
198string * build_postfix_name( string * name ) {
199 *name = string("__postfix_func_") + *name;
200 return name;
201} // build_postfix_name
202
203DeclarationNode * fieldDecl( DeclarationNode * typeSpec, DeclarationNode * fieldList ) {
204 if ( ! fieldList ) { // field declarator ?
205 if ( ! ( typeSpec->type && (typeSpec->type->kind == TypeData::Aggregate || typeSpec->type->kind == TypeData::Enum) ) ) {
206 stringstream ss;
207 // printf( "fieldDecl1 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
208 SemanticWarning( yylloc, Warning::SuperfluousDecl, ss.str().c_str() );
209 return nullptr;
210 } // if
211 // printf( "fieldDecl2 typeSpec %p\n", typeSpec ); typeSpec->type->print( std::cout );
212 fieldList = DeclarationNode::newName( nullptr );
213 } // if
214
215 // printf( "fieldDecl3 typeSpec %p\n", typeSpec ); typeSpec->print( std::cout, 0 );
216 DeclarationNode * temp = distAttr( typeSpec, fieldList ); // mark all fields in list
217 // printf( "fieldDecl4 temp %p\n", temp ); temp->print( std::cout, 0 );
218 return temp;
219} // fieldDecl
220
221#define NEW_ZERO new ExpressionNode( build_constantInteger( yylloc, *new string( "0" ) ) )
222#define NEW_ONE new ExpressionNode( build_constantInteger( yylloc, *new string( "1" ) ) )
223#define UPDOWN( compop, left, right ) (compop == OperKinds::LThan || compop == OperKinds::LEThan ? left : right)
224#define MISSING_ANON_FIELD "syntax error, missing loop fields with an anonymous loop index is meaningless as loop index is unavailable in loop body."
225#define MISSING_LOW "syntax error, missing low value for up-to range so index is uninitialized."
226#define MISSING_HIGH "syntax error, missing high value for down-to range so index is uninitialized."
227
228static ForCtrl * makeForCtrl(
229 const CodeLocation & location,
230 DeclarationNode * init,
231 enum OperKinds compop,
232 ExpressionNode * comp,
233 ExpressionNode * inc ) {
234 // Wrap both comp/inc if they are non-null.
235 if ( comp ) comp = new ExpressionNode( build_binary_val( location,
236 compop,
237 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
238 comp ) );
239 if ( inc ) inc = new ExpressionNode( build_binary_val( location,
240 // choose += or -= for upto/downto
241 compop == OperKinds::LThan || compop == OperKinds::LEThan ? OperKinds::PlusAssn : OperKinds::MinusAssn,
242 new ExpressionNode( build_varref( location, new string( *init->name ) ) ),
243 inc ) );
244 // The StatementNode call frees init->name, it must happen later.
245 return new ForCtrl( new StatementNode( init ), comp, inc );
246}
247
248ForCtrl * forCtrl( const CodeLocation & location, DeclarationNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
249 if ( index->initializer ) {
250 SemanticError( yylloc, "syntax error, direct initialization disallowed. Use instead: type var; initialization ~ comparison ~ increment." );
251 } // if
252 if ( index->next ) {
253 SemanticError( yylloc, "syntax error, multiple loop indexes disallowed in for-loop declaration." );
254 } // if
255 DeclarationNode * initDecl = index->addInitializer( new InitializerNode( start ) );
256 return makeForCtrl( location, initDecl, compop, comp, inc );
257} // forCtrl
258
259ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, string * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
260 ast::ConstantExpr * constant = dynamic_cast<ast::ConstantExpr *>(type->expr.get());
261 if ( constant && (constant->rep == "0" || constant->rep == "1") ) {
262 type = new ExpressionNode( new ast::CastExpr( location, maybeMoveBuild(type), new ast::BasicType( ast::BasicType::SignedInt ) ) );
263 } // if
264 DeclarationNode * initDecl = distAttr(
265 DeclarationNode::newTypeof( type, true ),
266 DeclarationNode::newName( index )->addInitializer( new InitializerNode( start ) )
267 );
268 return makeForCtrl( location, initDecl, compop, comp, inc );
269} // forCtrl
270
271ForCtrl * forCtrl( const CodeLocation & location, ExpressionNode * type, ExpressionNode * index, ExpressionNode * start, enum OperKinds compop, ExpressionNode * comp, ExpressionNode * inc ) {
272 if ( auto identifier = dynamic_cast<ast::NameExpr *>(index->expr.get()) ) {
273 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
274 } else if ( auto commaExpr = dynamic_cast<ast::CommaExpr *>( index->expr.get() ) ) {
275 if ( auto identifier = commaExpr->arg1.as<ast::NameExpr>() ) {
276 return forCtrl( location, type, new string( identifier->name ), start, compop, comp, inc );
277 } else {
278 SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
279 } // if
280 } else {
281 SemanticError( yylloc, "syntax error, loop-index name missing. Expression disallowed." ); return nullptr;
282 } // if
283} // forCtrl
284
285static void IdentifierBeforeIdentifier( string & identifier1, string & identifier2, const char * kind ) {
286 SemanticError( yylloc, "syntax error, adjacent identifiers \"%s\" and \"%s\" are not meaningful in an %s.\n"
287 "Possible cause is misspelled type name or missing generic parameter.",
288 identifier1.c_str(), identifier2.c_str(), kind );
289} // IdentifierBeforeIdentifier
290
291static void IdentifierBeforeType( string & identifier, const char * kind ) {
292 SemanticError( yylloc, "syntax error, identifier \"%s\" cannot appear before a %s.\n"
293 "Possible cause is misspelled storage/CV qualifier, misspelled typename, or missing generic parameter.",
294 identifier.c_str(), kind );
295} // IdentifierBeforeType
296
297bool forall = false; // aggregate have one or more forall qualifiers ?
298
299// https://www.gnu.org/software/bison/manual/bison.html#Location-Type
300#define YYLLOC_DEFAULT(Cur, Rhs, N) \
301if ( N ) { \
302 (Cur).first_line = YYRHSLOC( Rhs, 1 ).first_line; \
303 (Cur).first_column = YYRHSLOC( Rhs, 1 ).first_column; \
304 (Cur).last_line = YYRHSLOC( Rhs, N ).last_line; \
305 (Cur).last_column = YYRHSLOC( Rhs, N ).last_column; \
306 (Cur).filename = YYRHSLOC( Rhs, 1 ).filename; \
307} else { \
308 (Cur).first_line = (Cur).last_line = YYRHSLOC( Rhs, 0 ).last_line; \
309 (Cur).first_column = (Cur).last_column = YYRHSLOC( Rhs, 0 ).last_column; \
310 (Cur).filename = YYRHSLOC( Rhs, 0 ).filename; \
311}
312%}
313
314%define parse.error verbose
315
316// Types declaration for productions
317
318%union {
319 Token tok;
320 ExpressionNode * expr;
321 DeclarationNode * decl;
322 ast::AggregateDecl::Aggregate aggKey;
323 ast::TypeDecl::Kind tclass;
324 StatementNode * stmt;
325 ClauseNode * clause;
326 ast::WaitForStmt * wfs;
327 ast::WaitUntilStmt::ClauseNode * wucn;
328 CondCtl * ifctl;
329 ForCtrl * forctl;
330 LabelNode * labels;
331 InitializerNode * init;
332 OperKinds oper;
333 std::string * str;
334 bool is_volatile;
335 EnumHiding enum_hiding;
336 ast::ExceptionKind except_kind;
337 ast::GenericExpr * genexpr;
338}
339
340// ************************ TERMINAL TOKENS ********************************
341
342// keywords
343%token TYPEDEF
344%token EXTERN STATIC AUTO REGISTER
345%token THREADLOCALGCC THREADLOCALC11 // GCC, C11
346%token INLINE FORTRAN // C99, extension ISO/IEC 9899:1999 Section J.5.9(1)
347%token NORETURN // C11
348%token CONST VOLATILE
349%token RESTRICT // C99
350%token ATOMIC // C11
351%token FORALL MUTEX VIRTUAL VTABLE COERCE // CFA
352%token VOID CHAR SHORT INT LONG FLOAT DOUBLE SIGNED UNSIGNED
353%token BOOL COMPLEX IMAGINARY // C99
354%token INT128 UINT128 uuFLOAT80 uuFLOAT128 // GCC
355%token uFLOAT16 uFLOAT32 uFLOAT32X uFLOAT64 uFLOAT64X uFLOAT128 // GCC
356%token DECIMAL32 DECIMAL64 DECIMAL128 // GCC
357%token ZERO_T ONE_T // CFA
358%token SIZEOF TYPEOF VA_LIST VA_ARG AUTO_TYPE // GCC
359%token OFFSETOF BASETYPEOF TYPEID // CFA
360%token ENUM STRUCT UNION
361%token EXCEPTION // CFA
362%token GENERATOR COROUTINE MONITOR THREAD // CFA
363%token OTYPE FTYPE DTYPE TTYPE TRAIT // CFA
364// %token RESUME // CFA
365%token LABEL // GCC
366%token SUSPEND // CFA
367%token ATTRIBUTE EXTENSION // GCC
368%token IF ELSE SWITCH CASE DEFAULT DO WHILE FOR BREAK CONTINUE GOTO RETURN
369%token CHOOSE FALLTHRU FALLTHROUGH WITH WHEN WAITFOR WAITUNTIL // CFA
370%token CORUN COFOR
371%token DISABLE ENABLE TRY THROW THROWRESUME AT // CFA
372%token ASM // C99, extension ISO/IEC 9899:1999 Section J.5.10(1)
373%token ALIGNAS ALIGNOF GENERIC STATICASSERT // C11
374
375// names and constants: lexer differentiates between identifier and typedef names
376%token<tok> IDENTIFIER TYPEDIMname TYPEDEFname TYPEGENname
377%token<tok> TIMEOUT WAND WOR CATCH RECOVER CATCHRESUME FIXUP FINALLY // CFA
378%token<tok> INTEGERconstant CHARACTERconstant STRINGliteral
379%token<tok> DIRECTIVE
380// Floating point constant is broken into three kinds of tokens because of the ambiguity with tuple indexing and
381// overloading constants 0/1, e.g., x.1 is lexed as (x)(.1), where (.1) is a factional constant, but is semantically
382// converted into the tuple index (.)(1). e.g., 3.x
383%token<tok> FLOATING_DECIMALconstant FLOATING_FRACTIONconstant FLOATINGconstant
384
385// multi-character operators
386%token ARROW // ->
387%token ICR DECR // ++ --
388%token LS RS // << >>
389%token LE GE EQ NE // <= >= == !=
390%token ANDAND OROR // && ||
391%token ELLIPSIS // ...
392
393%token EXPassign MULTassign DIVassign MODassign // \= *= /= %=
394%token PLUSassign MINUSassign // += -=
395%token LSassign RSassign // <<= >>=
396%token ANDassign ERassign ORassign // &= ^= |=
397
398%token ErangeUpEq ErangeDown ErangeDownEq // ~= -~ -~=
399%token ATassign // @=
400
401%type<tok> identifier identifier_at identifier_or_type_name attr_name
402%type<tok> quasi_keyword
403%type<expr> string_literal
404%type<str> string_literal_list
405
406%type<enum_hiding> hide_opt visible_hide_opt
407
408// expressions
409%type<expr> constant
410%type<expr> tuple tuple_expression_list
411%type<oper> ptrref_operator unary_operator assignment_operator simple_assignment_operator compound_assignment_operator
412%type<expr> primary_expression postfix_expression unary_expression
413%type<expr> cast_expression_list cast_expression exponential_expression multiplicative_expression additive_expression
414%type<expr> shift_expression relational_expression equality_expression
415%type<expr> AND_expression exclusive_OR_expression inclusive_OR_expression
416%type<expr> logical_AND_expression logical_OR_expression
417%type<expr> conditional_expression constant_expression assignment_expression assignment_expression_opt
418%type<expr> comma_expression comma_expression_opt
419%type<expr> argument_expression_list_opt argument_expression_list argument_expression default_initializer_opt
420%type<ifctl> conditional_declaration
421%type<forctl> for_control_expression for_control_expression_list
422%type<oper> upupeq updown updowneq downupdowneq
423%type<expr> subrange
424%type<decl> asm_name_opt
425%type<expr> asm_operands_opt asm_operands_list asm_operand
426%type<labels> label_list
427%type<expr> asm_clobbers_list_opt
428%type<is_volatile> asm_volatile_opt
429%type<expr> handler_predicate_opt
430%type<genexpr> generic_association generic_assoc_list
431
432// statements
433%type<stmt> statement labeled_statement compound_statement
434%type<stmt> statement_decl statement_decl_list statement_list_nodecl
435%type<stmt> selection_statement if_statement
436%type<clause> switch_clause_list_opt switch_clause_list
437%type<expr> case_value
438%type<clause> case_clause case_value_list case_label case_label_list
439%type<stmt> iteration_statement jump_statement
440%type<stmt> expression_statement asm_statement
441%type<stmt> with_statement
442%type<expr> with_clause_opt
443%type<stmt> corun_statement cofor_statement
444%type<stmt> exception_statement
445%type<clause> handler_clause finally_clause
446%type<except_kind> handler_key
447%type<stmt> mutex_statement
448%type<expr> when_clause when_clause_opt waitfor waituntil timeout
449%type<stmt> waitfor_statement waituntil_statement
450%type<wfs> wor_waitfor_clause
451%type<wucn> waituntil_clause wand_waituntil_clause wor_waituntil_clause
452
453// declarations
454%type<decl> abstract_declarator abstract_ptr abstract_array abstract_function array_dimension multi_array_dimension
455%type<decl> abstract_parameter_declarator_opt abstract_parameter_declarator abstract_parameter_ptr abstract_parameter_array abstract_parameter_function array_parameter_dimension array_parameter_1st_dimension
456%type<decl> abstract_parameter_declaration
457
458%type<aggKey> aggregate_key aggregate_data aggregate_control
459%type<decl> aggregate_type aggregate_type_nobody
460
461%type<decl> assertion assertion_list assertion_list_opt
462
463%type<expr> bit_subrange_size_opt bit_subrange_size
464
465%type<decl> basic_declaration_specifier basic_type_name basic_type_specifier direct_type indirect_type
466%type<decl> vtable vtable_opt default_opt
467
468%type<decl> trait_declaration trait_declaration_list trait_declaring_list trait_specifier
469
470%type<decl> declaration declaration_list declaration_list_opt declaration_qualifier_list
471%type<decl> declaration_specifier declaration_specifier_nobody declarator declaring_list
472
473%type<decl> elaborated_type elaborated_type_nobody
474
475%type<decl> enumerator_list enum_type enum_type_nobody
476%type<init> enumerator_value_opt
477
478%type<decl> external_definition external_definition_list external_definition_list_opt
479
480%type<decl> exception_declaration
481
482%type<decl> field_declaration_list_opt field_declaration field_declaring_list_opt field_declarator field_abstract_list_opt field_abstract
483%type<expr> field field_name_list field_name fraction_constants_opt
484
485%type<decl> external_function_definition function_definition function_array function_declarator function_no_ptr function_ptr
486
487%type<decl> identifier_parameter_declarator identifier_parameter_ptr identifier_parameter_array identifier_parameter_function
488%type<decl> identifier_list
489
490%type<decl> cfa_abstract_array cfa_abstract_declarator_no_tuple cfa_abstract_declarator_tuple
491%type<decl> cfa_abstract_function cfa_abstract_parameter_declaration cfa_abstract_parameter_list
492%type<decl> cfa_abstract_ptr cfa_abstract_tuple
493
494%type<decl> cfa_array_parameter_1st_dimension
495
496%type<decl> cfa_trait_declaring_list cfa_declaration cfa_field_declaring_list cfa_field_abstract_list
497%type<decl> cfa_function_declaration cfa_function_return cfa_function_specifier
498
499%type<decl> cfa_identifier_parameter_array cfa_identifier_parameter_declarator_no_tuple
500%type<decl> cfa_identifier_parameter_declarator_tuple cfa_identifier_parameter_ptr
501
502%type<decl> cfa_parameter_declaration cfa_parameter_list cfa_parameter_ellipsis_list_opt
503
504%type<decl> cfa_typedef_declaration cfa_variable_declaration cfa_variable_specifier
505
506%type<decl> c_declaration static_assert
507%type<decl> KR_function_declarator KR_function_no_ptr KR_function_ptr KR_function_array
508%type<decl> KR_parameter_list KR_parameter_list_opt
509
510%type<decl> parameter_declaration parameter_list parameter_type_list_opt
511
512%type<decl> paren_identifier paren_type
513
514%type<decl> storage_class storage_class_list
515
516%type<decl> sue_declaration_specifier sue_declaration_specifier_nobody sue_type_specifier sue_type_specifier_nobody
517
518%type<tclass> type_class new_type_class
519%type<decl> type_declarator type_declarator_name type_declaring_list
520
521%type<decl> type_declaration_specifier type_type_specifier type_name typegen_name
522%type<decl> typedef_name typedef_declaration typedef_expression
523
524%type<decl> variable_type_redeclarator variable_type_ptr variable_type_array variable_type_function
525%type<decl> general_function_declarator function_type_redeclarator function_type_array function_type_no_ptr function_type_ptr
526
527%type<decl> type_parameter_redeclarator type_parameter_ptr type_parameter_array type_parameter_function
528
529%type<decl> type type_no_function
530%type<decl> type_parameter type_parameter_list type_initializer_opt
531
532%type<expr> type_parameters_opt type_list array_type_list
533
534%type<decl> type_qualifier type_qualifier_name forall type_qualifier_list_opt type_qualifier_list
535%type<decl> type_specifier type_specifier_nobody
536
537%type<decl> variable_declarator variable_ptr variable_array variable_function
538%type<decl> variable_abstract_declarator variable_abstract_ptr variable_abstract_array variable_abstract_function
539
540%type<decl> attribute_list_opt attribute_list attribute attribute_name_list attribute_name
541
542// initializers
543%type<init> initializer initializer_list_opt initializer_opt
544
545// designators
546%type<expr> designator designator_list designation
547
548
549// Handle shift/reduce conflict for dangling else by shifting the ELSE token. For example, this string is ambiguous:
550// .---------. matches IF '(' comma_expression ')' statement . (reduce)
551// if ( C ) S1 else S2
552// `-----------------' matches IF '(' comma_expression ')' statement . (shift) ELSE statement */
553// Similar issues exit with the waitfor statement.
554
555// Order of these lines matters (low-to-high precedence). THEN is left associative over WAND/WOR/TIMEOUT/ELSE, WAND/WOR
556// is left associative over TIMEOUT/ELSE, and TIMEOUT is left associative over ELSE.
557%precedence THEN // rule precedence for IF/WAITFOR statement
558%precedence ANDAND // token precedence for start of WAND in WAITFOR statement
559%precedence WAND // token precedence for start of WAND in WAITFOR statement
560%precedence OROR // token precedence for start of WOR in WAITFOR statement
561%precedence WOR // token precedence for start of WOR in WAITFOR statement
562%precedence TIMEOUT // token precedence for start of TIMEOUT in WAITFOR statement
563%precedence CATCH // token precedence for start of TIMEOUT in WAITFOR statement
564%precedence RECOVER // token precedence for start of TIMEOUT in WAITFOR statement
565%precedence CATCHRESUME // token precedence for start of TIMEOUT in WAITFOR statement
566%precedence FIXUP // token precedence for start of TIMEOUT in WAITFOR statement
567%precedence FINALLY // token precedence for start of TIMEOUT in WAITFOR statement
568%precedence ELSE // token precedence for start of else clause in IF/WAITFOR statement
569
570
571// Handle shift/reduce conflict for generic type by shifting the '(' token. For example, this string is ambiguous:
572// forall( otype T ) struct Foo { T v; };
573// .-----. matches pointer to function returning a generic (which is impossible without a type)
574// Foo ( *fp )( int );
575// `---' matches start of TYPEGENname '('
576// must be:
577// Foo( int ) ( *fp )( int );
578// The same problem occurs here:
579// forall( otype T ) struct Foo { T v; } ( *fp )( int );
580// must be:
581// forall( otype T ) struct Foo { T v; } ( int ) ( *fp )( int );
582
583// Order of these lines matters (low-to-high precedence).
584%precedence TYPEGENname
585%precedence '}'
586%precedence '('
587
588// %precedence RESUME
589// %precedence '{'
590// %precedence ')'
591
592%locations // support location tracking for error messages
593
594%start translation_unit // parse-tree root
595
596%%
597// ************************ Namespace Management ********************************
598
599// The C grammar is not context free because it relies on the distinct terminal symbols "identifier" and "TYPEDEFname",
600// which are lexically identical.
601//
602// typedef int foo; // identifier foo must now be scanned as TYPEDEFname
603// foo f; // to allow it to appear in this context
604//
605// While it may be possible to write a purely context-free grammar, such a grammar would obscure the relationship
606// between syntactic and semantic constructs. Cforall compounds this problem by introducing type names local to the
607// scope of a declaration (for instance, those introduced through "forall" qualifiers), and by introducing "type
608// generators" -- parameterized types. This latter type name creates a third class of identifiers, "TYPEGENname", which
609// must be distinguished by the lexical scanner.
610//
611// Since the scanner cannot distinguish among the different classes of identifiers without some context information,
612// there is a type table (typedefTable), which holds type names and identifiers that override type names, for each named
613// scope. During parsing, semantic actions update the type table by adding new identifiers in the current scope. For
614// each context that introduces a name scope, a new level is created in the type table and that level is popped on
615// exiting the scope. Since type names can be local to a particular declaration, each declaration is itself a scope.
616// This requires distinguishing between type names that are local to the current declaration scope and those that
617// persist past the end of the declaration (i.e., names defined in "typedef" or "otype" declarations).
618//
619// The non-terminals "push" and "pop" denote the opening and closing of named scopes. Every push has a matching pop in
620// the production rule. There are multiple lists of declarations, where each declaration is a named scope, so pop/push
621// around the list separator.
622//
623// XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
624// push pop push pop
625
626push:
627 { typedefTable.enterScope(); }
628 ;
629
630pop:
631 { typedefTable.leaveScope(); }
632 ;
633
634// ************************ CONSTANTS ********************************
635
636constant:
637 // ENUMERATIONconstant is not included here; it is treated as a variable with type "enumeration constant".
638 INTEGERconstant { $$ = new ExpressionNode( build_constantInteger( yylloc, *$1 ) ); }
639 | FLOATING_DECIMALconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
640 | FLOATING_FRACTIONconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
641 | FLOATINGconstant { $$ = new ExpressionNode( build_constantFloat( yylloc, *$1 ) ); }
642 | CHARACTERconstant { $$ = new ExpressionNode( build_constantChar( yylloc, *$1 ) ); }
643 ;
644
645quasi_keyword: // CFA
646 TIMEOUT
647 | WAND
648 | WOR
649 | CATCH
650 | RECOVER
651 | CATCHRESUME
652 | FIXUP
653 | FINALLY
654 ;
655
656identifier:
657 IDENTIFIER
658 | quasi_keyword
659 ;
660
661identifier_at:
662 identifier
663 | '@' // CFA
664 { Token tok = { new string( DeclarationNode::anonymous.newName() ), yylval.tok.loc }; $$ = tok; }
665 ;
666
667string_literal:
668 string_literal_list { $$ = new ExpressionNode( build_constantStr( yylloc, *$1 ) ); }
669 ;
670
671string_literal_list: // juxtaposed strings are concatenated
672 STRINGliteral { $$ = $1; } // conversion from tok to str
673 | string_literal_list STRINGliteral
674 {
675 if ( ! appendStr( *$1, *$2 ) ) YYERROR; // append 2nd juxtaposed string to 1st
676 delete $2; // allocated by lexer
677 $$ = $1; // conversion from tok to str
678 }
679 ;
680
681// ************************ EXPRESSIONS ********************************
682
683primary_expression:
684 IDENTIFIER // typedef name cannot be used as a variable name
685 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
686 | quasi_keyword
687 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
688 | TYPEDIMname // CFA, generic length argument
689 // { $$ = new ExpressionNode( new TypeExpr( maybeMoveBuildType( DeclarationNode::newFromTypedef( $1 ) ) ) ); }
690 // { $$ = new ExpressionNode( build_varref( $1 ) ); }
691 { $$ = new ExpressionNode( build_dimensionref( yylloc, $1 ) ); }
692 | tuple
693 | '(' comma_expression ')'
694 { $$ = $2; }
695 | '(' compound_statement ')' // GCC, lambda expression
696 { $$ = new ExpressionNode( new ast::StmtExpr( yylloc, dynamic_cast<ast::CompoundStmt *>( maybeMoveBuild( $2 ) ) ) ); }
697 | type_name '.' identifier // CFA, nested type
698 { $$ = new ExpressionNode( build_qualified_expr( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
699 | type_name '.' '[' field_name_list ']' // CFA, nested type / tuple field selector
700 { SemanticError( yylloc, "Qualified name is currently unimplemented." ); $$ = nullptr; }
701 | GENERIC '(' assignment_expression ',' generic_assoc_list ')' // C11
702 {
703 // add the missing control expression to the GenericExpr and return it
704 $5->control = maybeMoveBuild( $3 );
705 $$ = new ExpressionNode( $5 );
706 }
707 // | RESUME '(' comma_expression ')'
708 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
709 // | RESUME '(' comma_expression ')' compound_statement
710 // { SemanticError( yylloc, "Resume expression is currently unimplemented." ); $$ = nullptr; }
711 | IDENTIFIER IDENTIFIER // invalid syntax rule
712 { IdentifierBeforeIdentifier( *$1.str, *$2.str, "expression" ); $$ = nullptr; }
713 | IDENTIFIER type_qualifier // invalid syntax rule
714 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
715 | IDENTIFIER storage_class // invalid syntax rule
716 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
717 | IDENTIFIER basic_type_name // invalid syntax rule
718 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
719 | IDENTIFIER TYPEDEFname // invalid syntax rule
720 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
721 | IDENTIFIER TYPEGENname // invalid syntax rule
722 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
723 ;
724
725generic_assoc_list: // C11
726 generic_association
727 | generic_assoc_list ',' generic_association
728 {
729 // steal the association node from the singleton and delete the wrapper
730 assert( 1 == $3->associations.size() );
731 $1->associations.push_back( $3->associations.front() );
732 delete $3;
733 $$ = $1;
734 }
735 ;
736
737generic_association: // C11
738 type_no_function ':' assignment_expression
739 {
740 // create a GenericExpr wrapper with one association pair
741 $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuildType( $1 ), maybeMoveBuild( $3 ) } } );
742 }
743 | DEFAULT ':' assignment_expression
744 { $$ = new ast::GenericExpr( yylloc, nullptr, { { maybeMoveBuild( $3 ) } } ); }
745 ;
746
747postfix_expression:
748 primary_expression
749 | postfix_expression '[' assignment_expression ',' tuple_expression_list ']'
750 // Historic, transitional: Disallow commas in subscripts.
751 // Switching to this behaviour may help check if a C compatibilty case uses comma-exprs in subscripts.
752 // Current: Commas in subscripts make tuples.
753 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $5 ) ) )) ) ); }
754 | postfix_expression '[' assignment_expression ']'
755 // CFA, comma_expression disallowed in this context because it results in a common user error: subscripting a
756 // matrix with x[i,j] instead of x[i][j]. While this change is not backwards compatible, there seems to be
757 // little advantage to this feature and many disadvantages. It is possible to write x[(i,j)] in CFA, which is
758 // equivalent to the old x[i,j].
759 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
760 | constant '[' assignment_expression ']' // 3[a], 'a'[a], 3.5[a]
761 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
762 | string_literal '[' assignment_expression ']' // "abc"[3], 3["abc"]
763 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Index, $1, $3 ) ); }
764 | postfix_expression '{' argument_expression_list_opt '}' // CFA, constructor call
765 {
766 Token fn;
767 fn.str = new std::string( "?{}" ); // location undefined - use location of '{'?
768 $$ = new ExpressionNode( new ast::ConstructorExpr( yylloc, build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $1 )->set_last( $3 ) ) ) );
769 }
770 | postfix_expression '(' argument_expression_list_opt ')'
771 { $$ = new ExpressionNode( build_func( yylloc, $1, $3 ) ); }
772 | VA_ARG '(' primary_expression ',' declaration_specifier_nobody abstract_parameter_declarator_opt ')'
773 // { SemanticError( yylloc, "va_arg is currently unimplemented." ); $$ = nullptr; }
774 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, new string( "__builtin_va_arg") ) ),
775 (ExpressionNode *)($3->set_last( (ExpressionNode *)($6 ? $6->addType( $5 ) : $5) )) ) ); }
776 | postfix_expression '`' identifier // CFA, postfix call
777 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
778 | constant '`' identifier // CFA, postfix call
779 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
780 | string_literal '`' identifier // CFA, postfix call
781 { $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, build_postfix_name( $3 ) ) ), $1 ) ); }
782
783 // SKULLDUGGERY: The typedef table used for parsing does not store fields in structures. To parse a qualified
784 // name, it is assumed all name-tokens after the first are identifiers, regardless of how the lexer identifies
785 // them. For example:
786 //
787 // struct S;
788 // forall(T) struct T;
789 // union U;
790 // enum E { S, T, E };
791 // struct Z { int S, T, Z, E, U; };
792 // void fred () {
793 // Z z;
794 // z.S; // lexer returns S is TYPEDEFname
795 // z.T; // lexer returns T is TYPEGENname
796 // z.Z; // lexer returns Z is TYPEDEFname
797 // z.U; // lexer returns U is TYPEDEFname
798 // z.E; // lexer returns E is TYPEDEFname
799 // }
800 | postfix_expression '.' identifier
801 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
802 | postfix_expression '.' TYPEDEFname // CFA, SKULLDUGGERY
803 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
804 | postfix_expression '.' TYPEGENname // CFA, SKULLDUGGERY
805 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
806
807 | postfix_expression '.' INTEGERconstant // CFA, tuple index
808 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
809 | postfix_expression FLOATING_FRACTIONconstant // CFA, tuple index
810 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 ) ) ); }
811 | postfix_expression '.' '[' field_name_list ']' // CFA, tuple field selector
812 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
813 | postfix_expression '.' aggregate_control
814 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $3, $1 ) ); }
815 | postfix_expression ARROW identifier
816 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_varref( yylloc, $3 ) ) ); }
817 | postfix_expression ARROW INTEGERconstant // CFA, tuple index
818 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_constantInteger( yylloc, *$3 ) ) ); }
819 | postfix_expression ARROW '[' field_name_list ']' // CFA, tuple field selector
820 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
821 | postfix_expression ICR
822 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::IncrPost, $1 ) ); }
823 | postfix_expression DECR
824 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::DecrPost, $1 ) ); }
825 | '(' type_no_function ')' '{' initializer_list_opt comma_opt '}' // C99, compound-literal
826 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, new InitializerNode( $5, true ) ) ); }
827 | '(' type_no_function ')' '@' '{' initializer_list_opt comma_opt '}' // CFA, explicit C compound-literal
828 { $$ = new ExpressionNode( build_compoundLiteral( yylloc, $2, (new InitializerNode( $6, true ))->set_maybeConstructed( false ) ) ); }
829 | '^' primary_expression '{' argument_expression_list_opt '}' // CFA, destructor call
830 {
831 Token fn;
832 fn.str = new string( "^?{}" ); // location undefined
833 $$ = new ExpressionNode( build_func( yylloc, new ExpressionNode( build_varref( yylloc, fn ) ), (ExpressionNode *)( $2 )->set_last( $4 ) ) );
834 }
835 ;
836
837argument_expression_list_opt:
838 // empty
839 { $$ = nullptr; }
840 | argument_expression_list
841 ;
842
843argument_expression_list:
844 argument_expression
845 | argument_expression_list_opt ',' argument_expression
846 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
847 ;
848
849argument_expression:
850 '@' // CFA, default parameter
851 { SemanticError( yylloc, "Default parameter for argument is currently unimplemented." ); $$ = nullptr; }
852 // { $$ = new ExpressionNode( build_constantInteger( *new string( "2" ) ) ); }
853 | assignment_expression
854 ;
855
856field_name_list: // CFA, tuple field selector
857 field
858 | field_name_list ',' field { $$ = (ExpressionNode *)($1->set_last( $3 )); }
859 ;
860
861field: // CFA, tuple field selector
862 field_name
863 | FLOATING_DECIMALconstant field
864 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), maybeMoveBuild( $2 ) ) ); }
865 | FLOATING_DECIMALconstant '[' field_name_list ']'
866 { $$ = new ExpressionNode( build_fieldSel( yylloc, new ExpressionNode( build_field_name_FLOATING_DECIMALconstant( yylloc, *$1 ) ), build_tuple( yylloc, $3 ) ) ); }
867 | field_name '.' field
868 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
869 | field_name '.' '[' field_name_list ']'
870 { $$ = new ExpressionNode( build_fieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
871 | field_name ARROW field
872 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, maybeMoveBuild( $3 ) ) ); }
873 | field_name ARROW '[' field_name_list ']'
874 { $$ = new ExpressionNode( build_pfieldSel( yylloc, $1, build_tuple( yylloc, $4 ) ) ); }
875 ;
876
877field_name:
878 INTEGERconstant fraction_constants_opt
879 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_constantInteger( yylloc, *$1 ), $2 ) ); }
880 | FLOATINGconstant fraction_constants_opt
881 { $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_field_name_FLOATINGconstant( yylloc, *$1 ), $2 ) ); }
882 | identifier_at fraction_constants_opt // CFA, allow anonymous fields
883 {
884 $$ = new ExpressionNode( build_field_name_fraction_constants( yylloc, build_varref( yylloc, $1 ), $2 ) );
885 }
886 ;
887
888fraction_constants_opt:
889 // empty
890 { $$ = nullptr; }
891 | fraction_constants_opt FLOATING_FRACTIONconstant
892 {
893 ast::Expr * constant = build_field_name_FLOATING_FRACTIONconstant( yylloc, *$2 );
894 $$ = $1 != nullptr ? new ExpressionNode( build_fieldSel( yylloc, $1, constant ) ) : new ExpressionNode( constant );
895 }
896 ;
897
898unary_expression:
899 postfix_expression
900 // first location where constant/string can have operator applied: sizeof 3/sizeof "abc" still requires
901 // semantics checks, e.g., ++3, 3--, *3, &&3
902 | constant
903 | string_literal
904 { $$ = $1; }
905 | EXTENSION cast_expression // GCC
906 { $$ = $2->set_extension( true ); }
907 // '*' ('&') is separated from unary_operator because of shift/reduce conflict in:
908 // { * X; } // dereference X
909 // { * int X; } // CFA declaration of pointer to int
910 | ptrref_operator cast_expression // CFA
911 {
912 switch ( $1 ) {
913 case OperKinds::AddressOf:
914 $$ = new ExpressionNode( new ast::AddressExpr( maybeMoveBuild( $2 ) ) );
915 break;
916 case OperKinds::PointTo:
917 $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) );
918 break;
919 case OperKinds::And:
920 $$ = new ExpressionNode( new ast::AddressExpr( new ast::AddressExpr( maybeMoveBuild( $2 ) ) ) );
921 break;
922 default:
923 assert( false );
924 }
925 }
926 | unary_operator cast_expression
927 { $$ = new ExpressionNode( build_unary_val( yylloc, $1, $2 ) ); }
928 | ICR unary_expression
929 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Incr, $2 ) ); }
930 | DECR unary_expression
931 { $$ = new ExpressionNode( build_unary_val( yylloc, OperKinds::Decr, $2 ) ); }
932 | SIZEOF unary_expression
933 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
934 | SIZEOF '(' type_no_function ')'
935 { $$ = new ExpressionNode( new ast::SizeofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
936 | ALIGNOF unary_expression // GCC, variable alignment
937 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuild( $2 ) ) ); }
938 | ALIGNOF '(' type_no_function ')' // GCC, type alignment
939 { $$ = new ExpressionNode( new ast::AlignofExpr( yylloc, maybeMoveBuildType( $3 ) ) ); }
940 | OFFSETOF '(' type_no_function ',' identifier ')'
941 { $$ = new ExpressionNode( build_offsetOf( yylloc, $3, build_varref( yylloc, $5 ) ) ); }
942 | TYPEID '(' type_no_function ')'
943 {
944 SemanticError( yylloc, "typeid name is currently unimplemented." ); $$ = nullptr;
945 // $$ = new ExpressionNode( build_offsetOf( $3, build_varref( $5 ) ) );
946 }
947 ;
948
949ptrref_operator:
950 '*' { $$ = OperKinds::PointTo; }
951 | '&' { $$ = OperKinds::AddressOf; }
952 // GCC, address of label must be handled by semantic check for ref,ref,label
953 | ANDAND { $$ = OperKinds::And; }
954 ;
955
956unary_operator:
957 '+' { $$ = OperKinds::UnPlus; }
958 | '-' { $$ = OperKinds::UnMinus; }
959 | '!' { $$ = OperKinds::Neg; }
960 | '~' { $$ = OperKinds::BitNeg; }
961 ;
962
963cast_expression:
964 unary_expression
965 | '(' type_no_function ')' cast_expression
966 { $$ = new ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
967 | '(' aggregate_control '&' ')' cast_expression // CFA
968 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
969 | '(' aggregate_control '*' ')' cast_expression // CFA
970 { $$ = new ExpressionNode( build_keyword_cast( yylloc, $2, $5 ) ); }
971 | '(' VIRTUAL ')' cast_expression // CFA
972 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $4 ), maybeMoveBuildType( nullptr ) ) ); }
973 | '(' VIRTUAL type_no_function ')' cast_expression // CFA
974 { $$ = new ExpressionNode( new ast::VirtualCastExpr( yylloc, maybeMoveBuild( $5 ), maybeMoveBuildType( $3 ) ) ); }
975 | '(' RETURN type_no_function ')' cast_expression // CFA
976 { $$ = new ExpressionNode( build_cast( yylloc, $3, $5, ast::CastExpr::Return ) ); }
977 | '(' COERCE type_no_function ')' cast_expression // CFA
978 { SemanticError( yylloc, "Coerce cast is currently unimplemented." ); $$ = nullptr; }
979 | '(' qualifier_cast_list ')' cast_expression // CFA
980 { SemanticError( yylloc, "Qualifier cast is currently unimplemented." ); $$ = nullptr; }
981// | '(' type_no_function ')' tuple
982// { $$ = new ast::ExpressionNode( build_cast( yylloc, $2, $4 ) ); }
983 ;
984
985qualifier_cast_list:
986 cast_modifier type_qualifier_name
987 | cast_modifier MUTEX
988 | qualifier_cast_list cast_modifier type_qualifier_name
989 | qualifier_cast_list cast_modifier MUTEX
990 ;
991
992cast_modifier:
993 '-'
994 | '+'
995 ;
996
997exponential_expression:
998 cast_expression
999 | exponential_expression '\\' cast_expression
1000 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Exp, $1, $3 ) ); }
1001 ;
1002
1003multiplicative_expression:
1004 exponential_expression
1005 | multiplicative_expression '*' exponential_expression
1006 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mul, $1, $3 ) ); }
1007 | multiplicative_expression '/' exponential_expression
1008 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Div, $1, $3 ) ); }
1009 | multiplicative_expression '%' exponential_expression
1010 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Mod, $1, $3 ) ); }
1011 ;
1012
1013additive_expression:
1014 multiplicative_expression
1015 | additive_expression '+' multiplicative_expression
1016 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Plus, $1, $3 ) ); }
1017 | additive_expression '-' multiplicative_expression
1018 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Minus, $1, $3 ) ); }
1019 ;
1020
1021shift_expression:
1022 additive_expression
1023 | shift_expression LS additive_expression
1024 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LShift, $1, $3 ) ); }
1025 | shift_expression RS additive_expression
1026 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::RShift, $1, $3 ) ); }
1027 ;
1028
1029relational_expression:
1030 shift_expression
1031 | relational_expression '<' shift_expression
1032 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LThan, $1, $3 ) ); }
1033 | relational_expression '>' shift_expression
1034 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GThan, $1, $3 ) ); }
1035 | relational_expression LE shift_expression
1036 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::LEThan, $1, $3 ) ); }
1037 | relational_expression GE shift_expression
1038 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::GEThan, $1, $3 ) ); }
1039 ;
1040
1041equality_expression:
1042 relational_expression
1043 | equality_expression EQ relational_expression
1044 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Eq, $1, $3 ) ); }
1045 | equality_expression NE relational_expression
1046 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Neq, $1, $3 ) ); }
1047 ;
1048
1049AND_expression:
1050 equality_expression
1051 | AND_expression '&' equality_expression
1052 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitAnd, $1, $3 ) ); }
1053 ;
1054
1055exclusive_OR_expression:
1056 AND_expression
1057 | exclusive_OR_expression '^' AND_expression
1058 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::Xor, $1, $3 ) ); }
1059 ;
1060
1061inclusive_OR_expression:
1062 exclusive_OR_expression
1063 | inclusive_OR_expression '|' exclusive_OR_expression
1064 { $$ = new ExpressionNode( build_binary_val( yylloc, OperKinds::BitOr, $1, $3 ) ); }
1065 ;
1066
1067logical_AND_expression:
1068 inclusive_OR_expression
1069 | logical_AND_expression ANDAND inclusive_OR_expression
1070 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::AndExpr ) ); }
1071 ;
1072
1073logical_OR_expression:
1074 logical_AND_expression
1075 | logical_OR_expression OROR logical_AND_expression
1076 { $$ = new ExpressionNode( build_and_or( yylloc, $1, $3, ast::OrExpr ) ); }
1077 ;
1078
1079conditional_expression:
1080 logical_OR_expression
1081 | logical_OR_expression '?' comma_expression ':' conditional_expression
1082 { $$ = new ExpressionNode( build_cond( yylloc, $1, $3, $5 ) ); }
1083 // FIX ME: computes $1 twice
1084 | logical_OR_expression '?' /* empty */ ':' conditional_expression // GCC, omitted first operand
1085 { $$ = new ExpressionNode( build_cond( yylloc, $1, $1->clone(), $4 ) ); }
1086 ;
1087
1088constant_expression:
1089 conditional_expression
1090 ;
1091
1092assignment_expression:
1093 // CFA, assignment is separated from assignment_operator to ensure no assignment operations for tuples
1094 conditional_expression
1095 | unary_expression assignment_operator assignment_expression
1096 {
1097// if ( $2 == OperKinds::AtAssn ) {
1098// SemanticError( yylloc, "C @= assignment is currently unimplemented." ); $$ = nullptr;
1099// } else {
1100 $$ = new ExpressionNode( build_binary_val( yylloc, $2, $1, $3 ) );
1101// } // if
1102 }
1103 | unary_expression '=' '{' initializer_list_opt comma_opt '}'
1104 { SemanticError( yylloc, "Initializer assignment is currently unimplemented." ); $$ = nullptr; }
1105 ;
1106
1107assignment_expression_opt:
1108 // empty
1109 { $$ = nullptr; }
1110 | assignment_expression
1111 ;
1112
1113assignment_operator:
1114 simple_assignment_operator
1115 | compound_assignment_operator
1116 ;
1117
1118simple_assignment_operator:
1119 '=' { $$ = OperKinds::Assign; }
1120 | ATassign { $$ = OperKinds::AtAssn; } // CFA
1121 ;
1122
1123compound_assignment_operator:
1124 EXPassign { $$ = OperKinds::ExpAssn; }
1125 | MULTassign { $$ = OperKinds::MulAssn; }
1126 | DIVassign { $$ = OperKinds::DivAssn; }
1127 | MODassign { $$ = OperKinds::ModAssn; }
1128 | PLUSassign { $$ = OperKinds::PlusAssn; }
1129 | MINUSassign { $$ = OperKinds::MinusAssn; }
1130 | LSassign { $$ = OperKinds::LSAssn; }
1131 | RSassign { $$ = OperKinds::RSAssn; }
1132 | ANDassign { $$ = OperKinds::AndAssn; }
1133 | ERassign { $$ = OperKinds::ERAssn; }
1134 | ORassign { $$ = OperKinds::OrAssn; }
1135 ;
1136
1137tuple: // CFA, tuple
1138 // CFA, one assignment_expression is factored out of comma_expression to eliminate a shift/reduce conflict with
1139 // comma_expression in cfa_identifier_parameter_array and cfa_abstract_array
1140// '[' ']'
1141// { $$ = new ExpressionNode( build_tuple() ); }
1142// | '[' push assignment_expression pop ']'
1143// { $$ = new ExpressionNode( build_tuple( $3 ) ); }
1144 '[' ',' tuple_expression_list ']'
1145 { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)(new ExpressionNode( nullptr ) )->set_last( $3 ) ) ); }
1146 | '[' push assignment_expression pop ',' tuple_expression_list ']'
1147 { $$ = new ExpressionNode( build_tuple( yylloc, (ExpressionNode *)($3->set_last( $6 ) ) )); }
1148 ;
1149
1150tuple_expression_list:
1151 assignment_expression
1152 | '@' // CFA
1153 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1154 | tuple_expression_list ',' assignment_expression
1155 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1156 | tuple_expression_list ',' '@'
1157 { SemanticError( yylloc, "Eliding tuple element with '@' is currently unimplemented." ); $$ = nullptr; }
1158 ;
1159
1160comma_expression:
1161 assignment_expression
1162 | comma_expression ',' assignment_expression
1163 { $$ = new ExpressionNode( new ast::CommaExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1164 ;
1165
1166comma_expression_opt:
1167 // empty
1168 { $$ = nullptr; }
1169 | comma_expression
1170 ;
1171
1172// ************************** STATEMENTS *******************************
1173
1174statement:
1175 labeled_statement
1176 | compound_statement
1177 | expression_statement
1178 | selection_statement
1179 | iteration_statement
1180 | jump_statement
1181 | with_statement
1182 | mutex_statement
1183 | waitfor_statement
1184 | waituntil_statement
1185 | corun_statement
1186 | cofor_statement
1187 | exception_statement
1188 | enable_disable_statement
1189 { SemanticError( yylloc, "enable/disable statement is currently unimplemented." ); $$ = nullptr; }
1190 | asm_statement
1191 | DIRECTIVE
1192 { $$ = new StatementNode( build_directive( yylloc, $1 ) ); }
1193 ;
1194
1195labeled_statement:
1196 // labels cannot be identifiers 0 or 1
1197 identifier_or_type_name ':' attribute_list_opt statement
1198 { $$ = $4->add_label( yylloc, $1, $3 ); }
1199 | identifier_or_type_name ':' attribute_list_opt error // invalid syntax rule
1200 {
1201 SemanticError( yylloc, "syntx error, label \"%s\" must be associated with a statement, "
1202 "where a declaration, case, or default is not a statement.\n"
1203 "Move the label or terminate with a semicolon.", $1.str->c_str() );
1204 $$ = nullptr;
1205 }
1206 ;
1207
1208compound_statement:
1209 '{' '}'
1210 { $$ = new StatementNode( build_compound( yylloc, (StatementNode *)0 ) ); }
1211 | '{' push
1212 local_label_declaration_opt // GCC, local labels appear at start of block
1213 statement_decl_list // C99, intermix declarations and statements
1214 pop '}'
1215 { $$ = new StatementNode( build_compound( yylloc, $4 ) ); }
1216 ;
1217
1218statement_decl_list: // C99
1219 statement_decl
1220 | statement_decl_list statement_decl
1221 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1222 ;
1223
1224statement_decl:
1225 declaration // CFA, new & old style declarations
1226 { $$ = new StatementNode( $1 ); }
1227 | EXTENSION declaration // GCC
1228 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1229 | function_definition
1230 { $$ = new StatementNode( $1 ); }
1231 | EXTENSION function_definition // GCC
1232 { distExt( $2 ); $$ = new StatementNode( $2 ); }
1233 | statement
1234 ;
1235
1236statement_list_nodecl:
1237 statement
1238 | statement_list_nodecl statement
1239 { assert( $1 ); $1->set_last( $2 ); $$ = $1; }
1240 | statement_list_nodecl error // invalid syntax rule
1241 { SemanticError( yylloc, "syntax error, declarations only allowed at the start of the switch body, i.e., after the '{'." ); $$ = nullptr; }
1242 ;
1243
1244expression_statement:
1245 comma_expression_opt ';'
1246 { $$ = new StatementNode( build_expr( yylloc, $1 ) ); }
1247 ;
1248
1249selection_statement:
1250 // pop causes a S/R conflict without separating the IF statement into a non-terminal even after resolving
1251 // the inherent S/R conflict with THEN/ELSE.
1252 push if_statement pop
1253 { $$ = $2; }
1254 | SWITCH '(' comma_expression ')' case_clause
1255 { $$ = new StatementNode( build_switch( yylloc, true, $3, $5 ) ); }
1256 | SWITCH '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1257 {
1258 StatementNode *sw = new StatementNode( build_switch( yylloc, true, $3, $8 ) );
1259 // The semantics of the declaration list is changed to include associated initialization, which is performed
1260 // *before* the transfer to the appropriate case clause by hoisting the declarations into a compound
1261 // statement around the switch. Statements after the initial declaration list can never be executed, and
1262 // therefore, are removed from the grammar even though C allows it. The change also applies to choose
1263 // statement.
1264 $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1265 }
1266 | SWITCH '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule error
1267 { SemanticError( yylloc, "synatx error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1268 | CHOOSE '(' comma_expression ')' case_clause // CFA
1269 { $$ = new StatementNode( build_switch( yylloc, false, $3, $5 ) ); }
1270 | CHOOSE '(' comma_expression ')' '{' push declaration_list_opt switch_clause_list_opt pop '}' // CFA
1271 {
1272 StatementNode *sw = new StatementNode( build_switch( yylloc, false, $3, $8 ) );
1273 $$ = $7 ? new StatementNode( build_compound( yylloc, (StatementNode *)((new StatementNode( $7 ))->set_last( sw )) ) ) : sw;
1274 }
1275 | CHOOSE '(' comma_expression ')' '{' error '}' // CFA, invalid syntax rule
1276 { SemanticError( yylloc, "syntax error, declarations can only appear before the list of case clauses." ); $$ = nullptr; }
1277 ;
1278
1279if_statement:
1280 IF '(' conditional_declaration ')' statement %prec THEN
1281 // explicitly deal with the shift/reduce conflict on if/else
1282 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), nullptr ) ); }
1283 | IF '(' conditional_declaration ')' statement ELSE statement
1284 { $$ = new StatementNode( build_if( yylloc, $3, maybe_build_compound( yylloc, $5 ), maybe_build_compound( yylloc, $7 ) ) ); }
1285 ;
1286
1287conditional_declaration:
1288 comma_expression
1289 { $$ = new CondCtl( nullptr, $1 ); }
1290 | c_declaration // no semi-colon
1291 { $$ = new CondCtl( $1, nullptr ); }
1292 | cfa_declaration // no semi-colon
1293 { $$ = new CondCtl( $1, nullptr ); }
1294 | declaration comma_expression // semi-colon separated
1295 { $$ = new CondCtl( $1, $2 ); }
1296 ;
1297
1298// CASE and DEFAULT clauses are only allowed in the SWITCH statement, precluding Duff's device. In addition, a case
1299// clause allows a list of values and subranges.
1300
1301case_value: // CFA
1302 constant_expression { $$ = $1; }
1303 | constant_expression ELLIPSIS constant_expression // GCC, subrange
1304 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1305 | subrange // CFA, subrange
1306 ;
1307
1308case_value_list: // CFA
1309 case_value { $$ = new ClauseNode( build_case( yylloc, $1 ) ); }
1310 // convert case list, e.g., "case 1, 3, 5:" into "case 1: case 3: case 5"
1311 | case_value_list ',' case_value { $$ = $1->set_last( new ClauseNode( build_case( yylloc, $3 ) ) ); }
1312 ;
1313
1314case_label: // CFA
1315 CASE error // invalid syntax rule
1316 { SemanticError( yylloc, "syntax error, case list missing after case." ); $$ = nullptr; }
1317 | CASE case_value_list ':' { $$ = $2; }
1318 | CASE case_value_list error // invalid syntax rule
1319 { SemanticError( yylloc, "syntax error, colon missing after case list." ); $$ = nullptr; }
1320 | DEFAULT ':' { $$ = new ClauseNode( build_default( yylloc ) ); }
1321 // A semantic check is required to ensure only one default clause per switch/choose statement.
1322 | DEFAULT error // invalid syntax rule
1323 { SemanticError( yylloc, "syntax error, colon missing after default." ); $$ = nullptr; }
1324 ;
1325
1326case_label_list: // CFA
1327 case_label
1328 | case_label_list case_label { $$ = $1->set_last( $2 ); }
1329 ;
1330
1331case_clause: // CFA
1332 case_label_list statement { $$ = $1->append_last_case( maybe_build_compound( yylloc, $2 ) ); }
1333 ;
1334
1335switch_clause_list_opt: // CFA
1336 // empty
1337 { $$ = nullptr; }
1338 | switch_clause_list
1339 ;
1340
1341switch_clause_list: // CFA
1342 case_label_list statement_list_nodecl
1343 { $$ = $1->append_last_case( new StatementNode( build_compound( yylloc, $2 ) ) ); }
1344 | switch_clause_list case_label_list statement_list_nodecl
1345 { $$ = $1->set_last( $2->append_last_case( new StatementNode( build_compound( yylloc, $3 ) ) ) ); }
1346 ;
1347
1348iteration_statement:
1349 WHILE '(' ')' statement %prec THEN // CFA => while ( 1 )
1350 { $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) ); }
1351 | WHILE '(' ')' statement ELSE statement // CFA
1352 {
1353 $$ = new StatementNode( build_while( yylloc, new CondCtl( nullptr, NEW_ONE ), maybe_build_compound( yylloc, $4 ) ) );
1354 SemanticWarning( yylloc, Warning::SuperfluousElse );
1355 }
1356 | WHILE '(' conditional_declaration ')' statement %prec THEN
1357 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1358 | WHILE '(' conditional_declaration ')' statement ELSE statement // CFA
1359 { $$ = new StatementNode( build_while( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1360 | DO statement WHILE '(' ')' ';' // CFA => do while( 1 )
1361 { $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) ); }
1362 | DO statement WHILE '(' ')' ELSE statement // CFA
1363 {
1364 $$ = new StatementNode( build_do_while( yylloc, NEW_ONE, maybe_build_compound( yylloc, $2 ) ) );
1365 SemanticWarning( yylloc, Warning::SuperfluousElse );
1366 }
1367 | DO statement WHILE '(' comma_expression ')' ';'
1368 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ) ) ); }
1369 | DO statement WHILE '(' comma_expression ')' ELSE statement // CFA
1370 { $$ = new StatementNode( build_do_while( yylloc, $5, maybe_build_compound( yylloc, $2 ), $8 ) ); }
1371 | FOR '(' ')' statement %prec THEN // CFA => for ( ;; )
1372 { $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) ); }
1373 | FOR '(' ')' statement ELSE statement // CFA
1374 {
1375 $$ = new StatementNode( build_for( yylloc, new ForCtrl( nullptr, nullptr, nullptr ), maybe_build_compound( yylloc, $4 ) ) );
1376 SemanticWarning( yylloc, Warning::SuperfluousElse );
1377 }
1378 | FOR '(' for_control_expression_list ')' statement %prec THEN
1379 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1380 | FOR '(' for_control_expression_list ')' statement ELSE statement // CFA
1381 { $$ = new StatementNode( build_for( yylloc, $3, maybe_build_compound( yylloc, $5 ), $7 ) ); }
1382 ;
1383
1384for_control_expression_list:
1385 for_control_expression
1386 | for_control_expression_list ':' for_control_expression
1387 // ForCtrl + ForCtrl:
1388 // init + init => multiple declaration statements that are hoisted
1389 // condition + condition => (expression) && (expression)
1390 // change + change => (expression), (expression)
1391 {
1392 $1->init->set_last( $3->init );
1393 if ( $1->condition ) {
1394 if ( $3->condition ) {
1395 $1->condition->expr.reset( new ast::LogicalExpr( yylloc, $1->condition->expr.release(), $3->condition->expr.release(), ast::AndExpr ) );
1396 } // if
1397 } else $1->condition = $3->condition;
1398 if ( $1->change ) {
1399 if ( $3->change ) {
1400 $1->change->expr.reset( new ast::CommaExpr( yylloc, $1->change->expr.release(), $3->change->expr.release() ) );
1401 } // if
1402 } else $1->change = $3->change;
1403 $$ = $1;
1404 }
1405 ;
1406
1407for_control_expression:
1408 ';' comma_expression_opt ';' comma_expression_opt
1409 { $$ = new ForCtrl( nullptr, $2, $4 ); }
1410 | comma_expression ';' comma_expression_opt ';' comma_expression_opt
1411 {
1412 StatementNode * init = $1 ? new StatementNode( new ast::ExprStmt( yylloc, maybeMoveBuild( $1 ) ) ) : nullptr;
1413 $$ = new ForCtrl( init, $3, $5 );
1414 }
1415 | declaration comma_expression_opt ';' comma_expression_opt // C99, declaration has ';'
1416 { $$ = new ForCtrl( new StatementNode( $1 ), $2, $4 ); }
1417
1418 | '@' ';' comma_expression // CFA, empty loop-index
1419 { $$ = new ForCtrl( nullptr, $3, nullptr ); }
1420 | '@' ';' comma_expression ';' comma_expression // CFA, empty loop-index
1421 { $$ = new ForCtrl( nullptr, $3, $5 ); }
1422
1423 | comma_expression // CFA, anonymous loop-index
1424 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), NEW_ZERO, OperKinds::LThan, $1->clone(), NEW_ONE ); }
1425 | downupdowneq comma_expression // CFA, anonymous loop-index
1426 { $$ = forCtrl( yylloc, $2, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $1, NEW_ZERO, $2->clone() ), $1, UPDOWN( $1, $2->clone(), NEW_ZERO ), NEW_ONE ); }
1427
1428 | comma_expression updowneq comma_expression // CFA, anonymous loop-index
1429 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), NEW_ONE ); }
1430 | '@' updowneq comma_expression // CFA, anonymous loop-index
1431 {
1432 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1433 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, NEW_ONE );
1434 }
1435 | comma_expression updowneq '@' // CFA, anonymous loop-index
1436 {
1437 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1438 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1439 }
1440 | comma_expression updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1441 { $$ = forCtrl( yylloc, $1, new string( DeclarationNode::anonymous.newName() ), UPDOWN( $2, $1->clone(), $3 ), $2, UPDOWN( $2, $3->clone(), $1->clone() ), $5 ); }
1442 | '@' updowneq comma_expression '~' comma_expression // CFA, anonymous loop-index
1443 {
1444 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1445 else $$ = forCtrl( yylloc, $3, new string( DeclarationNode::anonymous.newName() ), $3->clone(), $2, nullptr, $5 );
1446 }
1447 | comma_expression updowneq '@' '~' comma_expression // CFA, anonymous loop-index
1448 {
1449 if ( $2 == OperKinds::LThan || $2 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1450 else { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1451 }
1452 | comma_expression updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1453 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1454 | '@' updowneq '@' // CFA, invalid syntax rule
1455 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1456 | '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1457 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1458 | comma_expression updowneq '@' '~' '@' // CFA, invalid syntax rule
1459 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1460 | '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1461 { SemanticError( yylloc, MISSING_ANON_FIELD ); $$ = nullptr; }
1462
1463 | comma_expression ';' comma_expression // CFA
1464 { $$ = forCtrl( yylloc, $3, $1, NEW_ZERO, OperKinds::LThan, $3->clone(), NEW_ONE ); }
1465 | comma_expression ';' downupdowneq comma_expression // CFA
1466 { $$ = forCtrl( yylloc, $4, $1, UPDOWN( $3, NEW_ZERO, $4->clone() ), $3, UPDOWN( $3, $4->clone(), NEW_ZERO ), NEW_ONE ); }
1467
1468 | comma_expression ';' comma_expression updowneq comma_expression // CFA
1469 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), NEW_ONE ); }
1470 | comma_expression ';' '@' updowneq comma_expression // CFA
1471 {
1472 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1473 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, NEW_ONE );
1474 }
1475 | comma_expression ';' comma_expression updowneq '@' // CFA
1476 {
1477 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1478 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1479 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, NEW_ONE );
1480 }
1481 | comma_expression ';' '@' updowneq '@' // CFA, invalid syntax rule
1482 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1483
1484 | comma_expression ';' comma_expression updowneq comma_expression '~' comma_expression // CFA
1485 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), $7 ); }
1486 | comma_expression ';' '@' updowneq comma_expression '~' comma_expression // CFA, invalid syntax rule
1487 {
1488 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1489 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, $7 );
1490 }
1491 | comma_expression ';' comma_expression updowneq '@' '~' comma_expression // CFA
1492 {
1493 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1494 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1495 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, $7 );
1496 }
1497 | comma_expression ';' comma_expression updowneq comma_expression '~' '@' // CFA
1498 { $$ = forCtrl( yylloc, $3, $1, UPDOWN( $4, $3->clone(), $5 ), $4, UPDOWN( $4, $5->clone(), $3->clone() ), nullptr ); }
1499 | comma_expression ';' '@' updowneq comma_expression '~' '@' // CFA, invalid syntax rule
1500 {
1501 if ( $4 == OperKinds::LThan || $4 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1502 else $$ = forCtrl( yylloc, $5, $1, $5->clone(), $4, nullptr, nullptr );
1503 }
1504 | comma_expression ';' comma_expression updowneq '@' '~' '@' // CFA
1505 {
1506 if ( $4 == OperKinds::GThan || $4 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1507 else if ( $4 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1508 else $$ = forCtrl( yylloc, $3, $1, $3->clone(), $4, nullptr, nullptr );
1509 }
1510 | comma_expression ';' '@' updowneq '@' '~' '@' // CFA
1511 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1512
1513 | declaration comma_expression // CFA
1514 { $$ = forCtrl( yylloc, $1, NEW_ZERO, OperKinds::LThan, $2, NEW_ONE ); }
1515 | declaration downupdowneq comma_expression // CFA
1516 { $$ = forCtrl( yylloc, $1, UPDOWN( $2, NEW_ZERO, $3 ), $2, UPDOWN( $2, $3->clone(), NEW_ZERO ), NEW_ONE ); }
1517
1518 | declaration comma_expression updowneq comma_expression // CFA
1519 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2->clone(), $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), NEW_ONE ); }
1520 | declaration '@' updowneq comma_expression // CFA
1521 {
1522 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1523 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, NEW_ONE );
1524 }
1525 | declaration comma_expression updowneq '@' // CFA
1526 {
1527 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1528 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1529 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, NEW_ONE );
1530 }
1531
1532 | declaration comma_expression updowneq comma_expression '~' comma_expression // CFA
1533 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), $6 ); }
1534 | declaration '@' updowneq comma_expression '~' comma_expression // CFA
1535 {
1536 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1537 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, $6 );
1538 }
1539 | declaration comma_expression updowneq '@' '~' comma_expression // CFA
1540 {
1541 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1542 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1543 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, $6 );
1544 }
1545 | declaration comma_expression updowneq comma_expression '~' '@' // CFA
1546 { $$ = forCtrl( yylloc, $1, UPDOWN( $3, $2, $4 ), $3, UPDOWN( $3, $4->clone(), $2->clone() ), nullptr ); }
1547 | declaration '@' updowneq comma_expression '~' '@' // CFA
1548 {
1549 if ( $3 == OperKinds::LThan || $3 == OperKinds::LEThan ) { SemanticError( yylloc, MISSING_LOW ); $$ = nullptr; }
1550 else $$ = forCtrl( yylloc, $1, $4, $3, nullptr, nullptr );
1551 }
1552 | declaration comma_expression updowneq '@' '~' '@' // CFA
1553 {
1554 if ( $3 == OperKinds::GThan || $3 == OperKinds::GEThan ) { SemanticError( yylloc, MISSING_HIGH ); $$ = nullptr; }
1555 else if ( $3 == OperKinds::LEThan ) { SemanticError( yylloc, "syntax error, equality with missing high value is meaningless. Use \"~\"." ); $$ = nullptr; }
1556 else $$ = forCtrl( yylloc, $1, $2, $3, nullptr, nullptr );
1557 }
1558 | declaration '@' updowneq '@' '~' '@' // CFA, invalid syntax rule
1559 { SemanticError( yylloc, "syntax error, missing low/high value for up/down-to range so index is uninitialized." ); $$ = nullptr; }
1560
1561 | comma_expression ';' TYPEDEFname // CFA, array type
1562 {
1563 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1564 //$$ = forCtrl( new ExpressionNode( build_varref( $3 ) ), $1, nullptr, OperKinds::Range, nullptr, nullptr );
1565 }
1566 | comma_expression ';' downupdowneq TYPEDEFname // CFA, array type
1567 {
1568 if ( $3 == OperKinds::LEThan || $3 == OperKinds::GEThan ) {
1569 SemanticError( yylloc, "syntax error, all enumeration ranges are equal (all values). Remove \"=~\"." ); $$ = nullptr;
1570 }
1571 SemanticError( yylloc, "Type iterator is currently unimplemented." ); $$ = nullptr;
1572 }
1573 ;
1574
1575downupdowneq:
1576 ErangeDown
1577 { $$ = OperKinds::GThan; }
1578 | ErangeUpEq
1579 { $$ = OperKinds::LEThan; }
1580 | ErangeDownEq
1581 { $$ = OperKinds::GEThan; }
1582 ;
1583
1584updown:
1585 '~'
1586 { $$ = OperKinds::LThan; }
1587 | ErangeDown
1588 { $$ = OperKinds::GThan; }
1589 ;
1590
1591updowneq:
1592 updown
1593 | ErangeUpEq
1594 { $$ = OperKinds::LEThan; }
1595 | ErangeDownEq
1596 { $$ = OperKinds::GEThan; }
1597 ;
1598
1599jump_statement:
1600 GOTO identifier_or_type_name ';'
1601 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Goto ) ); }
1602 | GOTO '*' comma_expression ';' // GCC, computed goto
1603 // The syntax for the GCC computed goto violates normal expression precedence, e.g., goto *i+3; => goto *(i+3);
1604 // whereas normal operator precedence yields goto (*i)+3;
1605 { $$ = new StatementNode( build_computedgoto( $3 ) ); }
1606 // A semantic check is required to ensure fallthru appears only in the body of a choose statement.
1607 | fall_through_name ';' // CFA
1608 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThrough ) ); }
1609 | fall_through_name identifier_or_type_name ';' // CFA
1610 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::FallThrough ) ); }
1611 | fall_through_name DEFAULT ';' // CFA
1612 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::FallThroughDefault ) ); }
1613 | CONTINUE ';'
1614 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1615 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Continue ) ); }
1616 | CONTINUE identifier_or_type_name ';' // CFA, multi-level continue
1617 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1618 // the target of the transfer appears only at the start of an iteration statement.
1619 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Continue ) ); }
1620 | BREAK ';'
1621 // A semantic check is required to ensure this statement appears only in the body of an iteration statement.
1622 { $$ = new StatementNode( build_branch( yylloc, ast::BranchStmt::Break ) ); }
1623 | BREAK identifier_or_type_name ';' // CFA, multi-level exit
1624 // A semantic check is required to ensure this statement appears only in the body of an iteration statement, and
1625 // the target of the transfer appears only at the start of an iteration statement.
1626 { $$ = new StatementNode( build_branch( yylloc, $2, ast::BranchStmt::Break ) ); }
1627 | RETURN comma_expression_opt ';'
1628 { $$ = new StatementNode( build_return( yylloc, $2 ) ); }
1629 | RETURN '{' initializer_list_opt comma_opt '}' ';'
1630 { SemanticError( yylloc, "Initializer return is currently unimplemented." ); $$ = nullptr; }
1631 | SUSPEND ';'
1632 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::None ) ); }
1633 | SUSPEND compound_statement
1634 { $$ = new StatementNode( build_suspend( yylloc, $2, ast::SuspendStmt::None ) ); }
1635 | SUSPEND COROUTINE ';'
1636 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Coroutine ) ); }
1637 | SUSPEND COROUTINE compound_statement
1638 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Coroutine ) ); }
1639 | SUSPEND GENERATOR ';'
1640 { $$ = new StatementNode( build_suspend( yylloc, nullptr, ast::SuspendStmt::Generator ) ); }
1641 | SUSPEND GENERATOR compound_statement
1642 { $$ = new StatementNode( build_suspend( yylloc, $3, ast::SuspendStmt::Generator ) ); }
1643 | THROW assignment_expression_opt ';' // handles rethrow
1644 { $$ = new StatementNode( build_throw( yylloc, $2 ) ); }
1645 | THROWRESUME assignment_expression_opt ';' // handles reresume
1646 { $$ = new StatementNode( build_resume( yylloc, $2 ) ); }
1647 | THROWRESUME assignment_expression_opt AT assignment_expression ';' // handles reresume
1648 { $$ = new StatementNode( build_resume_at( $2, $4 ) ); }
1649 ;
1650
1651fall_through_name: // CFA
1652 FALLTHRU
1653 | FALLTHROUGH
1654 ;
1655
1656with_statement:
1657 WITH '(' tuple_expression_list ')' statement
1658 { $$ = new StatementNode( build_with( yylloc, $3, $5 ) ); }
1659 ;
1660
1661// If MUTEX becomes a general qualifier, there are shift/reduce conflicts, so possibly change syntax to "with mutex".
1662mutex_statement:
1663 MUTEX '(' argument_expression_list_opt ')' statement
1664 {
1665 if ( ! $3 ) { SemanticError( yylloc, "syntax error, mutex argument list cannot be empty." ); $$ = nullptr; }
1666 $$ = new StatementNode( build_mutex( yylloc, $3, $5 ) );
1667 }
1668 ;
1669
1670when_clause:
1671 WHEN '(' comma_expression ')' { $$ = $3; }
1672 ;
1673
1674when_clause_opt:
1675 // empty
1676 { $$ = nullptr; }
1677 | when_clause
1678 ;
1679
1680cast_expression_list:
1681 cast_expression
1682 | cast_expression_list ',' cast_expression
1683 // { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1684 { SemanticError( yylloc, "List of mutex member is currently unimplemented." ); $$ = nullptr; }
1685 ;
1686
1687timeout:
1688 TIMEOUT '(' comma_expression ')' { $$ = $3; }
1689 ;
1690
1691wor:
1692 OROR
1693 | WOR
1694
1695waitfor:
1696 WAITFOR '(' cast_expression ')'
1697 { $$ = $3; }
1698 | WAITFOR '(' cast_expression_list ':' argument_expression_list_opt ')'
1699 { $$ = (ExpressionNode *)($3->set_last( $5 )); }
1700 ;
1701
1702wor_waitfor_clause:
1703 when_clause_opt waitfor statement %prec THEN
1704 // Called first: create header for WaitForStmt.
1705 { $$ = build_waitfor( yylloc, new ast::WaitForStmt( yylloc ), $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1706 | wor_waitfor_clause wor when_clause_opt waitfor statement
1707 { $$ = build_waitfor( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1708 | wor_waitfor_clause wor when_clause_opt ELSE statement
1709 { $$ = build_waitfor_else( yylloc, $1, $3, maybe_build_compound( yylloc, $5 ) ); }
1710 | wor_waitfor_clause wor when_clause_opt timeout statement %prec THEN
1711 { $$ = build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ); }
1712 // "else" must be conditional after timeout or timeout is never triggered (i.e., it is meaningless)
1713 | wor_waitfor_clause wor when_clause_opt timeout statement wor ELSE statement // invalid syntax rule
1714 { SemanticError( yylloc, "syntax error, else clause must be conditional after timeout or timeout never triggered." ); $$ = nullptr; }
1715 | wor_waitfor_clause wor when_clause_opt timeout statement wor when_clause ELSE statement
1716 { $$ = build_waitfor_else( yylloc, build_waitfor_timeout( yylloc, $1, $3, $4, maybe_build_compound( yylloc, $5 ) ), $7, maybe_build_compound( yylloc, $9 ) ); }
1717 ;
1718
1719waitfor_statement:
1720 wor_waitfor_clause %prec THEN
1721 { $$ = new StatementNode( $1 ); }
1722 ;
1723
1724wand:
1725 ANDAND
1726 | WAND
1727 ;
1728
1729waituntil:
1730 WAITUNTIL '(' comma_expression ')'
1731 { $$ = $3; }
1732 ;
1733
1734waituntil_clause:
1735 when_clause_opt waituntil statement
1736 { $$ = build_waituntil_clause( yylloc, $1, $2, maybe_build_compound( yylloc, $3 ) ); }
1737 | '(' wor_waituntil_clause ')'
1738 { $$ = $2; }
1739 ;
1740
1741wand_waituntil_clause:
1742 waituntil_clause %prec THEN
1743 { $$ = $1; }
1744 | waituntil_clause wand wand_waituntil_clause
1745 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::AND, $1, $3 ); }
1746 ;
1747
1748wor_waituntil_clause:
1749 wand_waituntil_clause
1750 { $$ = $1; }
1751 | wor_waituntil_clause wor wand_waituntil_clause
1752 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::OR, $1, $3 ); }
1753 | wor_waituntil_clause wor when_clause_opt ELSE statement
1754 { $$ = new ast::WaitUntilStmt::ClauseNode( ast::WaitUntilStmt::ClauseNode::Op::LEFT_OR, $1, build_waituntil_else( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1755 ;
1756
1757waituntil_statement:
1758 wor_waituntil_clause %prec THEN
1759 { $$ = new StatementNode( build_waituntil_stmt( yylloc, $1 ) ); }
1760 ;
1761
1762corun_statement:
1763 CORUN statement
1764 { $$ = new StatementNode( build_corun( yylloc, $2 ) ); }
1765 ;
1766
1767cofor_statement:
1768 COFOR '(' for_control_expression_list ')' statement
1769 { $$ = new StatementNode( build_cofor( yylloc, $3, maybe_build_compound( yylloc, $5 ) ) ); }
1770 ;
1771
1772exception_statement:
1773 TRY compound_statement handler_clause %prec THEN
1774 { $$ = new StatementNode( build_try( yylloc, $2, $3, nullptr ) ); }
1775 | TRY compound_statement finally_clause
1776 { $$ = new StatementNode( build_try( yylloc, $2, nullptr, $3 ) ); }
1777 | TRY compound_statement handler_clause finally_clause
1778 { $$ = new StatementNode( build_try( yylloc, $2, $3, $4 ) ); }
1779 ;
1780
1781handler_clause:
1782 handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1783 { $$ = new ClauseNode( build_catch( yylloc, $1, $4, $6, $8 ) ); }
1784 | handler_clause handler_key '(' push exception_declaration pop handler_predicate_opt ')' compound_statement
1785 { $$ = $1->set_last( new ClauseNode( build_catch( yylloc, $2, $5, $7, $9 ) ) ); }
1786 ;
1787
1788handler_predicate_opt:
1789 // empty
1790 { $$ = nullptr; }
1791 | ';' conditional_expression { $$ = $2; }
1792 ;
1793
1794handler_key:
1795 CATCH { $$ = ast::Terminate; }
1796 | RECOVER { $$ = ast::Terminate; }
1797 | CATCHRESUME { $$ = ast::Resume; }
1798 | FIXUP { $$ = ast::Resume; }
1799 ;
1800
1801finally_clause:
1802 FINALLY compound_statement { $$ = new ClauseNode( build_finally( yylloc, $2 ) ); }
1803 ;
1804
1805exception_declaration:
1806 // No SUE declaration in parameter list.
1807 type_specifier_nobody
1808 | type_specifier_nobody declarator
1809 { $$ = $2->addType( $1 ); }
1810 | type_specifier_nobody variable_abstract_declarator
1811 { $$ = $2->addType( $1 ); }
1812 | cfa_abstract_declarator_tuple identifier // CFA
1813 { $$ = $1->addName( $2 ); }
1814 | cfa_abstract_declarator_tuple // CFA
1815 ;
1816
1817enable_disable_statement:
1818 enable_disable_key identifier_list compound_statement
1819 ;
1820
1821enable_disable_key:
1822 ENABLE
1823 | DISABLE
1824 ;
1825
1826asm_statement:
1827 ASM asm_volatile_opt '(' string_literal ')' ';'
1828 { $$ = new StatementNode( build_asm( yylloc, $2, $4, nullptr ) ); }
1829 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ')' ';' // remaining GCC
1830 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6 ) ); }
1831 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ')' ';'
1832 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8 ) ); }
1833 | ASM asm_volatile_opt '(' string_literal ':' asm_operands_opt ':' asm_operands_opt ':' asm_clobbers_list_opt ')' ';'
1834 { $$ = new StatementNode( build_asm( yylloc, $2, $4, $6, $8, $10 ) ); }
1835 | ASM asm_volatile_opt GOTO '(' string_literal ':' ':' asm_operands_opt ':' asm_clobbers_list_opt ':' label_list ')' ';'
1836 { $$ = new StatementNode( build_asm( yylloc, $2, $5, nullptr, $8, $10, $12 ) ); }
1837 ;
1838
1839asm_volatile_opt: // GCC
1840 // empty
1841 { $$ = false; }
1842 | VOLATILE
1843 { $$ = true; }
1844 ;
1845
1846asm_operands_opt: // GCC
1847 // empty
1848 { $$ = nullptr; } // use default argument
1849 | asm_operands_list
1850 ;
1851
1852asm_operands_list: // GCC
1853 asm_operand
1854 | asm_operands_list ',' asm_operand
1855 { $$ = (ExpressionNode *)($1->set_last( $3 )); }
1856 ;
1857
1858asm_operand: // GCC
1859 string_literal '(' constant_expression ')'
1860 { $$ = new ExpressionNode( new ast::AsmExpr( yylloc, "", maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
1861 | '[' IDENTIFIER ']' string_literal '(' constant_expression ')'
1862 {
1863 $$ = new ExpressionNode( new ast::AsmExpr( yylloc, *$2.str, maybeMoveBuild( $4 ), maybeMoveBuild( $6 ) ) );
1864 delete $2.str;
1865 }
1866 ;
1867
1868asm_clobbers_list_opt: // GCC
1869 // empty
1870 { $$ = nullptr; } // use default argument
1871 | string_literal
1872 { $$ = $1; }
1873 | asm_clobbers_list_opt ',' string_literal
1874 { $$ = (ExpressionNode *)( $1->set_last( $3 ) ); }
1875 ;
1876
1877label_list:
1878 identifier
1879 {
1880 $$ = new LabelNode(); $$->labels.emplace_back( yylloc, *$1 );
1881 delete $1; // allocated by lexer
1882 }
1883 | label_list ',' identifier
1884 {
1885 $$ = $1; $1->labels.emplace_back( yylloc, *$3 );
1886 delete $3; // allocated by lexer
1887 }
1888 ;
1889
1890// ****************************** DECLARATIONS *********************************
1891
1892declaration_list_opt: // used at beginning of switch statement
1893 // empty
1894 { $$ = nullptr; }
1895 | declaration_list
1896 ;
1897
1898declaration_list:
1899 declaration
1900 | declaration_list declaration { $$ = $1->appendList( $2 ); }
1901 ;
1902
1903KR_parameter_list_opt: // used to declare parameter types in K&R style functions
1904 // empty
1905 { $$ = nullptr; }
1906 | KR_parameter_list
1907 ;
1908
1909KR_parameter_list:
1910 c_declaration ';'
1911 { $$ = $1; }
1912 | KR_parameter_list c_declaration ';'
1913 { $$ = $1->appendList( $2 ); }
1914 ;
1915
1916local_label_declaration_opt: // GCC, local label
1917 // empty
1918 | local_label_declaration_list
1919 ;
1920
1921local_label_declaration_list: // GCC, local label
1922 LABEL local_label_list ';'
1923 | local_label_declaration_list LABEL local_label_list ';'
1924 ;
1925
1926local_label_list: // GCC, local label
1927 identifier_or_type_name
1928 | local_label_list ',' identifier_or_type_name
1929 ;
1930
1931declaration: // old & new style declarations
1932 c_declaration ';'
1933 | cfa_declaration ';' // CFA
1934 | static_assert // C11
1935 ;
1936
1937static_assert:
1938 STATICASSERT '(' constant_expression ',' string_literal ')' ';' // C11
1939 { $$ = DeclarationNode::newStaticAssert( $3, maybeMoveBuild( $5 ) ); }
1940 | STATICASSERT '(' constant_expression ')' ';' // CFA
1941 { $$ = DeclarationNode::newStaticAssert( $3, build_constantStr( yylloc, *new string( "\"\"" ) ) ); }
1942
1943// C declaration syntax is notoriously confusing and error prone. Cforall provides its own type, variable and function
1944// declarations. CFA declarations use the same declaration tokens as in C; however, CFA places declaration modifiers to
1945// the left of the base type, while C declarations place modifiers to the right of the base type. CFA declaration
1946// modifiers are interpreted from left to right and the entire type specification is distributed across all variables in
1947// the declaration list (as in Pascal). ANSI C and the new CFA declarations may appear together in the same program
1948// block, but cannot be mixed within a specific declaration.
1949//
1950// CFA C
1951// [10] int x; int x[10]; // array of 10 integers
1952// [10] * char y; char *y[10]; // array of 10 pointers to char
1953
1954cfa_declaration: // CFA
1955 cfa_variable_declaration
1956 | cfa_typedef_declaration
1957 | cfa_function_declaration
1958 | type_declaring_list
1959 { SemanticError( yylloc, "otype declaration is currently unimplemented." ); $$ = nullptr; }
1960 | trait_specifier
1961 ;
1962
1963cfa_variable_declaration: // CFA
1964 cfa_variable_specifier initializer_opt
1965 { $$ = $1->addInitializer( $2 ); }
1966 | declaration_qualifier_list cfa_variable_specifier initializer_opt
1967 // declaration_qualifier_list also includes type_qualifier_list, so a semantic check is necessary to preclude
1968 // them as a type_qualifier cannot appear in that context.
1969 { $$ = $2->addQualifiers( $1 )->addInitializer( $3 ); }
1970 | cfa_variable_declaration pop ',' push identifier_or_type_name initializer_opt
1971 { $$ = $1->appendList( $1->cloneType( $5 )->addInitializer( $6 ) ); }
1972 ;
1973
1974cfa_variable_specifier: // CFA
1975 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
1976 // storage-class
1977 cfa_abstract_declarator_no_tuple identifier_or_type_name asm_name_opt
1978 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1979 | cfa_abstract_tuple identifier_or_type_name asm_name_opt
1980 { $$ = $1->addName( $2 )->addAsmName( $3 ); }
1981 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name asm_name_opt
1982 { $$ = $2->addQualifiers( $1 )->addName( $3 )->addAsmName( $4 ); }
1983 ;
1984
1985cfa_function_declaration: // CFA
1986 cfa_function_specifier
1987 | type_qualifier_list cfa_function_specifier
1988 { $$ = $2->addQualifiers( $1 ); }
1989 | declaration_qualifier_list cfa_function_specifier
1990 { $$ = $2->addQualifiers( $1 ); }
1991 | declaration_qualifier_list type_qualifier_list cfa_function_specifier
1992 { $$ = $3->addQualifiers( $1 )->addQualifiers( $2 ); }
1993 | cfa_function_declaration ',' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')'
1994 {
1995 // Append the return type at the start (left-hand-side) to each identifier in the list.
1996 DeclarationNode * ret = new DeclarationNode;
1997 ret->type = maybeCopy( $1->type->base );
1998 $$ = $1->appendList( DeclarationNode::newFunction( $3, ret, $6, nullptr ) );
1999 }
2000 ;
2001
2002cfa_function_specifier: // CFA
2003// '[' ']' identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' // S/R conflict
2004// {
2005// $$ = DeclarationNode::newFunction( $3, DeclarationNode::newTuple( 0 ), $6, nullptr, true );
2006// }
2007// '[' ']' identifier '(' push cfa_parameter_ellipsis_list_opt pop ')'
2008// {
2009// typedefTable.setNextIdentifier( *$5 );
2010// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
2011// }
2012// | '[' ']' TYPEDEFname '(' push cfa_parameter_ellipsis_list_opt pop ')'
2013// {
2014// typedefTable.setNextIdentifier( *$5 );
2015// $$ = DeclarationNode::newFunction( $5, DeclarationNode::newTuple( 0 ), $8, nullptr, true );
2016// }
2017// | '[' ']' typegen_name
2018 // identifier_or_type_name must be broken apart because of the sequence:
2019 //
2020 // '[' ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
2021 // '[' ']' type_specifier
2022 //
2023 // type_specifier can resolve to just TYPEDEFname (e.g., typedef int T; int f( T );). Therefore this must be
2024 // flattened to allow lookahead to the '(' without having to reduce identifier_or_type_name.
2025 cfa_abstract_tuple identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
2026 // To obtain LR(1 ), this rule must be factored out from function return type (see cfa_abstract_declarator).
2027 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2028 | cfa_function_return identifier_or_type_name '(' push cfa_parameter_ellipsis_list_opt pop ')' attribute_list_opt
2029 { $$ = DeclarationNode::newFunction( $2, $1, $5, nullptr )->addQualifiers( $8 ); }
2030 ;
2031
2032cfa_function_return: // CFA
2033 '[' push cfa_parameter_list pop ']'
2034 { $$ = DeclarationNode::newTuple( $3 ); }
2035 | '[' push cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ']'
2036 // To obtain LR(1 ), the last cfa_abstract_parameter_list is added into this flattened rule to lookahead to the ']'.
2037 { $$ = DeclarationNode::newTuple( $3->appendList( $7 ) ); }
2038 ;
2039
2040cfa_typedef_declaration: // CFA
2041 TYPEDEF cfa_variable_specifier
2042 {
2043 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 1" );
2044 $$ = $2->addTypedef();
2045 }
2046 | TYPEDEF cfa_function_specifier
2047 {
2048 typedefTable.addToEnclosingScope( *$2->name, TYPEDEFname, "cfa_typedef_declaration 2" );
2049 $$ = $2->addTypedef();
2050 }
2051 | cfa_typedef_declaration pop ',' push identifier
2052 {
2053 typedefTable.addToEnclosingScope( *$5, TYPEDEFname, "cfa_typedef_declaration 3" );
2054 $$ = $1->appendList( $1->cloneType( $5 ) );
2055 }
2056 ;
2057
2058// Traditionally typedef is part of storage-class specifier for syntactic convenience only. Here, it is factored out as
2059// a separate form of declaration, which syntactically precludes storage-class specifiers and initialization.
2060
2061typedef_declaration:
2062 TYPEDEF type_specifier declarator
2063 {
2064 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 1" );
2065 if ( $2->type->forall || ($2->type->kind == TypeData::Aggregate && $2->type->aggregate.params) ) {
2066 SemanticError( yylloc, "forall qualifier in typedef is currently unimplemented." ); $$ = nullptr;
2067 } else $$ = $3->addType( $2 )->addTypedef(); // watchout frees $2 and $3
2068 }
2069 | typedef_declaration ',' declarator
2070 {
2071 typedefTable.addToEnclosingScope( *$3->name, TYPEDEFname, "typedef_declaration 2" );
2072 $$ = $1->appendList( $1->cloneBaseType( $3 )->addTypedef() );
2073 }
2074 | type_qualifier_list TYPEDEF type_specifier declarator // remaining OBSOLESCENT (see 2 )
2075 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2076 | type_specifier TYPEDEF declarator
2077 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2078 | type_specifier TYPEDEF type_qualifier_list declarator
2079 { SemanticError( yylloc, "Type qualifiers/specifiers before TYPEDEF is deprecated, move after TYPEDEF." ); $$ = nullptr; }
2080 ;
2081
2082typedef_expression:
2083 // deprecated GCC, naming expression type: typedef name = exp; gives a name to the type of an expression
2084 TYPEDEF identifier '=' assignment_expression
2085 {
2086 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2087 }
2088 | typedef_expression ',' identifier '=' assignment_expression
2089 {
2090 SemanticError( yylloc, "TYPEDEF expression is deprecated, use typeof(...) instead." ); $$ = nullptr;
2091 }
2092 ;
2093
2094c_declaration:
2095 declaration_specifier declaring_list
2096 { $$ = distAttr( $1, $2 ); }
2097 | typedef_declaration
2098 | typedef_expression // deprecated GCC, naming expression type
2099 | sue_declaration_specifier
2100 {
2101 assert( $1->type );
2102 if ( $1->type->qualifiers.any() ) { // CV qualifiers ?
2103 SemanticError( yylloc, "syntax error, useless type qualifier(s) in empty declaration." ); $$ = nullptr;
2104 }
2105 // enums are never empty declarations because there must have at least one enumeration.
2106 if ( $1->type->kind == TypeData::AggregateInst && $1->storageClasses.any() ) { // storage class ?
2107 SemanticError( yylloc, "syntax error, useless storage qualifier(s) in empty aggregate declaration." ); $$ = nullptr;
2108 }
2109 }
2110 ;
2111
2112declaring_list:
2113 // A semantic check is required to ensure asm_name only appears on declarations with implicit or explicit static
2114 // storage-class
2115 variable_declarator asm_name_opt initializer_opt
2116 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2117 | variable_type_redeclarator asm_name_opt initializer_opt
2118 { $$ = $1->addAsmName( $2 )->addInitializer( $3 ); }
2119
2120 | general_function_declarator asm_name_opt
2121 { $$ = $1->addAsmName( $2 )->addInitializer( nullptr ); }
2122 | general_function_declarator asm_name_opt '=' VOID
2123 { $$ = $1->addAsmName( $2 )->addInitializer( new InitializerNode( true ) ); }
2124
2125 | declaring_list ',' attribute_list_opt declarator asm_name_opt initializer_opt
2126 { $$ = $1->appendList( $4->addQualifiers( $3 )->addAsmName( $5 )->addInitializer( $6 ) ); }
2127 ;
2128
2129general_function_declarator:
2130 function_type_redeclarator
2131 | function_declarator
2132 ;
2133
2134declaration_specifier: // type specifier + storage class
2135 basic_declaration_specifier
2136 | type_declaration_specifier
2137 | sue_declaration_specifier
2138 | sue_declaration_specifier invalid_types // invalid syntax rule
2139 {
2140 SemanticError( yylloc, "syntax error, expecting ';' at end of \"%s\" declaration.",
2141 $1->type->enumeration.name ? "enum" : ast::AggregateDecl::aggrString( $1->type->aggregate.kind ) );
2142 $$ = nullptr;
2143 }
2144 ;
2145
2146invalid_types:
2147 aggregate_key
2148 | basic_type_name
2149 | indirect_type
2150 ;
2151
2152declaration_specifier_nobody: // type specifier + storage class - {...}
2153 // Preclude SUE declarations in restricted scopes:
2154 //
2155 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2156 //
2157 // because it is impossible to call f due to name equivalence.
2158 basic_declaration_specifier
2159 | sue_declaration_specifier_nobody
2160 | type_declaration_specifier
2161 ;
2162
2163type_specifier: // type specifier
2164 basic_type_specifier
2165 | sue_type_specifier
2166 | type_type_specifier
2167 ;
2168
2169type_specifier_nobody: // type specifier - {...}
2170 // Preclude SUE declarations in restricted scopes:
2171 //
2172 // int f( struct S { int i; } s1, Struct S s2 ) { struct S s3; ... }
2173 //
2174 // because it is impossible to call f due to name equivalence.
2175 basic_type_specifier
2176 | sue_type_specifier_nobody
2177 | type_type_specifier
2178 ;
2179
2180type_qualifier_list_opt: // GCC, used in asm_statement
2181 // empty
2182 { $$ = nullptr; }
2183 | type_qualifier_list
2184 ;
2185
2186type_qualifier_list:
2187 // A semantic check is necessary to ensure a type qualifier is appropriate for the kind of declaration.
2188 //
2189 // ISO/IEC 9899:1999 Section 6.7.3(4 ) : If the same qualifier appears more than once in the same
2190 // specifier-qualifier-list, either directly or via one or more typedefs, the behavior is the same as if it
2191 // appeared only once.
2192 type_qualifier
2193 | type_qualifier_list type_qualifier
2194 { $$ = $1->addQualifiers( $2 ); }
2195 ;
2196
2197type_qualifier:
2198 type_qualifier_name
2199 | attribute // trick handles most attribute locations
2200 ;
2201
2202type_qualifier_name:
2203 CONST
2204 { $$ = DeclarationNode::newTypeQualifier( ast::CV::Const ); }
2205 | RESTRICT
2206 { $$ = DeclarationNode::newTypeQualifier( ast::CV::Restrict ); }
2207 | VOLATILE
2208 { $$ = DeclarationNode::newTypeQualifier( ast::CV::Volatile ); }
2209 | ATOMIC
2210 { $$ = DeclarationNode::newTypeQualifier( ast::CV::Atomic ); }
2211 | forall
2212 { $$ = DeclarationNode::newForall( $1 ); }
2213 ;
2214
2215forall:
2216 FORALL '(' type_parameter_list ')' // CFA
2217 { $$ = $3; }
2218 ;
2219
2220declaration_qualifier_list:
2221 storage_class_list
2222 | type_qualifier_list storage_class_list // remaining OBSOLESCENT (see 2 )
2223 { $$ = $1->addQualifiers( $2 ); }
2224 | declaration_qualifier_list type_qualifier_list storage_class_list
2225 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2226 ;
2227
2228storage_class_list:
2229 // A semantic check is necessary to ensure a storage class is appropriate for the kind of declaration and that
2230 // only one of each is specified, except for inline, which can appear with the others.
2231 //
2232 // ISO/IEC 9899:1999 Section 6.7.1(2) : At most, one storage-class specifier may be given in the declaration
2233 // specifiers in a declaration.
2234 storage_class
2235 | storage_class_list storage_class
2236 { $$ = $1->addQualifiers( $2 ); }
2237 ;
2238
2239storage_class:
2240 EXTERN
2241 { $$ = DeclarationNode::newStorageClass( ast::Storage::Extern ); }
2242 | STATIC
2243 { $$ = DeclarationNode::newStorageClass( ast::Storage::Static ); }
2244 | AUTO
2245 { $$ = DeclarationNode::newStorageClass( ast::Storage::Auto ); }
2246 | REGISTER
2247 { $$ = DeclarationNode::newStorageClass( ast::Storage::Register ); }
2248 | THREADLOCALGCC // GCC
2249 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalGcc ); }
2250 | THREADLOCALC11 // C11
2251 { $$ = DeclarationNode::newStorageClass( ast::Storage::ThreadLocalC11 ); }
2252 // Put function specifiers here to simplify parsing rules, but separate them semantically.
2253 | INLINE // C99
2254 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Inline ); }
2255 | FORTRAN // C99
2256 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Fortran ); }
2257 | NORETURN // C11
2258 { $$ = DeclarationNode::newFuncSpecifier( ast::Function::Noreturn ); }
2259 ;
2260
2261basic_type_name:
2262 VOID
2263 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2264 | BOOL // C99
2265 { $$ = DeclarationNode::newBasicType( DeclarationNode::Bool ); }
2266 | CHAR
2267 { $$ = DeclarationNode::newBasicType( DeclarationNode::Char ); }
2268 | INT
2269 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int ); }
2270 | INT128
2271 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 ); }
2272 | UINT128
2273 { $$ = DeclarationNode::newBasicType( DeclarationNode::Int128 )->addType( DeclarationNode::newSignedNess( DeclarationNode::Unsigned ) ); }
2274 | FLOAT
2275 { $$ = DeclarationNode::newBasicType( DeclarationNode::Float ); }
2276 | DOUBLE
2277 { $$ = DeclarationNode::newBasicType( DeclarationNode::Double ); }
2278 | uuFLOAT80
2279 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat80 ); }
2280 | uuFLOAT128
2281 { $$ = DeclarationNode::newBasicType( DeclarationNode::uuFloat128 ); }
2282 | uFLOAT16
2283 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat16 ); }
2284 | uFLOAT32
2285 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32 ); }
2286 | uFLOAT32X
2287 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat32x ); }
2288 | uFLOAT64
2289 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64 ); }
2290 | uFLOAT64X
2291 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat64x ); }
2292 | uFLOAT128
2293 { $$ = DeclarationNode::newBasicType( DeclarationNode::uFloat128 ); }
2294 | DECIMAL32
2295 { SemanticError( yylloc, "_Decimal32 is currently unimplemented." ); $$ = nullptr; }
2296 | DECIMAL64
2297 { SemanticError( yylloc, "_Decimal64 is currently unimplemented." ); $$ = nullptr; }
2298 | DECIMAL128
2299 { SemanticError( yylloc, "_Decimal128 is currently unimplemented." ); $$ = nullptr; }
2300 | COMPLEX // C99
2301 { $$ = DeclarationNode::newComplexType( DeclarationNode::Complex ); }
2302 | IMAGINARY // C99
2303 { $$ = DeclarationNode::newComplexType( DeclarationNode::Imaginary ); }
2304 | SIGNED
2305 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Signed ); }
2306 | UNSIGNED
2307 { $$ = DeclarationNode::newSignedNess( DeclarationNode::Unsigned ); }
2308 | SHORT
2309 { $$ = DeclarationNode::newLength( DeclarationNode::Short ); }
2310 | LONG
2311 { $$ = DeclarationNode::newLength( DeclarationNode::Long ); }
2312 | VA_LIST // GCC, __builtin_va_list
2313 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Valist ); }
2314 | AUTO_TYPE
2315 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::AutoType ); }
2316 | vtable
2317 ;
2318
2319vtable_opt:
2320 // empty
2321 { $$ = nullptr; }
2322 | vtable
2323 ;
2324
2325vtable:
2326 VTABLE '(' type_name ')' default_opt
2327 { $$ = DeclarationNode::newVtableType( $3 ); }
2328 // { SemanticError( yylloc, "vtable is currently unimplemented." ); $$ = nullptr; }
2329 ;
2330
2331default_opt:
2332 // empty
2333 { $$ = nullptr; }
2334 | DEFAULT
2335 { SemanticError( yylloc, "vtable default is currently unimplemented." ); $$ = nullptr; }
2336 ;
2337
2338basic_declaration_specifier:
2339 // A semantic check is necessary for conflicting storage classes.
2340 basic_type_specifier
2341 | declaration_qualifier_list basic_type_specifier
2342 { $$ = $2->addQualifiers( $1 ); }
2343 | basic_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2344 { $$ = $1->addQualifiers( $2 ); }
2345 | basic_declaration_specifier storage_class type_qualifier_list
2346 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2347 | basic_declaration_specifier storage_class basic_type_specifier
2348 { $$ = $3->addQualifiers( $2 )->addType( $1 ); }
2349 ;
2350
2351basic_type_specifier:
2352 direct_type
2353 // Cannot have type modifiers, e.g., short, long, etc.
2354 | type_qualifier_list_opt indirect_type type_qualifier_list_opt
2355 { $$ = $2->addQualifiers( $1 )->addQualifiers( $3 ); }
2356 ;
2357
2358direct_type:
2359 basic_type_name
2360 | type_qualifier_list basic_type_name
2361 { $$ = $2->addQualifiers( $1 ); }
2362 | direct_type type_qualifier
2363 { $$ = $1->addQualifiers( $2 ); }
2364 | direct_type basic_type_name
2365 { $$ = $1->addType( $2 ); }
2366 ;
2367
2368indirect_type:
2369 TYPEOF '(' type ')' // GCC: typeof( x ) y;
2370 { $$ = $3; }
2371 | TYPEOF '(' comma_expression ')' // GCC: typeof( a+b ) y;
2372 { $$ = DeclarationNode::newTypeof( $3 ); }
2373 | BASETYPEOF '(' type ')' // CFA: basetypeof( x ) y;
2374 { $$ = DeclarationNode::newTypeof( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ), true ); }
2375 | BASETYPEOF '(' comma_expression ')' // CFA: basetypeof( a+b ) y;
2376 { $$ = DeclarationNode::newTypeof( $3, true ); }
2377 | ZERO_T // CFA
2378 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::Zero ); }
2379 | ONE_T // CFA
2380 { $$ = DeclarationNode::newBuiltinType( DeclarationNode::One ); }
2381 ;
2382
2383sue_declaration_specifier: // struct, union, enum + storage class + type specifier
2384 sue_type_specifier
2385 | declaration_qualifier_list sue_type_specifier
2386 { $$ = $2->addQualifiers( $1 ); }
2387 | sue_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2388 { $$ = $1->addQualifiers( $2 ); }
2389 | sue_declaration_specifier storage_class type_qualifier_list
2390 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2391 ;
2392
2393sue_type_specifier: // struct, union, enum + type specifier
2394 elaborated_type
2395 | type_qualifier_list
2396 { if ( $1->type != nullptr && $1->type->forall ) forall = true; } // remember generic type
2397 elaborated_type
2398 { $$ = $3->addQualifiers( $1 ); }
2399 | sue_type_specifier type_qualifier
2400 {
2401 if ( $2->type != nullptr && $2->type->forall ) forall = true; // remember generic type
2402 $$ = $1->addQualifiers( $2 );
2403 }
2404 ;
2405
2406sue_declaration_specifier_nobody: // struct, union, enum - {...} + storage class + type specifier
2407 sue_type_specifier_nobody
2408 | declaration_qualifier_list sue_type_specifier_nobody
2409 { $$ = $2->addQualifiers( $1 ); }
2410 | sue_declaration_specifier_nobody storage_class // remaining OBSOLESCENT (see 2)
2411 { $$ = $1->addQualifiers( $2 ); }
2412 | sue_declaration_specifier_nobody storage_class type_qualifier_list
2413 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2414 ;
2415
2416sue_type_specifier_nobody: // struct, union, enum - {...} + type specifier
2417 elaborated_type_nobody
2418 | type_qualifier_list elaborated_type_nobody
2419 { $$ = $2->addQualifiers( $1 ); }
2420 | sue_type_specifier_nobody type_qualifier
2421 { $$ = $1->addQualifiers( $2 ); }
2422 ;
2423
2424type_declaration_specifier:
2425 type_type_specifier
2426 | declaration_qualifier_list type_type_specifier
2427 { $$ = $2->addQualifiers( $1 ); }
2428 | type_declaration_specifier storage_class // remaining OBSOLESCENT (see 2)
2429 { $$ = $1->addQualifiers( $2 ); }
2430 | type_declaration_specifier storage_class type_qualifier_list
2431 { $$ = $1->addQualifiers( $2 )->addQualifiers( $3 ); }
2432 ;
2433
2434type_type_specifier: // typedef types
2435 type_name
2436 | type_qualifier_list type_name
2437 { $$ = $2->addQualifiers( $1 ); }
2438 | type_type_specifier type_qualifier
2439 { $$ = $1->addQualifiers( $2 ); }
2440 ;
2441
2442type_name:
2443 TYPEDEFname
2444 { $$ = DeclarationNode::newFromTypedef( $1 ); }
2445 | '.' TYPEDEFname
2446 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), DeclarationNode::newFromTypedef( $2 ) ); }
2447 | type_name '.' TYPEDEFname
2448 { $$ = DeclarationNode::newQualifiedType( $1, DeclarationNode::newFromTypedef( $3 ) ); }
2449 | typegen_name
2450 | '.' typegen_name
2451 { $$ = DeclarationNode::newQualifiedType( DeclarationNode::newFromGlobalScope(), $2 ); }
2452 | type_name '.' typegen_name
2453 { $$ = DeclarationNode::newQualifiedType( $1, $3 ); }
2454 ;
2455
2456typegen_name: // CFA
2457 TYPEGENname
2458 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2459 | TYPEGENname '(' ')'
2460 { $$ = DeclarationNode::newFromTypeGen( $1, nullptr ); }
2461 | TYPEGENname '(' type_list ')'
2462 { $$ = DeclarationNode::newFromTypeGen( $1, $3 ); }
2463 ;
2464
2465elaborated_type: // struct, union, enum
2466 aggregate_type
2467 | enum_type
2468 ;
2469
2470elaborated_type_nobody: // struct, union, enum - {...}
2471 aggregate_type_nobody
2472 | enum_type_nobody
2473 ;
2474
2475aggregate_type: // struct, union
2476 aggregate_key attribute_list_opt
2477 { forall = false; } // reset
2478 '{' field_declaration_list_opt '}' type_parameters_opt
2479 { $$ = DeclarationNode::newAggregate( $1, nullptr, $7, $5, true )->addQualifiers( $2 ); }
2480 | aggregate_key attribute_list_opt identifier
2481 {
2482 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 1" );
2483 forall = false; // reset
2484 }
2485 '{' field_declaration_list_opt '}' type_parameters_opt
2486 {
2487 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2488 }
2489 | aggregate_key attribute_list_opt TYPEDEFname // unqualified type name
2490 {
2491 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 2" );
2492 forall = false; // reset
2493 }
2494 '{' field_declaration_list_opt '}' type_parameters_opt
2495 {
2496 DeclarationNode::newFromTypedef( $3 );
2497 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2498 }
2499 | aggregate_key attribute_list_opt TYPEGENname // unqualified type name
2500 {
2501 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type: 3" );
2502 forall = false; // reset
2503 }
2504 '{' field_declaration_list_opt '}' type_parameters_opt
2505 {
2506 DeclarationNode::newFromTypeGen( $3, nullptr );
2507 $$ = DeclarationNode::newAggregate( $1, $3, $8, $6, true )->addQualifiers( $2 );
2508 }
2509 | aggregate_type_nobody
2510 ;
2511
2512type_parameters_opt:
2513 // empty
2514 { $$ = nullptr; } %prec '}'
2515 | '(' type_list ')'
2516 { $$ = $2; }
2517 ;
2518
2519aggregate_type_nobody: // struct, union - {...}
2520 aggregate_key attribute_list_opt identifier
2521 {
2522 typedefTable.makeTypedef( *$3, forall || typedefTable.getEnclForall() ? TYPEGENname : TYPEDEFname, "aggregate_type_nobody" );
2523 forall = false; // reset
2524 $$ = DeclarationNode::newAggregate( $1, $3, nullptr, nullptr, false )->addQualifiers( $2 );
2525 }
2526 | aggregate_key attribute_list_opt type_name
2527 {
2528 forall = false; // reset
2529 // Create new generic declaration with same name as previous forward declaration, where the IDENTIFIER is
2530 // switched to a TYPEGENname. Link any generic arguments from typegen_name to new generic declaration and
2531 // delete newFromTypeGen.
2532 if ( $3->type->kind == TypeData::SymbolicInst && ! $3->type->symbolic.isTypedef ) {
2533 $$ = $3->addQualifiers( $2 );
2534 } else {
2535 $$ = DeclarationNode::newAggregate( $1, $3->type->symbolic.name, $3->type->symbolic.actuals, nullptr, false )->addQualifiers( $2 );
2536 $3->type->symbolic.name = nullptr; // copied to $$
2537 $3->type->symbolic.actuals = nullptr;
2538 delete $3;
2539 }
2540 }
2541 ;
2542
2543aggregate_key:
2544 aggregate_data
2545 | aggregate_control
2546 ;
2547
2548aggregate_data:
2549 STRUCT vtable_opt
2550 { $$ = ast::AggregateDecl::Struct; }
2551 | UNION
2552 { $$ = ast::AggregateDecl::Union; }
2553 | EXCEPTION // CFA
2554 { $$ = ast::AggregateDecl::Exception; }
2555 // { SemanticError( yylloc, "exception aggregate is currently unimplemented." ); $$ = ast::AggregateDecl::NoAggregate; }
2556 ;
2557
2558aggregate_control: // CFA
2559 MONITOR
2560 { $$ = ast::AggregateDecl::Monitor; }
2561 | MUTEX STRUCT
2562 { $$ = ast::AggregateDecl::Monitor; }
2563 | GENERATOR
2564 { $$ = ast::AggregateDecl::Generator; }
2565 | MUTEX GENERATOR
2566 {
2567 SemanticError( yylloc, "monitor generator is currently unimplemented." );
2568 $$ = ast::AggregateDecl::NoAggregate;
2569 }
2570 | COROUTINE
2571 { $$ = ast::AggregateDecl::Coroutine; }
2572 | MUTEX COROUTINE
2573 {
2574 SemanticError( yylloc, "monitor coroutine is currently unimplemented." );
2575 $$ = ast::AggregateDecl::NoAggregate;
2576 }
2577 | THREAD
2578 { $$ = ast::AggregateDecl::Thread; }
2579 | MUTEX THREAD
2580 {
2581 SemanticError( yylloc, "monitor thread is currently unimplemented." );
2582 $$ = ast::AggregateDecl::NoAggregate;
2583 }
2584 ;
2585
2586field_declaration_list_opt:
2587 // empty
2588 { $$ = nullptr; }
2589 | field_declaration_list_opt field_declaration
2590 { $$ = $1 ? $1->appendList( $2 ) : $2; }
2591 ;
2592
2593field_declaration:
2594 type_specifier field_declaring_list_opt ';'
2595 {
2596 // printf( "type_specifier1 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2597 $$ = fieldDecl( $1, $2 );
2598 // printf( "type_specifier2 %p %s\n", $$, $$->type->aggregate.name ? $$->type->aggregate.name->c_str() : "(nil)" );
2599 // for ( Attribute * attr: reverseIterate( $$->attributes ) ) {
2600 // printf( "\tattr %s\n", attr->name.c_str() );
2601 // } // for
2602 }
2603 | type_specifier field_declaring_list_opt '}' // invalid syntax rule
2604 {
2605 SemanticError( yylloc, "syntax error, expecting ';' at end of previous declaration." );
2606 $$ = nullptr;
2607 }
2608 | EXTENSION type_specifier field_declaring_list_opt ';' // GCC
2609 { $$ = fieldDecl( $2, $3 ); distExt( $$ ); }
2610 | STATIC type_specifier field_declaring_list_opt ';' // CFA
2611 { SemanticError( yylloc, "STATIC aggregate field qualifier currently unimplemented." ); $$ = nullptr; }
2612 | INLINE type_specifier field_abstract_list_opt ';' // CFA
2613 {
2614 if ( ! $3 ) { // field declarator ?
2615 $3 = DeclarationNode::newName( nullptr );
2616 } // if
2617 $3->inLine = true;
2618 $$ = distAttr( $2, $3 ); // mark all fields in list
2619 distInl( $3 );
2620 }
2621 | INLINE aggregate_control ';' // CFA
2622 { SemanticError( yylloc, "INLINE aggregate control currently unimplemented." ); $$ = nullptr; }
2623 | typedef_declaration ';' // CFA
2624 | cfa_field_declaring_list ';' // CFA, new style field declaration
2625 | EXTENSION cfa_field_declaring_list ';' // GCC
2626 { distExt( $2 ); $$ = $2; } // mark all fields in list
2627 | INLINE cfa_field_abstract_list ';' // CFA, new style field declaration
2628 { $$ = $2; } // mark all fields in list
2629 | cfa_typedef_declaration ';' // CFA
2630 | static_assert // C11
2631 ;
2632
2633field_declaring_list_opt:
2634 // empty
2635 { $$ = nullptr; }
2636 | field_declarator
2637 | field_declaring_list_opt ',' attribute_list_opt field_declarator
2638 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2639 ;
2640
2641field_declarator:
2642 bit_subrange_size // C special case, no field name
2643 { $$ = DeclarationNode::newBitfield( $1 ); }
2644 | variable_declarator bit_subrange_size_opt
2645 // A semantic check is required to ensure bit_subrange only appears on integral types.
2646 { $$ = $1->addBitfield( $2 ); }
2647 | variable_type_redeclarator bit_subrange_size_opt
2648 // A semantic check is required to ensure bit_subrange only appears on integral types.
2649 { $$ = $1->addBitfield( $2 ); }
2650 | function_type_redeclarator bit_subrange_size_opt
2651 // A semantic check is required to ensure bit_subrange only appears on integral types.
2652 { $$ = $1->addBitfield( $2 ); }
2653 ;
2654
2655field_abstract_list_opt:
2656 // empty
2657 { $$ = nullptr; }
2658 | field_abstract
2659 | field_abstract_list_opt ',' attribute_list_opt field_abstract
2660 { $$ = $1->appendList( $4->addQualifiers( $3 ) ); }
2661 ;
2662
2663field_abstract:
2664 // no bit fields
2665 variable_abstract_declarator
2666 ;
2667
2668cfa_field_declaring_list: // CFA, new style field declaration
2669 // bit-fields are handled by C declarations
2670 cfa_abstract_declarator_tuple identifier_or_type_name
2671 { $$ = $1->addName( $2 ); }
2672 | cfa_field_declaring_list ',' identifier_or_type_name
2673 { $$ = $1->appendList( $1->cloneType( $3 ) ); }
2674 ;
2675
2676cfa_field_abstract_list: // CFA, new style field declaration
2677 // bit-fields are handled by C declarations
2678 cfa_abstract_declarator_tuple
2679 | cfa_field_abstract_list ','
2680 { $$ = $1->appendList( $1->cloneType( 0 ) ); }
2681 ;
2682
2683bit_subrange_size_opt:
2684 // empty
2685 { $$ = nullptr; }
2686 | bit_subrange_size
2687 ;
2688
2689bit_subrange_size:
2690 ':' assignment_expression
2691 { $$ = $2; }
2692 ;
2693
2694enum_type:
2695 ENUM attribute_list_opt '{' enumerator_list comma_opt '}'
2696 { $$ = DeclarationNode::newEnum( nullptr, $4, true, false )->addQualifiers( $2 ); }
2697 | ENUM attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2698 { SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2699 | ENUM attribute_list_opt identifier
2700 { typedefTable.makeTypedef( *$3, "enum_type 1" ); }
2701 hide_opt '{' enumerator_list comma_opt '}'
2702 { $$ = DeclarationNode::newEnum( $3, $7, true, false, nullptr, $5 )->addQualifiers( $2 ); }
2703 | ENUM attribute_list_opt typedef_name hide_opt '{' enumerator_list comma_opt '}' // unqualified type name
2704 { $$ = DeclarationNode::newEnum( $3->name, $6, true, false, nullptr, $4 )->addQualifiers( $2 ); }
2705 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2706 {
2707 if ( $3->storageClasses.val != 0 || $3->type->qualifiers.any() ) {
2708 SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2709 }
2710 $$ = DeclarationNode::newEnum( nullptr, $7, true, true, $3 )->addQualifiers( $5 );
2711 }
2712 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // unqualified type name
2713 { SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2714 | ENUM '(' ')' attribute_list_opt '{' enumerator_list comma_opt '}'
2715 {
2716 $$ = DeclarationNode::newEnum( nullptr, $6, true, true )->addQualifiers( $4 );
2717 }
2718 | ENUM '(' ')' attribute_list_opt '!' '{' enumerator_list comma_opt '}' // invalid syntax rule
2719 { SemanticError( yylloc, "syntax error, hiding ('!') the enumerator names of an anonymous enumeration means the names are inaccessible." ); $$ = nullptr; }
2720 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt identifier attribute_list_opt
2721 {
2722 if ( $3 && ($3->storageClasses.any() || $3->type->qualifiers.val != 0 )) {
2723 SemanticError( yylloc, "syntax error, storage-class and CV qualifiers are not meaningful for enumeration constants, which are const." );
2724 }
2725 typedefTable.makeTypedef( *$6, "enum_type 2" );
2726 }
2727 hide_opt '{' enumerator_list comma_opt '}'
2728 {
2729 $$ = DeclarationNode::newEnum( $6, $11, true, true, $3, $9 )->addQualifiers( $5 )->addQualifiers( $7 );
2730 }
2731 | ENUM '(' ')' attribute_list_opt identifier attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2732 {
2733 $$ = DeclarationNode::newEnum( $5, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2734 }
2735 | ENUM '(' cfa_abstract_parameter_declaration ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2736 {
2737 $$ = DeclarationNode::newEnum( $6->name, $10, true, true, $3, $8 )->addQualifiers( $5 )->addQualifiers( $7 );
2738 }
2739 | ENUM '(' ')' attribute_list_opt typedef_name attribute_list_opt hide_opt '{' enumerator_list comma_opt '}'
2740 {
2741 $$ = DeclarationNode::newEnum( $5->name, $9, true, true, nullptr, $7 )->addQualifiers( $4 )->addQualifiers( $6 );
2742 }
2743 | enum_type_nobody
2744 ;
2745
2746hide_opt:
2747 // empty
2748 { $$ = EnumHiding::Visible; }
2749 | '!'
2750 { $$ = EnumHiding::Hide; }
2751 ;
2752
2753enum_type_nobody: // enum - {...}
2754 ENUM attribute_list_opt identifier
2755 {
2756 typedefTable.makeTypedef( *$3, "enum_type_nobody 1" );
2757 $$ = DeclarationNode::newEnum( $3, nullptr, false, false )->addQualifiers( $2 );
2758 }
2759 | ENUM attribute_list_opt type_name
2760 {
2761 typedefTable.makeTypedef( *$3->type->symbolic.name, "enum_type_nobody 2" );
2762 $$ = DeclarationNode::newEnum( $3->type->symbolic.name, nullptr, false, false )->addQualifiers( $2 );
2763 }
2764 ;
2765
2766enumerator_list:
2767 visible_hide_opt identifier_or_type_name enumerator_value_opt
2768 { $$ = DeclarationNode::newEnumValueGeneric( $2, $3 ); }
2769 | INLINE type_name
2770 { $$ = DeclarationNode::newEnumInLine( *$2->type->symbolic.name ); }
2771 | enumerator_list ',' visible_hide_opt identifier_or_type_name enumerator_value_opt
2772 { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( $4, $5 ) ); }
2773 | enumerator_list ',' INLINE type_name enumerator_value_opt
2774 { $$ = $1->appendList( DeclarationNode::newEnumValueGeneric( new string("inline"), nullptr ) ); }
2775 ;
2776
2777visible_hide_opt:
2778 hide_opt
2779 | '^'
2780 { $$ = EnumHiding::Visible; }
2781 ;
2782
2783enumerator_value_opt:
2784 // empty
2785 { $$ = nullptr; }
2786 | '=' constant_expression { $$ = new InitializerNode( $2 ); }
2787 | '=' '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $3, true ); }
2788 // | simple_assignment_operator initializer
2789 // { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2790 ;
2791
2792cfa_parameter_ellipsis_list_opt: // CFA, abstract + real
2793 // empty
2794 { $$ = DeclarationNode::newBasicType( DeclarationNode::Void ); }
2795 | ELLIPSIS
2796 { $$ = nullptr; }
2797 | cfa_abstract_parameter_list
2798 | cfa_parameter_list
2799 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list
2800 { $$ = $1->appendList( $5 ); }
2801 | cfa_abstract_parameter_list pop ',' push ELLIPSIS
2802 { $$ = $1->addVarArgs(); }
2803 | cfa_parameter_list pop ',' push ELLIPSIS
2804 { $$ = $1->addVarArgs(); }
2805 ;
2806
2807cfa_parameter_list: // CFA
2808 // To obtain LR(1) between cfa_parameter_list and cfa_abstract_tuple, the last cfa_abstract_parameter_list is
2809 // factored out from cfa_parameter_list, flattening the rules to get lookahead to the ']'.
2810 cfa_parameter_declaration
2811 | cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2812 { $$ = $1->appendList( $5 ); }
2813 | cfa_parameter_list pop ',' push cfa_parameter_declaration
2814 { $$ = $1->appendList( $5 ); }
2815 | cfa_parameter_list pop ',' push cfa_abstract_parameter_list pop ',' push cfa_parameter_declaration
2816 { $$ = $1->appendList( $5 )->appendList( $9 ); }
2817 ;
2818
2819cfa_abstract_parameter_list: // CFA, new & old style abstract
2820 cfa_abstract_parameter_declaration
2821 | cfa_abstract_parameter_list pop ',' push cfa_abstract_parameter_declaration
2822 { $$ = $1->appendList( $5 ); }
2823 ;
2824
2825parameter_type_list_opt:
2826 // empty
2827 { $$ = nullptr; }
2828 | ELLIPSIS
2829 { $$ = nullptr; }
2830 | parameter_list
2831 | parameter_list ',' ELLIPSIS
2832 { $$ = $1->addVarArgs(); }
2833 ;
2834
2835parameter_list: // abstract + real
2836 abstract_parameter_declaration
2837 | parameter_declaration
2838 | parameter_list ',' abstract_parameter_declaration
2839 { $$ = $1->appendList( $3 ); }
2840 | parameter_list ',' parameter_declaration
2841 { $$ = $1->appendList( $3 ); }
2842 ;
2843
2844// Provides optional identifier names (abstract_declarator/variable_declarator), no initialization, different semantics
2845// for typedef name by using type_parameter_redeclarator instead of typedef_redeclarator, and function prototypes.
2846
2847cfa_parameter_declaration: // CFA, new & old style parameter declaration
2848 parameter_declaration
2849 | cfa_identifier_parameter_declarator_no_tuple identifier_or_type_name default_initializer_opt
2850 { $$ = $1->addName( $2 ); }
2851 | cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2852 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2853 { $$ = $1->addName( $2 ); }
2854 | type_qualifier_list cfa_abstract_tuple identifier_or_type_name default_initializer_opt
2855 { $$ = $2->addName( $3 )->addQualifiers( $1 ); }
2856 | cfa_function_specifier
2857 ;
2858
2859cfa_abstract_parameter_declaration: // CFA, new & old style parameter declaration
2860 abstract_parameter_declaration
2861 | cfa_identifier_parameter_declarator_no_tuple
2862 | cfa_abstract_tuple
2863 // To obtain LR(1), these rules must be duplicated here (see cfa_abstract_declarator).
2864 | type_qualifier_list cfa_abstract_tuple
2865 { $$ = $2->addQualifiers( $1 ); }
2866 | cfa_abstract_function
2867 ;
2868
2869parameter_declaration:
2870 // No SUE declaration in parameter list.
2871 declaration_specifier_nobody identifier_parameter_declarator default_initializer_opt
2872 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2873 | declaration_specifier_nobody type_parameter_redeclarator default_initializer_opt
2874 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2875 ;
2876
2877abstract_parameter_declaration:
2878 declaration_specifier_nobody default_initializer_opt
2879 { $$ = $1->addInitializer( $2 ? new InitializerNode( $2 ) : nullptr ); }
2880 | declaration_specifier_nobody abstract_parameter_declarator default_initializer_opt
2881 { $$ = $2->addType( $1 )->addInitializer( $3 ? new InitializerNode( $3 ) : nullptr ); }
2882 ;
2883
2884// ISO/IEC 9899:1999 Section 6.9.1(6) : "An identifier declared as a typedef name shall not be redeclared as a
2885// parameter." Because the scope of the K&R-style parameter-list sees the typedef first, the following is based only on
2886// identifiers. The ANSI-style parameter-list can redefine a typedef name.
2887
2888identifier_list: // K&R-style parameter list => no types
2889 identifier
2890 { $$ = DeclarationNode::newName( $1 ); }
2891 | identifier_list ',' identifier
2892 { $$ = $1->appendList( DeclarationNode::newName( $3 ) ); }
2893 ;
2894
2895identifier_or_type_name:
2896 identifier
2897 | TYPEDEFname
2898 | TYPEGENname
2899 ;
2900
2901type_no_function: // sizeof, alignof, cast (constructor)
2902 cfa_abstract_declarator_tuple // CFA
2903 | type_specifier // cannot be type_specifier_nobody, e.g., (struct S {}){} is a thing
2904 | type_specifier abstract_declarator
2905 { $$ = $2->addType( $1 ); }
2906 ;
2907
2908type: // typeof, assertion
2909 type_no_function
2910 | cfa_abstract_function // CFA
2911 ;
2912
2913initializer_opt:
2914 // empty
2915 { $$ = nullptr; }
2916 | simple_assignment_operator initializer { $$ = $1 == OperKinds::Assign ? $2 : $2->set_maybeConstructed( false ); }
2917 | '=' VOID { $$ = new InitializerNode( true ); }
2918 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2919 ;
2920
2921initializer:
2922 assignment_expression { $$ = new InitializerNode( $1 ); }
2923 | '{' initializer_list_opt comma_opt '}' { $$ = new InitializerNode( $2, true ); }
2924 ;
2925
2926initializer_list_opt:
2927 // empty
2928 { $$ = nullptr; }
2929 | initializer
2930 | designation initializer { $$ = $2->set_designators( $1 ); }
2931 | initializer_list_opt ',' initializer { $$ = (InitializerNode *)( $1->set_last( $3 ) ); }
2932 | initializer_list_opt ',' designation initializer { $$ = (InitializerNode *)($1->set_last( $4->set_designators( $3 ) )); }
2933 ;
2934
2935// There is an unreconcileable parsing problem between C99 and CFA with respect to designators. The problem is use of
2936// '=' to separator the designator from the initializer value, as in:
2937//
2938// int x[10] = { [1] = 3 };
2939//
2940// The string "[1] = 3" can be parsed as a designator assignment or a tuple assignment. To disambiguate this case, CFA
2941// changes the syntax from "=" to ":" as the separator between the designator and initializer. GCC does uses ":" for
2942// field selection. The optional use of the "=" in GCC, or in this case ":", cannot be supported either due to
2943// shift/reduce conflicts
2944
2945designation:
2946 designator_list ':' // C99, CFA uses ":" instead of "="
2947 | identifier_at ':' // GCC, field name
2948 { $$ = new ExpressionNode( build_varref( yylloc, $1 ) ); }
2949 ;
2950
2951designator_list: // C99
2952 designator
2953 | designator_list designator
2954 { $$ = (ExpressionNode *)($1->set_last( $2 )); }
2955 //| designator_list designator { $$ = new ExpressionNode( $1, $2 ); }
2956 ;
2957
2958designator:
2959 '.' identifier_at // C99, field name
2960 { $$ = new ExpressionNode( build_varref( yylloc, $2 ) ); }
2961 | '[' push assignment_expression pop ']' // C99, single array element
2962 // assignment_expression used instead of constant_expression because of shift/reduce conflicts with tuple.
2963 { $$ = $3; }
2964 | '[' push subrange pop ']' // CFA, multiple array elements
2965 { $$ = $3; }
2966 | '[' push constant_expression ELLIPSIS constant_expression pop ']' // GCC, multiple array elements
2967 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $3 ), maybeMoveBuild( $5 ) ) ); }
2968 | '.' '[' push field_name_list pop ']' // CFA, tuple field selector
2969 { $$ = $4; }
2970 ;
2971
2972// The CFA type system is based on parametric polymorphism, the ability to declare functions with type parameters,
2973// rather than an object-oriented type system. This required four groups of extensions:
2974//
2975// Overloading: function, data, and operator identifiers may be overloaded.
2976//
2977// Type declarations: "otype" is used to generate new types for declaring objects. Similarly, "dtype" is used for object
2978// and incomplete types, and "ftype" is used for function types. Type declarations with initializers provide
2979// definitions of new types. Type declarations with storage class "extern" provide opaque types.
2980//
2981// Polymorphic functions: A forall clause declares a type parameter. The corresponding argument is inferred at the call
2982// site. A polymorphic function is not a template; it is a function, with an address and a type.
2983//
2984// Specifications and Assertions: Specifications are collections of declarations parameterized by one or more
2985// types. They serve many of the purposes of abstract classes, and specification hierarchies resemble subclass
2986// hierarchies. Unlike classes, they can define relationships between types. Assertions declare that a type or
2987// types provide the operations declared by a specification. Assertions are normally used to declare requirements
2988// on type arguments of polymorphic functions.
2989
2990type_parameter_list: // CFA
2991 type_parameter
2992 | type_parameter_list ',' type_parameter
2993 { $$ = $1->appendList( $3 ); }
2994 ;
2995
2996type_initializer_opt: // CFA
2997 // empty
2998 { $$ = nullptr; }
2999 | '=' type
3000 { $$ = $2; }
3001 ;
3002
3003type_parameter: // CFA
3004 type_class identifier_or_type_name
3005 {
3006 typedefTable.addToScope( *$2, TYPEDEFname, "type_parameter 1" );
3007 if ( $1 == ast::TypeDecl::Otype ) { SemanticError( yylloc, "otype keyword is deprecated, use T " ); }
3008 if ( $1 == ast::TypeDecl::Dtype ) { SemanticError( yylloc, "dtype keyword is deprecated, use T &" ); }
3009 if ( $1 == ast::TypeDecl::Ttype ) { SemanticError( yylloc, "ttype keyword is deprecated, use T ..." ); }
3010 }
3011 type_initializer_opt assertion_list_opt
3012 { $$ = DeclarationNode::newTypeParam( $1, $2 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3013 | identifier_or_type_name new_type_class
3014 { typedefTable.addToScope( *$1, TYPEDEFname, "type_parameter 2" ); }
3015 type_initializer_opt assertion_list_opt
3016 { $$ = DeclarationNode::newTypeParam( $2, $1 )->addTypeInitializer( $4 )->addAssertions( $5 ); }
3017 | '[' identifier_or_type_name ']'
3018 {
3019 typedefTable.addToScope( *$2, TYPEDIMname, "type_parameter 3" );
3020 $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dimension, $2 );
3021 }
3022 // | type_specifier identifier_parameter_declarator
3023 | assertion_list
3024 { $$ = DeclarationNode::newTypeParam( ast::TypeDecl::Dtype, new string( DeclarationNode::anonymous.newName() ) )->addAssertions( $1 ); }
3025 ;
3026
3027new_type_class: // CFA
3028 // empty
3029 { $$ = ast::TypeDecl::Otype; }
3030 | '&'
3031 { $$ = ast::TypeDecl::Dtype; }
3032 | '*'
3033 { $$ = ast::TypeDecl::DStype; } // dtype + sized
3034 // | '(' '*' ')'
3035 // { $$ = ast::TypeDecl::Ftype; }
3036 | ELLIPSIS
3037 { $$ = ast::TypeDecl::Ttype; }
3038 ;
3039
3040type_class: // CFA
3041 OTYPE
3042 { $$ = ast::TypeDecl::Otype; }
3043 | DTYPE
3044 { $$ = ast::TypeDecl::Dtype; }
3045 | FTYPE
3046 { $$ = ast::TypeDecl::Ftype; }
3047 | TTYPE
3048 { $$ = ast::TypeDecl::Ttype; }
3049 ;
3050
3051assertion_list_opt: // CFA
3052 // empty
3053 { $$ = nullptr; }
3054 | assertion_list
3055 ;
3056
3057assertion_list: // CFA
3058 assertion
3059 | assertion_list assertion
3060 { $$ = $1->appendList( $2 ); }
3061 ;
3062
3063assertion: // CFA
3064 '|' identifier_or_type_name '(' type_list ')'
3065 { $$ = DeclarationNode::newTraitUse( $2, $4 ); }
3066 | '|' '{' push trait_declaration_list pop '}'
3067 { $$ = $4; }
3068 // | '|' '(' push type_parameter_list pop ')' '{' push trait_declaration_list pop '}' '(' type_list ')'
3069 // { SemanticError( yylloc, "Generic data-type assertion is currently unimplemented." ); $$ = nullptr; }
3070 ;
3071
3072type_list: // CFA
3073 type
3074 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3075 | assignment_expression
3076 | type_list ',' type
3077 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3078 | type_list ',' assignment_expression
3079 { $$ = (ExpressionNode *)( $1->set_last( $3 )); }
3080 ;
3081
3082type_declaring_list: // CFA
3083 OTYPE type_declarator
3084 { $$ = $2; }
3085 | storage_class_list OTYPE type_declarator
3086 { $$ = $3->addQualifiers( $1 ); }
3087 | type_declaring_list ',' type_declarator
3088 { $$ = $1->appendList( $3->copySpecifiers( $1 ) ); }
3089 ;
3090
3091type_declarator: // CFA
3092 type_declarator_name assertion_list_opt
3093 { $$ = $1->addAssertions( $2 ); }
3094 | type_declarator_name assertion_list_opt '=' type
3095 { $$ = $1->addAssertions( $2 )->addType( $4 ); }
3096 ;
3097
3098type_declarator_name: // CFA
3099 identifier_or_type_name
3100 {
3101 typedefTable.addToEnclosingScope( *$1, TYPEDEFname, "type_declarator_name 1" );
3102 $$ = DeclarationNode::newTypeDecl( $1, nullptr );
3103 }
3104 | identifier_or_type_name '(' type_parameter_list ')'
3105 {
3106 typedefTable.addToEnclosingScope( *$1, TYPEGENname, "type_declarator_name 2" );
3107 $$ = DeclarationNode::newTypeDecl( $1, $3 );
3108 }
3109 ;
3110
3111trait_specifier: // CFA
3112 TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' '}'
3113 {
3114 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3115 $$ = DeclarationNode::newTrait( $2, $4, nullptr );
3116 }
3117 | forall TRAIT identifier_or_type_name '{' '}' // alternate
3118 { $$ = DeclarationNode::newTrait( $3, $1, nullptr ); }
3119 | TRAIT identifier_or_type_name '(' type_parameter_list ')' '{' push trait_declaration_list pop '}'
3120 {
3121 SemanticWarning( yylloc, Warning::DeprecTraitSyntax );
3122 $$ = DeclarationNode::newTrait( $2, $4, $8 );
3123 }
3124 | forall TRAIT identifier_or_type_name '{' push trait_declaration_list pop '}' // alternate
3125 { $$ = DeclarationNode::newTrait( $3, $1, $6 ); }
3126 ;
3127
3128trait_declaration_list: // CFA
3129 trait_declaration
3130 | trait_declaration_list pop push trait_declaration
3131 { $$ = $1->appendList( $4 ); }
3132 ;
3133
3134trait_declaration: // CFA
3135 cfa_trait_declaring_list ';'
3136 | trait_declaring_list ';'
3137 ;
3138
3139cfa_trait_declaring_list: // CFA
3140 cfa_variable_specifier
3141 | cfa_function_specifier
3142 | cfa_trait_declaring_list pop ',' push identifier_or_type_name
3143 { $$ = $1->appendList( $1->cloneType( $5 ) ); }
3144 ;
3145
3146trait_declaring_list: // CFA
3147 type_specifier declarator
3148 { $$ = $2->addType( $1 ); }
3149 | trait_declaring_list pop ',' push declarator
3150 { $$ = $1->appendList( $1->cloneBaseType( $5 ) ); }
3151 ;
3152
3153// **************************** EXTERNAL DEFINITIONS *****************************
3154
3155translation_unit:
3156 // empty, input file
3157 | external_definition_list
3158 { parseTree = parseTree ? parseTree->appendList( $1 ) : $1; }
3159 ;
3160
3161external_definition_list:
3162 push external_definition pop
3163 { $$ = $2; }
3164 | external_definition_list push external_definition pop
3165 { $$ = $1 ? $1->appendList( $3 ) : $3; }
3166 ;
3167
3168external_definition_list_opt:
3169 // empty
3170 { $$ = nullptr; }
3171 | external_definition_list
3172 ;
3173
3174up:
3175 { typedefTable.up( forall ); forall = false; }
3176 ;
3177
3178down:
3179 { typedefTable.down(); }
3180 ;
3181
3182external_definition:
3183 DIRECTIVE
3184 { $$ = DeclarationNode::newDirectiveStmt( new StatementNode( build_directive( yylloc, $1 ) ) ); }
3185 | declaration
3186 {
3187 // Variable declarations of anonymous types requires creating a unique type-name across multiple translation
3188 // unit, which is a dubious task, especially because C uses name rather than structural typing; hence it is
3189 // disallowed at the moment.
3190 if ( $1->linkage == ast::Linkage::Cforall && ! $1->storageClasses.is_static &&
3191 $1->type && $1->type->kind == TypeData::AggregateInst ) {
3192 if ( $1->type->aggInst.aggregate->kind == TypeData::Enum && $1->type->aggInst.aggregate->enumeration.anon ) {
3193 SemanticError( yylloc, "extern anonymous enumeration is currently unimplemented." ); $$ = nullptr;
3194 } else if ( $1->type->aggInst.aggregate->aggregate.anon ) { // handles struct or union
3195 SemanticError( yylloc, "extern anonymous struct/union is currently unimplemented." ); $$ = nullptr;
3196 }
3197 }
3198 }
3199 | IDENTIFIER IDENTIFIER
3200 { IdentifierBeforeIdentifier( *$1.str, *$2.str, " declaration" ); $$ = nullptr; }
3201 | IDENTIFIER type_qualifier // invalid syntax rule
3202 { IdentifierBeforeType( *$1.str, "type qualifier" ); $$ = nullptr; }
3203 | IDENTIFIER storage_class // invalid syntax rule
3204 { IdentifierBeforeType( *$1.str, "storage class" ); $$ = nullptr; }
3205 | IDENTIFIER basic_type_name // invalid syntax rule
3206 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3207 | IDENTIFIER TYPEDEFname // invalid syntax rule
3208 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3209 | IDENTIFIER TYPEGENname // invalid syntax rule
3210 { IdentifierBeforeType( *$1.str, "type" ); $$ = nullptr; }
3211 | external_function_definition
3212 | EXTENSION external_definition // GCC, multiple __extension__ allowed, meaning unknown
3213 {
3214 distExt( $2 ); // mark all fields in list
3215 $$ = $2;
3216 }
3217 | ASM '(' string_literal ')' ';' // GCC, global assembler statement
3218 { $$ = DeclarationNode::newAsmStmt( new StatementNode( build_asm( yylloc, false, $3, nullptr ) ) ); }
3219 | EXTERN STRINGliteral
3220 {
3221 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3222 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3223 }
3224 up external_definition down
3225 {
3226 linkage = linkageStack.top();
3227 linkageStack.pop();
3228 $$ = $5;
3229 }
3230 | EXTERN STRINGliteral // C++-style linkage specifier
3231 {
3232 linkageStack.push( linkage ); // handle nested extern "C"/"Cforall"
3233 linkage = ast::Linkage::update( yylloc, linkage, $2 );
3234 }
3235 '{' up external_definition_list_opt down '}'
3236 {
3237 linkage = linkageStack.top();
3238 linkageStack.pop();
3239 $$ = $6;
3240 }
3241 // global distribution
3242 | type_qualifier_list
3243 {
3244 if ( $1->type->qualifiers.any() ) {
3245 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3246 }
3247 if ( $1->type->forall ) forall = true; // remember generic type
3248 }
3249 '{' up external_definition_list_opt down '}' // CFA, namespace
3250 {
3251 distQual( $5, $1 );
3252 forall = false;
3253 $$ = $5;
3254 }
3255 | declaration_qualifier_list
3256 {
3257 if ( $1->type && $1->type->qualifiers.any() ) {
3258 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3259 }
3260 if ( $1->type && $1->type->forall ) forall = true; // remember generic type
3261 }
3262 '{' up external_definition_list_opt down '}' // CFA, namespace
3263 {
3264 distQual( $5, $1 );
3265 forall = false;
3266 $$ = $5;
3267 }
3268 | declaration_qualifier_list type_qualifier_list
3269 {
3270 if ( ($1->type && $1->type->qualifiers.any()) || ($2->type && $2->type->qualifiers.any()) ) {
3271 SemanticError( yylloc, "syntax error, CV qualifiers cannot be distributed; only storage-class and forall qualifiers." );
3272 }
3273 if ( ($1->type && $1->type->forall) || ($2->type && $2->type->forall) ) forall = true; // remember generic type
3274 }
3275 '{' up external_definition_list_opt down '}' // CFA, namespace
3276 {
3277 distQual( $6, $1->addQualifiers( $2 ) );
3278 forall = false;
3279 $$ = $6;
3280 }
3281 ;
3282
3283external_function_definition:
3284 function_definition
3285 // These rules are a concession to the "implicit int" type_specifier because there is a significant amount of
3286 // legacy code with global functions missing the type-specifier for the return type, and assuming "int".
3287 // Parsing is possible because function_definition does not appear in the context of an expression (nested
3288 // functions preclude this concession, i.e., all nested function must have a return type). A function prototype
3289 // declaration must still have a type_specifier. OBSOLESCENT (see 1)
3290 | function_declarator compound_statement
3291 { $$ = $1->addFunctionBody( $2 ); }
3292 | KR_function_declarator KR_parameter_list_opt compound_statement
3293 { $$ = $1->addOldDeclList( $2 )->addFunctionBody( $3 ); }
3294 ;
3295
3296with_clause_opt:
3297 // empty
3298 { $$ = nullptr; forall = false; }
3299 | WITH '(' tuple_expression_list ')' attribute_list_opt
3300 {
3301 $$ = $3; forall = false;
3302 if ( $5 ) {
3303 SemanticError( yylloc, "syntax error, attributes cannot be associated with function body. Move attribute(s) before \"with\" clause." );
3304 $$ = nullptr;
3305 } // if
3306 }
3307 ;
3308
3309function_definition:
3310 cfa_function_declaration with_clause_opt compound_statement // CFA
3311 {
3312 // Add the function body to the last identifier in the function definition list, i.e., foo3:
3313 // [const double] foo1(), foo2( int ), foo3( double ) { return 3.0; }
3314 $1->get_last()->addFunctionBody( $3, $2 );
3315 $$ = $1;
3316 }
3317 | declaration_specifier function_declarator with_clause_opt compound_statement
3318 {
3319 rebindForall( $1, $2 );
3320 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3321 }
3322 | declaration_specifier function_type_redeclarator with_clause_opt compound_statement
3323 {
3324 rebindForall( $1, $2 );
3325 $$ = $2->addFunctionBody( $4, $3 )->addType( $1 );
3326 }
3327 // handles default int return type, OBSOLESCENT (see 1)
3328 | type_qualifier_list function_declarator with_clause_opt compound_statement
3329 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3330 // handles default int return type, OBSOLESCENT (see 1)
3331 | declaration_qualifier_list function_declarator with_clause_opt compound_statement
3332 { $$ = $2->addFunctionBody( $4, $3 )->addQualifiers( $1 ); }
3333 // handles default int return type, OBSOLESCENT (see 1)
3334 | declaration_qualifier_list type_qualifier_list function_declarator with_clause_opt compound_statement
3335 { $$ = $3->addFunctionBody( $5, $4 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3336
3337 // Old-style K&R function definition, OBSOLESCENT (see 4)
3338 | declaration_specifier KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3339 {
3340 rebindForall( $1, $2 );
3341 $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addType( $1 );
3342 }
3343 // handles default int return type, OBSOLESCENT (see 1)
3344 | type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3345 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3346 // handles default int return type, OBSOLESCENT (see 1)
3347 | declaration_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3348 { $$ = $2->addOldDeclList( $3 )->addFunctionBody( $5, $4 )->addQualifiers( $1 ); }
3349 // handles default int return type, OBSOLESCENT (see 1)
3350 | declaration_qualifier_list type_qualifier_list KR_function_declarator KR_parameter_list_opt with_clause_opt compound_statement
3351 { $$ = $3->addOldDeclList( $4 )->addFunctionBody( $6, $5 )->addQualifiers( $2 )->addQualifiers( $1 ); }
3352 ;
3353
3354declarator:
3355 variable_declarator
3356 | variable_type_redeclarator
3357 | function_declarator
3358 | function_type_redeclarator
3359 ;
3360
3361subrange:
3362 constant_expression '~' constant_expression // CFA, integer subrange
3363 { $$ = new ExpressionNode( new ast::RangeExpr( yylloc, maybeMoveBuild( $1 ), maybeMoveBuild( $3 ) ) ); }
3364 ;
3365
3366asm_name_opt: // GCC
3367 // empty
3368 { $$ = nullptr; }
3369 | ASM '(' string_literal ')' attribute_list_opt
3370 {
3371 DeclarationNode * name = new DeclarationNode();
3372 name->asmName = maybeMoveBuild( $3 );
3373 $$ = name->addQualifiers( $5 );
3374 }
3375 ;
3376
3377attribute_list_opt: // GCC
3378 // empty
3379 { $$ = nullptr; }
3380 | attribute_list
3381 ;
3382
3383attribute_list: // GCC
3384 attribute
3385 | attribute_list attribute
3386 { $$ = $2->addQualifiers( $1 ); }
3387 ;
3388
3389attribute: // GCC
3390 ATTRIBUTE '(' '(' attribute_name_list ')' ')'
3391 { $$ = $4; }
3392 ;
3393
3394attribute_name_list: // GCC
3395 attribute_name
3396 | attribute_name_list ',' attribute_name
3397 { $$ = $3->addQualifiers( $1 ); }
3398 ;
3399
3400attribute_name: // GCC
3401 // empty
3402 { $$ = nullptr; }
3403 | attr_name
3404 { $$ = DeclarationNode::newAttribute( $1 ); }
3405 | attr_name '(' argument_expression_list_opt ')'
3406 { $$ = DeclarationNode::newAttribute( $1, $3 ); }
3407 ;
3408
3409attr_name: // GCC
3410 IDENTIFIER
3411 | quasi_keyword
3412 | TYPEDEFname
3413 | TYPEGENname
3414 | FALLTHROUGH
3415 { $$ = Token{ new string( "fallthrough" ), { nullptr, -1 } }; }
3416 | CONST
3417 { $$ = Token{ new string( "__const__" ), { nullptr, -1 } }; }
3418 ;
3419
3420// ============================================================================
3421// The following sections are a series of grammar patterns used to parse declarators. Multiple patterns are necessary
3422// because the type of an identifier in wrapped around the identifier in the same form as its usage in an expression, as
3423// in:
3424//
3425// int (*f())[10] { ... };
3426// ... (*f())[3] += 1; // definition mimics usage
3427//
3428// Because these patterns are highly recursive, changes at a lower level in the recursion require copying some or all of
3429// the pattern. Each of these patterns has some subtle variation to ensure correct syntax in a particular context.
3430// ============================================================================
3431
3432// ----------------------------------------------------------------------------
3433// The set of valid declarators before a compound statement for defining a function is less than the set of declarators
3434// to define a variable or function prototype, e.g.:
3435//
3436// valid declaration invalid definition
3437// ----------------- ------------------
3438// int f; int f {}
3439// int *f; int *f {}
3440// int f[10]; int f[10] {}
3441// int (*f)(int); int (*f)(int) {}
3442//
3443// To preclude this syntactic anomaly requires separating the grammar rules for variable and function declarators, hence
3444// variable_declarator and function_declarator.
3445// ----------------------------------------------------------------------------
3446
3447// This pattern parses a declaration of a variable that is not redefining a typedef name. The pattern precludes
3448// declaring an array of functions versus a pointer to an array of functions.
3449
3450paren_identifier:
3451 identifier_at
3452 { $$ = DeclarationNode::newName( $1 ); }
3453 | '(' paren_identifier ')' // redundant parenthesis
3454 { $$ = $2; }
3455 ;
3456
3457variable_declarator:
3458 paren_identifier attribute_list_opt
3459 { $$ = $1->addQualifiers( $2 ); }
3460 | variable_ptr
3461 | variable_array attribute_list_opt
3462 { $$ = $1->addQualifiers( $2 ); }
3463 | variable_function attribute_list_opt
3464 { $$ = $1->addQualifiers( $2 ); }
3465 ;
3466
3467variable_ptr:
3468 ptrref_operator variable_declarator
3469 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3470 | ptrref_operator type_qualifier_list variable_declarator
3471 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3472 | '(' variable_ptr ')' attribute_list_opt // redundant parenthesis
3473 { $$ = $2->addQualifiers( $4 ); }
3474 | '(' attribute_list variable_ptr ')' attribute_list_opt // redundant parenthesis
3475 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3476 ;
3477
3478variable_array:
3479 paren_identifier array_dimension
3480 { $$ = $1->addArray( $2 ); }
3481 | '(' variable_ptr ')' array_dimension
3482 { $$ = $2->addArray( $4 ); }
3483 | '(' attribute_list variable_ptr ')' array_dimension
3484 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3485 | '(' variable_array ')' multi_array_dimension // redundant parenthesis
3486 { $$ = $2->addArray( $4 ); }
3487 | '(' attribute_list variable_array ')' multi_array_dimension // redundant parenthesis
3488 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3489 | '(' variable_array ')' // redundant parenthesis
3490 { $$ = $2; }
3491 | '(' attribute_list variable_array ')' // redundant parenthesis
3492 { $$ = $3->addQualifiers( $2 ); }
3493 ;
3494
3495variable_function:
3496 '(' variable_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3497 { $$ = $2->addParamList( $5 ); }
3498 | '(' attribute_list variable_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3499 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3500 | '(' variable_function ')' // redundant parenthesis
3501 { $$ = $2; }
3502 | '(' attribute_list variable_function ')' // redundant parenthesis
3503 { $$ = $3->addQualifiers( $2 ); }
3504 ;
3505
3506// This pattern parses a function declarator that is not redefining a typedef name. For non-nested functions, there is
3507// no context where a function definition can redefine a typedef name, i.e., the typedef and function name cannot exist
3508// is the same scope. The pattern precludes returning arrays and functions versus pointers to arrays and functions.
3509
3510function_declarator:
3511 function_no_ptr attribute_list_opt
3512 { $$ = $1->addQualifiers( $2 ); }
3513 | function_ptr
3514 | function_array attribute_list_opt
3515 { $$ = $1->addQualifiers( $2 ); }
3516 ;
3517
3518function_no_ptr:
3519 paren_identifier '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3520 { $$ = $1->addParamList( $3 ); }
3521 | '(' function_ptr ')' '(' parameter_type_list_opt ')'
3522 { $$ = $2->addParamList( $5 ); }
3523 | '(' attribute_list function_ptr ')' '(' parameter_type_list_opt ')'
3524 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3525 | '(' function_no_ptr ')' // redundant parenthesis
3526 { $$ = $2; }
3527 | '(' attribute_list function_no_ptr ')' // redundant parenthesis
3528 { $$ = $3->addQualifiers( $2 ); }
3529 ;
3530
3531function_ptr:
3532 ptrref_operator function_declarator
3533 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3534 | ptrref_operator type_qualifier_list function_declarator
3535 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3536 | '(' function_ptr ')' attribute_list_opt
3537 { $$ = $2->addQualifiers( $4 ); }
3538 | '(' attribute_list function_ptr ')' attribute_list_opt
3539 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3540 ;
3541
3542function_array:
3543 '(' function_ptr ')' array_dimension
3544 { $$ = $2->addArray( $4 ); }
3545 | '(' attribute_list function_ptr ')' array_dimension
3546 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3547 | '(' function_array ')' multi_array_dimension // redundant parenthesis
3548 { $$ = $2->addArray( $4 ); }
3549 | '(' attribute_list function_array ')' multi_array_dimension // redundant parenthesis
3550 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3551 | '(' function_array ')' // redundant parenthesis
3552 { $$ = $2; }
3553 | '(' attribute_list function_array ')' // redundant parenthesis
3554 { $$ = $3->addQualifiers( $2 ); }
3555 ;
3556
3557// This pattern parses an old-style K&R function declarator (OBSOLESCENT, see 4)
3558//
3559// f( a, b, c ) int a, *b, c[]; {}
3560//
3561// that is not redefining a typedef name (see function_declarator for additional comments). The pattern precludes
3562// returning arrays and functions versus pointers to arrays and functions.
3563
3564KR_function_declarator:
3565 KR_function_no_ptr
3566 | KR_function_ptr
3567 | KR_function_array
3568 ;
3569
3570KR_function_no_ptr:
3571 paren_identifier '(' identifier_list ')' // function_declarator handles empty parameter
3572 { $$ = $1->addIdList( $3 ); }
3573 | '(' KR_function_ptr ')' '(' parameter_type_list_opt ')'
3574 { $$ = $2->addParamList( $5 ); }
3575 | '(' attribute_list KR_function_ptr ')' '(' parameter_type_list_opt ')'
3576 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3577 | '(' KR_function_no_ptr ')' // redundant parenthesis
3578 { $$ = $2; }
3579 | '(' attribute_list KR_function_no_ptr ')' // redundant parenthesis
3580 { $$ = $3->addQualifiers( $2 ); }
3581 ;
3582
3583KR_function_ptr:
3584 ptrref_operator KR_function_declarator
3585 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3586 | ptrref_operator type_qualifier_list KR_function_declarator
3587 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3588 | '(' KR_function_ptr ')'
3589 { $$ = $2; }
3590 | '(' attribute_list KR_function_ptr ')'
3591 { $$ = $3->addQualifiers( $2 ); }
3592 ;
3593
3594KR_function_array:
3595 '(' KR_function_ptr ')' array_dimension
3596 { $$ = $2->addArray( $4 ); }
3597 | '(' attribute_list KR_function_ptr ')' array_dimension
3598 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3599 | '(' KR_function_array ')' multi_array_dimension // redundant parenthesis
3600 { $$ = $2->addArray( $4 ); }
3601 | '(' attribute_list KR_function_array ')' multi_array_dimension // redundant parenthesis
3602 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3603 | '(' KR_function_array ')' // redundant parenthesis
3604 { $$ = $2; }
3605 | '(' attribute_list KR_function_array ')' // redundant parenthesis
3606 { $$ = $3->addQualifiers( $2 ); }
3607 ;
3608
3609// This pattern parses a declaration for a variable that redefines a type name, e.g.:
3610//
3611// typedef int foo;
3612// {
3613// int foo; // redefine typedef name in new scope
3614// }
3615
3616paren_type:
3617 typedef_name
3618 {
3619 // hide type name in enclosing scope by variable name
3620 typedefTable.addToEnclosingScope( *$1->name, IDENTIFIER, "paren_type" );
3621 }
3622 | '(' paren_type ')'
3623 { $$ = $2; }
3624 ;
3625
3626variable_type_redeclarator:
3627 paren_type attribute_list_opt
3628 { $$ = $1->addQualifiers( $2 ); }
3629 | variable_type_ptr
3630 | variable_type_array attribute_list_opt
3631 { $$ = $1->addQualifiers( $2 ); }
3632 | variable_type_function attribute_list_opt
3633 { $$ = $1->addQualifiers( $2 ); }
3634 ;
3635
3636variable_type_ptr:
3637 ptrref_operator variable_type_redeclarator
3638 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3639 | ptrref_operator type_qualifier_list variable_type_redeclarator
3640 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3641 | '(' variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3642 { $$ = $2->addQualifiers( $4 ); }
3643 | '(' attribute_list variable_type_ptr ')' attribute_list_opt // redundant parenthesis
3644 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3645 ;
3646
3647variable_type_array:
3648 paren_type array_dimension
3649 { $$ = $1->addArray( $2 ); }
3650 | '(' variable_type_ptr ')' array_dimension
3651 { $$ = $2->addArray( $4 ); }
3652 | '(' attribute_list variable_type_ptr ')' array_dimension
3653 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3654 | '(' variable_type_array ')' multi_array_dimension // redundant parenthesis
3655 { $$ = $2->addArray( $4 ); }
3656 | '(' attribute_list variable_type_array ')' multi_array_dimension // redundant parenthesis
3657 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3658 | '(' variable_type_array ')' // redundant parenthesis
3659 { $$ = $2; }
3660 | '(' attribute_list variable_type_array ')' // redundant parenthesis
3661 { $$ = $3->addQualifiers( $2 ); }
3662 ;
3663
3664variable_type_function:
3665 '(' variable_type_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3666 { $$ = $2->addParamList( $5 ); }
3667 | '(' attribute_list variable_type_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3668 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3669 | '(' variable_type_function ')' // redundant parenthesis
3670 { $$ = $2; }
3671 | '(' attribute_list variable_type_function ')' // redundant parenthesis
3672 { $$ = $3->addQualifiers( $2 ); }
3673 ;
3674
3675// This pattern parses a declaration for a function prototype that redefines a type name. It precludes declaring an
3676// array of functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to
3677// arrays and functions.
3678
3679function_type_redeclarator:
3680 function_type_no_ptr attribute_list_opt
3681 { $$ = $1->addQualifiers( $2 ); }
3682 | function_type_ptr
3683 | function_type_array attribute_list_opt
3684 { $$ = $1->addQualifiers( $2 ); }
3685 ;
3686
3687function_type_no_ptr:
3688 paren_type '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3689 { $$ = $1->addParamList( $3 ); }
3690 | '(' function_type_ptr ')' '(' parameter_type_list_opt ')'
3691 { $$ = $2->addParamList( $5 ); }
3692 | '(' attribute_list function_type_ptr ')' '(' parameter_type_list_opt ')'
3693 { $$ = $3->addQualifiers( $2 )->addParamList( $6 ); }
3694 | '(' function_type_no_ptr ')' // redundant parenthesis
3695 { $$ = $2; }
3696 | '(' attribute_list function_type_no_ptr ')' // redundant parenthesis
3697 { $$ = $3->addQualifiers( $2 ); }
3698 ;
3699
3700function_type_ptr:
3701 ptrref_operator function_type_redeclarator
3702 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3703 | ptrref_operator type_qualifier_list function_type_redeclarator
3704 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3705 | '(' function_type_ptr ')' attribute_list_opt
3706 { $$ = $2->addQualifiers( $4 ); }
3707 | '(' attribute_list function_type_ptr ')' attribute_list_opt
3708 { $$ = $3->addQualifiers( $2 )->addQualifiers( $5 ); }
3709 ;
3710
3711function_type_array:
3712 '(' function_type_ptr ')' array_dimension
3713 { $$ = $2->addArray( $4 ); }
3714 | '(' attribute_list function_type_ptr ')' array_dimension
3715 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3716 | '(' function_type_array ')' multi_array_dimension // redundant parenthesis
3717 { $$ = $2->addArray( $4 ); }
3718 | '(' attribute_list function_type_array ')' multi_array_dimension // redundant parenthesis
3719 { $$ = $3->addQualifiers( $2 )->addArray( $5 ); }
3720 | '(' function_type_array ')' // redundant parenthesis
3721 { $$ = $2; }
3722 | '(' attribute_list function_type_array ')' // redundant parenthesis
3723 { $$ = $3->addQualifiers( $2 ); }
3724 ;
3725
3726// This pattern parses a declaration for a parameter variable of a function prototype or actual that is not redefining a
3727// typedef name and allows the C99 array options, which can only appear in a parameter list. The pattern precludes
3728// declaring an array of functions versus a pointer to an array of functions, and returning arrays and functions versus
3729// pointers to arrays and functions.
3730
3731identifier_parameter_declarator:
3732 paren_identifier attribute_list_opt
3733 { $$ = $1->addQualifiers( $2 ); }
3734 | '&' MUTEX paren_identifier attribute_list_opt
3735 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( ast::CV::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3736 | identifier_parameter_ptr
3737 | identifier_parameter_array attribute_list_opt
3738 { $$ = $1->addQualifiers( $2 ); }
3739 | identifier_parameter_function attribute_list_opt
3740 { $$ = $1->addQualifiers( $2 ); }
3741 ;
3742
3743identifier_parameter_ptr:
3744 ptrref_operator identifier_parameter_declarator
3745 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3746 | ptrref_operator type_qualifier_list identifier_parameter_declarator
3747 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3748 | '(' identifier_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3749 { $$ = $2->addQualifiers( $4 ); }
3750 ;
3751
3752identifier_parameter_array:
3753 paren_identifier array_parameter_dimension
3754 { $$ = $1->addArray( $2 ); }
3755 | '(' identifier_parameter_ptr ')' array_dimension
3756 { $$ = $2->addArray( $4 ); }
3757 | '(' identifier_parameter_array ')' multi_array_dimension // redundant parenthesis
3758 { $$ = $2->addArray( $4 ); }
3759 | '(' identifier_parameter_array ')' // redundant parenthesis
3760 { $$ = $2; }
3761 ;
3762
3763identifier_parameter_function:
3764 paren_identifier '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3765 { $$ = $1->addParamList( $3 ); }
3766 | '(' identifier_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3767 { $$ = $2->addParamList( $5 ); }
3768 | '(' identifier_parameter_function ')' // redundant parenthesis
3769 { $$ = $2; }
3770 ;
3771
3772// This pattern parses a declaration for a parameter variable or function prototype that is redefining a typedef name,
3773// e.g.:
3774//
3775// typedef int foo;
3776// forall( otype T ) struct foo;
3777// int f( int foo ); // redefine typedef name in new scope
3778//
3779// and allows the C99 array options, which can only appear in a parameter list.
3780
3781type_parameter_redeclarator:
3782 typedef_name attribute_list_opt
3783 { $$ = $1->addQualifiers( $2 ); }
3784 | '&' MUTEX typedef_name attribute_list_opt
3785 { $$ = $3->addPointer( DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( ast::CV::Mutex ), OperKinds::AddressOf ) )->addQualifiers( $4 ); }
3786 | type_parameter_ptr
3787 | type_parameter_array attribute_list_opt
3788 { $$ = $1->addQualifiers( $2 ); }
3789 | type_parameter_function attribute_list_opt
3790 { $$ = $1->addQualifiers( $2 ); }
3791 ;
3792
3793typedef_name:
3794 TYPEDEFname
3795 { $$ = DeclarationNode::newName( $1 ); }
3796 | TYPEGENname
3797 { $$ = DeclarationNode::newName( $1 ); }
3798 ;
3799
3800type_parameter_ptr:
3801 ptrref_operator type_parameter_redeclarator
3802 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3803 | ptrref_operator type_qualifier_list type_parameter_redeclarator
3804 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3805 | '(' type_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3806 { $$ = $2->addQualifiers( $4 ); }
3807 ;
3808
3809type_parameter_array:
3810 typedef_name array_parameter_dimension
3811 { $$ = $1->addArray( $2 ); }
3812 | '(' type_parameter_ptr ')' array_parameter_dimension
3813 { $$ = $2->addArray( $4 ); }
3814 ;
3815
3816type_parameter_function:
3817 typedef_name '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3818 { $$ = $1->addParamList( $3 ); }
3819 | '(' type_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3820 { $$ = $2->addParamList( $5 ); }
3821 ;
3822
3823// This pattern parses a declaration of an abstract variable or function prototype, i.e., there is no identifier to
3824// which the type applies, e.g.:
3825//
3826// sizeof( int );
3827// sizeof( int * );
3828// sizeof( int [10] );
3829// sizeof( int (*)() );
3830// sizeof( int () );
3831//
3832// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3833// and functions versus pointers to arrays and functions.
3834
3835abstract_declarator:
3836 abstract_ptr
3837 | abstract_array attribute_list_opt
3838 { $$ = $1->addQualifiers( $2 ); }
3839 | abstract_function attribute_list_opt
3840 { $$ = $1->addQualifiers( $2 ); }
3841 ;
3842
3843abstract_ptr:
3844 ptrref_operator
3845 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3846 | ptrref_operator type_qualifier_list
3847 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3848 | ptrref_operator abstract_declarator
3849 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3850 | ptrref_operator type_qualifier_list abstract_declarator
3851 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3852 | '(' abstract_ptr ')' attribute_list_opt
3853 { $$ = $2->addQualifiers( $4 ); }
3854 ;
3855
3856abstract_array:
3857 array_dimension
3858 | '(' abstract_ptr ')' array_dimension
3859 { $$ = $2->addArray( $4 ); }
3860 | '(' abstract_array ')' multi_array_dimension // redundant parenthesis
3861 { $$ = $2->addArray( $4 ); }
3862 | '(' abstract_array ')' // redundant parenthesis
3863 { $$ = $2; }
3864 ;
3865
3866abstract_function:
3867 '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3868 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3869 | '(' abstract_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3870 { $$ = $2->addParamList( $5 ); }
3871 | '(' abstract_function ')' // redundant parenthesis
3872 { $$ = $2; }
3873 ;
3874
3875array_dimension:
3876 // Only the first dimension can be empty.
3877 '[' ']'
3878 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
3879 | '[' ']' multi_array_dimension
3880 { $$ = DeclarationNode::newArray( nullptr, nullptr, false )->addArray( $3 ); }
3881 // Cannot use constant_expression because of tuples => semantic check
3882 | '[' push assignment_expression pop ',' comma_expression ']' // CFA
3883 { $$ = DeclarationNode::newArray( $3, nullptr, false )->addArray( DeclarationNode::newArray( $6, nullptr, false ) ); }
3884 // { SemanticError( yylloc, "New array dimension is currently unimplemented." ); $$ = nullptr; }
3885 | '[' push array_type_list pop ']' // CFA
3886 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3887 | multi_array_dimension
3888 ;
3889
3890array_type_list:
3891 basic_type_name
3892 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3893 | type_name
3894 { $$ = new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $1 ) ) ); }
3895 | assignment_expression upupeq assignment_expression
3896 | array_type_list ',' basic_type_name
3897 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3898 | array_type_list ',' type_name
3899 { $$ = (ExpressionNode *)($1->set_last( new ExpressionNode( new ast::TypeExpr( yylloc, maybeMoveBuildType( $3 ) ) ) )); }
3900 | array_type_list ',' assignment_expression upupeq assignment_expression
3901 ;
3902
3903upupeq:
3904 '~'
3905 { $$ = OperKinds::LThan; }
3906 | ErangeUpEq
3907 { $$ = OperKinds::LEThan; }
3908 ;
3909
3910multi_array_dimension:
3911 '[' push assignment_expression pop ']'
3912 { $$ = DeclarationNode::newArray( $3, nullptr, false ); }
3913 | '[' push '*' pop ']' // C99
3914 { $$ = DeclarationNode::newVarArray( 0 ); }
3915 | multi_array_dimension '[' push assignment_expression pop ']'
3916 { $$ = $1->addArray( DeclarationNode::newArray( $4, nullptr, false ) ); }
3917 | multi_array_dimension '[' push '*' pop ']' // C99
3918 { $$ = $1->addArray( DeclarationNode::newVarArray( 0 ) ); }
3919 ;
3920
3921// This pattern parses a declaration of a parameter abstract variable or function prototype, i.e., there is no
3922// identifier to which the type applies, e.g.:
3923//
3924// int f( int ); // not handled here
3925// int f( int * ); // abstract function-prototype parameter; no parameter name specified
3926// int f( int (*)() ); // abstract function-prototype parameter; no parameter name specified
3927// int f( int (int) ); // abstract function-prototype parameter; no parameter name specified
3928//
3929// The pattern precludes declaring an array of functions versus a pointer to an array of functions, and returning arrays
3930// and functions versus pointers to arrays and functions. In addition, the pattern handles the
3931// special meaning of parenthesis around a typedef name:
3932//
3933// ISO/IEC 9899:1999 Section 6.7.5.3(11) : "In a parameter declaration, a single typedef name in
3934// parentheses is taken to be an abstract declarator that specifies a function with a single parameter,
3935// not as redundant parentheses around the identifier."
3936//
3937// For example:
3938//
3939// typedef float T;
3940// int f( int ( T [5] ) ); // see abstract_parameter_declarator
3941// int g( int ( T ( int ) ) ); // see abstract_parameter_declarator
3942// int f( int f1( T a[5] ) ); // see identifier_parameter_declarator
3943// int g( int g1( T g2( int p ) ) ); // see identifier_parameter_declarator
3944//
3945// In essence, a '(' immediately to the left of typedef name, T, is interpreted as starting a parameter type list, and
3946// not as redundant parentheses around a redeclaration of T. Finally, the pattern also precludes declaring an array of
3947// functions versus a pointer to an array of functions, and returning arrays and functions versus pointers to arrays and
3948// functions.
3949
3950abstract_parameter_declarator_opt:
3951 // empty
3952 { $$ = nullptr; }
3953 | abstract_parameter_declarator
3954 ;
3955
3956abstract_parameter_declarator:
3957 abstract_parameter_ptr
3958 | '&' MUTEX attribute_list_opt
3959 { $$ = DeclarationNode::newPointer( DeclarationNode::newTypeQualifier( ast::CV::Mutex ), OperKinds::AddressOf )->addQualifiers( $3 ); }
3960 | abstract_parameter_array attribute_list_opt
3961 { $$ = $1->addQualifiers( $2 ); }
3962 | abstract_parameter_function attribute_list_opt
3963 { $$ = $1->addQualifiers( $2 ); }
3964 ;
3965
3966abstract_parameter_ptr:
3967 ptrref_operator
3968 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
3969 | ptrref_operator type_qualifier_list
3970 { $$ = DeclarationNode::newPointer( $2, $1 ); }
3971 | ptrref_operator abstract_parameter_declarator
3972 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
3973 | ptrref_operator type_qualifier_list abstract_parameter_declarator
3974 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
3975 | '(' abstract_parameter_ptr ')' attribute_list_opt // redundant parenthesis
3976 { $$ = $2->addQualifiers( $4 ); }
3977 ;
3978
3979abstract_parameter_array:
3980 array_parameter_dimension
3981 | '(' abstract_parameter_ptr ')' array_parameter_dimension
3982 { $$ = $2->addArray( $4 ); }
3983 | '(' abstract_parameter_array ')' multi_array_dimension // redundant parenthesis
3984 { $$ = $2->addArray( $4 ); }
3985 | '(' abstract_parameter_array ')' // redundant parenthesis
3986 { $$ = $2; }
3987 ;
3988
3989abstract_parameter_function:
3990 '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3991 { $$ = DeclarationNode::newFunction( nullptr, nullptr, $2, nullptr ); }
3992 | '(' abstract_parameter_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
3993 { $$ = $2->addParamList( $5 ); }
3994 | '(' abstract_parameter_function ')' // redundant parenthesis
3995 { $$ = $2; }
3996 ;
3997
3998array_parameter_dimension:
3999 // Only the first dimension can be empty or have qualifiers.
4000 array_parameter_1st_dimension
4001 | array_parameter_1st_dimension multi_array_dimension
4002 { $$ = $1->addArray( $2 ); }
4003 | multi_array_dimension
4004 ;
4005
4006// The declaration of an array parameter has additional syntax over arrays in normal variable declarations:
4007//
4008// ISO/IEC 9899:1999 Section 6.7.5.2(1) : "The optional type qualifiers and the keyword static shall appear only in
4009// a declaration of a function parameter with an array type, and then only in the outermost array type derivation."
4010
4011array_parameter_1st_dimension:
4012 '[' ']'
4013 { $$ = DeclarationNode::newArray( nullptr, nullptr, false ); }
4014 // multi_array_dimension handles the '[' '*' ']' case
4015 | '[' push type_qualifier_list '*' pop ']' // remaining C99
4016 { $$ = DeclarationNode::newVarArray( $3 ); }
4017 | '[' push type_qualifier_list pop ']'
4018 { $$ = DeclarationNode::newArray( nullptr, $3, false ); }
4019 // multi_array_dimension handles the '[' assignment_expression ']' case
4020 | '[' push type_qualifier_list assignment_expression pop ']'
4021 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4022 | '[' push STATIC type_qualifier_list_opt assignment_expression pop ']'
4023 { $$ = DeclarationNode::newArray( $5, $4, true ); }
4024 | '[' push type_qualifier_list STATIC assignment_expression pop ']'
4025 { $$ = DeclarationNode::newArray( $5, $3, true ); }
4026 ;
4027
4028// This pattern parses a declaration of an abstract variable, but does not allow "int ()" for a function pointer.
4029//
4030// struct S {
4031// int;
4032// int *;
4033// int [10];
4034// int (*)();
4035// };
4036
4037variable_abstract_declarator:
4038 variable_abstract_ptr
4039 | variable_abstract_array attribute_list_opt
4040 { $$ = $1->addQualifiers( $2 ); }
4041 | variable_abstract_function attribute_list_opt
4042 { $$ = $1->addQualifiers( $2 ); }
4043 ;
4044
4045variable_abstract_ptr:
4046 ptrref_operator
4047 { $$ = DeclarationNode::newPointer( nullptr, $1 ); }
4048 | ptrref_operator type_qualifier_list
4049 { $$ = DeclarationNode::newPointer( $2, $1 ); }
4050 | ptrref_operator variable_abstract_declarator
4051 { $$ = $2->addPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4052 | ptrref_operator type_qualifier_list variable_abstract_declarator
4053 { $$ = $3->addPointer( DeclarationNode::newPointer( $2, $1 ) ); }
4054 | '(' variable_abstract_ptr ')' attribute_list_opt // redundant parenthesis
4055 { $$ = $2->addQualifiers( $4 ); }
4056 ;
4057
4058variable_abstract_array:
4059 array_dimension
4060 | '(' variable_abstract_ptr ')' array_dimension
4061 { $$ = $2->addArray( $4 ); }
4062 | '(' variable_abstract_array ')' multi_array_dimension // redundant parenthesis
4063 { $$ = $2->addArray( $4 ); }
4064 | '(' variable_abstract_array ')' // redundant parenthesis
4065 { $$ = $2; }
4066 ;
4067
4068variable_abstract_function:
4069 '(' variable_abstract_ptr ')' '(' parameter_type_list_opt ')' // empty parameter list OBSOLESCENT (see 3)
4070 { $$ = $2->addParamList( $5 ); }
4071 | '(' variable_abstract_function ')' // redundant parenthesis
4072 { $$ = $2; }
4073 ;
4074
4075// This pattern parses a new-style declaration for a parameter variable or function prototype that is either an
4076// identifier or typedef name and allows the C99 array options, which can only appear in a parameter list.
4077
4078cfa_identifier_parameter_declarator_tuple: // CFA
4079 cfa_identifier_parameter_declarator_no_tuple
4080 | cfa_abstract_tuple
4081 | type_qualifier_list cfa_abstract_tuple
4082 { $$ = $2->addQualifiers( $1 ); }
4083 ;
4084
4085cfa_identifier_parameter_declarator_no_tuple: // CFA
4086 cfa_identifier_parameter_ptr
4087 | cfa_identifier_parameter_array
4088 ;
4089
4090cfa_identifier_parameter_ptr: // CFA
4091 // No SUE declaration in parameter list.
4092 ptrref_operator type_specifier_nobody
4093 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4094 | type_qualifier_list ptrref_operator type_specifier_nobody
4095 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4096 | ptrref_operator cfa_abstract_function
4097 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4098 | type_qualifier_list ptrref_operator cfa_abstract_function
4099 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4100 | ptrref_operator cfa_identifier_parameter_declarator_tuple
4101 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4102 | type_qualifier_list ptrref_operator cfa_identifier_parameter_declarator_tuple
4103 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4104 ;
4105
4106cfa_identifier_parameter_array: // CFA
4107 // Only the first dimension can be empty or have qualifiers. Empty dimension must be factored out due to
4108 // shift/reduce conflict with new-style empty (void) function return type.
4109 '[' ']' type_specifier_nobody
4110 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4111 | cfa_array_parameter_1st_dimension type_specifier_nobody
4112 { $$ = $2->addNewArray( $1 ); }
4113 | '[' ']' multi_array_dimension type_specifier_nobody
4114 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4115 | cfa_array_parameter_1st_dimension multi_array_dimension type_specifier_nobody
4116 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4117 | multi_array_dimension type_specifier_nobody
4118 { $$ = $2->addNewArray( $1 ); }
4119
4120 | '[' ']' cfa_identifier_parameter_ptr
4121 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4122 | cfa_array_parameter_1st_dimension cfa_identifier_parameter_ptr
4123 { $$ = $2->addNewArray( $1 ); }
4124 | '[' ']' multi_array_dimension cfa_identifier_parameter_ptr
4125 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4126 | cfa_array_parameter_1st_dimension multi_array_dimension cfa_identifier_parameter_ptr
4127 { $$ = $3->addNewArray( $2 )->addNewArray( $1 ); }
4128 | multi_array_dimension cfa_identifier_parameter_ptr
4129 { $$ = $2->addNewArray( $1 ); }
4130 ;
4131
4132cfa_array_parameter_1st_dimension:
4133 '[' push type_qualifier_list '*' pop ']' // remaining C99
4134 { $$ = DeclarationNode::newVarArray( $3 ); }
4135 | '[' push type_qualifier_list assignment_expression pop ']'
4136 { $$ = DeclarationNode::newArray( $4, $3, false ); }
4137 | '[' push declaration_qualifier_list assignment_expression pop ']'
4138 // declaration_qualifier_list must be used because of shift/reduce conflict with
4139 // assignment_expression, so a semantic check is necessary to preclude them as a type_qualifier cannot
4140 // appear in this context.
4141 { $$ = DeclarationNode::newArray( $4, $3, true ); }
4142 | '[' push declaration_qualifier_list type_qualifier_list assignment_expression pop ']'
4143 { $$ = DeclarationNode::newArray( $5, $4->addQualifiers( $3 ), true ); }
4144 ;
4145
4146// This pattern parses a new-style declaration of an abstract variable or function prototype, i.e., there is no
4147// identifier to which the type applies, e.g.:
4148//
4149// [int] f( int ); // abstract variable parameter; no parameter name specified
4150// [int] f( [int] (int) ); // abstract function-prototype parameter; no parameter name specified
4151//
4152// These rules need LR(3):
4153//
4154// cfa_abstract_tuple identifier_or_type_name
4155// '[' cfa_parameter_list ']' identifier_or_type_name '(' cfa_parameter_ellipsis_list_opt ')'
4156//
4157// since a function return type can be syntactically identical to a tuple type:
4158//
4159// [int, int] t;
4160// [int, int] f( int );
4161//
4162// Therefore, it is necessary to look at the token after identifier_or_type_name to know when to reduce
4163// cfa_abstract_tuple. To make this LR(1), several rules have to be flattened (lengthened) to allow the necessary
4164// lookahead. To accomplish this, cfa_abstract_declarator has an entry point without tuple, and tuple declarations are
4165// duplicated when appearing with cfa_function_specifier.
4166
4167cfa_abstract_declarator_tuple: // CFA
4168 cfa_abstract_tuple
4169 | type_qualifier_list cfa_abstract_tuple
4170 { $$ = $2->addQualifiers( $1 ); }
4171 | cfa_abstract_declarator_no_tuple
4172 ;
4173
4174cfa_abstract_declarator_no_tuple: // CFA
4175 cfa_abstract_ptr
4176 | cfa_abstract_array
4177 ;
4178
4179cfa_abstract_ptr: // CFA
4180 ptrref_operator type_specifier
4181 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4182 | type_qualifier_list ptrref_operator type_specifier
4183 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4184 | ptrref_operator cfa_abstract_function
4185 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4186 | type_qualifier_list ptrref_operator cfa_abstract_function
4187 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4188 | ptrref_operator cfa_abstract_declarator_tuple
4189 { $$ = $2->addNewPointer( DeclarationNode::newPointer( nullptr, $1 ) ); }
4190 | type_qualifier_list ptrref_operator cfa_abstract_declarator_tuple
4191 { $$ = $3->addNewPointer( DeclarationNode::newPointer( $1, $2 ) ); }
4192 ;
4193
4194cfa_abstract_array: // CFA
4195 // Only the first dimension can be empty. Empty dimension must be factored out due to shift/reduce conflict with
4196 // empty (void) function return type.
4197 '[' ']' type_specifier
4198 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4199 | '[' ']' multi_array_dimension type_specifier
4200 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4201 | multi_array_dimension type_specifier
4202 { $$ = $2->addNewArray( $1 ); }
4203 | '[' ']' cfa_abstract_ptr
4204 { $$ = $3->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4205 | '[' ']' multi_array_dimension cfa_abstract_ptr
4206 { $$ = $4->addNewArray( $3 )->addNewArray( DeclarationNode::newArray( nullptr, nullptr, false ) ); }
4207 | multi_array_dimension cfa_abstract_ptr
4208 { $$ = $2->addNewArray( $1 ); }
4209 ;
4210
4211cfa_abstract_tuple: // CFA
4212 '[' push cfa_abstract_parameter_list pop ']'
4213 { $$ = DeclarationNode::newTuple( $3 ); }
4214 | '[' push type_specifier_nobody ELLIPSIS pop ']'
4215 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4216 | '[' push type_specifier_nobody ELLIPSIS constant_expression pop ']'
4217 { SemanticError( yylloc, "Tuple array currently unimplemented." ); $$ = nullptr; }
4218 ;
4219
4220cfa_abstract_function: // CFA
4221// '[' ']' '(' cfa_parameter_ellipsis_list_opt ')'
4222// { $$ = DeclarationNode::newFunction( nullptr, DeclarationNode::newTuple( nullptr ), $4, nullptr ); }
4223 cfa_abstract_tuple '(' push cfa_parameter_ellipsis_list_opt pop ')'
4224 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4225 | cfa_function_return '(' push cfa_parameter_ellipsis_list_opt pop ')'
4226 { $$ = DeclarationNode::newFunction( nullptr, $1, $4, nullptr ); }
4227 ;
4228
4229// 1) ISO/IEC 9899:1999 Section 6.7.2(2) : "At least one type specifier shall be given in the declaration specifiers in
4230// each declaration, and in the specifier-qualifier list in each structure declaration and type name."
4231//
4232// 2) ISO/IEC 9899:1999 Section 6.11.5(1) : "The placement of a storage-class specifier other than at the beginning of
4233// the declaration specifiers in a declaration is an obsolescent feature."
4234//
4235// 3) ISO/IEC 9899:1999 Section 6.11.6(1) : "The use of function declarators with empty parentheses (not
4236// prototype-format parameter type declarators) is an obsolescent feature."
4237//
4238// 4) ISO/IEC 9899:1999 Section 6.11.7(1) : "The use of function definitions with separate parameter identifier and
4239// declaration lists (not prototype-format parameter type and identifier declarators) is an obsolescent feature.
4240
4241// ************************ MISCELLANEOUS ********************************
4242
4243comma_opt: // redundant comma
4244 // empty
4245 | ','
4246 ;
4247
4248default_initializer_opt:
4249 // empty
4250 { $$ = nullptr; }
4251 | '=' assignment_expression
4252 { $$ = $2; }
4253 ;
4254
4255%%
4256
4257// ----end of grammar----
4258
4259// Local Variables: //
4260// mode: c++ //
4261// tab-width: 4 //
4262// compile-command: "make install" //
4263// End: //
Note: See TracBrowser for help on using the repository browser.