source: src/Parser/lex.ll @ 6e9ffd1

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsdeferred_resnenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprno_listpersistent-indexerpthread-emulationqualifiedEnum
Last change on this file since 6e9ffd1 was d69f4bb, checked in by Peter A. Buhr <pabuhr@…>, 6 years ago

add downto to for control

  • Property mode set to 100644
File size: 18.5 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.ll --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Wed Aug 29 15:02:41 2018
13 * Update Count     : 686
14 */
15
16%option yylineno
17%option noyywrap
18%option nounput
19
20%{
21// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
22// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
23// line-number directives) and C/C++ style comments, which are ignored.
24
25//**************************** Includes and Defines ****************************
26
27// trigger before each matching rule's action
28#define YY_USER_ACTION \
29        yylloc.first_line = yylineno; \
30        yylloc.first_column = column; \
31        column += yyleng; \
32        yylloc.last_column = column; \
33        yylloc.last_line = yylineno; \
34        yylloc.filename = yyfilename ? yyfilename : "";
35unsigned int column = 0;                                                                // position of the end of the last token parsed
36
37#include <string>
38#include <cstdio>                                                                               // FILENAME_MAX
39using namespace std;
40
41#include "ParseNode.h"
42#include "TypedefTable.h"
43
44char *yyfilename;
45string *strtext;                                                                                // accumulate parts of character and string constant value
46
47#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
48#define RETURN_VAL(x)           yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
49#define RETURN_CHAR(x)          yylval.tok.str = nullptr; RETURN_LOCN( x )
50#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
51
52#define WHITE_RETURN(x)         // do nothing
53#define NEWLINE_RETURN()        column = 0; WHITE_RETURN( '\n' )
54#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
55#define NAMEDOP_RETURN(x)       RETURN_CHAR( x )                        // multichar operator, with a name
56#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
57#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
58#define QKEYWORD_RETURN(x)      RETURN_VAL(x);                          // quasi-keyword
59#define IDENTIFIER_RETURN()     RETURN_VAL( typedefTable.isKind( yytext ) )
60#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
61
62void rm_underscore() {
63        // SKULLDUGGERY: remove underscores (ok to shorten?)
64        yyleng = 0;
65        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {          // copying non-underscore characters to front of string
66                if ( yytext[i] != '_' ) {
67                        yytext[yyleng] = yytext[i];
68                        yyleng += 1;
69                } // if
70        } // for
71        yytext[yyleng] = '\0';
72} // rm_underscore
73
74// Stop warning due to incorrectly generated flex code.
75#pragma GCC diagnostic ignored "-Wsign-compare"
76%}
77
78binary [0-1]
79octal [0-7]
80nonzero [1-9]
81decimal [0-9]
82hex [0-9a-fA-F]
83universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
84
85                                // identifier, GCC: $ in identifier
86identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
87
88                                // attribute identifier, GCC: $ in identifier
89attr_identifier "@"{identifier}
90
91                                // numeric constants, CFA: '_' in constant
92hex_quad {hex}("_"?{hex}){3}
93size_opt (8|16|32|64|128)?
94length ("ll"|"LL"|[lL]{size_opt})|("hh"|"HH"|[hH])
95integer_suffix_opt ("_"?(([uU]({length}?[iI]?)|([iI]{length}))|([iI]({length}?[uU]?)|([uU]{length}))|({length}([iI]?[uU]?)|([uU][iI]))|[zZ]))?
96
97octal_digits ({octal})|({octal}({octal}|"_")*{octal})
98octal_prefix "0""_"?
99octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix_opt}
100
101nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
102decimal_constant {nonzero_digits}{integer_suffix_opt}
103
104binary_digits ({binary})|({binary}({binary}|"_")*{binary})
105binary_prefix "0"[bB]"_"?
106binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
107
108hex_digits ({hex})|({hex}({hex}|"_")*{hex})
109hex_prefix "0"[xX]"_"?
110hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
111
112                                // GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
113exponent "_"?[eE]"_"?[+-]?{decimal_digits}
114floating_size 32|64|80|128
115floating_length ([fFdDlL]|[lL]{floating_size})
116floating_suffix ({floating_length}?[iI]?)|([iI]{floating_length})
117floating_suffix_opt ("_"?({floating_suffix}|"DL"))?
118decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
119floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
120floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
121floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})|({decimal_digits}{floating_fraction})
122
123binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
124hex_floating_suffix_opt ("_"?({floating_suffix}))?
125hex_floating_fraction ({hex_digits}?"."{hex_digits})|({hex_digits}".")
126hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
127
128                                // character escape sequence, GCC: \e => esc character
129simple_escape "\\"[abefnrtv'"?\\]
130                                // ' stop editor highlighting
131octal_escape "\\"{octal}("_"?{octal}){0,2}
132hex_escape "\\""x""_"?{hex_digits}
133escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
134cwide_prefix "L"|"U"|"u"
135swide_prefix {cwide_prefix}|"u8"
136
137                                // display/white-space characters
138h_tab [\011]
139form_feed [\014]
140v_tab [\013]
141c_return [\015]
142h_white [ ]|{h_tab}
143
144                                // overloadable operators
145op_unary_only "~"|"!"
146op_unary_binary "+"|"-"|"*"
147op_unary_pre_post "++"|"--"
148op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
149
150op_binary_only "/"|"%"|"\\"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"\\="|"&="|"|="|"^="|"<<="|">>="
151op_binary_over {op_unary_binary}|{op_binary_only}
152                                // op_binary_not_over "?"|"->"|"."|"&&"|"||"|"@="
153                                // operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
154
155%x COMMENT
156%x BKQUOTE
157%x QUOTE
158%x STRING
159
160%%
161                                /* line directives */
162^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["].*"\n" {
163        /* " stop editor highlighting */
164        static char filename[FILENAME_MAX];                                     // temporarily store current source-file name
165        char *end_num;
166        char *begin_string, *end_string;
167        long lineno, length;
168        lineno = strtol( yytext + 1, &end_num, 0 );
169        begin_string = strchr( end_num, '"' );
170        if ( begin_string ) {                                                           // file name ?
171                end_string = strchr( begin_string + 1, '"' );   // look for ending delimiter
172                assert( end_string );                                                   // closing quote ?
173                length = end_string - begin_string - 1;                 // file-name length without quotes or sentinel
174                assert( length < FILENAME_MAX );                                // room for sentinel ?
175                memcpy( &filename, begin_string + 1, length );  // copy file name from yytext
176                filename[ length ] = '\0';                                              // terminate string with sentinel
177                //cout << "file " << filename << " line " << lineno << endl;
178                yylineno = lineno;
179                yyfilename = filename;
180        } // if
181}
182
183                                /* preprocessor-style directives */
184^{h_white}*"#"[^\n]*"\n" { RETURN_VAL( DIRECTIVE ); }
185
186                                /* ignore C style comments (ALSO HANDLED BY CPP) */
187"/*"                    { BEGIN COMMENT; }
188<COMMENT>.|\n   ;
189<COMMENT>"*/"   { BEGIN 0; }
190
191                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
192"//"[^\n]*"\n"  ;
193
194                                /* ignore whitespace */
195{h_white}+              { WHITE_RETURN(' '); }
196({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
197({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
198
199                                /* keywords */
200_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
201_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
202__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
203__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
204asm                             { KEYWORD_RETURN(ASM); }
205__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
206__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
207_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
208__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
209__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
210auto                    { KEYWORD_RETURN(AUTO); }
211_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
212break                   { KEYWORD_RETURN(BREAK); }
213case                    { KEYWORD_RETURN(CASE); }
214catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
215catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
216char                    { KEYWORD_RETURN(CHAR); }
217choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
218_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
219__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
220__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
221const                   { KEYWORD_RETURN(CONST); }
222__const                 { KEYWORD_RETURN(CONST); }                              // GCC
223__const__               { KEYWORD_RETURN(CONST); }                              // GCC
224continue                { KEYWORD_RETURN(CONTINUE); }
225coroutine               { KEYWORD_RETURN(COROUTINE); }                  // CFA
226default                 { KEYWORD_RETURN(DEFAULT); }
227disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
228do                              { KEYWORD_RETURN(DO); }
229double                  { KEYWORD_RETURN(DOUBLE); }
230dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
231else                    { KEYWORD_RETURN(ELSE); }
232enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
233enum                    { KEYWORD_RETURN(ENUM); }
234__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
235exception               { KEYWORD_RETURN(EXCEPTION); }                  // CFA
236extern                  { KEYWORD_RETURN(EXTERN); }
237fallthrough             { KEYWORD_RETURN(FALLTHROUGH); }                // CFA
238fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
239finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
240float                   { KEYWORD_RETURN(FLOAT); }
241_Float32                { KEYWORD_RETURN(FLOAT); }                              // GCC
242_Float32x               { KEYWORD_RETURN(FLOAT); }                              // GCC
243_Float64                { KEYWORD_RETURN(DOUBLE); }                             // GCC
244_Float64x               { KEYWORD_RETURN(DOUBLE); }                             // GCC
245__float80               { KEYWORD_RETURN(FLOAT80); }                    // GCC
246float80                 { KEYWORD_RETURN(FLOAT80); }                    // GCC
247_Float128               { KEYWORD_RETURN(FLOAT128); }                   // GCC
248_Float128x              { KEYWORD_RETURN(FLOAT128); }                   // GCC
249__float128              { KEYWORD_RETURN(FLOAT128); }                   // GCC
250float128                { KEYWORD_RETURN(FLOAT128); }                   // GCC
251for                             { KEYWORD_RETURN(FOR); }
252forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
253fortran                 { KEYWORD_RETURN(FORTRAN); }
254ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
255_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
256goto                    { KEYWORD_RETURN(GOTO); }
257if                              { KEYWORD_RETURN(IF); }
258_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
259__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
260__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
261inline                  { KEYWORD_RETURN(INLINE); }                             // C99
262__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
263__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
264int                             { KEYWORD_RETURN(INT); }
265__int128                { KEYWORD_RETURN(INT128); }                             // GCC
266int128                  { KEYWORD_RETURN(INT128); }                             // GCC
267__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
268long                    { KEYWORD_RETURN(LONG); }
269monitor                 { KEYWORD_RETURN(MONITOR); }                    // CFA
270mutex                   { KEYWORD_RETURN(MUTEX); }                              // CFA
271_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
272__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); }                // GCC
273one_t                   { NUMERIC_RETURN(ONE_T); }                              // CFA
274or                              { QKEYWORD_RETURN(WOR); }                               // CFA
275otype                   { KEYWORD_RETURN(OTYPE); }                              // CFA
276register                { KEYWORD_RETURN(REGISTER); }
277restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
278__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
279__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
280return                  { KEYWORD_RETURN(RETURN); }
281short                   { KEYWORD_RETURN(SHORT); }
282signed                  { KEYWORD_RETURN(SIGNED); }
283__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
284__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
285sizeof                  { KEYWORD_RETURN(SIZEOF); }
286static                  { KEYWORD_RETURN(STATIC); }
287_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
288struct                  { KEYWORD_RETURN(STRUCT); }
289switch                  { KEYWORD_RETURN(SWITCH); }
290thread                  { KEYWORD_RETURN(THREAD); }                             // C11
291_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
292throw                   { KEYWORD_RETURN(THROW); }                              // CFA
293throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
294timeout                 { QKEYWORD_RETURN(TIMEOUT); }                   // CFA
295trait                   { KEYWORD_RETURN(TRAIT); }                              // CFA
296try                             { KEYWORD_RETURN(TRY); }                                // CFA
297ttype                   { KEYWORD_RETURN(TTYPE); }                              // CFA
298typedef                 { KEYWORD_RETURN(TYPEDEF); }
299typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
300__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
301__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
302union                   { KEYWORD_RETURN(UNION); }
303unsigned                { KEYWORD_RETURN(UNSIGNED); }
304__builtin_va_list { KEYWORD_RETURN(VALIST); }                   // GCC
305virtual                 { KEYWORD_RETURN(VIRTUAL); }                    // CFA
306void                    { KEYWORD_RETURN(VOID); }
307volatile                { KEYWORD_RETURN(VOLATILE); }
308__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
309__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
310waitfor                 { KEYWORD_RETURN(WAITFOR); }
311when                    { KEYWORD_RETURN(WHEN); }
312while                   { KEYWORD_RETURN(WHILE); }
313with                    { KEYWORD_RETURN(WITH); }                               // CFA
314zero_t                  { NUMERIC_RETURN(ZERO_T); }                             // CFA
315
316                                /* identifier */
317{identifier}    { IDENTIFIER_RETURN(); }
318"`"{identifier}"`" {                                                                    // CFA
319        yytext[yyleng - 1] = '\0'; yytext += 1;                         // SKULLDUGGERY: remove backquotes (ok to shorten?)
320        IDENTIFIER_RETURN();
321}
322{attr_identifier} { ATTRIBUTE_RETURN(); }
323
324                                /* numeric constants */
325{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
326{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
327{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
328{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
329{floating_decimal}      { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
330{floating_fraction}     { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
331{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
332{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
333
334                                /* character constant, allows empty value */
335({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
336<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
337<QUOTE>['\n]    { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
338                                /* ' stop editor highlighting */
339
340                                /* string constant */
341({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
342<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
343<STRING>["\n]   { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
344                                /* " stop editor highlighting */
345
346                                /* common character/string constant */
347<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
348<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
349<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
350
351                                /* punctuation */
352"@"                             { ASCIIOP_RETURN(); }
353"`"                             { ASCIIOP_RETURN(); }
354"["                             { ASCIIOP_RETURN(); }
355"]"                             { ASCIIOP_RETURN(); }
356"("                             { ASCIIOP_RETURN(); }
357")"                             { ASCIIOP_RETURN(); }
358"{"                             { ASCIIOP_RETURN(); }
359"}"                             { ASCIIOP_RETURN(); }
360","                             { ASCIIOP_RETURN(); }                                   // also operator
361":"                             { ASCIIOP_RETURN(); }
362";"                             { ASCIIOP_RETURN(); }
363"."                             { ASCIIOP_RETURN(); }                                   // also operator
364"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
365
366                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
367"<:"                    { RETURN_VAL('['); }
368":>"                    { RETURN_VAL(']'); }
369"<%"                    { RETURN_VAL('{'); }
370"%>"                    { RETURN_VAL('}'); }
371
372                                /* operators */
373"!"                             { ASCIIOP_RETURN(); }
374"+"                             { ASCIIOP_RETURN(); }
375"-"                             { ASCIIOP_RETURN(); }
376"*"                             { ASCIIOP_RETURN(); }
377"\\"                    { ASCIIOP_RETURN(); }                                   // CFA, exponentiation
378"/"                             { ASCIIOP_RETURN(); }
379"%"                             { ASCIIOP_RETURN(); }
380"^"                             { ASCIIOP_RETURN(); }
381"~"                             { ASCIIOP_RETURN(); }
382"&"                             { ASCIIOP_RETURN(); }
383"|"                             { ASCIIOP_RETURN(); }
384"<"                             { ASCIIOP_RETURN(); }
385">"                             { ASCIIOP_RETURN(); }
386"="                             { ASCIIOP_RETURN(); }
387"?"                             { ASCIIOP_RETURN(); }
388
389"++"                    { NAMEDOP_RETURN(ICR); }
390"--"                    { NAMEDOP_RETURN(DECR); }
391"=="                    { NAMEDOP_RETURN(EQ); }
392"!="                    { NAMEDOP_RETURN(NE); }
393"<<"                    { NAMEDOP_RETURN(LS); }
394">>"                    { NAMEDOP_RETURN(RS); }
395"<="                    { NAMEDOP_RETURN(LE); }
396">="                    { NAMEDOP_RETURN(GE); }
397"&&"                    { NAMEDOP_RETURN(ANDAND); }
398"||"                    { NAMEDOP_RETURN(OROR); }
399"->"                    { NAMEDOP_RETURN(ARROW); }
400"+="                    { NAMEDOP_RETURN(PLUSassign); }
401"-="                    { NAMEDOP_RETURN(MINUSassign); }
402"\\="                   { NAMEDOP_RETURN(EXPassign); }                  // CFA, exponentiation
403"*="                    { NAMEDOP_RETURN(MULTassign); }
404"/="                    { NAMEDOP_RETURN(DIVassign); }
405"%="                    { NAMEDOP_RETURN(MODassign); }
406"&="                    { NAMEDOP_RETURN(ANDassign); }
407"|="                    { NAMEDOP_RETURN(ORassign); }
408"^="                    { NAMEDOP_RETURN(ERassign); }
409"<<="                   { NAMEDOP_RETURN(LSassign); }
410">>="                   { NAMEDOP_RETURN(RSassign); }
411
412"@="                    { NAMEDOP_RETURN(ATassign); }                   // CFA
413"~="                    { NAMEDOP_RETURN(ErangeUpEq); }                 // CFA
414"-~"                    { NAMEDOP_RETURN(ErangeDown); }                 // CFA
415"-~="                   { NAMEDOP_RETURN(ErangeDownEq); }               // CFA
416
417                                /* CFA, operator identifier */
418{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
419"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
420"^?{}"                  { IDENTIFIER_RETURN(); }
421"?`"{identifier} { IDENTIFIER_RETURN(); }                               // postfix operator
422"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
423        /*
424          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"  can be
425          lexed as "*?"/"*?" or "*"/"?*?". Since it is common practise to put a unary operator juxtaposed to an identifier,
426          e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
427          a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
428          reparsing the trailing operator identifier.  Otherwise a space is needed between the unary operator and operator
429          identifier to disambiguate this common case.
430
431          A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers.  The ambiguity
432          occurs when the deference operator has no parameters, *?() and *?()(...), requiring arbitrary whitespace
433          look-ahead for the routine-call parameter-list to disambiguate.  However, the dereference operator must have a
434          parameter/argument to dereference *?(...).  Hence, always interpreting the string *?() as * ?() does not preclude
435          any meaningful program.
436
437          The remaining cases are with the increment/decrement operators and conditional expression:
438
439          i++? ...(...);
440          i?++ ...(...);
441
442          requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
443      incorrect expression (juxtaposed identifiers).  Therefore, it is necessary to disambiguate these cases with a
444      space:
445
446          i++ ? i : 0;
447          i? ++i : 0;
448        */
449{op_unary}"?"({op_unary_pre_post}|"()"|"[?]"|{op_binary_over}"?") {
450        // 1 or 2 character unary operator ?
451        int i = yytext[1] == '?' ? 1 : 2;
452        yyless( i );            // put back characters up to first '?'
453        if ( i > 1 ) {
454                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
455        } else {
456                ASCIIOP_RETURN();
457        } // if
458}
459
460                                /* unknown character */
461.                               { yyerror( "unknown character" ); }
462
463%%
464
465// ----end of lexer----
466
467void yyerror( const char * errmsg ) {
468        SemanticErrorThrow = true;
469        cerr << (yyfilename ? yyfilename : "*unknown file*") << ':' << yylineno << ':' << column - yyleng + 1
470                 << ": " << ErrorHelpers::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
471}
472
473// Local Variables: //
474// mode: c++ //
475// tab-width: 4 //
476// compile-command: "make install" //
477// End: //
Note: See TracBrowser for help on using the repository browser.