source: src/Parser/lex.ll @ 9ed4f94

aaron-thesisarm-ehcleanup-dtorsdeferred_resndemanglerjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerresolv-newwith_gc
Last change on this file since 9ed4f94 was 9ed4f94, checked in by Peter A. Buhr <pabuhr@…>, 4 years ago

update error message printing and add column to parsing errors

  • Property mode set to 100644
File size: 17.2 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Wed Aug 30 07:53:24 2017
13 * Update Count     : 583
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25//**************************** Includes and Defines ****************************
26
27unsigned int column = 0;                                                                // position of the end of the last token parsed
28#define YY_USER_ACTION column += yyleng;                                // trigger before each matching rule's action
29
30#include <string>
31#include <cstdio>                                                                               // FILENAME_MAX
32using namespace std;
33
34#include "ParseNode.h"
35#include "TypedefTable.h"
36
37char *yyfilename;
38string *strtext;                                                                                // accumulate parts of character and string constant value
39
40#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
41#define RETURN_VAL(x)           yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
42#define RETURN_CHAR(x)          yylval.tok.str = nullptr; RETURN_LOCN( x )
43#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
44
45#define WHITE_RETURN(x)         // do nothing
46#define NEWLINE_RETURN()        column = 0; WHITE_RETURN( '\n' )
47#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
48#define NAMEDOP_RETURN(x)       RETURN_CHAR( x )                        // multichar operator, with a name
49#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
50#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
51#define QKEYWORD_RETURN(x)      typedefTable.isKind( yytext ); RETURN_VAL(x); // quasi-keyword
52#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
53#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
54
55void rm_underscore() {
56        // Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
57        yyleng = 0;
58        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
59                if ( yytext[i] != '_' ) {
60                        yytext[yyleng] = yytext[i];
61                        yyleng += 1;
62                } // if
63        } // for
64        yytext[yyleng] = '\0';
65}
66
67// Stop warning due to incorrectly generated flex code.
68#pragma GCC diagnostic ignored "-Wsign-compare"
69%}
70
71octal [0-7]
72nonzero [1-9]
73decimal [0-9]
74hex [0-9a-fA-F]
75universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
76
77                                // identifier, GCC: $ in identifier
78identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
79
80                                // attribute identifier, GCC: $ in identifier
81attr_identifier "@"{identifier}
82
83                                // numeric constants, CFA: '_' in constant
84hex_quad {hex}("_"?{hex}){3}
85integer_suffix "_"?(([uU](("ll"|"LL"|[lL])[iI]|[iI]?("ll"|"LL"|[lL])?))|([iI](("ll"|"LL"|[lL])[uU]|[uU]?("ll"|"LL"|[lL])?))|(("ll"|"LL"|[lL])([iI][uU]|[uU]?[iI]?)))
86
87octal_digits ({octal})|({octal}({octal}|"_")*{octal})
88octal_prefix "0""_"?
89octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
90
91nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
92decimal_constant {nonzero_digits}{integer_suffix}?
93
94hex_digits ({hex})|({hex}({hex}|"_")*{hex})
95hex_prefix "0"[xX]"_"?
96hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
97
98decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
99real_decimal {decimal_digits}"."{exponent}?{floating_suffix}?
100real_fraction "."{decimal_digits}{exponent}?{floating_suffix}?
101real_constant {decimal_digits}{real_fraction}
102exponent "_"?[eE]"_"?[+-]?{decimal_digits}
103                                // GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
104floating_suffix "_"?([fFdDlL][iI]?|[iI][lLfFdD]?|"DL")
105floating_constant (({real_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
106
107binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
108hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
109hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
110
111                                // character escape sequence, GCC: \e => esc character
112simple_escape "\\"[abefnrtv'"?\\]
113                                // ' stop highlighting
114octal_escape "\\"{octal}("_"?{octal}){0,2}
115hex_escape "\\""x""_"?{hex_digits}
116escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
117cwide_prefix "L"|"U"|"u"
118swide_prefix {cwide_prefix}|"u8"
119
120                                // display/white-space characters
121h_tab [\011]
122form_feed [\014]
123v_tab [\013]
124c_return [\015]
125h_white [ ]|{h_tab}
126
127                                // overloadable operators
128op_unary_only "~"|"!"
129op_unary_binary "+"|"-"|"*"
130op_unary_pre_post "++"|"--"
131op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
132
133op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
134op_binary_over {op_unary_binary}|{op_binary_only}
135                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
136                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
137
138%x COMMENT
139%x BKQUOTE
140%x QUOTE
141%x STRING
142
143%%
144                                /* line directives */
145^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
146        /* " stop highlighting */
147        static char filename[FILENAME_MAX];                                     // temporarily store current source-file name
148        char *end_num;
149        char *begin_string, *end_string;
150        long lineno, length;
151        lineno = strtol( yytext + 1, &end_num, 0 );
152        begin_string = strchr( end_num, '"' );
153        if ( begin_string ) {                                                           // file name ?
154                end_string = strchr( begin_string + 1, '"' );   // look for ending delimiter
155                assert( end_string );                                                   // closing quote ?
156                length = end_string - begin_string - 1;                 // file-name length without quotes or sentinel
157                assert( length < FILENAME_MAX );                                // room for sentinel ?
158                memcpy( &filename, begin_string + 1, length );  // copy file name from yytext
159                filename[ length ] = '\0';                                              // terminate string with sentinel
160                //cout << "file " << filename << " line " << lineno << endl;
161                yylineno = lineno;
162                yyfilename = filename;
163        } // if
164}
165
166                                /* ignore preprocessor directives (for now) */
167^{h_white}*"#"[^\n]*"\n" ;
168
169                                /* ignore C style comments (ALSO HANDLED BY CPP) */
170"/*"                    { BEGIN COMMENT; }
171<COMMENT>.|\n   ;
172<COMMENT>"*/"   { BEGIN 0; }
173
174                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
175"//"[^\n]*"\n"  ;
176
177                                /* ignore whitespace */
178{h_white}+              { WHITE_RETURN(' '); }
179({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
180({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
181
182                                /* keywords */
183_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
184_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
185__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
186__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
187asm                             { KEYWORD_RETURN(ASM); }
188__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
189__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
190_At                             { KEYWORD_RETURN(AT); }                                 // CFA
191_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
192__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
193__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
194auto                    { KEYWORD_RETURN(AUTO); }
195_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
196break                   { KEYWORD_RETURN(BREAK); }
197case                    { KEYWORD_RETURN(CASE); }
198catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
199catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
200char                    { KEYWORD_RETURN(CHAR); }
201choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
202_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
203__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
204__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
205const                   { KEYWORD_RETURN(CONST); }
206__const                 { KEYWORD_RETURN(CONST); }                              // GCC
207__const__               { KEYWORD_RETURN(CONST); }                              // GCC
208continue                { KEYWORD_RETURN(CONTINUE); }
209coroutine               { KEYWORD_RETURN(COROUTINE); }                  // CFA
210default                 { KEYWORD_RETURN(DEFAULT); }
211disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
212do                              { KEYWORD_RETURN(DO); }
213double                  { KEYWORD_RETURN(DOUBLE); }
214dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
215else                    { KEYWORD_RETURN(ELSE); }
216enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
217enum                    { KEYWORD_RETURN(ENUM); }
218__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
219extern                  { KEYWORD_RETURN(EXTERN); }
220fallthrough             { KEYWORD_RETURN(FALLTHRU); }                   // CFA
221fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
222finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
223float                   { KEYWORD_RETURN(FLOAT); }
224__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
225for                             { KEYWORD_RETURN(FOR); }
226forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
227fortran                 { KEYWORD_RETURN(FORTRAN); }
228ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
229_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
230goto                    { KEYWORD_RETURN(GOTO); }
231if                              { KEYWORD_RETURN(IF); }
232_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
233__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
234__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
235inline                  { KEYWORD_RETURN(INLINE); }                             // C99
236__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
237__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
238int                             { KEYWORD_RETURN(INT); }
239__int128                { KEYWORD_RETURN(INT); }                                // GCC
240__int128_t              { KEYWORD_RETURN(INT); }                                // GCC
241__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
242long                    { KEYWORD_RETURN(LONG); }
243monitor                 { KEYWORD_RETURN(MONITOR); }                    // CFA
244mutex                   { KEYWORD_RETURN(MUTEX); }                              // CFA
245_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
246__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
247one_t                   { NUMERIC_RETURN(ONE_T); }                              // CFA
248otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
249register                { KEYWORD_RETURN(REGISTER); }
250restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
251__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
252__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
253return                  { KEYWORD_RETURN(RETURN); }
254short                   { KEYWORD_RETURN(SHORT); }
255signed                  { KEYWORD_RETURN(SIGNED); }
256__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
257__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
258sizeof                  { KEYWORD_RETURN(SIZEOF); }
259static                  { KEYWORD_RETURN(STATIC); }
260_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
261struct                  { KEYWORD_RETURN(STRUCT); }
262switch                  { KEYWORD_RETURN(SWITCH); }
263thread                  { KEYWORD_RETURN(THREAD); }                             // C11
264_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
265throw                   { KEYWORD_RETURN(THROW); }                              // CFA
266throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
267timeout                 { QKEYWORD_RETURN(TIMEOUT); }                   // CFA
268trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
269try                             { KEYWORD_RETURN(TRY); }                                // CFA
270ttype                   { KEYWORD_RETURN(TTYPE); }                              // CFA
271typedef                 { KEYWORD_RETURN(TYPEDEF); }
272typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
273__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
274__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
275__uint128_t             { KEYWORD_RETURN(INT); }                                // GCC
276union                   { KEYWORD_RETURN(UNION); }
277unsigned                { KEYWORD_RETURN(UNSIGNED); }
278__builtin_va_list { KEYWORD_RETURN(VALIST); }                   // GCC
279virtual                 { KEYWORD_RETURN(VIRTUAL); }                    // CFA
280void                    { KEYWORD_RETURN(VOID); }
281volatile                { KEYWORD_RETURN(VOLATILE); }
282__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
283__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
284waitfor                 { KEYWORD_RETURN(WAITFOR); }
285or                              { QKEYWORD_RETURN(WOR); }                               // CFA
286when                    { KEYWORD_RETURN(WHEN); }
287while                   { KEYWORD_RETURN(WHILE); }
288with                    { KEYWORD_RETURN(WITH); }                               // CFA
289zero_t                  { NUMERIC_RETURN(ZERO_T); }                             // CFA
290
291                                /* identifier */
292{identifier}    { IDENTIFIER_RETURN(); }
293{attr_identifier} { ATTRIBUTE_RETURN(); }
294"`"                             { BEGIN BKQUOTE; }
295<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
296<BKQUOTE>"`"    { BEGIN 0; }
297
298                                /* numeric constants */
299{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
300{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
301{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
302{real_decimal}  { NUMERIC_RETURN(REALDECIMALconstant); } // must appear before floating_constant
303{real_fraction} { NUMERIC_RETURN(REALFRACTIONconstant); } // must appear before floating_constant
304{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
305{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
306
307                                /* character constant, allows empty value */
308({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
309<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
310<QUOTE>['\n]    { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
311                                /* ' stop highlighting */
312
313                                /* string constant */
314({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
315<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
316<STRING>["\n]   { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
317                                /* " stop highlighting */
318
319                                /* common character/string constant */
320<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
321<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
322<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
323
324                                /* punctuation */
325"@"                             { ASCIIOP_RETURN(); }
326"["                             { ASCIIOP_RETURN(); }
327"]"                             { ASCIIOP_RETURN(); }
328"("                             { ASCIIOP_RETURN(); }
329")"                             { ASCIIOP_RETURN(); }
330"{"                             { ASCIIOP_RETURN(); }
331"}"                             { ASCIIOP_RETURN(); }
332","                             { ASCIIOP_RETURN(); }                                   // also operator
333":"                             { ASCIIOP_RETURN(); }
334";"                             { ASCIIOP_RETURN(); }
335"."                             { ASCIIOP_RETURN(); }                                   // also operator
336"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
337
338                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
339"<:"                    { RETURN_VAL('['); }
340":>"                    { RETURN_VAL(']'); }
341"<%"                    { RETURN_VAL('{'); }
342"%>"                    { RETURN_VAL('}'); }
343
344                                /* operators */
345"!"                             { ASCIIOP_RETURN(); }
346"+"                             { ASCIIOP_RETURN(); }
347"-"                             { ASCIIOP_RETURN(); }
348"*"                             { ASCIIOP_RETURN(); }
349"\\"                    { ASCIIOP_RETURN(); }                                   // CFA, exponentiation
350"/"                             { ASCIIOP_RETURN(); }
351"%"                             { ASCIIOP_RETURN(); }
352"^"                             { ASCIIOP_RETURN(); }
353"~"                             { ASCIIOP_RETURN(); }
354"&"                             { ASCIIOP_RETURN(); }
355"|"                             { ASCIIOP_RETURN(); }
356"<"                             { ASCIIOP_RETURN(); }
357">"                             { ASCIIOP_RETURN(); }
358"="                             { ASCIIOP_RETURN(); }
359"?"                             { ASCIIOP_RETURN(); }
360
361"++"                    { NAMEDOP_RETURN(ICR); }
362"--"                    { NAMEDOP_RETURN(DECR); }
363"=="                    { NAMEDOP_RETURN(EQ); }
364"!="                    { NAMEDOP_RETURN(NE); }
365"<<"                    { NAMEDOP_RETURN(LS); }
366">>"                    { NAMEDOP_RETURN(RS); }
367"<="                    { NAMEDOP_RETURN(LE); }
368">="                    { NAMEDOP_RETURN(GE); }
369"&&"                    { NAMEDOP_RETURN(ANDAND); }
370"||"                    { NAMEDOP_RETURN(OROR); }
371"->"                    { NAMEDOP_RETURN(ARROW); }
372"+="                    { NAMEDOP_RETURN(PLUSassign); }
373"-="                    { NAMEDOP_RETURN(MINUSassign); }
374"\\="                   { NAMEDOP_RETURN(EXPassign); }                  // CFA, exponentiation
375"*="                    { NAMEDOP_RETURN(MULTassign); }
376"/="                    { NAMEDOP_RETURN(DIVassign); }
377"%="                    { NAMEDOP_RETURN(MODassign); }
378"&="                    { NAMEDOP_RETURN(ANDassign); }
379"|="                    { NAMEDOP_RETURN(ORassign); }
380"^="                    { NAMEDOP_RETURN(ERassign); }
381"<<="                   { NAMEDOP_RETURN(LSassign); }
382">>="                   { NAMEDOP_RETURN(RSassign); }
383
384"@="                    { NAMEDOP_RETURN(ATassign); }                   // CFA
385
386                                /* CFA, operator identifier */
387{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
388"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
389"^?{}" { IDENTIFIER_RETURN(); }
390"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
391        /*
392          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"  can be
393          lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
394          e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
395          a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
396          reparsing the trailing operator identifier.  Otherwise a space is needed between the unary operator and operator
397          identifier to disambiguate this common case.
398
399          A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers.  The ambiguity
400          occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
401          look-ahead for the routine-call parameter-list to disambiguate.  However, the dereference operator must have a
402          parameter/argument to dereference *?(...).  Hence, always interpreting the string *?() as * ?() does not preclude
403          any meaningful program.
404
405          The remaining cases are with the increment/decrement operators and conditional expression:
406
407          i++? ...(...);
408          i?++ ...(...);
409
410          requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
411      incorrect expression (juxtaposed identifiers).  Therefore, it is necessary to disambiguate these cases with a
412      space:
413
414          i++ ? i : 0;
415          i? ++i : 0;
416        */
417{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
418        // 1 or 2 character unary operator ?
419        int i = yytext[1] == '?' ? 1 : 2;
420        yyless( i );            // put back characters up to first '?'
421        if ( i > 1 ) {
422                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
423        } else {
424                ASCIIOP_RETURN();
425        } // if
426}
427
428                                /* unknown character */
429.                               { yyerror( "unknown character" ); }
430
431%%
432// ----end of lexer----
433
434void yyerror( const char * errmsg ) {
435        cout << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
436                 << ':' << SemanticError::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
437}
438
439// Local Variables: //
440// mode: c++ //
441// tab-width: 4 //
442// compile-command: "make install" //
443// End: //
Note: See TracBrowser for help on using the repository browser.