source: src/Parser/lex.ll @ ce28c7b

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumwith_gc
Last change on this file since ce28c7b was ce28c7b, checked in by Peter A. Buhr <pabuhr@…>, 6 years ago

remove _At keyword, formatting

  • Property mode set to 100644
File size: 18.1 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Sat Mar 31 22:27:16 2018
13 * Update Count     : 669
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25//**************************** Includes and Defines ****************************
26
27unsigned int column = 0;                                                                // position of the end of the last token parsed
28#define YY_USER_ACTION yylloc.first_line = yylineno; yylloc.first_column = column; column += yyleng; yylloc.last_column = column; yylloc.last_line = yylineno; yylloc.filename = yyfilename ? yyfilename : "";                          // trigger before each matching rule's action
29
30#include <string>
31#include <cstdio>                                                                               // FILENAME_MAX
32using namespace std;
33
34#include "ParseNode.h"
35#include "TypedefTable.h"
36
37char *yyfilename;
38string *strtext;                                                                                // accumulate parts of character and string constant value
39
40#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
41#define RETURN_VAL(x)           yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
42#define RETURN_CHAR(x)          yylval.tok.str = nullptr; RETURN_LOCN( x )
43#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
44
45#define WHITE_RETURN(x)         // do nothing
46#define NEWLINE_RETURN()        column = 0; WHITE_RETURN( '\n' )
47#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
48#define NAMEDOP_RETURN(x)       RETURN_CHAR( x )                        // multichar operator, with a name
49#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
50#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
51#define QKEYWORD_RETURN(x)      typedefTable.isKind( yytext ); RETURN_VAL(x); // quasi-keyword
52#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
53#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
54
55void rm_underscore() {
56        // SKULLDUGGERY: remove underscores (ok to shorten?)
57        yyleng = 0;
58        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {          // copying non-underscore characters to front of string
59                if ( yytext[i] != '_' ) {
60                        yytext[yyleng] = yytext[i];
61                        yyleng += 1;
62                } // if
63        } // for
64        yytext[yyleng] = '\0';
65} // rm_underscore
66
67// Stop warning due to incorrectly generated flex code.
68#pragma GCC diagnostic ignored "-Wsign-compare"
69%}
70
71binary [0-1]
72octal [0-7]
73nonzero [1-9]
74decimal [0-9]
75hex [0-9a-fA-F]
76universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
77
78                                // identifier, GCC: $ in identifier
79identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
80
81                                // attribute identifier, GCC: $ in identifier
82attr_identifier "@"{identifier}
83
84                                // numeric constants, CFA: '_' in constant
85hex_quad {hex}("_"?{hex}){3}
86size_opt (8|16|32|64|128)?
87length ("ll"|"LL"|[lL]{size_opt})|("hh"|"HH"|[hH])
88integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]))?
89
90octal_digits ({octal})|({octal}({octal}|"_")*{octal})
91octal_prefix "0""_"?
92octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
93
94nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
95decimal_constant {nonzero_digits}{integer_suffix_opt}
96
97binary_digits ({binary})|({binary}({binary}|"_")*{binary})
98binary_prefix "0"[bB]"_"?
99binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
100
101hex_digits ({hex})|({hex}({hex}|"_")*{hex})
102hex_prefix "0"[xX]"_"?
103hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
104
105                                // GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
106exponent "_"?[eE]"_"?[+-]?{decimal_digits}
107floating_size 32|64|80|128
108floating_length ([fFdDlL]|[lL]{floating_size})
109floating_suffix ({floating_length}?[iI]?)|([iI]{floating_length})
110floating_suffix_opt ("_"?({floating_suffix}|"DL"))?
111decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
112floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
113floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
114floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
115
116binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
117hex_floating_suffix_opt ("_"?({floating_suffix}))?
118hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
119hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
120
121                                // character escape sequence, GCC: \e => esc character
122simple_escape "\\"[abefnrtv'"?\\]
123                                // ' stop editor highlighting
124octal_escape "\\"{octal}("_"?{octal}){0,2}
125hex_escape "\\""x""_"?{hex_digits}
126escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
127cwide_prefix "L"|"U"|"u"
128swide_prefix {cwide_prefix}|"u8"
129
130                                // display/white-space characters
131h_tab [\011]
132form_feed [\014]
133v_tab [\013]
134c_return [\015]
135h_white [ ]|{h_tab}
136
137                                // overloadable operators
138op_unary_only "~"|"!"
139op_unary_binary "+"|"-"|"*"
140op_unary_pre_post "++"|"--"
141op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
142
143op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
144op_binary_over {op_unary_binary}|{op_binary_only}
145                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
146                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
147
148%x COMMENT
149%x BKQUOTE
150%x QUOTE
151%x STRING
152
153%%
154                                /* line directives */
155^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
156        /* " stop editor highlighting */
157        static char filename[FILENAME_MAX];                                     // temporarily store current source-file name
158        char *end_num;
159        char *begin_string, *end_string;
160        long lineno, length;
161        lineno = strtol( yytext + 1, &end_num, 0 );
162        begin_string = strchr( end_num, '"' );
163        if ( begin_string ) {                                                           // file name ?
164                end_string = strchr( begin_string + 1, '"' );   // look for ending delimiter
165                assert( end_string );                                                   // closing quote ?
166                length = end_string - begin_string - 1;                 // file-name length without quotes or sentinel
167                assert( length < FILENAME_MAX );                                // room for sentinel ?
168                memcpy( &filename, begin_string + 1, length );  // copy file name from yytext
169                filename[ length ] = '\0';                                              // terminate string with sentinel
170                //cout << "file " << filename << " line " << lineno << endl;
171                yylineno = lineno;
172                yyfilename = filename;
173        } // if
174}
175
176                                /* ignore preprocessor directives (for now) */
177^{h_white}*"#"[^\n]*"\n" ;
178
179                                /* ignore C style comments (ALSO HANDLED BY CPP) */
180"/*"                    { BEGIN COMMENT; }
181<COMMENT>.|\n   ;
182<COMMENT>"*/"   { BEGIN 0; }
183
184                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
185"//"[^\n]*"\n"  ;
186
187                                /* ignore whitespace */
188{h_white}+              { WHITE_RETURN(' '); }
189({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
190({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
191
192                                /* keywords */
193_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
194_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
195__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
196__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
197asm                             { KEYWORD_RETURN(ASM); }
198__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
199__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
200_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
201__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
202__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
203auto                    { KEYWORD_RETURN(AUTO); }
204_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
205break                   { KEYWORD_RETURN(BREAK); }
206case                    { KEYWORD_RETURN(CASE); }
207catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
208catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
209char                    { KEYWORD_RETURN(CHAR); }
210choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
211_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
212__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
213__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
214const                   { KEYWORD_RETURN(CONST); }
215__const                 { KEYWORD_RETURN(CONST); }                              // GCC
216__const__               { KEYWORD_RETURN(CONST); }                              // GCC
217continue                { KEYWORD_RETURN(CONTINUE); }
218coroutine               { KEYWORD_RETURN(COROUTINE); }                  // CFA
219default                 { KEYWORD_RETURN(DEFAULT); }
220disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
221do                              { KEYWORD_RETURN(DO); }
222double                  { KEYWORD_RETURN(DOUBLE); }
223dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
224else                    { KEYWORD_RETURN(ELSE); }
225enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
226enum                    { KEYWORD_RETURN(ENUM); }
227__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
228exception               { KEYWORD_RETURN(EXCEPTION); }                  // CFA
229extern                  { KEYWORD_RETURN(EXTERN); }
230fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
231fallthrough             { KEYWORD_RETURN(FALLTHROUGH); }                // CFA
232finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
233float                   { KEYWORD_RETURN(FLOAT); }
234__float80               { KEYWORD_RETURN(FLOAT80); }                    // GCC
235float80                 { KEYWORD_RETURN(FLOAT80); }                    // GCC
236__float128              { KEYWORD_RETURN(FLOAT128); }                   // GCC
237float128                { KEYWORD_RETURN(FLOAT128); }                   // GCC
238for                             { KEYWORD_RETURN(FOR); }
239forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
240fortran                 { KEYWORD_RETURN(FORTRAN); }
241ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
242_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
243goto                    { KEYWORD_RETURN(GOTO); }
244if                              { KEYWORD_RETURN(IF); }
245_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
246__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
247__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
248inline                  { KEYWORD_RETURN(INLINE); }                             // C99
249__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
250__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
251int                             { KEYWORD_RETURN(INT); }
252__int128                { KEYWORD_RETURN(INT128); }                             // GCC
253int128                  { KEYWORD_RETURN(INT128); }                             // GCC
254__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
255long                    { KEYWORD_RETURN(LONG); }
256monitor                 { KEYWORD_RETURN(MONITOR); }                    // CFA
257mutex                   { KEYWORD_RETURN(MUTEX); }                              // CFA
258_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
259__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
260one_t                   { NUMERIC_RETURN(ONE_T); }                              // CFA
261or                              { QKEYWORD_RETURN(WOR); }                               // CFA
262otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
263register                { KEYWORD_RETURN(REGISTER); }
264restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
265__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
266__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
267return                  { KEYWORD_RETURN(RETURN); }
268short                   { KEYWORD_RETURN(SHORT); }
269signed                  { KEYWORD_RETURN(SIGNED); }
270__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
271__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
272sizeof                  { KEYWORD_RETURN(SIZEOF); }
273static                  { KEYWORD_RETURN(STATIC); }
274_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
275struct                  { KEYWORD_RETURN(STRUCT); }
276switch                  { KEYWORD_RETURN(SWITCH); }
277thread                  { KEYWORD_RETURN(THREAD); }                             // C11
278_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
279throw                   { KEYWORD_RETURN(THROW); }                              // CFA
280throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
281timeout                 { QKEYWORD_RETURN(TIMEOUT); }                   // CFA
282trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
283try                             { KEYWORD_RETURN(TRY); }                                // CFA
284ttype                   { KEYWORD_RETURN(TTYPE); }                              // CFA
285typedef                 { KEYWORD_RETURN(TYPEDEF); }
286typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
287__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
288__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
289union                   { KEYWORD_RETURN(UNION); }
290unsigned                { KEYWORD_RETURN(UNSIGNED); }
291__builtin_va_list { KEYWORD_RETURN(VALIST); }                   // GCC
292virtual                 { KEYWORD_RETURN(VIRTUAL); }                    // CFA
293void                    { KEYWORD_RETURN(VOID); }
294volatile                { KEYWORD_RETURN(VOLATILE); }
295__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
296__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
297waitfor                 { KEYWORD_RETURN(WAITFOR); }
298when                    { KEYWORD_RETURN(WHEN); }
299while                   { KEYWORD_RETURN(WHILE); }
300with                    { KEYWORD_RETURN(WITH); }                               // CFA
301zero_t                  { NUMERIC_RETURN(ZERO_T); }                             // CFA
302
303                                /* identifier */
304{identifier}    { IDENTIFIER_RETURN(); }
305"`"{identifier}"`" {                                                                    // CFA
306        yytext[yyleng - 1] = '\0'; yytext += 1;                         // SKULLDUGGERY: remove backquotes (ok to shorten?)
307        IDENTIFIER_RETURN();
308}
309{attr_identifier} { ATTRIBUTE_RETURN(); }
310
311                                /* numeric constants */
312{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
313{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
314{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
315{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
316{floating_decimal}      { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
317{floating_fraction}     { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
318{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
319{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
320
321                                /* character constant, allows empty value */
322({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
323<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
324<QUOTE>['\n]    { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
325                                /* ' stop editor highlighting */
326
327                                /* string constant */
328({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
329<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
330<STRING>["\n]   { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
331                                /* " stop editor highlighting */
332
333                                /* common character/string constant */
334<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
335<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
336<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
337
338                                /* punctuation */
339"@"                             { ASCIIOP_RETURN(); }
340"`"                             { ASCIIOP_RETURN(); }
341"["                             { ASCIIOP_RETURN(); }
342"]"                             { ASCIIOP_RETURN(); }
343"("                             { ASCIIOP_RETURN(); }
344")"                             { ASCIIOP_RETURN(); }
345"{"                             { ASCIIOP_RETURN(); }
346"}"                             { ASCIIOP_RETURN(); }
347","                             { ASCIIOP_RETURN(); }                                   // also operator
348":"                             { ASCIIOP_RETURN(); }
349";"                             { ASCIIOP_RETURN(); }
350"."                             { ASCIIOP_RETURN(); }                                   // also operator
351"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
352
353                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
354"<:"                    { RETURN_VAL('['); }
355":>"                    { RETURN_VAL(']'); }
356"<%"                    { RETURN_VAL('{'); }
357"%>"                    { RETURN_VAL('}'); }
358
359                                /* operators */
360"!"                             { ASCIIOP_RETURN(); }
361"+"                             { ASCIIOP_RETURN(); }
362"-"                             { ASCIIOP_RETURN(); }
363"*"                             { ASCIIOP_RETURN(); }
364"\\"                    { ASCIIOP_RETURN(); }                                   // CFA, exponentiation
365"/"                             { ASCIIOP_RETURN(); }
366"%"                             { ASCIIOP_RETURN(); }
367"^"                             { ASCIIOP_RETURN(); }
368"~"                             { ASCIIOP_RETURN(); }
369"&"                             { ASCIIOP_RETURN(); }
370"|"                             { ASCIIOP_RETURN(); }
371"<"                             { ASCIIOP_RETURN(); }
372">"                             { ASCIIOP_RETURN(); }
373"="                             { ASCIIOP_RETURN(); }
374"?"                             { ASCIIOP_RETURN(); }
375
376"++"                    { NAMEDOP_RETURN(ICR); }
377"--"                    { NAMEDOP_RETURN(DECR); }
378"=="                    { NAMEDOP_RETURN(EQ); }
379"!="                    { NAMEDOP_RETURN(NE); }
380"<<"                    { NAMEDOP_RETURN(LS); }
381">>"                    { NAMEDOP_RETURN(RS); }
382"<="                    { NAMEDOP_RETURN(LE); }
383">="                    { NAMEDOP_RETURN(GE); }
384"&&"                    { NAMEDOP_RETURN(ANDAND); }
385"||"                    { NAMEDOP_RETURN(OROR); }
386"->"                    { NAMEDOP_RETURN(ARROW); }
387"+="                    { NAMEDOP_RETURN(PLUSassign); }
388"-="                    { NAMEDOP_RETURN(MINUSassign); }
389"\\="                   { NAMEDOP_RETURN(EXPassign); }                  // CFA, exponentiation
390"*="                    { NAMEDOP_RETURN(MULTassign); }
391"/="                    { NAMEDOP_RETURN(DIVassign); }
392"%="                    { NAMEDOP_RETURN(MODassign); }
393"&="                    { NAMEDOP_RETURN(ANDassign); }
394"|="                    { NAMEDOP_RETURN(ORassign); }
395"^="                    { NAMEDOP_RETURN(ERassign); }
396"<<="                   { NAMEDOP_RETURN(LSassign); }
397">>="                   { NAMEDOP_RETURN(RSassign); }
398
399"@="                    { NAMEDOP_RETURN(ATassign); }                   // CFA
400
401                                /* CFA, operator identifier */
402{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
403"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
404"^?{}"                  { IDENTIFIER_RETURN(); }
405"?`"{identifier} { IDENTIFIER_RETURN(); }                               // postfix operator
406"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
407        /*
408          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"  can be
409          lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
410          e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
411          a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
412          reparsing the trailing operator identifier.  Otherwise a space is needed between the unary operator and operator
413          identifier to disambiguate this common case.
414
415          A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers.  The ambiguity
416          occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
417          look-ahead for the routine-call parameter-list to disambiguate.  However, the dereference operator must have a
418          parameter/argument to dereference *?(...).  Hence, always interpreting the string *?() as * ?() does not preclude
419          any meaningful program.
420
421          The remaining cases are with the increment/decrement operators and conditional expression:
422
423          i++? ...(...);
424          i?++ ...(...);
425
426          requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
427      incorrect expression (juxtaposed identifiers).  Therefore, it is necessary to disambiguate these cases with a
428      space:
429
430          i++ ? i : 0;
431          i? ++i : 0;
432        */
433{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
434        // 1 or 2 character unary operator ?
435        int i = yytext[1] == '?' ? 1 : 2;
436        yyless( i );            // put back characters up to first '?'
437        if ( i > 1 ) {
438                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
439        } else {
440                ASCIIOP_RETURN();
441        } // if
442}
443
444                                /* unknown character */
445.                               { yyerror( "unknown character" ); }
446
447%%
448// ----end of lexer----
449
450void yyerror( const char * errmsg ) {
451        cout << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
452                 << ": " << ErrorHelpers::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
453}
454
455// Local Variables: //
456// mode: c++ //
457// tab-width: 4 //
458// compile-command: "make install" //
459// End: //
Note: See TracBrowser for help on using the repository browser.