source: src/Parser/lex.ll @ cd623a4

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decaygc_noraiijacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newstringwith_gc
Last change on this file since cd623a4 was cd623a4, checked in by Peter A. Buhr <pabuhr@…>, 9 years ago

constant types, second attempt

  • Property mode set to 100644
File size: 15.0 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Sun Jun  7 07:14:16 2015
13 * Update Count     : 374
14 */
15
16%option yylineno
17
18%{
19// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive
20// have been performed and removed from the source. The only exceptions are preprocessor directives passed to
21// the compiler (e.g., line-number directives) and C/C++ style comments, which are ignored.
22
23//**************************** Includes and Defines ****************************
24
25#include <string>
26
27#include "lex.h"
28#include "ParseNode.h"
29#include "parser.h"                                                                             // YACC generated definitions based on C++ grammar
30
31char *yyfilename;
32std::string *strtext;                                                                   // accumulate parts of character and string constant value
33
34#define WHITE_RETURN(x)                                                                 // do nothing
35#define NEWLINE_RETURN()        WHITE_RETURN('\n')
36#define RETURN_VAL(x)           yylval.tok.str = new std::string( yytext ); \
37                                        yylval.tok.loc.file = yyfilename; \
38                                        yylval.tok.loc.line = yylineno; \
39                                        return(x)
40#define RETURN_STR(x)           yylval.tok.str = strtext; \
41                                        yylval.tok.loc.file = yyfilename; \
42                                        yylval.tok.loc.line = yylineno; \
43                                        return(x)
44
45#define KEYWORD_RETURN(x)       RETURN_VAL(x)                           // keyword
46#define IDENTIFIER_RETURN()     RETURN_VAL((typedefTable.isIdentifier(yytext) ? IDENTIFIER : typedefTable.isTypedef(yytext) ? TYPEDEFname : TYPEGENname))
47//#define ATTRIBUTE_RETURN()    RETURN_VAL((typedefTable.isIdentifier(yytext) ? ATTR_IDENTIFIER : typedefTable.isTypedef(yytext) ? ATTR_TYPEDEFname : ATTR_TYPEGENname))
48#define ATTRIBUTE_RETURN()      RETURN_VAL(ATTR_IDENTIFIER)
49
50#define ASCIIOP_RETURN()        RETURN_VAL((int)yytext[0])      // single character operator
51#define NAMEDOP_RETURN(x)       RETURN_VAL(x)                           // multichar operator, with a name
52
53#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL(x) // numeric constant
54
55void rm_underscore() {
56        // remove underscores in numeric constant
57        int j = 0;
58        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
59                if ( yytext[i] != '_' ) {
60                        yytext[j] = yytext[i];
61                        j += 1;
62                } // if
63        } // for
64        yyleng = j;
65        yytext[yyleng] = '\0';
66}
67
68%}
69
70octal [0-7]
71nonzero [1-9]
72decimal [0-9]
73hex [0-9a-fA-F]
74universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
75
76                                // identifier, GCC: $ in identifier
77identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
78
79                                // quoted identifier
80quoted_identifier "`"{identifier}"`"
81
82                                // attribute identifier, GCC: $ in identifier
83attr_identifier "@"{identifier}
84
85                                // numeric constants, CFA: '_' in constant
86hex_quad {hex}("_"?{hex}){3}
87integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
88
89octal_digits ({octal})|({octal}({octal}|"_")*{octal})
90octal_prefix "0""_"?
91octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
92
93nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
94decimal_constant {nonzero_digits}{integer_suffix}?
95
96hex_digits ({hex})|({hex}({hex}|"_")*{hex})
97hex_prefix "0"[xX]"_"?
98hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
99
100decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
101fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
102exponent "_"?[eE]"_"?[+-]?{decimal_digits}
103floating_suffix "_"?[flFL]
104floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
105
106binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
107hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
108hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
109
110                                // character escape sequence, GCC: \e => esc character
111simple_escape "\\"[abefnrtv'"?\\]
112                                // ' stop highlighting
113octal_escape "\\"{octal}("_"?{octal}){0,2}
114hex_escape "\\""x""_"?{hex_digits}
115escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
116cwide_prefix "L"|"U"|"u"
117swide_prefix {cwide_prefix}|"u8"
118
119                                // display/white-space characters
120h_tab [\011]
121form_feed [\014]
122v_tab [\013]
123c_return [\015]
124h_white [ ]|{h_tab}
125
126                                // operators
127op_unary_only "~"|"!"
128op_unary_binary "+"|"-"|"*"
129op_unary_pre_post "++"|"--"
130op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
131
132op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
133op_binary_over {op_unary_binary}|{op_binary_only}
134op_binary_not_over "?"|"->"|"&&"|"||"
135operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
136
137%x COMMENT
138%x BKQUOTE
139%x QUOTE
140%x STRING
141
142%%
143                                   /* line directives */
144^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["][^\n]*"\n" {
145        /* " stop highlighting */
146        char *end_num;
147        char *begin_string, *end_string;
148        char *filename;
149        long lineno, length;
150        lineno = strtol( yytext + 1, &end_num, 0 );
151        begin_string = strchr( end_num, '"' );
152        if ( begin_string ) {
153                end_string = strchr( begin_string + 1, '"' );
154                if ( end_string ) {
155                        length = end_string - begin_string - 1;
156                        filename = new char[ length + 1 ];
157                        memcpy( filename, begin_string + 1, length );
158                        filename[ length ] = '\0';
159                        //std::cout << "file " << filename << " line " << lineno << std::endl;
160                        yylineno = lineno;
161                        yyfilename = filename;
162                } // if
163        } // if
164}
165
166                                /* ignore preprocessor directives (for now) */
167^{h_white}*"#"[^\n]*"\n" ;
168
169                                /* ignore C style comments (ALSO HANDLED BY CPP) */
170"/*"                    { BEGIN COMMENT; }
171<COMMENT>.|\n   ;
172<COMMENT>"*/"   { BEGIN 0; }
173
174                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
175"//"[^\n]*"\n"  ;
176
177                                /* ignore whitespace */
178{h_white}+              { WHITE_RETURN(' '); }
179({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
180({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
181
182                                /* keywords */
183_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
184_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
185__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
186__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
187asm                             { KEYWORD_RETURN(ASM); }
188__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
189__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
190_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
191__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
192__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
193auto                    { KEYWORD_RETURN(AUTO); }
194_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
195break                   { KEYWORD_RETURN(BREAK); }
196case                    { KEYWORD_RETURN(CASE); }
197catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
198char                    { KEYWORD_RETURN(CHAR); }
199choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
200_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
201__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
202__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
203const                   { KEYWORD_RETURN(CONST); }
204__const                 { KEYWORD_RETURN(CONST); }                              // GCC
205__const__               { KEYWORD_RETURN(CONST); }                              // GCC
206context                 { KEYWORD_RETURN(CONTEXT); }                    // CFA
207continue                { KEYWORD_RETURN(CONTINUE); }
208default                 { KEYWORD_RETURN(DEFAULT); }
209do                              { KEYWORD_RETURN(DO); }
210double                  { KEYWORD_RETURN(DOUBLE); }
211dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
212else                    { KEYWORD_RETURN(ELSE); }
213enum                    { KEYWORD_RETURN(ENUM); }
214__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
215extern                  { KEYWORD_RETURN(EXTERN); }
216fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
217finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
218float                   { KEYWORD_RETURN(FLOAT); }
219__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
220for                             { KEYWORD_RETURN(FOR); }
221forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
222fortran                 { KEYWORD_RETURN(FORTRAN); }
223ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
224_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
225goto                    { KEYWORD_RETURN(GOTO); }
226if                              { KEYWORD_RETURN(IF); }
227_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
228__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
229__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
230inline                  { KEYWORD_RETURN(INLINE); }                             // C99
231__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
232__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
233int                             { KEYWORD_RETURN(INT); }
234__int128                { KEYWORD_RETURN(INT); }                                // GCC
235__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
236long                    { KEYWORD_RETURN(LONG); }
237lvalue                  { KEYWORD_RETURN(LVALUE); }                             // CFA
238_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
239register                { KEYWORD_RETURN(REGISTER); }
240restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
241__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
242__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
243return                  { KEYWORD_RETURN(RETURN); }
244short                   { KEYWORD_RETURN(SHORT); }
245signed                  { KEYWORD_RETURN(SIGNED); }
246__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
247__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
248sizeof                  { KEYWORD_RETURN(SIZEOF); }
249static                  { KEYWORD_RETURN(STATIC); }
250_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
251struct                  { KEYWORD_RETURN(STRUCT); }
252switch                  { KEYWORD_RETURN(SWITCH); }
253_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
254throw                   { KEYWORD_RETURN(THROW); }                              // CFA
255try                             { KEYWORD_RETURN(TRY); }                                // CFA
256type                    { KEYWORD_RETURN(TYPE); }                               // CFA
257typedef                 { KEYWORD_RETURN(TYPEDEF); }
258typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
259__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
260__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
261union                   { KEYWORD_RETURN(UNION); }
262unsigned                { KEYWORD_RETURN(UNSIGNED); }
263void                    { KEYWORD_RETURN(VOID); }
264volatile                { KEYWORD_RETURN(VOLATILE); }
265__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
266__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
267while                   { KEYWORD_RETURN(WHILE); }
268
269                                /* identifier */
270{identifier}    { IDENTIFIER_RETURN(); }
271{attr_identifier} { ATTRIBUTE_RETURN(); }
272"`"                     { BEGIN BKQUOTE; }
273<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
274<BKQUOTE>"`"    { BEGIN 0; }
275
276                                /* numeric constants */
277"0"                             { NUMERIC_RETURN(ZERO); }                               // CFA
278"1"                             { NUMERIC_RETURN(ONE); }                                // CFA
279{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
280{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
281{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
282{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
283{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
284
285                                /* character constant, allows empty value */
286({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
287<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
288<QUOTE>['\n]    { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
289                                /* ' stop highlighting */
290
291                                /* string constant */
292({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
293<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
294<STRING>["\n]   { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
295                                /* " stop highlighting */
296
297                                /* common character/string constant */
298<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
299<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
300<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
301
302                                /* punctuation */
303"["                             { ASCIIOP_RETURN(); }
304"]"                             { ASCIIOP_RETURN(); }
305"("                             { ASCIIOP_RETURN(); }
306")"                             { ASCIIOP_RETURN(); }
307"{"                             { ASCIIOP_RETURN(); }
308"}"                             { ASCIIOP_RETURN(); }
309","                             { ASCIIOP_RETURN(); }                                   // also operator
310":"                             { ASCIIOP_RETURN(); }
311";"                             { ASCIIOP_RETURN(); }
312"."                             { ASCIIOP_RETURN(); }                                   // also operator
313"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
314
315                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
316"<:"                    { RETURN_VAL('['); }
317":>"                    { RETURN_VAL(']'); }
318"<%"                    { RETURN_VAL('{'); }
319"%>"                    { RETURN_VAL('}'); }
320
321                                /* operators */
322"!"                             { ASCIIOP_RETURN(); }
323"+"                             { ASCIIOP_RETURN(); }
324"-"                             { ASCIIOP_RETURN(); }
325"*"                             { ASCIIOP_RETURN(); }
326"/"                             { ASCIIOP_RETURN(); }
327"%"                             { ASCIIOP_RETURN(); }
328"^"                             { ASCIIOP_RETURN(); }
329"~"                             { ASCIIOP_RETURN(); }
330"&"                             { ASCIIOP_RETURN(); }
331"|"                             { ASCIIOP_RETURN(); }
332"<"                             { ASCIIOP_RETURN(); }
333">"                             { ASCIIOP_RETURN(); }
334"="                             { ASCIIOP_RETURN(); }
335"?"                             { ASCIIOP_RETURN(); }
336
337"++"                    { NAMEDOP_RETURN(ICR); }
338"--"                    { NAMEDOP_RETURN(DECR); }
339"=="                    { NAMEDOP_RETURN(EQ); }
340"!="                    { NAMEDOP_RETURN(NE); }
341"<<"                    { NAMEDOP_RETURN(LS); }
342">>"                    { NAMEDOP_RETURN(RS); }
343"<="                    { NAMEDOP_RETURN(LE); }
344">="                    { NAMEDOP_RETURN(GE); }
345"&&"                    { NAMEDOP_RETURN(ANDAND); }
346"||"                    { NAMEDOP_RETURN(OROR); }
347"->"                    { NAMEDOP_RETURN(ARROW); }
348"+="                    { NAMEDOP_RETURN(PLUSassign); }
349"-="                    { NAMEDOP_RETURN(MINUSassign); }
350"*="                    { NAMEDOP_RETURN(MULTassign); }
351"/="                    { NAMEDOP_RETURN(DIVassign); }
352"%="                    { NAMEDOP_RETURN(MODassign); }
353"&="                    { NAMEDOP_RETURN(ANDassign); }
354"|="                    { NAMEDOP_RETURN(ORassign); }
355"^="                    { NAMEDOP_RETURN(ERassign); }
356"<<="                   { NAMEDOP_RETURN(LSassign); }
357">>="                   { NAMEDOP_RETURN(RSassign); }
358
359                                /* CFA, operator identifier */
360{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
361"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
362"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
363        /*
364          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
365          can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
366          to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
367          identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
368          case is for the function-call identifier "?()":
369
370          int * ?()();  // declaration: space required after '*'
371          * ?()();      // expression: space required after '*'
372
373          Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
374          ahead to determine if there is a '(', which is the start of an argument/parameter list.
375
376          The 4 remaining cases occur in expressions:
377
378          i++?i:0;              // space required before '?'
379          i--?i:0;              // space required before '?'
380          i?++i:0;              // space required after '?'
381          i?--i:0;              // space required after '?'
382
383          In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
384          "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
385          list.  In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
386          "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
387          an argument list.
388        */
389{op_unary}"?"(({op_unary_pre_post}|"[?]")|({op_binary_over}"?")) {
390        // 1 or 2 character unary operator ?
391        int i = yytext[1] == '?' ? 1 : 2;
392        yyless( i );            // put back characters up to first '?'
393        if ( i > 1 ) {
394                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
395        } else {
396                ASCIIOP_RETURN();
397        } // if
398}
399
400                                /* unknown characters */
401.                       { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
402
403%%
404
405// Local Variables: //
406// fill-column: 110 //
407// tab-width: 4 //
408// mode: c++ //
409// compile-command: "make install" //
410// End: //
Note: See TracBrowser for help on using the repository browser.