source: src/Parser/lex.ll @ d48e529

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newwith_gc
Last change on this file since d48e529 was d48e529, checked in by Rob Schluntz <rschlunt@…>, 5 years ago

Begin to introduce support for yylloc in the parser and extend CodeLocation? to include start column and end column/line number information

  • Property mode set to 100644
File size: 17.8 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Sun Sep 10 22:29:15 2017
13 * Update Count     : 620
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25//**************************** Includes and Defines ****************************
26
27unsigned int column = 0;                                                                // position of the end of the last token parsed
28#define YY_USER_ACTION yylloc.first_line = yylineno; yylloc.first_column = column; column += yyleng; yylloc.last_column = column; yylloc.last_line = yylineno; yylloc.filename = yyfilename ? yyfilename : "";                          // trigger before each matching rule's action
29
30#include <string>
31#include <cstdio>                                                                               // FILENAME_MAX
32using namespace std;
33
34#include "ParseNode.h"
35#include "TypedefTable.h"
36
37char *yyfilename;
38string *strtext;                                                                                // accumulate parts of character and string constant value
39
40#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
41#define RETURN_VAL(x)           yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
42#define RETURN_CHAR(x)          yylval.tok.str = nullptr; RETURN_LOCN( x )
43#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
44
45#define WHITE_RETURN(x)         // do nothing
46#define NEWLINE_RETURN()        column = 0; WHITE_RETURN( '\n' )
47#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
48#define NAMEDOP_RETURN(x)       RETURN_CHAR( x )                        // multichar operator, with a name
49#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
50#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
51#define QKEYWORD_RETURN(x)      typedefTable.isKind( yytext ); RETURN_VAL(x); // quasi-keyword
52#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
53#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
54
55void rm_underscore() {
56        // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
57        yyleng = 0;
58        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
59                if ( yytext[i] == '`' ) {
60                        // copy user suffix
61                        for ( ; yytext[i] != '\0'; i += 1 ) {
62                                yytext[yyleng] = yytext[i];
63                                yyleng += 1;
64                        } // for
65                        break;
66                } // if
67                if ( yytext[i] != '_' ) {
68                        yytext[yyleng] = yytext[i];
69                        yyleng += 1;
70                } // if
71        } // for
72        yytext[yyleng] = '\0';
73}
74
75// Stop warning due to incorrectly generated flex code.
76#pragma GCC diagnostic ignored "-Wsign-compare"
77%}
78
79octal [0-7]
80nonzero [1-9]
81decimal [0-9]
82hex [0-9a-fA-F]
83universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
84
85                                // identifier, GCC: $ in identifier
86identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
87
88                                // attribute identifier, GCC: $ in identifier
89attr_identifier "@"{identifier}
90
91user_suffix_opt ("`"{identifier})?
92
93                                // numeric constants, CFA: '_' in constant
94hex_quad {hex}("_"?{hex}){3}
95length ("ll"|"LL"|[lL])|("hh"|"HH"|[hH])
96integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]))?{user_suffix_opt}
97
98octal_digits ({octal})|({octal}({octal}|"_")*{octal})
99octal_prefix "0""_"?
100octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
101
102nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
103decimal_constant {nonzero_digits}{integer_suffix_opt}
104
105hex_digits ({hex})|({hex}({hex}|"_")*{hex})
106hex_prefix "0"[xX]"_"?
107hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
108
109                                // GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
110exponent "_"?[eE]"_"?[+-]?{decimal_digits}
111floating_suffix ([fFdDlL]?[iI]?)|([iI][lLfFdD])
112floating_suffix_opt ("_"?({floating_suffix}|"DL"))?{user_suffix_opt}
113decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
114floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
115floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
116floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
117
118binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
119hex_floating_suffix_opt ("_"?({floating_suffix}))?{user_suffix_opt}
120hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
121hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
122
123                                // character escape sequence, GCC: \e => esc character
124simple_escape "\\"[abefnrtv'"?\\]
125                                // ' stop editor highlighting
126octal_escape "\\"{octal}("_"?{octal}){0,2}
127hex_escape "\\""x""_"?{hex_digits}
128escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
129cwide_prefix "L"|"U"|"u"
130swide_prefix {cwide_prefix}|"u8"
131
132                                // display/white-space characters
133h_tab [\011]
134form_feed [\014]
135v_tab [\013]
136c_return [\015]
137h_white [ ]|{h_tab}
138
139                                // overloadable operators
140op_unary_only "~"|"!"
141op_unary_binary "+"|"-"|"*"
142op_unary_pre_post "++"|"--"
143op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
144
145op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
146op_binary_over {op_unary_binary}|{op_binary_only}
147                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
148                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
149
150%x COMMENT
151%x BKQUOTE
152%x QUOTE
153%x STRING
154
155%%
156                                /* line directives */
157^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
158        /* " stop editor highlighting */
159        static char filename[FILENAME_MAX];                                     // temporarily store current source-file name
160        char *end_num;
161        char *begin_string, *end_string;
162        long lineno, length;
163        lineno = strtol( yytext + 1, &end_num, 0 );
164        begin_string = strchr( end_num, '"' );
165        if ( begin_string ) {                                                           // file name ?
166                end_string = strchr( begin_string + 1, '"' );   // look for ending delimiter
167                assert( end_string );                                                   // closing quote ?
168                length = end_string - begin_string - 1;                 // file-name length without quotes or sentinel
169                assert( length < FILENAME_MAX );                                // room for sentinel ?
170                memcpy( &filename, begin_string + 1, length );  // copy file name from yytext
171                filename[ length ] = '\0';                                              // terminate string with sentinel
172                //cout << "file " << filename << " line " << lineno << endl;
173                yylineno = lineno;
174                yyfilename = filename;
175        } // if
176}
177
178                                /* ignore preprocessor directives (for now) */
179^{h_white}*"#"[^\n]*"\n" ;
180
181                                /* ignore C style comments (ALSO HANDLED BY CPP) */
182"/*"                    { BEGIN COMMENT; }
183<COMMENT>.|\n   ;
184<COMMENT>"*/"   { BEGIN 0; }
185
186                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
187"//"[^\n]*"\n"  ;
188
189                                /* ignore whitespace */
190{h_white}+              { WHITE_RETURN(' '); }
191({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
192({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
193
194                                /* keywords */
195_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
196_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
197__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
198__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
199asm                             { KEYWORD_RETURN(ASM); }
200__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
201__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
202_At                             { KEYWORD_RETURN(AT); }                                 // CFA
203_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
204__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
205__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
206auto                    { KEYWORD_RETURN(AUTO); }
207_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
208break                   { KEYWORD_RETURN(BREAK); }
209case                    { KEYWORD_RETURN(CASE); }
210catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
211catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
212char                    { KEYWORD_RETURN(CHAR); }
213choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
214_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
215__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
216__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
217const                   { KEYWORD_RETURN(CONST); }
218__const                 { KEYWORD_RETURN(CONST); }                              // GCC
219__const__               { KEYWORD_RETURN(CONST); }                              // GCC
220continue                { KEYWORD_RETURN(CONTINUE); }
221coroutine               { KEYWORD_RETURN(COROUTINE); }                  // CFA
222default                 { KEYWORD_RETURN(DEFAULT); }
223disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
224do                              { KEYWORD_RETURN(DO); }
225double                  { KEYWORD_RETURN(DOUBLE); }
226dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
227else                    { KEYWORD_RETURN(ELSE); }
228enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
229enum                    { KEYWORD_RETURN(ENUM); }
230__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
231extern                  { KEYWORD_RETURN(EXTERN); }
232fallthrough             { KEYWORD_RETURN(FALLTHRU); }                   // CFA
233fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
234finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
235float                   { KEYWORD_RETURN(FLOAT); }
236__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
237for                             { KEYWORD_RETURN(FOR); }
238forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
239fortran                 { KEYWORD_RETURN(FORTRAN); }
240ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
241_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
242goto                    { KEYWORD_RETURN(GOTO); }
243if                              { KEYWORD_RETURN(IF); }
244_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
245__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
246__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
247inline                  { KEYWORD_RETURN(INLINE); }                             // C99
248__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
249__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
250int                             { KEYWORD_RETURN(INT); }
251__int128                { KEYWORD_RETURN(INT); }                                // GCC
252__int128_t              { KEYWORD_RETURN(INT); }                                // GCC
253__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
254long                    { KEYWORD_RETURN(LONG); }
255monitor                 { KEYWORD_RETURN(MONITOR); }                    // CFA
256mutex                   { KEYWORD_RETURN(MUTEX); }                              // CFA
257_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
258__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
259one_t                   { NUMERIC_RETURN(ONE_T); }                              // CFA
260otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
261register                { KEYWORD_RETURN(REGISTER); }
262restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
263__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
264__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
265return                  { KEYWORD_RETURN(RETURN); }
266short                   { KEYWORD_RETURN(SHORT); }
267signed                  { KEYWORD_RETURN(SIGNED); }
268__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
269__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
270sizeof                  { KEYWORD_RETURN(SIZEOF); }
271static                  { KEYWORD_RETURN(STATIC); }
272_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
273struct                  { KEYWORD_RETURN(STRUCT); }
274switch                  { KEYWORD_RETURN(SWITCH); }
275thread                  { KEYWORD_RETURN(THREAD); }                             // C11
276_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
277throw                   { KEYWORD_RETURN(THROW); }                              // CFA
278throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
279timeout                 { QKEYWORD_RETURN(TIMEOUT); }                   // CFA
280trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
281try                             { KEYWORD_RETURN(TRY); }                                // CFA
282ttype                   { KEYWORD_RETURN(TTYPE); }                              // CFA
283typedef                 { KEYWORD_RETURN(TYPEDEF); }
284typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
285__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
286__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
287__uint128_t             { KEYWORD_RETURN(INT); }                                // GCC
288union                   { KEYWORD_RETURN(UNION); }
289unsigned                { KEYWORD_RETURN(UNSIGNED); }
290__builtin_va_list { KEYWORD_RETURN(VALIST); }                   // GCC
291virtual                 { KEYWORD_RETURN(VIRTUAL); }                    // CFA
292void                    { KEYWORD_RETURN(VOID); }
293volatile                { KEYWORD_RETURN(VOLATILE); }
294__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
295__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
296waitfor                 { KEYWORD_RETURN(WAITFOR); }
297or                              { QKEYWORD_RETURN(WOR); }                               // CFA
298when                    { KEYWORD_RETURN(WHEN); }
299while                   { KEYWORD_RETURN(WHILE); }
300with                    { KEYWORD_RETURN(WITH); }                               // CFA
301zero_t                  { NUMERIC_RETURN(ZERO_T); }                             // CFA
302
303                                /* identifier */
304{identifier}    { IDENTIFIER_RETURN(); }
305{attr_identifier} { ATTRIBUTE_RETURN(); }
306"`"                             { BEGIN BKQUOTE; }
307<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
308<BKQUOTE>"`"    { BEGIN 0; }
309
310                                /* numeric constants */
311{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
312{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
313{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
314{floating_decimal}      { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
315{floating_fraction}     { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
316{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
317{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
318
319                                /* character constant, allows empty value */
320({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
321<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
322<QUOTE>['\n]{user_suffix_opt}   { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
323                                /* ' stop editor highlighting */
324
325                                /* string constant */
326({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
327<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
328<STRING>["\n]{user_suffix_opt}  { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
329                                /* " stop editor highlighting */
330
331                                /* common character/string constant */
332<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
333<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
334<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
335
336                                /* punctuation */
337"@"                             { ASCIIOP_RETURN(); }
338"["                             { ASCIIOP_RETURN(); }
339"]"                             { ASCIIOP_RETURN(); }
340"("                             { ASCIIOP_RETURN(); }
341")"                             { ASCIIOP_RETURN(); }
342"{"                             { ASCIIOP_RETURN(); }
343"}"                             { ASCIIOP_RETURN(); }
344","                             { ASCIIOP_RETURN(); }                                   // also operator
345":"                             { ASCIIOP_RETURN(); }
346";"                             { ASCIIOP_RETURN(); }
347"."                             { ASCIIOP_RETURN(); }                                   // also operator
348"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
349
350                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
351"<:"                    { RETURN_VAL('['); }
352":>"                    { RETURN_VAL(']'); }
353"<%"                    { RETURN_VAL('{'); }
354"%>"                    { RETURN_VAL('}'); }
355
356                                /* operators */
357"!"                             { ASCIIOP_RETURN(); }
358"+"                             { ASCIIOP_RETURN(); }
359"-"                             { ASCIIOP_RETURN(); }
360"*"                             { ASCIIOP_RETURN(); }
361"\\"                    { ASCIIOP_RETURN(); }                                   // CFA, exponentiation
362"/"                             { ASCIIOP_RETURN(); }
363"%"                             { ASCIIOP_RETURN(); }
364"^"                             { ASCIIOP_RETURN(); }
365"~"                             { ASCIIOP_RETURN(); }
366"&"                             { ASCIIOP_RETURN(); }
367"|"                             { ASCIIOP_RETURN(); }
368"<"                             { ASCIIOP_RETURN(); }
369">"                             { ASCIIOP_RETURN(); }
370"="                             { ASCIIOP_RETURN(); }
371"?"                             { ASCIIOP_RETURN(); }
372
373"++"                    { NAMEDOP_RETURN(ICR); }
374"--"                    { NAMEDOP_RETURN(DECR); }
375"=="                    { NAMEDOP_RETURN(EQ); }
376"!="                    { NAMEDOP_RETURN(NE); }
377"<<"                    { NAMEDOP_RETURN(LS); }
378">>"                    { NAMEDOP_RETURN(RS); }
379"<="                    { NAMEDOP_RETURN(LE); }
380">="                    { NAMEDOP_RETURN(GE); }
381"&&"                    { NAMEDOP_RETURN(ANDAND); }
382"||"                    { NAMEDOP_RETURN(OROR); }
383"->"                    { NAMEDOP_RETURN(ARROW); }
384"+="                    { NAMEDOP_RETURN(PLUSassign); }
385"-="                    { NAMEDOP_RETURN(MINUSassign); }
386"\\="                   { NAMEDOP_RETURN(EXPassign); }                  // CFA, exponentiation
387"*="                    { NAMEDOP_RETURN(MULTassign); }
388"/="                    { NAMEDOP_RETURN(DIVassign); }
389"%="                    { NAMEDOP_RETURN(MODassign); }
390"&="                    { NAMEDOP_RETURN(ANDassign); }
391"|="                    { NAMEDOP_RETURN(ORassign); }
392"^="                    { NAMEDOP_RETURN(ERassign); }
393"<<="                   { NAMEDOP_RETURN(LSassign); }
394">>="                   { NAMEDOP_RETURN(RSassign); }
395
396"@="                    { NAMEDOP_RETURN(ATassign); }                   // CFA
397
398                                /* CFA, operator identifier */
399{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
400"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
401"^?{}"                  { IDENTIFIER_RETURN(); }
402"?`"{identifier} { IDENTIFIER_RETURN(); }                               // unit operator
403"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
404        /*
405          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"  can be
406          lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
407          e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
408          a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
409          reparsing the trailing operator identifier.  Otherwise a space is needed between the unary operator and operator
410          identifier to disambiguate this common case.
411
412          A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers.  The ambiguity
413          occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
414          look-ahead for the routine-call parameter-list to disambiguate.  However, the dereference operator must have a
415          parameter/argument to dereference *?(...).  Hence, always interpreting the string *?() as * ?() does not preclude
416          any meaningful program.
417
418          The remaining cases are with the increment/decrement operators and conditional expression:
419
420          i++? ...(...);
421          i?++ ...(...);
422
423          requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
424      incorrect expression (juxtaposed identifiers).  Therefore, it is necessary to disambiguate these cases with a
425      space:
426
427          i++ ? i : 0;
428          i? ++i : 0;
429        */
430{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
431        // 1 or 2 character unary operator ?
432        int i = yytext[1] == '?' ? 1 : 2;
433        yyless( i );            // put back characters up to first '?'
434        if ( i > 1 ) {
435                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
436        } else {
437                ASCIIOP_RETURN();
438        } // if
439}
440
441                                /* unknown character */
442.                               { yyerror( "unknown character" ); }
443
444%%
445// ----end of lexer----
446
447void yyerror( const char * errmsg ) {
448        cout << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
449                 << ": " << SemanticError::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
450}
451
452// Local Variables: //
453// mode: c++ //
454// tab-width: 4 //
455// compile-command: "make install" //
456// End: //
Note: See TracBrowser for help on using the repository browser.