Context Navigation

lex.ll @ 0a2168f

ADTaaron-thesisarm-ehast-experimentalcleanup-dtorsdeferred_resndemanglerenumforall-pointer-decayjacob/cs343-translationjenkins-sandboxnew-astnew-ast-unique-exprnew-envno_listpersistent-indexerpthread-emulationqualifiedEnumresolv-newwith_gc

Last change on this file since 0a2168f was 0a2168f, checked in by Peter A. Buhr <pabuhr@…>, 6 years ago
add gcc binary constants
Property mode set to `100644`
File size: 18.3 KB

Rev	Line
[b87a5ed]	1	/*
	2	* Cforall Version 1.0.0 Copyright (C) 2015 University of Waterloo
	3	*
	4	* The contents of this file are covered under the licence agreement in the
	5	* file "LICENCE" distributed with Cforall.
[8f60f0b]	6	*
[6016c87]	7	* lex.ll --
[8f60f0b]	8	*
[51b7345]	9	* Author : Peter A. Buhr
	10	* Created On : Sat Sep 22 08:58:10 2001
[926af74]	11	* Last Modified By : Peter A. Buhr
[0a2168f]	12	* Last Modified On : Sat Mar 3 18:38:16 2018
	13	* Update Count : 640
[51b7345]	14	*/
	15
	16	%option yylineno
[4e9c7c1]	17	%option noyywrap
[5f2f2d7]	18	%option nounput
[51b7345]	19
	20	%{
[9ed4f94]	21	// The lexer assumes the program has been preprocessed by cpp. Hence, all user level preprocessor directive have been
[de62360d]	22	// performed and removed from the source. The only exceptions are preprocessor directives passed to the compiler (e.g.,
	23	// line-number directives) and C/C++ style comments, which are ignored.
[51b7345]	24
[8c17ab0]	25	//************************** Includes and Defines **************************
[51b7345]	26
[9ed4f94]	27	unsigned int column = 0; // position of the end of the last token parsed
[d48e529]	28	#define YY_USER_ACTION yylloc.first_line = yylineno; yylloc.first_column = column; column += yyleng; yylloc.last_column = column; yylloc.last_line = yylineno; yylloc.filename = yyfilename ? yyfilename : ""; // trigger before each matching rule's action
[9ed4f94]	29
[51b7345]	30	#include <string>
[f487962]	31	#include <cstdio> // FILENAME_MAX
[9ed4f94]	32	using namespace std;
[51b7345]	33
[984dce6]	34	#include "ParseNode.h"
	35	#include "TypedefTable.h"
[51b7345]	36
	37	char *yyfilename;
[9ed4f94]	38	string *strtext; // accumulate parts of character and string constant value
[51b7345]	39
[de62360d]	40	#define RETURN_LOCN(x) yylval.tok.loc.file = yyfilename; yylval.tok.loc.line = yylineno; return( x )
[9ed4f94]	41	#define RETURN_VAL(x) yylval.tok.str = new string( yytext ); RETURN_LOCN( x )
[926af74]	42	#define RETURN_CHAR(x) yylval.tok.str = nullptr; RETURN_LOCN( x )
[de62360d]	43	#define RETURN_STR(x) yylval.tok.str = strtext; RETURN_LOCN( x )
[5f2f2d7]	44
[f487962]	45	#define WHITE_RETURN(x) // do nothing
[9ed4f94]	46	#define NEWLINE_RETURN() column = 0; WHITE_RETURN( '\n' )
[de62360d]	47	#define ASCIIOP_RETURN() RETURN_CHAR( (int)yytext[0] ) // single character operator
[f487962]	48	#define NAMEDOP_RETURN(x) RETURN_CHAR( x ) // multichar operator, with a name
[de62360d]	49	#define NUMERIC_RETURN(x) rm_underscore(); RETURN_VAL( x ) // numeric constant
	50	#define KEYWORD_RETURN(x) RETURN_CHAR( x ) // keyword
[5b2edbc]	51	#define QKEYWORD_RETURN(x) typedefTable.isKind( yytext ); RETURN_VAL(x); // quasi-keyword
[984dce6]	52	#define IDENTIFIER_RETURN() RETURN_VAL( typedefTable.isKind( yytext ) )
[de62360d]	53	#define ATTRIBUTE_RETURN() RETURN_VAL( ATTR_IDENTIFIER )
[51b7345]	54
[3848e0e]	55	void rm_underscore() {
[e7aed49]	56	// Remove underscores in numeric constant by copying the non-underscore characters to the front of the string.
	57	yyleng = 0;
[b87a5ed]	58	for ( int i = 0; yytext[i] != '\0'; i += 1 ) {
[76c62b2]	59	if ( yytext[i] == '`' ) {
	60	// copy user suffix
	61	for ( ; yytext[i] != '\0'; i += 1 ) {
	62	yytext[yyleng] = yytext[i];
	63	yyleng += 1;
	64	} // for
	65	break;
	66	} // if
[b87a5ed]	67	if ( yytext[i] != '_' ) {
[e7aed49]	68	yytext[yyleng] = yytext[i];
	69	yyleng += 1;
[b87a5ed]	70	} // if
	71	} // for
	72	yytext[yyleng] = '\0';
[51b7345]	73	}
	74
[7812f1d1]	75	// Stop warning due to incorrectly generated flex code.
	76	#pragma GCC diagnostic ignored "-Wsign-compare"
[51b7345]	77	%}
	78
[0a2168f]	79	binary [0-1]
[51b7345]	80	octal [0-7]
	81	nonzero [1-9]
	82	decimal [0-9]
	83	hex [0-9a-fA-F]
[3848e0e]	84	universal_char "\\"((u"_"?{hex_quad})\|(U"_"?{hex_quad}{2}))
[51b7345]	85
[b87a5ed]	86	// identifier, GCC: $ in identifier
[51b7345]	87	identifier ([a-zA-Z_$]\|{universal_char})([0-9a-zA-Z_$]\|{universal_char})*
	88
[b87a5ed]	89	// attribute identifier, GCC: $ in identifier
[51b7345]	90	attr_identifier "@"{identifier}
	91
[76c62b2]	92	user_suffix_opt ("`"{identifier})?
	93
[b87a5ed]	94	// numeric constants, CFA: '_' in constant
[3848e0e]	95	hex_quad {hex}("_"?{hex}){3}
[201aeb9]	96	size_opt (8\|16\|32\|64\|128)?
	97	length ("ll"\|"LL"\|[lL]{size_opt})\|("hh"\|"HH"\|[hH])
[930f69e]	98	integer_suffix_opt ("_"?(([uU]({length}?[iI]?)\|([iI]{length}))\|([iI]({length}?[uU]?)\|([uU]{length}))\|({length}([iI]?[uU]?)\|([uU][iI]))\|[zZ]))?{user_suffix_opt}
[51b7345]	99
	100	octal_digits ({octal})\|({octal}({octal}\|"_")*{octal})
	101	octal_prefix "0""_"?
[930f69e]	102	octal_constant (("0")\|({octal_prefix}{octal_digits})){integer_suffix_opt}
[51b7345]	103
	104	nonzero_digits ({nonzero})\|({nonzero}({decimal}\|"_")*{decimal})
[930f69e]	105	decimal_constant {nonzero_digits}{integer_suffix_opt}
[51b7345]	106
[0a2168f]	107	binary_digits ({binary})\|({binary}({binary}\|"_")*{binary})
	108	binary_prefix "0"[bB]"_"?
	109	binary_constant {binary_prefix}{binary_digits}{integer_suffix_opt}
	110
[51b7345]	111	hex_digits ({hex})\|({hex}({hex}\|"_")*{hex})
	112	hex_prefix "0"[xX]"_"?
[930f69e]	113	hex_constant {hex_prefix}{hex_digits}{integer_suffix_opt}
[51b7345]	114
[76c62b2]	115	// GCC: D (double) and iI (imaginary) suffixes, and DL (long double)
[51b7345]	116	exponent "_"?[eE]"_"?[+-]?{decimal_digits}
[201aeb9]	117	floating_size 32\|64\|80\|128
	118	floating_length ([fFdDlL]\|[lL]{floating_size})
	119	floating_suffix ({floating_length}?[iI]?)\|([iI]{floating_length})
[f4b77f2]	120	floating_suffix_opt ("_"?({floating_suffix}\|"DL"))?{user_suffix_opt}
	121	decimal_digits ({decimal})\|({decimal}({decimal}\|"_")*{decimal})
[930f69e]	122	floating_decimal {decimal_digits}"."{exponent}?{floating_suffix_opt}
	123	floating_fraction "."{decimal_digits}{exponent}?{floating_suffix_opt}
	124	floating_constant ({decimal_digits}{exponent}{floating_suffix_opt})\|({decimal_digits}{floating_fraction})
[51b7345]	125
	126	binary_exponent "_"?[pP]"_"?[+-]?{decimal_digits}
[f4b77f2]	127	hex_floating_suffix_opt ("_"?({floating_suffix}))?{user_suffix_opt}
[930f69e]	128	hex_floating_fraction ({hex_digits}?"."{hex_digits})\|({hex_digits}".")
[f4b77f2]	129	hex_floating_constant {hex_prefix}(({hex_floating_fraction}{binary_exponent})\|({hex_digits}{binary_exponent})){hex_floating_suffix_opt}
[51b7345]	130
[b87a5ed]	131	// character escape sequence, GCC: \e => esc character
[51b7345]	132	simple_escape "\\"[abefnrtv'"?\\]
[930f69e]	133	// ' stop editor highlighting
[3848e0e]	134	octal_escape "\\"{octal}("_"?{octal}){0,2}
	135	hex_escape "\\""x""_"?{hex_digits}
[51b7345]	136	escape_seq {simple_escape}\|{octal_escape}\|{hex_escape}\|{universal_char}
[59db689]	137	cwide_prefix "L"\|"U"\|"u"
	138	swide_prefix {cwide_prefix}\|"u8"
[51b7345]	139
[b87a5ed]	140	// display/white-space characters
[51b7345]	141	h_tab [\011]
	142	form_feed [\014]
	143	v_tab [\013]
	144	c_return [\015]
	145	h_white [ ]\|{h_tab}
	146
[e7aed49]	147	// overloadable operators
[51b7345]	148	op_unary_only "~"\|"!"
	149	op_unary_binary "+"\|"-"\|"*"
	150	op_unary_pre_post "++"\|"--"
	151	op_unary {op_unary_only}\|{op_unary_binary}\|{op_unary_pre_post}
	152
[994d080]	153	op_binary_only "/"\|"%"\|"\\"\|"^"\|"&"\|"\|"\|"<"\|">"\|"="\|"=="\|"!="\|"<<"\|">>"\|"<="\|">="\|"+="\|"-="\|"*="\|"/="\|"%="\|"\\="\|"&="\|"\|="\|"^="\|"<<="\|">>="
[51b7345]	154	op_binary_over {op_unary_binary}\|{op_binary_only}
[e7aed49]	155	// op_binary_not_over "?"\|"->"\|"."\|"&&"\|"\|\|"\|"@="
	156	// operator {op_unary_pre_post}\|{op_binary_over}\|{op_binary_not_over}
[51b7345]	157
	158	%x COMMENT
[3848e0e]	159	%x BKQUOTE
	160	%x QUOTE
	161	%x STRING
[51b7345]	162
	163	%%
[994d080]	164	/* line directives */
[4040425]	165	^{h_white}"#"{h_white}[0-9]+{h_white}["][^"\n]+["]."\n" {
[930f69e]	166	/* " stop editor highlighting */
[c1c1112]	167	static char filename[FILENAME_MAX]; // temporarily store current source-file name
[51b7345]	168	char *end_num;
	169	char begin_string, end_string;
	170	long lineno, length;
	171	lineno = strtol( yytext + 1, &end_num, 0 );
	172	begin_string = strchr( end_num, '"' );
[f487962]	173	if ( begin_string ) { // file name ?
	174	end_string = strchr( begin_string + 1, '"' ); // look for ending delimiter
	175	assert( end_string ); // closing quote ?
	176	length = end_string - begin_string - 1; // file-name length without quotes or sentinel
	177	assert( length < FILENAME_MAX ); // room for sentinel ?
	178	memcpy( &filename, begin_string + 1, length ); // copy file name from yytext
	179	filename[ length ] = '\0'; // terminate string with sentinel
[9ed4f94]	180	//cout << "file " << filename << " line " << lineno << endl;
[f487962]	181	yylineno = lineno;
[c1c1112]	182	yyfilename = filename;
[b87a5ed]	183	} // if
[51b7345]	184	}
	185
[b87a5ed]	186	/* ignore preprocessor directives (for now) */
[51b7345]	187	^{h_white}"#"[^\n]"\n" ;
	188
[cd623a4]	189	/* ignore C style comments (ALSO HANDLED BY CPP) */
[3848e0e]	190	"/*" { BEGIN COMMENT; }
[cd623a4]	191	<COMMENT>.\|\n ;
	192	<COMMENT>"*/" { BEGIN 0; }
[51b7345]	193
[cd623a4]	194	/* ignore C++ style comments (ALSO HANDLED BY CPP) */
	195	"//"[^\n]*"\n" ;
[51b7345]	196
[b87a5ed]	197	/* ignore whitespace */
[3848e0e]	198	{h_white}+ { WHITE_RETURN(' '); }
	199	({v_tab}\|{c_return}\|{form_feed})+ { WHITE_RETURN(' '); }
	200	({h_white}\|{v_tab}\|{c_return}\|{form_feed})*"\n" { NEWLINE_RETURN(); }
[51b7345]	201
[b87a5ed]	202	/* keywords */
	203	_Alignas { KEYWORD_RETURN(ALIGNAS); } // C11
	204	_Alignof { KEYWORD_RETURN(ALIGNOF); } // C11
	205	__alignof { KEYWORD_RETURN(ALIGNOF); } // GCC
	206	__alignof__ { KEYWORD_RETURN(ALIGNOF); } // GCC
	207	asm { KEYWORD_RETURN(ASM); }
	208	__asm { KEYWORD_RETURN(ASM); } // GCC
	209	__asm__ { KEYWORD_RETURN(ASM); } // GCC
[02e5ab6]	210	_At { KEYWORD_RETURN(AT); } // CFA
[b87a5ed]	211	_Atomic { KEYWORD_RETURN(ATOMIC); } // C11
	212	__attribute { KEYWORD_RETURN(ATTRIBUTE); } // GCC
	213	__attribute__ { KEYWORD_RETURN(ATTRIBUTE); } // GCC
[3848e0e]	214	auto { KEYWORD_RETURN(AUTO); }
[b87a5ed]	215	_Bool { KEYWORD_RETURN(BOOL); } // C99
[3848e0e]	216	break { KEYWORD_RETURN(BREAK); }
	217	case { KEYWORD_RETURN(CASE); }
[b87a5ed]	218	catch { KEYWORD_RETURN(CATCH); } // CFA
[02e5ab6]	219	catchResume { KEYWORD_RETURN(CATCHRESUME); } // CFA
[3848e0e]	220	char { KEYWORD_RETURN(CHAR); }
[b87a5ed]	221	choose { KEYWORD_RETURN(CHOOSE); } // CFA
	222	_Complex { KEYWORD_RETURN(COMPLEX); } // C99
	223	__complex { KEYWORD_RETURN(COMPLEX); } // GCC
	224	__complex__ { KEYWORD_RETURN(COMPLEX); } // GCC
[3848e0e]	225	const { KEYWORD_RETURN(CONST); }
[b87a5ed]	226	__const { KEYWORD_RETURN(CONST); } // GCC
	227	__const__ { KEYWORD_RETURN(CONST); } // GCC
[3848e0e]	228	continue { KEYWORD_RETURN(CONTINUE); }
[e04b636]	229	coroutine { KEYWORD_RETURN(COROUTINE); } // CFA
[3848e0e]	230	default { KEYWORD_RETURN(DEFAULT); }
[02e5ab6]	231	disable { KEYWORD_RETURN(DISABLE); } // CFA
[b87a5ed]	232	do { KEYWORD_RETURN(DO); }
[3848e0e]	233	double { KEYWORD_RETURN(DOUBLE); }
[b87a5ed]	234	dtype { KEYWORD_RETURN(DTYPE); } // CFA
[3848e0e]	235	else { KEYWORD_RETURN(ELSE); }
[02e5ab6]	236	enable { KEYWORD_RETURN(ENABLE); } // CFA
[3848e0e]	237	enum { KEYWORD_RETURN(ENUM); }
[b87a5ed]	238	__extension__ { KEYWORD_RETURN(EXTENSION); } // GCC
[c27fb59]	239	exception { KEYWORD_RETURN(EXCEPTION); } // CFA
[3848e0e]	240	extern { KEYWORD_RETURN(EXTERN); }
[b87a5ed]	241	fallthru { KEYWORD_RETURN(FALLTHRU); } // CFA
[bd7f401]	242	fallthrough { KEYWORD_RETURN(FALLTHROUGH); } // CFA
[b87a5ed]	243	finally { KEYWORD_RETURN(FINALLY); } // CFA
[3848e0e]	244	float { KEYWORD_RETURN(FLOAT); }
[201aeb9]	245	__float80 { KEYWORD_RETURN(FLOAT80); } // GCC
	246	float80 { KEYWORD_RETURN(FLOAT80); } // GCC
	247	__float128 { KEYWORD_RETURN(FLOAT128); } // GCC
	248	float128 { KEYWORD_RETURN(FLOAT128); } // GCC
[b87a5ed]	249	for { KEYWORD_RETURN(FOR); }
	250	forall { KEYWORD_RETURN(FORALL); } // CFA
[3848e0e]	251	fortran { KEYWORD_RETURN(FORTRAN); }
[b87a5ed]	252	ftype { KEYWORD_RETURN(FTYPE); } // CFA
	253	_Generic { KEYWORD_RETURN(GENERIC); } // C11
[3848e0e]	254	goto { KEYWORD_RETURN(GOTO); }
[b87a5ed]	255	if { KEYWORD_RETURN(IF); }
	256	_Imaginary { KEYWORD_RETURN(IMAGINARY); } // C99
	257	__imag { KEYWORD_RETURN(IMAGINARY); } // GCC
	258	__imag__ { KEYWORD_RETURN(IMAGINARY); } // GCC
	259	inline { KEYWORD_RETURN(INLINE); } // C99
	260	__inline { KEYWORD_RETURN(INLINE); } // GCC
	261	__inline__ { KEYWORD_RETURN(INLINE); } // GCC
	262	int { KEYWORD_RETURN(INT); }
[201aeb9]	263	__int128 { KEYWORD_RETURN(INT128); } // GCC
	264	int128 { KEYWORD_RETURN(INT128); } // GCC
[b87a5ed]	265	__label__ { KEYWORD_RETURN(LABEL); } // GCC
[3848e0e]	266	long { KEYWORD_RETURN(LONG); }
[6016c87]	267	monitor { KEYWORD_RETURN(MONITOR); } // CFA
[a7c90d4]	268	mutex { KEYWORD_RETURN(MUTEX); } // CFA
[b87a5ed]	269	_Noreturn { KEYWORD_RETURN(NORETURN); } // C11
[5721a6d]	270	__builtin_offsetof { KEYWORD_RETURN(OFFSETOF); } // GCC
[3a2128f]	271	one_t { NUMERIC_RETURN(ONE_T); } // CFA
[4040425]	272	otype { KEYWORD_RETURN(OTYPE); } // CFA
[3848e0e]	273	register { KEYWORD_RETURN(REGISTER); }
[b87a5ed]	274	restrict { KEYWORD_RETURN(RESTRICT); } // C99
	275	__restrict { KEYWORD_RETURN(RESTRICT); } // GCC
	276	__restrict__ { KEYWORD_RETURN(RESTRICT); } // GCC
[3848e0e]	277	return { KEYWORD_RETURN(RETURN); }
	278	short { KEYWORD_RETURN(SHORT); }
	279	signed { KEYWORD_RETURN(SIGNED); }
[b87a5ed]	280	__signed { KEYWORD_RETURN(SIGNED); } // GCC
	281	__signed__ { KEYWORD_RETURN(SIGNED); } // GCC
[3848e0e]	282	sizeof { KEYWORD_RETURN(SIZEOF); }
	283	static { KEYWORD_RETURN(STATIC); }
[b87a5ed]	284	_Static_assert { KEYWORD_RETURN(STATICASSERT); } // C11
[3848e0e]	285	struct { KEYWORD_RETURN(STRUCT); }
	286	switch { KEYWORD_RETURN(SWITCH); }
[bd4d011]	287	thread { KEYWORD_RETURN(THREAD); } // C11
[b87a5ed]	288	_Thread_local { KEYWORD_RETURN(THREADLOCAL); } // C11
	289	throw { KEYWORD_RETURN(THROW); } // CFA
[02e5ab6]	290	throwResume { KEYWORD_RETURN(THROWRESUME); } // CFA
[5b2edbc]	291	timeout { QKEYWORD_RETURN(TIMEOUT); } // CFA
[4040425]	292	trait { KEYWORD_RETURN(TRAIT); } // CFA
[b87a5ed]	293	try { KEYWORD_RETURN(TRY); } // CFA
[8f60f0b]	294	ttype { KEYWORD_RETURN(TTYPE); } // CFA
[3848e0e]	295	typedef { KEYWORD_RETURN(TYPEDEF); }
[b87a5ed]	296	typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	297	__typeof { KEYWORD_RETURN(TYPEOF); } // GCC
	298	__typeof__ { KEYWORD_RETURN(TYPEOF); } // GCC
[3848e0e]	299	union { KEYWORD_RETURN(UNION); }
	300	unsigned { KEYWORD_RETURN(UNSIGNED); }
[90c3b1c]	301	__builtin_va_list { KEYWORD_RETURN(VALIST); } // GCC
[72457b6]	302	virtual { KEYWORD_RETURN(VIRTUAL); } // CFA
[3848e0e]	303	void { KEYWORD_RETURN(VOID); }
	304	volatile { KEYWORD_RETURN(VOLATILE); }
[b87a5ed]	305	__volatile { KEYWORD_RETURN(VOLATILE); } // GCC
	306	__volatile__ { KEYWORD_RETURN(VOLATILE); } // GCC
[5b2edbc]	307	waitfor { KEYWORD_RETURN(WAITFOR); }
	308	or { QKEYWORD_RETURN(WOR); } // CFA
	309	when { KEYWORD_RETURN(WHEN); }
[3848e0e]	310	while { KEYWORD_RETURN(WHILE); }
[8b47e50]	311	with { KEYWORD_RETURN(WITH); } // CFA
[3a2128f]	312	zero_t { NUMERIC_RETURN(ZERO_T); } // CFA
[51b7345]	313
[b87a5ed]	314	/* identifier */
	315	{identifier} { IDENTIFIER_RETURN(); }
	316	{attr_identifier} { ATTRIBUTE_RETURN(); }
[c6b1105]	317	"`" { BEGIN BKQUOTE; }
[b87a5ed]	318	<BKQUOTE>{identifier} { IDENTIFIER_RETURN(); }
	319	<BKQUOTE>"`" { BEGIN 0; }
[51b7345]	320
[b87a5ed]	321	/* numeric constants */
[0a2168f]	322	{binary_constant} { NUMERIC_RETURN(INTEGERconstant); }
[59db689]	323	{octal_constant} { NUMERIC_RETURN(INTEGERconstant); }
[0a2168f]	324	{decimal_constant} { NUMERIC_RETURN(INTEGERconstant); }
[59db689]	325	{hex_constant} { NUMERIC_RETURN(INTEGERconstant); }
[930f69e]	326	{floating_decimal} { NUMERIC_RETURN(FLOATING_DECIMALconstant); } // must appear before floating_constant
	327	{floating_fraction} { NUMERIC_RETURN(FLOATING_FRACTIONconstant); } // must appear before floating_constant
[3848e0e]	328	{floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
	329	{hex_floating_constant} { NUMERIC_RETURN(FLOATINGconstant); }
[51b7345]	330
[b87a5ed]	331	/* character constant, allows empty value */
[9ed4f94]	332	({cwide_prefix}[_]?)?['] { BEGIN QUOTE; rm_underscore(); strtext = new string( yytext, yyleng ); }
[c1c1112]	333	<QUOTE>[^'\\\n]* { strtext->append( yytext, yyleng ); }
[76c62b2]	334	<QUOTE>['\n]{user_suffix_opt} { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(CHARACTERconstant); }
[930f69e]	335	/* ' stop editor highlighting */
[51b7345]	336
[b87a5ed]	337	/* string constant */
[9ed4f94]	338	({swide_prefix}[_]?)?["] { BEGIN STRING; rm_underscore(); strtext = new string( yytext, yyleng ); }
[c1c1112]	339	<STRING>[^"\\\n]* { strtext->append( yytext, yyleng ); }
[76c62b2]	340	<STRING>["\n]{user_suffix_opt} { BEGIN 0; strtext->append( yytext, yyleng ); RETURN_STR(STRINGliteral); }
[930f69e]	341	/* " stop editor highlighting */
[51b7345]	342
[59db689]	343	/* common character/string constant */
[c1c1112]	344	<QUOTE,STRING>{escape_seq} { rm_underscore(); strtext->append( yytext, yyleng ); }
[cd623a4]	345	<QUOTE,STRING>"\\"{h_white}*"\n" {} // continuation (ALSO HANDLED BY CPP)
[c1c1112]	346	<QUOTE,STRING>"\\" { strtext->append( yytext, yyleng ); } // unknown escape character
[3848e0e]	347
[b87a5ed]	348	/* punctuation */
[615a096]	349	"@" { ASCIIOP_RETURN(); }
[b87a5ed]	350	"[" { ASCIIOP_RETURN(); }
	351	"]" { ASCIIOP_RETURN(); }
	352	"(" { ASCIIOP_RETURN(); }
	353	")" { ASCIIOP_RETURN(); }
	354	"{" { ASCIIOP_RETURN(); }
	355	"}" { ASCIIOP_RETURN(); }
	356	"," { ASCIIOP_RETURN(); } // also operator
	357	":" { ASCIIOP_RETURN(); }
	358	";" { ASCIIOP_RETURN(); }
	359	"." { ASCIIOP_RETURN(); } // also operator
[3848e0e]	360	"..." { NAMEDOP_RETURN(ELLIPSIS); }
	361
[b87a5ed]	362	/* alternative C99 brackets, "<:" & "<:<:" handled by preprocessor */
[3848e0e]	363	"<:" { RETURN_VAL('['); }
	364	":>" { RETURN_VAL(']'); }
	365	"<%" { RETURN_VAL('{'); }
	366	"%>" { RETURN_VAL('}'); }
[51b7345]	367
[b87a5ed]	368	/* operators */
	369	"!" { ASCIIOP_RETURN(); }
	370	"+" { ASCIIOP_RETURN(); }
	371	"-" { ASCIIOP_RETURN(); }
	372	"*" { ASCIIOP_RETURN(); }
[e5f2a67]	373	"\\" { ASCIIOP_RETURN(); } // CFA, exponentiation
[b87a5ed]	374	"/" { ASCIIOP_RETURN(); }
	375	"%" { ASCIIOP_RETURN(); }
	376	"^" { ASCIIOP_RETURN(); }
	377	"~" { ASCIIOP_RETURN(); }
	378	"&" { ASCIIOP_RETURN(); }
	379	"\|" { ASCIIOP_RETURN(); }
	380	"<" { ASCIIOP_RETURN(); }
	381	">" { ASCIIOP_RETURN(); }
	382	"=" { ASCIIOP_RETURN(); }
	383	"?" { ASCIIOP_RETURN(); }
[3848e0e]	384
	385	"++" { NAMEDOP_RETURN(ICR); }
	386	"--" { NAMEDOP_RETURN(DECR); }
	387	"==" { NAMEDOP_RETURN(EQ); }
	388	"!=" { NAMEDOP_RETURN(NE); }
	389	"<<" { NAMEDOP_RETURN(LS); }
	390	">>" { NAMEDOP_RETURN(RS); }
	391	"<=" { NAMEDOP_RETURN(LE); }
	392	">=" { NAMEDOP_RETURN(GE); }
	393	"&&" { NAMEDOP_RETURN(ANDAND); }
	394	"\|\|" { NAMEDOP_RETURN(OROR); }
	395	"->" { NAMEDOP_RETURN(ARROW); }
	396	"+=" { NAMEDOP_RETURN(PLUSassign); }
	397	"-=" { NAMEDOP_RETURN(MINUSassign); }
[e5f2a67]	398	"\\=" { NAMEDOP_RETURN(EXPassign); } // CFA, exponentiation
[3848e0e]	399	"*=" { NAMEDOP_RETURN(MULTassign); }
	400	"/=" { NAMEDOP_RETURN(DIVassign); }
	401	"%=" { NAMEDOP_RETURN(MODassign); }
	402	"&=" { NAMEDOP_RETURN(ANDassign); }
	403	"\|=" { NAMEDOP_RETURN(ORassign); }
	404	"^=" { NAMEDOP_RETURN(ERassign); }
	405	"<<=" { NAMEDOP_RETURN(LSassign); }
	406	">>=" { NAMEDOP_RETURN(RSassign); }
[51b7345]	407
[08061589]	408	"@=" { NAMEDOP_RETURN(ATassign); } // CFA
[097e2b0]	409
[b87a5ed]	410	/* CFA, operator identifier */
	411	{op_unary}"?" { IDENTIFIER_RETURN(); } // unary
[a61fea9a]	412	"?"({op_unary_pre_post}\|"()"\|"[?]"\|"{}") { IDENTIFIER_RETURN(); }
[76c62b2]	413	"^?{}" { IDENTIFIER_RETURN(); }
	414	"?`"{identifier} { IDENTIFIER_RETURN(); } // unit operator
[b87a5ed]	415	"?"{op_binary_over}"?" { IDENTIFIER_RETURN(); } // binary
[51b7345]	416	/*
[daf9671]	417	This rule handles ambiguous cases with operator identifiers, e.g., "int ??()", where the string "??" can be
	418	lexed as "?"/"?" or ""/"??". Since it is common practise to put a unary operator juxtaposed to an identifier,
	419	e.g., "*i", users will be annoyed if they cannot do this with respect to operator identifiers. Therefore, there is
	420	a lexical look-ahead for the second case, with backtracking to return the leading unary operator and then
	421	reparsing the trailing operator identifier. Otherwise a space is needed between the unary operator and operator
	422	identifier to disambiguate this common case.
	423
	424	A similar issue occurs with the dereference, *?(...), and routine-call, ?()(...) identifiers. The ambiguity
	425	occurs when the deference operator has no parameters, ?() and ?()(...), requiring arbitrary whitespace
	426	look-ahead for the routine-call parameter-list to disambiguate. However, the dereference operator must have a
	427	parameter/argument to dereference ?(...). Hence, always interpreting the string ?() as * ?() does not preclude
	428	any meaningful program.
	429
	430	The remaining cases are with the increment/decrement operators and conditional expression:
	431
	432	i++? ...(...);
	433	i?++ ...(...);
	434
	435	requiring arbitrary whitespace look-ahead for the operator parameter-list, even though that interpretation is an
	436	incorrect expression (juxtaposed identifiers). Therefore, it is necessary to disambiguate these cases with a
	437	space:
	438
	439	i++ ? i : 0;
	440	i? ++i : 0;
[51b7345]	441	*/
[daf9671]	442	{op_unary}"?"({op_unary_pre_post}\|"()"\|"[?]"\|{op_binary_over}"?") {
[b87a5ed]	443	// 1 or 2 character unary operator ?
	444	int i = yytext[1] == '?' ? 1 : 2;
	445	yyless( i ); // put back characters up to first '?'
	446	if ( i > 1 ) {
	447	NAMEDOP_RETURN( yytext[0] == '+' ? ICR : DECR );
	448	} else {
	449	ASCIIOP_RETURN();
	450	} // if
	451	}
	452
[9ed4f94]	453	/* unknown character */
	454	. { yyerror( "unknown character" ); }
[51b7345]	455
	456	%%
[9ed4f94]	457	// ----end of lexer----
	458
	459	void yyerror( const char * errmsg ) {
	460	cout << (yyfilename ? yyfilename : "unknown file") << ':' << yylineno << ':' << column - yyleng + 1
[a16764a6]	461	<< ": " << ErrorHelpers::error_str() << errmsg << " at token \"" << (yytext[0] == '\0' ? "EOF" : yytext) << '"' << endl;
[9ed4f94]	462	}
[51b7345]	463
[b87a5ed]	464	// Local Variables: //
	465	// mode: c++ //
[de62360d]	466	// tab-width: 4 //
[b87a5ed]	467	// compile-command: "make install" //
	468	// End: //

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format