source: src/Parser/lex.ll @ 02e5ab6

aaron-thesisarm-ehcleanup-dtorsctordeferred_resndemanglerenumforall-pointer-decaygc_noraiijacob/cs343-translationjenkins-sandboxmemorynew-astnew-ast-unique-exprnew-envno_listpersistent-indexerresolv-newstringwith_gc
Last change on this file since 02e5ab6 was 02e5ab6, checked in by Peter A. Buhr <pabuhr@…>, 7 years ago

add preprocessor flag -DCFORALL=1, add syntax for constructor/destructor

  • Property mode set to 100644
File size: 15.0 KB
Line 
1/*
2 * Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
3 *
4 * The contents of this file are covered under the licence agreement in the
5 * file "LICENCE" distributed with Cforall.
6 *
7 * lex.l --
8 *
9 * Author           : Peter A. Buhr
10 * Created On       : Sat Sep 22 08:58:10 2001
11 * Last Modified By : Peter A. Buhr
12 * Last Modified On : Mon Sep 28 17:07:48 2015
13 * Update Count     : 402
14 */
15
16%option yylineno
17%option nounput
18
19%{
20// This lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
21// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
22// line-number directives) and C/C++ style comments, which are ignored.
23
24//**************************** Includes and Defines ****************************
25
26#include <string>
27
28#include "lex.h"
29#include "ParseNode.h"
30#include "parser.h"                                                                             // YACC generated definitions based on C++ grammar
31
32char *yyfilename;
33std::string *strtext;                                                                   // accumulate parts of character and string constant value
34
35#define RETURN_LOCN(x)          yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
36#define RETURN_VAL(x)           yylval.tok.str = new std::string( yytext ); RETURN_LOCN( x )
37#define RETURN_CHAR(x)          yylval.tok.str = NULL; RETURN_LOCN( x )
38#define RETURN_STR(x)           yylval.tok.str = strtext; RETURN_LOCN( x )
39
40#define WHITE_RETURN(x)                                                                 // do nothing
41#define NEWLINE_RETURN()        WHITE_RETURN( '\n' )
42#define ASCIIOP_RETURN()        RETURN_CHAR( (int)yytext[0] ) // single character operator
43#define NAMEDOP_RETURN(x)       RETURN_VAL( x )                         // multichar operator, with a name
44#define NUMERIC_RETURN(x)       rm_underscore(); RETURN_VAL( x ) // numeric constant
45#define KEYWORD_RETURN(x)       RETURN_CHAR( x )                        // keyword
46#define IDENTIFIER_RETURN()     RETURN_VAL( (typedefTable.isIdentifier( yytext ) ? IDENTIFIER : typedefTable.isTypedef( yytext ) ? TYPEDEFname : TYPEGENname ) )
47#define ATTRIBUTE_RETURN()      RETURN_VAL( ATTR_IDENTIFIER )
48
49void rm_underscore() {
50        // remove underscores in numeric constant
51        int j = 0;
52        for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
53                if ( yytext[i] != '_' ) {
54                        yytext[j] = yytext[i];
55                        j += 1;
56                } // if
57        } // for
58        yyleng = j;
59        yytext[yyleng] = '\0';
60}
61
62%}
63
64octal [0-7]
65nonzero [1-9]
66decimal [0-9]
67hex [0-9a-fA-F]
68universal_char "\\"((u"_"?{hex_quad})|(U"_"?{hex_quad}{2}))
69
70                                // identifier, GCC: $ in identifier
71identifier ([a-zA-Z_$]|{universal_char})([0-9a-zA-Z_$]|{universal_char})*
72
73                                // quoted identifier
74quoted_identifier "`"{identifier}"`"
75
76                                // attribute identifier, GCC: $ in identifier
77attr_identifier "@"{identifier}
78
79                                // numeric constants, CFA: '_' in constant
80hex_quad {hex}("_"?{hex}){3}
81integer_suffix "_"?(([uU][lL]?)|([uU]("ll"|"LL")?)|([lL][uU]?)|("ll"|"LL")[uU]?)
82
83octal_digits ({octal})|({octal}({octal}|"_")*{octal})
84octal_prefix "0""_"?
85octal_constant (("0")|({octal_prefix}{octal_digits})){integer_suffix}?
86
87nonzero_digits ({nonzero})|({nonzero}({decimal}|"_")*{decimal})
88decimal_constant {nonzero_digits}{integer_suffix}?
89
90hex_digits ({hex})|({hex}({hex}|"_")*{hex})
91hex_prefix "0"[xX]"_"?
92hex_constant {hex_prefix}{hex_digits}{integer_suffix}?
93
94decimal_digits ({decimal})|({decimal}({decimal}|"_")*{decimal})
95fractional_constant ({decimal_digits}?"."{decimal_digits})|({decimal_digits}".")
96exponent "_"?[eE]"_"?[+-]?{decimal_digits}
97floating_suffix "_"?[flFL]
98floating_constant (({fractional_constant}{exponent}?)|({decimal_digits}{exponent})){floating_suffix}?
99
100binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
101hex_fractional_constant ({hex_digits}?"."{hex_digits})|({hex_digits}".")
102hex_floating_constant {hex_prefix}(({hex_fractional_constant}{binary_exponent})|({hex_digits}{binary_exponent})){floating_suffix}?
103
104                                // character escape sequence, GCC: \e => esc character
105simple_escape "\\"[abefnrtv'"?\\]
106                                // ' stop highlighting
107octal_escape "\\"{octal}("_"?{octal}){0,2}
108hex_escape "\\""x""_"?{hex_digits}
109escape_seq {simple_escape}|{octal_escape}|{hex_escape}|{universal_char}
110cwide_prefix "L"|"U"|"u"
111swide_prefix {cwide_prefix}|"u8"
112
113                                // display/white-space characters
114h_tab [\011]
115form_feed [\014]
116v_tab [\013]
117c_return [\015]
118h_white [ ]|{h_tab}
119
120                                // operators
121op_unary_only "~"|"!"
122op_unary_binary "+"|"-"|"*"
123op_unary_pre_post "++"|"--"
124op_unary {op_unary_only}|{op_unary_binary}|{op_unary_pre_post}
125
126op_binary_only "/"|"%"|"^"|"&"|"|"|"<"|">"|"="|"=="|"!="|"<<"|">>"|"<="|">="|"+="|"-="|"*="|"/="|"%="|"&="|"|="|"^="|"<<="|">>="
127op_binary_over {op_unary_binary}|{op_binary_only}
128op_binary_not_over "?"|"->"|"&&"|"||"
129operator {op_unary_pre_post}|{op_binary_over}|{op_binary_not_over}
130
131%x COMMENT
132%x BKQUOTE
133%x QUOTE
134%x STRING
135
136%%
137                                   /* line directives */
138^{h_white}*"#"{h_white}*[0-9]+{h_white}*["][^"\n]+["][^\n]*"\n" {
139        /* " stop highlighting */
140        char *end_num;
141        char *begin_string, *end_string;
142        char *filename;
143        long lineno, length;
144        lineno = strtol( yytext + 1, &end_num, 0 );
145        begin_string = strchr( end_num, '"' );
146        if ( begin_string ) {
147                end_string = strchr( begin_string + 1, '"' );
148                if ( end_string ) {
149                        length = end_string - begin_string - 1;
150                        filename = new char[ length + 1 ];
151                        memcpy( filename, begin_string + 1, length );
152                        filename[ length ] = '\0';
153                        //std::cout << "file " << filename << " line " << lineno << std::endl;
154                        yylineno = lineno;
155                        yyfilename = filename;
156                } // if
157        } // if
158}
159
160                                /* ignore preprocessor directives (for now) */
161^{h_white}*"#"[^\n]*"\n" ;
162
163                                /* ignore C style comments (ALSO HANDLED BY CPP) */
164"/*"                    { BEGIN COMMENT; }
165<COMMENT>.|\n   ;
166<COMMENT>"*/"   { BEGIN 0; }
167
168                                /* ignore C++ style comments (ALSO HANDLED BY CPP) */
169"//"[^\n]*"\n"  ;
170
171                                /* ignore whitespace */
172{h_white}+              { WHITE_RETURN(' '); }
173({v_tab}|{c_return}|{form_feed})+ { WHITE_RETURN(' '); }
174({h_white}|{v_tab}|{c_return}|{form_feed})*"\n" { NEWLINE_RETURN(); }
175
176                                /* keywords */
177_Alignas                { KEYWORD_RETURN(ALIGNAS); }                    // C11
178_Alignof                { KEYWORD_RETURN(ALIGNOF); }                    // C11
179__alignof               { KEYWORD_RETURN(ALIGNOF); }                    // GCC
180__alignof__             { KEYWORD_RETURN(ALIGNOF); }                    // GCC
181asm                             { KEYWORD_RETURN(ASM); }
182__asm                   { KEYWORD_RETURN(ASM); }                                // GCC
183__asm__                 { KEYWORD_RETURN(ASM); }                                // GCC
184_At                             { KEYWORD_RETURN(AT); }                                 // CFA
185_Atomic                 { KEYWORD_RETURN(ATOMIC); }                             // C11
186__attribute             { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
187__attribute__   { KEYWORD_RETURN(ATTRIBUTE); }                  // GCC
188auto                    { KEYWORD_RETURN(AUTO); }
189_Bool                   { KEYWORD_RETURN(BOOL); }                               // C99
190break                   { KEYWORD_RETURN(BREAK); }
191case                    { KEYWORD_RETURN(CASE); }
192catch                   { KEYWORD_RETURN(CATCH); }                              // CFA
193catchResume             { KEYWORD_RETURN(CATCHRESUME); }                // CFA
194char                    { KEYWORD_RETURN(CHAR); }
195choose                  { KEYWORD_RETURN(CHOOSE); }                             // CFA
196_Complex                { KEYWORD_RETURN(COMPLEX); }                    // C99
197__complex               { KEYWORD_RETURN(COMPLEX); }                    // GCC
198__complex__             { KEYWORD_RETURN(COMPLEX); }                    // GCC
199const                   { KEYWORD_RETURN(CONST); }
200__const                 { KEYWORD_RETURN(CONST); }                              // GCC
201__const__               { KEYWORD_RETURN(CONST); }                              // GCC
202context                 { KEYWORD_RETURN(CONTEXT); }                    // CFA
203continue                { KEYWORD_RETURN(CONTINUE); }
204default                 { KEYWORD_RETURN(DEFAULT); }
205disable                 { KEYWORD_RETURN(DISABLE); }                    // CFA
206do                              { KEYWORD_RETURN(DO); }
207double                  { KEYWORD_RETURN(DOUBLE); }
208dtype                   { KEYWORD_RETURN(DTYPE); }                              // CFA
209else                    { KEYWORD_RETURN(ELSE); }
210enable                  { KEYWORD_RETURN(ENABLE); }                             // CFA
211enum                    { KEYWORD_RETURN(ENUM); }
212__extension__   { KEYWORD_RETURN(EXTENSION); }                  // GCC
213extern                  { KEYWORD_RETURN(EXTERN); }
214fallthru                { KEYWORD_RETURN(FALLTHRU); }                   // CFA
215finally                 { KEYWORD_RETURN(FINALLY); }                    // CFA
216float                   { KEYWORD_RETURN(FLOAT); }
217__float128              { KEYWORD_RETURN(FLOAT); }                              // GCC
218for                             { KEYWORD_RETURN(FOR); }
219forall                  { KEYWORD_RETURN(FORALL); }                             // CFA
220fortran                 { KEYWORD_RETURN(FORTRAN); }
221ftype                   { KEYWORD_RETURN(FTYPE); }                              // CFA
222_Generic                { KEYWORD_RETURN(GENERIC); }                    // C11
223goto                    { KEYWORD_RETURN(GOTO); }
224if                              { KEYWORD_RETURN(IF); }
225_Imaginary              { KEYWORD_RETURN(IMAGINARY); }                  // C99
226__imag                  { KEYWORD_RETURN(IMAGINARY); }                  // GCC
227__imag__                { KEYWORD_RETURN(IMAGINARY); }                  // GCC
228inline                  { KEYWORD_RETURN(INLINE); }                             // C99
229__inline                { KEYWORD_RETURN(INLINE); }                             // GCC
230__inline__              { KEYWORD_RETURN(INLINE); }                             // GCC
231int                             { KEYWORD_RETURN(INT); }
232__int128                { KEYWORD_RETURN(INT); }                                // GCC
233__label__               { KEYWORD_RETURN(LABEL); }                              // GCC
234long                    { KEYWORD_RETURN(LONG); }
235lvalue                  { KEYWORD_RETURN(LVALUE); }                             // CFA
236_Noreturn               { KEYWORD_RETURN(NORETURN); }                   // C11
237register                { KEYWORD_RETURN(REGISTER); }
238restrict                { KEYWORD_RETURN(RESTRICT); }                   // C99
239__restrict              { KEYWORD_RETURN(RESTRICT); }                   // GCC
240__restrict__    { KEYWORD_RETURN(RESTRICT); }                   // GCC
241return                  { KEYWORD_RETURN(RETURN); }
242short                   { KEYWORD_RETURN(SHORT); }
243signed                  { KEYWORD_RETURN(SIGNED); }
244__signed                { KEYWORD_RETURN(SIGNED); }                             // GCC
245__signed__              { KEYWORD_RETURN(SIGNED); }                             // GCC
246sizeof                  { KEYWORD_RETURN(SIZEOF); }
247static                  { KEYWORD_RETURN(STATIC); }
248_Static_assert  { KEYWORD_RETURN(STATICASSERT); }               // C11
249struct                  { KEYWORD_RETURN(STRUCT); }
250switch                  { KEYWORD_RETURN(SWITCH); }
251_Thread_local   { KEYWORD_RETURN(THREADLOCAL); }                // C11
252throw                   { KEYWORD_RETURN(THROW); }                              // CFA
253throwResume             { KEYWORD_RETURN(THROWRESUME); }                // CFA
254try                             { KEYWORD_RETURN(TRY); }                                // CFA
255type                    { KEYWORD_RETURN(TYPE); }                               // CFA
256typedef                 { KEYWORD_RETURN(TYPEDEF); }
257typeof                  { KEYWORD_RETURN(TYPEOF); }                             // GCC
258__typeof                { KEYWORD_RETURN(TYPEOF); }                             // GCC
259__typeof__              { KEYWORD_RETURN(TYPEOF); }                             // GCC
260union                   { KEYWORD_RETURN(UNION); }
261unsigned                { KEYWORD_RETURN(UNSIGNED); }
262void                    { KEYWORD_RETURN(VOID); }
263volatile                { KEYWORD_RETURN(VOLATILE); }
264__volatile              { KEYWORD_RETURN(VOLATILE); }                   // GCC
265__volatile__    { KEYWORD_RETURN(VOLATILE); }                   // GCC
266while                   { KEYWORD_RETURN(WHILE); }
267
268                                /* identifier */
269{identifier}    { IDENTIFIER_RETURN(); }
270{attr_identifier} { ATTRIBUTE_RETURN(); }
271"`"                     { BEGIN BKQUOTE; }
272<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
273<BKQUOTE>"`"    { BEGIN 0; }
274
275                                /* numeric constants */
276"0"                             { NUMERIC_RETURN(ZERO); }                               // CFA
277"1"                             { NUMERIC_RETURN(ONE); }                                // CFA
278{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
279{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
280{hex_constant}  { NUMERIC_RETURN(INTEGERconstant); }
281{floating_constant}     { NUMERIC_RETURN(FLOATINGconstant); }
282{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
283
284                                /* character constant, allows empty value */
285({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
286<QUOTE>[^'\\\n]* { *strtext += std::string( yytext ); }
287<QUOTE>['\n]    { BEGIN 0; *strtext += std::string( yytext); RETURN_STR(CHARACTERconstant); }
288                                /* ' stop highlighting */
289
290                                /* string constant */
291({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new std::string; *strtext += std::string( yytext ); }
292<STRING>[^"\\\n]* { *strtext += std::string( yytext ); }
293<STRING>["\n]   { BEGIN 0; *strtext += std::string( yytext ); RETURN_STR(STRINGliteral); }
294                                /* " stop highlighting */
295
296                                /* common character/string constant */
297<QUOTE,STRING>{escape_seq} { rm_underscore(); *strtext += std::string( yytext ); }
298<QUOTE,STRING>"\\"{h_white}*"\n" {}                                             // continuation (ALSO HANDLED BY CPP)
299<QUOTE,STRING>"\\" { *strtext += std::string( yytext ); } // unknown escape character
300
301                                /* punctuation */
302"["                             { ASCIIOP_RETURN(); }
303"]"                             { ASCIIOP_RETURN(); }
304"("                             { ASCIIOP_RETURN(); }
305")"                             { ASCIIOP_RETURN(); }
306"{"                             { ASCIIOP_RETURN(); }
307"}"                             { ASCIIOP_RETURN(); }
308","                             { ASCIIOP_RETURN(); }                                   // also operator
309":"                             { ASCIIOP_RETURN(); }
310";"                             { ASCIIOP_RETURN(); }
311"."                             { ASCIIOP_RETURN(); }                                   // also operator
312"..."                   { NAMEDOP_RETURN(ELLIPSIS); }
313
314                                /* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
315"<:"                    { RETURN_VAL('['); }
316":>"                    { RETURN_VAL(']'); }
317"<%"                    { RETURN_VAL('{'); }
318"%>"                    { RETURN_VAL('}'); }
319
320                                /* operators */
321"!"                             { ASCIIOP_RETURN(); }
322"+"                             { ASCIIOP_RETURN(); }
323"-"                             { ASCIIOP_RETURN(); }
324"*"                             { ASCIIOP_RETURN(); }
325"/"                             { ASCIIOP_RETURN(); }
326"%"                             { ASCIIOP_RETURN(); }
327"^"                             { ASCIIOP_RETURN(); }
328"~"                             { ASCIIOP_RETURN(); }
329"&"                             { ASCIIOP_RETURN(); }
330"|"                             { ASCIIOP_RETURN(); }
331"<"                             { ASCIIOP_RETURN(); }
332">"                             { ASCIIOP_RETURN(); }
333"="                             { ASCIIOP_RETURN(); }
334"?"                             { ASCIIOP_RETURN(); }
335
336"++"                    { NAMEDOP_RETURN(ICR); }
337"--"                    { NAMEDOP_RETURN(DECR); }
338"=="                    { NAMEDOP_RETURN(EQ); }
339"!="                    { NAMEDOP_RETURN(NE); }
340"<<"                    { NAMEDOP_RETURN(LS); }
341">>"                    { NAMEDOP_RETURN(RS); }
342"<="                    { NAMEDOP_RETURN(LE); }
343">="                    { NAMEDOP_RETURN(GE); }
344"&&"                    { NAMEDOP_RETURN(ANDAND); }
345"||"                    { NAMEDOP_RETURN(OROR); }
346"->"                    { NAMEDOP_RETURN(ARROW); }
347"+="                    { NAMEDOP_RETURN(PLUSassign); }
348"-="                    { NAMEDOP_RETURN(MINUSassign); }
349"*="                    { NAMEDOP_RETURN(MULTassign); }
350"/="                    { NAMEDOP_RETURN(DIVassign); }
351"%="                    { NAMEDOP_RETURN(MODassign); }
352"&="                    { NAMEDOP_RETURN(ANDassign); }
353"|="                    { NAMEDOP_RETURN(ORassign); }
354"^="                    { NAMEDOP_RETURN(ERassign); }
355"<<="                   { NAMEDOP_RETURN(LSassign); }
356">>="                   { NAMEDOP_RETURN(RSassign); }
357
358                                /* CFA, operator identifier */
359{op_unary}"?"   { IDENTIFIER_RETURN(); }                                // unary
360"?"({op_unary_pre_post}|"()"|"[?]"|"{}") { IDENTIFIER_RETURN(); }
361"^?{}" { IDENTIFIER_RETURN(); }
362"?"{op_binary_over}"?"  { IDENTIFIER_RETURN(); }                // binary
363        /*
364          This rule handles ambiguous cases with operator identifiers, e.g., "int *?*?()", where the string "*?*?"
365          can be lexed as "*"/"?*?" or "*?"/"*?". Since it is common practise to put a unary operator juxtaposed
366          to an identifier, e.g., "*i", users will be annoyed if they cannot do this with respect to operator
367          identifiers. Even with this special hack, there are 5 general cases that cannot be handled. The first
368          case is for the function-call identifier "?()":
369
370          int * ?()();  // declaration: space required after '*'
371          * ?()();      // expression: space required after '*'
372
373          Without the space, the string "*?()" is ambiguous without N character look ahead; it requires scanning
374          ahead to determine if there is a '(', which is the start of an argument/parameter list.
375
376          The 4 remaining cases occur in expressions:
377
378          i++?i:0;              // space required before '?'
379          i--?i:0;              // space required before '?'
380          i?++i:0;              // space required after '?'
381          i?--i:0;              // space required after '?'
382
383          In the first two cases, the string "i++?" is ambiguous, where this string can be lexed as "i"/"++?" or
384          "i++"/"?"; it requires scanning ahead to determine if there is a '(', which is the start of an argument
385          list.  In the second two cases, the string "?++x" is ambiguous, where this string can be lexed as
386          "?++"/"x" or "?"/"++x"; it requires scanning ahead to determine if there is a '(', which is the start of
387          an argument list.
388        */
389{op_unary}"?"({op_unary_pre_post}|"[?]"|{op_binary_over}"?") {
390        // 1 or 2 character unary operator ?
391        int i = yytext[1] == '?' ? 1 : 2;
392        yyless( i );            // put back characters up to first '?'
393        if ( i > 1 ) {
394                NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
395        } else {
396                ASCIIOP_RETURN();
397        } // if
398}
399
400                                /* unknown characters */
401.                       { printf("unknown character(s):\"%s\" on line %d\n", yytext, yylineno); }
402
403%%
404
405// Local Variables: //
406// mode: c++ //
407// tab-width: 4 //
408// compile-command: "make install" //
409// End: //
Note: See TracBrowser for help on using the repository browser.