source: src/Parser/lex.ll @ c6b1105

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decaygc_noraiijacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newwith_gc
Last change on this file since c6b1105 was c6b1105, checked in by Peter A. Buhr <pabuhr@…>, 8 years ago

add reference operator, labels cannot be 0/1, small changes to tests
  • Property mode set to 100644
File size: 15.3 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Thu Jun 23 07:29:30 2016
13 * Update Count     : 457
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27
28#include "lex.h"
29#include "parser.h"                                                                             // YACC generated definitions based on C++ grammar
30#include "ParseNode.h"
31#include "TypedefTable.h"
32
33char *yyfilename;
34std::string *strtext;                                                                   // accumulate parts of character and string constant value
35
36#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
37#define RETURN_VAL(x)           yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
38#define RETURN_CHAR(x)          yylval.tok.str = NULL; RETURN_LOCN( x )
39#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
40
41#define WHITE_RETURN(x)                                                                 // do nothing
42#define NEWLINE_RETURN()        WHITE_RETURN( '\n' )
43#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
44#define NAMEDOP_RETURN(x)       RETURN_VAL( x )                         // multichar operator, with a name
45#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
46#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
47#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
48#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
49
50void rm_underscore() {
51        // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
52        yyleng = 0;
53        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
54                if ( yytext[i] != '_' ) {
55                        yytext[yyleng] = yytext[i];
56                        yyleng += 1;
57                } // if
58        } // for
59        yytext[yyleng] = '\0';
60}
61
62%}
63
64octal [0-7]
65nonzero [1-9]
66decimal [0-9]
67hex [0-9a-fA-F]
68universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
69
70                                // identifier, GCC: $ in identifier
71identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
72
73                                // quoted identifier
74quoted_identifier "`"{identifier}"`"
75
76                                // attribute identifier, GCC: $ in identifier
77attr_identifier "@"{identifier}
78
79                                // numeric constants, CFA: '_' in constant
80hex_quad {hex}("_"?{hex}){3}
81integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
82
83octal_digits ({octal})|({octal}({octal}|"_")*{octal})
84octal_prefix "0""_"?
85octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
86
87nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
88decimal_constant {nonzero_digits}{integer_suffix}?
89
90hex_digits ({hex})|({hex}({hex}|"_")*{hex})
91hex_prefix "0"[xX]"_"?
92hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
93
94decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
95fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
96exponent "_"?[eE]"_"?[+-]?{decimal_digits}
97                                // GCC: D (double), DL (long double) and iI (imaginary) suffixes
98floating_suffix "_"?([fFdDlL][iI]?|"DL"|[iI][lLfFdD]?)
99                                //floating_suffix "_"?([fFdD]|[lL]|[D][L])|([iI][lLfFdD])|([lLfFdD][iI]))
100floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
101
102binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
103hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
104hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
105
106                                // character escape sequence, GCC: \e => esc character
107simple_escape "\\"[abefnrtv'"?\\]
108                                // ' stop highlighting
109octal_escape "\\"{octal}("_"?{octal}){0,2}
110hex_escape "\\""x""_"?{hex_digits}
111escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
112cwide_prefix "L"|"U"|"u"
113swide_prefix {cwide_prefix}|"u8"
114
115                                // display/white-space characters
116h_tab [\011]
117form_feed [\014]
118v_tab [\013]
119c_return [\015]
120h_white [ ]|{h_tab}
121
122                                // overloadable operators
123op_unary_only "~"|"!"
124op_unary_binary "+"|"-"|"*"
125op_unary_pre_post "++"|"--"
126op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
127
128op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
129op_binary_over {op_unary_binary}|{op_binary_only}
130                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
131                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
132
133%x COMMENT
134%x BKQUOTE
135%x QUOTE
136%x STRING
137
138%%
139                                   /* line directives */
140^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
141        /* " stop highlighting */
142        char *end_num;
143        char *begin_string, *end_string;
144        char *filename;
145        long lineno, length;
146        lineno = strtol( yytext + 1, &end_num, 0 );
147        begin_string = strchr( end_num, '"' );
148        if ( begin_string ) {
149                end_string = strchr( begin_string + 1, '"' );
150                if ( end_string ) {
151                        length = end_string - begin_string - 1;
152                        filename = new char[ length + 1 ];
153                        memcpy( filename, begin_string + 1, length );
154                        filename[ length ] = '\0';
155                        //std::cout << "file " << filename << " line " << lineno << std::endl;
156                        yylineno = lineno;
157                        yyfilename = filename;
158                } // if
159        } // if
160}
161
162                                /* ignore preprocessor directives (for now) */
163^{h_white}*"#"[^\n]*"\n" ;
164
165                                /* ignore C style comments (ALSO HANDLED BY CPP) */
166"/*"                    { BEGIN COMMENT; }
167<COMMENT>.|\n   ;
168<COMMENT>"*/"   { BEGIN 0; }
169
170                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
171"//"[^\n]*"\n"  ;
172
173                                /* ignore whitespace */
174{h_white}+              { WHITE_RETURN(' '); }
175({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
176({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
177
178                                /* keywords */
179_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
180_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
181__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
182__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
183asm                             { KEYWORD_RETURN(ASM); }
184__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
185__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
186_At                             { KEYWORD_RETURN(AT); }                                 // CFA
187_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
188__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
189__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
190auto                    { KEYWORD_RETURN(AUTO); }
191_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
192break                   { KEYWORD_RETURN(BREAK); }
193case                    { KEYWORD_RETURN(CASE); }
194catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
195catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
196char                    { KEYWORD_RETURN(CHAR); }
197choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
198_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
199__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
200__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
201const                   { KEYWORD_RETURN(CONST); }
202__const                 { KEYWORD_RETURN(CONST); }                              // GCC
203__const__               { KEYWORD_RETURN(CONST); }                              // GCC
204continue                { KEYWORD_RETURN(CONTINUE); }
205default                 { KEYWORD_RETURN(DEFAULT); }
206disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
207do                              { KEYWORD_RETURN(DO); }
208double                  { KEYWORD_RETURN(DOUBLE); }
209dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
210else                    { KEYWORD_RETURN(ELSE); }
211enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
212enum                    { KEYWORD_RETURN(ENUM); }
213__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
214extern                  { KEYWORD_RETURN(EXTERN); }
215fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
216finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
217float                   { KEYWORD_RETURN(FLOAT); }
218__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
219for                             { KEYWORD_RETURN(FOR); }
220forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
221fortran                 { KEYWORD_RETURN(FORTRAN); }
222ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
223_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
224goto                    { KEYWORD_RETURN(GOTO); }
225if                              { KEYWORD_RETURN(IF); }
226_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
227__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
228__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
229inline                  { KEYWORD_RETURN(INLINE); }                             // C99
230__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
231__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
232int                             { KEYWORD_RETURN(INT); }
233__int128                { KEYWORD_RETURN(INT); }                                // GCC
234__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
235long                    { KEYWORD_RETURN(LONG); }
236lvalue                  { KEYWORD_RETURN(LVALUE); }                             // CFA
237_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
238__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
239otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
240register                { KEYWORD_RETURN(REGISTER); }
241restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
242__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
243__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
244return                  { KEYWORD_RETURN(RETURN); }
245short                   { KEYWORD_RETURN(SHORT); }
246signed                  { KEYWORD_RETURN(SIGNED); }
247__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
248__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
249sizeof                  { KEYWORD_RETURN(SIZEOF); }
250static                  { KEYWORD_RETURN(STATIC); }
251_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
252struct                  { KEYWORD_RETURN(STRUCT); }
253switch                  { KEYWORD_RETURN(SWITCH); }
254_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
255throw                   { KEYWORD_RETURN(THROW); }                              // CFA
256throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
257trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
258try                             { KEYWORD_RETURN(TRY); }                                // CFA
259typedef                 { KEYWORD_RETURN(TYPEDEF); }
260typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
261__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
262__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
263union                   { KEYWORD_RETURN(UNION); }
264unsigned                { KEYWORD_RETURN(UNSIGNED); }
265__builtin_va_list { KEYWORD_RETURN(VALIST); }                   // GCC
266void                    { KEYWORD_RETURN(VOID); }
267volatile                { KEYWORD_RETURN(VOLATILE); }
268__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
269__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
270while                   { KEYWORD_RETURN(WHILE); }
271
272                                /* identifier */
273{identifier}    { IDENTIFIER_RETURN(); }
274{attr_identifier} { ATTRIBUTE_RETURN(); }
275"`"                             { BEGIN BKQUOTE; }
276<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
277<BKQUOTE>"`"    { BEGIN 0; }
278
279                                /* numeric constants */
280"0"                             { NUMERIC_RETURN(ZERO); }                               // CFA
281"1"                             { NUMERIC_RETURN(ONE); }                                // CFA
282{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
283{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
284{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
285{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
286{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
287
288                                /* character constant, allows empty value */
289({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
290<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
291<QUOTE>['\n]    { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
292                                /* ' stop highlighting */
293
294                                /* string constant */
295({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
296<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
297<STRING>["\n]   { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
298                                /* " stop highlighting */
299
300                                /* common character/string constant */
301<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
302<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
303<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
304
305                                /* punctuation */
306"["                             { ASCIIOP_RETURN(); }
307"]"                             { ASCIIOP_RETURN(); }
308"("                             { ASCIIOP_RETURN(); }
309")"                             { ASCIIOP_RETURN(); }
310"{"                             { ASCIIOP_RETURN(); }
311"}"                             { ASCIIOP_RETURN(); }
312","                             { ASCIIOP_RETURN(); }                                   // also operator
313":"                             { ASCIIOP_RETURN(); }
314";"                             { ASCIIOP_RETURN(); }
315"."                             { ASCIIOP_RETURN(); }                                   // also operator
316"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
317
318                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
319"<:"                    { RETURN_VAL('['); }
320":>"                    { RETURN_VAL(']'); }
321"<%"                    { RETURN_VAL('{'); }
322"%>"                    { RETURN_VAL('}'); }
323
324                                /* operators */
325"!"                             { ASCIIOP_RETURN(); }
326"+"                             { ASCIIOP_RETURN(); }
327"-"                             { ASCIIOP_RETURN(); }
328"*"                             { ASCIIOP_RETURN(); }
329"/"                             { ASCIIOP_RETURN(); }
330"%"                             { ASCIIOP_RETURN(); }
331"^"                             { ASCIIOP_RETURN(); }
332"~"                             { ASCIIOP_RETURN(); }
333"&"                             { ASCIIOP_RETURN(); }
334"|"                             { ASCIIOP_RETURN(); }
335"<"                             { ASCIIOP_RETURN(); }
336">"                             { ASCIIOP_RETURN(); }
337"="                             { ASCIIOP_RETURN(); }
338"?"                             { ASCIIOP_RETURN(); }
339
340"++"                    { NAMEDOP_RETURN(ICR); }
341"--"                    { NAMEDOP_RETURN(DECR); }
342"=="                    { NAMEDOP_RETURN(EQ); }
343"!="                    { NAMEDOP_RETURN(NE); }
344"<<"                    { NAMEDOP_RETURN(LS); }
345">>"                    { NAMEDOP_RETURN(RS); }
346"<="                    { NAMEDOP_RETURN(LE); }
347">="                    { NAMEDOP_RETURN(GE); }
348"&&"                    { NAMEDOP_RETURN(ANDAND); }
349"||"                    { NAMEDOP_RETURN(OROR); }
350"->"                    { NAMEDOP_RETURN(ARROW); }
351"+="                    { NAMEDOP_RETURN(PLUSassign); }
352"-="                    { NAMEDOP_RETURN(MINUSassign); }
353"*="                    { NAMEDOP_RETURN(MULTassign); }
354"/="                    { NAMEDOP_RETURN(DIVassign); }
355"%="                    { NAMEDOP_RETURN(MODassign); }
356"&="                    { NAMEDOP_RETURN(ANDassign); }
357"|="                    { NAMEDOP_RETURN(ORassign); }
358"^="                    { NAMEDOP_RETURN(ERassign); }
359"<<="                   { NAMEDOP_RETURN(LSassign); }
360">>="                   { NAMEDOP_RETURN(RSassign); }
361
362"@="                    { NAMEDOP_RETURN(ATassign); }
363
364                                /* CFA, operator identifier */
365{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
366"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
367"^?{}" { IDENTIFIER_RETURN(); }
368"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
369        /*
370          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
371          can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
372          to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
373          identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
374          case is for the function-call identifier "?()":
375
376          int * ?()();  // declaration: space required after '*'
377          * ?()();      // expression: space required after '*'
378
379          Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
380          ahead to determine if there is a '(', which is the start of an argument/parameter list.
381
382          The 4 remaining cases occur in expressions:
383
384          i++?i:0;              // space required before '?'
385          i--?i:0;              // space required before '?'
386          i?++i:0;              // space required after '?'
387          i?--i:0;              // space required after '?'
388
389          In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
390          "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
391          list.  In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
392          "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
393          an argument list.
394        */
395{op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
396        // 1 or 2 character unary operator ?
397        int i = yytext[1] == '?' ? 1 : 2;
398        yyless( i );            // put back characters up to first '?'
399        if ( i > 1 ) {
400                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
401        } else {
402                ASCIIOP_RETURN();
403        } // if
404}
405
406                                /* unknown characters */
407.                       { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
408
409%%
410
411// Local Variables: //
412// mode: c++ //
413// tab-width: 4 //
414// compile-command: "make install" //
415// End: //
Note: See TracBrowser for help on using the repository browser.